gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname).],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as.],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname).],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format.],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format.],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include.],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files.],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib      enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor.],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin.],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       Enable multibyte characters for C and C++.],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC.
 277   --enable-threads=LIB    use LIB thread package for target GCC.],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime.],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2          force the default debug format to be DWARF2.],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared       don't provide a shared libgcc.],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Find the native compiler
 339 AC_PROG_CC
 340 AC_PROG_CC_C_O
 341 # autoconf is lame and doesn't give us any substitution variable for this.
 342 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 343   NO_MINUS_C_MINUS_O=yes
 344 else
 345   OUTPUT_OPTION='-o $@'
 346 fi
 347 AC_SUBST(NO_MINUS_C_MINUS_O)
 348 AC_SUBST(OUTPUT_OPTION)
 349
 350 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 351 ac_cv_prog_cc_no_long_long,
 352 [save_CFLAGS="$CFLAGS"
 353 CFLAGS="-Wno-long-long"
 354 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 355                ac_cv_prog_cc_no_long_long=no)
 356 CFLAGS="$save_CFLAGS"])
 357 strict1_warn=
 358 if test $ac_cv_prog_cc_no_long_long = yes; then
 359   strict1_warn="-pedantic -Wno-long-long"
 360 fi
 361 AC_SUBST(strict1_warn)
 362
 363 AC_PROG_CPP
 364 AC_C_INLINE
 365 gcc_AC_C_VOLATILE
 366
 367 gcc_AC_C_LONG_DOUBLE
 368 gcc_AC_C_LONG_LONG
 369
 370 # sizeof(char) is 1 by definition.
 371 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 372 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 373 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 374 if test $ac_cv_c_long_long = yes; then
 375   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 376 fi
 377 if test $ac_cv_c___int64 = yes; then
 378   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 379 fi
 380
 381 gcc_AC_C_CHARSET
 382
 383 # If the native compiler is GCC, we can enable warnings even in stage1.
 384 # That's useful for people building cross-compilers, or just running a
 385 # quick `make'.
 386 warn_cflags=
 387 if test "x$GCC" = "xyes"; then
 388   warn_cflags='$(GCC_WARN_CFLAGS)'
 389 fi
 390 AC_SUBST(warn_cflags)
 391
 392 # Stage specific cflags for build.
 393 stage1_cflags=
 394 case $build in
 395 vax-*-*)
 396   if test x$GCC = xyes
 397   then
 398     stage1_cflags="-Wa,-J"
 399   else
 400     stage1_cflags="-J"
 401   fi
 402   ;;
 403 esac
 404 AC_SUBST(stage1_cflags)
 405
 406 AC_PROG_MAKE_SET
 407
 408 AC_MSG_CHECKING([whether a default assembler was specified])
 409 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 410     if test x"$gas_flag" = x"no"; then
 411         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 412     else
 413         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 414     fi
 415 else
 416     AC_MSG_RESULT(no)
 417 fi
 418
 419 AC_MSG_CHECKING([whether a default linker was specified])
 420 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 421     if test x"$gnu_ld_flag" = x"no"; then
 422         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 423     else
 424         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 425     fi
 426 else
 427     AC_MSG_RESULT(no)
 428 fi
 429
 430 AC_MSG_CHECKING(for GNU C library)
 431 AC_CACHE_VAL(gcc_cv_glibc,
 432 [AC_TRY_COMPILE(
 433   [#include <features.h>],[
 434 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 435 #error Not a GNU C library system
 436 #endif],
 437   [gcc_cv_glibc=yes],
 438   gcc_cv_glibc=no)])
 439 AC_MSG_RESULT($gcc_cv_glibc)
 440 if test $gcc_cv_glibc = yes; then
 441   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 442 fi
 443
 444 # Find some useful tools
 445 AC_PROG_AWK
 446 gcc_AC_PROG_LN
 447 gcc_AC_PROG_LN_S
 448 AC_PROG_RANLIB
 449 gcc_AC_PROG_INSTALL
 450
 451 AC_HEADER_STDC
 452 AC_HEADER_TIME
 453 gcc_AC_HEADER_STRING
 454 AC_HEADER_SYS_WAIT
 455 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 456                  fcntl.h unistd.h sys/file.h sys/time.h \
 457                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 458                  direct.h malloc.h langinfo.h iconv.h stdbool.h)
 459
 460 # Check for thread headers.
 461 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 462 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 463
 464 # These tests can't be done till we know if we have limits.h.
 465 gcc_AC_C_CHAR_BIT
 466 gcc_AC_C_COMPILE_ENDIAN
 467 gcc_AC_C_FLOAT_FORMAT
 468
 469 # See if GNAT has been installed
 470 AC_CHECK_PROG(have_gnat, gnatbind, yes, no)
 471
 472 # See if we have the mktemp command.
 473 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 474
 475 # Do we have a single-tree copy of texinfo?
 476 if test -f $srcdir/../texinfo/Makefile.in; then
 477   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 478   gcc_cv_prog_makeinfo_modern=yes
 479   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 480 else
 481   # See if makeinfo has been installed and is modern enough
 482   # that we can use it.
 483   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 484   [GNU texinfo.* \([0-9][0-9.]*\)],
 485   [4.*])
 486 fi
 487
 488 if test $gcc_cv_prog_makeinfo_modern = no; then
 489   AC_MSG_WARN([
 490 *** Makeinfo is missing or too old.
 491 *** Info documentation will not be built.])
 492   BUILD_INFO=
 493 else
 494   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 495 fi
 496
 497 # Is pod2man recent enough to regenerate manpages?
 498 AC_MSG_CHECKING([for recent Pod::Man])
 499 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 500   AC_MSG_RESULT(yes)
 501   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 502 else
 503   AC_MSG_RESULT(no)
 504   GENERATED_MANPAGES=
 505 fi
 506
 507 # How about lex?
 508 dnl Don't use AC_PROG_LEX; we insist on flex.
 509 dnl LEXLIB is not useful in gcc.
 510 if test -f $srcdir/../flex/skel.c; then
 511   FLEX='$(objdir)/../flex/flex'
 512 else
 513   AC_CHECK_PROG(FLEX, flex, flex, false)
 514 fi
 515
 516 # Bison?
 517 # The -L switch is so bison can find its skeleton file.
 518 if test -f $srcdir/../bison/bison.simple; then
 519   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 520 else
 521   AC_CHECK_PROG(BISON, bison, bison, false)
 522 fi
 523
 524 # These libraries may be used by collect2.
 525 # We may need a special search path to get them linked.
 526 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 527 [save_LIBS="$LIBS"
 528 for libs in '' -lld -lmld \
 529                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 530                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 531 do
 532         LIBS="$libs"
 533         AC_TRY_LINK_FUNC(ldopen,
 534                 [gcc_cv_collect2_libs="$libs"; break])
 535 done
 536 LIBS="$save_LIBS"
 537 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 538 case $gcc_cv_collect2_libs in
 539         "none required")        ;;
 540         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 541 esac
 542 AC_SUBST(COLLECT2_LIBS)
 543
 544 # When building Ada code on Alpha, we need exc_resume which is usually in
 545 # -lexc.  So test for it.
 546 save_LIBS="$LIBS"
 547 LIBS=
 548 AC_SEARCH_LIBS(exc_resume, exc)
 549 GNAT_LIBEXC="$LIBS"
 550 LIBS="$save_LIBS"
 551 AC_SUBST(GNAT_LIBEXC)
 552
 553 # See if the stage1 system preprocessor understands the ANSI C
 554 # preprocessor stringification operator.  (Used by symcat.h.)
 555 AC_C_STRINGIZE
 556
 557 # Use <inttypes.h> only if it exists,
 558 # doesn't clash with <sys/types.h>, and declares intmax_t.
 559 AC_MSG_CHECKING(for inttypes.h)
 560 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 561 [AC_TRY_COMPILE(
 562   [#include <sys/types.h>
 563 #include <inttypes.h>],
 564   [intmax_t i = -1;],
 565   [gcc_cv_header_inttypes_h=yes],
 566   gcc_cv_header_inttypes_h=no)])
 567 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 568 if test $gcc_cv_header_inttypes_h = yes; then
 569   AC_DEFINE(HAVE_INTTYPES_H, 1,
 570         [Define if you have a working <inttypes.h> header file.])
 571 fi
 572
 573 dnl Disabled until we have a complete test for buggy enum bitfields.
 574 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 575
 576 AC_CHECK_FUNCS(strtoul bsearch popen times clock \
 577         strchr strrchr kill getrlimit setrlimit atoll atoq \
 578         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 579         fputs_unlocked getrusage iconv nl_langinfo lstat)
 580
 581 AC_CHECK_TYPE(ssize_t, int)
 582
 583 # Try to determine the array type of the second argument of getgroups
 584 # for the target system (int or gid_t).
 585 AC_TYPE_GETGROUPS
 586 if test "${target}" = "${build}"; then
 587   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 588 else
 589   case "${target}" in
 590         # This condition may need some tweaking.  It should include all
 591         # targets where the array type of the second argument of getgroups
 592         # is int and the type of gid_t is not equivalent to int.
 593         *-*-sunos* | *-*-ultrix*)
 594                 TARGET_GETGROUPS_T=int
 595                 ;;
 596         *)
 597                 TARGET_GETGROUPS_T=gid_t
 598                 ;;
 599   esac
 600 fi
 601 AC_SUBST(TARGET_GETGROUPS_T)
 602
 603 gcc_AC_FUNC_VFPRINTF_DOPRNT
 604 gcc_AC_FUNC_STRSTR
 605 gcc_AC_FUNC_PRINTF_PTR
 606
 607 case "${host}" in
 608 *-*-uwin*)
 609   AC_MSG_ERROR([
 610 *** UWIN may not be used as a host platform because
 611 *** linking with posix.dll is not allowed by the GNU GPL])
 612   ;;
 613 esac
 614 AC_FUNC_VFORK
 615 AC_FUNC_MMAP_ANYWHERE
 616 AC_FUNC_MMAP_FILE
 617
 618 # We will need to find libiberty.h and ansidecl.h
 619 saved_CFLAGS="$CFLAGS"
 620 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 621 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 622         strsignal putc_unlocked fputs_unlocked strstr environ errno \
 623         malloc realloc calloc free basename getopt clock, , ,[
 624 #include "ansidecl.h"
 625 #include "system.h"])
 626
 627 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 628 #include "ansidecl.h"
 629 #include "system.h"
 630 #ifdef HAVE_SYS_RESOURCE_H
 631 #include <sys/resource.h>
 632 #endif
 633 ])
 634
 635 gcc_AC_CHECK_DECLS(times, , ,[
 636 #include "ansidecl.h"
 637 #include "system.h"
 638 #ifdef HAVE_SYS_TIMES_H
 639 #include <sys/times.h>
 640 #endif
 641 ])
 642
 643 # More time-related stuff.
 644 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 645 AC_TRY_COMPILE([
 646 #include "ansidecl.h"
 647 #include "system.h"
 648 #ifdef HAVE_SYS_TIMES_H
 649 #include <sys/times.h>
 650 #endif
 651 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 652 if test $ac_cv_struct_tms = yes; then
 653   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 654   [Define if <sys/times.h> defines struct tms.])
 655 fi
 656
 657 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 658 # revisit after autoconf 2.50.
 659 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 660 AC_TRY_COMPILE([
 661 #include "ansidecl.h"
 662 #include "system.h"
 663 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 664 if test $gcc_cv_type_clock_t = yes; then
 665   AC_DEFINE(HAVE_CLOCK_T, 1,
 666   [Define if <time.h> defines clock_t.])
 667 fi
 668
 669 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 670 CFLAGS="$saved_CFLAGS"
 671
 672 # mkdir takes a single argument on some systems.
 673 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 674
 675 # File extensions
 676 manext='.1'
 677 objext='.o'
 678 AC_SUBST(manext)
 679 AC_SUBST(objext)
 680
 681 build_xm_file=
 682 build_xm_defines=
 683 build_install_headers_dir=install-headers-tar
 684 build_exeext=
 685 host_xm_file=
 686 host_xm_defines=
 687 host_xmake_file=
 688 host_truncate_target=
 689 host_exeext=
 690
 691 # Decode the host machine, then the target machine.
 692 # For the host machine, we save the xm_file variable as host_xm_file;
 693 # then we decode the target machine and forget everything else
 694 # that came from the host machine.
 695 for machine in $build $host $target; do
 696         . ${srcdir}/config.gcc
 697 done
 698
 699 extra_objs="${host_extra_objs} ${extra_objs}"
 700
 701 # Default the target-machine variables that were not explicitly set.
 702 if test x"$tm_file" = x
 703 then tm_file=$cpu_type/$cpu_type.h; fi
 704
 705 if test x"$extra_headers" = x
 706 then extra_headers=; fi
 707
 708 if test x$md_file = x
 709 then md_file=$cpu_type/$cpu_type.md; fi
 710
 711 if test x$out_file = x
 712 then out_file=$cpu_type/$cpu_type.c; fi
 713
 714 if test x"$tmake_file" = x
 715 then tmake_file=$cpu_type/t-$cpu_type
 716 fi
 717
 718 if test x"$dwarf2" = xyes
 719 then tm_file="$tm_file tm-dwarf2.h"
 720 fi
 721
 722 if test x$float_format = x
 723 then float_format=i64
 724 fi
 725
 726 if test $float_format = none
 727 then float_h_file=Makefile.in
 728 else float_h_file=float-$float_format.h
 729 fi
 730
 731 # Handle cpp installation.
 732 if test x$enable_cpp != xno
 733 then
 734   tmake_file="$tmake_file t-install-cpp"
 735 fi
 736
 737 # Say what files are being used for the output code and MD file.
 738 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 739 echo "Using \`$srcdir/config/$md_file' as machine description file."
 740
 741 # If any of the xm_file variables contain nonexistent files, warn
 742 # about them and drop them.
 743
 744 changequote(,)dnl
 745 bx=
 746 for x in $build_xm_file; do
 747   if    test -f $srcdir/config/$x
 748   then      bx="$bx $x"
 749   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 750   fi
 751 done
 752 build_xm_file="$bx"
 753
 754 hx=
 755 for x in $host_xm_file; do
 756   if    test -f $srcdir/config/$x
 757   then      hx="$hx $x"
 758   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 759   fi
 760 done
 761 host_xm_file="$hx"
 762
 763 tx=
 764 for x in $xm_file; do
 765   if    test -f $srcdir/config/$x
 766   then      tx="$tx $x"
 767   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 768   fi
 769 done
 770 xm_file="$tx"
 771 changequote([,])dnl
 772
 773 count=a
 774 for f in $tm_file; do
 775         count=${count}x
 776 done
 777 if test $count = ax; then
 778         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 779 else
 780         echo "Using the following target machine macro files:"
 781         for f in $tm_file; do
 782                 echo "  $srcdir/config/$f"
 783         done
 784 fi
 785
 786 count=a
 787 for f in $host_xm_file; do
 788         count=${count}x
 789 done
 790 if test $count = a; then
 791         :
 792 elif test $count = ax; then
 793         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 794 else
 795         echo "Using the following host machine macro files:"
 796         for f in $host_xm_file; do
 797                 echo "  $srcdir/config/$f"
 798         done
 799 fi
 800
 801 if test "$host_xm_file" != "$build_xm_file"; then
 802         count=a
 803         for f in $build_xm_file; do
 804                 count=${count}x
 805         done
 806         if test $count = a; then
 807                 :
 808         elif test $count = ax; then
 809                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 810         else
 811                 echo "Using the following build machine macro files:"
 812                 for f in $build_xm_file; do
 813                         echo "  $srcdir/config/$f"
 814                 done
 815         fi
 816 fi
 817
 818 if test x$thread_file = x; then
 819         if test x$target_thread_file != x; then
 820                 thread_file=$target_thread_file
 821         else
 822                 thread_file='single'
 823         fi
 824 fi
 825
 826 # auto-host.h is the file containing items generated by autoconf and is
 827 # the first file included by config.h.
 828 # If host=build, it is correct to have hconfig include auto-host.h
 829 # as well.  If host!=build, we are in error and need to do more
 830 # work to find out the build config parameters.
 831 if test x$host = x$build
 832 then
 833         build_auto=auto-host.h
 834 else
 835         # We create a subdir, then run autoconf in the subdir.
 836         # To prevent recursion we set host and build for the new
 837         # invocation of configure to the build for this invocation
 838         # of configure.
 839         tempdir=build.$$
 840         rm -rf $tempdir
 841         mkdir $tempdir
 842         cd $tempdir
 843         case ${srcdir} in
 844         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 845         *) realsrcdir=../${srcdir};;
 846         esac
 847         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 848                 --target=$target --host=$build --build=$build
 849
 850         # We just finished tests for the build machine, so rename
 851         # the file auto-build.h in the gcc directory.
 852         mv auto-host.h ../auto-build.h
 853         cd ..
 854         rm -rf $tempdir
 855         build_auto=auto-build.h
 856 fi
 857
 858 tm_file="${tm_file} defaults.h"
 859 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 860 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 861 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 862
 863 # Truncate the target if necessary
 864 if test x$host_truncate_target != x; then
 865         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 866 fi
 867
 868 # Get the version trigger filename from the toplevel
 869 if test "${with_gcc_version_trigger+set}" = set; then
 870         gcc_version_trigger=$with_gcc_version_trigger
 871 else
 872         gcc_version_trigger=${srcdir}/version.c
 873 fi
 874 changequote(,)dnl
 875 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 876 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 877
 878 # Compile in configure arguments.
 879 if test -f configargs.h ; then
 880         # Being re-configured.
 881         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 882         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 883 else
 884         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 885 fi
 886 cat > configargs.h <<EOF
 887 /* Generated automatically. */
 888 static const char configuration_arguments[] = "$gcc_config_arguments";
 889 static const char thread_model[] = "$thread_file";
 890 EOF
 891 changequote([,])dnl
 892
 893 # Internationalization
 894 PACKAGE=gcc
 895 VERSION="$gcc_version"
 896 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 897         [Define to the name of the distribution.])
 898 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 899         [Define to the version of the distribution.])
 900 AC_SUBST(PACKAGE)
 901 AC_SUBST(VERSION)
 902
 903 ALL_LINGUAS="sv"
 904
 905 # Enable NLS support by default
 906 AC_ARG_ENABLE(nls,
 907   [  --enable-nls            use Native Language Support (default)],
 908   , enable_nls=yes)
 909
 910 # if cross compiling, disable NLS support.
 911 # It's not worth the trouble, at least for now.
 912
 913 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 914   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 915   enable_nls=no
 916 fi
 917
 918 # if NLS is enabled, also enable check in po subdir
 919 if test $enable_nls = yes; then
 920   CHECK_PO=check-po
 921 else
 922   CHECK_PO=""
 923 fi
 924
 925 AC_SUBST(CHECK_PO)
 926
 927 AM_GNU_GETTEXT
 928 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 929
 930 # Windows32 Registry support for specifying GCC installation paths.
 931 AC_ARG_ENABLE(win32-registry,
 932 [  --disable-win32-registry
 933                           Disable lookup of installation paths in the
 934                          Registry on Windows hosts.
 935   --enable-win32-registry Enable registry lookup (default).
 936   --enable-win32-registry=KEY
 937                           Use KEY instead of GCC version as the last portion
 938                          of the registry key.],,)
 939 case $host_os in
 940         win32 | pe | cygwin* | mingw32* | uwin*)
 941 AC_MSG_CHECKING(whether windows registry support is requested)
 942 if test x$enable_win32_registry != xno; then
 943   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 944 [Define to 1 if installation paths should be looked up in Windows32
 945    Registry. Ignored on non windows32 hosts.])
 946   AC_MSG_RESULT(yes)
 947   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 948 else
 949   AC_MSG_RESULT(no)
 950 fi
 951
 952 # Check if user specified a different registry key.
 953 case x${enable_win32_registry} in
 954 x | xyes)
 955   # default.
 956   gcc_cv_win32_registry_key="$VERSION"
 957   ;;
 958 xno)
 959   # no registry lookup.
 960   gcc_cv_win32_registry_key=''
 961   ;;
 962 *)
 963   # user-specified key.
 964   gcc_cv_win32_registry_key="$enable_win32_registry"
 965   ;;
 966 esac
 967
 968 if test x$enable_win32_registry != xno; then
 969   AC_MSG_CHECKING(registry key on windows hosts)
 970   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 971         [Define to be the last portion of registry key on windows hosts.])
 972   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 973 fi
 974 ;;
 975 esac
 976
 977 # Get an absolute path to the GCC top-level source directory
 978 holddir=`pwd`
 979 cd $srcdir
 980 topdir=`pwd`
 981 cd $holddir
 982
 983 # Conditionalize the makefile for this host machine.
 984 # Make-host contains the concatenation of all host makefile fragments
 985 # [there can be more than one].  This file is built by configure.frag.
 986 host_overrides=Make-host
 987 dep_host_xmake_file=
 988 for f in .. ${host_xmake_file}
 989 do
 990         if test -f ${srcdir}/config/$f
 991         then
 992                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 993         fi
 994 done
 995
 996 # Conditionalize the makefile for this target machine.
 997 # Make-target contains the concatenation of all host makefile fragments
 998 # [there can be more than one].  This file is built by configure.frag.
 999 target_overrides=Make-target
1000 dep_tmake_file=
1001 for f in .. ${tmake_file}
1002 do
1003         if test -f ${srcdir}/config/$f
1004         then
1005                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1006         fi
1007 done
1008
1009 # If the host doesn't support symlinks, modify CC in
1010 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1011 # Otherwise, we can use "CC=$(CC)".
1012 rm -f symtest.tem
1013 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1014 then
1015         cc_set_by_configure="\$(CC)"
1016         quoted_cc_set_by_configure="\$(CC)"
1017         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1018 else
1019         rm -f symtest.tem
1020         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1021         then
1022                 symbolic_link="cp -p"
1023         else
1024                 symbolic_link="cp"
1025         fi
1026         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1027         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1028         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1029 fi
1030 rm -f symtest.tem
1031
1032 out_object_file=`basename $out_file .c`.o
1033
1034 tm_file_list=
1035 for f in $tm_file; do
1036   case $f in
1037     ansidecl.h )
1038        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1039     defaults.h )
1040        tm_file_list="${tm_file_list} $f" ;;
1041     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1042   esac
1043 done
1044
1045 tm_p_file_list=
1046 for f in $tm_p_file; do
1047     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1048 done
1049
1050 host_xm_file_list=
1051 for f in $host_xm_file; do
1052   case $f in
1053     ansidecl.h )
1054        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1055     auto-host.h | defaults.h )
1056        host_xm_file_list="${host_xm_file_list} $f" ;;
1057     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1058   esac
1059 done
1060
1061 build_xm_file_list=
1062 for f in $build_xm_file; do
1063   case $f in
1064     ansidecl.h )
1065        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1066     auto-build.h | auto-host.h | defaults.h )
1067        build_xm_file_list="${build_xm_file_list} $f" ;;
1068     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1069   esac
1070 done
1071
1072 # Define macro CROSS_COMPILE in compilation
1073 # if this is a cross-compiler.
1074 # Also use all.cross instead of all.internal
1075 # and add cross-make to Makefile.
1076 cross_overrides="/dev/null"
1077 if test x$host != x$target
1078 then
1079         cross_defines="CROSS=-DCROSS_COMPILE"
1080         cross_overrides="${topdir}/cross-make"
1081 fi
1082
1083 # If this is a cross-compiler that does not
1084 # have its own set of headers then define
1085 # inhibit_libc
1086
1087 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1088 # This prevents libgcc2 from containing any code which requires libc
1089 # support.
1090 inhibit_libc=
1091 if [test x$host != x$target] && [test x$with_headers = x]; then
1092        inhibit_libc=-Dinhibit_libc
1093 else
1094        if [test x$with_newlib = xyes]; then
1095                inhibit_libc=-Dinhibit_libc
1096        fi
1097 fi
1098 AC_SUBST(inhibit_libc)
1099
1100 # When building gcc with a cross-compiler, we need to fix a few things.
1101 # This must come after cross-make as we want all.build to override
1102 # all.cross.
1103 build_overrides="/dev/null"
1104 if test x$build != x$host
1105 then
1106         build_overrides="${topdir}/build-make"
1107 fi
1108
1109 # Expand extra_headers to include complete path.
1110 # This substitutes for lots of t-* files.
1111 extra_headers_list=
1112 if test "x$extra_headers" = x
1113 then true
1114 else
1115         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1116         for file in $extra_headers;
1117         do
1118                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1119         done
1120 fi
1121
1122 if test x$use_collect2 = xno; then
1123         use_collect2=
1124 fi
1125
1126 # Add a definition of USE_COLLECT2 if system wants one.
1127 # Also tell toplev.c what to do.
1128 # This substitutes for lots of t-* files.
1129 if test x$use_collect2 = x
1130 then
1131         will_use_collect2=
1132         maybe_use_collect2=
1133 else
1134         will_use_collect2="collect2"
1135         maybe_use_collect2="-DUSE_COLLECT2"
1136 fi
1137
1138 # If we have gas in the build tree, make a link to it.
1139 if test -f ../gas/Makefile; then
1140         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1141 fi
1142
1143 # If we have nm in the build tree, make a link to it.
1144 if test -f ../binutils/Makefile; then
1145         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1146 fi
1147
1148 # If we have ld in the build tree, make a link to it.
1149 if test -f ../ld/Makefile; then
1150 #       if test x$use_collect2 = x; then
1151 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1152 #       else
1153                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1154 #       fi
1155 fi
1156
1157 # Figure out what assembler we will be using.
1158 AC_MSG_CHECKING(what assembler to use)
1159 gcc_cv_as=
1160 gcc_cv_gas_major_version=
1161 gcc_cv_gas_minor_version=
1162 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1163 if test -x "$DEFAULT_ASSEMBLER"; then
1164         gcc_cv_as="$DEFAULT_ASSEMBLER"
1165 elif test -x "$AS"; then
1166         gcc_cv_as="$AS"
1167 elif test -x as$host_exeext; then
1168         # Build using assembler in the current directory.
1169         gcc_cv_as=./as$host_exeext
1170 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1171         # Single tree build which includes gas.
1172         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1173         do
1174 changequote(,)dnl
1175                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1176 changequote([,])dnl
1177                 if test x$gcc_cv_gas_version != x; then
1178                         break
1179                 fi
1180         done
1181 changequote(,)dnl
1182         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1183         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1184 changequote([,])dnl
1185 fi
1186
1187 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1188         # Native build.
1189         # Search the same directories that the installed compiler will
1190         # search.  Else we may find the wrong assembler and lose.  If we
1191         # do not find a suitable assembler binary, then try the user's
1192         # path.
1193         #
1194         # Also note we have to check MD_EXEC_PREFIX before checking the
1195         # user's path.  Unfortunately, there is no good way to get at the
1196         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1197         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1198         # to be fixed as part of the make/configure rewrite too.
1199
1200         if test "x$exec_prefix" = xNONE; then
1201                 if test "x$prefix" = xNONE; then
1202                         test_prefix=/usr/local
1203                 else
1204                         test_prefix=$prefix
1205                 fi
1206         else
1207                 test_prefix=$exec_prefix
1208         fi
1209
1210         # If the loop below does not find an assembler, then use whatever
1211         # one we can find in the users's path.
1212         # user's path.
1213         gcc_cv_as=as$host_exeext
1214
1215         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1216                    $test_prefix/lib/gcc-lib/$target \
1217                    /usr/lib/gcc/$target/$gcc_version \
1218                    /usr/lib/gcc/$target \
1219                    $test_prefix/$target/bin/$target/$gcc_version \
1220                    $test_prefix/$target/bin \
1221                    /usr/libexec \
1222                    /usr/ccs/gcc \
1223                    /usr/ccs/bin \
1224                    /udk/usr/ccs/bin \
1225                    /bsd43/usr/lib/cmplrs/cc \
1226                    /usr/cross64/usr/bin \
1227                    /usr/lib/cmplrs/cc \
1228                    /sysv/usr/lib/cmplrs/cc \
1229                    /svr4/usr/lib/cmplrs/cc \
1230                    /usr/bin"
1231
1232         for dir in $test_dirs; do
1233                 if test -f $dir/as$host_exeext; then
1234                         gcc_cv_as=$dir/as$host_exeext
1235                         break;
1236                 fi
1237         done
1238 fi
1239 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1240   AC_MSG_RESULT("newly built gas")
1241 else
1242   AC_MSG_RESULT($gcc_cv_as)
1243 fi
1244
1245 # Figure out what nm we will be using.
1246 AC_MSG_CHECKING(what nm to use)
1247 if test -x nm$host_exeext; then
1248         gcc_cv_nm=./nm$host_exeext
1249 elif test x$host = x$target; then
1250         # Native build.
1251         gcc_cv_nm=nm$host_exeext
1252 fi
1253 AC_MSG_RESULT($gcc_cv_nm)
1254
1255 # Figure out what assembler alignment features are present.
1256 AC_MSG_CHECKING(assembler alignment features)
1257 gcc_cv_as_alignment_features=none
1258 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1259         # Gas version 2.6 and later support for .balign and .p2align.
1260         # bytes to skip when using .p2align.
1261         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1262                 gcc_cv_as_alignment_features=".balign and .p2align"
1263                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1264         fi
1265         # Gas version 2.8 and later support specifying the maximum
1266         # bytes to skip when using .p2align.
1267         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1268                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1269                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1270         fi
1271 elif test x$gcc_cv_as != x; then
1272         # Check if we have .balign and .p2align
1273         echo ".balign  4" > conftest.s
1274         echo ".p2align  2" >> conftest.s
1275         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1276                 gcc_cv_as_alignment_features=".balign and .p2align"
1277                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1278         fi
1279         rm -f conftest.s conftest.o
1280         # Check if specifying the maximum bytes to skip when
1281         # using .p2align is supported.
1282         echo ".p2align 4,,7" > conftest.s
1283         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1284                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1285                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1286         fi
1287         rm -f conftest.s conftest.o
1288 fi
1289 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1290
1291 AC_MSG_CHECKING(assembler subsection support)
1292 gcc_cv_as_subsections=no
1293 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1294   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1295     gcc_cv_as_subsections="working .subsection -1"
1296   fi
1297 elif test x$gcc_cv_as != x; then
1298         # Check if we have .subsection
1299         echo ".subsection 1" > conftest.s
1300         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1301                 gcc_cv_as_subsections=".subsection"
1302                 if test x$gcc_cv_nm != x; then
1303                         cat > conftest.s <<EOF
1304 conftest_label1: .word 0
1305 .subsection -1
1306 conftest_label2: .word 0
1307 .previous
1308 EOF
1309                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1310                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1311                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1312                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1313                                         :
1314                                 else
1315                                         gcc_cv_as_subsections="working .subsection -1"
1316                                 fi
1317                         fi
1318                 fi
1319         fi
1320         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1321 fi
1322 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1323         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1324 [Define if your assembler supports .subsection and .subsection -1 starts
1325    emitting at the beginning of your section.])
1326 fi
1327 AC_MSG_RESULT($gcc_cv_as_subsections)
1328
1329 AC_MSG_CHECKING(assembler weak support)
1330 gcc_cv_as_weak=no
1331 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1332   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1333     gcc_cv_as_weak="yes"
1334   fi
1335 elif test x$gcc_cv_as != x; then
1336         # Check if we have .weak
1337         echo "  .weak foobar" > conftest.s
1338         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1339                 gcc_cv_as_weak="yes"
1340         fi
1341         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1342 fi
1343 if test x"$gcc_cv_as_weak" = xyes; then
1344         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1345 fi
1346 AC_MSG_RESULT($gcc_cv_as_weak)
1347
1348 AC_MSG_CHECKING(assembler hidden support)
1349 gcc_cv_as_hidden=no
1350 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1351   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1352     gcc_cv_as_hidden="yes"
1353   fi
1354 elif test x$gcc_cv_as != x; then
1355         # Check if we have .hidden
1356         echo "  .hidden foobar" > conftest.s
1357         echo "foobar:" >> conftest.s
1358         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1359                 gcc_cv_as_hidden="yes"
1360         fi
1361         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1362 fi
1363 if test x"$gcc_cv_as_hidden" = xyes; then
1364         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1365                 [Define if your assembler supports .hidden.])
1366 fi
1367 AC_MSG_RESULT($gcc_cv_as_hidden)
1368
1369 AC_MSG_CHECKING(assembler leb128 support)
1370 gcc_cv_as_leb128=no
1371 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1372   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1373     gcc_cv_as_leb128="yes"
1374   fi
1375 elif test x$gcc_cv_as != x; then
1376         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1377         cat > conftest.s <<EOF
1378         .data
1379         .uleb128 L2 - L1
1380 L1:
1381         .uleb128 1280
1382         .sleb128 -1010
1383 L2:
1384 EOF
1385         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1386                 gcc_cv_as_leb128="yes"
1387
1388                 # GAS versions before 2.11 do not support uleb128,
1389                 # despite appearing to.
1390                 # ??? There exists an elf-specific test that will crash
1391                 # the assembler.  Perhaps it's better to figure out whether
1392                 # arbitrary sections are supported and try the test.
1393                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1394                 if echo "$as_ver" | grep GNU > /dev/null; then
1395                         as_ver=`echo $as_ver | sed -e 's/.* //'`
1396                         as_major=`echo $as_ver | sed 's/\..*//'`
1397 changequote(,)dnl
1398                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1399 changequote([,])dnl
1400                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1401                                 gcc_cv_as_leb128="no"
1402                         fi
1403                 fi
1404         fi
1405         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1406 fi
1407 if test x"$gcc_cv_as_leb128" = xyes; then
1408         AC_DEFINE(HAVE_AS_LEB128, 1,
1409                 [Define if your assembler supports .uleb128.])
1410 fi
1411 AC_MSG_RESULT($gcc_cv_as_leb128)
1412
1413 AC_MSG_CHECKING(assembler eh_frame optimization)
1414 gcc_cv_as_eh_frame=no
1415 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1416   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1417     gcc_cv_as_eh_frame="yes"
1418   fi
1419 elif test x$gcc_cv_as != x; then
1420         # Check if this is GAS.
1421         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1422         rm -f a.out 2> /dev/null
1423         if echo "$as_ver" | grep GNU > /dev/null; then
1424                 # Versions up to and including 2.11.0 may mis-optimize
1425                 # .eh_frame data.  Try something.
1426                 cat > conftest.s <<EOF
1427         .text
1428 .LFB1:
1429         .4byte  0
1430 .L1:
1431         .4byte  0
1432 .LFE1:
1433         .section        .eh_frame,"aw",@progbits
1434 __FRAME_BEGIN__:
1435         .4byte  .LECIE1-.LSCIE1
1436 .LSCIE1:
1437         .4byte  0x0
1438         .byte   0x1
1439         .ascii "z\0"
1440         .byte   0x1
1441         .byte   0x78
1442         .byte   0x1a
1443         .byte   0x0
1444         .byte   0x4
1445         .4byte  1
1446         .p2align 1
1447 .LECIE1:
1448 .LSFDE1:
1449         .4byte  .LEFDE1-.LASFDE1
1450 .LASFDE1:
1451         .4byte  .LASFDE1-__FRAME_BEGIN__
1452         .4byte  .LFB1
1453         .4byte  .LFE1-.LFB1
1454         .byte   0x4
1455         .4byte  .LFE1-.LFB1
1456         .byte   0x4
1457         .4byte  .L1-.LFB1
1458 .LEFDE1:
1459 EOF
1460                 cat > conftest.exp <<EOF
1461  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1462  0010 01000000 12000000 18000000 00000000  ................
1463  0020 08000000 04080000 0044               .........D
1464 EOF
1465                 # If the assembler didn't choke, and we can objdump,
1466                 # and we got the correct data, then succeed.
1467                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1468                    && objdump -s -j .eh_frame conftest.o 2>/dev/null \
1469                       | tail -3 > conftest.got \
1470                    && cmp conftest.exp conftest.got > /dev/null 2>&1
1471                 then
1472                         gcc_cv_as_eh_frame="yes"
1473                 else
1474                         gcc_cv_as_eh_frame="bad"
1475                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1476                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1477         [Define if your assembler mis-optimizes .eh_frame data.])
1478                         fi
1479                 fi
1480         fi
1481         rm -f conftest.*
1482 fi
1483 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1484
1485 case "$target" in
1486   sparc*-*-*)
1487     AC_CACHE_CHECK([assembler .register pseudo-op support],
1488         gcc_cv_as_register_pseudo_op, [
1489         gcc_cv_as_register_pseudo_op=unknown
1490         if test x$gcc_cv_as != x; then
1491             # Check if we have .register
1492             echo ".register %g2, #scratch" > conftest.s
1493             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1494                 gcc_cv_as_register_pseudo_op=yes
1495             else
1496                 gcc_cv_as_register_pseudo_op=no
1497             fi
1498             rm -f conftest.s conftest.o
1499         fi
1500     ])
1501     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1502         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1503                 [Define if your assembler supports .register.])
1504     fi
1505
1506     AC_CACHE_CHECK([assembler supports -relax],
1507         gcc_cv_as_relax_opt, [
1508         gcc_cv_as_relax_opt=unknown
1509         if test x$gcc_cv_as != x; then
1510             # Check if gas supports -relax
1511             echo ".text" > conftest.s
1512             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1513                 gcc_cv_as_relax_opt=yes
1514             else
1515                 gcc_cv_as_relax_opt=no
1516             fi
1517             rm -f conftest.s conftest.o
1518         fi
1519     ])
1520     if test "x$gcc_cv_as_relax_opt" = xyes; then
1521         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1522                 [Define if your assembler supports -relax option.])
1523     fi
1524
1525     case "$tm_file" in
1526     *64*)
1527         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1528             gcc_cv_as_flags64, [
1529                 if test -n "$gcc_cv_as"; then
1530                     echo ".xword foo" > conftest.s
1531                     gcc_cv_as_flags64=no
1532                     for flag in "-xarch=v9" "-64 -Av9"; do
1533                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1534                             > /dev/null 2>&1; then
1535                             gcc_cv_as_flags64=$flag
1536                             break
1537                         fi
1538                     done
1539                     rm -f conftest.s conftest.o
1540                 else
1541                     if test "$gas" = yes; then
1542                         gcc_cv_as_flags64="-64 -Av9"
1543                     else
1544                         gcc_cv_as_flags64="-xarch=v9"
1545                     fi
1546                 fi
1547         ])
1548         if test "x$gcc_cv_as_flags64" = xno; then
1549 changequote(, )
1550             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1551             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1552 changequote([, ])
1553         else
1554             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1555                         [Define if the assembler supports 64bit sparc.])
1556         fi
1557         ;;
1558     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1559         ;;
1560     esac
1561
1562     if test "x$gcc_cv_as_flags64" != xno; then
1563         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1564             gcc_cv_as_offsetable_lo10, [
1565             gcc_cv_as_offsetable_lo10=unknown
1566             if test "x$gcc_cv_as" != x; then
1567                 # Check if assembler has offsetable %lo()
1568                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1569                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1570                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1571                         > /dev/null 2>&1 &&
1572                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1573                         > /dev/null 2>&1; then
1574                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1575                         gcc_cv_as_offsetable_lo10=no
1576                     else
1577                         gcc_cv_as_offsetable_lo10=yes
1578                     fi
1579                 else
1580                     gcc_cv_as_offsetable_lo10=no
1581                 fi
1582                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1583             fi
1584         ])
1585         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1586             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1587                 [Define if your assembler supports offsetable %lo().])
1588         fi
1589     fi
1590     ;;
1591
1592 changequote(,)dnl
1593   i[34567]86-*-*)
1594 changequote([,])dnl
1595     AC_MSG_CHECKING(assembler instructions)
1596     gcc_cv_as_instructions=
1597     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1598       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1599         gcc_cv_as_instructions="filds fists"
1600       fi
1601     elif test x$gcc_cv_as != x; then
1602         set "filds fists" "filds mem; fists mem"
1603         while test $# -gt 0
1604         do
1605                 echo "$2" > conftest.s
1606                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1607                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1608                 fi
1609                 shift 2
1610         done
1611         rm -f conftest.s conftest.o
1612     fi
1613     if test x"$gcc_cv_as_instructions" != x; then
1614         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1615     fi
1616     AC_MSG_RESULT($gcc_cv_as_instructions)
1617     ;;
1618 esac
1619
1620 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1621 gcc_cv_as_dwarf2_debug_line=no
1622 # ??? Not all targets support dwarf2 debug_line, even within a version
1623 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1624 # info to the output file.  So, as supported targets are added to gas 2.11,
1625 # add some instruction here to (also) show we expect this might work.
1626 # ??? Once 2.11 is released, probably need to add first known working
1627 # version to the per-target configury.
1628 case "$target" in
1629   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-*)
1630     insn="nop"
1631     ;;
1632   ia64*-*-*)
1633     insn="nop 0"
1634     ;;
1635   esac
1636 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1637 then
1638   if test "$gcc_cv_gas_major_version" -eq 2 \
1639         -a "$gcc_cv_gas_minor_version" -ge 11 \
1640         -o "$gcc_cv_gas_major_version" -gt 2 \
1641      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1642      && test x"$insn" != x ; then
1643     gcc_cv_as_dwarf2_debug_line="yes"
1644   fi
1645 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1646         echo '  .file 1 "conftest.s"' > conftest.s
1647         echo '  .loc 1 3 0' >> conftest.s
1648         echo "  $insn" >> conftest.s
1649         # ??? This fails with non-gnu grep.
1650         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1651            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1652                 # The .debug_line file table must be in the exact order that
1653                 # we specified the files, since these indicies are also used
1654                 # by DW_AT_decl_file.  Approximate this test by testing if
1655                 # the assembler bitches if the same index is assigned twice.
1656                 echo '  .file 1 "foo.s"' > conftest.s
1657                 echo '  .file 1 "bar.s"' >> conftest.s
1658                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1659                 then
1660                   gcc_cv_as_dwarf2_debug_line="no"
1661                 else
1662                   gcc_cv_as_dwarf2_debug_line="yes"
1663                 fi
1664         fi
1665         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1666 fi
1667 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1668         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1669 [Define if your assembler supports dwarf2 .file/.loc directives,
1670    and preserves file table indicies exactly as given.])
1671 fi
1672 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1673
1674 # Figure out what language subdirectories are present.
1675 # Look if the user specified --enable-languages="..."; if not, use
1676 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1677 # go away some day.
1678 if test x"${enable_languages+set}" != xset; then
1679         if test x"${LANGUAGES+set}" = xset; then
1680                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1681         else
1682                 enable_languages=all
1683         fi
1684 else
1685         if test x"${enable_languages}" = x; then
1686                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1687         fi
1688 fi
1689
1690 # First scan to see if an enabled language requires some other language.
1691 # We assume that a given config-lang.in will list all the language
1692 # front ends it requires, even if some are required indirectly.
1693 for lang in ${srcdir}/*/config-lang.in ..
1694 do
1695    case $lang in
1696     ..)
1697        ;;
1698     # The odd quoting in the next line works around
1699     # an apparent bug in bash 1.12 on linux.
1700 changequote(,)dnl
1701     ${srcdir}/[*]/config-lang.in)
1702        ;;
1703     *)
1704        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1705        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1706        for other in $this_lang_requires
1707        do
1708           case ,${enable_languages}, in
1709            *,$other,*)
1710               ;;
1711            *,all,*)
1712               ;;
1713            *,$lang_alias,*)
1714               enable_languages="$enable_languages,$other"
1715               ;;
1716           esac
1717        done
1718        ;;
1719 changequote([,])dnl
1720    esac
1721 done
1722
1723 subdirs=
1724 for lang in ${srcdir}/*/config-lang.in ..
1725 do
1726         case $lang in
1727         ..) ;;
1728         # The odd quoting in the next line works around
1729         # an apparent bug in bash 1.12 on linux.
1730 changequote(,)dnl
1731         ${srcdir}/[*]/config-lang.in) ;;
1732         *)
1733           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1734           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1735           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1736           if test "x$lang_alias" = x
1737           then
1738                 echo "$lang doesn't set \$language." 1>&2
1739                 exit 1
1740           fi
1741           case ${build_by_default},${enable_languages}, in
1742           *,$lang_alias,*) add_this_lang=yes ;;
1743           no,*) add_this_lang=no ;;
1744           *,all,*) add_this_lang=yes ;;
1745           *) add_this_lang=no ;;
1746           esac
1747           if test x"${add_this_lang}" = xyes; then
1748                 case $lang in
1749                     ${srcdir}/ada/config-lang.in)
1750                         if test x$have_gnat = xyes ; then
1751                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1752                         fi
1753                         ;;
1754                     *)
1755                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1756                         ;;
1757                 esac
1758           fi
1759           ;;
1760 changequote([,])dnl
1761         esac
1762 done
1763
1764 # Make gthr-default.h if we have a thread file.
1765 gthread_flags=
1766 if test $thread_file != single; then
1767     rm -f gthr-default.h
1768     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1769     gthread_flags=-DHAVE_GTHR_DEFAULT
1770 fi
1771 AC_SUBST(gthread_flags)
1772
1773 # Find out what GC implementation we want, or may, use.
1774 AC_ARG_WITH(gc,
1775 [  --with-gc={simple,page} Choose the garbage collection mechanism to use
1776                            with the compiler.],
1777 [case "$withval" in
1778   simple | page)
1779     GGC=ggc-$withval
1780     ;;
1781   *)
1782     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1783     ;;
1784 esac],
1785 [GGC=ggc-page])
1786 AC_SUBST(GGC)
1787 echo "Using $GGC for garbage collection."
1788
1789 # Use the system's zlib library.
1790 zlibdir=-L../zlib
1791 zlibinc="-I\$(srcdir)/../zlib"
1792 AC_ARG_WITH(system-zlib,
1793 [  --with-system-zlib      use installed libz],
1794 zlibdir=
1795 zlibinc=
1796 )
1797 AC_SUBST(zlibdir)
1798 AC_SUBST(zlibinc)
1799
1800 dnl Very limited version of automake's enable-maintainer-mode
1801
1802 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1803   dnl maintainer-mode is disabled by default
1804   AC_ARG_ENABLE(maintainer-mode,
1805 [  --enable-maintainer-mode enable make rules and dependencies not useful
1806                           (and sometimes confusing) to the casual installer],
1807       maintainer_mode=$enableval,
1808       maintainer_mode=no)
1809
1810 AC_MSG_RESULT($maintainer_mode)
1811
1812 if test "$maintainer_mode" = "yes"; then
1813   MAINT=''
1814 else
1815   MAINT='#'
1816 fi
1817 AC_SUBST(MAINT)dnl
1818
1819 # With Setjmp/Longjmp based exception handling.
1820 AC_ARG_ENABLE(sjlj-exceptions,
1821 [  --enable-sjlj-exceptions arrange to use setjmp/longjmp exception handling.],
1822 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1823 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1824   [Define 0/1 to force the choice for exception handling model.])])
1825
1826 # Make empty files to contain the specs and options for each language.
1827 # Then add #include lines to for a compiler that has specs and/or options.
1828
1829 lang_specs_files=
1830 lang_options_files=
1831 lang_tree_files=
1832 rm -f specs.h options.h gencheck.h
1833 touch specs.h options.h gencheck.h
1834 for subdir in . $subdirs
1835 do
1836         if test -f $srcdir/$subdir/lang-specs.h; then
1837                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1838                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1839         fi
1840         if test -f $srcdir/$subdir/lang-options.h; then
1841                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1842                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1843         fi
1844         if test -f $srcdir/$subdir/$subdir-tree.def; then
1845                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1846                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1847         fi
1848 done
1849
1850 # These (without "all_") are set in each config-lang.in.
1851 # `language' must be a single word so is spelled singularly.
1852 all_languages=
1853 all_boot_languages=
1854 all_compilers=
1855 all_stagestuff=
1856 all_diff_excludes=
1857 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1858 # List of language makefile fragments.
1859 all_lang_makefiles=
1860 all_headers=
1861 all_lib2funcs=
1862
1863 # Add the language fragments.
1864 # Languages are added via two mechanisms.  Some information must be
1865 # recorded in makefile variables, these are defined in config-lang.in.
1866 # We accumulate them and plug them into the main Makefile.
1867 # The other mechanism is a set of hooks for each of the main targets
1868 # like `clean', `install', etc.
1869
1870 language_fragments="Make-lang"
1871 language_hooks="Make-hooks"
1872
1873 for s in .. $subdirs
1874 do
1875         if test $s != ".."
1876         then
1877                 language=
1878                 boot_language=
1879                 compilers=
1880                 stagestuff=
1881                 diff_excludes=
1882                 headers=
1883                 outputs=
1884                 lib2funcs=
1885                 . ${srcdir}/$s/config-lang.in
1886                 if test "x$language" = x
1887                 then
1888                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1889                         exit 1
1890                 fi
1891                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1892                 if test -f ${srcdir}/$s/Makefile.in
1893                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1894                 fi
1895                 all_languages="$all_languages $language"
1896                 if test "x$boot_language" = xyes
1897                 then
1898                         all_boot_languages="$all_boot_languages $language"
1899                 fi
1900                 all_compilers="$all_compilers $compilers"
1901                 all_stagestuff="$all_stagestuff $stagestuff"
1902                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1903                 all_headers="$all_headers $headers"
1904                 all_outputs="$all_outputs $outputs"
1905                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1906         fi
1907 done
1908
1909 check_languages=
1910 for language in .. $all_languages
1911 do
1912         if test $language != ".."
1913         then
1914                 check_languages="$check_languages check-$language"
1915         fi
1916 done
1917
1918 # Since we can't use `::' targets, we link each language in
1919 # with a set of hooks, reached indirectly via lang.${target}.
1920
1921 rm -f Make-hooks
1922 touch Make-hooks
1923 target_list="all.build all.cross start.encap rest.encap \
1924         info dvi \
1925         install-normal install-common install-info install-man \
1926         uninstall \
1927         mostlyclean clean distclean extraclean maintainer-clean \
1928         stage1 stage2 stage3 stage4"
1929 for t in $target_list
1930 do
1931         x=
1932         for lang in .. $all_languages
1933         do
1934                 if test $lang != ".."; then
1935                         x="$x $lang.$t"
1936                 fi
1937         done
1938         echo "lang.$t: $x" >> Make-hooks
1939 done
1940
1941 # Create .gdbinit.
1942
1943 echo "dir ." > .gdbinit
1944 echo "dir ${srcdir}" >> .gdbinit
1945 if test x$gdb_needs_out_file_path = xyes
1946 then
1947         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1948 fi
1949 if test "x$subdirs" != x; then
1950         for s in $subdirs
1951         do
1952                 echo "dir ${srcdir}/$s" >> .gdbinit
1953         done
1954 fi
1955 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
1956
1957 # Define variables host_canonical and build_canonical
1958 # because some Cygnus local changes in the Makefile depend on them.
1959 build_canonical=${build}
1960 host_canonical=${host}
1961 target_subdir=
1962 if test "${host}" != "${target}" ; then
1963     target_subdir=${target_alias}/
1964 fi
1965 AC_SUBST(build_canonical)
1966 AC_SUBST(host_canonical)
1967 AC_SUBST(target_subdir)
1968
1969 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1970 # absolute path for gcc_tooldir based on inserting the number of up-directory
1971 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1972 # $(libsubdir)/@(unlibsubdir) based path.
1973 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1974 # make and thus we'd get different behavior depending on where we built the
1975 # sources.
1976 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1977     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1978 else
1979 changequote(<<, >>)dnl
1980 # An explanation of the sed strings:
1981 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1982 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1983 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1984 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1985 #
1986 # (*) Note this pattern overwrites the first character of the string
1987 # with a forward slash if one is not already present.  This is not a
1988 # problem because the exact names of the sub-directories concerned is
1989 # unimportant, just the number of them matters.
1990 #
1991 # The practical upshot of these patterns is like this:
1992 #
1993 #  prefix     exec_prefix        result
1994 #  ------     -----------        ------
1995 #   /foo        /foo/bar          ../
1996 #   /foo/       /foo/bar          ../
1997 #   /foo        /foo/bar/         ../
1998 #   /foo/       /foo/bar/         ../
1999 #   /foo        /foo/bar/ugg      ../../
2000 #
2001     dollar='$$'
2002     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2003 changequote([, ])dnl
2004 fi
2005 AC_SUBST(gcc_tooldir)
2006 AC_SUBST(dollar)
2007
2008 # Find a directory in which to install a shared libgcc.
2009
2010 AC_ARG_ENABLE(version-specific-runtime-libs,
2011 [  --enable-version-specific-runtime-libs    Specify that runtime libraries shou
2012 ld be installed in a compiler-specific directory ])
2013
2014 AC_ARG_WITH(slibdir,
2015 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2016 slibdir="$with_slibdir",
2017 if test "${enable_version_specific_runtime_libs+set}" = set; then
2018   slibdir='$(libsubdir)'
2019 elif test "$host" != "$target"; then
2020   slibdir='$(build_tooldir)/lib'
2021 else
2022   slibdir='$(libdir)'
2023 fi)
2024 AC_SUBST(slibdir)
2025
2026 # Nothing to do for FLOAT_H, float_format already handled.
2027 objdir=`pwd`
2028 AC_SUBST(objdir)
2029
2030 # Process the language and host/target makefile fragments.
2031 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2032
2033 # Substitute configuration variables
2034 AC_SUBST(subdirs)
2035 AC_SUBST(all_boot_languages)
2036 AC_SUBST(all_compilers)
2037 AC_SUBST(all_diff_excludes)
2038 AC_SUBST(all_headers)
2039 AC_SUBST(all_lang_makefiles)
2040 AC_SUBST(all_languages)
2041 AC_SUBST(all_lib2funcs)
2042 AC_SUBST(all_stagestuff)
2043 AC_SUBST(build_exeext)
2044 AC_SUBST(build_install_headers_dir)
2045 AC_SUBST(build_xm_file_list)
2046 AC_SUBST(build_xm_file)
2047 AC_SUBST(build_xm_defines)
2048 AC_SUBST(check_languages)
2049 AC_SUBST(cc_set_by_configure)
2050 AC_SUBST(quoted_cc_set_by_configure)
2051 AC_SUBST(cpp_install_dir)
2052 AC_SUBST(dep_host_xmake_file)
2053 AC_SUBST(dep_tmake_file)
2054 AC_SUBST(extra_c_flags)
2055 AC_SUBST(extra_headers_list)
2056 AC_SUBST(extra_objs)
2057 AC_SUBST(extra_parts)
2058 AC_SUBST(extra_passes)
2059 AC_SUBST(extra_programs)
2060 AC_SUBST(float_h_file)
2061 AC_SUBST(gcc_config_arguments)
2062 AC_SUBST(gcc_gxx_include_dir)
2063 AC_SUBST(libstdcxx_incdir)
2064 AC_SUBST(gcc_version)
2065 AC_SUBST(gcc_version_full)
2066 AC_SUBST(gcc_version_trigger)
2067 AC_SUBST(host_exeext)
2068 AC_SUBST(host_extra_gcc_objs)
2069 AC_SUBST(host_xm_file_list)
2070 AC_SUBST(host_xm_file)
2071 AC_SUBST(host_xm_defines)
2072 AC_SUBST(install)
2073 AC_SUBST(lang_options_files)
2074 AC_SUBST(lang_specs_files)
2075 AC_SUBST(lang_tree_files)
2076 AC_SUBST(local_prefix)
2077 AC_SUBST(maybe_use_collect2)
2078 AC_SUBST(md_file)
2079 AC_SUBST(objc_boehm_gc)
2080 AC_SUBST(out_file)
2081 AC_SUBST(out_object_file)
2082 AC_SUBST(stage_prefix_set_by_configure)
2083 AC_SUBST(symbolic_link)
2084 AC_SUBST(thread_file)
2085 AC_SUBST(tm_file_list)
2086 AC_SUBST(tm_file)
2087 AC_SUBST(tm_p_file_list)
2088 AC_SUBST(tm_p_file)
2089 AC_SUBST(xm_file)
2090 AC_SUBST(xm_defines)
2091 AC_SUBST(will_use_collect2)
2092 AC_SUBST(c_target_objs)
2093 AC_SUBST(cxx_target_objs)
2094 AC_SUBST(target_cpu_default)
2095
2096 AC_SUBST_FILE(target_overrides)
2097 AC_SUBST_FILE(host_overrides)
2098 AC_SUBST(cross_defines)
2099 AC_SUBST_FILE(cross_overrides)
2100 AC_SUBST_FILE(build_overrides)
2101 AC_SUBST_FILE(language_fragments)
2102 AC_SUBST_FILE(language_hooks)
2103
2104 # Echo that links are built
2105 if test x$host = x$target
2106 then
2107         str1="native "
2108 else
2109         str1="cross-"
2110         str2=" from $host"
2111 fi
2112
2113 if test x$host != x$build
2114 then
2115         str3=" on a $build system"
2116 fi
2117
2118 if test "x$str2" != x || test "x$str3" != x
2119 then
2120         str4=
2121 fi
2122
2123 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2124
2125 if test "x$str2" != x || test "x$str3" != x
2126 then
2127         echo " ${str2}${str3}." 1>&2
2128 fi
2129
2130 # Truncate the target if necessary
2131 if test x$host_truncate_target != x; then
2132         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2133 fi
2134
2135 # Configure the subdirectories
2136 # AC_CONFIG_SUBDIRS($subdirs)
2137
2138 # Create the Makefile
2139 # and configure language subdirectories
2140 AC_OUTPUT($all_outputs,
2141 [
2142 case x$CONFIG_HEADERS in
2143 xauto-host.h:config.in)
2144 echo > cstamp-h ;;
2145 esac
2146 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2147 # bootstrapping and the installation procedure can still use
2148 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2149 # FLAGS_TO_PASS has been modified to solve the problem there.
2150 # This is virtually a duplicate of what happens in configure.lang; we do
2151 # an extra check to make sure this only happens if ln -s can be used.
2152 if test "$symbolic_link" = "ln -s"; then
2153  for d in .. ${subdirs} ; do
2154    if test $d != ..; then
2155         STARTDIR=`pwd`
2156         cd $d
2157         for t in stage1 stage2 stage3 stage4 include
2158         do
2159                 rm -f $t
2160                 $symbolic_link ../$t $t 2>/dev/null
2161         done
2162         cd $STARTDIR
2163    fi
2164  done
2165 else true ; fi
2166 # Avoid having to add intl to our include paths.
2167 if test -f intl/libintl.h; then
2168   echo creating libintl.h
2169   echo '#include "intl/libintl.h"' >libintl.h
2170 fi
2171 ],
2172 [
2173 host='${host}'
2174 build='${build}'
2175 target='${target}'
2176 target_alias='${target_alias}'
2177 srcdir='${srcdir}'
2178 subdirs='${subdirs}'
2179 symbolic_link='${symbolic_link}'
2180 program_transform_set='${program_transform_set}'
2181 program_transform_name='${program_transform_name}'
2182 dep_host_xmake_file='${dep_host_xmake_file}'
2183 host_xmake_file='${host_xmake_file}'
2184 dep_tmake_file='${dep_tmake_file}'
2185 tmake_file='${tmake_file}'
2186 thread_file='${thread_file}'
2187 gcc_config_arguments='${gcc_config_arguments}'
2188 gcc_version='${gcc_version}'
2189 gcc_version_full='${gcc_version_full}'
2190 gcc_version_trigger='${gcc_version_trigger}'
2191 local_prefix='${local_prefix}'
2192 build_install_headers_dir='${build_install_headers_dir}'
2193 build_exeext='${build_exeext}'
2194 host_exeext='${host_exeext}'
2195 out_file='${out_file}'
2196 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2197 SET_MAKE='${SET_MAKE}'
2198 target_list='${target_list}'
2199 target_overrides='${target_overrides}'
2200 host_overrides='${host_overrides}'
2201 cross_defines='${cross_defines}'
2202 cross_overrides='${cross_overrides}'
2203 build_overrides='${build_overrides}'
2204 cpp_install_dir='${cpp_install_dir}'
2205 ])