gcc/testsuite/lib/target-supports.exp

   1 #   Copyright (C) 1999, 2001, 2003, 2004 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # gcc-patches@gcc.gnu.org
  19
  20 # This file defines procs for determining features supported by the target.
  21
  22 # Try to compile some code and return the messages printed by the compiler.
  23 #
  24 # BASENAME is a basename to use for temporary files.
  25 # TYPE is the type of compilation to perform (see target_compile).
  26 # CONTENTS gives the contents of the input file.
  27 proc get_compiler_messages {basename type contents} {
  28     global tool
  29
  30     set src ${basename}[pid].c
  31     switch $type {
  32         assembly { set output ${basename}[pid].s }
  33         object { set output ${basename}[pid].o }
  34     }
  35     set f [open $src "w"]
  36     puts $f $contents
  37     close $f
  38     set lines [${tool}_target_compile $src $output $type ""]
  39     file delete $src
  40     remote_file build delete $output
  41
  42     return $lines
  43 }
  44
  45 ###############################
  46 # proc check_weak_available { }
  47 ###############################
  48
  49 # weak symbols are only supported in some configs/object formats
  50 # this proc returns 1 if they're supported, 0 if they're not, or -1 if unsure
  51
  52 proc check_weak_available { } {
  53     global target_triplet
  54     global target_cpu
  55
  56     # All mips targets should support it
  57
  58     if { [ string first "mips" $target_cpu ] >= 0 } {
  59         return 1
  60     }
  61
  62     # All solaris2 targets should support it
  63
  64     if { [regexp ".*-solaris2.*" $target_triplet] } {
  65         return 1
  66     }
  67
  68     # DEC OSF/1/Digital UNIX/Tru64 UNIX supports it
  69
  70     if { [regexp "alpha.*osf.*" $target_triplet] } {
  71         return 1
  72     }
  73
  74     # Windows targets Cygwin and MingW32 support it
  75
  76     if { [regexp ".*mingw32|.*cygwin" $target_triplet] } {
  77         return 1
  78     }
  79
  80     # ELF and ECOFF support it. a.out does with gas/gld but may also with
  81     # other linkers, so we should try it
  82
  83     set objformat [gcc_target_object_format]
  84
  85     switch $objformat {
  86         elf      { return 1 }
  87         ecoff    { return 1 }
  88         a.out    { return 1 }
  89         mach-o   { return 1 }
  90         unknown  { return -1 }
  91         default  { return 0 }
  92     }
  93 }
  94
  95 ###############################
  96 # proc check_visibility_available { }
  97 ###############################
  98
  99 # The visibility attribute is only support in some object formats
 100 # This proc returns 1 if it is supported, 0 if not, -1 if unsure.
 101
 102 proc check_visibility_available { } {
 103     global target_triplet
 104     global target_cpu
 105
 106     # On NetWare, support makes no sense.
 107
 108     if { [string match "*-*-netware*" $target_triplet] } {
 109         return 0
 110     }
 111
 112     # ELF supports it if the system has recent GNU ld and gas.
 113     # As a start we return 1 for all ELF systems; we'll let people
 114     # add exceptions as necessary.
 115
 116     set objformat [gcc_target_object_format]
 117
 118     switch $objformat {
 119         elf      { return 1 }
 120         mach-o   { return 1 }
 121         unknown  { return -1 }
 122         default  { return 0 }
 123     }
 124 }
 125
 126 ###############################
 127 # proc check_alias_available { }
 128 ###############################
 129
 130 # Determine if the target toolchain supports the alias attribute.
 131
 132 # Returns 2 if the target supports aliases.  Returns 1 if the target
 133 # only supports weak aliased.  Returns 0 if the target does not
 134 # support aliases at all.  Returns -1 if support for aliases could not
 135 # be determined.
 136
 137 proc check_alias_available { } {
 138     global alias_available_saved
 139     global tool
 140
 141     if [info exists alias_available_saved] {
 142         verbose "check_alias_available  returning saved $alias_available_saved" 2
 143     } else {
 144         set src alias[pid].c
 145         set obj alias[pid].o
 146         verbose "check_alias_available  compiling testfile $src" 2
 147         set f [open $src "w"]
 148         # Compile a small test program.  The definition of "g" is
 149         # necessary to keep the Solaris assembler from complaining
 150         # about the program.
 151         puts $f "#ifdef __cplusplus\nextern \"C\"\n#endif\n"
 152         puts $f "void g() {} void f() __attribute__((alias(\"g\")));"
 153         close $f
 154         set lines [${tool}_target_compile $src $obj object ""]
 155         file delete $src
 156         remote_file build delete $obj
 157
 158         if [string match "" $lines] then {
 159             # No error messages, everything is OK.
 160             set alias_available_saved 2
 161         } else {
 162             if [regexp "alias definitions not supported" $lines] {
 163                 verbose "check_alias_available  target does not support aliases" 2
 164
 165                 set objformat [gcc_target_object_format]
 166
 167                 if { $objformat == "elf" } {
 168                     verbose "check_alias_available  but target uses ELF format, so it ought to" 2
 169                     set alias_available_saved -1
 170                 } else {
 171                     set alias_available_saved 0
 172                 }
 173             } else {
 174                 if [regexp "only weak aliases are supported" $lines] {
 175                 verbose "check_alias_available  target supports only weak aliases" 2
 176                 set alias_available_saved 1
 177                 } else {
 178                     set alias_available_saved -1
 179                 }
 180             }
 181         }
 182
 183         verbose "check_alias_available  returning $alias_available_saved" 2
 184     }
 185
 186     return $alias_available_saved
 187 }
 188
 189 # Returns true if --gc-sections is supported on the target.
 190
 191 proc check_gc_sections_available { } {
 192     global gc_sections_available_saved
 193     global tool
 194
 195     if {![info exists gc_sections_available_saved]} {
 196         # Check if the ld used by gcc supports --gc-sections.
 197         set gcc_spec [${tool}_target_compile "-dumpspecs" "" "none" ""]
 198         regsub ".*\n\*linker:\[ \t\]*\n(\[^ \t\n\]*).*" "$gcc_spec" {\1} linker
 199         set gcc_ld [lindex [${tool}_target_compile "-print-prog-name=$linker" "" "none" ""] 0]
 200         set ld_output [remote_exec host "$gcc_ld" "--help"]
 201         if { [ string first "--gc-sections" $ld_output ] >= 0 } {
 202             set gc_sections_available_saved 1
 203         } else {
 204             set gc_sections_available_saved 0
 205         }
 206     }
 207     return $gc_sections_available_saved
 208 }
 209
 210 # Return true if profiling is supported on the target.
 211
 212 proc check_profiling_available { test_what } {
 213     global profiling_available_saved
 214
 215     verbose "Profiling argument is <$test_what>" 1
 216
 217     # These conditions depend on the argument so examine them before
 218     # looking at the cache variable.
 219
 220     # Support for -p on solaris2 relies on mcrt1.o which comes with the
 221     # vendor compiler.  We cannot reliably predict the directory where the
 222     # vendor compiler (and thus mcrt1.o) is installed so we can't
 223     # necessarily find mcrt1.o even if we have it.
 224     if { [istarget *-*-solaris2*] && [lindex $test_what 1] == "-p" } {
 225         return 0
 226     }
 227
 228     # Support for -p on irix relies on libprof1.a which doesn't appear to
 229     # exist on any irix6 system currently posting testsuite results.
 230     # Support for -pg on irix relies on gcrt1.o which doesn't exist yet.
 231     # See: http://gcc.gnu.org/ml/gcc/2002-10/msg00169.html
 232     if { [istarget mips*-*-irix*]
 233     && ([lindex $test_what 1] == "-p" || [lindex $test_what 1] == "-pg") } {
 234         return 0
 235     }
 236
 237     # Now examine the cache variable.
 238     if {![info exists profiling_available_saved]} {
 239         # Some targets don't have any implementation of __bb_init_func or are
 240         # missing other needed machinery.
 241         if { [istarget mmix-*-*]
 242              || [istarget arm*-*-eabi*]
 243              || [istarget arm*-*-elf]
 244              || [istarget arm*-*-symbianelf*]
 245              || [istarget powerpc-*-eabi*]
 246              || [istarget strongarm*-*-elf]
 247              || [istarget xscale*-*-elf]
 248              || [istarget cris-*-*]
 249              || [istarget h8300-*-*]
 250              || [istarget mips*-*-elf]
 251              || [istarget *-*-windiss] } {
 252             set profiling_available_saved 0
 253         } else {
 254             set profiling_available_saved 1
 255         }
 256     }
 257
 258     return $profiling_available_saved
 259 }
 260
 261 # Return true if iconv is supported on the target. In particular IBM-1047.
 262
 263 proc check_iconv_available { test_what } {
 264     global tool
 265     global libiconv
 266
 267     set result ""
 268
 269     set src iconv[pid].c
 270     set exe iconv[pid].x
 271     verbose "check_iconv_available compiling testfile $src" 2
 272     set f [open $src "w"]
 273     # Compile a small test program.
 274     puts $f "#include <iconv.h>\n"
 275     puts $f "int main (void)\n {\n iconv_t cd; \n"
 276     puts $f "cd = iconv_open (\"[lindex $test_what 1]\", \"UTF-8\");\n"
 277     puts $f "if (cd == (iconv_t) -1)\n return 1;\n"
 278     puts $f "return 0;\n}"
 279     close $f
 280
 281     set lines [${tool}_target_compile $src $exe executable "libs=$libiconv" ]
 282     file delete $src
 283
 284     if [string match "" $lines] then {
 285         # No error messages, everything is OK.
 286
 287         set result [${tool}_load "./$exe" "" ""]
 288         set status [lindex $result 0];
 289         remote_file build delete $exe
 290
 291         verbose "check_iconv_available status is <$status>" 2
 292
 293         if { $status == "pass" } then {
 294             return 1
 295         }
 296     }
 297
 298     return 0
 299 }
 300
 301 # Return true if named sections are supported on this target.
 302 # This proc does not cache results, because the answer may vary
 303 # when cycling over subtarget options (e.g. irix o32/n32/n64) in
 304 # the same test run.
 305 proc check_named_sections_available { } {
 306     verbose "check_named_sections_available: compiling source" 2
 307     set answer [string match "" [get_compiler_messages named object {
 308         int __attribute__ ((section("whatever"))) foo;
 309     }]]
 310     verbose "check_named_sections_available: returning $answer" 2
 311     return $answer
 312 }
 313
 314 # Return 1 if the target supports executing AltiVec instructions, 0
 315 # otherwise.  Cache the result.
 316
 317 proc check_vmx_hw_available { } {
 318     global vmx_hw_available_saved
 319     global tool
 320
 321     if [info exists vmx_hw_available_saved] {
 322         verbose "check_hw_available  returning saved $vmx_hw_available_saved" 2
 323     } else {
 324         set vmx_hw_available_saved 0
 325
 326         # Some simulators are known to not support VMX instructions.
 327         if { [istarget powerpc-*-eabi] || [istarget powerpc*-*-eabispe] } {
 328             verbose "check_hw_available  returning 0" 2
 329             return $vmx_hw_available_saved
 330         }
 331
 332         # Set up, compile, and execute a test program containing VMX
 333         # instructions.  Include the current process ID in the file
 334         # names to prevent conflicts with invocations for multiple
 335         # testsuites.
 336         set src vmx[pid].c
 337         set exe vmx[pid].x
 338
 339         set f [open $src "w"]
 340         puts $f "int main() {"
 341         puts $f "#ifdef __MACH__"
 342         puts $f "  asm volatile (\"vor v0,v0,v0\");"
 343         puts $f "#else"
 344         puts $f "  asm volatile (\"vor 0,0,0\");"
 345         puts $f "#endif"
 346         puts $f "  return 0; }"
 347         close $f
 348
 349         verbose "check_vmx_hw_available  compiling testfile $src" 2
 350         set lines [${tool}_target_compile $src $exe executable ""]
 351         file delete $src
 352
 353         if [string match "" $lines] then {
 354             # No error message, compilation succeeded.
 355             set result [${tool}_load "./$exe" "" ""]
 356             set status [lindex $result 0]
 357             remote_file build delete $exe
 358             verbose "check_vmx_hw_available testfile status is <$status>" 2
 359
 360             if { $status == "pass" } then {
 361                 set vmx_hw_available_saved 1
 362             }
 363         } else {
 364             verbose "check_vmx_hw_availalble testfile compilation failed" 2
 365         }
 366     }
 367
 368     return $vmx_hw_available_saved
 369 }
 370
 371 # Return 1 if we're generating 32-bit code using default options, 0
 372 # otherwise.
 373
 374 proc check_effective_target_ilp32 { } {
 375     verbose "check_effective_target_ilp32: compiling source" 2
 376     set answer [string match "" [get_compiler_messages ilp32 object {
 377         int dummy[(sizeof (int) == 4 && sizeof (void *) == 4 && sizeof (long) == 4 ) ? 1 : -1];
 378     }]]
 379     verbose "check_effective_target_ilp32: returning $answer" 2
 380     return $answer
 381 }
 382
 383 # Return 1 if we're generating 64-bit code using default options, 0
 384 # otherwise.
 385
 386 proc check_effective_target_lp64 { } {
 387     verbose "check_effective_target_lp64: compiling source" 2
 388     set answer [string match "" [get_compiler_messages lp64 object {
 389         int dummy[(sizeof (int) == 4 && sizeof (void *) == 8 && sizeof (long) == 8 ) ? 1 : -1];
 390     }]]
 391     verbose "check_effective_target_lp64: returning $answer" 2
 392     return $answer
 393 }
 394
 395 # Return 1 if the target matches the effective target 'arg', 0 otherwise.
 396 # This can be used with any check_* proc that takes no argument and
 397 # returns only 1 or 0.  It could be used with check_* procs that take
 398 # arguments with keywords that pass particular arguments.
 399
 400 proc is-effective-target { arg } {
 401     set selected 0
 402     switch $arg {
 403         "ilp32"  { set selected [check_effective_target_ilp32] }
 404         "lp64"   { set selected [check_effective_target_lp64] }
 405         "vmx_hw" { set selected [check_vmx_hw_available] }
 406         "named_sections" { set selected [check_named_sections_available] }
 407         "gc_sections" { set selected [check_gc_sections_available] }
 408         default  { error "unknown effective target selector `$arg'" }
 409     }
 410     verbose "is-effective-target: $arg $selected" 2
 411     return $selected
 412 }