www/jf_www.m4

   1 m4_divert(-1)
   2
   3 m4_define(`_Copyleft',
   4 `Copyright (C) 1997 Bob Hepple
   5
   6 This program is free software; you can redistribute it
   7 and/or modify it under the terms of the GNU General Public
   8 License as published by the Free Software Foundation; either
   9 version 2 of the License, or (at your option) any later
  10 version.
  11
  12 This program is distributed in the hope that it will be
  13 useful, but WITHOUT ANY WARRANTY; without even the implied
  14 warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15 PURPOSE.  See the GNU General Public License for more
  16 details.
  17
  18 You should have received a copy of the GNU General Public
  19 License along with this program; if not, write to the Free
  20 Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  21 02139, USA.')
  22
  23 m4_changecom(`[[[[')
  24
  25 m4_dnl define(`_LOCAL',1)
  26
  27 m4_ifdef(`_SUB_ONE',
  28   `m4_define(`_CSS',`../jf.css')',
  29   `m4_define(`_CSS',`jf.css')')
  30
  31 m4_ifdef(`_SUB_ONE',
  32   `m4_define(`_IMAGEDIR',`../images')',
  33   `m4_define(`_IMAGEDIR',`images')')
  34
  35 m4_ifdef(`_SUB_ONE',
  36   `m4_define(`_HOMEPAGE',`../index.html')',
  37   `m4_define(`_HOMEPAGE',`index.html')')
  38
  39
  40
  41 m4_define(`_EDIT_WARNING',`
  42 <!--
  43   ====================================================================
  44     DO NOT EDIT THIS FILE.  EDIT M4 SOURCE FILE OR M4 INCLUDE FILE.
  45     ¤³¤Î¥Õ¥¡¥¤¥ë¤ÏÊÔ½¸¤·¤Ê¤¤¤Ç¤¯¤À¤µ¤¤. M4 ¤Î¥½¡¼¥¹ ¤Þ¤¿¤Ï include
  46     ¤µ¤ì¤Æ¤¤¤ë¥Õ¥¡¥¤¥ë¤òÊÔ½¸¤·¤Æ¤¯¤À¤µ¤¤.
  47   ====================================================================
  48  -->')
  49
  50 m4_define(`_SURF',`http://surf.ap.seikei.ac.jp/~nakano/JF')
  51 m4_define(`_EMAIL_ADDRESS',jf@listserv.linux.or.jp)
  52
  53 m4_define(`_JF_',`JF Project')
  54 m4_define(`_JF_HOME',`http://linuxjf.sourceforge.jp')
  55
  56 m4_define(`_LDP_',`The Linux Documentation Project')
  57 m4_define(`_LINK_TO_LDP_HOME',`_LINK(http://tldp.org/,`LDP $1')')
  58 m4_define(`_METALAB',`http://metalab.unc.edu')
  59
  60 m4_define(`_NUM_CATEGORY',`./bin/categ_num.pl -d ../jfindex.db -c $1')
  61
  62 m4_define(`_MAILTO',<A HREF="mailto:$1">$2</A>)
  63
  64 m4_define(`_EMAILME',_MAILTO(_EMAIL_ADDRESS,$1))
  65
  66 m4_define(`_CODEQUOTE',<BLOCKQUOTE><PRE><CODE>$1</CODE></PRE></BLOCKQUOTE>)
  67
  68 m4_define(`_RSS',`_JF_HOME/update.xml')
  69
  70 m4_dnl Logical markup:
  71
  72 m4_define(`_EM',<EM>$1</EM>)
  73 m4_define(`_STRONG',<STRONG>$1</STRONG>)
  74 m4_define(`_CITE',<CITE>$1</CITE>)
  75 m4_define(`_PRE',<BLOCKQUOTE><PRE>$1</PRE></BLOCKQUOTE>)
  76 m4_define(`_CODE',<CODE>$1</CODE>)
  77
  78 m4_dnl Physical markup:
  79
  80 m4_define(`_BOLD',<B>$1</B>)
  81 m4_define(`_ITALICS',<I>$1</I>)
  82 m4_define(`_STRIKE',<S>$1</S>)
  83 m4_define(`_SUBSCRIPT',<SUB>$1</SUB>)
  84 m4_define(`_SUPERSCRIPT',<SUP>$1</SUP>)
  85 m4_define(`_COURIER',<TT>$1</TT>)
  86 m4_define(`_UNDERLINE',<U>$1</U>)
  87 m4_define(`_SMALL',<SMALL>$1</SMALL>)
  88 m4_define(`_BIG',<BIG>$1</BIG>)
  89
  90 m4_define(`_CENTER',<CENTER>$1</CENTER>)
  91
  92 m4_define(`_LIMAGE', <IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3>)
  93
  94 m4_define(`_RIMAGE', <IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3 ALIGN="right">)
  95
  96 m4_define(`_IMAGE', <P><CENTER><IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3></CENTER><P>)
  97
  98 m4_define(`_IMAGE2',<P><CENTER>
  99 <IMG SRC="$1" ALT="[$1]" ALIGN=TOP WIDTH=$2 HEIGHT=$3>
 100 <IMG SRC="$4" ALT="[$4]" ALIGN=TOP WIDTH=$5 HEIGHT=$6>
 101 </CENTER><P>)
 102
 103 m4_define(`_FTP',<A HREF="ftp:$1">$2</A>)
 104
 105 m4_define(`_HEAD1', <H2>$1</H2>)
 106
 107 m4_define(`_HEAD2', <H3>$1</H3>)
 108
 109 m4_define(`_LINK', <A HREF="$1">$2</A>)
 110 m4_define(`_SLINK', <STRONG><A HREF="$1">$2</A></STRONG>)
 111
 112 m4_define(`_VLINK', <A HREF="$1">$1</A>)
 113
 114 m4_define(`_SELFLINK', _LINK($1,$1))
 115
 116 m4_define(`_LOCALLINK',<A HREF="#$1">$2</A>)
 117
 118 m4_define(`_LABEL',<A NAME="$1"><H2>$1</H2></A>)
 119
 120 m4_define(`_LINK_TO_LABEL', _LOCALLINK($1,$1))
 121
 122 m4_define(`_PLUG',
 123   _LINK(http://www.ssc.com/linux/,
 124     _IMAGE(_HOMEPAGE/powered.gif,196,49))<BR>
 125 `If you are wondering, Linux is a free, non-commercial
 126 operating system for computers. It happens to be a hobby of
 127 mine and might well interest other hackers. Click on the logo
 128 to learn more...')
 129
 130 m4_define(`_HEADER', `
 131 <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN"
 132   "http://www.w3.org/TR/html4/loose.dtd">
 133 <HTML LANG="ja" DIR="LTR">
 134 <HEAD>
 135  <META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=UTF-8">
 136  m4_ifdef(`_TOP_PAGE',
 137  <title>$1</title>,
 138  <title>JF: $1</title>)
 139  <META NAME="author" LANG="en" CONTENT="JF Project Members">
 140  <META NAME="copyright" CONTENT="(C) 1998-2013 JF Project.">
 141  <META NAME="description" CONTENT="JF ¤Ï¡¢Linux ¤Ë´Ø¤¹¤ë²òÀâÊ¸½ñ¡¦FAQ ¤Ê¤É¤òºîÀ®¡¦¼ý½¸¡¦ÇÛÉÛ¤¹¤ë¥×¥í¥¸¥§¥¯¥È¤Ç¤¹¡£">
 142  <META NAME="keywords" CONTENT="JF,Linux,Japanese,ÆüËÜ¸ì,Ê¸½ñ,¥É¥¥å¥á¥ó¥È,ËÝÌõ,HOWTO,FAQ">
 143  <LINK REV="made" HREF="mailto:jf@listserv.linux.or.jp">
 144  <LINK REL="stylesheet" TYPE="text/css" HREF="_CSS">
 145  <LINK REL="alternate" TYPE="application/rss+xml" TITLE="RSS 2.0" HREF="_RSS">
 146
 147  m4_ifdef(`_ADDITIONAL_STYLE',
 148  <STYLE TYPE="text/css">
 149  <!--
 150   _ADDITIONAL_STYLE
 151  -->
 152  </STYLE>)
 153
 154 </HEAD>
 155
 156 <body>
 157  m4_ifdef(`_TOP_PAGE',
 158  <h1 id="top">$1</h1>,
 159  <h1 id="top">_LINK(_HOMEPAGE,JF): $1</h1>)
 160
 161 ')
 162
 163 m4_define(`_MIRROR_LIST',`
 164   <A HREF="http://www.linux.or.jp/JF/$1">primary</A> |
 165   <A HREF="http://ktarn.www.linux.or.jp/JF/$1">ktarn</A> |
 166   <A HREF="http://osaka-sandai.www.linux.or.jp/JF/$1">osaka-sandai</A>
 167 ')
 168
 169 m4_define(`_CREDITS',`
 170  <div class="copyright">
 171   _LINK(_HOMEPAGE,JF Project ¥á¥¤¥ó¥Ú¡¼¥¸¤Ø)<BR>
 172   _JF_ Á´ÈÌ¤Ë´Ø¤ï¤ë¤´°Õ¸«¤´Í×Ë¾¤Ï jf@listserv.linux.or.jp ¤Þ¤Ç¤ª´ê¤¤¤·¤Þ¤¹.
 173  </div>
 174 ')
 175
 176 m4_define(`_BACK_TO_HOME',`')
 177
 178 m4_dnl ----------------------------------------------
 179 m4_dnl TABLE OF CONTENTS
 180
 181 m4_define(`_Start_TOC',`<UL><P>m4_divert(-1)
 182   m4_define(`_H1_num',0)
 183   m4_define(`_H2_num',0)
 184   m4_define(`_H3_num',0)
 185   m4_define(`_H4_num',0)
 186   m4_divert(1)')
 187
 188 m4_define(`_H1', `m4_divert(-1)
 189   m4_define(`_H1_num',m4_incr(_H1_num))
 190   m4_define(`_H2_num',0)
 191   m4_define(`_H3_num',0)
 192   m4_define(`_H4_num',0)
 193   m4_define(`_TOC_label',`_H1_num. $1')
 194   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 195   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 196
 197 m4_define(`_H2', `m4_divert(-1)
 198   m4_define(`_H2_num',m4_incr(_H2_num))
 199   m4_define(`_H3_num',0)
 200   m4_define(`_H4_num',0)
 201   m4_define(`_TOC_label',`_H1_num._H2_num $1')
 202   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 203   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 204
 205 m4_define(`_H3', `m4_divert(-1)
 206   m4_define(`_H3_num',m4_incr(_H3_num))
 207   m4_define(`_H4_num',0)
 208   m4_define(`_TOC_label',`_H1_num._H2_num._H3_num $1')
 209   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 210   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 211
 212 m4_define(`_H4', `m4_divert(-1)
 213   m4_define(`_H4_num',m4_incr(_H4_num))
 214   m4_define(`_TOC_label',`_H1_num._H2_num._H3_num._H4_num $1')
 215   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
 216   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
 217
 218 m4_define(`_End_TOC',`m4_divert(0)</UL><P>')
 219
 220 m4_dnl ----------------------------------------------
 221 m4_dnl TABLES
 222
 223 m4_dnl _Start_Table(Columns,TABLE parameters)
 224 m4_dnl defaults are BORDER=1 CELLPADDING="1" CELLSPACING="1"
 225 m4_dnl WIDTH="n" pixels or "n%" of screen width
 226 m4_define(`_Start_Table',`<TABLE $1>')
 227
 228 m4_define(`_Table_Hdr_Item', `<th>$1</th>m4_ifelse($#,1,,`_Table_Hdr_Item(m4_shift($@))')')
 229
 230 m4_define(`_Table_Row_Item', `<td>$1</td>m4_ifelse($#,1,,`_Table_Row_Item(m4_shift($@))')')
 231
 232 m4_define(`_Table_Hdr',`<tr>_Table_Hdr_Item($@)</tr>')
 233 m4_define(`_Table_Row',`<tr>_Table_Row_Item($@)</tr>')
 234
 235 m4_define(`_End_Table',</TABLE>)
 236
 237 m4_define(`_TABLE_ROW_CLASS',`m4_ifelse(_TABLE_ROW_FLAG, `CLASS="odd"',
 238         `m4_define(`_TABLE_ROW_FLAG', `CLASS="even"')',
 239         `m4_define(`_TABLE_ROW_FLAG', `CLASS="odd"')')_TABLE_ROW_FLAG')
 240
 241 m4_divert