libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 LIBGCJ_CFLAGS="${libgcj_cflags}"
 218 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 219 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 220 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 221 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 222 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 223 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 224 AC_SUBST(LIBGCJ_CFLAGS)
 225 AC_SUBST(LIBGCJ_CXXFLAGS)
 226 AC_SUBST(LIBGCJ_JAVAFLAGS)
 227 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 228 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 229 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 231
 232 # Only use libltdl for non-newlib builds.
 233 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 234    AC_LTDL_SHLIBPATH
 235 fi
 236
 237 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 238
 239 # Possibly build libgcj as many sub-libraries.
 240 AC_ARG_ENABLE(libgcj-sublibs,
 241   AS_HELP_STRING([--enable-libgcj-sublibs],
 242                  [build libgcj as many sub-libraries]))
 243
 244 if test -z "$enable_libgcj_sublibs"; then
 245    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 246 fi
 247 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 248 if test "$enable_libgcj_sublibs" = yes ; then
 249   # In theory we could make do with only one override and simply
 250   # tag "_bc" onto the end of it when we use it to generate the
 251   # spec, but that's an ugly thing to do when there are multiple
 252   # words in the string and you're relying on the ordering to
 253   # append the correct one.
 254   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 255   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 256 fi
 257
 258
 259 # See if the user has requested runtime debugging.
 260 LIBGCJDEBUG="disable"
 261 AC_SUBST(LIBGCJDEBUG)
 262 AC_ARG_ENABLE(libgcj-debug,
 263   AS_HELP_STRING([--enable-libgcj-debug],
 264                  [enable runtime debugging code]),
 265   [if test "$enable_libgcj_debug" = yes; then
 266     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 267     LIBGCJDEBUG="enable"
 268   fi])
 269
 270 AC_ARG_WITH([escher],
 271          AS_HELP_STRING([--with-escher=ABS.PATH],
 272                         [specify path to escher dir or JAR for X peers]))
 273 case "$with_escher" in
 274 "")
 275         use_escher=false
 276         ;;
 277 "no")
 278         use_escher=false
 279         ;;
 280 "yes")
 281         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 282         ;;
 283 *)
 284         use_escher=true
 285         ;;
 286 esac
 287
 288 # Determine which AWT peer libraries to build
 289 AC_ARG_ENABLE(java-awt,
 290   AS_HELP_STRING([--enable-java-awt],
 291                  [list of AWT peer implementations to be built]))
 292
 293 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 294 use_xlib_awt=""
 295 use_gtk_awt=""
 296 use_qt_awt=""
 297 use_x_awt=""
 298 # The default toolkit to use is the first one specified.
 299 TOOLKIT=
 300 AC_SUBST(TOOLKIT)
 301
 302 for peer in $peerlibs ; do
 303   case $peer in
 304     xlib)
 305       if test "$no_x" = yes; then
 306         echo "*** xlib peers requested but no X library available" 1>&2
 307         exit 1
 308       else
 309         use_xlib_awt="yes"
 310         if test -z "$TOOLKIT"; then
 311            TOOLKIT=gnu.awt.xlib.XToolkit
 312         fi
 313       fi
 314       ;;
 315     gtk)
 316       if test "$no_x" = yes; then
 317          echo "*** gtk peers requested but no X library available" 1>&2
 318          exit 1
 319       else
 320          use_gtk_awt=yes
 321          if test -z "$TOOLKIT"; then
 322             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 323          fi
 324       fi
 325       ;;
 326     qt)
 327       if test "$no_x" = yes; then
 328          # Perhaps we should admit the possibility of embedded Qt.
 329          echo "*** Qt peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_qt_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 335          fi
 336       fi
 337       ;;
 338     x)
 339       use_x_awt=yes
 340       if test -z "$TOOLKIT"; then
 341          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 342       fi
 343       ;;
 344     no)
 345       use_xlib_awt=
 346       use_gtk_awt=
 347       use_qt_awt=
 348       use_x_awt=
 349       break
 350       ;;
 351     *)
 352       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 353       exit 1
 354   esac
 355 done
 356
 357 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 358 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 359
 360 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 361
 362 expanded_prefix=$prefix
 363 if test "X$prefix" = XNONE; then
 364   expanded_prefix=${ac_default_prefix}
 365 fi
 366
 367 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 368
 369 # Create standard.omit based on decisions we just made.
 370 cp $srcdir/standard.omit.in standard.omit
 371 if test "$use_xlib_awt" != yes; then
 372    echo gnu/awt/xlib >> standard.omit
 373    echo gnu/gcj/xlib >> standard.omit
 374 fi
 375 if test "$use_x_awt" != yes; then
 376    echo gnu/java/awt/peer/x >> standard.omit
 377 fi
 378
 379 # Tools that need to be compiled against classpath's tools classes
 380 : > vm-tools-packages
 381 for package in gnu/gcj/tools/gc_analyze ; do
 382     echo $package >> standard.omit
 383     echo $package >> vm-tools-packages
 384 done
 385
 386 if test -z "${with_multisubdir}"; then
 387    builddotdot=.
 388 else
 389    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 390 fi
 391
 392 NATIVE=yes
 393
 394 # Which gcj and host gcj (for ecjx) do we use?
 395 which_gcj=default
 396 host_exeext=${ac_exeext}
 397 GCJ_FOR_ECJX=
 398 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 399 if test -n "${with_cross_host}"; then
 400   # We are being configured with a cross compiler. We can't
 401   # use ac_exeext, because that is for the target platform.
 402   NATIVE=no
 403   cross_host_exeext=
 404   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 405   case "${with_cross_host}" in
 406      *mingw* | *cygwin*)
 407          cross_host_exeext=.exe
 408      ;;
 409   esac
 410   host_exeext=${cross_host_exeext}
 411   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 412      if test x"$build_noncanonical" = x"$with_cross_host"; then
 413         # Ordinary cross (host!=target and host=build)
 414         which_gcj=built
 415      else
 416         # Canadian cross (host!=target and host!=build)
 417         which_gcj=cross
 418      fi
 419   else
 420      which_gcj=cross
 421   fi
 422 else
 423   # We are being configured with a native or crossed-native compiler
 424   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 425      if test x"$build" = x"$host"; then
 426         # True native build (host=target and host=build)
 427         which_gcj=built
 428      else
 429         # Crossed-native build (host=target and host!=build)
 430         which_gcj=cross
 431      fi
 432   else
 433      which_gcj=path
 434   fi
 435 fi
 436 libgcjdir=`${PWDCMD-pwd}`
 437 case $GCJ in
 438 *" -B"*)
 439   # Just in case there is a comma in the build dir, quote it for the
 440   # sed command below.
 441   case $libgcjdir in
 442   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 443   *) qlibgcjdir=$libgcjdir;;
 444   esac
 445   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 446   ;;
 447 *)
 448   GCJ=$GCJ" -B$libgcjdir/"
 449   ;;
 450 esac
 451 case "${which_gcj}" in
 452    built)
 453       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 454    ;;
 455    cross)
 456       if test "x${with_newlib}" = "xyes"; then
 457          # FIXME (comment): Why is this needed?
 458          GCC_UNWIND_INCLUDE=
 459       fi
 460       GCJH='$(target_noncanonical)-gcjh'
 461    ;;
 462    path)
 463       GCJH=gcjh
 464    ;;
 465 esac
 466 JAVAC="$GCJ -C"
 467 export JAVAC
 468
 469 AC_SUBST(GCJ_FOR_ECJX)
 470 AC_SUBST(GCJH)
 471 AC_SUBST(host_exeext)
 472
 473 # Create it, so that compile/link tests don't fail
 474 test -f libgcj.spec || touch libgcj.spec
 475
 476
 477
 478 # Set up to configure Classpath.
 479 # FIXME: no supported way to pass args in autoconf.
 480 # Disable tool wrappers to avoid ltdl.h configure check.
 481 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 482 ac_configure_args="$ac_configure_args --disable-load-library"
 483 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 484 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 485 dir1=`cd $srcdir && pwd`
 486 dir2=`pwd`
 487 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 488 ac_configure_args="$ac_configure_args --disable-core-jni"
 489 dnl FIXME?
 490 ac_configure_args="$ac_configure_args --disable-examples"
 491 ac_configure_args="$ac_configure_args --with-glibj=build"
 492 if test "$browser_plugin_enabled" != yes; then
 493   ac_configure_args="$ac_configure_args --disable-plugin"
 494 else
 495   ac_configure_args="$ac_configure_args --enable-plugin"
 496 fi
 497 if test "$gconf_enabled" != yes; then
 498   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 499   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 500 fi
 501 if test "$use_gtk_awt" != yes; then
 502   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 503 fi
 504 if test "$use_qt_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-qt-peer"
 506 else
 507   # We need this as qt is disabled by default in classpath.
 508   ac_configure_args="$ac_configure_args --enable-qt-peer"
 509 fi
 510 if test "$use_x_awt" != yes; then
 511   ac_configure_args="$ac_configure_args --without-escher"
 512 else
 513   # We need this as escher is disabled by default in classpath.
 514   if test "$use_escher" != true; then
 515     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 516   else
 517     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 518   fi
 519 fi
 520 if test "x$BUILD_GJDOC" = xno; then
 521   ac_configure_args="$ac_configure_args --disable-gjdoc"
 522 fi
 523 # -Werror causes unavoidable problems in code using alsa.
 524 ac_configure_args="$ac_configure_args --disable-regen-headers"
 525 ac_configure_args="$ac_configure_args --disable-Werror"
 526 dnl --with-gcj=$GCJ
 527 dnl --with-javah=$GCJH
 528 dnl gtk-cairo -- just export here...
 529 dnl --enable-regen-headers?
 530
 531 # Only use libltdl for non-newlib builds.
 532 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 533    AC_LIBLTDL_CONVENIENCE
 534    AC_LIBTOOL_DLOPEN
 535    DIRLTDL=libltdl
 536    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 537    # Sigh.  Libtool's macro doesn't do the right thing.
 538    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 539    # FIXME: this is a hack.
 540    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 541    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 542 fi
 543 AC_SUBST(INCLTDL)
 544 AC_SUBST(LIBLTDL)
 545 AC_SUBST(DIRLTDL)
 546 AC_PROG_LIBTOOL
 547 AM_PROG_GCJ
 548 AM_PROG_CC_C_O
 549
 550 AC_CONFIG_SUBDIRS(classpath libltdl)
 551
 552 # The -no-testsuite modules omit the test subdir.
 553 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 554
 555 # Should the runtime set system properties by examining the
 556 # environment variable GCJ_PROPERTIES?
 557 AC_ARG_ENABLE(getenv-properties,
 558   AS_HELP_STRING([--disable-getenv-properties],
 559                  [don't set system properties from GCJ_PROPERTIES]))
 560
 561 # Whether GCJ_PROPERTIES is used depends on the target.
 562 if test -z "$enable_getenv_properties"; then
 563    enable_getenv_properties=${enable_getenv_properties_default-yes}
 564 fi
 565 if test "$enable_getenv_properties" = no; then
 566    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 567      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 568 fi
 569
 570 # Whether we should use arguments to main()
 571 if test -z "$enable_main_args"; then
 572    enable_main_args=${enable_main_args_default-yes}
 573 fi
 574 if test "$enable_main_args" = no; then
 575    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 576 fi
 577
 578
 579 # Should we use hashtable-based synchronization?
 580 # Currently works only for Linux X86/ia64
 581 # Typically faster and more space-efficient
 582 AC_ARG_ENABLE(hash-synchronization,
 583   AS_HELP_STRING([--enable-hash-synchronization],
 584                  [use global hash table for monitor locks]))
 585
 586 if test -z "$enable_hash_synchronization"; then
 587    enable_hash_synchronization=$enable_hash_synchronization_default
 588 fi
 589
 590
 591 install_ecj_jar=no
 592 ECJ_BUILD_JAR=
 593 ECJ_JAR=
 594 AC_ARG_WITH(ecj-jar,
 595         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 596         [ECJ_JAR=$withval],
 597         [if test -f $multi_basedir/ecj.jar; then
 598            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 599            ECJ_JAR='$(jardir)/ecj.jar'
 600            install_ecj_jar=yes
 601          fi])
 602 AC_SUBST(ECJ_BUILD_JAR)
 603 AC_SUBST(ECJ_JAR)
 604 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 605 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 606
 607 AC_ARG_WITH(java-home,
 608   AS_HELP_STRING([--with-java-home=DIRECTORY],
 609                  [value of java.home system property]),
 610                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 611 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 612 AC_SUBST(JAVA_HOME)
 613
 614 suppress_libgcj_bc=no
 615 AC_ARG_ENABLE(libgcj-bc,
 616   AS_HELP_STRING([--enable-libgcj-bc],
 617                  [enable(default) or disable BC ABI for portions of libgcj]),
 618   [if test "$enable_libgcj_bc" = "no"; then
 619      suppress_libgcj_bc=yes
 620    fi])
 621 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 622
 623 build_libgcj_reduced_reflection=no
 624 AC_ARG_ENABLE(reduced-reflection,
 625   AS_HELP_STRING([--enable-reduced-reflection],
 626                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 627   [if test "$enable_reduced_reflection" = "yes"; then
 628      build_libgcj_reduced_reflection=yes
 629    fi])
 630 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 631
 632 # What is the native OS API for MinGW?
 633 AC_ARG_WITH(win32-nlsapi,
 634   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 635                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 636 [case "${withval}" in
 637   ansi) with_win32_nlsapi=ansi ;;
 638   unicows) with_win32_nlsapi=unicows ;;
 639   unicode) with_win32_nlsapi=unicode ;;
 640   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 641 esac],[with_win32_nlsapi=ansi])
 642
 643 case "${with_win32_nlsapi}" in
 644   unicows | unicode)
 645     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 646       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 647     ;;
 648 esac
 649
 650 # configure.host sets slow_pthread_self if the synchronization code should
 651 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 652 if test "${slow_pthread_self}" = "yes"; then
 653   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 654     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 655 fi
 656
 657 # Check for gc debugging.  This option is handled both here and in the GC.
 658 AC_ARG_ENABLE(gc-debug,
 659    AS_HELP_STRING([--enable-gc-debug],
 660                   [include full support for pointer backtracing etc.]),
 661 [ if test "$enable_gc_debug" = "yes"; then
 662     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 663               [Define if we want to use debug calls into the garbage collector.])
 664   fi])
 665
 666 # See if the user has the interpreter included.
 667 AC_ARG_ENABLE(interpreter,
 668   AS_HELP_STRING([--enable-interpreter],
 669                  [enable interpreter]),
 670   [if test "$enable_interpreter" = yes; then
 671     # This can also be set in configure.host.
 672     libgcj_interpreter=yes
 673   elif test "$enable_interpreter" = no; then
 674     libgcj_interpreter=no
 675   fi])
 676
 677 if test "$libgcj_interpreter" = yes; then
 678    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 679 fi
 680 INTERPRETER="$libgcj_interpreter"
 681 AC_SUBST(INTERPRETER)
 682 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 683
 684 AC_MSG_CHECKING([for exception model to use])
 685 AC_LANG_PUSH(C++)
 686 AC_ARG_ENABLE(sjlj-exceptions,
 687   AS_HELP_STRING([--enable-sjlj-exceptions],
 688                  [force use of builtin_setjmp for exceptions]),
 689 [:],
 690 [dnl Botheration.  Now we've got to detect the exception model.
 691 dnl Link tests against libgcc.a are problematic since -- at least
 692 dnl as of this writing -- we've not been given proper -L bits for
 693 dnl single-tree newlib and libgloss.
 694 dnl
 695 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 696 dnl conftest files before we got a change to grep them first.
 697 cat > conftest.$ac_ext << EOF
 698 [#]line __oline__ "configure"
 699 struct S { ~S(); };
 700 void bar();
 701 void foo()
 702 {
 703   S s;
 704   bar();
 705 }
 706 EOF
 707 old_CXXFLAGS="$CXXFLAGS"
 708 CXXFLAGS=-S
 709 if AC_TRY_EVAL(ac_compile); then
 710   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 711     enable_sjlj_exceptions=yes
 712   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 713     enable_sjlj_exceptions=no
 714   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 715     # ARM EH ABI.
 716     enable_sjlj_exceptions=no
 717   fi
 718 fi
 719 CXXFLAGS="$old_CXXFLAGS"
 720 rm -f conftest*])
 721 if test x$enable_sjlj_exceptions = xyes; then
 722   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 723         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 724   ac_exception_model_name=sjlj
 725 elif test x$enable_sjlj_exceptions = xno; then
 726   ac_exception_model_name="call frame"
 727 else
 728   AC_MSG_ERROR([unable to detect exception model])
 729 fi
 730 AC_LANG_POP(C++)
 731 AC_MSG_RESULT($ac_exception_model_name)
 732
 733 # If we are non using SJLJ exceptions, and this host does not have support
 734 # for unwinding from a signal handler, enable checked dereferences and divides.
 735 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 736   CHECKREFSPEC=-fcheck-references
 737   DIVIDESPEC=-fuse-divide-subroutine
 738   EXCEPTIONSPEC=
 739 fi
 740
 741 # See if the user wants to disable java.net.  This is the mildly
 742 # ugly way that we admit that target-side configuration sucks.
 743 AC_ARG_ENABLE(java-net,
 744   AS_HELP_STRING([--disable-java-net],
 745                  [disable java.net]))
 746
 747 # Whether java.net is built by default can depend on the target.
 748 if test -z "$enable_java_net"; then
 749    enable_java_net=${enable_java_net_default-yes}
 750 fi
 751 if test "$enable_java_net" = no; then
 752    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 753 fi
 754
 755 # See if the user wants to configure without libffi.  Some
 756 # architectures don't support it, and default values are set in
 757 # configure.host.
 758 AC_ARG_WITH(libffi,
 759   AS_HELP_STRING([--without-libffi],
 760                  [don't use libffi]),
 761   [:],
 762   [with_libffi=${with_libffi_default-yes}])
 763
 764 LIBFFI=
 765 LIBFFIINCS=
 766 if test "$with_libffi" != no; then
 767    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 768    LIBFFI=../libffi/libffi_convenience.la
 769    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 770 fi
 771 AC_SUBST(LIBFFI)
 772 AC_SUBST(LIBFFIINCS)
 773
 774 # See if the user wants to disable JVMPI support.
 775 AC_ARG_ENABLE(jvmpi,
 776   AS_HELP_STRING([--disable-jvmpi],
 777                  [disable JVMPI support]))
 778
 779 if test "$enable_jvmpi" != no; then
 780     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 781 fi
 782
 783 # If the target is an eCos system, use the appropriate eCos
 784 # I/O routines.
 785 # FIXME: this should not be a local option but a global target
 786 # system; at present there is no eCos target.
 787 TARGET_ECOS=${PROCESS-"no"}
 788 AC_ARG_WITH(ecos,
 789 [  --with-ecos             enable runtime eCos target support],
 790 TARGET_ECOS="$with_ecos"
 791 )
 792
 793 case "$TARGET_ECOS" in
 794    no) case "$host" in
 795       *mingw*)
 796             PLATFORM=Win32
 797             PLATFORMNET=Win32
 798             PLATFORMH=win32.h
 799         CHECK_FOR_BROKEN_MINGW_LD
 800       ;;
 801       *)
 802             PLATFORM=Posix
 803             PLATFORMNET=Posix
 804             PLATFORMH=posix.h
 805       ;;
 806       esac
 807       ;;
 808    *)
 809       PLATFORM=Ecos
 810       PLATFORMNET=NoNet
 811       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 812       PLATFORMH=posix.h
 813       ;;
 814 esac
 815 AC_SUBST(PLATFORM)
 816 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 817
 818 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 819                                       [Define if you have int32_t and uint32_t.]))
 820 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 821                                         [Define if you have int32_t and uint32_t.]))
 822 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 823                                           [Define if you have u_int32_t]))
 824 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 825                                            [Define if you have u_int32_t]))
 826
 827 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 828 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 829
 830 case "$host" in
 831   *-darwin*) DARWIN_CRT=true ;;
 832   *) DARWIN_CRT=false ;;
 833 esac
 834 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 835
 836 # This may not be defined in a non-ANS conformant embedded system.
 837 # FIXME: Should these case a runtime exception in that case?
 838 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 839                                   [Define is you have 'localtime' in <time.h>]))
 840
 841 # Create the subdirectory for natFile.cc, or the attempt
 842 # to create the link will fail.
 843 test -d java || mkdir java
 844 test -d java/io || mkdir java/io
 845 test -d gnu || mkdir gnu
 846 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 847
 848 # Likewise for natConcreteProcess.cc.
 849 test -d java/lang || mkdir java/lang
 850 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 851
 852 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 853 test -d java/net || mkdir java/net
 854 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 855 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 856
 857 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 858 test -d gnu/java || mkdir gnu/java
 859 test -d gnu/java/net || mkdir gnu/java/net
 860 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 861 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 862
 863 # Likewise for natVMPipe.cc and natVMSelector.cc.
 864 test -d gnu/java/nio || mkdir gnu/java/nio
 865 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 866 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 867
 868 # Likewise for natFileChannelImpl.cc
 869 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 870 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 871
 872 # Likewise for natVMSecureRandom.cc
 873 test -d gnu/java/security || mkdir gnu/java/security
 874 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 875 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 876 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 877
 878 case "${host}" in
 879     *mingw*)
 880       SYSTEMSPEC="-lgdi32 -lws2_32"
 881       if test "${with_win32_nlsapi}" = "unicows"; then
 882         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 883       fi
 884     ;;
 885     *-*-darwin[[912]]*)
 886       SYSTEMSPEC="-allow_stack_execute"
 887     ;;
 888     *)
 889       SYSTEMSPEC=
 890     ;;
 891 esac
 892 AC_SUBST(SYSTEMSPEC)
 893
 894 AC_ARG_WITH(system-zlib,
 895   AS_HELP_STRING([--with-system-zlib],
 896                  [use installed libz]))
 897 ZLIBSPEC=
 898 AC_SUBST(ZLIBSPEC)
 899 ZLIBTESTSPEC=
 900 AC_SUBST(ZLIBTESTSPEC)
 901
 902 AC_PATH_XTRA
 903
 904 # FIXME: this should be _libs on some hosts.
 905 libsubdir=.libs
 906
 907 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 908
 909 LIBSTDCXXSPEC=
 910 # extra LD Flags which are required for targets
 911 case "${host}" in
 912 *-*-darwin[[0-7]].*)
 913     # For now we have to disable it on darwin[8-9] because it slows down
 914     # the linking phase. A possible bug in ld?
 915     # on Darwin -single_module speeds up loading of the dynamic libraries.
 916     extra_ldflags_libjava=-Wl,-single_module
 917     ;;
 918 arm*linux*eabi)
 919     # Some of the ARM unwinder code is actually in libstdc++.  We
 920     # could in principle replicate it in libgcj, but it's better to
 921     # have a dependency on libstdc++.
 922     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 923     LIBSTDCXXSPEC=-lstdc++
 924     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 925     ;;
 926 *-*-cygwin)
 927     extra_ldflags_libjava=-liconv
 928     ;;
 929 esac
 930
 931 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 932 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 933   [saved_ldflags="$LDFLAGS"
 934    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 935    AC_LINK_IFELSE([int main(void){ return 0;} ],
 936                       [eval "libgcj_cv_exidx=yes"],
 937                       [eval "libgcj_cv_exidx=no"])
 938    LDFLAGS="${saved_ldflags}"]
 939 )
 940 if test "${libgcj_cv_exidx}" = "yes"; then
 941   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 942   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 943 fi
 944
 945 AC_SUBST(extra_ldflags_libjava)
 946 AC_SUBST(extra_ldflags)
 947 AC_SUBST(LIBSTDCXXSPEC)
 948
 949 AC_SUBST(LIBGCJTESTSPEC)
 950
 951 # Allow the GC to be disabled.  Can be useful when debugging.
 952 AC_MSG_CHECKING([for garbage collector to use])
 953 AC_ARG_ENABLE(java-gc,
 954   AS_HELP_STRING([--enable-java-gc=TYPE],
 955                  [choose garbage collector (default is boehm)]),
 956   [GC=$enableval],
 957   [GC=boehm])
 958 GCLIBS=
 959 GCINCS=
 960 GCDEPS=
 961 GCSPEC=
 962 JC1GCSPEC=
 963 GCTESTSPEC=
 964 case "$GC" in
 965  boehm)
 966     AC_MSG_RESULT(boehm)
 967     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 968     JC1GCSPEC='-fuse-boehm-gc'
 969     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 970     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 971     GCOBJS=boehm.lo
 972     GCHDR=boehm-gc.h
 973     # The POSIX thread support needs to know this.
 974     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 975     ;;
 976  no)
 977     AC_MSG_RESULT(none)
 978     GCHDR=no-gc.h
 979     ;;
 980  *)
 981     AC_MSG_ERROR([unrecognized collector "$GC"])
 982     ;;
 983 esac
 984 AC_SUBST(GCLIBS)
 985 AC_SUBST(GCINCS)
 986 AC_SUBST(GCDEPS)
 987 AC_SUBST(GCSPEC)
 988 AC_SUBST(JC1GCSPEC)
 989 AC_SUBST(GCTESTSPEC)
 990 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 991 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 992 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 993
 994
 995 AC_MSG_CHECKING([for thread model used by GCC])
 996 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 997 AC_MSG_RESULT([$THREADS])
 998
 999 case "$THREADS" in
1000  no | none | single)
1001     THREADS=none
1002     ;;
1003  aix | posix | posix95 | pthreads)
1004     THREADS=posix
1005     case "$host" in
1006      *-*-linux*)
1007         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1008         ;;
1009     esac
1010     ;;
1011  win32)
1012     ;;
1013  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1014     AC_MSG_ERROR(thread package $THREADS not yet supported)
1015     ;;
1016  *)
1017     AC_MSG_ERROR($THREADS is an unknown thread package)
1018     ;;
1019 esac
1020
1021 THREADCXXFLAGS=
1022 THREADLDFLAGS=
1023 THREADLIBS=
1024 THREADINCS=
1025 THREADDEPS=
1026 THREADH=
1027 THREADSPEC=
1028 THREADSTARTFILESPEC=
1029 case "$THREADS" in
1030  posix)
1031     case "$host" in
1032      *-*-cygwin*)
1033         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1034         ;;
1035      *-*-freebsd[[1234]]*)
1036         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1037         # merely adds pthread_* functions) but it does have a -pthread switch
1038         # which is required at link-time to select -lc_r *instead* of -lc.
1039         THREADLDFLAGS=-pthread
1040         # Don't set THREADSPEC here as might be expected since -pthread is
1041         # not processed when found within a spec file, it must come from
1042         # the command line.  For now, the user must provide the -pthread
1043         # switch to link code compiled with gcj.  In future, consider adding
1044         # support for weak references to pthread_* functions ala gthr.h API.
1045         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1046         ;;
1047      *-*-freebsd*)
1048         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1049         # systems which support threads and -lpthread.
1050         THREADLDFLAGS=-pthread
1051         THREADSPEC=-lpthread
1052         ;;
1053      alpha*-dec-osf* | hppa*-hp-hpux*)
1054         THREADCXXFLAGS=-pthread
1055         # boehm-gc needs some functions from librt, so link that too.
1056         THREADLIBS='-lpthread -lrt'
1057         THREADSPEC='-lpthread -lrt'
1058         ;;
1059      *)
1060         THREADLIBS=-lpthread
1061         THREADSPEC=-lpthread
1062         ;;
1063     esac
1064     THREADH=posix-threads.h
1065     # MIT pthreads doesn't seem to have the mutexattr functions.
1066     # But for now we don't check for it.  We just assume you aren't
1067     # using MIT pthreads.
1068     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1069
1070     # If we're using the Boehm GC, then we happen to know that it
1071     # defines _REENTRANT, so we don't bother.  Eww.
1072     if test "$GC" != boehm; then
1073        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1074     fi
1075     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1076     ;;
1077
1078  win32)
1079     THREADH=win32-threads.h
1080     THREADCXXFLAGS=-mthreads
1081     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1082     # But we do not want the executables created to be dependent on
1083     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1084     # exception handling contexts.  The following kludge achieves this effect
1085     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1086     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1087     # A workaround is to explicitly use -mthreads while linking Java programs.
1088     # See PR libgcj/28263.
1089     #
1090     # FIXME: In Java we are able to detect thread death at the end of
1091     # Thread.run() so we should be able to clean up the exception handling
1092     # contexts ourselves.
1093     THREADSTARTFILESPEC='crtmt%O%s'
1094     ;;
1095
1096  none)
1097     THREADH=no-threads.h
1098     ;;
1099 esac
1100 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1101 AC_SUBST(THREADLIBS)
1102 AC_SUBST(THREADINCS)
1103 AC_SUBST(THREADDEPS)
1104 AC_SUBST(THREADSPEC)
1105 AC_SUBST(THREADSTARTFILESPEC)
1106 AC_SUBST(THREADLDFLAGS)
1107 AC_SUBST(THREADCXXFLAGS)
1108 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1109 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1110 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1111 if test "$enable_shared" != yes; then
1112   use_libgcj_bc=no
1113 fi
1114 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1115
1116 if test -d sysdep; then true; else mkdir sysdep; fi
1117 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1118 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1119 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1120
1121 LIBGCJ_SPEC_LGCJ=-lgcj
1122 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1123 if test x"$libgcj_spec_lgcj_override" != x ; then
1124   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1125 fi
1126 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1127   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1128 fi
1129 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1130 if test "$use_libgcj_bc" = yes; then
1131   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1132   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1133 fi
1134 AC_SUBST(LIBGCJ_SPEC)
1135 AC_SUBST(LIBGCJ_BC_SPEC)
1136
1137 HASH_SYNC_SPEC=
1138 # Hash synchronization is only useful with posix threads right now.
1139 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1140    HASH_SYNC_SPEC=-fhash-synchronization
1141    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1142 fi
1143 AC_SUBST(HASH_SYNC_SPEC)
1144
1145 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1146
1147 # We're in the tree with gcc, and need to include some of its headers.
1148 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1149
1150 if test "x${with_newlib}" = "xyes"; then
1151    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1152    # may not work correctly, because the compiler may not be able to
1153    # link executables.
1154
1155    # We assume newlib.  This lets us hard-code the functions we know
1156    # we'll have.
1157    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1158    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1159    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1160    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1161    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1162    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1163    # This is only for POSIX threads.
1164    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1165
1166    # Assume we do not have getuid and friends.
1167    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1168    PLATFORMNET=NoNet
1169 else
1170    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1171                    localtime_r getpwuid_r getcwd \
1172                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1173                    nl_langinfo setlocale \
1174                    inet_pton uname inet_ntoa \
1175                    getrlimit sigaction ftruncate mmap \
1176                    getifaddrs])
1177    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1178    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1179    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1180    AC_CHECK_LIB(dl, dladdr, [
1181        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1182        AC_CHECK_LIB(dld, dladdr, [
1183        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1184
1185    if test x"$cross_compiling" = x"no"; then
1186      AC_CHECK_FILES(/proc/self/exe, [
1187        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1188      AC_CHECK_FILES(/proc/self/maps, [
1189        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1190          [Define if you have /proc/self/maps])])
1191    else
1192      case $host in
1193      *-linux*)
1194        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1195        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1196        ;;
1197      esac
1198    fi
1199
1200    AM_ICONV
1201    AM_LC_MESSAGES
1202    AC_STRUCT_TIMEZONE
1203
1204    AC_CHECK_FUNCS(gethostbyname_r, [
1205      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1206        [Define if you have the 'gethostbyname_r' function.])
1207      # There are two different kinds of gethostbyname_r.
1208      # We look for the one that returns `int'.
1209      # Hopefully this check is robust enough.
1210      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1211        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1212
1213      case " $GCINCS " in
1214      *" -D_REENTRANT "*) ;;
1215      *)
1216         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1217         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1218         [libjava_cv_gethostbyname_r_needs_reentrant],
1219         [ AC_LANG_PUSH(C++)
1220           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1221             [[gethostbyname_r("", 0, 0);]])],
1222             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1223                 CPPFLAGS_SAVE="$CPPFLAGS"
1224                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1225                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1226                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1227                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1228                 CPPFLAGS="$CPPFLAGS_SAVE"
1229           ])
1230           AC_LANG_POP(C++)
1231         ])
1232         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1233           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1234         fi
1235      ;;
1236      esac
1237
1238      AC_CACHE_CHECK([for struct hostent_data],
1239         [libjava_cv_struct_hostent_data], [dnl
1240         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1241 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1242 # define _REENTRANT 1
1243 #endif
1244 #include <netdb.h>]], [[struct hostent_data data;]])],
1245           [libjava_cv_struct_hostent_data=yes],
1246           [libjava_cv_struct_hostent_data=no])])
1247      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1248        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1249          [Define if struct hostent_data is defined in netdb.h])
1250      fi
1251    ])
1252
1253    # FIXME: libjava source code expects to find a prototype for
1254    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1255    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1256    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1257    # linkage check is enough, yet C++ code requires proper prototypes.)
1258    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1259    AC_CHECK_FUNCS(gethostbyaddr_r, [
1260      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1261        [Define if you have the 'gethostbyaddr_r' function.])
1262      # There are two different kinds of gethostbyaddr_r.
1263      # We look for the one that returns `int'.
1264      # Hopefully this check is robust enough.
1265      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1266        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1267          [Define if gethostbyaddr_r returns 'int'.])])])])
1268
1269    AC_CHECK_FUNCS(gethostname, [
1270      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1271        [Define if you have the 'gethostname' function.])
1272      AC_EGREP_HEADER(gethostname, unistd.h, [
1273        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1274          [Define if gethostname is declared in <unistd.h>.])])])
1275
1276    AC_CHECK_FUNCS(usleep, [
1277      AC_EGREP_HEADER(usleep, unistd.h, [
1278        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1279           [Define if usleep is declared in <unistd.h>.])])])
1280
1281    # Look for these functions in the thread library, but only bother
1282    # if using POSIX threads.
1283    if test "$THREADS" = posix; then
1284       save_LIBS="$LIBS"
1285       LIBS="$LIBS $THREADLIBS"
1286
1287       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1288       # Solaris 7 the name librt is preferred.
1289       AC_CHECK_FUNCS(sched_yield, , [
1290         AC_CHECK_LIB(rt, sched_yield, [
1291           AC_DEFINE(HAVE_SCHED_YIELD)
1292           THREADLIBS="$THREADLIBS -lrt"
1293           THREADSPEC="$THREADSPEC -lrt"], [
1294           AC_CHECK_LIB(posix4, sched_yield, [
1295             AC_DEFINE(HAVE_SCHED_YIELD)
1296             THREADLIBS="$THREADLIBS -lposix4"
1297             THREADSPEC="$THREADSPEC -lposix4"])])])
1298
1299       AC_CHECK_LIB(rt, clock_gettime, [
1300          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1301          case "$THREADSPEC" in
1302            *-lrt*) ;;
1303            *)
1304              THREADSPEC="$THREADSPEC -lrt"
1305              THREADLIBS="$THREADLIBS -lrt"
1306              ;;
1307          esac])
1308
1309       LIBS="$save_LIBS"
1310
1311       # We can save a little space at runtime if the mutex has m_count
1312       # or __m_count.  This is a nice hack for Linux.
1313       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1314           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1315         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1316              [Define if pthread_mutex_t has m_count member.]), [
1317         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1318             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1319           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1320             [Define if pthread_mutex_t has __m_count member.]))])
1321    fi
1322
1323    # We require a way to get the time.
1324    time_found=no
1325    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1326    if test "$time_found" = no; then
1327       AC_MSG_ERROR([no function found to get the time])
1328    fi
1329
1330    AC_CHECK_FUNCS(memmove)
1331
1332    # We require memcpy.
1333    memcpy_found=no
1334    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1335    if test "$memcpy_found" = no; then
1336       AC_MSG_ERROR([memcpy is required])
1337    fi
1338    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1339    AC_CHECK_LIB(dl, dlopen, [
1340        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1341        AC_CHECK_LIB(dld, dlopen, [
1342        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1343
1344    # Some library-finding code we stole from Tcl.
1345    #--------------------------------------------------------------------
1346    #    Check for the existence of the -lsocket and -lnsl libraries.
1347    #    The order here is important, so that they end up in the right
1348    #    order in the command line generated by make.  Here are some
1349    #    special considerations:
1350    #    1. Use "connect" and "accept" to check for -lsocket, and
1351    #       "gethostbyname" to check for -lnsl.
1352    #    2. Use each function name only once:  can't redo a check because
1353    #       autoconf caches the results of the last check and won't redo it.
1354    #    3. Use -lnsl and -lsocket only if they supply procedures that
1355    #       aren't already present in the normal libraries.  This is because
1356    #       IRIX 5.2 has libraries, but they aren't needed and they're
1357    #       bogus:  they goof up name resolution if used.
1358    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1359    #       To get around this problem, check for both libraries together
1360    #       if -lsocket doesn't work by itself.
1361    #--------------------------------------------------------------------
1362
1363    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1364     [gcj_cv_lib_sockets=
1365      gcj_checkBoth=0
1366      unset ac_cv_func_connect
1367      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1368      if test "$gcj_checkSocket" = 1; then
1369          unset ac_cv_func_connect
1370          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1371                       gcj_checkBoth=1)
1372      fi
1373      if test "$gcj_checkBoth" = 1; then
1374          gcj_oldLibs=$LIBS
1375          LIBS="$LIBS -lsocket -lnsl"
1376          unset ac_cv_func_accept
1377          AC_CHECK_FUNC(accept,
1378                        [gcj_checkNsl=0
1379                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1380          unset ac_cv_func_accept
1381          LIBS=$gcj_oldLibs
1382      fi
1383      unset ac_cv_func_gethostbyname
1384      gcj_oldLibs=$LIBS
1385      LIBS="$LIBS $gcj_cv_lib_sockets"
1386      AC_CHECK_FUNC(gethostbyname, ,
1387                    [AC_CHECK_LIB(nsl, main,
1388                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1389      unset ac_cv_func_gethostbyname
1390      LIBS=$gcj_oldLIBS
1391    ])
1392    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1393
1394    if test "$with_system_zlib" = yes; then
1395       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1396    fi
1397
1398    # Test for Gtk stuff, if asked for.
1399    if test "$use_gtk_awt" = yes; then
1400       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1401       AC_SUBST(GTK_CFLAGS)
1402       AC_SUBST(GTK_LIBS)
1403
1404       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1405       AC_SUBST(GLIB_CFLAGS)
1406       AC_SUBST(GLIB_LIBS)
1407
1408       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1409       AC_SUBST(LIBART_CFLAGS)
1410       AC_SUBST(LIBART_LIBS)
1411
1412       # We require the XTest Extension to support java.awt.Robot.
1413       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1414                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1415                    [${X_LIBS}])
1416    fi
1417
1418    # On Solaris, and maybe other architectures, the Boehm collector
1419    # requires -ldl.
1420    if test "$GC" = boehm; then
1421       case "${host}" in
1422           mips-sgi-irix6*)
1423             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1424             # libgcj.spec is used, so override here
1425             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1426           ;;
1427           *)
1428             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1429           ;;
1430       esac
1431    fi
1432 fi
1433
1434 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1435 case $build in
1436     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1437     *)         CLASSPATH_SEPARATOR=':' ;;
1438 esac
1439 AC_SUBST(CLASSPATH_SEPARATOR)
1440
1441 # We must search the source tree for java.lang, since we still don't
1442 # have libgcj.jar nor java/lang/*.class
1443 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1444 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1445
1446 # Since some classes depend on this one, we need its source available
1447 # before we can do any GCJ compilation test :-(
1448 if test ! -f gnu/classpath/Configuration.java; then
1449   test -d gnu || mkdir gnu
1450   test -d gnu/classpath || mkdir gnu/classpath
1451   # Note that it is not crucial that all the values here be correct.
1452   sed -e "s,@prefix@,$expanded_prefix," \
1453       -e "s,@VERSION@,$VERSION," \
1454       -e "s,@LIBDEBUG@,false," \
1455       -e "s,@INIT_LOAD_LIBRARY@,false," \
1456       -e "s,@@,$LIBGCJDEBUG," \
1457       -e "s,@default_toolkit@,$TOOLKIT," \
1458       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1459       -e "s,@GTK_CAIRO_ENABLED@,false," \
1460       -e "s,@ECJ_JAR@,," \
1461       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1462         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1463         > gnu/classpath/Configuration.java
1464   # We do not want to redirect the output of the grep below to /dev/null,
1465   # but we add /dev/null to the input list so that grep will print the
1466   # filename of Configuration.java in case it finds any matches.
1467   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1468     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1469   fi
1470 fi
1471
1472 LT_AC_PROG_GCJ
1473
1474 # Now remove it.
1475 rm -f gnu/classpath/Configuration.java
1476
1477 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1478
1479 AC_CHECK_SIZEOF(void *)
1480
1481 AC_C_BIGENDIAN
1482
1483 ZLIBS=
1484 SYS_ZLIBS=
1485 ZINCS=
1486
1487 if test -z "$ZLIBSPEC"; then
1488    # Use zlib from the GCC tree.
1489    ZINCS='-I$(top_srcdir)/../zlib'
1490    ZLIBS=../zlib/libzgcj_convenience.la
1491 else
1492    # System's zlib.
1493    SYS_ZLIBS="$ZLIBSPEC"
1494 fi
1495 AC_SUBST(ZLIBS)
1496 AC_SUBST(SYS_ZLIBS)
1497 AC_SUBST(ZINCS)
1498 AC_SUBST(DIVIDESPEC)
1499 AC_SUBST(CHECKREFSPEC)
1500 AC_SUBST(EXCEPTIONSPEC)
1501 AC_SUBST(BACKTRACESPEC)
1502 AC_SUBST(IEEESPEC)
1503 AC_SUBST(ATOMICSPEC)
1504
1505 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1506 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1507 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1508 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1509 AC_SUBST(GCC_UNWIND_INCLUDE)
1510
1511 # Process the option "--enable-version-specific-runtime-libs"
1512 # Calculate toolexeclibdir
1513 case ${version_specific_libs} in
1514   yes)
1515     # Need the gcc compiler version to know where to install libraries
1516     # and header files if --enable-version-specific-runtime-libs option
1517     # is selected.
1518     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1519     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1520     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1521     toolexeclibdir=$toolexecmainlibdir
1522     ;;
1523   no)
1524     if test -n "$with_cross_host" &&
1525        test x"$with_cross_host" != x"no"; then
1526       # Install a library built with a cross compiler in tooldir, not libdir.
1527       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1528       toolexecmainlibdir='$(toolexecdir)/lib'
1529     else
1530       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1531       toolexecmainlibdir='$(libdir)'
1532     fi
1533     multi_os_directory=`$CC -print-multi-os-directory`
1534     case $multi_os_directory in
1535       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1536       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1537     esac
1538     ;;
1539 esac
1540 AC_SUBST(toolexecdir)
1541 AC_SUBST(toolexecmainlibdir)
1542 AC_SUBST(toolexeclibdir)
1543
1544 # Determine gcj and libgcj version number.
1545 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1546 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1547 GCJVERSION=$gcjversion
1548 AC_SUBST(GCJVERSION)
1549 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1550
1551 # Determine where the standard .db file and GNU Classpath JNI
1552 # libraries are found.
1553 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1554 multi_os_directory=`$CC -print-multi-os-directory`
1555 case $multi_os_directory in
1556   .)
1557    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1558    ;;
1559   *)
1560    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1561    ;;
1562 esac
1563 AC_SUBST(dbexecdir)
1564 AC_SUBST(gcjsubdir)
1565
1566 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1567 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1568
1569 TL_AC_GXX_INCLUDE_DIR
1570
1571 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1572 # On that system, sys/ioctl.h will not include sys/filio.h unless
1573 # BSD_COMP is defined; just including sys/filio.h is simpler.
1574 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1575 # for now.  If you change this, you also must update natFile.cc.
1576 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1577                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1578                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1579                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1580                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1581
1582 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1583 AC_CHECK_HEADERS(net/if.h, [], [], [
1584 #ifdef HAVE_SYS_SOCKET_H
1585 #include <sys/socket.h>
1586 #endif
1587 ])
1588
1589 AC_CHECK_HEADERS(inttypes.h, [
1590     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1591     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1592 ])
1593
1594 AC_CHECK_TYPE([ssize_t], [int])
1595 AC_CHECK_TYPE([magic_t], [
1596     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1597 #ifdef HAVE_MAGIC_H
1598 #include <magic.h>
1599 #endif])
1600
1601 AC_MSG_CHECKING([for in_addr_t])
1602 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1603 #if STDC_HEADERS
1604 #include <stdlib.h>
1605 #include <stddef.h>
1606 #endif
1607 #if HAVE_NETINET_IN_H
1608 #include <netinet/in.h>
1609 #endif]], [[in_addr_t foo;]])],
1610   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1611      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1612    AC_MSG_RESULT(yes)],
1613   [AC_MSG_RESULT(no)])
1614
1615 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1616 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1617   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1618      [Define if struct ip_mreq is defined in netinet/in.h.])
1619    AC_MSG_RESULT(yes)],
1620   [AC_MSG_RESULT(no)])
1621
1622 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1623 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1624   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1625      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1626    AC_MSG_RESULT(yes)],
1627   [AC_MSG_RESULT(no)])
1628
1629 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1630 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1631   [AC_DEFINE(HAVE_INET6, 1,
1632      [Define if inet6 structures are defined in netinet/in.h.])
1633    AC_MSG_RESULT(yes)],
1634   [AC_MSG_RESULT(no)])
1635
1636 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1637 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1638 #include <sys/types.h>
1639 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1640   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1641    AC_MSG_RESULT(yes)],
1642   [AC_MSG_RESULT(no)])
1643
1644 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1645 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1646   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1647    AC_MSG_RESULT(yes)],
1648   [AC_MSG_RESULT(no)
1649    AC_MSG_CHECKING([for global timezone variable])
1650    dnl FIXME: we don't want a link check here because that won't work
1651    dnl when cross-compiling.  So instead we make an assumption that
1652    dnl the header file will mention timezone if it exists.
1653    dnl Don't find the win32 function timezone
1654    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1655      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1656       AC_MSG_RESULT(yes)],
1657      [AC_MSG_RESULT(no)
1658        AC_MSG_CHECKING([for global _timezone variable])
1659        dnl FIXME: As above, don't want link check
1660        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1661          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1662             [Define if your platform has the global _timezone variable.])
1663           AC_MSG_RESULT(yes)],
1664           [AC_MSG_RESULT(no)])])])
1665
1666 AC_CHECK_PROGS(PERL, perl, false)
1667
1668 SYSDEP_SOURCES=
1669 SIGNAL_HANDLER_AUX=
1670
1671 case "${host}" in
1672  i?86-*-linux*)
1673     SIGNAL_HANDLER=include/i386-signal.h
1674     ;;
1675  sparc*-sun-solaris*)
1676     SIGNAL_HANDLER=include/sparc-signal.h
1677     ;;
1678 # ia64-*)
1679 #    SYSDEP_SOURCES=sysdep/ia64.c
1680 #    test -d sysdep || mkdir sysdep
1681 #    ;;
1682  hppa*-*-linux*)
1683     SIGNAL_HANDLER=include/pa-signal.h
1684     ;;
1685  hppa*-hp-hpux*)
1686     SIGNAL_HANDLER=include/hppa-signal.h
1687     ;;
1688  ia64-*-linux*)
1689     SIGNAL_HANDLER=include/dwarf2-signal.h
1690     ;;
1691  powerpc*-*-linux*)
1692     SIGNAL_HANDLER=include/powerpc-signal.h
1693     ;;
1694  alpha*-*-linux*)
1695     SIGNAL_HANDLER=include/dwarf2-signal.h
1696     ;;
1697  s390*-*-linux*)
1698     SIGNAL_HANDLER=include/s390-signal.h
1699     ;;
1700  x86_64*-*-linux*)
1701     SIGNAL_HANDLER=include/x86_64-signal.h
1702     SIGNAL_HANDLER_AUX=include/i386-signal.h
1703     ;;
1704  sparc*-*-linux*)
1705     SIGNAL_HANDLER=include/dwarf2-signal.h
1706     ;;
1707  sh*-*-linux*)
1708     SIGNAL_HANDLER=include/sh-signal.h
1709     ;;
1710  *mingw*)
1711     SIGNAL_HANDLER=include/win32-signal.h
1712     ;;
1713  mips*-*-linux*)
1714     SIGNAL_HANDLER=include/mips-signal.h
1715     ;;
1716  m68*-*-linux*)
1717     SIGNAL_HANDLER=include/dwarf2-signal.h
1718     ;;
1719  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1720     SIGNAL_HANDLER=include/darwin-signal.h
1721     ;;
1722  powerpc*-*-aix*)
1723     SIGNAL_HANDLER=include/aix-signal.h
1724     ;;
1725  *)
1726     SIGNAL_HANDLER=include/default-signal.h
1727     ;;
1728 esac
1729
1730 # If we're using sjlj exceptions, forget what we just learned.
1731 if test "$enable_sjlj_exceptions" = yes; then
1732    SIGNAL_HANDLER=include/default-signal.h
1733    SIGNAL_HANDLER_AUX=
1734 fi
1735
1736 AC_SUBST(SYSDEP_SOURCES)
1737
1738 if test -z "$SIGNAL_HANDLER_AUX"; then
1739   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1740 fi
1741
1742 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1743                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1744
1745 if test "${multilib}" = "yes"; then
1746   multilib_arg="--enable-multilib"
1747 else
1748   multilib_arg=
1749 fi
1750
1751 # See if we support thread-local storage.
1752 GCC_CHECK_TLS
1753
1754 # For _Unwind_GetIPInfo.
1755 GCC_CHECK_UNWIND_GETIPINFO
1756
1757 # See if linker supports anonymous version scripts.
1758 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1759   [libjava_cv_anon_version_script],
1760   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1761    libjava_cv_anon_version_script=no
1762    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1763    echo '{ global: globalsymb*; local: *; };' > conftest.map
1764    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1765                [libjava_cv_anon_version_script=yes], [])
1766    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1767   ])
1768 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1769
1770 # Check if linker supports static linking on a per library basis
1771 LD_START_STATIC_SPEC=
1772 LD_FINISH_STATIC_SPEC=
1773 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1774   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1775     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1776     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1777   fi
1778 fi
1779 AC_SUBST(LD_START_STATIC_SPEC)
1780 AC_SUBST(LD_FINISH_STATIC_SPEC)
1781
1782 here=`${PWDCMD-pwd}`
1783 AC_SUBST(here)
1784
1785 # We get this from the environment.
1786 AC_SUBST(GCJFLAGS)
1787
1788 AC_ARG_WITH([python-dir],
1789             AS_HELP_STRING([--with-python-dir],
1790                            [the location to install Python modules. This path should NOT include the prefix.]),
1791             [with_python_dir=$withval], [with_python_dir=""])
1792
1793 if test "x${with_python_dir}" = "x"
1794 then
1795   # Needed for installing Python modules during make install.
1796   python_mod_dir="\${prefix}/share/python"
1797   # Needed for substituting into aot-compile*
1798   python_mod_dir_expanded="${expanded_prefix}/share/python"
1799 else
1800   python_mod_dir="\${prefix}${with_python_dir}"
1801   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1802 fi
1803 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1804 AC_SUBST(python_mod_dir)
1805 AC_SUBST(python_mod_dir_expanded)
1806
1807 # needed for aot-compile-rpm
1808 MAKE=`which make`
1809 AC_SUBST(MAKE)
1810
1811 AC_ARG_ENABLE([aot-compile-rpm],
1812   [AS_HELP_STRING([--enable-aot-compile-rpm],
1813                  [enable installation of aot-compile-rpm [default=no]])],
1814   [case "${enableval}" in
1815     yes) AOT_RPM_ENABLED=yes ;;
1816     no)  AOT_RPM_ENABLED=no ;;
1817     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1818   esac],
1819   [AOT_RPM_ENABLED=no]
1820 )
1821 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1822
1823 AC_ARG_ENABLE([java-home],
1824   [AS_HELP_STRING([--enable-java-home],
1825                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1826   [case "${enableval}" in
1827     yes) JAVA_HOME_ENABLED=yes ;;
1828     no)  JAVA_HOME_ENABLED=no ;;
1829     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1830   esac],
1831   [JAVA_HOME_ENABLED=no]
1832 )
1833 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1834
1835 # Only do these checks if java-home above is enabled.
1836 if test "x${JAVA_HOME_ENABLED}" = xyes
1837 then
1838
1839   AC_ARG_WITH([gcc-suffix],
1840               AS_HELP_STRING([--with-gcc-suffix],
1841                              [the GCC tool suffix (defaults to empty string)]),
1842               [gcc_suffix=$withval], [gcc_suffix=""])
1843   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1844   AC_SUBST(gcc_suffix)
1845
1846   AC_ARG_WITH([arch-directory],
1847               AS_HELP_STRING([--with-arch-directory],
1848                              [the arch directory under jre/lib (defaults to auto-detect)]),
1849               [host_cpu=$withval], [host_cpu=""])
1850
1851   AC_ARG_WITH([os-directory],
1852               AS_HELP_STRING([--with-os-directory],
1853                              [the os directory under include (defaults to auto-detect)]),
1854               [host_os=$withval], [host_os=""])
1855
1856   AC_ARG_WITH([origin-name],
1857               AS_HELP_STRING([--with-origin-name],
1858                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1859               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1860   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1861
1862   AC_ARG_WITH([arch-suffix],
1863               AS_HELP_STRING([--with-arch-suffix],
1864                              [the arch directory suffix (default is the empty string]),
1865               [arch_suffix=$withval], [arch_suffix=""])
1866   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1867
1868   AC_ARG_WITH([jvm-root-dir],
1869               AS_HELP_STRING([--with-jvm-root-dir],
1870                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1871               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1872   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1873
1874   AC_ARG_WITH([jvm-jar-dir],
1875               AS_HELP_STRING([--with-jvm-jar-dir],
1876                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1877               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1878   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1879
1880   JAVA_VERSION=1.5.0
1881   BUILD_VERSION=0
1882   AC_SUBST(JAVA_VERSION)
1883   AC_SUBST(BUILD_VERSION)
1884   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1885
1886   jre_dir=jre
1887   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1888   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1889
1890   JVM_ROOT_DIR=${jvm_root_dir}
1891   AC_SUBST(JVM_ROOT_DIR)
1892   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1893
1894   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1895   AC_SUBST(JVM_JAR_ROOT_DIR)
1896   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1897
1898   JVM_JAR_DIR=${jvm_jar_dir}
1899   AC_SUBST(JVM_JAR_DIR)
1900   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1901
1902   JRE_DIR=${jre_dir}
1903   AC_SUBST(JRE_DIR)
1904
1905   JRE_LNK=${jre_lnk}
1906   AC_SUBST(JRE_LNK)
1907
1908   SDK_LNK=${sdk_lnk}
1909   AC_SUBST(SDK_LNK)
1910
1911   SDK_BIN_DIR=${jvm_root_dir}/bin
1912   AC_SUBST(SDK_BIN_DIR)
1913   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1914
1915   SDK_LIB_DIR=${jvm_root_dir}/lib
1916   AC_SUBST(SDK_LIB_DIR)
1917   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1918
1919   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1920   AC_SUBST(SDK_INCLUDE_DIR)
1921   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1922
1923   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1924   AC_SUBST(JRE_BIN_DIR)
1925   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1926
1927   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1928   AC_SUBST(JRE_LIB_DIR)
1929   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1930
1931   # Find gcj prefix using gcj found in PATH.
1932   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1933
1934   # Where do the gcj binaries live?
1935   # For jhbuild based builds, they all live in a sibling of bin called
1936   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1937   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1938   AC_SUBST(GCJ_BIN_DIR)
1939   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1940
1941   AC_MSG_RESULT(host is ${host})
1942   if test "x${host_cpu}" = "x"
1943   then
1944     case ${host} in
1945       *-mingw* | *-cygwin*)
1946         host_cpu=x86;;
1947       i486-* | i586-* | i686-*)
1948         host_cpu=i386;;
1949       x86_64-*)
1950         host_cpu=amd64;;
1951       *)
1952         host_cpu=${host_cpu};;
1953     esac
1954   fi
1955   AC_MSG_RESULT(arch directory: ${host_cpu})
1956   CPU=${host_cpu}
1957   AC_SUBST(CPU)
1958
1959   if test "x${host_os}" = "x"
1960   then
1961     case ${host} in
1962       *-mingw* | *-cygwin*)
1963         host_os=win32;;
1964       *-linux*)
1965         host_os=linux;;
1966       *)
1967         host_os=${host_os};;
1968     esac
1969   fi
1970   echo os directory: ${host_os}
1971   OS=${host_os}
1972   AC_SUBST(OS)
1973
1974   # make an expanded $libdir, for substituting into
1975   # scripts (and other non-Makefile things).
1976   LIBDIR=$libdir
1977   if test "x${exec_prefix}" = "xNONE"
1978   then
1979       lib_exec_prefix=$expanded_prefix
1980   else
1981       lib_exec_prefix=$exec_prefix
1982   fi
1983   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1984   AC_SUBST(LIBDIR)
1985 fi
1986
1987 AC_CONFIG_FILES([
1988 Makefile
1989 libgcj.pc
1990 libgcj.spec
1991 libgcj-test.spec
1992 gcj/Makefile
1993 include/Makefile
1994 testsuite/Makefile
1995 contrib/aotcompile.py
1996 contrib/aot-compile
1997 contrib/aot-compile-rpm
1998 contrib/generate-cacerts.pl
1999 contrib/rebuild-gcj-db
2000 ])
2001
2002 if test ${multilib} = yes; then
2003   multilib_arg="--enable-multilib"
2004 else
2005   multilib_arg=
2006 fi
2007
2008 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2009 AC_OUTPUT