qtcreator.pri

   1 defineReplace(cleanPath) {
   2     win32:1 ~= s|\\\\|/|g
   3     contains(1, ^/.*):pfx = /
   4     else:pfx =
   5     segs = $$split(1, /)
   6     out =
   7     for(seg, segs) {
   8         equals(seg, ..):out = $$member(out, 0, -2)
   9         else:!equals(seg, .):out += $$seg
  10     }
  11     return($$join(out, /, $$pfx))
  12 }
  13
  14 defineReplace(targetPath) {
  15     return($$replace(1, /, $$QMAKE_DIR_SEP))
  16 }
  17
  18 # For use in custom compilers which just copy files
  19 win32:i_flag = i
  20 defineReplace(stripSrcDir) {
  21     win32 {
  22         !contains(1, ^.:.*):1 = $$OUT_PWD/$$1
  23     } else {
  24         !contains(1, ^/.*):1 = $$OUT_PWD/$$1
  25     }
  26     out = $$cleanPath($$1)
  27     out ~= s|^$$re_escape($$PWD/)||$$i_flag
  28     return($$out)
  29 }
  30
  31 isEmpty(TEST):CONFIG(debug, debug|release) {
  32     !debug_and_release|build_pass {
  33         TEST = 1
  34     }
  35 }
  36
  37 isEmpty(IDE_LIBRARY_BASENAME) {
  38     IDE_LIBRARY_BASENAME = lib
  39 }
  40
  41 DEFINES += IDE_LIBRARY_BASENAME=\\\"$$IDE_LIBRARY_BASENAME\\\"
  42
  43 equals(TEST, 1) {
  44     QT +=testlib
  45     DEFINES += WITH_TESTS
  46 }
  47
  48 IDE_SOURCE_TREE = $$PWD
  49 isEmpty(IDE_BUILD_TREE) {
  50     sub_dir = $$_PRO_FILE_PWD_
  51     sub_dir ~= s,^$$re_escape($$PWD),,
  52     IDE_BUILD_TREE = $$cleanPath($$OUT_PWD)
  53     IDE_BUILD_TREE ~= s,$$re_escape($$sub_dir)$,,
  54 }
  55 IDE_APP_PATH = $$IDE_BUILD_TREE/bin
  56 macx {
  57     IDE_APP_TARGET   = "Qt Creator"
  58     IDE_LIBRARY_PATH = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/PlugIns
  59     IDE_PLUGIN_PATH  = $$IDE_LIBRARY_PATH
  60     IDE_LIBEXEC_PATH = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/Resources
  61     IDE_DATA_PATH    = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/Resources
  62     IDE_DOC_PATH     = $$IDE_DATA_PATH/doc
  63     IDE_BIN_PATH     = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/MacOS
  64     contains(QT_CONFIG, ppc):CONFIG += ppc x86
  65     copydata = 1
  66 } else {
  67     win32 {
  68         contains(TEMPLATE, vc.*)|contains(TEMPLATE_PREFIX, vc):vcproj = 1
  69         IDE_APP_TARGET   = qtcreator
  70     } else {
  71         IDE_APP_TARGET   = qtcreator
  72     }
  73     IDE_LIBRARY_PATH = $$IDE_BUILD_TREE/$$IDE_LIBRARY_BASENAME/qtcreator
  74     IDE_PLUGIN_PATH  = $$IDE_LIBRARY_PATH/plugins
  75     IDE_LIBEXEC_PATH = $$IDE_APP_PATH # FIXME
  76     IDE_DATA_PATH    = $$IDE_BUILD_TREE/share/qtcreator
  77     IDE_DOC_PATH     = $$IDE_BUILD_TREE/share/doc/qtcreator
  78     IDE_BIN_PATH     = $$IDE_APP_PATH
  79     !isEqual(IDE_SOURCE_TREE, $$IDE_BUILD_TREE):copydata = 1
  80 }
  81
  82 INCLUDEPATH += \
  83     $$IDE_SOURCE_TREE/src/libs \
  84     $$IDE_SOURCE_TREE/tools
  85
  86 DEPENDPATH += \
  87     $$IDE_SOURCE_TREE/src/libs \
  88     $$IDE_SOURCE_TREE/tools
  89
  90 LIBS += -L$$IDE_LIBRARY_PATH
  91
  92 #DEFINES += QT_NO_CAST_FROM_ASCII
  93 DEFINES += QT_NO_CAST_TO_ASCII
  94 !macx:DEFINES += QT_USE_FAST_OPERATOR_PLUS QT_USE_FAST_CONCATENATION
  95
  96 unix {
  97     CONFIG(debug, debug|release):OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
  98     CONFIG(release, debug|release):OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
  99
 100     CONFIG(debug, debug|release):MOC_DIR = $${OUT_PWD}/.moc/debug-shared
 101     CONFIG(release, debug|release):MOC_DIR = $${OUT_PWD}/.moc/release-shared
 102
 103     RCC_DIR = $${OUT_PWD}/.rcc
 104     UI_DIR = $${OUT_PWD}/.uic
 105 }
 106
 107 linux-g++-* {
 108     # Bail out on non-selfcontained libraries. Just a security measure
 109     # to prevent checking in code that does not compile on other platforms.
 110     QMAKE_LFLAGS += -Wl,--allow-shlib-undefined -Wl,--no-undefined
 111 }
 112
 113 win32-msvc* {
 114     #Don't warn about sprintf, fopen etc being 'unsafe'
 115     DEFINES += _CRT_SECURE_NO_WARNINGS
 116 }
 117
 118 # Handle S60 support: default on Windows, conditionally built on other platforms.
 119 macx:SUPPORT_QT_S60 = $$(QTCREATOR_WITH_S60)
 120 else:SUPPORT_QT_S60=1