gcc/optc-gen.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 #
  25 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  26 #            [-v header_name=header.h] < inputfile > options.c
  27
  28 BEGIN {
  29         n_opts = 0
  30         n_langs = 0
  31         n_target_save = 0
  32         quote = "\042"
  33         comma = ","
  34         FS=SUBSEP
  35         # Default the name of header created from opth-gen.awk to options.h
  36         if (header_name == "") header_name="options.h"
  37 }
  38
  39 # Collect the text and flags of each option into an array
  40         {
  41                 if ($1 == "Language") {
  42                         langs[n_langs] = $2
  43                         n_langs++;
  44                 }
  45                 else if ($1 == "TargetSave") {
  46                         # Make sure the declarations are put in source order
  47                         target_save_decl[n_target_save] = $2
  48                         n_target_save++
  49                 }
  50                 else {
  51                         name = opt_args("Mask", $1)
  52                         if (name == "") {
  53                                 opts[n_opts]  = $1
  54                                 flags[n_opts] = $2
  55                                 help[n_opts]  = $3
  56                                 for (i = 4; i <= NF; i++)
  57                                         help[n_opts] = help[n_opts] " " $i
  58                                 n_opts++;
  59                         }
  60                 }
  61         }
  62
  63 # Dump that array of options into a C file.
  64 END {
  65 print "/* This file is auto-generated by optc-gen.awk.  */"
  66 print ""
  67 n_headers = split(header_name, headers, " ")
  68 for (i = 1; i <= n_headers; i++)
  69         print "#include " quote headers[i] quote
  70 print "#include " quote "opts.h" quote
  71 print "#include " quote "intl.h" quote
  72 print ""
  73 print "#ifdef GCC_DRIVER"
  74 print "int target_flags;"
  75 print "#else"
  76 print "#include " quote "flags.h" quote
  77 print "#include " quote "target.h" quote
  78 print "#endif /* GCC_DRIVER */"
  79 print ""
  80
  81 have_save = 0;
  82 for (i = 0; i < n_opts; i++) {
  83         if (flag_set_p("Save", flags[i]))
  84                 have_save = 1;
  85
  86         name = var_name(flags[i]);
  87         if (name == "")
  88                 continue;
  89
  90         if (flag_set_p("VarExists", flags[i])) {
  91                 # Need it for the gcc driver.
  92                 if (name in var_seen)
  93                         continue;
  94                 init = ""
  95                 gcc_driver = 1
  96         }
  97         else {
  98                 init = opt_args("Init", flags[i])
  99                 if (init != "")
 100                         init = " = " init;
 101                 else if (name in var_seen)
 102                         continue;
 103                 gcc_driver = 0
 104         }
 105
 106         if (gcc_driver == 1)
 107                 print "#ifdef GCC_DRIVER"
 108         print "/* Set by -" opts[i] "."
 109         print "   " help[i] "  */"
 110         print var_type(flags[i]) name init ";"
 111         if (gcc_driver == 1)
 112                 print "#endif /* GCC_DRIVER */"
 113         print ""
 114
 115         var_seen[name] = 1;
 116 }
 117
 118 print ""
 119 print "/* Local state variables.  */"
 120 for (i = 0; i < n_opts; i++) {
 121         name = static_var(opts[i], flags[i]);
 122         if (name != "")
 123                 print "static " var_type(flags[i]) name ";"
 124 }
 125 print ""
 126
 127 print "const char * const lang_names[] =\n{"
 128 for (i = 0; i < n_langs; i++) {
 129         macros[i] = "CL_" langs[i]
 130         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
 131         s = substr("         ", length (macros[i]))
 132         print "  " quote langs[i] quote ","
 133     }
 134
 135 print "  0\n};\n"
 136 print "const unsigned int cl_options_count = N_OPTS;\n"
 137 print "const unsigned int cl_lang_count = " n_langs ";\n"
 138
 139 print "const struct cl_option cl_options[] =\n{"
 140
 141 j = 0
 142 for (i = 0; i < n_opts; i++) {
 143         back_chain[i] = "N_OPTS";
 144         indices[opts[i]] = j;
 145         # Combine the flags of identical switches.  Switches
 146         # appear many times if they are handled by many front
 147         # ends, for example.
 148         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 149                 flags[i + 1] = flags[i] " " flags[i + 1];
 150                 if (help[i + 1] == "")
 151                         help[i + 1] = help[i]
 152                 else if (help[i] != "" && help[i + 1] != help[i])
 153                         print "warning: multiple different help strings for " \
 154                                 opts[i] ":\n\t" help[i] "\n\t" help[i + 1] \
 155                                 | "cat 1>&2"
 156                 i++;
 157                 back_chain[i] = "N_OPTS";
 158                 indices[opts[i]] = j;
 159         }
 160         j++;
 161 }
 162
 163 for (i = 0; i < n_opts; i++) {
 164         # With identical flags, pick only the last one.  The
 165         # earlier loop ensured that it has all flags merged,
 166         # and a nonempty help text if one of the texts was nonempty.
 167         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 168                 i++;
 169         }
 170
 171         len = length (opts[i]);
 172         enum = "OPT_" opts[i]
 173         if (opts[i] == "finline-limit=" || opts[i] == "Wlarger-than=" \
 174             || opts[i] == "ftemplate-depth=")
 175                 enum = enum "eq"
 176         gsub ("[^A-Za-z0-9]", "_", enum)
 177
 178         # If this switch takes joined arguments, back-chain all
 179         # subsequent switches to it for which it is a prefix.  If
 180         # a later switch S is a longer prefix of a switch T, T
 181         # will be back-chained to S in a later iteration of this
 182         # for() loop, which is what we want.
 183         if (flag_set_p("Joined.*", flags[i])) {
 184                 for (j = i + 1; j < n_opts; j++) {
 185                         if (substr (opts[j], 1, len) != opts[i])
 186                                 break;
 187                         back_chain[j] = enum;
 188                 }
 189         }
 190
 191         s = substr("                                  ", length (opts[i]))
 192         if (i + 1 == n_opts)
 193                 comma = ""
 194
 195         if (help[i] == "")
 196                 hlp = "0"
 197         else
 198                 hlp = quote help[i] quote;
 199
 200         neg = opt_args("Negative", flags[i]);
 201         if (neg != "")
 202                 idx = indices[neg]
 203         else {
 204                 if (flag_set_p("RejectNegative", flags[i]))
 205                         idx = -1;
 206                 else {
 207                         if (opts[i] ~ "^[Wfm]")
 208                                 idx = indices[opts[i]];
 209                         else
 210                                 idx = -1;
 211                 }
 212         }
 213         # Split the printf after %u to work around an ia64-hp-hpux11.23
 214         # awk bug.
 215         printf("  { %c-%s%c,\n    %s,\n    %s, %u,",
 216                quote, opts[i], quote, hlp, back_chain[i], len)
 217         printf(" %d,\n", idx)
 218         condition = opt_args("Condition", flags[i])
 219         cl_flags = switch_flags(flags[i])
 220         if (condition != "")
 221                 printf("#if %s\n" \
 222                        "    %s,\n" \
 223                        "#else\n" \
 224                        "    CL_DISABLED,\n" \
 225                        "#endif\n",
 226                        condition, cl_flags, cl_flags)
 227         else
 228                 printf("    %s,\n", cl_flags)
 229         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 230                var_set(flags[i]), comma)
 231 }
 232
 233 print "};"
 234
 235 print "";
 236 print "#if !defined(GCC_DRIVER) && !defined(IN_LIBGCC2) && !defined(IN_TARGET_LIBS)"
 237 print "";
 238 print "/* Save optimization variables into a structure.  */"
 239 print "void";
 240 print "cl_optimization_save (struct cl_optimization *ptr)";
 241 print "{";
 242
 243 n_opt_char = 2;
 244 n_opt_short = 0;
 245 n_opt_int = 0;
 246 n_opt_other = 0;
 247 var_opt_char[0] = "optimize";
 248 var_opt_char[1] = "optimize_size";
 249 var_opt_range["optimize"] = "0, 255";
 250 var_opt_range["optimize_size"] = "0, 255";
 251
 252 # Sort by size to mimic how the structure is laid out to be friendlier to the
 253 # cache.
 254
 255 for (i = 0; i < n_opts; i++) {
 256         if (flag_set_p("Optimization", flags[i])) {
 257                 name = var_name(flags[i])
 258                 if(name == "")
 259                         continue;
 260
 261                 if(name in var_opt_seen)
 262                         continue;
 263
 264                 var_opt_seen[name]++;
 265                 otype = var_type_struct(flags[i]);
 266                 if (otype ~ "^((un)?signed +)?int *$")
 267                         var_opt_int[n_opt_int++] = name;
 268
 269                 else if (otype ~ "^((un)?signed +)?short *$")
 270                         var_opt_short[n_opt_short++] = name;
 271
 272                 else if (otype ~ "^((un)?signed +)?char *$") {
 273                         var_opt_char[n_opt_char++] = name;
 274                         if (otype ~ "^unsigned +char *$")
 275                                 var_opt_range[name] = "0, 255"
 276                         else if (otype ~ "^signed +char *$")
 277                                 var_opt_range[name] = "-128, 127"
 278                 }
 279                 else
 280                         var_opt_other[n_opt_other++] = name;
 281         }
 282 }
 283
 284 for (i = 0; i < n_opt_char; i++) {
 285         name = var_opt_char[i];
 286         if (var_opt_range[name] != "")
 287                 print "  gcc_assert (IN_RANGE (" name ", " var_opt_range[name] "));";
 288 }
 289
 290 print "";
 291 for (i = 0; i < n_opt_other; i++) {
 292         print "  ptr->" var_opt_other[i] " = " var_opt_other[i] ";";
 293 }
 294
 295 for (i = 0; i < n_opt_int; i++) {
 296         print "  ptr->" var_opt_int[i] " = " var_opt_int[i] ";";
 297 }
 298
 299 for (i = 0; i < n_opt_short; i++) {
 300         print "  ptr->" var_opt_short[i] " = " var_opt_short[i] ";";
 301 }
 302
 303 for (i = 0; i < n_opt_char; i++) {
 304         print "  ptr->" var_opt_char[i] " = " var_opt_char[i] ";";
 305 }
 306
 307 print "}";
 308
 309 print "";
 310 print "/* Restore optimization options from a structure.  */";
 311 print "void";
 312 print "cl_optimization_restore (struct cl_optimization *ptr)";
 313 print "{";
 314
 315 for (i = 0; i < n_opt_other; i++) {
 316         print "  " var_opt_other[i] " = ptr->" var_opt_other[i] ";";
 317 }
 318
 319 for (i = 0; i < n_opt_int; i++) {
 320         print "  " var_opt_int[i] " = ptr->" var_opt_int[i] ";";
 321 }
 322
 323 for (i = 0; i < n_opt_short; i++) {
 324         print "  " var_opt_short[i] " = ptr->" var_opt_short[i] ";";
 325 }
 326
 327 for (i = 0; i < n_opt_char; i++) {
 328         print "  " var_opt_char[i] " = ptr->" var_opt_char[i] ";";
 329 }
 330
 331 print "  targetm.override_options_after_change ();";
 332 print "}";
 333
 334 print "";
 335 print "/* Print optimization options from a structure.  */";
 336 print "void";
 337 print "cl_optimization_print (FILE *file,";
 338 print "                       int indent_to,";
 339 print "                       struct cl_optimization *ptr)";
 340 print "{";
 341
 342 print "  fputs (\"\\n\", file);";
 343 for (i = 0; i < n_opt_other; i++) {
 344         print "  if (ptr->" var_opt_other[i] ")";
 345         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 346         print "             indent_to, \"\",";
 347         print "             \"" var_opt_other[i] "\",";
 348         print "             (unsigned long)ptr->" var_opt_other[i] ");";
 349         print "";
 350 }
 351
 352 for (i = 0; i < n_opt_int; i++) {
 353         print "  if (ptr->" var_opt_int[i] ")";
 354         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 355         print "             indent_to, \"\",";
 356         print "             \"" var_opt_int[i] "\",";
 357         print "             ptr->" var_opt_int[i] ");";
 358         print "";
 359 }
 360
 361 for (i = 0; i < n_opt_short; i++) {
 362         print "  if (ptr->" var_opt_short[i] ")";
 363         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 364         print "             indent_to, \"\",";
 365         print "             \"" var_opt_short[i] "\",";
 366         print "             ptr->" var_opt_short[i] ");";
 367         print "";
 368 }
 369
 370 for (i = 0; i < n_opt_char; i++) {
 371         print "  if (ptr->" var_opt_char[i] ")";
 372         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 373         print "             indent_to, \"\",";
 374         print "             \"" var_opt_char[i] "\",";
 375         print "             ptr->" var_opt_char[i] ");";
 376         print "";
 377 }
 378
 379 print "}";
 380
 381 print "";
 382 print "/* Save selected option variables into a structure.  */"
 383 print "void";
 384 print "cl_target_option_save (struct cl_target_option *ptr)";
 385 print "{";
 386
 387 n_target_char = 0;
 388 n_target_short = 0;
 389 n_target_int = 0;
 390 n_target_other = 0;
 391
 392 if (have_save) {
 393         for (i = 0; i < n_opts; i++) {
 394                 if (flag_set_p("Save", flags[i])) {
 395                         name = var_name(flags[i])
 396                         if(name == "")
 397                                 name = "target_flags";
 398
 399                         if(name in var_save_seen)
 400                                 continue;
 401
 402                         var_save_seen[name]++;
 403                         otype = var_type_struct(flags[i])
 404                         if (otype ~ "^((un)?signed +)?int *$")
 405                                 var_target_int[n_target_int++] = name;
 406
 407                         else if (otype ~ "^((un)?signed +)?short *$")
 408                                 var_target_short[n_target_short++] = name;
 409
 410                         else if (otype ~ "^((un)?signed +)?char *$") {
 411                                 var_target_char[n_target_char++] = name;
 412                                 if (otype ~ "^unsigned +char *$")
 413                                         var_target_range[name] = "0, 255"
 414                                 else if (otype ~ "^signed +char *$")
 415                                         var_target_range[name] = "-128, 127"
 416                         }
 417                         else
 418                                 var_target_other[n_target_other++] = name;
 419                 }
 420         }
 421 } else {
 422         var_target_int[n_target_int++] = "target_flags";
 423 }
 424
 425 have_assert = 0;
 426 for (i = 0; i < n_target_char; i++) {
 427         name = var_target_char[i];
 428         if (var_target_range[name] != "") {
 429                 have_assert = 1;
 430                 print "  gcc_assert (IN_RANGE (" name ", " var_target_range[name] "));";
 431         }
 432 }
 433
 434 if (have_assert)
 435         print "";
 436
 437 print "  if (targetm.target_option.save)";
 438 print "    targetm.target_option.save (ptr);";
 439 print "";
 440
 441 for (i = 0; i < n_target_other; i++) {
 442         print "  ptr->" var_target_other[i] " = " var_target_other[i] ";";
 443 }
 444
 445 for (i = 0; i < n_target_int; i++) {
 446         print "  ptr->" var_target_int[i] " = " var_target_int[i] ";";
 447 }
 448
 449 for (i = 0; i < n_target_short; i++) {
 450         print "  ptr->" var_target_short[i] " = " var_target_short[i] ";";
 451 }
 452
 453 for (i = 0; i < n_target_char; i++) {
 454         print "  ptr->" var_target_char[i] " = " var_target_char[i] ";";
 455 }
 456
 457 print "}";
 458
 459 print "";
 460 print "/* Restore selected current options from a structure.  */";
 461 print "void";
 462 print "cl_target_option_restore (struct cl_target_option *ptr)";
 463 print "{";
 464
 465 for (i = 0; i < n_target_other; i++) {
 466         print "  " var_target_other[i] " = ptr->" var_target_other[i] ";";
 467 }
 468
 469 for (i = 0; i < n_target_int; i++) {
 470         print "  " var_target_int[i] " = ptr->" var_target_int[i] ";";
 471 }
 472
 473 for (i = 0; i < n_target_short; i++) {
 474         print "  " var_target_short[i] " = ptr->" var_target_short[i] ";";
 475 }
 476
 477 for (i = 0; i < n_target_char; i++) {
 478         print "  " var_target_char[i] " = ptr->" var_target_char[i] ";";
 479 }
 480
 481 # This must occur after the normal variables in case the code depends on those
 482 # variables.
 483 print "";
 484 print "  if (targetm.target_option.restore)";
 485 print "    targetm.target_option.restore (ptr);";
 486
 487 print "}";
 488
 489 print "";
 490 print "/* Print optimization options from a structure.  */";
 491 print "void";
 492 print "cl_target_option_print (FILE *file,";
 493 print "                        int indent,";
 494 print "                        struct cl_target_option *ptr)";
 495 print "{";
 496
 497 print "  fputs (\"\\n\", file);";
 498 for (i = 0; i < n_target_other; i++) {
 499         print "  if (ptr->" var_target_other[i] ")";
 500         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 501         print "             indent, \"\",";
 502         print "             \"" var_target_other[i] "\",";
 503         print "             (unsigned long)ptr->" var_target_other[i] ");";
 504         print "";
 505 }
 506
 507 for (i = 0; i < n_target_int; i++) {
 508         print "  if (ptr->" var_target_int[i] ")";
 509         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 510         print "             indent, \"\",";
 511         print "             \"" var_target_int[i] "\",";
 512         print "             ptr->" var_target_int[i] ");";
 513         print "";
 514 }
 515
 516 for (i = 0; i < n_target_short; i++) {
 517         print "  if (ptr->" var_target_short[i] ")";
 518         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 519         print "             indent, \"\",";
 520         print "             \"" var_target_short[i] "\",";
 521         print "             ptr->" var_target_short[i] ");";
 522         print "";
 523 }
 524
 525 for (i = 0; i < n_target_char; i++) {
 526         print "  if (ptr->" var_target_char[i] ")";
 527         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 528         print "             indent, \"\",";
 529         print "             \"" var_target_char[i] "\",";
 530         print "             ptr->" var_target_char[i] ");";
 531         print "";
 532 }
 533
 534 print "";
 535 print "  if (targetm.target_option.print)";
 536 print "    targetm.target_option.print (file, indent, ptr);";
 537
 538 print "}";
 539 print "#endif";
 540
 541 }