libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9 if test a = b; then
  10    # This is for automake
  11    AC_CONFIG_AUX_DIR([..])
  12 else
  13    # and this is for autoconf
  14    AC_CONFIG_AUX_DIRS(${multi_basedir})
  15  fi
  16
  17 AC_CANONICAL_SYSTEM
  18 target_alias=${target_alias-$host_alias}
  19
  20 AM_INIT_AUTOMAKE
  21
  22 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  23 # We must force CC to /not/ be precious variables; otherwise
  24 # the wrong, non-multilib-adjusted value will be used in multilibs.
  25 # As a side effect, we have to subst CFLAGS ourselves.
  26
  27 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  28 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  29 AC_PROG_CC
  30 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_PROG_AS
  35 AM_PROG_CC_C_O
  36 AC_PROG_LIBTOOL
  37
  38 AM_MAINTAINER_MODE
  39
  40 AC_CHECK_HEADERS(sys/mman.h)
  41 AC_CHECK_FUNCS(mmap)
  42 AC_FUNC_MMAP_BLACKLIST
  43
  44 dnl The -no-testsuite modules omit the test subdir.
  45 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  46
  47 TARGETDIR="unknown"
  48 case "$host" in
  49 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  50 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  54 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  55 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  57 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  58 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  61 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  62 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  63 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  64 mips64*-*);;
  65 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
  66 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  67 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  68 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  69 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  70 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  71 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  72 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  73 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
  74 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  75 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  76 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  77 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  78 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  79 hppa-*-linux* | parisc-*-linux*) TARGET=PA; TARGETDIR=pa;;
  80 esac
  81
  82 AC_SUBST(AM_RUNTESTFLAGS)
  83
  84 if test $TARGETDIR = unknown; then
  85   AC_MSG_ERROR(["libffi has not been ported to $host."])
  86 fi
  87
  88 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
  89 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  90 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  91 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  92 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  93 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  94 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  95 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  96 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  97 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  98 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  99 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 100 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 101 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 102 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 103 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 104 AM_CONDITIONAL(PA, test x$TARGET = xPA)
 105
 106 case x$TARGET in
 107   xMIPS*) TARGET=MIPS ;;
 108   *) ;;
 109 esac
 110
 111 AC_HEADER_STDC
 112 AC_CHECK_FUNCS(memcpy)
 113 AC_FUNC_ALLOCA
 114
 115 AC_COMPILE_CHECK_SIZEOF(double)
 116 AC_COMPILE_CHECK_SIZEOF(long double)
 117
 118 # Also AC_SUBST this variable for ffi.h.
 119 HAVE_LONG_DOUBLE=0
 120 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 121   if test $ac_cv_sizeof_long_double != 0; then
 122     HAVE_LONG_DOUBLE=1
 123     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 124   fi
 125 fi
 126 AC_SUBST(HAVE_LONG_DOUBLE)
 127
 128 AC_C_BIGENDIAN_CROSS
 129
 130 if test x$TARGET = xSPARC; then
 131     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 132         libffi_cv_as_sparc_ua_pcrel, [
 133         save_CFLAGS="$CFLAGS"
 134         save_LDFLAGS="$LDFLAGS"
 135         CFLAGS="$CFLAGS -fpic"
 136         LDFLAGS="$LDFLAGS -shared"
 137         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 138                     [libffi_cv_as_sparc_ua_pcrel=yes],
 139                     [libffi_cv_as_sparc_ua_pcrel=no])
 140         CFLAGS="$save_CFLAGS"
 141         LDFLAGS="$save_LDFLAGS"])
 142     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 143         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 144                   [Define if your assembler and linker support unaligned PC relative relocs.])
 145     fi
 146
 147     AC_CACHE_CHECK([assembler .register pseudo-op support],
 148        libffi_cv_as_register_pseudo_op, [
 149        libffi_cv_as_register_pseudo_op=unknown
 150        # Check if we have .register
 151        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 152                        [libffi_cv_as_register_pseudo_op=yes],
 153                        [libffi_cv_as_register_pseudo_op=no])
 154     ])
 155     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 156        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 157                [Define if your assembler supports .register.])
 158     fi
 159 fi
 160
 161 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 162     libffi_cv_ro_eh_frame, [
 163         libffi_cv_ro_eh_frame=no
 164         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 165         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 166             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 167                 libffi_cv_ro_eh_frame=yes
 168             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 169                  | grep -v '#write' > /dev/null; then
 170                 libffi_cv_ro_eh_frame=yes
 171             fi
 172         fi
 173         rm -f conftest.*
 174     ])
 175 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 176     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 177               [Define if .eh_frame sections should be read-only.])
 178     AC_DEFINE(EH_FRAME_FLAGS, "a",
 179               [Define to the flags needed for the .section .eh_frame directive.])
 180 else
 181     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 182               [Define to the flags needed for the .section .eh_frame directive.])
 183 fi
 184
 185 AC_SUBST(TARGET)
 186 AC_SUBST(TARGETDIR)
 187
 188 AC_SUBST(SHELL)
 189
 190 AC_ARG_ENABLE(debug,
 191 [  --enable-debug          debugging mode],
 192   if test "$enable_debug" = "yes"; then
 193     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 194   fi)
 195
 196 AC_ARG_ENABLE(structs,
 197 [  --disable-structs       omit code for struct support],
 198   if test "$enable_structs" = "no"; then
 199     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 200   fi)
 201
 202 AC_ARG_ENABLE(raw-api,
 203 [  --disable-raw-api       make the raw api unavailable],
 204   if test "$enable_raw_api" = "no"; then
 205     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 206   fi)
 207
 208 AC_ARG_ENABLE(purify-safety,
 209 [  --enable-purify-safety  purify-safe mode],
 210   if test "$enable_purify_safety" = "yes"; then
 211     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 212   fi)
 213
 214 if test -n "$with_cross_host" &&
 215    test x"$with_cross_host" != x"no"; then
 216   toolexecdir='$(exec_prefix)/$(target_alias)'
 217   toolexeclibdir='$(toolexecdir)/lib'
 218 else
 219   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 220   toolexeclibdir='$(libdir)'
 221 fi
 222 multi_os_directory=`$CC -print-multi-os-directory`
 223 case $multi_os_directory in
 224   .) ;; # Avoid trailing /.
 225   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 226 esac
 227 AC_SUBST(toolexecdir)
 228 AC_SUBST(toolexeclibdir)
 229
 230 #Figure out where generated headers like ffitarget.h get installed.
 231 changequote(,)dnl
 232 gcc_version_trigger=${srcdir}/../gcc/version.c
 233 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 234 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 235 tool_include_dir='$(libdir)/gcc/$(target_alias)/'${gcc_version}/include
 236 changequote([,])dnl
 237 AC_SUBST(tool_include_dir)
 238 AC_SUBST(gcc_version)
 239
 240
 241 if test "${multilib}" = "yes"; then
 242   multilib_arg="--enable-multilib"
 243 else
 244   multilib_arg=
 245 fi
 246
 247 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 248 AC_CONFIG_COMMANDS(src, [
 249 test -d src || mkdir src
 250 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 251 ], [TARGETDIR="$TARGETDIR"])
 252
 253 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 254
 255 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 256
 257 AC_OUTPUT