libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  gcc_version          (x.y.z format)
  36 dnl  SUBDIRS
  37 dnl Substs:
  38 dnl  glibcxx_builddir     (absolute path)
  39 dnl  glibcxx_srcdir       (absolute path)
  40 dnl  toplevel_srcdir      (absolute path)
  41 dnl  with_cross_host
  42 dnl  with_newlib
  43 dnl  with_target_subdir
  44 dnl plus
  45 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  46 dnl  - default settings for all AM_CONFITIONAL test variables
  47 dnl  - lots of tools, like CC and CXX
  48 dnl
  49 AC_DEFUN([GLIBCXX_CONFIGURE], [
  50   # Keep these sync'd with the list in Makefile.am.  The first provides an
  51   # expandable list at autoconf time; the second provides an expandable list
  52   # (i.e., shell variable) at configure time.
  53   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  54   SUBDIRS='glibcxx_SUBDIRS'
  55
  56   # These need to be absolute paths, yet at the same time need to
  57   # canonicalize only relative paths, because then amd will not unmount
  58   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  59   glibcxx_builddir=`${PWDCMD-pwd}`
  60   case $srcdir in
  61     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  62     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  63   esac
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_srcdir)
  68
  69   # We use these options to decide which functions to include.  They are
  70   # set from the top level.
  71   AC_ARG_WITH([target-subdir],
  72     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  73                    [configuring in a subdirectory]))
  74
  75   AC_ARG_WITH([cross-host],
  76     AC_HELP_STRING([--with-cross-host=HOST],
  77                    [configuring with a cross compiler]))
  78
  79   AC_ARG_WITH([newlib],
  80     AC_HELP_STRING([--with-newlib],
  81                    [assume newlib as a system C library]))
  82
  83   # We're almost certainly being configured before anything else which uses
  84   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  85   # we not cache the value of CXX that we "discover" here, because it's set
  86   # to something unique for us and libjava.  Other target libraries need to
  87   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  88   # process by sneakily renaming the cache variable.  This also lets us debug
  89   # the value of "our" CXX in postmortems.
  90   #
  91   # We must also force CXX to /not/ be a precious variable, otherwise the
  92   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  93   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  94   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  95   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  96   #
  97   # -fno-builtin must be present here so that a non-conflicting form of
  98   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  99
 100   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103   save_CXXFLAGS="$CXXFLAGS"
 104   CXXFLAGS="$CXXFLAGS -fno-builtin"
 105   AC_PROG_CC
 106   AC_PROG_CXX
 107   CXXFLAGS="$save_CXXFLAGS"
 108   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109   AC_SUBST(CFLAGS)
 110   AC_SUBST(CXXFLAGS)
 111
 112   # For directory versioning (e.g., headers) and other variables.
 113   AC_MSG_CHECKING([for GCC version number])
 114   gcc_version=`$CXX -dumpversion`
 115   AC_MSG_RESULT($gcc_version)
 116
 117   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 118   # available).  Uncomment the next line to force a particular method.
 119   AC_PROG_LN_S
 120   #LN_S='cp -p'
 121
 122   AC_CHECK_TOOL(AS, as)
 123   AC_CHECK_TOOL(AR, ar)
 124   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 125
 126   AM_MAINTAINER_MODE
 127
 128   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 129   # which are themselves conditionally expanded.
 130   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 131   ## other macros from doing the same.  This should be automated.)  -pme
 132   need_libmath=no
 133   enable_wchar_t=no
 134   #enable_libstdcxx_debug=no
 135   #enable_libstdcxx_pch=no
 136   #enable_cheaders=c
 137   #c_compatibility=no
 138   #enable_abi_check=no
 139   #enable_symvers=no
 140   #enable_hosted_libstdcxx=yes
 141
 142   # Find platform-specific directories containing configuration info.
 143   # Also possibly modify flags used elsewhere, as needed by the platform.
 144   GLIBCXX_CHECK_HOST
 145 ])
 146
 147
 148 m4_include([linkage.m4])
 149 m4_include([../config/no-executables.m4])
 150
 151
 152 dnl
 153 dnl Tests for newer compiler features, or features that are present in newer
 154 dnl compiler versions but not older compiler versions still in use, should
 155 dnl be placed here.
 156 dnl
 157 dnl Defines:
 158 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 159 dnl   new inlining code or the new system_header pragma will die on -Werror.
 160 dnl   Leave it out by default and use maint-mode to use it.
 161 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 162 dnl   compiler supports it and the user has not requested debug mode.
 163 dnl
 164 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 165   # All these tests are for C++; save the language and the compiler flags.
 166   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 167   # found in GLIBCXX_CONFIGURE.
 168   AC_LANG_SAVE
 169   AC_LANG_CPLUSPLUS
 170   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 171   ac_save_CXXFLAGS="$CXXFLAGS"
 172
 173   # Check for maintainer-mode bits.
 174   if test x"$USE_MAINTAINER_MODE" = xno; then
 175     WERROR=''
 176   else
 177     WERROR='-Werror'
 178   fi
 179
 180   # Check for -ffunction-sections -fdata-sections
 181   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 182   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 183   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 184   if test "$ac_test_CXXFLAGS" = set; then
 185     CXXFLAGS="$ac_save_CXXFLAGS"
 186   else
 187     # this is the suspicious part
 188     CXXFLAGS=''
 189   fi
 190   if test x"$ac_fdsections" = x"yes"; then
 191     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 192   fi
 193   AC_MSG_RESULT($ac_fdsections)
 194
 195   AC_LANG_RESTORE
 196   AC_SUBST(WERROR)
 197   AC_SUBST(SECTION_FLAGS)
 198 ])
 199
 200
 201 dnl
 202 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 203 dnl the native linker is in use, all variables will be defined to something
 204 dnl safe (like an empty string).
 205 dnl
 206 dnl Defines:
 207 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 208 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 209 dnl  LD (as a side effect of testing)
 210 dnl Sets:
 211 dnl  with_gnu_ld
 212 dnl  glibcxx_gnu_ld_version (possibly)
 213 dnl
 214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 215 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 216 dnl
 217 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 218   # If we're not using GNU ld, then there's no point in even trying these
 219   # tests.  Check for that first.  We should have already tested for gld
 220   # by now (in libtool), but require it now just to be safe...
 221   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 222   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 223   AC_REQUIRE([AC_PROG_LD])
 224   AC_REQUIRE([AC_PROG_AWK])
 225
 226   # The name set by libtool depends on the version of libtool.  Shame on us
 227   # for depending on an impl detail, but c'est la vie.  Older versions used
 228   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 229   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 230   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 231   # set (hence we're using an older libtool), then set it.
 232   if test x${with_gnu_ld+set} != xset; then
 233     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 234       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 235       with_gnu_ld=no
 236     else
 237       with_gnu_ld=$ac_cv_prog_gnu_ld
 238     fi
 239   fi
 240
 241   # Start by getting the version number.  I think the libtool test already
 242   # does some of this, but throws away the result.
 243   changequote(,)
 244   ldver=`$LD --version 2>/dev/null | head -1 | \
 245          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 246   changequote([,])
 247   glibcxx_gnu_ld_version=`echo $ldver | \
 248          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 249
 250   # Set --gc-sections.
 251   if test "$with_gnu_ld" = "notbroken"; then
 252     # GNU ld it is!  Joy and bunny rabbits!
 253
 254     # All these tests are for C++; save the language and the compiler flags.
 255     # Need to do this so that g++ won't try to link in libstdc++
 256     ac_test_CFLAGS="${CFLAGS+set}"
 257     ac_save_CFLAGS="$CFLAGS"
 258     CFLAGS='-x c++  -Wl,--gc-sections'
 259
 260     # Check for -Wl,--gc-sections
 261     # XXX This test is broken at the moment, as symbols required for linking
 262     # are now in libsupc++ (not built yet).  In addition, this test has
 263     # cored on solaris in the past.  In addition, --gc-sections doesn't
 264     # really work at the moment (keeps on discarding used sections, first
 265     # .eh_frame and now some of the glibc sections for iconv).
 266     # Bzzzzt.  Thanks for playing, maybe next time.
 267     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 268     AC_TRY_RUN([
 269      int main(void)
 270      {
 271        try { throw 1; }
 272        catch (...) { };
 273        return 0;
 274      }
 275     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 276     if test "$ac_test_CFLAGS" = set; then
 277       CFLAGS="$ac_save_CFLAGS"
 278     else
 279       # this is the suspicious part
 280       CFLAGS=''
 281     fi
 282     if test "$ac_sectionLDflags" = "yes"; then
 283       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 284     fi
 285     AC_MSG_RESULT($ac_sectionLDflags)
 286   fi
 287
 288   # Set linker optimization flags.
 289   if test x"$with_gnu_ld" = x"yes"; then
 290     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 291   fi
 292
 293   AC_SUBST(SECTION_LDFLAGS)
 294   AC_SUBST(OPT_LDFLAGS)
 295 ])
 296
 297
 298 dnl
 299 dnl Check to see if this target can enable the wchar_t parts.
 300 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 301 dnl must have been previously checked.)  By default, wide characters are
 302 dnl disabled.
 303 dnl
 304 dnl Defines:
 305 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 306 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 307 dnl Substs:
 308 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 309 dnl
 310 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
 311   # Test wchar.h for mbstate_t, which is needed for char_traits and
 312   # others even if wchar_t support is not on.
 313   AC_MSG_CHECKING([for mbstate_t])
 314   AC_TRY_COMPILE([#include <wchar.h>],
 315   [mbstate_t teststate;],
 316   have_mbstate_t=yes, have_mbstate_t=no)
 317   AC_MSG_RESULT($have_mbstate_t)
 318   if test x"$have_mbstate_t" = xyes; then
 319     AC_DEFINE(HAVE_MBSTATE_T)
 320   fi
 321
 322   # Sanity check for existence of ISO C99 headers for extended encoding.
 323   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 324   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 325
 326   # Only continue checking if the ISO C99 headers exist and support is on.
 327   if test x"$ac_has_wchar_h" = xyes &&
 328      test x"$ac_has_wctype_h" = xyes &&
 329      test x"$enable_c_mbchar" != xno; then
 330
 331     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 332     # numeric_limits can instantiate type_traits<wchar_t>
 333     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 334     AC_TRY_COMPILE([#include <wchar.h>],
 335     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 336     has_wchar_minmax=yes, has_wchar_minmax=no)
 337     AC_MSG_RESULT($has_wchar_minmax)
 338
 339     # Test wchar.h for WEOF, which is what we use to determine whether
 340     # to specialize for char_traits<wchar_t> or not.
 341     AC_MSG_CHECKING([for WEOF])
 342     AC_TRY_COMPILE([
 343       #include <wchar.h>
 344       #include <stddef.h>],
 345     [wint_t i = WEOF;],
 346     has_weof=yes, has_weof=no)
 347     AC_MSG_RESULT($has_weof)
 348
 349     # Tests for wide character functions used in char_traits<wchar_t>.
 350     ac_wfuncs=yes
 351     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 352     [],[ac_wfuncs=no])
 353
 354     # Checks for names injected into std:: by the c_std headers.
 355     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 356     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 357     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 358     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 359     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 360     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 361     [],[ac_wfuncs=no])
 362
 363     # Checks for wide character functions that are not required
 364     # for basic wchar_t support.  Don't disable support if they are missing.
 365     # Injection of these is wrapped with guard macros.
 366     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 367
 368     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 369     if test x"$has_weof" = xyes &&
 370        test x"$has_wchar_minmax" = xyes &&
 371        test x"$ac_wfuncs" = xyes;
 372     then
 373       ac_isoC99_wchar_t=yes
 374     else
 375       ac_isoC99_wchar_t=no
 376     fi
 377     AC_MSG_RESULT($ac_isoC99_wchar_t)
 378
 379     # Use iconv for wchar_t to char conversions. As such, check for
 380     # X/Open Portability Guide, version 2 features (XPG2).
 381     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 382     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 383
 384     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 385     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 386     ac_save_LIBS="$LIBS"
 387     LIBS="$LIBS $LIBICONV"
 388     AC_SUBST(LIBICONV)
 389
 390     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 391     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 392
 393     LIBS="$ac_save_LIBS"
 394
 395     AC_MSG_CHECKING([for XPG2 wchar_t support])
 396     if test x"$ac_has_iconv_h" = xyes &&
 397        test x"$ac_has_langinfo_h" = xyes &&
 398        test x"$ac_XPG2funcs" = xyes;
 399     then
 400       ac_XPG2_wchar_t=yes
 401     else
 402       ac_XPG2_wchar_t=no
 403     fi
 404     AC_MSG_RESULT($ac_XPG2_wchar_t)
 405
 406     # At the moment, only enable wchar_t specializations if all the
 407     # above support is present.
 408     if test x"$ac_isoC99_wchar_t" = xyes &&
 409        test x"$ac_XPG2_wchar_t" = xyes;
 410     then
 411       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 412       enable_wchar_t=yes
 413     fi
 414   fi
 415   AC_MSG_CHECKING([for enabled wchar_t specializations])
 416   AC_MSG_RESULT($enable_wchar_t)
 417 ])
 418
 419
 420 dnl
 421 dnl Check for headers for, and arguments to, the setrlimit() function.
 422 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 423 dnl
 424 dnl Defines:
 425 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 426 dnl  various HAVE_LIMIT_* for individual limit names
 427 dnl
 428 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 429   AC_TRY_COMPILE(
 430     [#include <unistd.h>
 431      #include <sys/time.h>
 432      #include <sys/resource.h>
 433     ],
 434     [ int f = RLIMIT_$1 ; ],
 435     [glibcxx_mresult=1], [glibcxx_mresult=0])
 436   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 437                      [Only used in build directory testsuite_hooks.h.])
 438 ])
 439
 440 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 441   setrlimit_have_headers=yes
 442   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 443                    [],
 444                    [setrlimit_have_headers=no])
 445   # If don't have the headers, then we can't run the tests now, and we
 446   # won't be seeing any of these during testsuite compilation.
 447   if test $setrlimit_have_headers = yes; then
 448     # Can't do these in a loop, else the resulting syntax is wrong.
 449     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 450     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 451     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 452     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 453     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 454
 455     # Check for rlimit, setrlimit.
 456     AC_CACHE_VAL(ac_setrlimit, [
 457       AC_TRY_COMPILE(
 458         [#include <unistd.h>
 459          #include <sys/time.h>
 460          #include <sys/resource.h>
 461         ],
 462         [struct rlimit r;
 463          setrlimit(0, &r);],
 464         [ac_setrlimit=yes], [ac_setrlimit=no])
 465     ])
 466   fi
 467
 468   AC_MSG_CHECKING([for testsuite resource limits support])
 469   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 470     ac_res_limits=yes
 471     AC_DEFINE(_GLIBCXX_RES_LIMITS)
 472   else
 473     ac_res_limits=no
 474   fi
 475   AC_MSG_RESULT($ac_res_limits)
 476 ])
 477
 478
 479 dnl
 480 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 481 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 482 dnl
 483 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 484   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 485     AC_TRY_LINK(
 486       [#include <sys/stat.h>],
 487       [struct stat buffer;
 488        fstat(0, &buffer);
 489        S_ISREG(buffer.st_mode);],
 490       [glibcxx_cv_S_ISREG=yes],
 491       [glibcxx_cv_S_ISREG=no])
 492   ])
 493   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 494     AC_TRY_LINK(
 495       [#include <sys/stat.h>],
 496       [struct stat buffer;
 497        fstat(0, &buffer);
 498        S_IFREG & buffer.st_mode;],
 499       [glibcxx_cv_S_IFREG=yes],
 500       [glibcxx_cv_S_IFREG=no])
 501   ])
 502   if test $glibcxx_cv_S_ISREG = yes; then
 503     AC_DEFINE(HAVE_S_ISREG)
 504   elif test $glibcxx_cv_S_IFREG = yes; then
 505     AC_DEFINE(HAVE_S_IFREG)
 506   fi
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 514   AC_CACHE_VAL(glibcxx_cv_POLL, [
 515     AC_TRY_LINK(
 516       [#include <poll.h>],
 517       [struct pollfd pfd[1];
 518        pfd[0].events = POLLIN;
 519        poll(pfd, 1, 0);],
 520       [glibcxx_cv_POLL=yes],
 521       [glibcxx_cv_POLL=no])
 522   ])
 523   if test $glibcxx_cv_POLL = yes; then
 524     AC_DEFINE(HAVE_POLL)
 525   fi
 526 ])
 527
 528
 529 dnl
 530 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 531 dnl
 532 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 533   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 534     AC_TRY_LINK(
 535       [#include <sys/uio.h>],
 536       [struct iovec iov[2];
 537        writev(0, iov, 0);],
 538       [glibcxx_cv_WRITEV=yes],
 539       [glibcxx_cv_WRITEV=no])
 540   ])
 541   if test $glibcxx_cv_WRITEV = yes; then
 542     AC_DEFINE(HAVE_WRITEV)
 543   fi
 544 ])
 545
 546
 547 dnl
 548 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 549 dnl
 550 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 551   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 552     AC_TRY_COMPILE(
 553       [#include <stdint.h>],
 554       [int64_t var;],
 555       [glibcxx_cv_INT64_T=yes],
 556       [glibcxx_cv_INT64_T=no])
 557   ])
 558   if test $glibcxx_cv_INT64_T = yes; then
 559     AC_DEFINE(HAVE_INT64_T)
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Check whether LFS support is available.
 566 dnl
 567 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 568   AC_LANG_SAVE
 569   AC_LANG_CPLUSPLUS
 570   ac_save_CXXFLAGS="$CXXFLAGS"
 571   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 572   AC_CACHE_VAL(glibcxx_cv_LFS, [
 573     AC_TRY_LINK(
 574       [#include <unistd.h>
 575        #include <stdio.h>
 576        #include <sys/stat.h>
 577       ],
 578       [FILE* fp;
 579        fopen64("t", "w");
 580        fseeko64(fp, 0, SEEK_CUR);
 581        ftello64(fp);
 582        lseek64(1, 0, SEEK_CUR);
 583        struct stat64 buf;
 584        fstat64(1, &buf);],
 585       [glibcxx_cv_LFS=yes],
 586       [glibcxx_cv_LFS=no])
 587   ])
 588   if test $glibcxx_cv_LFS = yes; then
 589     AC_DEFINE(_GLIBCXX_USE_LFS)
 590   fi
 591   CXXFLAGS="$ac_save_CXXFLAGS"
 592   AC_LANG_RESTORE
 593 ])
 594
 595
 596 dnl
 597 dnl Check for whether a fully dynamic basic_string implementation should
 598 dnl be turned on, that does not put empty objects in per-process static
 599 dnl memory (mostly useful together with shared memory allocators, see PR
 600 dnl libstdc++/16612 for details).
 601 dnl
 602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 603 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 604 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 605 dnl       Where DEFAULT is either `yes' or `no'.
 606 dnl
 607 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 608   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 609   if test $enable_fully_dynamic_string = yes; then
 610     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING)
 611   fi
 612 ])
 613
 614
 615 dnl
 616 dnl Does any necessary configuration of the testsuite directory.  Generates
 617 dnl the testsuite_hooks.h header.
 618 dnl
 619 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 620 dnl
 621 dnl Sets:
 622 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 623 dnl  GLIBCXX_TEST_WCHAR_T
 624 dnl  GLIBCXX_TEST_THREAD
 625 dnl Substs:
 626 dnl  baseline_dir
 627 dnl
 628 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 629   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 630     # Do checks for resource limit functions.
 631     GLIBCXX_CHECK_SETRLIMIT
 632
 633     # Look for setenv, so that extended locale tests can be performed.
 634     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 635
 636     if test $enable_symvers = no; then
 637       enable_abi_check=no
 638     else
 639       case "$host" in
 640         *-*-cygwin*)
 641           enable_abi_check=no ;;
 642         *)
 643           enable_abi_check=yes ;;
 644       esac
 645     fi
 646   else
 647     # Only build this as native, since automake does not understand
 648     # CXX_FOR_BUILD.
 649     enable_abi_check=no
 650   fi
 651
 652   # Export file names for ABI checking.
 653   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 654   AC_SUBST(baseline_dir)
 655
 656   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 657   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_THREAD, test $enable_thread = yes)
 658   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 659 ])
 660
 661
 662 dnl
 663 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 664 dnl
 665 dnl Substs:
 666 dnl  GLIBCXX_INCLUDES
 667 dnl  TOPLEVEL_INCLUDES
 668 dnl
 669 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 670   # Used for every C++ compile we perform.
 671   GLIBCXX_INCLUDES="\
 672 -I$glibcxx_builddir/include/$host_alias \
 673 -I$glibcxx_builddir/include \
 674 -I$glibcxx_srcdir/libsupc++"
 675
 676   # For Canadian crosses, pick this up too.
 677   if test $CANADIAN = yes; then
 678     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 679   fi
 680
 681   # Stuff in the actual top level.  Currently only used by libsupc++ to
 682   # get unwind* headers from the gcc dir.
 683   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 684   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 685
 686   # Now, export this to all the little Makefiles....
 687   AC_SUBST(GLIBCXX_INCLUDES)
 688   AC_SUBST(TOPLEVEL_INCLUDES)
 689 ])
 690
 691
 692 dnl
 693 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 694 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 695 dnl
 696 dnl Substs:
 697 dnl  OPTIMIZE_CXXFLAGS
 698 dnl  WARN_FLAGS
 699 dnl
 700 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 701   # Optimization flags that are probably a good idea for thrill-seekers. Just
 702   # uncomment the lines below and make, everything else is ready to go...
 703   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 704   OPTIMIZE_CXXFLAGS=
 705   AC_SUBST(OPTIMIZE_CXXFLAGS)
 706
 707   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 708   AC_SUBST(WARN_FLAGS)
 709 ])
 710
 711
 712 dnl
 713 dnl All installation directory information is determined here.
 714 dnl
 715 dnl Substs:
 716 dnl  gxx_install_dir
 717 dnl  glibcxx_prefixdir
 718 dnl  glibcxx_toolexecdir
 719 dnl  glibcxx_toolexeclibdir
 720 dnl
 721 dnl Assumes cross_compiling bits already done, and with_cross_host in
 722 dnl particular.
 723 dnl
 724 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 725   glibcxx_toolexecdir=no
 726   glibcxx_toolexeclibdir=no
 727   glibcxx_prefixdir=$prefix
 728
 729   AC_MSG_CHECKING([for gxx-include-dir])
 730   AC_ARG_WITH([gxx-include-dir],
 731     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 732                    [installation directory for include files]),
 733     [case "$withval" in
 734       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 735       no)  gxx_include_dir=no ;;
 736       *)   gxx_include_dir=$withval ;;
 737      esac],
 738     [gxx_include_dir=no])
 739   AC_MSG_RESULT($gxx_include_dir)
 740
 741   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 742   AC_ARG_ENABLE([version-specific-runtime-libs],
 743     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 744                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 745     [case "$enableval" in
 746       yes) version_specific_libs=yes ;;
 747       no)  version_specific_libs=no ;;
 748       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 749      esac],
 750     [version_specific_libs=no])
 751   AC_MSG_RESULT($version_specific_libs)
 752
 753   # Default case for install directory for include files.
 754   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 755     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 756   fi
 757
 758   # Version-specific runtime libs processing.
 759   if test $version_specific_libs = yes; then
 760     # Need the gcc compiler version to know where to install libraries
 761     # and header files if --enable-version-specific-runtime-libs option
 762     # is selected.  FIXME: these variables are misnamed, there are
 763     # no executables installed in _toolexecdir or _toolexeclibdir.
 764     if test x"$gxx_include_dir" = x"no"; then
 765       gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
 766     fi
 767     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 768     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 769   fi
 770
 771   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 772   # Install a library built with a cross compiler in tooldir, not libdir.
 773   if test x"$glibcxx_toolexecdir" = x"no"; then
 774     if test -n "$with_cross_host" &&
 775        test x"$with_cross_host" != x"no"; then
 776       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 777       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 778     else
 779       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 780       glibcxx_toolexeclibdir='${libdir}'
 781     fi
 782     multi_os_directory=`$CXX -print-multi-os-directory`
 783     case $multi_os_directory in
 784       .) ;; # Avoid trailing /.
 785       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 786     esac
 787   fi
 788
 789   AC_MSG_CHECKING([for install location])
 790   AC_MSG_RESULT($gxx_include_dir)
 791
 792   AC_SUBST(glibcxx_prefixdir)
 793   AC_SUBST(gxx_include_dir)
 794   AC_SUBST(glibcxx_toolexecdir)
 795   AC_SUBST(glibcxx_toolexeclibdir)
 796 ])
 797
 798
 799 dnl
 800 dnl GLIBCXX_ENABLE
 801 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 802 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 803 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 804 dnl
 805 dnl See docs/html/17_intro/configury.html#enable for documentation.
 806 dnl
 807 m4_define([GLIBCXX_ENABLE],[dnl
 808 m4_define([_g_switch],[--enable-$1])dnl
 809 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 810  AC_ARG_ENABLE($1,_g_help,
 811   m4_bmatch([$5],
 812    [^permit ],
 813      [[
 814       case "$enableval" in
 815        m4_bpatsubst([$5],[permit ])) ;;
 816        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 817           dnl Idea for future:  generate a URL pointing to
 818           dnl "onlinedocs/configopts.html#whatever"
 819       esac
 820      ]],
 821    [^$],
 822      [[
 823       case "$enableval" in
 824        yes|no) ;;
 825        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 826       esac
 827      ]],
 828    [[$5]]),
 829   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 830 m4_undefine([_g_switch])dnl
 831 m4_undefine([_g_help])dnl
 832 ])
 833
 834
 835 dnl
 836 dnl Check for ISO/IEC 9899:1999 "C99" support.
 837 dnl
 838 dnl --enable-c99 defines _GLIBCXX_USE_C99
 839 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 840 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 841 dnl       Where DEFAULT is either `yes' or `no'.
 842 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 843 dnl
 844 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 845   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 846
 847   AC_LANG_SAVE
 848   AC_LANG_CPLUSPLUS
 849
 850   # Check for the existence of <math.h> functions used if C99 is enabled.
 851   ac_c99_math=yes;
 852   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 853   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 856   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 860   AC_TRY_COMPILE([#include <math.h>],
 861                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 864   AC_TRY_COMPILE([#include <math.h>],
 865                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 866   AC_TRY_COMPILE([#include <math.h>],
 867                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 868   AC_MSG_RESULT($ac_c99_math)
 869
 870   if test x"$ac_c99_math" = x"yes"; then
 871     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 872   fi
 873
 874   # Check for the existence in <stdio.h> of vscanf, et. al.
 875   ac_c99_stdio=yes;
 876   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 877   AC_TRY_COMPILE([#include <stdio.h>],
 878                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 879   AC_TRY_COMPILE([#include <stdio.h>
 880                   #include <stdarg.h>
 881                   void foo(char* fmt, ...)
 882                   {va_list args; va_start(args, fmt);
 883                   vfscanf(stderr, "%i", args);}],
 884                   [],, [ac_c99_stdio=no])
 885   AC_TRY_COMPILE([#include <stdio.h>
 886                   #include <stdarg.h>
 887                   void foo(char* fmt, ...)
 888                   {va_list args; va_start(args, fmt);
 889                   vscanf("%i", args);}],
 890                   [],, [ac_c99_stdio=no])
 891   AC_TRY_COMPILE([#include <stdio.h>
 892                   #include <stdarg.h>
 893                   void foo(char* fmt, ...)
 894                   {va_list args; va_start(args, fmt);
 895                   vsnprintf(fmt, 0, "%i", args);}],
 896                   [],, [ac_c99_stdio=no])
 897   AC_TRY_COMPILE([#include <stdio.h>
 898                   #include <stdarg.h>
 899                   void foo(char* fmt, ...)
 900                   {va_list args; va_start(args, fmt);
 901                   vsscanf(fmt, "%i", args);}],
 902                   [],, [ac_c99_stdio=no])
 903   AC_MSG_RESULT($ac_c99_stdio)
 904
 905   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 906   ac_c99_stdlib=yes;
 907   AC_MSG_CHECKING([for lldiv_t declaration])
 908   AC_CACHE_VAL(ac_c99_lldiv_t, [
 909   AC_TRY_COMPILE([#include <stdlib.h>],
 910                    [ lldiv_t mydivt;],
 911                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 912   ])
 913   AC_MSG_RESULT($ac_c99_lldiv_t)
 914
 915   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 916   AC_TRY_COMPILE([#include <stdlib.h>],
 917                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 918   AC_TRY_COMPILE([#include <stdlib.h>],
 919                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 920   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 921   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 922   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 923   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 924   if test x"$ac_c99_lldiv_t" = x"no"; then
 925     ac_c99_stdlib=no;
 926   fi;
 927   AC_MSG_RESULT($ac_c99_stdlib)
 928
 929   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 930   # XXX the wchar.h checks should be rolled into the general C99 bits.
 931   ac_c99_wchar=yes;
 932   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 933   AC_TRY_COMPILE([#include <wchar.h>],
 934                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 935   AC_TRY_COMPILE([#include <wchar.h>],
 936                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 937   AC_TRY_COMPILE([#include <wchar.h>],
 938                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 939   AC_MSG_RESULT($ac_c99_wchar)
 940
 941   AC_MSG_CHECKING([for enabled ISO C99 support])
 942   if test x"$ac_c99_math" = x"no" ||
 943      test x"$ac_c99_stdio" = x"no" ||
 944      test x"$ac_c99_stdlib" = x"no" ||
 945      test x"$ac_c99_wchar" = x"no"; then
 946     enable_c99=no;
 947   fi;
 948   AC_MSG_RESULT($enable_c99)
 949
 950   if test x"$ac_99_math" = x"yes"; then
 951     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 952   fi
 953
 954   # Option parsed, now set things appropriately
 955   if test x"$enable_c99" = x"yes"; then
 956     AC_DEFINE(_GLIBCXX_USE_C99)
 957   fi
 958
 959   AC_LANG_RESTORE
 960 ])
 961
 962
 963 dnl
 964 dnl Check for what type of C headers to use.
 965 dnl
 966 dnl --enable-cheaders= [does stuff].
 967 dnl --disable-cheaders [does not do anything, really].
 968 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 969 dnl       Where DEFAULT is either `c' or `c_std'.
 970 dnl
 971 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
 972   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 973     [construct "C" headers for g++], [permit c|c_std])
 974   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 975
 976   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 977
 978   AC_SUBST(C_INCLUDE_DIR)
 979   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 980   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 981   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 982 ])
 983
 984
 985 dnl
 986 dnl Check for which locale library to use.  The choice is mapped to
 987 dnl a subdirectory of config/locale.
 988 dnl
 989 dnl Default is generic.
 990 dnl
 991 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
 992   AC_MSG_CHECKING([for C locale to use])
 993   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 994     [use MODEL for target locale package],
 995     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 996
 997   # If they didn't use this option switch, or if they specified --enable
 998   # with no specific model, we'll have to look for one.  If they
 999   # specified --disable (???), do likewise.
1000   if test $enable_clocale = no || test $enable_clocale = yes; then
1001      enable_clocale=auto
1002   fi
1003
1004   # Either a known package, or "auto"
1005   enable_clocale_flag=$enable_clocale
1006
1007   # Probe for locale support if no specific model is specified.
1008   # Default to "generic".
1009   if test $enable_clocale_flag = auto; then
1010     case ${target_os} in
1011       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1012         AC_EGREP_CPP([_GLIBCXX_ok], [
1013         #include <features.h>
1014         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1015           _GLIBCXX_ok
1016         #endif
1017         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1018
1019         # Test for bugs early in glibc-2.2.x series
1020           if test $enable_clocale_flag = gnu; then
1021           AC_TRY_RUN([
1022           #define _GNU_SOURCE 1
1023           #include <locale.h>
1024           #include <string.h>
1025           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1026           extern __typeof(newlocale) __newlocale;
1027           extern __typeof(duplocale) __duplocale;
1028           extern __typeof(strcoll_l) __strcoll_l;
1029           #endif
1030           int main()
1031           {
1032               const char __one[] = "Äuglein Augmen";
1033               const char __two[] = "Äuglein";
1034               int i;
1035               int j;
1036               __locale_t        loc;
1037                __locale_t        loc_dup;
1038               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1039               loc_dup = __duplocale(loc);
1040               i = __strcoll_l(__one, __two, loc);
1041               j = __strcoll_l(__one, __two, loc_dup);
1042               return 0;
1043           }
1044           ],
1045           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1046           [enable_clocale_flag=generic])
1047           fi
1048
1049         # ... at some point put __strxfrm_l tests in as well.
1050         ;;
1051       darwin*)
1052         enable_clocale_flag=darwin
1053         ;;
1054       *)
1055         enable_clocale_flag=generic
1056         ;;
1057     esac
1058   fi
1059
1060   # Deal with gettext issues.  Default to not using it (=no) until we detect
1061   # support for it later.  Let the user turn it off via --e/d, but let that
1062   # default to on for easier handling.
1063   USE_NLS=no
1064   AC_ARG_ENABLE(nls,
1065     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1066     [],
1067     [enable_nls=yes])
1068
1069   # Set configure bits for specified locale package
1070   case ${enable_clocale_flag} in
1071     generic)
1072       AC_MSG_RESULT(generic)
1073
1074       CLOCALE_H=config/locale/generic/c_locale.h
1075       CLOCALE_CC=config/locale/generic/c_locale.cc
1076       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1077       CCOLLATE_CC=config/locale/generic/collate_members.cc
1078       CCTYPE_CC=config/locale/generic/ctype_members.cc
1079       CMESSAGES_H=config/locale/generic/messages_members.h
1080       CMESSAGES_CC=config/locale/generic/messages_members.cc
1081       CMONEY_CC=config/locale/generic/monetary_members.cc
1082       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1083       CTIME_H=config/locale/generic/time_members.h
1084       CTIME_CC=config/locale/generic/time_members.cc
1085       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1086       ;;
1087     darwin)
1088       AC_MSG_RESULT(darwin)
1089
1090       CLOCALE_H=config/locale/generic/c_locale.h
1091       CLOCALE_CC=config/locale/generic/c_locale.cc
1092       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1093       CCOLLATE_CC=config/locale/generic/collate_members.cc
1094       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1095       CMESSAGES_H=config/locale/generic/messages_members.h
1096       CMESSAGES_CC=config/locale/generic/messages_members.cc
1097       CMONEY_CC=config/locale/generic/monetary_members.cc
1098       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1099       CTIME_H=config/locale/generic/time_members.h
1100       CTIME_CC=config/locale/generic/time_members.cc
1101       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1102       ;;
1103
1104     gnu)
1105       AC_MSG_RESULT(gnu)
1106
1107       # Declare intention to use gettext, and add support for specific
1108       # languages.
1109       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1110       ALL_LINGUAS="de fr"
1111
1112       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1113       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1114       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1115         USE_NLS=yes
1116       fi
1117       # Export the build objects.
1118       for ling in $ALL_LINGUAS; do \
1119         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1120         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1121       done
1122       AC_SUBST(glibcxx_MOFILES)
1123       AC_SUBST(glibcxx_POFILES)
1124
1125       CLOCALE_H=config/locale/gnu/c_locale.h
1126       CLOCALE_CC=config/locale/gnu/c_locale.cc
1127       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1128       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1129       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1130       CMESSAGES_H=config/locale/gnu/messages_members.h
1131       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1132       CMONEY_CC=config/locale/gnu/monetary_members.cc
1133       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1134       CTIME_H=config/locale/gnu/time_members.h
1135       CTIME_CC=config/locale/gnu/time_members.cc
1136       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1137       ;;
1138     ieee_1003.1-2001)
1139       AC_MSG_RESULT(IEEE 1003.1)
1140
1141       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1142       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1143       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1144       CCOLLATE_CC=config/locale/generic/collate_members.cc
1145       CCTYPE_CC=config/locale/generic/ctype_members.cc
1146       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1147       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1148       CMONEY_CC=config/locale/generic/monetary_members.cc
1149       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1150       CTIME_H=config/locale/generic/time_members.h
1151       CTIME_CC=config/locale/generic/time_members.cc
1152       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1153       ;;
1154   esac
1155
1156   # This is where the testsuite looks for locale catalogs, using the
1157   # -DLOCALEDIR define during testsuite compilation.
1158   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1159   AC_SUBST(glibcxx_localedir)
1160
1161   # A standalone libintl (e.g., GNU libintl) may be in use.
1162   if test $USE_NLS = yes; then
1163     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1164     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1165   fi
1166   if test $USE_NLS = yes; then
1167     AC_DEFINE(_GLIBCXX_USE_NLS)
1168   fi
1169
1170   AC_SUBST(USE_NLS)
1171   AC_SUBST(CLOCALE_H)
1172   AC_SUBST(CMESSAGES_H)
1173   AC_SUBST(CCODECVT_CC)
1174   AC_SUBST(CCOLLATE_CC)
1175   AC_SUBST(CCTYPE_CC)
1176   AC_SUBST(CMESSAGES_CC)
1177   AC_SUBST(CMONEY_CC)
1178   AC_SUBST(CNUMERIC_CC)
1179   AC_SUBST(CTIME_H)
1180   AC_SUBST(CTIME_CC)
1181   AC_SUBST(CLOCALE_CC)
1182   AC_SUBST(CLOCALE_INTERNAL_H)
1183 ])
1184
1185
1186 dnl
1187 dnl Check for which std::allocator base class to use.  The choice is
1188 dnl mapped from a subdirectory of include/ext.
1189 dnl
1190 dnl Default is new.
1191 dnl
1192 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1193   AC_MSG_CHECKING([for std::allocator base class to use])
1194   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1195     [use KIND for target std::allocator base],
1196     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1197
1198   # If they didn't use this option switch, or if they specified --enable
1199   # with no specific model, we'll have to look for one.  If they
1200   # specified --disable (???), do likewise.
1201   if test $enable_libstdcxx_allocator = no ||
1202      test $enable_libstdcxx_allocator = yes;
1203   then
1204      enable_libstdcxx_allocator=auto
1205   fi
1206
1207   # Either a known package, or "auto". Auto implies the default choice
1208   # for a particular platform.
1209   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1210
1211   # Probe for host-specific support if no specific model is specified.
1212   # Default to "new".
1213   if test $enable_libstdcxx_allocator_flag = auto; then
1214     case ${target_os} in
1215       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1216         enable_libstdcxx_allocator_flag=mt
1217         ;;
1218       *)
1219         enable_libstdcxx_allocator_flag=new
1220         ;;
1221     esac
1222   fi
1223   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1224
1225
1226   # Set configure bits for specified locale package
1227   case ${enable_libstdcxx_allocator_flag} in
1228     bitmap)
1229       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1230       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1231       ;;
1232     malloc)
1233       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1234       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1235       ;;
1236     mt)
1237       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1238       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1239       ;;
1240     new)
1241       ALLOCATOR_H=config/allocator/new_allocator_base.h
1242       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1243       ;;
1244     pool)
1245       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1246       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1247       ;;
1248   esac
1249
1250   AC_SUBST(ALLOCATOR_H)
1251   AC_SUBST(ALLOCATOR_NAME)
1252 ])
1253
1254
1255 dnl
1256 dnl Check for whether the Boost-derived checks should be turned on.
1257 dnl
1258 dnl --enable-concept-checks turns them on.
1259 dnl --disable-concept-checks leaves them off.
1260 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1261 dnl       Where DEFAULT is either `yes' or `no'.
1262 dnl
1263 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1264   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1265   if test $enable_concept_checks = yes; then
1266     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1267   fi
1268 ])
1269
1270
1271 dnl
1272 dnl Check for which I/O library to use:  stdio, or something specific.
1273 dnl
1274 dnl Default is stdio.
1275 dnl
1276 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1277   AC_MSG_CHECKING([for underlying I/O to use])
1278   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1279     [use target-specific I/O package], [permit stdio])
1280
1281   # Now that libio has been removed, you can have any color you want as long
1282   # as it's black.  This is one big no-op until other packages are added, but
1283   # showing the framework never hurts.
1284   case ${enable_cstdio} in
1285     stdio)
1286       CSTDIO_H=config/io/c_io_stdio.h
1287       BASIC_FILE_H=config/io/basic_file_stdio.h
1288       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1289       AC_MSG_RESULT(stdio)
1290       ;;
1291   esac
1292
1293   AC_SUBST(CSTDIO_H)
1294   AC_SUBST(BASIC_FILE_H)
1295   AC_SUBST(BASIC_FILE_CC)
1296 ])
1297
1298
1299 dnl
1300 dnl Check for "unusual" flags to pass to the compiler while building.
1301 dnl
1302 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1303 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1304 dnl --disable-cxx-flags passes nothing.
1305 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1306 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1307 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1308 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1309 dnl       If "default flags" is an empty string, the effect is the same
1310 dnl       as --disable or --enable=no.
1311 dnl
1312 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1313   AC_MSG_CHECKING([for extra compiler flags for building])
1314   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1315     [pass compiler FLAGS when building library],
1316     [case "x$enable_cxx_flags" in
1317       xno | x)   enable_cxx_flags= ;;
1318       x-*)       ;;
1319       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1320      esac])
1321
1322   # Run through flags (either default or command-line) and set anything
1323   # extra (e.g., #defines) that must accompany particular g++ options.
1324   if test -n "$enable_cxx_flags"; then
1325     for f in $enable_cxx_flags; do
1326       case "$f" in
1327         -fhonor-std)  ;;
1328         -*)  ;;
1329         *)   # and we're trying to pass /what/ exactly?
1330              AC_MSG_ERROR([compiler flags start with a -]) ;;
1331       esac
1332     done
1333   fi
1334
1335   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1336   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1337   AC_SUBST(EXTRA_CXX_FLAGS)
1338 ])
1339
1340
1341 dnl
1342 dnl Check for wide character support.  Has the same effect as the option
1343 dnl in gcc's configure, but in a form that autoconf can mess with.
1344 dnl
1345 dnl --enable-c-mbchar requests all the wchar_t stuff.
1346 dnl --disable-c-mbchar doesn't.
1347 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1348 dnl       Where DEFAULT is either `yes' or `no'.
1349 dnl
1350 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1351   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1352   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1353 ])
1354
1355
1356 dnl
1357 dnl Check to see if debugging libraries are to be built.
1358 dnl
1359 dnl --enable-libstdcxx-debug
1360 dnl builds a separate set of debugging libraries in addition to the
1361 dnl normal (shared, static) libstdc++ binaries.
1362 dnl
1363 dnl --disable-libstdcxx-debug
1364 dnl builds only one (non-debug) version of libstdc++.
1365 dnl
1366 dnl --enable-libstdcxx-debug-flags=FLAGS
1367 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1368 dnl
1369 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1370 dnl       Where DEFAULT is either `yes' or `no'.
1371 dnl
1372 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1373   AC_MSG_CHECKING([for additional debug build])
1374   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1375   AC_MSG_RESULT($enable_libstdcxx_debug)
1376   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1377 ])
1378
1379
1380 dnl
1381 dnl Check for explicit debug flags.
1382 dnl
1383 dnl --enable-libstdcxx-debug-flags='-O1'
1384 dnl is a general method for passing flags to be used when
1385 dnl building debug libraries with --enable-debug.
1386 dnl
1387 dnl --disable-libstdcxx-debug-flags does nothing.
1388 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1389 dnl       If "default flags" is an empty string, the effect is the same
1390 dnl       as --disable or --enable=no.
1391 dnl
1392 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1393   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1394     [pass compiler FLAGS when building debug library],
1395     [case "x$enable_libstdcxx_debug_flags" in
1396       xno | x)    enable_libstdcxx_debug_flags= ;;
1397       x-*)        ;;
1398       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1399      esac])
1400
1401   # Option parsed, now set things appropriately
1402   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1403   AC_SUBST(DEBUG_FLAGS)
1404
1405   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1406 ])
1407
1408
1409 dnl
1410 dnl Check if the user only wants a freestanding library implementation.
1411 dnl
1412 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1413 dnl installing only the headers required by [17.4.1.3] and the language
1414 dnl support library.  More than that will be built (to keep the Makefiles
1415 dnl conveniently clean), but not installed.
1416 dnl
1417 dnl Sets:
1418 dnl  is_hosted  (yes/no)
1419 dnl
1420 dnl Defines:
1421 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1422 dnl
1423 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1424   AC_ARG_ENABLE([hosted-libstdcxx],
1425     AC_HELP_STRING([--disable-hosted-libstdcxx],
1426                    [only build freestanding C++ runtime support]),,
1427     [case "$host" in
1428         arm*-*-symbianelf*)
1429             enable_hosted_libstdcxx=no
1430             ;;
1431         *)
1432             enable_hosted_libstdcxx=yes
1433             ;;
1434      esac])
1435   if test "$enable_hosted_libstdcxx" = no; then
1436     AC_MSG_NOTICE([Only freestanding libraries will be built])
1437     is_hosted=no
1438     hosted_define=0
1439     enable_abi_check=no
1440     enable_libstdcxx_pch=no
1441   else
1442     is_hosted=yes
1443     hosted_define=1
1444   fi
1445   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1446   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1447     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1448 ])
1449
1450
1451 dnl
1452 dnl Check for template specializations for the 'long long' type extension.
1453 dnl The result determines only whether 'long long' I/O is enabled; things
1454 dnl like numeric_limits<> specializations are always available.
1455 dnl
1456 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1457 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1458 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1459 dnl       Where DEFAULT is either `yes' or `no'.
1460 dnl
1461 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1462   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1463   if test $enable_long_long = yes; then
1464     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1465   fi
1466 ])
1467
1468
1469 dnl
1470 dnl Check to see if building and using a C++ precompiled header can be done.
1471 dnl
1472 dnl --enable-libstdcxx-pch=yes
1473 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1474 dnl may work, after some light-hearted attempts to puzzle out compiler
1475 dnl support, flip bits on in include/Makefile.am
1476 dnl
1477 dnl --disable-libstdcxx-pch
1478 dnl turns off attempts to use or build stdc++.h.gch.
1479 dnl
1480 dnl Substs:
1481 dnl  glibcxx_PCHFLAGS
1482 dnl
1483 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1484   AC_MSG_CHECKING([for enabled PCH])
1485   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1486   AC_MSG_RESULT([$enable_libstdcxx_pch])
1487
1488   if test $enable_libstdcxx_pch = yes; then
1489     AC_CACHE_CHECK([for compiler with PCH support],
1490       [glibcxx_cv_prog_CXX_pch],
1491       [ac_save_CXXFLAGS="$CXXFLAGS"
1492        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1493        AC_LANG_SAVE
1494        AC_LANG_CPLUSPLUS
1495        echo '#include <math.h>' > conftest.h
1496        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1497                           -o conftest.h.gch 1>&5 2>&1 &&
1498                 echo '#error "pch failed"' > conftest.h &&
1499           echo '#include "conftest.h"' > conftest.cc &&
1500                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1501        then
1502          glibcxx_cv_prog_CXX_pch=yes
1503        else
1504          glibcxx_cv_prog_CXX_pch=no
1505        fi
1506        rm -f conftest*
1507        CXXFLAGS=$ac_save_CXXFLAGS
1508        AC_LANG_RESTORE
1509       ])
1510     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1511   fi
1512
1513   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1514   if test $enable_libstdcxx_pch = yes; then
1515     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1516   else
1517     glibcxx_PCHFLAGS=""
1518   fi
1519   AC_SUBST(glibcxx_PCHFLAGS)
1520 ])
1521
1522
1523 dnl
1524 dnl Check for exception handling support.  If an explicit enable/disable
1525 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1526 dnl target may or may not support call frame exceptions.
1527 dnl
1528 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1529 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1530 dnl Neither one forces an attempt at detection.
1531 dnl
1532 dnl Defines:
1533 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1534 dnl
1535 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1536   AC_MSG_CHECKING([for exception model to use])
1537   AC_LANG_SAVE
1538   AC_LANG_CPLUSPLUS
1539   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1540     [force use of builtin_setjmp for exceptions],
1541     [permit yes|no|auto])
1542
1543   if test $enable_sjlj_exceptions = auto; then
1544     # Botheration.  Now we've got to detect the exception model.  Link tests
1545     # against libgcc.a are problematic since we've not been given proper -L
1546     # bits for single-tree newlib and libgloss.
1547     #
1548     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1549     cat > conftest.$ac_ext << EOF
1550 [#]line __oline__ "configure"
1551 struct S { ~S(); };
1552 void bar();
1553 void foo()
1554 {
1555   S s;
1556   bar();
1557 }
1558 EOF
1559     old_CXXFLAGS="$CXXFLAGS"
1560     CXXFLAGS=-S
1561     if AC_TRY_EVAL(ac_compile); then
1562       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1563         enable_sjlj_exceptions=yes
1564       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1565         enable_sjlj_exceptions=no
1566       fi
1567     fi
1568     CXXFLAGS="$old_CXXFLAGS"
1569     rm -f conftest*
1570   fi
1571
1572   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1573   # to two different models.
1574   case $enable_sjlj_exceptions in
1575     yes)
1576       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1577         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1578       ac_exception_model_name=sjlj
1579       ;;
1580     no)
1581       ac_exception_model_name="call frame"
1582       ;;
1583     *)
1584       AC_MSG_ERROR([unable to detect exception model])
1585       ;;
1586   esac
1587  AC_LANG_RESTORE
1588  AC_MSG_RESULT($ac_exception_model_name)
1589 ])
1590
1591
1592 dnl
1593 dnl Add version tags to symbols in shared library (or not), additionally
1594 dnl marking other symbols as private/local (or not).
1595 dnl
1596 dnl --enable-symvers=style adds a version script to the linker call when
1597 dnl       creating the shared library.  The choice of version script is
1598 dnl       controlled by 'style'.
1599 dnl --disable-symvers does not.
1600 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1601 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1602 dnl       choose a default style based on linker characteristics.  Passing
1603 dnl       'no' disables versioning.
1604 dnl
1605 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1606
1607 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1608   [enables symbol versioning of the shared library],
1609   [permit yes|no|gnu])
1610
1611 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1612 # don't know enough about $LD to do tricks...
1613 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1614 # FIXME  The following test is too strict, in theory.
1615 if test $enable_shared = no ||
1616         test "x$LD" = x ||
1617         test x$glibcxx_gnu_ld_version = x; then
1618   enable_symvers=no
1619 fi
1620
1621 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1622 if test $enable_symvers != no; then
1623   AC_MSG_CHECKING([for shared libgcc])
1624   ac_save_CFLAGS="$CFLAGS"
1625   CFLAGS=' -lgcc_s'
1626   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1627   CFLAGS="$ac_save_CFLAGS"
1628   if test $glibcxx_shared_libgcc = no; then
1629     cat > conftest.c <<EOF
1630 int main (void) { return 0; }
1631 EOF
1632 changequote(,)dnl
1633     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1634                              -shared -shared-libgcc -o conftest.so \
1635                              conftest.c -v 2>&1 >/dev/null \
1636                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1637 changequote([,])dnl
1638     rm -f conftest.c conftest.so
1639     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1640       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1641       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1642       CFLAGS="$ac_save_CFLAGS"
1643     fi
1644   fi
1645   AC_MSG_RESULT($glibcxx_shared_libgcc)
1646 fi
1647
1648 # For GNU ld, we need at least this version.  The format is described in
1649 # GLIBCXX_CHECK_LINKER_FEATURES above.
1650 glibcxx_min_gnu_ld_version=21400
1651 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1652
1653 # Check to see if unspecified "yes" value can win, given results above.
1654 # Change "yes" into either "no" or a style name.
1655 if test $enable_symvers = yes; then
1656   if test $with_gnu_ld = yes &&
1657      test $glibcxx_shared_libgcc = yes;
1658   then
1659     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1660       enable_symvers=gnu
1661     else
1662       # The right tools, the right setup, but too old.  Fallbacks?
1663       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1664       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1665       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1666       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1667       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1668         # Globbing fix is present, proper block support is not.
1669         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1670         dnl enable_symvers=???
1671         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1672         enable_symvers=no
1673       else
1674         # 2.11 or older.
1675         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1676         enable_symvers=no
1677       fi
1678     fi
1679   else
1680     # just fail for now
1681     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1682     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1683     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1684     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1685     enable_symvers=no
1686   fi
1687 fi
1688
1689 # Everything parsed; figure out what file to use.
1690 case $enable_symvers in
1691   no)
1692     SYMVER_MAP=config/linker-map.dummy
1693     ;;
1694   gnu)
1695     SYMVER_MAP=config/linker-map.gnu
1696     AC_DEFINE(_GLIBCXX_SYMVER)
1697     ;;
1698 esac
1699
1700 AC_SUBST(SYMVER_MAP)
1701 AC_SUBST(port_specific_symbol_files)
1702 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1703 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1704 ])
1705
1706
1707 dnl
1708 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1709 dnl We must stage the required headers so that they will be installed
1710 dnl with the library (unlike libgcc, the STL implementation is provided
1711 dnl solely within headers).  Since we must not inject random user-space
1712 dnl macro names into user-provided C++ code, we first stage into <file>-in
1713 dnl and process to <file> with an output command.  The reason for a two-
1714 dnl stage process here is to correctly handle $srcdir!=$objdir without
1715 dnl having to write complex code (the sed commands to clean the macro
1716 dnl namespace are complex and fragile enough as it is).  We must also
1717 dnl add a relative path so that -I- is supported properly.
1718 dnl
1719 dnl Substs:
1720 dnl  glibcxx_thread_h
1721 dnl
1722 dnl Defines:
1723 dnl  HAVE_GTHR_DEFAULT
1724 dnl
1725 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1726   AC_MSG_CHECKING([for thread model used by GCC])
1727   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1728   AC_MSG_RESULT([$target_thread_file])
1729
1730   if test $target_thread_file != single; then
1731     AC_DEFINE(HAVE_GTHR_DEFAULT)
1732   fi
1733
1734   glibcxx_thread_h=gthr-$target_thread_file.h
1735
1736   dnl Check for __GTHREADS define.
1737   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
1738   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
1739     enable_thread=yes
1740   else
1741    enable_thread=no
1742   fi
1743
1744   AC_SUBST(glibcxx_thread_h)
1745 ])
1746
1747
1748 # Check whether LC_MESSAGES is available in <locale.h>.
1749 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1750 #
1751 # This file file be copied and used freely without restrictions.  It can
1752 # be used in projects which are not available under the GNU Public License
1753 # but which still want to provide support for the GNU gettext functionality.
1754 # Please note that the actual code is *not* freely available.
1755
1756 # serial 1
1757 AC_DEFUN([AC_LC_MESSAGES], [
1758   AC_CHECK_HEADER(locale.h, [
1759     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1760       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1761        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1762     if test $ac_cv_val_LC_MESSAGES = yes; then
1763       AC_DEFINE(HAVE_LC_MESSAGES)
1764     fi
1765   ])
1766 ])
1767
1768
1769 sinclude([../libtool.m4])
1770 dnl The lines below arrange for aclocal not to bring an installed
1771 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1772 dnl add a definition of LIBTOOL to Makefile.in.
1773 ifelse(,,,[AC_SUBST(LIBTOOL)
1774 AC_DEFUN([AM_PROG_LIBTOOL])
1775 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1776 AC_DEFUN([AC_PROG_LD])
1777 ])
1778
1779 dnl vim:et:ts=2:sw=2