libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4
   5 AC_INIT([libffi], [3.0.9], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd* | amd64-*-openbsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   avr32*-*-*)
  59         TARGET=AVR32; TARGETDIR=avr32
  60         ;;
  61
  62   cris-*-*)
  63         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  64         ;;
  65
  66   frv-*-*)
  67         TARGET=FRV; TARGETDIR=frv
  68         ;;
  69
  70   hppa*-*-linux* | parisc*-*-linux*)
  71         TARGET=PA_LINUX; TARGETDIR=pa
  72         ;;
  73   hppa*64-*-hpux*)
  74         TARGET=PA64_HPUX; TARGETDIR=pa
  75         ;;
  76   hppa*-*-hpux*)
  77         TARGET=PA_HPUX; TARGETDIR=pa
  78         ;;
  79
  80   i?86-*-freebsd* | i?86-*-openbsd*)
  81         TARGET=X86_FREEBSD; TARGETDIR=x86
  82         ;;
  83   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  84         TARGET=X86_WIN32; TARGETDIR=x86
  85         # All mingw/cygwin/win32 builds require this for sharedlib
  86         AM_LTLDFLAGS="-no-undefined"
  87         ;;
  88   i?86-*-darwin*)
  89         TARGET=X86_DARWIN; TARGETDIR=x86
  90         ;;
  91   i?86-*-solaris2.1[[0-9]]*)
  92         TARGET=X86_64; TARGETDIR=x86
  93         ;;
  94   i?86-*-*)
  95         TARGET=X86; TARGETDIR=x86
  96         ;;
  97
  98   ia64*-*-*)
  99         TARGET=IA64; TARGETDIR=ia64
 100         ;;
 101
 102   m32r*-*-*)
 103         TARGET=M32R; TARGETDIR=m32r
 104         ;;
 105
 106   m68k-*-*)
 107         TARGET=M68K; TARGETDIR=m68k
 108         ;;
 109
 110   mips-sgi-irix5.* | mips-sgi-irix6.*)
 111         TARGET=MIPS; TARGETDIR=mips
 112         ;;
 113   mips*-*-linux*)
 114         # Support 128-bit long double for NewABI.
 115         HAVE_LONG_DOUBLE='defined(__mips64)'
 116         TARGET=MIPS; TARGETDIR=mips
 117         ;;
 118
 119   powerpc*-*-linux* | powerpc-*-sysv*)
 120         TARGET=POWERPC; TARGETDIR=powerpc
 121         ;;
 122   powerpc-*-beos*)
 123         TARGET=POWERPC; TARGETDIR=powerpc
 124         ;;
 125   powerpc-*-darwin*)
 126         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 127         ;;
 128   powerpc-*-aix* | rs6000-*-aix*)
 129         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 130         ;;
 131   powerpc-*-freebsd*)
 132         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 133         ;;
 134   powerpc*-*-rtems*)
 135         TARGET=POWERPC; TARGETDIR=powerpc
 136         ;;
 137
 138   s390-*-* | s390x-*-*)
 139         TARGET=S390; TARGETDIR=s390
 140         ;;
 141
 142   sh-*-* | sh[[34]]*-*-*)
 143         TARGET=SH; TARGETDIR=sh
 144         ;;
 145   sh64-*-* | sh5*-*-*)
 146         TARGET=SH64; TARGETDIR=sh64
 147         ;;
 148
 149   sparc*-*-*)
 150         TARGET=SPARC; TARGETDIR=sparc
 151         ;;
 152
 153   x86_64-*-darwin*)
 154         TARGET=X86_DARWIN; TARGETDIR=x86
 155         ;;
 156
 157   x86_64-*-cygwin* | x86_64-*-mingw*)
 158         TARGET=X86_WIN64; TARGETDIR=x86
 159         ;;
 160
 161   x86_64-*-*)
 162         TARGET=X86_64; TARGETDIR=x86
 163         ;;
 164 esac
 165
 166 AC_SUBST(AM_RUNTESTFLAGS)
 167 AC_SUBST(AM_LTLDFLAGS)
 168
 169 if test $TARGETDIR = unknown; then
 170   AC_MSG_ERROR(["libffi has not been ported to $host."])
 171 fi
 172
 173 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 174 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 175 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 176 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 177 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 178 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 179 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 180 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 181 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 182 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 183 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 184 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 185 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 186 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 187 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 188 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 189 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 190 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 191 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 192 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 193 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 194 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 195 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 196 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 197 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 198 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 199
 200 AC_HEADER_STDC
 201 AC_CHECK_FUNCS(memcpy)
 202 AC_FUNC_ALLOCA
 203
 204 AC_CHECK_SIZEOF(double)
 205 AC_CHECK_SIZEOF(long double)
 206
 207 # Also AC_SUBST this variable for ffi.h.
 208 if test -z "$HAVE_LONG_DOUBLE"; then
 209   HAVE_LONG_DOUBLE=0
 210   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 211     if test $ac_cv_sizeof_long_double != 0; then
 212       HAVE_LONG_DOUBLE=1
 213       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 214     fi
 215   fi
 216 fi
 217 AC_SUBST(HAVE_LONG_DOUBLE)
 218
 219 AC_C_BIGENDIAN
 220
 221 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 222     libffi_cv_as_cfi_pseudo_op, [
 223     libffi_cv_as_cfi_pseudo_op=unknown
 224     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 225                    [libffi_cv_as_cfi_pseudo_op=yes],
 226                    [libffi_cv_as_cfi_pseudo_op=no])
 227 ])
 228 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 229     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 230               [Define if your assembler supports .cfi_* directives.])
 231 fi
 232
 233 if test x$TARGET = xSPARC; then
 234     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 235         libffi_cv_as_sparc_ua_pcrel, [
 236         save_CFLAGS="$CFLAGS"
 237         save_LDFLAGS="$LDFLAGS"
 238         CFLAGS="$CFLAGS -fpic"
 239         LDFLAGS="$LDFLAGS -shared"
 240         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 241                     [libffi_cv_as_sparc_ua_pcrel=yes],
 242                     [libffi_cv_as_sparc_ua_pcrel=no])
 243         CFLAGS="$save_CFLAGS"
 244         LDFLAGS="$save_LDFLAGS"])
 245     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 246         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 247                   [Define if your assembler and linker support unaligned PC relative relocs.])
 248     fi
 249
 250     AC_CACHE_CHECK([assembler .register pseudo-op support],
 251        libffi_cv_as_register_pseudo_op, [
 252        libffi_cv_as_register_pseudo_op=unknown
 253        # Check if we have .register
 254        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 255                        [libffi_cv_as_register_pseudo_op=yes],
 256                        [libffi_cv_as_register_pseudo_op=no])
 257     ])
 258     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 259        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 260                [Define if your assembler supports .register.])
 261     fi
 262 fi
 263
 264 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 265     AC_CACHE_CHECK([assembler supports pc related relocs],
 266         libffi_cv_as_x86_pcrel, [
 267         libffi_cv_as_x86_pcrel=yes
 268         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 269         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 270             libffi_cv_as_x86_pcrel=no
 271         fi
 272         ])
 273     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 274         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 275                   [Define if your assembler supports PC relative relocs.])
 276     fi
 277 fi
 278
 279 case "$target" in
 280      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 281        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 282                  [Cannot use malloc on this target, so, we revert to
 283                    alternative means])
 284      ;;
 285 esac
 286
 287 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 288     libffi_cv_ro_eh_frame, [
 289         libffi_cv_ro_eh_frame=no
 290         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 291         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 292             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 293                 libffi_cv_ro_eh_frame=yes
 294             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 295                  | grep -v '#write' > /dev/null; then
 296                 libffi_cv_ro_eh_frame=yes
 297             fi
 298         fi
 299         rm -f conftest.*
 300     ])
 301 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 302     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 303               [Define if .eh_frame sections should be read-only.])
 304     AC_DEFINE(EH_FRAME_FLAGS, "a",
 305               [Define to the flags needed for the .section .eh_frame directive.])
 306 else
 307     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 308               [Define to the flags needed for the .section .eh_frame directive.])
 309 fi
 310
 311 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 312     libffi_cv_hidden_visibility_attribute, [
 313         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 314         libffi_cv_hidden_visibility_attribute=no
 315         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 316             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 317                 libffi_cv_hidden_visibility_attribute=yes
 318             fi
 319         fi
 320         rm -f conftest.*
 321     ])
 322 if test $libffi_cv_hidden_visibility_attribute = yes; then
 323     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 324               [Define if __attribute__((visibility("hidden"))) is supported.])
 325 fi
 326
 327 AH_BOTTOM([
 328 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 329 #ifdef LIBFFI_ASM
 330 #define FFI_HIDDEN(name) .hidden name
 331 #else
 332 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 333 #endif
 334 #else
 335 #ifdef LIBFFI_ASM
 336 #define FFI_HIDDEN(name)
 337 #else
 338 #define FFI_HIDDEN
 339 #endif
 340 #endif
 341 ])
 342
 343 AC_SUBST(TARGET)
 344 AC_SUBST(TARGETDIR)
 345
 346 AC_SUBST(SHELL)
 347
 348 AC_ARG_ENABLE(debug,
 349 [  --enable-debug          debugging mode],
 350   if test "$enable_debug" = "yes"; then
 351     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 352   fi)
 353
 354 AC_ARG_ENABLE(structs,
 355 [  --disable-structs       omit code for struct support],
 356   if test "$enable_structs" = "no"; then
 357     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 358   fi)
 359
 360 AC_ARG_ENABLE(raw-api,
 361 [  --disable-raw-api       make the raw api unavailable],
 362   if test "$enable_raw_api" = "no"; then
 363     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 364   fi)
 365
 366 AC_ARG_ENABLE(purify-safety,
 367 [  --enable-purify-safety  purify-safe mode],
 368   if test "$enable_purify_safety" = "yes"; then
 369     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 370   fi)
 371
 372 if test -n "$with_cross_host" &&
 373    test x"$with_cross_host" != x"no"; then
 374   toolexecdir='$(exec_prefix)/$(target_alias)'
 375   toolexeclibdir='$(toolexecdir)/lib'
 376 else
 377   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 378   toolexeclibdir='$(libdir)'
 379 fi
 380 multi_os_directory=`$CC -print-multi-os-directory`
 381 case $multi_os_directory in
 382   .) ;; # Avoid trailing /.
 383   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 384 esac
 385 AC_SUBST(toolexecdir)
 386 AC_SUBST(toolexeclibdir)
 387
 388 if test "${multilib}" = "yes"; then
 389   multilib_arg="--enable-multilib"
 390 else
 391   multilib_arg=
 392 fi
 393
 394 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 395 AC_CONFIG_COMMANDS(src, [
 396 test -d src || mkdir src
 397 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 398 ], [TARGETDIR="$TARGETDIR"])
 399
 400 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 401
 402 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile)
 403
 404 AC_OUTPUT