libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4-p5
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999, 2001 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize configure bits.
  15 dnl
  16 dnl GLIBCPP_TOPREL_CONFIGURE
  17 AC_DEFUN(GLIBCPP_TOPREL_CONFIGURE, [
  18   dnl Default to --enable-multilib (this is also passed by default
  19   dnl from the ubercommon-top-level configure)
  20   AC_ARG_ENABLE(multilib,
  21   [  --enable-multilib       build hella library versions (default)],
  22   [case "${enableval}" in
  23     yes) multilib=yes ;;
  24     no)  multilib=no ;;
  25     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  26    esac], [multilib=yes])dnl
  27
  28   # When building with srcdir == objdir, links to the source files will
  29   # be created in directories within the target_subdir.  We have to
  30   # adjust toplevel_srcdir accordingly, so that configure finds
  31   # install-sh and other auxiliary files that live in the top-level
  32   # source directory.
  33   if test "${srcdir}" = "."; then
  34     if test -z "${with_target_subdir}"; then
  35       toprel=".."
  36     else
  37       if test "${with_target_subdir}" != "."; then
  38         toprel="${with_multisrctop}../.."
  39       else
  40         toprel="${with_multisrctop}.."
  41       fi
  42     fi
  43   else
  44     toprel=".."
  45   fi
  46   AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  47   toplevel_srcdir=\${top_srcdir}/$toprel
  48   AC_SUBST(toplevel_srcdir)
  49 ])
  50
  51 dnl
  52 dnl Initialize configure bits.
  53 dnl
  54 dnl GLIBCPP_CONFIGURE
  55 AC_DEFUN(GLIBCPP_CONFIGURE, [
  56
  57 #possibly test for the presence of the compiler sources here?
  58
  59   # Export build and source directories.
  60   # These need to be absolute paths, yet at the same time need to
  61   # canonicalize only relative paths, because then amd will not unmount
  62   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  63   glibcpp_builddir=`${PWDCMD-pwd}`
  64   case $srcdir in
  65   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  66   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  67   esac
  68   AC_SUBST(glibcpp_builddir)
  69   AC_SUBST(glibcpp_srcdir)
  70
  71   dnl This is here just to satisfy automake.
  72   ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  73
  74   AC_PROG_AWK
  75   # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.5x, can also
  76   # be 'cp -p' if linking isn't available.  Uncomment the next line to
  77   # force a particular method.
  78   #ac_cv_prog_LN_S='cp -p'
  79   AC_PROG_LN_S
  80
  81   # We use these options to decide which functions to include.
  82   AC_ARG_WITH(target-subdir,
  83   [  --with-target-subdir=SUBDIR
  84                           configuring in a subdirectory])
  85   AC_ARG_WITH(cross-host,
  86   [  --with-cross-host=HOST  configuring with a cross compiler])
  87
  88   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  89   AC_SUBST(glibcpp_basedir)
  90
  91   # Never versions of autoconf add an underscore to these functions.
  92   # Prevent future problems ...
  93   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  94   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  95   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  96   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  97
  98   # AC_PROG_CC
  99   # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
 100   # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
 101   # are probably using a cross compiler, which will not be able to fully
 102   # link an executable.  This is addressed in later versions of autoconf.
 103
 104   AC_DEFUN(LIB_AC_PROG_CC,
 105   [AC_BEFORE([$0], [AC_PROG_CPP])dnl
 106   dnl Fool anybody using AC_PROG_CC.
 107   AC_PROVIDE([AC_PROG_CC])
 108   AC_CHECK_PROG(CC, gcc, gcc)
 109   if test -z "$CC"; then
 110     AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
 111     test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
 112   fi
 113
 114   AC_PROG_CC_GNU
 115
 116   if test $ac_cv_prog_gcc = yes; then
 117     GCC=yes
 118   dnl Check whether -g works, even if CFLAGS is set, in case the package
 119   dnl plays around with CFLAGS (such as to build both debugging and
 120   dnl normal versions of a library), tasteless as that idea is.
 121     ac_test_CFLAGS="${CFLAGS+set}"
 122     ac_save_CFLAGS="$CFLAGS"
 123     CFLAGS=
 124     AC_PROG_CC_G
 125     if test "$ac_test_CFLAGS" = set; then
 126       CFLAGS="$ac_save_CFLAGS"
 127     elif test $ac_cv_prog_cc_g = yes; then
 128       CFLAGS="-g -O2"
 129     else
 130       CFLAGS="-O2"
 131     fi
 132   else
 133     GCC=
 134     test "${CFLAGS+set}" = set || CFLAGS="-g"
 135   fi
 136   ])
 137
 138   LIB_AC_PROG_CC
 139
 140   # Likewise for AC_PROG_CXX.  We can't just call it directly because g++
 141   # will try to link in libstdc++.
 142   AC_DEFUN(LIB_AC_PROG_CXX,
 143   [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 144   dnl Fool anybody using AC_PROG_CXX.
 145   AC_PROVIDE([AC_PROG_CXX])
 146   # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 147   # flags that come in CXX while configuring libstdc++.  They're different
 148   # from those used for all other target libraries.  If CXX is set in
 149   # the environment, respect that here.
 150   glibcpp_CXX=$CXX
 151   AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 152   AC_SUBST(glibcpp_CXX)
 153   CXX=$glibcpp_CXX
 154   test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 155
 156   AC_PROG_CXX_GNU
 157
 158   if test $ac_cv_prog_gxx = yes; then
 159     GXX=yes
 160     dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 161     dnl plays around with CXXFLAGS (such as to build both debugging and
 162     dnl normal versions of a library), tasteless as that idea is.
 163     ac_test_CXXFLAGS="${CXXFLAGS+set}"
 164     ac_save_CXXFLAGS="$CXXFLAGS"
 165     CXXFLAGS=
 166     AC_PROG_CXX_G
 167     if test "$ac_test_CXXFLAGS" = set; then
 168       CXXFLAGS="$ac_save_CXXFLAGS"
 169     elif test $ac_cv_prog_cxx_g = yes; then
 170       CXXFLAGS="-g -O2"
 171     else
 172       CXXFLAGS="-O2"
 173     fi
 174   else
 175     GXX=
 176     test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 177   fi
 178   ])
 179
 180   LIB_AC_PROG_CXX
 181
 182   # For some reason, gettext needs this.
 183   AC_ISC_POSIX
 184
 185   AC_CHECK_TOOL(AS, as)
 186   AC_CHECK_TOOL(AR, ar)
 187   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 188   AC_PROG_INSTALL
 189
 190   AM_MAINTAINER_MODE
 191
 192   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 193   # at least currently, we never actually build a program, so we never
 194   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 195   # fails, because we are probably configuring with a cross compiler
 196   # which can't create executables.  So we include AC_EXEEXT to keep
 197   # automake happy, but we don't execute it, since we don't care about
 198   # the result.
 199   if false; then
 200     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 201     # to nothing, so nothing would remain between `then' and `fi' if it
 202     # were not for the `:' below.
 203     :
 204     AC_EXEEXT
 205   fi
 206
 207   case [$]{glibcpp_basedir} in
 208     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 209     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 210   esac
 211
 212   # Find platform-specific directories containing configuration info.  In
 213   # addition to possibly modifying the same flags, it also sets up symlinks.
 214   GLIBCPP_CHECK_TARGET
 215
 216 ])
 217
 218
 219 dnl
 220 dnl Check to see if g++ can compile this library, and if so, if any version-
 221 dnl specific precautions need to be taken.
 222 dnl
 223 dnl GLIBCPP_CHECK_COMPILER_VERSION
 224 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 225 if test ! -f stamp-sanity-compiler; then
 226   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 227   AC_LANG_SAVE
 228   AC_LANG_CPLUSPLUS
 229   AC_TRY_COMPILE(, [
 230   #if __GNUC__ < 3
 231     not_ok
 232   #endif
 233   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 234   AC_LANG_RESTORE
 235   AC_MSG_RESULT($gpp_satisfactory)
 236   touch stamp-sanity-compiler
 237 fi
 238 ])
 239
 240
 241 dnl
 242 dnl Tests for newer compiler features, or features that are present in newer
 243 dnl compiler versions but not older compiler versions still in use, should
 244 dnl be placed here.
 245 dnl
 246 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 247 dnl new inlining code or the new system_header pragma will die on -Werror.
 248 dnl Leave it out by default and use maint-mode to use it.
 249 dnl
 250 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 251 dnl compiler supports it and the user has not requested debug mode.
 252 dnl
 253 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 254 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 255   # All these tests are for C++; save the language and the compiler flags.
 256   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 257   # found in GLIBCPP_CONFIGURE.
 258   AC_LANG_SAVE
 259   AC_LANG_CPLUSPLUS
 260   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 261   ac_save_CXXFLAGS="$CXXFLAGS"
 262
 263   # Check for maintainer-mode bits.
 264   if test x"$USE_MAINTAINER_MODE" = xno; then
 265     WERROR=''
 266   else
 267     WERROR='-Werror'
 268   fi
 269
 270   # Check for -ffunction-sections -fdata-sections
 271   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 272   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 273   AC_TRY_COMPILE(, [int foo;
 274   ], [ac_fdsections=yes], [ac_fdsections=no])
 275   if test "$ac_test_CXXFLAGS" = set; then
 276     CXXFLAGS="$ac_save_CXXFLAGS"
 277   else
 278     # this is the suspicious part
 279     CXXFLAGS=''
 280   fi
 281   if test x"$ac_fdsections" = x"yes" &&
 282      test x"$enable_debug" = x"no"; then
 283     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 284   fi
 285   AC_MSG_RESULT($ac_fdsections)
 286
 287   AC_LANG_RESTORE
 288   AC_SUBST(WERROR)
 289   AC_SUBST(SECTION_FLAGS)
 290 ])
 291
 292
 293 dnl
 294 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 295 dnl the native linker is in use, all variables will be defined to something
 296 dnl safe (like an empty string).
 297 dnl
 298 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 299 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 300 dnl Define LD, with_gnu_ld, and (possibly) glibcpp_gnu_ld_version as
 301 dnl side-effects of testing.
 302 dnl
 303 dnl GLIBCPP_CHECK_LINKER_FEATURES
 304 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 305   # If we're not using GNU ld, then there's no point in even trying these
 306   # tests.  Check for that first.  We should have already tested for gld
 307   # by now (in libtool), but require it now just to be safe...
 308   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 309   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 310   AC_REQUIRE([AC_PROG_LD])
 311
 312   # The name set by libtool depends on the version of libtool.  Shame on us
 313   # for depending on an impl detail, but c'est la vie.  Older versions used
 314   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 315   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 316   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 317   # set (hence we're using an older libtool), then set it.
 318   if test x${with_gnu_ld+set} != xset; then
 319     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 320       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 321       with_gnu_ld=no
 322     else
 323       with_gnu_ld=$ac_cv_prog_gnu_ld
 324     fi
 325   fi
 326
 327   # Start by getting the version number.  I think the libtool test already
 328   # does some of this, but throws away the result.
 329   changequote(,)
 330   ldver=`$LD --version 2>/dev/null | head -1 | \
 331          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 332   changequote([,])
 333   glibcpp_gnu_ld_version=`echo $ldver | \
 334          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 335
 336   # Set --gc-sections.
 337   if test "$with_gnu_ld" = "notbroken"; then
 338     # GNU ld it is!  Joy and bunny rabbits!
 339
 340     # All these tests are for C++; save the language and the compiler flags.
 341     # Need to do this so that g++ won't try to link in libstdc++
 342     ac_test_CFLAGS="${CFLAGS+set}"
 343     ac_save_CFLAGS="$CFLAGS"
 344     CFLAGS='-x c++  -Wl,--gc-sections'
 345
 346     # Check for -Wl,--gc-sections
 347     # XXX This test is broken at the moment, as symbols required for
 348     # linking are now in libsupc++ (not built yet.....). In addition,
 349     # this test has cored on solaris in the past. In addition,
 350     # --gc-sections doesn't really work at the moment (keeps on discarding
 351     # used sections, first .eh_frame and now some of the glibc sections for
 352     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 353     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 354     AC_TRY_RUN([
 355      int main(void)
 356      {
 357        try { throw 1; }
 358        catch (...) { };
 359        return 0;
 360      }
 361     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 362     if test "$ac_test_CFLAGS" = set; then
 363       CFLAGS="$ac_save_CFLAGS"
 364     else
 365       # this is the suspicious part
 366       CFLAGS=''
 367     fi
 368     if test "$ac_sectionLDflags" = "yes"; then
 369       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 370     fi
 371     AC_MSG_RESULT($ac_sectionLDflags)
 372   fi
 373
 374   # Set linker optimization flags.
 375   if test x"$with_gnu_ld" = x"yes" && test x"$enable_debug" = x"no"; then
 376     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 377   fi
 378
 379   AC_SUBST(SECTION_LDFLAGS)
 380   AC_SUBST(OPT_LDFLAGS)
 381 ])
 382
 383
 384 dnl
 385 dnl Check to see if the (math function) argument passed is
 386 dnl declared when using the c++ compiler
 387 dnl ASSUMES argument is a math function with ONE parameter
 388 dnl
 389 dnl GLIBCPP_CHECK_MATH_DECL_1
 390 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 391   AC_MSG_CHECKING([for $1 declaration])
 392   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 393     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 394       AC_LANG_SAVE
 395       AC_LANG_CPLUSPLUS
 396       AC_TRY_COMPILE([#include <math.h>
 397                       #ifdef HAVE_IEEEFP_H
 398                       #include <ieeefp.h>
 399                       #endif
 400                      ],
 401                      [ $1(0);],
 402                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 403       AC_LANG_RESTORE
 404     ])
 405   fi
 406   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 407 ])
 408
 409 dnl
 410 dnl Check to see if the (math function) argument passed is
 411 dnl 1) declared when using the c++ compiler
 412 dnl 2) has "C" linkage
 413 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 414 dnl
 415 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 416 dnl
 417 dnl argument 1 is name of function to check
 418 dnl
 419 dnl ASSUMES argument is a math function with ONE parameter
 420 dnl
 421 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 422 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 423   GLIBCPP_CHECK_MATH_DECL_1($1)
 424   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 425     AC_CHECK_FUNCS($1)
 426   else
 427     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 428     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 429       AC_CHECK_FUNCS(_$1)
 430     fi
 431   fi
 432 ])
 433
 434
 435 dnl
 436 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 437 dnl of functions at once.  It's an all-or-nothing check -- either
 438 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 439 dnl Doing it this way saves significant configure time.
 440 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 441   AC_MSG_CHECKING([for $1 functions])
 442   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 443     AC_LANG_SAVE
 444     AC_LANG_CPLUSPLUS
 445     AC_TRY_COMPILE([#include <math.h>],
 446                    [ `for x in $3; do echo "$x (0);"; done` ],
 447                    [glibcpp_cv_func_$2_use=yes],
 448                    [glibcpp_cv_func_$2_use=no])
 449     AC_LANG_RESTORE])
 450   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 451   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 452     AC_CHECK_FUNCS($3)
 453   fi
 454 ])
 455
 456 dnl
 457 dnl Check to see if the (math function) argument passed is
 458 dnl declared when using the c++ compiler
 459 dnl ASSUMES argument is a math function with TWO parameters
 460 dnl
 461 dnl GLIBCPP_CHECK_MATH_DECL_2
 462 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 463   AC_MSG_CHECKING([for $1 declaration])
 464   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 465     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 466       AC_LANG_SAVE
 467       AC_LANG_CPLUSPLUS
 468       AC_TRY_COMPILE([#include <math.h>],
 469                      [ $1(0, 0);],
 470                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 471       AC_LANG_RESTORE
 472     ])
 473   fi
 474   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 475 ])
 476
 477 dnl
 478 dnl Check to see if the (math function) argument passed is
 479 dnl 1) declared when using the c++ compiler
 480 dnl 2) has "C" linkage
 481 dnl
 482 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 483 dnl
 484 dnl argument 1 is name of function to check
 485 dnl
 486 dnl ASSUMES argument is a math function with TWO parameters
 487 dnl
 488 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 489 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 490   GLIBCPP_CHECK_MATH_DECL_2($1)
 491   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 492     AC_CHECK_FUNCS($1)
 493   else
 494     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 495     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 496       AC_CHECK_FUNCS(_$1)
 497     fi
 498   fi
 499 ])
 500
 501
 502 dnl
 503 dnl Check to see if the (math function) argument passed is
 504 dnl declared when using the c++ compiler
 505 dnl ASSUMES argument is a math function with THREE parameters
 506 dnl
 507 dnl GLIBCPP_CHECK_MATH_DECL_3
 508 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 509   AC_MSG_CHECKING([for $1 declaration])
 510   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 511     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 512       AC_LANG_SAVE
 513       AC_LANG_CPLUSPLUS
 514       AC_TRY_COMPILE([#include <math.h>],
 515                      [ $1(0, 0, 0);],
 516                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 517       AC_LANG_RESTORE
 518     ])
 519   fi
 520   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 521 ])
 522
 523 dnl
 524 dnl Check to see if the (math function) argument passed is
 525 dnl 1) declared when using the c++ compiler
 526 dnl 2) has "C" linkage
 527 dnl
 528 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 529 dnl
 530 dnl argument 1 is name of function to check
 531 dnl
 532 dnl ASSUMES argument is a math function with THREE parameters
 533 dnl
 534 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 535 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 536   GLIBCPP_CHECK_MATH_DECL_3($1)
 537   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 538     AC_CHECK_FUNCS($1)
 539   else
 540     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 541     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 542       AC_CHECK_FUNCS(_$1)
 543     fi
 544   fi
 545 ])
 546
 547
 548 dnl
 549 dnl Check to see if the (stdlib function) argument passed is
 550 dnl 1) declared when using the c++ compiler
 551 dnl 2) has "C" linkage
 552 dnl
 553 dnl argument 1 is name of function to check
 554 dnl
 555 dnl ASSUMES argument is a math function with TWO parameters
 556 dnl
 557 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 558 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 559   AC_MSG_CHECKING([for $1 declaration])
 560   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 561     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 562       AC_LANG_SAVE
 563       AC_LANG_CPLUSPLUS
 564       AC_TRY_COMPILE([#include <stdlib.h>],
 565                      [ $1(0, 0);],
 566                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 567       AC_LANG_RESTORE
 568     ])
 569   fi
 570   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 571   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 572     AC_CHECK_FUNCS($1)
 573   fi
 574 ])
 575
 576
 577 dnl
 578 dnl Check to see if the (stdlib function) argument passed is
 579 dnl 1) declared when using the c++ compiler
 580 dnl 2) has "C" linkage
 581 dnl
 582 dnl argument 1 is name of function to check
 583 dnl
 584 dnl ASSUMES argument is a function with THREE parameters
 585 dnl
 586 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3
 587 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3, [
 588   AC_MSG_CHECKING([for $1 declaration])
 589   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 590     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 591       AC_LANG_SAVE
 592       AC_LANG_CPLUSPLUS
 593       AC_TRY_COMPILE([#include <stdlib.h>],
 594                      [ $1(0, 0, 0);],
 595                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 596       AC_LANG_RESTORE
 597     ])
 598   fi
 599   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 600   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 601     AC_CHECK_FUNCS($1)
 602   fi
 603 ])
 604
 605
 606 dnl
 607 dnl Because the builtins are picky picky picky about the arguments they take,
 608 dnl do an explict linkage tests here.
 609 dnl Check to see if the (math function) argument passed is
 610 dnl 1) declared when using the c++ compiler
 611 dnl 2) has "C" linkage
 612 dnl
 613 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 614 dnl
 615 dnl argument 1 is name of function to check
 616 dnl
 617 dnl ASSUMES argument is a math function with ONE parameter
 618 dnl
 619 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 620 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 621   AC_MSG_CHECKING([for $1 declaration])
 622   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 623     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 624       AC_LANG_SAVE
 625       AC_LANG_CPLUSPLUS
 626       AC_TRY_COMPILE([#include <math.h>],
 627                      [ $1(0);],
 628                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 629       AC_LANG_RESTORE
 630     ])
 631   fi
 632   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 633   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 634     AC_MSG_CHECKING([for $1 linkage])
 635     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 636       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 637         AC_TRY_LINK([#include <math.h>],
 638                     [ $1(0);],
 639                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 640       ])
 641     fi
 642     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 643     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 644       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 645       AC_DEFINE_UNQUOTED(${ac_tr_func})
 646     fi
 647   fi
 648 ])
 649
 650
 651 dnl
 652 dnl Check to see what builtin math functions are supported
 653 dnl
 654 dnl check for __builtin_abs
 655 dnl check for __builtin_fabsf
 656 dnl check for __builtin_fabs
 657 dnl check for __builtin_fabl
 658 dnl check for __builtin_labs
 659 dnl check for __builtin_sqrtf
 660 dnl check for __builtin_sqrtl
 661 dnl check for __builtin_sqrt
 662 dnl check for __builtin_sinf
 663 dnl check for __builtin_sin
 664 dnl check for __builtin_sinl
 665 dnl check for __builtin_cosf
 666 dnl check for __builtin_cos
 667 dnl check for __builtin_cosl
 668 dnl
 669 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 670 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 671   dnl Test for builtin math functions.
 672   dnl These are made in gcc/c-common.c
 673   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 674   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 675   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 676   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 677   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 678
 679   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 680   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 681   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 682
 683   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 684   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 685   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 686
 687   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 688   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 689   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 690
 691   dnl There is, without a doubt, a more elegant way to have these
 692   dnl names exported so that they won't be stripped out of acconfig.h by
 693   dnl autoheader. I leave this as an exercise to somebody less frustrated
 694   dnl than I.... please email the libstdc++ list if you can figure out a
 695   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 696   dnl AC_CHECK_FUNC for things to steal.)
 697   dummyvar=no
 698   if test x$dummyvar = x"yes"; then
 699     AC_DEFINE(HAVE___BUILTIN_ABS)
 700     AC_DEFINE(HAVE___BUILTIN_LABS)
 701     AC_DEFINE(HAVE___BUILTIN_COS)
 702     AC_DEFINE(HAVE___BUILTIN_COSF)
 703     AC_DEFINE(HAVE___BUILTIN_COSL)
 704     AC_DEFINE(HAVE___BUILTIN_FABS)
 705     AC_DEFINE(HAVE___BUILTIN_FABSF)
 706     AC_DEFINE(HAVE___BUILTIN_FABSL)
 707     AC_DEFINE(HAVE___BUILTIN_SIN)
 708     AC_DEFINE(HAVE___BUILTIN_SINF)
 709     AC_DEFINE(HAVE___BUILTIN_SINL)
 710     AC_DEFINE(HAVE___BUILTIN_SQRT)
 711     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 712     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 713   fi
 714 ])
 715
 716
 717 dnl
 718 dnl Check to see what the underlying c library
 719 dnl These checks need to do two things:
 720 dnl 1) make sure the name is declared when using the c++ compiler
 721 dnl 2) make sure the name has "C" linkage
 722 dnl This might seem like overkill but experience has shown that it's not...
 723 dnl
 724 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 725 dnl Define HAVE_STRTOF if "strtof" is declared and links
 726 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 727 dnl
 728 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 729 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 730   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 731   ac_save_CXXFLAGS="$CXXFLAGS"
 732   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 733
 734   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 735   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtof)
 736   AC_CHECK_FUNCS(drand48)
 737
 738   CXXFLAGS="$ac_save_CXXFLAGS"
 739 ])
 740
 741
 742 dnl
 743 dnl Check to see what the underlying c library or math library is like.
 744 dnl These checks need to do two things:
 745 dnl 1) make sure the name is declared when using the c++ compiler
 746 dnl 2) make sure the name has "C" linkage
 747 dnl This might seem like overkill but experience has shown that it's not...
 748 dnl
 749 dnl Define HAVE_CARGF etc if "cargf" is found.
 750 dnl
 751 dnl GLIBCPP_CHECK_MATH_SUPPORT
 752 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 753   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 754   ac_save_CXXFLAGS="$CXXFLAGS"
 755   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 756
 757   dnl Check libm
 758   AC_CHECK_LIB(m, sin, libm="-lm")
 759   ac_save_LIBS="$LIBS"
 760   LIBS="$LIBS $libm"
 761
 762   dnl Check to see if certain C math functions exist.
 763   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 764   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 765   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 766   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 767   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 768   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 769   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 770   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 771
 772   dnl Check to see if basic C math functions have float versions.
 773   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 774                                           float_trig,
 775                                           acosf asinf atanf \
 776                                           cosf sinf tanf \
 777                                           coshf sinhf tanhf)
 778   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 779                                           float_round,
 780                                           ceilf floorf)
 781   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 782   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 783   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 784   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 785   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 786   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 787   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 788   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 789   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 790   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 791   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 792   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 793   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 794   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 795   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 796   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 797
 798   dnl Check to see if basic C math functions have long double versions.
 799   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 800                                           long_double_trig,
 801                                           acosl asinl atanl \
 802                                           cosl sinl tanl \
 803                                           coshl sinhl tanhl)
 804   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 805                                           long_double_round,
 806                                           ceill floorl)
 807   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 808   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 809   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 810   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 811   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 812   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 813   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 814   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 815   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 816   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 817   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 818   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 819   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 820   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 821   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 822   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 823   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 824
 825   dnl Some runtimes have these functions with a preceding underscore. Please
 826   dnl keep this sync'd with the one above. And if you add any new symbol,
 827   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 828   dnl Check to see if certain C math functions exist.
 829
 830   dnl Check to see if basic C math functions have float versions.
 831   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 832                                           _float_trig,
 833                                           _acosf _asinf _atanf \
 834                                           _cosf _sinf _tanf \
 835                                           _coshf _sinhf _tanhf)
 836   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 837                                           _float_round,
 838                                           _ceilf _floorf)
 839
 840   dnl Check to see if basic C math functions have long double versions.
 841   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 842                                           _long_double_trig,
 843                                           _acosl _asinl _atanl \
 844                                           _cosl _sinl _tanl \
 845                                           _coshl _sinhl _tanhl)
 846   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 847                                           _long_double_round,
 848                                           _ceill _floorl)
 849
 850   LIBS="$ac_save_LIBS"
 851   CXXFLAGS="$ac_save_CXXFLAGS"
 852 ])
 853
 854
 855 dnl
 856 dnl Check to see if there is native support for complex
 857 dnl
 858 dnl Don't compile bits in math/* if native support exits.
 859 dnl
 860 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 861 dnl
 862 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 863 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 864   dnl Check for complex versions of math functions of platform.
 865   AC_CHECK_LIB(m, main)
 866   AC_REPLACE_MATHFUNCS(nan copysignf)
 867
 868   dnl For __signbit to signbit conversions.
 869   AC_CHECK_FUNCS([__signbit], , [LIBMATHOBJS="$LIBMATHOBJS signbit.lo"])
 870   AC_CHECK_FUNCS([__signbitf], , [LIBMATHOBJS="$LIBMATHOBJS signbitf.lo"])
 871
 872   dnl Compile the long double complex functions only if the function
 873   dnl provides the non-complex long double functions that are needed.
 874   dnl Currently this includes copysignl, which should be
 875   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 876   if test x$ac_cv_func_copysignl = x"yes"; then
 877     AC_CHECK_FUNCS([__signbitl], , [LIBMATHOBJS="$LIBMATHOBJS signbitl.lo"])
 878   fi
 879
 880   AC_SUBST(LIBMATHOBJS)
 881 ])
 882
 883
 884 dnl Check to see what architecture and operating system we are compiling
 885 dnl for.  Also, if architecture- or OS-specific flags are required for
 886 dnl compilation, pick them up here.
 887 dnl
 888 dnl GLIBCPP_CHECK_TARGET
 889 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 890     . [$]{glibcpp_basedir}/configure.target
 891     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 892     AC_MSG_RESULT(OS config directory is $os_include_dir)
 893 ])
 894
 895
 896 dnl
 897 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 898 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 899 dnl must have been previously checked.)
 900 dnl
 901 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 902 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 903 dnl
 904 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 905 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 906
 907   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 908   dnl others even if wchar_t support is not on.
 909   AC_MSG_CHECKING([for mbstate_t])
 910   AC_TRY_COMPILE([#include <wchar.h>],
 911   [mbstate_t teststate;],
 912   have_mbstate_t=yes, have_mbstate_t=no)
 913   AC_MSG_RESULT($have_mbstate_t)
 914   if test x"$have_mbstate_t" = xyes; then
 915     AC_DEFINE(HAVE_MBSTATE_T)
 916   fi
 917
 918   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 919   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 920   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 921
 922   dnl Only continue checking if the ISO C99 headers exist and support is on.
 923   if test x"$ac_has_wchar_h" = xyes &&
 924      test x"$ac_has_wctype_h" = xyes &&
 925      test x"$enable_c_mbchar" != xno; then
 926
 927     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 928     dnl numeric_limits can instantiate type_traits<wchar_t>
 929     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 930     AC_TRY_COMPILE([#include <wchar.h>],
 931     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 932     has_wchar_minmax=yes, has_wchar_minmax=no)
 933     AC_MSG_RESULT($has_wchar_minmax)
 934
 935     dnl Test wchar.h for WEOF, which is what we use to determine whether
 936     dnl to specialize for char_traits<wchar_t> or not.
 937     AC_MSG_CHECKING([for WEOF])
 938     AC_TRY_COMPILE([
 939       #include <wchar.h>
 940       #include <stddef.h>],
 941     [wint_t i = WEOF;],
 942     has_weof=yes, has_weof=no)
 943     AC_MSG_RESULT($has_weof)
 944
 945     dnl Tests for wide character functions used in char_traits<wchar_t>.
 946     ac_wfuncs=yes
 947     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 948     ac_wfuncs=no)
 949
 950     dnl Checks for names injected into std:: by the c_std headers.
 951     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 952     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 953     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 954     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 955     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 956     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 957     ac_wfuncs=no)
 958
 959     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 960     if test x"$has_weof" = xyes &&
 961        test x"$has_wchar_minmax" = xyes &&
 962        test x"$ac_wfuncs" = xyes; then
 963       ac_isoC99_wchar_t=yes
 964     else
 965       ac_isoC99_wchar_t=no
 966     fi
 967     AC_MSG_RESULT($ac_isoC99_wchar_t)
 968
 969     dnl Use iconv for wchar_t to char conversions. As such, check for
 970     dnl X/Open Portability Guide, version 2 features (XPG2).
 971     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 972     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 973
 974     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 975     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 976     ac_save_LIBS="$LIBS"
 977     LIBS="$LIBS $libiconv"
 978
 979     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 980     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 981
 982     LIBS="$ac_save_LIBS"
 983
 984     AC_MSG_CHECKING([for XPG2 wchar_t support])
 985     if test x"$ac_has_iconv_h" = xyes &&
 986        test x"$ac_has_langinfo_h" = xyes &&
 987        test x"$ac_XPG2funcs" = xyes; then
 988       ac_XPG2_wchar_t=yes
 989     else
 990       ac_XPG2_wchar_t=no
 991     fi
 992     AC_MSG_RESULT($ac_XPG2_wchar_t)
 993
 994     dnl At the moment, only enable wchar_t specializations if all the
 995     dnl above support is present.
 996     AC_MSG_CHECKING([for enabled wchar_t specializations])
 997     if test x"$ac_isoC99_wchar_t" = xyes &&
 998        test x"$ac_XPG2_wchar_t" = xyes; then
 999       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
1000       AC_MSG_RESULT("yes")
1001     else
1002       AC_MSG_RESULT("no")
1003     fi
1004   else
1005     dnl Wide characters disabled by the user.
1006     AC_MSG_WARN([wchar_t support disabled.])
1007   fi
1008 ])
1009
1010
1011 dnl
1012 dnl Check for special debugging mode; not for production use.
1013 dnl
1014 dnl GLIBCPP_ENABLE_DEBUG
1015 dnl --enable-debug sets '-ggdb3 -O0'.
1016 dnl --disable-debug sets '-g' and whatever optimization options the
1017 dnl     compiler can handle.
1018 dnl  +  --enable-maintainer-mode automatically defaults this to on.
1019 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
1020 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1021 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1022 dnl       defaults to `no'.
1023 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1024 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1025 AC_ARG_ENABLE(debug,
1026 changequote(<<, >>)dnl
1027 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1028 changequote([, ])dnl
1029 [case "${enableval}" in
1030  yes) enable_debug=yes ;;
1031  no)  enable_debug=no ;;
1032  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1033  esac],
1034 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1035
1036 dnl Option parsed, now set things appropriately
1037 case "${enable_debug}" in
1038     yes)
1039         DEBUG_FLAGS='-O0 -ggdb3'
1040         ;;
1041     no)
1042         DEBUG_FLAGS='-g'
1043         ;;
1044 esac
1045 AC_SUBST(DEBUG_FLAGS)
1046 ])
1047
1048
1049 dnl
1050 dnl Check for "unusual" flags to pass to the compiler while building.
1051 dnl
1052 dnl GLIBCPP_ENABLE_CXX_FLAGS
1053 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1054 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1055 dnl     Somehow this same set of flags must be passed when [re]building
1056 dnl     libgcc.
1057 dnl --disable-cxx-flags passes nothing.
1058 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1059 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1060 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1061 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1062 dnl       If "default flags" is an empty string (or "none"), the effect is
1063 dnl       the same as --disable or --enable=no.
1064 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1065 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1066 AC_ARG_ENABLE(cxx-flags,
1067 changequote(<<, >>)dnl
1068 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1069                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1070 changequote([, ])dnl
1071 [case "x$enableval" in
1072  xyes)
1073         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1074  xno|x)
1075         enable_cxx_flags='' ;;
1076  *)
1077         enable_cxx_flags="$enableval" ;;
1078  esac],
1079 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1080
1081 dnl Thinko on my part during design.  This kludge is the workaround.
1082 if test "$enable_cxx_flags" = "none"; then
1083   enable_cxx_flags='';
1084 fi
1085
1086 dnl Run through flags (either default or command-line) and set anything
1087 dnl extra (e.g., #defines) that must accompany particular g++ options.
1088 if test -n "$enable_cxx_flags"; then
1089     for f in $enable_cxx_flags; do
1090         case "$f" in
1091             -fhonor-std)  ;;
1092             -*)  ;;
1093             *)   # and we're trying to pass /what/ exactly?
1094                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1095         esac
1096     done
1097 fi
1098 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1099 AC_SUBST(EXTRA_CXX_FLAGS)
1100 ])
1101
1102
1103 dnl
1104 dnl Check for which locale library to use:  gnu or generic.
1105 dnl
1106 dnl GLIBCPP_ENABLE_CLOCALE
1107 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1108 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1109 dnl
1110 dnl default is generic
1111 dnl
1112 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1113   AC_MSG_CHECKING([for clocale to use])
1114   AC_ARG_ENABLE(clocale,
1115   [  --enable-clocale        enable model for target locale package.
1116   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1117   ],
1118   if test x$enable_clocale = xno; then
1119      enable_clocale=no
1120   fi,
1121      enable_clocale=no)
1122
1123   enable_clocale_flag=$enable_clocale
1124
1125   dnl Probe for locale support if no specific model is specified.
1126   dnl Default to "generic"
1127   if test x$enable_clocale_flag = xno; then
1128     case x${target_os} in
1129       xlinux* | xgnu*)
1130         AC_EGREP_CPP([_GLIBCPP_ok], [
1131         #include <features.h>
1132         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1133           _GLIBCPP_ok
1134         #endif
1135         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1136
1137         # Test for bugs early in glibc-2.2.x series
1138         if test x$enable_clocale_flag = xgnu; then
1139           AC_TRY_RUN([
1140           #define _GNU_SOURCE 1
1141           #include <locale.h>
1142           int main()
1143           {
1144             const char __one[] = "Äuglein Augmen";
1145             const char __two[] = "Äuglein";
1146             int i;
1147             int j;
1148             __locale_t  loc;
1149             __locale_t  loc_dup;
1150             loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1151             loc_dup = __duplocale(loc);
1152             i = __strcoll_l(__one, __two, loc);
1153             j = __strcoll_l(__one, __two, loc_dup);
1154             return 0;
1155           }
1156           ],
1157           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1158           [enable_clocale_flag=generic])
1159         fi
1160
1161         # ... at some point put __strxfrm_l tests in as well.
1162         ;;
1163       *)
1164         enable_clocale_flag=generic
1165         ;;
1166     esac
1167   fi
1168
1169   dnl Deal with gettext issues.
1170   AC_ARG_ENABLE(nls,
1171   [  --enable-nls            use Native Language Support (default)],
1172   , enable_nls=yes)
1173   USE_NLS=no
1174
1175   dnl Set configure bits for specified locale package
1176   case x${enable_clocale_flag} in
1177     xgeneric)
1178       AC_MSG_RESULT(generic)
1179
1180       CLOCALE_H=config/locale/generic/c_locale.h
1181       CLOCALE_CC=config/locale/generic/c_locale.cc
1182       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1183       CCOLLATE_CC=config/locale/generic/collate_members.cc
1184       CCTYPE_CC=config/locale/generic/ctype_members.cc
1185       CMESSAGES_H=config/locale/generic/messages_members.h
1186       CMESSAGES_CC=config/locale/generic/messages_members.cc
1187       CMONEY_CC=config/locale/generic/monetary_members.cc
1188       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1189       CTIME_CC=config/locale/generic/time_members.cc
1190       ;;
1191     xgnu)
1192       AC_MSG_RESULT(gnu)
1193
1194       # Declare intention to use gettext, and add support for specific
1195       # languages.
1196       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1197       ALL_LINGUAS="de fr"
1198
1199       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1200       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1201       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1202         USE_NLS=yes
1203       fi
1204       # Export the build objects.
1205       for ling in $ALL_LINGUAS; do \
1206         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1207         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1208       done
1209       AC_SUBST(glibcpp_MOFILES)
1210       AC_SUBST(glibcpp_POFILES)
1211
1212       CLOCALE_H=config/locale/gnu/c_locale.h
1213       CLOCALE_CC=config/locale/gnu/c_locale.cc
1214       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1215       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1216       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1217       CMESSAGES_H=config/locale/gnu/messages_members.h
1218       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1219       CMONEY_CC=config/locale/gnu/monetary_members.cc
1220       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1221       CTIME_CC=config/locale/gnu/time_members.cc
1222       ;;
1223     xieee_1003.1-2001)
1224       AC_MSG_RESULT(generic)
1225
1226       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1227       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1228       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1229       CCOLLATE_CC=config/locale/generic/collate_members.cc
1230       CCTYPE_CC=config/locale/generic/ctype_members.cc
1231       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1232       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1233       CMONEY_CC=config/locale/generic/monetary_members.cc
1234       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1235       CTIME_CC=config/locale/generic/time_members.cc
1236       ;;
1237     *)
1238       echo "$enable_clocale is an unknown locale package" 1>&2
1239       exit 1
1240       ;;
1241   esac
1242
1243   # This is where the testsuite looks for locale catalogs, using the
1244   # -DLOCALEDIR define during testsuite compilation.
1245   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1246   AC_SUBST(glibcpp_localedir)
1247
1248   AC_SUBST(USE_NLS)
1249   AC_SUBST(CLOCALE_H)
1250   AC_SUBST(CCODECVT_H)
1251   AC_SUBST(CMESSAGES_H)
1252   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1253   AC_LINK_FILES($CCOLLATE_CC, src/collate.cc)
1254   AC_LINK_FILES($CCTYPE_CC, src/ctype.cc)
1255   AC_LINK_FILES($CMESSAGES_CC, src/messages.cc)
1256   AC_LINK_FILES($CMONEY_CC, src/monetary.cc)
1257   AC_LINK_FILES($CNUMERIC_CC, src/numeric.cc)
1258   AC_LINK_FILES($CTIME_CC, src/time.cc)
1259 ])
1260
1261
1262 dnl
1263 dnl Check for which I/O library to use:  libio, or something specific.
1264 dnl
1265 dnl GLIBCPP_ENABLE_CSTDIO
1266 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1267 dnl
1268 dnl default is stdio
1269 dnl
1270 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1271   AC_MSG_CHECKING([for cstdio to use])
1272   AC_ARG_ENABLE(cstdio,
1273   [  --enable-cstdio         enable stdio for target io package.
1274   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1275   ],
1276   if test x$enable_cstdio = xno; then
1277      enable_cstdio=stdio
1278   fi,
1279      enable_cstdio=stdio)
1280
1281   enable_cstdio_flag=$enable_cstdio
1282
1283   dnl Check if a valid I/O package
1284   case x${enable_cstdio_flag} in
1285     xlibio)
1286       CSTDIO_H=config/io/c_io_libio.h
1287       BASIC_FILE_H=config/io/basic_file_libio.h
1288       BASIC_FILE_CC=config/io/basic_file_libio.cc
1289       AC_MSG_RESULT(libio)
1290
1291       # see if we are on a system with libio native (ie, linux)
1292       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1293
1294       # Need to check and see what version of glibc is being used. If
1295       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1296       # compile most of libio for linux systems.
1297       if test x$has_libio = x"yes"; then
1298         case "$target" in
1299           *-*-linux*)
1300               AC_MSG_CHECKING([for glibc version >= 2.2])
1301               AC_EGREP_CPP([ok], [
1302             #include <features.h>
1303               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1304                     ok
1305               #endif
1306               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1307               AC_MSG_RESULT($glibc_satisfactory)
1308             ;;
1309         esac
1310
1311         # XXX at the moment, admit defeat and force the recompilation
1312         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1313         glibc_satisfactory=no
1314
1315         if test x$glibc_satisfactory = x"yes"; then
1316            need_libio=no
1317            need_wlibio=no
1318         else
1319            need_libio=yes
1320            # bkoz XXX need to add checks to enable this
1321            # pme XXX here's a first pass at such a check
1322            if test x$enable_c_mbchar != xno; then
1323               need_wlibio=yes
1324            else
1325               need_wlibio=no
1326            fi
1327         fi
1328
1329       else
1330          # Using libio, but <libio.h> doesn't exist on the target system. . .
1331          need_libio=yes
1332          # bkoz XXX need to add checks to enable this
1333          # pme XXX here's a first pass at such a check
1334          if test x$enable_c_mbchar != xno; then
1335              need_wlibio=yes
1336          else
1337              need_wlibio=no
1338          fi
1339       fi
1340       ;;
1341     xstdio | x | xno | xnone | xyes)
1342       # default
1343       CSTDIO_H=config/io/c_io_stdio.h
1344       BASIC_FILE_H=config/io/basic_file_stdio.h
1345       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1346       AC_MSG_RESULT(stdio)
1347
1348       # We're not using stdio.
1349       need_libio=no
1350       need_wlibio=no
1351       ;;
1352     *)
1353       echo "$enable_cstdio is an unknown io package" 1>&2
1354       exit 1
1355       ;;
1356   esac
1357   AC_SUBST(CSTDIO_H)
1358   AC_SUBST(BASIC_FILE_H)
1359   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1360
1361   # 2000-08-04 bkoz hack
1362   CCODECVT_C=config/io/c_io_libio_codecvt.c
1363   AC_SUBST(CCODECVT_C)
1364   # 2000-08-04 bkoz hack
1365
1366   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1367                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1368   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1369   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1370   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1371     libio_la=../libio/libio.la
1372   else
1373     libio_la=
1374   fi
1375   AC_SUBST(libio_la)
1376 ])
1377
1378
1379 dnl
1380 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1381 dnl We must stage the required headers so that they will be installed
1382 dnl with the library (unlike libgcc, the STL implementation is provided
1383 dnl solely within headers).  Since we must not inject random user-space
1384 dnl macro names into user-provided C++ code, we first stage into <file>-in
1385 dnl and process to <file> with an output command.  The reason for a two-
1386 dnl stage process here is to correctly handle $srcdir!=$objdir without
1387 dnl having to write complex code (the sed commands to clean the macro
1388 dnl namespace are complex and fragile enough as it is).  We must also
1389 dnl add a relative path so that -I- is supported properly.
1390 dnl
1391 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1392   AC_MSG_CHECKING([for thread model used by GCC])
1393   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1394   AC_MSG_RESULT([$target_thread_file])
1395
1396   if test $target_thread_file != single; then
1397     AC_DEFINE(HAVE_GTHR_DEFAULT)
1398     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1399   fi
1400
1401   glibcpp_thread_h=gthr-$target_thread_file.h
1402   AC_SUBST(glibcpp_thread_h)
1403 ])
1404
1405
1406 dnl
1407 dnl Check for exception handling support.  If an explicit enable/disable
1408 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1409 dnl target may or may not support call frame exceptions.
1410 dnl
1411 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1412 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1413 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1414 dnl
1415 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1416 dnl
1417 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1418   AC_MSG_CHECKING([for exception model to use])
1419   AC_LANG_SAVE
1420   AC_LANG_CPLUSPLUS
1421   AC_ARG_ENABLE(sjlj-exceptions,
1422   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1423   [:],
1424   [dnl Botheration.  Now we've got to detect the exception model.
1425    dnl Link tests against libgcc.a are problematic since -- at least
1426    dnl as of this writing -- we've not been given proper -L bits for
1427    dnl single-tree newlib and libgloss.
1428    dnl
1429    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1430    dnl conftest files before we got a change to grep them first.
1431    cat > conftest.$ac_ext << EOF
1432 [#]line __oline__ "configure"
1433 struct S { ~S(); };
1434 void bar();
1435 void foo()
1436 {
1437   S s;
1438   bar();
1439 }
1440 EOF
1441    old_CXXFLAGS="$CXXFLAGS"
1442    CXXFLAGS=-S
1443    if AC_TRY_EVAL(ac_compile); then
1444      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1445        enable_sjlj_exceptions=yes
1446      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1447        enable_sjlj_exceptions=no
1448      fi
1449    fi
1450    CXXFLAGS="$old_CXXFLAGS"
1451    rm -f conftest*])
1452    if test x$enable_sjlj_exceptions = xyes; then
1453      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1454         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1455      ac_exception_model_name=sjlj
1456    elif test x$enable_sjlj_exceptions = xno; then
1457      ac_exception_model_name="call frame"
1458    else
1459      AC_MSG_ERROR([unable to detect exception model])
1460    fi
1461    AC_LANG_RESTORE
1462    AC_MSG_RESULT($ac_exception_model_name)
1463 ])
1464
1465
1466 dnl
1467 dnl Check for libunwind exception handling support. If enabled then
1468 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1469 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1470 dnl libunwind instead of libgcc and that libstdc++ has a dependency
1471 dnl on libunwind as well as libgcc.
1472 dnl
1473 dnl GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS
1474 dnl --enable-libunwind-exceptions forces the use of libunwind.
1475 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1476 dnl
1477 dnl Define _GLIBCPP_LIBUNWIND_EXCEPTIONS if requested.
1478 dnl
1479 AC_DEFUN(GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS, [
1480   AC_MSG_CHECKING([for use of libunwind])
1481   AC_ARG_ENABLE(libunwind-exceptions,
1482   [  --enable-libunwind-exceptions  force use of libunwind for exceptions],
1483   use_libunwind_exceptions=$enableval,
1484   use_libunwind_exceptions=no)
1485   AC_MSG_RESULT($use_libunwind_exceptions)
1486   dnl Option parsed, now set things appropriately
1487   if test x"$use_libunwind_exceptions" = xyes; then
1488     LIBUNWIND_FLAG="-lunwind"
1489   else
1490     LIBUNWIND_FLAG=""
1491   fi
1492   AC_SUBST(LIBUNWIND_FLAG)
1493 ])
1494
1495 dnl
1496 dnl Check for ISO/IEC 9899:1999 "C99" support.
1497 dnl
1498 dnl GLIBCPP_ENABLE_C99
1499 dnl --enable-c99 defines _GLIBCPP_USE_C99
1500 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1501 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1502 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1503 dnl       defaults to `no'.
1504 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1505 dnl
1506 dnl GLIBCPP_ENABLE_C99
1507 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1508   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1509
1510   AC_ARG_ENABLE(c99,
1511   changequote(<<, >>)dnl
1512   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1513   changequote([, ])dnl
1514   [case "$enableval" in
1515    yes) enable_c99=yes ;;
1516    no)  enable_c99=no ;;
1517    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1518    esac],
1519   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1520
1521   AC_LANG_SAVE
1522   AC_LANG_CPLUSPLUS
1523
1524   # Check for the existence of <math.h> functions used if C99 is enabled.
1525   ac_c99_math=yes;
1526   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1527   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1528   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1529   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1530   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1531   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1532   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1533   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1534   AC_TRY_COMPILE([#include <math.h>],
1535                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1536   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1537   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1538   AC_TRY_COMPILE([#include <math.h>],
1539                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1540   AC_TRY_COMPILE([#include <math.h>],
1541                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1542   AC_MSG_RESULT($ac_c99_math)
1543
1544   # Check for the existence in <stdio.h> of vscanf, et. al.
1545   ac_c99_stdio=yes;
1546   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1547   AC_TRY_COMPILE([#include <stdio.h>],
1548                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1549   AC_TRY_COMPILE([#include <stdio.h>
1550                   #include <stdarg.h>
1551                   void foo(char* fmt, ...)
1552                   {va_list args; va_start(args, fmt);
1553                   vfscanf(stderr, "%i", args);}],
1554                   [],, [ac_c99_stdio=no])
1555   AC_TRY_COMPILE([#include <stdio.h>
1556                   #include <stdarg.h>
1557                   void foo(char* fmt, ...)
1558                   {va_list args; va_start(args, fmt);
1559                   vscanf("%i", args);}],
1560                   [],, [ac_c99_stdio=no])
1561   AC_TRY_COMPILE([#include <stdio.h>
1562                   #include <stdarg.h>
1563                   void foo(char* fmt, ...)
1564                   {va_list args; va_start(args, fmt);
1565                   vsnprintf(fmt, 0, "%i", args);}],
1566                   [],, [ac_c99_stdio=no])
1567   AC_TRY_COMPILE([#include <stdio.h>
1568                   #include <stdarg.h>
1569                   void foo(char* fmt, ...)
1570                   {va_list args; va_start(args, fmt);
1571                   vsscanf(fmt, "%i", args);}],
1572                   [],, [ac_c99_stdio=no])
1573   AC_MSG_RESULT($ac_c99_stdio)
1574
1575   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1576   ac_c99_stdlib=yes;
1577   AC_MSG_CHECKING([for lldiv_t declaration])
1578   AC_CACHE_VAL(ac_c99_lldiv_t, [
1579   AC_TRY_COMPILE([#include <stdlib.h>],
1580                    [ lldiv_t mydivt;],
1581                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1582   ])
1583   AC_MSG_RESULT($ac_c99_lldiv_t)
1584
1585   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1586   AC_TRY_COMPILE([#include <stdlib.h>],
1587                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1588   AC_TRY_COMPILE([#include <stdlib.h>],
1589                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1590   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1591   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1592   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1593   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1594   if test x"$ac_c99_lldiv_t" = x"no"; then
1595     ac_c99_stdlib=no;
1596   fi;
1597   AC_MSG_RESULT($ac_c99_stdlib)
1598
1599   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1600   # XXX the wchar.h checks should be rolled into the general C99 bits.
1601   ac_c99_wchar=yes;
1602   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1603   AC_TRY_COMPILE([#include <wchar.h>],
1604                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1605   AC_TRY_COMPILE([#include <wchar.h>],
1606                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1607   AC_TRY_COMPILE([#include <wchar.h>],
1608                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1609   AC_MSG_RESULT($ac_c99_wchar)
1610
1611   AC_MSG_CHECKING([for enabled ISO C99 support])
1612   if test x"$ac_c99_math" = x"no" ||
1613      test x"$ac_c99_stdio" = x"no" ||
1614      test x"$ac_c99_stdlib" = x"no" ||
1615      test x"$ac_c99_wchar" = x"no"; then
1616     enable_c99=no;
1617   fi;
1618   AC_MSG_RESULT($enable_c99)
1619
1620   # Option parsed, now set things appropriately
1621   if test x"$enable_c99" = x"yes"; then
1622     AC_DEFINE(_GLIBCPP_USE_C99)
1623   fi
1624
1625   AC_LANG_RESTORE
1626 ])
1627
1628
1629 dnl
1630 dnl Check for template specializations for the 'long long' type extension.
1631 dnl The result determines only whether 'long long' I/O is enabled; things
1632 dnl like numeric_limits<> specializations are always available.
1633 dnl
1634 dnl GLIBCPP_ENABLE_LONG_LONG
1635 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1636 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1637 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1638 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1639 dnl       defaults to `no'.
1640 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1641 dnl
1642 dnl GLIBCPP_ENABLE_LONG_LONG
1643 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1644   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1645
1646   AC_ARG_ENABLE(long-long,
1647   changequote(<<, >>)dnl
1648   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1649   changequote([, ])dnl
1650   [case "$enableval" in
1651    yes) enable_long_long=yes ;;
1652    no)  enable_long_long=no ;;
1653    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1654    esac],
1655   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1656
1657   AC_LANG_SAVE
1658   AC_LANG_CPLUSPLUS
1659
1660   AC_MSG_CHECKING([for enabled long long I/O support])
1661   # iostreams require strtoll, strtoull to compile
1662   AC_TRY_COMPILE([#include <stdlib.h>],
1663                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1664   AC_TRY_COMPILE([#include <stdlib.h>],
1665                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1666
1667   # Option parsed, now set things appropriately
1668   if test x"$enable_long_long" = xyes; then
1669     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1670   fi
1671   AC_MSG_RESULT($enable_long_long)
1672
1673   AC_LANG_RESTORE
1674 ])
1675
1676
1677 dnl
1678 dnl Check for what kind of C headers to use.
1679 dnl
1680 dnl GLIBCPP_ENABLE_CHEADERS
1681 dnl --enable-cheaders= [does stuff].
1682 dnl --disable-cheaders [does not do anything, really].
1683 dnl  +  This will eventually need to be 'c_shadow' by default.
1684 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1685 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1686 dnl       If ommitted, it defaults to `c_std'.
1687 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1688 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1689 AC_MSG_CHECKING([for c header strategy to use])
1690 AC_ARG_ENABLE(cheaders,
1691 changequote(<<, >>)dnl
1692 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1693 changequote([, ])
1694   [case "$enableval" in
1695    c)
1696         enable_cheaders=c
1697         ;;
1698    c_std)
1699         enable_cheaders=c_std
1700         ;;
1701    c_shadow)
1702         enable_cheaders=c_shadow
1703         ;;
1704    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1705         ;;
1706   esac],
1707   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1708   AC_MSG_RESULT($enable_cheaders)
1709
1710   dnl Option parsed, now set things appropriately
1711   case "$enable_cheaders" in
1712     c_shadow)
1713         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_shadow'
1714         ;;
1715     c_std)
1716         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1717         ;;
1718     c)
1719         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1720         ;;
1721   esac
1722
1723   AC_SUBST(C_INCLUDE_DIR)
1724   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C, test "$enable_cheaders" = c)
1725   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C_STD, test "$enable_cheaders" = c_std)
1726   AM_CONDITIONAL(GLIBCPP_C_HEADERS_COMPATIBILITY, test "$c_compatibility" = yes)
1727 ])
1728
1729
1730 dnl
1731 dnl Check for wide character support.  Has the same effect as the option
1732 dnl in gcc's configure, but in a form that autoconf can mess with.
1733 dnl
1734 dnl GLIBCPP_ENABLE_C_MBCHAR
1735 dnl --enable-c-mbchar requests all the wchar_t stuff.
1736 dnl --disable-c-mbchar doesn't.
1737 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1738 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1739 dnl       defaults to `no'.
1740 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1741 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1742 AC_ARG_ENABLE(c-mbchar,
1743 changequote(<<, >>)dnl
1744 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1745 changequote([, ])dnl
1746 [case "$enableval" in
1747  yes) enable_c_mbchar=yes ;;
1748  no)  enable_c_mbchar=no ;;
1749  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1750  esac],
1751 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1752 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1753 ])
1754
1755
1756 dnl
1757 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1758 dnl
1759 dnl TOPLEVEL_INCLUDES
1760 dnl LIBMATH_INCLUDES
1761 dnl LIBSUPCXX_INCLUDES
1762 dnl LIBIO_INCLUDES
1763 dnl CSHADOW_INCLUDES
1764 dnl
1765 dnl GLIBCPP_EXPORT_INCLUDES
1766 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1767   # Root level of the build directory include sources.
1768   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1769
1770   # Passed down for canadian crosses.
1771   if test x"$CANADIAN" = xyes; then
1772     TOPLEVEL_INCLUDES='-I$(includedir)'
1773   fi
1774
1775   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1776
1777   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1778
1779   if test x"$need_libio" = xyes; then
1780     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1781     AC_SUBST(LIBIO_INCLUDES)
1782   fi
1783
1784   # Now, export this to all the little Makefiles....
1785   AC_SUBST(GLIBCPP_INCLUDES)
1786   AC_SUBST(TOPLEVEL_INCLUDES)
1787   AC_SUBST(LIBMATH_INCLUDES)
1788   AC_SUBST(LIBSUPCXX_INCLUDES)
1789 ])
1790
1791
1792 dnl
1793 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1794 dnl
1795 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1796   # Optimization flags that are probably a good idea for thrill-seekers. Just
1797   # uncomment the lines below and make, everything else is ready to go...
1798   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1799   OPTIMIZE_CXXFLAGS=
1800   AC_SUBST(OPTIMIZE_CXXFLAGS)
1801
1802   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1803   AC_SUBST(WARN_FLAGS)
1804 ])
1805
1806 dnl
1807 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1808 dnl  calculates gxx_install_dir
1809 dnl  exports glibcpp_toolexecdir
1810 dnl  exports glibcpp_toolexeclibdir
1811 dnl  exports glibcpp_prefixdir
1812 dnl
1813 dnl Assumes cross_compiling bits already done, and with_cross_host in
1814 dnl particular
1815 dnl
1816 dnl GLIBCPP_EXPORT_INSTALL_INFO
1817 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1818 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1819 # exported correctly in GLIBCPP_CONFIGURE.
1820 glibcpp_toolexecdir=no
1821 glibcpp_toolexeclibdir=no
1822 glibcpp_prefixdir=${prefix}
1823
1824 # Process the option --with-gxx-include-dir=<path to include-files directory>
1825 AC_MSG_CHECKING([for --with-gxx-include-dir])
1826 AC_ARG_WITH(gxx-include-dir,
1827 [  --with-gxx-include-dir  the installation directory for include files],
1828 [case "${withval}" in
1829   yes)
1830     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1831     gxx_include_dir=no
1832     ;;
1833   no)
1834     gxx_include_dir=no
1835     ;;
1836   *)
1837     gxx_include_dir=${withval}
1838     ;;
1839 esac], [gxx_include_dir=no])
1840 AC_MSG_RESULT($gxx_include_dir)
1841
1842 # Process the option "--enable-version-specific-runtime-libs"
1843 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1844 AC_ARG_ENABLE(version-specific-runtime-libs,
1845 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1846 [case "$enableval" in
1847  yes) version_specific_libs=yes ;;
1848  no)  version_specific_libs=no ;;
1849  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1850  esac],
1851 version_specific_libs=no)dnl
1852 # Option set, now we can test it.
1853 AC_MSG_RESULT($version_specific_libs)
1854
1855 # Get the gcc version number. This is lifted from gcc/configure.in
1856 AC_MSG_CHECKING([for gcc version number])
1857 changequote(,)dnl
1858 gcc_version_trigger=${srcdir}/../gcc/version.c
1859 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1860 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1861 changequote([,])dnl
1862 AC_MSG_RESULT($gcc_version)
1863
1864 # Default case for install directory for include files.
1865 if test $version_specific_libs = no && test $gxx_include_dir = no; then
1866   gxx_include_dir='$(prefix)'/include/c++/${gcc_version}
1867 fi
1868
1869 # Version-specific runtime libs processing.
1870 if test $version_specific_libs = yes; then
1871   # Need the gcc compiler version to know where to install libraries
1872   # and header files if --enable-version-specific-runtime-libs option
1873   # is selected.
1874   if test x"$gxx_include_dir" = x"no"; then
1875     gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/c++
1876   fi
1877   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1878   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1879 fi
1880
1881 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1882 # Install a library built with a cross compiler in tooldir, not libdir.
1883 if test x"$glibcpp_toolexecdir" = x"no"; then
1884   if test -n "$with_cross_host" &&
1885      test x"$with_cross_host" != x"no"; then
1886     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1887     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1888   else
1889     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1890     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1891   fi
1892 fi
1893
1894 AC_MSG_CHECKING([for install location])
1895 AC_MSG_RESULT($gxx_include_dir)
1896
1897 AC_SUBST(glibcpp_prefixdir)
1898 AC_SUBST(gxx_include_dir)
1899 AC_SUBST(glibcpp_toolexecdir)
1900 AC_SUBST(glibcpp_toolexeclibdir)
1901 ])
1902
1903
1904 # Check for functions in math library.
1905 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1906 #
1907 # This file can be copied and used freely without restrictions.  It can
1908 # be used in projects which are not available under the GNU Public License
1909 # but which still want to provide support for the GNU gettext functionality.
1910 # Please note that the actual code is *not* freely available.
1911
1912 # serial 1
1913
1914 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1915 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1916 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])])
1917
1918
1919 dnl This macro searches for a GNU version of make.  If a match is found, the
1920 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1921 dnl set to "#". This is useful for  including a special features in a Makefile,
1922 dnl which cannot be handled by other versions of make.  The variable
1923 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1924 dnl the empty string otherwise.
1925 dnl
1926 dnl Here is an example of its use:
1927 dnl
1928 dnl Makefile.in might contain:
1929 dnl
1930 dnl     # A failsafe way of putting a dependency rule into a makefile
1931 dnl     $(DEPEND):
1932 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1933 dnl
1934 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1935 dnl     @ifGNUmake@ include $(DEPEND)
1936 dnl     @ifGNUmake@ endif
1937 dnl
1938 dnl Then configure.in would normally contain:
1939 dnl
1940 dnl     CHECK_GNU_MAKE()
1941 dnl     AC_OUTPUT(Makefile)
1942 dnl
1943 dnl Then perhaps to cause gnu make to override any other make, we could do
1944 dnl something like this (note that GNU make always looks for GNUmakefile first):
1945 dnl
1946 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1947 dnl             mv Makefile GNUmakefile
1948 dnl             echo .DEFAULT: > Makefile ;
1949 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1950 dnl     fi
1951 dnl
1952 dnl Then, if any (well almost any) other make is called, and GNU make also
1953 dnl exists, then the other make wraps the GNU make.
1954 dnl
1955 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1956 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1957 dnl
1958 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1959 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1960 dnl #### conditional's subshell (" --version" is not a command), using a
1961 dnl #### different option to grep(1).
1962 dnl #### -pme
1963 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1964 dnl #### ${MAKE:-make}).
1965 dnl #### -msokolov
1966 AC_DEFUN(
1967   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1968           _cv_gnu_make_command='' ;
1969 dnl Search all the common names for GNU make
1970           for a in "${MAKE-make}" make gmake gnumake ; do
1971                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1972                   then
1973                           _cv_gnu_make_command=$a ;
1974                           break;
1975                   fi
1976           done ;
1977   ) ;
1978 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1979 dnl string, '#' otherwise
1980   if test  "x$_cv_gnu_make_command" != "x"  ; then
1981           ifGNUmake='' ;
1982   else
1983           ifGNUmake='#' ;
1984   fi
1985   AC_SUBST(ifGNUmake)
1986 ])
1987
1988
1989 dnl Check for headers for, and arguments to, the setrlimit() function.
1990 dnl Used only in testsuite_hooks.h.
1991 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
1992   AC_TRY_COMPILE([#include <unistd.h>
1993                   #include <sys/time.h>
1994                   #include <sys/resource.h>
1995                  ], [ int f = RLIMIT_$1 ; ],
1996                  [glibcpp_mresult=1], [glibcpp_mresult=0])
1997   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
1998                      [Only used in build directory testsuite_hooks.h.])
1999 ])
2000 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
2001   setrlimit_have_headers=yes
2002   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
2003                    [],
2004                    setrlimit_have_headers=no)
2005   # If don't have the headers, then we can't run the tests now, and we
2006   # won't be seeing any of these during testsuite compilation.
2007   if test $setrlimit_have_headers = yes; then
2008     # Can't do these in a loop, else the resulting syntax is wrong.
2009     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
2010     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
2011     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
2012     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
2013
2014     # Check for rlimit, setrlimit.
2015     AC_CACHE_VAL(ac_setrlimit, [
2016       AC_TRY_COMPILE([#include <unistd.h>
2017                   #include <sys/time.h>
2018                   #include <sys/resource.h>
2019                      ],
2020                      [ struct rlimit r; setrlimit(0, &r);],
2021                      [ac_setrlimit=yes], [ac_setrlimit=no])
2022     ])
2023   fi
2024
2025   AC_MSG_CHECKING([for testsuite memory limit support])
2026   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
2027     ac_mem_limits=yes
2028     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
2029   else
2030     ac_mem_limits=no
2031   fi
2032   AC_MSG_RESULT($ac_mem_limits)
2033 ])
2034
2035
2036 dnl
2037 dnl Does any necessary configuration of the testsuite directory.  Generates
2038 dnl the testsuite_hooks.h header.
2039 dnl
2040 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
2041 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
2042   GLIBCPP_CHECK_SETRLIMIT
2043
2044   # Look for setenv, so that extended locale tests can be performed.
2045   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
2046 ])
2047
2048
2049 sinclude(../libtool.m4)
2050 dnl The lines below arrange for aclocal not to bring an installed
2051 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
2052 dnl add a definition of LIBTOOL to Makefile.in.
2053 ifelse(,,,[AC_SUBST(LIBTOOL)
2054 AC_DEFUN([AM_PROG_LIBTOOL])
2055 AC_DEFUN([AC_LIBTOOL_DLOPEN])
2056 AC_DEFUN([AC_PROG_LD])
2057 ])
2058
2059
2060 # Check whether LC_MESSAGES is available in <locale.h>.
2061 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2062 #
2063 # This file file be copied and used freely without restrictions.  It can
2064 # be used in projects which are not available under the GNU Public License
2065 # but which still want to provide support for the GNU gettext functionality.
2066 # Please note that the actual code is *not* freely available.
2067
2068 # serial 1
2069
2070 AC_DEFUN(AC_LC_MESSAGES, [
2071   AC_CHECK_HEADER(locale.h, [
2072     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2073       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2074        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2075     if test $ac_cv_val_LC_MESSAGES = yes; then
2076       AC_DEFINE(HAVE_LC_MESSAGES)
2077     fi
2078   ])
2079 ])
2080
2081
2082 dnl
2083 dnl Check for whether the Boost-derived checks should be turned on.
2084 dnl
2085 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
2086 dnl --enable-concept-checks turns them on.
2087 dnl --disable-concept-checks leaves them off.
2088 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2089 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2090 dnl       defaults to `no'.
2091 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
2092 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
2093 AC_ARG_ENABLE(concept-checks,
2094 changequote(<<, >>)dnl
2095 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
2096 changequote([, ])dnl
2097 [case "$enableval" in
2098  yes) enable_concept_checks=yes ;;
2099  no)  enable_concept_checks=no ;;
2100  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
2101  esac],
2102 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
2103 dnl Option parsed, now set things appropriately
2104 if test x"$enable_concept_checks" = xyes; then
2105   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
2106 fi
2107 ])
2108
2109
2110 dnl
2111 dnl Add version tags to symbols in shared library (or not), additionally
2112 dnl marking other symbols as private/local (or not).
2113 dnl
2114 dnl GLIBCPP_ENABLE_SYMVERS
2115 dnl --enable-symvers=style adds a version script to the linker call when
2116 dnl       creating the shared library.  The choice of version script is
2117 dnl       controlled by 'style'.
2118 dnl --disable-symvers does not.
2119 dnl  +  Usage:  GLIBCPP_ENABLE_SYMVERS[(DEFAULT)]
2120 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2121 dnl       defaults to `no'.  Passing `yes' tries to choose a default style
2122 dnl       based on linker characteristics.  Passing 'no' disables versioning.
2123 AC_DEFUN(GLIBCPP_ENABLE_SYMVERS, [dnl
2124 define([GLIBCPP_ENABLE_SYMVERS_DEFAULT], ifelse($1, yes, yes, no))dnl
2125 AC_ARG_ENABLE(symvers,
2126 changequote(<<, >>)dnl
2127 <<  --enable-symvers=style  enables symbol versioning of the shared library [default=>>GLIBCPP_ENABLE_SYMVERS_DEFAULT],
2128 changequote([, ])dnl
2129 [case "$enableval" in
2130  yes) enable_symvers=yes ;;
2131  no)  enable_symvers=no ;;
2132  # other names here, just as sanity checks
2133  #gnu|sun|etcetera) enable_symvers=$enableval ;;
2134  gnu) enable_symvers=$enableval ;;
2135  *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]) ;;
2136  esac],
2137 enable_symvers=GLIBCPP_ENABLE_SYMVERS_DEFAULT)dnl
2138
2139 # If we never went through the GLIBCPP_CHECK_LINKER_FEATURES macro, then we
2140 # don't know enough about $LD to do tricks...
2141 if test x$enable_shared = xno ||
2142         test "x$LD" = x ||
2143         test x$glibcpp_gnu_ld_version = x; then
2144   enable_symvers=no
2145 fi
2146
2147 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2148 if test $enable_symvers != no; then
2149   AC_MSG_CHECKING([for shared libgcc])
2150   ac_save_CFLAGS="$CFLAGS"
2151   CFLAGS=' -lgcc_s'
2152   AC_TRY_LINK(, [return 0], glibcpp_shared_libgcc=yes, glibcpp_shared_libgcc=no)
2153   CFLAGS="$ac_save_CFLAGS"
2154   AC_MSG_RESULT($glibcpp_shared_libgcc)
2155 fi
2156
2157 # For GNU ld, we need at least this version.  It's 2.12 in the same format
2158 # as the tested-for version.  See GLIBCPP_CHECK_LINKER_FEATURES for more.
2159 glibcpp_min_gnu_ld_version=21200
2160
2161 # Check to see if unspecified "yes" value can win, given results
2162 # above.
2163 if test $enable_symvers = yes ; then
2164   if test $with_gnu_ld = yes &&
2165     test $glibcpp_shared_libgcc = yes ;
2166   then
2167     if test $glibcpp_gnu_ld_version -ge $glibcpp_min_gnu_ld_version ; then
2168         enable_symvers=gnu
2169     else
2170       ac_test_CFLAGS="${CFLAGS+set}"
2171       ac_save_CFLAGS="$CFLAGS"
2172       CFLAGS='-shared -Wl,--version-script,conftest.map'
2173       enable_symvers=no
2174       changequote(,)
2175       echo 'FOO { global: f[a-z]o; local: *; };' > conftest.map
2176       changequote([,])
2177       AC_TRY_LINK([int foo;],, enable_symvers=gnu)
2178       if test "$ac_test_CFLAGS" = set; then
2179         CFLAGS="$ac_save_CFLAGS"
2180       else
2181         # this is the suspicious part
2182         CFLAGS=''
2183       fi
2184       rm -f conftest.map
2185     fi
2186   else
2187     # just fail for now
2188     enable_symvers=no
2189   fi
2190 fi
2191
2192 dnl Everything parsed; figure out what file to use.
2193 case $enable_symvers in
2194   no)
2195       LINKER_MAP=config/linker-map.dummy
2196       ;;
2197   gnu)
2198       LINKER_MAP=config/linker-map.gnu
2199       ;;
2200 esac
2201
2202 AC_LINK_FILES($LINKER_MAP, src/linker.map)
2203 AM_CONDITIONAL(GLIBCPP_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
2204 AC_MSG_CHECKING([versioning on shared library symbols])
2205 AC_MSG_RESULT($enable_symvers)
2206 ])
2207
2208
2209 # isc-posix.m4 serial 1 (gettext-0.10.40)
2210 dnl Copyright (C) 1995-2002 Free Software Foundation, Inc.
2211 dnl This file is free software, distributed under the terms of the GNU
2212 dnl General Public License.  As a special exception to the GNU General
2213 dnl Public License, this file may be distributed as part of a program
2214 dnl that contains a configuration script generated by Autoconf, under
2215 dnl the same distribution terms as the rest of that program.
2216
2217 # This test replaces the one in autoconf.
2218 # Currently this macro should have the same name as the autoconf macro
2219 # because gettext's gettext.m4 (distributed in the automake package)
2220 # still uses it.  Otherwise, the use in gettext.m4 makes autoheader
2221 # give these diagnostics:
2222 #   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
2223 #   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
2224
2225 undefine([AC_ISC_POSIX])
2226
2227 AC_DEFUN([AC_ISC_POSIX],
2228   [
2229     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
2230     AC_CHECK_LIB(cposix, strerror, [LIBS="$LIBS -lcposix"])
2231   ]
2232 )
2233
2234 # Add --enable-maintainer-mode option to configure.
2235 # From Jim Meyering
2236
2237 # serial 1
2238
2239 AC_DEFUN([AM_MAINTAINER_MODE],
2240 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2241   dnl maintainer-mode is disabled by default
2242   AC_ARG_ENABLE(maintainer-mode,
2243 [  --enable-maintainer-mode enable make rules and dependencies not useful
2244                           (and sometimes confusing) to the casual installer],
2245       USE_MAINTAINER_MODE=$enableval,
2246       USE_MAINTAINER_MODE=no)
2247   AC_MSG_RESULT($USE_MAINTAINER_MODE)
2248   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
2249   MAINT=$MAINTAINER_MODE_TRUE
2250   AC_SUBST(MAINT)dnl
2251 ]
2252 )
2253
2254 # Define a conditional.
2255
2256 AC_DEFUN([AM_CONDITIONAL],
2257 [AC_SUBST($1_TRUE)
2258 AC_SUBST($1_FALSE)
2259 if $2; then
2260   $1_TRUE=
2261   $1_FALSE='#'
2262 else
2263   $1_TRUE='#'
2264   $1_FALSE=
2265 fi])
2266
2267 # Do all the work for Automake.  This macro actually does too much --
2268 # some checks are only needed if your package does certain things.
2269 # But this isn't really a big deal.
2270
2271 # serial 1
2272
2273 dnl Usage:
2274 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
2275
2276 AC_DEFUN([AM_INIT_AUTOMAKE],
2277 [AC_REQUIRE([AC_PROG_INSTALL])
2278 PACKAGE=[$1]
2279 AC_SUBST(PACKAGE)
2280 VERSION=[$2]
2281 AC_SUBST(VERSION)
2282 dnl test to see if srcdir already configured
2283 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
2284   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
2285 fi
2286 ifelse([$3],,
2287 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
2288 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
2289 AC_REQUIRE([AM_SANITY_CHECK])
2290 AC_REQUIRE([AC_ARG_PROGRAM])
2291 dnl FIXME This is truly gross.
2292 missing_dir=`cd $ac_aux_dir && pwd`
2293 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
2294 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
2295 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
2296 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
2297 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
2298 AC_REQUIRE([AC_PROG_MAKE_SET])])
2299
2300 #
2301 # Check to make sure that the build environment is sane.
2302 #
2303
2304 AC_DEFUN([AM_SANITY_CHECK],
2305 [AC_MSG_CHECKING([whether build environment is sane])
2306 # Just in case
2307 sleep 1
2308 echo timestamp > conftestfile
2309 # Do `set' in a subshell so we don't clobber the current shell's
2310 # arguments.  Must try -L first in case configure is actually a
2311 # symlink; some systems play weird games with the mod time of symlinks
2312 # (eg FreeBSD returns the mod time of the symlink's containing
2313 # directory).
2314 if (
2315    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
2316    if test "[$]*" = "X"; then
2317       # -L didn't work.
2318       set X `ls -t $srcdir/configure conftestfile`
2319    fi
2320    if test "[$]*" != "X $srcdir/configure conftestfile" \
2321       && test "[$]*" != "X conftestfile $srcdir/configure"; then
2322
2323       # If neither matched, then we have a broken ls.  This can happen
2324       # if, for instance, CONFIG_SHELL is bash and it inherits a
2325       # broken ls alias from the environment.  This has actually
2326       # happened.  Such a system could not be considered "sane".
2327       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2328 alias in your environment])
2329    fi
2330
2331    test "[$]2" = conftestfile
2332    )
2333 then
2334    # Ok.
2335    :
2336 else
2337    AC_MSG_ERROR([newly created file is older than distributed files!
2338 Check your system clock])
2339 fi
2340 rm -f conftest*
2341 AC_MSG_RESULT(yes)])
2342
2343 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
2344 dnl The program must properly implement --version.
2345 AC_DEFUN([AM_MISSING_PROG],
2346 [AC_MSG_CHECKING(for working $2)
2347 # Run test in a subshell; some versions of sh will print an error if
2348 # an executable is not found, even if stderr is redirected.
2349 # Redirect stdin to placate older versions of autoconf.  Sigh.
2350 if ($2 --version) < /dev/null > /dev/null 2>&1; then
2351    $1=$2
2352    AC_MSG_RESULT(found)
2353 else
2354    $1="$3/missing $2"
2355    AC_MSG_RESULT(missing)
2356 fi
2357 AC_SUBST($1)])
2358
2359 # Like AC_CONFIG_HEADER, but automatically create stamp file.
2360
2361 AC_DEFUN([AM_CONFIG_HEADER],
2362 [AC_PREREQ([2.12])
2363 AC_CONFIG_HEADER([$1])
2364 dnl When config.status generates a header, we must update the stamp-h file.
2365 dnl This file resides in the same directory as the config header
2366 dnl that is generated.  We must strip everything past the first ":",
2367 dnl and everything past the last "/".
2368 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
2369 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
2370 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
2371 <<am_indx=1
2372 for am_file in <<$1>>; do
2373   case " <<$>>CONFIG_HEADERS " in
2374   *" <<$>>am_file "*<<)>>
2375     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
2376     ;;
2377   esac
2378   am_indx=`expr "<<$>>am_indx" + 1`
2379 done<<>>dnl>>)
2380 changequote([,]))])
2381