libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 LIBGCJ_CFLAGS="${libgcj_cflags}"
 218 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 219 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 220 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 221 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 222 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 223 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 224 AC_SUBST(LIBGCJ_CFLAGS)
 225 AC_SUBST(LIBGCJ_CXXFLAGS)
 226 AC_SUBST(LIBGCJ_JAVAFLAGS)
 227 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 228 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 229 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 231
 232 # Only use libltdl for non-newlib builds.
 233 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 234    AC_LTDL_SHLIBPATH
 235 fi
 236
 237 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 238
 239 # Possibly build libgcj as many sub-libraries.
 240 AC_ARG_ENABLE(libgcj-sublibs,
 241   AS_HELP_STRING([--enable-libgcj-sublibs],
 242                  [build libgcj as many sub-libraries]))
 243
 244 if test -z "$enable_libgcj_sublibs"; then
 245    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 246 fi
 247 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 248 if test "$enable_libgcj_sublibs" = yes ; then
 249   # In theory we could make do with only one override and simply
 250   # tag "_bc" onto the end of it when we use it to generate the
 251   # spec, but that's an ugly thing to do when there are multiple
 252   # words in the string and you're relying on the ordering to
 253   # append the correct one.
 254   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 255   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 256 fi
 257
 258
 259 # See if the user has requested runtime debugging.
 260 LIBGCJDEBUG="disable"
 261 AC_SUBST(LIBGCJDEBUG)
 262 AC_ARG_ENABLE(libgcj-debug,
 263   AS_HELP_STRING([--enable-libgcj-debug],
 264                  [enable runtime debugging code]),
 265   [if test "$enable_libgcj_debug" = yes; then
 266     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 267     LIBGCJDEBUG="enable"
 268   fi])
 269
 270 AC_ARG_WITH([escher],
 271          AS_HELP_STRING([--with-escher=ABS.PATH],
 272                         [specify path to escher dir or JAR for X peers]))
 273 case "$with_escher" in
 274 "")
 275         use_escher=false
 276         ;;
 277 "no")
 278         use_escher=false
 279         ;;
 280 "yes")
 281         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 282         ;;
 283 *)
 284         use_escher=true
 285         ;;
 286 esac
 287
 288 # Determine which AWT peer libraries to build
 289 AC_ARG_ENABLE(java-awt,
 290   AS_HELP_STRING([--enable-java-awt],
 291                  [list of AWT peer implementations to be built]))
 292
 293 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 294 use_xlib_awt=""
 295 use_gtk_awt=""
 296 use_qt_awt=""
 297 use_x_awt=""
 298 # The default toolkit to use is the first one specified.
 299 TOOLKIT=
 300 AC_SUBST(TOOLKIT)
 301
 302 for peer in $peerlibs ; do
 303   case $peer in
 304     xlib)
 305       if test "$no_x" = yes; then
 306         echo "*** xlib peers requested but no X library available" 1>&2
 307         exit 1
 308       else
 309         use_xlib_awt="yes"
 310         if test -z "$TOOLKIT"; then
 311            TOOLKIT=gnu.awt.xlib.XToolkit
 312         fi
 313       fi
 314       ;;
 315     gtk)
 316       if test "$no_x" = yes; then
 317          echo "*** gtk peers requested but no X library available" 1>&2
 318          exit 1
 319       else
 320          use_gtk_awt=yes
 321          if test -z "$TOOLKIT"; then
 322             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 323          fi
 324       fi
 325       ;;
 326     qt)
 327       if test "$no_x" = yes; then
 328          # Perhaps we should admit the possibility of embedded Qt.
 329          echo "*** Qt peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_qt_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 335          fi
 336       fi
 337       ;;
 338     x)
 339       use_x_awt=yes
 340       if test -z "$TOOLKIT"; then
 341          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 342       fi
 343       ;;
 344     no)
 345       use_xlib_awt=
 346       use_gtk_awt=
 347       use_qt_awt=
 348       use_x_awt=
 349       break
 350       ;;
 351     *)
 352       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 353       exit 1
 354   esac
 355 done
 356
 357 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 358 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 359
 360 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 361
 362 expanded_prefix=$prefix
 363 if test "X$prefix" = XNONE; then
 364   expanded_prefix=${ac_default_prefix}
 365 fi
 366
 367 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 368
 369 # Create standard.omit based on decisions we just made.
 370 cp $srcdir/standard.omit.in standard.omit
 371 if test "$use_xlib_awt" != yes; then
 372    echo gnu/awt/xlib >> standard.omit
 373    echo gnu/gcj/xlib >> standard.omit
 374 fi
 375 if test "$use_x_awt" != yes; then
 376    echo gnu/java/awt/peer/x >> standard.omit
 377 fi
 378
 379 # Tools that need to be compiled against classpath's tools classes
 380 : > vm-tools-packages
 381 for package in gnu/gcj/tools/gc_analyze ; do
 382     echo $package >> standard.omit
 383     echo $package >> vm-tools-packages
 384 done
 385
 386 if test -z "${with_multisubdir}"; then
 387    builddotdot=.
 388 else
 389    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 390 fi
 391
 392 NATIVE=yes
 393
 394 # Which gcj and host gcj (for ecjx) do we use?
 395 which_gcj=default
 396 host_exeext=${ac_exeext}
 397 GCJ_FOR_ECJX='$(GCJ)'
 398 GCC_FOR_ECJX='$(CXX)'
 399 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 400 if test -n "${with_cross_host}"; then
 401   # We are being configured with a cross compiler. We can't
 402   # use ac_exeext, because that is for the target platform.
 403   NATIVE=no
 404   cross_host_exeext=
 405   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 406   GCC_FOR_ECJX="${with_cross_host}-gcc"
 407   case "${with_cross_host}" in
 408      *mingw* | *cygwin*)
 409          cross_host_exeext=.exe
 410      ;;
 411   esac
 412   host_exeext=${cross_host_exeext}
 413   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 414      if test x"$build_noncanonical" = x"$with_cross_host"; then
 415         # Ordinary cross (host!=target and host=build)
 416         which_gcj=built
 417      else
 418         # Canadian cross (host!=target and host!=build)
 419         which_gcj=cross
 420      fi
 421   else
 422      which_gcj=cross
 423   fi
 424 else
 425   # We are being configured with a native or crossed-native compiler
 426   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 427      if test x"$build" = x"$host"; then
 428         # True native build (host=target and host=build)
 429         which_gcj=built
 430      else
 431         # Crossed-native build (host=target and host!=build)
 432         which_gcj=cross
 433      fi
 434   else
 435      which_gcj=path
 436   fi
 437 fi
 438 libgcjdir=`${PWDCMD-pwd}`
 439 case $GCJ in
 440 *" -B"*)
 441   # Just in case there is a comma in the build dir, quote it for the
 442   # sed command below.
 443   case $libgcjdir in
 444   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 445   *) qlibgcjdir=$libgcjdir;;
 446   esac
 447   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 448   ;;
 449 *)
 450   GCJ=$GCJ" -B$libgcjdir/"
 451   ;;
 452 esac
 453 case "${which_gcj}" in
 454    built)
 455       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 456    ;;
 457    cross)
 458       if test "x${with_newlib}" = "xyes"; then
 459          # FIXME (comment): Why is this needed?
 460          GCC_UNWIND_INCLUDE=
 461       fi
 462       GCJH='$(target_noncanonical)-gcjh'
 463    ;;
 464    path)
 465       GCJH=gcjh
 466    ;;
 467 esac
 468 JAVAC="$GCJ -C"
 469 export JAVAC
 470
 471 AC_SUBST(GCJ_FOR_ECJX)
 472 AC_SUBST(GCC_FOR_ECJX)
 473 AC_SUBST(GCJH)
 474 AC_SUBST(host_exeext)
 475
 476 # Create it, so that compile/link tests don't fail
 477 test -f libgcj.spec || touch libgcj.spec
 478
 479
 480
 481 # Set up to configure Classpath.
 482 # FIXME: no supported way to pass args in autoconf.
 483 # Disable tool wrappers to avoid ltdl.h configure check.
 484 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 485 ac_configure_args="$ac_configure_args --disable-load-library"
 486 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 487 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 488 dir1=`cd $srcdir && pwd`
 489 dir2=`pwd`
 490 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 491 ac_configure_args="$ac_configure_args --disable-core-jni"
 492 dnl FIXME?
 493 ac_configure_args="$ac_configure_args --disable-examples"
 494 ac_configure_args="$ac_configure_args --with-glibj=build"
 495 if test "$browser_plugin_enabled" != yes; then
 496   ac_configure_args="$ac_configure_args --disable-plugin"
 497 else
 498   ac_configure_args="$ac_configure_args --enable-plugin"
 499 fi
 500 if test "$gconf_enabled" != yes; then
 501   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 502   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 503 fi
 504 if test "$use_gtk_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 506 fi
 507 if test "$use_qt_awt" != yes; then
 508   ac_configure_args="$ac_configure_args --disable-qt-peer"
 509 else
 510   # We need this as qt is disabled by default in classpath.
 511   ac_configure_args="$ac_configure_args --enable-qt-peer"
 512 fi
 513 if test "$use_x_awt" != yes; then
 514   ac_configure_args="$ac_configure_args --without-escher"
 515 else
 516   # We need this as escher is disabled by default in classpath.
 517   if test "$use_escher" != true; then
 518     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 519   else
 520     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 521   fi
 522 fi
 523 if test "x$BUILD_GJDOC" = xno; then
 524   ac_configure_args="$ac_configure_args --disable-gjdoc"
 525 fi
 526 # -Werror causes unavoidable problems in code using alsa.
 527 ac_configure_args="$ac_configure_args --disable-regen-headers"
 528 ac_configure_args="$ac_configure_args --disable-Werror"
 529 dnl --with-gcj=$GCJ
 530 dnl --with-javah=$GCJH
 531 dnl gtk-cairo -- just export here...
 532 dnl --enable-regen-headers?
 533
 534 # Only use libltdl for non-newlib builds.
 535 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 536    AC_LIBLTDL_CONVENIENCE
 537    AC_LIBTOOL_DLOPEN
 538    DIRLTDL=libltdl
 539    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 540    # Sigh.  Libtool's macro doesn't do the right thing.
 541    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 542    # FIXME: this is a hack.
 543    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 544    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 545 fi
 546 AC_SUBST(INCLTDL)
 547 AC_SUBST(LIBLTDL)
 548 AC_SUBST(DIRLTDL)
 549 AC_PROG_LIBTOOL
 550 AM_PROG_GCJ
 551 AM_PROG_CC_C_O
 552
 553 AC_CONFIG_SUBDIRS(classpath libltdl)
 554
 555 # The -no-testsuite modules omit the test subdir.
 556 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 557
 558 # Should the runtime set system properties by examining the
 559 # environment variable GCJ_PROPERTIES?
 560 AC_ARG_ENABLE(getenv-properties,
 561   AS_HELP_STRING([--disable-getenv-properties],
 562                  [don't set system properties from GCJ_PROPERTIES]))
 563
 564 # Whether GCJ_PROPERTIES is used depends on the target.
 565 if test -z "$enable_getenv_properties"; then
 566    enable_getenv_properties=${enable_getenv_properties_default-yes}
 567 fi
 568 if test "$enable_getenv_properties" = no; then
 569    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 570      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 571 fi
 572
 573 # Whether we should use arguments to main()
 574 if test -z "$enable_main_args"; then
 575    enable_main_args=${enable_main_args_default-yes}
 576 fi
 577 if test "$enable_main_args" = no; then
 578    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 579 fi
 580
 581
 582 # Should we use hashtable-based synchronization?
 583 # Currently works only for Linux X86/ia64
 584 # Typically faster and more space-efficient
 585 AC_ARG_ENABLE(hash-synchronization,
 586   AS_HELP_STRING([--enable-hash-synchronization],
 587                  [use global hash table for monitor locks]))
 588
 589 if test -z "$enable_hash_synchronization"; then
 590    enable_hash_synchronization=$enable_hash_synchronization_default
 591 fi
 592
 593
 594 install_ecj_jar=no
 595 ECJ_BUILD_JAR=
 596 ECJ_JAR=
 597 AC_ARG_WITH(ecj-jar,
 598         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 599         [ECJ_JAR=$withval],
 600         [if test -f $multi_basedir/ecj.jar; then
 601            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 602            ECJ_JAR='$(jardir)/ecj.jar'
 603            install_ecj_jar=yes
 604          fi])
 605 AC_SUBST(ECJ_BUILD_JAR)
 606 AC_SUBST(ECJ_JAR)
 607 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 608 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 609
 610 AC_ARG_WITH(java-home,
 611   AS_HELP_STRING([--with-java-home=DIRECTORY],
 612                  [value of java.home system property]),
 613                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 614 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 615 AC_SUBST(JAVA_HOME)
 616
 617 suppress_libgcj_bc=no
 618 AC_ARG_ENABLE(libgcj-bc,
 619   AS_HELP_STRING([--enable-libgcj-bc],
 620                  [enable(default) or disable BC ABI for portions of libgcj]),
 621   [if test "$enable_libgcj_bc" = "no"; then
 622      suppress_libgcj_bc=yes
 623    fi])
 624 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 625
 626 build_libgcj_reduced_reflection=no
 627 AC_ARG_ENABLE(reduced-reflection,
 628   AS_HELP_STRING([--enable-reduced-reflection],
 629                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 630   [if test "$enable_reduced_reflection" = "yes"; then
 631      build_libgcj_reduced_reflection=yes
 632    fi])
 633 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 634
 635 # What is the native OS API for MinGW?
 636 AC_ARG_WITH(win32-nlsapi,
 637   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 638                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 639 [case "${withval}" in
 640   ansi) with_win32_nlsapi=ansi ;;
 641   unicows) with_win32_nlsapi=unicows ;;
 642   unicode) with_win32_nlsapi=unicode ;;
 643   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 644 esac],[with_win32_nlsapi=ansi])
 645
 646 case "${with_win32_nlsapi}" in
 647   unicows | unicode)
 648     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 649       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 650     ;;
 651 esac
 652
 653 # configure.host sets slow_pthread_self if the synchronization code should
 654 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 655 if test "${slow_pthread_self}" = "yes"; then
 656   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 657     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 658 fi
 659
 660 # Check for gc debugging.  This option is handled both here and in the GC.
 661 AC_ARG_ENABLE(gc-debug,
 662    AS_HELP_STRING([--enable-gc-debug],
 663                   [include full support for pointer backtracing etc.]),
 664 [ if test "$enable_gc_debug" = "yes"; then
 665     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 666               [Define if we want to use debug calls into the garbage collector.])
 667   fi])
 668
 669 # See if the user has the interpreter included.
 670 AC_ARG_ENABLE(interpreter,
 671   AS_HELP_STRING([--enable-interpreter],
 672                  [enable interpreter]),
 673   [if test "$enable_interpreter" = yes; then
 674     # This can also be set in configure.host.
 675     libgcj_interpreter=yes
 676   elif test "$enable_interpreter" = no; then
 677     libgcj_interpreter=no
 678   fi])
 679
 680 if test "$libgcj_interpreter" = yes; then
 681    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 682 fi
 683 INTERPRETER="$libgcj_interpreter"
 684 AC_SUBST(INTERPRETER)
 685 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 686
 687 AC_MSG_CHECKING([for exception model to use])
 688 AC_LANG_PUSH(C++)
 689 AC_ARG_ENABLE(sjlj-exceptions,
 690   AS_HELP_STRING([--enable-sjlj-exceptions],
 691                  [force use of builtin_setjmp for exceptions]),
 692 [:],
 693 [dnl Botheration.  Now we've got to detect the exception model.
 694 dnl Link tests against libgcc.a are problematic since -- at least
 695 dnl as of this writing -- we've not been given proper -L bits for
 696 dnl single-tree newlib and libgloss.
 697 dnl
 698 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 699 dnl conftest files before we got a change to grep them first.
 700 cat > conftest.$ac_ext << EOF
 701 [#]line __oline__ "configure"
 702 struct S { ~S(); };
 703 void bar();
 704 void foo()
 705 {
 706   S s;
 707   bar();
 708 }
 709 EOF
 710 old_CXXFLAGS="$CXXFLAGS"
 711 CXXFLAGS=-S
 712 if AC_TRY_EVAL(ac_compile); then
 713   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 714     enable_sjlj_exceptions=yes
 715   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 716     enable_sjlj_exceptions=no
 717   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 718     # ARM EH ABI.
 719     enable_sjlj_exceptions=no
 720   fi
 721 fi
 722 CXXFLAGS="$old_CXXFLAGS"
 723 rm -f conftest*])
 724 if test x$enable_sjlj_exceptions = xyes; then
 725   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 726         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 727   ac_exception_model_name=sjlj
 728 elif test x$enable_sjlj_exceptions = xno; then
 729   ac_exception_model_name="call frame"
 730 else
 731   AC_MSG_ERROR([unable to detect exception model])
 732 fi
 733 AC_LANG_POP(C++)
 734 AC_MSG_RESULT($ac_exception_model_name)
 735
 736 # If we are non using SJLJ exceptions, and this host does not have support
 737 # for unwinding from a signal handler, enable checked dereferences and divides.
 738 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 739   CHECKREFSPEC=-fcheck-references
 740   DIVIDESPEC=-fuse-divide-subroutine
 741   EXCEPTIONSPEC=
 742 fi
 743
 744 # See if the user wants to disable java.net.  This is the mildly
 745 # ugly way that we admit that target-side configuration sucks.
 746 AC_ARG_ENABLE(java-net,
 747   AS_HELP_STRING([--disable-java-net],
 748                  [disable java.net]))
 749
 750 # Whether java.net is built by default can depend on the target.
 751 if test -z "$enable_java_net"; then
 752    enable_java_net=${enable_java_net_default-yes}
 753 fi
 754 if test "$enable_java_net" = no; then
 755    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 756 fi
 757
 758 # See if the user wants to configure without libffi.  Some
 759 # architectures don't support it, and default values are set in
 760 # configure.host.
 761 AC_ARG_WITH(libffi,
 762   AS_HELP_STRING([--without-libffi],
 763                  [don't use libffi]),
 764   [:],
 765   [with_libffi=${with_libffi_default-yes}])
 766
 767 LIBFFI=
 768 LIBFFIINCS=
 769 if test "$with_libffi" != no; then
 770    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 771    LIBFFI=../libffi/libffi_convenience.la
 772    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 773 fi
 774 AC_SUBST(LIBFFI)
 775 AC_SUBST(LIBFFIINCS)
 776
 777 # See if the user wants to disable JVMPI support.
 778 AC_ARG_ENABLE(jvmpi,
 779   AS_HELP_STRING([--disable-jvmpi],
 780                  [disable JVMPI support]))
 781
 782 if test "$enable_jvmpi" != no; then
 783     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 784 fi
 785
 786 # If the target is an eCos system, use the appropriate eCos
 787 # I/O routines.
 788 # FIXME: this should not be a local option but a global target
 789 # system; at present there is no eCos target.
 790 TARGET_ECOS=${PROCESS-"no"}
 791 AC_ARG_WITH(ecos,
 792 [  --with-ecos             enable runtime eCos target support],
 793 TARGET_ECOS="$with_ecos"
 794 )
 795
 796 case "$TARGET_ECOS" in
 797    no) case "$host" in
 798       *mingw*)
 799             PLATFORM=Win32
 800             PLATFORMNET=Win32
 801             PLATFORMH=win32.h
 802         CHECK_FOR_BROKEN_MINGW_LD
 803       ;;
 804       *)
 805             PLATFORM=Posix
 806             PLATFORMNET=Posix
 807             PLATFORMH=posix.h
 808       ;;
 809       esac
 810       ;;
 811    *)
 812       PLATFORM=Ecos
 813       PLATFORMNET=NoNet
 814       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 815       PLATFORMH=posix.h
 816       ;;
 817 esac
 818 AC_SUBST(PLATFORM)
 819 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 820
 821 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 822                                       [Define if you have int32_t and uint32_t.]))
 823 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 824                                         [Define if you have int32_t and uint32_t.]))
 825 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 826                                           [Define if you have u_int32_t]))
 827 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 828                                            [Define if you have u_int32_t]))
 829
 830 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 831 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 832
 833 case "$host" in
 834   *-darwin*) DARWIN_CRT=true ;;
 835   *) DARWIN_CRT=false ;;
 836 esac
 837 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 838
 839 # This may not be defined in a non-ANS conformant embedded system.
 840 # FIXME: Should these case a runtime exception in that case?
 841 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 842                                   [Define is you have 'localtime' in <time.h>]))
 843
 844 # Create the subdirectory for natFile.cc, or the attempt
 845 # to create the link will fail.
 846 test -d java || mkdir java
 847 test -d java/io || mkdir java/io
 848 test -d gnu || mkdir gnu
 849 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 850
 851 # Likewise for natConcreteProcess.cc.
 852 test -d java/lang || mkdir java/lang
 853 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 854
 855 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 856 test -d java/net || mkdir java/net
 857 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 858 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 859
 860 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 861 test -d gnu/java || mkdir gnu/java
 862 test -d gnu/java/net || mkdir gnu/java/net
 863 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 864 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 865
 866 # Likewise for natVMPipe.cc and natVMSelector.cc.
 867 test -d gnu/java/nio || mkdir gnu/java/nio
 868 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 869 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 870
 871 # Likewise for natFileChannelImpl.cc
 872 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 873 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 874
 875 # Likewise for natVMSecureRandom.cc
 876 test -d gnu/java/security || mkdir gnu/java/security
 877 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 878 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 879 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 880
 881 case "${host}" in
 882     *mingw*)
 883       SYSTEMSPEC="-lgdi32 -lws2_32"
 884       if test "${with_win32_nlsapi}" = "unicows"; then
 885         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 886       fi
 887     ;;
 888     *-*-darwin[[912]]*)
 889       SYSTEMSPEC="%{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 890     ;;
 891     *)
 892       SYSTEMSPEC=
 893     ;;
 894 esac
 895 AC_SUBST(SYSTEMSPEC)
 896
 897 AC_ARG_WITH(system-zlib,
 898   AS_HELP_STRING([--with-system-zlib],
 899                  [use installed libz]))
 900 ZLIBSPEC=
 901 AC_SUBST(ZLIBSPEC)
 902 ZLIBTESTSPEC=
 903 AC_SUBST(ZLIBTESTSPEC)
 904
 905 AC_PATH_XTRA
 906
 907 # FIXME: this should be _libs on some hosts.
 908 libsubdir=.libs
 909
 910 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 911
 912 LIBSTDCXXSPEC=
 913 # extra LD Flags which are required for targets
 914 case "${host}" in
 915 *-*-darwin[[0-7]].*)
 916     # For now we have to disable it on darwin[8-9] because it slows down
 917     # the linking phase. A possible bug in ld?
 918     # on Darwin -single_module speeds up loading of the dynamic libraries.
 919     extra_ldflags_libjava=-Wl,-single_module
 920     ;;
 921 arm*linux*eabi)
 922     # Some of the ARM unwinder code is actually in libstdc++.  We
 923     # could in principle replicate it in libgcj, but it's better to
 924     # have a dependency on libstdc++.
 925     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 926     LIBSTDCXXSPEC=-lstdc++
 927     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 928     ;;
 929 *-*-cygwin)
 930     extra_ldflags_libjava=-liconv
 931     ;;
 932 esac
 933
 934 LIBMATHSPEC=
 935 # extra LD Flags which are required for targets
 936 case "${host}" in
 937 *-*-darwin*)
 938      ;;
 939 *)
 940      LIBMATHSPEC=-lm
 941      ;;
 942 esac
 943
 944 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 945 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 946   [saved_ldflags="$LDFLAGS"
 947    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 948    # The IRIX 6 ld doesn't recognize --no-merge-exidx-entries, but only
 949    # warns about unknown options, which breaks the testsuite.  So enable
 950    # AC_LANG_WERROR, but there's currently (autoconf 2.64) no way to turn
 951    # it off again.  As a workaround, save and restore werror flag like
 952    # AC_PATH_XTRA.
 953    ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag=$ac_[]_AC_LANG_ABBREV[]_werror_flag
 954    AC_LANG_WERROR
 955    AC_LINK_IFELSE([int main(void){ return 0;} ],
 956                       [eval "libgcj_cv_exidx=yes"],
 957                       [eval "libgcj_cv_exidx=no"])
 958    ac_[]_AC_LANG_ABBREV[]_werror_flag=$ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag
 959    LDFLAGS="${saved_ldflags}"]
 960 )
 961 if test "${libgcj_cv_exidx}" = "yes"; then
 962   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 963   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 964 fi
 965
 966 AC_SUBST(extra_ldflags_libjava)
 967 AC_SUBST(extra_ldflags)
 968 AC_SUBST(LIBSTDCXXSPEC)
 969 AC_SUBST(LIBMATHSPEC)
 970
 971 AC_SUBST(LIBGCJTESTSPEC)
 972
 973 # Allow the GC to be disabled.  Can be useful when debugging.
 974 AC_MSG_CHECKING([for garbage collector to use])
 975 AC_ARG_ENABLE(java-gc,
 976   AS_HELP_STRING([--enable-java-gc=TYPE],
 977                  [choose garbage collector (default is boehm)]),
 978   [GC=$enableval],
 979   [GC=boehm])
 980 GCLIBS=
 981 GCINCS=
 982 GCDEPS=
 983 GCSPEC=
 984 JC1GCSPEC=
 985 GCTESTSPEC=
 986 case "$GC" in
 987  boehm)
 988     AC_MSG_RESULT(boehm)
 989     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 990     JC1GCSPEC='-fuse-boehm-gc'
 991     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 992     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 993     GCOBJS=boehm.lo
 994     GCHDR=boehm-gc.h
 995     # The POSIX thread support needs to know this.
 996     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 997     ;;
 998  no)
 999     AC_MSG_RESULT(none)
1000     GCHDR=no-gc.h
1001     ;;
1002  *)
1003     AC_MSG_ERROR([unrecognized collector "$GC"])
1004     ;;
1005 esac
1006 AC_SUBST(GCLIBS)
1007 AC_SUBST(GCINCS)
1008 AC_SUBST(GCDEPS)
1009 AC_SUBST(GCSPEC)
1010 AC_SUBST(JC1GCSPEC)
1011 AC_SUBST(GCTESTSPEC)
1012 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
1013 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1014 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1015
1016
1017 AC_MSG_CHECKING([for thread model used by GCC])
1018 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1019 AC_MSG_RESULT([$THREADS])
1020
1021 case "$THREADS" in
1022  no | none | single)
1023     THREADS=none
1024     ;;
1025  aix | posix | posix95 | pthreads)
1026     THREADS=posix
1027     case "$host" in
1028      *-*-linux*)
1029         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1030         ;;
1031     esac
1032     ;;
1033  win32)
1034     ;;
1035  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1036     AC_MSG_ERROR(thread package $THREADS not yet supported)
1037     ;;
1038  *)
1039     AC_MSG_ERROR($THREADS is an unknown thread package)
1040     ;;
1041 esac
1042
1043 THREADCXXFLAGS=
1044 THREADLDFLAGS=
1045 THREADLIBS=
1046 THREADINCS=
1047 THREADDEPS=
1048 THREADH=
1049 THREADSPEC=
1050 THREADSTARTFILESPEC=
1051 case "$THREADS" in
1052  posix)
1053     case "$host" in
1054      *-*-cygwin*)
1055         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1056         ;;
1057      *-*-freebsd[[1234]]*)
1058         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1059         # merely adds pthread_* functions) but it does have a -pthread switch
1060         # which is required at link-time to select -lc_r *instead* of -lc.
1061         THREADLDFLAGS=-pthread
1062         # Don't set THREADSPEC here as might be expected since -pthread is
1063         # not processed when found within a spec file, it must come from
1064         # the command line.  For now, the user must provide the -pthread
1065         # switch to link code compiled with gcj.  In future, consider adding
1066         # support for weak references to pthread_* functions ala gthr.h API.
1067         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1068         ;;
1069      *-*-freebsd*)
1070         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1071         # systems which support threads and -lpthread.
1072         THREADLDFLAGS=-pthread
1073         THREADSPEC=-lpthread
1074         ;;
1075      alpha*-dec-osf* | hppa*-hp-hpux*)
1076         THREADCXXFLAGS=-pthread
1077         # boehm-gc needs some functions from librt, so link that too.
1078         THREADLIBS='-lpthread -lrt'
1079         THREADSPEC='-lpthread -lrt'
1080         ;;
1081      *-*-solaris2.8)
1082         # Always use alternate thread library on Solaris 8.  Need libthread
1083         # for TLS support.
1084         # Need -Wl,-R to get it through libtool ...
1085         THREADLIBS='-L/usr/lib/lwp$(MULTISUBDIR) -Wl,-R -Wl,/usr/lib/lwp$(MULTISUBDIR) -lpthread -lthread'
1086         # ... while ld only accepts -R.
1087         THREADSPEC='-L/usr/lib/lwp%{m64:/64} -R/usr/lib/lwp%{m64:/64} -lpthread -lthread'
1088         ;;
1089      *-*-solaris2.9)
1090         # As on Solaris 8, need libthread for TLS support.
1091         THREADLIBS='-lpthread -lthread'
1092         THREADSPEC='-lpthread -lthread'
1093         ;;
1094      *-*-darwin*)
1095         # Don't set THREADLIBS or THREADSPEC as Darwin already
1096         # provides pthread via libSystem.
1097         ;;
1098      *)
1099         THREADLIBS=-lpthread
1100         THREADSPEC=-lpthread
1101         ;;
1102     esac
1103     THREADH=posix-threads.h
1104     # MIT pthreads doesn't seem to have the mutexattr functions.
1105     # But for now we don't check for it.  We just assume you aren't
1106     # using MIT pthreads.
1107     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1108
1109     # If we're using the Boehm GC, then we happen to know that it
1110     # defines _REENTRANT, so we don't bother.  Eww.
1111     if test "$GC" != boehm; then
1112        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1113     fi
1114     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1115     ;;
1116
1117  win32)
1118     THREADH=win32-threads.h
1119     THREADCXXFLAGS=-mthreads
1120     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1121     # But we do not want the executables created to be dependent on
1122     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1123     # exception handling contexts.  The following kludge achieves this effect
1124     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1125     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1126     # A workaround is to explicitly use -mthreads while linking Java programs.
1127     # See PR libgcj/28263.
1128     #
1129     # FIXME: In Java we are able to detect thread death at the end of
1130     # Thread.run() so we should be able to clean up the exception handling
1131     # contexts ourselves.
1132     THREADSTARTFILESPEC='crtmt%O%s'
1133     ;;
1134
1135  none)
1136     THREADH=no-threads.h
1137     ;;
1138 esac
1139 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1140 AC_SUBST(THREADLIBS)
1141 AC_SUBST(THREADINCS)
1142 AC_SUBST(THREADDEPS)
1143 AC_SUBST(THREADSPEC)
1144 AC_SUBST(THREADSTARTFILESPEC)
1145 AC_SUBST(THREADLDFLAGS)
1146 AC_SUBST(THREADCXXFLAGS)
1147 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1148 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1149 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1150 if test "$enable_shared" != yes; then
1151   use_libgcj_bc=no
1152 fi
1153 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1154
1155 if test -d sysdep; then true; else mkdir sysdep; fi
1156 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1157 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1158 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1159
1160 LIBGCJ_SPEC_LGCJ=-lgcj
1161 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1162 if test x"$libgcj_spec_lgcj_override" != x ; then
1163   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1164 fi
1165 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1166   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1167 fi
1168 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1169 if test "$use_libgcj_bc" = yes; then
1170   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1171   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1172 fi
1173 AC_SUBST(LIBGCJ_SPEC)
1174 AC_SUBST(LIBGCJ_BC_SPEC)
1175
1176 HASH_SYNC_SPEC=
1177 # Hash synchronization is only useful with posix threads right now.
1178 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1179    HASH_SYNC_SPEC=-fhash-synchronization
1180    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1181 fi
1182 AC_SUBST(HASH_SYNC_SPEC)
1183
1184 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1185
1186 # We're in the tree with gcc, and need to include some of its headers.
1187 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1188
1189 if test "x${with_newlib}" = "xyes"; then
1190    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1191    # may not work correctly, because the compiler may not be able to
1192    # link executables.
1193
1194    # We assume newlib.  This lets us hard-code the functions we know
1195    # we'll have.
1196    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1197    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1198    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1199    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1200    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1201    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1202    # This is only for POSIX threads.
1203    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1204
1205    # Assume we do not have getuid and friends.
1206    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1207    PLATFORMNET=NoNet
1208 else
1209    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1210                    localtime_r getpwuid_r getcwd \
1211                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1212                    nl_langinfo setlocale \
1213                    inet_pton uname inet_ntoa \
1214                    getrlimit sigaction ftruncate mmap \
1215                    getifaddrs])
1216    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1217    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1218    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1219    AC_CHECK_LIB(dl, dladdr, [
1220        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1221        AC_CHECK_LIB(dld, dladdr, [
1222        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1223
1224    if test x"$cross_compiling" = x"no"; then
1225      AC_CHECK_FILES(/proc/self/exe, [
1226        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1227      AC_CHECK_FILES(/proc/self/maps, [
1228        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1229          [Define if you have /proc/self/maps])])
1230    else
1231      case $host in
1232      *-linux*)
1233        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1234        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1235        ;;
1236      esac
1237    fi
1238
1239    AM_ICONV
1240    AM_LC_MESSAGES
1241    AC_STRUCT_TIMEZONE
1242
1243    AC_CHECK_FUNCS(gethostbyname_r, [
1244      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1245        [Define if you have the 'gethostbyname_r' function.])
1246      # There are two different kinds of gethostbyname_r.
1247      # We look for the one that returns `int'.
1248      # Hopefully this check is robust enough.
1249      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1250        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1251
1252      case " $GCINCS " in
1253      *" -D_REENTRANT "*) ;;
1254      *)
1255         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1256         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1257         [libjava_cv_gethostbyname_r_needs_reentrant],
1258         [ AC_LANG_PUSH(C++)
1259           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1260             [[gethostbyname_r("", 0, 0);]])],
1261             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1262                 CPPFLAGS_SAVE="$CPPFLAGS"
1263                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1264                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1265                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1266                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1267                 CPPFLAGS="$CPPFLAGS_SAVE"
1268           ])
1269           AC_LANG_POP(C++)
1270         ])
1271         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1272           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1273         fi
1274      ;;
1275      esac
1276
1277      AC_CACHE_CHECK([for struct hostent_data],
1278         [libjava_cv_struct_hostent_data], [dnl
1279         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1280 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1281 # define _REENTRANT 1
1282 #endif
1283 #include <netdb.h>]], [[struct hostent_data data;]])],
1284           [libjava_cv_struct_hostent_data=yes],
1285           [libjava_cv_struct_hostent_data=no])])
1286      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1287        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1288          [Define if struct hostent_data is defined in netdb.h])
1289      fi
1290    ])
1291
1292    # FIXME: libjava source code expects to find a prototype for
1293    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1294    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1295    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1296    # linkage check is enough, yet C++ code requires proper prototypes.)
1297    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1298    AC_CHECK_FUNCS(gethostbyaddr_r, [
1299      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1300        [Define if you have the 'gethostbyaddr_r' function.])
1301      # There are two different kinds of gethostbyaddr_r.
1302      # We look for the one that returns `int'.
1303      # Hopefully this check is robust enough.
1304      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1305        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1306          [Define if gethostbyaddr_r returns 'int'.])])])])
1307
1308    AC_CHECK_FUNCS(gethostname, [
1309      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1310        [Define if you have the 'gethostname' function.])
1311      AC_EGREP_HEADER(gethostname, unistd.h, [
1312        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1313          [Define if gethostname is declared in <unistd.h>.])])])
1314
1315    AC_CHECK_FUNCS(usleep, [
1316      AC_EGREP_HEADER(usleep, unistd.h, [
1317        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1318           [Define if usleep is declared in <unistd.h>.])])])
1319
1320    # Look for these functions in the thread library, but only bother
1321    # if using POSIX threads.
1322    if test "$THREADS" = posix; then
1323       save_LIBS="$LIBS"
1324       LIBS="$LIBS $THREADLIBS"
1325
1326       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1327       # Solaris 7 the name librt is preferred.
1328       AC_CHECK_FUNCS(sched_yield, , [
1329         AC_CHECK_LIB(rt, sched_yield, [
1330           AC_DEFINE(HAVE_SCHED_YIELD)
1331           THREADLIBS="$THREADLIBS -lrt"
1332           THREADSPEC="$THREADSPEC -lrt"], [
1333           AC_CHECK_LIB(posix4, sched_yield, [
1334             AC_DEFINE(HAVE_SCHED_YIELD)
1335             THREADLIBS="$THREADLIBS -lposix4"
1336             THREADSPEC="$THREADSPEC -lposix4"])])])
1337
1338       AC_CHECK_LIB(rt, clock_gettime, [
1339          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1340          case "$THREADSPEC" in
1341            *-lrt*) ;;
1342            *)
1343              THREADSPEC="$THREADSPEC -lrt"
1344              THREADLIBS="$THREADLIBS -lrt"
1345              ;;
1346          esac])
1347
1348       LIBS="$save_LIBS"
1349
1350       # We can save a little space at runtime if the mutex has m_count
1351       # or __m_count.  This is a nice hack for Linux.
1352       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1353           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1354         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1355              [Define if pthread_mutex_t has m_count member.]), [
1356         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1357             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1358           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1359             [Define if pthread_mutex_t has __m_count member.]))])
1360    fi
1361
1362    # We require a way to get the time.
1363    time_found=no
1364    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1365    if test "$time_found" = no; then
1366       AC_MSG_ERROR([no function found to get the time])
1367    fi
1368
1369    AC_CHECK_FUNCS(memmove)
1370
1371    # We require memcpy.
1372    memcpy_found=no
1373    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1374    if test "$memcpy_found" = no; then
1375       AC_MSG_ERROR([memcpy is required])
1376    fi
1377    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1378    AC_CHECK_LIB(dl, dlopen, [
1379        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1380        AC_CHECK_LIB(dld, dlopen, [
1381        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1382
1383    # Some library-finding code we stole from Tcl.
1384    #--------------------------------------------------------------------
1385    #    Check for the existence of the -lsocket and -lnsl libraries.
1386    #    The order here is important, so that they end up in the right
1387    #    order in the command line generated by make.  Here are some
1388    #    special considerations:
1389    #    1. Use "connect" and "accept" to check for -lsocket, and
1390    #       "gethostbyname" to check for -lnsl.
1391    #    2. Use each function name only once:  can't redo a check because
1392    #       autoconf caches the results of the last check and won't redo it.
1393    #    3. Use -lnsl and -lsocket only if they supply procedures that
1394    #       aren't already present in the normal libraries.  This is because
1395    #       IRIX 5.2 has libraries, but they aren't needed and they're
1396    #       bogus:  they goof up name resolution if used.
1397    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1398    #       To get around this problem, check for both libraries together
1399    #       if -lsocket doesn't work by itself.
1400    #--------------------------------------------------------------------
1401
1402    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1403     [gcj_cv_lib_sockets=
1404      gcj_checkBoth=0
1405      unset ac_cv_func_connect
1406      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1407      if test "$gcj_checkSocket" = 1; then
1408          unset ac_cv_func_connect
1409          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1410                       gcj_checkBoth=1)
1411      fi
1412      if test "$gcj_checkBoth" = 1; then
1413          gcj_oldLibs=$LIBS
1414          LIBS="$LIBS -lsocket -lnsl"
1415          unset ac_cv_func_accept
1416          AC_CHECK_FUNC(accept,
1417                        [gcj_checkNsl=0
1418                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1419          unset ac_cv_func_accept
1420          LIBS=$gcj_oldLibs
1421      fi
1422      unset ac_cv_func_gethostbyname
1423      gcj_oldLibs=$LIBS
1424      LIBS="$LIBS $gcj_cv_lib_sockets"
1425      AC_CHECK_FUNC(gethostbyname, ,
1426                    [AC_CHECK_LIB(nsl, main,
1427                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1428      unset ac_cv_func_gethostbyname
1429      LIBS=$gcj_oldLIBS
1430    ])
1431    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1432
1433    if test "$with_system_zlib" = yes; then
1434       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1435    fi
1436
1437    # Test for Gtk stuff, if asked for.
1438    if test "$use_gtk_awt" = yes; then
1439       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1440       AC_SUBST(GTK_CFLAGS)
1441       AC_SUBST(GTK_LIBS)
1442
1443       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1444       AC_SUBST(GLIB_CFLAGS)
1445       AC_SUBST(GLIB_LIBS)
1446
1447       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1448       AC_SUBST(LIBART_CFLAGS)
1449       AC_SUBST(LIBART_LIBS)
1450
1451       # We require the XTest Extension to support java.awt.Robot.
1452       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1453                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1454                    [${X_LIBS}])
1455    fi
1456
1457    # On Solaris, and maybe other architectures, the Boehm collector
1458    # requires -ldl.
1459    if test "$GC" = boehm; then
1460       case "${host}" in
1461           mips-sgi-irix6*)
1462             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1463             # libgcj.spec is used, so override here
1464             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1465           ;;
1466           *-*-darwin*)
1467           ;;
1468           *)
1469             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1470           ;;
1471       esac
1472    fi
1473 fi
1474
1475 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1476 case $build in
1477     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1478     *)         CLASSPATH_SEPARATOR=':' ;;
1479 esac
1480 AC_SUBST(CLASSPATH_SEPARATOR)
1481
1482 # We must search the source tree for java.lang, since we still don't
1483 # have libgcj.jar nor java/lang/*.class
1484 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1485 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1486
1487 # Since some classes depend on this one, we need its source available
1488 # before we can do any GCJ compilation test :-(
1489 if test ! -f gnu/classpath/Configuration.java; then
1490   test -d gnu || mkdir gnu
1491   test -d gnu/classpath || mkdir gnu/classpath
1492   # Note that it is not crucial that all the values here be correct.
1493   sed -e "s,@prefix@,$expanded_prefix," \
1494       -e "s,@VERSION@,$VERSION," \
1495       -e "s,@LIBDEBUG@,false," \
1496       -e "s,@INIT_LOAD_LIBRARY@,false," \
1497       -e "s,@@,$LIBGCJDEBUG," \
1498       -e "s,@default_toolkit@,$TOOLKIT," \
1499       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1500       -e "s,@GTK_CAIRO_ENABLED@,false," \
1501       -e "s,@ECJ_JAR@,," \
1502       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1503         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1504         > gnu/classpath/Configuration.java
1505   # We do not want to redirect the output of the grep below to /dev/null,
1506   # but we add /dev/null to the input list so that grep will print the
1507   # filename of Configuration.java in case it finds any matches.
1508   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1509     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1510   fi
1511 fi
1512
1513 LT_AC_PROG_GCJ
1514
1515 # Now remove it.
1516 rm -f gnu/classpath/Configuration.java
1517
1518 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1519
1520 AC_CHECK_SIZEOF(void *)
1521
1522 AC_C_BIGENDIAN
1523
1524 ZLIBS=
1525 SYS_ZLIBS=
1526 ZINCS=
1527
1528 if test -z "$ZLIBSPEC"; then
1529    # Use zlib from the GCC tree.
1530    ZINCS='-I$(top_srcdir)/../zlib'
1531    ZLIBS=../zlib/libzgcj_convenience.la
1532 else
1533    # System's zlib.
1534    SYS_ZLIBS="$ZLIBSPEC"
1535 fi
1536 AC_SUBST(ZLIBS)
1537 AC_SUBST(SYS_ZLIBS)
1538 AC_SUBST(ZINCS)
1539 AC_SUBST(DIVIDESPEC)
1540 AC_SUBST(CHECKREFSPEC)
1541 AC_SUBST(EXCEPTIONSPEC)
1542 AC_SUBST(BACKTRACESPEC)
1543 AC_SUBST(IEEESPEC)
1544 AC_SUBST(ATOMICSPEC)
1545
1546 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1547 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1548 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1549 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1550 AC_SUBST(GCC_UNWIND_INCLUDE)
1551
1552 # Process the option "--enable-version-specific-runtime-libs"
1553 # Calculate toolexeclibdir
1554 case ${version_specific_libs} in
1555   yes)
1556     # Need the gcc compiler version to know where to install libraries
1557     # and header files if --enable-version-specific-runtime-libs option
1558     # is selected.
1559     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1560     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1561     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1562     toolexeclibdir=$toolexecmainlibdir
1563     ;;
1564   no)
1565     if test -n "$with_cross_host" &&
1566        test x"$with_cross_host" != x"no"; then
1567       # Install a library built with a cross compiler in tooldir, not libdir.
1568       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1569       toolexecmainlibdir='$(toolexecdir)/lib'
1570     else
1571       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1572       toolexecmainlibdir='$(libdir)'
1573     fi
1574     multi_os_directory=`$CC -print-multi-os-directory`
1575     case $multi_os_directory in
1576       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1577       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1578     esac
1579     ;;
1580 esac
1581 AC_SUBST(toolexecdir)
1582 AC_SUBST(toolexecmainlibdir)
1583 AC_SUBST(toolexeclibdir)
1584
1585 # Determine gcj and libgcj version number.
1586 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1587 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1588 GCJVERSION=$gcjversion
1589 AC_SUBST(GCJVERSION)
1590 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1591
1592 # Determine where the standard .db file and GNU Classpath JNI
1593 # libraries are found.
1594 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1595 multi_os_directory=`$CC -print-multi-os-directory`
1596 case $multi_os_directory in
1597   .)
1598    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1599    ;;
1600   *)
1601    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1602    ;;
1603 esac
1604 AC_SUBST(dbexecdir)
1605 AC_SUBST(gcjsubdir)
1606
1607 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1608 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1609
1610 TL_AC_GXX_INCLUDE_DIR
1611
1612 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1613 # On that system, sys/ioctl.h will not include sys/filio.h unless
1614 # BSD_COMP is defined; just including sys/filio.h is simpler.
1615 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1616 # for now.  If you change this, you also must update natFile.cc.
1617 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1618                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1619                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1620                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1621                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1622
1623 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1624 AC_CHECK_HEADERS(net/if.h, [], [], [
1625 #ifdef HAVE_SYS_SOCKET_H
1626 #include <sys/socket.h>
1627 #endif
1628 ])
1629
1630 AC_CHECK_HEADERS(inttypes.h, [
1631     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1632     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1633 ])
1634
1635 AC_CHECK_TYPE([ssize_t], [int])
1636 AC_CHECK_TYPE([magic_t], [
1637     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1638 #ifdef HAVE_MAGIC_H
1639 #include <magic.h>
1640 #endif])
1641
1642 AC_MSG_CHECKING([for in_addr_t])
1643 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1644 #if STDC_HEADERS
1645 #include <stdlib.h>
1646 #include <stddef.h>
1647 #endif
1648 #if HAVE_NETINET_IN_H
1649 #include <netinet/in.h>
1650 #endif]], [[in_addr_t foo;]])],
1651   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1652      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1653    AC_MSG_RESULT(yes)],
1654   [AC_MSG_RESULT(no)])
1655
1656 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1657 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1658   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1659      [Define if struct ip_mreq is defined in netinet/in.h.])
1660    AC_MSG_RESULT(yes)],
1661   [AC_MSG_RESULT(no)])
1662
1663 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1664 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1665   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1666      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1667    AC_MSG_RESULT(yes)],
1668   [AC_MSG_RESULT(no)])
1669
1670 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1671 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1672   [AC_DEFINE(HAVE_INET6, 1,
1673      [Define if inet6 structures are defined in netinet/in.h.])
1674    AC_MSG_RESULT(yes)],
1675   [AC_MSG_RESULT(no)])
1676
1677 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1678 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1679 #include <sys/types.h>
1680 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1681   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1682    AC_MSG_RESULT(yes)],
1683   [AC_MSG_RESULT(no)])
1684
1685 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1686 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1687   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1688    AC_MSG_RESULT(yes)],
1689   [AC_MSG_RESULT(no)
1690    AC_MSG_CHECKING([for global timezone variable])
1691    dnl FIXME: we don't want a link check here because that won't work
1692    dnl when cross-compiling.  So instead we make an assumption that
1693    dnl the header file will mention timezone if it exists.
1694    dnl Don't find the win32 function timezone
1695    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1696      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1697       AC_MSG_RESULT(yes)],
1698      [AC_MSG_RESULT(no)
1699        AC_MSG_CHECKING([for global _timezone variable])
1700        dnl FIXME: As above, don't want link check
1701        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1702          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1703             [Define if your platform has the global _timezone variable.])
1704           AC_MSG_RESULT(yes)],
1705           [AC_MSG_RESULT(no)])])])
1706
1707 AC_CHECK_PROGS(PERL, perl, false)
1708
1709 SYSDEP_SOURCES=
1710 SIGNAL_HANDLER_AUX=
1711
1712 case "${host}" in
1713  i?86-*-linux*)
1714     SIGNAL_HANDLER=include/i386-signal.h
1715     ;;
1716  *-*-solaris2*)
1717     SIGNAL_HANDLER=include/solaris-signal.h
1718     ;;
1719 # ia64-*)
1720 #    SYSDEP_SOURCES=sysdep/ia64.c
1721 #    test -d sysdep || mkdir sysdep
1722 #    ;;
1723  hppa*-*-linux*)
1724     SIGNAL_HANDLER=include/pa-signal.h
1725     ;;
1726  hppa*-hp-hpux*)
1727     SIGNAL_HANDLER=include/hppa-signal.h
1728     ;;
1729  ia64-*-linux*)
1730     SIGNAL_HANDLER=include/dwarf2-signal.h
1731     ;;
1732  powerpc*-*-linux*)
1733     SIGNAL_HANDLER=include/powerpc-signal.h
1734     ;;
1735  alpha*-*-linux*)
1736     SIGNAL_HANDLER=include/dwarf2-signal.h
1737     ;;
1738  s390*-*-linux*)
1739     SIGNAL_HANDLER=include/s390-signal.h
1740     ;;
1741  x86_64*-*-linux*)
1742     SIGNAL_HANDLER=include/x86_64-signal.h
1743     SIGNAL_HANDLER_AUX=include/i386-signal.h
1744     ;;
1745  sparc*-*-linux*)
1746     SIGNAL_HANDLER=include/dwarf2-signal.h
1747     ;;
1748  sh*-*-linux*)
1749     SIGNAL_HANDLER=include/sh-signal.h
1750     ;;
1751  *mingw*)
1752     SIGNAL_HANDLER=include/win32-signal.h
1753     ;;
1754  mips*-*-linux*)
1755     SIGNAL_HANDLER=include/mips-signal.h
1756     ;;
1757  m68*-*-linux*)
1758     SIGNAL_HANDLER=include/dwarf2-signal.h
1759     ;;
1760  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1761     SIGNAL_HANDLER=include/darwin-signal.h
1762     ;;
1763  powerpc*-*-aix*)
1764     SIGNAL_HANDLER=include/aix-signal.h
1765     ;;
1766  *)
1767     SIGNAL_HANDLER=include/default-signal.h
1768     ;;
1769 esac
1770
1771 # If we're using sjlj exceptions, forget what we just learned.
1772 if test "$enable_sjlj_exceptions" = yes; then
1773    SIGNAL_HANDLER=include/default-signal.h
1774    SIGNAL_HANDLER_AUX=
1775 fi
1776
1777 AC_SUBST(SYSDEP_SOURCES)
1778
1779 if test -z "$SIGNAL_HANDLER_AUX"; then
1780   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1781 fi
1782
1783 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1784                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1785
1786 if test "${multilib}" = "yes"; then
1787   multilib_arg="--enable-multilib"
1788 else
1789   multilib_arg=
1790 fi
1791
1792 # See if we support thread-local storage.
1793 GCC_CHECK_TLS
1794
1795 # For _Unwind_GetIPInfo.
1796 GCC_CHECK_UNWIND_GETIPINFO
1797
1798 # See if linker supports anonymous version scripts.
1799 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1800   [libjava_cv_anon_version_script],
1801   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1802    libjava_cv_anon_version_script=no
1803    CFLAGS="$CFLAGS -fPIC";
1804    LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1805    echo '{ global: globalsymb*; local: *; };' > conftest.map
1806    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1807                [libjava_cv_anon_version_script=gnu], [])
1808    if test x$libjava_cv_anon_version_script = xno; then
1809      case "$target_os" in
1810        solaris2*)
1811          LDFLAGS="$save_LDFLAGS"
1812          LDFLAGS="$LDFLAGS -shared -Wl,-M,conftest.map"
1813          # Sun ld doesn't understand wildcards here.
1814          echo '{ global: globalsymbol; local: *; };' > conftest.map
1815          AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1816                      [libjava_cv_anon_version_script=sun], [])
1817          ;;
1818      esac
1819    fi
1820    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1821   ])
1822 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" != no)
1823 AM_CONDITIONAL(ANONVERSCRIPT_GNU, test "$libjava_cv_anon_version_script" = gnu)
1824 AM_CONDITIONAL(ANONVERSCRIPT_SUN, test "$libjava_cv_anon_version_script" = sun)
1825
1826 # Check if linker supports static linking on a per library basis
1827 LD_START_STATIC_SPEC=
1828 LD_FINISH_STATIC_SPEC=
1829 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1830   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1831     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1832     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1833   fi
1834 fi
1835 AC_SUBST(LD_START_STATIC_SPEC)
1836 AC_SUBST(LD_FINISH_STATIC_SPEC)
1837
1838 here=`${PWDCMD-pwd}`
1839 AC_SUBST(here)
1840
1841 # We get this from the environment.
1842 AC_SUBST(GCJFLAGS)
1843
1844 AC_ARG_WITH([python-dir],
1845             AS_HELP_STRING([--with-python-dir],
1846                            [the location to install Python modules. This path should NOT include the prefix.]),
1847             [with_python_dir=$withval], [with_python_dir=""])
1848
1849 if test "x${with_python_dir}" = "x"
1850 then
1851   # Needed for installing Python modules during make install.
1852   python_mod_dir="\${prefix}/share/python"
1853   # Needed for substituting into aot-compile*
1854   python_mod_dir_expanded="${expanded_prefix}/share/python"
1855 else
1856   python_mod_dir="\${prefix}${with_python_dir}"
1857   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1858 fi
1859 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1860 AC_SUBST(python_mod_dir)
1861 AC_SUBST(python_mod_dir_expanded)
1862
1863 # needed for aot-compile-rpm
1864 MAKE=`which make`
1865 AC_SUBST(MAKE)
1866
1867 AC_ARG_ENABLE([aot-compile-rpm],
1868   [AS_HELP_STRING([--enable-aot-compile-rpm],
1869                  [enable installation of aot-compile-rpm [default=no]])],
1870   [case "${enableval}" in
1871     yes) AOT_RPM_ENABLED=yes ;;
1872     no)  AOT_RPM_ENABLED=no ;;
1873     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1874   esac],
1875   [AOT_RPM_ENABLED=no]
1876 )
1877 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1878
1879 AC_ARG_ENABLE([java-home],
1880   [AS_HELP_STRING([--enable-java-home],
1881                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1882   [case "${enableval}" in
1883     yes) JAVA_HOME_ENABLED=yes ;;
1884     no)  JAVA_HOME_ENABLED=no ;;
1885     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1886   esac],
1887   [JAVA_HOME_ENABLED=no]
1888 )
1889 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1890
1891 # Only do these checks if java-home above is enabled.
1892 if test "x${JAVA_HOME_ENABLED}" = xyes
1893 then
1894
1895   AC_ARG_WITH([gcc-suffix],
1896               AS_HELP_STRING([--with-gcc-suffix],
1897                              [the GCC tool suffix (defaults to empty string)]),
1898               [gcc_suffix=$withval], [gcc_suffix=""])
1899   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1900   AC_SUBST(gcc_suffix)
1901
1902   AC_ARG_WITH([arch-directory],
1903               AS_HELP_STRING([--with-arch-directory],
1904                              [the arch directory under jre/lib (defaults to auto-detect)]),
1905               [host_cpu=$withval], [host_cpu=""])
1906
1907   AC_ARG_WITH([os-directory],
1908               AS_HELP_STRING([--with-os-directory],
1909                              [the os directory under include (defaults to auto-detect)]),
1910               [host_os=$withval], [host_os=""])
1911
1912   AC_ARG_WITH([origin-name],
1913               AS_HELP_STRING([--with-origin-name],
1914                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1915               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1916   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1917
1918   AC_ARG_WITH([arch-suffix],
1919               AS_HELP_STRING([--with-arch-suffix],
1920                              [the arch directory suffix (default is the empty string]),
1921               [arch_suffix=$withval], [arch_suffix=""])
1922   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1923
1924   AC_ARG_WITH([jvm-root-dir],
1925               AS_HELP_STRING([--with-jvm-root-dir],
1926                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1927               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1928   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1929
1930   AC_ARG_WITH([jvm-jar-dir],
1931               AS_HELP_STRING([--with-jvm-jar-dir],
1932                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1933               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1934   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1935
1936   JAVA_VERSION=1.5.0
1937   BUILD_VERSION=0
1938   AC_SUBST(JAVA_VERSION)
1939   AC_SUBST(BUILD_VERSION)
1940   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1941
1942   jre_dir=jre
1943   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1944   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1945
1946   JVM_ROOT_DIR=${jvm_root_dir}
1947   AC_SUBST(JVM_ROOT_DIR)
1948   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1949
1950   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1951   AC_SUBST(JVM_JAR_ROOT_DIR)
1952   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1953
1954   JVM_JAR_DIR=${jvm_jar_dir}
1955   AC_SUBST(JVM_JAR_DIR)
1956   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1957
1958   JRE_DIR=${jre_dir}
1959   AC_SUBST(JRE_DIR)
1960
1961   JRE_LNK=${jre_lnk}
1962   AC_SUBST(JRE_LNK)
1963
1964   SDK_LNK=${sdk_lnk}
1965   AC_SUBST(SDK_LNK)
1966
1967   SDK_BIN_DIR=${jvm_root_dir}/bin
1968   AC_SUBST(SDK_BIN_DIR)
1969   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1970
1971   SDK_LIB_DIR=${jvm_root_dir}/lib
1972   AC_SUBST(SDK_LIB_DIR)
1973   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1974
1975   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1976   AC_SUBST(SDK_INCLUDE_DIR)
1977   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1978
1979   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1980   AC_SUBST(JRE_BIN_DIR)
1981   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1982
1983   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1984   AC_SUBST(JRE_LIB_DIR)
1985   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1986
1987   # Find gcj prefix using gcj found in PATH.
1988   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1989
1990   # Where do the gcj binaries live?
1991   # For jhbuild based builds, they all live in a sibling of bin called
1992   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1993   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1994   AC_SUBST(GCJ_BIN_DIR)
1995   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1996
1997   AC_MSG_RESULT(host is ${host})
1998   if test "x${host_cpu}" = "x"
1999   then
2000     case ${host} in
2001       *-mingw* | *-cygwin*)
2002         host_cpu=x86;;
2003       i486-* | i586-* | i686-*)
2004         host_cpu=i386;;
2005       x86_64-*)
2006         host_cpu=amd64;;
2007       *)
2008         host_cpu=${host_cpu};;
2009     esac
2010   fi
2011   AC_MSG_RESULT(arch directory: ${host_cpu})
2012   CPU=${host_cpu}
2013   AC_SUBST(CPU)
2014
2015   if test "x${host_os}" = "x"
2016   then
2017     case ${host} in
2018       *-mingw* | *-cygwin*)
2019         host_os=win32;;
2020       *-linux*)
2021         host_os=linux;;
2022       *)
2023         host_os=${host_os};;
2024     esac
2025   fi
2026   echo os directory: ${host_os}
2027   OS=${host_os}
2028   AC_SUBST(OS)
2029
2030   # make an expanded $libdir, for substituting into
2031   # scripts (and other non-Makefile things).
2032   LIBDIR=$libdir
2033   if test "x${exec_prefix}" = "xNONE"
2034   then
2035       lib_exec_prefix=$expanded_prefix
2036   else
2037       lib_exec_prefix=$exec_prefix
2038   fi
2039   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
2040   AC_SUBST(LIBDIR)
2041 fi
2042
2043 AC_CONFIG_FILES([
2044 Makefile
2045 libgcj.pc
2046 libgcj.spec
2047 libgcj-test.spec
2048 gcj/Makefile
2049 include/Makefile
2050 testsuite/Makefile
2051 contrib/aotcompile.py
2052 contrib/aot-compile
2053 contrib/aot-compile-rpm
2054 contrib/generate-cacerts.pl
2055 contrib/rebuild-gcj-db
2056 ])
2057
2058 if test ${multilib} = yes; then
2059   multilib_arg="--enable-multilib"
2060 else
2061   multilib_arg=
2062 fi
2063
2064 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2065 AC_OUTPUT