libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.9], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd* | amd64-*-openbsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   avr32*-*-*)
  59         TARGET=AVR32; TARGETDIR=avr32
  60         ;;
  61
  62   cris-*-*)
  63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  64         ;;
  65
  66   frv-*-*)
  67         TARGET=FRV; TARGETDIR=frv
  68         ;;
  69
  70   hppa*-*-linux* | parisc*-*-linux*)
  71         TARGET=PA_LINUX; TARGETDIR=pa
  72         ;;
  73   hppa*64-*-hpux*)
  74         TARGET=PA64_HPUX; TARGETDIR=pa
  75         ;;
  76   hppa*-*-hpux*)
  77         TARGET=PA_HPUX; TARGETDIR=pa
  78         ;;
  79
  80   i?86-*-freebsd* | i?86-*-openbsd*)
  81         TARGET=X86_FREEBSD; TARGETDIR=x86
  82         ;;
  83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  84         TARGET=X86_WIN32; TARGETDIR=x86
  85         # All mingw/cygwin/win32 builds require this for sharedlib
  86         AM_LTLDFLAGS="-no-undefined"
  87         ;;
  88   i?86-*-darwin*)
  89         TARGET=X86_DARWIN; TARGETDIR=x86
  90         ;;
  91   i?86-*-solaris2.1[[0-9]]*)
  92         TARGET=X86_64; TARGETDIR=x86
  93         ;;
  94   i?86-*-*)
  95         TARGET=X86; TARGETDIR=x86
  96         ;;
  97
  98   ia64*-*-*)
  99         TARGET=IA64; TARGETDIR=ia64
 100         ;;
 101
 102   m32r*-*-*)
 103         TARGET=M32R; TARGETDIR=m32r
 104         ;;
 105
 106   m68k-*-*)
 107         TARGET=M68K; TARGETDIR=m68k
 108         ;;
 109
 110   mips-sgi-irix5.* | mips-sgi-irix6.*)
 111         TARGET=MIPS; TARGETDIR=mips
 112         ;;
 113   mips*-*-linux*)
 114         TARGET=MIPS; TARGETDIR=mips
 115         ;;
 116
 117   powerpc*-*-linux* | powerpc-*-sysv*)
 118         TARGET=POWERPC; TARGETDIR=powerpc
 119         ;;
 120   powerpc-*-beos*)
 121         TARGET=POWERPC; TARGETDIR=powerpc
 122         ;;
 123   powerpc-*-darwin*)
 124         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 125         ;;
 126   powerpc-*-aix* | rs6000-*-aix*)
 127         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 128         ;;
 129   powerpc-*-freebsd*)
 130         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 131         ;;
 132   powerpc*-*-rtems*)
 133         TARGET=POWERPC; TARGETDIR=powerpc
 134         ;;
 135
 136   s390-*-* | s390x-*-*)
 137         TARGET=S390; TARGETDIR=s390
 138         ;;
 139
 140   sh-*-* | sh[[34]]*-*-*)
 141         TARGET=SH; TARGETDIR=sh
 142         ;;
 143   sh64-*-* | sh5*-*-*)
 144         TARGET=SH64; TARGETDIR=sh64
 145         ;;
 146
 147   sparc*-*-*)
 148         TARGET=SPARC; TARGETDIR=sparc
 149         ;;
 150
 151   x86_64-*-darwin*)
 152         TARGET=X86_DARWIN; TARGETDIR=x86
 153         ;;
 154
 155   x86_64-*-cygwin* | x86_64-*-mingw*)
 156         TARGET=X86_WIN64; TARGETDIR=x86
 157         ;;
 158
 159   x86_64-*-*)
 160         TARGET=X86_64; TARGETDIR=x86
 161         ;;
 162 esac
 163
 164 AC_SUBST(AM_RUNTESTFLAGS)
 165 AC_SUBST(AM_LTLDFLAGS)
 166
 167 if test $TARGETDIR = unknown; then
 168   AC_MSG_ERROR(["libffi has not been ported to $host."])
 169 fi
 170
 171 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 172 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 173 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 174 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 175 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 176 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 177 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 178 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 179 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 180 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 181 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 182 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 183 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 184 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 185 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 186 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 187 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 188 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 189 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 190 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 191 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 192 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 193 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 194 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 195 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 196 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 197
 198 AC_HEADER_STDC
 199 AC_CHECK_FUNCS(memcpy)
 200 AC_FUNC_ALLOCA
 201
 202 AC_CHECK_SIZEOF(double)
 203 AC_CHECK_SIZEOF(long double)
 204
 205 # Also AC_SUBST this variable for ffi.h.
 206 if test -z "$HAVE_LONG_DOUBLE"; then
 207   HAVE_LONG_DOUBLE=0
 208   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 209     if test $ac_cv_sizeof_long_double != 0; then
 210       HAVE_LONG_DOUBLE=1
 211       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 212     fi
 213   fi
 214 fi
 215 AC_SUBST(HAVE_LONG_DOUBLE)
 216
 217 AC_C_BIGENDIAN
 218
 219 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 220     libffi_cv_as_cfi_pseudo_op, [
 221     libffi_cv_as_cfi_pseudo_op=unknown
 222     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 223                    [libffi_cv_as_cfi_pseudo_op=yes],
 224                    [libffi_cv_as_cfi_pseudo_op=no])
 225 ])
 226 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 227     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 228               [Define if your assembler supports .cfi_* directives.])
 229 fi
 230
 231 if test x$TARGET = xSPARC; then
 232     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 233         libffi_cv_as_sparc_ua_pcrel, [
 234         save_CFLAGS="$CFLAGS"
 235         save_LDFLAGS="$LDFLAGS"
 236         CFLAGS="$CFLAGS -fpic"
 237         LDFLAGS="$LDFLAGS -shared"
 238         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 239                     [libffi_cv_as_sparc_ua_pcrel=yes],
 240                     [libffi_cv_as_sparc_ua_pcrel=no])
 241         CFLAGS="$save_CFLAGS"
 242         LDFLAGS="$save_LDFLAGS"])
 243     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 244         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 245                   [Define if your assembler and linker support unaligned PC relative relocs.])
 246     fi
 247
 248     AC_CACHE_CHECK([assembler .register pseudo-op support],
 249        libffi_cv_as_register_pseudo_op, [
 250        libffi_cv_as_register_pseudo_op=unknown
 251        # Check if we have .register
 252        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 253                        [libffi_cv_as_register_pseudo_op=yes],
 254                        [libffi_cv_as_register_pseudo_op=no])
 255     ])
 256     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 257        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 258                [Define if your assembler supports .register.])
 259     fi
 260 fi
 261
 262 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 263     AC_CACHE_CHECK([assembler supports pc related relocs],
 264         libffi_cv_as_x86_pcrel, [
 265         libffi_cv_as_x86_pcrel=yes
 266         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 267         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 268             libffi_cv_as_x86_pcrel=no
 269         fi
 270         ])
 271     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 272         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 273                   [Define if your assembler supports PC relative relocs.])
 274     fi
 275 fi
 276
 277 case "$target" in
 278      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 279        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 280                  [Cannot use malloc on this target, so, we revert to
 281                    alternative means])
 282      ;;
 283 esac
 284
 285 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 286     libffi_cv_ro_eh_frame, [
 287         libffi_cv_ro_eh_frame=no
 288         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 289         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 290             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 291                 libffi_cv_ro_eh_frame=yes
 292             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 293                  | grep -v '#write' > /dev/null; then
 294                 libffi_cv_ro_eh_frame=yes
 295             fi
 296         fi
 297         rm -f conftest.*
 298     ])
 299 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 300     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 301               [Define if .eh_frame sections should be read-only.])
 302     AC_DEFINE(EH_FRAME_FLAGS, "a",
 303               [Define to the flags needed for the .section .eh_frame directive.])
 304 else
 305     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 306               [Define to the flags needed for the .section .eh_frame directive.])
 307 fi
 308
 309 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 310     libffi_cv_hidden_visibility_attribute, [
 311         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 312         libffi_cv_hidden_visibility_attribute=no
 313         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 314             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 315                 libffi_cv_hidden_visibility_attribute=yes
 316             fi
 317         fi
 318         rm -f conftest.*
 319     ])
 320 if test $libffi_cv_hidden_visibility_attribute = yes; then
 321     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 322               [Define if __attribute__((visibility("hidden"))) is supported.])
 323 fi
 324
 325 AH_BOTTOM([
 326 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 327 #ifdef LIBFFI_ASM
 328 #define FFI_HIDDEN(name) .hidden name
 329 #else
 330 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 331 #endif
 332 #else
 333 #ifdef LIBFFI_ASM
 334 #define FFI_HIDDEN(name)
 335 #else
 336 #define FFI_HIDDEN
 337 #endif
 338 #endif
 339 ])
 340
 341 AC_SUBST(TARGET)
 342 AC_SUBST(TARGETDIR)
 343
 344 AC_SUBST(SHELL)
 345
 346 AC_ARG_ENABLE(debug,
 347 [  --enable-debug          debugging mode],
 348   if test "$enable_debug" = "yes"; then
 349     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 350   fi)
 351
 352 AC_ARG_ENABLE(structs,
 353 [  --disable-structs       omit code for struct support],
 354   if test "$enable_structs" = "no"; then
 355     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 356   fi)
 357
 358 AC_ARG_ENABLE(raw-api,
 359 [  --disable-raw-api       make the raw api unavailable],
 360   if test "$enable_raw_api" = "no"; then
 361     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 362   fi)
 363
 364 AC_ARG_ENABLE(purify-safety,
 365 [  --enable-purify-safety  purify-safe mode],
 366   if test "$enable_purify_safety" = "yes"; then
 367     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 368   fi)
 369
 370 if test -n "$with_cross_host" &&
 371    test x"$with_cross_host" != x"no"; then
 372   toolexecdir='$(exec_prefix)/$(target_alias)'
 373   toolexeclibdir='$(toolexecdir)/lib'
 374 else
 375   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 376   toolexeclibdir='$(libdir)'
 377 fi
 378 multi_os_directory=`$CC -print-multi-os-directory`
 379 case $multi_os_directory in
 380   .) ;; # Avoid trailing /.
 381   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 382 esac
 383 AC_SUBST(toolexecdir)
 384 AC_SUBST(toolexeclibdir)
 385
 386 if test "${multilib}" = "yes"; then
 387   multilib_arg="--enable-multilib"
 388 else
 389   multilib_arg=
 390 fi
 391
 392 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 393 AC_CONFIG_COMMANDS(src, [
 394 test -d src || mkdir src
 395 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 396 ], [TARGETDIR="$TARGETDIR"])
 397
 398 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 399
 400 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 401
 402 AC_OUTPUT