libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 GCC_NO_EXECUTABLES
 113 AC_PROG_CC
 114 AC_PROG_CPP_WERROR
 115
 116 if test x$GCC = xyes; then
 117   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
 118 fi
 119 AC_SUBST(ac_libiberty_warn_cflags)
 120
 121 AC_PROG_CC_C_O
 122 # autoconf is lame and doesn't give us any substitution variable for this.
 123 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 124   NO_MINUS_C_MINUS_O=yes
 125 else
 126   OUTPUT_OPTION='-o $@'
 127 fi
 128 AC_SUBST(NO_MINUS_C_MINUS_O)
 129 AC_SUBST(OUTPUT_OPTION)
 130
 131 AC_C_CONST
 132 AC_C_INLINE
 133 AC_C_BIGENDIAN_CROSS
 134
 135 dnl When we start using libtool:
 136 dnl Default to a non shared library.  This may be overridden by the
 137 dnl configure option --enable-shared.
 138 dnl AM_DISABLE_SHARED
 139
 140 dnl When we start using libtool:
 141 dnl AM_PROG_LIBTOOL
 142
 143 dnl When we start using automake:
 144 dnl AM_CONFIG_HEADER(config.h:config.in)
 145 AC_CONFIG_HEADER(config.h:config.in)
 146
 147 dnl When we start using automake:
 148 dnl AM_MAINTAINER_MODE
 149 dnl AC_EXEEXT
 150
 151 dnl When we start using automake:
 152 dnl AM_PROG_INSTALL
 153 AC_PROG_INSTALL
 154
 155 . ${srcdir}/config.table
 156 host_makefile_frag=${frag}
 157 AC_SUBST_FILE(host_makefile_frag)
 158
 159 # It's OK to check for header files.  Although the compiler may not be
 160 # able to link anything, it had better be able to at least compile
 161 # something.
 162 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h)
 163 AC_HEADER_SYS_WAIT
 164 AC_HEADER_TIME
 165
 166 libiberty_AC_DECLARE_ERRNO
 167
 168 AC_CHECK_TYPE(uintptr_t, unsigned long)
 169 # Given the above check, we always have uintptr_t or a fallback
 170 # definition.  So define HAVE_UINTPTR_T in case any imported code
 171 # relies on it.
 172 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 173
 174 AC_TYPE_PID_T
 175
 176 # This is the list of functions which libiberty will provide if they
 177 # are not available on the host.
 178
 179 funcs="asprintf"
 180 funcs="$funcs atexit"
 181 funcs="$funcs basename"
 182 funcs="$funcs bcmp"
 183 funcs="$funcs bcopy"
 184 funcs="$funcs bsearch"
 185 funcs="$funcs bzero"
 186 funcs="$funcs calloc"
 187 funcs="$funcs clock"
 188 funcs="$funcs ffs"
 189 funcs="$funcs getcwd"
 190 funcs="$funcs getpagesize"
 191 funcs="$funcs index"
 192 funcs="$funcs insque"
 193 funcs="$funcs memchr"
 194 funcs="$funcs memcmp"
 195 funcs="$funcs memcpy"
 196 funcs="$funcs memmove"
 197 funcs="$funcs mempcpy"
 198 funcs="$funcs memset"
 199 funcs="$funcs mkstemps"
 200 funcs="$funcs putenv"
 201 funcs="$funcs random"
 202 funcs="$funcs rename"
 203 funcs="$funcs rindex"
 204 funcs="$funcs setenv"
 205 funcs="$funcs snprintf"
 206 funcs="$funcs sigsetmask"
 207 funcs="$funcs stpcpy"
 208 funcs="$funcs stpncpy"
 209 funcs="$funcs strcasecmp"
 210 funcs="$funcs strchr"
 211 funcs="$funcs strdup"
 212 funcs="$funcs strncasecmp"
 213 funcs="$funcs strrchr"
 214 funcs="$funcs strstr"
 215 funcs="$funcs strtod"
 216 funcs="$funcs strtol"
 217 funcs="$funcs strtoul"
 218 funcs="$funcs tmpnam"
 219 funcs="$funcs vasprintf"
 220 funcs="$funcs vfprintf"
 221 funcs="$funcs vprintf"
 222 funcs="$funcs vsnprintf"
 223 funcs="$funcs vsprintf"
 224 funcs="$funcs waitpid"
 225
 226 # Also in the old function.def file: alloca, vfork, getopt.
 227
 228 vars="sys_errlist sys_nerr sys_siglist"
 229
 230 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 231 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 232 checkfuncs="$checkfuncs getsysinfo table sysctl"
 233
 234 # These are neither executed nor required, but they help keep
 235 # autoheader happy without adding a bunch of text to acconfig.h.
 236 if test "x" = "y"; then
 237   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 238   getcwd getpagesize index insque mkstemps memchr memcmp memcpy \
 239   memmove mempcpy memset putenv random rename rindex sigsetmask \
 240   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr \
 241   strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \
 242   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 243   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 244   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl \
 245   realpath canonicalize_file_name)
 246   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 247   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 248   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 249 fi
 250
 251 # For each of these functions, if the host does not provide the
 252 # function we want to put FN.o in LIBOBJS, and if the host does
 253 # provide the function, we want to define HAVE_FN in config.h.
 254
 255 setobjs=
 256 CHECK=
 257 target_header_dir=
 258 if test -n "${with_target_subdir}"; then
 259
 260   # We are being configured as a target library.  AC_REPLACE_FUNCS
 261   # may not work correctly, because the compiler may not be able to
 262   # link executables.  Note that we may still be being configured
 263   # native.
 264
 265   # If we are being configured for newlib, we know which functions
 266   # newlib provide and which ones we will be expected to provide.
 267
 268   if test "x${with_newlib}" = "xyes"; then
 269     AC_LIBOBJ([asprintf])
 270     AC_LIBOBJ([basename])
 271     AC_LIBOBJ([insque])
 272     AC_LIBOBJ([random])
 273     AC_LIBOBJ([strdup])
 274     AC_LIBOBJ([vasprintf])
 275
 276     for f in $funcs; do
 277       case "$f" in
 278         asprintf | basename | insque | random | strdup | vasprintf)
 279           ;;
 280         *)
 281           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 282           AC_DEFINE_UNQUOTED($n)
 283           ;;
 284       esac
 285     done
 286
 287     # newlib doesnt provide any of the variables in $vars, so we
 288     # dont have to check them here.
 289
 290     # Of the functions in $checkfuncs, newlib only has strerror.
 291     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 292
 293     setobjs=yes
 294
 295   fi
 296
 297   # We may wish to install the target headers somewhere.
 298   AC_ARG_ENABLE(install-libiberty,
 299   [  --enable-install-libiberty       Install headers for end users],
 300   enable_install_libiberty=$enableval,
 301   enable_install_libiberty=no)dnl
 302
 303   # Option parsed, now set things appropriately.
 304   case x"$enable_install_libiberty" in
 305     xyes|x)
 306       target_header_dir=libiberty
 307       ;;
 308     xno)
 309       target_header_dir=
 310       ;;
 311     *)
 312       # This could be sanity-checked in various ways...
 313       target_header_dir="${enable_install_libiberty}"
 314       ;;
 315   esac
 316
 317
 318 else
 319
 320    # Not a target library, so we set things up to run the test suite.
 321    CHECK=check-cplus-dem
 322
 323 fi
 324
 325 AC_SUBST(CHECK)
 326 AC_SUBST(target_header_dir)
 327
 328 case "${host}" in
 329   *-*-cygwin* | *-*-mingw*)
 330     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 331     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 332     ;;
 333 esac
 334
 335 if test -z "${setobjs}"; then
 336   case "${host}" in
 337
 338   *-*-vxworks*)
 339     # Handle VxWorks configuration specially, since on VxWorks the
 340     # libraries are actually on the target board, not in the file
 341     # system.
 342     AC_LIBOBJ([basename])
 343     AC_LIBOBJ([getpagesize])
 344     AC_LIBOBJ([insque])
 345     AC_LIBOBJ([random])
 346     AC_LIBOBJ([strcasecmp])
 347     AC_LIBOBJ([strncasecmp])
 348     AC_LIBOBJ([strdup])
 349     AC_LIBOBJ([vfork])
 350     AC_LIBOBJ([waitpid])
 351     AC_LIBOBJ([vasprintf])
 352     for f in $funcs; do
 353       case "$f" in
 354         basename | getpagesize | insque | random | strcasecmp)
 355           ;;
 356         strncasecmp | strdup | vfork | waitpid | vasprintf)
 357           ;;
 358         *)
 359           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 360           AC_DEFINE_UNQUOTED($n)
 361           ;;
 362       esac
 363     done
 364
 365     # VxWorks doesn't provide any of the variables in $vars, so we
 366     # don't have to check them here.
 367
 368     # Of the functions in $checkfuncs, VxWorks only has strerror.
 369     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 370
 371     setobjs=yes
 372     ;;
 373
 374   esac
 375 fi
 376
 377 if test -z "${setobjs}"; then
 378
 379   case "${host}" in
 380
 381   *-*-cygwin*)
 382     # The Cygwin library actually uses a couple of files from
 383     # libiberty when it is built.  If we are building a native
 384     # Cygwin, and we run the tests, we will appear to have these
 385     # files.  However, when we go on to build winsup, we will wind up
 386     # with a library which does not have the files, since they should
 387     # have come from libiberty.
 388
 389     # We handle this by removing the functions the winsup library
 390     # provides from our shell variables, so that they appear to be
 391     # missing.
 392
 393     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 394
 395     if test -n "${with_target_subdir}"
 396     then
 397       funcs="`echo $funcs | sed -e 's/random//'`"
 398       AC_LIBOBJ([random])
 399       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 400       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 401     fi
 402     ;;
 403
 404   *-*-mingw32*)
 405     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 406     # macros, so the test below won't find them.
 407     libiberty_cv_var_sys_nerr=yes
 408     libiberty_cv_var_sys_errlist=yes
 409     ;;
 410
 411   *-*-uwin*)
 412     # Under some versions of uwin, vfork is notoriously buggy and the test
 413     # can hang configure; on other versions, vfork exists just as a stub.
 414     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 415     ac_cv_func_vfork_works=no
 416     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 417     # macros (actually, these are imported from a DLL, but the end effect
 418     # is the same), so the test below won't find them.
 419     libiberty_cv_var_sys_nerr=yes
 420     libiberty_cv_var_sys_errlist=yes
 421     ;;
 422
 423   *-*-*vms*)
 424     # Under VMS, vfork works very different than on Unix. The standard test
 425     # won't work, and it isn't easily adaptable. It makes more sense to
 426     # just force it.
 427     ac_cv_func_vfork_works=yes
 428     ;;
 429
 430   esac
 431
 432   # We haven't set the list of objects yet.  Use the standard autoconf
 433   # tests.  This will only work if the compiler works.
 434   AC_ISC_POSIX
 435   AC_REPLACE_FUNCS($funcs)
 436   libiberty_AC_FUNC_C_ALLOCA
 437   AC_FUNC_FORK
 438   if test $ac_cv_func_vfork_works = no; then
 439     AC_LIBOBJ([vfork])
 440   fi
 441   # We only need _doprnt if we might use it to implement v*printf.
 442   if test $ac_cv_func_vprintf != yes \
 443      || test $ac_cv_func_vfprintf != yes \
 444      || test $ac_cv_func_vsprintf != yes; then
 445     AC_REPLACE_FUNCS(_doprnt)
 446   else
 447     AC_CHECK_FUNCS(_doprnt)
 448   fi
 449
 450   for v in $vars; do
 451     AC_MSG_CHECKING([for $v])
 452     AC_CACHE_VAL(libiberty_cv_var_$v,
 453       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 454                       [eval "libiberty_cv_var_$v=yes"],
 455                       [eval "libiberty_cv_var_$v=no"])])
 456     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 457       AC_MSG_RESULT(yes)
 458       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 459       AC_DEFINE_UNQUOTED($n)
 460     else
 461       AC_MSG_RESULT(no)
 462     fi
 463   done
 464
 465   # special check for _system_configuration because AIX <4.3.2 do not
 466   # contain the `physmem' member.
 467   AC_MSG_CHECKING([for external symbol _system_configuration])
 468   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 469                         [[double x = _system_configuration.physmem;]])],
 470     [AC_MSG_RESULT([yes])
 471     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 472               [Define if you have the _system_configuration variable.])],
 473     [AC_MSG_RESULT([no])])
 474
 475   AC_CHECK_FUNCS($checkfuncs)
 476   libiberty_NEED_DECLARATION(canonicalize_file_name)
 477 fi
 478
 479 # Figure out which version of pexecute to use.
 480 case "${host}" in
 481      *-*-mingw* | *-*-winnt*)   pexecute=./pex-win32.o  ;;
 482      *-*-msdosdjgpp*)           pexecute=./pex-djgpp.o  ;;
 483      *-*-msdos*)                pexecute=./pex-msdos.o  ;;
 484      *-*-os2-emx*)              pexecute=./pex-os2.o    ;;
 485      *)                         pexecute=./pex-unix.o   ;;
 486 esac
 487 AC_SUBST(pexecute)
 488
 489 libiberty_AC_FUNC_STRNCMP
 490
 491 # Install a library built with a cross compiler in $(tooldir) rather
 492 # than $(libdir).
 493 if test -z "${with_cross_host}"; then
 494   INSTALL_DEST=libdir
 495 else
 496   INSTALL_DEST=tooldir
 497 fi
 498 AC_SUBST(INSTALL_DEST)
 499
 500 m4_pattern_allow(LIBOBJS)
 501 L=""
 502 for l in x $LIBOBJS; do
 503   case $l in
 504     x) ;;
 505     *) L="$L ./$l" ;;
 506   esac
 507 done
 508 LIBOBJS="$L"
 509
 510 # We need multilib support, but only if configuring for the target.
 511 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 512 AC_CONFIG_COMMANDS([default],
 513   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 514 if test -n "$CONFIG_FILES"; then
 515   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 516     # FIXME: We shouldn't need to set ac_file
 517     ac_file=Makefile
 518     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 519     . ${libiberty_topdir}/config-ml.in
 520   fi
 521 fi]],
 522 [[srcdir=${srcdir}
 523 host=${host}
 524 target=${target}
 525 with_target_subdir=${with_target_subdir}
 526 with_build_subdir=${with_build_subdir}
 527 with_multisubdir=${with_multisubdir}
 528 ac_configure_args="--enable-multilib ${ac_configure_args}"
 529 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 530 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 531 libiberty_topdir=${libiberty_topdir}
 532 ]])
 533 AC_OUTPUT