libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44   alpha*-*-*)
  45         TARGET=ALPHA; TARGETDIR=alpha;
  46         # Support 128-bit long double, changable via command-line switch.
  47         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  48         ;;
  49
  50   arm*-*-*)
  51         TARGET=ARM; TARGETDIR=arm
  52         ;;
  53
  54   cris-*-*)
  55         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  56         ;;
  57
  58   frv-*-*)
  59         TARGET=FRV; TARGETDIR=frv
  60         ;;
  61
  62   hppa*-*-linux* | parisc*-*-linux*)
  63         TARGET=PA_LINUX; TARGETDIR=pa
  64         ;;
  65   hppa*64-*-hpux*)
  66         TARGET=PA64_HPUX; TARGETDIR=pa
  67         ;;
  68   hppa*-*-hpux*)
  69         TARGET=PA_HPUX; TARGETDIR=pa
  70         ;;
  71
  72   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  73         TARGET=X86_WIN32; TARGETDIR=x86
  74         ;;
  75   i?86-*-darwin*)
  76         TARGET=X86_DARWIN; TARGETDIR=x86
  77         ;;
  78   i?86-*-solaris2.1[[0-9]]*)
  79         TARGET=X86_64; TARGETDIR=x86
  80         ;;
  81   i?86-*-*)
  82         TARGET=X86; TARGETDIR=x86
  83         ;;
  84
  85   ia64*-*-*)
  86         TARGET=IA64; TARGETDIR=ia64
  87         ;;
  88
  89   m32r*-*-*)
  90         TARGET=M32R; TARGETDIR=m32r
  91         ;;
  92
  93   m68k-*-*)
  94         TARGET=M68K; TARGETDIR=m68k
  95         ;;
  96
  97   mips-sgi-irix5.* | mips-sgi-irix6.*)
  98         TARGET=MIPS; TARGETDIR=mips
  99         ;;
 100   mips*-*-linux*)
 101         TARGET=MIPS; TARGETDIR=mips
 102         ;;
 103
 104   powerpc*-*-linux* | powerpc-*-sysv*)
 105         TARGET=POWERPC; TARGETDIR=powerpc
 106         ;;
 107   powerpc-*-beos*)
 108         TARGET=POWERPC; TARGETDIR=powerpc
 109         ;;
 110   powerpc-*-darwin*)
 111         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 112         ;;
 113   powerpc-*-aix* | rs6000-*-aix*)
 114         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 115         ;;
 116   powerpc-*-freebsd*)
 117         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 118         ;;
 119   powerpc*-*-rtems*)
 120         TARGET=POWERPC; TARGETDIR=powerpc
 121         ;;
 122
 123   s390-*-* | s390x-*-*)
 124         TARGET=S390; TARGETDIR=s390
 125         ;;
 126
 127   sh-*-* | sh[[34]]*-*-*)
 128         TARGET=SH; TARGETDIR=sh
 129         ;;
 130   sh64-*-* | sh5*-*-*)
 131         TARGET=SH64; TARGETDIR=sh64
 132         ;;
 133
 134   sparc*-*-*)
 135         TARGET=SPARC; TARGETDIR=sparc
 136         ;;
 137
 138   x86_64-*-darwin*)
 139         TARGET=X86_DARWIN; TARGETDIR=x86
 140         ;;
 141   x86_64-*-cygwin* | x86_64-*-mingw*)
 142         ;;
 143   x86_64-*-*)
 144         TARGET=X86_64; TARGETDIR=x86
 145         ;;
 146 esac
 147
 148 AC_SUBST(AM_RUNTESTFLAGS)
 149
 150 if test $TARGETDIR = unknown; then
 151   AC_MSG_ERROR(["libffi has not been ported to $host."])
 152 fi
 153
 154 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 155 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 156 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 157 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 158 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 159 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 160 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 161 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 162 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 163 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 164 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 165 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 166 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 167 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 168 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 169 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 170 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 171 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 172 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 173 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 174 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 175 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 176 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 177
 178 AC_HEADER_STDC
 179 AC_CHECK_FUNCS(memcpy)
 180 AC_FUNC_ALLOCA
 181
 182 AC_CHECK_SIZEOF(double)
 183 AC_CHECK_SIZEOF(long double)
 184
 185 # Also AC_SUBST this variable for ffi.h.
 186 if test -z "$HAVE_LONG_DOUBLE"; then
 187   HAVE_LONG_DOUBLE=0
 188   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 189     if test $ac_cv_sizeof_long_double != 0; then
 190       HAVE_LONG_DOUBLE=1
 191       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 192     fi
 193   fi
 194 fi
 195 AC_SUBST(HAVE_LONG_DOUBLE)
 196
 197 AC_C_BIGENDIAN
 198
 199 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 200     libffi_cv_as_cfi_pseudo_op, [
 201     libffi_cv_as_cfi_pseudo_op=unknown
 202     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 203                    [libffi_cv_as_cfi_pseudo_op=yes],
 204                    [libffi_cv_as_cfi_pseudo_op=no])
 205 ])
 206 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 207     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 208               [Define if your assembler supports .cfi_* directives.])
 209 fi
 210
 211 if test x$TARGET = xSPARC; then
 212     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 213         libffi_cv_as_sparc_ua_pcrel, [
 214         save_CFLAGS="$CFLAGS"
 215         save_LDFLAGS="$LDFLAGS"
 216         CFLAGS="$CFLAGS -fpic"
 217         LDFLAGS="$LDFLAGS -shared"
 218         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 219                     [libffi_cv_as_sparc_ua_pcrel=yes],
 220                     [libffi_cv_as_sparc_ua_pcrel=no])
 221         CFLAGS="$save_CFLAGS"
 222         LDFLAGS="$save_LDFLAGS"])
 223     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 224         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 225                   [Define if your assembler and linker support unaligned PC relative relocs.])
 226     fi
 227
 228     AC_CACHE_CHECK([assembler .register pseudo-op support],
 229        libffi_cv_as_register_pseudo_op, [
 230        libffi_cv_as_register_pseudo_op=unknown
 231        # Check if we have .register
 232        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 233                        [libffi_cv_as_register_pseudo_op=yes],
 234                        [libffi_cv_as_register_pseudo_op=no])
 235     ])
 236     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 237        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 238                [Define if your assembler supports .register.])
 239     fi
 240 fi
 241
 242 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 243     libffi_cv_ro_eh_frame, [
 244         libffi_cv_ro_eh_frame=no
 245         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 246         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 247             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 248                 libffi_cv_ro_eh_frame=yes
 249             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 250                  | grep -v '#write' > /dev/null; then
 251                 libffi_cv_ro_eh_frame=yes
 252             fi
 253         fi
 254         rm -f conftest.*
 255     ])
 256 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 257     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 258               [Define if .eh_frame sections should be read-only.])
 259     AC_DEFINE(EH_FRAME_FLAGS, "a",
 260               [Define to the flags needed for the .section .eh_frame directive.])
 261 else
 262     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 263               [Define to the flags needed for the .section .eh_frame directive.])
 264 fi
 265
 266 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 267     libffi_cv_hidden_visibility_attribute, [
 268         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 269         libffi_cv_hidden_visibility_attribute=no
 270         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 271             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 272                 libffi_cv_hidden_visibility_attribute=yes
 273             fi
 274         fi
 275         rm -f conftest.*
 276     ])
 277 if test $libffi_cv_hidden_visibility_attribute = yes; then
 278     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 279               [Define if __attribute__((visibility("hidden"))) is supported.])
 280 fi
 281
 282 AH_BOTTOM([
 283 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 284 #ifdef LIBFFI_ASM
 285 #define FFI_HIDDEN(name) .hidden name
 286 #else
 287 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 288 #endif
 289 #else
 290 #ifdef LIBFFI_ASM
 291 #define FFI_HIDDEN(name)
 292 #else
 293 #define FFI_HIDDEN
 294 #endif
 295 #endif
 296 ])
 297
 298 AC_SUBST(TARGET)
 299 AC_SUBST(TARGETDIR)
 300
 301 AC_SUBST(SHELL)
 302
 303 AC_ARG_ENABLE(debug,
 304 [  --enable-debug          debugging mode],
 305   if test "$enable_debug" = "yes"; then
 306     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 307   fi)
 308
 309 AC_ARG_ENABLE(structs,
 310 [  --disable-structs       omit code for struct support],
 311   if test "$enable_structs" = "no"; then
 312     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 313   fi)
 314
 315 AC_ARG_ENABLE(raw-api,
 316 [  --disable-raw-api       make the raw api unavailable],
 317   if test "$enable_raw_api" = "no"; then
 318     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 319   fi)
 320
 321 AC_ARG_ENABLE(purify-safety,
 322 [  --enable-purify-safety  purify-safe mode],
 323   if test "$enable_purify_safety" = "yes"; then
 324     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 325   fi)
 326
 327 if test -n "$with_cross_host" &&
 328    test x"$with_cross_host" != x"no"; then
 329   toolexecdir='$(exec_prefix)/$(target_alias)'
 330   toolexeclibdir='$(toolexecdir)/lib'
 331 else
 332   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 333   toolexeclibdir='$(libdir)'
 334 fi
 335 multi_os_directory=`$CC -print-multi-os-directory`
 336 case $multi_os_directory in
 337   .) ;; # Avoid trailing /.
 338   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 339 esac
 340 AC_SUBST(toolexecdir)
 341 AC_SUBST(toolexeclibdir)
 342
 343 if test "${multilib}" = "yes"; then
 344   multilib_arg="--enable-multilib"
 345 else
 346   multilib_arg=
 347 fi
 348
 349 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 350 AC_CONFIG_COMMANDS(src, [
 351 test -d src || mkdir src
 352 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 353 ], [TARGETDIR="$TARGETDIR"])
 354
 355 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 356
 357 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 358
 359 AC_OUTPUT