libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 146
 147 # Only use libltdl for non-newlib builds.
 148 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 149    AC_LIBLTDL_CONVENIENCE
 150    AC_LIBTOOL_DLOPEN
 151    DIRLTDL=libltdl
 152    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 153    # Sigh.  Libtool's macro doesn't do the right thing.
 154    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 155    # FIXME: this is a hack.
 156    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 157    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 158 fi
 159 AC_SUBST(INCLTDL)
 160 AC_SUBST(LIBLTDL)
 161 AC_SUBST(DIRLTDL)
 162 AC_PROG_LIBTOOL
 163 AM_PROG_GCJ
 164 AM_PROG_CC_C_O
 165 AC_CONFIG_SUBDIRS(libltdl)
 166
 167 # The -no-testsuite modules omit the test subdir.
 168 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 169
 170 # Should the runtime set system properties by examining the
 171 # environment variable GCJ_PROPERTIES?
 172 AC_ARG_ENABLE(getenv-properties,
 173   AS_HELP_STRING([--disable-getenv-properties],
 174                  [don't set system properties from GCJ_PROPERTIES]))
 175
 176 # Whether GCJ_PROPERTIES is used depends on the target.
 177 if test -z "$enable_getenv_properties"; then
 178    enable_getenv_properties=${enable_getenv_properties_default-yes}
 179 fi
 180 if test "$enable_getenv_properties" = no; then
 181    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 182      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 183 fi
 184
 185 # Whether we should use arguments to main()
 186 if test -z "$enable_main_args"; then
 187    enable_main_args=${enable_main_args_default-yes}
 188 fi
 189 if test "$enable_main_args" = no; then
 190    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 191 fi
 192
 193
 194 # Should we use hashtable-based synchronization?
 195 # Currently works only for Linux X86/ia64
 196 # Typically faster and more space-efficient
 197 AC_ARG_ENABLE(hash-synchronization,
 198   AS_HELP_STRING([--enable-hash-synchronization],
 199                  [use global hash table for monitor locks]))
 200
 201 if test -z "$enable_hash_synchronization"; then
 202    enable_hash_synchronization=$enable_hash_synchronization_default
 203 fi
 204
 205 AC_ARG_WITH(java-home,
 206   AS_HELP_STRING([--with-java-home=DIRECTORY],
 207                  [value of java.home system property]),
 208                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 209 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 210 AC_SUBST(JAVA_HOME)
 211
 212 # What is the native OS API for MinGW?
 213 AC_ARG_WITH(win32-nlsapi,
 214   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 215                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 216 [case "${withval}" in
 217   ansi) with_win32_nlsapi=ansi ;;
 218   unicows) with_win32_nlsapi=unicows ;;
 219   unicode) with_win32_nlsapi=unicode ;;
 220   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 221 esac],[with_win32_nlsapi=ansi])
 222
 223 case "${with_win32_nlsapi}" in
 224   unicows | unicode)
 225     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 226       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 227     ;;
 228 esac
 229
 230 # configure.host sets slow_pthread_self if the synchronization code should
 231 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 232 if test "${slow_pthread_self}" = "yes"; then
 233   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 234     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 235 fi
 236
 237
 238 # See if the user has requested runtime debugging.
 239 LIBGCJDEBUG="false"
 240 AC_SUBST(LIBGCJDEBUG)
 241 AC_ARG_ENABLE(libgcj-debug,
 242   AS_HELP_STRING([--enable-libgcj-debug],
 243                  [enable runtime debugging code]),
 244   [if test "$enable_libgcj_debug" = yes; then
 245     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 246     LIBGCJDEBUG="true"
 247   fi])
 248
 249 # Check for gc debugging.  This option is handled both here and in the GC.
 250 AC_ARG_ENABLE(gc-debug,
 251    AS_HELP_STRING([--enable-gc-debug],
 252                   [include full support for pointer backtracing etc.]),
 253 [ if test "$enable_gc_debug" = "yes"; then
 254     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 255               [Define if we want to use debug calls into the garbage collector.])
 256   fi])
 257
 258 # See if the user has the interpreter included.
 259 AC_ARG_ENABLE(interpreter,
 260   AS_HELP_STRING([--enable-interpreter],
 261                  [enable interpreter]),
 262   [if test "$enable_interpreter" = yes; then
 263     # This can also be set in configure.host.
 264     libgcj_interpreter=yes
 265   elif test "$enable_interpreter" = no; then
 266     libgcj_interpreter=no
 267   fi])
 268
 269 if test "$libgcj_interpreter" = yes; then
 270    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 271 fi
 272 INTERPRETER="$libgcj_interpreter"
 273 AC_SUBST(INTERPRETER)
 274
 275 AC_MSG_CHECKING([for exception model to use])
 276 AC_LANG_PUSH(C++)
 277 AC_ARG_ENABLE(sjlj-exceptions,
 278   AS_HELP_STRING([--enable-sjlj-exceptions],
 279                  [force use of builtin_setjmp for exceptions]),
 280 [:],
 281 [dnl Botheration.  Now we've got to detect the exception model.
 282 dnl Link tests against libgcc.a are problematic since -- at least
 283 dnl as of this writing -- we've not been given proper -L bits for
 284 dnl single-tree newlib and libgloss.
 285 dnl
 286 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 287 dnl conftest files before we got a change to grep them first.
 288 cat > conftest.$ac_ext << EOF
 289 [#]line __oline__ "configure"
 290 struct S { ~S(); };
 291 void bar();
 292 void foo()
 293 {
 294   S s;
 295   bar();
 296 }
 297 EOF
 298 old_CXXFLAGS="$CXXFLAGS"
 299 CXXFLAGS=-S
 300 if AC_TRY_EVAL(ac_compile); then
 301   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 302     enable_sjlj_exceptions=yes
 303   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 304     enable_sjlj_exceptions=no
 305   fi
 306 fi
 307 CXXFLAGS="$old_CXXFLAGS"
 308 rm -f conftest*])
 309 if test x$enable_sjlj_exceptions = xyes; then
 310   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 311         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 312   ac_exception_model_name=sjlj
 313 elif test x$enable_sjlj_exceptions = xno; then
 314   ac_exception_model_name="call frame"
 315 else
 316   AC_MSG_ERROR([unable to detect exception model])
 317 fi
 318 AC_LANG_POP(C++)
 319 AC_MSG_RESULT($ac_exception_model_name)
 320
 321 # If we are non using SJLJ exceptions, and this host does not have support
 322 # for unwinding from a signal handler, enable checked dereferences and divides.
 323 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 324   CHECKREFSPEC=-fcheck-references
 325   DIVIDESPEC=-fuse-divide-subroutine
 326   EXCEPTIONSPEC=
 327 fi
 328
 329 # See if the user wants to disable java.net.  This is the mildly
 330 # ugly way that we admit that target-side configuration sucks.
 331 AC_ARG_ENABLE(java-net,
 332   AS_HELP_STRING([--disable-java-net],
 333                  [disable java.net]))
 334
 335 # Whether java.net is built by default can depend on the target.
 336 if test -z "$enable_java_net"; then
 337    enable_java_net=${enable_java_net_default-yes}
 338 fi
 339 if test "$enable_java_net" = no; then
 340    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 341 fi
 342
 343 # See if the user wants to configure without libffi.  Some
 344 # architectures don't support it, and default values are set in
 345 # configure.host.
 346 AC_ARG_WITH(libffi,
 347   AS_HELP_STRING([--without-libffi],
 348                  [don't use libffi]),
 349   [:],
 350   [with_libffi=${with_libffi_default-yes}])
 351
 352 LIBFFI=
 353 LIBFFIINCS=
 354 if test "$with_libffi" != no; then
 355    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 356    LIBFFI=../libffi/libffi_convenience.la
 357    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 358 fi
 359 AC_SUBST(LIBFFI)
 360 AC_SUBST(LIBFFIINCS)
 361
 362 # See if the user wants to disable JVMPI support.
 363 AC_ARG_ENABLE(jvmpi,
 364   AS_HELP_STRING([--disable-jvmpi],
 365                  [disable JVMPI support]))
 366
 367 if test "$enable_jvmpi" != no; then
 368     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 369 fi
 370
 371 # If the target is an eCos system, use the appropriate eCos
 372 # I/O routines.
 373 # FIXME: this should not be a local option but a global target
 374 # system; at present there is no eCos target.
 375 TARGET_ECOS=${PROCESS-"no"}
 376 AC_ARG_WITH(ecos,
 377 [  --with-ecos             enable runtime eCos target support],
 378 TARGET_ECOS="$with_ecos"
 379 )
 380
 381 supply_backtrace=no
 382
 383 PLATFORM_INNER_NAT_HDRS=
 384 case "$TARGET_ECOS" in
 385    no) case "$host" in
 386       *mingw*)
 387             PLATFORM=Win32
 388             PLATFORMNET=Win32
 389             PLATFORMH=win32.h
 390         CHECK_FOR_BROKEN_MINGW_LD
 391       ;;
 392       *)
 393             PLATFORM=Posix
 394             PLATFORMNET=Posix
 395             PLATFORMH=posix.h
 396             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 397       ;;
 398       esac
 399       ;;
 400    *)
 401       PLATFORM=Ecos
 402       PLATFORMNET=NoNet
 403       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 404       PLATFORMH=posix.h
 405       ;;
 406 esac
 407 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 408 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 409
 410 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 411                                       [Define if you have int32_t and uint32_t.]))
 412 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 413                                         [Define if you have int32_t and uint32_t.]))
 414 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 415                                           [Define if you have u_int32_t]))
 416 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 417                                            [Define if you have u_int32_t]))
 418
 419 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 420 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 421 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 422
 423 case "$host" in
 424   *-darwin*) DARWIN_CRT=true ;;
 425   *) DARWIN_CRT=false ;;
 426 esac
 427 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 428
 429 # These may not be defined in a non-ANS conformant embedded system.
 430 # FIXME: Should these case a runtime exception in that case?
 431 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 432                                   [Define is you have 'mktime' in <time.h>]))
 433 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 434                                   [Define is you have 'localtime' in <time.h>]))
 435
 436 # Create the subdirectory for natFile.cc, or the attempt
 437 # to create the link will fail.
 438 test -d java || mkdir java
 439 test -d java/io || mkdir java/io
 440 test -d gnu || mkdir gnu
 441 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 442
 443 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 444 test -d java/lang || mkdir java/lang
 445 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 446 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 447
 448 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 449 test -d java/net || mkdir java/net
 450 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 451 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 452
 453 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 454 test -d gnu/java || mkdir gnu/java
 455 test -d gnu/java/net || mkdir gnu/java/net
 456 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 457 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 458
 459 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 460 test -d gnu/java/nio || mkdir gnu/java/nio
 461 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 462 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 463 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 464 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 465
 466 case "${host}" in
 467     *mingw*)
 468       SYSTEMSPEC="-lgdi32 -lws2_32"
 469       if test "${with_win32_nlsapi}" = "unicows"; then
 470         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 471       fi
 472     ;;
 473     *)
 474       SYSTEMSPEC=
 475     ;;
 476 esac
 477 AC_SUBST(SYSTEMSPEC)
 478
 479 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 480 AC_SUBST(LIBGCJTESTSPEC)
 481
 482 AC_ARG_WITH(system-zlib,
 483   AS_HELP_STRING([--with-system-zlib],
 484                  [use installed libz]))
 485 ZLIBSPEC=
 486 AC_SUBST(ZLIBSPEC)
 487 ZLIBTESTSPEC=
 488 AC_SUBST(ZLIBTESTSPEC)
 489
 490 AC_PATH_XTRA
 491
 492 # Determine which AWT peer libraries to build
 493 AC_ARG_ENABLE(java-awt,
 494   AS_HELP_STRING([--enable-java-awt],
 495                  [list of AWT peer implementations to be built]))
 496
 497 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 498 use_xlib_awt=""
 499 use_gtk_awt=""
 500 # The default toolkit to use is the first one specified.
 501 TOOLKIT=
 502 AC_SUBST(TOOLKIT)
 503
 504 for peer in $peerlibs ; do
 505   case $peer in
 506     xlib)
 507       if test "$no_x" = yes; then
 508         echo "*** xlib peers requested but no X library available" 1>&2
 509         exit 1
 510       else
 511         use_xlib_awt="yes"
 512         if test -z "$TOOLKIT"; then
 513            TOOLKIT=gnu.awt.xlib.XToolkit
 514         fi
 515       fi
 516       ;;
 517     gtk)
 518       if test "$no_x" = yes; then
 519          echo "*** xlib peers requested but no X library available" 1>&2
 520          exit 1
 521       else
 522          use_gtk_awt=yes
 523          if test -z "$TOOLKIT"; then
 524             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 525          fi
 526          test -d jniinclude || mkdir jniinclude
 527       fi
 528       ;;
 529     no)
 530       use_xlib_awt=
 531       use_gtk_awt=
 532       break
 533       ;;
 534     *)
 535       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 536       exit 1
 537   esac
 538 done
 539
 540 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 541 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 542
 543 # determine whether to enable the cairo GTK Graphics2D backend
 544 AC_ARG_ENABLE(gtk-cairo,
 545   AS_HELP_STRING([--enable-gtk-cairo],
 546                  [build the cairo Graphics2D implementation on GTK]))
 547 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 548 if test "x${enable_gtk_cairo}" = xyes
 549 then
 550         PKG_CHECK_MODULES(CAIRO, cairo)
 551         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 552 fi
 553 AC_SUBST(CAIRO_LIBS)
 554 AC_SUBST(CAIRO_CFLAGS)
 555 AC_SUBST(PANGOFT2_LIBS)
 556 AC_SUBST(PANGOFT2_CFLAGS)
 557
 558 # FIXME: this should be _libs on some hosts.
 559 libsubdir=.libs
 560
 561 # Allow the GC to be disabled.  Can be useful when debugging.
 562 AC_MSG_CHECKING([for garbage collector to use])
 563 AC_ARG_ENABLE(java-gc,
 564   AS_HELP_STRING([--enable-java-gc=TYPE],
 565                  [choose garbage collector (default is boehm)]),
 566   [GC=$enableval],
 567   [GC=boehm])
 568 GCLIBS=
 569 GCINCS=
 570 GCDEPS=
 571 GCSPEC=
 572 JC1GCSPEC=
 573 GCTESTSPEC=
 574 case "$GC" in
 575  boehm)
 576     AC_MSG_RESULT(boehm)
 577     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 578     JC1GCSPEC='-fuse-boehm-gc'
 579     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 580     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 581     GCOBJS=boehm.lo
 582     GCHDR=boehm-gc.h
 583     # The POSIX thread support needs to know this.
 584     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 585     ;;
 586  no)
 587     AC_MSG_RESULT(none)
 588     GCHDR=no-gc.h
 589     ;;
 590  *)
 591     AC_MSG_ERROR([unrecognized collector "$GC"])
 592     ;;
 593 esac
 594 AC_SUBST(GCLIBS)
 595 AC_SUBST(GCINCS)
 596 AC_SUBST(GCDEPS)
 597 AC_SUBST(GCSPEC)
 598 AC_SUBST(JC1GCSPEC)
 599 AC_SUBST(GCTESTSPEC)
 600 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 601 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 602 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 603
 604
 605 AC_MSG_CHECKING([for thread model used by GCC])
 606 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 607 AC_MSG_RESULT([$THREADS])
 608
 609 case "$THREADS" in
 610  no | none | single)
 611     THREADS=none
 612     ;;
 613  posix | posix95 | pthreads)
 614     THREADS=posix
 615     case "$host" in
 616      *-*-linux*)
 617         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 618         ;;
 619     esac
 620     ;;
 621  win32)
 622     ;;
 623  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 624     AC_MSG_ERROR(thread package $THREADS not yet supported)
 625     ;;
 626  *)
 627     AC_MSG_ERROR($THREADS is an unknown thread package)
 628     ;;
 629 esac
 630
 631 THREADCXXFLAGS=
 632 THREADLDFLAGS=
 633 THREADLIBS=
 634 THREADINCS=
 635 THREADDEPS=
 636 THREADH=
 637 THREADSPEC=
 638 case "$THREADS" in
 639  posix)
 640     case "$host" in
 641      *-*-cygwin*)
 642         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 643         ;;
 644      *-*-freebsd[[1234]]*)
 645         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 646         # merely adds pthread_* functions) but it does have a -pthread switch
 647         # which is required at link-time to select -lc_r *instead* of -lc.
 648         THREADLDFLAGS=-pthread
 649         # Don't set THREADSPEC here as might be expected since -pthread is
 650         # not processed when found within a spec file, it must come from
 651         # the command line.  For now, the user must provide the -pthread
 652         # switch to link code compiled with gcj.  In future, consider adding
 653         # support for weak references to pthread_* functions ala gthr.h API.
 654         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 655         ;;
 656      *-*-freebsd*)
 657         # FreeBSD 5 implements a model much closer to other modern UNIX
 658         # which support threads.  However, it still does not support
 659         # -lpthread.
 660         THREADLDFLAGS=-pthread
 661         THREADSPEC=-lc_r
 662         ;;
 663      alpha*-dec-osf*)
 664         THREADCXXFLAGS=-pthread
 665         # boehm-gc needs some functions from librt, so link that too.
 666         THREADLIBS='-lpthread -lrt'
 667         THREADSPEC='-lpthread -lrt'
 668         ;;
 669      *)
 670         THREADLIBS=-lpthread
 671         THREADSPEC=-lpthread
 672         ;;
 673     esac
 674     THREADH=posix-threads.h
 675     # MIT pthreads doesn't seem to have the mutexattr functions.
 676     # But for now we don't check for it.  We just assume you aren't
 677     # using MIT pthreads.
 678     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 679
 680     # If we're using the Boehm GC, then we happen to know that it
 681     # defines _REENTRANT, so we don't bother.  Eww.
 682     if test "$GC" != boehm; then
 683        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 684     fi
 685     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 686     ;;
 687
 688  win32)
 689     THREADH=win32-threads.h
 690     ;;
 691
 692  none)
 693     THREADH=no-threads.h
 694     ;;
 695 esac
 696 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 697 AC_SUBST(THREADLIBS)
 698 AC_SUBST(THREADINCS)
 699 AC_SUBST(THREADDEPS)
 700 AC_SUBST(THREADSPEC)
 701 AC_SUBST(THREADLDFLAGS)
 702 AC_SUBST(THREADCXXFLAGS)
 703 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 704 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 705 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 706
 707 if test -d sysdep; then true; else mkdir sysdep; fi
 708 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 709 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 710 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 711
 712 HASH_SYNC_SPEC=
 713 # Hash synchronization is only useful with posix threads right now.
 714 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 715    HASH_SYNC_SPEC=-fhash-synchronization
 716    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 717 fi
 718 AC_SUBST(HASH_SYNC_SPEC)
 719
 720 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 721
 722 # We're in the tree with gcc, and need to include some of its headers.
 723 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 724
 725 if test "x${with_newlib}" = "xyes"; then
 726    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 727    # may not work correctly, because the compiler may not be able to
 728    # link executables.
 729
 730    # We assume newlib.  This lets us hard-code the functions we know
 731    # we'll have.
 732    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 733    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 734    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 735    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 736    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 737    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 738    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 739    # This is only for POSIX threads.
 740    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 741    # We also assume we are using gcc, which provides alloca.
 742    AC_DEFINE(HAVE_ALLOCA)
 743
 744    # Assume we do not have getuid and friends.
 745    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 746    PLATFORMNET=NoNet
 747 else
 748    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 749                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 750                    access stat mkdir rename rmdir unlink realpath utime chmod \
 751                    nl_langinfo setlocale \
 752                    inet_pton uname inet_ntoa \
 753                    fork execvp pipe sigaction ftruncate])
 754    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 755    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 756    AC_CHECK_FUNC(backtrace, [
 757      case "$host" in
 758        ia64-*-linux*)
 759          # Has broken backtrace()
 760          ;;
 761        mips*-*-linux*)
 762          # Has broken backtrace(), but we supply our own.
 763          if test -d sysdep; then true; else mkdir -p sysdep; fi
 764          supply_backtrace=yes
 765          AC_DEFINE(HAVE_BACKTRACE, 1,
 766            [Define if your platform has a working backtrace() function.])
 767          ;;
 768        *)
 769          AC_DEFINE(HAVE_BACKTRACE, 1,
 770            [Define if your platform has a working backtrace() function.])
 771          ;;
 772      esac
 773    ], [
 774      case "$host" in
 775        *mingw*)
 776          # Has backtrace() defined in libgcj itself
 777          AC_DEFINE(HAVE_BACKTRACE, 1,
 778            [Define if your platform has a working backtrace() function.])
 779          ;;
 780      esac
 781    ])
 782
 783    AC_CHECK_LIB(dl, dladdr, [
 784      if test "x${disable_dladdr}" = "xyes"; then
 785        #Broken dladdr().
 786        true
 787      else
 788        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 789      fi
 790    ])
 791    if test x"$build" = x"$host"; then
 792      AC_CHECK_FILES(/proc/self/exe, [
 793        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 794    else
 795      case $host in
 796      *-linux*)
 797        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 798        ;;
 799      esac
 800    fi
 801
 802    AM_ICONV
 803    AM_LC_MESSAGES
 804    AC_STRUCT_TIMEZONE
 805
 806    AC_CHECK_FUNCS(gethostbyname_r, [
 807      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 808        [Define if you have the 'gethostbyname_r' function.])
 809      # There are two different kinds of gethostbyname_r.
 810      # We look for the one that returns `int'.
 811      # Hopefully this check is robust enough.
 812      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 813        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 814
 815      case " $GCINCS " in
 816      *" -D_REENTRANT "*) ;;
 817      *)
 818         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 819         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 820         [libjava_cv_gethostbyname_r_needs_reentrant],
 821         [ AC_LANG_PUSH(C++)
 822           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 823             [[gethostbyname_r("", 0, 0);]])],
 824             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 825                 CPPFLAGS_SAVE="$CPPFLAGS"
 826                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 827                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 828                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 829                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 830                 CPPFLAGS="$CPPFLAGS_SAVE"
 831           ])
 832           AC_LANG_POP(C++)
 833         ])
 834         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 835           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 836         fi
 837      ;;
 838      esac
 839
 840      AC_CACHE_CHECK([for struct hostent_data],
 841         [libjava_cv_struct_hostent_data], [dnl
 842         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 843 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 844 # define _REENTRANT 1
 845 #endif
 846 #include <netdb.h>]], [[struct hostent_data data;]])],
 847           [libjava_cv_struct_hostent_data=yes],
 848           [libjava_cv_struct_hostent_data=no])])
 849      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 850        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 851          [Define if struct hostent_data is defined in netdb.h])
 852      fi
 853    ])
 854
 855    # FIXME: libjava source code expects to find a prototype for
 856    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 857    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 858    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 859    # linkage check is enough, yet C++ code requires proper prototypes.)
 860    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 861    AC_CHECK_FUNCS(gethostbyaddr_r, [
 862      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 863        [Define if you have the 'gethostbyaddr_r' function.])
 864      # There are two different kinds of gethostbyaddr_r.
 865      # We look for the one that returns `int'.
 866      # Hopefully this check is robust enough.
 867      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 868        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 869          [Define if gethostbyaddr_r returns 'int'.])])])])
 870
 871    AC_CHECK_FUNCS(gethostname, [
 872      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 873        [Define if you have the 'gethostname' function.])
 874      AC_EGREP_HEADER(gethostname, unistd.h, [
 875        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 876          [Define if gethostname is declared in <unistd.h>.])])])
 877
 878    AC_CHECK_FUNCS(usleep, [
 879      AC_EGREP_HEADER(usleep, unistd.h, [
 880        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 881           [Define if usleep is declared in <unistd.h>.])])])
 882
 883    # Look for these functions in the thread library, but only bother
 884    # if using POSIX threads.
 885    if test "$THREADS" = posix; then
 886       save_LIBS="$LIBS"
 887       LIBS="$LIBS $THREADLIBS"
 888       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 889       # E.g., Solaris.
 890       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 891
 892       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 893       # Solaris 7 the name librt is preferred.
 894       AC_CHECK_FUNCS(sched_yield, , [
 895         AC_CHECK_LIB(rt, sched_yield, [
 896           AC_DEFINE(HAVE_SCHED_YIELD)
 897           THREADLIBS="$THREADLIBS -lrt"
 898           THREADSPEC="$THREADSPEC -lrt"], [
 899           AC_CHECK_LIB(posix4, sched_yield, [
 900             AC_DEFINE(HAVE_SCHED_YIELD)
 901             THREADLIBS="$THREADLIBS -lposix4"
 902             THREADSPEC="$THREADSPEC -lposix4"])])])
 903       LIBS="$save_LIBS"
 904
 905       # We can save a little space at runtime if the mutex has m_count
 906       # or __m_count.  This is a nice hack for Linux.
 907       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 908           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 909         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 910              [Define if pthread_mutex_t has m_count member.]), [
 911         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 912             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 913           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 914             [Define if pthread_mutex_t has __m_count member.]))])
 915    fi
 916
 917    # We require a way to get the time.
 918    time_found=no
 919    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 920    if test "$time_found" = no; then
 921       AC_MSG_ERROR([no function found to get the time])
 922    fi
 923
 924    AC_CHECK_FUNCS(memmove)
 925
 926    # We require memcpy.
 927    memcpy_found=no
 928    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 929    if test "$memcpy_found" = no; then
 930       AC_MSG_ERROR([memcpy is required])
 931    fi
 932
 933    AC_CHECK_LIB(dl, dlopen, [
 934        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 935
 936    # Some library-finding code we stole from Tcl.
 937    #--------------------------------------------------------------------
 938    #    Check for the existence of the -lsocket and -lnsl libraries.
 939    #    The order here is important, so that they end up in the right
 940    #    order in the command line generated by make.  Here are some
 941    #    special considerations:
 942    #    1. Use "connect" and "accept" to check for -lsocket, and
 943    #       "gethostbyname" to check for -lnsl.
 944    #    2. Use each function name only once:  can't redo a check because
 945    #       autoconf caches the results of the last check and won't redo it.
 946    #    3. Use -lnsl and -lsocket only if they supply procedures that
 947    #       aren't already present in the normal libraries.  This is because
 948    #       IRIX 5.2 has libraries, but they aren't needed and they're
 949    #       bogus:  they goof up name resolution if used.
 950    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 951    #       To get around this problem, check for both libraries together
 952    #       if -lsocket doesn't work by itself.
 953    #--------------------------------------------------------------------
 954
 955    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 956     [gcj_cv_lib_sockets=
 957      gcj_checkBoth=0
 958      unset ac_cv_func_connect
 959      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 960      if test "$gcj_checkSocket" = 1; then
 961          unset ac_cv_func_connect
 962          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 963                       gcj_checkBoth=1)
 964      fi
 965      if test "$gcj_checkBoth" = 1; then
 966          gcj_oldLibs=$LIBS
 967          LIBS="$LIBS -lsocket -lnsl"
 968          unset ac_cv_func_accept
 969          AC_CHECK_FUNC(accept,
 970                        [gcj_checkNsl=0
 971                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 972          unset ac_cv_func_accept
 973          LIBS=$gcj_oldLibs
 974      fi
 975      unset ac_cv_func_gethostbyname
 976      gcj_oldLibs=$LIBS
 977      LIBS="$LIBS $gcj_cv_lib_sockets"
 978      AC_CHECK_FUNC(gethostbyname, ,
 979                    [AC_CHECK_LIB(nsl, main,
 980                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 981      unset ac_cv_func_gethostbyname
 982      LIBS=$gcj_oldLIBS
 983    ])
 984    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 985
 986    if test "$with_system_zlib" = yes; then
 987       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 988    fi
 989
 990    # Test for Gtk stuff, if asked for.
 991    if test "$use_gtk_awt" = yes; then
 992       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
 993       AC_SUBST(GTK_CFLAGS)
 994       AC_SUBST(GTK_LIBS)
 995
 996       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
 997       AC_SUBST(GLIB_CFLAGS)
 998       AC_SUBST(GLIB_LIBS)
 999
1000       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1001       AC_SUBST(LIBART_CFLAGS)
1002       AC_SUBST(LIBART_LIBS)
1003
1004       # We require the XTest Extension to support java.awt.Robot.
1005       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1006                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1007                    [${X_LIBS}])
1008    fi
1009
1010    # On Solaris, and maybe other architectures, the Boehm collector
1011    # requires -ldl.
1012    if test "$GC" = boehm; then
1013       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1014    fi
1015 fi
1016 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1017
1018 if test -z "${with_multisubdir}"; then
1019    builddotdot=.
1020 else
1021    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1022 fi
1023
1024 NATIVE=yes
1025
1026 # Which gcj do we use?
1027 which_gcj=default
1028 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
1029 if test -n "${with_cross_host}"; then
1030   # We are being configured with a cross compiler. We can't
1031   # use ac_exeext, because that is for the target platform.
1032   NATIVE=no
1033   cross_host_exeext=
1034   case "${with_cross_host}" in
1035      *mingw* | *cygwin*)
1036          cross_host_exeext=.exe
1037      ;;
1038   esac
1039   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1040      if test x"$build_noncanonical" = x"$with_cross_host"; then
1041         # Ordinary cross (host!=target and host=build)
1042         which_gcj=built
1043      else
1044         # Canadian cross (host!=target and host!=build)
1045         which_gcj=cross
1046      fi
1047   else
1048      which_gcj=cross
1049   fi
1050 else
1051   # We are being configured with a native or crossed-native compiler
1052   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1053      if test x"$build" = x"$host"; then
1054         # True native build (host=target and host=build)
1055         which_gcj=built
1056      else
1057         # Crossed-native build (host=target and host!=build)
1058         which_gcj=cross
1059      fi
1060   else
1061      which_gcj=path
1062   fi
1063 fi
1064 case "${which_gcj}" in
1065    built)
1066       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1067       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
1068       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
1069    ;;
1070    cross)
1071       if test "x${with_newlib}" = "xyes"; then
1072          # FIXME (comment): Why is this needed?
1073          GCC_UNWIND_INCLUDE=
1074          GCJ="${target_noncanonical}-gcj"
1075       else
1076          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1077       fi
1078       ZIP='$(target_noncanonical)-fastjar'
1079       GCJH='$(target_noncanonical)-gcjh'
1080    ;;
1081    path)
1082       GCJ="gcj -B`${PWDCMD-pwd}`/"
1083       ## In this case, gcj is found outside the build tree.  However, zip is
1084       ## found in the build tree.
1085       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1086       GCJH=gcjh
1087    ;;
1088 esac
1089
1090 AC_SUBST(GCJH)
1091 AC_SUBST(ZIP)
1092
1093 # Create it, so that compile/link tests don't fail
1094 test -f libgcj.spec || touch libgcj.spec
1095
1096 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1097 case $build in
1098     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1099     *)         CLASSPATH_SEPARATOR=':' ;;
1100 esac
1101 AC_SUBST(CLASSPATH_SEPARATOR)
1102
1103 # We must search the source tree for java.lang, since we still don't
1104 # have libgcj.jar nor java/lang/*.class
1105 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1106 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1107
1108 # Since some classes depend on this one, we need its source available
1109 # before we can do any GCJ compilation test :-(
1110 if test ! -f gnu/classpath/Configuration.java; then
1111   test -d gnu || mkdir gnu
1112   test -d gnu/classpath || mkdir gnu/classpath
1113   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1114       -e 's,@TOOLKIT@,$TOOLKIT,' \
1115         < $srcdir/gnu/classpath/Configuration.java.in \
1116         > gnu/classpath/Configuration.java
1117   # We do not want to redirect the output of the grep below to /dev/null,
1118   # but we add /dev/null to the input list so that grep will print the
1119   # filename of Configuration.java in case it finds any matches.
1120   if grep @ gnu/classpath/Configuration.java /dev/null; then
1121     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1122   fi
1123 fi
1124
1125 LT_AC_PROG_GCJ
1126
1127 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1128
1129 AC_CHECK_SIZEOF(void *)
1130
1131 AC_C_BIGENDIAN
1132
1133 ZLIBS=
1134 SYS_ZLIBS=
1135 ZINCS=
1136
1137 if test -z "$ZLIBSPEC"; then
1138    # Use zlib from the GCC tree.
1139    ZINCS='-I$(top_srcdir)/../zlib'
1140    ZLIBS=../zlib/libzgcj_convenience.la
1141 else
1142    # System's zlib.
1143    SYS_ZLIBS="$ZLIBSPEC"
1144 fi
1145 AC_SUBST(ZLIBS)
1146 AC_SUBST(SYS_ZLIBS)
1147 AC_SUBST(ZINCS)
1148 AC_SUBST(DIVIDESPEC)
1149 AC_SUBST(CHECKREFSPEC)
1150 AC_SUBST(EXCEPTIONSPEC)
1151 AC_SUBST(IEEESPEC)
1152
1153 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1154 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1155 AC_SUBST(GCC_UNWIND_INCLUDE)
1156
1157 # Process the option "--enable-version-specific-runtime-libs"
1158 # Calculate toolexeclibdir
1159 case ${version_specific_libs} in
1160   yes)
1161     # Need the gcc compiler version to know where to install libraries
1162     # and header files if --enable-version-specific-runtime-libs option
1163     # is selected.
1164     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1165     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1166     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1167     toolexeclibdir=$toolexecmainlibdir
1168     ;;
1169   no)
1170     if test -n "$with_cross_host" &&
1171        test x"$with_cross_host" != x"no"; then
1172       # Install a library built with a cross compiler in tooldir, not libdir.
1173       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1174       toolexecmainlibdir='$(toolexecdir)/lib'
1175     else
1176       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1177       toolexecmainlibdir='$(libdir)'
1178     fi
1179     multi_os_directory=`$CC -print-multi-os-directory`
1180     case $multi_os_directory in
1181       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1182       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1183     esac
1184     ;;
1185 esac
1186 AC_SUBST(toolexecdir)
1187 AC_SUBST(toolexecmainlibdir)
1188 AC_SUBST(toolexeclibdir)
1189
1190 # Determine gcj version number.
1191 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1192 GCJVERSION=$gcjversion
1193 AC_SUBST(GCJVERSION)
1194 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1195
1196 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1197 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1198
1199 TL_AC_GXX_INCLUDE_DIR
1200
1201 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1202 # On that system, sys/ioctl.h will not include sys/filio.h unless
1203 # BSD_COMP is defined; just including sys/filio.h is simpler.
1204 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1205 # for now.  If you change this, you also must update natFile.cc.
1206 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1207                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1208                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1209                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1210                   dirent.h])
1211 AC_CHECK_HEADERS(inttypes.h, [
1212     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1213     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1214 ])
1215 AC_HEADER_SYS_WAIT
1216
1217 AC_CHECK_TYPE([ssize_t], [int])
1218
1219 AC_MSG_CHECKING([for in_addr_t])
1220 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1221 #if STDC_HEADERS
1222 #include <stdlib.h>
1223 #include <stddef.h>
1224 #endif
1225 #if HAVE_NETINET_IN_H
1226 #include <netinet/in.h>
1227 #endif]], [[in_addr_t foo;]])],
1228   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1229      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1230    AC_MSG_RESULT(yes)],
1231   [AC_MSG_RESULT(no)])
1232
1233 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1234 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1235   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1236      [Define if struct ip_mreq is defined in netinet/in.h.])
1237    AC_MSG_RESULT(yes)],
1238   [AC_MSG_RESULT(no)])
1239
1240 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1241 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1242   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1243      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1244    AC_MSG_RESULT(yes)],
1245   [AC_MSG_RESULT(no)])
1246
1247 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1248 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1249   [AC_DEFINE(HAVE_INET6, 1,
1250      [Define if inet6 structures are defined in netinet/in.h.])
1251    AC_MSG_RESULT(yes)],
1252   [AC_MSG_RESULT(no)])
1253
1254 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1255 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1256 #include <sys/types.h>
1257 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1258   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1259    AC_MSG_RESULT(yes)],
1260   [AC_MSG_RESULT(no)])
1261
1262 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1263 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1264   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1265    AC_MSG_RESULT(yes)],
1266   [AC_MSG_RESULT(no)
1267    AC_MSG_CHECKING([for global timezone variable])
1268    dnl FIXME: we don't want a link check here because that won't work
1269    dnl when cross-compiling.  So instead we make an assumption that
1270    dnl the header file will mention timezone if it exists.
1271    dnl Don't find the win32 function timezone
1272    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1273      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1274       AC_MSG_RESULT(yes)],
1275      [AC_MSG_RESULT(no)
1276        AC_MSG_CHECKING([for global _timezone variable])
1277        dnl FIXME: As above, don't want link check
1278        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1279          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1280             [Define if your platform has the global _timezone variable.])
1281           AC_MSG_RESULT(yes)],
1282           [AC_MSG_RESULT(no)])])])
1283
1284 AC_FUNC_ALLOCA
1285 AC_FUNC_MMAP
1286
1287 AC_CHECK_PROGS(PERL, perl, false)
1288
1289 SYSDEP_SOURCES=
1290 SIGNAL_HANDLER_AUX=
1291
1292 case "${host}" in
1293  i?86-*-linux*)
1294     SIGNAL_HANDLER=include/i386-signal.h
1295     ;;
1296  sparc*-sun-solaris*)
1297     SIGNAL_HANDLER=include/sparc-signal.h
1298     ;;
1299 # ia64-*)
1300 #    SYSDEP_SOURCES=sysdep/ia64.c
1301 #    test -d sysdep || mkdir sysdep
1302 #    ;;
1303  hppa*-*-linux*)
1304     SIGNAL_HANDLER=include/pa-signal.h
1305     ;;
1306  ia64-*-linux*)
1307     SIGNAL_HANDLER=include/dwarf2-signal.h
1308     ;;
1309  powerpc*-*-linux*)
1310     SIGNAL_HANDLER=include/powerpc-signal.h
1311     ;;
1312  alpha*-*-linux*)
1313     SIGNAL_HANDLER=include/dwarf2-signal.h
1314     ;;
1315  s390*-*-linux*)
1316     SIGNAL_HANDLER=include/s390-signal.h
1317     ;;
1318  x86_64*-*-linux*)
1319     SIGNAL_HANDLER=include/x86_64-signal.h
1320     SIGNAL_HANDLER_AUX=include/i386-signal.h
1321     ;;
1322  sparc*-*-linux*)
1323     SIGNAL_HANDLER=include/dwarf2-signal.h
1324     ;;
1325  sh*-*-linux*)
1326     SIGNAL_HANDLER=include/sh-signal.h
1327     ;;
1328  *mingw*)
1329     SIGNAL_HANDLER=include/win32-signal.h
1330     ;;
1331  mips*-*-linux*)
1332     SIGNAL_HANDLER=include/mips-signal.h
1333     ;;
1334  *-*-darwin*)
1335     SIGNAL_HANDLER=include/darwin-signal.h
1336     ;;
1337  *)
1338     SIGNAL_HANDLER=include/default-signal.h
1339     ;;
1340 esac
1341
1342 # If we're using sjlj exceptions, forget what we just learned.
1343 if test "$enable_sjlj_exceptions" = yes; then
1344    SIGNAL_HANDLER=include/default-signal.h
1345    SIGNAL_HANDLER_AUX=
1346 fi
1347
1348 # Define here any compiler flags that you need in order to make backtrace() work.
1349 BACKTRACESPEC=
1350 case "${host}" in
1351  x86_64*-*-linux*|i?86-*)
1352     BACKTRACESPEC=-fno-omit-frame-pointer
1353     ;;
1354 esac
1355 AC_SUBST(BACKTRACESPEC)
1356
1357 AC_SUBST(SYSDEP_SOURCES)
1358
1359 if test -z "$SIGNAL_HANDLER_AUX"; then
1360   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1361 fi
1362
1363 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1364                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1365
1366 if test "${multilib}" = "yes"; then
1367   multilib_arg="--enable-multilib"
1368 else
1369   multilib_arg=
1370 fi
1371
1372
1373
1374 here=`${PWDCMD-pwd}`
1375 AC_SUBST(here)
1376
1377 # We get this from the environment.
1378 AC_SUBST(GCJFLAGS)
1379
1380 AC_CONFIG_FILES([
1381 Makefile
1382 libgcj.pc
1383 libgcj.spec
1384 libgcj-test.spec
1385 gnu/classpath/Configuration.java
1386 gcj/Makefile
1387 include/Makefile
1388 testsuite/Makefile
1389 external/Makefile
1390 external/sax/Makefile
1391 external/w3c_dom/Makefile
1392 ])
1393
1394 AC_CONFIG_COMMANDS([default],
1395 [# Only add multilib support code if we just rebuilt top-level Makefile.
1396 case " $CONFIG_FILES " in
1397  *" Makefile "*)
1398    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1399    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1400    ;;
1401 esac
1402 for ac_multi_file in $CONFIG_FILES; do
1403   case $ac_multi_file in
1404   */Makefile)
1405     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1406   esac
1407 done
1408 ],
1409 srcdir=${srcdir}
1410 host=${host}
1411 target=${target}
1412 with_multisubdir=${with_multisubdir}
1413 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1414 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1415 libgcj_basedir=${libgcj_basedir}
1416 CC="${CC}"
1417 CXX="${CXX}"
1418 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1419 )
1420
1421 AC_OUTPUT