libquadmath/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GCC Quad-precision Math Library], 0.1,,[libquadmath])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
   9 #
  10 # You will slowly go insane if you do not grok the following fact:  when
  11 # building this library, the top-level /target/ becomes the library's /host/.
  12 #
  13 # configure then causes --target to default to --host, exactly like any
  14 # other package using autoconf.  Therefore, 'target' and 'host' will
  15 # always be the same.  This makes sense both for native and cross compilers
  16 # just think about it for a little while.  :-)
  17 #
  18 # Also, if this library is being configured as part of a cross compiler, the
  19 # top-level configure script will pass the "real" host as $with_cross_host.
  20 #
  21 # Do not delete or change the following two lines.  For why, see
  22 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  23 AC_CANONICAL_SYSTEM
  24 ACX_NONCANONICAL_TARGET
  25
  26 target_alias=${target_alias-$host_alias}
  27 AC_SUBST(target_alias)
  28
  29 AM_INIT_AUTOMAKE([1.9.0 foreign subdir-objects no-dist -Wall -Wno-override -Werror])
  30
  31 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  32 AC_ARG_ENABLE(version-specific-runtime-libs,
  33 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  34  [specify that runtime libraries should be installed in a compiler-specific directory]),
  35 [case "$enableval" in
  36  yes) version_specific_libs=yes ;;
  37  no)  version_specific_libs=no ;;
  38  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  39  esac],
  40 [version_specific_libs=no])
  41 AC_MSG_RESULT($version_specific_libs)
  42
  43 GCC_NO_EXECUTABLES
  44
  45 # See if makeinfo has been installed and is modern enough
  46 # that we can use it.
  47 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
  48                    [GNU texinfo.* \([0-9][0-9.]*\)],
  49                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
  50 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
  51
  52 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
  53
  54 # Configure libtool
  55 AM_PROG_LIBTOOL
  56 ACX_LT_HOST_FLAGS
  57 AC_SUBST(enable_shared)
  58 AC_SUBST(enable_static)
  59
  60 AM_MAINTAINER_MODE
  61 AM_ENABLE_MULTILIB(, ..)
  62
  63 AC_LANG_C
  64 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  65 # We must force CC to /not/ be precious variables; otherwise
  66 # the wrong, non-multilib-adjusted value will be used in multilibs.
  67 # As a side effect, we have to subst CFLAGS ourselves.
  68
  69 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  70 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  71 AC_PROG_CC
  72 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  73
  74 AC_SUBST(CFLAGS)
  75
  76 AM_PROG_CC_C_O
  77
  78 if test "x$GCC" != "xyes"; then
  79   AC_MSG_ERROR([libquadmath must be built with GCC])
  80 fi
  81 AC_PROG_CPP
  82
  83 # Calculate toolexeclibdir
  84 # Also toolexecdir, though it's only used in toolexeclibdir
  85 case ${version_specific_libs} in
  86   yes)
  87     # Need the gcc compiler version to know where to install libraries
  88     # and header files if --enable-version-specific-runtime-libs option
  89     # is selected.
  90     toolexecdir='$(libdir)/gcc/$(target_alias)'
  91     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  92     ;;
  93   no)
  94     if test -n "$with_cross_host" &&
  95        test x"$with_cross_host" != x"no"; then
  96       # Install a library built with a cross compiler in tooldir, not libdir.
  97       toolexecdir='$(exec_prefix)/$(target_alias)'
  98       toolexeclibdir='$(toolexecdir)/lib'
  99     else
 100       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 101       toolexeclibdir='$(libdir)'
 102     fi
 103     multi_os_directory=`$CC -print-multi-os-directory`
 104     case $multi_os_directory in
 105       .) ;; # Avoid trailing /.
 106       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 107     esac
 108     ;;
 109 esac
 110 AC_SUBST(toolexecdir)
 111 AC_SUBST(toolexeclibdir)
 112
 113 # If available, sqrtl and cbrtl speed up the calculation -
 114 # but they are not required
 115 if test x$gcc_no_link != xyes; then
 116   AC_CHECK_LIB([m],[sqrtl],[AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])])
 117   AC_CHECK_LIB([m],[cbrtl],[AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])])
 118 else
 119   if test "x$ac_cv_lib_m_sqrtl" = x""yes; then
 120     AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])
 121   fi
 122   if test "x$ac_cv_lib_m_cbrtl" = x""yes; then
 123     AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])
 124   fi
 125 fi
 126
 127 # Check for symbol versioning (copied from libssp).
 128 AC_MSG_CHECKING([whether symbol versioning is supported])
 129 if test x$gcc_no_link = xyes; then
 130   # If we cannot link, we cannot build shared libraries, so do not use
 131   # symbol versioning.
 132   quadmath_use_symver=no
 133 else
 134   save_LDFLAGS="$LDFLAGS"
 135   LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 136   cat > conftest.map <<EOF
 137 FOO_1.0 {
 138   global: *foo*; bar; local: *;
 139 };
 140 EOF
 141   AC_TRY_LINK([int foo;],[],[quadmath_use_symver=gnu],[quadmath_use_symver=no])
 142   if test x$quadmath_use_symver = xno; then
 143     case "$target_os" in
 144       solaris2*)
 145         LDFLAGS="$save_LDFLAGS"
 146         LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 147         # Sun ld cannot handle wildcards and treats all entries as undefined.
 148         cat > conftest.map <<EOF
 149 FOO_1.0 {
 150   global: foo; local: *;
 151 };
 152 EOF
 153         AC_TRY_LINK([int foo;],[],[quadmath_use_symver=sun],[quadmath_use_symver=no])
 154         ;;
 155     esac
 156   fi
 157   LDFLAGS="$save_LDFLAGS"
 158 fi
 159 AC_MSG_RESULT($quadmath_use_symver)
 160 AM_CONDITIONAL(LIBQUAD_USE_SYMVER, [test "x$quadmath_use_symver" != xno])
 161 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_GNU, [test "x$quadmath_use_symver" = xgnu])
 162 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_SUN, [test "x$quadmath_use_symver" = xsun])
 163
 164 AC_CACHE_CHECK([whether __float128 is supported], [libquad_cv_have_float128],
 165   [GCC_TRY_COMPILE_OR_LINK([
 166     typedef _Complex float __attribute__((mode(TC))) __complex128;
 167
 168     __float128 foo (__float128 x)
 169     {
 170
 171      __complex128 z1, z2;
 172
 173      z1 = x;
 174      z2 = x / 7.Q;
 175      z2 /= z1;
 176
 177      return (__float128) z2;
 178     }
 179
 180     __float128 bar (__float128 x)
 181     {
 182       return x * __builtin_huge_valq ();
 183     }
 184   ],[
 185     foo (1.2Q);
 186     bar (1.2Q);
 187   ],[
 188     libquad_cv_have_float128=yes
 189   ],[
 190     libquad_cv_have_float128=no
 191 ])])
 192 AM_CONDITIONAL(BUILD_LIBQUADMATH, [test "x$libquad_cv_have_float128" = xyes])
 193
 194 AC_CACHE_SAVE
 195
 196 if test ${multilib} = yes; then
 197   multilib_arg="--enable-multilib"
 198 else
 199   multilib_arg=
 200 fi
 201
 202
 203 # We would like our source tree to be readonly. However when releases or
 204 # pre-releases are generated, the flex/bison generated files as well as the
 205 # various formats of manuals need to be included along with the rest of the
 206 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 207 # just that.
 208 AC_MSG_CHECKING(generated-files-in-srcdir)
 209 AC_ARG_ENABLE(generated-files-in-srcdir,
 210 AS_HELP_STRING([--enable-generated-files-in-srcdir],
 211  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
 212 [case "$enableval" in
 213  yes) enable_generated_files_in_srcdir=yes ;;
 214  no)  enable_generated_files_in_srcdir=no ;;
 215  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 216  esac],
 217 [enable_generated_files_in_srcdir=no])
 218 AC_MSG_RESULT($enable_generated_files_in_srcdir)
 219 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
 220
 221
 222 AC_CONFIG_FILES(Makefile)
 223 AC_OUTPUT