libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   cris-*-*)
  55         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  56         ;;
  57
  58   frv-*-*)
  59         TARGET=FRV; TARGETDIR=frv
  60         ;;
  61
  62   hppa*-*-linux* | parisc*-*-linux*)
  63         TARGET=PA_LINUX; TARGETDIR=pa
  64         ;;
  65   hppa*64-*-hpux*)
  66         TARGET=PA64_HPUX; TARGETDIR=pa
  67         ;;
  68   hppa*-*-hpux*)
  69         TARGET=PA_HPUX; TARGETDIR=pa
  70         ;;
  71
  72   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  73         TARGET=X86_WIN32; TARGETDIR=x86
  74         ;;
  75   i?86-*-darwin*)
  76         TARGET=X86_DARWIN; TARGETDIR=x86
  77         ;;
  78   i?86-*-solaris2.1[[0-9]]*)
  79         TARGET=X86_64; TARGETDIR=x86
  80         ;;
  81   i?86-*-*)
  82         TARGET=X86; TARGETDIR=x86
  83         ;;
  84
  85   ia64*-*-*)
  86         TARGET=IA64; TARGETDIR=ia64
  87         ;;
  88
  89   m32r*-*-*)
  90         TARGET=M32R; TARGETDIR=m32r
  91         ;;
  92
  93   m68k-*-*)
  94         TARGET=M68K; TARGETDIR=m68k
  95         ;;
  96
  97   mips-sgi-irix5.* | mips-sgi-irix6.*)
  98         TARGET=MIPS_IRIX; TARGETDIR=mips
  99         ;;
 100   mips*-*-linux*)
 101         TARGET=MIPS_LINUX; TARGETDIR=mips
 102         ;;
 103
 104   powerpc*-*-linux* | powerpc-*-sysv*)
 105         TARGET=POWERPC; TARGETDIR=powerpc
 106         ;;
 107   powerpc-*-beos*)
 108         TARGET=POWERPC; TARGETDIR=powerpc
 109         ;;
 110   powerpc-*-darwin*)
 111         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 112         ;;
 113   powerpc-*-aix* | rs6000-*-aix*)
 114         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 115         ;;
 116   powerpc-*-freebsd*)
 117         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 118         ;;
 119   powerpc*-*-rtems*)
 120         TARGET=POWERPC; TARGETDIR=powerpc
 121         ;;
 122
 123   s390-*-* | s390x-*-*)
 124         TARGET=S390; TARGETDIR=s390
 125         ;;
 126
 127   sh-*-* | sh[[34]]*-*-*)
 128         TARGET=SH; TARGETDIR=sh
 129         ;;
 130   sh64-*-* | sh5*-*-*)
 131         TARGET=SH64; TARGETDIR=sh64
 132         ;;
 133
 134   sparc*-*-*)
 135         TARGET=SPARC; TARGETDIR=sparc
 136         ;;
 137
 138   x86_64-*-darwin*)
 139         TARGET=X86_DARWIN; TARGETDIR=x86
 140         ;;
 141   x86_64-*-cygwin* | x86_64-*-mingw*)
 142         ;;
 143   x86_64-*-*)
 144         TARGET=X86_64; TARGETDIR=x86
 145         ;;
 146 esac
 147
 148 AC_SUBST(AM_RUNTESTFLAGS)
 149
 150 if test $TARGETDIR = unknown; then
 151   AC_MSG_ERROR(["libffi has not been ported to $host."])
 152 fi
 153
 154 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
 155 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
 156 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 157 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 158 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 159 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 160 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 161 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 162 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 163 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 164 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 165 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 166 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 167 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 168 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 169 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 170 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 171 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 172 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 173 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 174 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 175 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 176 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 177 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 178
 179 case x$TARGET in
 180   xMIPS*) TARGET=MIPS ;;
 181   *) ;;
 182 esac
 183
 184 AC_HEADER_STDC
 185 AC_CHECK_FUNCS(memcpy)
 186 AC_FUNC_ALLOCA
 187
 188 AC_CHECK_SIZEOF(double)
 189 AC_CHECK_SIZEOF(long double)
 190
 191 # Also AC_SUBST this variable for ffi.h.
 192 if test -z "$HAVE_LONG_DOUBLE"; then
 193   HAVE_LONG_DOUBLE=0
 194   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 195     if test $ac_cv_sizeof_long_double != 0; then
 196       HAVE_LONG_DOUBLE=1
 197       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 198     fi
 199   fi
 200 fi
 201 AC_SUBST(HAVE_LONG_DOUBLE)
 202
 203 AC_C_BIGENDIAN
 204
 205 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 206     libffi_cv_as_cfi_pseudo_op, [
 207     libffi_cv_as_cfi_pseudo_op=unknown
 208     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 209                    [libffi_cv_as_cfi_pseudo_op=yes],
 210                    [libffi_cv_as_cfi_pseudo_op=no])
 211 ])
 212 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 213     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 214               [Define if your assembler supports .cfi_* directives.])
 215 fi
 216
 217 if test x$TARGET = xSPARC; then
 218     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 219         libffi_cv_as_sparc_ua_pcrel, [
 220         save_CFLAGS="$CFLAGS"
 221         save_LDFLAGS="$LDFLAGS"
 222         CFLAGS="$CFLAGS -fpic"
 223         LDFLAGS="$LDFLAGS -shared"
 224         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 225                     [libffi_cv_as_sparc_ua_pcrel=yes],
 226                     [libffi_cv_as_sparc_ua_pcrel=no])
 227         CFLAGS="$save_CFLAGS"
 228         LDFLAGS="$save_LDFLAGS"])
 229     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 230         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 231                   [Define if your assembler and linker support unaligned PC relative relocs.])
 232     fi
 233
 234     AC_CACHE_CHECK([assembler .register pseudo-op support],
 235        libffi_cv_as_register_pseudo_op, [
 236        libffi_cv_as_register_pseudo_op=unknown
 237        # Check if we have .register
 238        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 239                        [libffi_cv_as_register_pseudo_op=yes],
 240                        [libffi_cv_as_register_pseudo_op=no])
 241     ])
 242     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 243        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 244                [Define if your assembler supports .register.])
 245     fi
 246 fi
 247
 248 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 249     libffi_cv_ro_eh_frame, [
 250         libffi_cv_ro_eh_frame=no
 251         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 252         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 253             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 254                 libffi_cv_ro_eh_frame=yes
 255             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 256                  | grep -v '#write' > /dev/null; then
 257                 libffi_cv_ro_eh_frame=yes
 258             fi
 259         fi
 260         rm -f conftest.*
 261     ])
 262 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 263     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 264               [Define if .eh_frame sections should be read-only.])
 265     AC_DEFINE(EH_FRAME_FLAGS, "a",
 266               [Define to the flags needed for the .section .eh_frame directive.])
 267 else
 268     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 269               [Define to the flags needed for the .section .eh_frame directive.])
 270 fi
 271
 272 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 273     libffi_cv_hidden_visibility_attribute, [
 274         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 275         libffi_cv_hidden_visibility_attribute=no
 276         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 277             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 278                 libffi_cv_hidden_visibility_attribute=yes
 279             fi
 280         fi
 281         rm -f conftest.*
 282     ])
 283 if test $libffi_cv_hidden_visibility_attribute = yes; then
 284     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 285               [Define if __attribute__((visibility("hidden"))) is supported.])
 286 fi
 287
 288 AH_BOTTOM([
 289 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 290 #ifdef LIBFFI_ASM
 291 #define FFI_HIDDEN(name) .hidden name
 292 #else
 293 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 294 #endif
 295 #else
 296 #ifdef LIBFFI_ASM
 297 #define FFI_HIDDEN(name)
 298 #else
 299 #define FFI_HIDDEN
 300 #endif
 301 #endif
 302 ])
 303
 304 AC_SUBST(TARGET)
 305 AC_SUBST(TARGETDIR)
 306
 307 AC_SUBST(SHELL)
 308
 309 AC_ARG_ENABLE(debug,
 310 [  --enable-debug          debugging mode],
 311   if test "$enable_debug" = "yes"; then
 312     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 313   fi)
 314
 315 AC_ARG_ENABLE(structs,
 316 [  --disable-structs       omit code for struct support],
 317   if test "$enable_structs" = "no"; then
 318     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 319   fi)
 320
 321 AC_ARG_ENABLE(raw-api,
 322 [  --disable-raw-api       make the raw api unavailable],
 323   if test "$enable_raw_api" = "no"; then
 324     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 325   fi)
 326
 327 AC_ARG_ENABLE(purify-safety,
 328 [  --enable-purify-safety  purify-safe mode],
 329   if test "$enable_purify_safety" = "yes"; then
 330     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 331   fi)
 332
 333 if test -n "$with_cross_host" &&
 334    test x"$with_cross_host" != x"no"; then
 335   toolexecdir='$(exec_prefix)/$(target_alias)'
 336   toolexeclibdir='$(toolexecdir)/lib'
 337 else
 338   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 339   toolexeclibdir='$(libdir)'
 340 fi
 341 multi_os_directory=`$CC -print-multi-os-directory`
 342 case $multi_os_directory in
 343   .) ;; # Avoid trailing /.
 344   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 345 esac
 346 AC_SUBST(toolexecdir)
 347 AC_SUBST(toolexeclibdir)
 348
 349 if test "${multilib}" = "yes"; then
 350   multilib_arg="--enable-multilib"
 351 else
 352   multilib_arg=
 353 fi
 354
 355 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 356 AC_CONFIG_COMMANDS(src, [
 357 test -d src || mkdir src
 358 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 359 ], [TARGETDIR="$TARGETDIR"])
 360
 361 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 362
 363 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 364
 365 AC_OUTPUT