libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   cris-*-*)
  55         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  56         ;;
  57
  58   frv-*-*)
  59         TARGET=FRV; TARGETDIR=frv
  60         ;;
  61
  62   hppa*-*-linux* | parisc*-*-linux*)
  63         TARGET=PA_LINUX; TARGETDIR=pa
  64         ;;
  65   hppa*64-*-hpux*)
  66         TARGET=PA64_HPUX; TARGETDIR=pa
  67         ;;
  68   hppa*-*-hpux*)
  69         TARGET=PA_HPUX; TARGETDIR=pa
  70         ;;
  71
  72   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  73         TARGET=X86_WIN32; TARGETDIR=x86
  74         ;;
  75   i?86-*-darwin*)
  76         TARGET=X86_DARWIN; TARGETDIR=x86
  77         ;;
  78   i?86-*-*)
  79         TARGET=X86; TARGETDIR=x86
  80         ;;
  81
  82   ia64*-*-*)
  83         TARGET=IA64; TARGETDIR=ia64
  84         ;;
  85
  86   m32r*-*-*)
  87         TARGET=M32R; TARGETDIR=m32r
  88         ;;
  89
  90   m68k-*-*)
  91         TARGET=M68K; TARGETDIR=m68k
  92         ;;
  93
  94   mips64*-*)
  95         ;;
  96   mips-sgi-irix5.* | mips-sgi-irix6.*)
  97         TARGET=MIPS_IRIX; TARGETDIR=mips
  98         ;;
  99   mips*-*-linux*)
 100         TARGET=MIPS_LINUX; TARGETDIR=mips
 101         ;;
 102
 103   powerpc*-*-linux* | powerpc-*-sysv*)
 104         TARGET=POWERPC; TARGETDIR=powerpc
 105         ;;
 106   powerpc-*-beos*)
 107         TARGET=POWERPC; TARGETDIR=powerpc
 108         ;;
 109   powerpc-*-darwin*)
 110         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 111         ;;
 112   powerpc-*-aix* | rs6000-*-aix*)
 113         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 114         ;;
 115   powerpc-*-freebsd*)
 116         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 117         ;;
 118   powerpc*-*-rtems*)
 119         TARGET=POWERPC; TARGETDIR=powerpc
 120         ;;
 121
 122   s390-*-* | s390x-*-*)
 123         TARGET=S390; TARGETDIR=s390
 124         ;;
 125
 126   sh-*-* | sh[[34]]*-*-*)
 127         TARGET=SH; TARGETDIR=sh
 128         ;;
 129   sh64-*-* | sh5*-*-*)
 130         TARGET=SH64; TARGETDIR=sh64
 131         ;;
 132
 133   sparc*-*-*)
 134         TARGET=SPARC; TARGETDIR=sparc
 135         ;;
 136
 137   x86_64-*-darwin*)
 138         TARGET=X86_DARWIN; TARGETDIR=x86
 139         ;;
 140   x86_64-*-cygwin* | x86_64-*-mingw*)
 141         ;;
 142   x86_64-*-*)
 143         TARGET=X86_64; TARGETDIR=x86
 144         ;;
 145 esac
 146
 147 AC_SUBST(AM_RUNTESTFLAGS)
 148
 149 if test $TARGETDIR = unknown; then
 150   AC_MSG_ERROR(["libffi has not been ported to $host."])
 151 fi
 152
 153 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
 154 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
 155 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 156 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 157 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 158 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 159 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 160 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 161 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 162 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 163 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 164 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 165 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 166 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 167 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 168 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 169 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 170 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 171 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 172 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 173 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 174 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 175 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 176 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 177
 178 case x$TARGET in
 179   xMIPS*) TARGET=MIPS ;;
 180   *) ;;
 181 esac
 182
 183 AC_HEADER_STDC
 184 AC_CHECK_FUNCS(memcpy)
 185 AC_FUNC_ALLOCA
 186
 187 AC_CHECK_SIZEOF(double)
 188 AC_CHECK_SIZEOF(long double)
 189
 190 # Also AC_SUBST this variable for ffi.h.
 191 if test -z "$HAVE_LONG_DOUBLE"; then
 192   HAVE_LONG_DOUBLE=0
 193   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 194     if test $ac_cv_sizeof_long_double != 0; then
 195       HAVE_LONG_DOUBLE=1
 196       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 197     fi
 198   fi
 199 fi
 200 AC_SUBST(HAVE_LONG_DOUBLE)
 201
 202 AC_C_BIGENDIAN
 203
 204 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 205     libffi_cv_as_cfi_pseudo_op, [
 206     libffi_cv_as_cfi_pseudo_op=unknown
 207     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 208                    [libffi_cv_as_cfi_pseudo_op=yes],
 209                    [libffi_cv_as_cfi_pseudo_op=no])
 210 ])
 211 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 212     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 213               [Define if your assembler supports .cfi_* directives.])
 214 fi
 215
 216 if test x$TARGET = xSPARC; then
 217     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 218         libffi_cv_as_sparc_ua_pcrel, [
 219         save_CFLAGS="$CFLAGS"
 220         save_LDFLAGS="$LDFLAGS"
 221         CFLAGS="$CFLAGS -fpic"
 222         LDFLAGS="$LDFLAGS -shared"
 223         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 224                     [libffi_cv_as_sparc_ua_pcrel=yes],
 225                     [libffi_cv_as_sparc_ua_pcrel=no])
 226         CFLAGS="$save_CFLAGS"
 227         LDFLAGS="$save_LDFLAGS"])
 228     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 229         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 230                   [Define if your assembler and linker support unaligned PC relative relocs.])
 231     fi
 232
 233     AC_CACHE_CHECK([assembler .register pseudo-op support],
 234        libffi_cv_as_register_pseudo_op, [
 235        libffi_cv_as_register_pseudo_op=unknown
 236        # Check if we have .register
 237        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 238                        [libffi_cv_as_register_pseudo_op=yes],
 239                        [libffi_cv_as_register_pseudo_op=no])
 240     ])
 241     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 242        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 243                [Define if your assembler supports .register.])
 244     fi
 245 fi
 246
 247 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 248     libffi_cv_ro_eh_frame, [
 249         libffi_cv_ro_eh_frame=no
 250         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 251         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 252             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 253                 libffi_cv_ro_eh_frame=yes
 254             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 255                  | grep -v '#write' > /dev/null; then
 256                 libffi_cv_ro_eh_frame=yes
 257             fi
 258         fi
 259         rm -f conftest.*
 260     ])
 261 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 262     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 263               [Define if .eh_frame sections should be read-only.])
 264     AC_DEFINE(EH_FRAME_FLAGS, "a",
 265               [Define to the flags needed for the .section .eh_frame directive.])
 266 else
 267     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 268               [Define to the flags needed for the .section .eh_frame directive.])
 269 fi
 270
 271 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 272     libffi_cv_hidden_visibility_attribute, [
 273         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 274         libffi_cv_hidden_visibility_attribute=no
 275         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 276             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 277                 libffi_cv_hidden_visibility_attribute=yes
 278             fi
 279         fi
 280         rm -f conftest.*
 281     ])
 282 if test $libffi_cv_hidden_visibility_attribute = yes; then
 283     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 284               [Define if __attribute__((visibility("hidden"))) is supported.])
 285 fi
 286
 287 AH_BOTTOM([
 288 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 289 #ifdef LIBFFI_ASM
 290 #define FFI_HIDDEN(name) .hidden name
 291 #else
 292 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 293 #endif
 294 #else
 295 #ifdef LIBFFI_ASM
 296 #define FFI_HIDDEN(name)
 297 #else
 298 #define FFI_HIDDEN
 299 #endif
 300 #endif
 301 ])
 302
 303 AC_SUBST(TARGET)
 304 AC_SUBST(TARGETDIR)
 305
 306 AC_SUBST(SHELL)
 307
 308 AC_ARG_ENABLE(debug,
 309 [  --enable-debug          debugging mode],
 310   if test "$enable_debug" = "yes"; then
 311     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 312   fi)
 313
 314 AC_ARG_ENABLE(structs,
 315 [  --disable-structs       omit code for struct support],
 316   if test "$enable_structs" = "no"; then
 317     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 318   fi)
 319
 320 AC_ARG_ENABLE(raw-api,
 321 [  --disable-raw-api       make the raw api unavailable],
 322   if test "$enable_raw_api" = "no"; then
 323     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 324   fi)
 325
 326 AC_ARG_ENABLE(purify-safety,
 327 [  --enable-purify-safety  purify-safe mode],
 328   if test "$enable_purify_safety" = "yes"; then
 329     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 330   fi)
 331
 332 if test -n "$with_cross_host" &&
 333    test x"$with_cross_host" != x"no"; then
 334   toolexecdir='$(exec_prefix)/$(target_alias)'
 335   toolexeclibdir='$(toolexecdir)/lib'
 336 else
 337   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 338   toolexeclibdir='$(libdir)'
 339 fi
 340 multi_os_directory=`$CC -print-multi-os-directory`
 341 case $multi_os_directory in
 342   .) ;; # Avoid trailing /.
 343   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 344 esac
 345 AC_SUBST(toolexecdir)
 346 AC_SUBST(toolexeclibdir)
 347
 348 if test "${multilib}" = "yes"; then
 349   multilib_arg="--enable-multilib"
 350 else
 351   multilib_arg=
 352 fi
 353
 354 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 355 AC_CONFIG_COMMANDS(src, [
 356 test -d src || mkdir src
 357 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 358 ], [TARGETDIR="$TARGETDIR"])
 359
 360 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 361
 362 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 363
 364 AC_OUTPUT