gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144 changequote(<<, >>)dnl
 145     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/$libstdcxx_incdir"
 146 changequote([, ])dnl
 147   fi
 148 fi
 149
 150 AC_ARG_WITH(cpp_install_dir,
 151 [  --with-cpp-install-dir=DIR
 152                           install the user visible C preprocessor in DIR
 153                           (relative to PREFIX) as well as PREFIX/bin],
 154 [if test x$withval = xyes; then
 155   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 156 elif test x$withval != xno; then
 157   cpp_install_dir=$withval
 158 fi])
 159
 160 # We would like to our source tree to be readonly.  However when releases or
 161 # pre-releases are generated, the flex/bison generated files as well as the
 162 # various formats of manuals need to be included along with the rest of the
 163 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 164 # just that.
 165
 166 AC_MSG_CHECKING([whether to place generated files in the source directory])
 167   dnl generated-files-in-srcdir is disabled by default
 168   AC_ARG_ENABLE(generated-files-in-srcdir,
 169 [  --enable-generated-files-in-srcdir
 170                           put copies of generated files in source dir
 171                           intended for creating source tarballs for users
 172                           without texinfo bison or flex.],
 173       generated_files_in_srcdir=$enableval,
 174       generated_files_in_srcdir=no)
 175
 176 AC_MSG_RESULT($generated_files_in_srcdir)
 177
 178 if test "$generated_files_in_srcdir" = "yes"; then
 179   GENINSRC=''
 180 else
 181   GENINSRC='#'
 182 fi
 183 AC_SUBST(GENINSRC)
 184
 185 # -------------------
 186 # Find default linker
 187 # -------------------
 188
 189 # With GNU ld
 190 AC_ARG_WITH(gnu-ld,
 191 [  --with-gnu-ld           arrange to work with GNU ld.],
 192 gnu_ld_flag="$with_gnu_ld",
 193 gnu_ld_flag=no)
 194
 195 # With pre-defined ld
 196 AC_ARG_WITH(ld,
 197 [  --with-ld               arrange to use the specified ld (full pathname)],
 198 DEFAULT_LINKER="$with_ld")
 199 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 200   if test ! -x "$DEFAULT_LINKER"; then
 201     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 202   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 203     gnu_ld_flag=yes
 204   fi
 205   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 206         [Define to enable the use of a default linker.])
 207 fi
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 AC_MSG_CHECKING([whether a default assembler was specified])
 250 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 251   if test x"$gas_flag" = x"no"; then
 252     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 253   else
 254     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 255   fi
 256 else
 257   AC_MSG_RESULT(no)
 258 fi
 259
 260 # ---------------
 261 # Find C compiler
 262 # ---------------
 263
 264 # If a non-executable a.out is present (e.g. created by GNU as above even if
 265 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 266 # file, even when creating an executable, so an execution test fails.
 267 # Remove possible default executable files to avoid this.
 268 #
 269 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 270 # Autoconf includes it.
 271 rm -f a.out a.exe b.out
 272
 273 # Find the native compiler
 274 AC_PROG_CC
 275 AM_PROG_CC_C_O
 276 # autoconf is lame and doesn't give us any substitution variable for this.
 277 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 278   NO_MINUS_C_MINUS_O=yes
 279 else
 280   OUTPUT_OPTION='-o $@'
 281 fi
 282 AC_SUBST(NO_MINUS_C_MINUS_O)
 283 AC_SUBST(OUTPUT_OPTION)
 284
 285 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 286 # optimizations to be activated explicitly by the toplevel.
 287 case "$CC" in
 288   */prev-gcc/xgcc*) ;;
 289   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 290 esac
 291 AC_SUBST(CFLAGS)
 292
 293 # -------------------------
 294 # Check C compiler features
 295 # -------------------------
 296
 297 AC_PROG_CPP
 298 AC_C_INLINE
 299
 300 # sizeof(char) is 1 by definition.
 301 AC_CHECK_SIZEOF(void *)
 302 AC_CHECK_SIZEOF(short)
 303 AC_CHECK_SIZEOF(int)
 304 AC_CHECK_SIZEOF(long)
 305 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 306 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 307
 308 # ---------------------
 309 # Warnings and checking
 310 # ---------------------
 311
 312 # Check $CC warning features (if it's GCC).
 313 # We want to use -pedantic, but we don't want warnings about
 314 # * 'long long'
 315 # * variadic macros
 316 # * overlong strings
 317 # So, we only use -pedantic if we can disable those warnings.
 318
 319 AC_CACHE_CHECK(
 320   [whether ${CC} accepts -Wno-long-long],
 321   [ac_cv_prog_cc_w_no_long_long],
 322   [save_CFLAGS="$CFLAGS"
 323   CFLAGS="-Wno-long-long"
 324   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 325                     [ac_cv_prog_cc_w_no_long_long=yes],
 326                     [ac_cv_prog_cc_w_no_long_long=no])
 327   CFLAGS="$save_CFLAGS"
 328   ])
 329
 330 AC_CACHE_CHECK(
 331   [whether ${CC} accepts -Wno-variadic-macros],
 332   [ac_cv_prog_cc_w_no_variadic_macros],
 333   [save_CFLAGS="$CFLAGS"
 334   CFLAGS="-Wno-variadic-macros"
 335   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 336                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 337                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 338   CFLAGS="$save_CFLAGS"
 339   ])
 340
 341 AC_CACHE_CHECK(
 342   [whether ${CC} accepts -Wno-overlength-strings],
 343   [ac_cv_prog_cc_w_no_overlength_strings],
 344   [save_CFLAGS="$CFLAGS"
 345   CFLAGS="-Wno-overlength-strings"
 346   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 347                     [ac_cv_prog_cc_w_no_overlength_strings=yes],
 348                     [ac_cv_prog_cc_w_no_overlength_strings=no])
 349   CFLAGS="$save_CFLAGS"
 350   ])
 351
 352 strict1_warn=
 353 if test $ac_cv_prog_cc_w_no_long_long = yes \
 354    && test $ac_cv_prog_cc_w_no_variadic_macros = yes \
 355    && test $ac_cv_prog_cc_w_no_overlength_strings = yes ; then
 356   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros -Wno-overlength-strings"
 357 fi
 358
 359 # Add -Wold-style-definition if it's accepted
 360 AC_CACHE_CHECK(
 361   [whether ${CC} accepts -Wold-style-definition],
 362   [ac_cv_prog_cc_w_old_style_definition],
 363   [save_CFLAGS="$CFLAGS"
 364   CFLAGS="-Wold-style-definition"
 365   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 366                     [ac_cv_prog_cc_w_old_style_definition=yes],
 367                     [ac_cv_prog_cc_w_old_style_definition=no])
 368   CFLAGS="$save_CFLAGS"
 369   ])
 370 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 371   strict1_warn="${strict1_warn} -Wold-style-definition"
 372 fi
 373
 374 # Add -Wmissing-format-attribute if it's accepted
 375 AC_CACHE_CHECK(
 376   [whether ${CC} accepts -Wmissing-format-attribute],
 377   [ac_cv_prog_cc_w_missing_format_attribute],
 378   [save_CFLAGS="$CFLAGS"
 379   CFLAGS="-Wmissing-format-attribute"
 380   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 381                     [ac_cv_prog_cc_w_missing_format_attribute=yes],
 382                     [ac_cv_prog_cc_w_missing_format_attribute=no])
 383   CFLAGS="$save_CFLAGS"
 384   ])
 385 if test $ac_cv_prog_cc_w_missing_format_attribute = yes ; then
 386   strict1_warn="${strict1_warn} -Wmissing-format-attribute"
 387 fi
 388
 389 # Enable -Werror, period.
 390 AC_ARG_ENABLE(werror_always,
 391 [  --enable-werror-always         enable -Werror always], [],
 392 [enable_werror_always=no])
 393 if test x${enable_werror_always} = xyes ; then
 394   strict1_warn="${strict1_warn} -Werror"
 395   WERROR=-Werror
 396 fi
 397
 398 AC_SUBST(strict1_warn)
 399
 400 # Get C++ compatibility warning flag, if supported.
 401 AC_CACHE_CHECK(
 402   [whether ${CC} accepts -Wc++-compat],
 403   [ac_cv_prog_cc_w_cxx_compat],
 404   [save_CFLAGS="$CFLAGS"
 405   CFLAGS="-Wc++-compat"
 406   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 407                     [ac_cv_prog_cc_w_cxx_compat=yes],
 408                     [ac_cv_prog_cc_w_cxx_compat=no])
 409   CFLAGS="$save_CFLAGS"
 410   ])
 411 if test x${ac_cv_prog_cc_w_cxx_compat} = xyes; then
 412   cxx_compat_warn="-Wc++-compat"
 413 fi
 414 AC_SUBST(cxx_compat_warn)
 415
 416
 417 # If the native compiler is GCC, we can enable warnings even in stage1.
 418 # That's useful for people building cross-compilers, or just running a
 419 # quick `make'.
 420 warn_cflags=
 421 if test "x$GCC" = "xyes"; then
 422   warn_cflags='$(GCC_WARN_CFLAGS)'
 423 fi
 424 AC_SUBST(warn_cflags)
 425
 426 # Enable -Werror in bootstrap stage2 and later.
 427 is_release=
 428 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 429   is_release=yes
 430 fi
 431 AC_ARG_ENABLE(werror,
 432 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 433 [if test x$is_release = x ; then
 434   # Default to "yes" on development branches.
 435   enable_werror=yes
 436 else
 437   # Default to "no" on release branches.
 438   enable_werror=no
 439 fi])
 440 if test x$enable_werror = xyes ; then
 441   WERROR=-Werror
 442 fi
 443 AC_SUBST(WERROR)
 444
 445 # Enable expensive internal checks
 446 AC_ARG_ENABLE(checking,
 447 [  --enable-checking[=LIST]
 448                           enable expensive run-time checks.  With LIST,
 449                           enable only specific categories of checks.
 450                           Categories are: yes,no,all,none,release.
 451                           Flags are: assert,fold,gc,gcac,misc,
 452                           rtlflag,rtl,runtime,tree,valgrind.],
 453 [ac_checking_flags="${enableval}"],[
 454 # Determine the default checks.
 455 if test x$is_release = x ; then
 456   ac_checking_flags=yes
 457 else
 458   ac_checking_flags=release
 459 fi])
 460 ac_assert_checking=1
 461 ac_checking=
 462 ac_fold_checking=
 463 ac_gc_checking=
 464 ac_gc_always_collect=
 465 ac_rtl_checking=
 466 ac_rtlflag_checking=
 467 ac_runtime_checking=1
 468 ac_tree_checking=
 469 ac_valgrind_checking=
 470 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 471 for check in $ac_checking_flags
 472 do
 473         case $check in
 474         # these set all the flags to specific states
 475         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 476                         ac_fold_checking= ; ac_gc_checking=1 ;
 477                         ac_gc_always_collect= ; ac_rtl_checking= ;
 478                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 479                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 480         no|none)        ac_assert_checking= ; ac_checking= ;
 481                         ac_fold_checking= ; ac_gc_checking= ;
 482                         ac_gc_always_collect= ; ac_rtl_checking= ;
 483                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 484                         ac_tree_checking= ; ac_valgrind_checking= ;;
 485         all)            ac_assert_checking=1 ; ac_checking=1 ;
 486                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 487                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 488                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 489                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 490         release)        ac_assert_checking=1 ; ac_checking= ;
 491                         ac_fold_checking= ; ac_gc_checking= ;
 492                         ac_gc_always_collect= ; ac_rtl_checking= ;
 493                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 494                         ac_tree_checking= ; ac_valgrind_checking= ;;
 495         # these enable particular checks
 496         assert)         ac_assert_checking=1 ;;
 497         fold)           ac_fold_checking=1 ;;
 498         gc)             ac_gc_checking=1 ;;
 499         gcac)           ac_gc_always_collect=1 ;;
 500         misc)           ac_checking=1 ;;
 501         rtl)            ac_rtl_checking=1 ;;
 502         rtlflag)        ac_rtlflag_checking=1 ;;
 503         runtime)        ac_runtime_checking=1 ;;
 504         tree)           ac_tree_checking=1 ;;
 505         valgrind)       ac_valgrind_checking=1 ;;
 506         *)      AC_MSG_ERROR(unknown check category $check) ;;
 507         esac
 508 done
 509 IFS="$ac_save_IFS"
 510
 511 nocommon_flag=""
 512 if test x$ac_checking != x ; then
 513   AC_DEFINE(ENABLE_CHECKING, 1,
 514 [Define if you want more run-time sanity checks.  This one gets a grab
 515    bag of miscellaneous but relatively cheap checks.])
 516   nocommon_flag=-fno-common
 517 fi
 518 AC_SUBST(nocommon_flag)
 519 if test x$ac_assert_checking != x ; then
 520   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 521 [Define if you want assertions enabled.  This is a cheap check.])
 522 fi
 523 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 524 if test x$ac_runtime_checking != x ; then
 525   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 526 [Define if you want runtime assertions enabled.  This is a cheap check.])
 527 fi
 528 if test x$ac_tree_checking != x ; then
 529   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 530 [Define if you want all operations on trees (the basic data
 531    structure of the front ends) to be checked for dynamic type safety
 532    at runtime.  This is moderately expensive.  The tree browser debugging
 533    routines will also be enabled by this option.
 534    ])
 535   TREEBROWSER=tree-browser.o
 536 fi
 537 AC_SUBST(TREEBROWSER)
 538 if test x$ac_rtl_checking != x ; then
 539   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 540 [Define if you want all operations on RTL (the basic data structure
 541    of the optimizer and back end) to be checked for dynamic type safety
 542    at runtime.  This is quite expensive.])
 543 fi
 544 if test x$ac_rtlflag_checking != x ; then
 545   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 546 [Define if you want RTL flag accesses to be checked against the RTL
 547    codes that are supported for each access macro.  This is relatively
 548    cheap.])
 549 fi
 550 if test x$ac_gc_checking != x ; then
 551   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 552 [Define if you want the garbage collector to do object poisoning and
 553    other memory allocation checks.  This is quite expensive.])
 554 fi
 555 if test x$ac_gc_always_collect != x ; then
 556   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 557 [Define if you want the garbage collector to operate in maximally
 558    paranoid mode, validating the entire heap and collecting garbage at
 559    every opportunity.  This is extremely expensive.])
 560 fi
 561 if test x$ac_fold_checking != x ; then
 562   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 563 [Define if you want fold checked that it never destructs its argument.
 564    This is quite expensive.])
 565 fi
 566 valgrind_path_defines=
 567 valgrind_command=
 568
 569 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 570 dnl # an if statement.  This was the source of very frustrating bugs
 571 dnl # in converting to autoconf 2.5x!
 572 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 573
 574 if test x$ac_valgrind_checking != x ; then
 575   # It is certainly possible that there's valgrind but no valgrind.h.
 576   # GCC relies on making annotations so we must have both.
 577   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 578   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 579     [[#include <valgrind/memcheck.h>
 580 #ifndef VALGRIND_DISCARD
 581 #error VALGRIND_DISCARD not defined
 582 #endif]])],
 583   [gcc_cv_header_valgrind_memcheck_h=yes],
 584   [gcc_cv_header_valgrind_memcheck_h=no])
 585   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 586   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 587   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 588     [[#include <memcheck.h>
 589 #ifndef VALGRIND_DISCARD
 590 #error VALGRIND_DISCARD not defined
 591 #endif]])],
 592   [gcc_cv_header_memcheck_h=yes],
 593   [gcc_cv_header_memcheck_h=no])
 594   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 595   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 596         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 597   if test "x$valgrind_path" = "x" \
 598     || (test $have_valgrind_h = no \
 599         && test $gcc_cv_header_memcheck_h = no \
 600         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 601         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 602   fi
 603   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 604   valgrind_command="$valgrind_path -q"
 605   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 606 [Define if you want to run subprograms and generated programs
 607    through valgrind (a memory checker).  This is extremely expensive.])
 608   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 609     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 610         [Define if valgrind's valgrind/memcheck.h header is installed.])
 611   fi
 612   if test $gcc_cv_header_memcheck_h = yes; then
 613     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 614         [Define if valgrind's memcheck.h header is installed.])
 615   fi
 616 fi
 617 AC_SUBST(valgrind_path_defines)
 618 AC_SUBST(valgrind_command)
 619
 620 AC_ARG_ENABLE(mapped-location,
 621 [  --enable-mapped-location   location_t is fileline integer cookie],,
 622 enable_mapped_location=no)
 623
 624 if test "$enable_mapped_location" = yes ; then
 625   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 626 [Define if location_t is fileline integer cookie.])
 627 fi
 628
 629 # Enable code coverage collection
 630 AC_ARG_ENABLE(coverage,
 631 [  --enable-coverage[=LEVEL]
 632                           enable compiler's code coverage collection.
 633                           Use to measure compiler performance and locate
 634                           unused parts of the compiler. With LEVEL, specify
 635                           optimization. Values are opt, noopt,
 636                           default is noopt],
 637 [case "${enableval}" in
 638   yes|noopt)
 639     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 640     ;;
 641   opt)
 642     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 643     ;;
 644   no)
 645     # a.k.a. --disable-coverage
 646     coverage_flags=""
 647     ;;
 648   *)
 649     AC_MSG_ERROR(unknown coverage setting $enableval)
 650     ;;
 651 esac],
 652 [coverage_flags=""])
 653 AC_SUBST(coverage_flags)
 654
 655 AC_ARG_ENABLE(gather-detailed-mem-stats,
 656 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 657 [enable_gather_detailed_mem_stats=no])
 658 if test x$enable_gather_detailed_mem_stats = xyes ; then
 659   AC_DEFINE(GATHER_STATISTICS, 1,
 660         [Define to enable detailed memory allocation stats gathering.])
 661 fi
 662
 663 # -------------------------------
 664 # Miscenalleous configure options
 665 # -------------------------------
 666
 667 # With stabs
 668 AC_ARG_WITH(stabs,
 669 [  --with-stabs            arrange to use stabs instead of host debug format],
 670 stabs="$with_stabs",
 671 stabs=no)
 672
 673 # Determine whether or not multilibs are enabled.
 674 AC_ARG_ENABLE(multilib,
 675 [  --enable-multilib       enable library support for multiple ABIs],
 676 [], [enable_multilib=yes])
 677 AC_SUBST(enable_multilib)
 678
 679 # Enable __cxa_atexit for C++.
 680 AC_ARG_ENABLE(__cxa_atexit,
 681 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 682 [], [])
 683
 684 # Enable C extension for decimal float if target supports it.
 685 AC_ARG_ENABLE(decimal-float,
 686 [  --enable-decimal-float  enable decimal float extension to C],
 687 [
 688   if test x$enablevar = xyes ; then
 689     case $target in
 690     powerpc*-*-linux* | i?86*-*-linux*)
 691       enable_decimal_float=yes
 692       ;;
 693     *)
 694       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 695       enable_decimal_float=no
 696       ;;
 697     esac
 698   fi
 699 ], [enable_decimal_float=no])
 700
 701 AC_SUBST(enable_decimal_float)
 702
 703 dfp=`if test $enable_decimal_float = yes; then echo 1; else echo 0; fi`
 704 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 705 [Define to 1 to enable decimal float extension to C.])
 706
 707 # Enable threads
 708 # Pass with no value to take the default
 709 # Pass with a value to specify a thread package
 710 AC_ARG_ENABLE(threads,
 711 [  --enable-threads        enable thread usage for target GCC
 712   --enable-threads=LIB    use LIB thread package for target GCC],,
 713 [enable_threads=''])
 714
 715 AC_ARG_ENABLE(tls,
 716 [  --enable-tls            enable or disable generation of tls code
 717                           overriding the assembler check for tls support],
 718 [
 719   case $enable_tls in
 720     yes | no) ;;
 721     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 722 Valid choices are 'yes' and 'no'.]) ;;
 723   esac
 724 ], [enable_tls=''])
 725
 726 AC_ARG_ENABLE(objc-gc,
 727 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 728                           the GNU Objective-C runtime],
 729 if test x$enable_objc_gc = xno; then
 730         objc_boehm_gc=''
 731 else
 732         objc_boehm_gc=1
 733 fi,
 734 objc_boehm_gc='')
 735
 736 AC_ARG_WITH(dwarf2,
 737 [  --with-dwarf2           force the default debug format to be DWARF 2],
 738 dwarf2="$with_dwarf2",
 739 dwarf2=no)
 740
 741 AC_ARG_ENABLE(shared,
 742 [  --disable-shared        don't provide a shared libgcc],
 743 [
 744   case $enable_shared in
 745   yes | no) ;;
 746   *)
 747     enable_shared=no
 748     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 749     for pkg in $enableval; do
 750       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 751         enable_shared=yes
 752       fi
 753     done
 754     IFS="$ac_save_ifs"
 755     ;;
 756   esac
 757 ], [enable_shared=yes])
 758 AC_SUBST(enable_shared)
 759
 760 AC_ARG_WITH(build-sysroot,
 761   [  --with-build-sysroot=sysroot
 762                           use sysroot as the system root during the build])
 763
 764 AC_ARG_WITH(sysroot,
 765 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 766 [
 767  case ${with_sysroot} in
 768  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 769  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 770  esac
 771
 772  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 773  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 774
 775  if test "x$exec_prefix" = xNONE; then
 776   if test "x$prefix" = xNONE; then
 777    test_prefix=/usr/local
 778   else
 779    test_prefix=$prefix
 780   fi
 781  else
 782   test_prefix=$exec_prefix
 783  fi
 784  case ${TARGET_SYSTEM_ROOT} in
 785  "${test_prefix}"|"${test_prefix}/"*|\
 786  '${exec_prefix}'|'${exec_prefix}/'*)
 787    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 788    TARGET_SYSTEM_ROOT_DEFINE="$t"
 789    ;;
 790  esac
 791 ], [
 792  TARGET_SYSTEM_ROOT=
 793  TARGET_SYSTEM_ROOT_DEFINE=
 794  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 795 ])
 796 AC_SUBST(TARGET_SYSTEM_ROOT)
 797 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 798 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 799
 800 # Build with intermodule optimisations
 801 AC_ARG_ENABLE(intermodule,
 802 [  --enable-intermodule    build the compiler in one step],
 803 [case ${enable_intermodule} in
 804   yes) onestep="-onestep";;
 805   *) onestep="";;
 806 esac],
 807 [onestep=""])
 808 AC_SUBST(onestep)
 809
 810 # Sanity check enable_languages in case someone does not run the toplevel
 811 # configure # script.
 812 AC_ARG_ENABLE(languages,
 813 [  --enable-languages=LIST specify which front-ends to build],
 814 [case ,${enable_languages}, in
 815        ,,|,yes,)
 816                 # go safe -- we cannot be much sure without the toplevel
 817                 # configure's
 818                 # analysis of which target libs are present and usable
 819                 enable_languages=c
 820                 ;;
 821          *,all,*)
 822                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 823                 ;;
 824         *,c,*)
 825                 ;;
 826         *)
 827                 enable_languages=c,${enable_languages}
 828                 ;;
 829 esac],
 830 [enable_languages=c])
 831
 832 # Used by documentation targets
 833 AC_SUBST(datarootdir)
 834 AC_SUBST(docdir)
 835 AC_SUBST(htmldir)
 836
 837 # -------------------------
 838 # Checks for other programs
 839 # -------------------------
 840
 841 AC_PROG_MAKE_SET
 842
 843 # Find some useful tools
 844 AC_PROG_AWK
 845 # We need awk to create options.c and options.h.
 846 # Bail out if it's missing.
 847 case ${AWK} in
 848   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 849 esac
 850
 851 gcc_AC_PROG_LN_S
 852 ACX_PROG_LN($LN_S)
 853 AC_PROG_RANLIB
 854 case "${host}" in
 855 *-*-darwin*)
 856   # By default, the Darwin ranlib will not treat common symbols as
 857   # definitions when  building the archive table of contents.  Other
 858   # ranlibs do that; pass an option to the Darwin ranlib that makes
 859   # it behave similarly.
 860   ranlib_flags="-c"
 861   ;;
 862 *)
 863   ranlib_flags=""
 864 esac
 865 AC_SUBST(ranlib_flags)
 866
 867 gcc_AC_PROG_INSTALL
 868
 869 # See if cmp has --ignore-initial.
 870 gcc_AC_PROG_CMP_IGNORE_INITIAL
 871
 872 # See if we have the mktemp command.
 873 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 874
 875 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 876
 877 # See if makeinfo has been installed and is modern enough
 878 # that we can use it.
 879 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 880   [GNU texinfo.* \([0-9][0-9.]*\)],
 881   [4.[4-9]*])
 882 if test $gcc_cv_prog_makeinfo_modern = no; then
 883   MAKEINFO="$MISSING makeinfo"
 884   AC_MSG_WARN([
 885 *** Makeinfo is missing or too old.
 886 *** Info documentation will not be built.])
 887   BUILD_INFO=
 888 else
 889   BUILD_INFO=info
 890 fi
 891 AC_SUBST(BUILD_INFO)
 892
 893 # Is pod2man recent enough to regenerate manpages?
 894 AC_MSG_CHECKING([for recent Pod::Man])
 895 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 896   AC_MSG_RESULT(yes)
 897   GENERATED_MANPAGES=generated-manpages
 898 else
 899   AC_MSG_RESULT(no)
 900   GENERATED_MANPAGES=
 901 fi
 902 AC_SUBST(GENERATED_MANPAGES)
 903
 904 # How about lex?
 905 dnl Don't use AC_PROG_LEX; we insist on flex.
 906 dnl LEXLIB is not useful in gcc.
 907 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 908
 909 # Bison?
 910 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 911
 912 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 913 # check for build == host before using them.
 914
 915 # NM
 916 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 917   && test -d ../binutils ; then
 918   NM='$(objdir)/../binutils/nm-new'
 919 else
 920   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 921 fi
 922
 923 # AR
 924 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 925   && test -d ../binutils ; then
 926   AR='$(objdir)/../binutils/ar'
 927 else
 928   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 929 fi
 930
 931
 932 # --------------------
 933 # Checks for C headers
 934 # --------------------
 935
 936 AC_MSG_CHECKING(for GNU C library)
 937 AC_CACHE_VAL(gcc_cv_glibc,
 938 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 939   [[#include <features.h>]], [[
 940 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 941 #error Not a GNU C library system
 942 #endif]])],
 943   [gcc_cv_glibc=yes],
 944   [gcc_cv_glibc=no])])
 945 AC_MSG_RESULT($gcc_cv_glibc)
 946 if test $gcc_cv_glibc = yes; then
 947   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 948 fi
 949
 950 # Need to reject headers which give warnings, so that the -Werror bootstrap
 951 # works later. *sigh*  This needs to come before all header checks.
 952 AC_PROG_CPP_WERROR
 953
 954 AC_HEADER_STDC
 955 AC_HEADER_TIME
 956 ACX_HEADER_STRING
 957 AC_HEADER_SYS_WAIT
 958 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 959                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 960                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 961                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 962
 963 # Check for thread headers.
 964 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 965 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 966
 967 # These tests can't be done till we know if we have limits.h.
 968 gcc_AC_C_CHAR_BIT
 969 AC_C_BIGENDIAN
 970
 971 # --------
 972 # UNSORTED
 973 # --------
 974
 975 # Stage specific cflags for build.
 976 stage1_cflags=
 977 case $build in
 978 vax-*-*)
 979   if test x$GCC = xyes
 980   then
 981     stage1_cflags="-Wa,-J"
 982   else
 983     stage1_cflags="-J"
 984   fi
 985   ;;
 986 esac
 987 AC_SUBST(stage1_cflags)
 988
 989 # These libraries may be used by collect2.
 990 # We may need a special search path to get them linked.
 991 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 992 [save_LIBS="$LIBS"
 993 for libs in '' -lld -lmld \
 994                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 995                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 996 do
 997         LIBS="$libs"
 998         AC_TRY_LINK_FUNC(ldopen,
 999                 [gcc_cv_collect2_libs="$libs"; break])
1000 done
1001 LIBS="$save_LIBS"
1002 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1003 case $gcc_cv_collect2_libs in
1004         "none required")        ;;
1005         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1006 esac
1007 AC_SUBST(COLLECT2_LIBS)
1008
1009 # When building Ada code on Alpha, we need exc_resume which is usually in
1010 # -lexc.  So test for it.
1011 save_LIBS="$LIBS"
1012 LIBS=
1013 AC_SEARCH_LIBS(exc_resume, exc)
1014 GNAT_LIBEXC="$LIBS"
1015 LIBS="$save_LIBS"
1016 AC_SUBST(GNAT_LIBEXC)
1017
1018 # Some systems put ldexp and frexp in libm instead of libc; assume
1019 # they're both in the same place.  jcf-dump needs them.
1020 save_LIBS="$LIBS"
1021 LIBS=
1022 AC_SEARCH_LIBS(ldexp, m)
1023 LDEXP_LIB="$LIBS"
1024 LIBS="$save_LIBS"
1025 AC_SUBST(LDEXP_LIB)
1026
1027 # Use <inttypes.h> only if it exists,
1028 # doesn't clash with <sys/types.h>, and declares intmax_t.
1029 AC_MSG_CHECKING(for inttypes.h)
1030 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1031 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1032 [[#include <sys/types.h>
1033 #include <inttypes.h>]],
1034   [[intmax_t i = -1;]])],
1035   [gcc_cv_header_inttypes_h=yes],
1036   [gcc_cv_header_inttypes_h=no])])
1037 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1038 if test $gcc_cv_header_inttypes_h = yes; then
1039   AC_DEFINE(HAVE_INTTYPES_H, 1,
1040         [Define if you have a working <inttypes.h> header file.])
1041 fi
1042
1043 dnl Disabled until we have a complete test for buggy enum bitfields.
1044 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1045
1046 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1047   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1048   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1049   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1050   putchar_unlocked putc_unlocked)
1051 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1052         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1053         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1054         gcc_UNLOCKED_FUNCS)
1055
1056 if test x$ac_cv_func_mbstowcs = xyes; then
1057   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1058 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1059 int main()
1060 {
1061   mbstowcs(0, "", 0);
1062   return 0;
1063 }]])],
1064     [gcc_cv_func_mbstowcs_works=yes],
1065     [gcc_cv_func_mbstowcs_works=no],
1066     [gcc_cv_func_mbstowcs_works=yes])])
1067   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1068     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1069   [Define this macro if mbstowcs does not crash when its
1070    first argument is NULL.])
1071   fi
1072 fi
1073
1074 AC_CHECK_TYPE(ssize_t, int)
1075
1076 # Try to determine the array type of the second argument of getgroups
1077 # for the target system (int or gid_t).
1078 AC_TYPE_GETGROUPS
1079 if test "${target}" = "${build}"; then
1080   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1081 else
1082   case "${target}" in
1083         # This condition may need some tweaking.  It should include all
1084         # targets where the array type of the second argument of getgroups
1085         # is int and the type of gid_t is not equivalent to int.
1086         *-*-sunos* | *-*-ultrix*)
1087                 TARGET_GETGROUPS_T=int
1088                 ;;
1089         *)
1090                 TARGET_GETGROUPS_T=gid_t
1091                 ;;
1092   esac
1093 fi
1094 AC_SUBST(TARGET_GETGROUPS_T)
1095
1096 gcc_AC_FUNC_MMAP_BLACKLIST
1097
1098 case "${host}" in
1099 *-*-*vms*)
1100   # Under VMS, vfork works very differently than on Unix. The standard test
1101   # won't work, and it isn't easily adaptable. It makes more sense to
1102   # just force it.
1103   ac_cv_func_vfork_works=yes
1104   ;;
1105 esac
1106 AC_FUNC_FORK
1107
1108 AM_ICONV
1109 # Until we have in-tree GNU iconv:
1110 LIBICONV_DEP=
1111 AC_SUBST(LIBICONV_DEP)
1112
1113 AM_LC_MESSAGES
1114
1115 AM_LANGINFO_CODESET
1116
1117 # We will need to find libiberty.h and ansidecl.h
1118 saved_CFLAGS="$CFLAGS"
1119 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1120 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1121         strsignal strstr strverscmp \
1122         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1123         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1124 #include "ansidecl.h"
1125 #include "system.h"])
1126
1127 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1128 #include "ansidecl.h"
1129 #include "system.h"
1130 #ifdef HAVE_SYS_RESOURCE_H
1131 #include <sys/resource.h>
1132 #endif
1133 ])
1134
1135 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1136 #include "ansidecl.h"
1137 #include "system.h"
1138 #ifdef HAVE_SYS_RESOURCE_H
1139 #include <sys/resource.h>
1140 #endif
1141 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1142 [Define to \`long' if <sys/resource.h> doesn't define.])])
1143
1144 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1145 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1146 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1147 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1148 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1149 #include "ansidecl.h"
1150 #include "system.h"
1151 #ifdef HAVE_LDFCN_H
1152 #undef FREAD
1153 #undef FWRITE
1154 #include <ldfcn.h>
1155 #endif
1156 ])
1157
1158 gcc_AC_CHECK_DECLS(times, , ,[
1159 #include "ansidecl.h"
1160 #include "system.h"
1161 #ifdef HAVE_SYS_TIMES_H
1162 #include <sys/times.h>
1163 #endif
1164 ])
1165
1166 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1167 #include "ansidecl.h"
1168 #include "system.h"
1169 #include <signal.h>
1170 ])
1171
1172 # More time-related stuff.
1173 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1174 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1175 #include "ansidecl.h"
1176 #include "system.h"
1177 #ifdef HAVE_SYS_TIMES_H
1178 #include <sys/times.h>
1179 #endif
1180 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1181 if test $ac_cv_struct_tms = yes; then
1182   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1183   [Define if <sys/times.h> defines struct tms.])
1184 fi
1185
1186 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1187 # revisit after autoconf 2.50.
1188 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1189 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1190 #include "ansidecl.h"
1191 #include "system.h"
1192 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1193 if test $gcc_cv_type_clock_t = yes; then
1194   AC_DEFINE(HAVE_CLOCK_T, 1,
1195   [Define if <time.h> defines clock_t.])
1196 fi
1197
1198 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1199 CFLAGS="$saved_CFLAGS"
1200
1201 gcc_AC_INITFINI_ARRAY
1202
1203 # mkdir takes a single argument on some systems.
1204 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1205
1206 # File extensions
1207 manext='.1'
1208 objext='.o'
1209 AC_SUBST(manext)
1210 AC_SUBST(objext)
1211
1212 # With Setjmp/Longjmp based exception handling.
1213 AC_ARG_ENABLE(sjlj-exceptions,
1214 [  --enable-sjlj-exceptions
1215                           arrange to use setjmp/longjmp exception handling],
1216 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1217 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1218   [Define 0/1 to force the choice for exception handling model.])])
1219
1220 # For platforms with the unwind ABI which includes an unwind library,
1221 # libunwind, we can choose to use the system libunwind.
1222 AC_ARG_WITH(system-libunwind,
1223 [  --with-system-libunwind use installed libunwind])
1224
1225 # config.gcc also contains tests of with_system_libunwind.
1226 if test x$with_system_libunwind = xyes; then
1227         AC_DEFINE(HAVE_GETIPINFO, 1,
1228 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1229 fi
1230
1231 # --------------------------------------------------------
1232 # Build, host, and target specific configuration fragments
1233 # --------------------------------------------------------
1234
1235 # Collect build-machine-specific information.
1236 . ${srcdir}/config.build
1237
1238 # Collect host-machine-specific information.
1239 . ${srcdir}/config.host
1240
1241 target_gtfiles=
1242
1243 # Collect target-machine-specific information.
1244 . ${srcdir}/config.gcc
1245
1246 extra_objs="${host_extra_objs} ${extra_objs}"
1247 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1248
1249 # Default the target-machine variables that were not explicitly set.
1250 if test x"$tm_file" = x
1251 then tm_file=$cpu_type/$cpu_type.h; fi
1252
1253 if test x"$extra_headers" = x
1254 then extra_headers=; fi
1255
1256 if test x$md_file = x
1257 then md_file=$cpu_type/$cpu_type.md; fi
1258
1259 if test x$out_file = x
1260 then out_file=$cpu_type/$cpu_type.c; fi
1261
1262 if test x"$tmake_file" = x
1263 then tmake_file=$cpu_type/t-$cpu_type
1264 fi
1265
1266 if test x"$dwarf2" = xyes
1267 then tm_file="$tm_file tm-dwarf2.h"
1268 fi
1269
1270 # Say what files are being used for the output code and MD file.
1271 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1272 echo "Using \`$srcdir/config/$md_file' as machine description file."
1273
1274 # If any of the xm_file variables contain nonexistent files, warn
1275 # about them and drop them.
1276
1277 bx=
1278 for x in $build_xm_file; do
1279   if    test -f $srcdir/config/$x
1280   then      bx="$bx $x"
1281   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1282   fi
1283 done
1284 build_xm_file="$bx"
1285
1286 hx=
1287 for x in $host_xm_file; do
1288   if    test -f $srcdir/config/$x
1289   then      hx="$hx $x"
1290   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1291   fi
1292 done
1293 host_xm_file="$hx"
1294
1295 tx=
1296 for x in $xm_file; do
1297   if    test -f $srcdir/config/$x
1298   then      tx="$tx $x"
1299   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1300   fi
1301 done
1302 xm_file="$tx"
1303
1304 count=a
1305 for f in $tm_file; do
1306         count=${count}x
1307 done
1308 if test $count = ax; then
1309         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1310 else
1311         echo "Using the following target machine macro files:"
1312         for f in $tm_file; do
1313                 echo "  $srcdir/config/$f"
1314         done
1315 fi
1316
1317 if test x$need_64bit_hwint = xyes; then
1318         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1319 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1320 fi
1321
1322 if test x$use_long_long_for_widest_fast_int = xyes; then
1323         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1324 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1325 efficiently supported by the host hardware.])
1326 fi
1327
1328 count=a
1329 for f in $host_xm_file; do
1330         count=${count}x
1331 done
1332 if test $count = a; then
1333         :
1334 elif test $count = ax; then
1335         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1336 else
1337         echo "Using the following host machine macro files:"
1338         for f in $host_xm_file; do
1339                 echo "  $srcdir/config/$f"
1340         done
1341 fi
1342 echo "Using ${out_host_hook_obj} for host machine hooks."
1343
1344 if test "$host_xm_file" != "$build_xm_file"; then
1345         count=a
1346         for f in $build_xm_file; do
1347                 count=${count}x
1348         done
1349         if test $count = a; then
1350                 :
1351         elif test $count = ax; then
1352                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1353         else
1354                 echo "Using the following build machine macro files:"
1355                 for f in $build_xm_file; do
1356                         echo "  $srcdir/config/$f"
1357                 done
1358         fi
1359 fi
1360
1361 case ${host} in
1362   powerpc*-*-darwin*)
1363     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1364       gcc_cv_mcontext_underscores,
1365       AC_COMPILE_IFELSE([
1366 #include <sys/signal.h>
1367 #include <ucontext.h>
1368 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1369 ],
1370         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1371       if test $gcc_cv_mcontext_underscores = yes; then
1372         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1373           [mcontext_t fields start with __])
1374       fi
1375     ;;
1376 esac
1377
1378 # ---------
1379 # Threading
1380 # ---------
1381
1382 # Check if a valid thread package
1383 case ${enable_threads} in
1384   "" | no)
1385     # No threads
1386     target_thread_file='single'
1387     ;;
1388   yes)
1389     # default
1390     target_thread_file='single'
1391     ;;
1392   aix | dce | gnat | irix | posix | posix95 | rtems | \
1393   single | solaris | vxworks | win32 )
1394     target_thread_file=${enable_threads}
1395     ;;
1396   *)
1397     echo "${enable_threads} is an unknown thread package" 1>&2
1398     exit 1
1399     ;;
1400 esac
1401
1402 if test x${thread_file} = x; then
1403   # No thread file set by target-specific clauses in config.gcc,
1404   # so use file chosen by default logic above
1405   thread_file=${target_thread_file}
1406 fi
1407
1408 # Make gthr-default.h if we have a thread file.
1409 gthread_flags=
1410 if test $thread_file != single; then
1411   rm -f gthr-default.h
1412   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1413   gthread_flags=-DHAVE_GTHR_DEFAULT
1414 fi
1415 AC_SUBST(gthread_flags)
1416
1417 # --------
1418 # UNSORTED
1419 # --------
1420
1421 use_cxa_atexit=no
1422 if test x$enable___cxa_atexit = xyes || \
1423    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1424   if test x$host = x$target; then
1425     case $host in
1426       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1427       # keyed to flag_use_cxa_atexit
1428       *-*-mingw32*)
1429         use_cxa_atexit=yes
1430         ;;
1431       *)
1432         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1433           [echo "__cxa_atexit can't be enabled on this target"])
1434         ;;
1435     esac
1436   else
1437     # We can't check for __cxa_atexit when building a cross, so assume
1438     # it is available
1439     use_cxa_atexit=yes
1440   fi
1441   if test x$use_cxa_atexit = xyes; then
1442     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1443       [Define if you want to use __cxa_atexit, rather than atexit, to
1444       register C++ destructors for local statics and global objects.
1445       This is essential for fully standards-compliant handling of
1446       destructors, but requires __cxa_atexit in libc.])
1447   fi
1448 fi
1449
1450 use_getipinfo=yes
1451 if test x$with_system_libunwind = xyes; then
1452    if test x$host = x$target; then
1453      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1454    fi
1455 fi
1456 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1457 if test x$use_getipinfo = xyes; then
1458    AC_DEFINE(HAVE_GETIPINFO, 1,
1459         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1460 else
1461    echo "The system unwind library does not support _Unwind_GetIPInfo."
1462 fi
1463
1464 # Look for a file containing extra machine modes.
1465 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1466   extra_modes_file='$(srcdir)'/config/${extra_modes}
1467   AC_SUBST(extra_modes_file)
1468   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1469   [Define to the name of a file containing a list of extra machine modes
1470    for this architecture.])
1471 fi
1472
1473 # Convert extra_options into a form suitable for Makefile use.
1474 extra_opt_files=
1475 for f in $extra_options; do
1476   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1477 done
1478 AC_SUBST(extra_opt_files)
1479
1480 # auto-host.h is the file containing items generated by autoconf and is
1481 # the first file included by config.h.
1482 # If host=build, it is correct to have bconfig include auto-host.h
1483 # as well.  If host!=build, we are in error and need to do more
1484 # work to find out the build config parameters.
1485 if test x$host = x$build
1486 then
1487         build_auto=auto-host.h
1488 else
1489         # We create a subdir, then run autoconf in the subdir.
1490         # To prevent recursion we set host and build for the new
1491         # invocation of configure to the build for this invocation
1492         # of configure.
1493         tempdir=build.$$
1494         rm -rf $tempdir
1495         mkdir $tempdir
1496         cd $tempdir
1497         case ${srcdir} in
1498         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1499         *) realsrcdir=../${srcdir};;
1500         esac
1501         saved_CFLAGS="${CFLAGS}"
1502         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1503         ${realsrcdir}/configure \
1504                 --enable-languages=${enable_languages-all} \
1505                 --target=$target_alias --host=$build_alias --build=$build_alias
1506         CFLAGS="${saved_CFLAGS}"
1507
1508         # We just finished tests for the build machine, so rename
1509         # the file auto-build.h in the gcc directory.
1510         mv auto-host.h ../auto-build.h
1511         cd ..
1512         rm -rf $tempdir
1513         build_auto=auto-build.h
1514 fi
1515 AC_SUBST(build_subdir)
1516
1517 tm_file="${tm_file} defaults.h"
1518 tm_p_file="${tm_p_file} tm-preds.h"
1519 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1520 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1521 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1522 # put this back in temporarily.
1523 xm_file="auto-host.h ansidecl.h ${xm_file}"
1524
1525 # --------
1526 # UNSORTED
1527 # --------
1528
1529 changequote(,)dnl
1530 # Compile in configure arguments.
1531 if test -f configargs.h ; then
1532         # Being re-configured.
1533         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1534         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1535 else
1536         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1537 fi
1538
1539 # Double all backslashes and backslash all quotes to turn
1540 # gcc_config_arguments into a C string.
1541 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1542 $gcc_config_arguments
1543 EOF
1544 gcc_config_arguments_str=`cat conftest.out`
1545 rm -f conftest.out
1546
1547 cat > configargs.h <<EOF
1548 /* Generated automatically. */
1549 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1550 static const char thread_model[] = "$thread_file";
1551
1552 static const struct {
1553   const char *name, *value;
1554 } configure_default_options[] = $configure_default_options;
1555 EOF
1556 changequote([,])dnl
1557
1558 # Internationalization
1559 ZW_GNU_GETTEXT_SISTER_DIR
1560
1561 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1562 # -liconv on the link line twice.
1563 case "$LIBINTL" in *$LIBICONV*)
1564         LIBICONV= ;;
1565 esac
1566
1567 AC_ARG_ENABLE(secureplt,
1568 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1569 [], [])
1570
1571 # Windows32 Registry support for specifying GCC installation paths.
1572 AC_ARG_ENABLE(win32-registry,
1573 [  --disable-win32-registry
1574                           disable lookup of installation paths in the
1575                           Registry on Windows hosts
1576   --enable-win32-registry enable registry lookup (default)
1577   --enable-win32-registry=KEY
1578                           use KEY instead of GCC version as the last portion
1579                           of the registry key],,)
1580
1581 case $host_os in
1582   win32 | pe | cygwin* | mingw32* | uwin*)
1583     if test "x$enable_win32_registry" != xno; then
1584       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1585     fi
1586
1587     if test "x$enable_win32_registry" != xno; then
1588       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1589   [Define to 1 if installation paths should be looked up in the Windows
1590    Registry. Ignored on non-Windows hosts.])
1591
1592       if test "x$enable_win32_registry" != xyes \
1593          && test "x$enable_win32_registry" != x; then
1594         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1595   [Define to be the last component of the Windows registry key under which
1596    to look for installation paths.  The full key used will be
1597    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1598    The default is the GCC version number.])
1599       fi
1600     fi
1601   ;;
1602 esac
1603
1604 # Get an absolute path to the GCC top-level source directory
1605 holddir=`${PWDCMD-pwd}`
1606 cd $srcdir
1607 topdir=`${PWDCMD-pwd}`
1608 cd $holddir
1609
1610 # Conditionalize the makefile for this host machine.
1611 xmake_file=
1612 for f in ${host_xmake_file}
1613 do
1614         if test -f ${srcdir}/config/$f
1615         then
1616                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1617         fi
1618 done
1619
1620 # Conditionalize the makefile for this target machine.
1621 tmake_file_=
1622 for f in ${tmake_file}
1623 do
1624         if test -f ${srcdir}/config/$f
1625         then
1626                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1627         fi
1628 done
1629 tmake_file="${tmake_file_}"
1630
1631 # If the host doesn't support symlinks, modify CC in
1632 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1633 # Otherwise, we can use "CC=$(CC)".
1634 rm -f symtest.tem
1635 case "$LN_S" in
1636         *-s*)
1637                 cc_set_by_configure="\$(CC)"
1638                 quoted_cc_set_by_configure="\$(CC)"
1639                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1640                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1641                 ;;
1642         *)
1643                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1644                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1645                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1646                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1647                 ;;
1648 esac
1649
1650 # This is a terrible hack which will go away some day.
1651 host_cc_for_libada=${CC}
1652 AC_SUBST(host_cc_for_libada)
1653
1654 out_object_file=`basename $out_file .c`.o
1655
1656 tm_file_list="options.h"
1657 tm_include_list="options.h"
1658 for f in $tm_file; do
1659   case $f in
1660     defaults.h )
1661        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1662        tm_include_list="${tm_include_list} $f"
1663        ;;
1664     * )
1665        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1666        tm_include_list="${tm_include_list} config/$f"
1667        ;;
1668   esac
1669 done
1670
1671 tm_p_file_list=
1672 tm_p_include_list=
1673 for f in $tm_p_file; do
1674   case $f in
1675     tm-preds.h )
1676        tm_p_file_list="${tm_p_file_list} $f"
1677        tm_p_include_list="${tm_p_include_list} $f"
1678        ;;
1679     * )
1680        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1681        tm_p_include_list="${tm_p_include_list} config/$f"
1682   esac
1683 done
1684
1685 xm_file_list=
1686 xm_include_list=
1687 for f in $xm_file; do
1688   case $f in
1689     ansidecl.h )
1690        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1691        xm_include_list="${xm_include_list} $f"
1692        ;;
1693     auto-host.h )
1694        xm_file_list="${xm_file_list} $f"
1695        xm_include_list="${xm_include_list} $f"
1696        ;;
1697     * )
1698        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1699        xm_include_list="${xm_include_list} config/$f"
1700        ;;
1701   esac
1702 done
1703
1704 host_xm_file_list=
1705 host_xm_include_list=
1706 for f in $host_xm_file; do
1707   case $f in
1708     ansidecl.h )
1709        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1710        host_xm_include_list="${host_xm_include_list} $f"
1711        ;;
1712     auto-host.h )
1713        host_xm_file_list="${host_xm_file_list} $f"
1714        host_xm_include_list="${host_xm_include_list} $f"
1715        ;;
1716     * )
1717        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1718        host_xm_include_list="${host_xm_include_list} config/$f"
1719        ;;
1720   esac
1721 done
1722
1723 build_xm_file_list=
1724 for f in $build_xm_file; do
1725   case $f in
1726     ansidecl.h )
1727        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1728        build_xm_include_list="${build_xm_include_list} $f"
1729        ;;
1730     auto-build.h | auto-host.h )
1731        build_xm_file_list="${build_xm_file_list} $f"
1732        build_xm_include_list="${build_xm_include_list} $f"
1733        ;;
1734     * )
1735        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1736        build_xm_include_list="${build_xm_include_list} config/$f"
1737        ;;
1738   esac
1739 done
1740
1741 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1742 # cross-compiler which does not use the native headers and libraries.
1743 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1744 CROSS=                                          AC_SUBST(CROSS)
1745 ALL=all.internal                                AC_SUBST(ALL)
1746 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1747
1748 if test "x$with_build_sysroot" != x; then
1749   build_system_header_dir=$with_build_sysroot'$(NATIVE_SYSTEM_HEADER_DIR)'
1750 else
1751   # This value is used, even on a native system, because
1752   # CROSS_SYSTEM_HEADER_DIR is just
1753   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1754   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1755 fi
1756
1757 if test x$host != x$target
1758 then
1759         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1760         ALL=all.cross
1761         SYSTEM_HEADER_DIR=$build_system_header_dir
1762         case "$host","$target" in
1763         # Darwin crosses can use the host system's libraries and headers,
1764         # because of the fat library support.  Of course, it must be the
1765         # same version of Darwin on both sides.  Allow the user to
1766         # just say --target=foo-darwin without a version number to mean
1767         # "the version on this system".
1768             *-*-darwin*,*-*-darwin*)
1769                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1770                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1771                 if test $hostos = $targetos -o $targetos = darwin ; then
1772                     CROSS=
1773                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1774                     with_headers=yes
1775                 fi
1776                 ;;
1777
1778             i?86-*-*,x86_64-*-* \
1779             | powerpc*-*-*,powerpc64*-*-*)
1780                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1781         esac
1782 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1783         SYSTEM_HEADER_DIR=$build_system_header_dir
1784 fi
1785
1786 # If this is a cross-compiler that does not
1787 # have its own set of headers then define
1788 # inhibit_libc
1789
1790 # If this is using newlib, without having the headers available now,
1791 # then define inhibit_libc in LIBGCC2_CFLAGS.
1792 # This prevents libgcc2 from containing any code which requires libc
1793 # support.
1794 inhibit_libc=false
1795 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1796        test x$with_newlib = xyes ; } &&
1797      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1798        inhibit_libc=true
1799 fi
1800 AC_SUBST(inhibit_libc)
1801
1802 # When building gcc with a cross-compiler, we need to adjust things so
1803 # that the generator programs are still built with the native compiler.
1804 # Also, we cannot run fixincludes or fix-header.
1805
1806 # These are the normal (build=host) settings:
1807 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1808 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1809 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1810
1811 # Possibly disable fixproto, on a per-target basis.
1812 case ${use_fixproto} in
1813   no)
1814     STMP_FIXPROTO=
1815     ;;
1816   yes)
1817     STMP_FIXPROTO=stmp-fixproto
1818     ;;
1819 esac
1820 AC_SUBST(STMP_FIXPROTO)
1821
1822 # And these apply if build != host, or we are generating coverage data
1823 if test x$build != x$host || test "x$coverage_flags" != x
1824 then
1825     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1826
1827     if test "x$TARGET_SYSTEM_ROOT" = x; then
1828         if test "x$STMP_FIXPROTO" != x; then
1829           STMP_FIXPROTO=stmp-install-fixproto
1830         fi
1831     fi
1832 fi
1833
1834 # Expand extra_headers to include complete path.
1835 # This substitutes for lots of t-* files.
1836 extra_headers_list=
1837 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1838 for file in ${extra_headers} ; do
1839   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1840 done
1841
1842 # Define collect2 in Makefile.
1843 case $host_can_use_collect2 in
1844   no) collect2= ;;
1845   *) collect2='collect2$(exeext)' ;;
1846 esac
1847 AC_SUBST([collect2])
1848
1849 # Add a definition of USE_COLLECT2 if system wants one.
1850 case $use_collect2 in
1851   no) use_collect2= ;;
1852   "") ;;
1853   *)
1854     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1855     xm_defines="${xm_defines} USE_COLLECT2"
1856     case $host_can_use_collect2 in
1857       no)
1858         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1859         ;;
1860     esac
1861     ;;
1862 esac
1863
1864 # ---------------------------
1865 # Assembler & linker features
1866 # ---------------------------
1867
1868 # Identify the assembler which will work hand-in-glove with the newly
1869 # built GCC, so that we can examine its features.  This is the assembler
1870 # which will be driven by the driver program.
1871 #
1872 # If build != host, and we aren't building gas in-tree, we identify a
1873 # build->target assembler and hope that it will have the same features
1874 # as the host->target assembler we'll be using.
1875 gcc_cv_gas_major_version=
1876 gcc_cv_gas_minor_version=
1877 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1878
1879 m4_pattern_allow([AS_FOR_TARGET])dnl
1880 AS_VAR_SET_IF(gcc_cv_as,, [
1881 if test -x "$DEFAULT_ASSEMBLER"; then
1882         gcc_cv_as="$DEFAULT_ASSEMBLER"
1883 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1884      && test -f ../gas/Makefile \
1885      && test x$build = x$host; then
1886         gcc_cv_as=../gas/as-new$build_exeext
1887 elif test -x as$build_exeext; then
1888         # Build using assembler in the current directory.
1889         gcc_cv_as=./as$build_exeext
1890 elif test -x $AS_FOR_TARGET; then
1891         gcc_cv_as="$AS_FOR_TARGET"
1892 else
1893         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1894 fi])
1895
1896 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1897 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1898
1899 AC_MSG_CHECKING(what assembler to use)
1900 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1901   # Single tree build which includes gas.  We want to prefer it
1902   # over whatever linker top-level may have detected, since
1903   # we'll use what we're building after installation anyway.
1904   AC_MSG_RESULT(newly built gas)
1905   in_tree_gas=yes
1906   _gcc_COMPUTE_GAS_VERSION
1907   in_tree_gas_is_elf=no
1908   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1909      || (grep 'obj_format = multi' ../gas/Makefile \
1910          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1911   then
1912     in_tree_gas_is_elf=yes
1913   fi
1914 else
1915   AC_MSG_RESULT($gcc_cv_as)
1916   in_tree_gas=no
1917 fi
1918
1919 # Identify the linker which will work hand-in-glove with the newly
1920 # built GCC, so that we can examine its features.  This is the linker
1921 # which will be driven by the driver program.
1922 #
1923 # If build != host, and we aren't building gas in-tree, we identify a
1924 # build->target linker and hope that it will have the same features
1925 # as the host->target linker we'll be using.
1926 gcc_cv_gld_major_version=
1927 gcc_cv_gld_minor_version=
1928 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1929 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1930
1931 AS_VAR_SET_IF(gcc_cv_ld,, [
1932 if test -x "$DEFAULT_LINKER"; then
1933         gcc_cv_ld="$DEFAULT_LINKER"
1934 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1935      && test -f ../ld/Makefile \
1936      && test x$build = x$host; then
1937         gcc_cv_ld=../ld/ld-new$build_exeext
1938 elif test -x collect-ld$build_exeext; then
1939         # Build using linker in the current directory.
1940         gcc_cv_ld=./collect-ld$build_exeext
1941 elif test -x $LD_FOR_TARGET; then
1942         gcc_cv_ld="$LD_FOR_TARGET"
1943 else
1944         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1945 fi])
1946
1947 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1948 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1949
1950 AC_MSG_CHECKING(what linker to use)
1951 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1952         # Single tree build which includes ld.  We want to prefer it
1953         # over whatever linker top-level may have detected, since
1954         # we'll use what we're building after installation anyway.
1955         AC_MSG_RESULT(newly built ld)
1956         in_tree_ld=yes
1957         in_tree_ld_is_elf=no
1958         if (grep 'EMUL = .*elf' ../ld/Makefile \
1959             || grep 'EMUL = .*linux' ../ld/Makefile \
1960             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1961           in_tree_ld_is_elf=yes
1962         fi
1963         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1964         do
1965 changequote(,)dnl
1966                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1967                 if test x$gcc_cv_gld_version != x; then
1968                         break
1969                 fi
1970         done
1971         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1972         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1973 changequote([,])dnl
1974 else
1975         AC_MSG_RESULT($gcc_cv_ld)
1976         in_tree_ld=no
1977 fi
1978
1979 # Figure out what nm we will be using.
1980 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1981 AS_VAR_SET_IF(gcc_cv_nm,, [
1982 if test -f $gcc_cv_binutils_srcdir/configure.in \
1983      && test -f ../binutils/Makefile \
1984      && test x$build = x$host; then
1985         gcc_cv_nm=../binutils/nm-new$build_exeext
1986 elif test -x nm$build_exeext; then
1987         gcc_cv_nm=./nm$build_exeext
1988 elif test -x $NM_FOR_TARGET; then
1989         gcc_cv_nm="$NM_FOR_TARGET"
1990 else
1991         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1992 fi])
1993
1994 AC_MSG_CHECKING(what nm to use)
1995 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1996         # Single tree build which includes binutils.
1997         AC_MSG_RESULT(newly built nm)
1998         in_tree_nm=yes
1999 else
2000         AC_MSG_RESULT($gcc_cv_nm)
2001         in_tree_nm=no
2002 fi
2003
2004 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2005 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2006
2007 # Figure out what objdump we will be using.
2008 AS_VAR_SET_IF(gcc_cv_objdump,, [
2009 if test -f $gcc_cv_binutils_srcdir/configure.in \
2010      && test -f ../binutils/Makefile \
2011      && test x$build = x$host; then
2012         # Single tree build which includes binutils.
2013         gcc_cv_objdump=../binutils/objdump$build_exeext
2014 elif test -x objdump$build_exeext; then
2015         gcc_cv_objdump=./objdump$build_exeext
2016 elif test -x $OBJDUMP_FOR_TARGET; then
2017         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2018 else
2019         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2020 fi])
2021
2022 AC_MSG_CHECKING(what objdump to use)
2023 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2024         # Single tree build which includes binutils.
2025         AC_MSG_RESULT(newly built objdump)
2026 elif test x$gcc_cv_objdump = x; then
2027         AC_MSG_RESULT(not found)
2028 else
2029         AC_MSG_RESULT($gcc_cv_objdump)
2030 fi
2031
2032 # Figure out what assembler alignment features are present.
2033 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2034  [2,6,0],,
2035 [.balign 4
2036 .p2align 2],,
2037 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2038   [Define if your assembler supports .balign and .p2align.])])
2039
2040 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2041  [2,8,0],,
2042  [.p2align 4,,7],,
2043 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2044   [Define if your assembler supports specifying the maximum number
2045    of bytes to skip when using the GAS .p2align command.])])
2046
2047 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2048  [2,8,0],,
2049  [.literal16],,
2050 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2051   [Define if your assembler supports .literal16.])])
2052
2053 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2054  [elf,2,9,0],,
2055  [conftest_label1: .word 0
2056 .subsection -1
2057 conftest_label2: .word 0
2058 .previous],
2059  [if test x$gcc_cv_nm != x; then
2060     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2061     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2062     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2063     then :
2064     else gcc_cv_as_subsection_m1=yes
2065     fi
2066     rm -f conftest.nm1 conftest.nm2
2067   fi],
2068  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2069   [Define if your assembler supports .subsection and .subsection -1 starts
2070    emitting at the beginning of your section.])])
2071
2072 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2073  [2,2,0],,
2074  [      .weak foobar],,
2075 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2076
2077 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2078  [2,17,0],,
2079  [      .weakref foobar, barfnot],,
2080 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2081
2082 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2083  [2,15,91],,
2084  [      .SPACE $TEXT$
2085         .NSUBSPA $CODE$,COMDAT],,
2086 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2087
2088 # .hidden needs to be supported in both the assembler and the linker,
2089 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2090 # This is irritatingly difficult to feature test for; we have to check the
2091 # date string after the version number.  If we've got an in-tree
2092 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2093 # to be safe.
2094 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2095 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2096  [elf,2,13,0],,
2097 [       .hidden foobar
2098 foobar:])
2099
2100 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2101 [if test $in_tree_ld = yes ; then
2102   gcc_cv_ld_hidden=no
2103   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2104      && test $in_tree_ld_is_elf = yes; then
2105      gcc_cv_ld_hidden=yes
2106   fi
2107 else
2108   gcc_cv_ld_hidden=yes
2109   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2110   if echo "$ld_ver" | grep GNU > /dev/null; then
2111 changequote(,)dnl
2112     ld_vers=`echo $ld_ver | sed -n \
2113         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2114         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2115         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2116         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2117         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2118         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2119         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   -].*$,\1,p'`
2120     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2121     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2122     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2123     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2124     if test 0"$ld_date" -lt 20020404; then
2125       if test -n "$ld_date"; then
2126         # If there was date string, but was earlier than 2002-04-04, fail
2127         gcc_cv_ld_hidden=no
2128       elif test -z "$ld_vers"; then
2129         # If there was no date string nor ld version number, something is wrong
2130         gcc_cv_ld_hidden=no
2131       else
2132         test -z "$ld_vers_patch" && ld_vers_patch=0
2133         if test "$ld_vers_major" -lt 2; then
2134           gcc_cv_ld_hidden=no
2135         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2136           gcc_cv_ld_hidden="no"
2137         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2138           gcc_cv_ld_hidden=no
2139         fi
2140       fi
2141 changequote([,])dnl
2142     fi
2143   else
2144     case "${target}" in
2145       hppa64*-*-hpux* | ia64*-*-hpux*)
2146         gcc_cv_ld_hidden=yes
2147         ;;
2148       *)
2149         gcc_cv_ld_hidden=no
2150         ;;
2151     esac
2152   fi
2153 fi])
2154 libgcc_visibility=no
2155 AC_SUBST(libgcc_visibility)
2156 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2157 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2158   libgcc_visibility=yes
2159   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2160   [Define if your assembler and linker support .hidden.])
2161 fi
2162
2163 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2164 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2165   [elf,2,11,0],,
2166 [       .data
2167         .uleb128 L2 - L1
2168 L1:
2169         .uleb128 1280
2170         .sleb128 -1010
2171 L2:],
2172  [# GAS versions before 2.11 do not support uleb128,
2173   # despite appearing to.
2174   # ??? There exists an elf-specific test that will crash
2175   # the assembler.  Perhaps it's better to figure out whether
2176   # arbitrary sections are supported and try the test.
2177   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2178   if echo "$as_ver" | grep GNU > /dev/null; then
2179 changequote(,)dnl
2180     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2181     as_major=`echo $as_ver | sed 's/\..*//'`
2182     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2183 changequote([,])dnl
2184     if test $as_major -eq 2 && test $as_minor -lt 11
2185     then :
2186     else gcc_cv_as_leb128=yes
2187     fi
2188   fi],
2189   [AC_DEFINE(HAVE_AS_LEB128, 1,
2190     [Define if your assembler supports .sleb128 and .uleb128.])])
2191
2192 # GAS versions up to and including 2.11.0 may mis-optimize
2193 # .eh_frame data.
2194 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2195   [elf,2,12,0],,
2196 [       .text
2197 .LFB1:
2198         .4byte  0
2199 .L1:
2200         .4byte  0
2201 .LFE1:
2202         .section        .eh_frame,"aw",@progbits
2203 __FRAME_BEGIN__:
2204         .4byte  .LECIE1-.LSCIE1
2205 .LSCIE1:
2206         .4byte  0x0
2207         .byte   0x1
2208         .ascii "z\0"
2209         .byte   0x1
2210         .byte   0x78
2211         .byte   0x1a
2212         .byte   0x0
2213         .byte   0x4
2214         .4byte  1
2215         .p2align 1
2216 .LECIE1:
2217 .LSFDE1:
2218         .4byte  .LEFDE1-.LASFDE1
2219 .LASFDE1:
2220         .4byte  .LASFDE1-__FRAME_BEGIN__
2221         .4byte  .LFB1
2222         .4byte  .LFE1-.LFB1
2223         .byte   0x4
2224         .4byte  .LFE1-.LFB1
2225         .byte   0x4
2226         .4byte  .L1-.LFB1
2227 .LEFDE1:],
2228 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2229 cat > conftest.lit <<EOF
2230  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2231  0010 01000000 12000000 18000000 00000000  ................
2232  0020 08000000 04080000 0044               .........D      @&t@
2233 EOF
2234 cat > conftest.big <<EOF
2235  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2236  0010 00000001 00000012 00000018 00000000  ................
2237  0020 00000008 04000000 0844               .........D      @&t@
2238 EOF
2239   # If the assembler didn't choke, and we can objdump,
2240   # and we got the correct data, then succeed.
2241   # The text in the here-document typically retains its unix-style line
2242   # endings, while the output of objdump will use host line endings.
2243   # Therefore, use diff -b for the comparisons.
2244   if test x$gcc_cv_objdump != x \
2245   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2246      | tail -3 > conftest.got \
2247   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2248     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2249   then
2250     gcc_cv_as_eh_frame=yes
2251   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2252     gcc_cv_as_eh_frame=buggy
2253   else
2254     # Uh oh, what do we do now?
2255     gcc_cv_as_eh_frame=no
2256   fi])
2257
2258 if test $gcc_cv_as_eh_frame = buggy; then
2259   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2260   [Define if your assembler mis-optimizes .eh_frame data.])
2261 fi
2262
2263 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2264  [elf,2,12,0], [--fatal-warnings],
2265  [.section .rodata.str, "aMS", @progbits, 1])
2266 if test $gcc_cv_as_shf_merge = no; then
2267   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2268     [elf,2,12,0], [--fatal-warnings],
2269     [.section .rodata.str, "aMS", %progbits, 1])
2270 fi
2271 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2272   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2273 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2274
2275 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2276  [elf,2,16,0], [--fatal-warnings],
2277  [.section .text,"axG",@progbits,.foo,comdat])
2278 if test $gcc_cv_as_comdat_group = yes; then
2279   gcc_cv_as_comdat_group_percent=no
2280 else
2281  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2282    [elf,2,16,0], [--fatal-warnings],
2283    [.section .text,"axG",%progbits,.foo,comdat])
2284 fi
2285 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2286   comdat_group=yes
2287   if test 0"$ld_date" -lt 20050308; then
2288     if test -n "$ld_date"; then
2289       # If there was date string, but was earlier than 2005-03-08, fail
2290       comdat_group=no
2291     elif test "$ld_vers_major" -lt 2; then
2292       comdat_group=no
2293     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2294       comdat_group=no
2295     fi
2296   fi
2297 else
2298   # assume linkers other than GNU ld don't support COMDAT group
2299   comdat_group=no
2300 fi
2301 if test $comdat_group = no; then
2302   gcc_cv_as_comdat_group=no
2303   gcc_cv_as_comdat_group_percent=no
2304 fi
2305 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2306   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2307 [Define 0/1 if your assembler and linker support COMDAT groups.])
2308
2309 # Thread-local storage - the check is heavily parametrized.
2310 conftest_s=
2311 tls_first_major=
2312 tls_first_minor=
2313 tls_as_opt=
2314 case "$target" in
2315 changequote(,)dnl
2316   alpha*-*-*)
2317     conftest_s='
2318         .section ".tdata","awT",@progbits
2319 foo:    .long   25
2320         .text
2321         ldq     $27,__tls_get_addr($29)         !literal!1
2322         lda     $16,foo($29)                    !tlsgd!1
2323         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2324         ldq     $27,__tls_get_addr($29)         !literal!2
2325         lda     $16,foo($29)                    !tlsldm!2
2326         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2327         ldq     $1,foo($29)                     !gotdtprel
2328         ldah    $2,foo($29)                     !dtprelhi
2329         lda     $3,foo($2)                      !dtprello
2330         lda     $4,foo($29)                     !dtprel
2331         ldq     $1,foo($29)                     !gottprel
2332         ldah    $2,foo($29)                     !tprelhi
2333         lda     $3,foo($2)                      !tprello
2334         lda     $4,foo($29)                     !tprel'
2335         tls_first_major=2
2336         tls_first_minor=13
2337         tls_as_opt=--fatal-warnings
2338         ;;
2339   frv*-*-*)
2340     conftest_s='
2341         .section ".tdata","awT",@progbits
2342 x:      .long   25
2343         .text
2344         call    #gettlsoff(x)'
2345         tls_first_major=2
2346         tls_first_minor=14
2347         ;;
2348   hppa*-*-linux*)
2349     conftest_s='
2350 t1:     .reg    %r20
2351 t2:     .reg    %r21
2352 gp:     .reg    %r19
2353         .section ".tdata","awT",@progbits
2354 foo:    .long   25
2355         .text
2356         .align  4
2357         addil LT%foo-$tls_gdidx$,gp
2358         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2359         b __tls_get_addr
2360         nop
2361         addil LT%foo-$tls_ldidx$,gp
2362         b __tls_get_addr
2363         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2364         addil LR%foo-$tls_dtpoff$,%ret0
2365         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2366         mfctl %cr27,%t1
2367         addil LT%foo-$tls_ieoff$,gp
2368         ldw RT%foo-$tls_ieoff$(%r1),%t2
2369         add %t1,%t2,%t3
2370         mfctl %cr27,%t1
2371         addil LR%foo-$tls_leoff$,%t1
2372         ldo RR%foo-$tls_leoff$(%r1),%t2'
2373         tls_first_major=2
2374         tls_first_minor=15
2375         tls_as_opt=--fatal-warnings
2376         ;;
2377   arm*-*-*)
2378     conftest_s='
2379         .section ".tdata","awT",%progbits
2380 foo:    .long   25
2381         .text
2382 .word foo(gottpoff)
2383 .word foo(tpoff)
2384 .word foo(tlsgd)
2385 .word foo(tlsldm)
2386 .word foo(tlsldo)'
2387         tls_first_major=2
2388         tls_first_minor=17
2389         ;;
2390   i[34567]86-*-*)
2391     conftest_s='
2392         .section ".tdata","awT",@progbits
2393 foo:    .long   25
2394         .text
2395         movl    %gs:0, %eax
2396         leal    foo@TLSGD(,%ebx,1), %eax
2397         leal    foo@TLSLDM(%ebx), %eax
2398         leal    foo@DTPOFF(%eax), %edx
2399         movl    foo@GOTTPOFF(%ebx), %eax
2400         subl    foo@GOTTPOFF(%ebx), %eax
2401         addl    foo@GOTNTPOFF(%ebx), %eax
2402         movl    foo@INDNTPOFF, %eax
2403         movl    $foo@TPOFF, %eax
2404         subl    $foo@TPOFF, %eax
2405         leal    foo@NTPOFF(%ecx), %eax'
2406         tls_first_major=2
2407         tls_first_minor=14
2408         tls_as_opt=--fatal-warnings
2409         ;;
2410   x86_64-*-*)
2411     conftest_s='
2412         .section ".tdata","awT",@progbits
2413 foo:    .long   25
2414         .text
2415         movq    %fs:0, %rax
2416         leaq    foo@TLSGD(%rip), %rdi
2417         leaq    foo@TLSLD(%rip), %rdi
2418         leaq    foo@DTPOFF(%rax), %rdx
2419         movq    foo@GOTTPOFF(%rip), %rax
2420         movq    $foo@TPOFF, %rax'
2421         tls_first_major=2
2422         tls_first_minor=14
2423         tls_as_opt=--fatal-warnings
2424         ;;
2425   ia64-*-*)
2426     conftest_s='
2427         .section ".tdata","awT",@progbits
2428 foo:    data8   25
2429         .text
2430         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2431         addl    r17 = @ltoff(@dtprel(foo#)), gp
2432         addl    r18 = @ltoff(@tprel(foo#)), gp
2433         addl    r19 = @dtprel(foo#), gp
2434         adds    r21 = @dtprel(foo#), r13
2435         movl    r23 = @dtprel(foo#)
2436         addl    r20 = @tprel(foo#), gp
2437         adds    r22 = @tprel(foo#), r13
2438         movl    r24 = @tprel(foo#)'
2439         tls_first_major=2
2440         tls_first_minor=13
2441         tls_as_opt=--fatal-warnings
2442         ;;
2443   mips*-*-*)
2444     conftest_s='
2445         .section .tdata,"awT",@progbits
2446 x:
2447         .word 2
2448         .text
2449         addiu $4, $28, %tlsgd(x)
2450         addiu $4, $28, %tlsldm(x)
2451         lui $4, %dtprel_hi(x)
2452         addiu $4, $4, %dtprel_lo(x)
2453         lw $4, %gottprel(x)($28)
2454         lui $4, %tprel_hi(x)
2455         addiu $4, $4, %tprel_lo(x)'
2456         tls_first_major=2
2457         tls_first_minor=16
2458         tls_as_opt='-32 --fatal-warnings'
2459         ;;
2460   powerpc-*-*)
2461     conftest_s='
2462         .section ".tdata","awT",@progbits
2463         .align 2
2464 ld0:    .space 4
2465 ld1:    .space 4
2466 x1:     .space 4
2467 x2:     .space 4
2468 x3:     .space 4
2469         .text
2470         addi 3,31,ld0@got@tlsgd
2471         bl __tls_get_addr
2472         addi 3,31,x1@got@tlsld
2473         bl __tls_get_addr
2474         addi 9,3,x1@dtprel
2475         addis 9,3,x2@dtprel@ha
2476         addi 9,9,x2@dtprel@l
2477         lwz 9,x3@got@tprel(31)
2478         add 9,9,x@tls
2479         addi 9,2,x1@tprel
2480         addis 9,2,x2@tprel@ha
2481         addi 9,9,x2@tprel@l'
2482         tls_first_major=2
2483         tls_first_minor=14
2484         tls_as_opt="-a32 --fatal-warnings"
2485         ;;
2486   powerpc64-*-*)
2487     conftest_s='
2488         .section ".tdata","awT",@progbits
2489         .align 3
2490 ld0:    .space 8
2491 ld1:    .space 8
2492 x1:     .space 8
2493 x2:     .space 8
2494 x3:     .space 8
2495         .text
2496         addi 3,2,ld0@got@tlsgd
2497         bl .__tls_get_addr
2498         nop
2499         addi 3,2,ld1@toc
2500         bl .__tls_get_addr
2501         nop
2502         addi 3,2,x1@got@tlsld
2503         bl .__tls_get_addr
2504         nop
2505         addi 9,3,x1@dtprel
2506         bl .__tls_get_addr
2507         nop
2508         addis 9,3,x2@dtprel@ha
2509         addi 9,9,x2@dtprel@l
2510         bl .__tls_get_addr
2511         nop
2512         ld 9,x3@got@dtprel(2)
2513         add 9,9,3
2514         bl .__tls_get_addr
2515         nop'
2516         tls_first_major=2
2517         tls_first_minor=14
2518         tls_as_opt="-a64 --fatal-warnings"
2519         ;;
2520   s390-*-*)
2521     conftest_s='
2522         .section ".tdata","awT",@progbits
2523 foo:    .long   25
2524         .text
2525         .long   foo@TLSGD
2526         .long   foo@TLSLDM
2527         .long   foo@DTPOFF
2528         .long   foo@NTPOFF
2529         .long   foo@GOTNTPOFF
2530         .long   foo@INDNTPOFF
2531         l       %r1,foo@GOTNTPOFF(%r12)
2532         l       %r1,0(%r1):tls_load:foo
2533         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2534         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2535         tls_first_major=2
2536         tls_first_minor=14
2537         tls_as_opt="-m31 --fatal-warnings"
2538         ;;
2539   s390x-*-*)
2540     conftest_s='
2541         .section ".tdata","awT",@progbits
2542 foo:    .long   25
2543         .text
2544         .quad   foo@TLSGD
2545         .quad   foo@TLSLDM
2546         .quad   foo@DTPOFF
2547         .quad   foo@NTPOFF
2548         .quad   foo@GOTNTPOFF
2549         lg      %r1,foo@GOTNTPOFF(%r12)
2550         larl    %r1,foo@INDNTPOFF
2551         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2552         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2553         tls_first_major=2
2554         tls_first_minor=14
2555         tls_as_opt="-m64 -Aesame --fatal-warnings"
2556         ;;
2557   sh-*-* | sh[34]-*-*)
2558     conftest_s='
2559         .section ".tdata","awT",@progbits
2560 foo:    .long   25
2561         .text
2562         .long   foo@TLSGD
2563         .long   foo@TLSLDM
2564         .long   foo@DTPOFF
2565         .long   foo@GOTTPOFF
2566         .long   foo@TPOFF'
2567         tls_first_major=2
2568         tls_first_minor=13
2569         tls_as_opt=--fatal-warnings
2570         ;;
2571   sparc*-*-*)
2572     case "$target" in
2573       sparc*-sun-solaris2.[56789]*)
2574         # TLS was introduced in the Solaris 9 4/04 release but
2575         # we do not enable it by default on Solaris 9 either.
2576         if test "x$enable_tls" = xyes ; then
2577           on_solaris=yes
2578         else
2579           enable_tls=no;
2580         fi
2581         ;;
2582       sparc*-sun-solaris2.*)
2583         on_solaris=yes
2584         ;;
2585       *)
2586         on_solaris=no
2587         ;;
2588     esac
2589     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2590       conftest_s='
2591         .section ".tdata",#alloc,#write,#tls
2592 foo:    .long   25
2593         .text
2594         sethi   %tgd_hi22(foo), %o0
2595         add     %o0, %tgd_lo10(foo), %o1
2596         add     %l7, %o1, %o0, %tgd_add(foo)
2597         call    __tls_get_addr, %tgd_call(foo)
2598         sethi   %tldm_hi22(foo), %l1
2599         add     %l1, %tldm_lo10(foo), %l2
2600         add     %l7, %l2, %o0, %tldm_add(foo)
2601         call    __tls_get_addr, %tldm_call(foo)
2602         sethi   %tldo_hix22(foo), %l3
2603         xor     %l3, %tldo_lox10(foo), %l4
2604         add     %o0, %l4, %l5, %tldo_add(foo)
2605         sethi   %tie_hi22(foo), %o3
2606         add     %o3, %tie_lo10(foo), %o3
2607         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2608         add     %g7, %o2, %o4, %tie_add(foo)
2609         sethi   %tle_hix22(foo), %l1
2610         xor     %l1, %tle_lox10(foo), %o5
2611         ld      [%g7 + %o5], %o1'
2612         tls_first_major=0
2613         tls_first_minor=0
2614     else
2615       conftest_s='
2616         .section ".tdata","awT",@progbits
2617 foo:    .long   25
2618         .text
2619         sethi   %tgd_hi22(foo), %o0
2620         add     %o0, %tgd_lo10(foo), %o1
2621         add     %l7, %o1, %o0, %tgd_add(foo)
2622         call    __tls_get_addr, %tgd_call(foo)
2623         sethi   %tldm_hi22(foo), %l1
2624         add     %l1, %tldm_lo10(foo), %l2
2625         add     %l7, %l2, %o0, %tldm_add(foo)
2626         call    __tls_get_addr, %tldm_call(foo)
2627         sethi   %tldo_hix22(foo), %l3
2628         xor     %l3, %tldo_lox10(foo), %l4
2629         add     %o0, %l4, %l5, %tldo_add(foo)
2630         sethi   %tie_hi22(foo), %o3
2631         add     %o3, %tie_lo10(foo), %o3
2632         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2633         add     %g7, %o2, %o4, %tie_add(foo)
2634         sethi   %tle_hix22(foo), %l1
2635         xor     %l1, %tle_lox10(foo), %o5
2636         ld      [%g7 + %o5], %o1'
2637         tls_first_major=2
2638         tls_first_minor=14
2639         tls_as_opt="-32 --fatal-warnings"
2640       fi
2641         ;;
2642 changequote([,])dnl
2643 esac
2644 set_have_as_tls=no
2645 if test "x$enable_tls" = xno ; then
2646   : # TLS explicitly disabled.
2647 elif test "x$enable_tls" = xyes ; then
2648   set_have_as_tls=yes # TLS explicitly enabled.
2649 elif test -z "$tls_first_major"; then
2650   : # If we don't have a check, assume no support.
2651 else
2652   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2653   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2654   [set_have_as_tls=yes])
2655 fi
2656 if test $set_have_as_tls = yes ; then
2657   AC_DEFINE(HAVE_AS_TLS, 1,
2658             [Define if your assembler supports thread-local storage.])
2659 fi
2660
2661 # Target-specific assembler checks.
2662
2663 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2664 gcc_cv_ld_static_dynamic=no
2665 if test $in_tree_ld = yes ; then
2666   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2667     gcc_cv_ld_static_dynamic=yes
2668   fi
2669 elif test x$gcc_cv_ld != x; then
2670         # Check if linker supports -Bstatic/-Bdynamic option
2671         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2672           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2673                 gcc_cv_ld_static_dynamic=yes
2674         fi
2675 fi
2676 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2677         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2678 [Define if your linker supports -Bstatic/-Bdynamic option.])
2679 fi
2680 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2681
2682 if test x"$demangler_in_ld" = xyes; then
2683   AC_MSG_CHECKING(linker --demangle support)
2684   gcc_cv_ld_demangle=no
2685   if test $in_tree_ld = yes; then
2686     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2687       gcc_cv_ld_demangle=yes
2688     fi
2689   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2690     # Check if the GNU linker supports --demangle option
2691     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2692       gcc_cv_ld_demangle=yes
2693     fi
2694   fi
2695   if test x"$gcc_cv_ld_demangle" = xyes; then
2696     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2697 [Define if your linker supports --demangle option.])
2698   fi
2699   AC_MSG_RESULT($gcc_cv_ld_demangle)
2700 fi
2701
2702 case "$target" in
2703   # All TARGET_ABI_OSF targets.
2704   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2705     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2706         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2707 [       .set nomacro
2708         .text
2709         extbl   $3, $2, $3      !lituse_bytoff!1
2710         ldq     $2, a($29)      !literal!1
2711         ldq     $4, b($29)      !literal!2
2712         ldq_u   $3, 0($2)       !lituse_base!1
2713         ldq     $27, f($29)     !literal!5
2714         jsr     $26, ($27), f   !lituse_jsr!5
2715         ldah    $29, 0($26)     !gpdisp!3
2716         lda     $0, c($29)      !gprel
2717         ldah    $1, d($29)      !gprelhigh
2718         lda     $1, d($1)       !gprellow
2719         lda     $29, 0($29)     !gpdisp!3],,
2720     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2721   [Define if your assembler supports explicit relocations.])])
2722     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2723         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2724 [       .set nomacro
2725         .text
2726         ldq     $27, a($29)     !literal!1
2727         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2728     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2729   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2730     ;;
2731
2732   cris-*-*)
2733     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2734       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2735       [-no-mul-bug-abort], [.text],,
2736       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2737                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2738     ;;
2739
2740   sparc*-*-*)
2741     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2742       [.register %g2, #scratch],,
2743       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2744                 [Define if your assembler supports .register.])])
2745
2746     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2747       [-relax], [.text],,
2748       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2749                 [Define if your assembler supports -relax option.])])
2750
2751     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2752       gcc_cv_as_sparc_ua_pcrel,,
2753       [-K PIC],
2754 [.text
2755 foo:
2756         nop
2757 .data
2758 .align 4
2759 .byte 0
2760 .uaword %r_disp32(foo)],
2761       [if test x$gcc_cv_ld != x \
2762        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2763          gcc_cv_as_sparc_ua_pcrel=yes
2764        fi
2765        rm -f conftest],
2766       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2767                 [Define if your assembler and linker support unaligned PC relative relocs.])
2768
2769       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2770         gcc_cv_as_sparc_ua_pcrel_hidden,,
2771         [-K PIC],
2772 [.data
2773 .align 4
2774 .byte 0x31
2775 .uaword %r_disp32(foo)
2776 .byte 0x32, 0x33, 0x34
2777 .global foo
2778 .hidden foo
2779 foo:
2780 .skip 4],
2781         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2782          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2783          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2784             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2785             if $gcc_cv_objdump -R conftest 2> /dev/null \
2786                | grep 'DISP32' > /dev/null 2>&1; then
2787                 :
2788             else
2789                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2790             fi
2791          fi
2792          rm -f conftest],
2793          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2794                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2795     ]) # unaligned pcrel relocs
2796
2797     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2798       gcc_cv_as_sparc_offsetable_lo10,,
2799       [-xarch=v9],
2800 [.text
2801         or %g1, %lo(ab) + 12, %g1
2802         or %g1, %lo(ab + 12), %g1],
2803       [if test x$gcc_cv_objdump != x \
2804        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2805           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2806          gcc_cv_as_sparc_offsetable_lo10=yes
2807        fi],
2808        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2809                  [Define if your assembler supports offsetable %lo().])])
2810     ;;
2811
2812 changequote(,)dnl
2813   i[34567]86-*-* | x86_64-*-*)
2814 changequote([,])dnl
2815     case $target_os in
2816       cygwin* | pe | mingw32*)
2817         # Used for DWARF 2 in PE
2818         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2819           gcc_cv_as_ix86_pe_secrel32,
2820           [2,15,91],,
2821 [.text
2822 foo:    nop
2823 .data
2824         .secrel32 foo],
2825           [if test x$gcc_cv_ld != x \
2826            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2827              gcc_cv_as_ix86_pe_secrel32=yes
2828            fi
2829            rm -f conftest],
2830           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2831             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2832         ;;
2833     esac
2834
2835     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2836        gcc_cv_as_ix86_filds_fists,
2837       [2,9,0],, [filds mem; fists mem],,
2838       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2839         [Define if your assembler uses the new HImode fild and fist notation.])])
2840
2841     gcc_GAS_CHECK_FEATURE([cmov syntax],
2842       gcc_cv_as_ix86_cmov_sun_syntax,,,
2843       [cmovl.l %edx, %eax],,
2844       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2845         [Define if your assembler supports the Sun syntax for cmov.])])
2846
2847     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2848       gcc_cv_as_ix86_ffreep,,,
2849       [ffreep %st(1)],,
2850       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2851         [Define if your assembler supports the ffreep mnemonic.])])
2852
2853     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2854       gcc_cv_as_ix86_diff_sect_delta,,,
2855       [.section .rodata
2856 .L1:
2857         .long .L2-.L1
2858         .long .L3-.L1
2859         .text
2860 .L3:    nop
2861 .L2:    nop],,
2862       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2863         [Define if your assembler supports the subtraction of symbols in different sections.])])
2864
2865     # This one is used unconditionally by i386.[ch]; it is to be defined
2866     # to 1 if the feature is present, 0 otherwise.
2867     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2868         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2869 [       .text
2870 .L0:
2871         nop
2872         .data
2873         .long .L0@GOTOFF])
2874     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2875       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2876       [Define true if the assembler supports '.long foo@GOTOFF'.])
2877     ;;
2878
2879   ia64*-*-*)
2880     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2881         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2882 [       .text
2883         addl r15 = @ltoffx(x#), gp
2884         ;;
2885         ld8.mov r16 = [[r15]], x#],,
2886     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2887           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2888
2889     ;;
2890
2891   powerpc*-*-*)
2892     case $target in
2893       *-*-aix*) conftest_s='    .machine "pwr5"
2894         .csect .text[[PR]]
2895         mfcr 3,128';;
2896       *-*-darwin*)
2897         gcc_GAS_CHECK_FEATURE([.machine directive support],
2898           gcc_cv_as_machine_directive,,,
2899           [     .machine ppc7400])
2900         if test x$gcc_cv_as_machine_directive != xyes; then
2901           echo "*** This target requires an assembler supporting \".machine\"" >&2
2902           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2903           test x$build = x$target && exit 1
2904         fi
2905         conftest_s='    .text
2906         mfcr r3,128';;
2907       *) conftest_s='   .machine power4
2908         .text
2909         mfcr 3,128';;
2910     esac
2911
2912     gcc_GAS_CHECK_FEATURE([mfcr field support],
2913       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2914       [$conftest_s],,
2915       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2916           [Define if your assembler supports mfcr field.])])
2917
2918     case $target in
2919       *-*-aix*) conftest_s='    .machine "pwr5"
2920         .csect .text[[PR]]
2921         popcntb 3,3';;
2922       *) conftest_s='   .machine power5
2923         .text
2924         popcntb 3,3';;
2925     esac
2926
2927     gcc_GAS_CHECK_FEATURE([popcntb support],
2928       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2929       [$conftest_s],,
2930       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2931           [Define if your assembler supports popcntb field.])])
2932
2933     case $target in
2934       *-*-aix*) conftest_s='    .machine "pwr5x"
2935         .csect .text[[PR]]
2936         frin 1,1';;
2937       *) conftest_s='   .machine power5
2938         .text
2939         frin 1,1';;
2940     esac
2941
2942     gcc_GAS_CHECK_FEATURE([fp round support],
2943       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2944       [$conftest_s],,
2945       [AC_DEFINE(HAVE_AS_FPRND, 1,
2946           [Define if your assembler supports fprnd.])])
2947
2948     case $target in
2949       *-*-aix*) conftest_s='    .machine "pwr6"
2950         .csect .text[[PR]]
2951         mffgpr 1,3';;
2952       *) conftest_s='   .machine power6
2953         .text
2954         mffgpr 1,3';;
2955     esac
2956
2957     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2958       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2959       [$conftest_s],,
2960       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2961           [Define if your assembler supports mffgpr and mftgpr.])])
2962
2963     case $target in
2964       *-*-aix*) conftest_s='    .csect .text[[PR]]
2965 LCF..0:
2966         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2967       *-*-darwin*)
2968         conftest_s='    .text
2969 LCF0:
2970         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2971       *) conftest_s='   .text
2972 .LCF0:
2973         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2974     esac
2975
2976     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2977       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2978       [$conftest_s],,
2979       [AC_DEFINE(HAVE_AS_REL16, 1,
2980           [Define if your assembler supports R_PPC_REL16 relocs.])])
2981     ;;
2982
2983   mips*-*-*)
2984     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2985       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2986 [       lw $4,%gp_rel(foo)($4)],,
2987       [if test x$target_cpu_default = x
2988        then target_cpu_default=MASK_EXPLICIT_RELOCS
2989        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2990        fi])
2991     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2992       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2993       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2994                  [Define if the assembler understands -mno-shared.])])
2995     ;;
2996 esac
2997
2998 # Mips and HP-UX need the GNU assembler.
2999 # Linux on IA64 might be able to use the Intel assembler.
3000
3001 case "$target" in
3002   mips*-*-* | *-*-hpux* )
3003     if test x$gas_flag = xyes \
3004        || test x"$host" != x"$build" \
3005        || test ! -x "$gcc_cv_as" \
3006        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3007       :
3008     else
3009       echo "*** This configuration requires the GNU assembler" >&2
3010       exit 1
3011     fi
3012     ;;
3013 esac
3014
3015 # ??? Not all targets support dwarf2 debug_line, even within a version
3016 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3017 # info to the output file.  So, as supported targets are added to gas 2.11,
3018 # add some instruction here to (also) show we expect this might work.
3019 # ??? Once 2.11 is released, probably need to add first known working
3020 # version to the per-target configury.
3021 case "$target" in
3022   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3023   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3024   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-*)
3025     insn="nop"
3026     ;;
3027   ia64*-*-* | s390*-*-*)
3028     insn="nop 0"
3029     ;;
3030   mmix-*-*)
3031     insn="swym 0"
3032     ;;
3033 esac
3034 if test x"$insn" != x; then
3035  conftest_s="\
3036         .file 1 \"conftest.s\"
3037         .loc 1 3 0
3038         $insn"
3039  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3040   gcc_cv_as_dwarf2_debug_line,
3041   [elf,2,11,0],, [$conftest_s],
3042   [if test x$gcc_cv_objdump != x \
3043    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3044       | grep debug_line > /dev/null 2>&1; then
3045      gcc_cv_as_dwarf2_debug_line=yes
3046    fi])
3047
3048 # The .debug_line file table must be in the exact order that
3049 # we specified the files, since these indices are also used
3050 # by DW_AT_decl_file.  Approximate this test by testing if
3051 # the assembler bitches if the same index is assigned twice.
3052  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3053   gcc_cv_as_dwarf2_file_buggy,,,
3054 [       .file 1 "foo.s"
3055         .file 1 "bar.s"])
3056
3057  if test $gcc_cv_as_dwarf2_debug_line = yes \
3058  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3059         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3060   [Define if your assembler supports dwarf2 .file/.loc directives,
3061    and preserves file table indices exactly as given.])
3062  fi
3063
3064  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3065   gcc_cv_as_gdwarf2_flag,
3066   [elf,2,11,0], [--gdwarf2], [$insn],,
3067   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3068 [Define if your assembler supports the --gdwarf2 option.])])
3069
3070  gcc_GAS_CHECK_FEATURE([--gstabs option],
3071   gcc_cv_as_gstabs_flag,
3072   [elf,2,11,0], [--gstabs], [$insn],
3073   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3074    # and warns about it, but still exits successfully.  So check for
3075    # this.
3076    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3077    then :
3078    else gcc_cv_as_gstabs_flag=yes
3079    fi],
3080   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3081 [Define if your assembler supports the --gstabs option.])])
3082 fi
3083
3084 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3085 gcc_cv_ld_ro_rw_mix=unknown
3086 if test $in_tree_ld = yes ; then
3087   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3088      && test $in_tree_ld_is_elf = yes; then
3089     gcc_cv_ld_ro_rw_mix=read-write
3090   fi
3091 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3092   echo '.section myfoosect, "a"' > conftest1.s
3093   echo '.section myfoosect, "aw"' > conftest2.s
3094   echo '.byte 1' >> conftest2.s
3095   echo '.section myfoosect, "a"' > conftest3.s
3096   echo '.byte 0' >> conftest3.s
3097   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3098      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3099      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3100      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3101         conftest2.o conftest3.o > /dev/null 2>&1; then
3102     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3103                          | sed -e '/myfoosect/!d' -e N`
3104     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3105       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3106         gcc_cv_ld_ro_rw_mix=read-only
3107       else
3108         gcc_cv_ld_ro_rw_mix=read-write
3109       fi
3110     fi
3111   fi
3112 changequote(,)dnl
3113   rm -f conftest.* conftest[123].*
3114 changequote([,])dnl
3115 fi
3116 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3117         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3118   [Define if your linker links a mix of read-only
3119    and read-write sections into a read-write section.])
3120 fi
3121 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3122
3123 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3124 gcc_cv_ld_eh_frame_hdr=no
3125 if test $in_tree_ld = yes ; then
3126   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3127      && test $in_tree_ld_is_elf = yes; then
3128     gcc_cv_ld_eh_frame_hdr=yes
3129   fi
3130 elif test x$gcc_cv_ld != x; then
3131         # Check if linker supports --eh-frame-hdr option
3132         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3133                 gcc_cv_ld_eh_frame_hdr=yes
3134         fi
3135 fi
3136 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3137 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3138         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3139 [Define if your linker supports --eh-frame-hdr option.])
3140 fi
3141 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3142
3143 AC_MSG_CHECKING(linker position independent executable support)
3144 gcc_cv_ld_pie=no
3145 if test $in_tree_ld = yes ; then
3146   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3147      && test $in_tree_ld_is_elf = yes; then
3148     gcc_cv_ld_pie=yes
3149   fi
3150 elif test x$gcc_cv_ld != x; then
3151         # Check if linker supports -pie option
3152         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3153                 gcc_cv_ld_pie=yes
3154         fi
3155 fi
3156 if test x"$gcc_cv_ld_pie" = xyes; then
3157         AC_DEFINE(HAVE_LD_PIE, 1,
3158 [Define if your linker supports -pie option.])
3159 fi
3160 AC_MSG_RESULT($gcc_cv_ld_pie)
3161
3162 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3163 gcc_cv_ld_eh_gc_sections=no
3164 if test $in_tree_ld = yes ; then
3165   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3166      && test $in_tree_ld_is_elf = yes; then
3167     gcc_cv_ld_eh_gc_sections=yes
3168   fi
3169 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3170   cat > conftest.s <<EOF
3171         .section        .text
3172 .globl _start
3173         .type _start, @function
3174 _start:
3175         .long foo
3176         .size _start, .-_start
3177         .section        .text.foo,"ax",@progbits
3178         .type foo, @function
3179 foo:
3180         .long 0
3181         .size foo, .-foo
3182         .section        .gcc_except_table.foo,"a",@progbits
3183 .L0:
3184         .long 0
3185         .section        .eh_frame,"a",@progbits
3186         .long .L0
3187 EOF
3188   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3189     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3190          | grep "gc-sections option ignored" > /dev/null; then
3191       gcc_cv_ld_eh_gc_sections=no
3192     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3193       gcc_cv_ld_eh_gc_sections=yes
3194       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3195       if test x$gcc_cv_as_comdat_group != xyes; then
3196         gcc_cv_ld_eh_gc_sections=no
3197         cat > conftest.s <<EOF
3198         .section        .text
3199 .globl _start
3200         .type _start, @function
3201 _start:
3202         .long foo
3203         .size _start, .-_start
3204         .section        .gnu.linkonce.t.foo,"ax",@progbits
3205         .type foo, @function
3206 foo:
3207         .long 0
3208         .size foo, .-foo
3209         .section        .gcc_except_table.foo,"a",@progbits
3210 .L0:
3211         .long 0
3212         .section        .eh_frame,"a",@progbits
3213         .long .L0
3214 EOF
3215         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3216           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3217                | grep "gc-sections option ignored" > /dev/null; then
3218             gcc_cv_ld_eh_gc_sections=no
3219           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3220             gcc_cv_ld_eh_gc_sections=yes
3221           fi
3222         fi
3223       fi
3224     fi
3225   fi
3226   rm -f conftest.s conftest.o conftest
3227 fi
3228 case "$target" in
3229   hppa*-*-linux*)
3230     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3231     gcc_cv_ld_eh_gc_sections=no
3232     ;;
3233 esac
3234 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3235         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3236   [Define if your linker supports garbage collection of
3237    sections in presence of EH frames.])
3238 fi
3239 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3240
3241 # --------
3242 # UNSORTED
3243 # --------
3244
3245 AC_CACHE_CHECK(linker --as-needed support,
3246 gcc_cv_ld_as_needed,
3247 [gcc_cv_ld_as_needed=no
3248 if test $in_tree_ld = yes ; then
3249   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3250      && test $in_tree_ld_is_elf = yes; then
3251     gcc_cv_ld_as_needed=yes
3252   fi
3253 elif test x$gcc_cv_ld != x; then
3254         # Check if linker supports --as-needed and --no-as-needed options
3255         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3256                 gcc_cv_ld_as_needed=yes
3257         fi
3258 fi
3259 ])
3260 if test x"$gcc_cv_ld_as_needed" = xyes; then
3261         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3262 [Define if your linker supports --as-needed and --no-as-needed options.])
3263 fi
3264
3265 case "$target:$tm_file" in
3266   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3267     AC_CACHE_CHECK(linker support for omitting dot symbols,
3268     gcc_cv_ld_no_dot_syms,
3269     [gcc_cv_ld_no_dot_syms=no
3270     if test $in_tree_ld = yes ; then
3271       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3272         gcc_cv_ld_no_dot_syms=yes
3273       fi
3274     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3275       cat > conftest1.s <<EOF
3276         .text
3277         bl .foo
3278 EOF
3279       cat > conftest2.s <<EOF
3280         .section ".opd","aw"
3281         .align 3
3282         .globl foo
3283         .type foo,@function
3284 foo:
3285         .quad .LEfoo,.TOC.@tocbase,0
3286         .text
3287 .LEfoo:
3288         blr
3289         .size foo,.-.LEfoo
3290 EOF
3291       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3292          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3293          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3294         gcc_cv_ld_no_dot_syms=yes
3295       fi
3296       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3297     fi
3298     ])
3299     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3300       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3301     [Define if your PowerPC64 linker only needs function descriptor syms.])
3302     fi
3303     ;;
3304 esac
3305
3306 AC_CACHE_CHECK(linker --sysroot support,
3307   gcc_cv_ld_sysroot,
3308   [gcc_cv_ld_sysroot=no
3309   if test $in_tree_ld = yes ; then
3310       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3311         gcc_cv_ld_sysroot=yes
3312       fi
3313   elif test x$gcc_cv_ld != x; then
3314     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3315       gcc_cv_ld_sysroot=yes
3316     fi
3317   fi])
3318 if test x"$gcc_cv_ld_sysroot" = xyes; then
3319   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3320   [Define if your linker supports --sysroot.])
3321 fi
3322
3323 if test x$with_sysroot = x && test x$host = x$target \
3324    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3325    && test "$prefix" != "NONE"; then
3326   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3327 [Define to PREFIX/include if cpp should also search that directory.])
3328 fi
3329
3330 # Test for stack protector support in target C library.
3331 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3332       gcc_cv_libc_provides_ssp,
3333       [gcc_cv_libc_provides_ssp=no
3334     case "$target" in
3335        *-*-linux*)
3336       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3337         if test "x$with_sysroot" = x; then
3338           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3339         elif test "x$with_sysroot" = xyes; then
3340           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3341         else
3342           glibc_header_dir="${with_sysroot}/usr/include"
3343         fi
3344       else
3345         glibc_header_dir=/usr/include
3346       fi
3347       # glibc 2.4 and later provides __stack_chk_fail and
3348       # either __stack_chk_guard, or TLS access to stack guard canary.
3349       if test -f $glibc_header_dir/features.h \
3350          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3351             $glibc_header_dir/features.h > /dev/null; then
3352         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3353            $glibc_header_dir/features.h > /dev/null; then
3354           gcc_cv_libc_provides_ssp=yes
3355         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3356              $glibc_header_dir/features.h > /dev/null \
3357              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3358              $glibc_header_dir/features.h > /dev/null; then
3359           gcc_cv_libc_provides_ssp=yes
3360         fi
3361         fi
3362         ;;
3363        *-*-darwin*)
3364          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3365            [echo "no __stack_chk_fail on this target"])
3366         ;;
3367   *) gcc_cv_libc_provides_ssp=no ;;
3368     esac])
3369
3370 if test x$gcc_cv_libc_provides_ssp = xyes; then
3371   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3372             [Define if your target C library provides stack protector support])
3373 fi
3374
3375 # Check if TFmode long double should be used by default or not.
3376 # Some glibc targets used DFmode long double, but with glibc 2.4
3377 # and later they can use TFmode.
3378 case "$target" in
3379   powerpc*-*-*gnu* | \
3380   sparc*-*-linux* | \
3381   s390*-*-linux* | \
3382   alpha*-*-linux*)
3383     AC_ARG_WITH(long-double-128,
3384 [  --with-long-double-128  Use 128-bit long double by default.],
3385       gcc_cv_target_ldbl128="$with_long_double_128",
3386       [gcc_cv_target_ldbl128=no
3387       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3388         if test "x$with_sysroot" = x; then
3389           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3390         elif test "x$with_sysroot" = xyes; then
3391           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3392         else
3393           glibc_header_dir="${with_sysroot}/usr/include"
3394         fi
3395       else
3396         glibc_header_dir=/usr/include
3397       fi
3398 changequote(,)dnl
3399       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3400         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3401       && gcc_cv_target_ldbl128=yes
3402 changequote([,])dnl
3403       ])
3404     ;;
3405 esac
3406 if test x$gcc_cv_target_ldbl128 = xyes; then
3407   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3408             [Define if TFmode long double should be the default])
3409 fi
3410
3411 # Find out what GC implementation we want, or may, use.
3412 AC_ARG_WITH(gc,
3413 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3414                           with the compiler],
3415 [case "$withval" in
3416   page)
3417     GGC=ggc-$withval
3418     ;;
3419   zone)
3420     GGC=ggc-$withval
3421     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3422     ;;
3423   *)
3424     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3425     ;;
3426 esac],
3427 [GGC=ggc-page])
3428 AC_SUBST(GGC)
3429 echo "Using $GGC for garbage collection."
3430
3431 # Use the system's zlib library.
3432 zlibdir=-L../zlib
3433 zlibinc="-I\$(srcdir)/../zlib"
3434 AC_ARG_WITH(system-zlib,
3435 [  --with-system-zlib      use installed libz],
3436 zlibdir=
3437 zlibinc=
3438 )
3439 AC_SUBST(zlibdir)
3440 AC_SUBST(zlibinc)
3441
3442 dnl Very limited version of automake's enable-maintainer-mode
3443
3444 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3445   dnl maintainer-mode is disabled by default
3446   AC_ARG_ENABLE(maintainer-mode,
3447 [  --enable-maintainer-mode
3448                           enable make rules and dependencies not useful
3449                           (and sometimes confusing) to the casual installer],
3450       maintainer_mode=$enableval,
3451       maintainer_mode=no)
3452
3453 AC_MSG_RESULT($maintainer_mode)
3454
3455 if test "$maintainer_mode" = "yes"; then
3456   MAINT=''
3457 else
3458   MAINT='#'
3459 fi
3460 AC_SUBST(MAINT)dnl
3461
3462 # --------------
3463 # Language hooks
3464 # --------------
3465
3466 # Make empty files to contain the specs and options for each language.
3467 # Then add #include lines to for a compiler that has specs and/or options.
3468
3469 subdirs=
3470 lang_opt_files=
3471 lang_specs_files=
3472 lang_tree_files=
3473 # These (without "all_") are set in each config-lang.in.
3474 # `language' must be a single word so is spelled singularly.
3475 all_languages=
3476 all_boot_languages=
3477 all_compilers=
3478 all_stagestuff=
3479 all_outputs='Makefile gccbug libada-mk'
3480 # List of language makefile fragments.
3481 all_lang_makefrags=
3482 # List of language subdirectory makefiles.  Deprecated.
3483 all_lang_makefiles=
3484 # Files for gengtype
3485 all_gtfiles="$target_gtfiles"
3486 # Files for gengtype with language
3487 all_gtfiles_files_langs=
3488 all_gtfiles_files_files=
3489
3490 # These are the languages that are set in --enable-languages,
3491 # and are available in the GCC tree.
3492 all_selected_languages=
3493
3494 # Add the language fragments.
3495 # Languages are added via two mechanisms.  Some information must be
3496 # recorded in makefile variables, these are defined in config-lang.in.
3497 # We accumulate them and plug them into the main Makefile.
3498 # The other mechanism is a set of hooks for each of the main targets
3499 # like `clean', `install', etc.
3500
3501 language_hooks="Make-hooks"
3502
3503 for lang in ${srcdir}/*/config-lang.in
3504 do
3505 changequote(,)dnl
3506         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3507
3508         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3509         if test "x$lang_alias" = x
3510         then
3511               echo "$lang doesn't set \$language." 1>&2
3512               exit 1
3513         fi
3514         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3515         subdirs="$subdirs $subdir"
3516         case ",$enable_languages," in
3517         *,$lang_alias,*)
3518             all_selected_languages="$all_selected_languages $lang_alias"
3519             if test -f $srcdir/$subdir/lang-specs.h; then
3520                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3521             fi
3522             ;;
3523         esac
3524 changequote([,])dnl
3525
3526         language=
3527         boot_language=
3528         compilers=
3529         stagestuff=
3530         outputs=
3531         gtfiles=
3532         subdir_requires=
3533         . ${srcdir}/$subdir/config-lang.in
3534         if test "x$language" = x
3535         then
3536                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3537                 exit 1
3538         fi
3539
3540         ok=:
3541         case ",$enable_languages," in
3542                 *,$lang_alias,*) ;;
3543                 *)
3544                         for i in $subdir_requires; do
3545                                 test -f "${srcdir}/$i/config-lang.in" && continue
3546                                 ok=false
3547                                 break
3548                         done
3549                 ;;
3550         esac
3551         $ok || continue
3552
3553         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3554         if test -f $srcdir/$subdir/lang.opt; then
3555             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3556         fi
3557         if test -f $srcdir/$subdir/$subdir-tree.def; then
3558             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3559         fi
3560         if test -f ${srcdir}/$subdir/Makefile.in
3561                 then all_lang_makefiles="$subdir/Makefile"
3562         fi
3563         all_languages="$all_languages $language"
3564         if test "x$boot_language" = xyes
3565         then
3566                 all_boot_languages="$all_boot_languages $language"
3567         fi
3568         all_compilers="$all_compilers $compilers"
3569         all_stagestuff="$all_stagestuff $stagestuff"
3570         all_outputs="$all_outputs $outputs"
3571         all_gtfiles="$all_gtfiles $gtfiles"
3572         for f in $gtfiles
3573         do
3574                 all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3575                 all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3576         done
3577 done
3578
3579 # Pick up gtfiles for c
3580 gtfiles=
3581 subdir="c"
3582 . ${srcdir}/c-config-lang.in
3583 all_gtfiles="$all_gtfiles $gtfiles"
3584 for f in $gtfiles
3585 do
3586         all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3587         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3588 done
3589
3590 check_languages=
3591 for language in $all_selected_languages
3592 do
3593         check_languages="$check_languages check-$language"
3594 done
3595
3596 # We link each language in with a set of hooks, reached indirectly via
3597 # lang.${target}.  Only do so for selected languages.
3598
3599 rm -f Make-hooks
3600 touch Make-hooks
3601 target_list="all.cross start.encap rest.encap tags \
3602         install-common install-man install-info dvi pdf html \
3603         uninstall info man srcextra srcman srcinfo \
3604         mostlyclean clean distclean maintainer-clean \
3605         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3606
3607 for t in $target_list
3608 do
3609         x=
3610         for lang in $all_selected_languages
3611         do
3612                 x="$x $lang.$t"
3613         done
3614         echo "lang.$t: $x" >> Make-hooks
3615 done
3616
3617 # --------
3618 # UNSORTED
3619 # --------
3620
3621 # Create .gdbinit.
3622
3623 echo "dir ." > .gdbinit
3624 echo "dir ${srcdir}" >> .gdbinit
3625 if test x$gdb_needs_out_file_path = xyes
3626 then
3627         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3628 fi
3629 if test "x$subdirs" != x; then
3630         for s in $subdirs
3631         do
3632                 echo "dir ${srcdir}/$s" >> .gdbinit
3633         done
3634 fi
3635 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3636
3637 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3638 # absolute path for gcc_tooldir based on inserting the number of up-directory
3639 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3640 # $(libsubdir)/@(unlibsubdir) based path.
3641 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3642 # make and thus we'd get different behavior depending on where we built the
3643 # sources.
3644 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3645     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3646 else
3647 changequote(<<, >>)dnl
3648 # An explanation of the sed strings:
3649 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3650 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3651 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3652 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3653 #
3654 # (*) Note this pattern overwrites the first character of the string
3655 # with a forward slash if one is not already present.  This is not a
3656 # problem because the exact names of the sub-directories concerned is
3657 # unimportant, just the number of them matters.
3658 #
3659 # The practical upshot of these patterns is like this:
3660 #
3661 #  prefix     exec_prefix        result
3662 #  ------     -----------        ------
3663 #   /foo        /foo/bar          ../
3664 #   /foo/       /foo/bar          ../
3665 #   /foo        /foo/bar/         ../
3666 #   /foo/       /foo/bar/         ../
3667 #   /foo        /foo/bar/ugg      ../../
3668 #
3669     dollar='$$'
3670     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3671 changequote([, ])dnl
3672 fi
3673 AC_SUBST(gcc_tooldir)
3674 AC_SUBST(dollar)
3675
3676 # Find a directory in which to install a shared libgcc.
3677
3678 AC_ARG_ENABLE(version-specific-runtime-libs,
3679 [  --enable-version-specific-runtime-libs
3680                           specify that runtime libraries should be
3681                           installed in a compiler-specific directory])
3682
3683 AC_ARG_WITH(slibdir,
3684 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3685 slibdir="$with_slibdir",
3686 if test "${enable_version_specific_runtime_libs+set}" = set; then
3687   slibdir='$(libsubdir)'
3688 elif test "$host" != "$target"; then
3689   slibdir='$(build_tooldir)/lib'
3690 else
3691   slibdir='$(libdir)'
3692 fi)
3693 AC_SUBST(slibdir)
3694
3695 objdir=`${PWDCMD-pwd}`
3696 AC_SUBST(objdir)
3697
3698 AC_ARG_WITH(datarootdir,
3699 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3700 datarootdir="\${prefix}/$with_datarootdir",
3701 datarootdir='$(prefix)/share')
3702 AC_SUBST(datarootdir)
3703
3704 AC_ARG_WITH(docdir,
3705 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3706 docdir="\${prefix}/$with_docdir",
3707 docdir='$(datarootdir)')
3708 AC_SUBST(docdir)
3709
3710 AC_ARG_WITH(htmldir,
3711 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3712 htmldir="\${prefix}/$with_htmldir",
3713 htmldir='$(docdir)')
3714 AC_SUBST(htmldir)
3715
3716 # Substitute configuration variables
3717 AC_SUBST(subdirs)
3718 AC_SUBST(srcdir)
3719 AC_SUBST(all_boot_languages)
3720 AC_SUBST(all_compilers)
3721 AC_SUBST(all_gtfiles)
3722 AC_SUBST(all_gtfiles_files_langs)
3723 AC_SUBST(all_gtfiles_files_files)
3724 AC_SUBST(all_lang_makefrags)
3725 AC_SUBST(all_lang_makefiles)
3726 AC_SUBST(all_languages)
3727 AC_SUBST(all_selected_languages)
3728 AC_SUBST(all_stagestuff)
3729 AC_SUBST(build_exeext)
3730 AC_SUBST(build_install_headers_dir)
3731 AC_SUBST(build_xm_file_list)
3732 AC_SUBST(build_xm_include_list)
3733 AC_SUBST(build_xm_defines)
3734 AC_SUBST(check_languages)
3735 AC_SUBST(cc_set_by_configure)
3736 AC_SUBST(quoted_cc_set_by_configure)
3737 AC_SUBST(cpp_install_dir)
3738 AC_SUBST(xmake_file)
3739 AC_SUBST(tmake_file)
3740 AC_SUBST(extra_gcc_objs)
3741 AC_SUBST(extra_headers_list)
3742 AC_SUBST(extra_objs)
3743 AC_SUBST(extra_parts)
3744 AC_SUBST(extra_passes)
3745 AC_SUBST(extra_programs)
3746 AC_SUBST(float_h_file)
3747 AC_SUBST(gcc_config_arguments)
3748 AC_SUBST(gcc_gxx_include_dir)
3749 AC_SUBST(host_exeext)
3750 AC_SUBST(host_xm_file_list)
3751 AC_SUBST(host_xm_include_list)
3752 AC_SUBST(host_xm_defines)
3753 AC_SUBST(out_host_hook_obj)
3754 AC_SUBST(install)
3755 AC_SUBST(lang_opt_files)
3756 AC_SUBST(lang_specs_files)
3757 AC_SUBST(lang_tree_files)
3758 AC_SUBST(local_prefix)
3759 AC_SUBST(md_file)
3760 AC_SUBST(objc_boehm_gc)
3761 AC_SUBST(out_file)
3762 AC_SUBST(out_object_file)
3763 AC_SUBST(stage_prefix_set_by_configure)
3764 AC_SUBST(quoted_stage_prefix_set_by_configure)
3765 AC_SUBST(thread_file)
3766 AC_SUBST(tm_file_list)
3767 AC_SUBST(tm_include_list)
3768 AC_SUBST(tm_defines)
3769 AC_SUBST(tm_p_file_list)
3770 AC_SUBST(tm_p_include_list)
3771 AC_SUBST(xm_file_list)
3772 AC_SUBST(xm_include_list)
3773 AC_SUBST(xm_defines)
3774 AC_SUBST(c_target_objs)
3775 AC_SUBST(cxx_target_objs)
3776 AC_SUBST(target_cpu_default)
3777
3778 AC_SUBST_FILE(language_hooks)
3779
3780 # Echo link setup.
3781 if test x${build} = x${host} ; then
3782   if test x${host} = x${target} ; then
3783     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3784   else
3785     echo "Links are now set up to build a cross-compiler" 1>&2
3786     echo " from ${host} to ${target}." 1>&2
3787   fi
3788 else
3789   if test x${host} = x${target} ; then
3790     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3791     echo " for ${target}." 1>&2
3792   else
3793     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3794     echo " from ${host} to ${target}." 1>&2
3795   fi
3796 fi
3797
3798 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3799 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3800
3801 # Configure the subdirectories
3802 # AC_CONFIG_SUBDIRS($subdirs)
3803
3804 # Create the Makefile
3805 # and configure language subdirectories
3806 AC_CONFIG_FILES($all_outputs)
3807
3808 AC_CONFIG_COMMANDS([default],
3809 [
3810 case ${CONFIG_HEADERS} in
3811   *auto-host.h:config.in*)
3812   echo > cstamp-h ;;
3813 esac
3814 # Make sure all the subdirs exist.
3815 for d in $subdirs doc build
3816 do
3817     test -d $d || mkdir $d
3818 done
3819 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3820 # bootstrapping and the installation procedure can still use
3821 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3822 # FLAGS_TO_PASS has been modified to solve the problem there.
3823 # This is virtually a duplicate of what happens in configure.lang; we do
3824 # an extra check to make sure this only happens if ln -s can be used.
3825 case "$LN_S" in
3826   *-s*)
3827     for d in ${subdirs} ; do
3828         STARTDIR=`${PWDCMD-pwd}`
3829         cd $d
3830         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3831         do
3832                 rm -f $t
3833                 $LN_S ../$t $t 2>/dev/null
3834         done
3835         cd $STARTDIR
3836     done
3837   ;;
3838 esac
3839 ],
3840 [subdirs='$subdirs'])
3841 AC_OUTPUT