libf2c/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999, 2002 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.13)
  23 AC_INIT(libF77/Version.c)
  24
  25 # This works around the fact that libtool configuration may change LD
  26 # for this particular configuration, but some shells, instead of
  27 # keeping the changes in LD private, export them just because LD is
  28 # exported.
  29 ORIGINAL_LD_FOR_MULTILIBS=$LD
  30
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$target}
  33 AC_SUBST(target_alias)
  34
  35 GLIBCPP_CONFIGURE(.)
  36 GLIBCPP_EXPORT_INSTALL_INFO
  37
  38 # If the language specific compiler does not exist, but the "gcc" directory
  39 # does, we do not build anything. Note, $r is set by the top-level Makefile.
  40 # Note that when we look for the compiler, we search both with and without
  41 # extension to handle cross and canadian cross builds.
  42 compiler_name=f771
  43 rm -f skip-this-dir
  44 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  45 AC_CACHE_VAL(g77_cv_compiler_exists,
  46 [g77_cv_compiler_exists=yes
  47 if test -n "$r"; then
  48   if test -d "$r"/gcc; then
  49     if test -f "$r"/gcc/$compiler_name \
  50        || test -f "$r"/gcc/$compiler_name.exe; then
  51       true
  52     else
  53       g77_cv_compiler_exists=no
  54       echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  55     fi
  56   fi
  57 fi
  58 ])
  59 AC_MSG_RESULT($g77_cv_compiler_exists)
  60 if test x$g77_cv_compiler_exists = xno
  61 then
  62   rm -f Makefile conftest* confdefs* core
  63   exit 0
  64 fi
  65
  66 dnl Checks for programs.
  67
  68 AM_PROG_LIBTOOL
  69
  70 dnl These should be inherited in the recursive make, but ensure they are
  71 dnl defined:
  72 test "$AR" || AR=ar
  73 AC_SUBST(AR)
  74 if test "$RANLIB"; then :
  75   AC_SUBST(RANLIB)
  76 else
  77   AC_PROG_RANLIB
  78 fi
  79 AC_PROG_INSTALL
  80 AC_PROG_MAKE_SET
  81
  82 dnl Checks for header files.
  83 # Sanity check for the cross-compilation case:
  84 AC_CHECK_HEADER(stdio.h,:,
  85   [AC_MSG_ERROR([Can't find stdio.h.
  86 You must have a usable C system for the target already installed, at least
  87 including headers and, preferably, the library, before you can configure
  88 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  89 then the target library, then build with \`LANGUAGES=f77'.])])
  90
  91 dnl Checks for g77 integer types built into gcc's C front end.
  92 AC_MSG_CHECKING(for built-in g77 integer types)
  93 AC_CACHE_VAL(libf2c_cv_has_g77_builtin_types,
  94 [AC_TRY_COMPILE(,
  95   [__g77_integer g77i;
  96 __g77_uinteger g77ui;
  97 __g77_longint g77l;
  98 __g77_ulongint g77ul;],
  99   libf2c_cv_has_g77_builtin_types=yes,
 100   libf2c_cv_has_g77_builtin_types=no)])
 101 AC_MSG_RESULT($libf2c_cv_has_g77_builtin_types)
 102 if test $libf2c_cv_has_g77_builtin_types = no; then
 103   AC_MSG_ERROR([gcc doesn't define all of the built in types __g77_integer,
 104 __g77_uinteger, __g77_longint, and __g77_ulongint.  You may not be using
 105 a new enough version of gcc, or your target may not have type sizes which
 106 accommodate those types.])
 107 fi
 108
 109 # avoid confusion in case the `makefile's from the f2c distribution have
 110 # got put here
 111 test -f libF77/makefile && mv libF77/makefile  libF77/makefile.ori
 112 test -f libI77/makefile && mv libI77/makefile  libI77/makefile.ori
 113 test -f libU77/makefile && mv libU77/makefile  libU77/makefile.ori
 114
 115 AC_CONFIG_SUBDIRS(libU77 libI77 libF77)
 116 # Do Makefile first since g2c.h depends on it and shouldn't get an
 117 # earlier timestamp.  Of course, it does when the multilib gunk below
 118 # edits Makefile, sigh; see additional touch below.
 119 AC_OUTPUT(Makefile g2c.h:g2c.hin,
 120  [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 121 if test -n "$CONFIG_FILES"; then
 122   LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 123   if test -n "${with_target_subdir}"; then
 124     # FIXME: We shouldn't need to set ac_file
 125     ac_file=Makefile
 126     . ${toplevel_srcdir}/config-ml.in
 127     touch g2c.h   # to keep it more recent than Makefile
 128   fi
 129 fi],
 130 srcdir=${srcdir}
 131 host=${host}
 132 target=${target}
 133 with_target_subdir=${with_target_subdir}
 134 with_multisubdir=${with_multisubdir}
 135 ac_configure_args="--enable-multilib ${ac_configure_args}"
 136 toplevel_srcdir=${toplevel_srcdir}
 137 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 138 )
 139
 140
 141 dnl Local Variables:
 142 dnl comment-start: "dnl "
 143 dnl comment-end: ""
 144 dnl comment-start-skip: "\\bdnl\\b\\s *"
 145 dnl End: