libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  54 WERROR="-Werror"
  55 AC_SUBST(WERROR)
  56
  57 glibgo_toolexecdir=no
  58 glibgo_toolexeclibdir=no
  59 glibgo_prefixdir=$prefix
  60
  61 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  62 AC_ARG_ENABLE([version-specific-runtime-libs],
  63   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  64                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  65   [case "$enableval" in
  66     yes) version_specific_libs=yes ;;
  67     no)  version_specific_libs=no ;;
  68     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  69    esac],
  70   [version_specific_libs=no])
  71 AC_MSG_RESULT($version_specific_libs)
  72
  73 # Version-specific runtime libs processing.
  74 if test $version_specific_libs = yes; then
  75   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  76   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  77 fi
  78
  79 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  80 # Install a library built with a cross compiler in tooldir, not libdir.
  81 if test x"$glibgo_toolexecdir" = x"no"; then
  82   if test -n "$with_cross_host" &&
  83      test x"$with_cross_host" != x"no"; then
  84     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  85     glibgo_toolexeclibdir='${toolexecdir}/lib'
  86   else
  87     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  88     glibgo_toolexeclibdir='${libdir}'
  89   fi
  90   multi_os_directory=`$CC -print-multi-os-directory`
  91   case $multi_os_directory in
  92     .) ;; # Avoid trailing /.
  93     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  94   esac
  95 fi
  96
  97 AC_SUBST(glibgo_prefixdir)
  98 AC_SUBST(glibgo_toolexecdir)
  99 AC_SUBST(glibgo_toolexeclibdir)
 100
 101 # See if the user wants to configure without libffi.  Some
 102 # architectures don't support it.  FIXME: We should set a default
 103 # based on the host.
 104 AC_ARG_WITH(libffi,
 105   AS_HELP_STRING([--without-libffi],
 106                  [don't use libffi]),
 107   [:],
 108   [with_libffi=${with_libffi_default-yes}])
 109
 110 LIBFFI=
 111 LIBFFIINCS=
 112 if test "$with_libffi" != no; then
 113    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 114    LIBFFI=../libffi/libffi_convenience.la
 115    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 116 fi
 117 AC_SUBST(LIBFFI)
 118 AC_SUBST(LIBFFIINCS)
 119
 120 # Used to tell GNU make to include a file without telling automake to
 121 # include it.
 122 go_include="-include"
 123 AC_SUBST(go_include)
 124
 125 is_darwin=no
 126 is_freebsd=no
 127 is_irix=no
 128 is_linux=no
 129 is_netbsd=no
 130 is_rtems=no
 131 is_solaris=no
 132 GOOS=unknown
 133 case ${host} in
 134   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 135   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 136   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 137   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 138   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 139   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 140   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 141 esac
 142 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 143 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 144 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 145 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 146 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 147 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 148 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 149 AC_SUBST(GOOS)
 150
 151 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 152 is_386=no
 153 is_alpha=no
 154 is_arm=no
 155 is_m68k=no
 156 mips_abi=unknown
 157 is_ppc=no
 158 is_ppc64=no
 159 is_sparc=no
 160 is_sparc64=no
 161 is_x86_64=no
 162 GOARCH=unknown
 163 case ${host} in
 164   alpha*-*-*)
 165     is_alpha=yes
 166     GOARCH=alpha
 167     ;;
 168   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 169     is_arm=yes
 170     GOARCH=arm
 171     ;;
 172 changequote(,)dnl
 173   i[34567]86-*-* | x86_64-*-*)
 174 changequote([,])dnl
 175     AC_COMPILE_IFELSE([
 176 #ifdef __x86_64__
 177 #error 64-bit
 178 #endif],
 179 [is_386=yes], [is_x86_64=yes])
 180     if test "$is_386" = "yes"; then
 181       GOARCH=386
 182     else
 183       GOARCH=amd64
 184     fi
 185     ;;
 186   m68k*-*-*)
 187     is_m68k=yes
 188     GOARCH=m68k
 189     ;;
 190   mips*-*-*)
 191     AC_COMPILE_IFELSE([
 192 #if _MIPS_SIM != _ABIO32
 193 #error not o32
 194 #endif],
 195 [mips_abi="o32"],
 196         [AC_COMPILE_IFELSE([
 197 #if _MIPS_SIM != _ABIN32
 198 #error not n32
 199 #endif],
 200 [mips_abi="n32"],
 201         [AC_COMPILE_IFELSE([
 202 #if _MIPS_SIM != _ABI64
 203 #error not n64
 204 #endif],
 205 [mips_abi="n64"],
 206         [AC_COMPILE_IFELSE([
 207 #if _MIPS_SIM != _ABIO64
 208 #error not o64
 209 #endif],
 210 [mips_abi="o64"],
 211         [AC_MSG_ERROR([unknown MIPS ABI])
 212 [mips_abi="n32"]])])])])
 213     case "$mips_abi" in
 214     "o32") GOARCH=mipso32 ;;
 215     "n32") GOARCH=mipsn32 ;;
 216     "n64") GOARCH=mipsn64 ;;
 217     "o64") GOARCH=mipso64 ;;
 218     esac
 219     ;;
 220   rs6000*-*-* | powerpc*-*-*)
 221     AC_COMPILE_IFELSE([
 222 #ifdef _ARCH_PPC64
 223 #error 64-bit
 224 #endif],
 225 [is_ppc=yes], [is_ppc64=yes])
 226     if test "$is_ppc" = "yes"; then
 227       GOARCH=ppc
 228     else
 229       GOARCH=ppc64
 230     fi
 231     ;;
 232   sparc*-*-*)
 233     AC_COMPILE_IFELSE([
 234 #if defined(__sparcv9) || defined(__arch64__)
 235 #error 64-bit
 236 #endif],
 237 [is_sparc=yes], [is_sparc64=yes])
 238     if test "$is_sparc" = "yes"; then
 239       GOARCH=sparc
 240     else
 241       GOARCH=sparc64
 242     fi
 243     ;;
 244 esac
 245 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 246 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 247 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 248 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 249 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 250 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 251 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 252 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 253 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 254 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 255 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 256 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 257 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 258 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 259 AC_SUBST(GOARCH)
 260
 261 dnl Some files are only present when needed for specific architectures.
 262 GO_LIBCALL_OS_FILE=
 263 GO_LIBCALL_OS_ARCH_FILE=
 264 GO_SYSCALL_OS_FILE=
 265 GO_SYSCALL_OS_ARCH_FILE=
 266 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 267   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 268 fi
 269 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 270   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 271 fi
 272 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 273   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 274 fi
 275 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 276   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 277 fi
 278 AC_SUBST(GO_LIBCALL_OS_FILE)
 279 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 280 AC_SUBST(GO_SYSCALL_OS_FILE)
 281 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 282
 283 dnl Special flags used to generate sysinfo.go.
 284 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 285 case "$target" in
 286     mips-sgi-irix6.5*)
 287         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 288         # msghdr in <sys/socket.h>.
 289         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 290         ;;
 291     *-*-solaris2.[[89]])
 292         # Solaris 8/9 need this so struct msghdr gets the msg_control
 293         # etc. fields in <sys/socket.h> (_XPG4_2).
 294         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__"
 295         ;;
 296     *-*-solaris2.1[[01]])
 297         # Solaris 10+ needs this so struct msghdr gets the msg_control
 298         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 299         # above doesn't work with C99.
 300         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 301         ;;
 302 esac
 303 AC_SUBST(OSCFLAGS)
 304
 305 dnl Use -fsplit-stack when compiling C code if available.
 306 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 307 [libgo_cv_c_split_stack_supported],
 308 [CFLAGS_hold=$CFLAGS
 309 CFLAGS="$CFLAGS -fsplit-stack"
 310 AC_COMPILE_IFELSE([[int i;]],
 311 [libgo_cv_c_split_stack_supported=yes],
 312 [libgo_cv_c_split_stack_supported=no])
 313 CFLAGS=$CFLAGS_hold])
 314 if test "$libgo_cv_c_split_stack_supported" = yes; then
 315   SPLIT_STACK=-fsplit-stack
 316   AC_DEFINE(USING_SPLIT_STACK, 1,
 317                 [Define if the compiler supports -fsplit-stack])
 318 else
 319   SPLIT_STACK=
 320 fi
 321 AC_SUBST(SPLIT_STACK)
 322 AM_CONDITIONAL(USING_SPLIT_STACK,
 323         test "$libgo_cv_c_split_stack_supported" = yes)
 324
 325 dnl Check whether the linker does stack munging when calling from
 326 dnl split-stack into non-split-stack code.  We check this by looking
 327 dnl at the --help output.  FIXME: This is only half right: it's
 328 dnl possible for the linker to support this for some targets but not
 329 dnl others.
 330 AC_CACHE_CHECK([whether linker supports split stack],
 331 [libgo_cv_c_linker_supports_split_stack],
 332 libgo_cv_c_linker_supports_split_stack=no
 333 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 334   libgo_cv_c_linker_supports_split_stack=yes
 335 fi)
 336 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 337   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 338             [Define if the linker support split stack adjustments])
 339 fi
 340
 341 dnl Test for the -lm library.
 342 MATH_LIBS=
 343 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 344 AC_SUBST(MATH_LIBS)
 345
 346 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 347 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 348   [libgo_cv_lib_sockets=
 349    libgo_check_both=no
 350    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 351    if test "$libgo_check_socket" = "yes"; then
 352      unset ac_cv_func_connect
 353      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 354                   libgo_check_both=yes)
 355    fi
 356    if test "$libgo_check_both" = "yes"; then
 357      libgo_old_libs=$LIBS
 358      LIBS="$LIBS -lsocket -lnsl"
 359      unset ac_cv_func_accept
 360      AC_CHECK_FUNC(accept,
 361                    [libgo_check_nsl=no
 362                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 363      unset ac_cv_func_accept
 364      LIBS=$libgo_old_libs
 365    fi
 366    unset ac_cv_func_gethostbyname
 367    libgo_old_libs="$LIBS"
 368    AC_CHECK_FUNC(gethostbyname, ,
 369                  [AC_CHECK_LIB(nsl, main,
 370                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 371    unset ac_cv_func_gethostbyname
 372    LIBS=$libgo_old_libs
 373 ])
 374 NET_LIBS="$libgo_cv_lib_sockets"
 375 AC_SUBST(NET_LIBS)
 376
 377 dnl Test whether the compiler supports the -pthread option.
 378 AC_CACHE_CHECK([whether -pthread is supported],
 379 [libgo_cv_lib_pthread],
 380 [CFLAGS_hold=$CFLAGS
 381 CFLAGS="$CFLAGS -pthread"
 382 AC_COMPILE_IFELSE([[int i;]],
 383 [libgo_cv_lib_pthread=yes],
 384 [libgo_cv_lib_pthread=no])
 385 CFLAGS=$CFLAGS_hold])
 386 PTHREAD_CFLAGS=
 387 if test "$libgo_cv_lib_pthread" = yes; then
 388   PTHREAD_CFLAGS=-pthread
 389 fi
 390 AC_SUBST(PTHREAD_CFLAGS)
 391
 392 dnl Test for the -lpthread library.
 393 PTHREAD_LIBS=
 394 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 395 AC_SUBST(PTHREAD_LIBS)
 396
 397 dnl Test if -lrt is required for sched_yield.
 398 AC_SEARCH_LIBS([sched_yield], [rt])
 399
 400 AC_C_BIGENDIAN
 401
 402 GCC_CHECK_UNWIND_GETIPINFO
 403
 404 AC_ARG_ENABLE(sjlj-exceptions,
 405   AC_HELP_STRING([--enable-sjlj-exceptions],
 406                  [force use of builtin_setjmp for exceptions]),
 407   [case "$enableval" in
 408    yes|no|auto) ;;
 409    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 410    esac],
 411   [enable_sjlj_exceptions=auto])
 412
 413 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 414 [libgo_cv_lib_sjlj_exceptions],
 415 [AC_LANG_CONFTEST(
 416   [AC_LANG_SOURCE([
 417 void bar ();
 418 void clean (int *);
 419 void foo ()
 420 {
 421   int i __attribute__ ((cleanup (clean)));
 422   bar();
 423 }
 424 ])])
 425 CFLAGS_hold=$CFLAGS
 426 CFLAGS="--save-temps -fexceptions"
 427 libgo_cv_lib_sjlj_exceptions=unknown
 428 AS_IF([ac_fn_c_try_compile],
 429   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 430     libgo_cv_lib_sjlj_exceptions=yes
 431   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 432     libgo_cv_lib_sjlj_exceptions=no
 433   fi])
 434 CFLAGS=$CFLAGS_hold
 435 rm -f conftest*
 436 ])
 437
 438 if test "$enable_sjlj_exceptions" = "auto"; then
 439   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 440 fi
 441
 442 case $enable_sjlj_exceptions in
 443 yes)
 444   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 445         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 446   ;;
 447 no)
 448   ;;
 449 *)
 450   AC_MSG_ERROR([unable to detect exception model])
 451   ;;
 452 esac
 453
 454 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h)
 455
 456 AC_CHECK_HEADERS([linux/filter.h linux/netlink.h linux/rtnetlink.h], [], [],
 457 [#ifdef HAVE_SYS_SOCKET_H
 458 #include <sys/socket.h>
 459 #endif
 460 ])
 461
 462 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 463
 464 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv)
 465 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 466 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 467
 468 CFLAGS_hold="$CFLAGS"
 469 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 470 LIBS_hold="$LIBS"
 471 LIBS="$LIBS $PTHREAD_LIBS"
 472 AC_CHECK_FUNCS(sem_timedwait)
 473 CFLAGS="$CFLAGS_hold"
 474 LIBS="$LIBS_hold"
 475
 476 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 477 [libgo_cv_func___sync_bool_compare_and_swap_4],
 478 [AC_LINK_IFELSE([
 479 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 480 uint32 i;
 481 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 482 ],
 483 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 484 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 485 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 486   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 487     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 488 fi
 489
 490 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 491 [libgo_cv_func___sync_fetch_and_add_4],
 492 [AC_LINK_IFELSE([
 493 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 494 uint32 i;
 495 int main() { return __sync_fetch_and_add (&i, 1); }
 496 ],
 497 [libgo_cv_func___sync_fetch_and_add_4=yes],
 498 [libgo_cv_func___sync_fetch_and_add_4=no])])
 499 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 500   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 501     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 502 fi
 503
 504 dnl For x86 we want to use the -minline-all-stringops option to avoid
 505 dnl forcing a stack split when calling memcpy and friends.
 506 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 507 [libgo_cv_c_stringops],
 508 [CFLAGS_hold=$CFLAGS
 509 CFLAGS="$CFLAGS -minline-all-stringops"
 510 AC_COMPILE_IFELSE([int i;],
 511 [libgo_cv_c_stringops=yes],
 512 [libgo_cv_c_stringops=no])
 513 CFLAGS=$CFLAGS_hold])
 514 STRINGOPS_FLAG=
 515 if test "$libgo_cv_c_stringops" = yes; then
 516   STRINGOPS_FLAG=-minline-all-stringops
 517 fi
 518 AC_SUBST(STRINGOPS_FLAG)
 519
 520 CFLAGS_hold=$CFLAGS
 521 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 522 AC_CHECK_TYPES(off64_t)
 523 CFLAGS=$CFLAGS_hold
 524
 525 dnl Work out the size of the epoll_events struct on GNU/Linux.
 526 AC_CACHE_CHECK([epoll_event size],
 527 [libgo_cv_c_epoll_event_size],
 528 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 529 [sizeof (struct epoll_event)],
 530 [#include <sys/epoll.h>],
 531 [libgo_cv_c_epoll_event_size=0])])
 532 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 533 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 534
 535 dnl Work out the offset of the fd field in the epoll_events struct on
 536 dnl GNU/Linux.
 537 AC_CACHE_CHECK([epoll_event data.fd offset],
 538 [libgo_cv_c_epoll_event_fd_offset],
 539 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 540 [offsetof (struct epoll_event, data.fd)],
 541 [#include <stddef.h>
 542 #include <sys/epoll.h>],
 543 [libgo_cv_c_epoll_event_fd_offset=0])])
 544 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 545 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 546
 547 AC_CACHE_SAVE
 548
 549 if test ${multilib} = yes; then
 550   multilib_arg="--enable-multilib"
 551 else
 552   multilib_arg=
 553 fi
 554
 555 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 556
 557 AC_CONFIG_COMMANDS([default],
 558 [if test -n "$CONFIG_FILES"; then
 559    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 560    # that multilib installs will end up installed in the correct place.
 561    # The testsuite needs it for multilib-aware ABI baseline files.
 562    # To work around this not being passed down from config-ml.in ->
 563    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 564    # append it here.  Only modify Makefiles that have just been created.
 565    #
 566    # Also, get rid of this simulated-VPATH thing that automake does.
 567    cat > vpsed << \_EOF
 568 s!`test -f '$<' || echo '$(srcdir)/'`!!
 569 _EOF
 570    for i in $SUBDIRS; do
 571     case $CONFIG_FILES in
 572      *${i}/Makefile*)
 573        #echo "Adding MULTISUBDIR to $i/Makefile"
 574        sed -f vpsed $i/Makefile > tmp
 575        grep '^MULTISUBDIR =' Makefile >> tmp
 576        mv tmp $i/Makefile
 577        ;;
 578     esac
 579    done
 580    rm vpsed
 581  fi
 582 ],
 583 [
 584 # Variables needed in config.status (file generation) which aren't already
 585 # passed by autoconf.
 586 SUBDIRS="$SUBDIRS"
 587 ])
 588
 589 AC_OUTPUT