gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Set program_transform_name
 339 AC_ARG_PROGRAM
 340
 341 # Find the native compiler
 342 AC_PROG_CC
 343 AC_PROG_CC_C_O
 344 # autoconf is lame and doesn't give us any substitution variable for this.
 345 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 346   NO_MINUS_C_MINUS_O=yes
 347 else
 348   OUTPUT_OPTION='-o $@'
 349 fi
 350 AC_SUBST(NO_MINUS_C_MINUS_O)
 351 AC_SUBST(OUTPUT_OPTION)
 352
 353 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 354 ac_cv_prog_cc_no_long_long,
 355 [save_CFLAGS="$CFLAGS"
 356 CFLAGS="-Wno-long-long"
 357 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 358                ac_cv_prog_cc_no_long_long=no)
 359 CFLAGS="$save_CFLAGS"])
 360 strict1_warn=
 361 if test $ac_cv_prog_cc_no_long_long = yes; then
 362   strict1_warn="-pedantic -Wno-long-long"
 363 fi
 364 AC_SUBST(strict1_warn)
 365
 366 AC_PROG_CPP
 367 AC_C_INLINE
 368 gcc_AC_C_VOLATILE
 369
 370 gcc_AC_C_LONG_DOUBLE
 371 gcc_AC_C_LONG_LONG
 372 gcc_AC_C__BOOL
 373
 374 # sizeof(char) is 1 by definition.
 375 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 376 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 377 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 378 if test $ac_cv_c_long_long = yes; then
 379   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 380 fi
 381 if test $ac_cv_c___int64 = yes; then
 382   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 383 fi
 384
 385 gcc_AC_C_CHARSET
 386
 387 # If the native compiler is GCC, we can enable warnings even in stage1.
 388 # That's useful for people building cross-compilers, or just running a
 389 # quick `make'.
 390 warn_cflags=
 391 if test "x$GCC" = "xyes"; then
 392   warn_cflags='$(GCC_WARN_CFLAGS)'
 393 fi
 394 AC_SUBST(warn_cflags)
 395
 396 # Stage specific cflags for build.
 397 stage1_cflags=
 398 case $build in
 399 vax-*-*)
 400   if test x$GCC = xyes
 401   then
 402     stage1_cflags="-Wa,-J"
 403   else
 404     stage1_cflags="-J"
 405   fi
 406   ;;
 407 powerpc-*-darwin*)
 408   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 409   # sources; use -no-cpp-precomp to get to GNU cpp.
 410   # Apple's GCC has bugs in designated initializer handling, so disable
 411   # that too.
 412   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 413   ;;
 414 esac
 415 AC_SUBST(stage1_cflags)
 416
 417 AC_PROG_MAKE_SET
 418
 419 AC_MSG_CHECKING([whether a default assembler was specified])
 420 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 421     if test x"$gas_flag" = x"no"; then
 422         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 423     else
 424         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 425     fi
 426 else
 427     AC_MSG_RESULT(no)
 428 fi
 429
 430 AC_MSG_CHECKING([whether a default linker was specified])
 431 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 432     if test x"$gnu_ld_flag" = x"no"; then
 433         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 434     else
 435         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 436     fi
 437 else
 438     AC_MSG_RESULT(no)
 439 fi
 440
 441 AC_MSG_CHECKING(for GNU C library)
 442 AC_CACHE_VAL(gcc_cv_glibc,
 443 [AC_TRY_COMPILE(
 444   [#include <features.h>],[
 445 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 446 #error Not a GNU C library system
 447 #endif],
 448   [gcc_cv_glibc=yes],
 449   gcc_cv_glibc=no)])
 450 AC_MSG_RESULT($gcc_cv_glibc)
 451 if test $gcc_cv_glibc = yes; then
 452   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 453 fi
 454
 455 # Find some useful tools
 456 AC_PROG_AWK
 457 gcc_AC_PROG_LN
 458 gcc_AC_PROG_LN_S
 459 AC_PROG_RANLIB
 460 gcc_AC_PROG_INSTALL
 461
 462 AC_HEADER_STDC
 463 AC_HEADER_TIME
 464 gcc_AC_HEADER_STDBOOL
 465 gcc_AC_HEADER_STRING
 466 AC_HEADER_SYS_WAIT
 467 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 468                  fcntl.h unistd.h sys/file.h sys/time.h \
 469                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 470                  direct.h malloc.h langinfo.h)
 471
 472 # Check for thread headers.
 473 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 474 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 475
 476 # These tests can't be done till we know if we have limits.h.
 477 gcc_AC_C_CHAR_BIT
 478 gcc_AC_C_COMPILE_ENDIAN
 479 gcc_AC_C_FLOAT_FORMAT
 480
 481 # See if GNAT has been installed
 482 gcc_AC_PROG_GNAT
 483
 484 # See if we have the mktemp command.
 485 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 486
 487 # Do we have a single-tree copy of texinfo?
 488 if test -f $srcdir/../texinfo/Makefile.in; then
 489   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 490   gcc_cv_prog_makeinfo_modern=yes
 491   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 492 else
 493   # See if makeinfo has been installed and is modern enough
 494   # that we can use it.
 495   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 496   [GNU texinfo.* \([0-9][0-9.]*\)],
 497   [4.*])
 498 fi
 499
 500 if test $gcc_cv_prog_makeinfo_modern = no; then
 501   AC_MSG_WARN([
 502 *** Makeinfo is missing or too old.
 503 *** Info documentation will not be built.])
 504   BUILD_INFO=
 505 else
 506   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 507 fi
 508
 509 # Is pod2man recent enough to regenerate manpages?
 510 AC_MSG_CHECKING([for recent Pod::Man])
 511 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 512   AC_MSG_RESULT(yes)
 513   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 514 else
 515   AC_MSG_RESULT(no)
 516   GENERATED_MANPAGES=
 517 fi
 518
 519 # How about lex?
 520 dnl Don't use AC_PROG_LEX; we insist on flex.
 521 dnl LEXLIB is not useful in gcc.
 522 if test -f $srcdir/../flex/skel.c; then
 523   FLEX='$(objdir)/../flex/flex'
 524 else
 525   AC_CHECK_PROG(FLEX, flex, flex, false)
 526 fi
 527
 528 # Bison?
 529 # The -L switch is so bison can find its skeleton file.
 530 if test -f $srcdir/../bison/bison.simple; then
 531   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 532 else
 533   AC_CHECK_PROG(BISON, bison, bison, false)
 534 fi
 535
 536 # These libraries may be used by collect2.
 537 # We may need a special search path to get them linked.
 538 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 539 [save_LIBS="$LIBS"
 540 for libs in '' -lld -lmld \
 541                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 542                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 543 do
 544         LIBS="$libs"
 545         AC_TRY_LINK_FUNC(ldopen,
 546                 [gcc_cv_collect2_libs="$libs"; break])
 547 done
 548 LIBS="$save_LIBS"
 549 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 550 case $gcc_cv_collect2_libs in
 551         "none required")        ;;
 552         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 553 esac
 554 AC_SUBST(COLLECT2_LIBS)
 555
 556 # When building Ada code on Alpha, we need exc_resume which is usually in
 557 # -lexc.  So test for it.
 558 save_LIBS="$LIBS"
 559 LIBS=
 560 AC_SEARCH_LIBS(exc_resume, exc)
 561 GNAT_LIBEXC="$LIBS"
 562 LIBS="$save_LIBS"
 563 AC_SUBST(GNAT_LIBEXC)
 564
 565 # See if the stage1 system preprocessor understands the ANSI C
 566 # preprocessor stringification operator.  (Used by symcat.h.)
 567 AC_C_STRINGIZE
 568
 569 # Use <inttypes.h> only if it exists,
 570 # doesn't clash with <sys/types.h>, and declares intmax_t.
 571 AC_MSG_CHECKING(for inttypes.h)
 572 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 573 [AC_TRY_COMPILE(
 574   [#include <sys/types.h>
 575 #include <inttypes.h>],
 576   [intmax_t i = -1;],
 577   [gcc_cv_header_inttypes_h=yes],
 578   gcc_cv_header_inttypes_h=no)])
 579 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 580 if test $gcc_cv_header_inttypes_h = yes; then
 581   AC_DEFINE(HAVE_INTTYPES_H, 1,
 582         [Define if you have a working <inttypes.h> header file.])
 583 fi
 584
 585 dnl Disabled until we have a complete test for buggy enum bitfields.
 586 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 587
 588 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 589         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 590         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo lstat)
 591
 592 AC_CHECK_TYPE(ssize_t, int)
 593
 594 # Try to determine the array type of the second argument of getgroups
 595 # for the target system (int or gid_t).
 596 AC_TYPE_GETGROUPS
 597 if test "${target}" = "${build}"; then
 598   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 599 else
 600   case "${target}" in
 601         # This condition may need some tweaking.  It should include all
 602         # targets where the array type of the second argument of getgroups
 603         # is int and the type of gid_t is not equivalent to int.
 604         *-*-sunos* | *-*-ultrix*)
 605                 TARGET_GETGROUPS_T=int
 606                 ;;
 607         *)
 608                 TARGET_GETGROUPS_T=gid_t
 609                 ;;
 610   esac
 611 fi
 612 AC_SUBST(TARGET_GETGROUPS_T)
 613
 614 gcc_AC_FUNC_PRINTF_PTR
 615
 616 case "${host}" in
 617 *-*-uwin*)
 618   AC_MSG_ERROR([
 619 *** UWIN may not be used as a host platform because
 620 *** linking with posix.dll is not allowed by the GNU GPL])
 621   ;;
 622 *-*-*vms*)
 623   # Under VMS, vfork works very different than on Unix. The standard test
 624   # won't work, and it isn't easily adaptable. It makes more sense to
 625   # just force it.
 626   ac_cv_func_vfork_works=yes
 627   ;;
 628 esac
 629 AC_FUNC_VFORK
 630 AC_FUNC_MMAP_ANYWHERE
 631 AC_FUNC_MMAP_FILE
 632
 633 AM_ICONV
 634
 635 # We will need to find libiberty.h and ansidecl.h
 636 saved_CFLAGS="$CFLAGS"
 637 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 638 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 639         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 640         fprintf_unlocked strstr errno \
 641         malloc realloc calloc free basename getopt clock, , ,[
 642 #include "ansidecl.h"
 643 #include "system.h"])
 644
 645 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 646 #include "ansidecl.h"
 647 #include "system.h"
 648 #ifdef HAVE_SYS_RESOURCE_H
 649 #include <sys/resource.h>
 650 #endif
 651 ])
 652
 653 gcc_AC_CHECK_DECLS(times, , ,[
 654 #include "ansidecl.h"
 655 #include "system.h"
 656 #ifdef HAVE_SYS_TIMES_H
 657 #include <sys/times.h>
 658 #endif
 659 ])
 660
 661 # More time-related stuff.
 662 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 663 AC_TRY_COMPILE([
 664 #include "ansidecl.h"
 665 #include "system.h"
 666 #ifdef HAVE_SYS_TIMES_H
 667 #include <sys/times.h>
 668 #endif
 669 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 670 if test $ac_cv_struct_tms = yes; then
 671   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 672   [Define if <sys/times.h> defines struct tms.])
 673 fi
 674
 675 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 676 # revisit after autoconf 2.50.
 677 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 678 AC_TRY_COMPILE([
 679 #include "ansidecl.h"
 680 #include "system.h"
 681 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 682 if test $gcc_cv_type_clock_t = yes; then
 683   AC_DEFINE(HAVE_CLOCK_T, 1,
 684   [Define if <time.h> defines clock_t.])
 685 fi
 686
 687 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 688 CFLAGS="$saved_CFLAGS"
 689
 690 # mkdir takes a single argument on some systems.
 691 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 692
 693 # File extensions
 694 manext='.1'
 695 objext='.o'
 696 AC_SUBST(manext)
 697 AC_SUBST(objext)
 698
 699 build_xm_file=
 700 build_xm_defines=
 701 build_install_headers_dir=install-headers-tar
 702 build_exeext=
 703 host_xm_file=
 704 host_xm_defines=
 705 host_xmake_file=
 706 host_truncate_target=
 707 host_exeext=
 708
 709 # Decode the host machine, then the target machine.
 710 # For the host machine, we save the xm_file variable as host_xm_file;
 711 # then we decode the target machine and forget everything else
 712 # that came from the host machine.
 713 for machine in $build $host $target; do
 714         . ${srcdir}/config.gcc
 715 done
 716
 717 extra_objs="${host_extra_objs} ${extra_objs}"
 718
 719 # Default the target-machine variables that were not explicitly set.
 720 if test x"$tm_file" = x
 721 then tm_file=$cpu_type/$cpu_type.h; fi
 722
 723 if test x"$extra_headers" = x
 724 then extra_headers=; fi
 725
 726 if test x$md_file = x
 727 then md_file=$cpu_type/$cpu_type.md; fi
 728
 729 if test x$out_file = x
 730 then out_file=$cpu_type/$cpu_type.c; fi
 731
 732 if test x"$tmake_file" = x
 733 then tmake_file=$cpu_type/t-$cpu_type
 734 fi
 735
 736 if test x"$dwarf2" = xyes
 737 then tm_file="$tm_file tm-dwarf2.h"
 738 fi
 739
 740 if test x$float_format = x
 741 then float_format=i64
 742 fi
 743
 744 if test $float_format = none
 745 then float_h_file=Makefile.in
 746 else float_h_file=float-$float_format.h
 747 fi
 748
 749 # Handle cpp installation.
 750 if test x$enable_cpp != xno
 751 then
 752   tmake_file="$tmake_file t-install-cpp"
 753 fi
 754
 755 # Say what files are being used for the output code and MD file.
 756 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 757 echo "Using \`$srcdir/config/$md_file' as machine description file."
 758
 759 # If any of the xm_file variables contain nonexistent files, warn
 760 # about them and drop them.
 761
 762 bx=
 763 for x in $build_xm_file; do
 764   if    test -f $srcdir/config/$x
 765   then      bx="$bx $x"
 766   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 767   fi
 768 done
 769 build_xm_file="$bx"
 770
 771 hx=
 772 for x in $host_xm_file; do
 773   if    test -f $srcdir/config/$x
 774   then      hx="$hx $x"
 775   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 776   fi
 777 done
 778 host_xm_file="$hx"
 779
 780 tx=
 781 for x in $xm_file; do
 782   if    test -f $srcdir/config/$x
 783   then      tx="$tx $x"
 784   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 785   fi
 786 done
 787 xm_file="$tx"
 788
 789 count=a
 790 for f in $tm_file; do
 791         count=${count}x
 792 done
 793 if test $count = ax; then
 794         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 795 else
 796         echo "Using the following target machine macro files:"
 797         for f in $tm_file; do
 798                 echo "  $srcdir/config/$f"
 799         done
 800 fi
 801
 802 count=a
 803 for f in $host_xm_file; do
 804         count=${count}x
 805 done
 806 if test $count = a; then
 807         :
 808 elif test $count = ax; then
 809         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 810 else
 811         echo "Using the following host machine macro files:"
 812         for f in $host_xm_file; do
 813                 echo "  $srcdir/config/$f"
 814         done
 815 fi
 816
 817 if test "$host_xm_file" != "$build_xm_file"; then
 818         count=a
 819         for f in $build_xm_file; do
 820                 count=${count}x
 821         done
 822         if test $count = a; then
 823                 :
 824         elif test $count = ax; then
 825                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 826         else
 827                 echo "Using the following build machine macro files:"
 828                 for f in $build_xm_file; do
 829                         echo "  $srcdir/config/$f"
 830                 done
 831         fi
 832 fi
 833
 834 if test x$thread_file = x; then
 835         if test x$target_thread_file != x; then
 836                 thread_file=$target_thread_file
 837         else
 838                 thread_file='single'
 839         fi
 840 fi
 841
 842 # auto-host.h is the file containing items generated by autoconf and is
 843 # the first file included by config.h.
 844 # If host=build, it is correct to have hconfig include auto-host.h
 845 # as well.  If host!=build, we are in error and need to do more
 846 # work to find out the build config parameters.
 847 if test x$host = x$build
 848 then
 849         build_auto=auto-host.h
 850         FORBUILD=..
 851 else
 852         # We create a subdir, then run autoconf in the subdir.
 853         # To prevent recursion we set host and build for the new
 854         # invocation of configure to the build for this invocation
 855         # of configure.
 856         tempdir=build.$$
 857         rm -rf $tempdir
 858         mkdir $tempdir
 859         cd $tempdir
 860         case ${srcdir} in
 861         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 862         *) realsrcdir=../${srcdir};;
 863         esac
 864         saved_CFLAGS="${CFLAGS}"
 865         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 866         ${realsrcdir}/configure \
 867                 --target=$target --host=$build --build=$build
 868         CFLAGS="${saved_CFLAGS}"
 869
 870         # We just finished tests for the build machine, so rename
 871         # the file auto-build.h in the gcc directory.
 872         mv auto-host.h ../auto-build.h
 873         cd ..
 874         rm -rf $tempdir
 875         build_auto=auto-build.h
 876         FORBUILD=../$build
 877 fi
 878 AC_SUBST(FORBUILD)
 879
 880 tm_file="${tm_file} defaults.h"
 881 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 882 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 883 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 884
 885 # Truncate the target if necessary
 886 if test x$host_truncate_target != x; then
 887         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 888 fi
 889
 890 # Get the version trigger filename from the toplevel
 891 if test "${with_gcc_version_trigger+set}" = set; then
 892         gcc_version_trigger=$with_gcc_version_trigger
 893 else
 894         gcc_version_trigger=${srcdir}/version.c
 895 fi
 896 changequote(,)dnl
 897 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 898 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 899
 900 # Compile in configure arguments.
 901 if test -f configargs.h ; then
 902         # Being re-configured.
 903         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 904         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 905 else
 906         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 907 fi
 908 cat > configargs.h <<EOF
 909 /* Generated automatically. */
 910 static const char configuration_arguments[] = "$gcc_config_arguments";
 911 static const char thread_model[] = "$thread_file";
 912 EOF
 913 changequote([,])dnl
 914
 915 # Internationalization
 916 PACKAGE=gcc
 917 VERSION="$gcc_version"
 918 AC_SUBST(PACKAGE)
 919 AC_SUBST(VERSION)
 920
 921 # Enable NLS support by default
 922 AC_ARG_ENABLE(nls,
 923   [  --enable-nls            use Native Language Support (default)],
 924   , enable_nls=yes)
 925
 926 # if cross compiling, disable NLS support.
 927 # It's not worth the trouble, at least for now.
 928
 929 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 930   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 931   enable_nls=no
 932 fi
 933
 934 AM_GNU_GETTEXT
 935
 936 # Windows32 Registry support for specifying GCC installation paths.
 937 AC_ARG_ENABLE(win32-registry,
 938 [  --disable-win32-registry
 939                           disable lookup of installation paths in the
 940                           Registry on Windows hosts
 941   --enable-win32-registry enable registry lookup (default)
 942   --enable-win32-registry=KEY
 943                           use KEY instead of GCC version as the last portion
 944                           of the registry key],,)
 945 case $host_os in
 946         win32 | pe | cygwin* | mingw32* | uwin*)
 947 AC_MSG_CHECKING(whether windows registry support is requested)
 948 if test "x$enable_win32_registry" != xno; then
 949   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 950 [Define to 1 if installation paths should be looked up in Windows32
 951    Registry. Ignored on non windows32 hosts.])
 952   AC_MSG_RESULT(yes)
 953   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 954 else
 955   AC_MSG_RESULT(no)
 956 fi
 957
 958 # Check if user specified a different registry key.
 959 case "x${enable_win32_registry}" in
 960 x | xyes)
 961   # default.
 962   gcc_cv_win32_registry_key="$VERSION"
 963   ;;
 964 xno)
 965   # no registry lookup.
 966   gcc_cv_win32_registry_key=''
 967   ;;
 968 *)
 969   # user-specified key.
 970   gcc_cv_win32_registry_key="$enable_win32_registry"
 971   ;;
 972 esac
 973
 974 if test "x$enable_win32_registry" != xno; then
 975   AC_MSG_CHECKING(registry key on windows hosts)
 976   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 977         [Define to be the last portion of registry key on windows hosts.])
 978   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 979 fi
 980 ;;
 981 esac
 982
 983 # Get an absolute path to the GCC top-level source directory
 984 holddir=`pwd`
 985 cd $srcdir
 986 topdir=`pwd`
 987 cd $holddir
 988
 989 # Conditionalize the makefile for this host machine.
 990 # Make-host contains the concatenation of all host makefile fragments
 991 # [there can be more than one].  This file is built by configure.frag.
 992 host_overrides=Make-host
 993 dep_host_xmake_file=
 994 for f in .. ${host_xmake_file}
 995 do
 996         if test -f ${srcdir}/config/$f
 997         then
 998                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 999         fi
1000 done
1001
1002 # Conditionalize the makefile for this target machine.
1003 # Make-target contains the concatenation of all host makefile fragments
1004 # [there can be more than one].  This file is built by configure.frag.
1005 target_overrides=Make-target
1006 dep_tmake_file=
1007 for f in .. ${tmake_file}
1008 do
1009         if test -f ${srcdir}/config/$f
1010         then
1011                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1012         fi
1013 done
1014
1015 # If the host doesn't support symlinks, modify CC in
1016 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1017 # Otherwise, we can use "CC=$(CC)".
1018 rm -f symtest.tem
1019 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1020 then
1021         cc_set_by_configure="\$(CC)"
1022         quoted_cc_set_by_configure="\$(CC)"
1023         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1024         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1025 else
1026         rm -f symtest.tem
1027         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1028         then
1029                 symbolic_link="cp -p"
1030         else
1031                 symbolic_link="cp"
1032         fi
1033         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1034         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1035         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1036         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1037 fi
1038 rm -f symtest.tem
1039
1040 out_object_file=`basename $out_file .c`.o
1041
1042 tm_file_list=
1043 for f in $tm_file; do
1044   case $f in
1045     ansidecl.h )
1046        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1047     defaults.h )
1048        tm_file_list="${tm_file_list} $f" ;;
1049     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1050   esac
1051 done
1052
1053 tm_p_file_list=
1054 for f in $tm_p_file; do
1055     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1056 done
1057
1058 host_xm_file_list=
1059 for f in $host_xm_file; do
1060   case $f in
1061     ansidecl.h )
1062        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1063     auto-host.h | defaults.h )
1064        host_xm_file_list="${host_xm_file_list} $f" ;;
1065     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1066   esac
1067 done
1068
1069 build_xm_file_list=
1070 for f in $build_xm_file; do
1071   case $f in
1072     ansidecl.h )
1073        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1074     auto-build.h | auto-host.h | defaults.h )
1075        build_xm_file_list="${build_xm_file_list} $f" ;;
1076     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1077   esac
1078 done
1079
1080 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1081 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1082 CROSS=                                          AC_SUBST(CROSS)
1083 ALL=all.internal                                AC_SUBST(ALL)
1084 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1085 if test x$host != x$target
1086 then
1087         CROSS="-DCROSS_COMPILE"
1088         ALL=all.cross
1089         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1090 fi
1091
1092 # If this is a cross-compiler that does not
1093 # have its own set of headers then define
1094 # inhibit_libc
1095
1096 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1097 # This prevents libgcc2 from containing any code which requires libc
1098 # support.
1099 inhibit_libc=
1100 if [test x$host != x$target] && [test x$with_headers = x]; then
1101        inhibit_libc=-Dinhibit_libc
1102 else
1103        if [test x$with_newlib = xyes]; then
1104                inhibit_libc=-Dinhibit_libc
1105        fi
1106 fi
1107 AC_SUBST(inhibit_libc)
1108
1109 # When building gcc with a cross-compiler, we need to adjust things so
1110 # that the generator programs are still built with the native compiler.
1111 # Also, we cannot run fixincludes or fix-header.
1112 # Note that the terminology here is wrong; it should be BUILD_* throughout.
1113 # FIXME.
1114
1115 # These are the normal (build=host) settings:
1116 HOST_PREFIX=                    AC_SUBST(HOST_PREFIX)
1117 HOST_PREFIX_1=ignore-           AC_SUBST(HOST_PREFIX_1)
1118 HOST_CC='$(CC)'                 AC_SUBST(HOST_CC)
1119 HOST_CFLAGS='$(ALL_CFLAGS)'     AC_SUBST(HOST_CFLAGS)
1120
1121 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1122 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1123
1124 # And these apply if build != host.
1125 if test x$build != x$host
1126 then
1127     HOST_PREFIX=build-
1128     HOST_PREFIX_1=build-
1129     HOST_CC='$(CC_FOR_BUILD)'
1130     HOST_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD) $(XCFLAGS)'
1131
1132     STMP_FIXINC=
1133     STMP_FIXPROTO=
1134 fi
1135
1136 # Expand extra_headers to include complete path.
1137 # This substitutes for lots of t-* files.
1138 extra_headers_list=
1139 if test "x$extra_headers" = x
1140 then true
1141 else
1142         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1143         for file in $extra_headers;
1144         do
1145                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1146         done
1147 fi
1148
1149 if test x$use_collect2 = xno; then
1150         use_collect2=
1151 fi
1152
1153 # Add a definition of USE_COLLECT2 if system wants one.
1154 if test x$use_collect2 != x
1155 then
1156         host_xm_defines="${host_xm_defines} USE_COLLECT2"
1157         xm_defines="${xm_defines} USE_COLLECT2"
1158 fi
1159
1160 # If we have gas in the build tree, make a link to it.
1161 if test -f ../gas/Makefile; then
1162         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1163 fi
1164
1165 # If we have nm and objdump in the build tree, make a link to them.
1166 if test -f ../binutils/Makefile; then
1167         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1168         rm -f objdump; $symbolic_link ../binutils/objdump$host_exeext objdump$host_exeext 2>/dev/null
1169 fi
1170
1171 # If we have ld in the build tree, make a link to it.
1172 if test -f ../ld/Makefile; then
1173         rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1174 fi
1175
1176 # Figure out what assembler we will be using.
1177 AC_MSG_CHECKING(what assembler to use)
1178 gcc_cv_as=
1179 gcc_cv_gas_major_version=
1180 gcc_cv_gas_minor_version=
1181 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1182 gcc_cv_as_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1183 if test -x "$DEFAULT_ASSEMBLER"; then
1184         gcc_cv_as="$DEFAULT_ASSEMBLER"
1185 elif test -x "$AS"; then
1186         gcc_cv_as="$AS"
1187 elif test -x as$host_exeext; then
1188         # Build using assembler in the current directory.
1189         gcc_cv_as=./as$host_exeext
1190 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1191         # Single tree build which includes gas.
1192         for f in $gcc_cv_as_bfd_srcdir/configure $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1193         do
1194 changequote(,)dnl
1195                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1196 changequote([,])dnl
1197                 if test x$gcc_cv_gas_version != x; then
1198                         break
1199                 fi
1200         done
1201 changequote(,)dnl
1202         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1203         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1204 changequote([,])dnl
1205 fi
1206
1207 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1208         # Native build.
1209         # Search the same directories that the installed compiler will
1210         # search.  Else we may find the wrong assembler and lose.  If we
1211         # do not find a suitable assembler binary, then try the user's
1212         # path.
1213         #
1214         # Also note we have to check MD_EXEC_PREFIX before checking the
1215         # user's path.  Unfortunately, there is no good way to get at the
1216         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1217         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1218         # to be fixed as part of the make/configure rewrite too.
1219
1220         if test "x$exec_prefix" = xNONE; then
1221                 if test "x$prefix" = xNONE; then
1222                         test_prefix=/usr/local
1223                 else
1224                         test_prefix=$prefix
1225                 fi
1226         else
1227                 test_prefix=$exec_prefix
1228         fi
1229
1230         # If the loop below does not find an assembler, then use whatever
1231         # one we can find in the users's path.
1232         # user's path.
1233         gcc_cv_as=as$host_exeext
1234
1235         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1236                    $test_prefix/lib/gcc-lib/$target \
1237                    /usr/lib/gcc/$target/$gcc_version \
1238                    /usr/lib/gcc/$target \
1239                    $test_prefix/$target/bin/$target/$gcc_version \
1240                    $test_prefix/$target/bin \
1241                    /usr/libexec \
1242                    /usr/ccs/gcc \
1243                    /usr/ccs/bin \
1244                    /udk/usr/ccs/bin \
1245                    /bsd43/usr/lib/cmplrs/cc \
1246                    /usr/cross64/usr/bin \
1247                    /usr/lib/cmplrs/cc \
1248                    /sysv/usr/lib/cmplrs/cc \
1249                    /svr4/usr/lib/cmplrs/cc \
1250                    /usr/bin"
1251
1252         for dir in $test_dirs; do
1253                 if test -f $dir/as$host_exeext; then
1254                         gcc_cv_as=$dir/as$host_exeext
1255                         break;
1256                 fi
1257         done
1258 fi
1259 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1260   AC_MSG_RESULT("newly built gas")
1261 else
1262   AC_MSG_RESULT($gcc_cv_as)
1263 fi
1264
1265 # Figure out what linker we will be using.
1266 AC_MSG_CHECKING(what linker to use)
1267 gcc_cv_ld=
1268 gcc_cv_gld_major_version=
1269 gcc_cv_gld_minor_version=
1270 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1271 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1272 if test -x "$DEFAULT_LINKER"; then
1273         gcc_cv_ld="$DEFAULT_LINKER"
1274 elif test -x "$LD"; then
1275         gcc_cv_ld="$LD"
1276 elif test -x ld$host_exeext; then
1277         # Build using linker in the current directory.
1278         gcc_cv_ld=./ld$host_exeext
1279 elif test -f $gcc_cv_ld_gld_srcdir/configure.in -a -f ../ld/Makefile; then
1280         # Single tree build which includes ld.
1281         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1282         do
1283 changequote(,)dnl
1284                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1285 changequote([,])dnl
1286                 if test x$gcc_cv_gld_version != x; then
1287                         break
1288                 fi
1289         done
1290 changequote(,)dnl
1291         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1292         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1293 changequote([,])dnl
1294 fi
1295
1296 if test "x$gcc_cv_ld" = x -a x$host = x$target; then
1297         # Native build.
1298         # Search the same directories that the installed compiler will
1299         # search.  Else we may find the wrong linker and lose.  If we
1300         # do not find a suitable linker binary, then try the user's
1301         # path.
1302         #
1303         # Also note we have to check MD_EXEC_PREFIX before checking the
1304         # user's path.  Unfortunately, there is no good way to get at the
1305         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1306         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1307         # to be fixed as part of the make/configure rewrite too.
1308
1309         if test "x$exec_prefix" = xNONE; then
1310                 if test "x$prefix" = xNONE; then
1311                         test_prefix=/usr/local
1312                 else
1313                         test_prefix=$prefix
1314                 fi
1315         else
1316                 test_prefix=$exec_prefix
1317         fi
1318
1319         # If the loop below does not find an linker, then use whatever
1320         # one we can find in the users's path.
1321         # user's path.
1322         gcc_cv_ld=ld$host_exeext
1323
1324         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1325                    $test_prefix/lib/gcc-lib/$target \
1326                    /usr/lib/gcc/$target/$gcc_version \
1327                    /usr/lib/gcc/$target \
1328                    $test_prefix/$target/bin/$target/$gcc_version \
1329                    $test_prefix/$target/bin \
1330                    /usr/libexec \
1331                    /usr/ccs/gcc \
1332                    /usr/ccs/bin \
1333                    /udk/usr/ccs/bin \
1334                    /bsd43/usr/lib/cmplrs/cc \
1335                    /usr/cross64/usr/bin \
1336                    /usr/lib/cmplrs/cc \
1337                    /sysv/usr/lib/cmplrs/cc \
1338                    /svr4/usr/lib/cmplrs/cc \
1339                    /usr/bin"
1340
1341         for dir in $test_dirs; do
1342                 if test -f $dir/ld$host_exeext; then
1343                         gcc_cv_ld=$dir/ld$host_exeext
1344                         break;
1345                 fi
1346         done
1347 fi
1348 if test x$gcc_cv_gld_major_version != x -a x$gcc_cv_gld_minor_version != x; then
1349   AC_MSG_RESULT("newly built ld")
1350 else
1351   AC_MSG_RESULT($gcc_cv_ld)
1352 fi
1353
1354 # Figure out what nm we will be using.
1355 AC_MSG_CHECKING(what nm to use)
1356 if test -x nm$host_exeext; then
1357         gcc_cv_nm=./nm$host_exeext
1358 elif test x$host = x$target; then
1359         # Native build.
1360         gcc_cv_nm=nm$host_exeext
1361 fi
1362 AC_MSG_RESULT($gcc_cv_nm)
1363
1364 # Figure out what objdump we will be using.
1365 AC_MSG_CHECKING(what objdump to use)
1366 if test -x objdump$host_exeext; then
1367         gcc_cv_objdump=./objdump$host_exeext
1368 elif test x$host = x$target; then
1369         # Native build.
1370         gcc_cv_objdump=objdump$host_exeext
1371 fi
1372 AC_MSG_RESULT($gcc_cv_objdump)
1373
1374 # Figure out what assembler alignment features are present.
1375 AC_MSG_CHECKING(assembler alignment features)
1376 gcc_cv_as_alignment_features=none
1377 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1378         # Gas version 2.6 and later support for .balign and .p2align.
1379         # bytes to skip when using .p2align.
1380         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1381                 gcc_cv_as_alignment_features=".balign and .p2align"
1382                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1383         fi
1384         # Gas version 2.8 and later support specifying the maximum
1385         # bytes to skip when using .p2align.
1386         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1387                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1388                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1389         fi
1390 elif test x$gcc_cv_as != x; then
1391         # Check if we have .balign and .p2align
1392         echo ".balign  4" > conftest.s
1393         echo ".p2align  2" >> conftest.s
1394         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1395                 gcc_cv_as_alignment_features=".balign and .p2align"
1396                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1397         fi
1398         rm -f conftest.s conftest.o
1399         # Check if specifying the maximum bytes to skip when
1400         # using .p2align is supported.
1401         echo ".p2align 4,,7" > conftest.s
1402         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1403                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1404                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1405         fi
1406         rm -f conftest.s conftest.o
1407 fi
1408 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1409
1410 AC_MSG_CHECKING(assembler subsection support)
1411 gcc_cv_as_subsections=no
1412 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1413   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1414     gcc_cv_as_subsections="working .subsection -1"
1415   fi
1416 elif test x$gcc_cv_as != x; then
1417         # Check if we have .subsection
1418         echo ".subsection 1" > conftest.s
1419         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1420                 gcc_cv_as_subsections=".subsection"
1421                 if test x$gcc_cv_nm != x; then
1422                         cat > conftest.s <<EOF
1423 conftest_label1: .word 0
1424 .subsection -1
1425 conftest_label2: .word 0
1426 .previous
1427 EOF
1428                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1429                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1430                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1431                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1432                                         :
1433                                 else
1434                                         gcc_cv_as_subsections="working .subsection -1"
1435                                 fi
1436                         fi
1437                 fi
1438         fi
1439         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1440 fi
1441 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1442         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1443 [Define if your assembler supports .subsection and .subsection -1 starts
1444    emitting at the beginning of your section.])
1445 fi
1446 AC_MSG_RESULT($gcc_cv_as_subsections)
1447
1448 AC_MSG_CHECKING(assembler weak support)
1449 gcc_cv_as_weak=no
1450 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1451   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1452     gcc_cv_as_weak="yes"
1453   fi
1454 elif test x$gcc_cv_as != x; then
1455         # Check if we have .weak
1456         echo "  .weak foobar" > conftest.s
1457         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1458                 gcc_cv_as_weak="yes"
1459         fi
1460         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1461 fi
1462 if test x"$gcc_cv_as_weak" = xyes; then
1463         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1464 fi
1465 AC_MSG_RESULT($gcc_cv_as_weak)
1466
1467 AC_MSG_CHECKING(assembler hidden support)
1468 gcc_cv_as_hidden=no
1469 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1470   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1471     gcc_cv_as_hidden="yes"
1472   fi
1473 elif test x$gcc_cv_as != x; then
1474         # Check if we have .hidden
1475         echo "  .hidden foobar" > conftest.s
1476         echo "foobar:" >> conftest.s
1477         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1478                 gcc_cv_as_hidden="yes"
1479         fi
1480         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1481 fi
1482 if test x"$gcc_cv_as_hidden" = xyes; then
1483         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1484                 [Define if your assembler supports .hidden.])
1485 fi
1486 AC_MSG_RESULT($gcc_cv_as_hidden)
1487 libgcc_visibility=$gcc_cv_as_hidden
1488 AC_SUBST(libgcc_visibility)
1489
1490 AC_MSG_CHECKING(assembler leb128 support)
1491 gcc_cv_as_leb128=no
1492 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1493   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1494     gcc_cv_as_leb128="yes"
1495   fi
1496 elif test x$gcc_cv_as != x; then
1497         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1498         cat > conftest.s <<EOF
1499         .data
1500         .uleb128 L2 - L1
1501 L1:
1502         .uleb128 1280
1503         .sleb128 -1010
1504 L2:
1505 EOF
1506         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1507                 gcc_cv_as_leb128="yes"
1508
1509                 # GAS versions before 2.11 do not support uleb128,
1510                 # despite appearing to.
1511                 # ??? There exists an elf-specific test that will crash
1512                 # the assembler.  Perhaps it's better to figure out whether
1513                 # arbitrary sections are supported and try the test.
1514                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1515                 if echo "$as_ver" | grep GNU > /dev/null; then
1516 changequote(,)dnl
1517                         as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1518                         as_major=`echo $as_ver | sed 's/\..*//'`
1519                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1520 changequote([,])dnl
1521                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1522                                 gcc_cv_as_leb128="no"
1523                         fi
1524                 fi
1525         fi
1526         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1527 fi
1528 if test x"$gcc_cv_as_leb128" = xyes; then
1529         AC_DEFINE(HAVE_AS_LEB128, 1,
1530                 [Define if your assembler supports .uleb128.])
1531 fi
1532 AC_MSG_RESULT($gcc_cv_as_leb128)
1533
1534 AC_MSG_CHECKING(assembler eh_frame optimization)
1535 gcc_cv_as_eh_frame=no
1536 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1537   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1538     gcc_cv_as_eh_frame="yes"
1539   fi
1540 elif test x$gcc_cv_as != x; then
1541         # Check if this is GAS.
1542         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1543         rm -f a.out 2> /dev/null
1544         if echo "$as_ver" | grep GNU > /dev/null; then
1545                 # Versions up to and including 2.11.0 may mis-optimize
1546                 # .eh_frame data.  Try something.
1547                 cat > conftest.s <<EOF
1548         .text
1549 .LFB1:
1550         .4byte  0
1551 .L1:
1552         .4byte  0
1553 .LFE1:
1554         .section        .eh_frame,"aw",@progbits
1555 __FRAME_BEGIN__:
1556         .4byte  .LECIE1-.LSCIE1
1557 .LSCIE1:
1558         .4byte  0x0
1559         .byte   0x1
1560         .ascii "z\0"
1561         .byte   0x1
1562         .byte   0x78
1563         .byte   0x1a
1564         .byte   0x0
1565         .byte   0x4
1566         .4byte  1
1567         .p2align 1
1568 .LECIE1:
1569 .LSFDE1:
1570         .4byte  .LEFDE1-.LASFDE1
1571 .LASFDE1:
1572         .4byte  .LASFDE1-__FRAME_BEGIN__
1573         .4byte  .LFB1
1574         .4byte  .LFE1-.LFB1
1575         .byte   0x4
1576         .4byte  .LFE1-.LFB1
1577         .byte   0x4
1578         .4byte  .L1-.LFB1
1579 .LEFDE1:
1580 EOF
1581                 cat > conftest.lit <<EOF
1582  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1583  0010 01000000 12000000 18000000 00000000  ................
1584  0020 08000000 04080000 0044               .........D
1585 EOF
1586                 cat > conftest.big <<EOF
1587  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1588  0010 00000001 00000012 00000018 00000000  ................
1589  0020 00000008 04000000 0844               .........D
1590 EOF
1591                 # If the assembler didn't choke, and we can objdump,
1592                 # and we got the correct data, then succeed.
1593                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1594                    && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1595                       | tail -3 > conftest.got \
1596                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1597                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1598                 then
1599                         gcc_cv_as_eh_frame="yes"
1600                 else
1601                         gcc_cv_as_eh_frame="bad"
1602                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1603                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1604         [Define if your assembler mis-optimizes .eh_frame data.])
1605                         fi
1606                 fi
1607         fi
1608         rm -f conftest.*
1609 fi
1610 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1611
1612 AC_MSG_CHECKING(assembler section merging support)
1613 gcc_cv_as_shf_merge=no
1614 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1615   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1616     gcc_cv_as_shf_merge=yes
1617   fi
1618 elif test x$gcc_cv_as != x; then
1619         # Check if we support SHF_MERGE sections
1620         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
1621         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
1622                 gcc_cv_as_shf_merge=yes
1623         fi
1624         rm -f conftest.s conftest.o
1625 fi
1626 if test x"$gcc_cv_as_shf_merge" = xyes; then
1627         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1628 [Define if your assembler supports marking sections with SHF_MERGE flag.])
1629 fi
1630 AC_MSG_RESULT($gcc_cv_as_shf_merge)
1631
1632 case "$target" in
1633   # All TARGET_ABI_OSF targets.
1634   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
1635     AC_CACHE_CHECK([assembler supports explicit relocations],
1636         gcc_cv_as_explicit_relocs, [
1637         gcc_cv_as_explicit_relocs=unknown
1638         if test x$gcc_cv_gas_major_version != x \
1639                 -a x$gcc_cv_gas_minor_version != x
1640         then
1641            if test "$gcc_cv_gas_major_version" -eq 2 \
1642                    -a "$gcc_cv_gas_minor_version" -ge 12 \
1643                    -o "$gcc_cv_gas_major_version" -gt 2; then
1644               gcc_cv_as_explicit_relocs=yes
1645            fi
1646         elif test x$gcc_cv_as != x; then
1647             cat > conftest.s << 'EOF'
1648         .set nomacro
1649         .text
1650         extbl   $3, $2, $3      !lituse_bytoff!1
1651         ldq     $2, a($29)      !literal!1
1652         ldq     $4, b($29)      !literal!2
1653         ldq_u   $3, 0($2)       !lituse_base!1
1654         ldq     $27, f($29)     !literal!5
1655         jsr     $26, ($27), f   !lituse_jsr!5
1656         ldah    $29, 0($26)     !gpdisp!3
1657         lda     $0, c($29)      !gprel
1658         ldah    $1, d($29)      !gprelhigh
1659         lda     $1, d($1)       !gprellow
1660         lda     $29, 0($29)     !gpdisp!3
1661 EOF
1662             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1663                 gcc_cv_as_explicit_relocs=yes
1664             else
1665                 gcc_cv_as_explicit_relocs=no
1666             fi
1667             rm -f conftest.s conftest.o
1668         fi
1669     ])
1670     if test "x$gcc_cv_as_explicit_relocs" = xyes; then
1671         AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
1672                 [Define if your assembler supports explicit relocations.])
1673     fi
1674     ;;
1675   sparc*-*-*)
1676     AC_CACHE_CHECK([assembler .register pseudo-op support],
1677         gcc_cv_as_register_pseudo_op, [
1678         gcc_cv_as_register_pseudo_op=unknown
1679         if test x$gcc_cv_as != x; then
1680             # Check if we have .register
1681             echo ".register %g2, #scratch" > conftest.s
1682             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1683                 gcc_cv_as_register_pseudo_op=yes
1684             else
1685                 gcc_cv_as_register_pseudo_op=no
1686             fi
1687             rm -f conftest.s conftest.o
1688         fi
1689     ])
1690     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1691         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1692                 [Define if your assembler supports .register.])
1693     fi
1694
1695     AC_CACHE_CHECK([assembler supports -relax],
1696         gcc_cv_as_relax_opt, [
1697         gcc_cv_as_relax_opt=unknown
1698         if test x$gcc_cv_as != x; then
1699             # Check if gas supports -relax
1700             echo ".text" > conftest.s
1701             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1702                 gcc_cv_as_relax_opt=yes
1703             else
1704                 gcc_cv_as_relax_opt=no
1705             fi
1706             rm -f conftest.s conftest.o
1707         fi
1708     ])
1709     if test "x$gcc_cv_as_relax_opt" = xyes; then
1710         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1711                 [Define if your assembler supports -relax option.])
1712     fi
1713
1714     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
1715         gcc_cv_as_sparc_ua_pcrel, [
1716         gcc_cv_as_sparc_ua_pcrel=unknown
1717         if test x$gcc_cv_as != x -a x$gcc_cv_ld != x; then
1718             gcc_cv_as_sparc_ua_pcrel=no
1719             echo ".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo)" > conftest.s
1720             if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1; then
1721                 if $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
1722                     gcc_cv_as_sparc_ua_pcrel=yes
1723                 fi
1724             fi
1725             rm -f conftest.s conftest.o conftest
1726         fi
1727     ])
1728     if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
1729         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
1730                 [Define if your assembler and linker support unaligned PC relative relocs.])
1731     fi
1732
1733     case "$tm_file" in
1734     *64*)
1735         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1736             gcc_cv_as_flags64, [
1737                 if test -n "$gcc_cv_as"; then
1738                     echo ".xword foo" > conftest.s
1739                     gcc_cv_as_flags64=no
1740                     for flag in "-xarch=v9" "-64 -Av9"; do
1741                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1742                             > /dev/null 2>&1; then
1743                             gcc_cv_as_flags64=$flag
1744                             break
1745                         fi
1746                     done
1747                     rm -f conftest.s conftest.o
1748                 else
1749                     if test "$gas" = yes; then
1750                         gcc_cv_as_flags64="-64 -Av9"
1751                     else
1752                         gcc_cv_as_flags64="-xarch=v9"
1753                     fi
1754                 fi
1755         ])
1756         if test "x$gcc_cv_as_flags64" = xno; then
1757 changequote(, )
1758             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1759             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1760 changequote([, ])
1761         else
1762             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1763                         [Define if the assembler supports 64bit sparc.])
1764         fi
1765         ;;
1766     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1767         ;;
1768     esac
1769
1770     if test "x$gcc_cv_as_flags64" != xno; then
1771         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1772             gcc_cv_as_offsetable_lo10, [
1773             gcc_cv_as_offsetable_lo10=unknown
1774             if test "x$gcc_cv_as" != x; then
1775                 # Check if assembler has offsetable %lo()
1776                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1777                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1778                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1779                         > /dev/null 2>&1 &&
1780                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1781                         > /dev/null 2>&1; then
1782                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1783                         gcc_cv_as_offsetable_lo10=no
1784                     else
1785                         gcc_cv_as_offsetable_lo10=yes
1786                     fi
1787                 else
1788                     gcc_cv_as_offsetable_lo10=no
1789                 fi
1790                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1791             fi
1792         ])
1793         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1794             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1795                 [Define if your assembler supports offsetable %lo().])
1796         fi
1797     fi
1798
1799     ;;
1800
1801 changequote(,)dnl
1802   i[34567]86-*-* | x86_64-*-*)
1803 changequote([,])dnl
1804     AC_MSG_CHECKING(assembler instructions)
1805     gcc_cv_as_instructions=
1806     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1807       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1808         gcc_cv_as_instructions="filds fists"
1809       fi
1810     elif test x$gcc_cv_as != x; then
1811         set "filds fists" "filds mem; fists mem"
1812         while test $# -gt 0
1813         do
1814                 echo "$2" > conftest.s
1815                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1816                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1817                 fi
1818                 shift 2
1819         done
1820         rm -f conftest.s conftest.o
1821     fi
1822     if test x"$gcc_cv_as_instructions" != x; then
1823         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1824     fi
1825     AC_MSG_RESULT($gcc_cv_as_instructions)
1826
1827     AC_MSG_CHECKING(assembler GOTOFF in data directives)
1828     gcc_cv_as_gotoff_in_data=no
1829     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x
1830     then
1831       if test "$gcc_cv_gas_major_version" -eq 2 \
1832          -a "$gcc_cv_gas_minor_version" -ge 11 \
1833          -o "$gcc_cv_gas_major_version" -gt 2; then
1834         gcc_cv_as_gotoff_in_data=yes
1835       fi
1836     elif test x$gcc_cv_as != x; then
1837         cat > conftest.s <<EOF
1838         .text
1839 .L0:
1840         nop
1841         .data
1842         .long .L0@GOTOFF
1843 EOF
1844         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1845           gcc_cv_as_gotoff_in_data=yes
1846         fi
1847     fi
1848     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
1849       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
1850       [Define true if the assembler supports '.long foo@GOTOFF'.])
1851     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
1852     ;;
1853 esac
1854
1855 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1856 gcc_cv_as_dwarf2_debug_line=no
1857 # ??? Not all targets support dwarf2 debug_line, even within a version
1858 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1859 # info to the output file.  So, as supported targets are added to gas 2.11,
1860 # add some instruction here to (also) show we expect this might work.
1861 # ??? Once 2.11 is released, probably need to add first known working
1862 # version to the per-target configury.
1863 case "$target" in
1864   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* | x86_64*-*-*)
1865     insn="nop"
1866     ;;
1867   ia64*-*-*)
1868     insn="nop 0"
1869     ;;
1870   esac
1871 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1872 then
1873   if test "$gcc_cv_gas_major_version" -eq 2 \
1874         -a "$gcc_cv_gas_minor_version" -ge 11 \
1875         -o "$gcc_cv_gas_major_version" -gt 2 \
1876      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1877      && test x"$insn" != x ; then
1878     gcc_cv_as_dwarf2_debug_line="yes"
1879   fi
1880 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1881         echo '  .file 1 "conftest.s"' > conftest.s
1882         echo '  .loc 1 3 0' >> conftest.s
1883         echo "  $insn" >> conftest.s
1884         # ??? This fails with non-gnu grep.
1885         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1886            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1887                 # The .debug_line file table must be in the exact order that
1888                 # we specified the files, since these indices are also used
1889                 # by DW_AT_decl_file.  Approximate this test by testing if
1890                 # the assembler bitches if the same index is assigned twice.
1891                 echo '  .file 1 "foo.s"' > conftest.s
1892                 echo '  .file 1 "bar.s"' >> conftest.s
1893                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1894                 then
1895                   gcc_cv_as_dwarf2_debug_line="no"
1896                 else
1897                   gcc_cv_as_dwarf2_debug_line="yes"
1898                 fi
1899         fi
1900         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1901 fi
1902 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1903         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1904 [Define if your assembler supports dwarf2 .file/.loc directives,
1905    and preserves file table indices exactly as given.])
1906 fi
1907 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1908
1909 AC_MSG_CHECKING(assembler --gdwarf2 support)
1910 gcc_cv_as_gdwarf2_flag=no
1911 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1912 then
1913   if test "$gcc_cv_gas_major_version" -eq 2 \
1914         -a "$gcc_cv_gas_minor_version" -ge 11 \
1915         -o "$gcc_cv_gas_major_version" -gt 2 \
1916      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1917      && test x"$insn" != x ; then
1918     gcc_cv_as_gdwarf2_debug_flag="yes"
1919   fi
1920 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1921         echo '' > conftest.s
1922         # ??? This fails with non-gnu grep.
1923         if $gcc_cv_as --gdwarf2 -o conftest.o conftest.s > /dev/null 2>&1
1924           then
1925           gcc_cv_as_gdwarf2_flag="yes"
1926         fi
1927         rm -f conftest.s conftest.o
1928 fi
1929 if test x"$gcc_cv_as_gdwarf2_flag" = xyes; then
1930         AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
1931 [Define if your assembler supports the --gdwarf2 option.])
1932 fi
1933 AC_MSG_RESULT($gcc_cv_as_gdwarf2_flag)
1934
1935 AC_MSG_CHECKING(assembler --gstabs support)
1936 gcc_cv_as_gstabs_flag=no
1937 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1938 then
1939   if test "$gcc_cv_gas_major_version" -eq 2 \
1940         -a "$gcc_cv_gas_minor_version" -ge 11 \
1941         -o "$gcc_cv_gas_major_version" -gt 2 \
1942      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1943      && test x"$insn" != x ; then
1944     gcc_cv_as_gstabs_debug_flag="yes"
1945   fi
1946 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1947         echo '' > conftest.s
1948         # ??? This fails with non-gnu grep.
1949         if $gcc_cv_as --gstabs -o conftest.o conftest.s > /dev/null 2>&1 ; then
1950           gcc_cv_as_gstabs_flag="yes"
1951         fi
1952         rm -f conftest.s conftest.o
1953 fi
1954 if test x"$gcc_cv_as_gstabs_flag" = xyes; then
1955         AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
1956 [Define if your assembler supports the --gstabs option.])
1957 fi
1958 AC_MSG_RESULT($gcc_cv_as_gstabs_flag)
1959
1960 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
1961 gcc_cv_ld_eh_frame_hdr=no
1962 if test x$gcc_cv_gld_major_version != x -a x$gcc_cv_gld_minor_version != x; then
1963   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 && grep 'EMUL = elf' ../ld/Makefile > /dev/null; then
1964     gcc_cv_ld_eh_frame_hdr=yes
1965   fi
1966 elif test x$gcc_cv_ld != x; then
1967         # Check if linker supports --eh-frame-hdr option
1968         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
1969                 gcc_cv_ld_eh_frame_hdr=yes
1970         fi
1971 fi
1972 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
1973         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
1974 [Define if your linker supports --eh-frame-hdr option.])
1975 fi
1976 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
1977
1978 if test "$prefix" != "/usr" && test "$prefix" != "/usr/local" ; then
1979   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
1980 fi
1981
1982 # Figure out what language subdirectories are present.
1983 # Look if the user specified --enable-languages="..."; if not, use
1984 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1985 # go away some day.
1986 # NB:  embedded tabs in this IF block -- do not untabify
1987 if test x"${enable_languages+set}" != xset; then
1988         if test x"${LANGUAGES+set}" = xset; then
1989                 enable_languages="${LANGUAGES}"
1990                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
1991
1992         else
1993                 enable_languages=all
1994         fi
1995 else
1996         if test x"${enable_languages}" = x ||
1997            test x"${enable_languages}" = xyes;
1998         then
1999                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2000         fi
2001 fi
2002 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2003
2004 # First scan to see if an enabled language requires some other language.
2005 # We assume that a given config-lang.in will list all the language
2006 # front ends it requires, even if some are required indirectly.
2007 for lang in ${srcdir}/*/config-lang.in ..
2008 do
2009    case $lang in
2010     ..)
2011        ;;
2012     # The odd quoting in the next line works around
2013     # an apparent bug in bash 1.12 on linux.
2014 changequote(,)dnl
2015     ${srcdir}/[*]/config-lang.in)
2016        ;;
2017     *)
2018        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2019        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2020        for other in $this_lang_requires
2021        do
2022           case ,${enable_languages}, in
2023            *,$other,*)
2024               ;;
2025            *,all,*)
2026               ;;
2027            *,$lang_alias,*)
2028               enable_languages="$enable_languages,$other"
2029               ;;
2030           esac
2031        done
2032        ;;
2033 changequote([,])dnl
2034    esac
2035 done
2036
2037 subdirs=
2038 for lang in ${srcdir}/*/config-lang.in ..
2039 do
2040         case $lang in
2041         ..) ;;
2042         # The odd quoting in the next line works around
2043         # an apparent bug in bash 1.12 on linux.
2044 changequote(,)dnl
2045         ${srcdir}/[*]/config-lang.in) ;;
2046         *)
2047           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2048           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2049           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2050           if test "x$lang_alias" = x
2051           then
2052                 echo "$lang doesn't set \$language." 1>&2
2053                 exit 1
2054           fi
2055           case ${build_by_default},${enable_languages}, in
2056           *,$lang_alias,*) add_this_lang=yes ;;
2057           no,*) add_this_lang=no ;;
2058           *,all,*) add_this_lang=yes ;;
2059           *) add_this_lang=no ;;
2060           esac
2061           if test x"${add_this_lang}" = xyes; then
2062                 case $lang in
2063                     ${srcdir}/ada/config-lang.in)
2064                         if test x$have_gnat = xyes ; then
2065                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2066                         fi
2067                         ;;
2068                     *)
2069                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2070                         ;;
2071                 esac
2072           fi
2073           ;;
2074 changequote([,])dnl
2075         esac
2076 done
2077
2078 # Make gthr-default.h if we have a thread file.
2079 gthread_flags=
2080 if test $thread_file != single; then
2081     rm -f gthr-default.h
2082     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2083     gthread_flags=-DHAVE_GTHR_DEFAULT
2084 fi
2085 AC_SUBST(gthread_flags)
2086
2087 # Find out what GC implementation we want, or may, use.
2088 AC_ARG_WITH(gc,
2089 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2090                           with the compiler],
2091 [case "$withval" in
2092   simple | page)
2093     GGC=ggc-$withval
2094     ;;
2095   *)
2096     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2097     ;;
2098 esac],
2099 [GGC=ggc-page])
2100 AC_SUBST(GGC)
2101 echo "Using $GGC for garbage collection."
2102
2103 # Use the system's zlib library.
2104 zlibdir=-L../zlib
2105 zlibinc="-I\$(srcdir)/../zlib"
2106 AC_ARG_WITH(system-zlib,
2107 [  --with-system-zlib      use installed libz],
2108 zlibdir=
2109 zlibinc=
2110 )
2111 AC_SUBST(zlibdir)
2112 AC_SUBST(zlibinc)
2113
2114 dnl Very limited version of automake's enable-maintainer-mode
2115
2116 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2117   dnl maintainer-mode is disabled by default
2118   AC_ARG_ENABLE(maintainer-mode,
2119 [  --enable-maintainer-mode
2120                           enable make rules and dependencies not useful
2121                           (and sometimes confusing) to the casual installer],
2122       maintainer_mode=$enableval,
2123       maintainer_mode=no)
2124
2125 AC_MSG_RESULT($maintainer_mode)
2126
2127 if test "$maintainer_mode" = "yes"; then
2128   MAINT=''
2129 else
2130   MAINT='#'
2131 fi
2132 AC_SUBST(MAINT)dnl
2133
2134 # With Setjmp/Longjmp based exception handling.
2135 AC_ARG_ENABLE(sjlj-exceptions,
2136 [  --enable-sjlj-exceptions
2137                           arrange to use setjmp/longjmp exception handling],
2138 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
2139 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
2140   [Define 0/1 to force the choice for exception handling model.])])
2141
2142 # Make empty files to contain the specs and options for each language.
2143 # Then add #include lines to for a compiler that has specs and/or options.
2144
2145 lang_specs_files=
2146 lang_options_files=
2147 lang_tree_files=
2148 for subdir in . $subdirs
2149 do
2150         if test -f $srcdir/$subdir/lang-specs.h; then
2151             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2152         fi
2153         if test -f $srcdir/$subdir/lang-options.h; then
2154             lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
2155         fi
2156         if test -f $srcdir/$subdir/$subdir-tree.def; then
2157             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2158         fi
2159 done
2160
2161 # These (without "all_") are set in each config-lang.in.
2162 # `language' must be a single word so is spelled singularly.
2163 all_languages=
2164 all_boot_languages=
2165 all_compilers=
2166 all_stagestuff=
2167 all_outputs='Makefile intl/Makefile fixinc/Makefile gccbug mklibgcc'
2168 # List of language makefile fragments.
2169 all_lang_makefiles=
2170
2171 # Add the language fragments.
2172 # Languages are added via two mechanisms.  Some information must be
2173 # recorded in makefile variables, these are defined in config-lang.in.
2174 # We accumulate them and plug them into the main Makefile.
2175 # The other mechanism is a set of hooks for each of the main targets
2176 # like `clean', `install', etc.
2177
2178 language_fragments="Make-lang"
2179 language_hooks="Make-hooks"
2180
2181 for s in .. $subdirs
2182 do
2183         if test $s != ".."
2184         then
2185                 language=
2186                 boot_language=
2187                 compilers=
2188                 stagestuff=
2189                 outputs=
2190                 . ${srcdir}/$s/config-lang.in
2191                 if test "x$language" = x
2192                 then
2193                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2194                         exit 1
2195                 fi
2196                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
2197                 if test -f ${srcdir}/$s/Makefile.in
2198                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
2199                 fi
2200                 all_languages="$all_languages $language"
2201                 if test "x$boot_language" = xyes
2202                 then
2203                         all_boot_languages="$all_boot_languages $language"
2204                 fi
2205                 all_compilers="$all_compilers $compilers"
2206                 all_stagestuff="$all_stagestuff $stagestuff"
2207                 all_outputs="$all_outputs $outputs"
2208         fi
2209 done
2210
2211 check_languages=
2212 for language in .. $all_languages
2213 do
2214         if test $language != ".."
2215         then
2216                 check_languages="$check_languages check-$language"
2217         fi
2218 done
2219
2220 # Since we can't use `::' targets, we link each language in
2221 # with a set of hooks, reached indirectly via lang.${target}.
2222
2223 rm -f Make-hooks
2224 touch Make-hooks
2225 target_list="all.build all.cross start.encap rest.encap \
2226         info dvi generated-manpages \
2227         install-normal install-common install-info install-man \
2228         uninstall \
2229         mostlyclean clean distclean extraclean maintainer-clean \
2230         stage1 stage2 stage3 stage4"
2231 for t in $target_list
2232 do
2233         x=
2234         for lang in .. $all_languages
2235         do
2236                 if test $lang != ".."; then
2237                         x="$x $lang.$t"
2238                 fi
2239         done
2240         echo "lang.$t: $x" >> Make-hooks
2241 done
2242
2243 # Create .gdbinit.
2244
2245 echo "dir ." > .gdbinit
2246 echo "dir ${srcdir}" >> .gdbinit
2247 if test x$gdb_needs_out_file_path = xyes
2248 then
2249         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2250 fi
2251 if test "x$subdirs" != x; then
2252         for s in $subdirs
2253         do
2254                 echo "dir ${srcdir}/$s" >> .gdbinit
2255         done
2256 fi
2257 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2258
2259 # Define variables host_canonical and build_canonical
2260 # because some Cygnus local changes in the Makefile depend on them.
2261 build_canonical=${build}
2262 host_canonical=${host}
2263 target_subdir=
2264 if test "${host}" != "${target}" ; then
2265     target_subdir=${target_alias}/
2266 fi
2267 AC_SUBST(build_canonical)
2268 AC_SUBST(host_canonical)
2269 AC_SUBST(target_subdir)
2270
2271 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2272 # absolute path for gcc_tooldir based on inserting the number of up-directory
2273 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2274 # $(libsubdir)/@(unlibsubdir) based path.
2275 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2276 # make and thus we'd get different behavior depending on where we built the
2277 # sources.
2278 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2279     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2280 else
2281 changequote(<<, >>)dnl
2282 # An explanation of the sed strings:
2283 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2284 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2285 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2286 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2287 #
2288 # (*) Note this pattern overwrites the first character of the string
2289 # with a forward slash if one is not already present.  This is not a
2290 # problem because the exact names of the sub-directories concerned is
2291 # unimportant, just the number of them matters.
2292 #
2293 # The practical upshot of these patterns is like this:
2294 #
2295 #  prefix     exec_prefix        result
2296 #  ------     -----------        ------
2297 #   /foo        /foo/bar          ../
2298 #   /foo/       /foo/bar          ../
2299 #   /foo        /foo/bar/         ../
2300 #   /foo/       /foo/bar/         ../
2301 #   /foo        /foo/bar/ugg      ../../
2302 #
2303     dollar='$$'
2304     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2305 changequote([, ])dnl
2306 fi
2307 AC_SUBST(gcc_tooldir)
2308 AC_SUBST(dollar)
2309
2310 # Find a directory in which to install a shared libgcc.
2311
2312 AC_ARG_ENABLE(version-specific-runtime-libs,
2313 [  --enable-version-specific-runtime-libs
2314                           specify that runtime libraries should be
2315                           installed in a compiler-specific directory])
2316
2317 AC_ARG_WITH(slibdir,
2318 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2319 slibdir="$with_slibdir",
2320 if test "${enable_version_specific_runtime_libs+set}" = set; then
2321   slibdir='$(libsubdir)'
2322 elif test "$host" != "$target"; then
2323   slibdir='$(build_tooldir)/lib'
2324 else
2325   slibdir='$(libdir)'
2326 fi)
2327 AC_SUBST(slibdir)
2328
2329 # Nothing to do for FLOAT_H, float_format already handled.
2330 objdir=`pwd`
2331 AC_SUBST(objdir)
2332
2333 # Process the language and host/target makefile fragments.
2334 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2335
2336 # Substitute configuration variables
2337 AC_SUBST(subdirs)
2338 AC_SUBST(all_boot_languages)
2339 AC_SUBST(all_compilers)
2340 AC_SUBST(all_lang_makefiles)
2341 AC_SUBST(all_languages)
2342 AC_SUBST(all_stagestuff)
2343 AC_SUBST(build_exeext)
2344 AC_SUBST(build_install_headers_dir)
2345 AC_SUBST(build_xm_file_list)
2346 AC_SUBST(build_xm_file)
2347 AC_SUBST(build_xm_defines)
2348 AC_SUBST(check_languages)
2349 AC_SUBST(cc_set_by_configure)
2350 AC_SUBST(quoted_cc_set_by_configure)
2351 AC_SUBST(cpp_install_dir)
2352 AC_SUBST(dep_host_xmake_file)
2353 AC_SUBST(dep_tmake_file)
2354 AC_SUBST(extra_headers_list)
2355 AC_SUBST(extra_objs)
2356 AC_SUBST(extra_parts)
2357 AC_SUBST(extra_passes)
2358 AC_SUBST(extra_programs)
2359 AC_SUBST(float_h_file)
2360 AC_SUBST(gcc_config_arguments)
2361 AC_SUBST(gcc_gxx_include_dir)
2362 AC_SUBST(libstdcxx_incdir)
2363 AC_SUBST(gcc_version)
2364 AC_SUBST(gcc_version_full)
2365 AC_SUBST(gcc_version_trigger)
2366 AC_SUBST(host_exeext)
2367 AC_SUBST(host_extra_gcc_objs)
2368 AC_SUBST(host_xm_file_list)
2369 AC_SUBST(host_xm_file)
2370 AC_SUBST(host_xm_defines)
2371 AC_SUBST(install)
2372 AC_SUBST(lang_options_files)
2373 AC_SUBST(lang_specs_files)
2374 AC_SUBST(lang_tree_files)
2375 AC_SUBST(local_prefix)
2376 AC_SUBST(md_file)
2377 AC_SUBST(objc_boehm_gc)
2378 AC_SUBST(out_file)
2379 AC_SUBST(out_object_file)
2380 AC_SUBST(stage_prefix_set_by_configure)
2381 AC_SUBST(quoted_stage_prefix_set_by_configure)
2382 AC_SUBST(symbolic_link)
2383 AC_SUBST(thread_file)
2384 AC_SUBST(tm_file_list)
2385 AC_SUBST(tm_file)
2386 AC_SUBST(tm_p_file_list)
2387 AC_SUBST(tm_p_file)
2388 AC_SUBST(xm_file)
2389 AC_SUBST(xm_defines)
2390 AC_SUBST(target_alias)
2391 AC_SUBST(c_target_objs)
2392 AC_SUBST(cxx_target_objs)
2393 AC_SUBST(target_cpu_default)
2394
2395 AC_SUBST_FILE(target_overrides)
2396 AC_SUBST_FILE(host_overrides)
2397 AC_SUBST_FILE(language_fragments)
2398 AC_SUBST_FILE(language_hooks)
2399
2400 # Echo that links are built
2401 if test x$host = x$target
2402 then
2403         str1="native "
2404 else
2405         str1="cross-"
2406         str2=" from $host"
2407 fi
2408
2409 if test x$host != x$build
2410 then
2411         str3=" on a $build system"
2412 fi
2413
2414 if test "x$str2" != x || test "x$str3" != x
2415 then
2416         str4=
2417 fi
2418
2419 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2420
2421 if test "x$str2" != x || test "x$str3" != x
2422 then
2423         echo " ${str2}${str3}." 1>&2
2424 fi
2425
2426 # Truncate the target if necessary
2427 if test x$host_truncate_target != x; then
2428         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2429 fi
2430
2431 # Configure the subdirectories
2432 # AC_CONFIG_SUBDIRS($subdirs)
2433
2434 # Create the Makefile
2435 # and configure language subdirectories
2436 AC_OUTPUT($all_outputs,
2437 [
2438 case x$CONFIG_HEADERS in
2439 xauto-host.h:config.in)
2440 echo > cstamp-h ;;
2441 esac
2442 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2443 # bootstrapping and the installation procedure can still use
2444 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2445 # FLAGS_TO_PASS has been modified to solve the problem there.
2446 # This is virtually a duplicate of what happens in configure.lang; we do
2447 # an extra check to make sure this only happens if ln -s can be used.
2448 if test "$symbolic_link" = "ln -s"; then
2449  for d in .. ${subdirs} fixinc ; do
2450    if test $d != ..; then
2451         STARTDIR=`pwd`
2452         cd $d
2453         for t in stage1 stage2 stage3 stage4 include
2454         do
2455                 rm -f $t
2456                 $symbolic_link ../$t $t 2>/dev/null
2457         done
2458         cd $STARTDIR
2459    fi
2460  done
2461 else true ; fi
2462 # Avoid having to add intl to our include paths.
2463 if test -f intl/libintl.h; then
2464   echo creating libintl.h
2465   echo '#include "intl/libintl.h"' >libintl.h
2466 fi
2467 ],
2468 [subdirs='$subdirs'
2469 symbolic_link='$symbolic_link'
2470 ])