libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CONFIG_MACRO_DIR(../config)
   8 AC_CANONICAL_SYSTEM
   9
  10 # Checks for programs.
  11 AC_PROG_MAKE_SET
  12 AC_PROG_INSTALL
  13 AC_PROG_CC
  14 AC_PROG_RANLIB
  15
  16 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  17 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  18 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  19 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  20
  21 # Figure out what compiler warnings we can enable.
  22 # See config/warnings.m4 for details.
  23
  24 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  25                           -Wmissing-prototypes -Wold-style-definition \
  26                           -Wmissing-format-attribute])
  27 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  28
  29 # Only enable with --enable-werror-always until existing warnings are
  30 # corrected.
  31 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  32
  33 # Dependency checking.
  34 ZW_CREATE_DEPDIR
  35 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  36
  37 # Checks for header files.
  38 AC_HEADER_TIME
  39 ACX_HEADER_STRING
  40 AC_CHECK_HEADERS(iconv.h locale.h fcntl.h limits.h stddef.h \
  41         stdlib.h strings.h string.h sys/file.h unistd.h)
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_CONST
  45 AC_C_INLINE
  46 AC_FUNC_OBSTACK
  47 AC_TYPE_OFF_T
  48 AC_TYPE_SIZE_T
  49 AC_CHECK_TYPE(ssize_t, int)
  50 AC_STRUCT_TM
  51 AC_CHECK_SIZEOF(int)
  52 AC_CHECK_SIZEOF(long)
  53 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  54   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  55   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  56   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  57   putchar_unlocked putc_unlocked)
  58 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  59 AC_CHECK_DECLS(m4_split(m4_normalize(abort asprintf basename errno getopt \
  60   libcpp_UNLOCKED_FUNCS vasprintf)))
  61
  62 # Checks for library functions.
  63 AC_FUNC_ALLOCA
  64 AC_HEADER_STDC
  65 AC_SYS_LARGEFILE
  66 AM_LANGINFO_CODESET
  67 ZW_GNU_GETTEXT_SISTER_DIR
  68
  69 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  70 [AC_TRY_COMPILE([
  71 #include <sys/types.h>
  72 ],
  73 [if ((uchar *)0) return 0;
  74  if (sizeof(uchar)) return 0;],
  75 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
  76 if test $ac_cv_type_uchar = yes; then
  77   AC_DEFINE(HAVE_UCHAR, 1,
  78   [Define if <sys/types.h> defines \`uchar'.])
  79 fi
  80
  81 AM_ICONV
  82
  83 # More defines and substitutions.
  84 PACKAGE="$PACKAGE_TARNAME"
  85 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
  86 AC_SUBST(PACKAGE)
  87
  88 if test "x$enable_nls" != xno; then
  89   USED_CATALOGS='$(CATALOGS)'
  90 else
  91   USED_CATALOGS=
  92 fi
  93 AC_SUBST(USED_CATALOGS)
  94
  95 AC_ARG_ENABLE(maintainer-mode,
  96 [  --enable-maintainer-mode enable rules only needed by maintainers],,
  97 enable_maintainer_mode=no)
  98
  99 if test "x$enable_maintainer_mode" = xno; then
 100   MAINT='#'
 101 else
 102   MAINT=
 103 fi
 104 AC_SUBST(MAINT)
 105
 106 AC_ARG_ENABLE(checking,
 107 [  --enable-checking      enable expensive run-time checks],,
 108 enable_checking=no)
 109
 110 if test $enable_checking != no ; then
 111   AC_DEFINE(ENABLE_CHECKING, 1,
 112 [Define if you want more run-time sanity checks.])
 113 fi
 114
 115 m4_changequote(,)
 116 case $target in
 117         alpha*-*-* | \
 118         arm*-*-*eabi* | \
 119         arm*-*-symbianelf* | \
 120         x86_64-*-* | \
 121         ia64-*-* | \
 122         hppa*64*-*-* | \
 123         i[34567]86-*-darwin* | \
 124         i[34567]86-*-solaris2.1[0-9]* | \
 125         mips*-*-* | \
 126         mmix-*-* | \
 127         powerpc*-*-* | \
 128         rs6000*-*-* | \
 129         s390*-*-* | \
 130         sparc*-*-* | \
 131         spu-*-* | \
 132         sh[123456789lbe]*-*-* | sh-*-*)
 133                 need_64bit_hwint=yes ;;
 134         i[34567]86-*-linux*)
 135                 if test "x$enable_targets" = xall; then
 136                         need_64bit_hwint=yes
 137                 else
 138                         need_64bit_hwint=no
 139                 fi
 140                 ;;
 141         *)
 142                 need_64bit_hwint=no ;;
 143 esac
 144
 145 case $need_64bit_hwint:$ac_cv_sizeof_long in
 146         *:8 | no:*) host_wide_int=long ;;
 147         *) host_wide_int='long long' ;;
 148 esac
 149 m4_changequote([,])
 150
 151 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
 152 [Define to the widest efficient host integer type at least
 153    as wide as the target's size_t type.])
 154
 155 # Output.
 156
 157 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 158 AC_CONFIG_FILES(Makefile)
 159 AC_OUTPUT