libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   amd64-*-freebsd*)
  55         TARGET=X86_64; TARGETDIR=x86
  56         ;;
  57
  58   cris-*-*)
  59         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  60         ;;
  61
  62   frv-*-*)
  63         TARGET=FRV; TARGETDIR=frv
  64         ;;
  65
  66   hppa*-*-linux*)
  67         TARGET=PA_LINUX; TARGETDIR=pa
  68         ;;
  69   hppa*64-*-hpux*)
  70         TARGET=PA64_HPUX; TARGETDIR=pa
  71         ;;
  72   hppa*-*-hpux*)
  73         TARGET=PA_HPUX; TARGETDIR=pa
  74         ;;
  75
  76   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  77         TARGET=X86_WIN32; TARGETDIR=x86
  78         ;;
  79   i?86-*-darwin*)
  80         TARGET=X86_DARWIN; TARGETDIR=x86
  81         ;;
  82   i?86-*-solaris2.1[[0-9]]*)
  83         TARGET=X86_64; TARGETDIR=x86
  84         ;;
  85   i?86-*-*)
  86         TARGET=X86; TARGETDIR=x86
  87         ;;
  88
  89   ia64*-*-*)
  90         TARGET=IA64; TARGETDIR=ia64
  91         ;;
  92
  93   m32r*-*-*)
  94         TARGET=M32R; TARGETDIR=m32r
  95         ;;
  96
  97   m68k-*-*)
  98         TARGET=M68K; TARGETDIR=m68k
  99         ;;
 100
 101   mips-sgi-irix5.* | mips-sgi-irix6.*)
 102         TARGET=MIPS; TARGETDIR=mips
 103         ;;
 104   mips*-*-linux*)
 105         TARGET=MIPS; TARGETDIR=mips
 106         ;;
 107
 108   powerpc*-*-linux*)
 109         TARGET=POWERPC; TARGETDIR=powerpc
 110         ;;
 111   powerpc-*-darwin*)
 112         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 113         ;;
 114   powerpc-*-aix* | rs6000-*-aix*)
 115         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 116         ;;
 117   powerpc-*-freebsd*)
 118         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 119         ;;
 120   powerpc*-*-rtems*)
 121         TARGET=POWERPC; TARGETDIR=powerpc
 122         ;;
 123
 124   s390-*-* | s390x-*-*)
 125         TARGET=S390; TARGETDIR=s390
 126         ;;
 127
 128   sh-*-* | sh[[34]]*-*-*)
 129         TARGET=SH; TARGETDIR=sh
 130         ;;
 131   sh64-*-* | sh5*-*-*)
 132         TARGET=SH64; TARGETDIR=sh64
 133         ;;
 134
 135   sparc*-*-*)
 136         TARGET=SPARC; TARGETDIR=sparc
 137         ;;
 138
 139   x86_64-*-darwin*)
 140         TARGET=X86_DARWIN; TARGETDIR=x86
 141         ;;
 142   x86_64-*-cygwin* | x86_64-*-mingw*)
 143         ;;
 144   x86_64-*-*)
 145         TARGET=X86_64; TARGETDIR=x86
 146         ;;
 147 esac
 148
 149 AC_SUBST(AM_RUNTESTFLAGS)
 150
 151 if test $TARGETDIR = unknown; then
 152   AC_MSG_ERROR(["libffi has not been ported to $host."])
 153 fi
 154
 155 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 156 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 157 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 158 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 159 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 160 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 161 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 162 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 163 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 164 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 165 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 166 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 167 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 168 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 169 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 170 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 171 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 172 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 173 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 174 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 175 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 176 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 177 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 178
 179 AC_HEADER_STDC
 180 AC_CHECK_FUNCS(memcpy)
 181 AC_FUNC_ALLOCA
 182
 183 AC_CHECK_SIZEOF(double)
 184 AC_CHECK_SIZEOF(long double)
 185
 186 # Also AC_SUBST this variable for ffi.h.
 187 if test -z "$HAVE_LONG_DOUBLE"; then
 188   HAVE_LONG_DOUBLE=0
 189   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 190     if test $ac_cv_sizeof_long_double != 0; then
 191       HAVE_LONG_DOUBLE=1
 192       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 193     fi
 194   fi
 195 fi
 196 AC_SUBST(HAVE_LONG_DOUBLE)
 197
 198 AC_C_BIGENDIAN
 199
 200 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 201     libffi_cv_as_cfi_pseudo_op, [
 202     libffi_cv_as_cfi_pseudo_op=unknown
 203     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 204                    [libffi_cv_as_cfi_pseudo_op=yes],
 205                    [libffi_cv_as_cfi_pseudo_op=no])
 206 ])
 207 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 208     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 209               [Define if your assembler supports .cfi_* directives.])
 210 fi
 211
 212 if test x$TARGET = xSPARC; then
 213     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 214         libffi_cv_as_sparc_ua_pcrel, [
 215         save_CFLAGS="$CFLAGS"
 216         save_LDFLAGS="$LDFLAGS"
 217         CFLAGS="$CFLAGS -fpic"
 218         LDFLAGS="$LDFLAGS -shared"
 219         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 220                     [libffi_cv_as_sparc_ua_pcrel=yes],
 221                     [libffi_cv_as_sparc_ua_pcrel=no])
 222         CFLAGS="$save_CFLAGS"
 223         LDFLAGS="$save_LDFLAGS"])
 224     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 225         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 226                   [Define if your assembler and linker support unaligned PC relative relocs.])
 227     fi
 228
 229     AC_CACHE_CHECK([assembler .register pseudo-op support],
 230        libffi_cv_as_register_pseudo_op, [
 231        libffi_cv_as_register_pseudo_op=unknown
 232        # Check if we have .register
 233        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 234                        [libffi_cv_as_register_pseudo_op=yes],
 235                        [libffi_cv_as_register_pseudo_op=no])
 236     ])
 237     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 238        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 239                [Define if your assembler supports .register.])
 240     fi
 241 fi
 242
 243 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 244     libffi_cv_ro_eh_frame, [
 245         libffi_cv_ro_eh_frame=no
 246         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 247         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 248             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 249                 libffi_cv_ro_eh_frame=yes
 250             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 251                  | grep -v '#write' > /dev/null; then
 252                 libffi_cv_ro_eh_frame=yes
 253             fi
 254         fi
 255         rm -f conftest.*
 256     ])
 257 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 258     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 259               [Define if .eh_frame sections should be read-only.])
 260     AC_DEFINE(EH_FRAME_FLAGS, "a",
 261               [Define to the flags needed for the .section .eh_frame directive.])
 262 else
 263     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 264               [Define to the flags needed for the .section .eh_frame directive.])
 265 fi
 266
 267 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 268     libffi_cv_hidden_visibility_attribute, [
 269         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 270         libffi_cv_hidden_visibility_attribute=no
 271         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 272             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 273                 libffi_cv_hidden_visibility_attribute=yes
 274             fi
 275         fi
 276         rm -f conftest.*
 277     ])
 278 if test $libffi_cv_hidden_visibility_attribute = yes; then
 279     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 280               [Define if __attribute__((visibility("hidden"))) is supported.])
 281 fi
 282
 283 AH_BOTTOM([
 284 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 285 #ifdef LIBFFI_ASM
 286 #define FFI_HIDDEN(name) .hidden name
 287 #else
 288 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 289 #endif
 290 #else
 291 #ifdef LIBFFI_ASM
 292 #define FFI_HIDDEN(name)
 293 #else
 294 #define FFI_HIDDEN
 295 #endif
 296 #endif
 297 ])
 298
 299 AC_SUBST(TARGET)
 300 AC_SUBST(TARGETDIR)
 301
 302 AC_SUBST(SHELL)
 303
 304 AC_ARG_ENABLE(debug,
 305 [  --enable-debug          debugging mode],
 306   if test "$enable_debug" = "yes"; then
 307     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 308   fi)
 309
 310 AC_ARG_ENABLE(structs,
 311 [  --disable-structs       omit code for struct support],
 312   if test "$enable_structs" = "no"; then
 313     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 314   fi)
 315
 316 AC_ARG_ENABLE(raw-api,
 317 [  --disable-raw-api       make the raw api unavailable],
 318   if test "$enable_raw_api" = "no"; then
 319     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 320   fi)
 321
 322 AC_ARG_ENABLE(purify-safety,
 323 [  --enable-purify-safety  purify-safe mode],
 324   if test "$enable_purify_safety" = "yes"; then
 325     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 326   fi)
 327
 328 if test -n "$with_cross_host" &&
 329    test x"$with_cross_host" != x"no"; then
 330   toolexecdir='$(exec_prefix)/$(target_alias)'
 331   toolexeclibdir='$(toolexecdir)/lib'
 332 else
 333   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 334   toolexeclibdir='$(libdir)'
 335 fi
 336 multi_os_directory=`$CC -print-multi-os-directory`
 337 case $multi_os_directory in
 338   .) ;; # Avoid trailing /.
 339   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 340 esac
 341 AC_SUBST(toolexecdir)
 342 AC_SUBST(toolexeclibdir)
 343
 344 if test "${multilib}" = "yes"; then
 345   multilib_arg="--enable-multilib"
 346 else
 347   multilib_arg=
 348 fi
 349
 350 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 351 AC_CONFIG_COMMANDS(src, [
 352 test -d src || mkdir src
 353 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 354 ], [TARGETDIR="$TARGETDIR"])
 355
 356 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 357
 358 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 359
 360 AC_OUTPUT