gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Find the native compiler
 339 AC_PROG_CC
 340 AC_PROG_CC_C_O
 341 # autoconf is lame and doesn't give us any substitution variable for this.
 342 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 343   NO_MINUS_C_MINUS_O=yes
 344 else
 345   OUTPUT_OPTION='-o $@'
 346 fi
 347 AC_SUBST(NO_MINUS_C_MINUS_O)
 348 AC_SUBST(OUTPUT_OPTION)
 349
 350 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 351 ac_cv_prog_cc_no_long_long,
 352 [save_CFLAGS="$CFLAGS"
 353 CFLAGS="-Wno-long-long"
 354 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 355                ac_cv_prog_cc_no_long_long=no)
 356 CFLAGS="$save_CFLAGS"])
 357 strict1_warn=
 358 if test $ac_cv_prog_cc_no_long_long = yes; then
 359   strict1_warn="-pedantic -Wno-long-long"
 360 fi
 361 AC_SUBST(strict1_warn)
 362
 363 AC_PROG_CPP
 364 AC_C_INLINE
 365 gcc_AC_C_VOLATILE
 366
 367 gcc_AC_C_LONG_DOUBLE
 368 gcc_AC_C_LONG_LONG
 369 gcc_AC_C__BOOL
 370
 371 # sizeof(char) is 1 by definition.
 372 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 373 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 374 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 375 if test $ac_cv_c_long_long = yes; then
 376   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 377 fi
 378 if test $ac_cv_c___int64 = yes; then
 379   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 380 fi
 381
 382 gcc_AC_C_CHARSET
 383
 384 # If the native compiler is GCC, we can enable warnings even in stage1.
 385 # That's useful for people building cross-compilers, or just running a
 386 # quick `make'.
 387 warn_cflags=
 388 if test "x$GCC" = "xyes"; then
 389   warn_cflags='$(GCC_WARN_CFLAGS)'
 390 fi
 391 AC_SUBST(warn_cflags)
 392
 393 # Stage specific cflags for build.
 394 stage1_cflags=
 395 case $build in
 396 vax-*-*)
 397   if test x$GCC = xyes
 398   then
 399     stage1_cflags="-Wa,-J"
 400   else
 401     stage1_cflags="-J"
 402   fi
 403   ;;
 404 esac
 405 AC_SUBST(stage1_cflags)
 406
 407 AC_PROG_MAKE_SET
 408
 409 AC_MSG_CHECKING([whether a default assembler was specified])
 410 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 411     if test x"$gas_flag" = x"no"; then
 412         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 413     else
 414         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 415     fi
 416 else
 417     AC_MSG_RESULT(no)
 418 fi
 419
 420 AC_MSG_CHECKING([whether a default linker was specified])
 421 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 422     if test x"$gnu_ld_flag" = x"no"; then
 423         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 424     else
 425         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 426     fi
 427 else
 428     AC_MSG_RESULT(no)
 429 fi
 430
 431 AC_MSG_CHECKING(for GNU C library)
 432 AC_CACHE_VAL(gcc_cv_glibc,
 433 [AC_TRY_COMPILE(
 434   [#include <features.h>],[
 435 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 436 #error Not a GNU C library system
 437 #endif],
 438   [gcc_cv_glibc=yes],
 439   gcc_cv_glibc=no)])
 440 AC_MSG_RESULT($gcc_cv_glibc)
 441 if test $gcc_cv_glibc = yes; then
 442   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 443 fi
 444
 445 # Find some useful tools
 446 AC_PROG_AWK
 447 gcc_AC_PROG_LN
 448 gcc_AC_PROG_LN_S
 449 AC_PROG_RANLIB
 450 gcc_AC_PROG_INSTALL
 451
 452 AC_HEADER_STDC
 453 AC_HEADER_TIME
 454 gcc_AC_HEADER_STDBOOL
 455 gcc_AC_HEADER_STRING
 456 AC_HEADER_SYS_WAIT
 457 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 458                  fcntl.h unistd.h sys/file.h sys/time.h \
 459                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 460                  direct.h malloc.h langinfo.h)
 461
 462 # Check for thread headers.
 463 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 464 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 465
 466 # These tests can't be done till we know if we have limits.h.
 467 gcc_AC_C_CHAR_BIT
 468 gcc_AC_C_COMPILE_ENDIAN
 469 gcc_AC_C_FLOAT_FORMAT
 470
 471 # See if GNAT has been installed
 472 gcc_AC_PROG_GNAT
 473
 474 # See if we have the mktemp command.
 475 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 476
 477 # Do we have a single-tree copy of texinfo?
 478 if test -f $srcdir/../texinfo/Makefile.in; then
 479   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 480   gcc_cv_prog_makeinfo_modern=yes
 481   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 482 else
 483   # See if makeinfo has been installed and is modern enough
 484   # that we can use it.
 485   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 486   [GNU texinfo.* \([0-9][0-9.]*\)],
 487   [4.*])
 488 fi
 489
 490 if test $gcc_cv_prog_makeinfo_modern = no; then
 491   AC_MSG_WARN([
 492 *** Makeinfo is missing or too old.
 493 *** Info documentation will not be built.])
 494   BUILD_INFO=
 495 else
 496   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 497 fi
 498
 499 # Is pod2man recent enough to regenerate manpages?
 500 AC_MSG_CHECKING([for recent Pod::Man])
 501 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 502   AC_MSG_RESULT(yes)
 503   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 504 else
 505   AC_MSG_RESULT(no)
 506   GENERATED_MANPAGES=
 507 fi
 508
 509 # How about lex?
 510 dnl Don't use AC_PROG_LEX; we insist on flex.
 511 dnl LEXLIB is not useful in gcc.
 512 if test -f $srcdir/../flex/skel.c; then
 513   FLEX='$(objdir)/../flex/flex'
 514 else
 515   AC_CHECK_PROG(FLEX, flex, flex, false)
 516 fi
 517
 518 # Bison?
 519 # The -L switch is so bison can find its skeleton file.
 520 if test -f $srcdir/../bison/bison.simple; then
 521   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 522 else
 523   AC_CHECK_PROG(BISON, bison, bison, false)
 524 fi
 525
 526 # These libraries may be used by collect2.
 527 # We may need a special search path to get them linked.
 528 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 529 [save_LIBS="$LIBS"
 530 for libs in '' -lld -lmld \
 531                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 532                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 533 do
 534         LIBS="$libs"
 535         AC_TRY_LINK_FUNC(ldopen,
 536                 [gcc_cv_collect2_libs="$libs"; break])
 537 done
 538 LIBS="$save_LIBS"
 539 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 540 case $gcc_cv_collect2_libs in
 541         "none required")        ;;
 542         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 543 esac
 544 AC_SUBST(COLLECT2_LIBS)
 545
 546 # When building Ada code on Alpha, we need exc_resume which is usually in
 547 # -lexc.  So test for it.
 548 save_LIBS="$LIBS"
 549 LIBS=
 550 AC_SEARCH_LIBS(exc_resume, exc)
 551 GNAT_LIBEXC="$LIBS"
 552 LIBS="$save_LIBS"
 553 AC_SUBST(GNAT_LIBEXC)
 554
 555 # See if the stage1 system preprocessor understands the ANSI C
 556 # preprocessor stringification operator.  (Used by symcat.h.)
 557 AC_C_STRINGIZE
 558
 559 # Use <inttypes.h> only if it exists,
 560 # doesn't clash with <sys/types.h>, and declares intmax_t.
 561 AC_MSG_CHECKING(for inttypes.h)
 562 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 563 [AC_TRY_COMPILE(
 564   [#include <sys/types.h>
 565 #include <inttypes.h>],
 566   [intmax_t i = -1;],
 567   [gcc_cv_header_inttypes_h=yes],
 568   gcc_cv_header_inttypes_h=no)])
 569 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 570 if test $gcc_cv_header_inttypes_h = yes; then
 571   AC_DEFINE(HAVE_INTTYPES_H, 1,
 572         [Define if you have a working <inttypes.h> header file.])
 573 fi
 574
 575 dnl Disabled until we have a complete test for buggy enum bitfields.
 576 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 577
 578 AC_CHECK_FUNCS(strtoul bsearch popen times clock \
 579         strchr strrchr kill getrlimit setrlimit atoll atoq \
 580         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 581         fputs_unlocked fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 582         lstat)
 583
 584 AC_CHECK_TYPE(ssize_t, int)
 585
 586 # Try to determine the array type of the second argument of getgroups
 587 # for the target system (int or gid_t).
 588 AC_TYPE_GETGROUPS
 589 if test "${target}" = "${build}"; then
 590   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 591 else
 592   case "${target}" in
 593         # This condition may need some tweaking.  It should include all
 594         # targets where the array type of the second argument of getgroups
 595         # is int and the type of gid_t is not equivalent to int.
 596         *-*-sunos* | *-*-ultrix*)
 597                 TARGET_GETGROUPS_T=int
 598                 ;;
 599         *)
 600                 TARGET_GETGROUPS_T=gid_t
 601                 ;;
 602   esac
 603 fi
 604 AC_SUBST(TARGET_GETGROUPS_T)
 605
 606 gcc_AC_FUNC_VFPRINTF_DOPRNT
 607 gcc_AC_FUNC_STRSTR
 608 gcc_AC_FUNC_PRINTF_PTR
 609
 610 case "${host}" in
 611 *-*-uwin*)
 612   AC_MSG_ERROR([
 613 *** UWIN may not be used as a host platform because
 614 *** linking with posix.dll is not allowed by the GNU GPL])
 615   ;;
 616 esac
 617 AC_FUNC_VFORK
 618 AC_FUNC_MMAP_ANYWHERE
 619 AC_FUNC_MMAP_FILE
 620
 621 AM_ICONV
 622
 623 # We will need to find libiberty.h and ansidecl.h
 624 saved_CFLAGS="$CFLAGS"
 625 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 626 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 627         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 628         fprintf_unlocked strstr environ errno \
 629         malloc realloc calloc free basename getopt clock, , ,[
 630 #include "ansidecl.h"
 631 #include "system.h"])
 632
 633 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 634 #include "ansidecl.h"
 635 #include "system.h"
 636 #ifdef HAVE_SYS_RESOURCE_H
 637 #include <sys/resource.h>
 638 #endif
 639 ])
 640
 641 gcc_AC_CHECK_DECLS(times, , ,[
 642 #include "ansidecl.h"
 643 #include "system.h"
 644 #ifdef HAVE_SYS_TIMES_H
 645 #include <sys/times.h>
 646 #endif
 647 ])
 648
 649 # More time-related stuff.
 650 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 651 AC_TRY_COMPILE([
 652 #include "ansidecl.h"
 653 #include "system.h"
 654 #ifdef HAVE_SYS_TIMES_H
 655 #include <sys/times.h>
 656 #endif
 657 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 658 if test $ac_cv_struct_tms = yes; then
 659   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 660   [Define if <sys/times.h> defines struct tms.])
 661 fi
 662
 663 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 664 # revisit after autoconf 2.50.
 665 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 666 AC_TRY_COMPILE([
 667 #include "ansidecl.h"
 668 #include "system.h"
 669 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 670 if test $gcc_cv_type_clock_t = yes; then
 671   AC_DEFINE(HAVE_CLOCK_T, 1,
 672   [Define if <time.h> defines clock_t.])
 673 fi
 674
 675 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 676 CFLAGS="$saved_CFLAGS"
 677
 678 # mkdir takes a single argument on some systems.
 679 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 680
 681 # File extensions
 682 manext='.1'
 683 objext='.o'
 684 AC_SUBST(manext)
 685 AC_SUBST(objext)
 686
 687 build_xm_file=
 688 build_xm_defines=
 689 build_install_headers_dir=install-headers-tar
 690 build_exeext=
 691 host_xm_file=
 692 host_xm_defines=
 693 host_xmake_file=
 694 host_truncate_target=
 695 host_exeext=
 696
 697 # Decode the host machine, then the target machine.
 698 # For the host machine, we save the xm_file variable as host_xm_file;
 699 # then we decode the target machine and forget everything else
 700 # that came from the host machine.
 701 for machine in $build $host $target; do
 702         . ${srcdir}/config.gcc
 703 done
 704
 705 extra_objs="${host_extra_objs} ${extra_objs}"
 706
 707 # Default the target-machine variables that were not explicitly set.
 708 if test x"$tm_file" = x
 709 then tm_file=$cpu_type/$cpu_type.h; fi
 710
 711 if test x"$extra_headers" = x
 712 then extra_headers=; fi
 713
 714 if test x$md_file = x
 715 then md_file=$cpu_type/$cpu_type.md; fi
 716
 717 if test x$out_file = x
 718 then out_file=$cpu_type/$cpu_type.c; fi
 719
 720 if test x"$tmake_file" = x
 721 then tmake_file=$cpu_type/t-$cpu_type
 722 fi
 723
 724 if test x"$dwarf2" = xyes
 725 then tm_file="$tm_file tm-dwarf2.h"
 726 fi
 727
 728 if test x$float_format = x
 729 then float_format=i64
 730 fi
 731
 732 if test $float_format = none
 733 then float_h_file=Makefile.in
 734 else float_h_file=float-$float_format.h
 735 fi
 736
 737 # Handle cpp installation.
 738 if test x$enable_cpp != xno
 739 then
 740   tmake_file="$tmake_file t-install-cpp"
 741 fi
 742
 743 # Say what files are being used for the output code and MD file.
 744 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 745 echo "Using \`$srcdir/config/$md_file' as machine description file."
 746
 747 # If any of the xm_file variables contain nonexistent files, warn
 748 # about them and drop them.
 749
 750 bx=
 751 for x in $build_xm_file; do
 752   if    test -f $srcdir/config/$x
 753   then      bx="$bx $x"
 754   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 755   fi
 756 done
 757 build_xm_file="$bx"
 758
 759 hx=
 760 for x in $host_xm_file; do
 761   if    test -f $srcdir/config/$x
 762   then      hx="$hx $x"
 763   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 764   fi
 765 done
 766 host_xm_file="$hx"
 767
 768 tx=
 769 for x in $xm_file; do
 770   if    test -f $srcdir/config/$x
 771   then      tx="$tx $x"
 772   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 773   fi
 774 done
 775 xm_file="$tx"
 776
 777 count=a
 778 for f in $tm_file; do
 779         count=${count}x
 780 done
 781 if test $count = ax; then
 782         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 783 else
 784         echo "Using the following target machine macro files:"
 785         for f in $tm_file; do
 786                 echo "  $srcdir/config/$f"
 787         done
 788 fi
 789
 790 count=a
 791 for f in $host_xm_file; do
 792         count=${count}x
 793 done
 794 if test $count = a; then
 795         :
 796 elif test $count = ax; then
 797         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 798 else
 799         echo "Using the following host machine macro files:"
 800         for f in $host_xm_file; do
 801                 echo "  $srcdir/config/$f"
 802         done
 803 fi
 804
 805 if test "$host_xm_file" != "$build_xm_file"; then
 806         count=a
 807         for f in $build_xm_file; do
 808                 count=${count}x
 809         done
 810         if test $count = a; then
 811                 :
 812         elif test $count = ax; then
 813                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 814         else
 815                 echo "Using the following build machine macro files:"
 816                 for f in $build_xm_file; do
 817                         echo "  $srcdir/config/$f"
 818                 done
 819         fi
 820 fi
 821
 822 if test x$thread_file = x; then
 823         if test x$target_thread_file != x; then
 824                 thread_file=$target_thread_file
 825         else
 826                 thread_file='single'
 827         fi
 828 fi
 829
 830 # auto-host.h is the file containing items generated by autoconf and is
 831 # the first file included by config.h.
 832 # If host=build, it is correct to have hconfig include auto-host.h
 833 # as well.  If host!=build, we are in error and need to do more
 834 # work to find out the build config parameters.
 835 if test x$host = x$build
 836 then
 837         build_auto=auto-host.h
 838 else
 839         # We create a subdir, then run autoconf in the subdir.
 840         # To prevent recursion we set host and build for the new
 841         # invocation of configure to the build for this invocation
 842         # of configure.
 843         tempdir=build.$$
 844         rm -rf $tempdir
 845         mkdir $tempdir
 846         cd $tempdir
 847         case ${srcdir} in
 848         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 849         *) realsrcdir=../${srcdir};;
 850         esac
 851         saved_CFLAGS="${CFLAGS}"
 852         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 853         ${realsrcdir}/configure \
 854                 --target=$target --host=$build --build=$build
 855         CFLAGS="${saved_CFLAGS}"
 856
 857         # We just finished tests for the build machine, so rename
 858         # the file auto-build.h in the gcc directory.
 859         mv auto-host.h ../auto-build.h
 860         cd ..
 861         rm -rf $tempdir
 862         build_auto=auto-build.h
 863 fi
 864
 865 tm_file="${tm_file} defaults.h"
 866 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 867 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 868 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 869
 870 # Truncate the target if necessary
 871 if test x$host_truncate_target != x; then
 872         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 873 fi
 874
 875 # Get the version trigger filename from the toplevel
 876 if test "${with_gcc_version_trigger+set}" = set; then
 877         gcc_version_trigger=$with_gcc_version_trigger
 878 else
 879         gcc_version_trigger=${srcdir}/version.c
 880 fi
 881 changequote(,)dnl
 882 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 883 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 884
 885 # Compile in configure arguments.
 886 if test -f configargs.h ; then
 887         # Being re-configured.
 888         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 889         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 890 else
 891         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 892 fi
 893 cat > configargs.h <<EOF
 894 /* Generated automatically. */
 895 static const char configuration_arguments[] = "$gcc_config_arguments";
 896 static const char thread_model[] = "$thread_file";
 897 EOF
 898 changequote([,])dnl
 899
 900 # Internationalization
 901 PACKAGE=gcc
 902 VERSION="$gcc_version"
 903 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 904         [Define to the name of the distribution.])
 905 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 906         [Define to the version of the distribution.])
 907 AC_SUBST(PACKAGE)
 908 AC_SUBST(VERSION)
 909
 910 ALL_LINGUAS="sv"
 911
 912 # Enable NLS support by default
 913 AC_ARG_ENABLE(nls,
 914   [  --enable-nls            use Native Language Support (default)],
 915   , enable_nls=yes)
 916
 917 # if cross compiling, disable NLS support.
 918 # It's not worth the trouble, at least for now.
 919
 920 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 921   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 922   enable_nls=no
 923 fi
 924
 925 AM_GNU_GETTEXT
 926 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 927
 928 # Windows32 Registry support for specifying GCC installation paths.
 929 AC_ARG_ENABLE(win32-registry,
 930 [  --disable-win32-registry
 931                           disable lookup of installation paths in the
 932                           Registry on Windows hosts
 933   --enable-win32-registry enable registry lookup (default)
 934   --enable-win32-registry=KEY
 935                           use KEY instead of GCC version as the last portion
 936                           of the registry key],,)
 937 case $host_os in
 938         win32 | pe | cygwin* | mingw32* | uwin*)
 939 AC_MSG_CHECKING(whether windows registry support is requested)
 940 if test "x$enable_win32_registry" != xno; then
 941   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 942 [Define to 1 if installation paths should be looked up in Windows32
 943    Registry. Ignored on non windows32 hosts.])
 944   AC_MSG_RESULT(yes)
 945   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 946 else
 947   AC_MSG_RESULT(no)
 948 fi
 949
 950 # Check if user specified a different registry key.
 951 case "x${enable_win32_registry}" in
 952 x | xyes)
 953   # default.
 954   gcc_cv_win32_registry_key="$VERSION"
 955   ;;
 956 xno)
 957   # no registry lookup.
 958   gcc_cv_win32_registry_key=''
 959   ;;
 960 *)
 961   # user-specified key.
 962   gcc_cv_win32_registry_key="$enable_win32_registry"
 963   ;;
 964 esac
 965
 966 if test "x$enable_win32_registry" != xno; then
 967   AC_MSG_CHECKING(registry key on windows hosts)
 968   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 969         [Define to be the last portion of registry key on windows hosts.])
 970   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 971 fi
 972 ;;
 973 esac
 974
 975 # Get an absolute path to the GCC top-level source directory
 976 holddir=`pwd`
 977 cd $srcdir
 978 topdir=`pwd`
 979 cd $holddir
 980
 981 # Conditionalize the makefile for this host machine.
 982 # Make-host contains the concatenation of all host makefile fragments
 983 # [there can be more than one].  This file is built by configure.frag.
 984 host_overrides=Make-host
 985 dep_host_xmake_file=
 986 for f in .. ${host_xmake_file}
 987 do
 988         if test -f ${srcdir}/config/$f
 989         then
 990                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 991         fi
 992 done
 993
 994 # Conditionalize the makefile for this target machine.
 995 # Make-target contains the concatenation of all host makefile fragments
 996 # [there can be more than one].  This file is built by configure.frag.
 997 target_overrides=Make-target
 998 dep_tmake_file=
 999 for f in .. ${tmake_file}
1000 do
1001         if test -f ${srcdir}/config/$f
1002         then
1003                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1004         fi
1005 done
1006
1007 # If the host doesn't support symlinks, modify CC in
1008 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1009 # Otherwise, we can use "CC=$(CC)".
1010 rm -f symtest.tem
1011 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1012 then
1013         cc_set_by_configure="\$(CC)"
1014         quoted_cc_set_by_configure="\$(CC)"
1015         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1016 else
1017         rm -f symtest.tem
1018         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1019         then
1020                 symbolic_link="cp -p"
1021         else
1022                 symbolic_link="cp"
1023         fi
1024         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1025         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1026         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1027 fi
1028 rm -f symtest.tem
1029
1030 out_object_file=`basename $out_file .c`.o
1031
1032 tm_file_list=
1033 for f in $tm_file; do
1034   case $f in
1035     ansidecl.h )
1036        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1037     defaults.h )
1038        tm_file_list="${tm_file_list} $f" ;;
1039     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1040   esac
1041 done
1042
1043 tm_p_file_list=
1044 for f in $tm_p_file; do
1045     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1046 done
1047
1048 host_xm_file_list=
1049 for f in $host_xm_file; do
1050   case $f in
1051     ansidecl.h )
1052        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1053     auto-host.h | defaults.h )
1054        host_xm_file_list="${host_xm_file_list} $f" ;;
1055     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1056   esac
1057 done
1058
1059 build_xm_file_list=
1060 for f in $build_xm_file; do
1061   case $f in
1062     ansidecl.h )
1063        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1064     auto-build.h | auto-host.h | defaults.h )
1065        build_xm_file_list="${build_xm_file_list} $f" ;;
1066     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1067   esac
1068 done
1069
1070 # Define macro CROSS_COMPILE in compilation
1071 # if this is a cross-compiler.
1072 # Also use all.cross instead of all.internal
1073 # and add cross-make to Makefile.
1074 cross_overrides="/dev/null"
1075 if test x$host != x$target
1076 then
1077         cross_defines="CROSS=-DCROSS_COMPILE"
1078         cross_overrides="${topdir}/cross-make"
1079 fi
1080
1081 # If this is a cross-compiler that does not
1082 # have its own set of headers then define
1083 # inhibit_libc
1084
1085 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1086 # This prevents libgcc2 from containing any code which requires libc
1087 # support.
1088 inhibit_libc=
1089 if [test x$host != x$target] && [test x$with_headers = x]; then
1090        inhibit_libc=-Dinhibit_libc
1091 else
1092        if [test x$with_newlib = xyes]; then
1093                inhibit_libc=-Dinhibit_libc
1094        fi
1095 fi
1096 AC_SUBST(inhibit_libc)
1097
1098 # When building gcc with a cross-compiler, we need to fix a few things.
1099 # This must come after cross-make as we want all.build to override
1100 # all.cross.
1101 build_overrides="/dev/null"
1102 if test x$build != x$host
1103 then
1104         build_overrides="${topdir}/build-make"
1105 fi
1106
1107 # Expand extra_headers to include complete path.
1108 # This substitutes for lots of t-* files.
1109 extra_headers_list=
1110 if test "x$extra_headers" = x
1111 then true
1112 else
1113         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1114         for file in $extra_headers;
1115         do
1116                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1117         done
1118 fi
1119
1120 if test x$use_collect2 = xno; then
1121         use_collect2=
1122 fi
1123
1124 # Add a definition of USE_COLLECT2 if system wants one.
1125 if test x$use_collect2 != x
1126 then
1127         host_xm_defines="${host_xm_defines} USE_COLLECT2"
1128         xm_defines="${xm_defines} USE_COLLECT2"
1129 fi
1130
1131 # If we have gas in the build tree, make a link to it.
1132 if test -f ../gas/Makefile; then
1133         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1134 fi
1135
1136 # If we have nm in the build tree, make a link to it.
1137 if test -f ../binutils/Makefile; then
1138         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1139 fi
1140
1141 # If we have ld in the build tree, make a link to it.
1142 if test -f ../ld/Makefile; then
1143         rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1144 fi
1145
1146 # Figure out what assembler we will be using.
1147 AC_MSG_CHECKING(what assembler to use)
1148 gcc_cv_as=
1149 gcc_cv_gas_major_version=
1150 gcc_cv_gas_minor_version=
1151 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1152 gcc_cv_as_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1153 if test -x "$DEFAULT_ASSEMBLER"; then
1154         gcc_cv_as="$DEFAULT_ASSEMBLER"
1155 elif test -x "$AS"; then
1156         gcc_cv_as="$AS"
1157 elif test -x as$host_exeext; then
1158         # Build using assembler in the current directory.
1159         gcc_cv_as=./as$host_exeext
1160 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1161         # Single tree build which includes gas.
1162         for f in $gcc_cv_as_bfd_srcdir/configure $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1163         do
1164 changequote(,)dnl
1165                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1166 changequote([,])dnl
1167                 if test x$gcc_cv_gas_version != x; then
1168                         break
1169                 fi
1170         done
1171 changequote(,)dnl
1172         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1173         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1174 changequote([,])dnl
1175 fi
1176
1177 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1178         # Native build.
1179         # Search the same directories that the installed compiler will
1180         # search.  Else we may find the wrong assembler and lose.  If we
1181         # do not find a suitable assembler binary, then try the user's
1182         # path.
1183         #
1184         # Also note we have to check MD_EXEC_PREFIX before checking the
1185         # user's path.  Unfortunately, there is no good way to get at the
1186         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1187         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1188         # to be fixed as part of the make/configure rewrite too.
1189
1190         if test "x$exec_prefix" = xNONE; then
1191                 if test "x$prefix" = xNONE; then
1192                         test_prefix=/usr/local
1193                 else
1194                         test_prefix=$prefix
1195                 fi
1196         else
1197                 test_prefix=$exec_prefix
1198         fi
1199
1200         # If the loop below does not find an assembler, then use whatever
1201         # one we can find in the users's path.
1202         # user's path.
1203         gcc_cv_as=as$host_exeext
1204
1205         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1206                    $test_prefix/lib/gcc-lib/$target \
1207                    /usr/lib/gcc/$target/$gcc_version \
1208                    /usr/lib/gcc/$target \
1209                    $test_prefix/$target/bin/$target/$gcc_version \
1210                    $test_prefix/$target/bin \
1211                    /usr/libexec \
1212                    /usr/ccs/gcc \
1213                    /usr/ccs/bin \
1214                    /udk/usr/ccs/bin \
1215                    /bsd43/usr/lib/cmplrs/cc \
1216                    /usr/cross64/usr/bin \
1217                    /usr/lib/cmplrs/cc \
1218                    /sysv/usr/lib/cmplrs/cc \
1219                    /svr4/usr/lib/cmplrs/cc \
1220                    /usr/bin"
1221
1222         for dir in $test_dirs; do
1223                 if test -f $dir/as$host_exeext; then
1224                         gcc_cv_as=$dir/as$host_exeext
1225                         break;
1226                 fi
1227         done
1228 fi
1229 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1230   AC_MSG_RESULT("newly built gas")
1231 else
1232   AC_MSG_RESULT($gcc_cv_as)
1233 fi
1234
1235 # Figure out what nm we will be using.
1236 AC_MSG_CHECKING(what nm to use)
1237 if test -x nm$host_exeext; then
1238         gcc_cv_nm=./nm$host_exeext
1239 elif test x$host = x$target; then
1240         # Native build.
1241         gcc_cv_nm=nm$host_exeext
1242 fi
1243 AC_MSG_RESULT($gcc_cv_nm)
1244
1245 # Figure out what assembler alignment features are present.
1246 AC_MSG_CHECKING(assembler alignment features)
1247 gcc_cv_as_alignment_features=none
1248 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1249         # Gas version 2.6 and later support for .balign and .p2align.
1250         # bytes to skip when using .p2align.
1251         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1252                 gcc_cv_as_alignment_features=".balign and .p2align"
1253                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1254         fi
1255         # Gas version 2.8 and later support specifying the maximum
1256         # bytes to skip when using .p2align.
1257         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1258                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1259                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1260         fi
1261 elif test x$gcc_cv_as != x; then
1262         # Check if we have .balign and .p2align
1263         echo ".balign  4" > conftest.s
1264         echo ".p2align  2" >> conftest.s
1265         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1266                 gcc_cv_as_alignment_features=".balign and .p2align"
1267                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1268         fi
1269         rm -f conftest.s conftest.o
1270         # Check if specifying the maximum bytes to skip when
1271         # using .p2align is supported.
1272         echo ".p2align 4,,7" > conftest.s
1273         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1274                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1275                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1276         fi
1277         rm -f conftest.s conftest.o
1278 fi
1279 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1280
1281 AC_MSG_CHECKING(assembler subsection support)
1282 gcc_cv_as_subsections=no
1283 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1284   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1285     gcc_cv_as_subsections="working .subsection -1"
1286   fi
1287 elif test x$gcc_cv_as != x; then
1288         # Check if we have .subsection
1289         echo ".subsection 1" > conftest.s
1290         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1291                 gcc_cv_as_subsections=".subsection"
1292                 if test x$gcc_cv_nm != x; then
1293                         cat > conftest.s <<EOF
1294 conftest_label1: .word 0
1295 .subsection -1
1296 conftest_label2: .word 0
1297 .previous
1298 EOF
1299                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1300                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1301                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1302                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1303                                         :
1304                                 else
1305                                         gcc_cv_as_subsections="working .subsection -1"
1306                                 fi
1307                         fi
1308                 fi
1309         fi
1310         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1311 fi
1312 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1313         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1314 [Define if your assembler supports .subsection and .subsection -1 starts
1315    emitting at the beginning of your section.])
1316 fi
1317 AC_MSG_RESULT($gcc_cv_as_subsections)
1318
1319 AC_MSG_CHECKING(assembler weak support)
1320 gcc_cv_as_weak=no
1321 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1322   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1323     gcc_cv_as_weak="yes"
1324   fi
1325 elif test x$gcc_cv_as != x; then
1326         # Check if we have .weak
1327         echo "  .weak foobar" > conftest.s
1328         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1329                 gcc_cv_as_weak="yes"
1330         fi
1331         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1332 fi
1333 if test x"$gcc_cv_as_weak" = xyes; then
1334         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1335 fi
1336 AC_MSG_RESULT($gcc_cv_as_weak)
1337
1338 AC_MSG_CHECKING(assembler hidden support)
1339 gcc_cv_as_hidden=no
1340 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1341   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1342     gcc_cv_as_hidden="yes"
1343   fi
1344 elif test x$gcc_cv_as != x; then
1345         # Check if we have .hidden
1346         echo "  .hidden foobar" > conftest.s
1347         echo "foobar:" >> conftest.s
1348         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1349                 gcc_cv_as_hidden="yes"
1350         fi
1351         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1352 fi
1353 if test x"$gcc_cv_as_hidden" = xyes; then
1354         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1355                 [Define if your assembler supports .hidden.])
1356 fi
1357 AC_MSG_RESULT($gcc_cv_as_hidden)
1358
1359 AC_MSG_CHECKING(assembler leb128 support)
1360 gcc_cv_as_leb128=no
1361 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1362   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1363     gcc_cv_as_leb128="yes"
1364   fi
1365 elif test x$gcc_cv_as != x; then
1366         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1367         cat > conftest.s <<EOF
1368         .data
1369         .uleb128 L2 - L1
1370 L1:
1371         .uleb128 1280
1372         .sleb128 -1010
1373 L2:
1374 EOF
1375         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1376                 gcc_cv_as_leb128="yes"
1377
1378                 # GAS versions before 2.11 do not support uleb128,
1379                 # despite appearing to.
1380                 # ??? There exists an elf-specific test that will crash
1381                 # the assembler.  Perhaps it's better to figure out whether
1382                 # arbitrary sections are supported and try the test.
1383                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1384                 if echo "$as_ver" | grep GNU > /dev/null; then
1385                         as_ver=`echo $as_ver | sed -e 's/.* //'`
1386                         as_major=`echo $as_ver | sed 's/\..*//'`
1387 changequote(,)dnl
1388                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1389 changequote([,])dnl
1390                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1391                                 gcc_cv_as_leb128="no"
1392                         fi
1393                 fi
1394         fi
1395         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1396 fi
1397 if test x"$gcc_cv_as_leb128" = xyes; then
1398         AC_DEFINE(HAVE_AS_LEB128, 1,
1399                 [Define if your assembler supports .uleb128.])
1400 fi
1401 AC_MSG_RESULT($gcc_cv_as_leb128)
1402
1403 AC_MSG_CHECKING(assembler eh_frame optimization)
1404 gcc_cv_as_eh_frame=no
1405 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1406   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1407     gcc_cv_as_eh_frame="yes"
1408   fi
1409 elif test x$gcc_cv_as != x; then
1410         # Check if this is GAS.
1411         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1412         rm -f a.out 2> /dev/null
1413         if echo "$as_ver" | grep GNU > /dev/null; then
1414                 # Versions up to and including 2.11.0 may mis-optimize
1415                 # .eh_frame data.  Try something.
1416                 cat > conftest.s <<EOF
1417         .text
1418 .LFB1:
1419         .4byte  0
1420 .L1:
1421         .4byte  0
1422 .LFE1:
1423         .section        .eh_frame,"aw",@progbits
1424 __FRAME_BEGIN__:
1425         .4byte  .LECIE1-.LSCIE1
1426 .LSCIE1:
1427         .4byte  0x0
1428         .byte   0x1
1429         .ascii "z\0"
1430         .byte   0x1
1431         .byte   0x78
1432         .byte   0x1a
1433         .byte   0x0
1434         .byte   0x4
1435         .4byte  1
1436         .p2align 1
1437 .LECIE1:
1438 .LSFDE1:
1439         .4byte  .LEFDE1-.LASFDE1
1440 .LASFDE1:
1441         .4byte  .LASFDE1-__FRAME_BEGIN__
1442         .4byte  .LFB1
1443         .4byte  .LFE1-.LFB1
1444         .byte   0x4
1445         .4byte  .LFE1-.LFB1
1446         .byte   0x4
1447         .4byte  .L1-.LFB1
1448 .LEFDE1:
1449 EOF
1450                 cat > conftest.lit <<EOF
1451  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1452  0010 01000000 12000000 18000000 00000000  ................
1453  0020 08000000 04080000 0044               .........D
1454 EOF
1455                 cat > conftest.big <<EOF
1456  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1457  0010 00000001 00000012 00000018 00000000  ................
1458  0020 00000008 04000000 0844               .........D
1459 EOF
1460                 # If the assembler didn't choke, and we can objdump,
1461                 # and we got the correct data, then succeed.
1462                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1463                    && objdump -s -j .eh_frame conftest.o 2>/dev/null \
1464                       | tail -3 > conftest.got \
1465                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1466                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1467                 then
1468                         gcc_cv_as_eh_frame="yes"
1469                 else
1470                         gcc_cv_as_eh_frame="bad"
1471                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1472                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1473         [Define if your assembler mis-optimizes .eh_frame data.])
1474                         fi
1475                 fi
1476         fi
1477         rm -f conftest.*
1478 fi
1479 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1480
1481 AC_MSG_CHECKING(assembler section merging support)
1482 gcc_cv_as_shf_merge=no
1483 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1484   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1485     gcc_cv_as_shf_merge=yes
1486   fi
1487 elif test x$gcc_cv_as != x; then
1488         # Check if we support SHF_MERGE sections
1489         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
1490         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
1491                 gcc_cv_as_shf_merge=yes
1492         fi
1493         rm -f conftest.s conftest.o
1494 fi
1495 if test x"$gcc_cv_as_shf_merge" = xyes; then
1496         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1497 [Define if your assembler supports marking sections with SHF_MERGE flag.])
1498 fi
1499 AC_MSG_RESULT($gcc_cv_as_shf_merge)
1500
1501 case "$target" in
1502   sparc*-*-*)
1503     AC_CACHE_CHECK([assembler .register pseudo-op support],
1504         gcc_cv_as_register_pseudo_op, [
1505         gcc_cv_as_register_pseudo_op=unknown
1506         if test x$gcc_cv_as != x; then
1507             # Check if we have .register
1508             echo ".register %g2, #scratch" > conftest.s
1509             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1510                 gcc_cv_as_register_pseudo_op=yes
1511             else
1512                 gcc_cv_as_register_pseudo_op=no
1513             fi
1514             rm -f conftest.s conftest.o
1515         fi
1516     ])
1517     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1518         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1519                 [Define if your assembler supports .register.])
1520     fi
1521
1522     AC_CACHE_CHECK([assembler supports -relax],
1523         gcc_cv_as_relax_opt, [
1524         gcc_cv_as_relax_opt=unknown
1525         if test x$gcc_cv_as != x; then
1526             # Check if gas supports -relax
1527             echo ".text" > conftest.s
1528             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1529                 gcc_cv_as_relax_opt=yes
1530             else
1531                 gcc_cv_as_relax_opt=no
1532             fi
1533             rm -f conftest.s conftest.o
1534         fi
1535     ])
1536     if test "x$gcc_cv_as_relax_opt" = xyes; then
1537         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1538                 [Define if your assembler supports -relax option.])
1539     fi
1540
1541     case "$tm_file" in
1542     *64*)
1543         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1544             gcc_cv_as_flags64, [
1545                 if test -n "$gcc_cv_as"; then
1546                     echo ".xword foo" > conftest.s
1547                     gcc_cv_as_flags64=no
1548                     for flag in "-xarch=v9" "-64 -Av9"; do
1549                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1550                             > /dev/null 2>&1; then
1551                             gcc_cv_as_flags64=$flag
1552                             break
1553                         fi
1554                     done
1555                     rm -f conftest.s conftest.o
1556                 else
1557                     if test "$gas" = yes; then
1558                         gcc_cv_as_flags64="-64 -Av9"
1559                     else
1560                         gcc_cv_as_flags64="-xarch=v9"
1561                     fi
1562                 fi
1563         ])
1564         if test "x$gcc_cv_as_flags64" = xno; then
1565 changequote(, )
1566             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1567             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1568 changequote([, ])
1569         else
1570             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1571                         [Define if the assembler supports 64bit sparc.])
1572         fi
1573         ;;
1574     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1575         ;;
1576     esac
1577
1578     if test "x$gcc_cv_as_flags64" != xno; then
1579         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1580             gcc_cv_as_offsetable_lo10, [
1581             gcc_cv_as_offsetable_lo10=unknown
1582             if test "x$gcc_cv_as" != x; then
1583                 # Check if assembler has offsetable %lo()
1584                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1585                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1586                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1587                         > /dev/null 2>&1 &&
1588                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1589                         > /dev/null 2>&1; then
1590                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1591                         gcc_cv_as_offsetable_lo10=no
1592                     else
1593                         gcc_cv_as_offsetable_lo10=yes
1594                     fi
1595                 else
1596                     gcc_cv_as_offsetable_lo10=no
1597                 fi
1598                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1599             fi
1600         ])
1601         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1602             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1603                 [Define if your assembler supports offsetable %lo().])
1604         fi
1605     fi
1606
1607     ;;
1608
1609 changequote(,)dnl
1610   i[34567]86-*-*)
1611 changequote([,])dnl
1612     AC_MSG_CHECKING(assembler instructions)
1613     gcc_cv_as_instructions=
1614     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1615       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1616         gcc_cv_as_instructions="filds fists"
1617       fi
1618     elif test x$gcc_cv_as != x; then
1619         set "filds fists" "filds mem; fists mem"
1620         while test $# -gt 0
1621         do
1622                 echo "$2" > conftest.s
1623                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1624                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1625                 fi
1626                 shift 2
1627         done
1628         rm -f conftest.s conftest.o
1629     fi
1630     if test x"$gcc_cv_as_instructions" != x; then
1631         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1632     fi
1633     AC_MSG_RESULT($gcc_cv_as_instructions)
1634
1635     AC_MSG_CHECKING(assembler GOTOFF in data directives)
1636     gcc_cv_as_gotoff_in_data=no
1637     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x
1638     then
1639       if test "$gcc_cv_gas_major_version" -eq 2 \
1640          -a "$gcc_cv_gas_minor_version" -ge 11 \
1641          -o "$gcc_cv_gas_major_version" -gt 2; then
1642         gcc_cv_as_gotoff_in_data=yes
1643       fi
1644     elif test x$gcc_cv_as != x; then
1645         cat > conftest.s <<EOF
1646         .text
1647 .L0:
1648         nop
1649         .data
1650         .long .L0@GOTOFF
1651 EOF
1652         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1653           gcc_cv_as_gotoff_in_data=yes
1654         fi
1655     fi
1656     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
1657       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
1658       [Define true if the assembler supports '.long foo@GOTOFF'.])
1659     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
1660     ;;
1661 esac
1662
1663 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1664 gcc_cv_as_dwarf2_debug_line=no
1665 # ??? Not all targets support dwarf2 debug_line, even within a version
1666 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1667 # info to the output file.  So, as supported targets are added to gas 2.11,
1668 # add some instruction here to (also) show we expect this might work.
1669 # ??? Once 2.11 is released, probably need to add first known working
1670 # version to the per-target configury.
1671 case "$target" in
1672   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-*)
1673     insn="nop"
1674     ;;
1675   ia64*-*-*)
1676     insn="nop 0"
1677     ;;
1678   esac
1679 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1680 then
1681   if test "$gcc_cv_gas_major_version" -eq 2 \
1682         -a "$gcc_cv_gas_minor_version" -ge 11 \
1683         -o "$gcc_cv_gas_major_version" -gt 2 \
1684      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1685      && test x"$insn" != x ; then
1686     gcc_cv_as_dwarf2_debug_line="yes"
1687   fi
1688 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1689         echo '  .file 1 "conftest.s"' > conftest.s
1690         echo '  .loc 1 3 0' >> conftest.s
1691         echo "  $insn" >> conftest.s
1692         # ??? This fails with non-gnu grep.
1693         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1694            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1695                 # The .debug_line file table must be in the exact order that
1696                 # we specified the files, since these indicies are also used
1697                 # by DW_AT_decl_file.  Approximate this test by testing if
1698                 # the assembler bitches if the same index is assigned twice.
1699                 echo '  .file 1 "foo.s"' > conftest.s
1700                 echo '  .file 1 "bar.s"' >> conftest.s
1701                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1702                 then
1703                   gcc_cv_as_dwarf2_debug_line="no"
1704                 else
1705                   gcc_cv_as_dwarf2_debug_line="yes"
1706                 fi
1707         fi
1708         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1709 fi
1710 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1711         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1712 [Define if your assembler supports dwarf2 .file/.loc directives,
1713    and preserves file table indicies exactly as given.])
1714 fi
1715 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1716
1717 if test "$prefix" != "/usr" && test "$prefix" != "/usr/local" ; then
1718   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
1719 fi
1720
1721 # Figure out what language subdirectories are present.
1722 # Look if the user specified --enable-languages="..."; if not, use
1723 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1724 # go away some day.
1725 if test x"${enable_languages+set}" != xset; then
1726         if test x"${LANGUAGES+set}" = xset; then
1727                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1728         else
1729                 enable_languages=all
1730         fi
1731 else
1732         if test x"${enable_languages}" = x; then
1733                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1734         fi
1735 fi
1736
1737 # First scan to see if an enabled language requires some other language.
1738 # We assume that a given config-lang.in will list all the language
1739 # front ends it requires, even if some are required indirectly.
1740 for lang in ${srcdir}/*/config-lang.in ..
1741 do
1742    case $lang in
1743     ..)
1744        ;;
1745     # The odd quoting in the next line works around
1746     # an apparent bug in bash 1.12 on linux.
1747 changequote(,)dnl
1748     ${srcdir}/[*]/config-lang.in)
1749        ;;
1750     *)
1751        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1752        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1753        for other in $this_lang_requires
1754        do
1755           case ,${enable_languages}, in
1756            *,$other,*)
1757               ;;
1758            *,all,*)
1759               ;;
1760            *,$lang_alias,*)
1761               enable_languages="$enable_languages,$other"
1762               ;;
1763           esac
1764        done
1765        ;;
1766 changequote([,])dnl
1767    esac
1768 done
1769
1770 subdirs=
1771 for lang in ${srcdir}/*/config-lang.in ..
1772 do
1773         case $lang in
1774         ..) ;;
1775         # The odd quoting in the next line works around
1776         # an apparent bug in bash 1.12 on linux.
1777 changequote(,)dnl
1778         ${srcdir}/[*]/config-lang.in) ;;
1779         *)
1780           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1781           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1782           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1783           if test "x$lang_alias" = x
1784           then
1785                 echo "$lang doesn't set \$language." 1>&2
1786                 exit 1
1787           fi
1788           case ${build_by_default},${enable_languages}, in
1789           *,$lang_alias,*) add_this_lang=yes ;;
1790           no,*) add_this_lang=no ;;
1791           *,all,*) add_this_lang=yes ;;
1792           *) add_this_lang=no ;;
1793           esac
1794           if test x"${add_this_lang}" = xyes; then
1795                 case $lang in
1796                     ${srcdir}/ada/config-lang.in)
1797                         if test x$have_gnat = xyes ; then
1798                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1799                         fi
1800                         ;;
1801                     *)
1802                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1803                         ;;
1804                 esac
1805           fi
1806           ;;
1807 changequote([,])dnl
1808         esac
1809 done
1810
1811 # Make gthr-default.h if we have a thread file.
1812 gthread_flags=
1813 if test $thread_file != single; then
1814     rm -f gthr-default.h
1815     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1816     gthread_flags=-DHAVE_GTHR_DEFAULT
1817 fi
1818 AC_SUBST(gthread_flags)
1819
1820 # Find out what GC implementation we want, or may, use.
1821 AC_ARG_WITH(gc,
1822 [  --with-gc={simple,page} choose the garbage collection mechanism to use
1823                           with the compiler],
1824 [case "$withval" in
1825   simple | page)
1826     GGC=ggc-$withval
1827     ;;
1828   *)
1829     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1830     ;;
1831 esac],
1832 [GGC=ggc-page])
1833 AC_SUBST(GGC)
1834 echo "Using $GGC for garbage collection."
1835
1836 # Use the system's zlib library.
1837 zlibdir=-L../zlib
1838 zlibinc="-I\$(srcdir)/../zlib"
1839 AC_ARG_WITH(system-zlib,
1840 [  --with-system-zlib      use installed libz],
1841 zlibdir=
1842 zlibinc=
1843 )
1844 AC_SUBST(zlibdir)
1845 AC_SUBST(zlibinc)
1846
1847 dnl Very limited version of automake's enable-maintainer-mode
1848
1849 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1850   dnl maintainer-mode is disabled by default
1851   AC_ARG_ENABLE(maintainer-mode,
1852 [  --enable-maintainer-mode
1853                           enable make rules and dependencies not useful
1854                           (and sometimes confusing) to the casual installer],
1855       maintainer_mode=$enableval,
1856       maintainer_mode=no)
1857
1858 AC_MSG_RESULT($maintainer_mode)
1859
1860 if test "$maintainer_mode" = "yes"; then
1861   MAINT=''
1862 else
1863   MAINT='#'
1864 fi
1865 AC_SUBST(MAINT)dnl
1866
1867 # With Setjmp/Longjmp based exception handling.
1868 AC_ARG_ENABLE(sjlj-exceptions,
1869 [  --enable-sjlj-exceptions
1870                           arrange to use setjmp/longjmp exception handling],
1871 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1872 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1873   [Define 0/1 to force the choice for exception handling model.])])
1874
1875 # Make empty files to contain the specs and options for each language.
1876 # Then add #include lines to for a compiler that has specs and/or options.
1877
1878 lang_specs_files=
1879 lang_options_files=
1880 lang_tree_files=
1881 rm -f specs.h options.h gencheck.h
1882 touch specs.h options.h gencheck.h
1883 for subdir in . $subdirs
1884 do
1885         if test -f $srcdir/$subdir/lang-specs.h; then
1886                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1887                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1888         fi
1889         if test -f $srcdir/$subdir/lang-options.h; then
1890                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1891                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1892         fi
1893         if test -f $srcdir/$subdir/$subdir-tree.def; then
1894                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1895                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1896         fi
1897 done
1898
1899 # These (without "all_") are set in each config-lang.in.
1900 # `language' must be a single word so is spelled singularly.
1901 all_languages=
1902 all_boot_languages=
1903 all_compilers=
1904 all_stagestuff=
1905 all_diff_excludes=
1906 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1907 # List of language makefile fragments.
1908 all_lang_makefiles=
1909 all_headers=
1910 all_lib2funcs=
1911
1912 # Add the language fragments.
1913 # Languages are added via two mechanisms.  Some information must be
1914 # recorded in makefile variables, these are defined in config-lang.in.
1915 # We accumulate them and plug them into the main Makefile.
1916 # The other mechanism is a set of hooks for each of the main targets
1917 # like `clean', `install', etc.
1918
1919 language_fragments="Make-lang"
1920 language_hooks="Make-hooks"
1921
1922 for s in .. $subdirs
1923 do
1924         if test $s != ".."
1925         then
1926                 language=
1927                 boot_language=
1928                 compilers=
1929                 stagestuff=
1930                 diff_excludes=
1931                 headers=
1932                 outputs=
1933                 lib2funcs=
1934                 . ${srcdir}/$s/config-lang.in
1935                 if test "x$language" = x
1936                 then
1937                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1938                         exit 1
1939                 fi
1940                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1941                 if test -f ${srcdir}/$s/Makefile.in
1942                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1943                 fi
1944                 all_languages="$all_languages $language"
1945                 if test "x$boot_language" = xyes
1946                 then
1947                         all_boot_languages="$all_boot_languages $language"
1948                 fi
1949                 all_compilers="$all_compilers $compilers"
1950                 all_stagestuff="$all_stagestuff $stagestuff"
1951                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1952                 all_headers="$all_headers $headers"
1953                 all_outputs="$all_outputs $outputs"
1954                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1955         fi
1956 done
1957
1958 check_languages=
1959 for language in .. $all_languages
1960 do
1961         if test $language != ".."
1962         then
1963                 check_languages="$check_languages check-$language"
1964         fi
1965 done
1966
1967 # Since we can't use `::' targets, we link each language in
1968 # with a set of hooks, reached indirectly via lang.${target}.
1969
1970 rm -f Make-hooks
1971 touch Make-hooks
1972 target_list="all.build all.cross start.encap rest.encap \
1973         info dvi \
1974         install-normal install-common install-info install-man \
1975         uninstall \
1976         mostlyclean clean distclean extraclean maintainer-clean \
1977         stage1 stage2 stage3 stage4"
1978 for t in $target_list
1979 do
1980         x=
1981         for lang in .. $all_languages
1982         do
1983                 if test $lang != ".."; then
1984                         x="$x $lang.$t"
1985                 fi
1986         done
1987         echo "lang.$t: $x" >> Make-hooks
1988 done
1989
1990 # Create .gdbinit.
1991
1992 echo "dir ." > .gdbinit
1993 echo "dir ${srcdir}" >> .gdbinit
1994 if test x$gdb_needs_out_file_path = xyes
1995 then
1996         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1997 fi
1998 if test "x$subdirs" != x; then
1999         for s in $subdirs
2000         do
2001                 echo "dir ${srcdir}/$s" >> .gdbinit
2002         done
2003 fi
2004 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2005
2006 # Define variables host_canonical and build_canonical
2007 # because some Cygnus local changes in the Makefile depend on them.
2008 build_canonical=${build}
2009 host_canonical=${host}
2010 target_subdir=
2011 if test "${host}" != "${target}" ; then
2012     target_subdir=${target_alias}/
2013 fi
2014 AC_SUBST(build_canonical)
2015 AC_SUBST(host_canonical)
2016 AC_SUBST(target_subdir)
2017
2018 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2019 # absolute path for gcc_tooldir based on inserting the number of up-directory
2020 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2021 # $(libsubdir)/@(unlibsubdir) based path.
2022 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2023 # make and thus we'd get different behavior depending on where we built the
2024 # sources.
2025 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2026     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2027 else
2028 changequote(<<, >>)dnl
2029 # An explanation of the sed strings:
2030 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2031 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2032 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2033 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
2034 #
2035 # (*) Note this pattern overwrites the first character of the string
2036 # with a forward slash if one is not already present.  This is not a
2037 # problem because the exact names of the sub-directories concerned is
2038 # unimportant, just the number of them matters.
2039 #
2040 # The practical upshot of these patterns is like this:
2041 #
2042 #  prefix     exec_prefix        result
2043 #  ------     -----------        ------
2044 #   /foo        /foo/bar          ../
2045 #   /foo/       /foo/bar          ../
2046 #   /foo        /foo/bar/         ../
2047 #   /foo/       /foo/bar/         ../
2048 #   /foo        /foo/bar/ugg      ../../
2049 #
2050     dollar='$$'
2051     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2052 changequote([, ])dnl
2053 fi
2054 AC_SUBST(gcc_tooldir)
2055 AC_SUBST(dollar)
2056
2057 # Find a directory in which to install a shared libgcc.
2058
2059 AC_ARG_ENABLE(version-specific-runtime-libs,
2060 [  --enable-version-specific-runtime-libs
2061                           specify that runtime libraries should be
2062                           installed in a compiler-specific directory])
2063
2064 AC_ARG_WITH(slibdir,
2065 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2066 slibdir="$with_slibdir",
2067 if test "${enable_version_specific_runtime_libs+set}" = set; then
2068   slibdir='$(libsubdir)'
2069 elif test "$host" != "$target"; then
2070   slibdir='$(build_tooldir)/lib'
2071 else
2072   slibdir='$(libdir)'
2073 fi)
2074 AC_SUBST(slibdir)
2075
2076 # Nothing to do for FLOAT_H, float_format already handled.
2077 objdir=`pwd`
2078 AC_SUBST(objdir)
2079
2080 # Process the language and host/target makefile fragments.
2081 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2082
2083 # Substitute configuration variables
2084 AC_SUBST(subdirs)
2085 AC_SUBST(all_boot_languages)
2086 AC_SUBST(all_compilers)
2087 AC_SUBST(all_diff_excludes)
2088 AC_SUBST(all_headers)
2089 AC_SUBST(all_lang_makefiles)
2090 AC_SUBST(all_languages)
2091 AC_SUBST(all_lib2funcs)
2092 AC_SUBST(all_stagestuff)
2093 AC_SUBST(build_exeext)
2094 AC_SUBST(build_install_headers_dir)
2095 AC_SUBST(build_xm_file_list)
2096 AC_SUBST(build_xm_file)
2097 AC_SUBST(build_xm_defines)
2098 AC_SUBST(check_languages)
2099 AC_SUBST(cc_set_by_configure)
2100 AC_SUBST(quoted_cc_set_by_configure)
2101 AC_SUBST(cpp_install_dir)
2102 AC_SUBST(dep_host_xmake_file)
2103 AC_SUBST(dep_tmake_file)
2104 AC_SUBST(extra_c_flags)
2105 AC_SUBST(extra_headers_list)
2106 AC_SUBST(extra_objs)
2107 AC_SUBST(extra_parts)
2108 AC_SUBST(extra_passes)
2109 AC_SUBST(extra_programs)
2110 AC_SUBST(float_h_file)
2111 AC_SUBST(gcc_config_arguments)
2112 AC_SUBST(gcc_gxx_include_dir)
2113 AC_SUBST(libstdcxx_incdir)
2114 AC_SUBST(gcc_version)
2115 AC_SUBST(gcc_version_full)
2116 AC_SUBST(gcc_version_trigger)
2117 AC_SUBST(host_exeext)
2118 AC_SUBST(host_extra_gcc_objs)
2119 AC_SUBST(host_xm_file_list)
2120 AC_SUBST(host_xm_file)
2121 AC_SUBST(host_xm_defines)
2122 AC_SUBST(install)
2123 AC_SUBST(lang_options_files)
2124 AC_SUBST(lang_specs_files)
2125 AC_SUBST(lang_tree_files)
2126 AC_SUBST(local_prefix)
2127 AC_SUBST(md_file)
2128 AC_SUBST(objc_boehm_gc)
2129 AC_SUBST(out_file)
2130 AC_SUBST(out_object_file)
2131 AC_SUBST(stage_prefix_set_by_configure)
2132 AC_SUBST(symbolic_link)
2133 AC_SUBST(thread_file)
2134 AC_SUBST(tm_file_list)
2135 AC_SUBST(tm_file)
2136 AC_SUBST(tm_p_file_list)
2137 AC_SUBST(tm_p_file)
2138 AC_SUBST(xm_file)
2139 AC_SUBST(xm_defines)
2140 AC_SUBST(c_target_objs)
2141 AC_SUBST(cxx_target_objs)
2142 AC_SUBST(target_cpu_default)
2143
2144 AC_SUBST_FILE(target_overrides)
2145 AC_SUBST_FILE(host_overrides)
2146 AC_SUBST(cross_defines)
2147 AC_SUBST_FILE(cross_overrides)
2148 AC_SUBST_FILE(build_overrides)
2149 AC_SUBST_FILE(language_fragments)
2150 AC_SUBST_FILE(language_hooks)
2151
2152 # Echo that links are built
2153 if test x$host = x$target
2154 then
2155         str1="native "
2156 else
2157         str1="cross-"
2158         str2=" from $host"
2159 fi
2160
2161 if test x$host != x$build
2162 then
2163         str3=" on a $build system"
2164 fi
2165
2166 if test "x$str2" != x || test "x$str3" != x
2167 then
2168         str4=
2169 fi
2170
2171 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2172
2173 if test "x$str2" != x || test "x$str3" != x
2174 then
2175         echo " ${str2}${str3}." 1>&2
2176 fi
2177
2178 # Truncate the target if necessary
2179 if test x$host_truncate_target != x; then
2180         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2181 fi
2182
2183 # Configure the subdirectories
2184 # AC_CONFIG_SUBDIRS($subdirs)
2185
2186 # Create the Makefile
2187 # and configure language subdirectories
2188 AC_OUTPUT($all_outputs,
2189 [
2190 case x$CONFIG_HEADERS in
2191 xauto-host.h:config.in)
2192 echo > cstamp-h ;;
2193 esac
2194 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2195 # bootstrapping and the installation procedure can still use
2196 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2197 # FLAGS_TO_PASS has been modified to solve the problem there.
2198 # This is virtually a duplicate of what happens in configure.lang; we do
2199 # an extra check to make sure this only happens if ln -s can be used.
2200 if test "$symbolic_link" = "ln -s"; then
2201  for d in .. ${subdirs} ; do
2202    if test $d != ..; then
2203         STARTDIR=`pwd`
2204         cd $d
2205         for t in stage1 stage2 stage3 stage4 include
2206         do
2207                 rm -f $t
2208                 $symbolic_link ../$t $t 2>/dev/null
2209         done
2210         cd $STARTDIR
2211    fi
2212  done
2213 else true ; fi
2214 # Avoid having to add intl to our include paths.
2215 if test -f intl/libintl.h; then
2216   echo creating libintl.h
2217   echo '#include "intl/libintl.h"' >libintl.h
2218 fi
2219 ],
2220 [
2221 host='${host}'
2222 build='${build}'
2223 target='${target}'
2224 target_alias='${target_alias}'
2225 srcdir='${srcdir}'
2226 subdirs='${subdirs}'
2227 symbolic_link='${symbolic_link}'
2228 program_transform_set='${program_transform_set}'
2229 program_transform_name='${program_transform_name}'
2230 dep_host_xmake_file='${dep_host_xmake_file}'
2231 host_xmake_file='${host_xmake_file}'
2232 dep_tmake_file='${dep_tmake_file}'
2233 tmake_file='${tmake_file}'
2234 thread_file='${thread_file}'
2235 gcc_config_arguments='${gcc_config_arguments}'
2236 gcc_version='${gcc_version}'
2237 gcc_version_full='${gcc_version_full}'
2238 gcc_version_trigger='${gcc_version_trigger}'
2239 local_prefix='${local_prefix}'
2240 build_install_headers_dir='${build_install_headers_dir}'
2241 build_exeext='${build_exeext}'
2242 host_exeext='${host_exeext}'
2243 out_file='${out_file}'
2244 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2245 SET_MAKE='${SET_MAKE}'
2246 target_list='${target_list}'
2247 target_overrides='${target_overrides}'
2248 host_overrides='${host_overrides}'
2249 cross_defines='${cross_defines}'
2250 cross_overrides='${cross_overrides}'
2251 build_overrides='${build_overrides}'
2252 cpp_install_dir='${cpp_install_dir}'
2253 ])