libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Find platform-specific directories containing configuration info.
 129   # Also possibly modify flags used elsewhere, as needed by the platform.
 130   GLIBCXX_CHECK_HOST
 131 ])
 132
 133
 134 dnl
 135 dnl Tests for newer compiler features, or features that are present in newer
 136 dnl compiler versions but not older compiler versions still in use, should
 137 dnl be placed here.
 138 dnl
 139 dnl Defines:
 140 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 141 dnl   new inlining code or the new system_header pragma will die on -Werror.
 142 dnl   Leave it out by default and use maint-mode to use it.
 143 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 144 dnl   compiler supports it and the user has not requested debug mode.
 145 dnl
 146 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 147   # All these tests are for C++; save the language and the compiler flags.
 148   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 149   # found in GLIBCXX_CONFIGURE.
 150   AC_LANG_SAVE
 151   AC_LANG_CPLUSPLUS
 152   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 153   ac_save_CXXFLAGS="$CXXFLAGS"
 154
 155   # Check for maintainer-mode bits.
 156   if test x"$USE_MAINTAINER_MODE" = xno; then
 157     WERROR=''
 158   else
 159     WERROR='-Werror'
 160   fi
 161
 162   # Check for -ffunction-sections -fdata-sections
 163   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 164   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 165   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 166   if test "$ac_test_CXXFLAGS" = set; then
 167     CXXFLAGS="$ac_save_CXXFLAGS"
 168   else
 169     # this is the suspicious part
 170     CXXFLAGS=''
 171   fi
 172   if test x"$ac_fdsections" = x"yes"; then
 173     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 174   fi
 175   AC_MSG_RESULT($ac_fdsections)
 176
 177   AC_LANG_RESTORE
 178   AC_SUBST(WERROR)
 179   AC_SUBST(SECTION_FLAGS)
 180 ])
 181
 182
 183 dnl
 184 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 185 dnl the native linker is in use, all variables will be defined to something
 186 dnl safe (like an empty string).
 187 dnl
 188 dnl Defines:
 189 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 190 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 191 dnl  LD (as a side effect of testing)
 192 dnl Sets:
 193 dnl  with_gnu_ld
 194 dnl  glibcxx_gnu_ld_version (possibly)
 195 dnl
 196 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 197 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 198 dnl
 199 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 200   # If we're not using GNU ld, then there's no point in even trying these
 201   # tests.  Check for that first.  We should have already tested for gld
 202   # by now (in libtool), but require it now just to be safe...
 203   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 204   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 205   AC_REQUIRE([AC_PROG_LD])
 206   AC_REQUIRE([AC_PROG_AWK])
 207
 208   # The name set by libtool depends on the version of libtool.  Shame on us
 209   # for depending on an impl detail, but c'est la vie.  Older versions used
 210   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 211   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 212   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 213   # set (hence we're using an older libtool), then set it.
 214   if test x${with_gnu_ld+set} != xset; then
 215     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 216       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 217       with_gnu_ld=no
 218     else
 219       with_gnu_ld=$ac_cv_prog_gnu_ld
 220     fi
 221   fi
 222
 223   # Start by getting the version number.  I think the libtool test already
 224   # does some of this, but throws away the result.
 225   AC_MSG_CHECKING([for ld version])
 226   changequote(,)
 227   ldver=`$LD --version 2>/dev/null | head -1 | \
 228          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 229   changequote([,])
 230   glibcxx_gnu_ld_version=`echo $ldver | \
 231          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 232   AC_MSG_RESULT($glibcxx_gnu_ld_version)
 233
 234   # Set --gc-sections.
 235   glibcxx_gcsections_min_ld=21602
 236   if test x"$with_gnu_ld" = x"yes" &&
 237         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 238
 239     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 240     # NB: This flag only works reliably after 2.16.1. Configure tests
 241     # for this are difficult, so hard wire a value that should work.
 242
 243     # All these tests are for C++, but run with the "C" compiler driver.
 244     # Need to do this so that g++ won't try to link in libstdc++/libsupc++.
 245     ac_test_CFLAGS="${CFLAGS+set}"
 246     ac_save_CFLAGS="$CFLAGS"
 247     CFLAGS='-x c++ -Wl,--gc-sections'
 248
 249     # Check for -Wl,--gc-sections
 250     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 251     AC_TRY_LINK([ int one(void) { return 1; }
 252      int two(void) { return 2; }
 253         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 254     if test "$ac_gcsections" = "yes"; then
 255       rm -f conftest.c
 256       touch conftest.c
 257       if $CC -c conftest.c; then
 258         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 259            grep "Warning: gc-sections option ignored" > /dev/null; then
 260           ac_gcsections=no
 261         fi
 262       fi
 263       rm -f conftest.c conftest.o conftest
 264     fi
 265     if test "$ac_gcsections" = "yes"; then
 266       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 267     fi
 268     AC_MSG_RESULT($ac_gcsections)
 269
 270     if test "$ac_test_CFLAGS" = set; then
 271       CFLAGS="$ac_save_CFLAGS"
 272     else
 273       # this is the suspicious part
 274       CFLAGS=''
 275     fi
 276   fi
 277
 278   # Set -z,relro.
 279   # Note this is only for shared objects.
 280   ac_ld_relro=no
 281   if test x"$with_gnu_ld" = x"yes"; then
 282     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 283     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 284     if test -n "$cxx_z_relo"; then
 285       OPT_LDFLAGS="-Wl,-z,relro"
 286       ac_ld_relro=yes
 287     fi
 288     AC_MSG_RESULT($ac_ld_relro)
 289   fi
 290
 291   # Set linker optimization flags.
 292   if test x"$with_gnu_ld" = x"yes"; then
 293     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 294   fi
 295
 296   AC_SUBST(SECTION_LDFLAGS)
 297   AC_SUBST(OPT_LDFLAGS)
 298 ])
 299
 300
 301 dnl
 302 dnl Check to see if this target can enable the iconv specializations.
 303 dnl If --disable-c-mbchar was given, no wchar_t specialization is enabled.
 304 dnl (This must have been previously checked, along with the rest of C99
 305 dnl support.) By default, iconv support is disabled.
 306 dnl
 307 dnl Defines:
 308 dnl  _GLIBCXX_USE_ICONV if all the bits are found.
 309 dnl Substs:
 310 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 311 dnl
 312 AC_DEFUN([GLIBCXX_CHECK_ICONV_SUPPORT], [
 313
 314   enable_iconv=no
 315   # Only continue checking if the ISO C99 headers exist and support is on.
 316   if test x"$enable_wchar_t" = xyes; then
 317
 318     # Use iconv for wchar_t to char conversions. As such, check for
 319     # X/Open Portability Guide, version 2 features (XPG2).
 320     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 321     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 322
 323     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 324     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 325     ac_save_LIBS="$LIBS"
 326     LIBS="$LIBS $LIBICONV"
 327     AC_SUBST(LIBICONV)
 328
 329     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 330     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 331
 332     LIBS="$ac_save_LIBS"
 333
 334     if test x"$ac_has_iconv_h" = xyes &&
 335        test x"$ac_has_langinfo_h" = xyes &&
 336        test x"$ac_XPG2funcs" = xyes;
 337     then
 338       AC_DEFINE([_GLIBCXX_USE_ICONV],1,
 339                 [Define if iconv and related functions exist and are usable.])
 340       enable_iconv=yes
 341     fi
 342   fi
 343   AC_MSG_CHECKING([for enabled iconv specializations])
 344   AC_MSG_RESULT($enable_iconv)
 345 ])
 346
 347
 348 dnl
 349 dnl Check for headers for, and arguments to, the setrlimit() function.
 350 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 351 dnl
 352 dnl Defines:
 353 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 354 dnl  various HAVE_LIMIT_* for individual limit names
 355 dnl
 356 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 357   AC_MSG_CHECKING([for RLIMIT_$1])
 358   AC_TRY_COMPILE(
 359     [#include <unistd.h>
 360      #include <sys/time.h>
 361      #include <sys/resource.h>
 362     ],
 363     [ int f = RLIMIT_$1 ; ],
 364     [glibcxx_mresult=1], [glibcxx_mresult=0])
 365   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 366                      [Only used in build directory testsuite_hooks.h.])
 367   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 368   AC_MSG_RESULT($res)
 369 ])
 370
 371 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 372   setrlimit_have_headers=yes
 373   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 374                    [],
 375                    [setrlimit_have_headers=no])
 376   # If don't have the headers, then we can't run the tests now, and we
 377   # won't be seeing any of these during testsuite compilation.
 378   if test $setrlimit_have_headers = yes; then
 379     # Can't do these in a loop, else the resulting syntax is wrong.
 380     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 381     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 382     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 383     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 384     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 385
 386     # Check for rlimit, setrlimit.
 387     AC_CACHE_VAL(ac_setrlimit, [
 388       AC_TRY_COMPILE(
 389         [#include <unistd.h>
 390          #include <sys/time.h>
 391          #include <sys/resource.h>
 392         ],
 393         [struct rlimit r;
 394          setrlimit(0, &r);],
 395         [ac_setrlimit=yes], [ac_setrlimit=no])
 396     ])
 397   fi
 398
 399   AC_MSG_CHECKING([for testsuite resource limits support])
 400   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 401     ac_res_limits=yes
 402     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 403               [Define if using setrlimit to set resource limits during
 404               "make check"])
 405   else
 406     ac_res_limits=no
 407   fi
 408   AC_MSG_RESULT($ac_res_limits)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 414 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 415 dnl
 416 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 417   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 418   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 419     AC_TRY_LINK(
 420       [#include <sys/stat.h>],
 421       [struct stat buffer;
 422        fstat(0, &buffer);
 423        S_ISREG(buffer.st_mode);],
 424       [glibcxx_cv_S_ISREG=yes],
 425       [glibcxx_cv_S_ISREG=no])
 426   ])
 427   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 428     AC_TRY_LINK(
 429       [#include <sys/stat.h>],
 430       [struct stat buffer;
 431        fstat(0, &buffer);
 432        S_IFREG & buffer.st_mode;],
 433       [glibcxx_cv_S_IFREG=yes],
 434       [glibcxx_cv_S_IFREG=no])
 435   ])
 436   res=no
 437   if test $glibcxx_cv_S_ISREG = yes; then
 438     AC_DEFINE(HAVE_S_ISREG, 1,
 439               [Define if S_IFREG is available in <sys/stat.h>.])
 440     res=S_ISREG
 441   elif test $glibcxx_cv_S_IFREG = yes; then
 442     AC_DEFINE(HAVE_S_IFREG, 1,
 443               [Define if S_IFREG is available in <sys/stat.h>.])
 444     res=S_IFREG
 445   fi
 446   AC_MSG_RESULT($res)
 447 ])
 448
 449
 450 dnl
 451 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 452 dnl
 453 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 454   AC_MSG_CHECKING([for poll])
 455   AC_CACHE_VAL(glibcxx_cv_POLL, [
 456     AC_TRY_LINK(
 457       [#include <poll.h>],
 458       [struct pollfd pfd[1];
 459        pfd[0].events = POLLIN;
 460        poll(pfd, 1, 0);],
 461       [glibcxx_cv_POLL=yes],
 462       [glibcxx_cv_POLL=no])
 463   ])
 464   if test $glibcxx_cv_POLL = yes; then
 465     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 466   fi
 467   AC_MSG_RESULT($glibcxx_cv_POLL)
 468 ])
 469
 470
 471 dnl
 472 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 473 dnl
 474 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 475   AC_MSG_CHECKING([for writev])
 476   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 477     AC_TRY_LINK(
 478       [#include <sys/uio.h>],
 479       [struct iovec iov[2];
 480        writev(0, iov, 0);],
 481       [glibcxx_cv_WRITEV=yes],
 482       [glibcxx_cv_WRITEV=no])
 483   ])
 484   if test $glibcxx_cv_WRITEV = yes; then
 485     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 486   fi
 487   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 488 ])
 489
 490
 491 dnl
 492 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 493 dnl
 494 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 495   AC_MSG_CHECKING([for int64_t])
 496   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 497     AC_TRY_COMPILE(
 498       [#include <stdint.h>],
 499       [int64_t var;],
 500       [glibcxx_cv_INT64_T=yes],
 501       [glibcxx_cv_INT64_T=no])
 502   ])
 503   if test $glibcxx_cv_INT64_T = yes; then
 504     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 505   fi
 506   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether LFS support is available.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 514   AC_LANG_SAVE
 515   AC_LANG_CPLUSPLUS
 516   ac_save_CXXFLAGS="$CXXFLAGS"
 517   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 518   AC_MSG_CHECKING([for LFS support])
 519   AC_CACHE_VAL(glibcxx_cv_LFS, [
 520     AC_TRY_LINK(
 521       [#include <unistd.h>
 522        #include <stdio.h>
 523        #include <sys/stat.h>
 524       ],
 525       [FILE* fp;
 526        fopen64("t", "w");
 527        fseeko64(fp, 0, SEEK_CUR);
 528        ftello64(fp);
 529        lseek64(1, 0, SEEK_CUR);
 530        struct stat64 buf;
 531        fstat64(1, &buf);],
 532       [glibcxx_cv_LFS=yes],
 533       [glibcxx_cv_LFS=no])
 534   ])
 535   if test $glibcxx_cv_LFS = yes; then
 536     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 537   fi
 538   AC_MSG_RESULT($glibcxx_cv_LFS)
 539   CXXFLAGS="$ac_save_CXXFLAGS"
 540   AC_LANG_RESTORE
 541 ])
 542
 543
 544 dnl
 545 dnl Check for whether a fully dynamic basic_string implementation should
 546 dnl be turned on, that does not put empty objects in per-process static
 547 dnl memory (mostly useful together with shared memory allocators, see PR
 548 dnl libstdc++/16612 for details).
 549 dnl
 550 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 551 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 552 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 553 dnl       Where DEFAULT is either `yes' or `no'.
 554 dnl
 555 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 556   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 557   if test $enable_fully_dynamic_string = yes; then
 558     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 559               [Define if a fully dynamic basic_string is wanted.])
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Does any necessary configuration of the testsuite directory.  Generates
 566 dnl the testsuite_hooks.h header.
 567 dnl
 568 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 569 dnl
 570 dnl Sets:
 571 dnl  enable_abi_check
 572 dnl  GLIBCXX_TEST_WCHAR_T
 573 dnl  GLIBCXX_TEST_THREAD
 574 dnl Substs:
 575 dnl  baseline_dir
 576 dnl
 577 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 578   if $GLIBCXX_IS_NATIVE ; then
 579     # Do checks for resource limit functions.
 580     GLIBCXX_CHECK_SETRLIMIT
 581
 582     # Look for setenv, so that extended locale tests can be performed.
 583     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 584   fi
 585
 586   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 587      test $enable_symvers != no; then
 588     case "$host" in
 589       *-*-cygwin*)
 590         enable_abi_check=no ;;
 591       *)
 592         enable_abi_check=yes ;;
 593     esac
 594   else
 595     # Only build this as native, since automake does not understand
 596     # CXX_FOR_BUILD.
 597     enable_abi_check=no
 598   fi
 599
 600   # Export file names for ABI checking.
 601   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 602   AC_SUBST(baseline_dir)
 603 ])
 604
 605
 606 dnl
 607 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 608 dnl
 609 dnl Substs:
 610 dnl  GLIBCXX_INCLUDES
 611 dnl  TOPLEVEL_INCLUDES
 612 dnl
 613 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 614   # Used for every C++ compile we perform.
 615   GLIBCXX_INCLUDES="\
 616 -I$glibcxx_builddir/include/$host_alias \
 617 -I$glibcxx_builddir/include \
 618 -I$glibcxx_srcdir/libsupc++"
 619
 620   # For Canadian crosses, pick this up too.
 621   if test $CANADIAN = yes; then
 622     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 623   fi
 624
 625   # Stuff in the actual top level.  Currently only used by libsupc++ to
 626   # get unwind* headers from the gcc dir.
 627   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 628   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 629
 630   # Now, export this to all the little Makefiles....
 631   AC_SUBST(GLIBCXX_INCLUDES)
 632   AC_SUBST(TOPLEVEL_INCLUDES)
 633 ])
 634
 635
 636 dnl
 637 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 638 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 639 dnl
 640 dnl Substs:
 641 dnl  OPTIMIZE_CXXFLAGS
 642 dnl  WARN_FLAGS
 643 dnl
 644 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 645   # Optimization flags that are probably a good idea for thrill-seekers. Just
 646   # uncomment the lines below and make, everything else is ready to go...
 647   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 648   OPTIMIZE_CXXFLAGS=
 649   AC_SUBST(OPTIMIZE_CXXFLAGS)
 650
 651   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 652   AC_SUBST(WARN_FLAGS)
 653 ])
 654
 655
 656 dnl
 657 dnl All installation directory information is determined here.
 658 dnl
 659 dnl Substs:
 660 dnl  gxx_install_dir
 661 dnl  glibcxx_prefixdir
 662 dnl  glibcxx_toolexecdir
 663 dnl  glibcxx_toolexeclibdir
 664 dnl
 665 dnl Assumes cross_compiling bits already done, and with_cross_host in
 666 dnl particular.
 667 dnl
 668 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 669   glibcxx_toolexecdir=no
 670   glibcxx_toolexeclibdir=no
 671   glibcxx_prefixdir=$prefix
 672
 673   AC_MSG_CHECKING([for gxx-include-dir])
 674   AC_ARG_WITH([gxx-include-dir],
 675     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 676                    [installation directory for include files]),
 677     [case "$withval" in
 678       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 679       no)  gxx_include_dir=no ;;
 680       *)   gxx_include_dir=$withval ;;
 681      esac],
 682     [gxx_include_dir=no])
 683   AC_MSG_RESULT($gxx_include_dir)
 684
 685   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 686   AC_ARG_ENABLE([version-specific-runtime-libs],
 687     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 688                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 689     [case "$enableval" in
 690       yes) version_specific_libs=yes ;;
 691       no)  version_specific_libs=no ;;
 692       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 693      esac],
 694     [version_specific_libs=no])
 695   AC_MSG_RESULT($version_specific_libs)
 696
 697   # Default case for install directory for include files.
 698   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 699     gxx_include_dir='${prefix}/include/c++/${gcc_version}'
 700   fi
 701
 702   # Version-specific runtime libs processing.
 703   if test $version_specific_libs = yes; then
 704     # Need the gcc compiler version to know where to install libraries
 705     # and header files if --enable-version-specific-runtime-libs option
 706     # is selected.  FIXME: these variables are misnamed, there are
 707     # no executables installed in _toolexecdir or _toolexeclibdir.
 708     if test x"$gxx_include_dir" = x"no"; then
 709       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 710     fi
 711     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 712     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 713   fi
 714
 715   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 716   # Install a library built with a cross compiler in tooldir, not libdir.
 717   if test x"$glibcxx_toolexecdir" = x"no"; then
 718     if test -n "$with_cross_host" &&
 719        test x"$with_cross_host" != x"no"; then
 720       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 721       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 722     else
 723       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 724       glibcxx_toolexeclibdir='${libdir}'
 725     fi
 726     multi_os_directory=`$CXX -print-multi-os-directory`
 727     case $multi_os_directory in
 728       .) ;; # Avoid trailing /.
 729       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 730     esac
 731   fi
 732
 733   AC_MSG_CHECKING([for install location])
 734   AC_MSG_RESULT($gxx_include_dir)
 735
 736   AC_SUBST(glibcxx_prefixdir)
 737   AC_SUBST(gxx_include_dir)
 738   AC_SUBST(glibcxx_toolexecdir)
 739   AC_SUBST(glibcxx_toolexeclibdir)
 740 ])
 741
 742
 743 dnl
 744 dnl GLIBCXX_ENABLE
 745 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 746 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 747 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 748 dnl
 749 dnl See docs/html/17_intro/configury.html#enable for documentation.
 750 dnl
 751 m4_define([GLIBCXX_ENABLE],[dnl
 752 m4_define([_g_switch],[--enable-$1])dnl
 753 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 754  AC_ARG_ENABLE($1,_g_help,
 755   m4_bmatch([$5],
 756    [^permit ],
 757      [[
 758       case "$enableval" in
 759        m4_bpatsubst([$5],[permit ])) ;;
 760        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 761           dnl Idea for future:  generate a URL pointing to
 762           dnl "onlinedocs/configopts.html#whatever"
 763       esac
 764      ]],
 765    [^$],
 766      [[
 767       case "$enableval" in
 768        yes|no) ;;
 769        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 770       esac
 771      ]],
 772    [[$5]]),
 773   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 774 m4_undefine([_g_switch])dnl
 775 m4_undefine([_g_help])dnl
 776 ])
 777
 778
 779 dnl
 780 dnl Check for ISO/IEC 9899:1999 "C99" support.
 781 dnl
 782 dnl --enable-c99 defines _GLIBCXX_USE_C99
 783 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 784 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 785 dnl       Where DEFAULT is either `yes' or `no'.
 786 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 787 dnl
 788 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 789   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 790
 791   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos
 792   # even if C99 support is turned off.
 793   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 794   AC_MSG_CHECKING([for mbstate_t])
 795   AC_TRY_COMPILE([#include <wchar.h>],
 796   [mbstate_t teststate;],
 797   have_mbstate_t=yes, have_mbstate_t=no)
 798   AC_MSG_RESULT($have_mbstate_t)
 799   if test x"$have_mbstate_t" = xyes; then
 800     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 801   fi
 802
 803   if test x"$enable_c99" = x"yes"; then
 804
 805   AC_LANG_SAVE
 806   AC_LANG_CPLUSPLUS
 807
 808   # Check for the existence of <math.h> functions used if C99 is enabled.
 809   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 810   AC_CACHE_VAL(ac_c99_math, [
 811   AC_TRY_COMPILE([#include <math.h>],
 812                  [fpclassify(0.0);
 813                   isfinite(0.0);
 814                   isinf(0.0);
 815                   isnan(0.0);
 816                   isnormal(0.0);
 817                   signbit(0.0);
 818                   isgreater(0.0,0.0);
 819                   isgreaterequal(0.0,0.0);
 820                   isless(0.0,0.0);
 821                   islessequal(0.0,0.0);
 822                   islessgreater(0.0,0.0);
 823                   islessgreater(0.0,0.0);
 824                   isunordered(0.0,0.0);
 825                  ],[ac_c99_math=yes], [ac_c99_math=no])
 826   ])
 827   AC_MSG_RESULT($ac_c99_math)
 828   if test x"$ac_c99_math" = x"yes"; then
 829     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 830               [Define if C99 functions or macros in <math.h> should be imported
 831               in <cmath> in namespace std.])
 832   fi
 833
 834   # Check for the existence of <complex.h> complex math functions.
 835   # This is necessary even though libstdc++ uses the builtin versions
 836   # of these functions, because if the builtin cannot be used, a reference
 837   # to the library function is emitted.
 838   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 839   ac_c99_complex=no;
 840   if test x"$ac_has_complex_h" = x"yes"; then
 841     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 842     AC_TRY_COMPILE([#include <complex.h>],
 843                    [typedef __complex__ float float_type; float_type tmpf;
 844                     cabsf(tmpf);
 845                     cargf(tmpf);
 846                     ccosf(tmpf);
 847                     ccoshf(tmpf);
 848                     cexpf(tmpf);
 849                     clogf(tmpf);
 850                     csinf(tmpf);
 851                     csinhf(tmpf);
 852                     csqrtf(tmpf);
 853                     ctanf(tmpf);
 854                     ctanhf(tmpf);
 855                     cpowf(tmpf, tmpf);
 856                     typedef __complex__ double double_type; double_type tmpd;
 857                     cabs(tmpd);
 858                     carg(tmpd);
 859                     ccos(tmpd);
 860                     ccosh(tmpd);
 861                     cexp(tmpd);
 862                     clog(tmpd);
 863                     csin(tmpd);
 864                     csinh(tmpd);
 865                     csqrt(tmpd);
 866                     ctan(tmpd);
 867                     ctanh(tmpd);
 868                     cpow(tmpd, tmpd);
 869                     typedef __complex__ long double ld_type; ld_type tmpld;
 870                     cabsl(tmpld);
 871                     cargl(tmpld);
 872                     ccosl(tmpld);
 873                     ccoshl(tmpld);
 874                     cexpl(tmpld);
 875                     clogl(tmpld);
 876                     csinl(tmpld);
 877                     csinhl(tmpld);
 878                     csqrtl(tmpld);
 879                     ctanl(tmpld);
 880                     ctanhl(tmpld);
 881                     cpowl(tmpld, tmpld);
 882                    ],[ac_c99_complex=yes], [ac_c99_complex=no])
 883   fi
 884   AC_MSG_RESULT($ac_c99_complex)
 885   if test x"$ac_c99_complex" = x"yes"; then
 886     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 887               [Define if C99 functions in <complex.h> should be used in
 888               <complex>. Using compiler builtins for these functions requires
 889               corresponding C99 library functions to be present.])
 890   fi
 891
 892   # Check for the existence in <stdio.h> of vscanf, et. al.
 893   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 894   AC_CACHE_VAL(ac_c99_stdio, [
 895   AC_TRY_COMPILE([#include <stdio.h>
 896                   #include <stdarg.h>
 897                   void foo(char* fmt, ...)
 898                   {
 899                     va_list args; va_start(args, fmt);
 900                     vfscanf(stderr, "%i", args);
 901                     vscanf("%i", args);
 902                     vsnprintf(fmt, 0, "%i", args);
 903                     vsscanf(fmt, "%i", args);
 904                   }],
 905                  [snprintf("12", 0, "%i");],
 906                  [ac_c99_stdio=yes], [ac_c99_stdio=no])
 907   ])
 908   AC_MSG_RESULT($ac_c99_stdio)
 909
 910   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 911   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 912   AC_CACHE_VAL(ac_c99_stdlib, [
 913   AC_TRY_COMPILE([#include <stdlib.h>],
 914                  [char* tmp;
 915                   strtof("gnu", &tmp);
 916                   strtold("gnu", &tmp);
 917                   strtoll("gnu", &tmp, 10);
 918                   strtoull("gnu", &tmp, 10);
 919                   llabs(10);
 920                   lldiv(10,1);
 921                   atoll("10");
 922                   _Exit(0);
 923                   lldiv_t mydivt;],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 924   ])
 925   AC_MSG_RESULT($ac_c99_stdlib)
 926
 927   # Check for the existence in <wchar.h> of wcstoull, WEOF, etc.
 928   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 929   ac_c99_wchar=no;
 930   if test x"$ac_has_wchar_h" = xyes &&
 931      test x"$ac_has_wctype_h" = xyes; then
 932     AC_TRY_COMPILE([#include <wchar.h>
 933                     #include <stddef.h>
 934                     wint_t i;
 935                     long l = WEOF;
 936                     long j = WCHAR_MIN;
 937                     long k = WCHAR_MAX;
 938                     namespace test
 939                     {
 940                       using ::btowc;
 941                       using ::fgetwc;
 942                       using ::fgetws;
 943                       using ::fputwc;
 944                       using ::fputws;
 945                       using ::fwide;
 946                       using ::fwprintf;
 947                       using ::fwscanf;
 948                       using ::getwc;
 949                       using ::getwchar;
 950                       using ::mbrlen;
 951                       using ::mbrtowc;
 952                       using ::mbsinit;
 953                       using ::mbsrtowcs;
 954                       using ::putwc;
 955                       using ::putwchar;
 956                       using ::swprintf;
 957                       using ::swscanf;
 958                       using ::ungetwc;
 959                       using ::vfwprintf;
 960                       using ::vswprintf;
 961                       using ::vwprintf;
 962                       using ::wcrtomb;
 963                       using ::wcscat;
 964                       using ::wcschr;
 965                       using ::wcscmp;
 966                       using ::wcscoll;
 967                       using ::wcscpy;
 968                       using ::wcscspn;
 969                       using ::wcsftime;
 970                       using ::wcslen;
 971                       using ::wcsncat;
 972                       using ::wcsncmp;
 973                       using ::wcsncpy;
 974                       using ::wcspbrk;
 975                       using ::wcsrchr;
 976                       using ::wcsrtombs;
 977                       using ::wcsspn;
 978                       using ::wcsstr;
 979                       using ::wcstod;
 980                       using ::wcstok;
 981                       using ::wcstol;
 982                       using ::wcstold;
 983                       using ::wcstoll;
 984                       using ::wcstoul;
 985                       using ::wcstoull;
 986                       using ::wcsxfrm;
 987                       using ::wctob;
 988                       using ::wmemchr;
 989                       using ::wmemcmp;
 990                       using ::wmemcpy;
 991                       using ::wmemmove;
 992                       using ::wmemset;
 993                       using ::wprintf;
 994                       using ::wscanf;
 995                     }
 996                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 997
 998     # Checks for wide character functions that may not be present.
 999     # Injection of these is wrapped with guard macros.
1000     # NB: only put functions here, instead of immediately above, if
1001     # absolutely necessary.
1002     AC_TRY_COMPILE([#include <wchar.h>
1003                     namespace test { using ::vfwscanf; } ], [],
1004                    [AC_DEFINE(HAVE_VFWSCANF,1,
1005                         [Defined if vfwscanf exists.])],[])
1006
1007     AC_TRY_COMPILE([#include <wchar.h>
1008                     namespace test { using ::vswscanf; } ], [],
1009                    [AC_DEFINE(HAVE_VSWSCANF,1,
1010                         [Defined if vswscanf exists.])],[])
1011
1012     AC_TRY_COMPILE([#include <wchar.h>
1013                     namespace test { using ::vwscanf; } ], [],
1014                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1015
1016     AC_TRY_COMPILE([#include <wchar.h>
1017                     namespace test { using ::wcstof; } ], [],
1018                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1019
1020     AC_TRY_COMPILE([#include <wctype.h>],
1021                    [ wint_t t; int i = iswblank(t);],
1022                    [AC_DEFINE(HAVE_ISWBLANK,1,
1023                         [Defined if iswblank exists.])],[])
1024
1025     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1026     AC_MSG_RESULT($ac_c99_wchar)
1027   fi
1028
1029   # Option parsed, now set things appropriately.
1030   if test x"$ac_c99_math" = x"no" ||
1031      test x"$ac_c99_complex" = x"no" ||
1032      test x"$ac_c99_stdio" = x"no" ||
1033      test x"$ac_c99_stdlib" = x"no" ||
1034      test x"$ac_c99_wchar" = x"no"; then
1035     enable_c99=no;
1036   else
1037     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1038     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1039     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1040   fi
1041
1042   AC_LANG_RESTORE
1043   fi
1044
1045   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1046   AC_MSG_RESULT($enable_c99)
1047 ])
1048
1049
1050 dnl
1051 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1052 dnl facilities in Chapter 8, "C compatibility".
1053 dnl
1054 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1055
1056   AC_LANG_SAVE
1057   AC_LANG_CPLUSPLUS
1058
1059   # Check for the existence of <complex.h> complex math functions used
1060   # by tr1/complex.
1061   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1062   ac_c99_complex_tr1=no;
1063   if test x"$ac_has_complex_h" = x"yes"; then
1064     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1065     AC_TRY_COMPILE([#include <complex.h>],
1066                    [typedef __complex__ float float_type; float_type tmpf;
1067                     cacosf(tmpf);
1068                     casinf(tmpf);
1069                     catanf(tmpf);
1070                     cacoshf(tmpf);
1071                     casinhf(tmpf);
1072                     catanhf(tmpf);
1073                     typedef __complex__ double double_type; double_type tmpd;
1074                     cacos(tmpd);
1075                     casin(tmpd);
1076                     catan(tmpd);
1077                     cacosh(tmpd);
1078                     casinh(tmpd);
1079                     catanh(tmpd);
1080                     typedef __complex__ long double ld_type; ld_type tmpld;
1081                     cacosl(tmpld);
1082                     casinl(tmpld);
1083                     catanl(tmpld);
1084                     cacoshl(tmpld);
1085                     casinhl(tmpld);
1086                     catanhl(tmpld);
1087                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1088   fi
1089   AC_MSG_RESULT($ac_c99_complex_tr1)
1090   if test x"$ac_c99_complex_tr1" = x"yes"; then
1091     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1092               [Define if C99 functions in <complex.h> should be used in
1093               <tr1/complex>. Using compiler builtins for these functions
1094               requires corresponding C99 library functions to be present.])
1095   fi
1096
1097   # Check for the existence of <ctype.h> functions.
1098   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1099   AC_CACHE_VAL(ac_c99_ctype_tr1, [
1100   AC_TRY_COMPILE([#include <ctype.h>],
1101                  [int ch;
1102                   int ret;
1103                   ret = isblank(ch);
1104                  ],[ac_c99_ctype_tr1=yes], [ac_c99_ctype_tr1=no])
1105   ])
1106   AC_MSG_RESULT($ac_c99_ctype_tr1)
1107   if test x"$ac_c99_ctype_tr1" = x"yes"; then
1108     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1109               [Define if C99 functions in <ctype.h> should be imported in
1110               <tr1/cctype> in namespace std::tr1.])
1111   fi
1112
1113   # Check for the existence of <fenv.h> functions.
1114   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1115   ac_c99_fenv_tr1=no;
1116   if test x"$ac_has_fenv_h" = x"yes"; then
1117     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1118     AC_TRY_COMPILE([#include <fenv.h>],
1119                    [int except, mode;
1120                     fexcept_t* pflag;
1121                     fenv_t* penv;
1122                     int ret;
1123                     ret = feclearexcept(except);
1124                     ret = fegetexceptflag(pflag, except);
1125                     ret = feraiseexcept(except);
1126                     ret = fesetexceptflag(pflag, except);
1127                     ret = fetestexcept(except);
1128                     ret = fegetround();
1129                     ret = fesetround(mode);
1130                     ret = fegetenv(penv);
1131                     ret = feholdexcept(penv);
1132                     ret = fesetenv(penv);
1133                     ret = feupdateenv(penv);
1134                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1135   fi
1136   AC_MSG_RESULT($ac_c99_fenv_tr1)
1137   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1138     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1139               [Define if C99 functions in <fenv.h> should be imported in
1140               <tr1/cfenv> in namespace std::tr1.])
1141   fi
1142
1143   # Check for the existence of <stdint.h> types.
1144   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1145   AC_CACHE_VAL(ac_c99_stdint_tr1, [
1146   AC_TRY_COMPILE([#include <stdint.h>],
1147                  [typedef int8_t          my_int8_t;
1148                   typedef int16_t         my_int16_t;
1149                   typedef int32_t         my_int32_t;
1150                   typedef int64_t         my_int64_t;
1151                   typedef int_fast8_t     my_int_fast8_t;
1152                   typedef int_fast16_t    my_int_fast16_t;
1153                   typedef int_fast32_t    my_int_fast32_t;
1154                   typedef int_fast64_t    my_int_fast64_t;
1155                   typedef int_least8_t    my_int_least8_t;
1156                   typedef int_least16_t   my_int_least16_t;
1157                   typedef int_least32_t   my_int_least32_t;
1158                   typedef int_least64_t   my_int_least64_t;
1159                   typedef intmax_t        my_intmax_t;
1160                   typedef intptr_t        my_intptr_t;
1161                   typedef uint8_t         my_uint8_t;
1162                   typedef uint16_t        my_uint16_t;
1163                   typedef uint32_t        my_uint32_t;
1164                   typedef uint64_t        my_uint64_t;
1165                   typedef uint_fast8_t    my_uint_fast8_t;
1166                   typedef uint_fast16_t   my_uint_fast16_t;
1167                   typedef uint_fast32_t   my_uint_fast32_t;
1168                   typedef uint_fast64_t   my_uint_fast64_t;
1169                   typedef uint_least8_t   my_uint_least8_t;
1170                   typedef uint_least16_t  my_uint_least16_t;
1171                   typedef uint_least32_t  my_uint_least32_t;
1172                   typedef uint_least64_t  my_uint_least64_t;
1173                   typedef uintmax_t       my_uintmax_t;
1174                   typedef uintptr_t       my_uintptr_t;
1175                  ],[ac_c99_stdint_tr1=yes], [ac_c99_stdint_tr1=no])
1176   ])
1177   AC_MSG_RESULT($ac_c99_stdint_tr1)
1178   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1179     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1180               [Define if C99 types in <stdint.h> should be imported in
1181               <tr1/cstdint> in namespace std::tr1.])
1182   fi
1183
1184   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1185   # sense if the previous check fails, per C99, 7.8/1).
1186   ac_c99_inttypes_tr1=no;
1187   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1188     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1189     AC_TRY_COMPILE([#include <inttypes.h>],
1190                    [intmax_t i, numer, denom, base;
1191                     const char* s;
1192                     char** endptr;
1193                     intmax_t ret = imaxabs(i);
1194                     imaxdiv_t dret = imaxdiv(numer, denom);
1195                     ret = strtoimax(s, endptr, base);
1196                     uintmax_t uret = strtoumax(s, endptr, base);
1197                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1198   fi
1199   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1200   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1201     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1202               [Define if C99 functions in <inttypes.h> should be imported in
1203               <tr1/cinttypes> in namespace std::tr1.])
1204   fi
1205
1206   AC_LANG_RESTORE
1207 ])
1208
1209
1210 dnl
1211 dnl Check for what type of C headers to use.
1212 dnl
1213 dnl --enable-cheaders= [does stuff].
1214 dnl --disable-cheaders [does not do anything, really].
1215 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1216 dnl       Where DEFAULT is either `c' or `c_std'.
1217 dnl
1218 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1219   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1220     [construct "C" headers for g++], [permit c|c_std])
1221   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1222
1223   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1224
1225   AC_SUBST(C_INCLUDE_DIR)
1226   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1227   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1228   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1229 ])
1230
1231
1232 dnl
1233 dnl Check for which locale library to use.  The choice is mapped to
1234 dnl a subdirectory of config/locale.
1235 dnl
1236 dnl Default is generic.
1237 dnl
1238 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1239   AC_MSG_CHECKING([for C locale to use])
1240   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1241     [use MODEL for target locale package],
1242     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1243
1244   # If they didn't use this option switch, or if they specified --enable
1245   # with no specific model, we'll have to look for one.  If they
1246   # specified --disable (???), do likewise.
1247   if test $enable_clocale = no || test $enable_clocale = yes; then
1248      enable_clocale=auto
1249   fi
1250
1251   # Either a known package, or "auto"
1252   enable_clocale_flag=$enable_clocale
1253
1254   # Probe for locale support if no specific model is specified.
1255   # Default to "generic".
1256   if test $enable_clocale_flag = auto; then
1257     case ${target_os} in
1258       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1259         AC_EGREP_CPP([_GLIBCXX_ok], [
1260         #include <features.h>
1261         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1262           _GLIBCXX_ok
1263         #endif
1264         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1265
1266         # Test for bugs early in glibc-2.2.x series
1267           if test $enable_clocale_flag = gnu; then
1268           AC_TRY_RUN([
1269           #define _GNU_SOURCE 1
1270           #include <locale.h>
1271           #include <string.h>
1272           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1273           extern __typeof(newlocale) __newlocale;
1274           extern __typeof(duplocale) __duplocale;
1275           extern __typeof(strcoll_l) __strcoll_l;
1276           #endif
1277           int main()
1278           {
1279               const char __one[] = "Äuglein Augmen";
1280               const char __two[] = "Äuglein";
1281               int i;
1282               int j;
1283               __locale_t        loc;
1284                __locale_t        loc_dup;
1285               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1286               loc_dup = __duplocale(loc);
1287               i = __strcoll_l(__one, __two, loc);
1288               j = __strcoll_l(__one, __two, loc_dup);
1289               return 0;
1290           }
1291           ],
1292           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1293           [enable_clocale_flag=generic])
1294           fi
1295
1296         # ... at some point put __strxfrm_l tests in as well.
1297         ;;
1298       darwin* | freebsd*)
1299         enable_clocale_flag=darwin
1300         ;;
1301       *)
1302         enable_clocale_flag=generic
1303         ;;
1304     esac
1305   fi
1306
1307   # Deal with gettext issues.  Default to not using it (=no) until we detect
1308   # support for it later.  Let the user turn it off via --e/d, but let that
1309   # default to on for easier handling.
1310   USE_NLS=no
1311   AC_ARG_ENABLE(nls,
1312     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1313     [],
1314     [enable_nls=yes])
1315
1316   # Set configure bits for specified locale package
1317   case ${enable_clocale_flag} in
1318     generic)
1319       AC_MSG_RESULT(generic)
1320
1321       CLOCALE_H=config/locale/generic/c_locale.h
1322       CLOCALE_CC=config/locale/generic/c_locale.cc
1323       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1324       CCOLLATE_CC=config/locale/generic/collate_members.cc
1325       CCTYPE_CC=config/locale/generic/ctype_members.cc
1326       CMESSAGES_H=config/locale/generic/messages_members.h
1327       CMESSAGES_CC=config/locale/generic/messages_members.cc
1328       CMONEY_CC=config/locale/generic/monetary_members.cc
1329       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1330       CTIME_H=config/locale/generic/time_members.h
1331       CTIME_CC=config/locale/generic/time_members.cc
1332       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1333       ;;
1334     darwin)
1335       AC_MSG_RESULT(darwin or freebsd)
1336
1337       CLOCALE_H=config/locale/generic/c_locale.h
1338       CLOCALE_CC=config/locale/generic/c_locale.cc
1339       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1340       CCOLLATE_CC=config/locale/generic/collate_members.cc
1341       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1342       CMESSAGES_H=config/locale/generic/messages_members.h
1343       CMESSAGES_CC=config/locale/generic/messages_members.cc
1344       CMONEY_CC=config/locale/generic/monetary_members.cc
1345       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1346       CTIME_H=config/locale/generic/time_members.h
1347       CTIME_CC=config/locale/generic/time_members.cc
1348       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1349       ;;
1350
1351     gnu)
1352       AC_MSG_RESULT(gnu)
1353
1354       # Declare intention to use gettext, and add support for specific
1355       # languages.
1356       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1357       ALL_LINGUAS="de fr"
1358
1359       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1360       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1361       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1362         USE_NLS=yes
1363       fi
1364       # Export the build objects.
1365       for ling in $ALL_LINGUAS; do \
1366         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1367         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1368       done
1369       AC_SUBST(glibcxx_MOFILES)
1370       AC_SUBST(glibcxx_POFILES)
1371
1372       CLOCALE_H=config/locale/gnu/c_locale.h
1373       CLOCALE_CC=config/locale/gnu/c_locale.cc
1374       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1375       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1376       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1377       CMESSAGES_H=config/locale/gnu/messages_members.h
1378       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1379       CMONEY_CC=config/locale/gnu/monetary_members.cc
1380       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1381       CTIME_H=config/locale/gnu/time_members.h
1382       CTIME_CC=config/locale/gnu/time_members.cc
1383       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1384       ;;
1385     ieee_1003.1-2001)
1386       AC_MSG_RESULT(IEEE 1003.1)
1387
1388       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1389       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1390       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1391       CCOLLATE_CC=config/locale/generic/collate_members.cc
1392       CCTYPE_CC=config/locale/generic/ctype_members.cc
1393       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1394       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1395       CMONEY_CC=config/locale/generic/monetary_members.cc
1396       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1397       CTIME_H=config/locale/generic/time_members.h
1398       CTIME_CC=config/locale/generic/time_members.cc
1399       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1400       ;;
1401   esac
1402
1403   # This is where the testsuite looks for locale catalogs, using the
1404   # -DLOCALEDIR define during testsuite compilation.
1405   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1406   AC_SUBST(glibcxx_localedir)
1407
1408   # A standalone libintl (e.g., GNU libintl) may be in use.
1409   if test $USE_NLS = yes; then
1410     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1411     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1412   fi
1413   if test $USE_NLS = yes; then
1414     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1415               [Define if NLS translations are to be used.])
1416   fi
1417
1418   AC_SUBST(USE_NLS)
1419   AC_SUBST(CLOCALE_H)
1420   AC_SUBST(CMESSAGES_H)
1421   AC_SUBST(CCODECVT_CC)
1422   AC_SUBST(CCOLLATE_CC)
1423   AC_SUBST(CCTYPE_CC)
1424   AC_SUBST(CMESSAGES_CC)
1425   AC_SUBST(CMONEY_CC)
1426   AC_SUBST(CNUMERIC_CC)
1427   AC_SUBST(CTIME_H)
1428   AC_SUBST(CTIME_CC)
1429   AC_SUBST(CLOCALE_CC)
1430   AC_SUBST(CLOCALE_INTERNAL_H)
1431 ])
1432
1433
1434 dnl
1435 dnl Check for which std::allocator base class to use.  The choice is
1436 dnl mapped from a subdirectory of include/ext.
1437 dnl
1438 dnl Default is new.
1439 dnl
1440 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1441   AC_MSG_CHECKING([for std::allocator base class])
1442   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1443     [use KIND for target std::allocator base],
1444     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1445
1446   # If they didn't use this option switch, or if they specified --enable
1447   # with no specific model, we'll have to look for one.  If they
1448   # specified --disable (???), do likewise.
1449   if test $enable_libstdcxx_allocator = no ||
1450      test $enable_libstdcxx_allocator = yes;
1451   then
1452      enable_libstdcxx_allocator=auto
1453   fi
1454
1455   # Either a known package, or "auto". Auto implies the default choice
1456   # for a particular platform.
1457   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1458
1459   # Probe for host-specific support if no specific model is specified.
1460   # Default to "new".
1461   if test $enable_libstdcxx_allocator_flag = auto; then
1462     case ${target_os} in
1463       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1464         enable_libstdcxx_allocator_flag=new
1465         ;;
1466       *)
1467         enable_libstdcxx_allocator_flag=new
1468         ;;
1469     esac
1470   fi
1471   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1472
1473
1474   # Set configure bits for specified locale package
1475   case ${enable_libstdcxx_allocator_flag} in
1476     bitmap)
1477       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1478       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1479       ;;
1480     malloc)
1481       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1482       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1483       ;;
1484     mt)
1485       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1486       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1487       ;;
1488     new)
1489       ALLOCATOR_H=config/allocator/new_allocator_base.h
1490       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1491       ;;
1492     pool)
1493       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1494       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1495       ;;
1496   esac
1497
1498   AC_SUBST(ALLOCATOR_H)
1499   AC_SUBST(ALLOCATOR_NAME)
1500 ])
1501
1502
1503 dnl
1504 dnl Check for whether the Boost-derived checks should be turned on.
1505 dnl
1506 dnl --enable-concept-checks turns them on.
1507 dnl --disable-concept-checks leaves them off.
1508 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1509 dnl       Where DEFAULT is either `yes' or `no'.
1510 dnl
1511 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1512   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1513   if test $enable_concept_checks = yes; then
1514     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1515               [Define to use concept checking code from the boost libraries.])
1516   fi
1517 ])
1518
1519
1520 dnl
1521 dnl Check for which I/O library to use:  stdio, or something specific.
1522 dnl
1523 dnl Default is stdio.
1524 dnl
1525 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1526   AC_MSG_CHECKING([for underlying I/O to use])
1527   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1528     [use target-specific I/O package], [permit stdio])
1529
1530   # Now that libio has been removed, you can have any color you want as long
1531   # as it's black.  This is one big no-op until other packages are added, but
1532   # showing the framework never hurts.
1533   case ${enable_cstdio} in
1534     stdio)
1535       CSTDIO_H=config/io/c_io_stdio.h
1536       BASIC_FILE_H=config/io/basic_file_stdio.h
1537       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1538       AC_MSG_RESULT(stdio)
1539       ;;
1540   esac
1541
1542   AC_SUBST(CSTDIO_H)
1543   AC_SUBST(BASIC_FILE_H)
1544   AC_SUBST(BASIC_FILE_CC)
1545 ])
1546
1547
1548 dnl
1549 dnl Check for "unusual" flags to pass to the compiler while building.
1550 dnl
1551 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1552 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1553 dnl --disable-cxx-flags passes nothing.
1554 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1555 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1556 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1557 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1558 dnl       If "default flags" is an empty string, the effect is the same
1559 dnl       as --disable or --enable=no.
1560 dnl
1561 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1562   AC_MSG_CHECKING([for extra compiler flags for building])
1563   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1564     [pass compiler FLAGS when building library],
1565     [case "x$enable_cxx_flags" in
1566       xno | x)   enable_cxx_flags= ;;
1567       x-*)       ;;
1568       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1569      esac])
1570
1571   # Run through flags (either default or command-line) and set anything
1572   # extra (e.g., #defines) that must accompany particular g++ options.
1573   if test -n "$enable_cxx_flags"; then
1574     for f in $enable_cxx_flags; do
1575       case "$f" in
1576         -fhonor-std)  ;;
1577         -*)  ;;
1578         *)   # and we're trying to pass /what/ exactly?
1579              AC_MSG_ERROR([compiler flags start with a -]) ;;
1580       esac
1581     done
1582   fi
1583
1584   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1585   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1586   AC_SUBST(EXTRA_CXX_FLAGS)
1587 ])
1588
1589
1590 dnl
1591 dnl Check to see if debugging libraries are to be built.
1592 dnl
1593 dnl --enable-libstdcxx-debug
1594 dnl builds a separate set of debugging libraries in addition to the
1595 dnl normal (shared, static) libstdc++ binaries.
1596 dnl
1597 dnl --disable-libstdcxx-debug
1598 dnl builds only one (non-debug) version of libstdc++.
1599 dnl
1600 dnl --enable-libstdcxx-debug-flags=FLAGS
1601 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1602 dnl
1603 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1604 dnl       Where DEFAULT is either `yes' or `no'.
1605 dnl
1606 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1607   AC_MSG_CHECKING([for additional debug build])
1608   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1609   AC_MSG_RESULT($enable_libstdcxx_debug)
1610   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1611 ])
1612
1613
1614 dnl
1615 dnl Check for explicit debug flags.
1616 dnl
1617 dnl --enable-libstdcxx-debug-flags='-O1'
1618 dnl is a general method for passing flags to be used when
1619 dnl building debug libraries with --enable-debug.
1620 dnl
1621 dnl --disable-libstdcxx-debug-flags does nothing.
1622 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1623 dnl       If "default flags" is an empty string, the effect is the same
1624 dnl       as --disable or --enable=no.
1625 dnl
1626 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1627   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1628     [pass compiler FLAGS when building debug library],
1629     [case "x$enable_libstdcxx_debug_flags" in
1630       xno | x)    enable_libstdcxx_debug_flags= ;;
1631       x-*)        ;;
1632       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1633      esac])
1634
1635   # Option parsed, now set things appropriately
1636   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1637   AC_SUBST(DEBUG_FLAGS)
1638
1639   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1640 ])
1641
1642
1643 dnl
1644 dnl Check if the user only wants a freestanding library implementation.
1645 dnl
1646 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1647 dnl installing only the headers required by [17.4.1.3] and the language
1648 dnl support library.  More than that will be built (to keep the Makefiles
1649 dnl conveniently clean), but not installed.
1650 dnl
1651 dnl Sets:
1652 dnl  is_hosted  (yes/no)
1653 dnl
1654 dnl Defines:
1655 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1656 dnl
1657 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1658   AC_ARG_ENABLE([hosted-libstdcxx],
1659     AC_HELP_STRING([--disable-hosted-libstdcxx],
1660                    [only build freestanding C++ runtime support]),,
1661     [case "$host" in
1662         arm*-*-symbianelf*)
1663             enable_hosted_libstdcxx=no
1664             ;;
1665         *)
1666             enable_hosted_libstdcxx=yes
1667             ;;
1668      esac])
1669   if test "$enable_hosted_libstdcxx" = no; then
1670     AC_MSG_NOTICE([Only freestanding libraries will be built])
1671     is_hosted=no
1672     hosted_define=0
1673     enable_abi_check=no
1674     enable_libstdcxx_pch=no
1675   else
1676     is_hosted=yes
1677     hosted_define=1
1678   fi
1679   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1680   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1681     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1682 ])
1683
1684
1685 dnl
1686 dnl Check for template specializations for the 'long long' type.
1687 dnl The result determines only whether 'long long' I/O is enabled; things
1688 dnl like numeric_limits<> specializations are always available.
1689 dnl
1690 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1691 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1692 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1693 dnl       Where DEFAULT is either `yes' or `no'.
1694 dnl
1695 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1696   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1697   if test $enable_long_long = yes; then
1698     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
1699               [Define if code specialized for long long should be used.])
1700   fi
1701   AC_MSG_CHECKING([for enabled long long specializations])
1702   AC_MSG_RESULT([$enable_long_long])
1703 ])
1704
1705
1706 dnl
1707 dnl Check for template specializations for the 'wchar_t' type.
1708 dnl
1709 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1710 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1711 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1712 dnl       Where DEFAULT is either `yes' or `no'.
1713 dnl
1714 dnl Necessary support (probed along with C99 support) must also be present.
1715 dnl
1716 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
1717   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
1718   if test x"$ac_c99_wchar" = x"yes" && test x"$enable_wchar_t" = x"yes"; then
1719     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
1720               [Define if code specialized for wchar_t should be used.])
1721   fi
1722   AC_MSG_CHECKING([for enabled wchar_t specializations])
1723   AC_MSG_RESULT([$enable_wchar_t])
1724 ])
1725
1726
1727 dnl
1728 dnl Check to see if building and using a C++ precompiled header can be done.
1729 dnl
1730 dnl --enable-libstdcxx-pch=yes
1731 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1732 dnl may work, after some light-hearted attempts to puzzle out compiler
1733 dnl support, flip bits on in include/Makefile.am
1734 dnl
1735 dnl --disable-libstdcxx-pch
1736 dnl turns off attempts to use or build stdc++.h.gch.
1737 dnl
1738 dnl Substs:
1739 dnl  glibcxx_PCHFLAGS
1740 dnl
1741 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1742   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1743   if test $enable_libstdcxx_pch = yes; then
1744     AC_CACHE_CHECK([for compiler with PCH support],
1745       [glibcxx_cv_prog_CXX_pch],
1746       [ac_save_CXXFLAGS="$CXXFLAGS"
1747        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1748        AC_LANG_SAVE
1749        AC_LANG_CPLUSPLUS
1750        echo '#include <math.h>' > conftest.h
1751        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1752                           -o conftest.h.gch 1>&5 2>&1 &&
1753                 echo '#error "pch failed"' > conftest.h &&
1754           echo '#include "conftest.h"' > conftest.cc &&
1755                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1756        then
1757          glibcxx_cv_prog_CXX_pch=yes
1758        else
1759          glibcxx_cv_prog_CXX_pch=no
1760        fi
1761        rm -f conftest*
1762        CXXFLAGS=$ac_save_CXXFLAGS
1763        AC_LANG_RESTORE
1764       ])
1765     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1766   fi
1767
1768   AC_MSG_CHECKING([for enabled PCH])
1769   AC_MSG_RESULT([$enable_libstdcxx_pch])
1770
1771   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1772   if test $enable_libstdcxx_pch = yes; then
1773     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1774   else
1775     glibcxx_PCHFLAGS=""
1776   fi
1777   AC_SUBST(glibcxx_PCHFLAGS)
1778 ])
1779
1780
1781 dnl
1782 dnl Check for exception handling support.  If an explicit enable/disable
1783 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1784 dnl target may or may not support call frame exceptions.
1785 dnl
1786 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1787 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1788 dnl Neither one forces an attempt at detection.
1789 dnl
1790 dnl Defines:
1791 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1792 dnl
1793 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1794   AC_MSG_CHECKING([for exception model to use])
1795   AC_LANG_SAVE
1796   AC_LANG_CPLUSPLUS
1797   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1798     [force use of builtin_setjmp for exceptions],
1799     [permit yes|no|auto])
1800
1801   if test $enable_sjlj_exceptions = auto; then
1802     # Botheration.  Now we've got to detect the exception model.  Link tests
1803     # against libgcc.a are problematic since we've not been given proper -L
1804     # bits for single-tree newlib and libgloss.
1805     #
1806     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1807     cat > conftest.$ac_ext << EOF
1808 [#]line __oline__ "configure"
1809 struct S { ~S(); };
1810 void bar();
1811 void foo()
1812 {
1813   S s;
1814   bar();
1815 }
1816 EOF
1817     old_CXXFLAGS="$CXXFLAGS"
1818     CXXFLAGS=-S
1819     if AC_TRY_EVAL(ac_compile); then
1820       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1821         enable_sjlj_exceptions=yes
1822       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1823         enable_sjlj_exceptions=no
1824       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
1825         enable_sjlj_exceptions=no
1826       fi
1827     fi
1828     CXXFLAGS="$old_CXXFLAGS"
1829     rm -f conftest*
1830   fi
1831
1832   # This is a tad weird, for hysterical raisins.  We have to map
1833   # enable/disable to two different models.
1834   case $enable_sjlj_exceptions in
1835     yes)
1836       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1837         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1838       ac_exception_model_name=sjlj
1839       ;;
1840     no)
1841       ac_exception_model_name="call frame"
1842       ;;
1843     *)
1844       AC_MSG_ERROR([unable to detect exception model])
1845       ;;
1846   esac
1847  AC_LANG_RESTORE
1848  AC_MSG_RESULT($ac_exception_model_name)
1849 ])
1850
1851
1852 dnl
1853 dnl Add version tags to symbols in shared library (or not), additionally
1854 dnl marking other symbols as private/local (or not).
1855 dnl
1856 dnl --enable-symvers=style adds a version script to the linker call when
1857 dnl       creating the shared library.  The choice of version script is
1858 dnl       controlled by 'style'.
1859 dnl --disable-symvers does not.
1860 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1861 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1862 dnl       choose a default style based on linker characteristics.  Passing
1863 dnl       'no' disables versioning.
1864 dnl
1865 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1866
1867 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1868   [enables symbol versioning of the shared library],
1869   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
1870
1871 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1872 # don't know enough about $LD to do tricks...
1873 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1874
1875 # Turn a 'yes' into a suitable default.
1876 if test x$enable_symvers = xyes ; then
1877   if test $enable_shared = no || test "x$LD" = x ; then
1878     enable_symvers=no
1879   else
1880     if test $with_gnu_ld = yes ; then
1881       enable_symvers=gnu
1882     else
1883       case ${target_os} in
1884         darwin*)
1885           enable_symvers=darwin ;;
1886         *)
1887           enable_symvers=no ;;
1888       esac
1889     fi
1890   fi
1891 fi
1892
1893 # Check to see if 'darwin' or 'darwin-export' can win.
1894 if test x$enable_symvers = xdarwin-export ; then
1895     enable_symvers=darwin
1896 fi
1897
1898 # Check to see if 'gnu' can win.
1899 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
1900   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1901   AC_MSG_CHECKING([for shared libgcc])
1902   ac_save_CFLAGS="$CFLAGS"
1903   CFLAGS=' -lgcc_s'
1904   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1905   CFLAGS="$ac_save_CFLAGS"
1906   if test $glibcxx_shared_libgcc = no; then
1907     cat > conftest.c <<EOF
1908 int main (void) { return 0; }
1909 EOF
1910 changequote(,)dnl
1911     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1912                              -shared -shared-libgcc -o conftest.so \
1913                              conftest.c -v 2>&1 >/dev/null \
1914                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1915 changequote([,])dnl
1916     rm -f conftest.c conftest.so
1917     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1918       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1919       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1920       CFLAGS="$ac_save_CFLAGS"
1921     fi
1922   fi
1923   AC_MSG_RESULT($glibcxx_shared_libgcc)
1924
1925   # For GNU ld, we need at least this version.  The format is described in
1926   # GLIBCXX_CHECK_LINKER_FEATURES above.
1927   glibcxx_min_gnu_ld_version=21400
1928
1929   # If no shared libgcc, can't win.
1930   if test $glibcxx_shared_libgcc != yes; then
1931       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
1932       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
1933       AC_MSG_WARN([=== Symbol versioning will be disabled.])
1934       enable_symvers=no
1935   elif test $with_gnu_ld != yes ; then
1936     # just fail for now
1937     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
1938     AC_MSG_WARN([=== you are not using the GNU linker.])
1939     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1940     enable_symvers=no
1941   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
1942     # The right tools, the right setup, but too old.  Fallbacks?
1943     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1944     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1945     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1946     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1947     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1948     enable_symvers=no
1949   fi
1950 fi
1951
1952 # Everything parsed; figure out what file to use.
1953 case $enable_symvers in
1954   no)
1955     SYMVER_FILE=config/abi/pre/none.ver
1956     ;;
1957   gnu)
1958     SYMVER_FILE=config/abi/pre/gnu.ver
1959     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
1960               [Define to use GNU versioning in the shared library.])
1961     ;;
1962   gnu-versioned-namespace)
1963     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
1964     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
1965               [Define to use GNU namespace versioning in the shared library.])
1966     ;;
1967   darwin)
1968     SYMVER_FILE=config/abi/pre/gnu.ver
1969     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
1970               [Define to use darwin versioning in the shared library.])
1971     ;;
1972 esac
1973
1974 if test x$enable_symvers != xno ; then
1975   AC_DEFINE(_GLIBCXX_SYMVER, 1,
1976          [Define to use symbol versioning in the shared library.])
1977 fi
1978
1979 AC_SUBST(SYMVER_FILE)
1980 AC_SUBST(port_specific_symbol_files)
1981 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
1982 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
1983 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
1984 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
1985 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1986
1987 # Now, set up compatibility support, if any.
1988 # In addition, need this to deal with std::size_t mangling in
1989 # src/compatibility.cc.  In a perfect world, could use
1990 # typeid(std::size_t).name()[0] to do direct substitution.
1991 AC_MSG_CHECKING([for size_t as unsigned int])
1992 ac_save_CFLAGS="$CFLAGS"
1993 CFLAGS="-Werror"
1994 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
1995                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
1996 CFLAGS=$ac_save_CFLAGS
1997 if test "$glibcxx_size_t_is_i" = yes; then
1998   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
1999 fi
2000 AC_MSG_RESULT([$glibcxx_size_t_is_i])
2001
2002 AC_MSG_CHECKING([for ptrdiff_t as int])
2003 ac_save_CFLAGS="$CFLAGS"
2004 CFLAGS="-Werror"
2005 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
2006                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
2007 CFLAGS=$ac_save_CFLAGS
2008 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
2009   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
2010 fi
2011 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
2012 ])
2013
2014
2015 dnl
2016 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
2017 dnl We must stage the required headers so that they will be installed
2018 dnl with the library (unlike libgcc, the STL implementation is provided
2019 dnl solely within headers).  Since we must not inject random user-space
2020 dnl macro names into user-provided C++ code, we first stage into <file>-in
2021 dnl and process to <file> with an output command.  The reason for a two-
2022 dnl stage process here is to correctly handle $srcdir!=$objdir without
2023 dnl having to write complex code (the sed commands to clean the macro
2024 dnl namespace are complex and fragile enough as it is).  We must also
2025 dnl add a relative path so that -I- is supported properly.
2026 dnl
2027 dnl Substs:
2028 dnl  glibcxx_thread_h
2029 dnl
2030 dnl Defines:
2031 dnl  HAVE_GTHR_DEFAULT
2032 dnl
2033 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
2034   AC_MSG_CHECKING([for thread model used by GCC])
2035   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
2036   AC_MSG_RESULT([$target_thread_file])
2037
2038   if test $target_thread_file != single; then
2039     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
2040               [Define if gthr-default.h exists
2041               (meaning that threading support is enabled).])
2042   fi
2043
2044   glibcxx_thread_h=gthr-$target_thread_file.h
2045
2046   dnl Check for __GTHREADS define.
2047   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
2048   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
2049     enable_thread=yes
2050   else
2051    enable_thread=no
2052   fi
2053
2054   AC_SUBST(glibcxx_thread_h)
2055 ])
2056
2057
2058 # Check whether LC_MESSAGES is available in <locale.h>.
2059 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2060 #
2061 # This file file be copied and used freely without restrictions.  It can
2062 # be used in projects which are not available under the GNU Public License
2063 # but which still want to provide support for the GNU gettext functionality.
2064 # Please note that the actual code is *not* freely available.
2065
2066 # serial 1
2067 AC_DEFUN([AC_LC_MESSAGES], [
2068   AC_CHECK_HEADER(locale.h, [
2069     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2070       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2071        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2072     if test $ac_cv_val_LC_MESSAGES = yes; then
2073       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2074                 [Define if LC_MESSAGES is available in <locale.h>.])
2075     fi
2076   ])
2077 ])
2078
2079 # Macros from the top-level gcc directory.
2080 m4_include([../config/tls.m4])
2081