libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:6:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   GCC_NO_EXECUTABLES
  45 else
  46   GLIBCXX_IS_NATIVE=true
  47 fi
  48
  49 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  50 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  51 #  1.x:  minimum required version
  52 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  53 #              of other PACKAGE_* variables will, however, and there's nothing
  54 #              we can do about that; they come from AC_INIT).
  55 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  56 #            file in the top srcdir, etc, etc), so stop complaining.
  57 #  no-dependencies:  turns off auto dependency generation (just for now)
  58 #  -Wall:  turns on all automake warnings...
  59 #  -Wno-portability:  ...except this one, since GNU make is now required.
  60 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  61 AH_TEMPLATE(PACKAGE, [Name of package])
  62 AH_TEMPLATE(VERSION, [Version number of package])
  63
  64 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  65 # up critical shell variables.
  66 GLIBCXX_CONFIGURE
  67
  68 AC_LIBTOOL_DLOPEN
  69 AM_PROG_LIBTOOL
  70 AC_SUBST(enable_shared)
  71 AC_SUBST(enable_static)
  72
  73 # Possibly disable most of the library.
  74 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  75 ## than just ignoring the results.  Faster /and/ more correct, win win.
  76 GLIBCXX_ENABLE_HOSTED
  77
  78 # Check for compiler support that doesn't require linking.
  79 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  80 GLIBCXX_ENABLE_PCH($is_hosted)
  81
  82 # Enable all the variable C++ runtime options.
  83 GLIBCXX_ENABLE_CSTDIO
  84 GLIBCXX_ENABLE_CLOCALE
  85 GLIBCXX_ENABLE_ALLOCATOR
  86 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
  87 GLIBCXX_ENABLE_C99([yes])
  88 GLIBCXX_ENABLE_LONG_LONG([yes])
  89 GLIBCXX_ENABLE_WCHAR_T([yes])
  90 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
  91 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
  92 GLIBCXX_ENABLE_DEBUG([no])
  93 GLIBCXX_ENABLE_CXX_FLAGS
  94 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
  95
  96 # No surprises, no surprises...
  97 GLIBCXX_ENABLE_THREADS
  98 if test $atomicity_dir = cpu/generic ; then
  99   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 100   if test $target_thread_file = single; then
 101     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 102     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 103   else
 104     AC_MSG_WARN([They will be faked using a mutex.])
 105     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 106   fi
 107 fi
 108
 109
 110 if $GLIBCXX_IS_NATIVE; then
 111
 112   # We can do more elaborate tests that assume a working linker.
 113   CANADIAN=no
 114
 115   # Check for available headers.
 116   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 117   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 118   sys/types.h sys/ipc.h sys/sem.h])
 119
 120   GLIBCXX_CHECK_COMPILER_FEATURES
 121   GLIBCXX_CHECK_LINKER_FEATURES
 122   GLIBCXX_CHECK_MATH_SUPPORT
 123   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 124   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 125   GLIBCXX_CHECK_ICONV_SUPPORT
 126   GLIBCXX_CHECK_STDLIB_SUPPORT
 127
 128   # For showmanyc_helper().
 129   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 130   GLIBCXX_CHECK_POLL
 131   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 132
 133   # For xsputn_2().
 134   AC_CHECK_HEADERS(sys/uio.h)
 135   GLIBCXX_CHECK_WRITEV
 136
 137   # For the __streamoff_base_type typedef.
 138   GLIBCXX_CHECK_INT64_T
 139
 140   # For LFS support.
 141   GLIBCXX_CHECK_LFS
 142
 143   AC_LC_MESSAGES
 144
 145   AC_TRY_COMPILE(
 146     [#include <setjmp.h>],
 147     [sigjmp_buf env;
 148      while (! sigsetjmp (env, 1))
 149        siglongjmp (env, 1);
 150     ],
 151     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 152
 153   AC_FUNC_MMAP
 154
 155 else
 156
 157   # This lets us hard-code the functionality we know we'll have in the cross
 158   # target environment.  "Let" is a sugar-coated word placed on an especially
 159   # dull and tedious hack, actually.
 160   #
 161   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 162   # that involve linking, can't be used:
 163   #    "cannot open sim-crt0.o"
 164   #    "cannot open crt0.o"
 165   # etc.  All this is because there currently exists no unified, consistent
 166   # way for top level CC information to be passed down to target directories:
 167   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 168   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 169   # crosses can be removed.
 170
 171   # If Canadian cross, then don't pick up tools from the build directory.
 172   # Used only in GLIBCXX_EXPORT_INCLUDES.
 173   if test -n "$with_cross_host" &&
 174      test x"$build_alias" != x"$with_cross_host" &&
 175      test x"$build" != x"$target";
 176   then
 177     CANADIAN=yes
 178   else
 179     CANADIAN=no
 180   fi
 181
 182   # Construct crosses by hand, eliminating bits that need ld...
 183   # GLIBCXX_CHECK_COMPILER_FEATURES
 184   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 185   # GLIBCXX_CHECK_MATH_SUPPORT
 186
 187   # First, test for "known" system libraries.  We may be using newlib even
 188   # on a hosted environment.
 189   if test "x${with_newlib}" = "xyes"; then
 190     os_include_dir="os/newlib"
 191     AC_DEFINE(HAVE_HYPOT)
 192
 193     # GLIBCXX_CHECK_STDLIB_SUPPORT
 194     AC_DEFINE(HAVE_STRTOF)
 195     # AC_FUNC_MMAP
 196     AC_DEFINE(HAVE_MMAP)
 197
 198     AC_DEFINE(HAVE_ACOSF)
 199     AC_DEFINE(HAVE_ASINF)
 200     AC_DEFINE(HAVE_ATAN2F)
 201     AC_DEFINE(HAVE_ATANF)
 202     AC_DEFINE(HAVE_CEILF)
 203     AC_DEFINE(HAVE_COPYSIGN)
 204     AC_DEFINE(HAVE_COPYSIGNF)
 205     AC_DEFINE(HAVE_COSF)
 206     AC_DEFINE(HAVE_COSHF)
 207     AC_DEFINE(HAVE_EXPF)
 208     AC_DEFINE(HAVE_FABSF)
 209     AC_DEFINE(HAVE_FLOORF)
 210     AC_DEFINE(HAVE_FMODF)
 211     AC_DEFINE(HAVE_FREXPF)
 212     AC_DEFINE(HAVE_LDEXPF)
 213     AC_DEFINE(HAVE_LOG10F)
 214     AC_DEFINE(HAVE_LOGF)
 215     AC_DEFINE(HAVE_MODFF)
 216     AC_DEFINE(HAVE_POWF)
 217     AC_DEFINE(HAVE_SINF)
 218     AC_DEFINE(HAVE_SINHF)
 219     AC_DEFINE(HAVE_SQRTF)
 220     AC_DEFINE(HAVE_TANF)
 221     AC_DEFINE(HAVE_TANHF)
 222
 223     AC_DEFINE(HAVE_S_ISREG)
 224     AC_DEFINE(HAVE_S_IFREG)
 225   else
 226     GLIBCXX_CROSSCONFIG
 227   fi
 228
 229   # At some point, we should differentiate between architectures
 230   # like x86, which have long double versions, and alpha/powerpc/etc.,
 231   # which don't. For the time being, punt.
 232   if test x"long_double_math_on_this_cpu" = x"yes"; then
 233     AC_DEFINE(HAVE_ACOSL)
 234     AC_DEFINE(HAVE_ASINL)
 235     AC_DEFINE(HAVE_ATAN2L)
 236     AC_DEFINE(HAVE_ATANL)
 237     AC_DEFINE(HAVE_CEILL)
 238     AC_DEFINE(HAVE_COPYSIGNL)
 239     AC_DEFINE(HAVE_COSL)
 240     AC_DEFINE(HAVE_COSHL)
 241     AC_DEFINE(HAVE_EXPL)
 242     AC_DEFINE(HAVE_FABSL)
 243     AC_DEFINE(HAVE_FLOORL)
 244     AC_DEFINE(HAVE_FMODL)
 245     AC_DEFINE(HAVE_FREXPL)
 246     AC_DEFINE(HAVE_LDEXPL)
 247     AC_DEFINE(HAVE_LOG10L)
 248     AC_DEFINE(HAVE_LOGL)
 249     AC_DEFINE(HAVE_MODFL)
 250     AC_DEFINE(HAVE_POWL)
 251     AC_DEFINE(HAVE_SINCOSL)
 252     AC_DEFINE(HAVE_SINL)
 253     AC_DEFINE(HAVE_SINHL)
 254     AC_DEFINE(HAVE_SQRTL)
 255     AC_DEFINE(HAVE_TANL)
 256     AC_DEFINE(HAVE_TANHL)
 257   fi
 258
 259 fi
 260
 261 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 262 GLIBCXX_ENABLE_SYMVERS([yes])
 263
 264 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 265 GLIBCXX_CONFIGURE_TESTSUITE
 266
 267 # Propagate the target-specific source directories through the build chain.
 268 ATOMICITY_SRCDIR=config/${atomicity_dir}
 269 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 270 OS_INC_SRCDIR=config/${os_include_dir}
 271 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 272 AC_SUBST(ATOMICITY_SRCDIR)
 273 AC_SUBST(ATOMIC_WORD_SRCDIR)
 274 AC_SUBST(ABI_TWEAKS_SRCDIR)
 275 AC_SUBST(OS_INC_SRCDIR)
 276
 277 # Determine cross-compile flags and AM_CONDITIONALs.
 278 #AC_SUBST(GLIBCXX_IS_NATIVE)
 279 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 280 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 281 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 282 GLIBCXX_EVALUATE_CONDITIONALS
 283
 284 AC_CACHE_SAVE
 285
 286 if test ${multilib} = yes; then
 287   multilib_arg="--enable-multilib"
 288 else
 289   multilib_arg=
 290 fi
 291
 292 # Export all the install information.
 293 GLIBCXX_EXPORT_INSTALL_INFO
 294
 295 # Export all the include and flag information to Makefiles.
 296 GLIBCXX_EXPORT_INCLUDES
 297 GLIBCXX_EXPORT_FLAGS
 298
 299 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 300    grep "enable shared" > /dev/null;
 301 then
 302   LIBSUPCXX_PICFLAGS=-prefer-pic
 303 else
 304   LIBSUPCXX_PICFLAGS=
 305 fi
 306 AC_SUBST(LIBSUPCXX_PICFLAGS)
 307
 308 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 309 dnl which can all be called multiple times as needed, plus one (different)
 310 dnl AC_OUTPUT macro.  This one lists the files to be created:
 311 AC_CONFIG_FILES( \
 312   Makefile \
 313   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 314   )
 315 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 316
 317 dnl These commands are run at the end of config.status:
 318 AC_CONFIG_COMMANDS([default],
 319 [if test -n "$CONFIG_FILES"; then
 320    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 321    # that multilib installs will end up installed in the correct place.
 322    # The testsuite needs it for multilib-aware ABI baseline files.
 323    # To work around this not being passed down from config-ml.in ->
 324    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 325    # append it here.  Only modify Makefiles that have just been created.
 326    #
 327    # Also, get rid of this simulated-VPATH thing that automake does.
 328    cat > vpsed << \_EOF
 329 s!`test -f '$<' || echo '$(srcdir)/'`!!
 330 _EOF
 331    for i in $SUBDIRS; do
 332     case $CONFIG_FILES in
 333      *${i}/Makefile*)
 334        #echo "Adding MULTISUBDIR to $i/Makefile"
 335        sed -f vpsed $i/Makefile > tmp
 336        grep '^MULTISUBDIR =' Makefile >> tmp
 337        mv tmp $i/Makefile
 338        ;;
 339     esac
 340    done
 341    rm vpsed
 342  fi
 343  (cd include && ${MAKE-make})
 344 ],
 345 [
 346 # Variables needed in config.status (file generation) which aren't already
 347 # passed by autoconf.
 348 SUBDIRS="$SUBDIRS"
 349 ])
 350
 351 dnl And this actually makes things happen:
 352 AC_OUTPUT