libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(LD, ld)
 117 AC_CHECK_TOOL(AR, ar)
 118 AC_CHECK_TOOL(RANLIB, ranlib, :)
 119
 120 AC_PROG_INSTALL
 121
 122 AM_MAINTAINER_MODE
 123
 124 AC_EXEEXT
 125
 126 # configure.host sets the following important variables
 127 #       libgcj_cflags    - host specific C compiler flags
 128 #       libgcj_cxxflags  - host specific C++ compiler flags
 129 #       libgcj_javaflags - host specific Java compiler flags
 130
 131 libgcj_cflags=
 132 libgcj_cxxflags=
 133 libgcj_javaflags=
 134
 135 . ${srcdir}/configure.host
 136
 137 LIBGCJ_CFLAGS="${libgcj_cflags}"
 138 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 139 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 140 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 141 AC_SUBST(LIBGCJ_CFLAGS)
 142 AC_SUBST(LIBGCJ_CXXFLAGS)
 143 AC_SUBST(LIBGCJ_JAVAFLAGS)
 144 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 145
 146 # Only use libltdl for non-newlib builds.
 147 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 148    AC_LTDL_SHLIBPATH
 149 fi
 150
 151 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 152
 153 # See if the user has requested runtime debugging.
 154 LIBGCJDEBUG="disable"
 155 AC_SUBST(LIBGCJDEBUG)
 156 AC_ARG_ENABLE(libgcj-debug,
 157   AS_HELP_STRING([--enable-libgcj-debug],
 158                  [enable runtime debugging code]),
 159   [if test "$enable_libgcj_debug" = yes; then
 160     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 161     LIBGCJDEBUG="enable"
 162   fi])
 163
 164 # Determine which AWT peer libraries to build
 165 AC_ARG_ENABLE(java-awt,
 166   AS_HELP_STRING([--enable-java-awt],
 167                  [list of AWT peer implementations to be built]))
 168
 169 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 170 use_xlib_awt=""
 171 use_gtk_awt=""
 172 use_qt_awt=""
 173 # The default toolkit to use is the first one specified.
 174 TOOLKIT=
 175 AC_SUBST(TOOLKIT)
 176
 177 for peer in $peerlibs ; do
 178   case $peer in
 179     xlib)
 180       if test "$no_x" = yes; then
 181         echo "*** xlib peers requested but no X library available" 1>&2
 182         exit 1
 183       else
 184         use_xlib_awt="yes"
 185         if test -z "$TOOLKIT"; then
 186            TOOLKIT=gnu.awt.xlib.XToolkit
 187         fi
 188       fi
 189       ;;
 190     gtk)
 191       if test "$no_x" = yes; then
 192          echo "*** gtk peers requested but no X library available" 1>&2
 193          exit 1
 194       else
 195          use_gtk_awt=yes
 196          if test -z "$TOOLKIT"; then
 197             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 198          fi
 199       fi
 200       ;;
 201     qt)
 202       if test "$no_x" = yes; then
 203          # Perhaps we should admit the possibility of embedded Qt.
 204          echo "*** Qt peers requested but no X library available" 1>&2
 205          exit 1
 206       else
 207          use_qt_awt=yes
 208          if test -z "$TOOLKIT"; then
 209             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 210          fi
 211       fi
 212       ;;
 213     no)
 214       use_xlib_awt=
 215       use_gtk_awt=
 216       use_qt_awt=
 217       break
 218       ;;
 219     *)
 220       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 221       exit 1
 222   esac
 223 done
 224
 225 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 226 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 227 AM_CONDITIONAL(QT_AWT, test "$use_qt_awt" = yes)
 228
 229 # Create standard.omit based on decisions we just made.
 230 cp $srcdir/standard.omit.in standard.omit
 231 if test "$use_xlib_awt" != yes; then
 232    echo gnu/awt/xlib >> standard.omit
 233    echo gnu/gcj/xlib >> standard.omit
 234 fi
 235 if test "$use_gtk_awt" != yes; then
 236    echo gnu/java/awt/peer/gtk >> standard.omit
 237 fi
 238 if test "$use_qt_awt" != yes; then
 239    echo gnu/java/awt/peer/qt >> standard.omit
 240 fi
 241
 242 if test -z "${with_multisubdir}"; then
 243    builddotdot=.
 244 else
 245    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 246 fi
 247
 248 NATIVE=yes
 249
 250 # Which gcj do we use?
 251 which_gcj=default
 252 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 253 if test -n "${with_cross_host}"; then
 254   # We are being configured with a cross compiler. We can't
 255   # use ac_exeext, because that is for the target platform.
 256   NATIVE=no
 257   cross_host_exeext=
 258   case "${with_cross_host}" in
 259      *mingw* | *cygwin*)
 260          cross_host_exeext=.exe
 261      ;;
 262   esac
 263   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 264      if test x"$build_noncanonical" = x"$with_cross_host"; then
 265         # Ordinary cross (host!=target and host=build)
 266         which_gcj=built
 267      else
 268         # Canadian cross (host!=target and host!=build)
 269         which_gcj=cross
 270      fi
 271   else
 272      which_gcj=cross
 273   fi
 274 else
 275   # We are being configured with a native or crossed-native compiler
 276   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 277      if test x"$build" = x"$host"; then
 278         # True native build (host=target and host=build)
 279         which_gcj=built
 280      else
 281         # Crossed-native build (host=target and host!=build)
 282         which_gcj=cross
 283      fi
 284   else
 285      which_gcj=path
 286   fi
 287 fi
 288 case "${which_gcj}" in
 289    built)
 290       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 291       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 292       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 293    ;;
 294    cross)
 295       if test "x${with_newlib}" = "xyes"; then
 296          # FIXME (comment): Why is this needed?
 297          GCC_UNWIND_INCLUDE=
 298          GCJ="${target_noncanonical}-gcj"
 299       else
 300          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 301       fi
 302       ZIP='$(target_noncanonical)-fastjar'
 303       GCJH='$(target_noncanonical)-gcjh'
 304    ;;
 305    path)
 306       GCJ="gcj -B`${PWDCMD-pwd}`/"
 307       ## In this case, gcj is found outside the build tree.  However, zip is
 308       ## found in the build tree.
 309       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 310       GCJH=gcjh
 311    ;;
 312 esac
 313
 314 AC_SUBST(GCJH)
 315 AC_SUBST(ZIP)
 316
 317 # Create it, so that compile/link tests don't fail
 318 test -f libgcj.spec || touch libgcj.spec
 319
 320
 321
 322 # Set up to configure Classpath.
 323 # FIXME: no supported way to pass args in autoconf.
 324 ac_configure_args="$ac_configure_args --disable-load-library"
 325 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 326 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 327 dir1=`cd $srcdir && pwd`
 328 dir2=`pwd`
 329 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 330 ac_configure_args="$ac_configure_args --disable-core-jni"
 331 dnl FIXME?
 332 ac_configure_args="$ac_configure_args --disable-examples"
 333 ac_configure_args="$ac_configure_args --with-glibj=build"
 334 if test "$use_gtk_awt" != yes; then
 335   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 336 fi
 337 if test "$use_qt_awt" != yes; then
 338   ac_configure_args="$ac_configure_args --disable-qt-peer"
 339 else
 340   # We need this as qt is disabled by default in classpath.
 341   ac_configure_args="$ac_configure_args --enable-qt-peer"
 342 fi
 343 dnl --with-gcj=$GCJ
 344 dnl --with-javah=$GCJH
 345 dnl gjdoc?
 346 dnl gtk-cairo -- just export here...
 347 dnl --enable-regen-headers?
 348
 349 # Only use libltdl for non-newlib builds.
 350 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 351    AC_LIBLTDL_CONVENIENCE
 352    AC_LIBTOOL_DLOPEN
 353    DIRLTDL=libltdl
 354    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 355    # Sigh.  Libtool's macro doesn't do the right thing.
 356    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 357    # FIXME: this is a hack.
 358    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 359    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 360 fi
 361 AC_SUBST(INCLTDL)
 362 AC_SUBST(LIBLTDL)
 363 AC_SUBST(DIRLTDL)
 364 AC_PROG_LIBTOOL
 365 AM_PROG_GCJ
 366 AM_PROG_CC_C_O
 367
 368 AC_CONFIG_SUBDIRS(classpath libltdl)
 369
 370 # The -no-testsuite modules omit the test subdir.
 371 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 372
 373 # Should the runtime set system properties by examining the
 374 # environment variable GCJ_PROPERTIES?
 375 AC_ARG_ENABLE(getenv-properties,
 376   AS_HELP_STRING([--disable-getenv-properties],
 377                  [don't set system properties from GCJ_PROPERTIES]))
 378
 379 # Whether GCJ_PROPERTIES is used depends on the target.
 380 if test -z "$enable_getenv_properties"; then
 381    enable_getenv_properties=${enable_getenv_properties_default-yes}
 382 fi
 383 if test "$enable_getenv_properties" = no; then
 384    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 385      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 386 fi
 387
 388 # Whether we should use arguments to main()
 389 if test -z "$enable_main_args"; then
 390    enable_main_args=${enable_main_args_default-yes}
 391 fi
 392 if test "$enable_main_args" = no; then
 393    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 394 fi
 395
 396
 397 # Should we use hashtable-based synchronization?
 398 # Currently works only for Linux X86/ia64
 399 # Typically faster and more space-efficient
 400 AC_ARG_ENABLE(hash-synchronization,
 401   AS_HELP_STRING([--enable-hash-synchronization],
 402                  [use global hash table for monitor locks]))
 403
 404 if test -z "$enable_hash_synchronization"; then
 405    enable_hash_synchronization=$enable_hash_synchronization_default
 406 fi
 407
 408 AC_ARG_WITH(java-home,
 409   AS_HELP_STRING([--with-java-home=DIRECTORY],
 410                  [value of java.home system property]),
 411                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 412 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 413 AC_SUBST(JAVA_HOME)
 414
 415 # What is the native OS API for MinGW?
 416 AC_ARG_WITH(win32-nlsapi,
 417   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 418                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 419 [case "${withval}" in
 420   ansi) with_win32_nlsapi=ansi ;;
 421   unicows) with_win32_nlsapi=unicows ;;
 422   unicode) with_win32_nlsapi=unicode ;;
 423   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 424 esac],[with_win32_nlsapi=ansi])
 425
 426 case "${with_win32_nlsapi}" in
 427   unicows | unicode)
 428     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 429       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 430     ;;
 431 esac
 432
 433 # configure.host sets slow_pthread_self if the synchronization code should
 434 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 435 if test "${slow_pthread_self}" = "yes"; then
 436   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 437     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 438 fi
 439
 440 # Check for gc debugging.  This option is handled both here and in the GC.
 441 AC_ARG_ENABLE(gc-debug,
 442    AS_HELP_STRING([--enable-gc-debug],
 443                   [include full support for pointer backtracing etc.]),
 444 [ if test "$enable_gc_debug" = "yes"; then
 445     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 446               [Define if we want to use debug calls into the garbage collector.])
 447   fi])
 448
 449 # See if the user has the interpreter included.
 450 AC_ARG_ENABLE(interpreter,
 451   AS_HELP_STRING([--enable-interpreter],
 452                  [enable interpreter]),
 453   [if test "$enable_interpreter" = yes; then
 454     # This can also be set in configure.host.
 455     libgcj_interpreter=yes
 456   elif test "$enable_interpreter" = no; then
 457     libgcj_interpreter=no
 458   fi])
 459
 460 if test "$libgcj_interpreter" = yes; then
 461    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 462 fi
 463 INTERPRETER="$libgcj_interpreter"
 464 AC_SUBST(INTERPRETER)
 465
 466 AC_MSG_CHECKING([for exception model to use])
 467 AC_LANG_PUSH(C++)
 468 AC_ARG_ENABLE(sjlj-exceptions,
 469   AS_HELP_STRING([--enable-sjlj-exceptions],
 470                  [force use of builtin_setjmp for exceptions]),
 471 [:],
 472 [dnl Botheration.  Now we've got to detect the exception model.
 473 dnl Link tests against libgcc.a are problematic since -- at least
 474 dnl as of this writing -- we've not been given proper -L bits for
 475 dnl single-tree newlib and libgloss.
 476 dnl
 477 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 478 dnl conftest files before we got a change to grep them first.
 479 cat > conftest.$ac_ext << EOF
 480 [#]line __oline__ "configure"
 481 struct S { ~S(); };
 482 void bar();
 483 void foo()
 484 {
 485   S s;
 486   bar();
 487 }
 488 EOF
 489 old_CXXFLAGS="$CXXFLAGS"
 490 CXXFLAGS=-S
 491 if AC_TRY_EVAL(ac_compile); then
 492   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 493     enable_sjlj_exceptions=yes
 494   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 495     enable_sjlj_exceptions=no
 496   fi
 497 fi
 498 CXXFLAGS="$old_CXXFLAGS"
 499 rm -f conftest*])
 500 if test x$enable_sjlj_exceptions = xyes; then
 501   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 502         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 503   ac_exception_model_name=sjlj
 504 elif test x$enable_sjlj_exceptions = xno; then
 505   ac_exception_model_name="call frame"
 506 else
 507   AC_MSG_ERROR([unable to detect exception model])
 508 fi
 509 AC_LANG_POP(C++)
 510 AC_MSG_RESULT($ac_exception_model_name)
 511
 512 # If we are non using SJLJ exceptions, and this host does not have support
 513 # for unwinding from a signal handler, enable checked dereferences and divides.
 514 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 515   CHECKREFSPEC=-fcheck-references
 516   DIVIDESPEC=-fuse-divide-subroutine
 517   EXCEPTIONSPEC=
 518 fi
 519
 520 # See if the user wants to disable java.net.  This is the mildly
 521 # ugly way that we admit that target-side configuration sucks.
 522 AC_ARG_ENABLE(java-net,
 523   AS_HELP_STRING([--disable-java-net],
 524                  [disable java.net]))
 525
 526 # Whether java.net is built by default can depend on the target.
 527 if test -z "$enable_java_net"; then
 528    enable_java_net=${enable_java_net_default-yes}
 529 fi
 530 if test "$enable_java_net" = no; then
 531    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 532 fi
 533
 534 # See if the user wants to configure without libffi.  Some
 535 # architectures don't support it, and default values are set in
 536 # configure.host.
 537 AC_ARG_WITH(libffi,
 538   AS_HELP_STRING([--without-libffi],
 539                  [don't use libffi]),
 540   [:],
 541   [with_libffi=${with_libffi_default-yes}])
 542
 543 LIBFFI=
 544 LIBFFIINCS=
 545 if test "$with_libffi" != no; then
 546    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 547    LIBFFI=../libffi/libffi_convenience.la
 548    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 549 fi
 550 AC_SUBST(LIBFFI)
 551 AC_SUBST(LIBFFIINCS)
 552
 553 # See if the user wants to disable JVMPI support.
 554 AC_ARG_ENABLE(jvmpi,
 555   AS_HELP_STRING([--disable-jvmpi],
 556                  [disable JVMPI support]))
 557
 558 if test "$enable_jvmpi" != no; then
 559     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 560 fi
 561
 562 # If the target is an eCos system, use the appropriate eCos
 563 # I/O routines.
 564 # FIXME: this should not be a local option but a global target
 565 # system; at present there is no eCos target.
 566 TARGET_ECOS=${PROCESS-"no"}
 567 AC_ARG_WITH(ecos,
 568 [  --with-ecos             enable runtime eCos target support],
 569 TARGET_ECOS="$with_ecos"
 570 )
 571
 572 PLATFORM_INNER_NAT_HDRS=
 573 case "$TARGET_ECOS" in
 574    no) case "$host" in
 575       *mingw*)
 576             PLATFORM=Win32
 577             PLATFORMNET=Win32
 578             PLATFORMH=win32.h
 579         CHECK_FOR_BROKEN_MINGW_LD
 580       ;;
 581       *)
 582             PLATFORM=Posix
 583             PLATFORMNET=Posix
 584             PLATFORMH=posix.h
 585             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 586       ;;
 587       esac
 588       ;;
 589    *)
 590       PLATFORM=Ecos
 591       PLATFORMNET=NoNet
 592       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 593       PLATFORMH=posix.h
 594       ;;
 595 esac
 596 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 597 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 598
 599 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 600                                       [Define if you have int32_t and uint32_t.]))
 601 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 602                                         [Define if you have int32_t and uint32_t.]))
 603 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 604                                           [Define if you have u_int32_t]))
 605 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 606                                            [Define if you have u_int32_t]))
 607
 608 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 609 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 610
 611 case "$host" in
 612   *-darwin*) DARWIN_CRT=true ;;
 613   *) DARWIN_CRT=false ;;
 614 esac
 615 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 616
 617 # These may not be defined in a non-ANS conformant embedded system.
 618 # FIXME: Should these case a runtime exception in that case?
 619 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 620                                   [Define is you have 'mktime' in <time.h>]))
 621 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 622                                   [Define is you have 'localtime' in <time.h>]))
 623
 624 # Create the subdirectory for natFile.cc, or the attempt
 625 # to create the link will fail.
 626 test -d java || mkdir java
 627 test -d java/io || mkdir java/io
 628 test -d gnu || mkdir gnu
 629 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 630
 631 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 632 test -d java/lang || mkdir java/lang
 633 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 634 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 635
 636 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 637 test -d java/net || mkdir java/net
 638 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 639 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 640
 641 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 642 test -d gnu/java || mkdir gnu/java
 643 test -d gnu/java/net || mkdir gnu/java/net
 644 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 645 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 646
 647 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 648 test -d gnu/java/nio || mkdir gnu/java/nio
 649 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 650 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 651 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 652 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 653
 654 case "${host}" in
 655     *mingw*)
 656       SYSTEMSPEC="-lgdi32 -lws2_32"
 657       if test "${with_win32_nlsapi}" = "unicows"; then
 658         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 659       fi
 660     ;;
 661     *)
 662       SYSTEMSPEC=
 663     ;;
 664 esac
 665 AC_SUBST(SYSTEMSPEC)
 666
 667 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 668 AC_SUBST(LIBGCJTESTSPEC)
 669
 670 AC_ARG_WITH(system-zlib,
 671   AS_HELP_STRING([--with-system-zlib],
 672                  [use installed libz]))
 673 ZLIBSPEC=
 674 AC_SUBST(ZLIBSPEC)
 675 ZLIBTESTSPEC=
 676 AC_SUBST(ZLIBTESTSPEC)
 677
 678 AC_PATH_XTRA
 679
 680 # determine whether to enable the cairo GTK Graphics2D backend
 681 AC_ARG_ENABLE(gtk-cairo,
 682   AS_HELP_STRING([--enable-gtk-cairo],
 683                  [build the cairo Graphics2D implementation on GTK]))
 684 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 685 if test "x${enable_gtk_cairo}" = xyes
 686 then
 687         PKG_CHECK_MODULES(CAIRO, cairo)
 688         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 689 fi
 690 AC_SUBST(CAIRO_LIBS)
 691 AC_SUBST(CAIRO_CFLAGS)
 692 AC_SUBST(PANGOFT2_LIBS)
 693 AC_SUBST(PANGOFT2_CFLAGS)
 694
 695 # FIXME: this should be _libs on some hosts.
 696 libsubdir=.libs
 697
 698 # extra LD Flags which are required for targets
 699 case "${host}" in
 700 *-*-darwin[[0-7]].*)
 701     # For now we have to disable it on darwin[8-9] because it slows down
 702     # the linking phase. A possible bug in ld?
 703     # on Darwin -single_module speeds up loading of the dynamic libraries.
 704     extra_ldflags_libjava=-Wl,-single_module
 705     ;;
 706 esac
 707 AC_SUBST(extra_ldflags_libjava)
 708
 709 # Allow the GC to be disabled.  Can be useful when debugging.
 710 AC_MSG_CHECKING([for garbage collector to use])
 711 AC_ARG_ENABLE(java-gc,
 712   AS_HELP_STRING([--enable-java-gc=TYPE],
 713                  [choose garbage collector (default is boehm)]),
 714   [GC=$enableval],
 715   [GC=boehm])
 716 GCLIBS=
 717 GCINCS=
 718 GCDEPS=
 719 GCSPEC=
 720 JC1GCSPEC=
 721 GCTESTSPEC=
 722 case "$GC" in
 723  boehm)
 724     AC_MSG_RESULT(boehm)
 725     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 726     JC1GCSPEC='-fuse-boehm-gc'
 727     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 728     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 729     GCOBJS=boehm.lo
 730     GCHDR=boehm-gc.h
 731     # The POSIX thread support needs to know this.
 732     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 733     ;;
 734  no)
 735     AC_MSG_RESULT(none)
 736     GCHDR=no-gc.h
 737     ;;
 738  *)
 739     AC_MSG_ERROR([unrecognized collector "$GC"])
 740     ;;
 741 esac
 742 AC_SUBST(GCLIBS)
 743 AC_SUBST(GCINCS)
 744 AC_SUBST(GCDEPS)
 745 AC_SUBST(GCSPEC)
 746 AC_SUBST(JC1GCSPEC)
 747 AC_SUBST(GCTESTSPEC)
 748 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 749 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 750 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 751
 752
 753 AC_MSG_CHECKING([for thread model used by GCC])
 754 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 755 AC_MSG_RESULT([$THREADS])
 756
 757 case "$THREADS" in
 758  no | none | single)
 759     THREADS=none
 760     ;;
 761  posix | posix95 | pthreads)
 762     THREADS=posix
 763     case "$host" in
 764      *-*-linux*)
 765         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 766         ;;
 767     esac
 768     ;;
 769  win32)
 770     ;;
 771  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 772     AC_MSG_ERROR(thread package $THREADS not yet supported)
 773     ;;
 774  *)
 775     AC_MSG_ERROR($THREADS is an unknown thread package)
 776     ;;
 777 esac
 778
 779 THREADCXXFLAGS=
 780 THREADLDFLAGS=
 781 THREADLIBS=
 782 THREADINCS=
 783 THREADDEPS=
 784 THREADH=
 785 THREADSPEC=
 786 case "$THREADS" in
 787  posix)
 788     case "$host" in
 789      *-*-cygwin*)
 790         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 791         ;;
 792      *-*-freebsd[[1234]]*)
 793         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 794         # merely adds pthread_* functions) but it does have a -pthread switch
 795         # which is required at link-time to select -lc_r *instead* of -lc.
 796         THREADLDFLAGS=-pthread
 797         # Don't set THREADSPEC here as might be expected since -pthread is
 798         # not processed when found within a spec file, it must come from
 799         # the command line.  For now, the user must provide the -pthread
 800         # switch to link code compiled with gcj.  In future, consider adding
 801         # support for weak references to pthread_* functions ala gthr.h API.
 802         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 803         ;;
 804      *-*-freebsd*)
 805         # FreeBSD 5 implements a model much closer to other modern UNIX
 806         # which support threads.  However, it still does not support
 807         # -lpthread.
 808         THREADLDFLAGS=-pthread
 809         THREADSPEC=-lc_r
 810         ;;
 811      alpha*-dec-osf*)
 812         THREADCXXFLAGS=-pthread
 813         # boehm-gc needs some functions from librt, so link that too.
 814         THREADLIBS='-lpthread -lrt'
 815         THREADSPEC='-lpthread -lrt'
 816         ;;
 817      *)
 818         THREADLIBS=-lpthread
 819         THREADSPEC=-lpthread
 820         ;;
 821     esac
 822     THREADH=posix-threads.h
 823     # MIT pthreads doesn't seem to have the mutexattr functions.
 824     # But for now we don't check for it.  We just assume you aren't
 825     # using MIT pthreads.
 826     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 827
 828     # If we're using the Boehm GC, then we happen to know that it
 829     # defines _REENTRANT, so we don't bother.  Eww.
 830     if test "$GC" != boehm; then
 831        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 832     fi
 833     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 834     ;;
 835
 836  win32)
 837     THREADH=win32-threads.h
 838     ;;
 839
 840  none)
 841     THREADH=no-threads.h
 842     ;;
 843 esac
 844 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 845 AC_SUBST(THREADLIBS)
 846 AC_SUBST(THREADINCS)
 847 AC_SUBST(THREADDEPS)
 848 AC_SUBST(THREADSPEC)
 849 AC_SUBST(THREADLDFLAGS)
 850 AC_SUBST(THREADCXXFLAGS)
 851 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 852 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 853 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 854
 855 if test -d sysdep; then true; else mkdir sysdep; fi
 856 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 857 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 858 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 859
 860 HASH_SYNC_SPEC=
 861 # Hash synchronization is only useful with posix threads right now.
 862 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 863    HASH_SYNC_SPEC=-fhash-synchronization
 864    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 865 fi
 866 AC_SUBST(HASH_SYNC_SPEC)
 867
 868 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 869
 870 # We're in the tree with gcc, and need to include some of its headers.
 871 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 872
 873 if test "x${with_newlib}" = "xyes"; then
 874    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 875    # may not work correctly, because the compiler may not be able to
 876    # link executables.
 877
 878    # We assume newlib.  This lets us hard-code the functions we know
 879    # we'll have.
 880    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 881    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 882    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 883    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 884    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 885    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 886    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 887    # This is only for POSIX threads.
 888    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 889    # We also assume we are using gcc, which provides alloca.
 890    AC_DEFINE(HAVE_ALLOCA)
 891
 892    # Assume we do not have getuid and friends.
 893    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 894    PLATFORMNET=NoNet
 895 else
 896    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 897                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 898                    access stat mkdir rename rmdir unlink realpath utime chmod \
 899                    nl_langinfo setlocale \
 900                    inet_pton uname inet_ntoa \
 901                    fork execvp pipe sigaction ftruncate])
 902    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 903    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 904    AC_CHECK_LIB(dl, dladdr, [
 905        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])
 906
 907    if test x"$build" = x"$host"; then
 908      AC_CHECK_FILES(/proc/self/exe, [
 909        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 910    else
 911      case $host in
 912      *-linux*)
 913        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 914        ;;
 915      esac
 916    fi
 917
 918    AM_ICONV
 919    AM_LC_MESSAGES
 920    AC_STRUCT_TIMEZONE
 921
 922    AC_CHECK_FUNCS(gethostbyname_r, [
 923      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 924        [Define if you have the 'gethostbyname_r' function.])
 925      # There are two different kinds of gethostbyname_r.
 926      # We look for the one that returns `int'.
 927      # Hopefully this check is robust enough.
 928      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 929        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 930
 931      case " $GCINCS " in
 932      *" -D_REENTRANT "*) ;;
 933      *)
 934         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 935         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 936         [libjava_cv_gethostbyname_r_needs_reentrant],
 937         [ AC_LANG_PUSH(C++)
 938           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 939             [[gethostbyname_r("", 0, 0);]])],
 940             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 941                 CPPFLAGS_SAVE="$CPPFLAGS"
 942                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 943                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 944                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 945                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 946                 CPPFLAGS="$CPPFLAGS_SAVE"
 947           ])
 948           AC_LANG_POP(C++)
 949         ])
 950         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 951           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 952         fi
 953      ;;
 954      esac
 955
 956      AC_CACHE_CHECK([for struct hostent_data],
 957         [libjava_cv_struct_hostent_data], [dnl
 958         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 959 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 960 # define _REENTRANT 1
 961 #endif
 962 #include <netdb.h>]], [[struct hostent_data data;]])],
 963           [libjava_cv_struct_hostent_data=yes],
 964           [libjava_cv_struct_hostent_data=no])])
 965      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 966        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 967          [Define if struct hostent_data is defined in netdb.h])
 968      fi
 969    ])
 970
 971    # FIXME: libjava source code expects to find a prototype for
 972    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 973    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 974    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 975    # linkage check is enough, yet C++ code requires proper prototypes.)
 976    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 977    AC_CHECK_FUNCS(gethostbyaddr_r, [
 978      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 979        [Define if you have the 'gethostbyaddr_r' function.])
 980      # There are two different kinds of gethostbyaddr_r.
 981      # We look for the one that returns `int'.
 982      # Hopefully this check is robust enough.
 983      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 984        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 985          [Define if gethostbyaddr_r returns 'int'.])])])])
 986
 987    AC_CHECK_FUNCS(gethostname, [
 988      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 989        [Define if you have the 'gethostname' function.])
 990      AC_EGREP_HEADER(gethostname, unistd.h, [
 991        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 992          [Define if gethostname is declared in <unistd.h>.])])])
 993
 994    AC_CHECK_FUNCS(usleep, [
 995      AC_EGREP_HEADER(usleep, unistd.h, [
 996        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 997           [Define if usleep is declared in <unistd.h>.])])])
 998
 999    # Look for these functions in the thread library, but only bother
1000    # if using POSIX threads.
1001    if test "$THREADS" = posix; then
1002       save_LIBS="$LIBS"
1003       LIBS="$LIBS $THREADLIBS"
1004       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1005       # E.g., Solaris.
1006       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1007
1008       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1009       # Solaris 7 the name librt is preferred.
1010       AC_CHECK_FUNCS(sched_yield, , [
1011         AC_CHECK_LIB(rt, sched_yield, [
1012           AC_DEFINE(HAVE_SCHED_YIELD)
1013           THREADLIBS="$THREADLIBS -lrt"
1014           THREADSPEC="$THREADSPEC -lrt"], [
1015           AC_CHECK_LIB(posix4, sched_yield, [
1016             AC_DEFINE(HAVE_SCHED_YIELD)
1017             THREADLIBS="$THREADLIBS -lposix4"
1018             THREADSPEC="$THREADSPEC -lposix4"])])])
1019
1020       AC_CHECK_LIB(rt, clock_gettime, [
1021          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1022          case "$THREADSPEC" in
1023            *-lrt*) ;;
1024            *)
1025              THREADSPEC="$THREADSPEC -lrt"
1026              THREADLIBS="$THREADLIBS -lrt"
1027              ;;
1028          esac])
1029
1030       LIBS="$save_LIBS"
1031
1032       # We can save a little space at runtime if the mutex has m_count
1033       # or __m_count.  This is a nice hack for Linux.
1034       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1035           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1036         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1037              [Define if pthread_mutex_t has m_count member.]), [
1038         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1039             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1040           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1041             [Define if pthread_mutex_t has __m_count member.]))])
1042    fi
1043
1044    # We require a way to get the time.
1045    time_found=no
1046    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1047    if test "$time_found" = no; then
1048       AC_MSG_ERROR([no function found to get the time])
1049    fi
1050
1051    AC_CHECK_FUNCS(memmove)
1052
1053    # We require memcpy.
1054    memcpy_found=no
1055    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1056    if test "$memcpy_found" = no; then
1057       AC_MSG_ERROR([memcpy is required])
1058    fi
1059
1060    AC_CHECK_LIB(dl, dlopen, [
1061        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1062
1063    # Some library-finding code we stole from Tcl.
1064    #--------------------------------------------------------------------
1065    #    Check for the existence of the -lsocket and -lnsl libraries.
1066    #    The order here is important, so that they end up in the right
1067    #    order in the command line generated by make.  Here are some
1068    #    special considerations:
1069    #    1. Use "connect" and "accept" to check for -lsocket, and
1070    #       "gethostbyname" to check for -lnsl.
1071    #    2. Use each function name only once:  can't redo a check because
1072    #       autoconf caches the results of the last check and won't redo it.
1073    #    3. Use -lnsl and -lsocket only if they supply procedures that
1074    #       aren't already present in the normal libraries.  This is because
1075    #       IRIX 5.2 has libraries, but they aren't needed and they're
1076    #       bogus:  they goof up name resolution if used.
1077    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1078    #       To get around this problem, check for both libraries together
1079    #       if -lsocket doesn't work by itself.
1080    #--------------------------------------------------------------------
1081
1082    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1083     [gcj_cv_lib_sockets=
1084      gcj_checkBoth=0
1085      unset ac_cv_func_connect
1086      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1087      if test "$gcj_checkSocket" = 1; then
1088          unset ac_cv_func_connect
1089          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1090                       gcj_checkBoth=1)
1091      fi
1092      if test "$gcj_checkBoth" = 1; then
1093          gcj_oldLibs=$LIBS
1094          LIBS="$LIBS -lsocket -lnsl"
1095          unset ac_cv_func_accept
1096          AC_CHECK_FUNC(accept,
1097                        [gcj_checkNsl=0
1098                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1099          unset ac_cv_func_accept
1100          LIBS=$gcj_oldLibs
1101      fi
1102      unset ac_cv_func_gethostbyname
1103      gcj_oldLibs=$LIBS
1104      LIBS="$LIBS $gcj_cv_lib_sockets"
1105      AC_CHECK_FUNC(gethostbyname, ,
1106                    [AC_CHECK_LIB(nsl, main,
1107                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1108      unset ac_cv_func_gethostbyname
1109      LIBS=$gcj_oldLIBS
1110    ])
1111    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1112
1113    if test "$with_system_zlib" = yes; then
1114       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1115    fi
1116
1117    # Test for Gtk stuff, if asked for.
1118    if test "$use_gtk_awt" = yes; then
1119       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1120       AC_SUBST(GTK_CFLAGS)
1121       AC_SUBST(GTK_LIBS)
1122
1123       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1124       AC_SUBST(GLIB_CFLAGS)
1125       AC_SUBST(GLIB_LIBS)
1126
1127       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1128       AC_SUBST(LIBART_CFLAGS)
1129       AC_SUBST(LIBART_LIBS)
1130
1131       # We require the XTest Extension to support java.awt.Robot.
1132       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1133                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1134                    [${X_LIBS}])
1135    fi
1136
1137    # On Solaris, and maybe other architectures, the Boehm collector
1138    # requires -ldl.
1139    if test "$GC" = boehm; then
1140       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1141    fi
1142 fi
1143
1144 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1145 case $build in
1146     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1147     *)         CLASSPATH_SEPARATOR=':' ;;
1148 esac
1149 AC_SUBST(CLASSPATH_SEPARATOR)
1150
1151 # We must search the source tree for java.lang, since we still don't
1152 # have libgcj.jar nor java/lang/*.class
1153 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1154 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1155
1156 # Since some classes depend on this one, we need its source available
1157 # before we can do any GCJ compilation test :-(
1158 if test ! -f gnu/classpath/Configuration.java; then
1159   test -d gnu || mkdir gnu
1160   test -d gnu/classpath || mkdir gnu/classpath
1161   # Note that it is not crucial that all the values here be correct.
1162   sed -e "s,@prefix@,$prefix," \
1163       -e "s,@VERSION@,$VERSION," \
1164       -e "s,@LIBDEBUG@,false," \
1165       -e "s,@INIT_LOAD_LIBRARY@,false," \
1166       -e "s,@@,$LIBGCJDEBUG," \
1167       -e "s,@default_toolkit@,$TOOLKIT," \
1168       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1169       -e "s,@GTK_CAIRO_ENABLED@,false," \
1170         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1171         > gnu/classpath/Configuration.java
1172   # We do not want to redirect the output of the grep below to /dev/null,
1173   # but we add /dev/null to the input list so that grep will print the
1174   # filename of Configuration.java in case it finds any matches.
1175   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1176     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1177   fi
1178 fi
1179
1180 LT_AC_PROG_GCJ
1181
1182 # Now remove it.
1183 rm -f gnu/classpath/Configuration.java
1184
1185 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1186
1187 AC_CHECK_SIZEOF(void *)
1188
1189 AC_C_BIGENDIAN
1190
1191 ZLIBS=
1192 SYS_ZLIBS=
1193 ZINCS=
1194
1195 if test -z "$ZLIBSPEC"; then
1196    # Use zlib from the GCC tree.
1197    ZINCS='-I$(top_srcdir)/../zlib'
1198    ZLIBS=../zlib/libzgcj_convenience.la
1199 else
1200    # System's zlib.
1201    SYS_ZLIBS="$ZLIBSPEC"
1202 fi
1203 AC_SUBST(ZLIBS)
1204 AC_SUBST(SYS_ZLIBS)
1205 AC_SUBST(ZINCS)
1206 AC_SUBST(DIVIDESPEC)
1207 AC_SUBST(CHECKREFSPEC)
1208 AC_SUBST(EXCEPTIONSPEC)
1209 AC_SUBST(BACKTRACESPEC)
1210 AC_SUBST(IEEESPEC)
1211
1212 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1213 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1214 AC_SUBST(GCC_UNWIND_INCLUDE)
1215
1216 # Process the option "--enable-version-specific-runtime-libs"
1217 # Calculate toolexeclibdir
1218 case ${version_specific_libs} in
1219   yes)
1220     # Need the gcc compiler version to know where to install libraries
1221     # and header files if --enable-version-specific-runtime-libs option
1222     # is selected.
1223     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1224     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1225     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1226     toolexeclibdir=$toolexecmainlibdir
1227     ;;
1228   no)
1229     if test -n "$with_cross_host" &&
1230        test x"$with_cross_host" != x"no"; then
1231       # Install a library built with a cross compiler in tooldir, not libdir.
1232       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1233       toolexecmainlibdir='$(toolexecdir)/lib'
1234     else
1235       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1236       toolexecmainlibdir='$(libdir)'
1237     fi
1238     multi_os_directory=`$CC -print-multi-os-directory`
1239     case $multi_os_directory in
1240       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1241       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1242     esac
1243     ;;
1244 esac
1245 AC_SUBST(toolexecdir)
1246 AC_SUBST(toolexecmainlibdir)
1247 AC_SUBST(toolexeclibdir)
1248
1249 # Determine where the standard .db file is found.
1250 multi_os_directory=`$CC -print-multi-os-directory`
1251 case $multi_os_directory in
1252   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1253   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1254 esac
1255 AC_SUBST(dbexecdir)
1256
1257 # Determine gcj version number.
1258 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1259 GCJVERSION=$gcjversion
1260 AC_SUBST(GCJVERSION)
1261 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1262
1263 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1264 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1265
1266 TL_AC_GXX_INCLUDE_DIR
1267
1268 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1269 # On that system, sys/ioctl.h will not include sys/filio.h unless
1270 # BSD_COMP is defined; just including sys/filio.h is simpler.
1271 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1272 # for now.  If you change this, you also must update natFile.cc.
1273 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1274                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1275                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1276                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1277                   dirent.h])
1278 AC_CHECK_HEADERS(inttypes.h, [
1279     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1280     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1281 ])
1282 AC_HEADER_SYS_WAIT
1283
1284 AC_CHECK_TYPE([ssize_t], [int])
1285
1286 AC_MSG_CHECKING([for in_addr_t])
1287 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1288 #if STDC_HEADERS
1289 #include <stdlib.h>
1290 #include <stddef.h>
1291 #endif
1292 #if HAVE_NETINET_IN_H
1293 #include <netinet/in.h>
1294 #endif]], [[in_addr_t foo;]])],
1295   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1296      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1297    AC_MSG_RESULT(yes)],
1298   [AC_MSG_RESULT(no)])
1299
1300 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1301 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1302   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1303      [Define if struct ip_mreq is defined in netinet/in.h.])
1304    AC_MSG_RESULT(yes)],
1305   [AC_MSG_RESULT(no)])
1306
1307 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1308 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1309   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1310      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1311    AC_MSG_RESULT(yes)],
1312   [AC_MSG_RESULT(no)])
1313
1314 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1315 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1316   [AC_DEFINE(HAVE_INET6, 1,
1317      [Define if inet6 structures are defined in netinet/in.h.])
1318    AC_MSG_RESULT(yes)],
1319   [AC_MSG_RESULT(no)])
1320
1321 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1322 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1323 #include <sys/types.h>
1324 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1325   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1326    AC_MSG_RESULT(yes)],
1327   [AC_MSG_RESULT(no)])
1328
1329 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1330 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1331   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1332    AC_MSG_RESULT(yes)],
1333   [AC_MSG_RESULT(no)
1334    AC_MSG_CHECKING([for global timezone variable])
1335    dnl FIXME: we don't want a link check here because that won't work
1336    dnl when cross-compiling.  So instead we make an assumption that
1337    dnl the header file will mention timezone if it exists.
1338    dnl Don't find the win32 function timezone
1339    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1340      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1341       AC_MSG_RESULT(yes)],
1342      [AC_MSG_RESULT(no)
1343        AC_MSG_CHECKING([for global _timezone variable])
1344        dnl FIXME: As above, don't want link check
1345        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1346          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1347             [Define if your platform has the global _timezone variable.])
1348           AC_MSG_RESULT(yes)],
1349           [AC_MSG_RESULT(no)])])])
1350
1351 AC_FUNC_ALLOCA
1352 AC_FUNC_MMAP
1353
1354 AC_CHECK_PROGS(PERL, perl, false)
1355
1356 SYSDEP_SOURCES=
1357 SIGNAL_HANDLER_AUX=
1358
1359 case "${host}" in
1360  i?86-*-linux*)
1361     SIGNAL_HANDLER=include/i386-signal.h
1362     ;;
1363  sparc*-sun-solaris*)
1364     SIGNAL_HANDLER=include/sparc-signal.h
1365     ;;
1366 # ia64-*)
1367 #    SYSDEP_SOURCES=sysdep/ia64.c
1368 #    test -d sysdep || mkdir sysdep
1369 #    ;;
1370  hppa*-*-linux*)
1371     SIGNAL_HANDLER=include/pa-signal.h
1372     ;;
1373  ia64-*-linux*)
1374     SIGNAL_HANDLER=include/dwarf2-signal.h
1375     ;;
1376  powerpc*-*-linux*)
1377     SIGNAL_HANDLER=include/powerpc-signal.h
1378     ;;
1379  alpha*-*-linux*)
1380     SIGNAL_HANDLER=include/dwarf2-signal.h
1381     ;;
1382  s390*-*-linux*)
1383     SIGNAL_HANDLER=include/s390-signal.h
1384     ;;
1385  x86_64*-*-linux*)
1386     SIGNAL_HANDLER=include/x86_64-signal.h
1387     SIGNAL_HANDLER_AUX=include/i386-signal.h
1388     ;;
1389  sparc*-*-linux*)
1390     SIGNAL_HANDLER=include/dwarf2-signal.h
1391     ;;
1392  sh*-*-linux*)
1393     SIGNAL_HANDLER=include/sh-signal.h
1394     ;;
1395  *mingw*)
1396     SIGNAL_HANDLER=include/win32-signal.h
1397     ;;
1398  mips*-*-linux*)
1399     SIGNAL_HANDLER=include/mips-signal.h
1400     ;;
1401  *-*-darwin*)
1402     SIGNAL_HANDLER=include/darwin-signal.h
1403     ;;
1404  *)
1405     SIGNAL_HANDLER=include/default-signal.h
1406     ;;
1407 esac
1408
1409 # If we're using sjlj exceptions, forget what we just learned.
1410 if test "$enable_sjlj_exceptions" = yes; then
1411    SIGNAL_HANDLER=include/default-signal.h
1412    SIGNAL_HANDLER_AUX=
1413 fi
1414
1415 AC_SUBST(SYSDEP_SOURCES)
1416
1417 if test -z "$SIGNAL_HANDLER_AUX"; then
1418   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1419 fi
1420
1421 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1422                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1423
1424 if test "${multilib}" = "yes"; then
1425   multilib_arg="--enable-multilib"
1426 else
1427   multilib_arg=
1428 fi
1429
1430 # See if we support thread-local storage.
1431 GCC_CHECK_TLS
1432
1433 # Check if linker supports static linking on a per library basis
1434 LD_START_STATIC_SPEC=
1435 LD_FINISH_STATIC_SPEC=
1436 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1437   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1438     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1439     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1440   fi
1441 fi
1442 AC_SUBST(LD_START_STATIC_SPEC)
1443 AC_SUBST(LD_FINISH_STATIC_SPEC)
1444
1445 here=`${PWDCMD-pwd}`
1446 AC_SUBST(here)
1447
1448 # We get this from the environment.
1449 AC_SUBST(GCJFLAGS)
1450
1451 AC_CONFIG_FILES([
1452 Makefile
1453 libgcj.pc
1454 libgcj.spec
1455 libgcj-test.spec
1456 gcj/Makefile
1457 include/Makefile
1458 testsuite/Makefile
1459 ])
1460
1461 AC_CONFIG_COMMANDS([default],
1462 [# Only add multilib support code if we just rebuilt top-level Makefile.
1463 case " $CONFIG_FILES " in
1464  *" Makefile "*)
1465    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1466    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1467    ;;
1468 esac
1469 for ac_multi_file in $CONFIG_FILES; do
1470   case $ac_multi_file in
1471   */Makefile)
1472     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1473   esac
1474 done
1475 ],
1476 srcdir=${srcdir}
1477 host=${host}
1478 target=${target}
1479 with_multisubdir=${with_multisubdir}
1480 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1481 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1482 libgcj_basedir=${libgcj_basedir}
1483 CC="${CC}"
1484 CXX="${CXX}"
1485 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1486 )
1487
1488 AC_OUTPUT