gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname).],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as.],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname).],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format.],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format.],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include.],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files.],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib      enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor.],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin.],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       Enable multibyte characters for C and C++.],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC.
 277   --enable-threads=LIB    use LIB thread package for target GCC.],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime.],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2          force the default debug format to be DWARF2.],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared       don't provide a shared libgcc.],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Find the native compiler
 339 AC_PROG_CC
 340 AC_PROG_CC_C_O
 341 # autoconf is lame and doesn't give us any substitution variable for this.
 342 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 343   NO_MINUS_C_MINUS_O=yes
 344 else
 345   OUTPUT_OPTION='-o $@'
 346 fi
 347 AC_SUBST(NO_MINUS_C_MINUS_O)
 348 AC_SUBST(OUTPUT_OPTION)
 349
 350 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 351 ac_cv_prog_cc_no_long_long,
 352 [save_CFLAGS="$CFLAGS"
 353 CFLAGS="-Wno-long-long"
 354 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 355                ac_cv_prog_cc_no_long_long=no)
 356 CFLAGS="$save_CFLAGS"])
 357 strict1_warn=
 358 if test $ac_cv_prog_cc_no_long_long = yes; then
 359   strict1_warn="-pedantic -Wno-long-long"
 360 fi
 361 AC_SUBST(strict1_warn)
 362
 363 AC_PROG_CPP
 364 AC_C_INLINE
 365 gcc_AC_C_VOLATILE
 366
 367 gcc_AC_C_LONG_DOUBLE
 368 gcc_AC_C_LONG_LONG
 369
 370 # sizeof(char) is 1 by definition.
 371 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 372 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 373 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 374 if test $ac_cv_c_long_long = yes; then
 375   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 376 fi
 377 if test $ac_cv_c___int64 = yes; then
 378   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 379 fi
 380
 381 gcc_AC_C_CHARSET
 382 gcc_AC_C_FLOAT_FORMAT
 383
 384 # If the native compiler is GCC, we can enable warnings even in stage1.
 385 # That's useful for people building cross-compilers, or just running a
 386 # quick `make'.
 387 warn_cflags=
 388 if test "x$GCC" = "xyes"; then
 389   warn_cflags='$(GCC_WARN_CFLAGS)'
 390 fi
 391 AC_SUBST(warn_cflags)
 392
 393 # Stage specific cflags for build.
 394 stage1_cflags=
 395 case $build in
 396 vax-*-*)
 397   if test x$GCC = xyes
 398   then
 399     stage1_cflags="-Wa,-J"
 400   else
 401     stage1_cflags="-J"
 402   fi
 403   ;;
 404 esac
 405 AC_SUBST(stage1_cflags)
 406
 407 AC_PROG_MAKE_SET
 408
 409 AC_MSG_CHECKING([whether a default assembler was specified])
 410 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 411     if test x"$gas_flag" = x"no"; then
 412         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 413     else
 414         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 415     fi
 416 else
 417     AC_MSG_RESULT(no)
 418 fi
 419
 420 AC_MSG_CHECKING([whether a default linker was specified])
 421 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 422     if test x"$gnu_ld_flag" = x"no"; then
 423         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 424     else
 425         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 426     fi
 427 else
 428     AC_MSG_RESULT(no)
 429 fi
 430
 431 AC_MSG_CHECKING(for GNU C library)
 432 AC_CACHE_VAL(gcc_cv_glibc,
 433 [AC_TRY_COMPILE(
 434   [#include <features.h>],[
 435 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 436 #error Not a GNU C library system
 437 #endif],
 438   [gcc_cv_glibc=yes],
 439   gcc_cv_glibc=no)])
 440 AC_MSG_RESULT($gcc_cv_glibc)
 441 if test $gcc_cv_glibc = yes; then
 442   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 443 fi
 444
 445 # Find some useful tools
 446 AC_PROG_AWK
 447 gcc_AC_PROG_LN
 448 gcc_AC_PROG_LN_S
 449 AC_PROG_RANLIB
 450 gcc_AC_PROG_INSTALL
 451
 452 AC_HEADER_STDC
 453 AC_HEADER_TIME
 454 gcc_AC_HEADER_STRING
 455 AC_HEADER_SYS_WAIT
 456 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 457                  fcntl.h unistd.h stab.h sys/file.h sys/time.h \
 458                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 459                  direct.h malloc.h langinfo.h iconv.h stdbool.h)
 460
 461 # Check for thread headers.
 462 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 463 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 464
 465 # These tests can't be done till we know if we have limits.h.
 466 gcc_AC_C_CHAR_BIT
 467 gcc_AC_C_COMPILE_BIGENDIAN
 468
 469 # See if GNAT has been installed
 470 AC_CHECK_PROG(have_gnat, gnatbind, yes, no)
 471
 472 # See if we have the mktemp command.
 473 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 474
 475 # Do we have a single-tree copy of texinfo?
 476 if test -f $srcdir/../texinfo/Makefile.in; then
 477   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 478   gcc_cv_prog_makeinfo_modern=yes
 479   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 480 else
 481   # See if makeinfo has been installed and is modern enough
 482   # that we can use it.
 483   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 484   [GNU texinfo.* \([0-9][0-9.]*\)],
 485   [4.*])
 486 fi
 487
 488 if test $gcc_cv_prog_makeinfo_modern = no; then
 489   AC_MSG_WARN([
 490 *** Makeinfo is missing or too old.
 491 *** Info documentation will not be built.])
 492   BUILD_INFO=
 493 else
 494   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 495 fi
 496
 497 # Is pod2man recent enough to regenerate manpages?
 498 AC_MSG_CHECKING([for recent Pod::Man])
 499 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 500   AC_MSG_RESULT(yes)
 501   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 502 else
 503   AC_MSG_RESULT(no)
 504   GENERATED_MANPAGES=
 505 fi
 506
 507 # How about lex?
 508 dnl Don't use AC_PROG_LEX; we insist on flex.
 509 dnl LEXLIB is not useful in gcc.
 510 if test -f $srcdir/../flex/skel.c; then
 511   FLEX='$(objdir)/../flex/flex'
 512 else
 513   AC_CHECK_PROG(FLEX, flex, flex, false)
 514 fi
 515
 516 # Bison?
 517 # The -L switch is so bison can find its skeleton file.
 518 if test -f $srcdir/../bison/bison.simple; then
 519   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 520 else
 521   AC_CHECK_PROG(BISON, bison, bison, false)
 522 fi
 523
 524 # See if the stage1 system preprocessor understands the ANSI C
 525 # preprocessor stringification operator.
 526 AC_C_STRINGIZE
 527
 528 # Use <inttypes.h> only if it exists,
 529 # doesn't clash with <sys/types.h>, and declares intmax_t.
 530 AC_MSG_CHECKING(for inttypes.h)
 531 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 532 [AC_TRY_COMPILE(
 533   [#include <sys/types.h>
 534 #include <inttypes.h>],
 535   [intmax_t i = -1;],
 536   [gcc_cv_header_inttypes_h=yes],
 537   gcc_cv_header_inttypes_h=no)])
 538 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 539 if test $gcc_cv_header_inttypes_h = yes; then
 540   AC_DEFINE(HAVE_INTTYPES_H, 1,
 541         [Define if you have a working <inttypes.h> header file.])
 542 fi
 543
 544 dnl Disabled until we have a complete test for buggy enum bitfields.
 545 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 546
 547 AC_CHECK_FUNCS(strtoul bsearch putenv popen bcopy \
 548         strchr strrchr kill getrlimit setrlimit atoll atoq \
 549         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 550         fputs_unlocked getrusage iconv nl_langinfo)
 551
 552 AC_CHECK_TYPE(ssize_t, int)
 553
 554 # Try to determine the array type of the second argument of getgroups
 555 # for the target system (int or gid_t).
 556 AC_TYPE_GETGROUPS
 557 if test "${target}" = "${build}"; then
 558   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 559 else
 560   case "${target}" in
 561         # This condition may need some tweaking.  It should include all
 562         # targets where the array type of the second argument of getgroups
 563         # is int and the type of gid_t is not equivalent to int.
 564         *-*-sunos* | *-*-ultrix*)
 565                 TARGET_GETGROUPS_T=int
 566                 ;;
 567         *)
 568                 TARGET_GETGROUPS_T=gid_t
 569                 ;;
 570   esac
 571 fi
 572 AC_SUBST(TARGET_GETGROUPS_T)
 573
 574 gcc_AC_FUNC_VFPRINTF_DOPRNT
 575 gcc_AC_FUNC_STRSTR
 576 gcc_AC_FUNC_PRINTF_PTR
 577
 578 case "${host}" in
 579 *-*-uwin*)
 580   AC_MSG_ERROR([
 581 *** UWIN may not be used as a host platform because
 582 *** linking with posix.dll is not allowed by the GNU GPL])
 583   ;;
 584 esac
 585 AC_FUNC_VFORK
 586 AC_FUNC_MMAP_ANYWHERE
 587 AC_FUNC_MMAP_FILE
 588
 589 # We will need to find libiberty.h and ansidecl.h
 590 saved_CFLAGS="$CFLAGS"
 591 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 592 gcc_AC_CHECK_DECLS(bcopy \
 593         getenv atol sbrk abort atof getcwd getwd \
 594         strsignal putc_unlocked fputs_unlocked strstr environ \
 595         malloc realloc calloc free basename getopt, , ,[
 596 #include "gansidecl.h"
 597 #include "system.h"])
 598
 599 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 600 #include "gansidecl.h"
 601 #include "system.h"
 602 #ifdef HAVE_SYS_RESOURCE_H
 603 #include <sys/resource.h>
 604 #endif
 605 ])
 606
 607 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 608 CFLAGS="$saved_CFLAGS"
 609
 610 # mkdir takes a single argument on some systems.
 611 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 612
 613 # File extensions
 614 manext='.1'
 615 objext='.o'
 616 AC_SUBST(manext)
 617 AC_SUBST(objext)
 618
 619 build_xm_file=
 620 build_xm_defines=
 621 build_install_headers_dir=install-headers-tar
 622 build_exeext=
 623 host_xm_file=
 624 host_xm_defines=
 625 host_xmake_file=
 626 host_truncate_target=
 627 host_exeext=
 628
 629 # Decode the host machine, then the target machine.
 630 # For the host machine, we save the xm_file variable as host_xm_file;
 631 # then we decode the target machine and forget everything else
 632 # that came from the host machine.
 633 for machine in $build $host $target; do
 634         . ${srcdir}/config.gcc
 635 done
 636
 637 extra_objs="${host_extra_objs} ${extra_objs}"
 638
 639 # Default the target-machine variables that were not explicitly set.
 640 if test x"$tm_file" = x
 641 then tm_file=$cpu_type/$cpu_type.h; fi
 642
 643 if test x"$extra_headers" = x
 644 then extra_headers=; fi
 645
 646 if test x"$xm_file" = x
 647 then xm_file=$cpu_type/xm-$cpu_type.h; fi
 648
 649 if test x$md_file = x
 650 then md_file=$cpu_type/$cpu_type.md; fi
 651
 652 if test x$out_file = x
 653 then out_file=$cpu_type/$cpu_type.c; fi
 654
 655 if test x"$tmake_file" = x
 656 then tmake_file=$cpu_type/t-$cpu_type
 657 fi
 658
 659 if test x"$dwarf2" = xyes
 660 then tm_file="$tm_file tm-dwarf2.h"
 661 fi
 662
 663 if test x$float_format = x
 664 then float_format=i64
 665 fi
 666
 667 if test $float_format = none
 668 then float_h_file=Makefile.in
 669 else float_h_file=float-$float_format.h
 670 fi
 671
 672 # Handle cpp installation.
 673 if test x$enable_cpp != xno
 674 then
 675   tmake_file="$tmake_file t-install-cpp"
 676 fi
 677
 678 # Say what files are being used for the output code and MD file.
 679 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 680 echo "Using \`$srcdir/config/$md_file' as machine description file."
 681
 682 # If any of the xm_file variables contain nonexistent files, warn
 683 # about them and drop them.  But $cpu/xm-$cpu.h is allowed not to
 684 # exist, if we have nothing for it to do.
 685 changequote(,)dnl
 686 bx=
 687 for x in $build_xm_file; do
 688   if    test -f $srcdir/config/$x
 689   then      bx="$bx $x"
 690   elif  expr $x : '\([^/]*\)/xm-\1\.h' >/dev/null
 691   then      :
 692   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 693   fi
 694 done
 695 build_xm_file="$bx"
 696
 697 hx=
 698 for x in $host_xm_file; do
 699   if    test -f $srcdir/config/$x
 700   then      hx="$hx $x"
 701   elif  expr $x : '\([^/]*\)/xm-\1\.h' >/dev/null
 702   then      :
 703   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 704   fi
 705 done
 706 host_xm_file="$hx"
 707
 708 tx=
 709 for x in $xm_file; do
 710   if    test -f $srcdir/config/$x
 711   then      tx="$tx $x"
 712   elif  expr $x : '\([^/]*\)/xm-\1\.h' >/dev/null
 713   then      :
 714   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 715   fi
 716 done
 717 xm_file="$tx"
 718 changequote([,])dnl
 719
 720 count=a
 721 for f in $tm_file; do
 722         count=${count}x
 723 done
 724 if test $count = ax; then
 725         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 726 else
 727         echo "Using the following target machine macro files:"
 728         for f in $tm_file; do
 729                 echo "  $srcdir/config/$f"
 730         done
 731 fi
 732
 733 count=a
 734 for f in $host_xm_file; do
 735         count=${count}x
 736 done
 737 if test $count = a; then
 738         :
 739 elif test $count = ax; then
 740         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 741 else
 742         echo "Using the following host machine macro files:"
 743         for f in $host_xm_file; do
 744                 echo "  $srcdir/config/$f"
 745         done
 746 fi
 747
 748 if test "$host_xm_file" != "$build_xm_file"; then
 749         count=a
 750         for f in $build_xm_file; do
 751                 count=${count}x
 752         done
 753         if test $count = a; then
 754                 :
 755         elif test $count = ax; then
 756                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 757         else
 758                 echo "Using the following build machine macro files:"
 759                 for f in $build_xm_file; do
 760                         echo "  $srcdir/config/$f"
 761                 done
 762         fi
 763 fi
 764
 765 if test x$thread_file = x; then
 766         if test x$target_thread_file != x; then
 767                 thread_file=$target_thread_file
 768         else
 769                 thread_file='single'
 770         fi
 771 fi
 772
 773 # auto-host.h is the file containing items generated by autoconf and is
 774 # the first file included by config.h.
 775 # If host=build, it is correct to have hconfig include auto-host.h
 776 # as well.  If host!=build, we are in error and need to do more
 777 # work to find out the build config parameters.
 778 if test x$host = x$build
 779 then
 780         build_auto=auto-host.h
 781 else
 782         # We create a subdir, then run autoconf in the subdir.
 783         # To prevent recursion we set host and build for the new
 784         # invocation of configure to the build for this invocation
 785         # of configure.
 786         tempdir=build.$$
 787         rm -rf $tempdir
 788         mkdir $tempdir
 789         cd $tempdir
 790         case ${srcdir} in
 791         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 792         *) realsrcdir=../${srcdir};;
 793         esac
 794         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 795                 --target=$target --host=$build --build=$build
 796
 797         # We just finished tests for the build machine, so rename
 798         # the file auto-build.h in the gcc directory.
 799         mv auto-host.h ../auto-build.h
 800         cd ..
 801         rm -rf $tempdir
 802         build_auto=auto-build.h
 803 fi
 804
 805 tm_file="${tm_file} defaults.h"
 806 host_xm_file="auto-host.h gansidecl.h ${host_xm_file} ${tm_file}"
 807 build_xm_file="${build_auto} gansidecl.h ${build_xm_file} ${tm_file}"
 808 xm_file="gansidecl.h ${xm_file} ${tm_file}"
 809
 810 # Truncate the target if necessary
 811 if test x$host_truncate_target != x; then
 812         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 813 fi
 814
 815 # Get the version trigger filename from the toplevel
 816 if test "${with_gcc_version_trigger+set}" = set; then
 817         gcc_version_trigger=$with_gcc_version_trigger
 818 else
 819         gcc_version_trigger=${srcdir}/version.c
 820 fi
 821 changequote(,)dnl
 822 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 823 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 824
 825 # Compile in configure arguments.
 826 if test -f configargs.h ; then
 827         # Being re-configured.
 828         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 829         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 830 else
 831         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 832 fi
 833 cat > configargs.h <<EOF
 834 /* Generated automatically. */
 835 static const char configuration_arguments[] = "$gcc_config_arguments";
 836 EOF
 837 changequote([,])dnl
 838
 839 # Internationalization
 840 PACKAGE=gcc
 841 VERSION="$gcc_version"
 842 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 843         [Define to the name of the distribution.])
 844 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 845         [Define to the version of the distribution.])
 846 AC_SUBST(PACKAGE)
 847 AC_SUBST(VERSION)
 848
 849 ALL_LINGUAS="sv"
 850
 851 # Enable NLS support by default
 852 AC_ARG_ENABLE(nls,
 853   [  --enable-nls            use Native Language Support (default)],
 854   , enable_nls=yes)
 855
 856 # if cross compiling, disable NLS support.
 857 # It's not worth the trouble, at least for now.
 858
 859 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 860   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 861   enable_nls=no
 862 fi
 863
 864 # if NLS is enabled, also enable check in po subdir
 865 if test $enable_nls = yes; then
 866   CHECK_PO=check-po
 867 else
 868   CHECK_PO=""
 869 fi
 870
 871 AC_SUBST(CHECK_PO)
 872
 873 AM_GNU_GETTEXT
 874 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 875
 876 # Windows32 Registry support for specifying GCC installation paths.
 877 AC_ARG_ENABLE(win32-registry,
 878 [  --disable-win32-registry
 879                           Disable lookup of installation paths in the
 880                          Registry on Windows hosts.
 881   --enable-win32-registry Enable registry lookup (default).
 882   --enable-win32-registry=KEY
 883                           Use KEY instead of GCC version as the last portion
 884                          of the registry key.],,)
 885
 886 AC_MSG_CHECKING(whether windows registry support is requested)
 887 if test x$enable_win32_registry != xno; then
 888   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 889 [Define to 1 if installation paths should be looked up in Windows32
 890    Registry. Ignored on non windows32 hosts.])
 891   AC_MSG_RESULT(yes)
 892 else
 893   AC_MSG_RESULT(no)
 894 fi
 895
 896 # Check if user specified a different registry key.
 897 case x${enable_win32_registry} in
 898 x | xyes)
 899   # default.
 900   gcc_cv_win32_registry_key="$VERSION"
 901   ;;
 902 xno)
 903   # no registry lookup.
 904   gcc_cv_win32_registry_key=''
 905   ;;
 906 *)
 907   # user-specified key.
 908   gcc_cv_win32_registry_key="$enable_win32_registry"
 909   ;;
 910 esac
 911
 912 if test x$enable_win32_registry != xno; then
 913   AC_MSG_CHECKING(registry key on windows hosts)
 914   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 915         [Define to be the last portion of registry key on windows hosts.])
 916   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 917 fi
 918
 919 # Get an absolute path to the GCC top-level source directory
 920 holddir=`pwd`
 921 cd $srcdir
 922 topdir=`pwd`
 923 cd $holddir
 924
 925 # Conditionalize the makefile for this host machine.
 926 # Make-host contains the concatenation of all host makefile fragments
 927 # [there can be more than one].  This file is built by configure.frag.
 928 host_overrides=Make-host
 929 dep_host_xmake_file=
 930 for f in .. ${host_xmake_file}
 931 do
 932         if test -f ${srcdir}/config/$f
 933         then
 934                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 935         fi
 936 done
 937
 938 # Conditionalize the makefile for this target machine.
 939 # Make-target contains the concatenation of all host makefile fragments
 940 # [there can be more than one].  This file is built by configure.frag.
 941 target_overrides=Make-target
 942 dep_tmake_file=
 943 for f in .. ${tmake_file}
 944 do
 945         if test -f ${srcdir}/config/$f
 946         then
 947                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
 948         fi
 949 done
 950
 951 # If the host doesn't support symlinks, modify CC in
 952 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
 953 # Otherwise, we can use "CC=$(CC)".
 954 rm -f symtest.tem
 955 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
 956 then
 957         cc_set_by_configure="\$(CC)"
 958         quoted_cc_set_by_configure="\$(CC)"
 959         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
 960 else
 961         rm -f symtest.tem
 962         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
 963         then
 964                 symbolic_link="cp -p"
 965         else
 966                 symbolic_link="cp"
 967         fi
 968         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
 969         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
 970         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
 971 fi
 972 rm -f symtest.tem
 973
 974 out_object_file=`basename $out_file .c`.o
 975
 976 tm_file_list=
 977 for f in $tm_file; do
 978   case $f in
 979     gansidecl.h | defaults.h )
 980        tm_file_list="${tm_file_list} $f" ;;
 981     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
 982   esac
 983 done
 984
 985 tm_p_file_list=
 986 for f in $tm_p_file; do
 987     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
 988 done
 989
 990 host_xm_file_list=
 991 for f in $host_xm_file; do
 992   case $f in
 993     auto-host.h | gansidecl.h | defaults.h )
 994        host_xm_file_list="${host_xm_file_list} $f" ;;
 995     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
 996   esac
 997 done
 998
 999 build_xm_file_list=
1000 for f in $build_xm_file; do
1001   case $f in
1002     auto-build.h | auto-host.h | gansidecl.h | defaults.h )
1003        build_xm_file_list="${build_xm_file_list} $f" ;;
1004     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1005   esac
1006 done
1007
1008 # Define macro CROSS_COMPILE in compilation
1009 # if this is a cross-compiler.
1010 # Also use all.cross instead of all.internal
1011 # and add cross-make to Makefile.
1012 cross_overrides="/dev/null"
1013 if test x$host != x$target
1014 then
1015         cross_defines="CROSS=-DCROSS_COMPILE"
1016         cross_overrides="${topdir}/cross-make"
1017 fi
1018
1019 # If this is a cross-compiler that does not
1020 # have its own set of headers then define
1021 # inhibit_libc
1022
1023 # If this is using newlib, then define inhibit_libc in
1024 # LIBGCC2_CFLAGS.  This will cause __eprintf to be left out of
1025 # libgcc.a, but that's OK because newlib should have its own version of
1026 # assert.h.
1027 inhibit_libc=
1028 if [test x$host != x$target] && [test x$with_headers = x]; then
1029        inhibit_libc=-Dinhibit_libc
1030 else
1031        if [test x$with_newlib = xyes]; then
1032                inhibit_libc=-Dinhibit_libc
1033        fi
1034 fi
1035 AC_SUBST(inhibit_libc)
1036
1037 # When building gcc with a cross-compiler, we need to fix a few things.
1038 # This must come after cross-make as we want all.build to override
1039 # all.cross.
1040 build_overrides="/dev/null"
1041 if test x$build != x$host
1042 then
1043         build_overrides="${topdir}/build-make"
1044 fi
1045
1046 # Expand extra_headers to include complete path.
1047 # This substitutes for lots of t-* files.
1048 extra_headers_list=
1049 if test "x$extra_headers" = x
1050 then true
1051 else
1052         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1053         for file in $extra_headers;
1054         do
1055                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1056         done
1057 fi
1058
1059 if test x$use_collect2 = xno; then
1060         use_collect2=
1061 fi
1062
1063 # Add a definition of USE_COLLECT2 if system wants one.
1064 # Also tell toplev.c what to do.
1065 # This substitutes for lots of t-* files.
1066 if test x$use_collect2 = x
1067 then
1068         will_use_collect2=
1069         maybe_use_collect2=
1070 else
1071         will_use_collect2="collect2"
1072         maybe_use_collect2="-DUSE_COLLECT2"
1073 fi
1074
1075 # If we have gas in the build tree, make a link to it.
1076 if test -f ../gas/Makefile; then
1077         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1078 fi
1079
1080 # If we have nm in the build tree, make a link to it.
1081 if test -f ../binutils/Makefile; then
1082         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1083 fi
1084
1085 # If we have ld in the build tree, make a link to it.
1086 if test -f ../ld/Makefile; then
1087 #       if test x$use_collect2 = x; then
1088 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1089 #       else
1090                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1091 #       fi
1092 fi
1093
1094 # Figure out what assembler we will be using.
1095 AC_MSG_CHECKING(what assembler to use)
1096 gcc_cv_as=
1097 gcc_cv_gas_major_version=
1098 gcc_cv_gas_minor_version=
1099 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1100 if test -x "$DEFAULT_ASSEMBLER"; then
1101         gcc_cv_as="$DEFAULT_ASSEMBLER"
1102 elif test -x "$AS"; then
1103         gcc_cv_as="$AS"
1104 elif test -x as$host_exeext; then
1105         # Build using assembler in the current directory.
1106         gcc_cv_as=./as$host_exeext
1107 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1108         # Single tree build which includes gas.
1109         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1110         do
1111 changequote(,)dnl
1112                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1113 changequote([,])dnl
1114                 if test x$gcc_cv_gas_version != x; then
1115                         break
1116                 fi
1117         done
1118 changequote(,)dnl
1119         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1120         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1121 changequote([,])dnl
1122 fi
1123
1124 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1125         # Native build.
1126         # Search the same directories that the installed compiler will
1127         # search.  Else we may find the wrong assembler and lose.  If we
1128         # do not find a suitable assembler binary, then try the user's
1129         # path.
1130         #
1131         # Also note we have to check MD_EXEC_PREFIX before checking the
1132         # user's path.  Unfortunately, there is no good way to get at the
1133         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1134         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1135         # to be fixed as part of the make/configure rewrite too.
1136
1137         if test "x$exec_prefix" = xNONE; then
1138                 if test "x$prefix" = xNONE; then
1139                         test_prefix=/usr/local
1140                 else
1141                         test_prefix=$prefix
1142                 fi
1143         else
1144                 test_prefix=$exec_prefix
1145         fi
1146
1147         # If the loop below does not find an assembler, then use whatever
1148         # one we can find in the users's path.
1149         # user's path.
1150         gcc_cv_as=as$host_exeext
1151
1152         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1153                    $test_prefix/lib/gcc-lib/$target \
1154                    /usr/lib/gcc/$target/$gcc_version \
1155                    /usr/lib/gcc/$target \
1156                    $test_prefix/$target/bin/$target/$gcc_version \
1157                    $test_prefix/$target/bin \
1158                    /usr/libexec \
1159                    /usr/ccs/gcc \
1160                    /usr/ccs/bin \
1161                    /udk/usr/ccs/bin \
1162                    /bsd43/usr/lib/cmplrs/cc \
1163                    /usr/cross64/usr/bin \
1164                    /usr/lib/cmplrs/cc \
1165                    /sysv/usr/lib/cmplrs/cc \
1166                    /svr4/usr/lib/cmplrs/cc \
1167                    /usr/bin"
1168
1169         for dir in $test_dirs; do
1170                 if test -f $dir/as$host_exeext; then
1171                         gcc_cv_as=$dir/as$host_exeext
1172                         break;
1173                 fi
1174         done
1175 fi
1176 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1177   AC_MSG_RESULT("newly built gas")
1178 else
1179   AC_MSG_RESULT($gcc_cv_as)
1180 fi
1181
1182 # Figure out what nm we will be using.
1183 AC_MSG_CHECKING(what nm to use)
1184 if test -x nm$host_exeext; then
1185         gcc_cv_nm=./nm$host_exeext
1186 elif test x$host = x$target; then
1187         # Native build.
1188         gcc_cv_nm=nm$host_exeext
1189 fi
1190 AC_MSG_RESULT($gcc_cv_nm)
1191
1192 # Figure out what assembler alignment features are present.
1193 AC_MSG_CHECKING(assembler alignment features)
1194 gcc_cv_as_alignment_features=none
1195 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1196         # Gas version 2.6 and later support for .balign and .p2align.
1197         # bytes to skip when using .p2align.
1198         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1199                 gcc_cv_as_alignment_features=".balign and .p2align"
1200                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1201         fi
1202         # Gas version 2.8 and later support specifying the maximum
1203         # bytes to skip when using .p2align.
1204         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1205                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1206                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1207         fi
1208 elif test x$gcc_cv_as != x; then
1209         # Check if we have .balign and .p2align
1210         echo ".balign  4" > conftest.s
1211         echo ".p2align  2" >> conftest.s
1212         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1213                 gcc_cv_as_alignment_features=".balign and .p2align"
1214                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1215         fi
1216         rm -f conftest.s conftest.o
1217         # Check if specifying the maximum bytes to skip when
1218         # using .p2align is supported.
1219         echo ".p2align 4,,7" > conftest.s
1220         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1221                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1222                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1223         fi
1224         rm -f conftest.s conftest.o
1225 fi
1226 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1227
1228 AC_MSG_CHECKING(assembler subsection support)
1229 gcc_cv_as_subsections=no
1230 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1231   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1232     gcc_cv_as_subsections="working .subsection -1"
1233   fi
1234 elif test x$gcc_cv_as != x; then
1235         # Check if we have .subsection
1236         echo ".subsection 1" > conftest.s
1237         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1238                 gcc_cv_as_subsections=".subsection"
1239                 if test x$gcc_cv_nm != x; then
1240                         cat > conftest.s <<EOF
1241 conftest_label1: .word 0
1242 .subsection -1
1243 conftest_label2: .word 0
1244 .previous
1245 EOF
1246                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1247                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1248                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1249                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1250                                         :
1251                                 else
1252                                         gcc_cv_as_subsections="working .subsection -1"
1253                                 fi
1254                         fi
1255                 fi
1256         fi
1257         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1258 fi
1259 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1260         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1261 [Define if your assembler supports .subsection and .subsection -1 starts
1262    emitting at the beginning of your section.])
1263 fi
1264 AC_MSG_RESULT($gcc_cv_as_subsections)
1265
1266 AC_MSG_CHECKING(assembler weak support)
1267 gcc_cv_as_weak=no
1268 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1269   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1270     gcc_cv_as_weak="yes"
1271   fi
1272 elif test x$gcc_cv_as != x; then
1273         # Check if we have .weak
1274         echo "  .weak foobar" > conftest.s
1275         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1276                 gcc_cv_as_weak="yes"
1277         fi
1278         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1279 fi
1280 if test x"$gcc_cv_as_weak" = xyes; then
1281         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1282 fi
1283 AC_MSG_RESULT($gcc_cv_as_weak)
1284
1285 AC_MSG_CHECKING(assembler hidden support)
1286 gcc_cv_as_hidden=no
1287 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1288   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1289     gcc_cv_as_hidden="yes"
1290   fi
1291 elif test x$gcc_cv_as != x; then
1292         # Check if we have .hidden
1293         echo "  .hidden foobar" > conftest.s
1294         echo "foobar:" >> conftest.s
1295         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1296                 gcc_cv_as_hidden="yes"
1297         fi
1298         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1299 fi
1300 if test x"$gcc_cv_as_hidden" = xyes; then
1301         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1302                 [Define if your assembler supports .hidden.])
1303 fi
1304 AC_MSG_RESULT($gcc_cv_as_hidden)
1305
1306 AC_MSG_CHECKING(assembler leb128 support)
1307 gcc_cv_as_hidden=no
1308 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1309   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1310     gcc_cv_as_leb128="yes"
1311   fi
1312 elif test x$gcc_cv_as != x; then
1313         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1314         cat > conftest.s <<EOF
1315         .data
1316         .uleb128 L2 - L1
1317 L1:
1318         .uleb128 1280
1319         .sleb128 -1010
1320 L2:
1321 EOF
1322         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1323                 gcc_cv_as_leb128="yes"
1324         fi
1325         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1326 fi
1327 if test x"$gcc_cv_as_leb128" = xyes; then
1328         AC_DEFINE(HAVE_AS_LEB128, 1,
1329                 [Define if your assembler supports .uleb128.])
1330 fi
1331 AC_MSG_RESULT($gcc_cv_as_leb128)
1332
1333 case "$target" in
1334   sparc*-*-*)
1335     AC_CACHE_CHECK([assembler .register pseudo-op support],
1336         gcc_cv_as_register_pseudo_op, [
1337         gcc_cv_as_register_pseudo_op=unknown
1338         if test x$gcc_cv_as != x; then
1339             # Check if we have .register
1340             echo ".register %g2, #scratch" > conftest.s
1341             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1342                 gcc_cv_as_register_pseudo_op=yes
1343             else
1344                 gcc_cv_as_register_pseudo_op=no
1345             fi
1346             rm -f conftest.s conftest.o
1347         fi
1348     ])
1349     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1350         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1351                 [Define if your assembler supports .register.])
1352     fi
1353
1354     AC_CACHE_CHECK([assembler supports -relax],
1355         gcc_cv_as_relax_opt, [
1356         gcc_cv_as_relax_opt=unknown
1357         if test x$gcc_cv_as != x; then
1358             # Check if gas supports -relax
1359             echo ".text" > conftest.s
1360             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1361                 gcc_cv_as_relax_opt=yes
1362             else
1363                 gcc_cv_as_relax_opt=no
1364             fi
1365             rm -f conftest.s conftest.o
1366         fi
1367     ])
1368     if test "x$gcc_cv_as_relax_opt" = xyes; then
1369         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1370                 [Define if your assembler supports -relax option.])
1371     fi
1372
1373     case "$tm_file" in
1374     *64*)
1375         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1376             gcc_cv_as_flags64, [
1377                 if test -n "$gcc_cv_as"; then
1378                     echo ".xword foo" > conftest.s
1379                     gcc_cv_as_flags64=no
1380                     for flag in "-xarch=v9" "-64 -Av9"; do
1381                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1382                             > /dev/null 2>&1; then
1383                             gcc_cv_as_flags64=$flag
1384                             break
1385                         fi
1386                     done
1387                     rm -f conftest.s conftest.o
1388                 else
1389                     if test "$gas" = yes; then
1390                         gcc_cv_as_flags64="-64 -Av9"
1391                     else
1392                         gcc_cv_as_flags64="-xarch=v9"
1393                     fi
1394                 fi
1395         ])
1396         if test "x$gcc_cv_as_flags64" = xno; then
1397 changequote(, )
1398             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1399             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1400 changequote([, ])
1401         else
1402             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1403                         [Define if the assembler supports 64bit sparc.])
1404         fi
1405         ;;
1406     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1407         ;;
1408     esac
1409
1410     if test "x$gcc_cv_as_flags64" != xno; then
1411         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1412             gcc_cv_as_offsetable_lo10, [
1413             gcc_cv_as_offsetable_lo10=unknown
1414             if test "x$gcc_cv_as" != x; then
1415                 # Check if assembler has offsetable %lo()
1416                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1417                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1418                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1419                         > /dev/null 2>&1 &&
1420                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1421                         > /dev/null 2>&1; then
1422                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1423                         gcc_cv_as_offsetable_lo10=no
1424                     else
1425                         gcc_cv_as_offsetable_lo10=yes
1426                     fi
1427                 else
1428                     gcc_cv_as_offsetable_lo10=no
1429                 fi
1430                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1431             fi
1432         ])
1433         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1434             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1435                 [Define if your assembler supports offsetable %lo().])
1436         fi
1437     fi
1438     ;;
1439
1440 changequote(,)dnl
1441   i[34567]86-*-*)
1442 changequote([,])dnl
1443     AC_MSG_CHECKING(assembler instructions)
1444     gcc_cv_as_instructions=
1445     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1446       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1447         gcc_cv_as_instructions="filds fists"
1448       fi
1449     elif test x$gcc_cv_as != x; then
1450         set "filds fists" "filds mem; fists mem"
1451         while test $# -gt 0
1452         do
1453                 echo "$2" > conftest.s
1454                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1455                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1456                 fi
1457                 shift 2
1458         done
1459         rm -f conftest.s conftest.o
1460     fi
1461     if test x"$gcc_cv_as_instructions" != x; then
1462         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1463     fi
1464     AC_MSG_RESULT($gcc_cv_as_instructions)
1465     ;;
1466 esac
1467
1468 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1469 gcc_cv_as_dwarf2_debug_line=no
1470 # ??? Not all targets support dwarf2 debug_line, even within a version
1471 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1472 # info to the output file.  So, as supported targets are added to gas 2.11,
1473 # add some instruction here to (also) show we expect this might work.
1474 # ??? Once 2.11 is released, probably need to add first known working
1475 # version to the per-target configury.
1476 case "$target" in
1477   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-*)
1478     insn="nop"
1479     ;;
1480   ia64*-*-*)
1481     insn="nop 0"
1482     ;;
1483   esac
1484 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1485 then
1486   if test "$gcc_cv_gas_major_version" -eq 2 \
1487         -a "$gcc_cv_gas_minor_version" -ge 11 \
1488         -o "$gcc_cv_gas_major_version" -gt 2 \
1489      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1490      && test x"$insn" != x ; then
1491     gcc_cv_as_dwarf2_debug_line="yes"
1492   fi
1493 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1494         echo '  .file 0 "conftest.s"' > conftest.s
1495         echo '  .loc 0 3 0' >> conftest.s
1496         echo "  $insn" >> conftest.s
1497         # ??? This fails with non-gnu grep.
1498         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1499            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1500                 # The .debug_line file table must be in the exact order that
1501                 # we specified the files, since these indicies are also used
1502                 # by DW_AT_decl_file.  Approximate this test by testing if
1503                 # the assembler bitches if the same index is assigned twice.
1504                 echo '  .file 1 "foo.s"' > conftest.s
1505                 echo '  .file 1 "bar.s"' >> conftest.s
1506                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1507                 then
1508                   gcc_cv_as_dwarf2_debug_line="no"
1509                 else
1510                   gcc_cv_as_dwarf2_debug_line="yes"
1511                 fi
1512         fi
1513         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1514 fi
1515 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1516         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1517 [Define if your assembler supports dwarf2 .file/.loc directives,
1518    and preserves file table indicies exactly as given.])
1519 fi
1520 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1521
1522 # Figure out what language subdirectories are present.
1523 # Look if the user specified --enable-languages="..."; if not, use
1524 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1525 # go away some day.
1526 if test x"${enable_languages+set}" != xset; then
1527         if test x"${LANGUAGES+set}" = xset; then
1528                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1529         else
1530                 enable_languages=all
1531         fi
1532 else
1533         if test x"${enable_languages}" = x; then
1534                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1535         fi
1536 fi
1537
1538 # First scan to see if an enabled language requires some other language.
1539 # We assume that a given config-lang.in will list all the language
1540 # front ends it requires, even if some are required indirectly.
1541 for lang in ${srcdir}/*/config-lang.in ..
1542 do
1543    case $lang in
1544     ..)
1545        ;;
1546     # The odd quoting in the next line works around
1547     # an apparent bug in bash 1.12 on linux.
1548 changequote(,)dnl
1549     ${srcdir}/[*]/config-lang.in)
1550        ;;
1551     *)
1552        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1553        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1554        for other in $this_lang_requires
1555        do
1556           case ,${enable_languages}, in
1557            *,$other,*)
1558               ;;
1559            *,all,*)
1560               ;;
1561            *,$lang_alias,*)
1562               enable_languages="$enable_languages,$other"
1563               ;;
1564           esac
1565        done
1566        ;;
1567 changequote([,])dnl
1568    esac
1569 done
1570
1571 subdirs=
1572 for lang in ${srcdir}/*/config-lang.in ..
1573 do
1574         case $lang in
1575         ..) ;;
1576         # The odd quoting in the next line works around
1577         # an apparent bug in bash 1.12 on linux.
1578 changequote(,)dnl
1579         ${srcdir}/[*]/config-lang.in) ;;
1580         *)
1581           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1582           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1583           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1584           if test "x$lang_alias" = x
1585           then
1586                 echo "$lang doesn't set \$language." 1>&2
1587                 exit 1
1588           fi
1589           case ${build_by_default},${enable_languages}, in
1590           *,$lang_alias,*) add_this_lang=yes ;;
1591           no,*) add_this_lang=no ;;
1592           *,all,*) add_this_lang=yes ;;
1593           *) add_this_lang=no ;;
1594           esac
1595           if test x"${add_this_lang}" = xyes; then
1596                 case $lang in
1597                     ${srcdir}/ada/config-lang.in)
1598                         if test x$have_gnat = xyes ; then
1599                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1600                         fi
1601                         ;;
1602                     *)
1603                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1604                         ;;
1605                 esac
1606           fi
1607           ;;
1608 changequote([,])dnl
1609         esac
1610 done
1611
1612 # Make gthr-default.h if we have a thread file.
1613 gthread_flags=
1614 if test $thread_file != single; then
1615     rm -f gthr-default.h
1616     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1617     gthread_flags=-DHAVE_GTHR_DEFAULT
1618 fi
1619 AC_SUBST(gthread_flags)
1620
1621 # Find out what GC implementation we want, or may, use.
1622 AC_ARG_WITH(gc,
1623 [  --with-gc={simple,page} Choose the garbage collection mechanism to use
1624                            with the compiler.],
1625 [case "$withval" in
1626   simple | page)
1627     GGC=ggc-$withval
1628     ;;
1629   *)
1630     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1631     ;;
1632 esac],
1633 [GGC=ggc-page])
1634 AC_SUBST(GGC)
1635 echo "Using $GGC for garbage collection."
1636
1637 # Use the system's zlib library.
1638 zlibdir=-L../zlib
1639 zlibinc="-I\$(srcdir)/../zlib"
1640 AC_ARG_WITH(system-zlib,
1641 [  --with-system-zlib      use installed libz],
1642 zlibdir=
1643 zlibinc=
1644 )
1645 AC_SUBST(zlibdir)
1646 AC_SUBST(zlibinc)
1647
1648 AC_DEFINE_UNQUOTED(ENABLE_STD_NAMESPACE, 1,
1649   [Define to 1 if you want to enable namespaces (-fhonor-std) by default.])
1650
1651 dnl Very limited version of automake's enable-maintainer-mode
1652
1653 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1654   dnl maintainer-mode is disabled by default
1655   AC_ARG_ENABLE(maintainer-mode,
1656 [  --enable-maintainer-mode enable make rules and dependencies not useful
1657                           (and sometimes confusing) to the casual installer],
1658       maintainer_mode=$enableval,
1659       maintainer_mode=no)
1660
1661 AC_MSG_RESULT($maintainer_mode)
1662
1663 if test "$maintainer_mode" = "yes"; then
1664   MAINT=''
1665 else
1666   MAINT='#'
1667 fi
1668 AC_SUBST(MAINT)dnl
1669
1670 # Make empty files to contain the specs and options for each language.
1671 # Then add #include lines to for a compiler that has specs and/or options.
1672
1673 lang_specs_files=
1674 lang_options_files=
1675 lang_tree_files=
1676 rm -f specs.h options.h gencheck.h
1677 touch specs.h options.h gencheck.h
1678 for subdir in . $subdirs
1679 do
1680         if test -f $srcdir/$subdir/lang-specs.h; then
1681                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1682                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1683         fi
1684         if test -f $srcdir/$subdir/lang-options.h; then
1685                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1686                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1687         fi
1688         if test -f $srcdir/$subdir/$subdir-tree.def; then
1689                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1690                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1691         fi
1692 done
1693
1694 # These (without "all_") are set in each config-lang.in.
1695 # `language' must be a single word so is spelled singularly.
1696 all_languages=
1697 all_boot_languages=
1698 all_compilers=
1699 all_stagestuff=
1700 all_diff_excludes=
1701 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1702 # List of language makefile fragments.
1703 all_lang_makefiles=
1704 all_headers=
1705 all_lib2funcs=
1706
1707 # Add the language fragments.
1708 # Languages are added via two mechanisms.  Some information must be
1709 # recorded in makefile variables, these are defined in config-lang.in.
1710 # We accumulate them and plug them into the main Makefile.
1711 # The other mechanism is a set of hooks for each of the main targets
1712 # like `clean', `install', etc.
1713
1714 language_fragments="Make-lang"
1715 language_hooks="Make-hooks"
1716
1717 for s in .. $subdirs
1718 do
1719         if test $s != ".."
1720         then
1721                 language=
1722                 boot_language=
1723                 compilers=
1724                 stagestuff=
1725                 diff_excludes=
1726                 headers=
1727                 outputs=
1728                 lib2funcs=
1729                 . ${srcdir}/$s/config-lang.in
1730                 if test "x$language" = x
1731                 then
1732                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1733                         exit 1
1734                 fi
1735                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1736                 if test -f ${srcdir}/$s/Makefile.in
1737                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1738                 fi
1739                 all_languages="$all_languages $language"
1740                 if test "x$boot_language" = xyes
1741                 then
1742                         all_boot_languages="$all_boot_languages $language"
1743                 fi
1744                 all_compilers="$all_compilers $compilers"
1745                 all_stagestuff="$all_stagestuff $stagestuff"
1746                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1747                 all_headers="$all_headers $headers"
1748                 all_outputs="$all_outputs $outputs"
1749                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1750         fi
1751 done
1752
1753 check_languages=
1754 for language in .. $all_languages
1755 do
1756         if test $language != ".."
1757         then
1758                 check_languages="$check_languages check-$language"
1759         fi
1760 done
1761
1762 # Since we can't use `::' targets, we link each language in
1763 # with a set of hooks, reached indirectly via lang.${target}.
1764
1765 rm -f Make-hooks
1766 touch Make-hooks
1767 target_list="all.build all.cross start.encap rest.encap \
1768         info dvi \
1769         install-normal install-common install-info install-man \
1770         uninstall \
1771         mostlyclean clean distclean extraclean maintainer-clean \
1772         stage1 stage2 stage3 stage4"
1773 for t in $target_list
1774 do
1775         x=
1776         for lang in .. $all_languages
1777         do
1778                 if test $lang != ".."; then
1779                         x="$x $lang.$t"
1780                 fi
1781         done
1782         echo "lang.$t: $x" >> Make-hooks
1783 done
1784
1785 # Create .gdbinit.
1786
1787 echo "dir ." > .gdbinit
1788 echo "dir ${srcdir}" >> .gdbinit
1789 if test x$gdb_needs_out_file_path = xyes
1790 then
1791         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1792 fi
1793 if test "x$subdirs" != x; then
1794         for s in $subdirs
1795         do
1796                 echo "dir ${srcdir}/$s" >> .gdbinit
1797         done
1798 fi
1799 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
1800
1801 # Define variables host_canonical and build_canonical
1802 # because some Cygnus local changes in the Makefile depend on them.
1803 build_canonical=${build}
1804 host_canonical=${host}
1805 target_subdir=
1806 if test "${host}" != "${target}" ; then
1807     target_subdir=${target}/
1808 fi
1809 AC_SUBST(build_canonical)
1810 AC_SUBST(host_canonical)
1811 AC_SUBST(target_subdir)
1812
1813 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1814 # absolute path for gcc_tooldir based on inserting the number of up-directory
1815 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1816 # $(libsubdir)/@(unlibsubdir) based path.
1817 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1818 # make and thus we'd get different behavior depending on where we built the
1819 # sources.
1820 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1821     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1822 else
1823 changequote(<<, >>)dnl
1824 # An explanation of the sed strings:
1825 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1826 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1827 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1828 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1829 #
1830 # (*) Note this pattern overwrites the first character of the string
1831 # with a forward slash if one is not already present.  This is not a
1832 # problem because the exact names of the sub-directories concerned is
1833 # unimportant, just the number of them matters.
1834 #
1835 # The practical upshot of these patterns is like this:
1836 #
1837 #  prefix     exec_prefix        result
1838 #  ------     -----------        ------
1839 #   /foo        /foo/bar          ../
1840 #   /foo/       /foo/bar          ../
1841 #   /foo        /foo/bar/         ../
1842 #   /foo/       /foo/bar/         ../
1843 #   /foo        /foo/bar/ugg      ../../
1844 #
1845     dollar='$$'
1846     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
1847 changequote([, ])dnl
1848 fi
1849 AC_SUBST(gcc_tooldir)
1850 AC_SUBST(dollar)
1851
1852 # Find a directory in which to install a shared libgcc.
1853
1854 AC_ARG_ENABLE(version-specific-runtime-libs,
1855 [  --enable-version-specific-runtime-libs    Specify that runtime libraries shou
1856 ld be installed in a compiler-specific directory ])
1857
1858 AC_ARG_WITH(slibdir,
1859 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
1860 slibdir="$with_slibdir",
1861 if test "${enable_version_specific_runtime_libs+set}" = set; then
1862   slibdir='$(libsubdir)'
1863 elif test "$host" != "$target"; then
1864   slibdir='$(build_tooldir)/lib'
1865 else
1866   slibdir='$(libdir)'
1867 fi)
1868 AC_SUBST(slibdir)
1869
1870 # Nothing to do for FLOAT_H, float_format already handled.
1871 objdir=`pwd`
1872 AC_SUBST(objdir)
1873
1874 # Process the language and host/target makefile fragments.
1875 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
1876
1877 # Substitute configuration variables
1878 AC_SUBST(subdirs)
1879 AC_SUBST(all_boot_languages)
1880 AC_SUBST(all_compilers)
1881 AC_SUBST(all_diff_excludes)
1882 AC_SUBST(all_headers)
1883 AC_SUBST(all_lang_makefiles)
1884 AC_SUBST(all_languages)
1885 AC_SUBST(all_lib2funcs)
1886 AC_SUBST(all_stagestuff)
1887 AC_SUBST(build_exeext)
1888 AC_SUBST(build_install_headers_dir)
1889 AC_SUBST(build_xm_file_list)
1890 AC_SUBST(build_xm_file)
1891 AC_SUBST(build_xm_defines)
1892 AC_SUBST(check_languages)
1893 AC_SUBST(cc_set_by_configure)
1894 AC_SUBST(quoted_cc_set_by_configure)
1895 AC_SUBST(cpp_install_dir)
1896 AC_SUBST(dep_host_xmake_file)
1897 AC_SUBST(dep_tmake_file)
1898 AC_SUBST(extra_c_flags)
1899 AC_SUBST(extra_headers_list)
1900 AC_SUBST(extra_objs)
1901 AC_SUBST(extra_parts)
1902 AC_SUBST(extra_passes)
1903 AC_SUBST(extra_programs)
1904 AC_SUBST(float_h_file)
1905 AC_SUBST(gcc_config_arguments)
1906 AC_SUBST(gcc_gxx_include_dir)
1907 AC_SUBST(libstdcxx_incdir)
1908 AC_SUBST(gcc_version)
1909 AC_SUBST(gcc_version_full)
1910 AC_SUBST(gcc_version_trigger)
1911 AC_SUBST(host_exeext)
1912 AC_SUBST(host_extra_gcc_objs)
1913 AC_SUBST(host_xm_file_list)
1914 AC_SUBST(host_xm_file)
1915 AC_SUBST(host_xm_defines)
1916 AC_SUBST(install)
1917 AC_SUBST(lang_options_files)
1918 AC_SUBST(lang_specs_files)
1919 AC_SUBST(lang_tree_files)
1920 AC_SUBST(local_prefix)
1921 AC_SUBST(maybe_use_collect2)
1922 AC_SUBST(md_file)
1923 AC_SUBST(objc_boehm_gc)
1924 AC_SUBST(out_file)
1925 AC_SUBST(out_object_file)
1926 AC_SUBST(stage_prefix_set_by_configure)
1927 AC_SUBST(symbolic_link)
1928 AC_SUBST(thread_file)
1929 AC_SUBST(tm_file_list)
1930 AC_SUBST(tm_file)
1931 AC_SUBST(tm_p_file_list)
1932 AC_SUBST(tm_p_file)
1933 AC_SUBST(xm_file)
1934 AC_SUBST(xm_defines)
1935 AC_SUBST(will_use_collect2)
1936 AC_SUBST(c_target_objs)
1937 AC_SUBST(cxx_target_objs)
1938 AC_SUBST(target_cpu_default)
1939
1940 AC_SUBST_FILE(target_overrides)
1941 AC_SUBST_FILE(host_overrides)
1942 AC_SUBST(cross_defines)
1943 AC_SUBST_FILE(cross_overrides)
1944 AC_SUBST_FILE(build_overrides)
1945 AC_SUBST_FILE(language_fragments)
1946 AC_SUBST_FILE(language_hooks)
1947
1948 # Echo that links are built
1949 if test x$host = x$target
1950 then
1951         str1="native "
1952 else
1953         str1="cross-"
1954         str2=" from $host"
1955 fi
1956
1957 if test x$host != x$build
1958 then
1959         str3=" on a $build system"
1960 fi
1961
1962 if test "x$str2" != x || test "x$str3" != x
1963 then
1964         str4=
1965 fi
1966
1967 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
1968
1969 if test "x$str2" != x || test "x$str3" != x
1970 then
1971         echo " ${str2}${str3}." 1>&2
1972 fi
1973
1974 # Truncate the target if necessary
1975 if test x$host_truncate_target != x; then
1976         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
1977 fi
1978
1979 # Configure the subdirectories
1980 # AC_CONFIG_SUBDIRS($subdirs)
1981
1982 # Create the Makefile
1983 # and configure language subdirectories
1984 AC_OUTPUT($all_outputs,
1985 [
1986 case x$CONFIG_HEADERS in
1987 xauto-host.h:config.in)
1988 echo > cstamp-h ;;
1989 esac
1990 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
1991 # bootstrapping and the installation procedure can still use
1992 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
1993 # FLAGS_TO_PASS has been modified to solve the problem there.
1994 # This is virtually a duplicate of what happens in configure.lang; we do
1995 # an extra check to make sure this only happens if ln -s can be used.
1996 if test "$symbolic_link" = "ln -s"; then
1997  for d in .. ${subdirs} ; do
1998    if test $d != ..; then
1999         STARTDIR=`pwd`
2000         cd $d
2001         for t in stage1 stage2 stage3 stage4 include
2002         do
2003                 rm -f $t
2004                 $symbolic_link ../$t $t 2>/dev/null
2005         done
2006         cd $STARTDIR
2007    fi
2008  done
2009 else true ; fi
2010 # Avoid having to add intl to our include paths.
2011 if test -f intl/libintl.h; then
2012   echo creating libintl.h
2013   echo '#include "intl/libintl.h"' >libintl.h
2014 fi
2015 ],
2016 [
2017 host='${host}'
2018 build='${build}'
2019 target='${target}'
2020 target_alias='${target_alias}'
2021 srcdir='${srcdir}'
2022 subdirs='${subdirs}'
2023 symbolic_link='${symbolic_link}'
2024 program_transform_set='${program_transform_set}'
2025 program_transform_name='${program_transform_name}'
2026 dep_host_xmake_file='${dep_host_xmake_file}'
2027 host_xmake_file='${host_xmake_file}'
2028 dep_tmake_file='${dep_tmake_file}'
2029 tmake_file='${tmake_file}'
2030 thread_file='${thread_file}'
2031 gcc_config_arguments='${gcc_config_arguments}'
2032 gcc_version='${gcc_version}'
2033 gcc_version_full='${gcc_version_full}'
2034 gcc_version_trigger='${gcc_version_trigger}'
2035 local_prefix='${local_prefix}'
2036 build_install_headers_dir='${build_install_headers_dir}'
2037 build_exeext='${build_exeext}'
2038 host_exeext='${host_exeext}'
2039 out_file='${out_file}'
2040 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2041 SET_MAKE='${SET_MAKE}'
2042 target_list='${target_list}'
2043 target_overrides='${target_overrides}'
2044 host_overrides='${host_overrides}'
2045 cross_defines='${cross_defines}'
2046 cross_overrides='${cross_overrides}'
2047 build_overrides='${build_overrides}'
2048 cpp_install_dir='${cpp_install_dir}'
2049 ])