libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120
 121 # We need a jar that supports -@.  This is a GNU extension.
 122 if test "$JAR" != no; then
 123    rm -f config-test.jar
 124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 125    if test -f config-test.jar; then
 126      rm -f config-test.jar
 127    else
 128      JAR=no
 129    fi
 130 fi
 131
 132 # Prefer the jar we found, but fall back to our jar script.
 133 if test "$JAR" = no; then
 134   if test "$ZIP" = no; then
 135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 136   else
 137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 138     JAR=`pwd`/scripts/jar
 139   fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 AM_MAINTAINER_MODE
 145
 146 AC_EXEEXT
 147
 148 # configure.host sets the following important variables
 149 #       libgcj_cflags    - host specific C compiler flags
 150 #       libgcj_cxxflags  - host specific C++ compiler flags
 151 #       libgcj_javaflags - host specific Java compiler flags
 152
 153 libgcj_cflags=
 154 libgcj_cxxflags=
 155 libgcj_javaflags=
 156
 157 . ${srcdir}/configure.host
 158
 159 ACX_PROG_LD_GNU_SYMBOLIC
 160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 161 if test -z "$libgcj_ld_symbolic"; then
 162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 163 fi
 164
 165 LIBGCJ_CFLAGS="${libgcj_cflags}"
 166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 170 AC_SUBST(LIBGCJ_CFLAGS)
 171 AC_SUBST(LIBGCJ_CXXFLAGS)
 172 AC_SUBST(LIBGCJ_JAVAFLAGS)
 173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 175
 176 # Only use libltdl for non-newlib builds.
 177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 178    AC_LTDL_SHLIBPATH
 179 fi
 180
 181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 182
 183 # See if the user has requested runtime debugging.
 184 LIBGCJDEBUG="disable"
 185 AC_SUBST(LIBGCJDEBUG)
 186 AC_ARG_ENABLE(libgcj-debug,
 187   AS_HELP_STRING([--enable-libgcj-debug],
 188                  [enable runtime debugging code]),
 189   [if test "$enable_libgcj_debug" = yes; then
 190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 191     LIBGCJDEBUG="enable"
 192   fi])
 193
 194 AC_ARG_WITH([escher],
 195          AS_HELP_STRING([--with-escher=ABS.PATH],
 196                         [specify path to escher dir or JAR for X peers]))
 197 case "$with_escher" in
 198 "")
 199         use_escher=false
 200         ;;
 201 "no")
 202         use_escher=false
 203         ;;
 204 "yes")
 205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 206         ;;
 207 *)
 208         use_escher=true
 209         ;;
 210 esac
 211
 212 # Determine which AWT peer libraries to build
 213 AC_ARG_ENABLE(java-awt,
 214   AS_HELP_STRING([--enable-java-awt],
 215                  [list of AWT peer implementations to be built]))
 216
 217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 218 use_xlib_awt=""
 219 use_gtk_awt=""
 220 use_qt_awt=""
 221 use_x_awt=""
 222 # The default toolkit to use is the first one specified.
 223 TOOLKIT=
 224 AC_SUBST(TOOLKIT)
 225
 226 for peer in $peerlibs ; do
 227   case $peer in
 228     xlib)
 229       if test "$no_x" = yes; then
 230         echo "*** xlib peers requested but no X library available" 1>&2
 231         exit 1
 232       else
 233         use_xlib_awt="yes"
 234         if test -z "$TOOLKIT"; then
 235            TOOLKIT=gnu.awt.xlib.XToolkit
 236         fi
 237       fi
 238       ;;
 239     gtk)
 240       if test "$no_x" = yes; then
 241          echo "*** gtk peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_gtk_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 247          fi
 248       fi
 249       ;;
 250     qt)
 251       if test "$no_x" = yes; then
 252          # Perhaps we should admit the possibility of embedded Qt.
 253          echo "*** Qt peers requested but no X library available" 1>&2
 254          exit 1
 255       else
 256          use_qt_awt=yes
 257          if test -z "$TOOLKIT"; then
 258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 259          fi
 260       fi
 261       ;;
 262     x)
 263       use_x_awt=yes
 264       if test -z "$TOOLKIT"; then
 265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 266       fi
 267       ;;
 268     no)
 269       use_xlib_awt=
 270       use_gtk_awt=
 271       use_qt_awt=
 272       use_x_awt=
 273       break
 274       ;;
 275     *)
 276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 277       exit 1
 278   esac
 279 done
 280
 281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 283
 284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 285
 286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 287
 288 # Create standard.omit based on decisions we just made.
 289 cp $srcdir/standard.omit.in standard.omit
 290 if test "$use_xlib_awt" != yes; then
 291    echo gnu/awt/xlib >> standard.omit
 292    echo gnu/gcj/xlib >> standard.omit
 293 fi
 294 if test "$use_x_awt" != yes; then
 295    echo gnu/java/awt/peer/x >> standard.omit
 296 fi
 297
 298 # Tools that need to be compiled against classpath's tools classes
 299 : > vm-tools-packages
 300 for package in gnu/gcj/tools/gc_analyze ; do
 301     echo $package >> standard.omit
 302     echo $package >> vm-tools-packages
 303 done
 304
 305 if test -z "${with_multisubdir}"; then
 306    builddotdot=.
 307 else
 308    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 309 fi
 310
 311 NATIVE=yes
 312
 313 # Which gcj and host gcj (for ecjx) do we use?
 314 which_gcj=default
 315 host_exeext=${ac_exeext}
 316 GCJ_FOR_ECJX=
 317 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 318 if test -n "${with_cross_host}"; then
 319   # We are being configured with a cross compiler. We can't
 320   # use ac_exeext, because that is for the target platform.
 321   NATIVE=no
 322   cross_host_exeext=
 323   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 324   case "${with_cross_host}" in
 325      *mingw* | *cygwin*)
 326          cross_host_exeext=.exe
 327      ;;
 328   esac
 329   host_exeext=${cross_host_exeext}
 330   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 331      if test x"$build_noncanonical" = x"$with_cross_host"; then
 332         # Ordinary cross (host!=target and host=build)
 333         which_gcj=built
 334      else
 335         # Canadian cross (host!=target and host!=build)
 336         which_gcj=cross
 337      fi
 338   else
 339      which_gcj=cross
 340   fi
 341 else
 342   # We are being configured with a native or crossed-native compiler
 343   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 344      if test x"$build" = x"$host"; then
 345         # True native build (host=target and host=build)
 346         which_gcj=built
 347      else
 348         # Crossed-native build (host=target and host!=build)
 349         which_gcj=cross
 350      fi
 351   else
 352      which_gcj=path
 353   fi
 354 fi
 355 case "${which_gcj}" in
 356    built)
 357       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 358       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 359    ;;
 360    cross)
 361       if test "x${with_newlib}" = "xyes"; then
 362          # FIXME (comment): Why is this needed?
 363          GCC_UNWIND_INCLUDE=
 364          GCJ="${target_noncanonical}-gcj"
 365       else
 366          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 367       fi
 368       GCJH='$(target_noncanonical)-gcjh'
 369    ;;
 370    path)
 371       GCJ="gcj -B`${PWDCMD-pwd}`/"
 372       GCJH=gcjh
 373    ;;
 374 esac
 375 JAVAC="$GCJ -C"
 376 export JAVAC
 377
 378 AC_SUBST(GCJ_FOR_ECJX)
 379 AC_SUBST(GCJH)
 380 AC_SUBST(host_exeext)
 381
 382 # Create it, so that compile/link tests don't fail
 383 test -f libgcj.spec || touch libgcj.spec
 384
 385
 386
 387 # Set up to configure Classpath.
 388 # FIXME: no supported way to pass args in autoconf.
 389 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 390 # Disable tool wrappers to avoid ltdl.h configure check.
 391 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 392 ac_configure_args="$ac_configure_args --disable-load-library"
 393 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 394 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 395 dir1=`cd $srcdir && pwd`
 396 dir2=`pwd`
 397 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 398 ac_configure_args="$ac_configure_args --disable-core-jni"
 399 dnl FIXME?
 400 ac_configure_args="$ac_configure_args --disable-examples"
 401 ac_configure_args="$ac_configure_args --with-glibj=build"
 402 if test "$plugin_enabled" != yes; then
 403   ac_configure_args="$ac_configure_args --disable-plugin"
 404 fi
 405 if test "$gconf_enabled" != yes; then
 406   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 407   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 408 fi
 409 if test "$use_gtk_awt" != yes; then
 410   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 411 fi
 412 if test "$use_qt_awt" != yes; then
 413   ac_configure_args="$ac_configure_args --disable-qt-peer"
 414 else
 415   # We need this as qt is disabled by default in classpath.
 416   ac_configure_args="$ac_configure_args --enable-qt-peer"
 417 fi
 418 if test "$use_x_awt" != yes; then
 419   ac_configure_args="$ac_configure_args --without-escher"
 420 else
 421   # We need this as escher is disabled by default in classpath.
 422   if test "$use_escher" != true; then
 423     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 424   else
 425     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 426   fi
 427 fi
 428 # -Werror causes unavoidable problems in code using alsa.
 429 ac_configure_args="$ac_configure_args --disable-regen-headers"
 430 ac_configure_args="$ac_configure_args --disable-Werror"
 431 dnl --with-gcj=$GCJ
 432 dnl --with-javah=$GCJH
 433 dnl gjdoc?
 434 dnl gtk-cairo -- just export here...
 435 dnl --enable-regen-headers?
 436
 437 # Only use libltdl for non-newlib builds.
 438 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 439    AC_LIBLTDL_CONVENIENCE
 440    AC_LIBTOOL_DLOPEN
 441    DIRLTDL=libltdl
 442    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 443    # Sigh.  Libtool's macro doesn't do the right thing.
 444    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 445    # FIXME: this is a hack.
 446    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 447    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 448 fi
 449 AC_SUBST(INCLTDL)
 450 AC_SUBST(LIBLTDL)
 451 AC_SUBST(DIRLTDL)
 452 AC_PROG_LIBTOOL
 453 AM_PROG_GCJ
 454 AM_PROG_CC_C_O
 455
 456 AC_CONFIG_SUBDIRS(classpath libltdl)
 457
 458 # The -no-testsuite modules omit the test subdir.
 459 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 460
 461 # Should the runtime set system properties by examining the
 462 # environment variable GCJ_PROPERTIES?
 463 AC_ARG_ENABLE(getenv-properties,
 464   AS_HELP_STRING([--disable-getenv-properties],
 465                  [don't set system properties from GCJ_PROPERTIES]))
 466
 467 # Whether GCJ_PROPERTIES is used depends on the target.
 468 if test -z "$enable_getenv_properties"; then
 469    enable_getenv_properties=${enable_getenv_properties_default-yes}
 470 fi
 471 if test "$enable_getenv_properties" = no; then
 472    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 473      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 474 fi
 475
 476 # Whether we should use arguments to main()
 477 if test -z "$enable_main_args"; then
 478    enable_main_args=${enable_main_args_default-yes}
 479 fi
 480 if test "$enable_main_args" = no; then
 481    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 482 fi
 483
 484
 485 # Should we use hashtable-based synchronization?
 486 # Currently works only for Linux X86/ia64
 487 # Typically faster and more space-efficient
 488 AC_ARG_ENABLE(hash-synchronization,
 489   AS_HELP_STRING([--enable-hash-synchronization],
 490                  [use global hash table for monitor locks]))
 491
 492 if test -z "$enable_hash_synchronization"; then
 493    enable_hash_synchronization=$enable_hash_synchronization_default
 494 fi
 495
 496
 497 install_ecj_jar=no
 498 ECJ_BUILD_JAR=
 499 ECJ_JAR=
 500 AC_ARG_WITH(ecj-jar,
 501         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 502         [ECJ_JAR=$withval],
 503         [if test -f $multi_basedir/ecj.jar; then
 504            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 505            ECJ_JAR='$(jardir)/ecj.jar'
 506            install_ecj_jar=yes
 507          fi])
 508 AC_SUBST(ECJ_BUILD_JAR)
 509 AC_SUBST(ECJ_JAR)
 510 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 511 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 512
 513 AC_ARG_WITH(java-home,
 514   AS_HELP_STRING([--with-java-home=DIRECTORY],
 515                  [value of java.home system property]),
 516                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 517 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 518 AC_SUBST(JAVA_HOME)
 519
 520 suppress_libgcj_bc=no
 521 AC_ARG_ENABLE(libgcj-bc,
 522   AS_HELP_STRING([--enable-libgcj-bc],
 523                  [enable(default) or disable BC ABI for portions of libgcj]),
 524   [if test "$enable_libgcj_bc" = "no"; then
 525      suppress_libgcj_bc=yes
 526    fi])
 527 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 528
 529 build_libgcj_reduced_reflection=no
 530 AC_ARG_ENABLE(reduced-reflection,
 531   AS_HELP_STRING([--enable-reduced-reflection],
 532                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 533   [if test "$enable_reduced_reflection" = "yes"; then
 534      build_libgcj_reduced_reflection=yes
 535    fi])
 536 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 537
 538 # What is the native OS API for MinGW?
 539 AC_ARG_WITH(win32-nlsapi,
 540   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 541                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 542 [case "${withval}" in
 543   ansi) with_win32_nlsapi=ansi ;;
 544   unicows) with_win32_nlsapi=unicows ;;
 545   unicode) with_win32_nlsapi=unicode ;;
 546   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 547 esac],[with_win32_nlsapi=ansi])
 548
 549 case "${with_win32_nlsapi}" in
 550   unicows | unicode)
 551     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 552       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 553     ;;
 554 esac
 555
 556 # configure.host sets slow_pthread_self if the synchronization code should
 557 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 558 if test "${slow_pthread_self}" = "yes"; then
 559   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 560     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 561 fi
 562
 563 # Check for gc debugging.  This option is handled both here and in the GC.
 564 AC_ARG_ENABLE(gc-debug,
 565    AS_HELP_STRING([--enable-gc-debug],
 566                   [include full support for pointer backtracing etc.]),
 567 [ if test "$enable_gc_debug" = "yes"; then
 568     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 569               [Define if we want to use debug calls into the garbage collector.])
 570   fi])
 571
 572 # See if the user has the interpreter included.
 573 AC_ARG_ENABLE(interpreter,
 574   AS_HELP_STRING([--enable-interpreter],
 575                  [enable interpreter]),
 576   [if test "$enable_interpreter" = yes; then
 577     # This can also be set in configure.host.
 578     libgcj_interpreter=yes
 579   elif test "$enable_interpreter" = no; then
 580     libgcj_interpreter=no
 581   fi])
 582
 583 if test "$libgcj_interpreter" = yes; then
 584    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 585 fi
 586 INTERPRETER="$libgcj_interpreter"
 587 AC_SUBST(INTERPRETER)
 588 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 589
 590 AC_MSG_CHECKING([for exception model to use])
 591 AC_LANG_PUSH(C++)
 592 AC_ARG_ENABLE(sjlj-exceptions,
 593   AS_HELP_STRING([--enable-sjlj-exceptions],
 594                  [force use of builtin_setjmp for exceptions]),
 595 [:],
 596 [dnl Botheration.  Now we've got to detect the exception model.
 597 dnl Link tests against libgcc.a are problematic since -- at least
 598 dnl as of this writing -- we've not been given proper -L bits for
 599 dnl single-tree newlib and libgloss.
 600 dnl
 601 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 602 dnl conftest files before we got a change to grep them first.
 603 cat > conftest.$ac_ext << EOF
 604 [#]line __oline__ "configure"
 605 struct S { ~S(); };
 606 void bar();
 607 void foo()
 608 {
 609   S s;
 610   bar();
 611 }
 612 EOF
 613 old_CXXFLAGS="$CXXFLAGS"
 614 CXXFLAGS=-S
 615 if AC_TRY_EVAL(ac_compile); then
 616   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 617     enable_sjlj_exceptions=yes
 618   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 619     enable_sjlj_exceptions=no
 620   fi
 621 fi
 622 CXXFLAGS="$old_CXXFLAGS"
 623 rm -f conftest*])
 624 if test x$enable_sjlj_exceptions = xyes; then
 625   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 626         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 627   ac_exception_model_name=sjlj
 628 elif test x$enable_sjlj_exceptions = xno; then
 629   ac_exception_model_name="call frame"
 630 else
 631   AC_MSG_ERROR([unable to detect exception model])
 632 fi
 633 AC_LANG_POP(C++)
 634 AC_MSG_RESULT($ac_exception_model_name)
 635
 636 # If we are non using SJLJ exceptions, and this host does not have support
 637 # for unwinding from a signal handler, enable checked dereferences and divides.
 638 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 639   CHECKREFSPEC=-fcheck-references
 640   DIVIDESPEC=-fuse-divide-subroutine
 641   EXCEPTIONSPEC=
 642 fi
 643
 644 # See if the user wants to disable java.net.  This is the mildly
 645 # ugly way that we admit that target-side configuration sucks.
 646 AC_ARG_ENABLE(java-net,
 647   AS_HELP_STRING([--disable-java-net],
 648                  [disable java.net]))
 649
 650 # Whether java.net is built by default can depend on the target.
 651 if test -z "$enable_java_net"; then
 652    enable_java_net=${enable_java_net_default-yes}
 653 fi
 654 if test "$enable_java_net" = no; then
 655    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 656 fi
 657
 658 # See if the user wants to configure without libffi.  Some
 659 # architectures don't support it, and default values are set in
 660 # configure.host.
 661 AC_ARG_WITH(libffi,
 662   AS_HELP_STRING([--without-libffi],
 663                  [don't use libffi]),
 664   [:],
 665   [with_libffi=${with_libffi_default-yes}])
 666
 667 LIBFFI=
 668 LIBFFIINCS=
 669 if test "$with_libffi" != no; then
 670    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 671    LIBFFI=../libffi/libffi_convenience.la
 672    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 673 fi
 674 AC_SUBST(LIBFFI)
 675 AC_SUBST(LIBFFIINCS)
 676
 677 # See if the user wants to disable JVMPI support.
 678 AC_ARG_ENABLE(jvmpi,
 679   AS_HELP_STRING([--disable-jvmpi],
 680                  [disable JVMPI support]))
 681
 682 if test "$enable_jvmpi" != no; then
 683     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 684 fi
 685
 686 # If the target is an eCos system, use the appropriate eCos
 687 # I/O routines.
 688 # FIXME: this should not be a local option but a global target
 689 # system; at present there is no eCos target.
 690 TARGET_ECOS=${PROCESS-"no"}
 691 AC_ARG_WITH(ecos,
 692 [  --with-ecos             enable runtime eCos target support],
 693 TARGET_ECOS="$with_ecos"
 694 )
 695
 696 case "$TARGET_ECOS" in
 697    no) case "$host" in
 698       *mingw*)
 699             PLATFORM=Win32
 700             PLATFORMNET=Win32
 701             PLATFORMH=win32.h
 702         CHECK_FOR_BROKEN_MINGW_LD
 703       ;;
 704       *)
 705             PLATFORM=Posix
 706             PLATFORMNET=Posix
 707             PLATFORMH=posix.h
 708       ;;
 709       esac
 710       ;;
 711    *)
 712       PLATFORM=Ecos
 713       PLATFORMNET=NoNet
 714       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 715       PLATFORMH=posix.h
 716       ;;
 717 esac
 718 AC_SUBST(PLATFORM)
 719 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 720
 721 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 722                                       [Define if you have int32_t and uint32_t.]))
 723 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 724                                         [Define if you have int32_t and uint32_t.]))
 725 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 726                                           [Define if you have u_int32_t]))
 727 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 728                                            [Define if you have u_int32_t]))
 729
 730 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 731 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 732
 733 case "$host" in
 734   *-darwin*) DARWIN_CRT=true ;;
 735   *) DARWIN_CRT=false ;;
 736 esac
 737 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 738
 739 # This may not be defined in a non-ANS conformant embedded system.
 740 # FIXME: Should these case a runtime exception in that case?
 741 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 742                                   [Define is you have 'localtime' in <time.h>]))
 743
 744 # Create the subdirectory for natFile.cc, or the attempt
 745 # to create the link will fail.
 746 test -d java || mkdir java
 747 test -d java/io || mkdir java/io
 748 test -d gnu || mkdir gnu
 749 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 750
 751 # Likewise for natConcreteProcess.cc.
 752 test -d java/lang || mkdir java/lang
 753 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 754
 755 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 756 test -d java/net || mkdir java/net
 757 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 758 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 759
 760 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 761 test -d gnu/java || mkdir gnu/java
 762 test -d gnu/java/net || mkdir gnu/java/net
 763 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 764 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 765
 766 # Likewise for natVMPipe.cc and natVMSelector.cc.
 767 test -d gnu/java/nio || mkdir gnu/java/nio
 768 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 769 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 770
 771 # Likewise for natFileChannelImpl.cc
 772 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 773 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 774
 775 case "${host}" in
 776     *mingw*)
 777       SYSTEMSPEC="-lgdi32 -lws2_32"
 778       if test "${with_win32_nlsapi}" = "unicows"; then
 779         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 780       fi
 781     ;;
 782     *)
 783       SYSTEMSPEC=
 784     ;;
 785 esac
 786 AC_SUBST(SYSTEMSPEC)
 787
 788 AC_ARG_WITH(system-zlib,
 789   AS_HELP_STRING([--with-system-zlib],
 790                  [use installed libz]))
 791 ZLIBSPEC=
 792 AC_SUBST(ZLIBSPEC)
 793 ZLIBTESTSPEC=
 794 AC_SUBST(ZLIBTESTSPEC)
 795
 796 AC_PATH_XTRA
 797
 798 # FIXME: this should be _libs on some hosts.
 799 libsubdir=.libs
 800
 801 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 802
 803 LIBSTDCXXSPEC=
 804 # extra LD Flags which are required for targets
 805 case "${host}" in
 806 *-*-darwin[[0-7]].*)
 807     # For now we have to disable it on darwin[8-9] because it slows down
 808     # the linking phase. A possible bug in ld?
 809     # on Darwin -single_module speeds up loading of the dynamic libraries.
 810     extra_ldflags_libjava=-Wl,-single_module
 811     ;;
 812 *-*-darwin[[9]]*)
 813     extra_gij_ldflags=-Wl,-allow_stack_execute
 814     ;;
 815 arm*linux*eabi)
 816     # Some of the ARM unwinder code is actually in libstdc++.  We
 817     # could in principle replicate it in libgcj, but it's better to
 818     # have a dependency on libstdc++.
 819     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 820     LIBSTDCXXSPEC=-lstdc++
 821     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 822     ;;
 823 esac
 824 AC_SUBST(extra_ldflags_libjava)
 825 AC_SUBST(extra_gij_ldflags)
 826 AC_SUBST(extra_ldflags)
 827 AC_SUBST(LIBSTDCXXSPEC)
 828
 829 AC_SUBST(LIBGCJTESTSPEC)
 830
 831 # Allow the GC to be disabled.  Can be useful when debugging.
 832 AC_MSG_CHECKING([for garbage collector to use])
 833 AC_ARG_ENABLE(java-gc,
 834   AS_HELP_STRING([--enable-java-gc=TYPE],
 835                  [choose garbage collector (default is boehm)]),
 836   [GC=$enableval],
 837   [GC=boehm])
 838 GCLIBS=
 839 GCINCS=
 840 GCDEPS=
 841 GCSPEC=
 842 JC1GCSPEC=
 843 GCTESTSPEC=
 844 case "$GC" in
 845  boehm)
 846     AC_MSG_RESULT(boehm)
 847     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 848     JC1GCSPEC='-fuse-boehm-gc'
 849     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 850     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 851     GCOBJS=boehm.lo
 852     GCHDR=boehm-gc.h
 853     # The POSIX thread support needs to know this.
 854     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 855     ;;
 856  no)
 857     AC_MSG_RESULT(none)
 858     GCHDR=no-gc.h
 859     ;;
 860  *)
 861     AC_MSG_ERROR([unrecognized collector "$GC"])
 862     ;;
 863 esac
 864 AC_SUBST(GCLIBS)
 865 AC_SUBST(GCINCS)
 866 AC_SUBST(GCDEPS)
 867 AC_SUBST(GCSPEC)
 868 AC_SUBST(JC1GCSPEC)
 869 AC_SUBST(GCTESTSPEC)
 870 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 871 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 872 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 873
 874
 875 AC_MSG_CHECKING([for thread model used by GCC])
 876 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 877 AC_MSG_RESULT([$THREADS])
 878
 879 case "$THREADS" in
 880  no | none | single)
 881     THREADS=none
 882     ;;
 883  posix | posix95 | pthreads)
 884     THREADS=posix
 885     case "$host" in
 886      *-*-linux*)
 887         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 888         ;;
 889     esac
 890     ;;
 891  win32)
 892     ;;
 893  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 894     AC_MSG_ERROR(thread package $THREADS not yet supported)
 895     ;;
 896  *)
 897     AC_MSG_ERROR($THREADS is an unknown thread package)
 898     ;;
 899 esac
 900
 901 THREADCXXFLAGS=
 902 THREADLDFLAGS=
 903 THREADLIBS=
 904 THREADINCS=
 905 THREADDEPS=
 906 THREADH=
 907 THREADSPEC=
 908 THREADSTARTFILESPEC=
 909 case "$THREADS" in
 910  posix)
 911     case "$host" in
 912      *-*-cygwin*)
 913         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 914         ;;
 915      *-*-freebsd[[1234]]*)
 916         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 917         # merely adds pthread_* functions) but it does have a -pthread switch
 918         # which is required at link-time to select -lc_r *instead* of -lc.
 919         THREADLDFLAGS=-pthread
 920         # Don't set THREADSPEC here as might be expected since -pthread is
 921         # not processed when found within a spec file, it must come from
 922         # the command line.  For now, the user must provide the -pthread
 923         # switch to link code compiled with gcj.  In future, consider adding
 924         # support for weak references to pthread_* functions ala gthr.h API.
 925         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 926         ;;
 927      *-*-freebsd*)
 928         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 929         # systems which support threads and -lpthread.
 930         THREADLDFLAGS=-pthread
 931         THREADSPEC=-lpthread
 932         ;;
 933      alpha*-dec-osf* | hppa*-hp-hpux*)
 934         THREADCXXFLAGS=-pthread
 935         # boehm-gc needs some functions from librt, so link that too.
 936         THREADLIBS='-lpthread -lrt'
 937         THREADSPEC='-lpthread -lrt'
 938         ;;
 939      *)
 940         THREADLIBS=-lpthread
 941         THREADSPEC=-lpthread
 942         ;;
 943     esac
 944     THREADH=posix-threads.h
 945     # MIT pthreads doesn't seem to have the mutexattr functions.
 946     # But for now we don't check for it.  We just assume you aren't
 947     # using MIT pthreads.
 948     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 949
 950     # If we're using the Boehm GC, then we happen to know that it
 951     # defines _REENTRANT, so we don't bother.  Eww.
 952     if test "$GC" != boehm; then
 953        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 954     fi
 955     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 956     ;;
 957
 958  win32)
 959     THREADH=win32-threads.h
 960     THREADCXXFLAGS=-mthreads
 961     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 962     # But we do not want the executables created to be dependent on
 963     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 964     # exception handling contexts.  The following kludge achieves this effect
 965     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 966     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 967     # A workaround is to explicitly use -mthreads while linking Java programs.
 968     # See PR libgcj/28263.
 969     #
 970     # FIXME: In Java we are able to detect thread death at the end of
 971     # Thread.run() so we should be able to clean up the exception handling
 972     # contexts ourselves.
 973     THREADSTARTFILESPEC='crtmt%O%s'
 974     ;;
 975
 976  none)
 977     THREADH=no-threads.h
 978     ;;
 979 esac
 980 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 981 AC_SUBST(THREADLIBS)
 982 AC_SUBST(THREADINCS)
 983 AC_SUBST(THREADDEPS)
 984 AC_SUBST(THREADSPEC)
 985 AC_SUBST(THREADSTARTFILESPEC)
 986 AC_SUBST(THREADLDFLAGS)
 987 AC_SUBST(THREADCXXFLAGS)
 988 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 989 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 990 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 991 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 992
 993 if test -d sysdep; then true; else mkdir sysdep; fi
 994 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 995 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 996 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 997
 998 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 999 if test "$use_libgcj_bc" = yes; then
1000   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
1001 fi
1002 AC_SUBST(LIBGCJ_SPEC)
1003
1004 HASH_SYNC_SPEC=
1005 # Hash synchronization is only useful with posix threads right now.
1006 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1007    HASH_SYNC_SPEC=-fhash-synchronization
1008    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1009 fi
1010 AC_SUBST(HASH_SYNC_SPEC)
1011
1012 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1013
1014 # We're in the tree with gcc, and need to include some of its headers.
1015 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1016
1017 if test "x${with_newlib}" = "xyes"; then
1018    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1019    # may not work correctly, because the compiler may not be able to
1020    # link executables.
1021
1022    # We assume newlib.  This lets us hard-code the functions we know
1023    # we'll have.
1024    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1025    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1026    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1027    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1028    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1029    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1030    # This is only for POSIX threads.
1031    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1032
1033    # Assume we do not have getuid and friends.
1034    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1035    PLATFORMNET=NoNet
1036 else
1037    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1038                    localtime_r getpwuid_r getcwd \
1039                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1040                    nl_langinfo setlocale \
1041                    inet_pton uname inet_ntoa \
1042                    getrlimit sigaction ftruncate mmap \
1043                    getifaddrs])
1044    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1045    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1046    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1047    AC_CHECK_LIB(dl, dladdr, [
1048        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1049        AC_CHECK_LIB(dld, dladdr, [
1050        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1051
1052    if test x"$cross_compiling" = x"no"; then
1053      AC_CHECK_FILES(/proc/self/exe, [
1054        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1055      AC_CHECK_FILES(/proc/self/maps, [
1056        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1057          [Define if you have /proc/self/maps])])
1058    else
1059      case $host in
1060      *-linux*)
1061        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1062        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1063        ;;
1064      esac
1065    fi
1066
1067    AM_ICONV
1068    AM_LC_MESSAGES
1069    AC_STRUCT_TIMEZONE
1070
1071    AC_CHECK_FUNCS(gethostbyname_r, [
1072      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1073        [Define if you have the 'gethostbyname_r' function.])
1074      # There are two different kinds of gethostbyname_r.
1075      # We look for the one that returns `int'.
1076      # Hopefully this check is robust enough.
1077      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1078        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1079
1080      case " $GCINCS " in
1081      *" -D_REENTRANT "*) ;;
1082      *)
1083         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1084         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1085         [libjava_cv_gethostbyname_r_needs_reentrant],
1086         [ AC_LANG_PUSH(C++)
1087           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1088             [[gethostbyname_r("", 0, 0);]])],
1089             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1090                 CPPFLAGS_SAVE="$CPPFLAGS"
1091                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1092                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1093                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1094                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1095                 CPPFLAGS="$CPPFLAGS_SAVE"
1096           ])
1097           AC_LANG_POP(C++)
1098         ])
1099         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1100           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1101         fi
1102      ;;
1103      esac
1104
1105      AC_CACHE_CHECK([for struct hostent_data],
1106         [libjava_cv_struct_hostent_data], [dnl
1107         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1108 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1109 # define _REENTRANT 1
1110 #endif
1111 #include <netdb.h>]], [[struct hostent_data data;]])],
1112           [libjava_cv_struct_hostent_data=yes],
1113           [libjava_cv_struct_hostent_data=no])])
1114      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1115        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1116          [Define if struct hostent_data is defined in netdb.h])
1117      fi
1118    ])
1119
1120    # FIXME: libjava source code expects to find a prototype for
1121    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1122    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1123    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1124    # linkage check is enough, yet C++ code requires proper prototypes.)
1125    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1126    AC_CHECK_FUNCS(gethostbyaddr_r, [
1127      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1128        [Define if you have the 'gethostbyaddr_r' function.])
1129      # There are two different kinds of gethostbyaddr_r.
1130      # We look for the one that returns `int'.
1131      # Hopefully this check is robust enough.
1132      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1133        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1134          [Define if gethostbyaddr_r returns 'int'.])])])])
1135
1136    AC_CHECK_FUNCS(gethostname, [
1137      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1138        [Define if you have the 'gethostname' function.])
1139      AC_EGREP_HEADER(gethostname, unistd.h, [
1140        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1141          [Define if gethostname is declared in <unistd.h>.])])])
1142
1143    AC_CHECK_FUNCS(usleep, [
1144      AC_EGREP_HEADER(usleep, unistd.h, [
1145        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1146           [Define if usleep is declared in <unistd.h>.])])])
1147
1148    # Look for these functions in the thread library, but only bother
1149    # if using POSIX threads.
1150    if test "$THREADS" = posix; then
1151       save_LIBS="$LIBS"
1152       LIBS="$LIBS $THREADLIBS"
1153
1154       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1155       # Solaris 7 the name librt is preferred.
1156       AC_CHECK_FUNCS(sched_yield, , [
1157         AC_CHECK_LIB(rt, sched_yield, [
1158           AC_DEFINE(HAVE_SCHED_YIELD)
1159           THREADLIBS="$THREADLIBS -lrt"
1160           THREADSPEC="$THREADSPEC -lrt"], [
1161           AC_CHECK_LIB(posix4, sched_yield, [
1162             AC_DEFINE(HAVE_SCHED_YIELD)
1163             THREADLIBS="$THREADLIBS -lposix4"
1164             THREADSPEC="$THREADSPEC -lposix4"])])])
1165
1166       AC_CHECK_LIB(rt, clock_gettime, [
1167          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1168          case "$THREADSPEC" in
1169            *-lrt*) ;;
1170            *)
1171              THREADSPEC="$THREADSPEC -lrt"
1172              THREADLIBS="$THREADLIBS -lrt"
1173              ;;
1174          esac])
1175
1176       LIBS="$save_LIBS"
1177
1178       # We can save a little space at runtime if the mutex has m_count
1179       # or __m_count.  This is a nice hack for Linux.
1180       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1181           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1182         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1183              [Define if pthread_mutex_t has m_count member.]), [
1184         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1185             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1186           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1187             [Define if pthread_mutex_t has __m_count member.]))])
1188    fi
1189
1190    # We require a way to get the time.
1191    time_found=no
1192    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1193    if test "$time_found" = no; then
1194       AC_MSG_ERROR([no function found to get the time])
1195    fi
1196
1197    AC_CHECK_FUNCS(memmove)
1198
1199    # We require memcpy.
1200    memcpy_found=no
1201    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1202    if test "$memcpy_found" = no; then
1203       AC_MSG_ERROR([memcpy is required])
1204    fi
1205    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1206    AC_CHECK_LIB(dl, dlopen, [
1207        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1208        AC_CHECK_LIB(dld, dlopen, [
1209        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1210
1211    # Some library-finding code we stole from Tcl.
1212    #--------------------------------------------------------------------
1213    #    Check for the existence of the -lsocket and -lnsl libraries.
1214    #    The order here is important, so that they end up in the right
1215    #    order in the command line generated by make.  Here are some
1216    #    special considerations:
1217    #    1. Use "connect" and "accept" to check for -lsocket, and
1218    #       "gethostbyname" to check for -lnsl.
1219    #    2. Use each function name only once:  can't redo a check because
1220    #       autoconf caches the results of the last check and won't redo it.
1221    #    3. Use -lnsl and -lsocket only if they supply procedures that
1222    #       aren't already present in the normal libraries.  This is because
1223    #       IRIX 5.2 has libraries, but they aren't needed and they're
1224    #       bogus:  they goof up name resolution if used.
1225    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1226    #       To get around this problem, check for both libraries together
1227    #       if -lsocket doesn't work by itself.
1228    #--------------------------------------------------------------------
1229
1230    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1231     [gcj_cv_lib_sockets=
1232      gcj_checkBoth=0
1233      unset ac_cv_func_connect
1234      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1235      if test "$gcj_checkSocket" = 1; then
1236          unset ac_cv_func_connect
1237          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1238                       gcj_checkBoth=1)
1239      fi
1240      if test "$gcj_checkBoth" = 1; then
1241          gcj_oldLibs=$LIBS
1242          LIBS="$LIBS -lsocket -lnsl"
1243          unset ac_cv_func_accept
1244          AC_CHECK_FUNC(accept,
1245                        [gcj_checkNsl=0
1246                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1247          unset ac_cv_func_accept
1248          LIBS=$gcj_oldLibs
1249      fi
1250      unset ac_cv_func_gethostbyname
1251      gcj_oldLibs=$LIBS
1252      LIBS="$LIBS $gcj_cv_lib_sockets"
1253      AC_CHECK_FUNC(gethostbyname, ,
1254                    [AC_CHECK_LIB(nsl, main,
1255                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1256      unset ac_cv_func_gethostbyname
1257      LIBS=$gcj_oldLIBS
1258    ])
1259    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1260
1261    if test "$with_system_zlib" = yes; then
1262       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1263    fi
1264
1265    # Test for Gtk stuff, if asked for.
1266    if test "$use_gtk_awt" = yes; then
1267       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1268       AC_SUBST(GTK_CFLAGS)
1269       AC_SUBST(GTK_LIBS)
1270
1271       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1272       AC_SUBST(GLIB_CFLAGS)
1273       AC_SUBST(GLIB_LIBS)
1274
1275       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1276       AC_SUBST(LIBART_CFLAGS)
1277       AC_SUBST(LIBART_LIBS)
1278
1279       # We require the XTest Extension to support java.awt.Robot.
1280       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1281                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1282                    [${X_LIBS}])
1283    fi
1284
1285    # On Solaris, and maybe other architectures, the Boehm collector
1286    # requires -ldl.
1287    if test "$GC" = boehm; then
1288       case "${host}" in
1289           mips-sgi-irix6*)
1290             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1291             # libgcj.spec is used, so override here
1292             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1293           ;;
1294           *)
1295             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1296           ;;
1297       esac
1298    fi
1299 fi
1300
1301 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1302 case $build in
1303     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1304     *)         CLASSPATH_SEPARATOR=':' ;;
1305 esac
1306 AC_SUBST(CLASSPATH_SEPARATOR)
1307
1308 # We must search the source tree for java.lang, since we still don't
1309 # have libgcj.jar nor java/lang/*.class
1310 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1311 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1312
1313 # Since some classes depend on this one, we need its source available
1314 # before we can do any GCJ compilation test :-(
1315 if test ! -f gnu/classpath/Configuration.java; then
1316   test -d gnu || mkdir gnu
1317   test -d gnu/classpath || mkdir gnu/classpath
1318   # Note that it is not crucial that all the values here be correct.
1319   sed -e "s,@prefix@,$prefix," \
1320       -e "s,@VERSION@,$VERSION," \
1321       -e "s,@LIBDEBUG@,false," \
1322       -e "s,@INIT_LOAD_LIBRARY@,false," \
1323       -e "s,@@,$LIBGCJDEBUG," \
1324       -e "s,@default_toolkit@,$TOOLKIT," \
1325       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1326       -e "s,@GTK_CAIRO_ENABLED@,false," \
1327       -e "s,@ECJ_JAR@,," \
1328         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1329         > gnu/classpath/Configuration.java
1330   # We do not want to redirect the output of the grep below to /dev/null,
1331   # but we add /dev/null to the input list so that grep will print the
1332   # filename of Configuration.java in case it finds any matches.
1333   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1334     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1335   fi
1336 fi
1337
1338 LT_AC_PROG_GCJ
1339
1340 # Now remove it.
1341 rm -f gnu/classpath/Configuration.java
1342
1343 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1344
1345 AC_CHECK_SIZEOF(void *)
1346
1347 AC_C_BIGENDIAN
1348
1349 ZLIBS=
1350 SYS_ZLIBS=
1351 ZINCS=
1352
1353 if test -z "$ZLIBSPEC"; then
1354    # Use zlib from the GCC tree.
1355    ZINCS='-I$(top_srcdir)/../zlib'
1356    ZLIBS=../zlib/libzgcj_convenience.la
1357 else
1358    # System's zlib.
1359    SYS_ZLIBS="$ZLIBSPEC"
1360 fi
1361 AC_SUBST(ZLIBS)
1362 AC_SUBST(SYS_ZLIBS)
1363 AC_SUBST(ZINCS)
1364 AC_SUBST(DIVIDESPEC)
1365 AC_SUBST(CHECKREFSPEC)
1366 AC_SUBST(EXCEPTIONSPEC)
1367 AC_SUBST(BACKTRACESPEC)
1368 AC_SUBST(IEEESPEC)
1369
1370 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1371 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1372 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1373 AC_SUBST(GCC_UNWIND_INCLUDE)
1374
1375 # Process the option "--enable-version-specific-runtime-libs"
1376 # Calculate toolexeclibdir
1377 case ${version_specific_libs} in
1378   yes)
1379     # Need the gcc compiler version to know where to install libraries
1380     # and header files if --enable-version-specific-runtime-libs option
1381     # is selected.
1382     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1383     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1384     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1385     toolexeclibdir=$toolexecmainlibdir
1386     ;;
1387   no)
1388     if test -n "$with_cross_host" &&
1389        test x"$with_cross_host" != x"no"; then
1390       # Install a library built with a cross compiler in tooldir, not libdir.
1391       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1392       toolexecmainlibdir='$(toolexecdir)/lib'
1393     else
1394       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1395       toolexecmainlibdir='$(libdir)'
1396     fi
1397     multi_os_directory=`$CC -print-multi-os-directory`
1398     case $multi_os_directory in
1399       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1400       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1401     esac
1402     ;;
1403 esac
1404 AC_SUBST(toolexecdir)
1405 AC_SUBST(toolexecmainlibdir)
1406 AC_SUBST(toolexeclibdir)
1407
1408 # Determine gcj and libgcj version number.
1409 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1410 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1411 GCJVERSION=$gcjversion
1412 AC_SUBST(GCJVERSION)
1413 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1414
1415 # Determine where the standard .db file and GNU Classpath JNI
1416 # libraries are found.
1417 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1418 multi_os_directory=`$CC -print-multi-os-directory`
1419 case $multi_os_directory in
1420   .)
1421    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1422    ;;
1423   *)
1424    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1425    ;;
1426 esac
1427 AC_SUBST(dbexecdir)
1428 AC_SUBST(gcjsubdir)
1429
1430 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1431 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1432
1433 TL_AC_GXX_INCLUDE_DIR
1434
1435 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1436 # On that system, sys/ioctl.h will not include sys/filio.h unless
1437 # BSD_COMP is defined; just including sys/filio.h is simpler.
1438 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1439 # for now.  If you change this, you also must update natFile.cc.
1440 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1441                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1442                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1443                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1444                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1445 AC_CHECK_HEADERS(inttypes.h, [
1446     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1447     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1448 ])
1449
1450 AC_CHECK_TYPE([ssize_t], [int])
1451 AC_CHECK_TYPE([magic_t], [
1452     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1453 #ifdef HAVE_MAGIC_H
1454 #include <magic.h>
1455 #endif])
1456
1457 AC_MSG_CHECKING([for in_addr_t])
1458 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1459 #if STDC_HEADERS
1460 #include <stdlib.h>
1461 #include <stddef.h>
1462 #endif
1463 #if HAVE_NETINET_IN_H
1464 #include <netinet/in.h>
1465 #endif]], [[in_addr_t foo;]])],
1466   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1467      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1468    AC_MSG_RESULT(yes)],
1469   [AC_MSG_RESULT(no)])
1470
1471 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1472 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1473   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1474      [Define if struct ip_mreq is defined in netinet/in.h.])
1475    AC_MSG_RESULT(yes)],
1476   [AC_MSG_RESULT(no)])
1477
1478 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1479 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1480   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1481      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1482    AC_MSG_RESULT(yes)],
1483   [AC_MSG_RESULT(no)])
1484
1485 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1486 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1487   [AC_DEFINE(HAVE_INET6, 1,
1488      [Define if inet6 structures are defined in netinet/in.h.])
1489    AC_MSG_RESULT(yes)],
1490   [AC_MSG_RESULT(no)])
1491
1492 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1493 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1494 #include <sys/types.h>
1495 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1496   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1497    AC_MSG_RESULT(yes)],
1498   [AC_MSG_RESULT(no)])
1499
1500 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1501 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1502   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1503    AC_MSG_RESULT(yes)],
1504   [AC_MSG_RESULT(no)
1505    AC_MSG_CHECKING([for global timezone variable])
1506    dnl FIXME: we don't want a link check here because that won't work
1507    dnl when cross-compiling.  So instead we make an assumption that
1508    dnl the header file will mention timezone if it exists.
1509    dnl Don't find the win32 function timezone
1510    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1511      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1512       AC_MSG_RESULT(yes)],
1513      [AC_MSG_RESULT(no)
1514        AC_MSG_CHECKING([for global _timezone variable])
1515        dnl FIXME: As above, don't want link check
1516        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1517          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1518             [Define if your platform has the global _timezone variable.])
1519           AC_MSG_RESULT(yes)],
1520           [AC_MSG_RESULT(no)])])])
1521
1522 AC_CHECK_PROGS(PERL, perl, false)
1523
1524 SYSDEP_SOURCES=
1525 SIGNAL_HANDLER_AUX=
1526
1527 case "${host}" in
1528  i?86-*-linux*)
1529     SIGNAL_HANDLER=include/i386-signal.h
1530     ;;
1531  sparc*-sun-solaris*)
1532     SIGNAL_HANDLER=include/sparc-signal.h
1533     ;;
1534 # ia64-*)
1535 #    SYSDEP_SOURCES=sysdep/ia64.c
1536 #    test -d sysdep || mkdir sysdep
1537 #    ;;
1538  hppa*-*-linux*)
1539     SIGNAL_HANDLER=include/pa-signal.h
1540     ;;
1541  hppa*-hp-hpux*)
1542     SIGNAL_HANDLER=include/hppa-signal.h
1543     ;;
1544  ia64-*-linux*)
1545     SIGNAL_HANDLER=include/dwarf2-signal.h
1546     ;;
1547  powerpc*-*-linux*)
1548     SIGNAL_HANDLER=include/powerpc-signal.h
1549     ;;
1550  alpha*-*-linux*)
1551     SIGNAL_HANDLER=include/dwarf2-signal.h
1552     ;;
1553  s390*-*-linux*)
1554     SIGNAL_HANDLER=include/s390-signal.h
1555     ;;
1556  x86_64*-*-linux*)
1557     SIGNAL_HANDLER=include/x86_64-signal.h
1558     SIGNAL_HANDLER_AUX=include/i386-signal.h
1559     ;;
1560  sparc*-*-linux*)
1561     SIGNAL_HANDLER=include/dwarf2-signal.h
1562     ;;
1563  sh*-*-linux*)
1564     SIGNAL_HANDLER=include/sh-signal.h
1565     ;;
1566  *mingw*)
1567     SIGNAL_HANDLER=include/win32-signal.h
1568     ;;
1569  mips*-*-linux*)
1570     SIGNAL_HANDLER=include/mips-signal.h
1571     ;;
1572  m68*-*-linux*)
1573     SIGNAL_HANDLER=include/dwarf2-signal.h
1574     ;;
1575  powerpc*-*-darwin* | i?86-*-darwin9* | x86_64-*-darwin9*)
1576     SIGNAL_HANDLER=include/darwin-signal.h
1577     ;;
1578  *)
1579     SIGNAL_HANDLER=include/default-signal.h
1580     ;;
1581 esac
1582
1583 # If we're using sjlj exceptions, forget what we just learned.
1584 if test "$enable_sjlj_exceptions" = yes; then
1585    SIGNAL_HANDLER=include/default-signal.h
1586    SIGNAL_HANDLER_AUX=
1587 fi
1588
1589 AC_SUBST(SYSDEP_SOURCES)
1590
1591 if test -z "$SIGNAL_HANDLER_AUX"; then
1592   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1593 fi
1594
1595 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1596                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1597
1598 if test "${multilib}" = "yes"; then
1599   multilib_arg="--enable-multilib"
1600 else
1601   multilib_arg=
1602 fi
1603
1604 # See if we support thread-local storage.
1605 GCC_CHECK_TLS
1606
1607 # For _Unwind_GetIPInfo.
1608 GCC_CHECK_UNWIND_GETIPINFO
1609
1610 # See if linker supports anonymous version scripts.
1611 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1612   [libjava_cv_anon_version_script],
1613   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1614    libjava_cv_anon_version_script=no
1615    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1616    echo '{ global: globalsymb*; local: *; };' > conftest.map
1617    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1618                [libjava_cv_anon_version_script=yes], [])
1619    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1620   ])
1621 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1622
1623 # Check if linker supports static linking on a per library basis
1624 LD_START_STATIC_SPEC=
1625 LD_FINISH_STATIC_SPEC=
1626 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1627   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1628     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1629     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1630   fi
1631 fi
1632 AC_SUBST(LD_START_STATIC_SPEC)
1633 AC_SUBST(LD_FINISH_STATIC_SPEC)
1634
1635 here=`${PWDCMD-pwd}`
1636 AC_SUBST(here)
1637
1638 # We get this from the environment.
1639 AC_SUBST(GCJFLAGS)
1640
1641 AC_ARG_WITH([python-dir],
1642             AS_HELP_STRING([--with-python-dir],
1643                            [the location to install Python modules. This path should NOT include the prefix.]),
1644             [with_python_dir=$withval], [with_python_dir=""])
1645
1646 if test "x${with_python_dir}" = "x"
1647 then
1648   # Needed for installing Python modules during make install.
1649   python_mod_dir="\${prefix}/share/python"
1650   # Needed for substituting into aot-compile*
1651   python_mod_dir_expanded="${prefix}/share/python"
1652 else
1653   python_mod_dir="\${prefix}${with_python_dir}"
1654   python_mod_dir_expanded="${prefix}${with_python_dir}"
1655 fi
1656 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1657 AC_SUBST(python_mod_dir)
1658 AC_SUBST(python_mod_dir_expanded)
1659
1660 # needed for aot-compile-rpm
1661 MAKE=`which make`
1662 AC_SUBST(MAKE)
1663
1664 AC_ARG_ENABLE([aot-compile-rpm],
1665   [AS_HELP_STRING([--enable-aot-compile-rpm],
1666                  [enable installation of aot-compile-rpm [default=no]])],
1667   [case "${enableval}" in
1668     yes) AOT_RPM_ENABLED=yes ;;
1669     no)  AOT_RPM_ENABLED=no ;;
1670     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1671   esac],
1672   [AOT_RPM_ENABLED=no]
1673 )
1674 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" == xyes)
1675
1676 AC_ARG_ENABLE([java-home],
1677   [AS_HELP_STRING([--enable-java-home],
1678                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1679   [case "${enableval}" in
1680     yes) JAVA_HOME_ENABLED=yes ;;
1681     no)  JAVA_HOME_ENABLED=no ;;
1682     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1683   esac],
1684   [JAVA_HOME_ENABLED=no]
1685 )
1686 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" == xyes)
1687
1688 # Only do these checks if java-home above is enabled.
1689 if test "x${JAVA_HOME_ENABLED}" == xyes
1690 then
1691
1692   AC_ARG_WITH([gcc-suffix],
1693               AS_HELP_STRING([--with-gcc-suffix],
1694                              [the GCC tool suffix (defaults to empty string)]),
1695               [gcc_suffix=$withval], [gcc_suffix=""])
1696   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1697   AC_SUBST(gcc_suffix)
1698
1699   AC_ARG_WITH([arch-directory],
1700               AS_HELP_STRING([--with-arch-directory],
1701                              [the arch directory under jre/lib (defaults to auto-detect)]),
1702               [host_cpu=$withval], [host_cpu=""])
1703
1704   AC_ARG_WITH([os-directory],
1705               AS_HELP_STRING([--with-os-directory],
1706                              [the os directory under include (defaults to auto-detect)]),
1707               [host_os=$withval], [host_os=""])
1708
1709   AC_ARG_WITH([origin-name],
1710               AS_HELP_STRING([--with-origin-name],
1711                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1712               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1713   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1714
1715   AC_ARG_WITH([arch-suffix],
1716               AS_HELP_STRING([--with-arch-suffix],
1717                              [the arch directory suffix (default is the empty string]),
1718               [arch_suffix=$withval], [arch_suffix=""])
1719   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1720
1721   AC_ARG_WITH([jvm-root-dir],
1722               AS_HELP_STRING([--with-jvm-root-dir],
1723                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1724               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1725   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1726
1727   AC_ARG_WITH([jvm-jar-dir],
1728               AS_HELP_STRING([--with-jvm-jar-dir],
1729                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1730               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1731   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1732
1733   JAVA_VERSION=1.5.0
1734   BUILD_VERSION=0
1735   AC_SUBST(JAVA_VERSION)
1736   AC_SUBST(BUILD_VERSION)
1737   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1738
1739   jre_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}/jre
1740   sdk_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}
1741   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1742   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1743
1744   JVM_ROOT_DIR=${jvm_root_dir}
1745   AC_SUBST(JVM_ROOT_DIR)
1746   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1747
1748   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1749   AC_SUBST(JVM_JAR_ROOT_DIR)
1750   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1751
1752   JVM_JAR_DIR=${jvm_jar_dir}/${sdk_dir}
1753   AC_SUBST(JVM_JAR_DIR)
1754   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1755
1756   JRE_DIR=${jre_dir}
1757   AC_SUBST(JRE_DIR)
1758
1759   SDK_DIR=${sdk_dir}
1760   AC_SUBST(SDK_DIR)
1761
1762   JRE_LNK=${jre_lnk}
1763   AC_SUBST(JRE_LNK)
1764
1765   SDK_LNK=${sdk_lnk}
1766   AC_SUBST(SDK_LNK)
1767
1768   SDK_BIN_DIR=${jvm_root_dir}/${sdk_dir}/bin
1769   AC_SUBST(SDK_BIN_DIR)
1770   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1771
1772   SDK_LIB_DIR=${jvm_root_dir}/${sdk_dir}/lib
1773   AC_SUBST(SDK_LIB_DIR)
1774   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1775
1776   SDK_INCLUDE_DIR=${jvm_root_dir}/${sdk_dir}/include
1777   AC_SUBST(SDK_INCLUDE_DIR)
1778   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1779
1780   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1781   AC_SUBST(JRE_BIN_DIR)
1782   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1783
1784   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1785   AC_SUBST(JRE_LIB_DIR)
1786   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1787
1788   # Find gcj prefix using gcj found in PATH.
1789   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1790
1791   # Where do the gcj binaries live?
1792   # For jhbuild based builds, they all live in a sibling of bin called
1793   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1794   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1795   AC_SUBST(GCJ_BIN_DIR)
1796   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1797
1798   echo host is ${host}
1799   if test "x${host_cpu}" = "x"
1800   then
1801     case ${host} in
1802       *-mingw* | *-cygwin*)
1803         host_cpu=x86;;
1804       i486-* | i586-* | i686-*)
1805         host_cpu=i386;;
1806       *)
1807         host_cpu=${host_cpu};;
1808     esac
1809   fi
1810   AC_MSG_RESULT(arch directory: ${host_cpu})
1811   CPU=${host_cpu}
1812   AC_SUBST(CPU)
1813
1814   if test "x${host_os}" = "x"
1815   then
1816     case ${host} in
1817       *-mingw* | *-cygwin*)
1818         host_os=win32;;
1819       *-linux*)
1820         host_os=linux;;
1821       *)
1822         host_os=${host_os};;
1823     esac
1824   fi
1825   echo os directory: ${host_os}
1826   OS=${host_os}
1827   AC_SUBST(OS)
1828
1829   # make an expanded $libdir, for substituting into
1830   # scripts (and other non-Makefile things).
1831   LIBDIR=$libdir
1832   if test "x${exec_prefix}" = "xNONE"
1833   then
1834       lib_exec_prefix=$prefix
1835   else
1836       lib_exec_prefix=$exec_prefix
1837   fi
1838   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1839   AC_SUBST(LIBDIR)
1840 fi
1841
1842 AC_CONFIG_FILES([
1843 Makefile
1844 libgcj.pc
1845 libgcj.spec
1846 libgcj-test.spec
1847 gcj/Makefile
1848 include/Makefile
1849 testsuite/Makefile
1850 contrib/aotcompile.py
1851 contrib/aot-compile
1852 contrib/aot-compile-rpm
1853 contrib/rebuild-gcj-db
1854 ])
1855
1856 if test ${multilib} = yes; then
1857   multilib_arg="--enable-multilib"
1858 else
1859   multilib_arg=
1860 fi
1861
1862 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1863 AC_OUTPUT