libgfortran/acinclude.m4

   1 m4_include(../config/acx.m4)
   2 m4_include(../config/no-executables.m4)
   3
   4 dnl Check that we have a working GNU Fortran compiler
   5 AC_DEFUN([LIBGFOR_WORKING_GFORTRAN], [
   6 AC_MSG_CHECKING([whether the GNU Fortran compiler is working])
   7 AC_LANG_PUSH([Fortran])
   8 AC_COMPILE_IFELSE([[
   9       program foo
  10       real, parameter :: bar = sin (12.34 / 2.5)
  11       end program foo]],
  12     [AC_MSG_RESULT([yes])],
  13     [AC_MSG_RESULT([no])
  14      AC_MSG_ERROR([GNU Fortran is not working; please report a bug in http://gcc.gnu.org/bugzilla, attaching $PWD/config.log])
  15     ])
  16 AC_LANG_POP([Fortran])
  17 ])
  18
  19
  20 sinclude(../libtool.m4)
  21 dnl The lines below arrange for aclocal not to bring an installed
  22 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
  23 dnl add a definition of LIBTOOL to Makefile.in.
  24 ifelse(,,,[AC_SUBST(LIBTOOL)
  25 AC_DEFUN([AM_PROG_LIBTOOL])
  26 AC_DEFUN([AC_LIBTOOL_DLOPEN])
  27 AC_DEFUN([AC_PROG_LD])
  28 ])
  29
  30 dnl Check whether the target supports hidden visibility.
  31 AC_DEFUN([LIBGFOR_CHECK_ATTRIBUTE_VISIBILITY], [
  32   AC_CACHE_CHECK([whether the target supports hidden visibility],
  33                  libgfor_cv_have_attribute_visibility, [
  34   save_CFLAGS="$CFLAGS"
  35   CFLAGS="$CFLAGS -Werror"
  36   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
  37                  [], libgfor_cv_have_attribute_visibility=yes,
  38                  libgfor_cv_have_attribute_visibility=no)
  39   CFLAGS="$save_CFLAGS"])
  40   if test $libgfor_cv_have_attribute_visibility = yes; then
  41     AC_DEFINE(HAVE_ATTRIBUTE_VISIBILITY, 1,
  42       [Define to 1 if the target supports __attribute__((visibility(...))).])
  43   fi])
  44
  45 dnl Check whether the target supports dllexport
  46 AC_DEFUN([LIBGFOR_CHECK_ATTRIBUTE_DLLEXPORT], [
  47   AC_CACHE_CHECK([whether the target supports dllexport],
  48                  libgfor_cv_have_attribute_dllexport, [
  49   save_CFLAGS="$CFLAGS"
  50   CFLAGS="$CFLAGS -Werror"
  51   AC_TRY_COMPILE([void __attribute__((dllexport)) foo(void) { }],
  52                  [], libgfor_cv_have_attribute_dllexport=yes,
  53                  libgfor_cv_have_attribute_dllexport=no)
  54   CFLAGS="$save_CFLAGS"])
  55   if test $libgfor_cv_have_attribute_dllexport = yes; then
  56     AC_DEFINE(HAVE_ATTRIBUTE_DLLEXPORT, 1,
  57       [Define to 1 if the target supports __attribute__((dllexport)).])
  58   fi])
  59
  60 dnl Check whether the target supports symbol aliases.
  61 AC_DEFUN([LIBGFOR_CHECK_ATTRIBUTE_ALIAS], [
  62   AC_CACHE_CHECK([whether the target supports symbol aliases],
  63                  libgfor_cv_have_attribute_alias, [
  64   AC_TRY_LINK([
  65 void foo(void) { }
  66 extern void bar(void) __attribute__((alias("foo")));],
  67     [bar();], libgfor_cv_have_attribute_alias=yes, libgfor_cv_have_attribute_alias=no)])
  68   if test $libgfor_cv_have_attribute_alias = yes; then
  69     AC_DEFINE(HAVE_ATTRIBUTE_ALIAS, 1,
  70       [Define to 1 if the target supports __attribute__((alias(...))).])
  71   fi])
  72
  73 dnl Check whether the target supports __sync_fetch_and_add.
  74 AC_DEFUN([LIBGFOR_CHECK_SYNC_FETCH_AND_ADD], [
  75   AC_CACHE_CHECK([whether the target supports __sync_fetch_and_add],
  76                  libgfor_cv_have_sync_fetch_and_add, [
  77   AC_TRY_LINK([int foovar = 0;], [
  78 if (foovar <= 0) return __sync_fetch_and_add (&foovar, 1);
  79 if (foovar > 10) return __sync_add_and_fetch (&foovar, -1);],
  80               libgfor_cv_have_sync_fetch_and_add=yes, libgfor_cv_have_sync_fetch_and_add=no)])
  81   if test $libgfor_cv_have_sync_fetch_and_add = yes; then
  82     AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
  83               [Define to 1 if the target supports __sync_fetch_and_add])
  84   fi])
  85
  86 dnl Check if threads are supported.
  87 AC_DEFUN([LIBGFOR_CHECK_GTHR_DEFAULT], [
  88   AC_CACHE_CHECK([configured target thread model],
  89                  libgfor_cv_target_thread_file, [
  90 libgfor_cv_target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`])
  91
  92   if test $libgfor_cv_target_thread_file != single; then
  93     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
  94               [Define if the compiler has a thread header that is non single.])
  95   fi])
  96
  97 dnl Check for pragma weak.
  98 AC_DEFUN([LIBGFOR_GTHREAD_WEAK], [
  99   AC_CACHE_CHECK([whether pragma weak works],
 100                  libgfor_cv_have_pragma_weak, [
 101   gfor_save_CFLAGS="$CFLAGS"
 102   CFLAGS="$CFLAGS -Wunknown-pragmas"
 103   AC_TRY_COMPILE([void foo (void);
 104 #pragma weak foo], [if (foo) foo ();],
 105                  libgfor_cv_have_pragma_weak=yes, libgfor_cv_have_pragma_weak=no)])
 106   if test $libgfor_cv_have_pragma_weak = yes; then
 107     AC_DEFINE(SUPPORTS_WEAK, 1,
 108               [Define to 1 if the target supports #pragma weak])
 109   fi
 110   case "$host" in
 111     *-*-darwin* | *-*-hpux* | *-*-cygwin* | *-*-mingw* )
 112       AC_DEFINE(GTHREAD_USE_WEAK, 0,
 113                 [Define to 0 if the target shouldn't use #pragma weak])
 114       ;;
 115   esac])
 116
 117 dnl Check whether target can unlink a file still open.
 118 AC_DEFUN([LIBGFOR_CHECK_UNLINK_OPEN_FILE], [
 119   AC_CACHE_CHECK([whether the target can unlink an open file],
 120                   libgfor_cv_have_unlink_open_file, [
 121   AC_TRY_RUN([
 122 #include <errno.h>
 123 #include <fcntl.h>
 124 #include <unistd.h>
 125 #include <sys/stat.h>
 126
 127 int main ()
 128 {
 129   int fd;
 130
 131   fd = open ("testfile", O_RDWR | O_CREAT, S_IWRITE | S_IREAD);
 132   if (fd <= 0)
 133     return 0;
 134   if (unlink ("testfile") == -1)
 135     return 1;
 136   write (fd, "This is a test\n", 15);
 137   close (fd);
 138
 139   if (open ("testfile", O_RDONLY, S_IWRITE | S_IREAD) == -1 && errno == ENOENT)
 140     return 0;
 141   else
 142     return 1;
 143 }], libgfor_cv_have_unlink_open_file=yes, libgfor_cv_have_unlink_open_file=no, [
 144 case "${target}" in
 145   *mingw*) libgfor_cv_have_unlink_open_file=no ;;
 146   *) libgfor_cv_have_unlink_open_file=yes;;
 147 esac])])
 148 if test x"$libgfor_cv_have_unlink_open_file" = xyes; then
 149   AC_DEFINE(HAVE_UNLINK_OPEN_FILE, 1, [Define if target can unlink open files.])
 150 fi])
 151
 152 dnl Check whether CRLF is the line terminator
 153 AC_DEFUN([LIBGFOR_CHECK_CRLF], [
 154   AC_CACHE_CHECK([whether the target has CRLF as line terminator],
 155                   libgfor_cv_have_crlf, [
 156   AC_TRY_RUN([
 157 /* This test program should exit with status 0 if system uses a CRLF as
 158    line terminator, and status 1 otherwise.
 159    Since it is used to check for mingw systems, and should return 0 in any
 160    other case, in case of a failure we will not use CRLF.  */
 161 #include <sys/stat.h>
 162 #include <stdlib.h>
 163 #include <fcntl.h>
 164 #include <stdio.h>
 165
 166 int main ()
 167 {
 168 #ifndef O_BINARY
 169   exit(1);
 170 #else
 171   int fd, bytes;
 172   char buff[5];
 173
 174   fd = open ("foo", O_WRONLY | O_CREAT | O_TRUNC, S_IRWXU);
 175   if (fd < 0)
 176     exit(1);
 177   if (write (fd, "\n", 1) < 0)
 178     perror ("write");
 179
 180   close (fd);
 181
 182   if ((fd = open ("foo", O_RDONLY | O_BINARY, S_IRWXU)) < 0)
 183     exit(1);
 184   bytes = read (fd, buff, 5);
 185   if (bytes == 2 && buff[0] == '\r' && buff[1] == '\n')
 186     exit(0);
 187   else
 188     exit(1);
 189 #endif
 190 }], libgfor_cv_have_crlf=yes, libgfor_cv_have_crlf=no, [
 191 case "${target}" in
 192   *mingw*) libgfor_cv_have_crlf=yes ;;
 193   *) libgfor_cv_have_crlf=no;;
 194 esac])])
 195 if test x"$libgfor_cv_have_crlf" = xyes; then
 196   AC_DEFINE(HAVE_CRLF, 1, [Define if CRLF is line terminator.])
 197 fi])
 198
 199 dnl Check whether the st_ino and st_dev stat fields taken together uniquely
 200 dnl identify the file within the system. This is should be true for POSIX
 201 dnl systems; it is known to be false on mingw32.
 202 AC_DEFUN([LIBGFOR_CHECK_WORKING_STAT], [
 203   AC_CACHE_CHECK([whether the target stat is reliable],
 204                   libgfor_cv_have_working_stat, [
 205   AC_TRY_RUN([
 206 #include <stdio.h>
 207 #include <sys/types.h>
 208 #include <sys/stat.h>
 209 #include <unistd.h>
 210
 211 int main ()
 212 {
 213   FILE *f, *g;
 214   struct stat st1, st2;
 215
 216   f = fopen ("foo", "w");
 217   g = fopen ("bar", "w");
 218   if (stat ("foo", &st1) != 0 || stat ("bar", &st2))
 219     return 1;
 220   if (st1.st_dev == st2.st_dev && st1.st_ino == st2.st_ino)
 221     return 1;
 222   fclose(f);
 223   fclose(g);
 224   return 0;
 225 }], libgfor_cv_have_working_stat=yes, libgfor_cv_have_working_stat=no, [
 226 case "${target}" in
 227   *mingw*) libgfor_cv_have_working_stat=no ;;
 228   *) libgfor_cv_have_working_stat=yes;;
 229 esac])])
 230 if test x"$libgfor_cv_have_working_stat" = xyes; then
 231   AC_DEFINE(HAVE_WORKING_STAT, 1, [Define if target has a reliable stat.])
 232 fi])
 233
 234 dnl Checks for fpsetmask function.
 235 AC_DEFUN([LIBGFOR_CHECK_FPSETMASK], [
 236   AC_CACHE_CHECK([whether fpsetmask is present], libgfor_cv_have_fpsetmask, [
 237     AC_TRY_LINK([
 238 #if HAVE_FLOATINGPOINT_H
 239 # include <floatingpoint.h>
 240 #endif /* HAVE_FLOATINGPOINT_H */
 241 #if HAVE_IEEEFP_H
 242 # include <ieeefp.h>
 243 #endif /* HAVE_IEEEFP_H */],[fpsetmask(0);],
 244     eval "libgfor_cv_have_fpsetmask=yes", eval "libgfor_cv_have_fpsetmask=no")
 245   ])
 246   if test x"$libgfor_cv_have_fpsetmask" = xyes; then
 247     have_fpsetmask=yes
 248     AC_DEFINE(HAVE_FPSETMASK, 1, [Define if you have fpsetmask.])
 249   fi
 250 ])
 251
 252 dnl Check whether we have a mingw that provides a __mingw_snprintf function
 253 AC_DEFUN([LIBGFOR_CHECK_MINGW_SNPRINTF], [
 254   AC_CACHE_CHECK([whether __mingw_snprintf is present], libgfor_cv_have_mingw_snprintf, [
 255     AC_TRY_LINK([
 256 #include <stdio.h>
 257 extern int __mingw_snprintf (char *, size_t, const char *, ...);
 258 ],[
 259 __mingw_snprintf (NULL, 0, "%d\n", 1);
 260 ],
 261     eval "libgfor_cv_have_mingw_snprintf=yes", eval "libgfor_cv_have_mingw_snprintf=no")
 262   ])
 263   if test x"$libgfor_cv_have_mingw_snprintf" = xyes; then
 264     AC_DEFINE(HAVE_MINGW_SNPRINTF, 1, [Define if you have __mingw_snprintf.])
 265   fi
 266 ])
 267
 268 dnl Check whether we have a broken powf implementation
 269 AC_DEFUN([LIBGFOR_CHECK_FOR_BROKEN_POWF], [
 270   AC_CACHE_CHECK([whether powf is broken], libgfor_cv_have_broken_powf, [
 271 case "${target}" in
 272   hppa*64*-*-hpux*) libgfor_cv_have_broken_powf=yes ;;
 273   *) libgfor_cv_have_broken_powf=no;;
 274 esac])
 275   if test x"$libgfor_cv_have_broken_powf" = xyes; then
 276     AC_DEFINE(HAVE_BROKEN_POWF, 1, [Define if powf is broken.])
 277   fi
 278 ])
 279
 280 dnl Check whether we have a __float128 type
 281 AC_DEFUN([LIBGFOR_CHECK_FLOAT128], [
 282   LIBQUADSPEC=
 283
 284   if test "x$enable_libquadmath_support" != xno; then
 285
 286   AC_CACHE_CHECK([whether we have a usable __float128 type],
 287                  libgfor_cv_have_float128, [
 288    GCC_TRY_COMPILE_OR_LINK([
 289     typedef _Complex float __attribute__((mode(TC))) __complex128;
 290
 291     __float128 foo (__float128 x)
 292     {
 293
 294      __complex128 z1, z2;
 295
 296      z1 = x;
 297      z2 = x / 7.Q;
 298      z2 /= z1;
 299
 300      return (__float128) z2;
 301     }
 302
 303     __float128 bar (__float128 x)
 304     {
 305       return x * __builtin_huge_valq ();
 306     }
 307   ],[
 308     foo (1.2Q);
 309     bar (1.2Q);
 310   ],[
 311     libgfor_cv_have_float128=yes
 312   ],[
 313     libgfor_cv_have_float128=no
 314 ])])
 315
 316   if test "x$libgfor_cv_have_float128" = xyes; then
 317     AC_DEFINE(HAVE_FLOAT128, 1, [Define if have a usable __float128 type.])
 318
 319     dnl Check whether -Wl,--as-needed is supported
 320     dnl
 321     dnl Turn warnings into error to avoid testsuite breakage.  So enable
 322     dnl AC_LANG_WERROR, but there's currently (autoconf 2.64) no way to turn
 323     dnl it off again.  As a workaround, save and restore werror flag like
 324     dnl AC_PATH_XTRA.
 325     dnl Cf. http://gcc.gnu.org/ml/gcc-patches/2010-05/msg01889.html
 326     ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag=$ac_[]_AC_LANG_ABBREV[]_werror_flag
 327     AC_CACHE_CHECK([whether --as-needed works],
 328       [libgfor_cv_have_as_needed],
 329       [
 330       save_LDFLAGS="$LDFLAGS"
 331       LDFLAGS="$LDFLAGS -Wl,--as-needed -lm -Wl,--no-as-needed"
 332       libgfor_cv_have_as_needed=no
 333       AC_LANG_WERROR
 334       AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 335                      [libgfor_cv_have_as_needed=yes],
 336                      [libgfor_cv_have_as_needed=no])
 337       LDFLAGS="$save_LDFLAGS"
 338       ac_[]_AC_LANG_ABBREV[]_werror_flag=$ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag
 339     ])
 340
 341     dnl For static libgfortran linkage, depend on libquadmath only if needed.
 342     if test "x$libgfor_cv_have_as_needed" = xyes; then
 343       LIBQUADSPEC="%{static-libgfortran:--as-needed} -lquadmath %{static-libgfortran:--no-as-needed}"
 344     else
 345       LIBQUADSPEC="-lquadmath"
 346     fi
 347     if test -f ../libquadmath/libquadmath.la; then
 348       LIBQUADLIB=../libquadmath/libquadmath.la
 349       LIBQUADLIB_DEP=../libquadmath/libquadmath.la
 350       LIBQUADINCLUDE='-I$(srcdir)/../libquadmath'
 351     else
 352       LIBQUADLIB="-lquadmath"
 353       LIBQUADLIB_DEP=
 354       LIBQUADINCLUDE=
 355     fi
 356   fi
 357   else
 358     # for --disable-quadmath
 359     LIBQUADLIB=
 360     LIBQUADLIB_DEP=
 361     LIBQUADINCLUDE=
 362   fi
 363
 364   dnl For the spec file
 365   AC_SUBST(LIBQUADSPEC)
 366   AC_SUBST(LIBQUADLIB)
 367   AC_SUBST(LIBQUADLIB_DEP)
 368   AC_SUBST(LIBQUADINCLUDE)
 369
 370   dnl We need a conditional for the Makefile
 371   AM_CONDITIONAL(LIBGFOR_BUILD_QUAD, [test "x$libgfor_cv_have_float128" = xyes])
 372 ])