gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Set program_transform_name
 339 AC_ARG_PROGRAM
 340
 341 # Find the native compiler
 342 AC_PROG_CC
 343 AC_PROG_CC_C_O
 344 # autoconf is lame and doesn't give us any substitution variable for this.
 345 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 346   NO_MINUS_C_MINUS_O=yes
 347 else
 348   OUTPUT_OPTION='-o $@'
 349 fi
 350 AC_SUBST(NO_MINUS_C_MINUS_O)
 351 AC_SUBST(OUTPUT_OPTION)
 352
 353 # See if GNAT has been installed
 354 gcc_AC_PROG_GNAT
 355
 356 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 357 ac_cv_prog_cc_no_long_long,
 358 [save_CFLAGS="$CFLAGS"
 359 CFLAGS="-Wno-long-long"
 360 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 361                ac_cv_prog_cc_no_long_long=no)
 362 CFLAGS="$save_CFLAGS"])
 363
 364 if test x$have_gnat != xno ; then
 365 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
 366 ac_cv_prog_adac_no_long_long,
 367 [cat >conftest.adb <<EOF
 368 procedure conftest is begin null; end conftest;
 369 EOF
 370 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
 371   ac_cv_prog_adac_no_long_long=yes
 372 else
 373   ac_cv_prog_adac_no_long_long=no
 374 fi
 375 rm -f conftest*])
 376 else
 377   ac_cv_prog_adac_no_long_long=yes
 378 fi
 379
 380 strict1_warn=
 381 if test $ac_cv_prog_cc_no_long_long = yes && \
 382     test $ac_cv_prog_adac_no_long_long = yes ; then
 383   strict1_warn="-pedantic -Wno-long-long"
 384 fi
 385 AC_SUBST(strict1_warn)
 386
 387 AC_PROG_CPP
 388 AC_C_INLINE
 389 gcc_AC_C_VOLATILE
 390
 391 gcc_AC_C_LONG_DOUBLE
 392 gcc_AC_C_LONG_LONG
 393 gcc_AC_C__BOOL
 394
 395 # sizeof(char) is 1 by definition.
 396 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 397 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 398 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 399 if test $ac_cv_c_long_long = yes; then
 400   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 401 fi
 402 if test $ac_cv_c___int64 = yes; then
 403   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 404 fi
 405
 406 gcc_AC_C_CHARSET
 407
 408 # If the native compiler is GCC, we can enable warnings even in stage1.
 409 # That's useful for people building cross-compilers, or just running a
 410 # quick `make'.
 411 warn_cflags=
 412 if test "x$GCC" = "xyes"; then
 413   warn_cflags='$(GCC_WARN_CFLAGS)'
 414 fi
 415 AC_SUBST(warn_cflags)
 416
 417 # Stage specific cflags for build.
 418 stage1_cflags=
 419 case $build in
 420 vax-*-*)
 421   if test x$GCC = xyes
 422   then
 423     stage1_cflags="-Wa,-J"
 424   else
 425     stage1_cflags="-J"
 426   fi
 427   ;;
 428 powerpc-*-darwin*)
 429   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 430   # sources; use -no-cpp-precomp to get to GNU cpp.
 431   # Apple's GCC has bugs in designated initializer handling, so disable
 432   # that too.
 433   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 434   ;;
 435 esac
 436 AC_SUBST(stage1_cflags)
 437
 438 AC_PROG_MAKE_SET
 439
 440 AC_MSG_CHECKING([whether a default assembler was specified])
 441 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 442     if test x"$gas_flag" = x"no"; then
 443         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 444     else
 445         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 446     fi
 447 else
 448     AC_MSG_RESULT(no)
 449 fi
 450
 451 AC_MSG_CHECKING([whether a default linker was specified])
 452 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 453     if test x"$gnu_ld_flag" = x"no"; then
 454         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 455     else
 456         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 457     fi
 458 else
 459     AC_MSG_RESULT(no)
 460 fi
 461
 462 AC_MSG_CHECKING(for GNU C library)
 463 AC_CACHE_VAL(gcc_cv_glibc,
 464 [AC_TRY_COMPILE(
 465   [#include <features.h>],[
 466 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 467 #error Not a GNU C library system
 468 #endif],
 469   [gcc_cv_glibc=yes],
 470   gcc_cv_glibc=no)])
 471 AC_MSG_RESULT($gcc_cv_glibc)
 472 if test $gcc_cv_glibc = yes; then
 473   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 474 fi
 475
 476 # Find some useful tools
 477 AC_PROG_AWK
 478 gcc_AC_PROG_LN
 479 gcc_AC_PROG_LN_S
 480 AC_PROG_RANLIB
 481 gcc_AC_PROG_INSTALL
 482
 483 AC_HEADER_STDC
 484 AC_HEADER_TIME
 485 gcc_AC_HEADER_STDBOOL
 486 gcc_AC_HEADER_STRING
 487 AC_HEADER_SYS_WAIT
 488 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 489                  fcntl.h unistd.h sys/file.h sys/time.h \
 490                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 491                  direct.h malloc.h langinfo.h)
 492
 493 # Check for thread headers.
 494 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 495 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 496
 497 # These tests can't be done till we know if we have limits.h.
 498 gcc_AC_C_CHAR_BIT
 499 gcc_AC_C_COMPILE_ENDIAN
 500 gcc_AC_C_FLOAT_FORMAT
 501
 502 # See if we have the mktemp command.
 503 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 504
 505 # Do we have a single-tree copy of texinfo?
 506 if test -f $srcdir/../texinfo/Makefile.in; then
 507   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 508   gcc_cv_prog_makeinfo_modern=yes
 509   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 510 else
 511   # See if makeinfo has been installed and is modern enough
 512   # that we can use it.
 513   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 514   [GNU texinfo.* \([0-9][0-9.]*\)],
 515   [4.[1-9]*])
 516 fi
 517
 518 if test $gcc_cv_prog_makeinfo_modern = no; then
 519   AC_MSG_WARN([
 520 *** Makeinfo is missing or too old.
 521 *** Info documentation will not be built.])
 522   BUILD_INFO=
 523 else
 524   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 525 fi
 526
 527 # Is pod2man recent enough to regenerate manpages?
 528 AC_MSG_CHECKING([for recent Pod::Man])
 529 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 530   AC_MSG_RESULT(yes)
 531   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 532 else
 533   AC_MSG_RESULT(no)
 534   GENERATED_MANPAGES=
 535 fi
 536
 537 # How about lex?
 538 dnl Don't use AC_PROG_LEX; we insist on flex.
 539 dnl LEXLIB is not useful in gcc.
 540 if test -f $srcdir/../flex/skel.c; then
 541   FLEX='$(objdir)/../flex/flex'
 542 else
 543   AC_CHECK_PROG(FLEX, flex, flex, false)
 544 fi
 545
 546 # Bison?
 547 # The -L switch is so bison can find its skeleton file.
 548 if test -f $srcdir/../bison/bison.simple; then
 549   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 550 else
 551   AC_CHECK_PROG(BISON, bison, bison, false)
 552 fi
 553
 554 # These libraries may be used by collect2.
 555 # We may need a special search path to get them linked.
 556 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 557 [save_LIBS="$LIBS"
 558 for libs in '' -lld -lmld \
 559                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 560                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 561 do
 562         LIBS="$libs"
 563         AC_TRY_LINK_FUNC(ldopen,
 564                 [gcc_cv_collect2_libs="$libs"; break])
 565 done
 566 LIBS="$save_LIBS"
 567 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 568 case $gcc_cv_collect2_libs in
 569         "none required")        ;;
 570         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 571 esac
 572 AC_SUBST(COLLECT2_LIBS)
 573
 574 # When building Ada code on Alpha, we need exc_resume which is usually in
 575 # -lexc.  So test for it.
 576 save_LIBS="$LIBS"
 577 LIBS=
 578 AC_SEARCH_LIBS(exc_resume, exc)
 579 GNAT_LIBEXC="$LIBS"
 580 LIBS="$save_LIBS"
 581 AC_SUBST(GNAT_LIBEXC)
 582
 583 # See if the stage1 system preprocessor understands the ANSI C
 584 # preprocessor stringification operator.  (Used by symcat.h.)
 585 AC_C_STRINGIZE
 586
 587 # Use <inttypes.h> only if it exists,
 588 # doesn't clash with <sys/types.h>, and declares intmax_t.
 589 AC_MSG_CHECKING(for inttypes.h)
 590 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 591 [AC_TRY_COMPILE(
 592   [#include <sys/types.h>
 593 #include <inttypes.h>],
 594   [intmax_t i = -1;],
 595   [gcc_cv_header_inttypes_h=yes],
 596   gcc_cv_header_inttypes_h=no)])
 597 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 598 if test $gcc_cv_header_inttypes_h = yes; then
 599   AC_DEFINE(HAVE_INTTYPES_H, 1,
 600         [Define if you have a working <inttypes.h> header file.])
 601 fi
 602
 603 dnl Disabled until we have a complete test for buggy enum bitfields.
 604 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 605
 606 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 607         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 608         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo lstat)
 609
 610 AC_CHECK_TYPE(ssize_t, int)
 611
 612 # Try to determine the array type of the second argument of getgroups
 613 # for the target system (int or gid_t).
 614 AC_TYPE_GETGROUPS
 615 if test "${target}" = "${build}"; then
 616   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 617 else
 618   case "${target}" in
 619         # This condition may need some tweaking.  It should include all
 620         # targets where the array type of the second argument of getgroups
 621         # is int and the type of gid_t is not equivalent to int.
 622         *-*-sunos* | *-*-ultrix*)
 623                 TARGET_GETGROUPS_T=int
 624                 ;;
 625         *)
 626                 TARGET_GETGROUPS_T=gid_t
 627                 ;;
 628   esac
 629 fi
 630 AC_SUBST(TARGET_GETGROUPS_T)
 631
 632 gcc_AC_FUNC_PRINTF_PTR
 633
 634 case "${host}" in
 635 *-*-uwin*)
 636   AC_MSG_ERROR([
 637 *** UWIN may not be used as a host platform because
 638 *** linking with posix.dll is not allowed by the GNU GPL])
 639   ;;
 640 *-*-*vms*)
 641   # Under VMS, vfork works very different than on Unix. The standard test
 642   # won't work, and it isn't easily adaptable. It makes more sense to
 643   # just force it.
 644   ac_cv_func_vfork_works=yes
 645   ;;
 646 esac
 647 AC_FUNC_VFORK
 648 AC_FUNC_MMAP_ANYWHERE
 649 AC_FUNC_MMAP_FILE
 650
 651 AM_ICONV
 652
 653 # We will need to find libiberty.h and ansidecl.h
 654 saved_CFLAGS="$CFLAGS"
 655 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 656 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 657         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 658         fprintf_unlocked strstr errno \
 659         malloc realloc calloc free basename getopt clock, , ,[
 660 #include "ansidecl.h"
 661 #include "system.h"])
 662
 663 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 664 #include "ansidecl.h"
 665 #include "system.h"
 666 #ifdef HAVE_SYS_RESOURCE_H
 667 #include <sys/resource.h>
 668 #endif
 669 ])
 670
 671 gcc_AC_CHECK_DECLS(times, , ,[
 672 #include "ansidecl.h"
 673 #include "system.h"
 674 #ifdef HAVE_SYS_TIMES_H
 675 #include <sys/times.h>
 676 #endif
 677 ])
 678
 679 # More time-related stuff.
 680 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 681 AC_TRY_COMPILE([
 682 #include "ansidecl.h"
 683 #include "system.h"
 684 #ifdef HAVE_SYS_TIMES_H
 685 #include <sys/times.h>
 686 #endif
 687 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 688 if test $ac_cv_struct_tms = yes; then
 689   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 690   [Define if <sys/times.h> defines struct tms.])
 691 fi
 692
 693 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 694 # revisit after autoconf 2.50.
 695 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 696 AC_TRY_COMPILE([
 697 #include "ansidecl.h"
 698 #include "system.h"
 699 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 700 if test $gcc_cv_type_clock_t = yes; then
 701   AC_DEFINE(HAVE_CLOCK_T, 1,
 702   [Define if <time.h> defines clock_t.])
 703 fi
 704
 705 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 706 CFLAGS="$saved_CFLAGS"
 707
 708 # mkdir takes a single argument on some systems.
 709 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 710
 711 # File extensions
 712 manext='.1'
 713 objext='.o'
 714 AC_SUBST(manext)
 715 AC_SUBST(objext)
 716
 717 build_xm_file=
 718 build_xm_defines=
 719 build_install_headers_dir=install-headers-tar
 720 build_exeext=
 721 host_xm_file=
 722 host_xm_defines=
 723 host_xmake_file=
 724 host_truncate_target=
 725 host_exeext=
 726
 727 # Decode the host machine, then the target machine.
 728 # For the host machine, we save the xm_file variable as host_xm_file;
 729 # then we decode the target machine and forget everything else
 730 # that came from the host machine.
 731 for machine in $build $host $target; do
 732         . ${srcdir}/config.gcc
 733 done
 734
 735 extra_objs="${host_extra_objs} ${extra_objs}"
 736
 737 # Default the target-machine variables that were not explicitly set.
 738 if test x"$tm_file" = x
 739 then tm_file=$cpu_type/$cpu_type.h; fi
 740
 741 if test x"$extra_headers" = x
 742 then extra_headers=; fi
 743
 744 if test x$md_file = x
 745 then md_file=$cpu_type/$cpu_type.md; fi
 746
 747 if test x$out_file = x
 748 then out_file=$cpu_type/$cpu_type.c; fi
 749
 750 if test x"$tmake_file" = x
 751 then tmake_file=$cpu_type/t-$cpu_type
 752 fi
 753
 754 if test x"$dwarf2" = xyes
 755 then tm_file="$tm_file tm-dwarf2.h"
 756 fi
 757
 758 if test x$float_format = x
 759 then float_format=i64
 760 fi
 761
 762 if test $float_format = none
 763 then float_h_file=Makefile.in
 764 else float_h_file=float-$float_format.h
 765 fi
 766
 767 # Handle cpp installation.
 768 if test x$enable_cpp != xno
 769 then
 770   tmake_file="$tmake_file t-install-cpp"
 771 fi
 772
 773 # Say what files are being used for the output code and MD file.
 774 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 775 echo "Using \`$srcdir/config/$md_file' as machine description file."
 776
 777 # If any of the xm_file variables contain nonexistent files, warn
 778 # about them and drop them.
 779
 780 bx=
 781 for x in $build_xm_file; do
 782   if    test -f $srcdir/config/$x
 783   then      bx="$bx $x"
 784   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 785   fi
 786 done
 787 build_xm_file="$bx"
 788
 789 hx=
 790 for x in $host_xm_file; do
 791   if    test -f $srcdir/config/$x
 792   then      hx="$hx $x"
 793   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 794   fi
 795 done
 796 host_xm_file="$hx"
 797
 798 tx=
 799 for x in $xm_file; do
 800   if    test -f $srcdir/config/$x
 801   then      tx="$tx $x"
 802   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 803   fi
 804 done
 805 xm_file="$tx"
 806
 807 count=a
 808 for f in $tm_file; do
 809         count=${count}x
 810 done
 811 if test $count = ax; then
 812         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 813 else
 814         echo "Using the following target machine macro files:"
 815         for f in $tm_file; do
 816                 echo "  $srcdir/config/$f"
 817         done
 818 fi
 819
 820 count=a
 821 for f in $host_xm_file; do
 822         count=${count}x
 823 done
 824 if test $count = a; then
 825         :
 826 elif test $count = ax; then
 827         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 828 else
 829         echo "Using the following host machine macro files:"
 830         for f in $host_xm_file; do
 831                 echo "  $srcdir/config/$f"
 832         done
 833 fi
 834
 835 if test "$host_xm_file" != "$build_xm_file"; then
 836         count=a
 837         for f in $build_xm_file; do
 838                 count=${count}x
 839         done
 840         if test $count = a; then
 841                 :
 842         elif test $count = ax; then
 843                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 844         else
 845                 echo "Using the following build machine macro files:"
 846                 for f in $build_xm_file; do
 847                         echo "  $srcdir/config/$f"
 848                 done
 849         fi
 850 fi
 851
 852 if test x$thread_file = x; then
 853         if test x$target_thread_file != x; then
 854                 thread_file=$target_thread_file
 855         else
 856                 thread_file='single'
 857         fi
 858 fi
 859
 860 # auto-host.h is the file containing items generated by autoconf and is
 861 # the first file included by config.h.
 862 # If host=build, it is correct to have hconfig include auto-host.h
 863 # as well.  If host!=build, we are in error and need to do more
 864 # work to find out the build config parameters.
 865 if test x$host = x$build
 866 then
 867         build_auto=auto-host.h
 868         FORBUILD=..
 869 else
 870         # We create a subdir, then run autoconf in the subdir.
 871         # To prevent recursion we set host and build for the new
 872         # invocation of configure to the build for this invocation
 873         # of configure.
 874         tempdir=build.$$
 875         rm -rf $tempdir
 876         mkdir $tempdir
 877         cd $tempdir
 878         case ${srcdir} in
 879         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 880         *) realsrcdir=../${srcdir};;
 881         esac
 882         saved_CFLAGS="${CFLAGS}"
 883         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 884         ${realsrcdir}/configure \
 885                 --target=$target_alias --host=$build_alias --build=$build_alias
 886         CFLAGS="${saved_CFLAGS}"
 887
 888         # We just finished tests for the build machine, so rename
 889         # the file auto-build.h in the gcc directory.
 890         mv auto-host.h ../auto-build.h
 891         cd ..
 892         rm -rf $tempdir
 893         build_auto=auto-build.h
 894         FORBUILD=../$build
 895 fi
 896 AC_SUBST(FORBUILD)
 897
 898 tm_file="${tm_file} defaults.h"
 899 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 900 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 901 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 902
 903 # Truncate the target if necessary
 904 if test x$host_truncate_target != x; then
 905         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 906 fi
 907
 908 # Get the version trigger filename from the toplevel
 909 if test "${with_gcc_version_trigger+set}" = set; then
 910         gcc_version_trigger=$with_gcc_version_trigger
 911 else
 912         gcc_version_trigger=${srcdir}/version.c
 913 fi
 914 changequote(,)dnl
 915 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 916 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 917
 918 # Compile in configure arguments.
 919 if test -f configargs.h ; then
 920         # Being re-configured.
 921         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 922         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 923 else
 924         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 925 fi
 926 cat > configargs.h <<EOF
 927 /* Generated automatically. */
 928 static const char configuration_arguments[] = "$gcc_config_arguments";
 929 static const char thread_model[] = "$thread_file";
 930 EOF
 931 changequote([,])dnl
 932
 933 # Internationalization
 934 PACKAGE=gcc
 935 VERSION="$gcc_version"
 936 AC_SUBST(PACKAGE)
 937 AC_SUBST(VERSION)
 938
 939 # Enable NLS support by default
 940 AC_ARG_ENABLE(nls,
 941   [  --enable-nls            use Native Language Support (default)],
 942   , enable_nls=yes)
 943
 944 # if cross compiling, disable NLS support.
 945 # It's not worth the trouble, at least for now.
 946
 947 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 948   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 949   enable_nls=no
 950 fi
 951
 952 AM_GNU_GETTEXT
 953
 954 # Windows32 Registry support for specifying GCC installation paths.
 955 AC_ARG_ENABLE(win32-registry,
 956 [  --disable-win32-registry
 957                           disable lookup of installation paths in the
 958                           Registry on Windows hosts
 959   --enable-win32-registry enable registry lookup (default)
 960   --enable-win32-registry=KEY
 961                           use KEY instead of GCC version as the last portion
 962                           of the registry key],,)
 963 case $host_os in
 964         win32 | pe | cygwin* | mingw32* | uwin*)
 965 AC_MSG_CHECKING(whether windows registry support is requested)
 966 if test "x$enable_win32_registry" != xno; then
 967   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 968 [Define to 1 if installation paths should be looked up in Windows32
 969    Registry. Ignored on non windows32 hosts.])
 970   AC_MSG_RESULT(yes)
 971   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 972 else
 973   AC_MSG_RESULT(no)
 974 fi
 975
 976 # Check if user specified a different registry key.
 977 case "x${enable_win32_registry}" in
 978 x | xyes)
 979   # default.
 980   gcc_cv_win32_registry_key="$VERSION"
 981   ;;
 982 xno)
 983   # no registry lookup.
 984   gcc_cv_win32_registry_key=''
 985   ;;
 986 *)
 987   # user-specified key.
 988   gcc_cv_win32_registry_key="$enable_win32_registry"
 989   ;;
 990 esac
 991
 992 if test "x$enable_win32_registry" != xno; then
 993   AC_MSG_CHECKING(registry key on windows hosts)
 994   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 995         [Define to be the last portion of registry key on windows hosts.])
 996   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 997 fi
 998 ;;
 999 esac
1000
1001 # Get an absolute path to the GCC top-level source directory
1002 holddir=`pwd`
1003 cd $srcdir
1004 topdir=`pwd`
1005 cd $holddir
1006
1007 # Conditionalize the makefile for this host machine.
1008 # Make-host contains the concatenation of all host makefile fragments
1009 # [there can be more than one].  This file is built by configure.frag.
1010 host_overrides=Make-host
1011 dep_host_xmake_file=
1012 for f in .. ${host_xmake_file}
1013 do
1014         if test -f ${srcdir}/config/$f
1015         then
1016                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
1017         fi
1018 done
1019
1020 # Conditionalize the makefile for this target machine.
1021 # Make-target contains the concatenation of all host makefile fragments
1022 # [there can be more than one].  This file is built by configure.frag.
1023 target_overrides=Make-target
1024 dep_tmake_file=
1025 for f in .. ${tmake_file}
1026 do
1027         if test -f ${srcdir}/config/$f
1028         then
1029                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1030         fi
1031 done
1032
1033 # If the host doesn't support symlinks, modify CC in
1034 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1035 # Otherwise, we can use "CC=$(CC)".
1036 rm -f symtest.tem
1037 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1038 then
1039         cc_set_by_configure="\$(CC)"
1040         quoted_cc_set_by_configure="\$(CC)"
1041         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1042         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1043 else
1044         rm -f symtest.tem
1045         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1046         then
1047                 symbolic_link="cp -p"
1048         else
1049                 symbolic_link="cp"
1050         fi
1051         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1052         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1053         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1054         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1055 fi
1056 rm -f symtest.tem
1057
1058 out_object_file=`basename $out_file .c`.o
1059
1060 tm_file_list=
1061 for f in $tm_file; do
1062   case $f in
1063     ansidecl.h )
1064        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1065     defaults.h )
1066        tm_file_list="${tm_file_list} $f" ;;
1067     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1068   esac
1069 done
1070
1071 tm_p_file_list=
1072 for f in $tm_p_file; do
1073     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1074 done
1075
1076 host_xm_file_list=
1077 for f in $host_xm_file; do
1078   case $f in
1079     ansidecl.h )
1080        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1081     auto-host.h | defaults.h )
1082        host_xm_file_list="${host_xm_file_list} $f" ;;
1083     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1084   esac
1085 done
1086
1087 build_xm_file_list=
1088 for f in $build_xm_file; do
1089   case $f in
1090     ansidecl.h )
1091        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1092     auto-build.h | auto-host.h | defaults.h )
1093        build_xm_file_list="${build_xm_file_list} $f" ;;
1094     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1095   esac
1096 done
1097
1098 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1099 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1100 CROSS=                                          AC_SUBST(CROSS)
1101 ALL=all.internal                                AC_SUBST(ALL)
1102 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1103 if test x$host != x$target
1104 then
1105         CROSS="-DCROSS_COMPILE"
1106         ALL=all.cross
1107         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1108 fi
1109
1110 # If this is a cross-compiler that does not
1111 # have its own set of headers then define
1112 # inhibit_libc
1113
1114 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1115 # This prevents libgcc2 from containing any code which requires libc
1116 # support.
1117 inhibit_libc=
1118 if [test x$host != x$target] && [test x$with_headers = x]; then
1119        inhibit_libc=-Dinhibit_libc
1120 else
1121        if [test x$with_newlib = xyes]; then
1122                inhibit_libc=-Dinhibit_libc
1123        fi
1124 fi
1125 AC_SUBST(inhibit_libc)
1126
1127 # When building gcc with a cross-compiler, we need to adjust things so
1128 # that the generator programs are still built with the native compiler.
1129 # Also, we cannot run fixincludes or fix-header.
1130 # Note that the terminology here is wrong; it should be BUILD_* throughout.
1131 # FIXME.
1132
1133 # These are the normal (build=host) settings:
1134 HOST_PREFIX=                    AC_SUBST(HOST_PREFIX)
1135 HOST_PREFIX_1=ignore-           AC_SUBST(HOST_PREFIX_1)
1136 HOST_CC='$(CC)'                 AC_SUBST(HOST_CC)
1137 HOST_CFLAGS='$(ALL_CFLAGS)'     AC_SUBST(HOST_CFLAGS)
1138
1139 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1140 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1141
1142 # And these apply if build != host.
1143 if test x$build != x$host
1144 then
1145     HOST_PREFIX=build-
1146     HOST_PREFIX_1=build-
1147     HOST_CC='$(CC_FOR_BUILD)'
1148     HOST_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD) $(XCFLAGS)'
1149
1150     STMP_FIXINC=
1151     STMP_FIXPROTO=
1152 fi
1153
1154 # Expand extra_headers to include complete path.
1155 # This substitutes for lots of t-* files.
1156 extra_headers_list=
1157 if test "x$extra_headers" = x
1158 then true
1159 else
1160         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1161         for file in $extra_headers;
1162         do
1163                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1164         done
1165 fi
1166
1167 if test x$use_collect2 = xno; then
1168         use_collect2=
1169 fi
1170
1171 # Add a definition of USE_COLLECT2 if system wants one.
1172 if test x$use_collect2 != x
1173 then
1174         host_xm_defines="${host_xm_defines} USE_COLLECT2"
1175         xm_defines="${xm_defines} USE_COLLECT2"
1176 fi
1177
1178 # If we have gas in the build tree, make a link to it.
1179 if test -f ../gas/Makefile; then
1180         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1181 fi
1182
1183 # If we have nm and objdump in the build tree, make a link to them.
1184 if test -f ../binutils/Makefile; then
1185         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1186         rm -f objdump; $symbolic_link ../binutils/objdump$host_exeext objdump$host_exeext 2>/dev/null
1187 fi
1188
1189 # If we have ld in the build tree, make a link to it.
1190 if test -f ../ld/Makefile; then
1191         rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1192 fi
1193
1194 # Figure out what assembler we will be using.
1195 AC_MSG_CHECKING(what assembler to use)
1196 gcc_cv_as=
1197 gcc_cv_gas_major_version=
1198 gcc_cv_gas_minor_version=
1199 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1200 gcc_cv_as_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1201 if test -x "$DEFAULT_ASSEMBLER"; then
1202         gcc_cv_as="$DEFAULT_ASSEMBLER"
1203 elif test -x "$AS"; then
1204         gcc_cv_as="$AS"
1205 elif test -x as$host_exeext; then
1206         # Build using assembler in the current directory.
1207         gcc_cv_as=./as$host_exeext
1208 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1209         # Single tree build which includes gas.
1210         for f in $gcc_cv_as_bfd_srcdir/configure $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1211         do
1212 changequote(,)dnl
1213                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1214 changequote([,])dnl
1215                 if test x$gcc_cv_gas_version != x; then
1216                         break
1217                 fi
1218         done
1219 changequote(,)dnl
1220         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1221         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1222 changequote([,])dnl
1223 fi
1224
1225 if test "x$gcc_cv_as" = x; then
1226         # Search the same directories that the installed compiler will
1227         # search.  Else we may find the wrong assembler and lose.  If we
1228         # do not find a suitable assembler binary, then try the user's
1229         # path.
1230         #
1231         # Also note we have to check MD_EXEC_PREFIX before checking the
1232         # user's path.  Unfortunately, there is no good way to get at the
1233         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1234         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1235         # to be fixed as part of the make/configure rewrite too.
1236
1237         if test "x$exec_prefix" = xNONE; then
1238                 if test "x$prefix" = xNONE; then
1239                         test_prefix=/usr/local
1240                 else
1241                         test_prefix=$prefix
1242                 fi
1243         else
1244                 test_prefix=$exec_prefix
1245         fi
1246
1247         # If the loop below does not find an assembler, then use whatever
1248         # one we can find in the users's path.
1249         # user's path.
1250         if test "x$program_prefix" != xNONE; then
1251                 gcc_cv_as=${program_prefix}as$host_exeext
1252         else
1253                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1254         fi
1255
1256         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1257                    $test_prefix/lib/gcc-lib/$target_alias \
1258                    /usr/lib/gcc/$target_alias/$gcc_version \
1259                    /usr/lib/gcc/$target_alias \
1260                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1261                    $test_prefix/$target_alias/bin"
1262
1263         if test x$host = x$target; then
1264             test_dirs="$test_dirs \
1265                    /usr/libexec \
1266                    /usr/ccs/gcc \
1267                    /usr/ccs/bin \
1268                    /udk/usr/ccs/bin \
1269                    /bsd43/usr/lib/cmplrs/cc \
1270                    /usr/cross64/usr/bin \
1271                    /usr/lib/cmplrs/cc \
1272                    /sysv/usr/lib/cmplrs/cc \
1273                    /svr4/usr/lib/cmplrs/cc \
1274                    /usr/bin"
1275         fi
1276
1277         for dir in $test_dirs; do
1278                 if test -x $dir/as$host_exeext; then
1279                         gcc_cv_as=$dir/as$host_exeext
1280                         break;
1281                 fi
1282         done
1283 fi
1284 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1285   AC_MSG_RESULT("newly built gas")
1286 else
1287   AC_MSG_RESULT($gcc_cv_as)
1288 fi
1289
1290 # Figure out what linker we will be using.
1291 AC_MSG_CHECKING(what linker to use)
1292 gcc_cv_ld=
1293 gcc_cv_gld_major_version=
1294 gcc_cv_gld_minor_version=
1295 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1296 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1297 if test -x "$DEFAULT_LINKER"; then
1298         gcc_cv_ld="$DEFAULT_LINKER"
1299 elif test -x "$LD"; then
1300         gcc_cv_ld="$LD"
1301 elif test -x ld$host_exeext; then
1302         # Build using linker in the current directory.
1303         gcc_cv_ld=./ld$host_exeext
1304 elif test -f $gcc_cv_ld_gld_srcdir/configure.in -a -f ../ld/Makefile; then
1305         # Single tree build which includes ld.
1306         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1307         do
1308 changequote(,)dnl
1309                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1310 changequote([,])dnl
1311                 if test x$gcc_cv_gld_version != x; then
1312                         break
1313                 fi
1314         done
1315 changequote(,)dnl
1316         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1317         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1318 changequote([,])dnl
1319 fi
1320
1321 if test "x$gcc_cv_ld" = x; then
1322         # Search the same directories that the installed compiler will
1323         # search.  Else we may find the wrong linker and lose.  If we
1324         # do not find a suitable linker binary, then try the user's
1325         # path.
1326         #
1327         # Also note we have to check MD_EXEC_PREFIX before checking the
1328         # user's path.  Unfortunately, there is no good way to get at the
1329         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1330         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1331         # to be fixed as part of the make/configure rewrite too.
1332
1333         if test "x$exec_prefix" = xNONE; then
1334                 if test "x$prefix" = xNONE; then
1335                         test_prefix=/usr/local
1336                 else
1337                         test_prefix=$prefix
1338                 fi
1339         else
1340                 test_prefix=$exec_prefix
1341         fi
1342
1343         # If the loop below does not find an linker, then use whatever
1344         # one we can find in the users's path.
1345         # user's path.
1346         if test "x$program_prefix" != xNONE; then
1347                 gcc_cv_ld=${program_prefix}ld$host_exeext
1348         else
1349                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1350         fi
1351
1352         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1353                    $test_prefix/lib/gcc-lib/$target_alias \
1354                    /usr/lib/gcc/$target_alias/$gcc_version \
1355                    /usr/lib/gcc/$target_alias \
1356                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1357                    $test_prefix/$target_alias/bin"
1358
1359         if test x$host = x$target; then
1360             test_dirs="$test_dirs \
1361                    /usr/libexec \
1362                    /usr/ccs/gcc \
1363                    /usr/ccs/bin \
1364                    /udk/usr/ccs/bin \
1365                    /bsd43/usr/lib/cmplrs/cc \
1366                    /usr/cross64/usr/bin \
1367                    /usr/lib/cmplrs/cc \
1368                    /sysv/usr/lib/cmplrs/cc \
1369                    /svr4/usr/lib/cmplrs/cc \
1370                    /usr/bin"
1371         fi
1372
1373         for dir in $test_dirs; do
1374                 if test -x $dir/ld$host_exeext; then
1375                         gcc_cv_ld=$dir/ld$host_exeext
1376                         break;
1377                 fi
1378         done
1379 fi
1380 if test x$gcc_cv_gld_major_version != x -a x$gcc_cv_gld_minor_version != x; then
1381   AC_MSG_RESULT("newly built ld")
1382 else
1383   AC_MSG_RESULT($gcc_cv_ld)
1384 fi
1385
1386 # Figure out what nm we will be using.
1387 AC_MSG_CHECKING(what nm to use)
1388 if test -x nm$host_exeext; then
1389         gcc_cv_nm=./nm$host_exeext
1390 elif test "x$program_prefix" != xNONE; then
1391         gcc_cv_nm=${program_prefix}nm$host_exeext
1392 else
1393         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1394 fi
1395 AC_MSG_RESULT($gcc_cv_nm)
1396
1397 # Figure out what objdump we will be using.
1398 AC_MSG_CHECKING(what objdump to use)
1399 if test -x objdump$host_exeext; then
1400         gcc_cv_objdump=./objdump$host_exeext
1401 elif test "x$program_prefix" != xNONE; then
1402         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1403 else
1404         gcc_cv_objdump=`echo objdump | sed ${program_transform_name}`$host_exeext
1405 fi
1406 AC_MSG_RESULT($gcc_cv_objdump)
1407
1408 # Figure out what assembler alignment features are present.
1409 AC_MSG_CHECKING(assembler alignment features)
1410 gcc_cv_as_alignment_features=none
1411 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1412         # Gas version 2.6 and later support for .balign and .p2align.
1413         # bytes to skip when using .p2align.
1414         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1415                 gcc_cv_as_alignment_features=".balign and .p2align"
1416                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1417         fi
1418         # Gas version 2.8 and later support specifying the maximum
1419         # bytes to skip when using .p2align.
1420         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1421                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1422                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1423         fi
1424 elif test x$gcc_cv_as != x; then
1425         # Check if we have .balign and .p2align
1426         echo ".balign  4" > conftest.s
1427         echo ".p2align  2" >> conftest.s
1428         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1429                 gcc_cv_as_alignment_features=".balign and .p2align"
1430                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1431         fi
1432         rm -f conftest.s conftest.o
1433         # Check if specifying the maximum bytes to skip when
1434         # using .p2align is supported.
1435         echo ".p2align 4,,7" > conftest.s
1436         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1437                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1438                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1439         fi
1440         rm -f conftest.s conftest.o
1441 fi
1442 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1443
1444 AC_MSG_CHECKING(assembler subsection support)
1445 gcc_cv_as_subsections=no
1446 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1447   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1448     gcc_cv_as_subsections="working .subsection -1"
1449   fi
1450 elif test x$gcc_cv_as != x; then
1451         # Check if we have .subsection
1452         echo ".subsection 1" > conftest.s
1453         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1454                 gcc_cv_as_subsections=".subsection"
1455                 if test x$gcc_cv_nm != x; then
1456                         cat > conftest.s <<EOF
1457 conftest_label1: .word 0
1458 .subsection -1
1459 conftest_label2: .word 0
1460 .previous
1461 EOF
1462                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1463                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1464                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1465                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1466                                         :
1467                                 else
1468                                         gcc_cv_as_subsections="working .subsection -1"
1469                                 fi
1470                         fi
1471                 fi
1472         fi
1473         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1474 fi
1475 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1476         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1477 [Define if your assembler supports .subsection and .subsection -1 starts
1478    emitting at the beginning of your section.])
1479 fi
1480 AC_MSG_RESULT($gcc_cv_as_subsections)
1481
1482 AC_MSG_CHECKING(assembler weak support)
1483 gcc_cv_as_weak=no
1484 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1485   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1486     gcc_cv_as_weak="yes"
1487   fi
1488 elif test x$gcc_cv_as != x; then
1489         # Check if we have .weak
1490         echo "  .weak foobar" > conftest.s
1491         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1492                 gcc_cv_as_weak="yes"
1493         fi
1494         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1495 fi
1496 if test x"$gcc_cv_as_weak" = xyes; then
1497         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1498 fi
1499 AC_MSG_RESULT($gcc_cv_as_weak)
1500
1501 AC_MSG_CHECKING(assembler hidden support)
1502 gcc_cv_as_hidden=no
1503 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1504   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1505     gcc_cv_as_hidden="yes"
1506   fi
1507 elif test x$gcc_cv_as != x; then
1508         # Check if we have .hidden
1509         echo "  .hidden foobar" > conftest.s
1510         echo "foobar:" >> conftest.s
1511         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1512                 gcc_cv_as_hidden="yes"
1513         fi
1514         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1515 fi
1516 if test x"$gcc_cv_as_hidden" = xyes; then
1517         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1518                 [Define if your assembler supports .hidden.])
1519 fi
1520 AC_MSG_RESULT($gcc_cv_as_hidden)
1521 libgcc_visibility=$gcc_cv_as_hidden
1522 AC_SUBST(libgcc_visibility)
1523
1524 AC_MSG_CHECKING(assembler leb128 support)
1525 gcc_cv_as_leb128=no
1526 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1527   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1528     gcc_cv_as_leb128="yes"
1529   fi
1530 elif test x$gcc_cv_as != x; then
1531         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1532         cat > conftest.s <<EOF
1533         .data
1534         .uleb128 L2 - L1
1535 L1:
1536         .uleb128 1280
1537         .sleb128 -1010
1538 L2:
1539 EOF
1540         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1541                 gcc_cv_as_leb128="yes"
1542
1543                 # GAS versions before 2.11 do not support uleb128,
1544                 # despite appearing to.
1545                 # ??? There exists an elf-specific test that will crash
1546                 # the assembler.  Perhaps it's better to figure out whether
1547                 # arbitrary sections are supported and try the test.
1548                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1549                 if echo "$as_ver" | grep GNU > /dev/null; then
1550 changequote(,)dnl
1551                         as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1552                         as_major=`echo $as_ver | sed 's/\..*//'`
1553                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1554 changequote([,])dnl
1555                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1556                                 gcc_cv_as_leb128="no"
1557                         fi
1558                 fi
1559         fi
1560         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1561 fi
1562 if test x"$gcc_cv_as_leb128" = xyes; then
1563         AC_DEFINE(HAVE_AS_LEB128, 1,
1564                 [Define if your assembler supports .uleb128.])
1565 fi
1566 AC_MSG_RESULT($gcc_cv_as_leb128)
1567
1568 AC_MSG_CHECKING(assembler eh_frame optimization)
1569 gcc_cv_as_eh_frame=no
1570 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1571   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1572     gcc_cv_as_eh_frame="yes"
1573   fi
1574 elif test x$gcc_cv_as != x; then
1575         # Check if this is GAS.
1576         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1577         rm -f a.out 2> /dev/null
1578         if echo "$as_ver" | grep GNU > /dev/null; then
1579                 # Versions up to and including 2.11.0 may mis-optimize
1580                 # .eh_frame data.  Try something.
1581                 cat > conftest.s <<EOF
1582         .text
1583 .LFB1:
1584         .4byte  0
1585 .L1:
1586         .4byte  0
1587 .LFE1:
1588         .section        .eh_frame,"aw",@progbits
1589 __FRAME_BEGIN__:
1590         .4byte  .LECIE1-.LSCIE1
1591 .LSCIE1:
1592         .4byte  0x0
1593         .byte   0x1
1594         .ascii "z\0"
1595         .byte   0x1
1596         .byte   0x78
1597         .byte   0x1a
1598         .byte   0x0
1599         .byte   0x4
1600         .4byte  1
1601         .p2align 1
1602 .LECIE1:
1603 .LSFDE1:
1604         .4byte  .LEFDE1-.LASFDE1
1605 .LASFDE1:
1606         .4byte  .LASFDE1-__FRAME_BEGIN__
1607         .4byte  .LFB1
1608         .4byte  .LFE1-.LFB1
1609         .byte   0x4
1610         .4byte  .LFE1-.LFB1
1611         .byte   0x4
1612         .4byte  .L1-.LFB1
1613 .LEFDE1:
1614 EOF
1615                 cat > conftest.lit <<EOF
1616  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1617  0010 01000000 12000000 18000000 00000000  ................
1618  0020 08000000 04080000 0044               .........D
1619 EOF
1620                 cat > conftest.big <<EOF
1621  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1622  0010 00000001 00000012 00000018 00000000  ................
1623  0020 00000008 04000000 0844               .........D
1624 EOF
1625                 # If the assembler didn't choke, and we can objdump,
1626                 # and we got the correct data, then succeed.
1627                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1628                    && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1629                       | tail -3 > conftest.got \
1630                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1631                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1632                 then
1633                         gcc_cv_as_eh_frame="yes"
1634                 else
1635                         gcc_cv_as_eh_frame="bad"
1636                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1637                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1638         [Define if your assembler mis-optimizes .eh_frame data.])
1639                         fi
1640                 fi
1641         fi
1642         rm -f conftest.*
1643 fi
1644 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1645
1646 AC_MSG_CHECKING(assembler section merging support)
1647 gcc_cv_as_shf_merge=no
1648 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1649   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1650     gcc_cv_as_shf_merge=yes
1651   fi
1652 elif test x$gcc_cv_as != x; then
1653         # Check if we support SHF_MERGE sections
1654         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
1655         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
1656                 gcc_cv_as_shf_merge=yes
1657         fi
1658         rm -f conftest.s conftest.o
1659 fi
1660 if test x"$gcc_cv_as_shf_merge" = xyes; then
1661         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1662 [Define if your assembler supports marking sections with SHF_MERGE flag.])
1663 fi
1664 AC_MSG_RESULT($gcc_cv_as_shf_merge)
1665
1666 case "$target" in
1667   # All TARGET_ABI_OSF targets.
1668   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
1669     AC_CACHE_CHECK([assembler supports explicit relocations],
1670         gcc_cv_as_explicit_relocs, [
1671         gcc_cv_as_explicit_relocs=unknown
1672         if test x$gcc_cv_gas_major_version != x \
1673                 -a x$gcc_cv_gas_minor_version != x
1674         then
1675            if test "$gcc_cv_gas_major_version" -eq 2 \
1676                    -a "$gcc_cv_gas_minor_version" -ge 12 \
1677                    -o "$gcc_cv_gas_major_version" -gt 2; then
1678               gcc_cv_as_explicit_relocs=yes
1679            fi
1680         elif test x$gcc_cv_as != x; then
1681             cat > conftest.s << 'EOF'
1682         .set nomacro
1683         .text
1684         extbl   $3, $2, $3      !lituse_bytoff!1
1685         ldq     $2, a($29)      !literal!1
1686         ldq     $4, b($29)      !literal!2
1687         ldq_u   $3, 0($2)       !lituse_base!1
1688         ldq     $27, f($29)     !literal!5
1689         jsr     $26, ($27), f   !lituse_jsr!5
1690         ldah    $29, 0($26)     !gpdisp!3
1691         lda     $0, c($29)      !gprel
1692         ldah    $1, d($29)      !gprelhigh
1693         lda     $1, d($1)       !gprellow
1694         lda     $29, 0($29)     !gpdisp!3
1695 EOF
1696             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1697                 gcc_cv_as_explicit_relocs=yes
1698             else
1699                 gcc_cv_as_explicit_relocs=no
1700             fi
1701             rm -f conftest.s conftest.o
1702         fi
1703     ])
1704     if test "x$gcc_cv_as_explicit_relocs" = xyes; then
1705         AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
1706                 [Define if your assembler supports explicit relocations.])
1707     fi
1708     ;;
1709   sparc*-*-*)
1710     AC_CACHE_CHECK([assembler .register pseudo-op support],
1711         gcc_cv_as_register_pseudo_op, [
1712         gcc_cv_as_register_pseudo_op=unknown
1713         if test x$gcc_cv_as != x; then
1714             # Check if we have .register
1715             echo ".register %g2, #scratch" > conftest.s
1716             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1717                 gcc_cv_as_register_pseudo_op=yes
1718             else
1719                 gcc_cv_as_register_pseudo_op=no
1720             fi
1721             rm -f conftest.s conftest.o
1722         fi
1723     ])
1724     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1725         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1726                 [Define if your assembler supports .register.])
1727     fi
1728
1729     AC_CACHE_CHECK([assembler supports -relax],
1730         gcc_cv_as_relax_opt, [
1731         gcc_cv_as_relax_opt=unknown
1732         if test x$gcc_cv_as != x; then
1733             # Check if gas supports -relax
1734             echo ".text" > conftest.s
1735             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1736                 gcc_cv_as_relax_opt=yes
1737             else
1738                 gcc_cv_as_relax_opt=no
1739             fi
1740             rm -f conftest.s conftest.o
1741         fi
1742     ])
1743     if test "x$gcc_cv_as_relax_opt" = xyes; then
1744         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1745                 [Define if your assembler supports -relax option.])
1746     fi
1747
1748     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
1749         gcc_cv_as_sparc_ua_pcrel, [
1750         gcc_cv_as_sparc_ua_pcrel=unknown
1751         if test x$gcc_cv_as != x -a x$gcc_cv_ld != x; then
1752             gcc_cv_as_sparc_ua_pcrel=no
1753             echo ".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo)" > conftest.s
1754             if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1 \
1755                && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
1756                 gcc_cv_as_sparc_ua_pcrel=yes
1757             fi
1758             rm -f conftest.s conftest.o conftest
1759         fi
1760     ])
1761     if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
1762         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
1763                 [Define if your assembler and linker support unaligned PC relative relocs.])
1764     fi
1765
1766     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs against hidden symbols],
1767         gcc_cv_as_sparc_ua_pcrel_hidden, [
1768         if test "x$gcc_cv_as_sparc_ua_pcrel" = xyes; then
1769             gcc_cv_as_sparc_ua_pcrel_hidden=unknown
1770             if test x$gcc_cv_objdump != x; then
1771                 gcc_cv_as_sparc_ua_pcrel_hidden=no
1772                 echo ".data; .align 4; .byte 0x31; .uaword %r_disp32(foo)" > conftest.s
1773                 echo ".byte 0x32, 0x33, 0x34; .global foo; .hidden foo" >> conftest.s
1774                 echo "foo: .skip 4" >> conftest.s
1775                 if $gcc_cv_as -K PIC -o conftest.o conftest.s > /dev/null 2>&1 \
1776                    && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
1777                    && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
1778                       | grep ' 31000000 07323334' > /dev/null 2>&1; then
1779                     if $gcc_cv_objdump -R conftest 2> /dev/null \
1780                        | grep 'DISP32' > /dev/null 2>&1; then
1781                         :
1782                     else
1783                         gcc_cv_as_sparc_ua_pcrel_hidden=yes
1784                     fi
1785                 fi
1786             fi
1787             rm -f conftest.s conftest.o conftest
1788         else
1789             gcc_cv_as_sparc_ua_pcrel_hidden="$gcc_cv_as_sparc_ua_pcrel"
1790         fi
1791     ])
1792     if test "x$gcc_cv_as_sparc_ua_pcrel_hidden" = xyes; then
1793         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
1794                 [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])
1795     fi
1796
1797     if test "x$gcc_cv_as_flags64" != xno; then
1798         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1799             gcc_cv_as_offsetable_lo10, [
1800             gcc_cv_as_offsetable_lo10=unknown
1801             if test "x$gcc_cv_as" != x; then
1802                 # Check if assembler has offsetable %lo()
1803                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1804                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1805                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1806                         > /dev/null 2>&1 &&
1807                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1808                         > /dev/null 2>&1; then
1809                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1810                         gcc_cv_as_offsetable_lo10=no
1811                     else
1812                         gcc_cv_as_offsetable_lo10=yes
1813                     fi
1814                 else
1815                     gcc_cv_as_offsetable_lo10=no
1816                 fi
1817                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1818             fi
1819         ])
1820         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1821             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1822                 [Define if your assembler supports offsetable %lo().])
1823         fi
1824     fi
1825
1826     ;;
1827
1828 changequote(,)dnl
1829   i[34567]86-*-* | x86_64-*-*)
1830 changequote([,])dnl
1831     AC_MSG_CHECKING(assembler instructions)
1832     gcc_cv_as_instructions=
1833     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1834       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1835         gcc_cv_as_instructions="filds fists"
1836       fi
1837     elif test x$gcc_cv_as != x; then
1838         set "filds fists" "filds mem; fists mem"
1839         while test $# -gt 0
1840         do
1841                 echo "$2" > conftest.s
1842                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1843                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1844                 fi
1845                 shift 2
1846         done
1847         rm -f conftest.s conftest.o
1848     fi
1849     if test x"$gcc_cv_as_instructions" != x; then
1850         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1851     fi
1852     AC_MSG_RESULT($gcc_cv_as_instructions)
1853
1854     AC_MSG_CHECKING(assembler GOTOFF in data directives)
1855     gcc_cv_as_gotoff_in_data=no
1856     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x
1857     then
1858       if test "$gcc_cv_gas_major_version" -eq 2 \
1859          -a "$gcc_cv_gas_minor_version" -ge 11 \
1860          -o "$gcc_cv_gas_major_version" -gt 2; then
1861         gcc_cv_as_gotoff_in_data=yes
1862       fi
1863     elif test x$gcc_cv_as != x; then
1864         cat > conftest.s <<EOF
1865         .text
1866 .L0:
1867         nop
1868         .data
1869         .long .L0@GOTOFF
1870 EOF
1871         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1872           gcc_cv_as_gotoff_in_data=yes
1873         fi
1874     fi
1875     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
1876       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
1877       [Define true if the assembler supports '.long foo@GOTOFF'.])
1878     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
1879     ;;
1880 esac
1881
1882 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1883 gcc_cv_as_dwarf2_debug_line=no
1884 # ??? Not all targets support dwarf2 debug_line, even within a version
1885 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1886 # info to the output file.  So, as supported targets are added to gas 2.11,
1887 # add some instruction here to (also) show we expect this might work.
1888 # ??? Once 2.11 is released, probably need to add first known working
1889 # version to the per-target configury.
1890 case "$target" in
1891   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* | x86_64*-*-* | hppa*-*-*)
1892     insn="nop"
1893     ;;
1894   ia64*-*-*)
1895     insn="nop 0"
1896     ;;
1897   esac
1898 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1899 then
1900   if test "$gcc_cv_gas_major_version" -eq 2 \
1901         -a "$gcc_cv_gas_minor_version" -ge 11 \
1902         -o "$gcc_cv_gas_major_version" -gt 2 \
1903      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1904      && test x"$insn" != x ; then
1905     gcc_cv_as_dwarf2_debug_line="yes"
1906   fi
1907 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1908         echo '  .file 1 "conftest.s"' > conftest.s
1909         echo '  .loc 1 3 0' >> conftest.s
1910         echo "  $insn" >> conftest.s
1911         # ??? This fails with non-gnu grep.
1912         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1913            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1914                 # The .debug_line file table must be in the exact order that
1915                 # we specified the files, since these indices are also used
1916                 # by DW_AT_decl_file.  Approximate this test by testing if
1917                 # the assembler bitches if the same index is assigned twice.
1918                 echo '  .file 1 "foo.s"' > conftest.s
1919                 echo '  .file 1 "bar.s"' >> conftest.s
1920                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1921                 then
1922                   gcc_cv_as_dwarf2_debug_line="no"
1923                 else
1924                   gcc_cv_as_dwarf2_debug_line="yes"
1925                 fi
1926         fi
1927         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1928 fi
1929 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1930         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1931 [Define if your assembler supports dwarf2 .file/.loc directives,
1932    and preserves file table indices exactly as given.])
1933 fi
1934 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1935
1936 AC_MSG_CHECKING(assembler --gdwarf2 support)
1937 gcc_cv_as_gdwarf2_flag=no
1938 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1939 then
1940   if test "$gcc_cv_gas_major_version" -eq 2 \
1941         -a "$gcc_cv_gas_minor_version" -ge 11 \
1942         -o "$gcc_cv_gas_major_version" -gt 2 \
1943      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1944      && test x"$insn" != x ; then
1945     gcc_cv_as_gdwarf2_debug_flag="yes"
1946   fi
1947 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1948         echo '' > conftest.s
1949         # ??? This fails with non-gnu grep.
1950         if $gcc_cv_as --gdwarf2 -o conftest.o conftest.s > /dev/null 2>&1
1951           then
1952           gcc_cv_as_gdwarf2_flag="yes"
1953         fi
1954         rm -f conftest.s conftest.o
1955 fi
1956 if test x"$gcc_cv_as_gdwarf2_flag" = xyes; then
1957         AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
1958 [Define if your assembler supports the --gdwarf2 option.])
1959 fi
1960 AC_MSG_RESULT($gcc_cv_as_gdwarf2_flag)
1961
1962 AC_MSG_CHECKING(assembler --gstabs support)
1963 gcc_cv_as_gstabs_flag=no
1964 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1965 then
1966   if test "$gcc_cv_gas_major_version" -eq 2 \
1967         -a "$gcc_cv_gas_minor_version" -ge 11 \
1968         -o "$gcc_cv_gas_major_version" -gt 2 \
1969      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1970      && test x"$insn" != x ; then
1971     gcc_cv_as_gstabs_debug_flag="yes"
1972   fi
1973 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1974         echo '' > conftest.s
1975         # ??? This fails with non-gnu grep.
1976         if $gcc_cv_as --gstabs -o conftest.o conftest.s > /dev/null 2>&1 ; then
1977           gcc_cv_as_gstabs_flag="yes"
1978         fi
1979         rm -f conftest.s conftest.o
1980 fi
1981 if test x"$gcc_cv_as_gstabs_flag" = xyes; then
1982         AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
1983 [Define if your assembler supports the --gstabs option.])
1984 fi
1985 AC_MSG_RESULT($gcc_cv_as_gstabs_flag)
1986
1987 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
1988 gcc_cv_ld_eh_frame_hdr=no
1989 if test x$gcc_cv_gld_major_version != x -a x$gcc_cv_gld_minor_version != x; then
1990   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 && grep 'EMUL = elf' ../ld/Makefile > /dev/null; then
1991     gcc_cv_ld_eh_frame_hdr=yes
1992   fi
1993 elif test x$gcc_cv_ld != x; then
1994         # Check if linker supports --eh-frame-hdr option
1995         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
1996                 gcc_cv_ld_eh_frame_hdr=yes
1997         fi
1998 fi
1999 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2000         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2001 [Define if your linker supports --eh-frame-hdr option.])
2002 fi
2003 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2004
2005 if test "$prefix" != "/usr" && test "$prefix" != "/usr/local" ; then
2006   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
2007 fi
2008
2009 # Figure out what language subdirectories are present.
2010 # Look if the user specified --enable-languages="..."; if not, use
2011 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2012 # go away some day.
2013 # NB:  embedded tabs in this IF block -- do not untabify
2014 if test x"${enable_languages+set}" != xset; then
2015         if test x"${LANGUAGES+set}" = xset; then
2016                 enable_languages="${LANGUAGES}"
2017                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2018
2019         else
2020                 enable_languages=all
2021         fi
2022 else
2023         if test x"${enable_languages}" = x ||
2024            test x"${enable_languages}" = xyes;
2025         then
2026                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2027         fi
2028 fi
2029 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2030
2031 # First scan to see if an enabled language requires some other language.
2032 # We assume that a given config-lang.in will list all the language
2033 # front ends it requires, even if some are required indirectly.
2034 for lang in ${srcdir}/*/config-lang.in ..
2035 do
2036    case $lang in
2037     ..)
2038        ;;
2039     # The odd quoting in the next line works around
2040     # an apparent bug in bash 1.12 on linux.
2041 changequote(,)dnl
2042     ${srcdir}/[*]/config-lang.in)
2043        ;;
2044     *)
2045        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2046        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2047        for other in $this_lang_requires
2048        do
2049           case ,${enable_languages}, in
2050            *,$other,*)
2051               ;;
2052            *,all,*)
2053               ;;
2054            *,$lang_alias,*)
2055               enable_languages="$enable_languages,$other"
2056               ;;
2057           esac
2058        done
2059        ;;
2060 changequote([,])dnl
2061    esac
2062 done
2063
2064 subdirs=
2065 for lang in ${srcdir}/*/config-lang.in ..
2066 do
2067         case $lang in
2068         ..) ;;
2069         # The odd quoting in the next line works around
2070         # an apparent bug in bash 1.12 on linux.
2071 changequote(,)dnl
2072         ${srcdir}/[*]/config-lang.in) ;;
2073         *)
2074           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2075           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2076           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2077           if test "x$lang_alias" = x
2078           then
2079                 echo "$lang doesn't set \$language." 1>&2
2080                 exit 1
2081           fi
2082           case ${build_by_default},${enable_languages}, in
2083           *,$lang_alias,*) add_this_lang=yes ;;
2084           no,*) add_this_lang=no ;;
2085           *,all,*) add_this_lang=yes ;;
2086           *) add_this_lang=no ;;
2087           esac
2088           if test x"${add_this_lang}" = xyes; then
2089                 case $lang in
2090                     ${srcdir}/ada/config-lang.in)
2091                         if test x$have_gnat = xyes ; then
2092                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2093                         fi
2094                         ;;
2095                     *)
2096                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2097                         ;;
2098                 esac
2099           fi
2100           ;;
2101 changequote([,])dnl
2102         esac
2103 done
2104
2105 # Make gthr-default.h if we have a thread file.
2106 gthread_flags=
2107 if test $thread_file != single; then
2108     rm -f gthr-default.h
2109     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2110     gthread_flags=-DHAVE_GTHR_DEFAULT
2111 fi
2112 AC_SUBST(gthread_flags)
2113
2114 # Find out what GC implementation we want, or may, use.
2115 AC_ARG_WITH(gc,
2116 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2117                           with the compiler],
2118 [case "$withval" in
2119   simple | page)
2120     GGC=ggc-$withval
2121     ;;
2122   *)
2123     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2124     ;;
2125 esac],
2126 [GGC=ggc-page])
2127 AC_SUBST(GGC)
2128 echo "Using $GGC for garbage collection."
2129
2130 # Use the system's zlib library.
2131 zlibdir=-L../zlib
2132 zlibinc="-I\$(srcdir)/../zlib"
2133 AC_ARG_WITH(system-zlib,
2134 [  --with-system-zlib      use installed libz],
2135 zlibdir=
2136 zlibinc=
2137 )
2138 AC_SUBST(zlibdir)
2139 AC_SUBST(zlibinc)
2140
2141 dnl Very limited version of automake's enable-maintainer-mode
2142
2143 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2144   dnl maintainer-mode is disabled by default
2145   AC_ARG_ENABLE(maintainer-mode,
2146 [  --enable-maintainer-mode
2147                           enable make rules and dependencies not useful
2148                           (and sometimes confusing) to the casual installer],
2149       maintainer_mode=$enableval,
2150       maintainer_mode=no)
2151
2152 AC_MSG_RESULT($maintainer_mode)
2153
2154 if test "$maintainer_mode" = "yes"; then
2155   MAINT=''
2156 else
2157   MAINT='#'
2158 fi
2159 AC_SUBST(MAINT)dnl
2160
2161 # With Setjmp/Longjmp based exception handling.
2162 AC_ARG_ENABLE(sjlj-exceptions,
2163 [  --enable-sjlj-exceptions
2164                           arrange to use setjmp/longjmp exception handling],
2165 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
2166 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
2167   [Define 0/1 to force the choice for exception handling model.])])
2168
2169 # Make empty files to contain the specs and options for each language.
2170 # Then add #include lines to for a compiler that has specs and/or options.
2171
2172 lang_specs_files=
2173 lang_options_files=
2174 lang_tree_files=
2175 for subdir in . $subdirs
2176 do
2177         if test -f $srcdir/$subdir/lang-specs.h; then
2178             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2179         fi
2180         if test -f $srcdir/$subdir/lang-options.h; then
2181             lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
2182         fi
2183         if test -f $srcdir/$subdir/$subdir-tree.def; then
2184             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2185         fi
2186 done
2187
2188 # These (without "all_") are set in each config-lang.in.
2189 # `language' must be a single word so is spelled singularly.
2190 all_languages=
2191 all_boot_languages=
2192 all_compilers=
2193 all_stagestuff=
2194 all_outputs='Makefile intl/Makefile fixinc/Makefile gccbug mklibgcc'
2195 # List of language makefile fragments.
2196 all_lang_makefiles=
2197
2198 # Add the language fragments.
2199 # Languages are added via two mechanisms.  Some information must be
2200 # recorded in makefile variables, these are defined in config-lang.in.
2201 # We accumulate them and plug them into the main Makefile.
2202 # The other mechanism is a set of hooks for each of the main targets
2203 # like `clean', `install', etc.
2204
2205 language_fragments="Make-lang"
2206 language_hooks="Make-hooks"
2207
2208 for s in .. $subdirs
2209 do
2210         if test $s != ".."
2211         then
2212                 language=
2213                 boot_language=
2214                 compilers=
2215                 stagestuff=
2216                 outputs=
2217                 . ${srcdir}/$s/config-lang.in
2218                 if test "x$language" = x
2219                 then
2220                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2221                         exit 1
2222                 fi
2223                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
2224                 if test -f ${srcdir}/$s/Makefile.in
2225                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
2226                 fi
2227                 all_languages="$all_languages $language"
2228                 if test "x$boot_language" = xyes
2229                 then
2230                         all_boot_languages="$all_boot_languages $language"
2231                 fi
2232                 all_compilers="$all_compilers $compilers"
2233                 all_stagestuff="$all_stagestuff $stagestuff"
2234                 all_outputs="$all_outputs $outputs"
2235         fi
2236 done
2237
2238 check_languages=
2239 for language in .. $all_languages
2240 do
2241         if test $language != ".."
2242         then
2243                 check_languages="$check_languages check-$language"
2244         fi
2245 done
2246
2247 # Since we can't use `::' targets, we link each language in
2248 # with a set of hooks, reached indirectly via lang.${target}.
2249
2250 rm -f Make-hooks
2251 touch Make-hooks
2252 target_list="all.build all.cross start.encap rest.encap \
2253         info dvi generated-manpages \
2254         install-normal install-common install-info install-man \
2255         uninstall \
2256         mostlyclean clean distclean extraclean maintainer-clean \
2257         stage1 stage2 stage3 stage4"
2258 for t in $target_list
2259 do
2260         x=
2261         for lang in .. $all_languages
2262         do
2263                 if test $lang != ".."; then
2264                         x="$x $lang.$t"
2265                 fi
2266         done
2267         echo "lang.$t: $x" >> Make-hooks
2268 done
2269
2270 # Create .gdbinit.
2271
2272 echo "dir ." > .gdbinit
2273 echo "dir ${srcdir}" >> .gdbinit
2274 if test x$gdb_needs_out_file_path = xyes
2275 then
2276         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2277 fi
2278 if test "x$subdirs" != x; then
2279         for s in $subdirs
2280         do
2281                 echo "dir ${srcdir}/$s" >> .gdbinit
2282         done
2283 fi
2284 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2285
2286 # Define variables host_canonical and build_canonical
2287 # because some Cygnus local changes in the Makefile depend on them.
2288 build_canonical=${build}
2289 host_canonical=${host}
2290 target_subdir=
2291 if test "${host}" != "${target}" ; then
2292     target_subdir=${target_alias}/
2293 fi
2294 AC_SUBST(build_canonical)
2295 AC_SUBST(host_canonical)
2296 AC_SUBST(target_subdir)
2297
2298 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2299 # absolute path for gcc_tooldir based on inserting the number of up-directory
2300 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2301 # $(libsubdir)/@(unlibsubdir) based path.
2302 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2303 # make and thus we'd get different behavior depending on where we built the
2304 # sources.
2305 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2306     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2307 else
2308 changequote(<<, >>)dnl
2309 # An explanation of the sed strings:
2310 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2311 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2312 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2313 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2314 #
2315 # (*) Note this pattern overwrites the first character of the string
2316 # with a forward slash if one is not already present.  This is not a
2317 # problem because the exact names of the sub-directories concerned is
2318 # unimportant, just the number of them matters.
2319 #
2320 # The practical upshot of these patterns is like this:
2321 #
2322 #  prefix     exec_prefix        result
2323 #  ------     -----------        ------
2324 #   /foo        /foo/bar          ../
2325 #   /foo/       /foo/bar          ../
2326 #   /foo        /foo/bar/         ../
2327 #   /foo/       /foo/bar/         ../
2328 #   /foo        /foo/bar/ugg      ../../
2329 #
2330     dollar='$$'
2331     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2332 changequote([, ])dnl
2333 fi
2334 AC_SUBST(gcc_tooldir)
2335 AC_SUBST(dollar)
2336
2337 # Find a directory in which to install a shared libgcc.
2338
2339 AC_ARG_ENABLE(version-specific-runtime-libs,
2340 [  --enable-version-specific-runtime-libs
2341                           specify that runtime libraries should be
2342                           installed in a compiler-specific directory])
2343
2344 AC_ARG_WITH(slibdir,
2345 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2346 slibdir="$with_slibdir",
2347 if test "${enable_version_specific_runtime_libs+set}" = set; then
2348   slibdir='$(libsubdir)'
2349 elif test "$host" != "$target"; then
2350   slibdir='$(build_tooldir)/lib'
2351 else
2352   slibdir='$(libdir)'
2353 fi)
2354 AC_SUBST(slibdir)
2355
2356 # Nothing to do for FLOAT_H, float_format already handled.
2357 objdir=`pwd`
2358 AC_SUBST(objdir)
2359
2360 # Process the language and host/target makefile fragments.
2361 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2362
2363 # Substitute configuration variables
2364 AC_SUBST(subdirs)
2365 AC_SUBST(all_boot_languages)
2366 AC_SUBST(all_compilers)
2367 AC_SUBST(all_lang_makefiles)
2368 AC_SUBST(all_languages)
2369 AC_SUBST(all_stagestuff)
2370 AC_SUBST(build_exeext)
2371 AC_SUBST(build_install_headers_dir)
2372 AC_SUBST(build_xm_file_list)
2373 AC_SUBST(build_xm_file)
2374 AC_SUBST(build_xm_defines)
2375 AC_SUBST(check_languages)
2376 AC_SUBST(cc_set_by_configure)
2377 AC_SUBST(quoted_cc_set_by_configure)
2378 AC_SUBST(cpp_install_dir)
2379 AC_SUBST(dep_host_xmake_file)
2380 AC_SUBST(dep_tmake_file)
2381 AC_SUBST(extra_headers_list)
2382 AC_SUBST(extra_objs)
2383 AC_SUBST(extra_parts)
2384 AC_SUBST(extra_passes)
2385 AC_SUBST(extra_programs)
2386 AC_SUBST(float_h_file)
2387 AC_SUBST(gcc_config_arguments)
2388 AC_SUBST(gcc_gxx_include_dir)
2389 AC_SUBST(libstdcxx_incdir)
2390 AC_SUBST(gcc_version)
2391 AC_SUBST(gcc_version_full)
2392 AC_SUBST(gcc_version_trigger)
2393 AC_SUBST(host_exeext)
2394 AC_SUBST(host_extra_gcc_objs)
2395 AC_SUBST(host_xm_file_list)
2396 AC_SUBST(host_xm_file)
2397 AC_SUBST(host_xm_defines)
2398 AC_SUBST(install)
2399 AC_SUBST(lang_options_files)
2400 AC_SUBST(lang_specs_files)
2401 AC_SUBST(lang_tree_files)
2402 AC_SUBST(local_prefix)
2403 AC_SUBST(md_file)
2404 AC_SUBST(objc_boehm_gc)
2405 AC_SUBST(out_file)
2406 AC_SUBST(out_object_file)
2407 AC_SUBST(stage_prefix_set_by_configure)
2408 AC_SUBST(quoted_stage_prefix_set_by_configure)
2409 AC_SUBST(symbolic_link)
2410 AC_SUBST(thread_file)
2411 AC_SUBST(tm_file_list)
2412 AC_SUBST(tm_file)
2413 AC_SUBST(tm_p_file_list)
2414 AC_SUBST(tm_p_file)
2415 AC_SUBST(xm_file)
2416 AC_SUBST(xm_defines)
2417 AC_SUBST(target_alias)
2418 AC_SUBST(c_target_objs)
2419 AC_SUBST(cxx_target_objs)
2420 AC_SUBST(target_cpu_default)
2421
2422 AC_SUBST_FILE(target_overrides)
2423 AC_SUBST_FILE(host_overrides)
2424 AC_SUBST_FILE(language_fragments)
2425 AC_SUBST_FILE(language_hooks)
2426
2427 # Echo that links are built
2428 if test x$host = x$target
2429 then
2430         str1="native "
2431 else
2432         str1="cross-"
2433         str2=" from $host"
2434 fi
2435
2436 if test x$host != x$build
2437 then
2438         str3=" on a $build system"
2439 fi
2440
2441 if test "x$str2" != x || test "x$str3" != x
2442 then
2443         str4=
2444 fi
2445
2446 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2447
2448 if test "x$str2" != x || test "x$str3" != x
2449 then
2450         echo " ${str2}${str3}." 1>&2
2451 fi
2452
2453 # Truncate the target if necessary
2454 if test x$host_truncate_target != x; then
2455         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2456 fi
2457
2458 # Configure the subdirectories
2459 # AC_CONFIG_SUBDIRS($subdirs)
2460
2461 # Create the Makefile
2462 # and configure language subdirectories
2463 AC_OUTPUT($all_outputs,
2464 [
2465 case x$CONFIG_HEADERS in
2466 xauto-host.h:config.in)
2467 echo > cstamp-h ;;
2468 esac
2469 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2470 # bootstrapping and the installation procedure can still use
2471 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2472 # FLAGS_TO_PASS has been modified to solve the problem there.
2473 # This is virtually a duplicate of what happens in configure.lang; we do
2474 # an extra check to make sure this only happens if ln -s can be used.
2475 if test "$symbolic_link" = "ln -s"; then
2476  for d in .. ${subdirs} fixinc ; do
2477    if test $d != ..; then
2478         STARTDIR=`pwd`
2479         cd $d
2480         for t in stage1 stage2 stage3 stage4 include
2481         do
2482                 rm -f $t
2483                 $symbolic_link ../$t $t 2>/dev/null
2484         done
2485         cd $STARTDIR
2486    fi
2487  done
2488 else true ; fi
2489 # Avoid having to add intl to our include paths.
2490 if test -f intl/libintl.h; then
2491   echo creating libintl.h
2492   echo '#include "intl/libintl.h"' >libintl.h
2493 fi
2494 ],
2495 [subdirs='$subdirs'
2496 symbolic_link='$symbolic_link'
2497 ])