libjava/testsuite/lib/libjava.exp

   1 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation
   2
   3 proc load_gcc_lib { filename } {
   4     global srcdir
   5     load_file $srcdir/../../gcc/testsuite/lib/$filename
   6 }
   7
   8 load_lib libgloss.exp
   9 load_gcc_lib target-libpath.exp
  10
  11 # GCJ_UNDER_TEST is the compiler under test.
  12
  13 global tmpdir
  14
  15 if ![info exists tmpdir] {
  16     set tmpdir "/tmp"
  17 }
  18
  19 # This is like `prune_warnings', but it also prunes away a warning
  20 # from the bytecode front end that we don't care about.
  21 proc libjava_prune_warnings {text} {
  22     set text [prune_warnings $text]
  23     set tlist [split $text \n]
  24     set len [llength $tlist]
  25     for {set i [expr {$len - 1}]} {$i >= 2} {incr i -1} {
  26         if {[string match "*unreachable bytecode*" [lindex $tlist $i]]} {
  27             # Delete this line, all other unreachable warnings and the previous
  28             # two lines containing the method and class.
  29             set j [expr {$i - 1}]
  30             while {[string match "*unreachable bytecode*" [lindex $tlist $j]]} {
  31                 incr j -1
  32             }
  33             incr j -1
  34             set tlist [lreplace $tlist $j $i]
  35             set i $j
  36         }
  37     }
  38     return [join $tlist \n]
  39 }
  40
  41 # This is like `target_compile' but it does some surgery to work
  42 # around stupid DejaGNU bugs.  In particular DejaGNU has very poor
  43 # quoting, so for instance a `$' will be re-evaluated at spawn time.
  44 # We don't want that.
  45 proc libjava_tcompile {source destfile type options} {
  46     # This strange-looking expression really does quote the `$'.
  47     regsub -all -- {\$} $source {\$} source
  48     regsub -all -- {\$} $destfile {\$} destfile
  49     return [target_compile $source $destfile $type $options]
  50 }
  51
  52 # Read an `xfail' file if it exists.  Returns a list of xfail tokens.
  53 proc libjava_read_xfail {file} {
  54     if {! [file exists $file]} {
  55         return ""
  56     }
  57     set fd [open $file r]
  58     set tokens [string trim [read $fd]]
  59     close $fd
  60     return $tokens
  61 }
  62
  63 # Find a particular executable.  FIXME: this relies on DejaGnu
  64 # internals.  These should probably be exposed in a better way.
  65 proc libjava_find_program {prog} {
  66     global tool_root_dir
  67
  68     set file [lookfor_file $tool_root_dir $prog]
  69     if { $file == "" } {
  70         set file [lookfor_file $tool_root_dir gcc/$prog];
  71     }
  72     if {$file == ""} {
  73         set file $prog
  74     }
  75     return $file
  76 }
  77
  78 # Find `jv-scan'.
  79 proc find_jvscan {} {
  80     return [libjava_find_program jv-scan]
  81 }
  82
  83 # Find `gcjh'.
  84 proc find_gcjh {} {
  85     return [libjava_find_program gcjh]
  86 }
  87
  88 proc find_javac {} {
  89     global SUN_JAVAC GCJ_UNDER_TEST env libgcj_jar
  90     # If JDK doesn't run on your platform but some other
  91     # JDK-compatible javac does, you may set SUN_JAVAC to point to it.
  92     # One of the most important properties of a SUN_JAVAC is that it
  93     # must create class-files even for classes that have not been
  94     # specified in the command line, but that were needed to compile
  95     # those that have.  For example, Pizza won't do it, but you can
  96     # use `kaffe sun.tools.javac.Main', if you have Sun's classes.zip
  97     # in the kaffe's default search path.
  98     if {![info exists SUN_JAVAC]} {
  99         if {[info exists env(SUN_JAVAC)]} {
 100             set SUN_JAVAC $env(SUN_JAVAC)
 101         } else {
 102             set SUN_JAVAC "$GCJ_UNDER_TEST -C -I$libgcj_jar"
 103         }
 104     }
 105     return $SUN_JAVAC
 106 }
 107
 108 proc bytecompile_file { file objdir {classpath {}} } {
 109     global env
 110     set dirname [file dirname $file]
 111
 112     set javac [find_javac]
 113     if {$classpath != ""} then {
 114         set env(CLASSPATH) $classpath
 115     }
 116     set here [pwd]
 117     cd $dirname
 118     send_log "byte compile: $javac -g [list $file] -d $objdir 2>@ stdout\n"
 119     if {[catch {
 120         set q [eval exec "$javac -g [list $file] -d $objdir 2>@ stdout"]
 121     } msg]} then {
 122         send_log "couldn't compile $file: $msg\n"
 123         set r 0
 124     } else {
 125         set r 1
 126     }
 127     cd $here
 128     return $r
 129 }
 130
 131 set libjava_initialized 0
 132
 133 #
 134 # Build the status wrapper library as needed.
 135 #
 136 proc libjava_init { args } {
 137     global wrapper_file;
 138     global wrap_compile_flags;
 139     global libjava_initialized libjava_uses_threads
 140     global GCJ_UNDER_TEST
 141     global TOOL_EXECUTABLE
 142     global env objdir
 143     global env libgcj_jar
 144     global tool_root_dir
 145     global libjava_libgcc_s_path
 146     global target_triplet
 147
 148     # We set LC_ALL and LANG to C so that we get the same error messages as expected.
 149     setenv LC_ALL C
 150     setenv LANG C
 151
 152     if { $libjava_initialized == 1 } { return; }
 153
 154     if ![info exists GCJ_UNDER_TEST] {
 155         if [info exists TOOL_EXECUTABLE] {
 156             set GCJ_UNDER_TEST $TOOL_EXECUTABLE;
 157         } else {
 158             if [info exists env(GCJ)] {
 159                 set GCJ_UNDER_TEST $env(GCJ)
 160             } else {
 161                 set GCJ_UNDER_TEST "[find_gcj]"
 162             }
 163         }
 164     }
 165
 166     # Find the libgcj jar file.
 167     set libgcj_jar [glob $objdir/../libgcj-*.jar]
 168     verbose "jar file is $libgcj_jar"
 169
 170     # FIXME: This finds libgcj.spec for the default multilib.
 171     # If thread models differ between multilibs, this has to be moved
 172     # to libjava_arguments
 173     set specdir [libjava_find_spec]
 174
 175     # The -B is so we find libgcj.spec.
 176     set text [eval exec "$GCJ_UNDER_TEST -B$specdir -v 2>@ stdout"]
 177     regexp -- "Thread model: (\[^\n\]+)\n" $text ignore model
 178     set libjava_uses_threads [expr {! ($model == "no"
 179                                        || $model == "none"
 180                                        || $model == "single")}]
 181
 182     # Always set encoding used by gcj.
 183     append GCJ_UNDER_TEST " --encoding=UTF-8"
 184
 185     set wrapper_file "";
 186     set wrap_compile_flags "";
 187     if [target_info exists needs_status_wrapper] {
 188         set result [build_wrapper "testglue.o"];
 189         if { $result != "" } {
 190             set wrapper_file [lindex $result 0];
 191             set wrap_compile_flags [lindex $result 1];
 192         } else {
 193             warning "Status wrapper failed to build."
 194         }
 195     }
 196
 197     # Finally, add the gcc build directory so that we can find the
 198     # shared libgcc.  This, like much of dejagnu, is hideous.
 199     set libjava_libgcc_s_path {}
 200
 201     if { [string match "powerpc-*-darwin*" $target_triplet] } {
 202         set so_extension "dylib"
 203     } else {
 204         set so_extension "so"
 205     }
 206     set gccdir [lookfor_file $tool_root_dir gcc/libgcc_s.${so_extension}]
 207     if {$gccdir != ""} {
 208         set gccdir [file dirname $gccdir]
 209         lappend libjava_libgcc_s_path $gccdir
 210         verbose "libjava_libgcc_s_path = $libjava_libgcc_s_path"
 211         set compiler ${gccdir}/xgcc
 212         if { [is_remote host] == 0 && [which $compiler] != 0 } {
 213             foreach i "[exec $compiler --print-multi-lib]" {
 214                 set mldir ""
 215                 regexp -- "\[a-z0-9=/\.-\]*;" $i mldir
 216                 set mldir [string trimright $mldir "\;@"]
 217                 if { "$mldir" == "." } {
 218                     continue
 219                 }
 220                 if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.${so_extension}.*]] >= 1 } {
 221                     lappend libjava_libgcc_s_path "${gccdir}/${mldir}"
 222                 }
 223             }
 224         }
 225     }
 226
 227     set libjava_initialized 1
 228 }
 229
 230 # Find a library.  We know where libtool puts the actual libraries,
 231 # and we look there.  The implementation is fairly hacky.  We can't
 232 # compile with -nodefaultlibs, because that will also eliminate the
 233 # system libraries we need.  In order to have gcj still work, it must
 234 # find the appropriate libraries so we must add -L options for their
 235 # paths.  However we can't simply use those libraries; we still need
 236 # libtool for linking.
 237 # Don't return the the lib${name}.la files here, since this causes the
 238 # libraries to be linked twice: once as lib${name}.so/dylib and another time
 239 # via gcj's implicit -l${name}.  This is both unnecessary and causes the
 240 # Solaris ld to warn: attempted multiple inclusion of file.  This warning
 241 # is not ignored by the dejagnu framework and cannot be disabled.
 242 proc libjava_find_lib {dir name} {
 243     global base_dir
 244     set gp [get_multilibs]
 245     foreach extension {so dll a} {
 246         foreach sub {.libs _libs} {
 247             if {$gp != ""} {
 248                 if {[file exists $gp/$dir/$sub/lib${name}.${extension}]} then {
 249                     # Just return the `-L' option.  The library itself
 250                     # will be picked up via the spec file.
 251                     return "-L$gp/$dir/$sub"
 252                 }
 253             }
 254             # Just return the `-L' option.  The library itself will be
 255             # picked up via the spec file.
 256             set lib [findfile \
 257                        $base_dir/../../$dir/$sub/lib${name}.${extension} \
 258                        "-L$base_dir/../../$dir/$sub" \
 259                        ""]
 260             if {$lib != ""} {
 261                 return $lib
 262             }
 263         }
 264     }
 265     return ""
 266 }
 267
 268 # Find libgcj.spec.  We need to use the file corresponding to the multilib
 269 # under test since they might differ.  Append a trailing slash since this
 270 # is used with -B.
 271 proc libjava_find_spec {} {
 272     global objdir
 273     return "$objdir/../"
 274 }
 275
 276 # Find `gij'.  Return empty string if not found.
 277 proc libjava_find_gij {} {
 278     global base_dir objdir
 279
 280     if {! [file exists $objdir/../gij]} {
 281         return ""
 282     }
 283     return $objdir/../gij
 284 }
 285
 286 # Remove a bunch of files.
 287 proc gcj_cleanup {args} {
 288     foreach file $args {
 289         if {[string match *.o $file]} {
 290             verbose "removing [file rootname $file].lo"
 291             file delete -force [file rootname $file].lo
 292         }
 293         file delete -force -- $file
 294         verbose "removing $file"
 295     }
 296     # It is simplest to do this instead of trying to figure out what
 297     # bits in .libs ought to be removed.
 298     catch {system "rm -rf .libs"}
 299 }
 300
 301 # Compute arguments needed for compiler.  MODE is a libtool mode:
 302 # either compile or link.
 303 proc libjava_arguments {{mode compile}} {
 304     global base_dir
 305     global LIBJAVA
 306     global srcdir subdir objdir
 307     global TOOL_OPTIONS
 308     global GCJ_UNDER_TEST
 309     global tmpdir
 310     global runtests
 311     global env
 312     global tool_root_dir
 313     global libgcj_jar
 314     global libjava_libgcc_s_path
 315     global libjava_ld_library_path
 316     global ld_library_path
 317     global target_triplet
 318
 319     if [info exists LIBJAVA] {
 320         set libjava $LIBJAVA;
 321     } else {
 322         set libjava [libjava_find_lib libjava gcj]
 323     }
 324
 325     verbose "using LIBJAVA = $libjava" 2
 326     set args ""
 327
 328     # Basically we want to build up a colon separated path list from
 329     # the value of $libjava.
 330
 331     set lpath "."
 332     foreach dir [list $libjava] {
 333         foreach item [split $dir " "] {
 334             switch -glob -- $item {
 335                 "-L*" {
 336                     lappend lpath [string range $item 2 end]
 337                 }
 338             }
 339         }
 340     }
 341
 342     set lpath [concat $lpath $libjava_libgcc_s_path]
 343     verbose "lpath = $lpath ; libgcc_s_path = $libjava_libgcc_s_path"
 344     set ld_library_path [join $lpath :]
 345     set libjava_ld_library_path "$ld_library_path"
 346
 347     # That's enough to make things work for the normal case.
 348     # If we wanted to handle an arbitrary value of libjava,
 349     # then we'd have to do a lot more work.
 350
 351     set_ld_library_path_env_vars
 352     if [info exists env(LD_LIBRARY_PATH)] {
 353         verbose "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
 354     }
 355
 356     # Determine CLASSPATH separator
 357     if { [string match "i?86-pc-mingw32*" $target_triplet] } {
 358         set sep ";"
 359     } else {
 360         set sep ":"
 361     }
 362
 363     # Set the CLASSPATH environment variable
 364     global env
 365     set env(CLASSPATH) \
 366         [join [list . $srcdir/$subdir $objdir $libgcj_jar] $sep]
 367     verbose "CLASSPATH is $env(CLASSPATH)"
 368
 369     if {$mode == "link"} {
 370         global wrapper_file wrap_compile_flags
 371         lappend args "additional_flags=$wrap_compile_flags"
 372         lappend args "libs=$wrapper_file"
 373         lappend args "libs=$libjava"
 374         lappend args debug
 375     }
 376
 377     if { [target_info needs_status_wrapper]!="" && [info exists gluefile] } {
 378         lappend args "libs=${gluefile}"
 379         lappend args "ldflags=$wrap_flags"
 380     }
 381
 382     if [info exists TOOL_OPTIONS] {
 383         lappend args "additional_flags=$TOOL_OPTIONS"
 384     }
 385
 386     # Determine libgcj.spec corresponding to multilib under test.
 387     set specdir [libjava_find_spec]
 388
 389     # Search for libtool.  We need it to link.
 390     set found_compiler 0
 391     set d [absolute $objdir]
 392     foreach x {. .. ../.. ../../..} {
 393         if {[file exists $d/$x/libtool]} then {
 394             # We have to run silently to avoid DejaGNU lossage.
 395             lappend args \
 396               "compiler=$d/$x/libtool --silent --tag=GCJ --mode=$mode $GCJ_UNDER_TEST -B$specdir"
 397             set found_compiler 1
 398             break
 399         }
 400     }
 401     if {! $found_compiler} {
 402         # Append -B$specdir so that we find libgcj.spec before it
 403         # is installed.
 404         lappend args "compiler=$GCJ_UNDER_TEST -B$specdir"
 405     }
 406
 407     # Avoid libtool wrapper scripts when possible.
 408     # but not if libtool warnings results in FAILs
 409     if {$mode == "link"} {
 410         if {! [istarget "*-*-cygwin*"] && ! [istarget "*-*-mingw*"] } {
 411             lappend args "additional_flags=-no-install"
 412         }
 413         if { [istarget "*-*-darwin*"] } {
 414             lappend args "additional_flags=-bind_at_load"
 415             lappend args "additional_flags=-multiply_defined suppress"
 416         }
 417     }
 418
 419     return $args
 420 }
 421
 422 # Link a bunch of objects into a program.  MAIN is the name of the
 423 # class holding `main'.  Return 0 on failure.
 424 proc gcj_link {program main files {options {}}} {
 425     set arguments [libjava_arguments link]
 426     if {[llength $options]} {
 427         eval lappend arguments $options
 428     }
 429     lappend arguments "additional_flags=--main=$main"
 430     set x [libjava_prune_warnings \
 431              [libjava_tcompile $files $program executable $arguments]]
 432     if {$x != ""} {
 433         verbose "link failure: $x" 2
 434         fail "linking $program"
 435         setup_xfail "*-*-*"
 436         fail "running $program"
 437         return 0
 438     }
 439
 440     pass "linking $program"
 441     return 1
 442 }
 443
 444 # Invoke the program and see what happens.  Return 0 on failure.
 445 proc gcj_invoke {program expectFile ld_library_additions} {
 446   global env
 447   global libjava_ld_library_path
 448   global ld_library_path
 449
 450   set ld_library_path "$libjava_ld_library_path"
 451   if {[llength $ld_library_additions] > 0} {
 452     append ld_library_path :[join $ld_library_additions :]
 453   }
 454
 455   set_ld_library_path_env_vars
 456   if [info exists env(LD_LIBRARY_PATH)] {
 457     verbose "LD_LIBRARY_PATH=$env(LD_LIBRARY_PATH)"
 458   }
 459
 460   set result [libjava_load ./$program]
 461   set status [lindex $result 0]
 462   set output [lindex $result 1]
 463
 464   # Restore setting
 465   restore_ld_library_path_env_vars
 466
 467   if {$status != "pass"} {
 468     verbose "got $output"
 469     fail "$program run"
 470     untested "$program output"
 471     return 0
 472   }
 473
 474   set id [open $expectFile r]
 475   set expected [read $id]
 476   close $id
 477
 478   if {! [string compare $output $expected]} {
 479     pass "$program output"
 480     return 1
 481   } else {
 482     fail "$program output"
 483     return 0
 484   }
 485 }
 486
 487 # Invoke a program and check its output.  EXECUTABLE is the program;
 488 # ARGS are the arguments to the program.  Returns 1 if tests passed
 489 # (or things were left untested), 0 otherwise.
 490 proc libjava_invoke {errname testName optName executable inpfile resultfile
 491                       ld_library_additions args} {
 492     global env
 493     global libjava_ld_library_path
 494     global ld_library_path
 495
 496     set ld_library_path "$libjava_ld_library_path"
 497     if {[llength $ld_library_additions] > 0} {
 498         append ld_library_path :[join $ld_library_additions :]
 499     }
 500
 501     set_ld_library_path_env_vars
 502     if [info exists env(LD_LIBRARY_PATH)] {
 503         verbose "LD_LIBRARY_PATH=$env(LD_LIBRARY_PATH)"
 504     }
 505
 506     upvar $optName opts
 507
 508     if {[info exists opts(no-exec)]} {
 509         if {[info exists opts(need-threads)]} {
 510             # This means we wanted to try to run it but we couldn't
 511             # because threads aren't supported.  So we have to
 512             # generate an `untested'.
 513             untested "$errname execution - $testName"
 514             untested "$errname output - $testName"
 515         }
 516         return 1
 517     }
 518
 519     set result [libjava_load $executable $args "$inpfile"]
 520     set status [lindex $result 0]
 521     set output [lindex $result 1]
 522
 523     # Restore LD_LIBRARY_PATH setting.
 524     restore_ld_library_path_env_vars
 525
 526     if {[info exists opts(xfail-exec)]} then {
 527         setup_xfail *-*-*
 528     }
 529     $status "$errname execution - $testName"
 530     if { $status != "pass" } {
 531         untested "$errname output - $testName"
 532         return 0
 533     }
 534
 535     verbose "resultfile is $resultfile"
 536     set id [open $resultfile r]
 537     set expected ""
 538     append expected [read $id]
 539     regsub -all "\r" "$output" "" output
 540     regsub "\n*$" $expected "" expected
 541     regsub "\n*$" $output "" output
 542     regsub "^\n*" $expected "" expected
 543     regsub "^\n*" $output "" output
 544     regsub -all "\[ \t\]\[ \t\]*" $expected " " expected
 545     regsub -all "\[ \t\]*\n\n*" $expected "\n" expected
 546     regsub -all "\[ \t\]\[ \t\]*" $output " " output
 547     regsub -all "\[ \t\]*\n\n*" $output "\n" output
 548     verbose "expected is $expected"
 549     verbose "actual is $output"
 550     set passed 0
 551     if {[info exists opts(regexp_match)]} {
 552         if [regexp $expected $output] {
 553             set passed 1
 554         }
 555     } else {
 556         if { $expected == $output } {
 557             set passed 1
 558         }
 559     }
 560     if {[info exists opts(xfail-output)]} {
 561         setup_xfail *-*-*
 562     }
 563     if { $passed == 1 } {
 564         pass "$errname output - $testName"
 565     } else {
 566         fail "$errname output - $testName"
 567     }
 568     close $id
 569
 570     return $passed
 571 }
 572
 573 #
 574 # Run the test specified by srcfile and resultfile. compile_args and
 575 # exec_args are options telling this proc how to work.
 576 #
 577 proc test_libjava_from_source { options srcfile compile_args inpfile resultfile exec_args } {
 578     global base_dir
 579     global srcdir subdir objdir
 580     global TOOL_OPTIONS
 581     global GCJ_UNDER_TEST
 582     global tmpdir
 583     global runtests
 584
 585     # Make opts into an array.
 586     set opts(_) x
 587     unset opts(_)
 588     foreach item $exec_args {
 589         set opts($item) x
 590     }
 591
 592     # If we need threads and we don't have them then set the `no-exec'
 593     # flag.  This is case is also handled specially later.
 594     if {[info exists opts(need-threads)]} {
 595         global libjava_uses_threads
 596         if {! $libjava_uses_threads} {
 597             set opts(no-exec) x
 598         }
 599     }
 600
 601     set errname [file rootname [file tail $srcfile]]
 602     if {! [runtest_file_p $runtests $errname]} {
 603         return
 604     }
 605
 606     if {[info exists opts(no-link)]} {
 607         set mode compile
 608     } else {
 609         set mode link
 610     }
 611     set args [libjava_arguments $mode]
 612     if {! [info exists opts(no-link)]} {
 613         # Add the --main flag
 614         lappend args "additional_flags=--main=[file rootname [file tail $srcfile]]"
 615         if { $compile_args != "" } {
 616             lappend args "additional_flags=$compile_args"
 617         }
 618     }
 619
 620     regsub "^.*/(\[^/.\]+)\[.\]\[^/]*$" "$srcfile" "\\1" out
 621     set executable "${objdir}/$out"
 622     if {[info exists opts(no-link)]} {
 623         append executable ".o"
 624         set target object
 625     } else {
 626         # DOS/win32 targets default to .exe if no suffix is given
 627         # We then try to delete a file that doesn't exist.  It is
 628         # simpler to add the suffix everywhere.
 629         append executable ".exe"
 630         set target executable
 631     }
 632     if { $compile_args != "" } {
 633         set errname "$errname $compile_args"
 634     }
 635
 636     set removeList [list $executable]
 637
 638     set x [libjava_prune_warnings \
 639              [libjava_tcompile $srcfile "$executable" $target $args]]
 640     if {[info exists opts(xfail-gcj)]} {
 641         setup_xfail *-*-*
 642     }
 643     if { $x != "" } {
 644         verbose "target_compile failed: $x" 2
 645
 646         if {[info exists opts(shouldfail)]} {
 647             pass "$errname compilation from source"
 648             eval gcj_cleanup $removeList
 649             return
 650         }
 651
 652         fail "$errname compilation from source"
 653         if {[info exists opts(xfail-gcj)]
 654             || ! [info exists opts(no-exec)]
 655             || [info exists opts(need-threads)]} {
 656             untested "$errname execution from source compiled test"
 657             untested "$errname output from source compiled test"
 658         }
 659         return
 660     }
 661     if {[info exists opts(shouldfail)]} {
 662         fail "$errname compilation from source"
 663         return
 664     }
 665     pass "$errname compilation from source"
 666
 667     # Set up the options the way they are expected by libjava_invoke.
 668     if {[info exists opts(xfail-source-output)]} {
 669         set opts(xfail-output) x
 670     }
 671     if {[libjava_invoke $errname "source compiled test" opts $executable \
 672            $inpfile $resultfile ""]} {
 673         # Everything ok, so clean up.
 674         eval gcj_cleanup $removeList
 675     }
 676 }
 677
 678 #
 679 # Run the test specified by srcfile and resultfile. compile_args and
 680 # exec_args are options telling this proc how to work.
 681 #
 682 proc test_libjava_from_javac { options srcfile compile_args inpfile resultfile exec_args } {
 683     global base_dir
 684     global srcdir subdir objdir
 685     global TOOL_OPTIONS
 686     global GCJ_UNDER_TEST
 687     global tmpdir
 688     global runtests
 689     global INTERPRETER
 690
 691     # Make opts into an array.
 692     set opts(_) x
 693     unset opts(_)
 694     foreach item $exec_args {
 695         set opts($item) x
 696     }
 697
 698     # If we need threads and we don't have them then set the `no-exec'
 699     # flag.  This is case is also handled specially later.
 700     if {[info exists opts(need-threads)]} {
 701         global libjava_uses_threads
 702         if {! $libjava_uses_threads} {
 703             set opts(no-exec) x
 704         }
 705     }
 706     set errname [file rootname [file tail $srcfile]]
 707     if {! [runtest_file_p $runtests $errname]} {
 708         return
 709     }
 710
 711     # bytecompile files with Sun's compiler for now.
 712     set bc_ok [bytecompile_file $srcfile $objdir]
 713
 714     set javac [find_javac]
 715     # This is an ugly heuristic but it will have to do.
 716     if {[string match *gcj* $javac]} {
 717         set tag gcjC
 718     } else {
 719         set tag javac
 720     }
 721     if {[info exists opts(xfail-$tag)]} {
 722         setup_xfail *-*-*
 723     }
 724     if {! $bc_ok} then {
 725         if {[info exists opts(shouldfail)]} {
 726             pass "$errname byte compilation"
 727             return
 728         }
 729         fail "$errname byte compilation"
 730         untested "$errname compilation from bytecode"
 731         if {! [info exists opts(no-exec)]
 732             || [info exists opts(need-threads)]} {
 733             untested "$errname execution from bytecode->native test"
 734             untested "$errname output from bytecode->native test"
 735         }
 736         return
 737     }
 738     if {[info exists opts(shouldfail)]} {
 739         fail "$errname byte compilation"
 740         return
 741     }
 742     pass "$errname byte compilation"
 743
 744     set removeList {}
 745
 746     # Find name to use for --main, and name of all class files.
 747     set jvscan [find_jvscan]
 748     verbose "jvscan is $jvscan"
 749     set main_name [string trim \
 750                      [libjava_prune_warnings \
 751                         [lindex [local_exec "$jvscan --encoding=UTF-8 $srcfile --print-main" "" "" 300] 1]]]
 752     verbose "main name is $main_name"
 753     set class_out [string trim \
 754                      [libjava_prune_warnings \
 755                         [lindex [local_exec "$jvscan --encoding=UTF-8 $srcfile --list-class" "" "" 300] 1]]]
 756     verbose "class list is $class_out"
 757
 758     if {[string match "*parse error*" $main_name]
 759         || [string match "*parse error*" $class_out]} {
 760         untested "$errname compilation from bytecode"
 761         if {! [info exists opts(no-exec)]
 762             || [info exists opts(need-threads)]} {
 763             untested "$errname execution from bytecode->native test"
 764             untested "$errname output from bytecode->native test"
 765         }
 766         return
 767     }
 768
 769     # Turn "a b" into "a.class b.class".
 770     # Also, turn "foo.bar" into "foo/bar.class".
 771     set class_files {}
 772     foreach file [split [string trim $class_out]] {
 773         set file [join [split $file .] /]
 774         lappend class_files $objdir/$file.class
 775     }
 776
 777     eval lappend removeList $class_files
 778
 779     # Usually it is an error for a test program not to have a `main'
 780     # method.  However, for no-exec tests it is ok.  Treat no-link
 781     # like no-exec here.
 782     if {[info exists opts(no-link)]} {
 783         set opts(no-exec) x
 784     }
 785     set largs {}
 786
 787     if {[info exists opts(no-exec)]} {
 788         set type object
 789         set mode compile
 790     } elseif {$main_name == ""} {
 791         perror "No `main' given in program $errname"
 792         return
 793     } else {
 794         set type executable
 795         lappend largs "additional_flags=--main=$main_name"
 796         # DOS/win32 targets default to .exe if no suffix is given
 797         # We then try to delete a file that doesn't exist.  It is
 798         # simpler to add the suffix everywhere.
 799         set executable "${objdir}/${main_name}.exe"
 800         set mode link
 801     }
 802
 803     # We purposely ignore errors here; we still want to run the other
 804     # appropriate tests.
 805     set gij [libjava_find_gij]
 806     # libjava_find_gij will return "" if it couldn't find the
 807     # program; in this case we want to skip the test.
 808     if {$INTERPRETER == "yes" && $gij != ""} {
 809         libjava_invoke $errname "gij test" opts $gij \
 810           $inpfile $resultfile "" $main_name
 811     }
 812
 813     # Initial arguments.
 814     set args [libjava_arguments $mode]
 815     eval lappend args $largs
 816
 817     if { $compile_args != "" } {
 818         lappend args "additional_flags=$compile_args"
 819     }
 820
 821     if { $compile_args != "" } {
 822         set errname "$errname $compile_args"
 823     }
 824
 825     verbose "compilation command = $args" 2
 826     # When compiling and not linking, we have to build each .o
 827     # separately.  We do this because DejaGNU's target_compile won't
 828     # accept an empty "destfile" argument when the mode is "compile".
 829     if {$mode == "compile"} {
 830         foreach c_file $class_files {
 831             set executable [file rootname [file tail $c_file]].o
 832             # Don't write files which contain $ chars.
 833             regsub -all "\\$" $executable "\^" executable
 834             set x [libjava_prune_warnings \
 835                      [libjava_tcompile '$c_file' "$executable" $type $args]]
 836             lappend removeList $executable
 837             if {$x != ""} {
 838                 break
 839             }
 840         }
 841     } else {
 842         # This is so evil: we de-listify CLASS_FILES so that we can
 843         # turn around and quote the `$' in it for the shell.  I really
 844         # hate DejaGNU.  It is so !@#$!@# unpredictable.
 845         set hack ""
 846         foreach stupid $class_files {
 847             set hack "$hack $stupid"
 848         }
 849         lappend removeList $executable
 850         set x [libjava_prune_warnings \
 851                  [libjava_tcompile $hack "$executable" $type $args]]
 852     }
 853     if {[info exists opts(xfail-byte)]} {
 854         setup_xfail *-*-*
 855     }
 856     if { $x != "" } {
 857         verbose "target_compile failed: $x" 2
 858         fail "$errname compilation from bytecode"
 859         if {! [info exists opts(no-exec)]
 860             || [info exists opts(need-threads)]} {
 861             untested "$errname execution from bytecode->native test"
 862             untested "$errname output from bytecode->native test"
 863         }
 864         return;
 865     }
 866     pass "$errname compilation from bytecode"
 867
 868     # Set up the options the way they are expected by libjava_invoke.
 869     if {[info exists opts(xfail-byte-output)]} {
 870         set opts(xfail-output) x
 871     }
 872     if {[libjava_invoke $errname "bytecode->native test" opts $executable \
 873            $inpfile $resultfile ""]} {
 874         # Everything ok, so clean up.
 875         eval gcj_cleanup $removeList
 876     }
 877 }
 878
 879 #
 880 # Run the test specified by srcfile and resultfile. compile_args and
 881 # exec_args are options telling this proc how to work.
 882 #   `no-link'     don't try to link the program
 883 #   `no-exec'     don't try to run the test
 884 #   `xfail-gcj'   compilation from source will fail
 885 #   `xfail-javac' compilation with javac will fail
 886 #   `xfail-gcjC'  compilation with gcj -C will fail
 887 #   `shouldfail'  compilation from source is supposed to fail
 888 #                 This is different from xfail, which marks a known
 889 #                 failure that we just haven't fixed.
 890 #                 A compilation marked this way should fail with any
 891 #                 front end.
 892 #   `xfail-byte'  compilation from bytecode will fail
 893 #   `xfail-exec'  exec will fail
 894 #   `xfail-output'
 895 #                 output will be wrong
 896 #   `xfail-byte-output'
 897 #                 output will be wrong when compiled from bytecode
 898 #   `xfail-source-output'
 899 #                 output will be wrong when compiled from source code
 900 #   `need-threads'
 901 #                 test relies on thread support
 902 #
 903 proc test_libjava { options srcfile compile_args inpfile resultfile exec_args } {
 904     test_libjava_from_source $options $srcfile $compile_args $inpfile $resultfile $exec_args
 905     test_libjava_from_javac $options $srcfile $compile_args $inpfile $resultfile $exec_args
 906  }
 907
 908 #
 909 # libjava_version -- extract and print the version number of libjavap
 910 #
 911 proc default_libjava_version {} {
 912 }
 913
 914 proc default_libjava_start { } {
 915 }
 916
 917 # Local Variables:
 918 # tcl-indent-level:4
 919 # End: