gcc/optc-gen.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 #
  25 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  26 #            [-v header_name=header.h] < inputfile > options.c
  27
  28 BEGIN {
  29         n_opts = 0
  30         n_langs = 0
  31         n_target_save = 0
  32         quote = "\042"
  33         comma = ","
  34         FS=SUBSEP
  35         # Default the name of header created from opth-gen.awk to options.h
  36         if (header_name == "") header_name="options.h"
  37 }
  38
  39 # Collect the text and flags of each option into an array
  40         {
  41                 if ($1 == "Language") {
  42                         langs[n_langs] = $2
  43                         n_langs++;
  44                 }
  45                 else if ($1 == "TargetSave") {
  46                         # Make sure the declarations are put in source order
  47                         target_save_decl[n_target_save] = $2
  48                         n_target_save++
  49                 }
  50                 else {
  51                         name = opt_args("Mask", $1)
  52                         if (name == "") {
  53                                 opts[n_opts]  = $1
  54                                 flags[n_opts] = $2
  55                                 help[n_opts]  = $3
  56                                 for (i = 4; i <= NF; i++)
  57                                         help[n_opts] = help[n_opts] " " $i
  58                                 n_opts++;
  59                         }
  60                 }
  61         }
  62
  63 # Dump that array of options into a C file.
  64 END {
  65 print "/* This file is auto-generated by optc-gen.awk.  */"
  66 print ""
  67 n_headers = split(header_name, headers, " ")
  68 for (i = 1; i <= n_headers; i++)
  69         print "#include " quote headers[i] quote
  70 print "#include " quote "opts.h" quote
  71 print "#include " quote "intl.h" quote
  72 print ""
  73 print "#ifdef GCC_DRIVER"
  74 print "int target_flags;"
  75 print "#else"
  76 print "#include " quote "flags.h" quote
  77 print "#include " quote "target.h" quote
  78 print "#endif /* GCC_DRIVER */"
  79 print ""
  80
  81 have_save = 0;
  82 for (i = 0; i < n_opts; i++) {
  83         if (flag_set_p("Save", flags[i]))
  84                 have_save = 1;
  85
  86         name = var_name(flags[i]);
  87         if (name == "")
  88                 continue;
  89
  90         if (flag_set_p("VarExists", flags[i])) {
  91                 # Need it for the gcc driver.
  92                 if (name in var_seen)
  93                         continue;
  94                 init = ""
  95                 gcc_driver = 1
  96         }
  97         else {
  98                 init = opt_args("Init", flags[i])
  99                 if (init != "")
 100                         init = " = " init;
 101                 else if (name in var_seen)
 102                         continue;
 103                 gcc_driver = 0
 104         }
 105
 106         if (gcc_driver == 1)
 107                 print "#ifdef GCC_DRIVER"
 108         print "/* Set by -" opts[i] "."
 109         print "   " help[i] "  */"
 110         print var_type(flags[i]) name init ";"
 111         if (gcc_driver == 1)
 112                 print "#endif /* GCC_DRIVER */"
 113         print ""
 114
 115         var_seen[name] = 1;
 116 }
 117
 118 print ""
 119 print "/* Local state variables.  */"
 120 for (i = 0; i < n_opts; i++) {
 121         name = static_var(opts[i], flags[i]);
 122         if (name != "")
 123                 print "static " var_type(flags[i]) name ";"
 124 }
 125 print ""
 126
 127 print "const char * const lang_names[] =\n{"
 128 for (i = 0; i < n_langs; i++) {
 129         macros[i] = "CL_" langs[i]
 130         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
 131         s = substr("         ", length (macros[i]))
 132         print "  " quote langs[i] quote ","
 133     }
 134
 135 print "  0\n};\n"
 136 print "const unsigned int cl_options_count = N_OPTS;\n"
 137 print "const unsigned int cl_lang_count = " n_langs ";\n"
 138
 139 print "const struct cl_option cl_options[] =\n{"
 140
 141 j = 0
 142 for (i = 0; i < n_opts; i++) {
 143         back_chain[i] = "N_OPTS";
 144         indices[opts[i]] = j;
 145         # Combine the flags of identical switches.  Switches
 146         # appear many times if they are handled by many front
 147         # ends, for example.
 148         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 149                 flags[i + 1] = flags[i] " " flags[i + 1];
 150                 if (help[i + 1] == "")
 151                         help[i + 1] = help[i]
 152                 else if (help[i] != "" && help[i + 1] != help[i])
 153                         print "warning: multiple different help strings for " \
 154                                 opts[i] ":\n\t" help[i] "\n\t" help[i + 1] \
 155                                 | "cat 1>&2"
 156                 i++;
 157                 back_chain[i] = "N_OPTS";
 158                 indices[opts[i]] = j;
 159         }
 160         j++;
 161 }
 162
 163 for (i = 0; i < n_opts; i++) {
 164         # With identical flags, pick only the last one.  The
 165         # earlier loop ensured that it has all flags merged,
 166         # and a nonempty help text if one of the texts was nonempty.
 167         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 168                 i++;
 169         }
 170
 171         len = length (opts[i]);
 172         enum = "OPT_" opts[i]
 173         if (opts[i] == "finline-limit=" || opts[i] == "Wlarger-than=")
 174                 enum = enum "eq"
 175         gsub ("[^A-Za-z0-9]", "_", enum)
 176
 177         # If this switch takes joined arguments, back-chain all
 178         # subsequent switches to it for which it is a prefix.  If
 179         # a later switch S is a longer prefix of a switch T, T
 180         # will be back-chained to S in a later iteration of this
 181         # for() loop, which is what we want.
 182         if (flag_set_p("Joined.*", flags[i])) {
 183                 for (j = i + 1; j < n_opts; j++) {
 184                         if (substr (opts[j], 1, len) != opts[i])
 185                                 break;
 186                         back_chain[j] = enum;
 187                 }
 188         }
 189
 190         s = substr("                                  ", length (opts[i]))
 191         if (i + 1 == n_opts)
 192                 comma = ""
 193
 194         if (help[i] == "")
 195                 hlp = "0"
 196         else
 197                 hlp = quote help[i] quote;
 198
 199         neg = opt_args("Negative", flags[i]);
 200         if (neg != "")
 201                 idx = indices[neg]
 202         else {
 203                 if (flag_set_p("RejectNegative", flags[i]))
 204                         idx = -1;
 205                 else {
 206                         if (opts[i] ~ "^[Wfm]")
 207                                 idx = indices[opts[i]];
 208                         else
 209                                 idx = -1;
 210                 }
 211         }
 212         # Split the printf after %u to work around an ia64-hp-hpux11.23
 213         # awk bug.
 214         printf("  { %c-%s%c,\n    %s,\n    %s, %u,",
 215                quote, opts[i], quote, hlp, back_chain[i], len)
 216         printf(" %d,\n", idx)
 217         condition = opt_args("Condition", flags[i])
 218         cl_flags = switch_flags(flags[i])
 219         if (condition != "")
 220                 printf("#if %s\n" \
 221                        "    %s,\n" \
 222                        "#else\n" \
 223                        "    CL_DISABLED,\n" \
 224                        "#endif\n",
 225                        condition, cl_flags, cl_flags)
 226         else
 227                 printf("    %s,\n", cl_flags)
 228         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 229                var_set(flags[i]), comma)
 230 }
 231
 232 print "};"
 233
 234 print "";
 235 print "#if !defined(GCC_DRIVER) && !defined(IN_LIBGCC2) && !defined(IN_TARGET_LIBS)"
 236 print "";
 237 print "/* Save optimization variables into a structure.  */"
 238 print "void";
 239 print "cl_optimization_save (struct cl_optimization *ptr)";
 240 print "{";
 241
 242 n_opt_char = 2;
 243 n_opt_short = 0;
 244 n_opt_int = 0;
 245 n_opt_other = 0;
 246 var_opt_char[0] = "optimize";
 247 var_opt_char[1] = "optimize_size";
 248 var_opt_range["optimize"] = "0, 255";
 249 var_opt_range["optimize_size"] = "0, 255";
 250
 251 # Sort by size to mimic how the structure is laid out to be friendlier to the
 252 # cache.
 253
 254 for (i = 0; i < n_opts; i++) {
 255         if (flag_set_p("Optimization", flags[i])) {
 256                 name = var_name(flags[i])
 257                 if(name == "")
 258                         continue;
 259
 260                 if(name in var_opt_seen)
 261                         continue;
 262
 263                 var_opt_seen[name]++;
 264                 otype = var_type_struct(flags[i]);
 265                 if (otype ~ "^((un)?signed +)?int *$")
 266                         var_opt_int[n_opt_int++] = name;
 267
 268                 else if (otype ~ "^((un)?signed +)?short *$")
 269                         var_opt_short[n_opt_short++] = name;
 270
 271                 else if (otype ~ "^((un)?signed +)?char *$") {
 272                         var_opt_char[n_opt_char++] = name;
 273                         if (otype ~ "^unsigned +char *$")
 274                                 var_opt_range[name] = "0, 255"
 275                         else if (otype ~ "^signed +char *$")
 276                                 var_opt_range[name] = "-128, 127"
 277                 }
 278                 else
 279                         var_opt_other[n_opt_other++] = name;
 280         }
 281 }
 282
 283 for (i = 0; i < n_opt_char; i++) {
 284         name = var_opt_char[i];
 285         if (var_opt_range[name] != "")
 286                 print "  gcc_assert (IN_RANGE (" name ", " var_opt_range[name] "));";
 287 }
 288
 289 print "";
 290 for (i = 0; i < n_opt_other; i++) {
 291         print "  ptr->" var_opt_other[i] " = " var_opt_other[i] ";";
 292 }
 293
 294 for (i = 0; i < n_opt_int; i++) {
 295         print "  ptr->" var_opt_int[i] " = " var_opt_int[i] ";";
 296 }
 297
 298 for (i = 0; i < n_opt_short; i++) {
 299         print "  ptr->" var_opt_short[i] " = " var_opt_short[i] ";";
 300 }
 301
 302 for (i = 0; i < n_opt_char; i++) {
 303         print "  ptr->" var_opt_char[i] " = " var_opt_char[i] ";";
 304 }
 305
 306 print "}";
 307
 308 print "";
 309 print "/* Restore optimization options from a structure.  */";
 310 print "void";
 311 print "cl_optimization_restore (struct cl_optimization *ptr)";
 312 print "{";
 313
 314 for (i = 0; i < n_opt_other; i++) {
 315         print "  " var_opt_other[i] " = ptr->" var_opt_other[i] ";";
 316 }
 317
 318 for (i = 0; i < n_opt_int; i++) {
 319         print "  " var_opt_int[i] " = ptr->" var_opt_int[i] ";";
 320 }
 321
 322 for (i = 0; i < n_opt_short; i++) {
 323         print "  " var_opt_short[i] " = ptr->" var_opt_short[i] ";";
 324 }
 325
 326 for (i = 0; i < n_opt_char; i++) {
 327         print "  " var_opt_char[i] " = ptr->" var_opt_char[i] ";";
 328 }
 329
 330 print "}";
 331
 332 print "";
 333 print "/* Print optimization options from a structure.  */";
 334 print "void";
 335 print "cl_optimization_print (FILE *file,";
 336 print "                       int indent_to,";
 337 print "                       struct cl_optimization *ptr)";
 338 print "{";
 339
 340 print "  fputs (\"\\n\", file);";
 341 for (i = 0; i < n_opt_other; i++) {
 342         print "  if (ptr->" var_opt_other[i] ")";
 343         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 344         print "             indent_to, \"\",";
 345         print "             \"" var_opt_other[i] "\",";
 346         print "             (unsigned long)ptr->" var_opt_other[i] ");";
 347         print "";
 348 }
 349
 350 for (i = 0; i < n_opt_int; i++) {
 351         print "  if (ptr->" var_opt_int[i] ")";
 352         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 353         print "             indent_to, \"\",";
 354         print "             \"" var_opt_int[i] "\",";
 355         print "             ptr->" var_opt_int[i] ");";
 356         print "";
 357 }
 358
 359 for (i = 0; i < n_opt_short; i++) {
 360         print "  if (ptr->" var_opt_short[i] ")";
 361         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 362         print "             indent_to, \"\",";
 363         print "             \"" var_opt_short[i] "\",";
 364         print "             ptr->" var_opt_short[i] ");";
 365         print "";
 366 }
 367
 368 for (i = 0; i < n_opt_char; i++) {
 369         print "  if (ptr->" var_opt_char[i] ")";
 370         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 371         print "             indent_to, \"\",";
 372         print "             \"" var_opt_char[i] "\",";
 373         print "             ptr->" var_opt_char[i] ");";
 374         print "";
 375 }
 376
 377 print "}";
 378
 379 print "";
 380 print "/* Save selected option variables into a structure.  */"
 381 print "void";
 382 print "cl_target_option_save (struct cl_target_option *ptr)";
 383 print "{";
 384
 385 n_target_char = 0;
 386 n_target_short = 0;
 387 n_target_int = 0;
 388 n_target_other = 0;
 389
 390 if (have_save) {
 391         for (i = 0; i < n_opts; i++) {
 392                 if (flag_set_p("Save", flags[i])) {
 393                         name = var_name(flags[i])
 394                         if(name == "")
 395                                 name = "target_flags";
 396
 397                         if(name in var_save_seen)
 398                                 continue;
 399
 400                         var_save_seen[name]++;
 401                         otype = var_type_struct(flags[i])
 402                         if (otype ~ "^((un)?signed +)?int *$")
 403                                 var_target_int[n_target_int++] = name;
 404
 405                         else if (otype ~ "^((un)?signed +)?short *$")
 406                                 var_target_short[n_target_short++] = name;
 407
 408                         else if (otype ~ "^((un)?signed +)?char *$") {
 409                                 var_target_char[n_target_char++] = name;
 410                                 if (otype ~ "^unsigned +char *$")
 411                                         var_target_range[name] = "0, 255"
 412                                 else if (otype ~ "^signed +char *$")
 413                                         var_target_range[name] = "-128, 127"
 414                         }
 415                         else
 416                                 var_target_other[n_target_other++] = name;
 417                 }
 418         }
 419 } else {
 420         var_target_int[n_target_int++] = "target_flags";
 421 }
 422
 423 have_assert = 0;
 424 for (i = 0; i < n_target_char; i++) {
 425         name = var_target_char[i];
 426         if (var_target_range[name] != "") {
 427                 have_assert = 1;
 428                 print "  gcc_assert (IN_RANGE (" name ", " var_target_range[name] "));";
 429         }
 430 }
 431
 432 if (have_assert)
 433         print "";
 434
 435 print "  if (targetm.target_option.save)";
 436 print "    targetm.target_option.save (ptr);";
 437 print "";
 438
 439 for (i = 0; i < n_target_other; i++) {
 440         print "  ptr->" var_target_other[i] " = " var_target_other[i] ";";
 441 }
 442
 443 for (i = 0; i < n_target_int; i++) {
 444         print "  ptr->" var_target_int[i] " = " var_target_int[i] ";";
 445 }
 446
 447 for (i = 0; i < n_target_short; i++) {
 448         print "  ptr->" var_target_short[i] " = " var_target_short[i] ";";
 449 }
 450
 451 for (i = 0; i < n_target_char; i++) {
 452         print "  ptr->" var_target_char[i] " = " var_target_char[i] ";";
 453 }
 454
 455 print "}";
 456
 457 print "";
 458 print "/* Restore selected current options from a structure.  */";
 459 print "void";
 460 print "cl_target_option_restore (struct cl_target_option *ptr)";
 461 print "{";
 462
 463 for (i = 0; i < n_target_other; i++) {
 464         print "  " var_target_other[i] " = ptr->" var_target_other[i] ";";
 465 }
 466
 467 for (i = 0; i < n_target_int; i++) {
 468         print "  " var_target_int[i] " = ptr->" var_target_int[i] ";";
 469 }
 470
 471 for (i = 0; i < n_target_short; i++) {
 472         print "  " var_target_short[i] " = ptr->" var_target_short[i] ";";
 473 }
 474
 475 for (i = 0; i < n_target_char; i++) {
 476         print "  " var_target_char[i] " = ptr->" var_target_char[i] ";";
 477 }
 478
 479 # This must occur after the normal variables in case the code depends on those
 480 # variables.
 481 print "";
 482 print "  if (targetm.target_option.restore)";
 483 print "    targetm.target_option.restore (ptr);";
 484
 485 print "}";
 486
 487 print "";
 488 print "/* Print optimization options from a structure.  */";
 489 print "void";
 490 print "cl_target_option_print (FILE *file,";
 491 print "                        int indent,";
 492 print "                        struct cl_target_option *ptr)";
 493 print "{";
 494
 495 print "  fputs (\"\\n\", file);";
 496 for (i = 0; i < n_target_other; i++) {
 497         print "  if (ptr->" var_target_other[i] ")";
 498         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 499         print "             indent, \"\",";
 500         print "             \"" var_target_other[i] "\",";
 501         print "             (unsigned long)ptr->" var_target_other[i] ");";
 502         print "";
 503 }
 504
 505 for (i = 0; i < n_target_int; i++) {
 506         print "  if (ptr->" var_target_int[i] ")";
 507         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 508         print "             indent, \"\",";
 509         print "             \"" var_target_int[i] "\",";
 510         print "             ptr->" var_target_int[i] ");";
 511         print "";
 512 }
 513
 514 for (i = 0; i < n_target_short; i++) {
 515         print "  if (ptr->" var_target_short[i] ")";
 516         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 517         print "             indent, \"\",";
 518         print "             \"" var_target_short[i] "\",";
 519         print "             ptr->" var_target_short[i] ");";
 520         print "";
 521 }
 522
 523 for (i = 0; i < n_target_char; i++) {
 524         print "  if (ptr->" var_target_char[i] ")";
 525         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 526         print "             indent, \"\",";
 527         print "             \"" var_target_char[i] "\",";
 528         print "             ptr->" var_target_char[i] ");";
 529         print "";
 530 }
 531
 532 print "";
 533 print "  if (targetm.target_option.print)";
 534 print "    targetm.target_option.print (file, indent, ptr);";
 535
 536 print "}";
 537 print "#endif";
 538
 539 }