libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  27   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN(GLIBCXX_CONFIGURE, [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 387     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     # Checks for wide character functions that are not required
 394     # for basic wchar_t support.  Don't disable support if they are missing.
 395     # Injection of these is wrapped with guard macros.
 396     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 397
 398     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 399     if test x"$has_weof" = xyes &&
 400        test x"$has_wchar_minmax" = xyes &&
 401        test x"$ac_wfuncs" = xyes;
 402     then
 403       ac_isoC99_wchar_t=yes
 404     else
 405       ac_isoC99_wchar_t=no
 406     fi
 407     AC_MSG_RESULT($ac_isoC99_wchar_t)
 408
 409     # Use iconv for wchar_t to char conversions. As such, check for
 410     # X/Open Portability Guide, version 2 features (XPG2).
 411     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 412     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 413
 414     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 415     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 416     ac_save_LIBS="$LIBS"
 417     LIBS="$LIBS $libiconv"
 418
 419     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 420     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 421
 422     LIBS="$ac_save_LIBS"
 423
 424     AC_MSG_CHECKING([for XPG2 wchar_t support])
 425     if test x"$ac_has_iconv_h" = xyes &&
 426        test x"$ac_has_langinfo_h" = xyes &&
 427        test x"$ac_XPG2funcs" = xyes;
 428     then
 429       ac_XPG2_wchar_t=yes
 430     else
 431       ac_XPG2_wchar_t=no
 432     fi
 433     AC_MSG_RESULT($ac_XPG2_wchar_t)
 434
 435     # At the moment, only enable wchar_t specializations if all the
 436     # above support is present.
 437     if test x"$ac_isoC99_wchar_t" = xyes &&
 438        test x"$ac_XPG2_wchar_t" = xyes;
 439     then
 440       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 441       enable_wchar_t=yes
 442     fi
 443   fi
 444   AC_MSG_CHECKING([for enabled wchar_t specializations])
 445   AC_MSG_RESULT($enable_wchar_t)
 446 ])
 447
 448
 449 dnl
 450 dnl Check for headers for, and arguments to, the setrlimit() function.
 451 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 452 dnl
 453 dnl Defines:
 454 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 455 dnl  various HAVE_MEMLIMIT_* for individual limit names
 456 dnl
 457 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 458   AC_TRY_COMPILE(
 459     [#include <unistd.h>
 460      #include <sys/time.h>
 461      #include <sys/resource.h>
 462     ],
 463     [ int f = RLIMIT_$1 ; ],
 464     [glibcxx_mresult=1], [glibcxx_mresult=0])
 465   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 466                      [Only used in build directory testsuite_hooks.h.])
 467 ])
 468
 469 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 470   setrlimit_have_headers=yes
 471   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 472                    [],
 473                    [setrlimit_have_headers=no])
 474   # If don't have the headers, then we can't run the tests now, and we
 475   # won't be seeing any of these during testsuite compilation.
 476   if test $setrlimit_have_headers = yes; then
 477     # Can't do these in a loop, else the resulting syntax is wrong.
 478     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 479     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 480     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 481     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 482
 483     # Check for rlimit, setrlimit.
 484     AC_CACHE_VAL(ac_setrlimit, [
 485       AC_TRY_COMPILE(
 486         [#include <unistd.h>
 487          #include <sys/time.h>
 488          #include <sys/resource.h>
 489         ],
 490         [struct rlimit r;
 491          setrlimit(0, &r);],
 492         [ac_setrlimit=yes], [ac_setrlimit=no])
 493     ])
 494   fi
 495
 496   AC_MSG_CHECKING([for testsuite memory limit support])
 497   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 498     ac_mem_limits=yes
 499     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 500   else
 501     ac_mem_limits=no
 502   fi
 503   AC_MSG_RESULT($ac_mem_limits)
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 509 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 510 dnl
 511 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 512   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 513     AC_TRY_LINK(
 514       [#include <sys/stat.h>],
 515       [struct stat buffer;
 516        fstat(0, &buffer);
 517        S_ISREG(buffer.st_mode);],
 518       [glibcxx_cv_S_ISREG=yes],
 519       [glibcxx_cv_S_ISREG=no])
 520   ])
 521   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 522     AC_TRY_LINK(
 523       [#include <sys/stat.h>],
 524       [struct stat buffer;
 525        fstat(0, &buffer);
 526        S_IFREG & buffer.st_mode;],
 527       [glibcxx_cv_S_IFREG=yes],
 528       [glibcxx_cv_S_IFREG=no])
 529   ])
 530   if test $glibcxx_cv_S_ISREG = yes; then
 531     AC_DEFINE(HAVE_S_ISREG)
 532   elif test $glibcxx_cv_S_IFREG = yes; then
 533     AC_DEFINE(HAVE_S_IFREG)
 534   fi
 535 ])
 536
 537
 538 dnl
 539 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 540 dnl
 541 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 542   AC_CACHE_VAL(glibcxx_cv_POLL, [
 543     AC_TRY_LINK(
 544       [#include <poll.h>],
 545       [struct pollfd pfd[1];
 546        pfd[0].events = POLLIN;
 547        poll(pfd, 1, 0);],
 548       [glibcxx_cv_POLL=yes],
 549       [glibcxx_cv_POLL=no])
 550   ])
 551   if test $glibcxx_cv_POLL = yes; then
 552     AC_DEFINE(HAVE_POLL)
 553   fi
 554 ])
 555
 556
 557 dnl
 558 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 559 dnl
 560 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 561   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 562     AC_TRY_LINK(
 563       [#include <sys/uio.h>],
 564       [struct iovec iov[2];
 565        writev(0, iov, 0);],
 566       [glibcxx_cv_WRITEV=yes],
 567       [glibcxx_cv_WRITEV=no])
 568   ])
 569   if test $glibcxx_cv_WRITEV = yes; then
 570     AC_DEFINE(HAVE_WRITEV)
 571   fi
 572 ])
 573
 574
 575 dnl
 576 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 577 dnl
 578 AC_DEFUN(GLIBCXX_CHECK_INT64_T, [
 579   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 580     AC_TRY_COMPILE(
 581       [#include <stdint.h>],
 582       [int64_t var;],
 583       [glibcxx_cv_INT64_T=yes],
 584       [glibcxx_cv_INT64_T=no])
 585   ])
 586   if test $glibcxx_cv_INT64_T = yes; then
 587     AC_DEFINE(HAVE_INT64_T)
 588   fi
 589 ])
 590
 591
 592 dnl
 593 dnl Check whether LFS support is available.
 594 dnl
 595 AC_DEFUN(GLIBCXX_CHECK_LFS, [
 596   AC_LANG_SAVE
 597   AC_LANG_CPLUSPLUS
 598   AC_CACHE_VAL(glibcxx_cv_LFS, [
 599     AC_TRY_LINK(
 600       [#include <unistd.h>
 601        #include <stdio.h>
 602       ],
 603       [fopen64("t", "w");
 604        lseek64(1, 0, SEEK_CUR);],
 605       [glibcxx_cv_LFS=yes],
 606       [glibcxx_cv_LFS=no])
 607   ])
 608   if test $glibcxx_cv_LFS = yes; then
 609     AC_DEFINE(_GLIBCXX_USE_LFS)
 610   fi
 611   AC_LANG_RESTORE
 612 ])
 613
 614
 615 dnl
 616 dnl Does any necessary configuration of the testsuite directory.  Generates
 617 dnl the testsuite_hooks.h header.
 618 dnl
 619 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 620 dnl
 621 dnl Sets:
 622 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 623 dnl Substs:
 624 dnl  baseline_dir
 625 dnl
 626 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 627   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 628     # Do checks for memory limit functions.
 629     GLIBCXX_CHECK_SETRLIMIT
 630
 631     # Look for setenv, so that extended locale tests can be performed.
 632     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 633
 634     if test $enable_symvers = no; then
 635       enable_abi_check=no
 636     else
 637       case "$host" in
 638         *-*-cygwin*)
 639           enable_abi_check=no ;;
 640         *)
 641           enable_abi_check=yes ;;
 642       esac
 643     fi
 644   else
 645     # Only build this as native, since automake does not understand
 646     # CXX_FOR_BUILD.
 647     enable_abi_check=no
 648   fi
 649
 650   # Export file names for ABI checking.
 651   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 652   AC_SUBST(baseline_dir)
 653
 654   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 655   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 656 ])
 657
 658
 659 dnl
 660 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 661 dnl
 662 dnl Substs:
 663 dnl  GLIBCXX_INCLUDES
 664 dnl  TOPLEVEL_INCLUDES
 665 dnl
 666 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 667   # Used for every C++ compile we perform.
 668   GLIBCXX_INCLUDES="\
 669 -I$glibcxx_builddir/include/$host_alias \
 670 -I$glibcxx_builddir/include \
 671 -I$glibcxx_srcdir/libsupc++"
 672
 673   # For Canadian crosses, pick this up too.
 674   if test $CANADIAN = yes; then
 675     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 676   fi
 677
 678   # Stuff in the actual top level.  Currently only used by libsupc++ to
 679   # get unwind* headers from the gcc dir.
 680   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 681   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 682
 683   # Now, export this to all the little Makefiles....
 684   AC_SUBST(GLIBCXX_INCLUDES)
 685   AC_SUBST(TOPLEVEL_INCLUDES)
 686 ])
 687
 688
 689 dnl
 690 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 691 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 692 dnl
 693 dnl Substs:
 694 dnl  OPTIMIZE_CXXFLAGS
 695 dnl  WARN_FLAGS
 696 dnl
 697 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 698   # Optimization flags that are probably a good idea for thrill-seekers. Just
 699   # uncomment the lines below and make, everything else is ready to go...
 700   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 701   OPTIMIZE_CXXFLAGS=
 702   AC_SUBST(OPTIMIZE_CXXFLAGS)
 703
 704   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 705   AC_SUBST(WARN_FLAGS)
 706 ])
 707
 708
 709 dnl
 710 dnl All installation directory information is determined here.
 711 dnl
 712 dnl Substs:
 713 dnl  gxx_install_dir
 714 dnl  glibcxx_prefixdir
 715 dnl  glibcxx_toolexecdir
 716 dnl  glibcxx_toolexeclibdir
 717 dnl
 718 dnl Assumes cross_compiling bits already done, and with_cross_host in
 719 dnl particular.
 720 dnl
 721 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 722   glibcxx_toolexecdir=no
 723   glibcxx_toolexeclibdir=no
 724   glibcxx_prefixdir=$prefix
 725
 726   AC_MSG_CHECKING([for gxx-include-dir])
 727   AC_ARG_WITH([gxx-include-dir],
 728     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 729                    [installation directory for include files]),
 730     [case "$withval" in
 731       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 732       no)  gxx_include_dir=no ;;
 733       *)   gxx_include_dir=$withval ;;
 734      esac],
 735     [gxx_include_dir=no])
 736   AC_MSG_RESULT($gxx_include_dir)
 737
 738   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 739   AC_ARG_ENABLE([version-specific-runtime-libs],
 740     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 741                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 742     [case "$enableval" in
 743       yes) version_specific_libs=yes ;;
 744       no)  version_specific_libs=no ;;
 745       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 746      esac],
 747     [version_specific_libs=no])
 748   AC_MSG_RESULT($version_specific_libs)
 749
 750   # Default case for install directory for include files.
 751   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 752     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 753   fi
 754
 755   # Version-specific runtime libs processing.
 756   if test $version_specific_libs = yes; then
 757     # Need the gcc compiler version to know where to install libraries
 758     # and header files if --enable-version-specific-runtime-libs option
 759     # is selected.
 760     if test x"$gxx_include_dir" = x"no"; then
 761       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 762     fi
 763     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 764     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 765   fi
 766
 767   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 768   # Install a library built with a cross compiler in tooldir, not libdir.
 769   if test x"$glibcxx_toolexecdir" = x"no"; then
 770     if test -n "$with_cross_host" &&
 771        test x"$with_cross_host" != x"no"; then
 772       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 773       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 774     else
 775       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 776       glibcxx_toolexeclibdir='${libdir}'
 777     fi
 778     multi_os_directory=`$CXX -print-multi-os-directory`
 779     case $multi_os_directory in
 780       .) ;; # Avoid trailing /.
 781       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 782     esac
 783   fi
 784
 785   AC_MSG_CHECKING([for install location])
 786   AC_MSG_RESULT($gxx_include_dir)
 787
 788   AC_SUBST(glibcxx_prefixdir)
 789   AC_SUBST(gxx_include_dir)
 790   AC_SUBST(glibcxx_toolexecdir)
 791   AC_SUBST(glibcxx_toolexeclibdir)
 792 ])
 793
 794
 795 dnl
 796 dnl GLIBCXX_ENABLE
 797 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 798 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 799 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 800 dnl
 801 dnl See docs/html/17_intro/configury.html#enable for documentation.
 802 dnl
 803 m4_define([GLIBCXX_ENABLE],[dnl
 804 m4_define([_g_switch],[--enable-$1])dnl
 805 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 806  AC_ARG_ENABLE($1,_g_help,
 807   m4_bmatch([$5],
 808    [^permit ],
 809      [[
 810       case "$enableval" in
 811        m4_bpatsubst([$5],[permit ])) ;;
 812        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 813           dnl Idea for future:  generate a URL pointing to
 814           dnl "onlinedocs/configopts.html#whatever"
 815       esac
 816      ]],
 817    [^$],
 818      [[
 819       case "$enableval" in
 820        yes|no) ;;
 821        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 822       esac
 823      ]],
 824    [[$5]]),
 825   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 826 m4_undefine([_g_switch])dnl
 827 m4_undefine([_g_help])dnl
 828 ])
 829
 830
 831 dnl
 832 dnl Check for ISO/IEC 9899:1999 "C99" support.
 833 dnl
 834 dnl --enable-c99 defines _GLIBCXX_USE_C99
 835 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 836 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 837 dnl       Where DEFAULT is either `yes' or `no'.
 838 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 839 dnl
 840 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 841   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 842
 843   AC_LANG_SAVE
 844   AC_LANG_CPLUSPLUS
 845
 846   # Check for the existence of <math.h> functions used if C99 is enabled.
 847   ac_c99_math=yes;
 848   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 849   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 850   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 851   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 852   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 853   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 856   AC_TRY_COMPILE([#include <math.h>],
 857                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 860   AC_TRY_COMPILE([#include <math.h>],
 861                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],
 863                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 864   AC_MSG_RESULT($ac_c99_math)
 865
 866   # Check for the existence in <stdio.h> of vscanf, et. al.
 867   ac_c99_stdio=yes;
 868   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 869   AC_TRY_COMPILE([#include <stdio.h>],
 870                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 871   AC_TRY_COMPILE([#include <stdio.h>
 872                   #include <stdarg.h>
 873                   void foo(char* fmt, ...)
 874                   {va_list args; va_start(args, fmt);
 875                   vfscanf(stderr, "%i", args);}],
 876                   [],, [ac_c99_stdio=no])
 877   AC_TRY_COMPILE([#include <stdio.h>
 878                   #include <stdarg.h>
 879                   void foo(char* fmt, ...)
 880                   {va_list args; va_start(args, fmt);
 881                   vscanf("%i", args);}],
 882                   [],, [ac_c99_stdio=no])
 883   AC_TRY_COMPILE([#include <stdio.h>
 884                   #include <stdarg.h>
 885                   void foo(char* fmt, ...)
 886                   {va_list args; va_start(args, fmt);
 887                   vsnprintf(fmt, 0, "%i", args);}],
 888                   [],, [ac_c99_stdio=no])
 889   AC_TRY_COMPILE([#include <stdio.h>
 890                   #include <stdarg.h>
 891                   void foo(char* fmt, ...)
 892                   {va_list args; va_start(args, fmt);
 893                   vsscanf(fmt, "%i", args);}],
 894                   [],, [ac_c99_stdio=no])
 895   AC_MSG_RESULT($ac_c99_stdio)
 896
 897   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 898   ac_c99_stdlib=yes;
 899   AC_MSG_CHECKING([for lldiv_t declaration])
 900   AC_CACHE_VAL(ac_c99_lldiv_t, [
 901   AC_TRY_COMPILE([#include <stdlib.h>],
 902                    [ lldiv_t mydivt;],
 903                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 904   ])
 905   AC_MSG_RESULT($ac_c99_lldiv_t)
 906
 907   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 908   AC_TRY_COMPILE([#include <stdlib.h>],
 909                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 910   AC_TRY_COMPILE([#include <stdlib.h>],
 911                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 912   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 913   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 914   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 915   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 916   if test x"$ac_c99_lldiv_t" = x"no"; then
 917     ac_c99_stdlib=no;
 918   fi;
 919   AC_MSG_RESULT($ac_c99_stdlib)
 920
 921   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 922   # XXX the wchar.h checks should be rolled into the general C99 bits.
 923   ac_c99_wchar=yes;
 924   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 925   AC_TRY_COMPILE([#include <wchar.h>],
 926                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 927   AC_TRY_COMPILE([#include <wchar.h>],
 928                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 929   AC_TRY_COMPILE([#include <wchar.h>],
 930                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 931   AC_MSG_RESULT($ac_c99_wchar)
 932
 933   AC_MSG_CHECKING([for enabled ISO C99 support])
 934   if test x"$ac_c99_math" = x"no" ||
 935      test x"$ac_c99_stdio" = x"no" ||
 936      test x"$ac_c99_stdlib" = x"no" ||
 937      test x"$ac_c99_wchar" = x"no"; then
 938     enable_c99=no;
 939   fi;
 940   AC_MSG_RESULT($enable_c99)
 941
 942   # Option parsed, now set things appropriately
 943   if test x"$enable_c99" = x"yes"; then
 944     AC_DEFINE(_GLIBCXX_USE_C99)
 945   fi
 946
 947   AC_LANG_RESTORE
 948 ])
 949
 950
 951 dnl
 952 dnl Check for what type of C headers to use.
 953 dnl
 954 dnl --enable-cheaders= [does stuff].
 955 dnl --disable-cheaders [does not do anything, really].
 956 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 957 dnl       Where DEFAULT is either `c' or `c_std'.
 958 dnl
 959 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 960   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 961     [construct "C" headers for g++], [permit c|c_std])
 962   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 963
 964   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 965
 966   AC_SUBST(C_INCLUDE_DIR)
 967   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 968   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 969   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 970 ])
 971
 972
 973 dnl
 974 dnl Check for which locale library to use.  The choice is mapped to
 975 dnl a subdirectory of config/locale.
 976 dnl
 977 dnl Default is generic.
 978 dnl
 979 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 980   AC_MSG_CHECKING([for C locale to use])
 981   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 982     [use MODEL for target locale package],
 983     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 984
 985   # If they didn't use this option switch, or if they specified --enable
 986   # with no specific model, we'll have to look for one.  If they
 987   # specified --disable (???), do likewise.
 988   if test $enable_clocale = no || test $enable_clocale = yes; then
 989      enable_clocale=auto
 990   fi
 991
 992   # Either a known package, or "auto"
 993   enable_clocale_flag=$enable_clocale
 994
 995   # Probe for locale support if no specific model is specified.
 996   # Default to "generic".
 997   if test $enable_clocale_flag = auto; then
 998     case x${target_os} in
 999       xlinux* | xgnu* | xkfreebsd*-gnu | xknetbsd*-gnu)
1000         AC_EGREP_CPP([_GLIBCXX_ok], [
1001         #include <features.h>
1002         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1003           _GLIBCXX_ok
1004         #endif
1005         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1006
1007         # Test for bugs early in glibc-2.2.x series
1008           if test x$enable_clocale_flag = xgnu; then
1009           AC_TRY_RUN([
1010           #define _GNU_SOURCE 1
1011           #include <locale.h>
1012           #include <string.h>
1013           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1014           extern __typeof(newlocale) __newlocale;
1015           extern __typeof(duplocale) __duplocale;
1016           extern __typeof(strcoll_l) __strcoll_l;
1017           #endif
1018           int main()
1019           {
1020               const char __one[] = "Äuglein Augmen";
1021               const char __two[] = "Äuglein";
1022               int i;
1023               int j;
1024               __locale_t        loc;
1025                __locale_t        loc_dup;
1026               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1027               loc_dup = __duplocale(loc);
1028               i = __strcoll_l(__one, __two, loc);
1029               j = __strcoll_l(__one, __two, loc_dup);
1030               return 0;
1031           }
1032           ],
1033           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1034           [enable_clocale_flag=generic])
1035           fi
1036
1037         # ... at some point put __strxfrm_l tests in as well.
1038         ;;
1039       *)
1040         enable_clocale_flag=generic
1041         ;;
1042     esac
1043   fi
1044
1045   # Deal with gettext issues.  Default to not using it (=no) until we detect
1046   # support for it later.  Let the user turn it off via --e/d, but let that
1047   # default to on for easier handling.
1048   USE_NLS=no
1049   AC_ARG_ENABLE(nls,
1050     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1051     [],
1052     [enable_nls=yes])
1053
1054   # Set configure bits for specified locale package
1055   case ${enable_clocale_flag} in
1056     generic)
1057       AC_MSG_RESULT(generic)
1058
1059       CLOCALE_H=config/locale/generic/c_locale.h
1060       CLOCALE_CC=config/locale/generic/c_locale.cc
1061       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1062       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1063       CCOLLATE_CC=config/locale/generic/collate_members.cc
1064       CCTYPE_CC=config/locale/generic/ctype_members.cc
1065       CMESSAGES_H=config/locale/generic/messages_members.h
1066       CMESSAGES_CC=config/locale/generic/messages_members.cc
1067       CMONEY_CC=config/locale/generic/monetary_members.cc
1068       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1069       CTIME_H=config/locale/generic/time_members.h
1070       CTIME_CC=config/locale/generic/time_members.cc
1071       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1072       ;;
1073     gnu)
1074       AC_MSG_RESULT(gnu)
1075
1076       # Declare intention to use gettext, and add support for specific
1077       # languages.
1078       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1079       ALL_LINGUAS="de fr"
1080
1081       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1082       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1083       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1084         USE_NLS=yes
1085       fi
1086       # Export the build objects.
1087       for ling in $ALL_LINGUAS; do \
1088         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1089         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1090       done
1091       AC_SUBST(glibcxx_MOFILES)
1092       AC_SUBST(glibcxx_POFILES)
1093
1094       CLOCALE_H=config/locale/gnu/c_locale.h
1095       CLOCALE_CC=config/locale/gnu/c_locale.cc
1096       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1097       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1098       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1099       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1100       CMESSAGES_H=config/locale/gnu/messages_members.h
1101       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1102       CMONEY_CC=config/locale/gnu/monetary_members.cc
1103       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1104       CTIME_H=config/locale/gnu/time_members.h
1105       CTIME_CC=config/locale/gnu/time_members.cc
1106       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1107       ;;
1108     ieee_1003.1-2001)
1109       AC_MSG_RESULT(IEEE 1003.1)
1110
1111       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1112       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1113       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1114       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1115       CCOLLATE_CC=config/locale/generic/collate_members.cc
1116       CCTYPE_CC=config/locale/generic/ctype_members.cc
1117       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1118       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1119       CMONEY_CC=config/locale/generic/monetary_members.cc
1120       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1121       CTIME_H=config/locale/generic/time_members.h
1122       CTIME_CC=config/locale/generic/time_members.cc
1123       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1124       ;;
1125   esac
1126
1127   # This is where the testsuite looks for locale catalogs, using the
1128   # -DLOCALEDIR define during testsuite compilation.
1129   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1130   AC_SUBST(glibcxx_localedir)
1131
1132   # A standalone libintl (e.g., GNU libintl) may be in use.
1133   if test $USE_NLS = yes; then
1134     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1135     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1136   fi
1137   if test $USE_NLS = yes; then
1138     AC_DEFINE(_GLIBCXX_USE_NLS)
1139   fi
1140
1141   AC_SUBST(USE_NLS)
1142   AC_SUBST(CLOCALE_H)
1143   AC_SUBST(CCODECVT_H)
1144   AC_SUBST(CMESSAGES_H)
1145   AC_SUBST(CCODECVT_CC)
1146   AC_SUBST(CCOLLATE_CC)
1147   AC_SUBST(CCTYPE_CC)
1148   AC_SUBST(CMESSAGES_CC)
1149   AC_SUBST(CMONEY_CC)
1150   AC_SUBST(CNUMERIC_CC)
1151   AC_SUBST(CTIME_H)
1152   AC_SUBST(CTIME_CC)
1153   AC_SUBST(CLOCALE_CC)
1154   AC_SUBST(CLOCALE_INTERNAL_H)
1155 ])
1156
1157
1158 dnl
1159 dnl Check for whether the Boost-derived checks should be turned on.
1160 dnl
1161 dnl --enable-concept-checks turns them on.
1162 dnl --disable-concept-checks leaves them off.
1163 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1164 dnl       Where DEFAULT is either `yes' or `no'.
1165 dnl
1166 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1167   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1168   if test $enable_concept_checks = yes; then
1169     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1170   fi
1171 ])
1172
1173
1174 dnl
1175 dnl Check for which I/O library to use:  stdio, or something specific.
1176 dnl
1177 dnl Default is stdio.
1178 dnl
1179 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1180   AC_MSG_CHECKING([for underlying I/O to use])
1181   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1182     [use target-specific I/O package], [permit stdio])
1183
1184   # Now that libio has been removed, you can have any color you want as long
1185   # as it's black.  This is one big no-op until other packages are added, but
1186   # showing the framework never hurts.
1187   case ${enable_cstdio} in
1188     stdio)
1189       CSTDIO_H=config/io/c_io_stdio.h
1190       BASIC_FILE_H=config/io/basic_file_stdio.h
1191       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1192       AC_MSG_RESULT(stdio)
1193       ;;
1194   esac
1195
1196   AC_SUBST(CSTDIO_H)
1197   AC_SUBST(BASIC_FILE_H)
1198   AC_SUBST(BASIC_FILE_CC)
1199 ])
1200
1201
1202 dnl
1203 dnl Check for "unusual" flags to pass to the compiler while building.
1204 dnl
1205 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1206 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1207 dnl --disable-cxx-flags passes nothing.
1208 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1209 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1210 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1211 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1212 dnl       If "default flags" is an empty string, the effect is the same
1213 dnl       as --disable or --enable=no.
1214 dnl
1215 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1216   AC_MSG_CHECKING([for extra compiler flags for building])
1217   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1218     [pass compiler FLAGS when building library],
1219     [case "x$enable_cxx_flags" in
1220       xno | x)   enable_cxx_flags= ;;
1221       x-*)       ;;
1222       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1223      esac])
1224
1225   # Run through flags (either default or command-line) and set anything
1226   # extra (e.g., #defines) that must accompany particular g++ options.
1227   if test -n "$enable_cxx_flags"; then
1228     for f in $enable_cxx_flags; do
1229       case "$f" in
1230         -fhonor-std)  ;;
1231         -*)  ;;
1232         *)   # and we're trying to pass /what/ exactly?
1233              AC_MSG_ERROR([compiler flags start with a -]) ;;
1234       esac
1235     done
1236   fi
1237
1238   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1239   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1240   AC_SUBST(EXTRA_CXX_FLAGS)
1241 ])
1242
1243
1244 dnl
1245 dnl Check for wide character support.  Has the same effect as the option
1246 dnl in gcc's configure, but in a form that autoconf can mess with.
1247 dnl
1248 dnl --enable-c-mbchar requests all the wchar_t stuff.
1249 dnl --disable-c-mbchar doesn't.
1250 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1251 dnl       Where DEFAULT is either `yes' or `no'.
1252 dnl
1253 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1254   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1255   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1256 ])
1257
1258
1259 dnl
1260 dnl Check to see if debugging libraries are to be built.
1261 dnl
1262 dnl --enable-libstdcxx-debug
1263 dnl builds a separate set of debugging libraries in addition to the
1264 dnl normal (shared, static) libstdc++ binaries.
1265 dnl
1266 dnl --disable-libstdcxx-debug
1267 dnl builds only one (non-debug) version of libstdc++.
1268 dnl
1269 dnl --enable-libstdcxx-debug-flags=FLAGS
1270 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1271 dnl
1272 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1273 dnl       Where DEFAULT is either `yes' or `no'.
1274 dnl
1275 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1276   AC_MSG_CHECKING([for additional debug build])
1277   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1278   AC_MSG_RESULT($enable_libstdcxx_debug)
1279   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1280 ])
1281
1282
1283 dnl
1284 dnl Check for explicit debug flags.
1285 dnl
1286 dnl --enable-libstdcxx-debug-flags='-O1'
1287 dnl is a general method for passing flags to be used when
1288 dnl building debug libraries with --enable-debug.
1289 dnl
1290 dnl --disable-libstdcxx-debug-flags does nothing.
1291 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1292 dnl       If "default flags" is an empty string, the effect is the same
1293 dnl       as --disable or --enable=no.
1294 dnl
1295 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1296   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1297     [pass compiler FLAGS when building debug library],
1298     [case "x$enable_libstdcxx_debug_flags" in
1299       xno | x)    enable_libstdcxx_debug_flags= ;;
1300       x-*)        ;;
1301       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1302      esac])
1303
1304   # Option parsed, now set things appropriately
1305   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1306   AC_SUBST(DEBUG_FLAGS)
1307
1308   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1309 ])
1310
1311
1312 dnl
1313 dnl Check if the user only wants a freestanding library implementation.
1314 dnl
1315 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1316 dnl installing only the headers required by [17.4.1.3] and the language
1317 dnl support library.  More than that will be built (to keep the Makefiles
1318 dnl conveniently clean), but not installed.
1319 dnl
1320 dnl Sets:
1321 dnl  is_hosted  (yes/no)
1322 dnl
1323 dnl Defines:
1324 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1325 dnl
1326 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1327   AC_ARG_ENABLE([hosted-libstdcxx],
1328     AC_HELP_STRING([--disable-hosted-libstdcxx],
1329                    [only build freestanding C++ runtime support]),,
1330     [enable_hosted_libstdcxx=yes])
1331   if test "$enable_hosted_libstdcxx" = no; then
1332     AC_MSG_NOTICE([Only freestanding libraries will be built])
1333     is_hosted=no
1334     hosted_define=0
1335     enable_abi_check=no
1336     enable_libstdcxx_pch=no
1337   else
1338     is_hosted=yes
1339     hosted_define=1
1340   fi
1341   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1342   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1343     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1344 ])
1345
1346
1347 dnl
1348 dnl Check for libunwind exception handling support.  If enabled, then
1349 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1350 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1351 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1352 dnl on libunwind as well as libgcc.
1353 dnl
1354 dnl --enable-libunwind-exceptions forces the use of libunwind.
1355 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1356 dnl
1357 dnl Substs:
1358 dnl  LIBUNWIND_FLAG
1359 dnl
1360 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1361   AC_MSG_CHECKING([for use of libunwind])
1362   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1363     [force use of libunwind for exceptions])
1364   AC_MSG_RESULT($use_libunwind_exceptions)
1365   if test $enable_libunwind_exceptions = yes; then
1366     LIBUNWIND_FLAG="-lunwind"
1367   else
1368     LIBUNWIND_FLAG=""
1369   fi
1370   AC_SUBST(LIBUNWIND_FLAG)
1371 ])
1372
1373
1374 dnl
1375 dnl Check for template specializations for the 'long long' type extension.
1376 dnl The result determines only whether 'long long' I/O is enabled; things
1377 dnl like numeric_limits<> specializations are always available.
1378 dnl
1379 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1380 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1381 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1382 dnl       Where DEFAULT is either `yes' or `no'.
1383 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1384 dnl
1385 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1386   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1387
1388   AC_LANG_SAVE
1389   AC_LANG_CPLUSPLUS
1390
1391   AC_MSG_CHECKING([for enabled long long I/O support])
1392   # iostreams require strtoll, strtoull to compile
1393   AC_TRY_COMPILE([#include <stdlib.h>],
1394                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1395   AC_TRY_COMPILE([#include <stdlib.h>],
1396                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1397
1398   # Option parsed, now set things appropriately
1399   if test $enable_long_long = yes; then
1400     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1401   fi
1402   AC_MSG_RESULT($enable_long_long)
1403
1404   AC_LANG_RESTORE
1405 ])
1406
1407
1408 dnl
1409 dnl Check to see if building and using a C++ precompiled header can be done.
1410 dnl
1411 dnl --enable-libstdcxx-pch=yes
1412 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1413 dnl may work, after some light-hearted attempts to puzzle out compiler
1414 dnl support, flip bits on in include/Makefile.am
1415 dnl
1416 dnl --disable-libstdcxx-pch
1417 dnl turns off attempts to use or build stdc++.h.gch.
1418 dnl
1419 dnl Substs:
1420 dnl  glibcxx_PCHFLAGS
1421 dnl
1422 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1423   AC_MSG_CHECKING([for enabled PCH])
1424   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1425   AC_MSG_RESULT([$enable_libstdcxx_pch])
1426
1427   if test $enable_libstdcxx_pch = yes; then
1428     AC_CACHE_CHECK([for compiler with PCH support],
1429       [glibcxx_cv_prog_CXX_pch],
1430       [ac_save_CXXFLAGS="$CXXFLAGS"
1431        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1432        AC_LANG_SAVE
1433        AC_LANG_CPLUSPLUS
1434        echo '#include <math.h>' > conftest.h
1435        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1436                           -o conftest.h.gch 1>&5 2>&1 &&
1437                 echo '#error "pch failed"' > conftest.h &&
1438           echo '#include "conftest.h"' > conftest.cc &&
1439                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1440        then
1441          glibcxx_cv_prog_CXX_pch=yes
1442        else
1443          glibcxx_cv_prog_CXX_pch=no
1444        fi
1445        rm -f conftest*
1446        CXXFLAGS=$ac_save_CXXFLAGS
1447        AC_LANG_RESTORE
1448       ])
1449     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1450   fi
1451
1452   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1453   if test $enable_libstdcxx_pch = yes; then
1454     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1455   else
1456     glibcxx_PCHFLAGS=""
1457   fi
1458   AC_SUBST(glibcxx_PCHFLAGS)
1459 ])
1460
1461
1462 dnl
1463 dnl Check for exception handling support.  If an explicit enable/disable
1464 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1465 dnl target may or may not support call frame exceptions.
1466 dnl
1467 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1468 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1469 dnl Neither one forces an attempt at detection.
1470 dnl
1471 dnl Defines:
1472 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1473 dnl
1474 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1475   AC_MSG_CHECKING([for exception model to use])
1476   AC_LANG_SAVE
1477   AC_LANG_CPLUSPLUS
1478   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1479     [force use of builtin_setjmp for exceptions],
1480     [permit yes|no|auto])
1481
1482   if test $enable_sjlj_exceptions = auto; then
1483     # Botheration.  Now we've got to detect the exception model.  Link tests
1484     # against libgcc.a are problematic since we've not been given proper -L
1485     # bits for single-tree newlib and libgloss.
1486     #
1487     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1488     cat > conftest.$ac_ext << EOF
1489 [#]line __oline__ "configure"
1490 struct S { ~S(); };
1491 void bar();
1492 void foo()
1493 {
1494   S s;
1495   bar();
1496 }
1497 EOF
1498     old_CXXFLAGS="$CXXFLAGS"
1499     CXXFLAGS=-S
1500     if AC_TRY_EVAL(ac_compile); then
1501       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1502         enable_sjlj_exceptions=yes
1503       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1504         enable_sjlj_exceptions=no
1505       fi
1506     fi
1507     CXXFLAGS="$old_CXXFLAGS"
1508     rm -f conftest*
1509   fi
1510
1511   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1512   # to two different models.
1513   case $enable_sjlj_exceptions in
1514     yes)
1515       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1516         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1517       ac_exception_model_name=sjlj
1518       ;;
1519     no)
1520       ac_exception_model_name="call frame"
1521       ;;
1522     *)
1523       AC_MSG_ERROR([unable to detect exception model])
1524       ;;
1525   esac
1526  AC_LANG_RESTORE
1527  AC_MSG_RESULT($ac_exception_model_name)
1528 ])
1529
1530
1531 dnl
1532 dnl Add version tags to symbols in shared library (or not), additionally
1533 dnl marking other symbols as private/local (or not).
1534 dnl
1535 dnl --enable-symvers=style adds a version script to the linker call when
1536 dnl       creating the shared library.  The choice of version script is
1537 dnl       controlled by 'style'.
1538 dnl --disable-symvers does not.
1539 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1540 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1541 dnl       choose a default style based on linker characteristics.  Passing
1542 dnl       'no' disables versioning.
1543 dnl
1544 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1545
1546 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1547   [enables symbol versioning of the shared library],
1548   [permit yes|no|gnu])
1549
1550 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1551 # don't know enough about $LD to do tricks...
1552 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1553 # FIXME  The following test is too strict, in theory.
1554 if test $enable_shared = no ||
1555         test "x$LD" = x ||
1556         test x$glibcxx_gnu_ld_version = x; then
1557   enable_symvers=no
1558 fi
1559
1560 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1561 if test $enable_symvers != no; then
1562   AC_MSG_CHECKING([for shared libgcc])
1563   ac_save_CFLAGS="$CFLAGS"
1564   CFLAGS=' -lgcc_s'
1565   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1566   CFLAGS="$ac_save_CFLAGS"
1567   AC_MSG_RESULT($glibcxx_shared_libgcc)
1568 fi
1569
1570 # For GNU ld, we need at least this version.  The format is described in
1571 # GLIBCXX_CHECK_LINKER_FEATURES above.
1572 glibcxx_min_gnu_ld_version=21400
1573 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1574
1575 # Check to see if unspecified "yes" value can win, given results above.
1576 # Change "yes" into either "no" or a style name.
1577 if test $enable_symvers = yes; then
1578   if test $with_gnu_ld = yes &&
1579      test $glibcxx_shared_libgcc = yes;
1580   then
1581     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1582       enable_symvers=gnu
1583     else
1584       # The right tools, the right setup, but too old.  Fallbacks?
1585       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1586       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1587       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1588       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1589       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1590         # Globbing fix is present, proper block support is not.
1591         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1592         dnl enable_symvers=???
1593         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1594         enable_symvers=no
1595       else
1596         # 2.11 or older.
1597         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1598         enable_symvers=no
1599       fi
1600     fi
1601   else
1602     # just fail for now
1603     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1604     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1605     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1606     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1607     enable_symvers=no
1608   fi
1609 fi
1610
1611 # Everything parsed; figure out what file to use.
1612 case $enable_symvers in
1613   no)
1614     SYMVER_MAP=config/linker-map.dummy
1615     ;;
1616   gnu)
1617     SYMVER_MAP=config/linker-map.gnu
1618     AC_DEFINE(_GLIBCXX_SYMVER)
1619     ;;
1620 esac
1621
1622 AC_SUBST(SYMVER_MAP)
1623 AC_SUBST(port_specific_symbol_files)
1624 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1625 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1626 ])
1627
1628
1629 dnl
1630 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1631 dnl We must stage the required headers so that they will be installed
1632 dnl with the library (unlike libgcc, the STL implementation is provided
1633 dnl solely within headers).  Since we must not inject random user-space
1634 dnl macro names into user-provided C++ code, we first stage into <file>-in
1635 dnl and process to <file> with an output command.  The reason for a two-
1636 dnl stage process here is to correctly handle $srcdir!=$objdir without
1637 dnl having to write complex code (the sed commands to clean the macro
1638 dnl namespace are complex and fragile enough as it is).  We must also
1639 dnl add a relative path so that -I- is supported properly.
1640 dnl
1641 dnl Substs:
1642 dnl  glibcxx_thread_h
1643 dnl
1644 dnl Defines:
1645 dnl  HAVE_GTHR_DEFAULT
1646 dnl  _GLIBCXX_SUPPORTS_WEAK
1647 dnl
1648 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1649   AC_MSG_CHECKING([for thread model used by GCC])
1650   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1651   AC_MSG_RESULT([$target_thread_file])
1652
1653   if test $target_thread_file != single; then
1654     AC_DEFINE(HAVE_GTHR_DEFAULT)
1655     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1656   fi
1657
1658   glibcxx_thread_h=gthr-$target_thread_file.h
1659   AC_SUBST(glibcxx_thread_h)
1660 ])
1661
1662
1663 # Check whether LC_MESSAGES is available in <locale.h>.
1664 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1665 #
1666 # This file file be copied and used freely without restrictions.  It can
1667 # be used in projects which are not available under the GNU Public License
1668 # but which still want to provide support for the GNU gettext functionality.
1669 # Please note that the actual code is *not* freely available.
1670
1671 # serial 1
1672 AC_DEFUN(AC_LC_MESSAGES, [
1673   AC_CHECK_HEADER(locale.h, [
1674     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1675       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1676        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1677     if test $ac_cv_val_LC_MESSAGES = yes; then
1678       AC_DEFINE(HAVE_LC_MESSAGES)
1679     fi
1680   ])
1681 ])
1682
1683
1684 sinclude([../libtool.m4])
1685 dnl The lines below arrange for aclocal not to bring an installed
1686 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1687 dnl add a definition of LIBTOOL to Makefile.in.
1688 ifelse(,,,[AC_SUBST(LIBTOOL)
1689 AC_DEFUN([AM_PROG_LIBTOOL])
1690 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1691 AC_DEFUN([AC_PROG_LD])
1692 ])
1693
1694 dnl vim:et:ts=2:sw=2