libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.5)
   4 AC_INIT(pexecute.c)
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory])
   9 AC_ARG_WITH(cross-host,
  10 [  --with-cross-host=HOST           Configuring with a cross compiler])
  11 AC_ARG_WITH(newlib,
  12 [  --with-newlib                    Configuring with newlib])
  13
  14 if test "${srcdir}" = "."; then
  15   if test -z "${with_target_subdir}"; then
  16     libiberty_topdir="${srcdir}/.."
  17   else
  18     if test "${with_target_subdir}" != "."; then
  19       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  20     else
  21       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  22     fi
  23   fi
  24 else
  25   libiberty_topdir="${srcdir}/.."
  26 fi
  27 AC_CONFIG_AUX_DIR($libiberty_topdir)
  28
  29 AC_CANONICAL_HOST
  30
  31 dnl When we start using automake:
  32 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  40 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  41 # are probably using a cross compiler, which will not be able to fully
  42 # link an executable.  This should really be fixed in autoconf
  43 # itself.
  44
  45 AC_DEFUN(LIB_AC_PROG_CC,
  46 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  47 AC_PROVIDE([AC_PROG_CC])
  48 AC_CHECK_PROG(CC, gcc, gcc)
  49 if test -z "$CC"; then
  50   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  51   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  52 fi
  53
  54 AC_PROG_CC_GNU
  55
  56 if test $ac_cv_prog_gcc = yes; then
  57   GCC=yes
  58 dnl Check whether -g works, even if CFLAGS is set, in case the package
  59 dnl plays around with CFLAGS (such as to build both debugging and
  60 dnl normal versions of a library), tasteless as that idea is.
  61   ac_test_CFLAGS="${CFLAGS+set}"
  62   ac_save_CFLAGS="$CFLAGS"
  63   CFLAGS=
  64   AC_PROG_CC_G
  65   if test "$ac_test_CFLAGS" = set; then
  66     CFLAGS="$ac_save_CFLAGS"
  67   elif test $ac_cv_prog_cc_g = yes; then
  68     CFLAGS="-g -O2"
  69   else
  70     CFLAGS="-O2"
  71   fi
  72 else
  73   GCC=
  74   test "${CFLAGS+set}" = set || CFLAGS="-g"
  75 fi
  76 ])
  77
  78 LIB_AC_PROG_CC
  79
  80 AC_ISC_POSIX
  81
  82 dnl When we start using libtool:
  83 dnl Default to a non shared library.  This may be overridden by the
  84 dnl configure option --enable-shared.
  85 dnl AM_DISABLE_SHARED
  86
  87 dnl When we start using libtool:
  88 dnl AM_PROG_LIBTOOL
  89
  90 dnl When we start using automake:
  91 dnl AM_CONFIG_HEADER(config.h:config.in)
  92 AC_CONFIG_HEADER(config.h:config.in)
  93
  94 dnl When we start using automake:
  95 dnl AM_MAINTAINER_MODE
  96 dnl AM_EXEEXT
  97
  98 dnl When we start using automake:
  99 dnl AM_PROG_INSTALL
 100 AC_PROG_INSTALL
 101
 102 . ${srcdir}/config.table
 103 host_makefile_frag=${frag}
 104 AC_SUBST_FILE(host_makefile_frag)
 105
 106 # It's OK to check for header files.  Although the compiler may not be
 107 # able to link anything, it had better be able to at least compile
 108 # something.
 109 AC_CHECK_HEADERS(sys/file.h sys/param.h stdlib.h string.h unistd.h)
 110
 111 # This is the list of functions which libiberty will provide if they
 112 # are not available on the host.
 113
 114 funcs="asprintf"
 115 funcs="$funcs atexit"
 116 funcs="$funcs basename"
 117 funcs="$funcs bcmp"
 118 funcs="$funcs bcopy"
 119 funcs="$funcs bzero"
 120 funcs="$funcs clock"
 121 funcs="$funcs getcwd"
 122 funcs="$funcs getpagesize"
 123 funcs="$funcs index"
 124 funcs="$funcs insque"
 125 funcs="$funcs memchr"
 126 funcs="$funcs memcmp"
 127 funcs="$funcs memcpy"
 128 funcs="$funcs memmove"
 129 funcs="$funcs memset"
 130 funcs="$funcs random"
 131 funcs="$funcs rename"
 132 funcs="$funcs rindex"
 133 funcs="$funcs sigsetmask"
 134 funcs="$funcs strcasecmp"
 135 funcs="$funcs strchr"
 136 funcs="$funcs strdup"
 137 funcs="$funcs strncasecmp"
 138 funcs="$funcs strrchr"
 139 funcs="$funcs strstr"
 140 funcs="$funcs strtod"
 141 funcs="$funcs strtol"
 142 funcs="$funcs strtoul"
 143 funcs="$funcs tmpnam"
 144 funcs="$funcs vasprintf"
 145 funcs="$funcs vfprintf"
 146 funcs="$funcs vprintf"
 147 funcs="$funcs vsprintf"
 148 funcs="$funcs waitpid"
 149
 150 # Also in the old function.def file: alloca, vfork, getopt.
 151
 152 vars="sys_errlist sys_nerr sys_siglist"
 153
 154 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times"
 155
 156 # These are neither executed nor required, but they help keep
 157 # autoheader happy without adding a bunch of text to acconfig.h.
 158 if test "x" = "y"; then
 159   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bzero clock getcwd)
 160   AC_CHECK_FUNCS(getpagesize index insque memchr memcmp memcpy memmove)
 161   AC_CHECK_FUNCS(memset random rename rindex sigsetmask strcasecmp)
 162   AC_CHECK_FUNCS(strchr strdup strncasecmp strrchr strstr strtod strtol)
 163   AC_CHECK_FUNCS(strtoul tmpnam vasprintf vfprintf vprintf vsprintf waitpid)
 164   AC_DEFINE(HAVE_SYS_ERRLIST)
 165   AC_DEFINE(HAVE_SYS_NERR)
 166   AC_DEFINE(HAVE_SYS_SIGLIST)
 167   AC_CHECK_FUNCS(getrusage on_exit psignal strerror strsignal sysconf times)
 168 fi
 169
 170 # For each of these functions, if the host does not provide the
 171 # function we want to put FN.o in LIBOBJS, and if the host does
 172 # provide the function, we want to define HAVE_FN in config.h.  Also,
 173 # if the host does not provide alloca, we set ALLOCA to alloca.o
 174
 175 setobjs=
 176 if test -n "${with_target_subdir}"; then
 177
 178   # We are being configured as a target library.  AC_REPLACE_FUNCS
 179   # may not work correctly, because the compiler may not be able to
 180   # link executables.  Note that we may still be being configured
 181   # native.
 182
 183   # If we are being configured for newlib, we know which functions
 184   # newlib provide and which ones we will be expected to provide.
 185
 186   if test "x${with_newlib}" = "xyes"; then
 187     ALLOCA="alloca.o"
 188     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 189
 190     for f in $funcs; do
 191       case "$f" in
 192         asprintf | basename | insque | random | strdup | vasprintf)
 193           ;;
 194         *)
 195           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 196           AC_DEFINE_UNQUOTED($n)
 197           ;;
 198       esac
 199     done
 200
 201     # newlib doesnt provide any of the variables in $vars, so we
 202     # dont have to check them here.
 203
 204     # Of the functions in $checkfuncs, newlib only has strerror.
 205     AC_DEFINE(HAVE_STRERROR)
 206
 207     setobjs=yes
 208
 209   fi
 210 fi
 211
 212 if test -z "${setobjs}"; then
 213   case "${host}" in
 214
 215   *-*-vxworks*)
 216     # Handle VxWorks configuration specially, since on VxWorks the
 217     # libraries are actually on the target board, not in the file
 218     # system.
 219     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 220     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 221     for f in $funcs; do
 222       case "$f" in
 223         basename | getpagesize | insque | random | strcasecmp)
 224           ;;
 225         strncasecmp | strdup | vfork | waitpid | vasprintf)
 226           ;;
 227         *)
 228           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 229           AC_DEFINE_UNQUOTED($n)
 230           ;;
 231       esac
 232     done
 233
 234     # VxWorks doesn't provide any of the variables in $vars, so we
 235     # don't have to check them here.
 236
 237     # Of the functions in $checkfuncs, VxWorks only has strerror.
 238     AC_DEFINE(HAVE_STRERROR)
 239
 240     setobjs=yes
 241     ;;
 242
 243   esac
 244 fi
 245
 246 if test -z "${setobjs}"; then
 247
 248   case "${host}" in
 249
 250   *-*-cygwin32*)
 251     # The cygwin32 library actually uses a couple of files from
 252     # libiberty when it is built.  If we are building a native
 253     # cygwin32, and we run the tests, we will appear to have these
 254     # files.  However, when we go on to build winsup, we will wind up
 255     # with a library which does not have the files, since they should
 256     # have come from libiberty.
 257
 258     # We handle this by removing the functions the winsup library
 259     # provides from our shell variables, so that they appear to be
 260     # missing.
 261
 262     funcs="`echo $funcs | sed -e 's/random//'`"
 263     LIBOBJS="$LIBOBJS random.o"
 264     vars="`echo $vars | sed -e 's/sys_siglist//'`"
 265     checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 266     ;;
 267
 268   *-*-mingw32*)
 269     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 270     # macros, so the test below won't find them.
 271     vars="`echo $vars | sed -e 's/sys_nerr//' -e 's/sys_errlist//'`"
 272     AC_DEFINE(HAVE_SYS_NERR)
 273     AC_DEFINE(HAVE_SYS_ERRLIST)
 274     ;;
 275
 276   esac
 277
 278   # We haven't set the list of objects yet.  Use the standard autoconf
 279   # tests.  This will only work if the compiler works.
 280   AC_PROG_CC_WORKS
 281   AC_REPLACE_FUNCS($funcs)
 282   AC_FUNC_ALLOCA
 283   AC_FUNC_VFORK
 284   if test $ac_cv_func_vfork_works = no; then
 285     LIBOBJS="$LIBOBJS vfork.o"
 286   fi
 287   for v in $vars; do
 288     AC_MSG_CHECKING([for $v])
 289     AC_CACHE_VAL(libiberty_cv_var_$v,
 290       [AC_TRY_LINK([int *p;], [extern int $v; p = &$v;],
 291                    [eval "libiberty_cv_var_$v=yes"],
 292                    [eval "libiberty_cv_var_$v=no"])])
 293     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 294       AC_MSG_RESULT(yes)
 295       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 296       AC_DEFINE_UNQUOTED($n)
 297     else
 298       AC_MSG_RESULT(no)
 299     fi
 300   done
 301   AC_CHECK_FUNCS($checkfuncs)
 302 fi
 303
 304 # Install a library built with a cross compiler in $(tooldir) rather
 305 # than $(libdir).
 306 if test -z "${with_cross_host}"; then
 307   INSTALL_DEST=libdir
 308 else
 309   INSTALL_DEST=tooldir
 310 fi
 311 AC_SUBST(INSTALL_DEST)
 312
 313 # We need multilib support, but only if configuring for the target.
 314 AC_OUTPUT(Makefile,
 315 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 316 if test -n "$CONFIG_FILES"; then
 317   if test -n "${with_target_subdir}"; then
 318     # FIXME: We shouldn't need to set ac_file
 319     ac_file=Makefile
 320     . ${libiberty_topdir}/config-ml.in
 321   fi
 322 fi],
 323 srcdir=${srcdir}
 324 host=${host}
 325 target=${target}
 326 with_target_subdir=${with_target_subdir}
 327 with_multisubdir=${with_multisubdir}
 328 ac_configure_args="--enable-multilib ${ac_configure_args}"
 329 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 330 libiberty_topdir=${libiberty_topdir}
 331 )