libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -n "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66 dnl See if the user has requested runtime debugging.
  67 AC_ARG_ENABLE(libgcj-debug,
  68 [  --enable-libgcj-debug   enable runtime debugging code],
  69   if test "$enable_libgcj_debug" = yes; then
  70      AC_DEFINE(DEBUG)
  71   fi)
  72
  73 dnl See if the user has the interpreter included.
  74 AC_ARG_ENABLE(interpreter,
  75 [  --enable-interpreter    enable interpreter],
  76   if test "$enable_interpreter" = yes; then
  77     # This can also be set in configure.host.
  78     libgcj_interpreter=yes
  79   elif test "$enable_interpreter" = no; then
  80     libgcj_interpreter=no
  81   fi)
  82
  83 if test "$libgcj_interpreter" = yes; then
  84    AC_DEFINE(INTERPRETER)
  85 fi
  86
  87 EXCEPTIONSPEC=
  88 dnl See if we should use setjmp/longjmp exceptions
  89 AC_ARG_ENABLE(sjlj-exceptions,
  90 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  91   if test "$enable_sjlj_exceptions" = yes; then
  92      # This can be set in configure.host.
  93      libgcj_sjlj=yes
  94   fi)
  95
  96 if test "$libgcj_sjlj" = yes; then
  97    EXCEPTIONSPEC="-fsjlj-exceptions"
  98    AC_DEFINE(SJLJ_EXCEPTIONS)
  99 fi
 100
 101 FORCELIBGCCSPEC=
 102 dnl Work around libgcc design flaw.
 103 if test "$ac_cv_prog_gnu_ld" = yes; then
 104    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 105 fi
 106
 107 AC_MSG_CHECKING([for data_start])
 108 LIBDATASTARTSPEC=
 109 NEEDS_DATA_START=
 110 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 111   [AC_MSG_RESULT(found it)],
 112   [LIBDATASTARTSPEC="-u data_start -lgcjdata"
 113    NEEDS_DATA_START=yes
 114    AC_MSG_RESULT(missing)])
 115 AC_SUBST(LIBDATASTARTSPEC)
 116
 117 dnl See if the user wants to disable java.net.  This is the mildly
 118 dnl ugly way that we admit that target-side configuration sucks.
 119 AC_ARG_ENABLE(java-net,
 120 [  --disable-java-net      disable java.net])
 121
 122 dnl Whether java.net is built by default can depend on the target.
 123 if test -n "$enable_java_net"; then
 124    enable_java_net=${enable_java_net_default-yes}
 125 fi
 126 if test "$enable_java_net" = no; then
 127    AC_DEFINE(DISABLE_JAVA_NET)
 128 fi
 129
 130 dnl See if the user wants to disable JVMPI support.
 131 AC_ARG_ENABLE(jvmpi,
 132 [  --disable-jvmpi         disable JVMPI support])
 133
 134 if test "$enable_jvmpi" != no; then
 135     AC_DEFINE(ENABLE_JVMPI)
 136 fi
 137
 138 dnl If the target is an eCos system, use the appropriate eCos
 139 dnl I/O routines.
 140 dnl FIXME: this should not be a local option but a global target
 141 dnl system; at present there is no eCos target.
 142 TARGET_ECOS="no"
 143 AC_ARG_WITH(ecos,
 144 [  --with-ecos             enable runtime eCos target support],
 145 TARGET_ECOS="$with_ecos"
 146 )
 147
 148 case "$TARGET_ECOS" in
 149    no)
 150       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 151       PROCESS=${PROCESS-Posix}
 152       ;;
 153    *)
 154       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 155       PROCESS=Ecos
 156       AC_DEFINE(ECOS)
 157       ;;
 158 esac
 159
 160 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 161 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 162 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 163 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 164
 165
 166 dnl These may not be defined in a non-ANS conformant embedded system.
 167 dnl FIXME: Should these case a runtime exception in that case?
 168 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 169 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 170
 171 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 172 dnl to create the link will fail.
 173 test -d java || mkdir java
 174 test -d java/io || mkdir java/io
 175 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 176
 177 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 178 test -d java/lang || mkdir java/lang
 179 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 180 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 181
 182 SYSTEMSPEC=
 183 AC_SUBST(SYSTEMSPEC)
 184
 185 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 186 AC_SUBST(LIBGCJTESTSPEC)
 187
 188 AC_ARG_WITH(system-zlib,
 189 [  --with-system-zlib      use installed libz])
 190 ZLIBSPEC=
 191 AC_SUBST(ZLIBSPEC)
 192 ZLIBTESTSPEC=
 193 AC_SUBST(ZLIBTESTSPEC)
 194
 195 dnl FIXME: this should be _libs on some hosts.
 196 libsubdir=.libs
 197
 198 dnl Allow the GC to be disabled.  Can be useful when debugging.
 199 AC_MSG_CHECKING([for garbage collector to use])
 200 AC_ARG_ENABLE(java-gc,
 201 changequote(<<,>>)dnl
 202 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 203 changequote([,])
 204   GC=$enableval,
 205   GC=boehm)
 206 GCLIBS=
 207 GCINCS=
 208 GCDEPS=
 209 GCOBJS=
 210 GCSPEC=
 211 GCTESTSPEC=
 212 case "$GC" in
 213  boehm)
 214     AC_MSG_RESULT(boehm)
 215     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 216     # We include the path to the boehm-gc build directory.
 217     # See Makefile.am to understand why.
 218     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 219     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 220     GCSPEC='-lgcjgc'
 221     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 222     dnl We also want to pick up some cpp flags required when including
 223     dnl boehm-config.h.  Yuck.
 224     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 225     GCOBJS=boehm.lo
 226     GCHDR=boehm-gc.h
 227     dnl The POSIX thread support needs to know this.
 228     AC_DEFINE(HAVE_BOEHM_GC)
 229     ;;
 230  no)
 231     AC_MSG_RESULT(none)
 232     GCOBJS=nogc.lo
 233     GCHDR=no-gc.h
 234     ;;
 235  *)
 236     AC_MSG_ERROR(unrecognized collector \"$GC\")
 237     ;;
 238 esac
 239 AC_SUBST(GCLIBS)
 240 AC_SUBST(GCINCS)
 241 AC_SUBST(GCDEPS)
 242 AC_SUBST(GCOBJS)
 243 AC_SUBST(GCSPEC)
 244 AC_SUBST(GCTESTSPEC)
 245 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 246
 247
 248 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 249 dnl In particular both packages must make the same decision about which
 250 dnl thread package to use.
 251 AC_MSG_CHECKING([for threads package to use])
 252 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 253   THREADS=$enableval,
 254   dnl FIXME: figure out native threads to use here.
 255   THREADS=no)
 256
 257 if test "$THREADS" = yes; then
 258    case "$host" in
 259     *-*-vxworks*)
 260        THREADS=vxworks
 261        ;;
 262     *-*-linux*)
 263        # FIXME: this isn't correct in all cases.
 264        THREADS=posix
 265        ;;
 266     *-*-win*)
 267        THREADS=win32
 268        ;;
 269     *-*-irix*)
 270        # FIXME: for now, choose POSIX, because we implement that.
 271        # Later, choose irix threads.
 272        THREADS=posix
 273        ;;
 274     *-*-solaris*)
 275        # FIXME: for now, choose POSIX, because we implement that.
 276        # Later, choose solaris threads.
 277        THREADS=posix
 278        ;;
 279     *)
 280        # For now.
 281        THREADS=none
 282        ;;
 283    esac
 284 fi
 285
 286 case "$THREADS" in
 287  no | none | single)
 288     THREADS=none
 289     ;;
 290  posix | pthreads)
 291     THREADS=posix
 292     case "$host" in
 293      *-*-linux*)
 294         AC_DEFINE(LINUX_THREADS)
 295         ;;
 296     esac
 297     ;;
 298  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 299     AC_MSG_ERROR(thread package $THREADS not yet supported)
 300     ;;
 301  *)
 302     AC_MSG_ERROR($THREADS is an unknown thread package)
 303     ;;
 304 esac
 305 AC_MSG_RESULT($THREADS)
 306
 307 THREADLIBS=
 308 THREADINCS=
 309 THREADDEPS=
 310 THREADOBJS=
 311 THREADH=
 312 THREADSPEC=
 313 case "$THREADS" in
 314  posix)
 315     THREADLIBS=-lpthread
 316     THREADSPEC=-lpthread
 317     THREADOBJS=posix-threads.lo
 318     THREADH=posix-threads.h
 319     # MIT pthreads doesn't seem to have the mutexattr functions.
 320     # But for now we don't check for it.  We just assume you aren't
 321     # using MIT pthreads.
 322     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 323     ;;
 324
 325  none)
 326     THREADOBJS=no-threads.lo
 327     THREADH=no-threads.h
 328     ;;
 329 esac
 330 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 331 AC_SUBST(THREADLIBS)
 332 AC_SUBST(THREADINCS)
 333 AC_SUBST(THREADDEPS)
 334 AC_SUBST(THREADOBJS)
 335 AC_SUBST(THREADSPEC)
 336
 337 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 338
 339 CANADIAN=no
 340 NULL_TARGET=no
 341 NATIVE=yes
 342
 343 # Find eh-common.h and support headers.  If we're in the tree with
 344 # gcc, then look there.  Otherwise look in compat-include.  If all else
 345 # fails, just hope the user has set things up somehow.
 346 if test -r $srcdir/../gcc/eh-common.h; then
 347    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 348 else
 349    if test -d $srcdir/../compat-include; then
 350       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 351    else
 352       EH_COMMON_INCLUDE=
 353    fi
 354 fi
 355
 356 if test -n "${with_cross_host}"; then
 357    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 358    # may not work correctly, because the compiler may not be able to
 359    # link executables.
 360
 361    # We assume newlib.  This lets us hard-code the functions we know
 362    # we'll have.
 363    AC_DEFINE(HAVE_MEMMOVE)
 364    AC_DEFINE(HAVE_MEMCPY)
 365    AC_DEFINE(HAVE_STRERROR)
 366    AC_DEFINE(HAVE_GMTIME_R)
 367    AC_DEFINE(HAVE_LOCALTIME_R)
 368    dnl This is only for POSIX threads.
 369    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 370    dnl We also assume we are using gcc, which provides alloca.
 371    AC_DEFINE(HAVE_ALLOCA)
 372
 373    dnl Assume we do not have getuid and friends.
 374    AC_DEFINE(NO_GETUID)
 375
 376    ZLIBSPEC=-lzgcj
 377    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 378
 379    # If Canadian cross, then don't pick up tools from the build
 380    # directory.
 381    if test "$build" != "$with_cross_host"; then
 382       CANADIAN=yes
 383       EH_COMMON_INCLUDE=
 384       GCJ="${target_alias}-gcj"
 385    else
 386       GCJ=
 387    fi
 388    NATIVE=no
 389 else
 390    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 391    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 392    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath iconv)
 393    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 394    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 395    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 396    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 397    AC_CHECK_LIB(dl, dladdr, [
 398      AC_DEFINE(HAVE_DLADDR)])
 399    AC_CHECK_FILES(/proc/self/exe, [
 400      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 401
 402    AC_CHECK_FUNCS(gethostbyname_r, [
 403      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 404      # There are two different kinds of gethostbyname_r.
 405      # We look for the one that returns `int'.
 406      # Hopefully this check is robust enough.
 407      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 408        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 409
 410      case " $GCINCS " in
 411      *" -D_REENTRANT "*) ;;
 412      *)
 413         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 414         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 415         [libjava_cv_gethostbyname_r_needs_reentrant],
 416         [ AC_LANG_SAVE
 417           AC_LANG_CPLUSPLUS
 418           AC_TRY_COMPILE([#include <netdb.h>],
 419             [gethostbyname_r("", 0, 0);],
 420             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 421                 CPPFLAGS_SAVE="$CPPFLAGS"
 422                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 423                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 424                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 425                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 426                 CPPFLAGS="$CPPFLAGS_SAVE"
 427           ])
 428           AC_LANG_RESTORE
 429         ])
 430         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 431           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 432         fi
 433      ;;
 434      esac
 435
 436      AC_CACHE_CHECK([for struct hostent_data],
 437         [libjava_cv_struct_hostent_data], [dnl
 438         AC_TRY_COMPILE([
 439 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 440 # define _REENTRANT 1
 441 #endif
 442 #include <netdb.h>], [struct hostent_data data;],
 443           [libjava_cv_struct_hostent_data=yes],
 444           [libjava_cv_struct_hostent_data=no])])
 445      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 446        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 447          [Define if struct hostent_data is defined in netdb.h])
 448      fi
 449    ])
 450
 451    AC_CHECK_FUNCS(gethostbyaddr_r, [
 452      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 453      # There are two different kinds of gethostbyaddr_r.
 454      # We look for the one that returns `int'.
 455      # Hopefully this check is robust enough.
 456      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 457        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 458
 459    AC_CHECK_FUNCS(gethostname, [
 460      AC_DEFINE(HAVE_GETHOSTNAME)
 461      AC_EGREP_HEADER(gethostname, unistd.h, [
 462        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 463
 464    # Look for these functions in the thread library, but only bother
 465    # if using POSIX threads.
 466    if test "$THREADS" = posix; then
 467       save_LIBS="$LIBS"
 468       LIBS="$LIBS $THREADLIBS"
 469       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 470       # E.g., Solaris.
 471       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 472
 473       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 474       # Solaris 7 the name librt is preferred.
 475       AC_CHECK_FUNCS(sched_yield, , [
 476         AC_CHECK_LIB(rt, sched_yield, [
 477           AC_DEFINE(HAVE_SCHED_YIELD)
 478           THREADLIBS="$THREADLIBS -lrt"
 479           THREADSPEC="$THREADSPEC -lrt"], [
 480           AC_CHECK_LIB(posix4, sched_yield, [
 481             AC_DEFINE(HAVE_SCHED_YIELD)
 482             THREADLIBS="$THREADLIBS -lposix4"
 483             THREADSPEC="$THREADSPEC -lposix4"])])])
 484       LIBS="$save_LIBS"
 485
 486       # We can save a little space at runtime if the mutex has m_count
 487       # or __m_count.  This is a nice hack for Linux.
 488       AC_TRY_COMPILE([#include <pthread.h>], [
 489           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 490         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 491         AC_TRY_COMPILE([#include <pthread.h>], [
 492             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 493           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 494    fi
 495
 496    # We require a way to get the time.
 497    time_found=no
 498    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 499    if test "$time_found" = no; then
 500       AC_MSG_ERROR([no function found to get the time])
 501    fi
 502
 503    AC_CHECK_FUNCS(memmove)
 504
 505    # We require memcpy.
 506    memcpy_found=no
 507    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 508    if test "$memcpy_found" = no; then
 509       AC_MSG_ERROR([memcpy is required])
 510    fi
 511
 512    # Some library-finding code we stole from Tcl.
 513    #--------------------------------------------------------------------
 514    #    Check for the existence of the -lsocket and -lnsl libraries.
 515    #    The order here is important, so that they end up in the right
 516    #    order in the command line generated by make.  Here are some
 517    #    special considerations:
 518    #    1. Use "connect" and "accept" to check for -lsocket, and
 519    #       "gethostbyname" to check for -lnsl.
 520    #    2. Use each function name only once:  can't redo a check because
 521    #       autoconf caches the results of the last check and won't redo it.
 522    #    3. Use -lnsl and -lsocket only if they supply procedures that
 523    #       aren't already present in the normal libraries.  This is because
 524    #       IRIX 5.2 has libraries, but they aren't needed and they're
 525    #       bogus:  they goof up name resolution if used.
 526    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 527    #       To get around this problem, check for both libraries together
 528    #       if -lsocket doesn't work by itself.
 529    #--------------------------------------------------------------------
 530
 531    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 532     [gcj_cv_lib_sockets=
 533      gcj_checkBoth=0
 534      unset ac_cv_func_connect
 535      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 536      if test "$gcj_checkSocket" = 1; then
 537          unset ac_cv_func_connect
 538          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 539                       gcj_checkBoth=1)
 540      fi
 541      if test "$gcj_checkBoth" = 1; then
 542          gcj_oldLibs=$LIBS
 543          LIBS="$LIBS -lsocket -lnsl"
 544          unset ac_cv_func_accept
 545          AC_CHECK_FUNC(accept,
 546                        [gcj_checkNsl=0
 547                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 548          unset ac_cv_func_accept
 549          LIBS=$gcj_oldLibs
 550      fi
 551      unset ac_cv_func_gethostbyname
 552      gcj_oldLibs=$LIBS
 553      LIBS="$LIBS $gcj_cv_lib_sockets"
 554      AC_CHECK_FUNC(gethostbyname, ,
 555                    [AC_CHECK_LIB(nsl, main,
 556                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 557      unset ac_cv_func_gethostbyname
 558      LIBS=$gcj_oldLIBS
 559    ])
 560    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 561
 562    if test "$with_system_zlib" = yes; then
 563       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 564    else
 565       ZLIBSPEC=-lzgcj
 566       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 567    fi
 568
 569    # On Solaris, and maybe other architectures, the Boehm collector
 570    # requires -ldl.
 571    if test "$GC" = boehm; then
 572       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 573    fi
 574
 575    if test -d "$libgcj_basedir/../gcc/java"; then
 576       GCJ=
 577    else
 578       CANADIAN=yes
 579       NULL_TARGET=yes
 580       GCJ=gcj
 581    fi
 582 fi
 583
 584 dnl FIXME: cross compilation
 585 AC_CHECK_SIZEOF(void *)
 586
 587 ZLIBS=
 588 ZDEPS=
 589 ZINCS=
 590 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 591    # We include the path to the zlib build directory.
 592    # See Makefile.am to understand why.
 593    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 594    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 595    ZINCS='-I$(top_srcdir)/../zlib'
 596 else
 597    ZLIBS="$ZLIBSPEC"
 598 fi
 599 AC_SUBST(ZLIBS)
 600 AC_SUBST(ZDEPS)
 601 AC_SUBST(ZINCS)
 602 AC_SUBST(DIVIDESPEC)
 603 AC_SUBST(EXCEPTIONSPEC)
 604 AC_SUBST(FORCELIBGCCSPEC)
 605
 606 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 607 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 608 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 609 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 610 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 611 AC_SUBST(EH_COMMON_INCLUDE)
 612
 613 # Determine gcj version number.
 614 if test "$GCJ" = ""; then
 615    if test -z "${with_multisubdir}"; then
 616       builddotdot=.
 617    else
 618 changequote(<<,>>)
 619       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 620 changequote([,])
 621    fi
 622    dir="`cd ${builddotdot}/../../gcc && pwd`"
 623    GCJ="$dir/gcj -B$dir/"
 624 fi
 625 changequote(<<,>>)
 626 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 627 changequote([,])
 628 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 629
 630 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 631 # we want to continue to support that version.
 632 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 633 cat > conftest.java << 'END'
 634 public class conftest { }
 635 END
 636 use_fuse=yes
 637 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 638    conftest.java > /dev/null 2>&1 \
 639    || use_fuse=no
 640 rm -f conftest.java
 641 if test "$use_fuse" = no; then
 642    DIVIDESPEC=
 643 fi
 644 AC_MSG_RESULT($use_fuse)
 645
 646 AC_SUBST(AM_RUNTESTFLAGS)
 647
 648 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 649 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 650 save_CFLAGS="$CFLAGS"
 651 CFLAGS="-x c++ -O2 -ffloat-store"
 652 AC_TRY_COMPILE([#include <math.h>], ,
 653   [AC_MSG_RESULT(no)],
 654   [AC_DEFINE(__NO_MATH_INLINES)
 655    AC_MSG_RESULT(yes)])
 656 CFLAGS="$save_CFLAGS"
 657
 658 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 659 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 660 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 661 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 662 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 663 dnl for now.  If you change this, you also must update natFile.cc.
 664 AC_CHECK_HEADERS(dirent.h)
 665
 666 AC_CHECK_TYPE([ssize_t], [int])
 667
 668 AC_MSG_CHECKING([for in_addr_t])
 669 AC_TRY_COMPILE([#include <sys/types.h>
 670 #if STDC_HEADERS
 671 #include <stdlib.h>
 672 #include <stddef.h>
 673 #endif
 674 #if HAVE_NETINET_IN_H
 675 #include <netinet/in.h>
 676 #endif], [in_addr_t foo;],
 677   [AC_DEFINE([HAVE_IN_ADDR_T])
 678    AC_MSG_RESULT(yes)],
 679   [AC_MSG_RESULT(no)])
 680
 681 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 682 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 683   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 684    AC_MSG_RESULT(yes)],
 685   [AC_MSG_RESULT(no)])
 686
 687 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 688 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 689   [AC_DEFINE(HAVE_INET6)
 690    AC_MSG_RESULT(yes)],
 691   [AC_MSG_RESULT(no)])
 692
 693 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 694 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 695   [AC_DEFINE(HAVE_SOCKLEN_T)
 696    AC_MSG_RESULT(yes)],
 697   [AC_MSG_RESULT(no)])
 698
 699 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 700 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 701   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 702    AC_MSG_RESULT(yes)],
 703   [AC_MSG_RESULT(no)
 704    AC_MSG_CHECKING([for global timezone variable])
 705    dnl FIXME: we don't want a link check here because that won't work
 706    dnl when cross-compiling.  So instead we make an assumption that
 707    dnl the header file will mention timezone if it exists.
 708    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 709      [AC_DEFINE(HAVE_TIMEZONE)
 710       AC_MSG_RESULT(yes)],
 711      [AC_MSG_RESULT(no)])])
 712
 713 AC_FUNC_ALLOCA
 714
 715 AC_CHECK_PROGS(PERL, perl, false)
 716
 717 if test "$enable_sjlj_exceptions" = yes; then
 718    SIGNAL_HANDLER=include/default-signal.h
 719 else
 720    case "${host}" in
 721     i?86-*-linux*)
 722        SIGNAL_HANDLER=include/i386-signal.h
 723        ;;
 724     sparc-sun-solaris*)
 725        SIGNAL_HANDLER=include/sparc-signal.h
 726        ;;
 727     *)
 728        SIGNAL_HANDLER=include/default-signal.h
 729        ;;
 730    esac
 731 fi
 732
 733 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 734
 735 if test "${multilib}" = "yes"; then
 736   multilib_arg="--enable-multilib"
 737 else
 738   multilib_arg=
 739 fi
 740
 741 here=`pwd`
 742 AC_SUBST(here)
 743
 744 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gcj/Makefile include/Makefile testsuite/Makefile,
 745 [if test -n "$CONFIG_FILES"; then
 746   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 747 fi],
 748 srcdir=${srcdir}
 749 host=${host}
 750 target=${target}
 751 with_multisubdir=${with_multisubdir}
 752 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 753 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 754 libgcj_basedir=${libgcj_basedir}
 755 CC="${CC}"
 756 CXX="${CXX}"
 757 )