libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 AC_PROG_LN_S
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR
   9                            configuring in a subdirectory])
  10 AC_ARG_WITH(cross-host,
  11 [  --with-cross-host=HOST  configuring with a cross compiler])
  12
  13 LIBGCJ_CONFIGURE(.)
  14
  15 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
  16
  17 # Only use libltdl for native builds.
  18 if test -z "${with_cross_host}"; then
  19    AC_LIBLTDL_CONVENIENCE
  20    AC_LIBTOOL_DLOPEN
  21    DIRLTDL=libltdl
  22    AC_DEFINE(USE_LTDL)
  23    # Sigh.  Libtool's macro doesn't do the right thing.
  24    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  25    # FIXME: this is a hack.
  26    sub_auxdir="`cd $ac_aux_dir && pwd`"
  27    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl Should the runtime set system properties by examining the
  46 dnl environment variable GCJ_PROPERTIES?
  47 AC_ARG_ENABLE(getenv-properties,
  48 [  --disable-getenv-properties
  49                           don't set system properties from GCJ_PROPERTIES])
  50
  51 dnl Whether GCJ_PROPERTIES is used depends on the target.
  52 if test -z "$enable_getenv_properties"; then
  53    enable_getenv_properties=${enable_getenv_properties_default-yes}
  54 fi
  55 if test "$enable_getenv_properties" = no; then
  56    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  57 fi
  58
  59 dnl Whether we should use arguments to main()
  60 if test -z "$enable_main_args"; then
  61    enable_main_args=${enable_main_args_default-yes}
  62 fi
  63 if test "$enable_main_args" = no; then
  64    AC_DEFINE(DISABLE_MAIN_ARGS)
  65 fi
  66
  67
  68 dnl Should we use hashtable-based synchronization?
  69 dnl Currently works only for Linux X86/ia64
  70 dnl Typically faster and more space-efficient
  71 AC_ARG_ENABLE(hash-synchronization,
  72 [  --enable-hash-synchronization
  73                           Use global hash table for monitor locks])
  74
  75 if test -z "$enable_hash_synchronization"; then
  76    enable_hash_synchronization=$enable_hash_synchronization_default
  77 fi
  78
  79 dnl configure.host sets slow_pthread_self if the synchronization code should
  80 dnl try to avoid pthread_self calls by caching thread IDs in a hashtable.
  81 if test "${slow_pthread_self}" = "yes"; then
  82   AC_DEFINE(SLOW_PTHREAD_SELF)
  83 fi
  84
  85
  86 dnl See if the user has requested runtime debugging.
  87 LIBGCJDEBUG="false"
  88 AC_SUBST(LIBGCJDEBUG)
  89 AC_ARG_ENABLE(libgcj-debug,
  90 [  --enable-libgcj-debug   enable runtime debugging code],
  91   if test "$enable_libgcj_debug" = yes; then
  92     AC_DEFINE(DEBUG)
  93     LIBGCJDEBUG="true"
  94   fi)
  95
  96 dnl See if the user has the interpreter included.
  97 AC_ARG_ENABLE(interpreter,
  98 [  --enable-interpreter    enable interpreter],
  99   if test "$enable_interpreter" = yes; then
 100     # This can also be set in configure.host.
 101     libgcj_interpreter=yes
 102   elif test "$enable_interpreter" = no; then
 103     libgcj_interpreter=no
 104   fi)
 105
 106 if test "$libgcj_interpreter" = yes; then
 107    AC_DEFINE(INTERPRETER)
 108 fi
 109
 110 AC_MSG_CHECKING([for exception model to use])
 111 AC_LANG_SAVE
 112 AC_LANG_CPLUSPLUS
 113 AC_ARG_ENABLE(sjlj-exceptions,
 114 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
 115 [:],
 116 [dnl Botheration.  Now we've got to detect the exception model.
 117 dnl Link tests against libgcc.a are problematic since -- at least
 118 dnl as of this writing -- we've not been given proper -L bits for
 119 dnl single-tree newlib and libgloss.
 120 dnl
 121 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 122 dnl conftest files before we got a change to grep them first.
 123 cat > conftest.$ac_ext << EOF
 124 [#]line __oline__ "configure"
 125 struct S { ~S(); };
 126 void bar();
 127 void foo()
 128 {
 129   S s;
 130   bar();
 131 }
 132 EOF
 133 old_CXXFLAGS="$CXXFLAGS"
 134 CXXFLAGS=-S
 135 if AC_TRY_EVAL(ac_compile); then
 136   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 137     enable_sjlj_exceptions=yes
 138   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 139     enable_sjlj_exceptions=no
 140   fi
 141 fi
 142 CXXFLAGS="$old_CXXFLAGS"
 143 rm -f conftest*])
 144 if test x$enable_sjlj_exceptions = xyes; then
 145   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 146         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 147   ac_exception_model_name=sjlj
 148 elif test x$enable_sjlj_exceptions = xno; then
 149   ac_exception_model_name="call frame"
 150 else
 151   AC_MSG_ERROR([unable to detect exception model])
 152 fi
 153 AC_LANG_RESTORE
 154 AC_MSG_RESULT($ac_exception_model_name)
 155
 156 dnl See if the user wants to disable java.net.  This is the mildly
 157 dnl ugly way that we admit that target-side configuration sucks.
 158 AC_ARG_ENABLE(java-net,
 159 [  --disable-java-net      disable java.net])
 160
 161 dnl Whether java.net is built by default can depend on the target.
 162 if test -z "$enable_java_net"; then
 163    enable_java_net=${enable_java_net_default-yes}
 164 fi
 165 if test "$enable_java_net" = no; then
 166    AC_DEFINE(DISABLE_JAVA_NET)
 167 fi
 168
 169 dnl See if the user wants to configure without libffi.  Some
 170 dnl architectures don't support it, and default values are set in
 171 dnl configure.host.
 172 AC_ARG_WITH(libffi,
 173 [  --without-libffi        don't use libffi],,with_libffi=${with_libffi_default-yes})
 174
 175 LIBFFI=
 176 LIBFFIINCS=
 177 if test "$with_libffi" != no; then
 178    AC_DEFINE(USE_LIBFFI)
 179    LIBFFI=../libffi/libffi_convenience.la
 180    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I$(MULTIBUILDTOP)../libffi/include'
 181 fi
 182 AC_SUBST(LIBFFI)
 183 AC_SUBST(LIBFFIINCS)
 184
 185 dnl See if the user wants to disable JVMPI support.
 186 AC_ARG_ENABLE(jvmpi,
 187 [  --disable-jvmpi         disable JVMPI support])
 188
 189 if test "$enable_jvmpi" != no; then
 190     AC_DEFINE(ENABLE_JVMPI)
 191 fi
 192
 193 dnl If the target is an eCos system, use the appropriate eCos
 194 dnl I/O routines.
 195 dnl FIXME: this should not be a local option but a global target
 196 dnl system; at present there is no eCos target.
 197 TARGET_ECOS=${PROCESS-"no"}
 198 AC_ARG_WITH(ecos,
 199 [  --with-ecos             enable runtime eCos target support],
 200 TARGET_ECOS="$with_ecos"
 201 )
 202
 203 PLATFORMOBJS=
 204 case "$TARGET_ECOS" in
 205    no) case "$host" in
 206       *mingw*)
 207             PLATFORM=Win32
 208             PLATFORMOBJS=win32.lo
 209             PLATFORMH=win32.h
 210       ;;
 211       *)
 212             PLATFORM=Posix
 213             PLATFORMOBJS=posix.lo
 214             PLATFORMH=posix.h
 215       ;;
 216       esac
 217       ;;
 218    *)
 219       PLATFORM=Ecos
 220       AC_DEFINE(ECOS)
 221       PLATFORMOBJS=posix.lo
 222       PLATFORMH=posix.h
 223       ;;
 224 esac
 225 AC_SUBST(PLATFORMOBJS)
 226 AC_LINK_FILES(include/$PLATFORMH, include/platform.h)
 227
 228 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 229 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 230 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 231 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 232
 233
 234 dnl These may not be defined in a non-ANS conformant embedded system.
 235 dnl FIXME: Should these case a runtime exception in that case?
 236 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 237 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 238
 239 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 240 dnl to create the link will fail.
 241 test -d java || mkdir java
 242 test -d java/io || mkdir java/io
 243 test -d gnu || mkdir gnu
 244 AC_LINK_FILES(java/io/natFile${FILE-${PLATFORM}}.cc, java/io/natFile.cc)
 245 AC_LINK_FILES(java/io/natFileDescriptor${FILE-${PLATFORM}}.cc, java/io/natFileDescriptor.cc)
 246
 247 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 248 test -d java/lang || mkdir java/lang
 249 AC_LINK_FILES(java/lang/${PLATFORM}Process.java, java/lang/ConcreteProcess.java)
 250 AC_LINK_FILES(java/lang/nat${PLATFORM}Process.cc, java/lang/natConcreteProcess.cc)
 251
 252 case "${host}" in
 253     *mingw*)
 254       SYSTEMSPEC="-lgdi32 -lwsock32 -lws2_32"
 255     ;;
 256     *)
 257       SYSTEMSPEC=
 258     ;;
 259 esac
 260 AC_SUBST(SYSTEMSPEC)
 261
 262 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 263 AC_SUBST(LIBGCJTESTSPEC)
 264
 265 AC_ARG_WITH(system-zlib,
 266 [  --with-system-zlib      use installed libz])
 267 ZLIBSPEC=
 268 AC_SUBST(ZLIBSPEC)
 269 ZLIBTESTSPEC=
 270 AC_SUBST(ZLIBTESTSPEC)
 271
 272 dnl FIXME: this should be _libs on some hosts.
 273 libsubdir=.libs
 274
 275 dnl Allow the GC to be disabled.  Can be useful when debugging.
 276 AC_MSG_CHECKING([for garbage collector to use])
 277 AC_ARG_ENABLE(java-gc,
 278 changequote(<<,>>)dnl
 279 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 280 changequote([,])
 281   GC=$enableval,
 282   GC=boehm)
 283 GCLIBS=
 284 GCINCS=
 285 GCDEPS=
 286 GCOBJS=
 287 GCSPEC=
 288 JC1GCSPEC=
 289 GCTESTSPEC=
 290 case "$GC" in
 291  boehm)
 292     AC_MSG_RESULT(boehm)
 293     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 294     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 295     JC1GCSPEC='-fuse-boehm-gc'
 296     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 297
 298     dnl We also want to pick up some cpp flags required when including
 299     dnl boehm-config.h.  Yuck.
 300     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 301     GCOBJS=boehm.lo
 302     GCHDR=boehm-gc.h
 303     dnl The POSIX thread support needs to know this.
 304     AC_DEFINE(HAVE_BOEHM_GC)
 305     ;;
 306  no)
 307     AC_MSG_RESULT(none)
 308     GCOBJS=nogc.lo
 309     GCHDR=no-gc.h
 310     ;;
 311  *)
 312     AC_MSG_ERROR(unrecognized collector \"$GC\")
 313     ;;
 314 esac
 315 AC_SUBST(GCLIBS)
 316 AC_SUBST(GCINCS)
 317 AC_SUBST(GCDEPS)
 318 AC_SUBST(GCOBJS)
 319 AC_SUBST(GCSPEC)
 320 AC_SUBST(JC1GCSPEC)
 321 AC_SUBST(GCTESTSPEC)
 322 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 323
 324
 325 AC_MSG_CHECKING([for thread model used by GCC])
 326 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 327 AC_MSG_RESULT([$THREADS])
 328
 329 case "$THREADS" in
 330  no | none | single)
 331     THREADS=none
 332     ;;
 333  posix | pthreads)
 334     THREADS=posix
 335     case "$host" in
 336      *-*-linux*)
 337         AC_DEFINE(LINUX_THREADS)
 338         ;;
 339     esac
 340     ;;
 341  win32)
 342     ;;
 343  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 344     AC_MSG_ERROR(thread package $THREADS not yet supported)
 345     ;;
 346  *)
 347     AC_MSG_ERROR($THREADS is an unknown thread package)
 348     ;;
 349 esac
 350
 351 THREADLIBS=
 352 THREADINCS=
 353 THREADDEPS=
 354 THREADOBJS=
 355 THREADH=
 356 THREADSPEC=
 357 case "$THREADS" in
 358  posix)
 359     case "$host" in
 360      *-*-cygwin*)
 361         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 362         ;;
 363 changequote(<<,>>)
 364      *-*-freebsd[1234]*)
 365 changequote([,])
 366         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 367         # merely adds pthread_* functions) but it does have a -pthread switch
 368         # which is required at link-time to select -lc_r *instead* of -lc.
 369         THREADLIBS=-pthread
 370         # Don't set THREADSPEC here as might be expected since -pthread is
 371         # not processed when found within a spec file, it must come from
 372         # the command line.  For now, the user must provide the -pthread
 373         # switch to link code compiled with gcj.  In future, consider adding
 374         # support for weak references to pthread_* functions ala gthr.h API.
 375         THREADSPEC='%{!pthread: %eUnder this configuration, the user must provide -pthread when linking.}'
 376         ;;
 377      *-*-freebsd*)
 378         # FreeBSD 5 implements a model much closer to other modern UNIX
 379         # which support threads.  However, it still does not support
 380         # -lpthread.
 381         THREADLIBS=-pthread
 382         THREADSPEC=-lc_r
 383         ;;
 384      *)
 385         THREADLIBS=-lpthread
 386         THREADSPEC=-lpthread
 387         ;;
 388     esac
 389     THREADOBJS=posix-threads.lo
 390     THREADH=posix-threads.h
 391     # MIT pthreads doesn't seem to have the mutexattr functions.
 392     # But for now we don't check for it.  We just assume you aren't
 393     # using MIT pthreads.
 394     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 395
 396     # If we're using the Boehm GC, then we happen to know that it
 397     # defines _REENTRANT, so we don't bother.  Eww.
 398     if test "$GC" != boehm; then
 399        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 400     fi
 401     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 402     ;;
 403
 404  win32)
 405     THREADOBJS=win32-threads.lo
 406     THREADH=win32-threads.h
 407     ;;
 408
 409  none)
 410     THREADOBJS=no-threads.lo
 411     THREADH=no-threads.h
 412     ;;
 413 esac
 414 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 415 AC_SUBST(THREADLIBS)
 416 AC_SUBST(THREADINCS)
 417 AC_SUBST(THREADDEPS)
 418 AC_SUBST(THREADOBJS)
 419 AC_SUBST(THREADSPEC)
 420
 421 AC_LINK_FILES(sysdep/$sysdeps_dir, sysdep)
 422
 423 HASH_SYNC_SPEC=
 424 # Hash synchronization is only useful with posix threads right now.
 425 if test "$enable_hash_synchronization" = yes && test "$THREADS" = "posix"; then
 426    HASH_SYNC_SPEC=-fhash-synchronization
 427    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 428 fi
 429 AC_SUBST(HASH_SYNC_SPEC)
 430
 431
 432 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 433
 434 CANADIAN=no
 435 NULL_TARGET=no
 436 NATIVE=yes
 437
 438 # We're in the tree with gcc, and need to include some of its headers.
 439 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 440
 441 # Figure out where generated headers like libgcj-config.h get installed.
 442 changequote(,)dnl
 443 gcc_version_trigger=${srcdir}/../gcc/version.c
 444 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 445 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 446 tool_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include
 447 changequote([,])dnl
 448 AC_SUBST(tool_include_dir)
 449
 450 if test -n "${with_cross_host}"; then
 451    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 452    # may not work correctly, because the compiler may not be able to
 453    # link executables.
 454
 455    # We assume newlib.  This lets us hard-code the functions we know
 456    # we'll have.
 457    AC_DEFINE(HAVE_MEMMOVE)
 458    AC_DEFINE(HAVE_MEMCPY)
 459    AC_DEFINE(HAVE_STRERROR)
 460    AC_DEFINE(HAVE_TIME)
 461    AC_DEFINE(HAVE_GMTIME_R)
 462    AC_DEFINE(HAVE_LOCALTIME_R)
 463    dnl This is only for POSIX threads.
 464    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 465    dnl We also assume we are using gcc, which provides alloca.
 466    AC_DEFINE(HAVE_ALLOCA)
 467
 468    dnl Assume we do not have getuid and friends.
 469    AC_DEFINE(NO_GETUID)
 470
 471    # If Canadian cross, then don't pick up tools from the build
 472    # directory.
 473    if test x"$build" != x"$with_cross_host" && x"$build" != x"$target"; then
 474       CANADIAN=yes
 475       GCC_UNWIND_INCLUDE=
 476       GCJ="${target_alias}-gcj"
 477    fi
 478    NATIVE=no
 479 else
 480    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 481    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 482    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 483    AC_CHECK_FUNCS(nl_langinfo setlocale)
 484    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 485    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 486    AC_CHECK_FUNCS(backtrace fork execvp pipe sigaction)
 487    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 488    AC_CHECK_LIB(dl, dladdr, [
 489      AC_DEFINE(HAVE_DLADDR)])
 490    AC_CHECK_FILES(/proc/self/exe, [
 491      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 492
 493    AM_ICONV
 494    AM_LC_MESSAGES
 495    AC_STRUCT_TIMEZONE
 496
 497    AC_CHECK_FUNCS(gethostbyname_r, [
 498      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 499      # There are two different kinds of gethostbyname_r.
 500      # We look for the one that returns `int'.
 501      # Hopefully this check is robust enough.
 502      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 503        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 504
 505      case " $GCINCS " in
 506      *" -D_REENTRANT "*) ;;
 507      *)
 508         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 509         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 510         [libjava_cv_gethostbyname_r_needs_reentrant],
 511         [ AC_LANG_SAVE
 512           AC_LANG_CPLUSPLUS
 513           AC_TRY_COMPILE([#include <netdb.h>],
 514             [gethostbyname_r("", 0, 0);],
 515             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 516                 CPPFLAGS_SAVE="$CPPFLAGS"
 517                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 518                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 519                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 520                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 521                 CPPFLAGS="$CPPFLAGS_SAVE"
 522           ])
 523           AC_LANG_RESTORE
 524         ])
 525         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 526           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 527         fi
 528      ;;
 529      esac
 530
 531      AC_CACHE_CHECK([for struct hostent_data],
 532         [libjava_cv_struct_hostent_data], [dnl
 533         AC_TRY_COMPILE([
 534 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 535 # define _REENTRANT 1
 536 #endif
 537 #include <netdb.h>], [struct hostent_data data;],
 538           [libjava_cv_struct_hostent_data=yes],
 539           [libjava_cv_struct_hostent_data=no])])
 540      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 541        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 542          [Define if struct hostent_data is defined in netdb.h])
 543      fi
 544    ])
 545
 546    # FIXME: libjava source code expects to find a prototype for
 547    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 548    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 549    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 550    # linkage check is enough, yet C++ code requires proper prototypes.)
 551    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 552    AC_CHECK_FUNCS(gethostbyaddr_r, [
 553      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 554      # There are two different kinds of gethostbyaddr_r.
 555      # We look for the one that returns `int'.
 556      # Hopefully this check is robust enough.
 557      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 558        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])])
 559
 560    AC_CHECK_FUNCS(gethostname, [
 561      AC_DEFINE(HAVE_GETHOSTNAME)
 562      AC_EGREP_HEADER(gethostname, unistd.h, [
 563        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 564
 565    # Look for these functions in the thread library, but only bother
 566    # if using POSIX threads.
 567    if test "$THREADS" = posix; then
 568       save_LIBS="$LIBS"
 569       LIBS="$LIBS $THREADLIBS"
 570       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 571       # E.g., Solaris.
 572       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 573
 574       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 575       # Solaris 7 the name librt is preferred.
 576       AC_CHECK_FUNCS(sched_yield, , [
 577         AC_CHECK_LIB(rt, sched_yield, [
 578           AC_DEFINE(HAVE_SCHED_YIELD)
 579           THREADLIBS="$THREADLIBS -lrt"
 580           THREADSPEC="$THREADSPEC -lrt"], [
 581           AC_CHECK_LIB(posix4, sched_yield, [
 582             AC_DEFINE(HAVE_SCHED_YIELD)
 583             THREADLIBS="$THREADLIBS -lposix4"
 584             THREADSPEC="$THREADSPEC -lposix4"])])])
 585       LIBS="$save_LIBS"
 586
 587       # We can save a little space at runtime if the mutex has m_count
 588       # or __m_count.  This is a nice hack for Linux.
 589       AC_TRY_COMPILE([#include <pthread.h>], [
 590           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 591         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 592         AC_TRY_COMPILE([#include <pthread.h>], [
 593             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 594           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 595    fi
 596
 597    # We require a way to get the time.
 598    time_found=no
 599    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 600    if test "$time_found" = no; then
 601       AC_MSG_ERROR([no function found to get the time])
 602    fi
 603
 604    AC_CHECK_FUNCS(memmove)
 605
 606    # We require memcpy.
 607    memcpy_found=no
 608    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 609    if test "$memcpy_found" = no; then
 610       AC_MSG_ERROR([memcpy is required])
 611    fi
 612
 613    AC_CHECK_LIB(dl, dlopen, [
 614        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 615
 616    # Some library-finding code we stole from Tcl.
 617    #--------------------------------------------------------------------
 618    #    Check for the existence of the -lsocket and -lnsl libraries.
 619    #    The order here is important, so that they end up in the right
 620    #    order in the command line generated by make.  Here are some
 621    #    special considerations:
 622    #    1. Use "connect" and "accept" to check for -lsocket, and
 623    #       "gethostbyname" to check for -lnsl.
 624    #    2. Use each function name only once:  can't redo a check because
 625    #       autoconf caches the results of the last check and won't redo it.
 626    #    3. Use -lnsl and -lsocket only if they supply procedures that
 627    #       aren't already present in the normal libraries.  This is because
 628    #       IRIX 5.2 has libraries, but they aren't needed and they're
 629    #       bogus:  they goof up name resolution if used.
 630    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 631    #       To get around this problem, check for both libraries together
 632    #       if -lsocket doesn't work by itself.
 633    #--------------------------------------------------------------------
 634
 635    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 636     [gcj_cv_lib_sockets=
 637      gcj_checkBoth=0
 638      unset ac_cv_func_connect
 639      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 640      if test "$gcj_checkSocket" = 1; then
 641          unset ac_cv_func_connect
 642          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 643                       gcj_checkBoth=1)
 644      fi
 645      if test "$gcj_checkBoth" = 1; then
 646          gcj_oldLibs=$LIBS
 647          LIBS="$LIBS -lsocket -lnsl"
 648          unset ac_cv_func_accept
 649          AC_CHECK_FUNC(accept,
 650                        [gcj_checkNsl=0
 651                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 652          unset ac_cv_func_accept
 653          LIBS=$gcj_oldLibs
 654      fi
 655      unset ac_cv_func_gethostbyname
 656      gcj_oldLibs=$LIBS
 657      LIBS="$LIBS $gcj_cv_lib_sockets"
 658      AC_CHECK_FUNC(gethostbyname, ,
 659                    [AC_CHECK_LIB(nsl, main,
 660                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 661      unset ac_cv_func_gethostbyname
 662      LIBS=$gcj_oldLIBS
 663    ])
 664    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 665
 666    if test "$with_system_zlib" = yes; then
 667       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 668    fi
 669
 670    # On Solaris, and maybe other architectures, the Boehm collector
 671    # requires -ldl.
 672    if test "$GC" = boehm; then
 673       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 674    fi
 675
 676    if test -z "${with_multisubdir}"; then
 677       builddotdot=.
 678    else
 679 changequote(<<,>>)
 680       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 681 changequote([,])
 682    fi
 683    if test -x "${builddotdot}/../../gcc/gcj"; then
 684       dir="`cd ${builddotdot}/../../gcc && pwd`"
 685       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 686    else
 687       CANADIAN=yes
 688       NULL_TARGET=yes
 689       GCJ="gcj -B`pwd`/"
 690    fi
 691 fi
 692
 693 # Create it, so that compile/link tests don't fail
 694 test -f libgcj.spec || touch libgcj.spec
 695
 696 # We must search the source tree for java.lang, since we still don't
 697 # have libgcj.jar nor java/lang/*.class
 698 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 699 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 700
 701 # Since some classes depend on this one, we need its source available
 702 # before we can do any GCJ compilation test :-(
 703 if test ! -f gnu/classpath/Configuration.java; then
 704   test -d gnu || mkdir gnu
 705   test -d gnu/classpath || mkdir gnu/classpath
 706   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 707         < $srcdir/gnu/classpath/Configuration.java.in \
 708         > gnu/classpath/Configuration.java
 709   # We do not want to redirect the output of the grep below to /dev/null,
 710   # but we add /dev/null to the input list so that grep will print the
 711   # filename of Configuration.java in case it finds any matches.
 712   if grep @ gnu/classpath/Configuration.java /dev/null; then
 713     AC_MSG_ERROR([configure.in is missing the substitutions above])
 714   fi
 715 fi
 716
 717 LT_AC_PROG_GCJ
 718
 719 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 720
 721 AC_COMPILE_CHECK_SIZEOF(void *)
 722
 723 ZLIBS=
 724 SYS_ZLIBS=
 725 ZINCS=
 726
 727 if test -z "$ZLIBSPEC"; then
 728    # Use zlib from the GCC tree.
 729    ZINCS='-I$(top_srcdir)/../zlib'
 730    ZLIBS=../zlib/libzgcj_convenience.la
 731 else
 732    # System's zlib.
 733    SYS_ZLIBS="$ZLIBSPEC"
 734 fi
 735 AC_SUBST(ZLIBS)
 736 AC_SUBST(SYS_ZLIBS)
 737 AC_SUBST(ZINCS)
 738 AC_SUBST(DIVIDESPEC)
 739 AC_SUBST(EXCEPTIONSPEC)
 740
 741 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 742 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 743 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 744 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 745 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 746 AC_SUBST(GCC_UNWIND_INCLUDE)
 747
 748 AC_SUBST(AM_RUNTESTFLAGS)
 749
 750 # Determine gcj version number.
 751 changequote(<<,>>)
 752 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`
 753 changequote([,])
 754 GCJVERSION=$gcjversion
 755 AC_SUBST(GCJVERSION)
 756 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
 757
 758 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 759 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 760 save_CFLAGS="$CFLAGS"
 761 CFLAGS="-x c++ -O2 -ffloat-store"
 762 AC_TRY_COMPILE([#include <math.h>], ,
 763   [AC_MSG_RESULT(no)],
 764   [AC_DEFINE(__NO_MATH_INLINES)
 765    AC_MSG_RESULT(yes)])
 766 CFLAGS="$save_CFLAGS"
 767
 768 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 769 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 770 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 771 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
 772 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 773 dnl for now.  If you change this, you also must update natFile.cc.
 774 AC_CHECK_HEADERS(dirent.h)
 775 AC_CHECK_HEADERS(inttypes.h, [
 776     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
 777     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
 778 ])
 779 AC_HEADER_SYS_WAIT
 780
 781 AC_CHECK_TYPE([ssize_t], [int])
 782
 783 AC_MSG_CHECKING([for in_addr_t])
 784 AC_TRY_COMPILE([#include <sys/types.h>
 785 #if STDC_HEADERS
 786 #include <stdlib.h>
 787 #include <stddef.h>
 788 #endif
 789 #if HAVE_NETINET_IN_H
 790 #include <netinet/in.h>
 791 #endif], [in_addr_t foo;],
 792   [AC_DEFINE([HAVE_IN_ADDR_T])
 793    AC_MSG_RESULT(yes)],
 794   [AC_MSG_RESULT(no)])
 795
 796 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 797 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 798   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 799    AC_MSG_RESULT(yes)],
 800   [AC_MSG_RESULT(no)])
 801
 802 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
 803 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ipv6_mreq mreq6;],
 804   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ)
 805    AC_MSG_RESULT(yes)],
 806   [AC_MSG_RESULT(no)])
 807
 808 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 809 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 810   [AC_DEFINE(HAVE_INET6)
 811    AC_MSG_RESULT(yes)],
 812   [AC_MSG_RESULT(no)])
 813
 814 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 815 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
 816 #include <sys/types.h>
 817 #include <sys/socket.h>], [socklen_t x = 5;],
 818   [AC_DEFINE(HAVE_SOCKLEN_T)
 819    AC_MSG_RESULT(yes)],
 820   [AC_MSG_RESULT(no)])
 821
 822 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 823 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 824   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 825    AC_MSG_RESULT(yes)],
 826   [AC_MSG_RESULT(no)
 827    AC_MSG_CHECKING([for global timezone variable])
 828    dnl FIXME: we don't want a link check here because that won't work
 829    dnl when cross-compiling.  So instead we make an assumption that
 830    dnl the header file will mention timezone if it exists.
 831    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 832      [AC_DEFINE(HAVE_TIMEZONE)
 833       AC_MSG_RESULT(yes)],
 834      [AC_MSG_RESULT(no)])])
 835
 836 AC_FUNC_ALLOCA
 837
 838 AC_CHECK_PROGS(PERL, perl, false)
 839
 840 SYSDEP_SOURCES=
 841
 842 case "${host}" in
 843  i?86-*-linux*)
 844     SIGNAL_HANDLER=include/i386-signal.h
 845     ;;
 846  sparc-sun-solaris*)
 847     SIGNAL_HANDLER=include/sparc-signal.h
 848     ;;
 849 # ia64-*)
 850 #    SYSDEP_SOURCES=sysdep/ia64.c
 851 #    test -d sysdep || mkdir sysdep
 852 #    ;;
 853  powerpc-*-linux*)
 854     SIGNAL_HANDLER=include/dwarf2-signal.h
 855     ;;
 856  alpha*-*-linux*)
 857     SIGNAL_HANDLER=include/dwarf2-signal.h
 858     ;;
 859  *mingw*)
 860     SIGNAL_HANDLER=include/win32-signal.h
 861     ;;
 862  *)
 863     SIGNAL_HANDLER=include/default-signal.h
 864     ;;
 865 esac
 866
 867 # If we're using sjlj exceptions, forget what we just learned.
 868 if test "$enable_sjlj_exceptions" = yes; then
 869    SIGNAL_HANDLER=include/default-signal.h
 870 fi
 871
 872 AC_SUBST(SYSDEP_SOURCES)
 873
 874 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 875
 876 if test "${multilib}" = "yes"; then
 877   multilib_arg="--enable-multilib"
 878 else
 879   multilib_arg=
 880 fi
 881
 882 AC_PATH_XTRA
 883
 884 dnl Determine which AWT peer libraries to build
 885 AC_ARG_ENABLE(java-awt,
 886 [  --enable-java-awt       list of AWT peer implementations to be built])
 887
 888 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 889 use_xlib_awt=""
 890 use_gtk_awt=""
 891
 892 for peer in $peerlibs ; do
 893   case $peer in
 894     xlib)
 895       if [test "$no_x" = yes]; then
 896         echo "*** xlib peers requested but no X library available" 1>&2
 897         exit 1
 898       else
 899         use_xlib_awt="yes"
 900       fi
 901       ;;
 902     gtk)
 903       # Nothing, yet...
 904       ;;
 905     no)
 906       use_xlib_awt=
 907       use_gtk_awt=
 908       break
 909       ;;
 910     *)
 911       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 912       exit 1
 913   esac
 914 done
 915
 916 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 917 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 918
 919
 920 here=`pwd`
 921 AC_SUBST(here)
 922
 923 # We get this from the environment.
 924 AC_SUBST(GCJFLAGS)
 925
 926 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 927 [# Only add multilib support code if we just rebuilt top-level Makefile.
 928 case " $CONFIG_FILES " in
 929  *" Makefile "*)
 930    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 931    ;;
 932 esac
 933
 934 # Make subdirectories and `.d' files.  Look in both srcdir and
 935 # builddir for the .java files.
 936 h=`pwd`
 937 : > deps.mk
 938 ( (cd $srcdir && find . \( -name '*.java' -o -name '*.cc' \) -print) ;
 939   find . \( -name '*.java' -o -name '*.cc' \) -print) | \
 940    fgrep -v testsuite | \
 941    sed -e 's/\.java/.d/'\;'s/\.cc/.d/' | \
 942    while read f; do
 943       echo "include $f" >> deps.mk
 944       test -f $f || {
 945 changequote(<<,>>)
 946          d=`echo $f | sed -e 's,/[^/]*$,,'`
 947 changequote([,])
 948          if test ! -d $d; then
 949            $libgcj_basedir/../mkinstalldirs $d
 950          fi;
 951          echo > $f
 952       }
 953    done
 954 ],
 955 srcdir=${srcdir}
 956 host=${host}
 957 target=${target}
 958 with_multisubdir=${with_multisubdir}
 959 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 960 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 961 libgcj_basedir=${libgcj_basedir}
 962 CC="${CC}"
 963 CXX="${CXX}"
 964 )