gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.13)
  29 AC_INIT(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 # Determine the host, build, and target systems
  33 AC_CANONICAL_SYSTEM
  34
  35 # Determine the target- and build-specific subdirectories
  36 GCC_TOPLEV_SUBDIRS
  37
  38 # Set program_transform_name
  39 AC_ARG_PROGRAM
  40
  41 # Check for bogus environment variables.
  42 # Test if LIBRARY_PATH contains the notation for the current directory
  43 # since this would lead to problems installing/building glibc.
  44 # LIBRARY_PATH contains the current directory if one of the following
  45 # is true:
  46 # - one of the terminals (":" and ";") is the first or last sign
  47 # - two terminals occur directly after each other
  48 # - the path contains an element with a dot in it
  49 AC_MSG_CHECKING(LIBRARY_PATH variable)
  50 changequote(,)dnl
  51 case ${LIBRARY_PATH} in
  52   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  53     library_path_setting="contains current directory"
  54     ;;
  55   *)
  56     library_path_setting="ok"
  57     ;;
  58 esac
  59 changequote([,])dnl
  60 AC_MSG_RESULT($library_path_setting)
  61 if test "$library_path_setting" != "ok"; then
  62 AC_MSG_ERROR([
  63 *** LIBRARY_PATH shouldn't contain the current directory when
  64 *** building gcc. Please change the environment variable
  65 *** and run configure again.])
  66 fi
  67
  68 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  69 # since this would lead to problems installing/building glibc.
  70 # GCC_EXEC_PREFIX contains the current directory if one of the following
  71 # is true:
  72 # - one of the terminals (":" and ";") is the first or last sign
  73 # - two terminals occur directly after each other
  74 # - the path contains an element with a dot in it
  75 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  76 changequote(,)dnl
  77 case ${GCC_EXEC_PREFIX} in
  78   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  79     gcc_exec_prefix_setting="contains current directory"
  80     ;;
  81   *)
  82     gcc_exec_prefix_setting="ok"
  83     ;;
  84 esac
  85 changequote([,])dnl
  86 AC_MSG_RESULT($gcc_exec_prefix_setting)
  87 if test "$gcc_exec_prefix_setting" != "ok"; then
  88 AC_MSG_ERROR([
  89 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  90 *** building gcc. Please change the environment variable
  91 *** and run configure again.])
  92 fi
  93
  94 # -----------
  95 # Directories
  96 # -----------
  97
  98 # Specify the local prefix
  99 local_prefix=
 100 AC_ARG_WITH(local-prefix,
 101 [  --with-local-prefix=DIR specifies directory to put local include],
 102 [case "${withval}" in
 103 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 104 no)     ;;
 105 *)      local_prefix=$with_local_prefix ;;
 106 esac])
 107
 108 # Default local prefix if it is empty
 109 if test x$local_prefix = x; then
 110         local_prefix=/usr/local
 111 fi
 112
 113 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 114 # passed in by the toplevel make and thus we'd get different behavior
 115 # depending on where we built the sources.
 116 gcc_gxx_include_dir=
 117 # Specify the g++ header file directory
 118 AC_ARG_WITH(gxx-include-dir,
 119 [  --with-gxx-include-dir=DIR
 120                           specifies directory to put g++ header files],
 121 [case "${withval}" in
 122 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 123 no)     ;;
 124 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 125 esac])
 126
 127 if test x${gcc_gxx_include_dir} = x; then
 128   if test x${enable_version_specific_runtime_libs} = xyes; then
 129     gcc_gxx_include_dir='${libsubdir}/include/c++'
 130   else
 131     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 132 changequote(<<, >>)dnl
 133     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 134 changequote([, ])dnl
 135   fi
 136 fi
 137
 138 AC_ARG_WITH(cpp_install_dir,
 139 [  --with-cpp-install-dir=DIR
 140                           install the user visible C preprocessor in DIR
 141                           (relative to PREFIX) as well as PREFIX/bin],
 142 [if test x$withval = xyes; then
 143   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 144 elif test x$withval != xno; then
 145   cpp_install_dir=$withval
 146 fi])
 147
 148 # -------------------
 149 # Find default linker
 150 # -------------------
 151
 152 # With GNU ld
 153 AC_ARG_WITH(gnu-ld,
 154 [  --with-gnu-ld           arrange to work with GNU ld.],
 155 gnu_ld_flag="$with_gnu_ld",
 156 gnu_ld_flag=no)
 157
 158 # With pre-defined ld
 159 AC_ARG_WITH(ld,
 160 [  --with-ld               arrange to use the specified ld (full pathname)],
 161 DEFAULT_LINKER="$with_ld")
 162 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 163   if test ! -x "$DEFAULT_LINKER"; then
 164     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 165   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 166     gnu_ld_flag=yes
 167   fi
 168   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 169         [Define to enable the use of a default linker.])
 170 fi
 171
 172 AC_MSG_CHECKING([whether a default linker was specified])
 173 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 174   if test x"$gnu_ld_flag" = x"no"; then
 175     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 176   else
 177     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 178   fi
 179 else
 180   AC_MSG_RESULT(no)
 181 fi
 182
 183 # ----------------------
 184 # Find default assembler
 185 # ----------------------
 186
 187 # With GNU as
 188 AC_ARG_WITH(gnu-as,
 189 [  --with-gnu-as           arrange to work with GNU as],
 190 gas_flag="$with_gnu_as",
 191 gas_flag=no)
 192
 193 AC_ARG_WITH(as,
 194 [  --with-as               arrange to use the specified as (full pathname)],
 195 DEFAULT_ASSEMBLER="$with_as")
 196 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_ASSEMBLER"; then
 198     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 199   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gas_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 203         [Define to enable the use of a default assembler.])
 204 fi
 205
 206 AC_MSG_CHECKING([whether a default assembler was specified])
 207 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 208   if test x"$gas_flag" = x"no"; then
 209     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 210   else
 211     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 212   fi
 213 else
 214   AC_MSG_RESULT(no)
 215 fi
 216
 217 # ---------------
 218 # Find C compiler
 219 # ---------------
 220
 221 # Find the native compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_C_O
 224 # autoconf is lame and doesn't give us any substitution variable for this.
 225 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 226   NO_MINUS_C_MINUS_O=yes
 227 else
 228   OUTPUT_OPTION='-o $@'
 229 fi
 230 AC_SUBST(NO_MINUS_C_MINUS_O)
 231 AC_SUBST(OUTPUT_OPTION)
 232
 233 # -------------------------
 234 # Check C compiler features
 235 # -------------------------
 236
 237 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 238 ac_cv_prog_cc_no_long_long,
 239 [save_CFLAGS="$CFLAGS"
 240 CFLAGS="-Wno-long-long"
 241 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 242                ac_cv_prog_cc_no_long_long=no)
 243 CFLAGS="$save_CFLAGS"])
 244
 245 AC_PROG_CPP
 246 AC_C_INLINE
 247
 248 gcc_AC_C_LONG_LONG
 249 gcc_AC_C__BOOL
 250
 251 # sizeof(char) is 1 by definition.
 252 AC_COMPILE_CHECK_SIZEOF(void *)
 253 AC_COMPILE_CHECK_SIZEOF(short)
 254 AC_COMPILE_CHECK_SIZEOF(int)
 255 AC_COMPILE_CHECK_SIZEOF(long)
 256 if test $ac_cv_c_long_long = yes; then
 257   AC_COMPILE_CHECK_SIZEOF(long long)
 258 fi
 259 if test $ac_cv_c___int64 = yes; then
 260   AC_COMPILE_CHECK_SIZEOF(__int64)
 261 fi
 262
 263 # -----------------
 264 # Find Ada compiler
 265 # -----------------
 266
 267 # See if GNAT has been installed
 268 gcc_AC_PROG_GNAT
 269
 270 if test x$have_gnat != xno ; then
 271 AC_CACHE_CHECK(whether ${ADAC} accepts -Wno-long-long,
 272 ac_cv_prog_adac_no_long_long,
 273 [cat >conftest.adb <<EOF
 274 procedure conftest is begin null; end conftest;
 275 EOF
 276 if $ADAC -Wno-long-long -c conftest.adb 1>&5 2>&5 ; then
 277   ac_cv_prog_adac_no_long_long=yes
 278 else
 279   ac_cv_prog_adac_no_long_long=no
 280 fi
 281 rm -f conftest*])
 282 else
 283   ac_cv_prog_adac_no_long_long=yes
 284 fi
 285
 286 # ---------------------
 287 # Warnings and checking
 288 # ---------------------
 289
 290 strict1_warn=
 291 if test $ac_cv_prog_cc_no_long_long = yes && \
 292     test $ac_cv_prog_adac_no_long_long = yes ; then
 293   strict1_warn="-pedantic -Wno-long-long"
 294 fi
 295 AC_SUBST(strict1_warn)
 296
 297 # If the native compiler is GCC, we can enable warnings even in stage1.
 298 # That's useful for people building cross-compilers, or just running a
 299 # quick `make'.
 300 warn_cflags=
 301 if test "x$GCC" = "xyes"; then
 302   warn_cflags='$(GCC_WARN_CFLAGS)'
 303 fi
 304 AC_SUBST(warn_cflags)
 305
 306 # Enable -Werror in bootstrap stage2 and later.
 307 # Change the default to "no" on release branches.
 308 AC_ARG_ENABLE(werror,
 309 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 310 [enable_werror=yes])
 311 if test x$enable_werror = xyes ; then
 312   WERROR=-Werror
 313 fi
 314 AC_SUBST(WERROR)
 315
 316 # Enable expensive internal checks
 317 AC_ARG_ENABLE(checking,
 318 [  --enable-checking[=LIST]
 319                           enable expensive run-time checks.  With LIST,
 320                           enable only specific categories of checks.
 321                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 322                           default is misc,tree,gc,rtlflag],
 323 [ac_checking=
 324 ac_tree_checking=
 325 ac_rtl_checking=
 326 ac_rtlflag_checking=
 327 ac_gc_checking=
 328 ac_gc_always_collect=
 329 ac_fold_checking=
 330 case "${enableval}" in
 331 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 332         ac_rtlflag_checking=1 ;;
 333 no)     ;;
 334 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 335         set fnord $enableval; shift
 336         IFS="$ac_save_IFS"
 337         for check
 338         do
 339                 case $check in
 340                 misc)   ac_checking=1 ;;
 341                 tree)   ac_tree_checking=1 ;;
 342                 rtlflag)        ac_rtlflag_checking=1 ;;
 343                 rtl)    ac_rtl_checking=1 ;;
 344                 gc)     ac_gc_checking=1 ;;
 345                 gcac)   ac_gc_always_collect=1 ;;
 346                 fold)   ac_fold_checking=1 ;;
 347                 valgrind)       ac_checking_valgrind=1 ;;
 348                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 349                 esac
 350         done
 351         ;;
 352 esac
 353 ],
 354 # Enable some checks by default for development versions of GCC
 355 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 356 nocommon_flag=""
 357 if test x$ac_checking != x ; then
 358   AC_DEFINE(ENABLE_CHECKING, 1,
 359 [Define if you want more run-time sanity checks.  This one gets a grab
 360    bag of miscellaneous but relatively cheap checks.])
 361   nocommon_flag=-fno-common
 362 fi
 363 AC_SUBST(nocommon_flag)
 364 if test x$ac_tree_checking != x ; then
 365   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 366 [Define if you want all operations on trees (the basic data
 367    structure of the front ends) to be checked for dynamic type safety
 368    at runtime.  This is moderately expensive.])
 369 fi
 370 if test x$ac_rtl_checking != x ; then
 371   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 372 [Define if you want all operations on RTL (the basic data structure
 373    of the optimizer and back end) to be checked for dynamic type safety
 374    at runtime.  This is quite expensive.])
 375 fi
 376 if test x$ac_rtlflag_checking != x ; then
 377   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 378 [Define if you want RTL flag accesses to be checked against the RTL
 379    codes that are supported for each access macro.  This is relatively
 380    cheap.])
 381 fi
 382 if test x$ac_gc_checking != x ; then
 383   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 384 [Define if you want the garbage collector to do object poisoning and
 385    other memory allocation checks.  This is quite expensive.])
 386 fi
 387 if test x$ac_gc_always_collect != x ; then
 388   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 389 [Define if you want the garbage collector to operate in maximally
 390    paranoid mode, validating the entire heap and collecting garbage at
 391    every opportunity.  This is extremely expensive.])
 392 fi
 393 if test x$ac_fold_checking != x ; then
 394   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 395 [Define if you want fold checked that it never destructs its argument.
 396    This is quite expensive.])
 397 fi
 398 valgrind_path_defines=
 399 valgrind_command=
 400 if test x$ac_checking_valgrind != x ; then
 401   # It is certainly possible that there's valgrind but no valgrind.h.
 402   # GCC relies on making annotations so we must have both.
 403   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 404   AC_TRY_CPP(
 405     [#include <memcheck.h>
 406 #ifndef VALGRIND_DISCARD
 407 #error VALGRIND_DISCARD not defined
 408 #endif],
 409   [gcc_cv_header_memcheck_h=yes],
 410   gcc_cv_header_memcheck_h=no)
 411   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 412   AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 413   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 414         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 415   if test "x$valgrind_path" = "x" || (test $have_valgrind_h = no && test $gcc_cv_header_memcheck_h = no); then
 416         AC_MSG_ERROR([*** Can't find both valgrind and valgrind.h/memcheck.h])
 417   fi
 418   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 419   valgrind_command="$valgrind_path -q"
 420   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 421 [Define if you want to run subprograms and generated programs
 422    through valgrind (a memory checker).  This is extremely expensive.])
 423   if test $gcc_cv_header_memcheck_h = yes; then
 424     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 425         [Define if valgrind's memcheck.h header is installed.])
 426   fi
 427 fi
 428 AC_SUBST(valgrind_path_defines)
 429 AC_SUBST(valgrind_command)
 430
 431 # Enable code coverage collection
 432 AC_ARG_ENABLE(coverage,
 433 [  --enable-coverage[=LEVEL]
 434                           enable compiler\'s code coverage collection.
 435                           Use to measure compiler performance and locate
 436                           unused parts of the compiler. With LEVEL, specify
 437                           optimization. Values are opt, noopt,
 438                           default is noopt],
 439 [case "${enableval}" in
 440 yes|noopt)
 441         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 442         ;;
 443 opt)
 444         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 445         ;;
 446 *)
 447         AC_MSG_ERROR(unknown coverage setting $enableval)
 448         ;;
 449 esac],
 450 [coverage_flags=""])
 451 AC_SUBST(coverage_flags)
 452
 453 # -------------------------------
 454 # Miscenalleous configure options
 455 # -------------------------------
 456
 457 # With stabs
 458 AC_ARG_WITH(stabs,
 459 [  --with-stabs            arrange to use stabs instead of host debug format],
 460 stabs="$with_stabs",
 461 stabs=no)
 462
 463 # With ELF
 464 AC_ARG_WITH(elf,
 465 [  --with-elf              arrange to use ELF instead of host debug format],
 466 elf="$with_elf",
 467 elf=no)
 468
 469 # Determine whether or not multilibs are enabled.
 470 AC_ARG_ENABLE(multilib,
 471 [  --enable-multilib       enable library support for multiple ABIs],
 472 [], [enable_multilib=yes])
 473 AC_SUBST(enable_multilib)
 474
 475 # Enable __cxa_atexit for C++.
 476 AC_ARG_ENABLE(__cxa_atexit,
 477 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 478 [], [])
 479
 480 # Enable threads
 481 # Pass with no value to take the default
 482 # Pass with a value to specify a thread package
 483 AC_ARG_ENABLE(threads,
 484 [  --enable-threads        enable thread usage for target GCC
 485   --enable-threads=LIB    use LIB thread package for target GCC],,
 486 enable_threads='')
 487
 488 enable_threads_flag=$enable_threads
 489 # Check if a valid thread package
 490 case x${enable_threads_flag} in
 491         x | xno)
 492                 # No threads
 493                 target_thread_file='single'
 494                 ;;
 495         xyes)
 496                 # default
 497                 target_thread_file=''
 498                 ;;
 499         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 500         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix | xgnat)
 501                 target_thread_file=$enable_threads_flag
 502                 ;;
 503         *)
 504                 echo "$enable_threads is an unknown thread package" 1>&2
 505                 exit 1
 506                 ;;
 507 esac
 508
 509 AC_ARG_ENABLE(objc-gc,
 510 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 511                           the GNU Objective-C runtime],
 512 if test x$enable_objc_gc = xno; then
 513         objc_boehm_gc=''
 514 else
 515         objc_boehm_gc=1
 516 fi,
 517 objc_boehm_gc='')
 518
 519 AC_ARG_WITH(dwarf2,
 520 [  --with-dwarf2           force the default debug format to be DWARF 2],
 521 dwarf2="$with_dwarf2",
 522 dwarf2=no)
 523
 524 AC_ARG_ENABLE(shared,
 525 [  --disable-shared        don't provide a shared libgcc],
 526 [
 527   case $enable_shared in
 528   yes | no) ;;
 529   *)
 530     enable_shared=no
 531     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 532     for pkg in $enableval; do
 533       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 534         enable_shared=yes
 535       fi
 536     done
 537     IFS="$ac_save_ifs"
 538     ;;
 539   esac
 540 ], [enable_shared=yes])
 541 AC_SUBST(enable_shared)
 542
 543 AC_ARG_WITH(sysroot,
 544 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 545 [
 546  case ${with_sysroot} in
 547  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 548  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 549  esac
 550
 551  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 552  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 553
 554  if test "x$exec_prefix" = xNONE; then
 555   if test "x$prefix" = xNONE; then
 556    test_prefix=/usr/local
 557   else
 558    test_prefix=$prefix
 559   fi
 560  else
 561   test_prefix=$exec_prefix
 562  fi
 563  case ${TARGET_SYSTEM_ROOT} in
 564  "${test_prefix}"|"${test_prefix}/"*|\
 565  '${exec_prefix}'|'${exec_prefix}/'*)
 566    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 567    TARGET_SYSTEM_ROOT_DEFINE="$t"
 568    ;;
 569  esac
 570 ], [
 571  TARGET_SYSTEM_ROOT=
 572  TARGET_SYSTEM_ROOT_DEFINE=
 573  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 574 ])
 575 AC_SUBST(TARGET_SYSTEM_ROOT)
 576 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 577 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 578
 579 # Build with intermodule optimisations
 580 AC_ARG_ENABLE(intermodule,
 581 [  --enable-intermodule    build the compiler in one step],
 582 [case ${enable_intermodule} in
 583   yes) onestep="-onestep";;
 584   *) onestep="";;
 585 esac],
 586 [onestep=""])
 587 AC_SUBST(onestep)
 588
 589 # -------------------------
 590 # Checks for other programs
 591 # -------------------------
 592
 593 AC_PROG_MAKE_SET
 594
 595 # Find some useful tools
 596 AC_PROG_AWK
 597 gcc_AC_PROG_LN
 598 gcc_AC_PROG_LN_S
 599 AC_PROG_RANLIB
 600 gcc_AC_PROG_INSTALL
 601
 602 # See if cmp has --ignore-initial.
 603 gcc_AC_PROG_CMP_IGNORE_INITIAL
 604
 605 # See if we have the mktemp command.
 606 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 607
 608 # Do we have a single-tree copy of texinfo?
 609 if test -f $srcdir/../texinfo/Makefile.in; then
 610   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 611   gcc_cv_prog_makeinfo_modern=yes
 612   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 613 else
 614   # See if makeinfo has been installed and is modern enough
 615   # that we can use it.
 616   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 617   [GNU texinfo.* \([0-9][0-9.]*\)],
 618   [4.[2-9]*])
 619 fi
 620
 621 if test $gcc_cv_prog_makeinfo_modern = no; then
 622   AC_MSG_WARN([
 623 *** Makeinfo is missing or too old.
 624 *** Info documentation will not be built.])
 625   BUILD_INFO=
 626 else
 627   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 628 fi
 629
 630 # Is pod2man recent enough to regenerate manpages?
 631 AC_MSG_CHECKING([for recent Pod::Man])
 632 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 633   AC_MSG_RESULT(yes)
 634   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 635 else
 636   AC_MSG_RESULT(no)
 637   GENERATED_MANPAGES=
 638 fi
 639
 640 # How about lex?
 641 dnl Don't use AC_PROG_LEX; we insist on flex.
 642 dnl LEXLIB is not useful in gcc.
 643 if test -f $srcdir/../flex/skel.c; then
 644   FLEX='$(objdir)/../flex/flex'
 645 else
 646   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 647 fi
 648
 649 # Bison?
 650 # The -L switch is so bison can find its skeleton file.
 651 if test -f $srcdir/../bison/bison.simple; then
 652   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 653 else
 654   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 655 fi
 656
 657 # --------------------
 658 # Checks for C headers
 659 # --------------------
 660
 661 AC_MSG_CHECKING(for GNU C library)
 662 AC_CACHE_VAL(gcc_cv_glibc,
 663 [AC_TRY_COMPILE(
 664   [#include <features.h>],[
 665 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 666 #error Not a GNU C library system
 667 #endif],
 668   [gcc_cv_glibc=yes],
 669   gcc_cv_glibc=no)])
 670 AC_MSG_RESULT($gcc_cv_glibc)
 671 if test $gcc_cv_glibc = yes; then
 672   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 673 fi
 674
 675 AC_HEADER_STDC
 676 AC_HEADER_TIME
 677 gcc_AC_HEADER_STDBOOL
 678 gcc_AC_HEADER_STRING
 679 AC_HEADER_SYS_WAIT
 680 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 681                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 682                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 683                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 684
 685 # Check for thread headers.
 686 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 687 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 688
 689 # These tests can't be done till we know if we have limits.h.
 690 gcc_AC_C_CHAR_BIT
 691 AC_C_BIGENDIAN_CROSS
 692
 693 # --------
 694 # UNSORTED
 695 # --------
 696
 697 # Stage specific cflags for build.
 698 stage1_cflags=
 699 case $build in
 700 vax-*-*)
 701   if test x$GCC = xyes
 702   then
 703     stage1_cflags="-Wa,-J"
 704   else
 705     stage1_cflags="-J"
 706   fi
 707   ;;
 708 powerpc-*-darwin*)
 709   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 710   # sources; use -no-cpp-precomp to get to GNU cpp.
 711   # Apple's GCC has bugs in designated initializer handling, so disable
 712   # that too.
 713   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 714   ;;
 715 esac
 716 AC_SUBST(stage1_cflags)
 717
 718 # These libraries may be used by collect2.
 719 # We may need a special search path to get them linked.
 720 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 721 [save_LIBS="$LIBS"
 722 for libs in '' -lld -lmld \
 723                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 724                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 725 do
 726         LIBS="$libs"
 727         AC_TRY_LINK_FUNC(ldopen,
 728                 [gcc_cv_collect2_libs="$libs"; break])
 729 done
 730 LIBS="$save_LIBS"
 731 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 732 case $gcc_cv_collect2_libs in
 733         "none required")        ;;
 734         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 735 esac
 736 AC_SUBST(COLLECT2_LIBS)
 737
 738 # When building Ada code on Alpha, we need exc_resume which is usually in
 739 # -lexc.  So test for it.
 740 save_LIBS="$LIBS"
 741 LIBS=
 742 AC_SEARCH_LIBS(exc_resume, exc)
 743 GNAT_LIBEXC="$LIBS"
 744 LIBS="$save_LIBS"
 745 AC_SUBST(GNAT_LIBEXC)
 746
 747 # Some systems put ldexp and frexp in libm instead of libc; assume
 748 # they're both in the same place.  jcf-dump needs them.
 749 save_LIBS="$LIBS"
 750 LIBS=
 751 AC_SEARCH_LIBS(ldexp, m)
 752 LDEXP_LIB="$LIBS"
 753 LIBS="$save_LIBS"
 754 AC_SUBST(LDEXP_LIB)
 755
 756 # Use <inttypes.h> only if it exists,
 757 # doesn't clash with <sys/types.h>, and declares intmax_t.
 758 AC_MSG_CHECKING(for inttypes.h)
 759 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 760 [AC_TRY_COMPILE(
 761   [#include <sys/types.h>
 762 #include <inttypes.h>],
 763   [intmax_t i = -1;],
 764   [gcc_cv_header_inttypes_h=yes],
 765   gcc_cv_header_inttypes_h=no)])
 766 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 767 if test $gcc_cv_header_inttypes_h = yes; then
 768   AC_DEFINE(HAVE_INTTYPES_H, 1,
 769         [Define if you have a working <inttypes.h> header file.])
 770 fi
 771
 772 dnl Disabled until we have a complete test for buggy enum bitfields.
 773 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 774
 775 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 776         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 777         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 778         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 779         setlocale)
 780
 781 if test x$ac_cv_func_mbstowcs = xyes; then
 782   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 783 [    AC_TRY_RUN([#include <stdlib.h>
 784 int main()
 785 {
 786   mbstowcs(0, "", 0);
 787   return 0;
 788 }],
 789     gcc_cv_func_mbstowcs_works=yes,
 790     gcc_cv_func_mbstowcs_works=no,
 791     gcc_cv_func_mbstowcs_works=yes)])
 792   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 793     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 794   [Define this macro if mbstowcs does not crash when its
 795    first argument is NULL.])
 796   fi
 797 fi
 798
 799 gcc_AC_CHECK_TYPE(ssize_t, int)
 800
 801 # Try to determine the array type of the second argument of getgroups
 802 # for the target system (int or gid_t).
 803 AC_TYPE_GETGROUPS
 804 if test "${target}" = "${build}"; then
 805   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 806 else
 807   case "${target}" in
 808         # This condition may need some tweaking.  It should include all
 809         # targets where the array type of the second argument of getgroups
 810         # is int and the type of gid_t is not equivalent to int.
 811         *-*-sunos* | *-*-ultrix*)
 812                 TARGET_GETGROUPS_T=int
 813                 ;;
 814         *)
 815                 TARGET_GETGROUPS_T=gid_t
 816                 ;;
 817   esac
 818 fi
 819 AC_SUBST(TARGET_GETGROUPS_T)
 820
 821 gcc_AC_FUNC_PRINTF_PTR
 822 gcc_AC_FUNC_MMAP_BLACKLIST
 823
 824 case "${host}" in
 825 *-*-uwin*)
 826   AC_MSG_ERROR([
 827 *** UWIN may not be used as a host platform because
 828 *** linking with posix.dll is not allowed by the GNU GPL])
 829   ;;
 830 *-*-*vms*)
 831   # Under VMS, vfork works very different than on Unix. The standard test
 832   # won't work, and it isn't easily adaptable. It makes more sense to
 833   # just force it.
 834   ac_cv_func_vfork_works=yes
 835   ;;
 836 esac
 837 AC_FUNC_VFORK
 838
 839 AM_ICONV
 840 # Until we have in-tree GNU iconv:
 841 LIBICONV_DEP=
 842 AC_SUBST(LIBICONV_DEP)
 843
 844 AM_LC_MESSAGES
 845
 846 # We will need to find libiberty.h and ansidecl.h
 847 saved_CFLAGS="$CFLAGS"
 848 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 849 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 850         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 851         fprintf_unlocked strstr errno vasprintf \
 852         malloc realloc calloc free basename getopt clock, , ,[
 853 #include "ansidecl.h"
 854 #include "system.h"])
 855
 856 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 857 #include "ansidecl.h"
 858 #include "system.h"
 859 #ifdef HAVE_SYS_RESOURCE_H
 860 #include <sys/resource.h>
 861 #endif
 862 ])
 863
 864 AC_TRY_COMPILE([
 865 #include "ansidecl.h"
 866 #include "system.h"
 867 #ifdef HAVE_SYS_RESOURCE_H
 868 #include <sys/resource.h>
 869 #endif
 870 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 871 [Define to \`long' if <sys/resource.h> doesn't define.])])
 872
 873 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 874 #include "ansidecl.h"
 875 #include "system.h"
 876 #ifdef HAVE_LDFCN_H
 877 #include <ldfcn.h>
 878 #endif
 879 ])
 880
 881 gcc_AC_CHECK_DECLS(times, , ,[
 882 #include "ansidecl.h"
 883 #include "system.h"
 884 #ifdef HAVE_SYS_TIMES_H
 885 #include <sys/times.h>
 886 #endif
 887 ])
 888
 889 # More time-related stuff.
 890 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 891 AC_TRY_COMPILE([
 892 #include "ansidecl.h"
 893 #include "system.h"
 894 #ifdef HAVE_SYS_TIMES_H
 895 #include <sys/times.h>
 896 #endif
 897 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 898 if test $ac_cv_struct_tms = yes; then
 899   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 900   [Define if <sys/times.h> defines struct tms.])
 901 fi
 902
 903 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 904 # revisit after autoconf 2.50.
 905 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 906 AC_TRY_COMPILE([
 907 #include "ansidecl.h"
 908 #include "system.h"
 909 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 910 if test $gcc_cv_type_clock_t = yes; then
 911   AC_DEFINE(HAVE_CLOCK_T, 1,
 912   [Define if <time.h> defines clock_t.])
 913 fi
 914
 915 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 916 [AC_TRY_COMPILE([
 917 #include "ansidecl.h"
 918 #include "system.h"
 919 ],
 920 [if ((uchar *)0) return 0;
 921  if (sizeof(uchar)) return 0;],
 922 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 923 if test $ac_cv_type_uchar = yes; then
 924   AC_DEFINE(HAVE_UCHAR, 1,
 925   [Define if <sys/types.h> defines \`uchar'.])
 926 fi
 927
 928 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 929 CFLAGS="$saved_CFLAGS"
 930
 931 gcc_AC_INITFINI_ARRAY
 932
 933 # mkdir takes a single argument on some systems.
 934 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 935
 936 # File extensions
 937 manext='.1'
 938 objext='.o'
 939 AC_SUBST(manext)
 940 AC_SUBST(objext)
 941
 942 # With Setjmp/Longjmp based exception handling.
 943 AC_ARG_ENABLE(sjlj-exceptions,
 944 [  --enable-sjlj-exceptions
 945                           arrange to use setjmp/longjmp exception handling],
 946 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 947 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 948   [Define 0/1 to force the choice for exception handling model.])])
 949
 950 AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 951 # Use libunwind based exception handling.
 952 AC_ARG_ENABLE(libunwind-exceptions,
 953 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 954 use_libunwind_exceptions=$enableval,
 955 use_libunwind_exceptions=$use_libunwind_default)
 956 if test x"$use_libunwind_exceptions" = xyes; then
 957    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 958         [Define if gcc should use -lunwind.])
 959 fi
 960
 961 # --------------------------------------------------------
 962 # Build, host, and target specific configuration fragments
 963 # --------------------------------------------------------
 964
 965 # Collect build-machine-specific information.
 966 . ${srcdir}/config.build
 967
 968 # Collect host-machine-specific information.
 969 . ${srcdir}/config.host
 970
 971 target_gtfiles=
 972
 973 # Collect target-machine-specific information.
 974 for machine in $target ; do
 975         . ${srcdir}/config.gcc
 976 done
 977
 978 extra_objs="${host_extra_objs} ${extra_objs}"
 979
 980 # Default the target-machine variables that were not explicitly set.
 981 if test x"$tm_file" = x
 982 then tm_file=$cpu_type/$cpu_type.h; fi
 983
 984 if test x"$extra_headers" = x
 985 then extra_headers=; fi
 986
 987 if test x$md_file = x
 988 then md_file=$cpu_type/$cpu_type.md; fi
 989
 990 if test x$out_file = x
 991 then out_file=$cpu_type/$cpu_type.c; fi
 992
 993 if test x"$tmake_file" = x
 994 then tmake_file=$cpu_type/t-$cpu_type
 995 fi
 996
 997 if test x"$dwarf2" = xyes
 998 then tm_file="$tm_file tm-dwarf2.h"
 999 fi
1000
1001 # Say what files are being used for the output code and MD file.
1002 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1003 echo "Using \`$srcdir/config/$md_file' as machine description file."
1004
1005 # If any of the xm_file variables contain nonexistent files, warn
1006 # about them and drop them.
1007
1008 bx=
1009 for x in $build_xm_file; do
1010   if    test -f $srcdir/config/$x
1011   then      bx="$bx $x"
1012   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1013   fi
1014 done
1015 build_xm_file="$bx"
1016
1017 hx=
1018 for x in $host_xm_file; do
1019   if    test -f $srcdir/config/$x
1020   then      hx="$hx $x"
1021   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1022   fi
1023 done
1024 host_xm_file="$hx"
1025
1026 tx=
1027 for x in $xm_file; do
1028   if    test -f $srcdir/config/$x
1029   then      tx="$tx $x"
1030   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1031   fi
1032 done
1033 xm_file="$tx"
1034
1035 count=a
1036 for f in $tm_file; do
1037         count=${count}x
1038 done
1039 if test $count = ax; then
1040         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1041 else
1042         echo "Using the following target machine macro files:"
1043         for f in $tm_file; do
1044                 echo "  $srcdir/config/$f"
1045         done
1046 fi
1047
1048 if test x$need_64bit_hwint = xyes; then
1049         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1050 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1051 fi
1052
1053 count=a
1054 for f in $host_xm_file; do
1055         count=${count}x
1056 done
1057 if test $count = a; then
1058         :
1059 elif test $count = ax; then
1060         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1061 else
1062         echo "Using the following host machine macro files:"
1063         for f in $host_xm_file; do
1064                 echo "  $srcdir/config/$f"
1065         done
1066 fi
1067 echo "Using ${out_host_hook_obj} for host machine hooks."
1068
1069 if test "$host_xm_file" != "$build_xm_file"; then
1070         count=a
1071         for f in $build_xm_file; do
1072                 count=${count}x
1073         done
1074         if test $count = a; then
1075                 :
1076         elif test $count = ax; then
1077                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1078         else
1079                 echo "Using the following build machine macro files:"
1080                 for f in $build_xm_file; do
1081                         echo "  $srcdir/config/$f"
1082                 done
1083         fi
1084 fi
1085
1086 if test x$thread_file = x; then
1087         if test x$target_thread_file != x; then
1088                 thread_file=$target_thread_file
1089         else
1090                 thread_file='single'
1091         fi
1092 fi
1093
1094 if test x$enable___cxa_atexit = xyes || \
1095    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1096   AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1097   [Define if you want to use __cxa_atexit, rather than atexit, to
1098    register C++ destructors for local statics and global objects.
1099    This is essential for fully standards-compliant handling of
1100    destructors, but requires __cxa_atexit in libc.])
1101 fi
1102
1103 # Look for a file containing extra machine modes.
1104 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1105   extra_modes_file='$(srcdir)'/config/${extra_modes}
1106   AC_SUBST(extra_modes_file)
1107   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1108   [Define to the name of a file containing a list of extra machine modes
1109    for this architecture.])
1110   AC_DEFINE(EXTRA_CC_MODES, 1,
1111   [Define if the target architecture needs extra machine modes to represent
1112    the results of comparisons.])
1113 fi
1114
1115 # auto-host.h is the file containing items generated by autoconf and is
1116 # the first file included by config.h.
1117 # If host=build, it is correct to have bconfig include auto-host.h
1118 # as well.  If host!=build, we are in error and need to do more
1119 # work to find out the build config parameters.
1120 if test x$host = x$build
1121 then
1122         build_auto=auto-host.h
1123         FORBUILD=..
1124 else
1125         # We create a subdir, then run autoconf in the subdir.
1126         # To prevent recursion we set host and build for the new
1127         # invocation of configure to the build for this invocation
1128         # of configure.
1129         tempdir=build.$$
1130         rm -rf $tempdir
1131         mkdir $tempdir
1132         cd $tempdir
1133         case ${srcdir} in
1134         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1135         *) realsrcdir=../${srcdir};;
1136         esac
1137         saved_CFLAGS="${CFLAGS}"
1138         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1139         ${realsrcdir}/configure \
1140                 --target=$target_alias --host=$build_alias --build=$build_alias
1141         CFLAGS="${saved_CFLAGS}"
1142
1143         # We just finished tests for the build machine, so rename
1144         # the file auto-build.h in the gcc directory.
1145         mv auto-host.h ../auto-build.h
1146         cd ..
1147         rm -rf $tempdir
1148         build_auto=auto-build.h
1149         FORBUILD=../${build_subdir}
1150 fi
1151 AC_SUBST(FORBUILD)
1152
1153 tm_file="${tm_file} defaults.h"
1154 tm_p_file="${tm_p_file} tm-preds.h"
1155 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1156 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1157 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1158 # put this back in temporarily.
1159 xm_file="ansidecl.h ${xm_file}"
1160
1161 # --------
1162 # UNSORTED
1163 # --------
1164
1165 # Get the version trigger filename from the toplevel
1166 if test "${with_gcc_version_trigger+set}" = set; then
1167         gcc_version_trigger=$with_gcc_version_trigger
1168 else
1169         gcc_version_trigger=${srcdir}/version.c
1170 fi
1171 changequote(,)dnl
1172 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1173 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1174
1175 # Compile in configure arguments.
1176 if test -f configargs.h ; then
1177         # Being re-configured.
1178         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1179         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1180 else
1181         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1182 fi
1183 cat > configargs.h <<EOF
1184 /* Generated automatically. */
1185 static const char configuration_arguments[] = "$gcc_config_arguments";
1186 static const char thread_model[] = "$thread_file";
1187
1188 static const struct {
1189   const char *name, *value;
1190 } configure_default_options[] = $configure_default_options;
1191 EOF
1192 changequote([,])dnl
1193
1194 # Internationalization
1195 PACKAGE=gcc
1196 VERSION="$gcc_version"
1197 AC_SUBST(PACKAGE)
1198 AC_SUBST(VERSION)
1199
1200 ZW_GNU_GETTEXT_SISTER_DIR
1201
1202 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1203 # -liconv on the link line twice.
1204 case "$LIBINTL" in *$LIBICONV*)
1205         LIBICONV= ;;
1206 esac
1207
1208 # Windows32 Registry support for specifying GCC installation paths.
1209 AC_ARG_ENABLE(win32-registry,
1210 [  --disable-win32-registry
1211                           disable lookup of installation paths in the
1212                           Registry on Windows hosts
1213   --enable-win32-registry enable registry lookup (default)
1214   --enable-win32-registry=KEY
1215                           use KEY instead of GCC version as the last portion
1216                           of the registry key],,)
1217 case $host_os in
1218         win32 | pe | cygwin* | mingw32* | uwin*)
1219 AC_MSG_CHECKING(whether windows registry support is requested)
1220 if test "x$enable_win32_registry" != xno; then
1221   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1222 [Define to 1 if installation paths should be looked up in Windows32
1223    Registry. Ignored on non windows32 hosts.])
1224   AC_MSG_RESULT(yes)
1225   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1226 else
1227   AC_MSG_RESULT(no)
1228 fi
1229
1230 # Check if user specified a different registry key.
1231 case "x${enable_win32_registry}" in
1232 x | xyes)
1233   # default.
1234   gcc_cv_win32_registry_key="$VERSION"
1235   ;;
1236 xno)
1237   # no registry lookup.
1238   gcc_cv_win32_registry_key=''
1239   ;;
1240 *)
1241   # user-specified key.
1242   gcc_cv_win32_registry_key="$enable_win32_registry"
1243   ;;
1244 esac
1245
1246 if test "x$enable_win32_registry" != xno; then
1247   AC_MSG_CHECKING(registry key on windows hosts)
1248   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1249         [Define to be the last portion of registry key on windows hosts.])
1250   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1251 fi
1252 ;;
1253 esac
1254
1255 # Get an absolute path to the GCC top-level source directory
1256 holddir=`${PWDCMD-pwd}`
1257 cd $srcdir
1258 topdir=`${PWDCMD-pwd}`
1259 cd $holddir
1260
1261 # Conditionalize the makefile for this host machine.
1262 xmake_file=
1263 for f in ${host_xmake_file}
1264 do
1265         if test -f ${srcdir}/config/$f
1266         then
1267                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1268         fi
1269 done
1270
1271 # Conditionalize the makefile for this target machine.
1272 tmake_file_=
1273 for f in ${tmake_file}
1274 do
1275         if test -f ${srcdir}/config/$f
1276         then
1277                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1278         fi
1279 done
1280 tmake_file="${tmake_file_}"
1281
1282 symbolic_link='ln -s'
1283
1284 # If the host doesn't support symlinks, modify CC in
1285 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1286 # Otherwise, we can use "CC=$(CC)".
1287 rm -f symtest.tem
1288 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1289 then
1290         cc_set_by_configure="\$(CC)"
1291         quoted_cc_set_by_configure="\$(CC)"
1292         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1293         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1294 else
1295         rm -f symtest.tem
1296         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1297         then
1298                 symbolic_link="cp -p"
1299         else
1300                 symbolic_link="cp"
1301         fi
1302         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1303         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1304         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1305         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1306 fi
1307 rm -f symtest.tem
1308
1309 out_object_file=`basename $out_file .c`.o
1310
1311 tm_file_list=
1312 tm_include_list=
1313 for f in $tm_file; do
1314   case $f in
1315     defaults.h )
1316        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1317        tm_include_list="${tm_include_list} $f"
1318        ;;
1319     * )
1320        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1321        tm_include_list="${tm_include_list} config/$f"
1322        ;;
1323   esac
1324 done
1325
1326 tm_p_file_list=
1327 tm_p_include_list=
1328 for f in $tm_p_file; do
1329   case $f in
1330     tm-preds.h )
1331        tm_p_file_list="${tm_p_file_list} $f"
1332        tm_p_include_list="${tm_p_include_list} $f"
1333        ;;
1334     * )
1335        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1336        tm_p_include_list="${tm_p_include_list} config/$f"
1337   esac
1338 done
1339
1340 xm_file_list=
1341 xm_include_list=
1342 for f in $xm_file; do
1343   case $f in
1344     ansidecl.h )
1345        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1346        xm_include_list="${xm_include_list} $f"
1347        ;;
1348     auto-host.h )
1349        xm_file_list="${xm_file_list} $f"
1350        xm_include_list="${xm_include_list} $f"
1351        ;;
1352     * )
1353        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1354        xm_include_list="${xm_include_list} config/$f"
1355        ;;
1356   esac
1357 done
1358
1359 host_xm_file_list=
1360 host_xm_include_list=
1361 for f in $host_xm_file; do
1362   case $f in
1363     ansidecl.h )
1364        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1365        host_xm_include_list="${host_xm_include_list} $f"
1366        ;;
1367     auto-host.h )
1368        host_xm_file_list="${host_xm_file_list} $f"
1369        host_xm_include_list="${host_xm_include_list} $f"
1370        ;;
1371     * )
1372        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1373        host_xm_include_list="${host_xm_include_list} config/$f"
1374        ;;
1375   esac
1376 done
1377
1378 build_xm_file_list=
1379 for f in $build_xm_file; do
1380   case $f in
1381     ansidecl.h )
1382        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1383        build_xm_include_list="${build_xm_include_list} $f"
1384        ;;
1385     auto-build.h | auto-host.h )
1386        build_xm_file_list="${build_xm_file_list} $f"
1387        build_xm_include_list="${build_xm_include_list} $f"
1388        ;;
1389     * )
1390        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1391        build_xm_include_list="${build_xm_include_list} config/$f"
1392        ;;
1393   esac
1394 done
1395
1396 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1397 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1398 CROSS=                                          AC_SUBST(CROSS)
1399 ALL=all.internal                                AC_SUBST(ALL)
1400 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1401 if test x$host != x$target
1402 then
1403         CROSS="-DCROSS_COMPILE"
1404         ALL=all.cross
1405         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1406         case "$host","$target" in
1407         # Darwin crosses can use the host system's libraries and headers,
1408         # because of the fat library support.  Of course, it must be the
1409         # same version of Darwin on both sides.  Allow the user to
1410         # just say --target=foo-darwin without a version number to mean
1411         # "the version on this system".
1412             *-*-darwin*,*-*-darwin*)
1413                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1414                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1415                 if test $hostos = $targetos -o $targetos = darwin ; then
1416                     CROSS=
1417                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1418                     with_headers=yes
1419                 fi
1420                 ;;
1421
1422             i?86-*-*,x86_64-*-* \
1423             | powerpc*-*-*,powerpc64*-*-*)
1424                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1425         esac
1426 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1427         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1428         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1429 fi
1430
1431 # If this is a cross-compiler that does not
1432 # have its own set of headers then define
1433 # inhibit_libc
1434
1435 # If this is using newlib, without having the headers available now,
1436 # then define inhibit_libc in LIBGCC2_CFLAGS.
1437 # This prevents libgcc2 from containing any code which requires libc
1438 # support.
1439 inhibit_libc=
1440 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1441        test x$with_newlib = xyes ; } &&
1442      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1443        inhibit_libc=-Dinhibit_libc
1444 fi
1445 AC_SUBST(inhibit_libc)
1446
1447 # When building gcc with a cross-compiler, we need to adjust things so
1448 # that the generator programs are still built with the native compiler.
1449 # Also, we cannot run fixincludes or fix-header.
1450
1451 # These are the normal (build=host) settings:
1452 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1453 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1454 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1455 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1456
1457 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1458 STMP_FIXPROTO=stmp-fixproto     AC_SUBST(STMP_FIXPROTO)
1459
1460 # And these apply if build != host, or we are generating coverage data
1461 if test x$build != x$host || test "x$coverage_flags" != x
1462 then
1463     BUILD_PREFIX=build-
1464     BUILD_PREFIX_1=build-
1465     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1466
1467     if test "x$TARGET_SYSTEM_ROOT" = x; then
1468         STMP_FIXINC=
1469         STMP_FIXPROTO=
1470     fi
1471 fi
1472
1473 # Expand extra_headers to include complete path.
1474 # This substitutes for lots of t-* files.
1475 extra_headers_list=
1476 if test "x$extra_headers" = x
1477 then true
1478 else
1479         # Prepend ${srcdir}/config/${cpu_type}/ to every entry in extra_headers.
1480         for file in $extra_headers;
1481         do
1482                 extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1483         done
1484 fi
1485
1486 # Add a definition of USE_COLLECT2 if system wants one.
1487 case $use_collect2 in
1488   no) use_collect2= ;;
1489   "") ;;
1490   *)
1491     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1492     xm_defines="${xm_defines} USE_COLLECT2"
1493     ;;
1494 esac
1495
1496 # Identify the assembler which will work hand-in-glove with the newly
1497 # built GCC, so that we can examine its features.  This is the assembler
1498 # which will be driven by the driver program.
1499 #
1500 # If build != host, and we aren't building gas in-tree, we identify a
1501 # build->target assembler and hope that it will have the same features
1502 # as the host->target assembler we'll be using.
1503 AC_MSG_CHECKING(what assembler to use)
1504 in_tree_gas=no
1505 gcc_cv_as=
1506 gcc_cv_gas_major_version=
1507 gcc_cv_gas_minor_version=
1508 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1509 if test -x "$DEFAULT_ASSEMBLER"; then
1510         gcc_cv_as="$DEFAULT_ASSEMBLER"
1511 elif test -x "$AS"; then
1512         gcc_cv_as="$AS"
1513 elif test -x as$host_exeext; then
1514         # Build using assembler in the current directory.
1515         gcc_cv_as=./as$host_exeext
1516 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1517      && test -f ../gas/Makefile; then
1518   # Single tree build which includes gas.
1519   in_tree_gas=yes
1520   _gcc_COMPUTE_GAS_VERSION
1521   rm -f as$host_exeext
1522   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1523   in_tree_gas_is_elf=no
1524   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1525      || (grep 'obj_format = multi' ../gas/Makefile \
1526          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1527   then
1528     in_tree_gas_is_elf=yes
1529   fi
1530 fi
1531
1532 if test "x$gcc_cv_as" = x; then
1533         # Search the same directories that the installed compiler will
1534         # search.  Else we may find the wrong assembler and lose.  If we
1535         # do not find a suitable assembler binary, then try the user's
1536         # path.
1537         #
1538         # Also note we have to check MD_EXEC_PREFIX before checking the
1539         # user's path.  Unfortunately, there is no good way to get at the
1540         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1541         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1542         # to be fixed as part of the make/configure rewrite too.
1543
1544         if test "x$exec_prefix" = xNONE; then
1545                 if test "x$prefix" = xNONE; then
1546                         test_prefix=/usr/local
1547                 else
1548                         test_prefix=$prefix
1549                 fi
1550         else
1551                 test_prefix=$exec_prefix
1552         fi
1553
1554         # If the loop below does not find an assembler, then use whatever
1555         # one we can find in the users's path.
1556         # user's path.
1557         if test "x$program_prefix" != xNONE; then
1558                 gcc_cv_as=${program_prefix}as$host_exeext
1559         else
1560                 gcc_cv_as=`echo as | sed ${program_transform_name}`$host_exeext
1561         fi
1562
1563         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1564                    $test_prefix/lib/gcc-lib/$target_alias \
1565                    /usr/lib/gcc/$target_alias/$gcc_version \
1566                    /usr/lib/gcc/$target_alias \
1567                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1568                    $test_prefix/$target_alias/bin"
1569
1570         if test x$host = x$target; then
1571             test_dirs="$test_dirs \
1572                    /usr/libexec \
1573                    /usr/ccs/gcc \
1574                    /usr/ccs/bin \
1575                    /udk/usr/ccs/bin \
1576                    /bsd43/usr/lib/cmplrs/cc \
1577                    /usr/cross64/usr/bin \
1578                    /usr/lib/cmplrs/cc \
1579                    /sysv/usr/lib/cmplrs/cc \
1580                    /svr4/usr/lib/cmplrs/cc \
1581                    /usr/bin"
1582         fi
1583
1584         for dir in $test_dirs; do
1585                 if test -x $dir/as$host_exeext; then
1586                         gcc_cv_as=$dir/as$host_exeext
1587                         break;
1588                 fi
1589         done
1590 fi
1591 case $in_tree_gas in
1592   yes)
1593     AC_MSG_RESULT("newly built gas")
1594     ;;
1595   no)
1596     AC_MSG_RESULT($gcc_cv_as)
1597     ;;
1598 esac
1599
1600 # Identify the linker which will work hand-in-glove with the newly
1601 # built GCC, so that we can examine its features.  This is the linker
1602 # which will be driven by the driver program.
1603 #
1604 # If build != host, and we aren't building gas in-tree, we identify a
1605 # build->target linker and hope that it will have the same features
1606 # as the host->target linker we'll be using.
1607 AC_MSG_CHECKING(what linker to use)
1608 in_tree_ld=no
1609 gcc_cv_ld=
1610 gcc_cv_gld_major_version=
1611 gcc_cv_gld_minor_version=
1612 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1613 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1614 if test -x "$DEFAULT_LINKER"; then
1615         gcc_cv_ld="$DEFAULT_LINKER"
1616 elif test -x "$LD"; then
1617         gcc_cv_ld="$LD"
1618 elif test -x collect-ld$host_exeext; then
1619         # Build using linker in the current directory.
1620         gcc_cv_ld=./collect-ld$host_exeext
1621 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1622      && test -f ../ld/Makefile; then
1623         # Single tree build which includes ld.
1624         in_tree_ld=yes
1625         in_tree_ld_is_elf=no
1626         if (grep 'EMUL = .*elf' ../ld/Makefile \
1627             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1628           in_tree_ld_is_elf=yes
1629         fi
1630         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1631         do
1632 changequote(,)dnl
1633                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1634 changequote([,])dnl
1635                 if test x$gcc_cv_gld_version != x; then
1636                         break
1637                 fi
1638         done
1639 changequote(,)dnl
1640         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1641         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1642 changequote([,])dnl
1643         rm -f collect-ld$host_exeext
1644         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1645                 2>/dev/null
1646 fi
1647
1648 if test "x$gcc_cv_ld" = x; then
1649         # Search the same directories that the installed compiler will
1650         # search.  Else we may find the wrong linker and lose.  If we
1651         # do not find a suitable linker binary, then try the user's
1652         # path.
1653         #
1654         # Also note we have to check MD_EXEC_PREFIX before checking the
1655         # user's path.  Unfortunately, there is no good way to get at the
1656         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1657         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1658         # to be fixed as part of the make/configure rewrite too.
1659
1660         if test "x$exec_prefix" = xNONE; then
1661                 if test "x$prefix" = xNONE; then
1662                         test_prefix=/usr/local
1663                 else
1664                         test_prefix=$prefix
1665                 fi
1666         else
1667                 test_prefix=$exec_prefix
1668         fi
1669
1670         # If the loop below does not find an linker, then use whatever
1671         # one we can find in the users's path.
1672         # user's path.
1673         if test "x$program_prefix" != xNONE; then
1674                 gcc_cv_ld=${program_prefix}ld$host_exeext
1675         else
1676                 gcc_cv_ld=`echo ld | sed ${program_transform_name}`$host_exeext
1677         fi
1678
1679         test_dirs="$test_prefix/lib/gcc-lib/$target_alias/$gcc_version \
1680                    $test_prefix/lib/gcc-lib/$target_alias \
1681                    /usr/lib/gcc/$target_alias/$gcc_version \
1682                    /usr/lib/gcc/$target_alias \
1683                    $test_prefix/$target_alias/bin/$target_alias/$gcc_version \
1684                    $test_prefix/$target_alias/bin"
1685
1686         if test x$host = x$target; then
1687             test_dirs="$test_dirs \
1688                    /usr/libexec \
1689                    /usr/ccs/gcc \
1690                    /usr/ccs/bin \
1691                    /udk/usr/ccs/bin \
1692                    /bsd43/usr/lib/cmplrs/cc \
1693                    /usr/cross64/usr/bin \
1694                    /usr/lib/cmplrs/cc \
1695                    /sysv/usr/lib/cmplrs/cc \
1696                    /svr4/usr/lib/cmplrs/cc \
1697                    /usr/bin"
1698         fi
1699
1700         for dir in $test_dirs; do
1701                 if test -x $dir/ld$host_exeext; then
1702                         gcc_cv_ld=$dir/ld$host_exeext
1703                         break;
1704                 fi
1705         done
1706 fi
1707 case $in_tree_ld in
1708   yes)
1709     AC_MSG_RESULT("newly built ld")
1710     ;;
1711   no)
1712     AC_MSG_RESULT($gcc_cv_ld)
1713     ;;
1714 esac
1715
1716 # Figure out what nm we will be using.
1717 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1718 AC_MSG_CHECKING(what nm to use)
1719 in_tree_nm=no
1720 if test -x nm$host_exeext; then
1721         gcc_cv_nm=./nm$host_exeext
1722 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1723      && test -f ../binutils/Makefile; then
1724         # Single tree build which includes binutils.
1725         in_tree_nm=yes
1726         gcc_cv_nm=./nm$host_exeext
1727         rm -f nm$host_exeext
1728         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1729 elif test "x$program_prefix" != xNONE; then
1730         gcc_cv_nm=${program_prefix}nm$host_exeext
1731 else
1732         gcc_cv_nm=`echo nm | sed ${program_transform_name}`$host_exeext
1733 fi
1734 case $in_tree_nm in
1735   yes) AC_MSG_RESULT("newly built nm") ;;
1736   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1737 esac
1738
1739 # Figure out what objdump we will be using.
1740 AC_MSG_CHECKING(what objdump to use)
1741 in_tree_objdump=no
1742 if test -x objdump$host_exeext; then
1743         gcc_cv_objdump=./objdump$host_exeext
1744 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1745      && test -f ../binutils/Makefile; then
1746         # Single tree build which includes binutils.
1747         in_tree_objdump=yes
1748         gcc_cv_objdump=./objdump$host_exeext
1749         rm -f objdump$host_exeext
1750         $symbolic_link ../binutils/objdump$host_exeext \
1751                 objdump$host_exeext 2>/dev/null
1752 elif test "x$program_prefix" != xNONE; then
1753         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1754 else
1755         gcc_cv_objdump=`echo objdump | \
1756                 sed ${program_transform_name}`$host_exeext
1757 fi
1758 case $in_tree_objdump in
1759   yes) AC_MSG_RESULT("newly built objdump") ;;
1760   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1761 esac
1762
1763 # Figure out what assembler alignment features are present.
1764 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1765  [2,6,0],,
1766 [.balign 4
1767 .p2align 2],,
1768 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1769   [Define if your assembler supports .balign and .p2align.])])
1770
1771 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1772  [2,8,0],,
1773  [.p2align 4,,7],,
1774 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1775   [Define if your assembler supports specifying the maximum number
1776    of bytes to skip when using the GAS .p2align command.])])
1777
1778 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1779  [elf,2,9,0],,
1780  [conftest_label1: .word 0
1781 .subsection -1
1782 conftest_label2: .word 0
1783 .previous],
1784  [if test x$gcc_cv_nm != x; then
1785     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1786     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1787     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1788     then :
1789     else gcc_cv_as_subsection_m1=yes
1790     fi
1791     rm -f conftest.nm1 conftest.nm2
1792   fi],
1793  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1794   [Define if your assembler supports .subsection and .subsection -1 starts
1795    emitting at the beginning of your section.])])
1796
1797 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1798  [2,2,0],,
1799  [      .weak foobar],,
1800 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1801
1802 # .hidden needs to be supported in both the assembler and the linker,
1803 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1804 # This is irritatingly difficult to feature test for; we have to check the
1805 # date string after the version number.  If we've got an in-tree
1806 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1807 # to be safe.
1808 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1809 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1810  [elf,2,13,0],,
1811 [       .hidden foobar
1812 foobar:])
1813
1814 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1815 [if test $in_tree_ld = yes ; then
1816   gcc_cv_ld_hidden=no
1817   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1818      && test $in_tree_ld_is_elf = yes; then
1819      gcc_cv_ld_hidden=yes
1820   fi
1821 else
1822   gcc_cv_ld_hidden=yes
1823   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1824   if echo "$ld_ver" | grep GNU > /dev/null; then
1825 changequote(,)dnl
1826     ld_vers=`echo $ld_ver | sed -n \
1827         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1828         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1829         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1830         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1831         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1832         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1833     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1834     if test 0"$ld_date" -lt 20020404; then
1835       if test -n "$ld_date"; then
1836         # If there was date string, but was earlier than 2002-04-04, fail
1837         gcc_cv_ld_hidden=no
1838       elif test -z "$ld_vers"; then
1839         # If there was no date string nor ld version number, something is wrong
1840         gcc_cv_ld_hidden=no
1841       else
1842         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1843         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1844         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1845         test -z "$ld_vers_patch" && ld_vers_patch=0
1846         if test "$ld_vers_major" -lt 2; then
1847           gcc_cv_ld_hidden=no
1848         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1849           gcc_cv_ld_hidden="no"
1850         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1851           gcc_cv_ld_hidden=no
1852         fi
1853       fi
1854 changequote([,])dnl
1855     fi
1856   else
1857     # non-GNU linkers don't seem to support .hidden yet
1858     if test x"$gnu_ld_flag" = x"no"; then
1859       gcc_cv_ld_hidden=no
1860     fi
1861   fi
1862 fi])
1863 libgcc_visibility=no
1864 AC_SUBST(libgcc_visibility)
1865 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1866   libgcc_visibility=yes
1867   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1868   [Define if your assembler and linker support .hidden.])
1869 fi
1870
1871 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1872 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1873   [elf,2,11,0],,
1874 [       .data
1875         .uleb128 L2 - L1
1876 L1:
1877         .uleb128 1280
1878         .sleb128 -1010
1879 L2:],
1880  [# GAS versions before 2.11 do not support uleb128,
1881   # despite appearing to.
1882   # ??? There exists an elf-specific test that will crash
1883   # the assembler.  Perhaps it's better to figure out whether
1884   # arbitrary sections are supported and try the test.
1885   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1886   if echo "$as_ver" | grep GNU > /dev/null; then
1887 changequote(,)dnl
1888     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1889     as_major=`echo $as_ver | sed 's/\..*//'`
1890     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1891 changequote([,])dnl
1892     if test $as_major -eq 2 && test $as_minor -lt 11
1893     then :
1894     else gcc_cv_as_leb128=yes
1895     fi
1896   fi],
1897   [AC_DEFINE(HAVE_AS_LEB128, 1,
1898     [Define if your assembler supports .sleb128 and .uleb128.])])
1899
1900 # GAS versions up to and including 2.11.0 may mis-optimize
1901 # .eh_frame data.
1902 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1903   [elf,2,12,0],,
1904 [       .text
1905 .LFB1:
1906         .4byte  0
1907 .L1:
1908         .4byte  0
1909 .LFE1:
1910         .section        .eh_frame,"aw",@progbits
1911 __FRAME_BEGIN__:
1912         .4byte  .LECIE1-.LSCIE1
1913 .LSCIE1:
1914         .4byte  0x0
1915         .byte   0x1
1916         .ascii "z\0"
1917         .byte   0x1
1918         .byte   0x78
1919         .byte   0x1a
1920         .byte   0x0
1921         .byte   0x4
1922         .4byte  1
1923         .p2align 1
1924 .LECIE1:
1925 .LSFDE1:
1926         .4byte  .LEFDE1-.LASFDE1
1927 .LASFDE1:
1928         .4byte  .LASFDE1-__FRAME_BEGIN__
1929         .4byte  .LFB1
1930         .4byte  .LFE1-.LFB1
1931         .byte   0x4
1932         .4byte  .LFE1-.LFB1
1933         .byte   0x4
1934         .4byte  .L1-.LFB1
1935 .LEFDE1:],
1936 [  cat > conftest.lit <<EOF
1937  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1938  0010 01000000 12000000 18000000 00000000  ................
1939  0020 08000000 04080000 0044               .........D
1940 EOF
1941   cat > conftest.big <<EOF
1942  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1943  0010 00000001 00000012 00000018 00000000  ................
1944  0020 00000008 04000000 0844               .........D
1945 EOF
1946   # If the assembler didn't choke, and we can objdump,
1947   # and we got the correct data, then succeed.
1948   if test x$gcc_cv_objdump != x \
1949   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1950      | tail -3 > conftest.got \
1951   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1952     || cmp conftest.big conftest.got > /dev/null 2>&1; }
1953   then
1954     gcc_cv_as_eh_frame=yes
1955   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
1956     gcc_cv_as_eh_frame=buggy
1957   else
1958     # Uh oh, what do we do now?
1959     gcc_cv_as_eh_frame=no
1960   fi])
1961
1962 if test $gcc_cv_as_eh_frame = buggy; then
1963   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1964   [Define if your assembler mis-optimizes .eh_frame data.])
1965 fi
1966
1967 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
1968  [elf,2,12,0], [--fatal-warnings],
1969  [.section .rodata.str, "aMS", @progbits, 1],,
1970  [AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1971 [Define if your assembler supports marking sections with SHF_MERGE flag.])])
1972
1973 # Thread-local storage - the check is heavily parametrized.
1974 conftest_s=
1975 tls_first_major=
1976 tls_first_minor=
1977 tls_as_opt=
1978 case "$target" in
1979 changequote(,)dnl
1980   alpha*-*-*)
1981     conftest_s='
1982         .section ".tdata","awT",@progbits
1983 foo:    .long   25
1984         .text
1985         ldq     $27,__tls_get_addr($29)         !literal!1
1986         lda     $16,foo($29)                    !tlsgd!1
1987         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
1988         ldq     $27,__tls_get_addr($29)         !literal!2
1989         lda     $16,foo($29)                    !tlsldm!2
1990         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
1991         ldq     $1,foo($29)                     !gotdtprel
1992         ldah    $2,foo($29)                     !dtprelhi
1993         lda     $3,foo($2)                      !dtprello
1994         lda     $4,foo($29)                     !dtprel
1995         ldq     $1,foo($29)                     !gottprel
1996         ldah    $2,foo($29)                     !tprelhi
1997         lda     $3,foo($2)                      !tprello
1998         lda     $4,foo($29)                     !tprel'
1999         tls_first_major=2
2000         tls_first_minor=13
2001         ;;
2002   i[34567]86-*-*)
2003     conftest_s='
2004         .section ".tdata","awT",@progbits
2005 foo:    .long   25
2006         .text
2007         movl    %gs:0, %eax
2008         leal    foo@TLSGD(,%ebx,1), %eax
2009         leal    foo@TLSLDM(%ebx), %eax
2010         leal    foo@DTPOFF(%eax), %edx
2011         movl    foo@GOTTPOFF(%ebx), %eax
2012         subl    foo@GOTTPOFF(%ebx), %eax
2013         addl    foo@GOTNTPOFF(%ebx), %eax
2014         movl    foo@INDNTPOFF, %eax
2015         movl    $foo@TPOFF, %eax
2016         subl    $foo@TPOFF, %eax
2017         leal    foo@NTPOFF(%ecx), %eax'
2018         tls_first_major=2
2019         tls_first_minor=14
2020         ;;
2021   x86_64-*-*)
2022     conftest_s='
2023         .section ".tdata","awT",@progbits
2024 foo:    .long   25
2025         .text
2026         movq    %fs:0, %rax
2027         leaq    foo@TLSGD(%rip), %rdi
2028         leaq    foo@TLSLD(%rip), %rdi
2029         leaq    foo@DTPOFF(%rax), %rdx
2030         movq    foo@GOTTPOFF(%rip), %rax
2031         movq    $foo@TPOFF, %rax'
2032         tls_first_major=2
2033         tls_first_minor=14
2034         ;;
2035   ia64-*-*)
2036     conftest_s='
2037         .section ".tdata","awT",@progbits
2038 foo:    data8   25
2039         .text
2040         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2041         addl    r17 = @ltoff(@dtprel(foo#)), gp
2042         addl    r18 = @ltoff(@tprel(foo#)), gp
2043         addl    r19 = @dtprel(foo#), gp
2044         adds    r21 = @dtprel(foo#), r13
2045         movl    r23 = @dtprel(foo#)
2046         addl    r20 = @tprel(foo#), gp
2047         adds    r22 = @tprel(foo#), r13
2048         movl    r24 = @tprel(foo#)'
2049         tls_first_major=2
2050         tls_first_minor=13
2051         ;;
2052   powerpc-*-*)
2053     conftest_s='
2054         .section ".tdata","awT",@progbits
2055         .align 2
2056 ld0:    .space 4
2057 ld1:    .space 4
2058 x1:     .space 4
2059 x2:     .space 4
2060 x3:     .space 4
2061         .text
2062         addi 3,31,ld0@got@tlsgd
2063         bl __tls_get_addr
2064         addi 3,31,x1@got@tlsld
2065         bl __tls_get_addr
2066         addi 9,3,x1@dtprel
2067         addis 9,3,x2@dtprel@ha
2068         addi 9,9,x2@dtprel@l
2069         lwz 9,x3@got@tprel(31)
2070         add 9,9,x@tls
2071         addi 9,2,x1@tprel
2072         addis 9,2,x2@tprel@ha
2073         addi 9,9,x2@tprel@l'
2074         tls_first_major=2
2075         tls_first_minor=14
2076         tls_as_opt=-a32
2077         ;;
2078   powerpc64-*-*)
2079     conftest_s='
2080         .section ".tdata","awT",@progbits
2081         .align 3
2082 ld0:    .space 8
2083 ld1:    .space 8
2084 x1:     .space 8
2085 x2:     .space 8
2086 x3:     .space 8
2087         .text
2088         addi 3,2,ld0@got@tlsgd
2089         bl .__tls_get_addr
2090         nop
2091         addi 3,2,ld1@toc
2092         bl .__tls_get_addr
2093         nop
2094         addi 3,2,x1@got@tlsld
2095         bl .__tls_get_addr
2096         nop
2097         addi 9,3,x1@dtprel
2098         bl .__tls_get_addr
2099         nop
2100         addis 9,3,x2@dtprel@ha
2101         addi 9,9,x2@dtprel@l
2102         bl .__tls_get_addr
2103         nop
2104         ld 9,x3@got@dtprel(2)
2105         add 9,9,3
2106         bl .__tls_get_addr
2107         nop'
2108         tls_first_major=2
2109         tls_first_minor=14
2110         tls_as_opt=-a64
2111         ;;
2112   s390-*-*)
2113     conftest_s='
2114         .section ".tdata","awT",@progbits
2115 foo:    .long   25
2116         .text
2117         .long   foo@TLSGD
2118         .long   foo@TLSLDM
2119         .long   foo@DTPOFF
2120         .long   foo@NTPOFF
2121         .long   foo@GOTNTPOFF
2122         .long   foo@INDNTPOFF
2123         l       %r1,foo@GOTNTPOFF(%r12)
2124         l       %r1,0(%r1):tls_load:foo
2125         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2126         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2127         tls_first_major=2
2128         tls_first_minor=14
2129         tls_as_opt=-m31
2130         ;;
2131   s390x-*-*)
2132     conftest_s='
2133         .section ".tdata","awT",@progbits
2134 foo:    .long   25
2135         .text
2136         .quad   foo@TLSGD
2137         .quad   foo@TLSLDM
2138         .quad   foo@DTPOFF
2139         .quad   foo@NTPOFF
2140         .quad   foo@GOTNTPOFF
2141         lg      %r1,foo@GOTNTPOFF(%r12)
2142         larl    %r1,foo@INDNTPOFF
2143         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2144         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2145         tls_first_major=2
2146         tls_first_minor=14
2147         tls_as_opt="-m64 -Aesame"
2148         ;;
2149   sparc*-*-*)
2150     conftest_s='
2151         .section ".tdata","awT",@progbits
2152 foo:    .long   25
2153         .text
2154         sethi   %tgd_hi22(foo), %o0
2155         add     %o0, %tgd_lo10(foo), %o1
2156         add     %l7, %o1, %o0, %tgd_add(foo)
2157         call    __tls_get_addr, %tgd_call(foo)
2158         sethi   %tldm_hi22(foo), %l1
2159         add     %l1, %tldm_lo10(foo), %l2
2160         add     %l7, %l2, %o0, %tldm_add(foo)
2161         call    __tls_get_addr, %tldm_call(foo)
2162         sethi   %tldo_hix22(foo), %l3
2163         xor     %l3, %tldo_lox10(foo), %l4
2164         add     %o0, %l4, %l5, %tldo_add(foo)
2165         sethi   %tie_hi22(foo), %o3
2166         add     %o3, %tie_lo10(foo), %o3
2167         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2168         add     %g7, %o2, %o4, %tie_add(foo)
2169         sethi   %tle_hix22(foo), %l1
2170         xor     %l1, %tle_lox10(foo), %o5
2171         ld      [%g7 + %o5], %o1'
2172         tls_first_major=2
2173         tls_first_minor=14
2174         tls_as_opt=-32
2175         ;;
2176 changequote([,])dnl
2177 esac
2178 if test -z "$tls_first_major"; then
2179   : # If we don't have a check, assume no support.
2180 else
2181   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2182   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt --fatal-warnings],
2183   [$conftest_s],,
2184   [AC_DEFINE(HAVE_AS_TLS, 1,
2185             [Define if your assembler supports thread-local storage.])])
2186 fi
2187
2188 # Target-specific assembler checks.
2189
2190 case "$target" in
2191   # All TARGET_ABI_OSF targets.
2192   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2193     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2194         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2195 [       .set nomacro
2196         .text
2197         extbl   $3, $2, $3      !lituse_bytoff!1
2198         ldq     $2, a($29)      !literal!1
2199         ldq     $4, b($29)      !literal!2
2200         ldq_u   $3, 0($2)       !lituse_base!1
2201         ldq     $27, f($29)     !literal!5
2202         jsr     $26, ($27), f   !lituse_jsr!5
2203         ldah    $29, 0($26)     !gpdisp!3
2204         lda     $0, c($29)      !gprel
2205         ldah    $1, d($29)      !gprelhigh
2206         lda     $1, d($1)       !gprellow
2207         lda     $29, 0($29)     !gpdisp!3],,
2208     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2209   [Define if your assembler supports explicit relocations.])])
2210     ;;
2211
2212   sparc*-*-*)
2213     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2214       [.register %g2, #scratch],,
2215       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2216                 [Define if your assembler supports .register.])])
2217
2218     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2219       [-relax], [.text],,
2220       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2221                 [Define if your assembler supports -relax option.])])
2222
2223     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2224       gcc_cv_as_sparc_ua_pcrel,,
2225       [-K PIC],
2226 [.text
2227 foo:
2228         nop
2229 .data
2230 .align 4
2231 .byte 0
2232 .uaword %r_disp32(foo)],
2233       [if test x$gcc_cv_ld != x \
2234        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2235          gcc_cv_as_sparc_ua_pcrel=yes
2236        fi
2237        rm -f conftest],
2238       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2239                 [Define if your assembler and linker support unaligned PC relative relocs.])
2240
2241       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2242         gcc_cv_as_sparc_ua_pcrel_hidden,,
2243         [-K PIC],
2244 [.data
2245 .align 4
2246 .byte 0x31
2247 .uaword %r_disp32(foo)
2248 .byte 0x32, 0x33, 0x34
2249 .global foo
2250 .hidden foo
2251 foo:
2252 .skip 4],
2253         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2254          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2255          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2256             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2257             if $gcc_cv_objdump -R conftest 2> /dev/null \
2258                | grep 'DISP32' > /dev/null 2>&1; then
2259                 :
2260             else
2261                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2262             fi
2263          fi
2264          rm -f conftest],
2265          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2266                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2267     ]) # unaligned pcrel relocs
2268
2269     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2270       gcc_cv_as_sparc_offsetable_lo10,,
2271       [-xarch=v9],
2272 [.text
2273         or %g1, %lo(ab) + 12, %g1
2274         or %g1, %lo(ab + 12), %g1],
2275       [if test x$gcc_cv_objdump != x \
2276        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2277           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2278          gcc_cv_as_offsetable_lo10=yes
2279        fi],
2280        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2281                  [Define if your assembler supports offsetable %lo().])])
2282     ;;
2283
2284 changequote(,)dnl
2285   i[34567]86-*-* | x86_64-*-*)
2286 changequote([,])dnl
2287     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2288        gcc_cv_as_ix86_filds_fists,
2289       [2,9,0],, [filds mem; fists mem],,
2290       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2291         [Define if your assembler uses the new HImode fild and fist notation.])])
2292
2293     gcc_GAS_CHECK_FEATURE([cmov syntax],
2294       gcc_cv_as_ix86_cmov_sun_syntax,,,
2295       [cmovl.l %edx, %eax],,
2296       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2297         [Define if your assembler supports the Sun syntax for cmov.])])
2298
2299     # This one is used unconditionally by i386.[ch]; it is to be defined
2300     # to 1 if the feature is present, 0 otherwise.
2301     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2302         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2303 [       .text
2304 .L0:
2305         nop
2306         .data
2307         .long .L0@GOTOFF])
2308     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2309       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2310       [Define true if the assembler supports '.long foo@GOTOFF'.])
2311     ;;
2312
2313   ia64*-*-*)
2314     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2315         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2316 [       .text
2317         addl r15 = @ltoffx(x#), gp
2318         ;;
2319         ld8.mov r16 = [[r15]], x#],,
2320     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2321           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2322
2323     ;;
2324
2325   powerpc*-*-*)
2326     case $target in
2327       *-*-aix) conftest_s='     .csect .text[PR]';;
2328       *)       conftest_s='     .text';;
2329     esac
2330     conftest_s="$conftest_s
2331         mfcr 3,128"
2332
2333     gcc_GAS_CHECK_FEATURE([mfcr field support],
2334       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2335       [$conftest_s],,
2336       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2337           [Define if your assembler supports mfcr field.])])
2338     ;;
2339
2340   mips*-*-*)
2341     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2342       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2343 [       lw $4,%gp_rel(foo)($4)],,
2344       [if test x$target_cpu_default = x
2345        then target_cpu_default=MASK_EXPLICIT_RELOCS
2346        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2347        fi])
2348
2349     ;;
2350 esac
2351 # ??? Not all targets support dwarf2 debug_line, even within a version
2352 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2353 # info to the output file.  So, as supported targets are added to gas 2.11,
2354 # add some instruction here to (also) show we expect this might work.
2355 # ??? Once 2.11 is released, probably need to add first known working
2356 # version to the per-target configury.
2357 case "$target" in
2358   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2359   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2360   | xstormy16*-*-* | cris-*-*)
2361     insn="nop"
2362     ;;
2363   ia64*-*-*)
2364     insn="nop 0"
2365     ;;
2366   mmix-*-*)
2367     insn="swym 0"
2368     ;;
2369 esac
2370 if test x"$insn" != x; then
2371  conftest_s="\
2372         .file 1 \"conftest.s\"
2373         .loc 1 3 0
2374         $insn"
2375  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2376   gcc_cv_as_dwarf2_debug_line,
2377   [elf,2,11,0],, [$conftest_s],
2378   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2379    if grep debug_line conftest.o > /dev/null 2>&1; then
2380      gcc_cv_as_dwarf2_debug_line=yes
2381    fi])
2382
2383 # The .debug_line file table must be in the exact order that
2384 # we specified the files, since these indices are also used
2385 # by DW_AT_decl_file.  Approximate this test by testing if
2386 # the assembler bitches if the same index is assigned twice.
2387  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2388   gcc_cv_as_dwarf2_file_buggy,,,
2389 [       .file 1 "foo.s"
2390         .file 1 "bar.s"])
2391
2392  if test $gcc_cv_as_dwarf2_debug_line = yes \
2393  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2394         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2395   [Define if your assembler supports dwarf2 .file/.loc directives,
2396    and preserves file table indices exactly as given.])
2397  fi
2398
2399  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2400   gcc_cv_as_gdwarf2_flag,
2401   [elf,2,11,0], [--gdwarf2], [$insn],,
2402   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2403 [Define if your assembler supports the --gdwarf2 option.])])
2404
2405  gcc_GAS_CHECK_FEATURE([--gstabs option],
2406   gcc_cv_as_gstabs_flag,
2407   [elf,2,11,0], [--gstabs], [$insn],
2408   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2409    # and warns about it, but still exits successfully.  So check for
2410    # this.
2411    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2412    then :
2413    else gcc_cv_as_gstabs_flag=yes
2414    fi],
2415   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2416 [Define if your assembler supports the --gstabs option.])])
2417 fi
2418
2419 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2420 gcc_cv_ld_ro_rw_mix=unknown
2421 if test $in_tree_ld = yes ; then
2422   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2423      && test $in_tree_ld_is_elf = yes; then
2424     gcc_cv_ld_ro_rw_mix=read-write
2425   fi
2426 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2427   echo '.section myfoosect, "a"' > conftest1.s
2428   echo '.section myfoosect, "aw"' > conftest2.s
2429   echo '.byte 1' >> conftest2.s
2430   echo '.section myfoosect, "a"' > conftest3.s
2431   echo '.byte 0' >> conftest3.s
2432   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2433      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2434      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2435      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2436         conftest2.o conftest3.o > /dev/null 2>&1; then
2437     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2438                          | sed -e '/myfoosect/!d' -e N`
2439     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2440       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2441         gcc_cv_ld_ro_rw_mix=read-only
2442       else
2443         gcc_cv_ld_ro_rw_mix=read-write
2444       fi
2445     fi
2446   fi
2447 changequote(,)dnl
2448   rm -f conftest.* conftest[123].*
2449 changequote([,])dnl
2450 fi
2451 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2452         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2453   [Define if your linker links a mix of read-only
2454    and read-write sections into a read-write section.])
2455 fi
2456 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2457
2458 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2459 gcc_cv_ld_eh_frame_hdr=no
2460 if test $in_tree_ld = yes ; then
2461   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2462      && test $in_tree_ld_is_elf = yes; then
2463     gcc_cv_ld_eh_frame_hdr=yes
2464   fi
2465 elif test x$gcc_cv_ld != x; then
2466         # Check if linker supports --eh-frame-hdr option
2467         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2468                 gcc_cv_ld_eh_frame_hdr=yes
2469         fi
2470 fi
2471 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2472         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2473 [Define if your linker supports --eh-frame-hdr option.])
2474 fi
2475 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2476
2477 AC_MSG_CHECKING(linker position independent executable support)
2478 gcc_cv_ld_pie=no
2479 if test $in_tree_ld = yes ; then
2480   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2481      && test $in_tree_ld_is_elf = yes; then
2482     gcc_cv_ld_pie=yes
2483   fi
2484 elif test x$gcc_cv_ld != x; then
2485         # Check if linker supports -pie option
2486         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2487                 gcc_cv_ld_pie=yes
2488         fi
2489 fi
2490 if test x"$gcc_cv_ld_pie" = xyes; then
2491         AC_DEFINE(HAVE_LD_PIE, 1,
2492 [Define if your linker supports -pie option.])
2493 fi
2494 AC_MSG_RESULT($gcc_cv_ld_pie)
2495
2496 # Miscellaneous target-specific checks.
2497 case "$target" in
2498   mips*-*-*)
2499     AC_MSG_CHECKING(whether libgloss uses STARTUP directives consistently)
2500     gcc_cv_mips_libgloss_startup=no
2501     gcc_cv_libgloss_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/libgloss
2502     if test "x$exec_prefix" = xNONE; then
2503       if test "x$prefix" = xNONE; then
2504         test_prefix=/usr/local
2505       else
2506         test_prefix=$prefix
2507       fi
2508     else
2509       test_prefix=$exec_prefix
2510     fi
2511     for f in $gcc_cv_libgloss_srcdir/mips/idt.ld $test_prefix/$target_alias/lib/idt.ld
2512     do
2513       if grep '^STARTUP' $f > /dev/null 2>&1; then
2514         gcc_cv_mips_libgloss_startup=yes
2515         break
2516       fi
2517     done
2518     if test x"$gcc_cv_mips_libgloss_startup" = xyes; then
2519       AC_DEFINE(HAVE_MIPS_LIBGLOSS_STARTUP_DIRECTIVES, 1,
2520         [Define if your MIPS libgloss linker scripts consistently include STARTUP directives.])
2521     fi
2522     AC_MSG_RESULT($gcc_cv_mips_libgloss_startup)
2523     ;;
2524 esac
2525
2526 if test x$with_sysroot = x && test x$host = x$target \
2527    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2528   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2529 [Define to PREFIX/include if cpp should also search that directory.])
2530 fi
2531
2532 # Figure out what language subdirectories are present.
2533 # Look if the user specified --enable-languages="..."; if not, use
2534 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2535 # go away some day.
2536 # NB:  embedded tabs in this IF block -- do not untabify
2537 if test x"${enable_languages+set}" != xset; then
2538         if test x"${LANGUAGES+set}" = xset; then
2539                 enable_languages="${LANGUAGES}"
2540                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2541
2542         else
2543                 enable_languages=all
2544         fi
2545 else
2546         if test x"${enable_languages}" = x \
2547         || test x"${enable_languages}" = xyes;
2548         then
2549                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2550         fi
2551 fi
2552 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2553
2554 # First scan to see if an enabled language requires some other language.
2555 # We assume that a given config-lang.in will list all the language
2556 # front ends it requires, even if some are required indirectly.
2557 for lang in ${srcdir}/*/config-lang.in
2558 do
2559    case $lang in
2560     # The odd quoting in the next line works around
2561     # an apparent bug in bash 1.12 on linux.
2562 changequote(,)dnl
2563     ${srcdir}/[*]/config-lang.in)
2564        ;;
2565     *)
2566        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2567        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2568        for other in $this_lang_requires
2569        do
2570           case ,${enable_languages}, in
2571            *,$other,*)
2572               ;;
2573            *,all,*)
2574               ;;
2575            *,$lang_alias,*)
2576               enable_languages="$enable_languages,$other"
2577               ;;
2578           esac
2579        done
2580        ;;
2581 changequote([,])dnl
2582    esac
2583 done
2584
2585 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2586 found_languages=
2587 subdirs=
2588 for lang in ${srcdir}/*/config-lang.in
2589 do
2590         case $lang in
2591         # The odd quoting in the next line works around
2592         # an apparent bug in bash 1.12 on linux.
2593 changequote(,)dnl
2594         ${srcdir}/[*]/config-lang.in) ;;
2595         *)
2596           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2597           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2598           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2599           if test "x$lang_alias" = x
2600           then
2601                 echo "$lang doesn't set \$language." 1>&2
2602                 exit 1
2603           fi
2604           case ${build_by_default},${enable_languages}, in
2605           *,$lang_alias,*) add_this_lang=yes ;;
2606           no,*) add_this_lang=no ;;
2607           *,all,*) add_this_lang=yes ;;
2608           *) add_this_lang=no ;;
2609           esac
2610           found_languages="${found_languages} ${lang_alias}"
2611           if test x"${add_this_lang}" = xyes; then
2612                 case $lang in
2613                     ${srcdir}/ada/config-lang.in)
2614                         if test x$have_gnat = xyes ; then
2615                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2616                         fi
2617                         ;;
2618                     *)
2619                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2620                         ;;
2621                 esac
2622           fi
2623           ;;
2624 changequote([,])dnl
2625         esac
2626 done
2627
2628 missing_languages=
2629 for expected_language in ${expected_languages} ..
2630 do
2631     if test "${expected_language}" != ..; then
2632         missing_language="${expected_language}"
2633         if test "${expected_language}" = "c" \
2634            || test "${expected_language}" = "all"; then
2635                 missing_language=
2636         fi
2637         for found_language in ${found_languages} ..
2638         do
2639             if test "${found_language}" != ..; then
2640                 if test "${expected_language}" = "${found_language}"; then
2641                     missing_language=
2642                 fi
2643             fi
2644         done
2645         if test "x${missing_language}" != x; then
2646            missing_languages="${missing_languages} ${missing_language}"
2647         fi
2648     fi
2649 done
2650
2651 if test "x$missing_languages" != x; then
2652   AC_MSG_ERROR([
2653 The following requested languages were not found:${missing_languages}
2654 The following languages were available: c${found_languages}])
2655 fi
2656
2657 # Make gthr-default.h if we have a thread file.
2658 gthread_flags=
2659 if test $thread_file != single; then
2660     rm -f gthr-default.h
2661     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2662     gthread_flags=-DHAVE_GTHR_DEFAULT
2663 fi
2664 AC_SUBST(gthread_flags)
2665
2666 # Find out what GC implementation we want, or may, use.
2667 AC_ARG_WITH(gc,
2668 [  --with-gc={simple,page} choose the garbage collection mechanism to use
2669                           with the compiler],
2670 [case "$withval" in
2671   simple | page)
2672     GGC=ggc-$withval
2673     ;;
2674   *)
2675     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2676     ;;
2677 esac],
2678 [GGC=ggc-page])
2679 AC_SUBST(GGC)
2680 echo "Using $GGC for garbage collection."
2681
2682 # Use the system's zlib library.
2683 zlibdir=-L../zlib
2684 zlibinc="-I\$(srcdir)/../zlib"
2685 AC_ARG_WITH(system-zlib,
2686 [  --with-system-zlib      use installed libz],
2687 zlibdir=
2688 zlibinc=
2689 )
2690 AC_SUBST(zlibdir)
2691 AC_SUBST(zlibinc)
2692
2693 dnl Very limited version of automake's enable-maintainer-mode
2694
2695 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2696   dnl maintainer-mode is disabled by default
2697   AC_ARG_ENABLE(maintainer-mode,
2698 [  --enable-maintainer-mode
2699                           enable make rules and dependencies not useful
2700                           (and sometimes confusing) to the casual installer],
2701       maintainer_mode=$enableval,
2702       maintainer_mode=no)
2703
2704 AC_MSG_RESULT($maintainer_mode)
2705
2706 if test "$maintainer_mode" = "yes"; then
2707   MAINT=''
2708 else
2709   MAINT='#'
2710 fi
2711 AC_SUBST(MAINT)dnl
2712
2713 # Make empty files to contain the specs and options for each language.
2714 # Then add #include lines to for a compiler that has specs and/or options.
2715
2716 lang_opt_files=
2717 lang_specs_files=
2718 lang_tree_files=
2719 for subdir in . $subdirs
2720 do
2721         if test -f $srcdir/$subdir/lang.opt; then
2722             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2723         fi
2724         if test -f $srcdir/$subdir/lang-specs.h; then
2725             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2726         fi
2727         if test -f $srcdir/$subdir/$subdir-tree.def; then
2728             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2729         fi
2730 done
2731
2732 # These (without "all_") are set in each config-lang.in.
2733 # `language' must be a single word so is spelled singularly.
2734 all_languages=
2735 all_boot_languages=
2736 all_compilers=
2737 all_stagestuff=
2738 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2739 # List of language makefile fragments.
2740 all_lang_makefrags=
2741 # List of language subdirectory makefiles.  Deprecated.
2742 all_lang_makefiles=
2743 # Files for gengtype
2744 all_gtfiles="$target_gtfiles"
2745 # Files for gengtype with language
2746 all_gtfiles_files_langs=
2747 all_gtfiles_files_files=
2748
2749 # Add the language fragments.
2750 # Languages are added via two mechanisms.  Some information must be
2751 # recorded in makefile variables, these are defined in config-lang.in.
2752 # We accumulate them and plug them into the main Makefile.
2753 # The other mechanism is a set of hooks for each of the main targets
2754 # like `clean', `install', etc.
2755
2756 language_hooks="Make-hooks"
2757
2758 for s in $subdirs
2759 do
2760                 language=
2761                 boot_language=
2762                 compilers=
2763                 stagestuff=
2764                 outputs=
2765                 gtfiles=
2766                 . ${srcdir}/$s/config-lang.in
2767                 if test "x$language" = x
2768                 then
2769                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2770                         exit 1
2771                 fi
2772                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2773                 if test -f ${srcdir}/$s/Makefile.in
2774                 then all_lang_makefiles="$s/Makefile"
2775                 fi
2776                 all_languages="$all_languages $language"
2777                 if test "x$boot_language" = xyes
2778                 then
2779                         all_boot_languages="$all_boot_languages $language"
2780                 fi
2781                 all_compilers="$all_compilers $compilers"
2782                 all_stagestuff="$all_stagestuff $stagestuff"
2783                 all_outputs="$all_outputs $outputs"
2784                 all_gtfiles="$all_gtfiles $gtfiles"
2785                 for f in $gtfiles
2786                 do
2787                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2788                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2789                 done
2790 done
2791
2792 # Pick up gtfiles for c
2793 gtfiles=
2794 s="c"
2795 . ${srcdir}/c-config-lang.in
2796 all_gtfiles="$all_gtfiles $gtfiles"
2797 for f in $gtfiles
2798 do
2799         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2800         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2801 done
2802
2803 check_languages=
2804 for language in $all_languages
2805 do
2806                 check_languages="$check_languages check-$language"
2807 done
2808
2809 # Since we can't use `::' targets, we link each language in
2810 # with a set of hooks, reached indirectly via lang.${target}.
2811
2812 rm -f Make-hooks
2813 touch Make-hooks
2814 target_list="all.build all.cross start.encap rest.encap tags \
2815         info dvi generated-manpages \
2816         install-normal install-common install-info install-man \
2817         uninstall \
2818         mostlyclean clean distclean extraclean maintainer-clean \
2819         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2820 for t in $target_list
2821 do
2822         x=
2823         for lang in $all_languages
2824         do
2825                         x="$x $lang.$t"
2826         done
2827         echo "lang.$t: $x" >> Make-hooks
2828 done
2829
2830 # Create .gdbinit.
2831
2832 echo "dir ." > .gdbinit
2833 echo "dir ${srcdir}" >> .gdbinit
2834 if test x$gdb_needs_out_file_path = xyes
2835 then
2836         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2837 fi
2838 if test "x$subdirs" != x; then
2839         for s in $subdirs
2840         do
2841                 echo "dir ${srcdir}/$s" >> .gdbinit
2842         done
2843 fi
2844 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2845
2846 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2847 # absolute path for gcc_tooldir based on inserting the number of up-directory
2848 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2849 # $(libsubdir)/@(unlibsubdir) based path.
2850 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2851 # make and thus we'd get different behavior depending on where we built the
2852 # sources.
2853 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2854     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2855 else
2856 changequote(<<, >>)dnl
2857 # An explanation of the sed strings:
2858 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2859 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2860 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2861 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2862 #
2863 # (*) Note this pattern overwrites the first character of the string
2864 # with a forward slash if one is not already present.  This is not a
2865 # problem because the exact names of the sub-directories concerned is
2866 # unimportant, just the number of them matters.
2867 #
2868 # The practical upshot of these patterns is like this:
2869 #
2870 #  prefix     exec_prefix        result
2871 #  ------     -----------        ------
2872 #   /foo        /foo/bar          ../
2873 #   /foo/       /foo/bar          ../
2874 #   /foo        /foo/bar/         ../
2875 #   /foo/       /foo/bar/         ../
2876 #   /foo        /foo/bar/ugg      ../../
2877 #
2878     dollar='$$'
2879     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2880 changequote([, ])dnl
2881 fi
2882 AC_SUBST(gcc_tooldir)
2883 AC_SUBST(dollar)
2884
2885 # Find a directory in which to install a shared libgcc.
2886
2887 AC_ARG_ENABLE(version-specific-runtime-libs,
2888 [  --enable-version-specific-runtime-libs
2889                           specify that runtime libraries should be
2890                           installed in a compiler-specific directory])
2891
2892 AC_ARG_WITH(slibdir,
2893 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2894 slibdir="$with_slibdir",
2895 if test "${enable_version_specific_runtime_libs+set}" = set; then
2896   slibdir='$(libsubdir)'
2897 elif test "$host" != "$target"; then
2898   slibdir='$(build_tooldir)/lib'
2899 else
2900   slibdir='$(libdir)'
2901 fi)
2902 AC_SUBST(slibdir)
2903
2904 objdir=`${PWDCMD-pwd}`
2905 AC_SUBST(objdir)
2906
2907 # Substitute configuration variables
2908 AC_SUBST(subdirs)
2909 AC_SUBST(srcdir)
2910 AC_SUBST(all_boot_languages)
2911 AC_SUBST(all_compilers)
2912 AC_SUBST(all_gtfiles)
2913 AC_SUBST(all_gtfiles_files_langs)
2914 AC_SUBST(all_gtfiles_files_files)
2915 AC_SUBST(all_lang_makefrags)
2916 AC_SUBST(all_lang_makefiles)
2917 AC_SUBST(all_languages)
2918 AC_SUBST(all_stagestuff)
2919 AC_SUBST(build_exeext)
2920 AC_SUBST(build_install_headers_dir)
2921 AC_SUBST(build_xm_file_list)
2922 AC_SUBST(build_xm_include_list)
2923 AC_SUBST(build_xm_defines)
2924 AC_SUBST(check_languages)
2925 AC_SUBST(cc_set_by_configure)
2926 AC_SUBST(quoted_cc_set_by_configure)
2927 AC_SUBST(cpp_install_dir)
2928 AC_SUBST(xmake_file)
2929 AC_SUBST(tmake_file)
2930 AC_SUBST(extra_headers_list)
2931 AC_SUBST(extra_objs)
2932 AC_SUBST(extra_parts)
2933 AC_SUBST(extra_passes)
2934 AC_SUBST(extra_programs)
2935 AC_SUBST(float_h_file)
2936 AC_SUBST(gcc_config_arguments)
2937 AC_SUBST(gcc_gxx_include_dir)
2938 AC_SUBST(libstdcxx_incdir)
2939 AC_SUBST(gcc_version)
2940 AC_SUBST(gcc_version_full)
2941 AC_SUBST(gcc_version_trigger)
2942 AC_SUBST(host_exeext)
2943 AC_SUBST(host_extra_gcc_objs)
2944 AC_SUBST(host_xm_file_list)
2945 AC_SUBST(host_xm_include_list)
2946 AC_SUBST(host_xm_defines)
2947 AC_SUBST(out_host_hook_obj)
2948 AC_SUBST(install)
2949 AC_SUBST(lang_opt_files)
2950 AC_SUBST(lang_specs_files)
2951 AC_SUBST(lang_tree_files)
2952 AC_SUBST(local_prefix)
2953 AC_SUBST(md_file)
2954 AC_SUBST(objc_boehm_gc)
2955 AC_SUBST(out_file)
2956 AC_SUBST(out_object_file)
2957 AC_SUBST(stage_prefix_set_by_configure)
2958 AC_SUBST(quoted_stage_prefix_set_by_configure)
2959 AC_SUBST(symbolic_link)
2960 AC_SUBST(thread_file)
2961 AC_SUBST(tm_file_list)
2962 AC_SUBST(tm_include_list)
2963 AC_SUBST(tm_defines)
2964 AC_SUBST(tm_p_file_list)
2965 AC_SUBST(tm_p_include_list)
2966 AC_SUBST(xm_file_list)
2967 AC_SUBST(xm_include_list)
2968 AC_SUBST(xm_defines)
2969 AC_SUBST(target_alias)
2970 AC_SUBST(c_target_objs)
2971 AC_SUBST(cxx_target_objs)
2972 AC_SUBST(target_cpu_default)
2973
2974 AC_SUBST_FILE(language_hooks)
2975
2976 # Echo that links are built
2977 if test x$host = x$target
2978 then
2979         str1="native "
2980 else
2981         str1="cross-"
2982         str2=" from $host"
2983 fi
2984
2985 if test x$host != x$build
2986 then
2987         str3=" on a $build system"
2988 fi
2989
2990 if test "x$str2" != x || test "x$str3" != x
2991 then
2992         str4=
2993 fi
2994
2995 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2996
2997 if test "x$str2" != x || test "x$str3" != x
2998 then
2999         echo " ${str2}${str3}." 1>&2
3000 fi
3001
3002 # Configure the subdirectories
3003 # AC_CONFIG_SUBDIRS($subdirs)
3004
3005 # Create the Makefile
3006 # and configure language subdirectories
3007 AC_OUTPUT($all_outputs,
3008 [
3009 case x$CONFIG_HEADERS in
3010 xauto-host.h:config.in)
3011 echo > cstamp-h ;;
3012 esac
3013 # Make sure all the subdirs exist.
3014 for d in $subdirs
3015 do
3016     test -d $d || mkdir $d
3017 done
3018 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3019 # bootstrapping and the installation procedure can still use
3020 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3021 # FLAGS_TO_PASS has been modified to solve the problem there.
3022 # This is virtually a duplicate of what happens in configure.lang; we do
3023 # an extra check to make sure this only happens if ln -s can be used.
3024 if test "$symbolic_link" = "ln -s"; then
3025  for d in ${subdirs} fixinc ; do
3026         STARTDIR=`${PWDCMD-pwd}`
3027         cd $d
3028         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3029         do
3030                 rm -f $t
3031                 $symbolic_link ../$t $t 2>/dev/null
3032         done
3033         cd $STARTDIR
3034  done
3035 else true ; fi
3036 ],
3037 [subdirs='$subdirs'
3038 symbolic_link='$symbolic_link'
3039 ])