libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 # Only use libltdl for native builds.
  21 if test -z "${with_cross_host}"; then
  22    AC_LIBLTDL_CONVENIENCE
  23    AC_LIBTOOL_DLOPEN
  24    DIRLTDL=libltdl
  25    AC_DEFINE(USE_LTDL)
  26    # Sigh.  Libtool's macro doesn't do the right thing.
  27    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -n "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66 dnl See if the user has requested runtime debugging.
  67 AC_ARG_ENABLE(libgcj-debug,
  68 [  --enable-libgcj-debug   enable runtime debugging code],
  69   if test "$enable_libgcj_debug" = yes; then
  70      AC_DEFINE(DEBUG)
  71   fi)
  72
  73 dnl See if the user has the interpreter included.
  74 AC_ARG_ENABLE(interpreter,
  75 [  --enable-interpreter    enable interpreter],
  76   if test "$enable_interpreter" = yes; then
  77     # This can also be set in configure.host.
  78     libgcj_interpreter=yes
  79   elif test "$enable_interpreter" = no; then
  80     libgcj_interpreter=no
  81   fi)
  82
  83 if test "$libgcj_interpreter" = yes; then
  84    AC_DEFINE(INTERPRETER)
  85 fi
  86
  87 EXCEPTIONSPEC=
  88 dnl See if we should use setjmp/longjmp exceptions
  89 AC_ARG_ENABLE(sjlj-exceptions,
  90 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  91   if test "$enable_sjlj_exceptions" = yes; then
  92      # This can be set in configure.host.
  93      libgcj_sjlj=yes
  94   fi)
  95
  96 if test "$libgcj_sjlj" = yes; then
  97    EXCEPTIONSPEC="-fsjlj-exceptions"
  98    AC_DEFINE(SJLJ_EXCEPTIONS)
  99 fi
 100
 101 FORCELIBGCCSPEC=
 102 dnl Work around libgcc design flaw.
 103 if test "$ac_cv_prog_gnu_ld" = yes; then
 104    FORCELIBGCCSPEC="-u __rethrow -u __frame_state_for -lgcc"
 105 fi
 106
 107 AC_MSG_CHECKING([for data_start])
 108 LIBDATASTARTSPEC=
 109 NEEDS_DATA_START=
 110 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 111   [AC_MSG_RESULT(found it)],
 112   [LIBDATASTARTSPEC="-u data_start -lgcjdata"
 113    NEEDS_DATA_START=yes
 114    AC_MSG_RESULT(missing)])
 115 AC_SUBST(LIBDATASTARTSPEC)
 116
 117 dnl See if the user wants to disable java.net.  This is the mildly
 118 dnl ugly way that we admit that target-side configuration sucks.
 119 AC_ARG_ENABLE(java-net,
 120 [  --disable-java-net      disable java.net])
 121
 122 dnl Whether java.net is built by default can depend on the target.
 123 if test -n "$enable_java_net"; then
 124    enable_java_net=${enable_java_net_default-yes}
 125 fi
 126 if test "$enable_java_net" = no; then
 127    AC_DEFINE(DISABLE_JAVA_NET)
 128 fi
 129
 130 dnl See if the user wants to disable JVMPI support.
 131 AC_ARG_ENABLE(jvmpi,
 132 [  --disable-jvmpi         disable JVMPI support])
 133
 134 if test "$enable_jvmpi" != no; then
 135     AC_DEFINE(ENABLE_JVMPI)
 136 fi
 137
 138 dnl If the target is an eCos system, use the appropriate eCos
 139 dnl I/O routines.
 140 dnl FIXME: this should not be a local option but a global target
 141 dnl system; at present there is no eCos target.
 142 TARGET_ECOS="no"
 143 AC_ARG_WITH(ecos,
 144 [  --with-ecos             enable runtime eCos target support],
 145 TARGET_ECOS="$with_ecos"
 146 )
 147
 148 case "$TARGET_ECOS" in
 149    no)
 150       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 151       PROCESS=${PROCESS-Posix}
 152       ;;
 153    *)
 154       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 155       PROCESS=Ecos
 156       AC_DEFINE(ECOS)
 157       ;;
 158 esac
 159
 160 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 161 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 162 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 163 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 164
 165
 166 dnl These may not be defined in a non-ANS conformant embedded system.
 167 dnl FIXME: Should these case a runtime exception in that case?
 168 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 169 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 170
 171 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 172 dnl to create the link will fail.
 173 test -d java || mkdir java
 174 test -d java/io || mkdir java/io
 175 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 176
 177 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 178 test -d java/lang || mkdir java/lang
 179 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 180 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 181
 182 SYSTEMSPEC=
 183 AC_SUBST(SYSTEMSPEC)
 184
 185 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 186 AC_SUBST(LIBGCJTESTSPEC)
 187
 188 AC_ARG_WITH(system-zlib,
 189 [  --with-system-zlib      use installed libz])
 190 ZLIBSPEC=
 191 AC_SUBST(ZLIBSPEC)
 192 ZLIBTESTSPEC=
 193 AC_SUBST(ZLIBTESTSPEC)
 194
 195 dnl FIXME: this should be _libs on some hosts.
 196 libsubdir=.libs
 197
 198 dnl Allow the GC to be disabled.  Can be useful when debugging.
 199 AC_MSG_CHECKING([for garbage collector to use])
 200 AC_ARG_ENABLE(java-gc,
 201 changequote(<<,>>)dnl
 202 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 203 changequote([,])
 204   GC=$enableval,
 205   GC=boehm)
 206 GCLIBS=
 207 GCINCS=
 208 GCDEPS=
 209 GCOBJS=
 210 GCSPEC=
 211 GCTESTSPEC=
 212 case "$GC" in
 213  boehm)
 214     AC_MSG_RESULT(boehm)
 215     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 216     # We include the path to the boehm-gc build directory.
 217     # See Makefile.am to understand why.
 218     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 219     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 220     GCSPEC='-lgcjgc'
 221     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 222     dnl We also want to pick up some cpp flags required when including
 223     dnl boehm-config.h.  Yuck.
 224     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 225     GCOBJS=boehm.lo
 226     GCHDR=boehm-gc.h
 227     dnl The POSIX thread support needs to know this.
 228     AC_DEFINE(HAVE_BOEHM_GC)
 229     ;;
 230  no)
 231     AC_MSG_RESULT(none)
 232     GCOBJS=nogc.lo
 233     GCHDR=no-gc.h
 234     ;;
 235  *)
 236     AC_MSG_ERROR(unrecognized collector \"$GC\")
 237     ;;
 238 esac
 239 AC_SUBST(GCLIBS)
 240 AC_SUBST(GCINCS)
 241 AC_SUBST(GCDEPS)
 242 AC_SUBST(GCOBJS)
 243 AC_SUBST(GCSPEC)
 244 AC_SUBST(GCTESTSPEC)
 245 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 246
 247
 248 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 249 dnl In particular both packages must make the same decision about which
 250 dnl thread package to use.
 251 AC_MSG_CHECKING([for threads package to use])
 252 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 253   THREADS=$enableval,
 254   dnl FIXME: figure out native threads to use here.
 255   THREADS=no)
 256
 257 if test "$THREADS" = yes; then
 258    case "$host" in
 259     *-*-vxworks*)
 260        THREADS=vxworks
 261        ;;
 262     *-*-linux*)
 263        # FIXME: this isn't correct in all cases.
 264        THREADS=posix
 265        ;;
 266     *-*-win*)
 267        THREADS=win32
 268        ;;
 269     *-*-irix*)
 270        # FIXME: for now, choose POSIX, because we implement that.
 271        # Later, choose irix threads.
 272        THREADS=posix
 273        ;;
 274     *-*-solaris*)
 275        # FIXME: for now, choose POSIX, because we implement that.
 276        # Later, choose solaris threads.
 277        THREADS=posix
 278        ;;
 279     *)
 280        # For now.
 281        THREADS=none
 282        ;;
 283    esac
 284 fi
 285
 286 case "$THREADS" in
 287  no | none | single)
 288     THREADS=none
 289     ;;
 290  posix | pthreads)
 291     THREADS=posix
 292     case "$host" in
 293      *-*-linux*)
 294         AC_DEFINE(LINUX_THREADS)
 295         ;;
 296     esac
 297     ;;
 298  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 299     AC_MSG_ERROR(thread package $THREADS not yet supported)
 300     ;;
 301  *)
 302     AC_MSG_ERROR($THREADS is an unknown thread package)
 303     ;;
 304 esac
 305 AC_MSG_RESULT($THREADS)
 306
 307 THREADLIBS=
 308 THREADINCS=
 309 THREADDEPS=
 310 THREADOBJS=
 311 THREADH=
 312 THREADSPEC=
 313 case "$THREADS" in
 314  posix)
 315     THREADLIBS=-lpthread
 316     THREADSPEC=-lpthread
 317     THREADOBJS=posix-threads.lo
 318     THREADH=posix-threads.h
 319     # MIT pthreads doesn't seem to have the mutexattr functions.
 320     # But for now we don't check for it.  We just assume you aren't
 321     # using MIT pthreads.
 322     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 323
 324     # If we're using the Boehm GC, then we happen to know that it
 325     # defines _REENTRANT, so we don't bother.  Eww.
 326     if test "$GC" != boehm; then
 327        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 328     fi
 329     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 330     ;;
 331
 332  none)
 333     THREADOBJS=no-threads.lo
 334     THREADH=no-threads.h
 335     ;;
 336 esac
 337 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 338 AC_SUBST(THREADLIBS)
 339 AC_SUBST(THREADINCS)
 340 AC_SUBST(THREADDEPS)
 341 AC_SUBST(THREADOBJS)
 342 AC_SUBST(THREADSPEC)
 343
 344 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 345
 346 CANADIAN=no
 347 NULL_TARGET=no
 348 NATIVE=yes
 349
 350 # Find eh-common.h and support headers.  If we're in the tree with
 351 # gcc, then look there.  Otherwise look in compat-include.  If all else
 352 # fails, just hope the user has set things up somehow.
 353 if test -r $srcdir/../gcc/eh-common.h; then
 354    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 355 else
 356    if test -d $srcdir/../compat-include; then
 357       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 358    else
 359       EH_COMMON_INCLUDE=
 360    fi
 361 fi
 362
 363 if test -n "${with_cross_host}"; then
 364    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 365    # may not work correctly, because the compiler may not be able to
 366    # link executables.
 367
 368    # We assume newlib.  This lets us hard-code the functions we know
 369    # we'll have.
 370    AC_DEFINE(HAVE_MEMMOVE)
 371    AC_DEFINE(HAVE_MEMCPY)
 372    AC_DEFINE(HAVE_STRERROR)
 373    AC_DEFINE(HAVE_GMTIME_R)
 374    AC_DEFINE(HAVE_LOCALTIME_R)
 375    dnl This is only for POSIX threads.
 376    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 377    dnl We also assume we are using gcc, which provides alloca.
 378    AC_DEFINE(HAVE_ALLOCA)
 379
 380    dnl Assume we do not have getuid and friends.
 381    AC_DEFINE(NO_GETUID)
 382
 383    ZLIBSPEC=-lzgcj
 384    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 385
 386    # If Canadian cross, then don't pick up tools from the build
 387    # directory.
 388    if test "$build" != "$with_cross_host"; then
 389       CANADIAN=yes
 390       EH_COMMON_INCLUDE=
 391       GCJ="${target_alias}-gcj"
 392    else
 393       GCJ=
 394    fi
 395    NATIVE=no
 396 else
 397    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 398    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 399    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 400    AC_CHECK_FUNCS(iconv nl_langinfo)
 401    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 402    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 403    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 404    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 405    AC_CHECK_LIB(dl, dladdr, [
 406      AC_DEFINE(HAVE_DLADDR)])
 407    AC_CHECK_FILES(/proc/self/exe, [
 408      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 409
 410    AC_CHECK_FUNCS(gethostbyname_r, [
 411      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 412      # There are two different kinds of gethostbyname_r.
 413      # We look for the one that returns `int'.
 414      # Hopefully this check is robust enough.
 415      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 416        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 417
 418      case " $GCINCS " in
 419      *" -D_REENTRANT "*) ;;
 420      *)
 421         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 422         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 423         [libjava_cv_gethostbyname_r_needs_reentrant],
 424         [ AC_LANG_SAVE
 425           AC_LANG_CPLUSPLUS
 426           AC_TRY_COMPILE([#include <netdb.h>],
 427             [gethostbyname_r("", 0, 0);],
 428             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 429                 CPPFLAGS_SAVE="$CPPFLAGS"
 430                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 431                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 432                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 433                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 434                 CPPFLAGS="$CPPFLAGS_SAVE"
 435           ])
 436           AC_LANG_RESTORE
 437         ])
 438         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 439           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 440         fi
 441      ;;
 442      esac
 443
 444      AC_CACHE_CHECK([for struct hostent_data],
 445         [libjava_cv_struct_hostent_data], [dnl
 446         AC_TRY_COMPILE([
 447 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 448 # define _REENTRANT 1
 449 #endif
 450 #include <netdb.h>], [struct hostent_data data;],
 451           [libjava_cv_struct_hostent_data=yes],
 452           [libjava_cv_struct_hostent_data=no])])
 453      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 454        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 455          [Define if struct hostent_data is defined in netdb.h])
 456      fi
 457    ])
 458
 459    AC_CHECK_FUNCS(gethostbyaddr_r, [
 460      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 461      # There are two different kinds of gethostbyaddr_r.
 462      # We look for the one that returns `int'.
 463      # Hopefully this check is robust enough.
 464      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 465        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 466
 467    AC_CHECK_FUNCS(gethostname, [
 468      AC_DEFINE(HAVE_GETHOSTNAME)
 469      AC_EGREP_HEADER(gethostname, unistd.h, [
 470        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 471
 472    # Look for these functions in the thread library, but only bother
 473    # if using POSIX threads.
 474    if test "$THREADS" = posix; then
 475       save_LIBS="$LIBS"
 476       LIBS="$LIBS $THREADLIBS"
 477       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 478       # E.g., Solaris.
 479       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 480
 481       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 482       # Solaris 7 the name librt is preferred.
 483       AC_CHECK_FUNCS(sched_yield, , [
 484         AC_CHECK_LIB(rt, sched_yield, [
 485           AC_DEFINE(HAVE_SCHED_YIELD)
 486           THREADLIBS="$THREADLIBS -lrt"
 487           THREADSPEC="$THREADSPEC -lrt"], [
 488           AC_CHECK_LIB(posix4, sched_yield, [
 489             AC_DEFINE(HAVE_SCHED_YIELD)
 490             THREADLIBS="$THREADLIBS -lposix4"
 491             THREADSPEC="$THREADSPEC -lposix4"])])])
 492       LIBS="$save_LIBS"
 493
 494       # We can save a little space at runtime if the mutex has m_count
 495       # or __m_count.  This is a nice hack for Linux.
 496       AC_TRY_COMPILE([#include <pthread.h>], [
 497           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 498         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 499         AC_TRY_COMPILE([#include <pthread.h>], [
 500             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 501           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 502    fi
 503
 504    # We require a way to get the time.
 505    time_found=no
 506    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 507    if test "$time_found" = no; then
 508       AC_MSG_ERROR([no function found to get the time])
 509    fi
 510
 511    AC_CHECK_FUNCS(memmove)
 512
 513    # We require memcpy.
 514    memcpy_found=no
 515    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 516    if test "$memcpy_found" = no; then
 517       AC_MSG_ERROR([memcpy is required])
 518    fi
 519
 520    # Some library-finding code we stole from Tcl.
 521    #--------------------------------------------------------------------
 522    #    Check for the existence of the -lsocket and -lnsl libraries.
 523    #    The order here is important, so that they end up in the right
 524    #    order in the command line generated by make.  Here are some
 525    #    special considerations:
 526    #    1. Use "connect" and "accept" to check for -lsocket, and
 527    #       "gethostbyname" to check for -lnsl.
 528    #    2. Use each function name only once:  can't redo a check because
 529    #       autoconf caches the results of the last check and won't redo it.
 530    #    3. Use -lnsl and -lsocket only if they supply procedures that
 531    #       aren't already present in the normal libraries.  This is because
 532    #       IRIX 5.2 has libraries, but they aren't needed and they're
 533    #       bogus:  they goof up name resolution if used.
 534    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 535    #       To get around this problem, check for both libraries together
 536    #       if -lsocket doesn't work by itself.
 537    #--------------------------------------------------------------------
 538
 539    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 540     [gcj_cv_lib_sockets=
 541      gcj_checkBoth=0
 542      unset ac_cv_func_connect
 543      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 544      if test "$gcj_checkSocket" = 1; then
 545          unset ac_cv_func_connect
 546          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 547                       gcj_checkBoth=1)
 548      fi
 549      if test "$gcj_checkBoth" = 1; then
 550          gcj_oldLibs=$LIBS
 551          LIBS="$LIBS -lsocket -lnsl"
 552          unset ac_cv_func_accept
 553          AC_CHECK_FUNC(accept,
 554                        [gcj_checkNsl=0
 555                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 556          unset ac_cv_func_accept
 557          LIBS=$gcj_oldLibs
 558      fi
 559      unset ac_cv_func_gethostbyname
 560      gcj_oldLibs=$LIBS
 561      LIBS="$LIBS $gcj_cv_lib_sockets"
 562      AC_CHECK_FUNC(gethostbyname, ,
 563                    [AC_CHECK_LIB(nsl, main,
 564                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 565      unset ac_cv_func_gethostbyname
 566      LIBS=$gcj_oldLIBS
 567    ])
 568    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 569
 570    if test "$with_system_zlib" = yes; then
 571       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 572    else
 573       ZLIBSPEC=-lzgcj
 574       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 575    fi
 576
 577    # On Solaris, and maybe other architectures, the Boehm collector
 578    # requires -ldl.
 579    if test "$GC" = boehm; then
 580       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 581    fi
 582
 583    if test -d "$libgcj_basedir/../gcc/java"; then
 584       GCJ=
 585    else
 586       CANADIAN=yes
 587       NULL_TARGET=yes
 588       GCJ=gcj
 589    fi
 590 fi
 591
 592 dnl FIXME: cross compilation
 593 AC_CHECK_SIZEOF(void *)
 594
 595 ZLIBS=
 596 ZDEPS=
 597 ZINCS=
 598 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 599    # We include the path to the zlib build directory.
 600    # See Makefile.am to understand why.
 601    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 602    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 603    ZINCS='-I$(top_srcdir)/../zlib'
 604 else
 605    ZLIBS="$ZLIBSPEC"
 606 fi
 607 AC_SUBST(ZLIBS)
 608 AC_SUBST(ZDEPS)
 609 AC_SUBST(ZINCS)
 610 AC_SUBST(DIVIDESPEC)
 611 AC_SUBST(EXCEPTIONSPEC)
 612 AC_SUBST(FORCELIBGCCSPEC)
 613
 614 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 615 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 616 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 617 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 618 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 619 AC_SUBST(EH_COMMON_INCLUDE)
 620
 621 # Determine gcj version number.
 622 if test "$GCJ" = ""; then
 623    if test -z "${with_multisubdir}"; then
 624       builddotdot=.
 625    else
 626 changequote(<<,>>)
 627       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 628 changequote([,])
 629    fi
 630    dir="`cd ${builddotdot}/../../gcc && pwd`"
 631    GCJ="$dir/gcj -B$dir/"
 632 fi
 633 changequote(<<,>>)
 634 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 635 changequote([,])
 636 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 637
 638 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 639 # we want to continue to support that version.
 640 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 641 cat > conftest.java << 'END'
 642 public class conftest { }
 643 END
 644 use_fuse=yes
 645 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 646    conftest.java > /dev/null 2>&1 \
 647    || use_fuse=no
 648 rm -f conftest.java
 649 if test "$use_fuse" = no; then
 650    DIVIDESPEC=
 651 fi
 652 AC_MSG_RESULT($use_fuse)
 653
 654 AC_SUBST(AM_RUNTESTFLAGS)
 655
 656 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 657 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 658 save_CFLAGS="$CFLAGS"
 659 CFLAGS="-x c++ -O2 -ffloat-store"
 660 AC_TRY_COMPILE([#include <math.h>], ,
 661   [AC_MSG_RESULT(no)],
 662   [AC_DEFINE(__NO_MATH_INLINES)
 663    AC_MSG_RESULT(yes)])
 664 CFLAGS="$save_CFLAGS"
 665
 666 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 667 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 668 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 669 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h)
 670 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 671 dnl for now.  If you change this, you also must update natFile.cc.
 672 AC_CHECK_HEADERS(dirent.h)
 673
 674 AC_CHECK_TYPE([ssize_t], [int])
 675
 676 AC_MSG_CHECKING([for in_addr_t])
 677 AC_TRY_COMPILE([#include <sys/types.h>
 678 #if STDC_HEADERS
 679 #include <stdlib.h>
 680 #include <stddef.h>
 681 #endif
 682 #if HAVE_NETINET_IN_H
 683 #include <netinet/in.h>
 684 #endif], [in_addr_t foo;],
 685   [AC_DEFINE([HAVE_IN_ADDR_T])
 686    AC_MSG_RESULT(yes)],
 687   [AC_MSG_RESULT(no)])
 688
 689 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 690 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 691   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 692    AC_MSG_RESULT(yes)],
 693   [AC_MSG_RESULT(no)])
 694
 695 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 696 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 697   [AC_DEFINE(HAVE_INET6)
 698    AC_MSG_RESULT(yes)],
 699   [AC_MSG_RESULT(no)])
 700
 701 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 702 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 703   [AC_DEFINE(HAVE_SOCKLEN_T)
 704    AC_MSG_RESULT(yes)],
 705   [AC_MSG_RESULT(no)])
 706
 707 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 708 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 709   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 710    AC_MSG_RESULT(yes)],
 711   [AC_MSG_RESULT(no)
 712    AC_MSG_CHECKING([for global timezone variable])
 713    dnl FIXME: we don't want a link check here because that won't work
 714    dnl when cross-compiling.  So instead we make an assumption that
 715    dnl the header file will mention timezone if it exists.
 716    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 717      [AC_DEFINE(HAVE_TIMEZONE)
 718       AC_MSG_RESULT(yes)],
 719      [AC_MSG_RESULT(no)])])
 720
 721 AC_FUNC_ALLOCA
 722
 723 AC_CHECK_PROGS(PERL, perl, false)
 724
 725 SYSDEP_SOURCES=
 726
 727 case "${host}" in
 728  i?86-*-linux*)
 729     SIGNAL_HANDLER=include/i386-signal.h
 730     ;;
 731  sparc-sun-solaris*)
 732     SIGNAL_HANDLER=include/sparc-signal.h
 733     ;;
 734  ia64-*)
 735     SYSDEP_SOURCES=sysdep/ia64.c
 736     test -d sysdep || mkdir sysdep
 737     ;;
 738  *)
 739     SIGNAL_HANDLER=include/default-signal.h
 740     ;;
 741 esac
 742
 743 # If we're using sjlj exceptions, forget what we just learned.
 744 if test "$libgcj_sjlj" = yes; then
 745    SIGNAL_HANDLER=include/default-signal.h
 746 fi
 747
 748 AC_SUBST(SYSDEP_SOURCES)
 749
 750 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 751
 752 if test "${multilib}" = "yes"; then
 753   multilib_arg="--enable-multilib"
 754 else
 755   multilib_arg=
 756 fi
 757
 758 here=`pwd`
 759 AC_SUBST(here)
 760
 761 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gcj/Makefile include/Makefile testsuite/Makefile,
 762 [if test -n "$CONFIG_FILES"; then
 763   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 764 fi],
 765 srcdir=${srcdir}
 766 host=${host}
 767 target=${target}
 768 with_multisubdir=${with_multisubdir}
 769 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 770 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 771 libgcj_basedir=${libgcj_basedir}
 772 CC="${CC}"
 773 CXX="${CXX}"
 774 )