gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.57)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 _GCC_TOPLEV_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # ----------------------
 215 # Find default assembler
 216 # ----------------------
 217
 218 # With GNU as
 219 AC_ARG_WITH(gnu-as,
 220 [  --with-gnu-as           arrange to work with GNU as],
 221 gas_flag="$with_gnu_as",
 222 gas_flag=no)
 223
 224 AC_ARG_WITH(as,
 225 [  --with-as               arrange to use the specified as (full pathname)],
 226 DEFAULT_ASSEMBLER="$with_as")
 227 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 228   if test ! -x "$DEFAULT_ASSEMBLER"; then
 229     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 230   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 231     gas_flag=yes
 232   fi
 233   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 234         [Define to enable the use of a default assembler.])
 235 fi
 236
 237 AC_MSG_CHECKING([whether a default assembler was specified])
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test x"$gas_flag" = x"no"; then
 240     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 241   else
 242     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 243   fi
 244 else
 245   AC_MSG_RESULT(no)
 246 fi
 247
 248 # ---------------
 249 # Find C compiler
 250 # ---------------
 251
 252 # If a non-executable a.out is present (e.g. created by GNU as above even if
 253 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 254 # file, even when creating an executable, so an execution test fails.
 255 # Remove possible default executable files to avoid this.
 256 #
 257 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 258 # Autoconf includes it.
 259 rm -f a.out a.exe b.out
 260
 261 # Find the native compiler
 262 AC_PROG_CC
 263 AC_PROG_CC_C_O
 264 # autoconf is lame and doesn't give us any substitution variable for this.
 265 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 266   NO_MINUS_C_MINUS_O=yes
 267 else
 268   OUTPUT_OPTION='-o $@'
 269 fi
 270 AC_SUBST(NO_MINUS_C_MINUS_O)
 271 AC_SUBST(OUTPUT_OPTION)
 272
 273 # -------------------------
 274 # Check C compiler features
 275 # -------------------------
 276
 277 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 278 ac_cv_prog_cc_no_long_long,
 279 [save_CFLAGS="$CFLAGS"
 280 CFLAGS="-Wno-long-long"
 281 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 282                ac_cv_prog_cc_no_long_long=no)
 283 CFLAGS="$save_CFLAGS"])
 284
 285 AC_PROG_CPP
 286 AC_C_INLINE
 287
 288 gcc_AC_C_LONG_LONG
 289 gcc_AC_C__BOOL
 290
 291 # sizeof(char) is 1 by definition.
 292 AC_COMPILE_CHECK_SIZEOF(void *)
 293 AC_COMPILE_CHECK_SIZEOF(short)
 294 AC_COMPILE_CHECK_SIZEOF(int)
 295 AC_COMPILE_CHECK_SIZEOF(long)
 296 if test $ac_cv_c_long_long = yes; then
 297   AC_COMPILE_CHECK_SIZEOF(long long)
 298 fi
 299 if test $ac_cv_c___int64 = yes; then
 300   AC_COMPILE_CHECK_SIZEOF(__int64)
 301 fi
 302
 303 # -----------------
 304 # Find Ada compiler
 305 # -----------------
 306
 307 # See if GNAT has been installed
 308 gcc_AC_PROG_GNAT
 309
 310 # ---------------------
 311 # Warnings and checking
 312 # ---------------------
 313
 314 strict1_warn=
 315 if test $ac_cv_prog_cc_no_long_long = yes ; then
 316   strict1_warn="-pedantic -Wno-long-long"
 317 fi
 318 AC_SUBST(strict1_warn)
 319
 320 # If the native compiler is GCC, we can enable warnings even in stage1.
 321 # That's useful for people building cross-compilers, or just running a
 322 # quick `make'.
 323 warn_cflags=
 324 if test "x$GCC" = "xyes"; then
 325   warn_cflags='$(GCC_WARN_CFLAGS)'
 326 fi
 327 AC_SUBST(warn_cflags)
 328
 329 # Enable -Werror in bootstrap stage2 and later.
 330 # Change the default to "no" on release branches.
 331 AC_ARG_ENABLE(werror,
 332 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 333 [enable_werror=yes])
 334 if test x$enable_werror = xyes ; then
 335   WERROR=-Werror
 336 fi
 337 AC_SUBST(WERROR)
 338
 339 # Enable expensive internal checks
 340 AC_ARG_ENABLE(checking,
 341 [  --enable-checking[=LIST]
 342                           enable expensive run-time checks.  With LIST,
 343                           enable only specific categories of checks.
 344                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 345                           default is misc,tree,gc,rtlflag],
 346 [ac_checking=
 347 ac_tree_checking=
 348 ac_rtl_checking=
 349 ac_rtlflag_checking=
 350 ac_gc_checking=
 351 ac_gc_always_collect=
 352 ac_fold_checking=
 353 case "${enableval}" in
 354 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 355         ac_rtlflag_checking=1 ;;
 356 no)     ;;
 357 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 358         set fnord $enableval; shift
 359         IFS="$ac_save_IFS"
 360         for check
 361         do
 362                 case $check in
 363                 misc)   ac_checking=1 ;;
 364                 tree)   ac_tree_checking=1 ;;
 365                 rtlflag)        ac_rtlflag_checking=1 ;;
 366                 rtl)    ac_rtl_checking=1 ;;
 367                 gc)     ac_gc_checking=1 ;;
 368                 gcac)   ac_gc_always_collect=1 ;;
 369                 fold)   ac_fold_checking=1 ;;
 370                 valgrind)       ac_checking_valgrind=1 ;;
 371                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 372                 esac
 373         done
 374         ;;
 375 esac
 376 ],
 377 # Enable some checks by default for development versions of GCC
 378 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 379 nocommon_flag=""
 380 if test x$ac_checking != x ; then
 381   AC_DEFINE(ENABLE_CHECKING, 1,
 382 [Define if you want more run-time sanity checks.  This one gets a grab
 383    bag of miscellaneous but relatively cheap checks.])
 384   nocommon_flag=-fno-common
 385 fi
 386 AC_SUBST(nocommon_flag)
 387 if test x$ac_tree_checking != x ; then
 388   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 389 [Define if you want all operations on trees (the basic data
 390    structure of the front ends) to be checked for dynamic type safety
 391    at runtime.  This is moderately expensive.])
 392 fi
 393 if test x$ac_rtl_checking != x ; then
 394   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 395 [Define if you want all operations on RTL (the basic data structure
 396    of the optimizer and back end) to be checked for dynamic type safety
 397    at runtime.  This is quite expensive.])
 398 fi
 399 if test x$ac_rtlflag_checking != x ; then
 400   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 401 [Define if you want RTL flag accesses to be checked against the RTL
 402    codes that are supported for each access macro.  This is relatively
 403    cheap.])
 404 fi
 405 if test x$ac_gc_checking != x ; then
 406   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 407 [Define if you want the garbage collector to do object poisoning and
 408    other memory allocation checks.  This is quite expensive.])
 409 fi
 410 if test x$ac_gc_always_collect != x ; then
 411   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 412 [Define if you want the garbage collector to operate in maximally
 413    paranoid mode, validating the entire heap and collecting garbage at
 414    every opportunity.  This is extremely expensive.])
 415 fi
 416 if test x$ac_fold_checking != x ; then
 417   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 418 [Define if you want fold checked that it never destructs its argument.
 419    This is quite expensive.])
 420 fi
 421 valgrind_path_defines=
 422 valgrind_command=
 423
 424 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 425 dnl # an if statement.  This was the source of very frustrating bugs
 426 dnl # in converting to autoconf 2.5x!
 427 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 428
 429 if test x$ac_checking_valgrind != x ; then
 430   # It is certainly possible that there's valgrind but no valgrind.h.
 431   # GCC relies on making annotations so we must have both.
 432   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 433   AC_TRY_CPP(
 434     [#include <valgrind/memcheck.h>
 435 #ifndef VALGRIND_DISCARD
 436 #error VALGRIND_DISCARD not defined
 437 #endif],
 438   [gcc_cv_header_valgrind_memcheck_h=yes],
 439   [gcc_cv_header_valgrind_memcheck_h=no])
 440   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 441   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 442   AC_TRY_CPP(
 443     [#include <memcheck.h>
 444 #ifndef VALGRIND_DISCARD
 445 #error VALGRIND_DISCARD not defined
 446 #endif],
 447   [gcc_cv_header_memcheck_h=yes],
 448   gcc_cv_header_memcheck_h=no)
 449   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 450   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 451         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 452   if test "x$valgrind_path" = "x" \
 453     || (test $have_valgrind_h = no \
 454         && test $gcc_cv_header_memcheck_h = no \
 455         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 456         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 457   fi
 458   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 459   valgrind_command="$valgrind_path -q"
 460   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 461 [Define if you want to run subprograms and generated programs
 462    through valgrind (a memory checker).  This is extremely expensive.])
 463   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 464     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 465         [Define if valgrind's valgrind/memcheck.h header is installed.])
 466   fi
 467   if test $gcc_cv_header_memcheck_h = yes; then
 468     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 469         [Define if valgrind's memcheck.h header is installed.])
 470   fi
 471 fi
 472 AC_SUBST(valgrind_path_defines)
 473 AC_SUBST(valgrind_command)
 474
 475 # Enable code coverage collection
 476 AC_ARG_ENABLE(coverage,
 477 [  --enable-coverage[=LEVEL]
 478                           enable compiler\'s code coverage collection.
 479                           Use to measure compiler performance and locate
 480                           unused parts of the compiler. With LEVEL, specify
 481                           optimization. Values are opt, noopt,
 482                           default is noopt],
 483 [case "${enableval}" in
 484 yes|noopt)
 485         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 486         ;;
 487 opt)
 488         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 489         ;;
 490 *)
 491         AC_MSG_ERROR(unknown coverage setting $enableval)
 492         ;;
 493 esac],
 494 [coverage_flags=""])
 495 AC_SUBST(coverage_flags)
 496
 497 AC_ARG_ENABLE(gather-detailed-mem-stats,
 498 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 499 [enable_gather_detailed_mem_stats=no])
 500 if test x$enable_gather_detailed_mem_stats = xyes ; then
 501   AC_DEFINE(GATHER_STATISTICS, 1,
 502         [Define to enable detailed memory allocation stats gathering.])
 503 fi
 504
 505 # -------------------------------
 506 # Miscenalleous configure options
 507 # -------------------------------
 508
 509 # With stabs
 510 AC_ARG_WITH(stabs,
 511 [  --with-stabs            arrange to use stabs instead of host debug format],
 512 stabs="$with_stabs",
 513 stabs=no)
 514
 515 # Determine whether or not multilibs are enabled.
 516 AC_ARG_ENABLE(multilib,
 517 [  --enable-multilib       enable library support for multiple ABIs],
 518 [], [enable_multilib=yes])
 519 AC_SUBST(enable_multilib)
 520
 521 # Enable __cxa_atexit for C++.
 522 AC_ARG_ENABLE(__cxa_atexit,
 523 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 524 [], [])
 525
 526 # Enable threads
 527 # Pass with no value to take the default
 528 # Pass with a value to specify a thread package
 529 AC_ARG_ENABLE(threads,
 530 [  --enable-threads        enable thread usage for target GCC
 531   --enable-threads=LIB    use LIB thread package for target GCC],,
 532 enable_threads='')
 533 # Save in case it gets overwritten in config.gcc
 534 enable_threads_flag=$enable_threads
 535
 536 AC_ARG_ENABLE(objc-gc,
 537 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 538                           the GNU Objective-C runtime],
 539 if test x$enable_objc_gc = xno; then
 540         objc_boehm_gc=''
 541 else
 542         objc_boehm_gc=1
 543 fi,
 544 objc_boehm_gc='')
 545
 546 AC_ARG_WITH(dwarf2,
 547 [  --with-dwarf2           force the default debug format to be DWARF 2],
 548 dwarf2="$with_dwarf2",
 549 dwarf2=no)
 550
 551 AC_ARG_ENABLE(shared,
 552 [  --disable-shared        don't provide a shared libgcc],
 553 [
 554   case $enable_shared in
 555   yes | no) ;;
 556   *)
 557     enable_shared=no
 558     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 559     for pkg in $enableval; do
 560       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 561         enable_shared=yes
 562       fi
 563     done
 564     IFS="$ac_save_ifs"
 565     ;;
 566   esac
 567 ], [enable_shared=yes])
 568 AC_SUBST(enable_shared)
 569
 570 AC_ARG_WITH(sysroot,
 571 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 572 [
 573  case ${with_sysroot} in
 574  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 575  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 576  esac
 577
 578  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 579  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 580
 581  if test "x$exec_prefix" = xNONE; then
 582   if test "x$prefix" = xNONE; then
 583    test_prefix=/usr/local
 584   else
 585    test_prefix=$prefix
 586   fi
 587  else
 588   test_prefix=$exec_prefix
 589  fi
 590  case ${TARGET_SYSTEM_ROOT} in
 591  "${test_prefix}"|"${test_prefix}/"*|\
 592  '${exec_prefix}'|'${exec_prefix}/'*)
 593    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 594    TARGET_SYSTEM_ROOT_DEFINE="$t"
 595    ;;
 596  esac
 597 ], [
 598  TARGET_SYSTEM_ROOT=
 599  TARGET_SYSTEM_ROOT_DEFINE=
 600  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 601 ])
 602 AC_SUBST(TARGET_SYSTEM_ROOT)
 603 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 604 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 605
 606 # Build with intermodule optimisations
 607 AC_ARG_ENABLE(intermodule,
 608 [  --enable-intermodule    build the compiler in one step],
 609 [case ${enable_intermodule} in
 610   yes) onestep="-onestep";;
 611   *) onestep="";;
 612 esac],
 613 [onestep=""])
 614 AC_SUBST(onestep)
 615
 616 # -------------------------
 617 # Checks for other programs
 618 # -------------------------
 619
 620 AC_PROG_MAKE_SET
 621
 622 # Find some useful tools
 623 AC_PROG_AWK
 624 # We need awk to run opts.sh (to create options.c and options.h).
 625 # Bail out if it's missing.
 626 case ${AWK} in
 627   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 628 esac
 629
 630 gcc_AC_PROG_LN
 631 gcc_AC_PROG_LN_S
 632 AC_PROG_RANLIB
 633 gcc_AC_PROG_INSTALL
 634
 635 # See if cmp has --ignore-initial.
 636 gcc_AC_PROG_CMP_IGNORE_INITIAL
 637
 638 # See if we have the mktemp command.
 639 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 640
 641 # Do we have a single-tree copy of texinfo?
 642 if test -f $srcdir/../texinfo/Makefile.in; then
 643   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 644   gcc_cv_prog_makeinfo_modern=yes
 645   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 646 else
 647   # See if makeinfo has been installed and is modern enough
 648   # that we can use it.
 649   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 650   [GNU texinfo.* \([0-9][0-9.]*\)],
 651   [4.[2-9]*])
 652 fi
 653
 654 if test $gcc_cv_prog_makeinfo_modern = no; then
 655   AC_MSG_WARN([
 656 *** Makeinfo is missing or too old.
 657 *** Info documentation will not be built.])
 658   BUILD_INFO=
 659 else
 660   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 661 fi
 662
 663 # Is pod2man recent enough to regenerate manpages?
 664 AC_MSG_CHECKING([for recent Pod::Man])
 665 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 666   AC_MSG_RESULT(yes)
 667   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 668 else
 669   AC_MSG_RESULT(no)
 670   GENERATED_MANPAGES=
 671 fi
 672
 673 # How about lex?
 674 dnl Don't use AC_PROG_LEX; we insist on flex.
 675 dnl LEXLIB is not useful in gcc.
 676 if test -f $srcdir/../flex/skel.c; then
 677   FLEX='$(objdir)/../flex/flex'
 678 else
 679   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 680 fi
 681
 682 # Bison?
 683 # The -L switch is so bison can find its skeleton file.
 684 if test -f $srcdir/../bison/bison.simple; then
 685   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 686 else
 687   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 688 fi
 689
 690 # --------------------
 691 # Checks for C headers
 692 # --------------------
 693
 694 AC_MSG_CHECKING(for GNU C library)
 695 AC_CACHE_VAL(gcc_cv_glibc,
 696 [AC_TRY_COMPILE(
 697   [#include <features.h>],[
 698 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 699 #error Not a GNU C library system
 700 #endif],
 701   [gcc_cv_glibc=yes],
 702   gcc_cv_glibc=no)])
 703 AC_MSG_RESULT($gcc_cv_glibc)
 704 if test $gcc_cv_glibc = yes; then
 705   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 706 fi
 707
 708 # Need to reject headers which give warnings, so that the -Werror bootstrap
 709 # works later. *sigh*  This needs to come before all header checks.
 710 AC_PROG_CPP_WERROR
 711
 712 AC_HEADER_STDC
 713 AC_HEADER_TIME
 714 gcc_AC_HEADER_STDBOOL
 715 gcc_AC_HEADER_STRING
 716 AC_HEADER_SYS_WAIT
 717 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 718                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 719                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 720                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 721
 722 # Check for thread headers.
 723 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 724 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 725
 726 # These tests can't be done till we know if we have limits.h.
 727 gcc_AC_C_CHAR_BIT
 728 AC_C_BIGENDIAN_CROSS
 729
 730 # --------
 731 # UNSORTED
 732 # --------
 733
 734 # Stage specific cflags for build.
 735 stage1_cflags=
 736 case $build in
 737 vax-*-*)
 738   if test x$GCC = xyes
 739   then
 740     stage1_cflags="-Wa,-J"
 741   else
 742     stage1_cflags="-J"
 743   fi
 744   ;;
 745 powerpc-*-darwin*)
 746   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 747   # sources; use -no-cpp-precomp to get to GNU cpp.
 748   # Apple's GCC has bugs in designated initializer handling, so disable
 749   # that too.
 750   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 751   ;;
 752 esac
 753 AC_SUBST(stage1_cflags)
 754
 755 # These libraries may be used by collect2.
 756 # We may need a special search path to get them linked.
 757 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 758 [save_LIBS="$LIBS"
 759 for libs in '' -lld -lmld \
 760                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 761                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 762 do
 763         LIBS="$libs"
 764         AC_TRY_LINK_FUNC(ldopen,
 765                 [gcc_cv_collect2_libs="$libs"; break])
 766 done
 767 LIBS="$save_LIBS"
 768 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 769 case $gcc_cv_collect2_libs in
 770         "none required")        ;;
 771         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 772 esac
 773 AC_SUBST(COLLECT2_LIBS)
 774
 775 # When building Ada code on Alpha, we need exc_resume which is usually in
 776 # -lexc.  So test for it.
 777 save_LIBS="$LIBS"
 778 LIBS=
 779 AC_SEARCH_LIBS(exc_resume, exc)
 780 GNAT_LIBEXC="$LIBS"
 781 LIBS="$save_LIBS"
 782 AC_SUBST(GNAT_LIBEXC)
 783
 784 # Some systems put ldexp and frexp in libm instead of libc; assume
 785 # they're both in the same place.  jcf-dump needs them.
 786 save_LIBS="$LIBS"
 787 LIBS=
 788 AC_SEARCH_LIBS(ldexp, m)
 789 LDEXP_LIB="$LIBS"
 790 LIBS="$save_LIBS"
 791 AC_SUBST(LDEXP_LIB)
 792
 793 # Use <inttypes.h> only if it exists,
 794 # doesn't clash with <sys/types.h>, and declares intmax_t.
 795 AC_MSG_CHECKING(for inttypes.h)
 796 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 797 [AC_TRY_COMPILE(
 798   [#include <sys/types.h>
 799 #include <inttypes.h>],
 800   [intmax_t i = -1;],
 801   [gcc_cv_header_inttypes_h=yes],
 802   gcc_cv_header_inttypes_h=no)])
 803 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 804 if test $gcc_cv_header_inttypes_h = yes; then
 805   AC_DEFINE(HAVE_INTTYPES_H, 1,
 806         [Define if you have a working <inttypes.h> header file.])
 807 fi
 808
 809 dnl Disabled until we have a complete test for buggy enum bitfields.
 810 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 811
 812 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 813         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 814         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 815         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 816         setlocale)
 817
 818 if test x$ac_cv_func_mbstowcs = xyes; then
 819   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 820 [    AC_TRY_RUN([#include <stdlib.h>
 821 int main()
 822 {
 823   mbstowcs(0, "", 0);
 824   return 0;
 825 }],
 826     gcc_cv_func_mbstowcs_works=yes,
 827     gcc_cv_func_mbstowcs_works=no,
 828     gcc_cv_func_mbstowcs_works=yes)])
 829   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 830     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 831   [Define this macro if mbstowcs does not crash when its
 832    first argument is NULL.])
 833   fi
 834 fi
 835
 836 AC_CHECK_TYPE(ssize_t, int)
 837
 838 # Try to determine the array type of the second argument of getgroups
 839 # for the target system (int or gid_t).
 840 AC_TYPE_GETGROUPS
 841 if test "${target}" = "${build}"; then
 842   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 843 else
 844   case "${target}" in
 845         # This condition may need some tweaking.  It should include all
 846         # targets where the array type of the second argument of getgroups
 847         # is int and the type of gid_t is not equivalent to int.
 848         *-*-sunos* | *-*-ultrix*)
 849                 TARGET_GETGROUPS_T=int
 850                 ;;
 851         *)
 852                 TARGET_GETGROUPS_T=gid_t
 853                 ;;
 854   esac
 855 fi
 856 AC_SUBST(TARGET_GETGROUPS_T)
 857
 858 gcc_AC_FUNC_PRINTF_PTR
 859 gcc_AC_FUNC_MMAP_BLACKLIST
 860
 861 case "${host}" in
 862 *-*-*vms*)
 863   # Under VMS, vfork works very differently than on Unix. The standard test
 864   # won't work, and it isn't easily adaptable. It makes more sense to
 865   # just force it.
 866   ac_cv_func_vfork_works=yes
 867   ;;
 868 esac
 869 AC_FUNC_VFORK
 870
 871 AM_ICONV
 872 # Until we have in-tree GNU iconv:
 873 LIBICONV_DEP=
 874 AC_SUBST(LIBICONV_DEP)
 875
 876 AM_LC_MESSAGES
 877
 878 # We will need to find libiberty.h and ansidecl.h
 879 saved_CFLAGS="$CFLAGS"
 880 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 881 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 882         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 883         fprintf_unlocked strstr errno snprintf vasprintf \
 884         malloc realloc calloc free basename getopt clock, , ,[
 885 #include "ansidecl.h"
 886 #include "system.h"])
 887
 888 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 889 #include "ansidecl.h"
 890 #include "system.h"
 891 #ifdef HAVE_SYS_RESOURCE_H
 892 #include <sys/resource.h>
 893 #endif
 894 ])
 895
 896 AC_TRY_COMPILE([
 897 #include "ansidecl.h"
 898 #include "system.h"
 899 #ifdef HAVE_SYS_RESOURCE_H
 900 #include <sys/resource.h>
 901 #endif
 902 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 903 [Define to \`long' if <sys/resource.h> doesn't define.])])
 904
 905 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 906 #include "ansidecl.h"
 907 #include "system.h"
 908 #ifdef HAVE_LDFCN_H
 909 #include <ldfcn.h>
 910 #endif
 911 ])
 912
 913 gcc_AC_CHECK_DECLS(times, , ,[
 914 #include "ansidecl.h"
 915 #include "system.h"
 916 #ifdef HAVE_SYS_TIMES_H
 917 #include <sys/times.h>
 918 #endif
 919 ])
 920
 921 # More time-related stuff.
 922 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 923 AC_TRY_COMPILE([
 924 #include "ansidecl.h"
 925 #include "system.h"
 926 #ifdef HAVE_SYS_TIMES_H
 927 #include <sys/times.h>
 928 #endif
 929 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 930 if test $ac_cv_struct_tms = yes; then
 931   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 932   [Define if <sys/times.h> defines struct tms.])
 933 fi
 934
 935 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 936 # revisit after autoconf 2.50.
 937 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 938 AC_TRY_COMPILE([
 939 #include "ansidecl.h"
 940 #include "system.h"
 941 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 942 if test $gcc_cv_type_clock_t = yes; then
 943   AC_DEFINE(HAVE_CLOCK_T, 1,
 944   [Define if <time.h> defines clock_t.])
 945 fi
 946
 947 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 948 [AC_TRY_COMPILE([
 949 #include "ansidecl.h"
 950 #include "system.h"
 951 ],
 952 [if ((uchar *)0) return 0;
 953  if (sizeof(uchar)) return 0;],
 954 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 955 if test $ac_cv_type_uchar = yes; then
 956   AC_DEFINE(HAVE_UCHAR, 1,
 957   [Define if <sys/types.h> defines \`uchar'.])
 958 fi
 959
 960 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 961 CFLAGS="$saved_CFLAGS"
 962
 963 gcc_AC_INITFINI_ARRAY
 964
 965 # mkdir takes a single argument on some systems.
 966 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 967
 968 # File extensions
 969 manext='.1'
 970 objext='.o'
 971 AC_SUBST(manext)
 972 AC_SUBST(objext)
 973
 974 # With Setjmp/Longjmp based exception handling.
 975 AC_ARG_ENABLE(sjlj-exceptions,
 976 [  --enable-sjlj-exceptions
 977                           arrange to use setjmp/longjmp exception handling],
 978 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 979 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 980   [Define 0/1 to force the choice for exception handling model.])])
 981
 982 if test x$host = x$target; then
 983    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 984 else
 985    use_libunwind_default=no
 986 fi
 987 # Use libunwind based exception handling.
 988 AC_ARG_ENABLE(libunwind-exceptions,
 989 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 990 use_libunwind_exceptions=$enableval,
 991 use_libunwind_exceptions=$use_libunwind_default)
 992 if test x"$use_libunwind_exceptions" = xyes; then
 993    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 994         [Define if gcc should use -lunwind.])
 995 fi
 996
 997 # --------------------------------------------------------
 998 # Build, host, and target specific configuration fragments
 999 # --------------------------------------------------------
1000
1001 # Collect build-machine-specific information.
1002 . ${srcdir}/config.build
1003
1004 # Collect host-machine-specific information.
1005 . ${srcdir}/config.host
1006
1007 target_gtfiles=
1008
1009 # Collect target-machine-specific information.
1010 . ${srcdir}/config.gcc
1011
1012 extra_objs="${host_extra_objs} ${extra_objs}"
1013
1014 # Default the target-machine variables that were not explicitly set.
1015 if test x"$tm_file" = x
1016 then tm_file=$cpu_type/$cpu_type.h; fi
1017
1018 if test x"$extra_headers" = x
1019 then extra_headers=; fi
1020
1021 if test x$md_file = x
1022 then md_file=$cpu_type/$cpu_type.md; fi
1023
1024 if test x$out_file = x
1025 then out_file=$cpu_type/$cpu_type.c; fi
1026
1027 if test x"$tmake_file" = x
1028 then tmake_file=$cpu_type/t-$cpu_type
1029 fi
1030
1031 if test x"$dwarf2" = xyes
1032 then tm_file="$tm_file tm-dwarf2.h"
1033 fi
1034
1035 # Say what files are being used for the output code and MD file.
1036 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1037 echo "Using \`$srcdir/config/$md_file' as machine description file."
1038
1039 # If any of the xm_file variables contain nonexistent files, warn
1040 # about them and drop them.
1041
1042 bx=
1043 for x in $build_xm_file; do
1044   if    test -f $srcdir/config/$x
1045   then      bx="$bx $x"
1046   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1047   fi
1048 done
1049 build_xm_file="$bx"
1050
1051 hx=
1052 for x in $host_xm_file; do
1053   if    test -f $srcdir/config/$x
1054   then      hx="$hx $x"
1055   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1056   fi
1057 done
1058 host_xm_file="$hx"
1059
1060 tx=
1061 for x in $xm_file; do
1062   if    test -f $srcdir/config/$x
1063   then      tx="$tx $x"
1064   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1065   fi
1066 done
1067 xm_file="$tx"
1068
1069 count=a
1070 for f in $tm_file; do
1071         count=${count}x
1072 done
1073 if test $count = ax; then
1074         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1075 else
1076         echo "Using the following target machine macro files:"
1077         for f in $tm_file; do
1078                 echo "  $srcdir/config/$f"
1079         done
1080 fi
1081
1082 if test x$need_64bit_hwint = xyes; then
1083         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1084 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1085 fi
1086
1087 count=a
1088 for f in $host_xm_file; do
1089         count=${count}x
1090 done
1091 if test $count = a; then
1092         :
1093 elif test $count = ax; then
1094         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1095 else
1096         echo "Using the following host machine macro files:"
1097         for f in $host_xm_file; do
1098                 echo "  $srcdir/config/$f"
1099         done
1100 fi
1101 echo "Using ${out_host_hook_obj} for host machine hooks."
1102
1103 if test "$host_xm_file" != "$build_xm_file"; then
1104         count=a
1105         for f in $build_xm_file; do
1106                 count=${count}x
1107         done
1108         if test $count = a; then
1109                 :
1110         elif test $count = ax; then
1111                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1112         else
1113                 echo "Using the following build machine macro files:"
1114                 for f in $build_xm_file; do
1115                         echo "  $srcdir/config/$f"
1116                 done
1117         fi
1118 fi
1119
1120 # Check if a valid thread package
1121 case ${enable_threads_flag} in
1122   "" | no)
1123     # No threads
1124     target_thread_file='single'
1125     ;;
1126   yes)
1127     # default
1128     target_thread_file='single'
1129     ;;
1130   aix | dce | gnat | irix | posix | rtems | \
1131   single | solaris | vxworks | win32 )
1132     target_thread_file=${enable_threads_flag}
1133     ;;
1134   *)
1135     echo "${enable_threads_flag} is an unknown thread package" 1>&2
1136     exit 1
1137     ;;
1138 esac
1139
1140 if test x${thread_file} = x; then
1141   # No thread file set by target-specific clauses in config.gcc,
1142   # so use file chosen by default logic above
1143   thread_file=${target_thread_file}
1144 fi
1145
1146 if test x$enable___cxa_atexit = xyes || \
1147    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1148    AC_CHECK_FUNC(__cxa_atexit,
1149         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1150         [Define if you want to use __cxa_atexit, rather than atexit, to
1151         register C++ destructors for local statics and global objects.
1152         This is essential for fully standards-compliant handling of
1153         destructors, but requires __cxa_atexit in libc.])],
1154         echo "__cxa_atexit can't be enabled on this target")
1155 fi
1156
1157 # Look for a file containing extra machine modes.
1158 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1159   extra_modes_file='$(srcdir)'/config/${extra_modes}
1160   AC_SUBST(extra_modes_file)
1161   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1162   [Define to the name of a file containing a list of extra machine modes
1163    for this architecture.])
1164 fi
1165
1166 # auto-host.h is the file containing items generated by autoconf and is
1167 # the first file included by config.h.
1168 # If host=build, it is correct to have bconfig include auto-host.h
1169 # as well.  If host!=build, we are in error and need to do more
1170 # work to find out the build config parameters.
1171 if test x$host = x$build
1172 then
1173         build_auto=auto-host.h
1174         FORBUILD=..
1175 else
1176         # We create a subdir, then run autoconf in the subdir.
1177         # To prevent recursion we set host and build for the new
1178         # invocation of configure to the build for this invocation
1179         # of configure.
1180         tempdir=build.$$
1181         rm -rf $tempdir
1182         mkdir $tempdir
1183         cd $tempdir
1184         case ${srcdir} in
1185         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1186         *) realsrcdir=../${srcdir};;
1187         esac
1188         saved_CFLAGS="${CFLAGS}"
1189         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1190         ${realsrcdir}/configure \
1191                 --enable-languages=${enable_languages} \
1192                 --target=$target_alias --host=$build_alias --build=$build_alias
1193         CFLAGS="${saved_CFLAGS}"
1194
1195         # We just finished tests for the build machine, so rename
1196         # the file auto-build.h in the gcc directory.
1197         mv auto-host.h ../auto-build.h
1198         cd ..
1199         rm -rf $tempdir
1200         build_auto=auto-build.h
1201         FORBUILD=../${build_subdir}
1202 fi
1203 AC_SUBST(FORBUILD)
1204
1205 tm_file="${tm_file} defaults.h"
1206 tm_p_file="${tm_p_file} tm-preds.h"
1207 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1208 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1209 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1210 # put this back in temporarily.
1211 xm_file="ansidecl.h ${xm_file}"
1212
1213 # --------
1214 # UNSORTED
1215 # --------
1216
1217 # Get the version trigger filename from the toplevel
1218 if test "${with_gcc_version_trigger+set}" = set; then
1219         gcc_version_trigger=$with_gcc_version_trigger
1220 else
1221         gcc_version_trigger=${srcdir}/version.c
1222 fi
1223 changequote(,)dnl
1224 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1225 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1226
1227 # Compile in configure arguments.
1228 if test -f configargs.h ; then
1229         # Being re-configured.
1230         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1231         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1232 else
1233         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1234 fi
1235
1236 # Double all backslashes and backslash all quotes to turn
1237 # gcc_config_arguments into a C string.
1238 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1239 $gcc_config_arguments
1240 EOF
1241 gcc_config_arguments_str=`cat conftest.out`
1242 rm -f conftest.out
1243
1244 cat > configargs.h <<EOF
1245 /* Generated automatically. */
1246 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1247 static const char thread_model[] = "$thread_file";
1248
1249 static const struct {
1250   const char *name, *value;
1251 } configure_default_options[] = $configure_default_options;
1252 EOF
1253 changequote([,])dnl
1254
1255 # Internationalization
1256 PACKAGE=gcc
1257 VERSION="$gcc_version"
1258 AC_SUBST(PACKAGE)
1259 AC_SUBST(VERSION)
1260
1261 ZW_GNU_GETTEXT_SISTER_DIR
1262
1263 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1264 # -liconv on the link line twice.
1265 case "$LIBINTL" in *$LIBICONV*)
1266         LIBICONV= ;;
1267 esac
1268
1269 # Windows32 Registry support for specifying GCC installation paths.
1270 AC_ARG_ENABLE(win32-registry,
1271 [  --disable-win32-registry
1272                           disable lookup of installation paths in the
1273                           Registry on Windows hosts
1274   --enable-win32-registry enable registry lookup (default)
1275   --enable-win32-registry=KEY
1276                           use KEY instead of GCC version as the last portion
1277                           of the registry key],,)
1278 case $host_os in
1279         win32 | pe | cygwin* | mingw32* | uwin*)
1280 AC_MSG_CHECKING(whether windows registry support is requested)
1281 if test "x$enable_win32_registry" != xno; then
1282   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1283 [Define to 1 if installation paths should be looked up in Windows32
1284    Registry. Ignored on non windows32 hosts.])
1285   AC_MSG_RESULT(yes)
1286   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1287 else
1288   AC_MSG_RESULT(no)
1289 fi
1290
1291 # Check if user specified a different registry key.
1292 case "x${enable_win32_registry}" in
1293 x | xyes)
1294   # default.
1295   gcc_cv_win32_registry_key="$VERSION"
1296   ;;
1297 xno)
1298   # no registry lookup.
1299   gcc_cv_win32_registry_key=''
1300   ;;
1301 *)
1302   # user-specified key.
1303   gcc_cv_win32_registry_key="$enable_win32_registry"
1304   ;;
1305 esac
1306
1307 if test "x$enable_win32_registry" != xno; then
1308   AC_MSG_CHECKING(registry key on windows hosts)
1309   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1310         [Define to be the last portion of registry key on windows hosts.])
1311   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1312 fi
1313 ;;
1314 esac
1315
1316 # Get an absolute path to the GCC top-level source directory
1317 holddir=`${PWDCMD-pwd}`
1318 cd $srcdir
1319 topdir=`${PWDCMD-pwd}`
1320 cd $holddir
1321
1322 # Conditionalize the makefile for this host machine.
1323 xmake_file=
1324 for f in ${host_xmake_file}
1325 do
1326         if test -f ${srcdir}/config/$f
1327         then
1328                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1329         fi
1330 done
1331
1332 # Conditionalize the makefile for this target machine.
1333 tmake_file_=
1334 for f in ${tmake_file}
1335 do
1336         if test -f ${srcdir}/config/$f
1337         then
1338                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1339         fi
1340 done
1341 tmake_file="${tmake_file_}"
1342
1343 symbolic_link='ln -s'
1344
1345 # If the host doesn't support symlinks, modify CC in
1346 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1347 # Otherwise, we can use "CC=$(CC)".
1348 rm -f symtest.tem
1349 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1350 then
1351         cc_set_by_configure="\$(CC)"
1352         quoted_cc_set_by_configure="\$(CC)"
1353         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1354         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1355 else
1356         rm -f symtest.tem
1357         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1358         then
1359                 symbolic_link="cp -p"
1360         else
1361                 symbolic_link="cp"
1362         fi
1363         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1364         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1365         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1366         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1367 fi
1368 rm -f symtest.tem
1369
1370 out_object_file=`basename $out_file .c`.o
1371
1372 tm_file_list=
1373 tm_include_list=
1374 for f in $tm_file; do
1375   case $f in
1376     defaults.h )
1377        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1378        tm_include_list="${tm_include_list} $f"
1379        ;;
1380     * )
1381        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1382        tm_include_list="${tm_include_list} config/$f"
1383        ;;
1384   esac
1385 done
1386
1387 tm_p_file_list=
1388 tm_p_include_list=
1389 for f in $tm_p_file; do
1390   case $f in
1391     tm-preds.h )
1392        tm_p_file_list="${tm_p_file_list} $f"
1393        tm_p_include_list="${tm_p_include_list} $f"
1394        ;;
1395     * )
1396        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1397        tm_p_include_list="${tm_p_include_list} config/$f"
1398   esac
1399 done
1400
1401 xm_file_list=
1402 xm_include_list=
1403 for f in $xm_file; do
1404   case $f in
1405     ansidecl.h )
1406        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1407        xm_include_list="${xm_include_list} $f"
1408        ;;
1409     auto-host.h )
1410        xm_file_list="${xm_file_list} $f"
1411        xm_include_list="${xm_include_list} $f"
1412        ;;
1413     * )
1414        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1415        xm_include_list="${xm_include_list} config/$f"
1416        ;;
1417   esac
1418 done
1419
1420 host_xm_file_list=
1421 host_xm_include_list=
1422 for f in $host_xm_file; do
1423   case $f in
1424     ansidecl.h )
1425        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1426        host_xm_include_list="${host_xm_include_list} $f"
1427        ;;
1428     auto-host.h )
1429        host_xm_file_list="${host_xm_file_list} $f"
1430        host_xm_include_list="${host_xm_include_list} $f"
1431        ;;
1432     * )
1433        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1434        host_xm_include_list="${host_xm_include_list} config/$f"
1435        ;;
1436   esac
1437 done
1438
1439 build_xm_file_list=
1440 for f in $build_xm_file; do
1441   case $f in
1442     ansidecl.h )
1443        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1444        build_xm_include_list="${build_xm_include_list} $f"
1445        ;;
1446     auto-build.h | auto-host.h )
1447        build_xm_file_list="${build_xm_file_list} $f"
1448        build_xm_include_list="${build_xm_include_list} $f"
1449        ;;
1450     * )
1451        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1452        build_xm_include_list="${build_xm_include_list} config/$f"
1453        ;;
1454   esac
1455 done
1456
1457 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1458 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1459 CROSS=                                          AC_SUBST(CROSS)
1460 ALL=all.internal                                AC_SUBST(ALL)
1461 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1462 if test x$host != x$target
1463 then
1464         CROSS="-DCROSS_COMPILE"
1465         ALL=all.cross
1466         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1467         case "$host","$target" in
1468         # Darwin crosses can use the host system's libraries and headers,
1469         # because of the fat library support.  Of course, it must be the
1470         # same version of Darwin on both sides.  Allow the user to
1471         # just say --target=foo-darwin without a version number to mean
1472         # "the version on this system".
1473             *-*-darwin*,*-*-darwin*)
1474                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1475                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1476                 if test $hostos = $targetos -o $targetos = darwin ; then
1477                     CROSS=
1478                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1479                     with_headers=yes
1480                 fi
1481                 ;;
1482
1483             i?86-*-*,x86_64-*-* \
1484             | powerpc*-*-*,powerpc64*-*-*)
1485                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1486         esac
1487 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1488         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1489         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1490 fi
1491
1492 # If this is a cross-compiler that does not
1493 # have its own set of headers then define
1494 # inhibit_libc
1495
1496 # If this is using newlib, without having the headers available now,
1497 # then define inhibit_libc in LIBGCC2_CFLAGS.
1498 # This prevents libgcc2 from containing any code which requires libc
1499 # support.
1500 inhibit_libc=
1501 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1502        test x$with_newlib = xyes ; } &&
1503      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1504        inhibit_libc=-Dinhibit_libc
1505 fi
1506 AC_SUBST(inhibit_libc)
1507
1508 # When building gcc with a cross-compiler, we need to adjust things so
1509 # that the generator programs are still built with the native compiler.
1510 # Also, we cannot run fixincludes or fix-header.
1511
1512 # These are the normal (build=host) settings:
1513 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1514 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1515 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1516 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1517
1518 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1519
1520 # Possibly disable fixproto, on a per-target basis.
1521 case ${use_fixproto} in
1522   no)
1523     STMP_FIXPROTO=
1524     ;;
1525   yes)
1526     STMP_FIXPROTO=stmp-fixproto
1527     ;;
1528 esac
1529 AC_SUBST(STMP_FIXPROTO)
1530
1531 # And these apply if build != host, or we are generating coverage data
1532 if test x$build != x$host || test "x$coverage_flags" != x
1533 then
1534     BUILD_PREFIX=build-
1535     BUILD_PREFIX_1=build-
1536     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1537
1538     if test "x$TARGET_SYSTEM_ROOT" = x; then
1539         STMP_FIXINC=
1540         STMP_FIXPROTO=
1541     fi
1542 fi
1543
1544 # Expand extra_headers to include complete path.
1545 # This substitutes for lots of t-* files.
1546 extra_headers_list=
1547 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1548 for file in ${extra_headers} ; do
1549   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1550 done
1551
1552 # Add a definition of USE_COLLECT2 if system wants one.
1553 case $use_collect2 in
1554   no) use_collect2= ;;
1555   "") ;;
1556   *)
1557     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1558     xm_defines="${xm_defines} USE_COLLECT2"
1559     ;;
1560 esac
1561
1562 # Identify the assembler which will work hand-in-glove with the newly
1563 # built GCC, so that we can examine its features.  This is the assembler
1564 # which will be driven by the driver program.
1565 #
1566 # If build != host, and we aren't building gas in-tree, we identify a
1567 # build->target assembler and hope that it will have the same features
1568 # as the host->target assembler we'll be using.
1569 AC_MSG_CHECKING(what assembler to use)
1570 in_tree_gas=no
1571 gcc_cv_as=
1572 gcc_cv_gas_major_version=
1573 gcc_cv_gas_minor_version=
1574 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1575 if test -x "$DEFAULT_ASSEMBLER"; then
1576         gcc_cv_as="$DEFAULT_ASSEMBLER"
1577 elif test -x "$AS"; then
1578         gcc_cv_as="$AS"
1579 elif test -x as$host_exeext; then
1580         # Build using assembler in the current directory.
1581         gcc_cv_as=./as$host_exeext
1582 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1583      && test -f ../gas/Makefile; then
1584   # Single tree build which includes gas.
1585   in_tree_gas=yes
1586   _gcc_COMPUTE_GAS_VERSION
1587   rm -f as$host_exeext
1588   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1589   in_tree_gas_is_elf=no
1590   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1591      || (grep 'obj_format = multi' ../gas/Makefile \
1592          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1593   then
1594     in_tree_gas_is_elf=yes
1595   fi
1596 fi
1597
1598 if test "x$gcc_cv_as" = x; then
1599         # Search the same directories that the installed compiler will
1600         # search.  Else we may find the wrong assembler and lose.  If we
1601         # do not find a suitable assembler binary, then try the user's
1602         # path.
1603         #
1604         # Also note we have to check MD_EXEC_PREFIX before checking the
1605         # user's path.  Unfortunately, there is no good way to get at the
1606         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1607         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1608         # to be fixed as part of the make/configure rewrite too.
1609
1610         if test "x$exec_prefix" = xNONE; then
1611                 if test "x$prefix" = xNONE; then
1612                         test_prefix=/usr/local
1613                 else
1614                         test_prefix=$prefix
1615                 fi
1616         else
1617                 test_prefix=$exec_prefix
1618         fi
1619
1620         # If the loop below does not find an assembler, then use whatever
1621         # one we can find in the users's path.
1622         # user's path.
1623         if test "x$program_prefix" != xNONE; then
1624                 gcc_cv_as=${program_prefix}as$host_exeext
1625         else
1626                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1627         fi
1628
1629         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1630                    $test_prefix/libexec/gcc/$target_noncanonical \
1631                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1632                    /usr/lib/gcc/$target_noncanonical \
1633                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1634                    $test_prefix/$target_noncanonical/bin"
1635
1636         if test x$host = x$target; then
1637             test_dirs="$test_dirs \
1638                    /usr/libexec \
1639                    /usr/ccs/gcc \
1640                    /usr/ccs/bin \
1641                    /udk/usr/ccs/bin \
1642                    /bsd43/usr/lib/cmplrs/cc \
1643                    /usr/cross64/usr/bin \
1644                    /usr/lib/cmplrs/cc \
1645                    /sysv/usr/lib/cmplrs/cc \
1646                    /svr4/usr/lib/cmplrs/cc \
1647                    /usr/bin"
1648         fi
1649
1650         for dir in $test_dirs; do
1651                 if test -x $dir/as$host_exeext; then
1652                         gcc_cv_as=$dir/as$host_exeext
1653                         break;
1654                 fi
1655         done
1656 fi
1657 case $in_tree_gas in
1658   yes)
1659     AC_MSG_RESULT("newly built gas")
1660     ;;
1661   no)
1662     AC_MSG_RESULT($gcc_cv_as)
1663     ;;
1664 esac
1665
1666 # Identify the linker which will work hand-in-glove with the newly
1667 # built GCC, so that we can examine its features.  This is the linker
1668 # which will be driven by the driver program.
1669 #
1670 # If build != host, and we aren't building gas in-tree, we identify a
1671 # build->target linker and hope that it will have the same features
1672 # as the host->target linker we'll be using.
1673 AC_MSG_CHECKING(what linker to use)
1674 in_tree_ld=no
1675 gcc_cv_ld=
1676 gcc_cv_gld_major_version=
1677 gcc_cv_gld_minor_version=
1678 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1679 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1680 if test -x "$DEFAULT_LINKER"; then
1681         gcc_cv_ld="$DEFAULT_LINKER"
1682 elif test -x "$LD_FOR_TARGET"; then
1683         gcc_cv_ld="$LD_FOR_TARGET"
1684 elif test -x "$LD" && test x$host = x$target; then
1685         gcc_cv_ld="$LD"
1686 elif test -x collect-ld$host_exeext; then
1687         # Build using linker in the current directory.
1688         gcc_cv_ld=./collect-ld$host_exeext
1689 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1690      && test -f ../ld/Makefile; then
1691         # Single tree build which includes ld.
1692         in_tree_ld=yes
1693         in_tree_ld_is_elf=no
1694         if (grep 'EMUL = .*elf' ../ld/Makefile \
1695             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1696           in_tree_ld_is_elf=yes
1697         fi
1698         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1699         do
1700 changequote(,)dnl
1701                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1702 changequote([,])dnl
1703                 if test x$gcc_cv_gld_version != x; then
1704                         break
1705                 fi
1706         done
1707 changequote(,)dnl
1708         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1709         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1710 changequote([,])dnl
1711         rm -f collect-ld$host_exeext
1712         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1713                 2>/dev/null
1714 fi
1715
1716 if test "x$gcc_cv_ld" = x; then
1717         # Search the same directories that the installed compiler will
1718         # search.  Else we may find the wrong linker and lose.  If we
1719         # do not find a suitable linker binary, then try the user's
1720         # path.
1721         #
1722         # Also note we have to check MD_EXEC_PREFIX before checking the
1723         # user's path.  Unfortunately, there is no good way to get at the
1724         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1725         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1726         # to be fixed as part of the make/configure rewrite too.
1727
1728         if test "x$exec_prefix" = xNONE; then
1729                 if test "x$prefix" = xNONE; then
1730                         test_prefix=/usr/local
1731                 else
1732                         test_prefix=$prefix
1733                 fi
1734         else
1735                 test_prefix=$exec_prefix
1736         fi
1737
1738         # If the loop below does not find an linker, then use whatever
1739         # one we can find in the users's path.
1740         # user's path.
1741         if test "x$program_prefix" != xNONE; then
1742                 gcc_cv_ld=${program_prefix}ld$host_exeext
1743         else
1744                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1745         fi
1746
1747         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1748                    $test_prefix/libexec/gcc/$target_noncanonical \
1749                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1750                    /usr/lib/gcc/$target_noncanonical \
1751                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1752                    $test_prefix/$target_noncanonical/bin"
1753
1754         if test x$host = x$target; then
1755             test_dirs="$test_dirs \
1756                    /usr/libexec \
1757                    /usr/ccs/gcc \
1758                    /usr/ccs/bin \
1759                    /udk/usr/ccs/bin \
1760                    /bsd43/usr/lib/cmplrs/cc \
1761                    /usr/cross64/usr/bin \
1762                    /usr/lib/cmplrs/cc \
1763                    /sysv/usr/lib/cmplrs/cc \
1764                    /svr4/usr/lib/cmplrs/cc \
1765                    /usr/bin"
1766         fi
1767
1768         for dir in $test_dirs; do
1769                 if test -x $dir/ld$host_exeext; then
1770                         gcc_cv_ld=$dir/ld$host_exeext
1771                         break;
1772                 fi
1773         done
1774 fi
1775 case $in_tree_ld in
1776   yes)
1777     AC_MSG_RESULT("newly built ld")
1778     ;;
1779   no)
1780     AC_MSG_RESULT($gcc_cv_ld)
1781     ;;
1782 esac
1783
1784 # Figure out what nm we will be using.
1785 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1786 AC_MSG_CHECKING(what nm to use)
1787 in_tree_nm=no
1788 if test -x nm$host_exeext; then
1789         gcc_cv_nm=./nm$host_exeext
1790 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1791      && test -f ../binutils/Makefile; then
1792         # Single tree build which includes binutils.
1793         in_tree_nm=yes
1794         gcc_cv_nm=./nm$host_exeext
1795         rm -f nm$host_exeext
1796         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1797 elif test "x$program_prefix" != xNONE; then
1798         gcc_cv_nm=${program_prefix}nm$host_exeext
1799 else
1800         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1801 fi
1802 case $in_tree_nm in
1803   yes) AC_MSG_RESULT("newly built nm") ;;
1804   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1805 esac
1806
1807 # Figure out what objdump we will be using.
1808 AC_MSG_CHECKING(what objdump to use)
1809 in_tree_objdump=no
1810 if test -x objdump$host_exeext; then
1811         gcc_cv_objdump=./objdump$host_exeext
1812 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1813      && test -f ../binutils/Makefile; then
1814         # Single tree build which includes binutils.
1815         in_tree_objdump=yes
1816         gcc_cv_objdump=./objdump$host_exeext
1817         rm -f objdump$host_exeext
1818         $symbolic_link ../binutils/objdump$host_exeext \
1819                 objdump$host_exeext 2>/dev/null
1820 elif test "x$program_prefix" != xNONE; then
1821         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1822 else
1823         gcc_cv_objdump=`echo objdump | \
1824                 sed "${program_transform_name}"`$host_exeext
1825 fi
1826 case $in_tree_objdump in
1827   yes) AC_MSG_RESULT("newly built objdump") ;;
1828   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1829 esac
1830
1831 # Figure out what assembler alignment features are present.
1832 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1833  [2,6,0],,
1834 [.balign 4
1835 .p2align 2],,
1836 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1837   [Define if your assembler supports .balign and .p2align.])])
1838
1839 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1840  [2,8,0],,
1841  [.p2align 4,,7],,
1842 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1843   [Define if your assembler supports specifying the maximum number
1844    of bytes to skip when using the GAS .p2align command.])])
1845
1846 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1847  [elf,2,9,0],,
1848  [conftest_label1: .word 0
1849 .subsection -1
1850 conftest_label2: .word 0
1851 .previous],
1852  [if test x$gcc_cv_nm != x; then
1853     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1854     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1855     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1856     then :
1857     else gcc_cv_as_subsection_m1=yes
1858     fi
1859     rm -f conftest.nm1 conftest.nm2
1860   fi],
1861  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1862   [Define if your assembler supports .subsection and .subsection -1 starts
1863    emitting at the beginning of your section.])])
1864
1865 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1866  [2,2,0],,
1867  [      .weak foobar],,
1868 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1869
1870 # .hidden needs to be supported in both the assembler and the linker,
1871 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1872 # This is irritatingly difficult to feature test for; we have to check the
1873 # date string after the version number.  If we've got an in-tree
1874 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1875 # to be safe.
1876 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1877 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1878  [elf,2,13,0],,
1879 [       .hidden foobar
1880 foobar:])
1881
1882 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1883 [if test $in_tree_ld = yes ; then
1884   gcc_cv_ld_hidden=no
1885   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1886      && test $in_tree_ld_is_elf = yes; then
1887      gcc_cv_ld_hidden=yes
1888   fi
1889 else
1890   gcc_cv_ld_hidden=yes
1891   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1892   if echo "$ld_ver" | grep GNU > /dev/null; then
1893 changequote(,)dnl
1894     ld_vers=`echo $ld_ver | sed -n \
1895         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1896         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1897         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1898         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1899         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1900         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1901     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1902     if test 0"$ld_date" -lt 20020404; then
1903       if test -n "$ld_date"; then
1904         # If there was date string, but was earlier than 2002-04-04, fail
1905         gcc_cv_ld_hidden=no
1906       elif test -z "$ld_vers"; then
1907         # If there was no date string nor ld version number, something is wrong
1908         gcc_cv_ld_hidden=no
1909       else
1910         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1911         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1912         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1913         test -z "$ld_vers_patch" && ld_vers_patch=0
1914         if test "$ld_vers_major" -lt 2; then
1915           gcc_cv_ld_hidden=no
1916         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1917           gcc_cv_ld_hidden="no"
1918         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1919           gcc_cv_ld_hidden=no
1920         fi
1921       fi
1922 changequote([,])dnl
1923     fi
1924   else
1925     case "${target}" in
1926       hppa64*-*-hpux* | ia64*-*-hpux*)
1927         gcc_cv_ld_hidden=yes
1928         ;;
1929       *)
1930         gcc_cv_ld_hidden=no
1931         ;;
1932     esac
1933   fi
1934 fi])
1935 libgcc_visibility=no
1936 AC_SUBST(libgcc_visibility)
1937 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1938   libgcc_visibility=yes
1939   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1940   [Define if your assembler and linker support .hidden.])
1941 fi
1942
1943 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1944 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1945   [elf,2,11,0],,
1946 [       .data
1947         .uleb128 L2 - L1
1948 L1:
1949         .uleb128 1280
1950         .sleb128 -1010
1951 L2:],
1952  [# GAS versions before 2.11 do not support uleb128,
1953   # despite appearing to.
1954   # ??? There exists an elf-specific test that will crash
1955   # the assembler.  Perhaps it's better to figure out whether
1956   # arbitrary sections are supported and try the test.
1957   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1958   if echo "$as_ver" | grep GNU > /dev/null; then
1959 changequote(,)dnl
1960     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1961     as_major=`echo $as_ver | sed 's/\..*//'`
1962     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1963 changequote([,])dnl
1964     if test $as_major -eq 2 && test $as_minor -lt 11
1965     then :
1966     else gcc_cv_as_leb128=yes
1967     fi
1968   fi],
1969   [AC_DEFINE(HAVE_AS_LEB128, 1,
1970     [Define if your assembler supports .sleb128 and .uleb128.])])
1971
1972 # GAS versions up to and including 2.11.0 may mis-optimize
1973 # .eh_frame data.
1974 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1975   [elf,2,12,0],,
1976 [       .text
1977 .LFB1:
1978         .4byte  0
1979 .L1:
1980         .4byte  0
1981 .LFE1:
1982         .section        .eh_frame,"aw",@progbits
1983 __FRAME_BEGIN__:
1984         .4byte  .LECIE1-.LSCIE1
1985 .LSCIE1:
1986         .4byte  0x0
1987         .byte   0x1
1988         .ascii "z\0"
1989         .byte   0x1
1990         .byte   0x78
1991         .byte   0x1a
1992         .byte   0x0
1993         .byte   0x4
1994         .4byte  1
1995         .p2align 1
1996 .LECIE1:
1997 .LSFDE1:
1998         .4byte  .LEFDE1-.LASFDE1
1999 .LASFDE1:
2000         .4byte  .LASFDE1-__FRAME_BEGIN__
2001         .4byte  .LFB1
2002         .4byte  .LFE1-.LFB1
2003         .byte   0x4
2004         .4byte  .LFE1-.LFB1
2005         .byte   0x4
2006         .4byte  .L1-.LFB1
2007 .LEFDE1:],
2008 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2009 cat > conftest.lit <<EOF
2010  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2011  0010 01000000 12000000 18000000 00000000  ................
2012  0020 08000000 04080000 0044               .........D      @&t@
2013 EOF
2014 cat > conftest.big <<EOF
2015  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2016  0010 00000001 00000012 00000018 00000000  ................
2017  0020 00000008 04000000 0844               .........D      @&t@
2018 EOF
2019   # If the assembler didn't choke, and we can objdump,
2020   # and we got the correct data, then succeed.
2021   if test x$gcc_cv_objdump != x \
2022   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2023      | tail -3 > conftest.got \
2024   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2025     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2026   then
2027     gcc_cv_as_eh_frame=yes
2028   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2029     gcc_cv_as_eh_frame=buggy
2030   else
2031     # Uh oh, what do we do now?
2032     gcc_cv_as_eh_frame=no
2033   fi])
2034
2035 if test $gcc_cv_as_eh_frame = buggy; then
2036   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2037   [Define if your assembler mis-optimizes .eh_frame data.])
2038 fi
2039
2040 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2041  [elf,2,12,0], [--fatal-warnings],
2042  [.section .rodata.str, "aMS", @progbits, 1])
2043 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2044   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2045 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2046
2047 # Thread-local storage - the check is heavily parametrized.
2048 conftest_s=
2049 tls_first_major=
2050 tls_first_minor=
2051 tls_as_opt=
2052 case "$target" in
2053 changequote(,)dnl
2054   alpha*-*-*)
2055     conftest_s='
2056         .section ".tdata","awT",@progbits
2057 foo:    .long   25
2058         .text
2059         ldq     $27,__tls_get_addr($29)         !literal!1
2060         lda     $16,foo($29)                    !tlsgd!1
2061         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2062         ldq     $27,__tls_get_addr($29)         !literal!2
2063         lda     $16,foo($29)                    !tlsldm!2
2064         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2065         ldq     $1,foo($29)                     !gotdtprel
2066         ldah    $2,foo($29)                     !dtprelhi
2067         lda     $3,foo($2)                      !dtprello
2068         lda     $4,foo($29)                     !dtprel
2069         ldq     $1,foo($29)                     !gottprel
2070         ldah    $2,foo($29)                     !tprelhi
2071         lda     $3,foo($2)                      !tprello
2072         lda     $4,foo($29)                     !tprel'
2073         tls_first_major=2
2074         tls_first_minor=13
2075         tls_as_opt=--fatal-warnings
2076         ;;
2077   i[34567]86-*-*)
2078     conftest_s='
2079         .section ".tdata","awT",@progbits
2080 foo:    .long   25
2081         .text
2082         movl    %gs:0, %eax
2083         leal    foo@TLSGD(,%ebx,1), %eax
2084         leal    foo@TLSLDM(%ebx), %eax
2085         leal    foo@DTPOFF(%eax), %edx
2086         movl    foo@GOTTPOFF(%ebx), %eax
2087         subl    foo@GOTTPOFF(%ebx), %eax
2088         addl    foo@GOTNTPOFF(%ebx), %eax
2089         movl    foo@INDNTPOFF, %eax
2090         movl    $foo@TPOFF, %eax
2091         subl    $foo@TPOFF, %eax
2092         leal    foo@NTPOFF(%ecx), %eax'
2093         tls_first_major=2
2094         tls_first_minor=14
2095         tls_as_opt=--fatal-warnings
2096         ;;
2097   x86_64-*-*)
2098     conftest_s='
2099         .section ".tdata","awT",@progbits
2100 foo:    .long   25
2101         .text
2102         movq    %fs:0, %rax
2103         leaq    foo@TLSGD(%rip), %rdi
2104         leaq    foo@TLSLD(%rip), %rdi
2105         leaq    foo@DTPOFF(%rax), %rdx
2106         movq    foo@GOTTPOFF(%rip), %rax
2107         movq    $foo@TPOFF, %rax'
2108         tls_first_major=2
2109         tls_first_minor=14
2110         tls_as_opt=--fatal-warnings
2111         ;;
2112   ia64-*-*)
2113     conftest_s='
2114         .section ".tdata","awT",@progbits
2115 foo:    data8   25
2116         .text
2117         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2118         addl    r17 = @ltoff(@dtprel(foo#)), gp
2119         addl    r18 = @ltoff(@tprel(foo#)), gp
2120         addl    r19 = @dtprel(foo#), gp
2121         adds    r21 = @dtprel(foo#), r13
2122         movl    r23 = @dtprel(foo#)
2123         addl    r20 = @tprel(foo#), gp
2124         adds    r22 = @tprel(foo#), r13
2125         movl    r24 = @tprel(foo#)'
2126         tls_first_major=2
2127         tls_first_minor=13
2128         tls_as_opt=--fatal-warnings
2129         ;;
2130   powerpc-*-*)
2131     conftest_s='
2132         .section ".tdata","awT",@progbits
2133         .align 2
2134 ld0:    .space 4
2135 ld1:    .space 4
2136 x1:     .space 4
2137 x2:     .space 4
2138 x3:     .space 4
2139         .text
2140         addi 3,31,ld0@got@tlsgd
2141         bl __tls_get_addr
2142         addi 3,31,x1@got@tlsld
2143         bl __tls_get_addr
2144         addi 9,3,x1@dtprel
2145         addis 9,3,x2@dtprel@ha
2146         addi 9,9,x2@dtprel@l
2147         lwz 9,x3@got@tprel(31)
2148         add 9,9,x@tls
2149         addi 9,2,x1@tprel
2150         addis 9,2,x2@tprel@ha
2151         addi 9,9,x2@tprel@l'
2152         tls_first_major=2
2153         tls_first_minor=14
2154         tls_as_opt="-a32 --fatal-warnings"
2155         ;;
2156   powerpc64-*-*)
2157     conftest_s='
2158         .section ".tdata","awT",@progbits
2159         .align 3
2160 ld0:    .space 8
2161 ld1:    .space 8
2162 x1:     .space 8
2163 x2:     .space 8
2164 x3:     .space 8
2165         .text
2166         addi 3,2,ld0@got@tlsgd
2167         bl .__tls_get_addr
2168         nop
2169         addi 3,2,ld1@toc
2170         bl .__tls_get_addr
2171         nop
2172         addi 3,2,x1@got@tlsld
2173         bl .__tls_get_addr
2174         nop
2175         addi 9,3,x1@dtprel
2176         bl .__tls_get_addr
2177         nop
2178         addis 9,3,x2@dtprel@ha
2179         addi 9,9,x2@dtprel@l
2180         bl .__tls_get_addr
2181         nop
2182         ld 9,x3@got@dtprel(2)
2183         add 9,9,3
2184         bl .__tls_get_addr
2185         nop'
2186         tls_first_major=2
2187         tls_first_minor=14
2188         tls_as_opt="-a64 --fatal-warnings"
2189         ;;
2190   s390-*-*)
2191     conftest_s='
2192         .section ".tdata","awT",@progbits
2193 foo:    .long   25
2194         .text
2195         .long   foo@TLSGD
2196         .long   foo@TLSLDM
2197         .long   foo@DTPOFF
2198         .long   foo@NTPOFF
2199         .long   foo@GOTNTPOFF
2200         .long   foo@INDNTPOFF
2201         l       %r1,foo@GOTNTPOFF(%r12)
2202         l       %r1,0(%r1):tls_load:foo
2203         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2204         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2205         tls_first_major=2
2206         tls_first_minor=14
2207         tls_as_opt="-m31 --fatal-warnings"
2208         ;;
2209   s390x-*-*)
2210     conftest_s='
2211         .section ".tdata","awT",@progbits
2212 foo:    .long   25
2213         .text
2214         .quad   foo@TLSGD
2215         .quad   foo@TLSLDM
2216         .quad   foo@DTPOFF
2217         .quad   foo@NTPOFF
2218         .quad   foo@GOTNTPOFF
2219         lg      %r1,foo@GOTNTPOFF(%r12)
2220         larl    %r1,foo@INDNTPOFF
2221         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2222         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2223         tls_first_major=2
2224         tls_first_minor=14
2225         tls_as_opt="-m64 -Aesame --fatal-warnings"
2226         ;;
2227   sh-*-* | sh[34]-*-*)
2228     conftest_s='
2229         .section ".tdata","awT",@progbits
2230 foo:    .long   25
2231         .text
2232         .long   foo@TLSGD
2233         .long   foo@TLSLDM
2234         .long   foo@DTPOFF
2235         .long   foo@GOTTPOFF
2236         .long   foo@TPOFF'
2237         tls_first_major=2
2238         tls_first_minor=13
2239         tls_as_opt=--fatal-warnings
2240         ;;
2241   sparc*-*-*)
2242     case "$target" in
2243       sparc*-sun-solaris2.*)
2244         on_solaris=yes
2245         ;;
2246       *)
2247         on_solaris=no
2248         ;;
2249     esac
2250     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2251       conftest_s='
2252         .section ".tdata",#alloc,#write,#tls
2253 foo:    .long   25
2254         .text
2255         sethi   %tgd_hi22(foo), %o0
2256         add     %o0, %tgd_lo10(foo), %o1
2257         add     %l7, %o1, %o0, %tgd_add(foo)
2258         call    __tls_get_addr, %tgd_call(foo)
2259         sethi   %tldm_hi22(foo), %l1
2260         add     %l1, %tldm_lo10(foo), %l2
2261         add     %l7, %l2, %o0, %tldm_add(foo)
2262         call    __tls_get_addr, %tldm_call(foo)
2263         sethi   %tldo_hix22(foo), %l3
2264         xor     %l3, %tldo_lox10(foo), %l4
2265         add     %o0, %l4, %l5, %tldo_add(foo)
2266         sethi   %tie_hi22(foo), %o3
2267         add     %o3, %tie_lo10(foo), %o3
2268         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2269         add     %g7, %o2, %o4, %tie_add(foo)
2270         sethi   %tle_hix22(foo), %l1
2271         xor     %l1, %tle_lox10(foo), %o5
2272         ld      [%g7 + %o5], %o1'
2273         tls_first_major=0
2274         tls_first_minor=0
2275     else
2276       conftest_s='
2277         .section ".tdata","awT",@progbits
2278 foo:    .long   25
2279         .text
2280         sethi   %tgd_hi22(foo), %o0
2281         add     %o0, %tgd_lo10(foo), %o1
2282         add     %l7, %o1, %o0, %tgd_add(foo)
2283         call    __tls_get_addr, %tgd_call(foo)
2284         sethi   %tldm_hi22(foo), %l1
2285         add     %l1, %tldm_lo10(foo), %l2
2286         add     %l7, %l2, %o0, %tldm_add(foo)
2287         call    __tls_get_addr, %tldm_call(foo)
2288         sethi   %tldo_hix22(foo), %l3
2289         xor     %l3, %tldo_lox10(foo), %l4
2290         add     %o0, %l4, %l5, %tldo_add(foo)
2291         sethi   %tie_hi22(foo), %o3
2292         add     %o3, %tie_lo10(foo), %o3
2293         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2294         add     %g7, %o2, %o4, %tie_add(foo)
2295         sethi   %tle_hix22(foo), %l1
2296         xor     %l1, %tle_lox10(foo), %o5
2297         ld      [%g7 + %o5], %o1'
2298         tls_first_major=2
2299         tls_first_minor=14
2300         tls_as_opt="-32 --fatal-warnings"
2301       fi
2302         ;;
2303 changequote([,])dnl
2304 esac
2305 if test -z "$tls_first_major"; then
2306   : # If we don't have a check, assume no support.
2307 else
2308   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2309   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2310   [AC_DEFINE(HAVE_AS_TLS, 1,
2311             [Define if your assembler supports thread-local storage.])])
2312 fi
2313
2314 # Target-specific assembler checks.
2315
2316 case "$target" in
2317   # All TARGET_ABI_OSF targets.
2318   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2319     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2320         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2321 [       .set nomacro
2322         .text
2323         extbl   $3, $2, $3      !lituse_bytoff!1
2324         ldq     $2, a($29)      !literal!1
2325         ldq     $4, b($29)      !literal!2
2326         ldq_u   $3, 0($2)       !lituse_base!1
2327         ldq     $27, f($29)     !literal!5
2328         jsr     $26, ($27), f   !lituse_jsr!5
2329         ldah    $29, 0($26)     !gpdisp!3
2330         lda     $0, c($29)      !gprel
2331         ldah    $1, d($29)      !gprelhigh
2332         lda     $1, d($1)       !gprellow
2333         lda     $29, 0($29)     !gpdisp!3],,
2334     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2335   [Define if your assembler supports explicit relocations.])])
2336     ;;
2337
2338   sparc*-*-*)
2339     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2340       [.register %g2, #scratch],,
2341       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2342                 [Define if your assembler supports .register.])])
2343
2344     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2345       [-relax], [.text],,
2346       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2347                 [Define if your assembler supports -relax option.])])
2348
2349     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2350       gcc_cv_as_sparc_ua_pcrel,,
2351       [-K PIC],
2352 [.text
2353 foo:
2354         nop
2355 .data
2356 .align 4
2357 .byte 0
2358 .uaword %r_disp32(foo)],
2359       [if test x$gcc_cv_ld != x \
2360        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2361          gcc_cv_as_sparc_ua_pcrel=yes
2362        fi
2363        rm -f conftest],
2364       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2365                 [Define if your assembler and linker support unaligned PC relative relocs.])
2366
2367       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2368         gcc_cv_as_sparc_ua_pcrel_hidden,,
2369         [-K PIC],
2370 [.data
2371 .align 4
2372 .byte 0x31
2373 .uaword %r_disp32(foo)
2374 .byte 0x32, 0x33, 0x34
2375 .global foo
2376 .hidden foo
2377 foo:
2378 .skip 4],
2379         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2380          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2381          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2382             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2383             if $gcc_cv_objdump -R conftest 2> /dev/null \
2384                | grep 'DISP32' > /dev/null 2>&1; then
2385                 :
2386             else
2387                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2388             fi
2389          fi
2390          rm -f conftest],
2391          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2392                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2393     ]) # unaligned pcrel relocs
2394
2395     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2396       gcc_cv_as_sparc_offsetable_lo10,,
2397       [-xarch=v9],
2398 [.text
2399         or %g1, %lo(ab) + 12, %g1
2400         or %g1, %lo(ab + 12), %g1],
2401       [if test x$gcc_cv_objdump != x \
2402        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2403           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2404          gcc_cv_as_offsetable_lo10=yes
2405        fi],
2406        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2407                  [Define if your assembler supports offsetable %lo().])])
2408     ;;
2409
2410 changequote(,)dnl
2411   i[34567]86-*-* | x86_64-*-*)
2412 changequote([,])dnl
2413     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2414        gcc_cv_as_ix86_filds_fists,
2415       [2,9,0],, [filds mem; fists mem],,
2416       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2417         [Define if your assembler uses the new HImode fild and fist notation.])])
2418
2419     gcc_GAS_CHECK_FEATURE([cmov syntax],
2420       gcc_cv_as_ix86_cmov_sun_syntax,,,
2421       [cmovl.l %edx, %eax],,
2422       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2423         [Define if your assembler supports the Sun syntax for cmov.])])
2424
2425     # This one is used unconditionally by i386.[ch]; it is to be defined
2426     # to 1 if the feature is present, 0 otherwise.
2427     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2428         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2429 [       .text
2430 .L0:
2431         nop
2432         .data
2433         .long .L0@GOTOFF])
2434     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2435       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2436       [Define true if the assembler supports '.long foo@GOTOFF'.])
2437     ;;
2438
2439   ia64*-*-*)
2440     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2441         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2442 [       .text
2443         addl r15 = @ltoffx(x#), gp
2444         ;;
2445         ld8.mov r16 = [[r15]], x#],,
2446     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2447           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2448
2449     ;;
2450
2451   powerpc*-*-*)
2452     case $target in
2453       *-*-aix*) conftest_s='    .csect .text[[PR]]
2454         mfcr 3,128';;
2455       *-*-darwin*) conftest_s=' .text
2456         mfcr r3,128';;
2457       *)       conftest_s='     .text
2458         mfcr 3,128';;
2459     esac
2460
2461     gcc_GAS_CHECK_FEATURE([mfcr field support],
2462       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2463       [$conftest_s],,
2464       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2465           [Define if your assembler supports mfcr field.])])
2466     ;;
2467
2468   mips*-*-*)
2469     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2470       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2471 [       lw $4,%gp_rel(foo)($4)],,
2472       [if test x$target_cpu_default = x
2473        then target_cpu_default=MASK_EXPLICIT_RELOCS
2474        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2475        fi])
2476
2477     ;;
2478 esac
2479 # ??? Not all targets support dwarf2 debug_line, even within a version
2480 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2481 # info to the output file.  So, as supported targets are added to gas 2.11,
2482 # add some instruction here to (also) show we expect this might work.
2483 # ??? Once 2.11 is released, probably need to add first known working
2484 # version to the per-target configury.
2485 case "$target" in
2486   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2487   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2488   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2489     insn="nop"
2490     ;;
2491   ia64*-*-* | s390*-*-*)
2492     insn="nop 0"
2493     ;;
2494   mmix-*-*)
2495     insn="swym 0"
2496     ;;
2497 esac
2498 if test x"$insn" != x; then
2499  conftest_s="\
2500         .file 1 \"conftest.s\"
2501         .loc 1 3 0
2502         $insn"
2503  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2504   gcc_cv_as_dwarf2_debug_line,
2505   [elf,2,11,0],, [$conftest_s],
2506   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2507    if grep debug_line conftest.o > /dev/null 2>&1; then
2508      gcc_cv_as_dwarf2_debug_line=yes
2509    fi])
2510
2511 # The .debug_line file table must be in the exact order that
2512 # we specified the files, since these indices are also used
2513 # by DW_AT_decl_file.  Approximate this test by testing if
2514 # the assembler bitches if the same index is assigned twice.
2515  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2516   gcc_cv_as_dwarf2_file_buggy,,,
2517 [       .file 1 "foo.s"
2518         .file 1 "bar.s"])
2519
2520  if test $gcc_cv_as_dwarf2_debug_line = yes \
2521  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2522         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2523   [Define if your assembler supports dwarf2 .file/.loc directives,
2524    and preserves file table indices exactly as given.])
2525  fi
2526
2527  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2528   gcc_cv_as_gdwarf2_flag,
2529   [elf,2,11,0], [--gdwarf2], [$insn],,
2530   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2531 [Define if your assembler supports the --gdwarf2 option.])])
2532
2533  gcc_GAS_CHECK_FEATURE([--gstabs option],
2534   gcc_cv_as_gstabs_flag,
2535   [elf,2,11,0], [--gstabs], [$insn],
2536   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2537    # and warns about it, but still exits successfully.  So check for
2538    # this.
2539    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2540    then :
2541    else gcc_cv_as_gstabs_flag=yes
2542    fi],
2543   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2544 [Define if your assembler supports the --gstabs option.])])
2545 fi
2546
2547 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2548 gcc_cv_ld_ro_rw_mix=unknown
2549 if test $in_tree_ld = yes ; then
2550   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2551      && test $in_tree_ld_is_elf = yes; then
2552     gcc_cv_ld_ro_rw_mix=read-write
2553   fi
2554 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2555   echo '.section myfoosect, "a"' > conftest1.s
2556   echo '.section myfoosect, "aw"' > conftest2.s
2557   echo '.byte 1' >> conftest2.s
2558   echo '.section myfoosect, "a"' > conftest3.s
2559   echo '.byte 0' >> conftest3.s
2560   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2561      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2562      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2563      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2564         conftest2.o conftest3.o > /dev/null 2>&1; then
2565     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2566                          | sed -e '/myfoosect/!d' -e N`
2567     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2568       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2569         gcc_cv_ld_ro_rw_mix=read-only
2570       else
2571         gcc_cv_ld_ro_rw_mix=read-write
2572       fi
2573     fi
2574   fi
2575 changequote(,)dnl
2576   rm -f conftest.* conftest[123].*
2577 changequote([,])dnl
2578 fi
2579 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2580         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2581   [Define if your linker links a mix of read-only
2582    and read-write sections into a read-write section.])
2583 fi
2584 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2585
2586 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2587 gcc_cv_ld_eh_frame_hdr=no
2588 if test $in_tree_ld = yes ; then
2589   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2590      && test $in_tree_ld_is_elf = yes; then
2591     gcc_cv_ld_eh_frame_hdr=yes
2592   fi
2593 elif test x$gcc_cv_ld != x; then
2594         # Check if linker supports --eh-frame-hdr option
2595         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2596                 gcc_cv_ld_eh_frame_hdr=yes
2597         fi
2598 fi
2599 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2600         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2601 [Define if your linker supports --eh-frame-hdr option.])
2602 fi
2603 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2604
2605 AC_MSG_CHECKING(linker position independent executable support)
2606 gcc_cv_ld_pie=no
2607 if test $in_tree_ld = yes ; then
2608   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2609      && test $in_tree_ld_is_elf = yes; then
2610     gcc_cv_ld_pie=yes
2611   fi
2612 elif test x$gcc_cv_ld != x; then
2613         # Check if linker supports -pie option
2614         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2615                 gcc_cv_ld_pie=yes
2616         fi
2617 fi
2618 if test x"$gcc_cv_ld_pie" = xyes; then
2619         AC_DEFINE(HAVE_LD_PIE, 1,
2620 [Define if your linker supports -pie option.])
2621 fi
2622 AC_MSG_RESULT($gcc_cv_ld_pie)
2623
2624 if test x$with_sysroot = x && test x$host = x$target \
2625    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2626   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2627 [Define to PREFIX/include if cpp should also search that directory.])
2628 fi
2629
2630 # Figure out what language subdirectories are present.
2631 # Look if the user specified --enable-languages="..."; if not, use
2632 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2633 # go away some day.
2634 # NB:  embedded tabs in this IF block -- do not untabify
2635 if test x"${enable_languages+set}" != xset; then
2636         if test x"${LANGUAGES+set}" = xset; then
2637                 enable_languages="${LANGUAGES}"
2638                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2639
2640         else
2641                 enable_languages=all
2642         fi
2643 else
2644         if test x"${enable_languages}" = x \
2645         || test x"${enable_languages}" = xyes;
2646         then
2647                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2648         fi
2649 fi
2650 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2651
2652 # First scan to see if an enabled language requires some other language.
2653 # We assume that a given config-lang.in will list all the language
2654 # front ends it requires, even if some are required indirectly.
2655 for lang in ${srcdir}/*/config-lang.in
2656 do
2657    case $lang in
2658     # The odd quoting in the next line works around
2659     # an apparent bug in bash 1.12 on linux.
2660 changequote(,)dnl
2661     ${srcdir}/[*]/config-lang.in)
2662        ;;
2663     *)
2664        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2665        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2666        for other in $this_lang_requires
2667        do
2668           case ,${enable_languages}, in
2669            *,$other,*)
2670               ;;
2671            *,all,*)
2672               ;;
2673            *,$lang_alias,*)
2674               enable_languages="$enable_languages,$other"
2675               ;;
2676           esac
2677        done
2678        ;;
2679 changequote([,])dnl
2680    esac
2681 done
2682
2683 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2684 found_languages=
2685 subdirs=
2686 for lang in ${srcdir}/*/config-lang.in
2687 do
2688         case $lang in
2689         # The odd quoting in the next line works around
2690         # an apparent bug in bash 1.12 on linux.
2691 changequote(,)dnl
2692         ${srcdir}/[*]/config-lang.in) ;;
2693         *)
2694           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2695           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2696           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2697           if test "x$lang_alias" = x
2698           then
2699                 echo "$lang doesn't set \$language." 1>&2
2700                 exit 1
2701           fi
2702           case ${build_by_default},${enable_languages}, in
2703           *,$lang_alias,*) add_this_lang=yes ;;
2704           no,*) add_this_lang=no ;;
2705           *,all,*) add_this_lang=yes ;;
2706           *) add_this_lang=no ;;
2707           esac
2708           found_languages="${found_languages} ${lang_alias}"
2709           if test x"${add_this_lang}" = xyes; then
2710                 case $lang in
2711                     ${srcdir}/ada/config-lang.in)
2712                         if test x$have_gnat = xyes ; then
2713                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2714                         fi
2715                         ;;
2716                     *)
2717                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2718                         ;;
2719                 esac
2720           fi
2721           ;;
2722 changequote([,])dnl
2723         esac
2724 done
2725
2726 missing_languages=
2727 for expected_language in ${expected_languages} ..
2728 do
2729     if test "${expected_language}" != ..; then
2730         missing_language="${expected_language}"
2731         if test "${expected_language}" = "c" \
2732            || test "${expected_language}" = "all"; then
2733                 missing_language=
2734         fi
2735         for found_language in ${found_languages} ..
2736         do
2737             if test "${found_language}" != ..; then
2738                 if test "${expected_language}" = "${found_language}"; then
2739                     missing_language=
2740                 fi
2741             fi
2742         done
2743         if test "x${missing_language}" != x; then
2744            missing_languages="${missing_languages} ${missing_language}"
2745         fi
2746     fi
2747 done
2748
2749 if test "x$missing_languages" != x; then
2750   AC_MSG_ERROR([
2751 The following requested languages were not found:${missing_languages}
2752 The following languages were available: c${found_languages}])
2753 fi
2754
2755 # Make gthr-default.h if we have a thread file.
2756 gthread_flags=
2757 if test $thread_file != single; then
2758     rm -f gthr-default.h
2759     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2760     gthread_flags=-DHAVE_GTHR_DEFAULT
2761 fi
2762 AC_SUBST(gthread_flags)
2763
2764 # Find out what GC implementation we want, or may, use.
2765 AC_ARG_WITH(gc,
2766 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2767                           with the compiler],
2768 [case "$withval" in
2769   page | zone)
2770     GGC=ggc-$withval
2771     ;;
2772   *)
2773     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2774     ;;
2775 esac],
2776 [GGC=ggc-page])
2777 AC_SUBST(GGC)
2778 echo "Using $GGC for garbage collection."
2779
2780 # Use the system's zlib library.
2781 zlibdir=-L../zlib
2782 zlibinc="-I\$(srcdir)/../zlib"
2783 AC_ARG_WITH(system-zlib,
2784 [  --with-system-zlib      use installed libz],
2785 zlibdir=
2786 zlibinc=
2787 )
2788 AC_SUBST(zlibdir)
2789 AC_SUBST(zlibinc)
2790
2791 dnl Very limited version of automake's enable-maintainer-mode
2792
2793 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2794   dnl maintainer-mode is disabled by default
2795   AC_ARG_ENABLE(maintainer-mode,
2796 [  --enable-maintainer-mode
2797                           enable make rules and dependencies not useful
2798                           (and sometimes confusing) to the casual installer],
2799       maintainer_mode=$enableval,
2800       maintainer_mode=no)
2801
2802 AC_MSG_RESULT($maintainer_mode)
2803
2804 if test "$maintainer_mode" = "yes"; then
2805   MAINT=''
2806 else
2807   MAINT='#'
2808 fi
2809 AC_SUBST(MAINT)dnl
2810
2811 # Make empty files to contain the specs and options for each language.
2812 # Then add #include lines to for a compiler that has specs and/or options.
2813
2814 lang_opt_files=
2815 lang_specs_files=
2816 lang_tree_files=
2817 for subdir in . $subdirs
2818 do
2819         if test -f $srcdir/$subdir/lang.opt; then
2820             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2821         fi
2822         if test -f $srcdir/$subdir/lang-specs.h; then
2823             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2824         fi
2825         if test -f $srcdir/$subdir/$subdir-tree.def; then
2826             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2827         fi
2828 done
2829
2830 # These (without "all_") are set in each config-lang.in.
2831 # `language' must be a single word so is spelled singularly.
2832 all_languages=
2833 all_boot_languages=
2834 all_compilers=
2835 all_stagestuff=
2836 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2837 # List of language makefile fragments.
2838 all_lang_makefrags=
2839 # List of language subdirectory makefiles.  Deprecated.
2840 all_lang_makefiles=
2841 # Files for gengtype
2842 all_gtfiles="$target_gtfiles"
2843 # Files for gengtype with language
2844 all_gtfiles_files_langs=
2845 all_gtfiles_files_files=
2846
2847 # Add the language fragments.
2848 # Languages are added via two mechanisms.  Some information must be
2849 # recorded in makefile variables, these are defined in config-lang.in.
2850 # We accumulate them and plug them into the main Makefile.
2851 # The other mechanism is a set of hooks for each of the main targets
2852 # like `clean', `install', etc.
2853
2854 language_hooks="Make-hooks"
2855
2856 for s in $subdirs
2857 do
2858                 language=
2859                 boot_language=
2860                 compilers=
2861                 stagestuff=
2862                 outputs=
2863                 gtfiles=
2864                 . ${srcdir}/$s/config-lang.in
2865                 if test "x$language" = x
2866                 then
2867                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2868                         exit 1
2869                 fi
2870                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2871                 if test -f ${srcdir}/$s/Makefile.in
2872                 then all_lang_makefiles="$s/Makefile"
2873                 fi
2874                 all_languages="$all_languages $language"
2875                 if test "x$boot_language" = xyes
2876                 then
2877                         all_boot_languages="$all_boot_languages $language"
2878                 fi
2879                 all_compilers="$all_compilers $compilers"
2880                 all_stagestuff="$all_stagestuff $stagestuff"
2881                 all_outputs="$all_outputs $outputs"
2882                 all_gtfiles="$all_gtfiles $gtfiles"
2883                 for f in $gtfiles
2884                 do
2885                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2886                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2887                 done
2888 done
2889
2890 # Pick up gtfiles for c
2891 gtfiles=
2892 s="c"
2893 . ${srcdir}/c-config-lang.in
2894 all_gtfiles="$all_gtfiles $gtfiles"
2895 for f in $gtfiles
2896 do
2897         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2898         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2899 done
2900
2901 check_languages=
2902 for language in $all_languages
2903 do
2904                 check_languages="$check_languages check-$language"
2905 done
2906
2907 # We link each language in with a set of hooks, reached indirectly via
2908 # lang.${target}.
2909
2910 rm -f Make-hooks
2911 touch Make-hooks
2912 target_list="all.build all.cross start.encap rest.encap tags \
2913         install-normal install-common install-man \
2914         uninstall info man srcextra srcman srcinfo \
2915         mostlyclean clean distclean maintainer-clean \
2916         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2917 for t in $target_list
2918 do
2919         x=
2920         for lang in $all_languages
2921         do
2922                         x="$x $lang.$t"
2923         done
2924         echo "lang.$t: $x" >> Make-hooks
2925 done
2926
2927 # Create .gdbinit.
2928
2929 echo "dir ." > .gdbinit
2930 echo "dir ${srcdir}" >> .gdbinit
2931 if test x$gdb_needs_out_file_path = xyes
2932 then
2933         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2934 fi
2935 if test "x$subdirs" != x; then
2936         for s in $subdirs
2937         do
2938                 echo "dir ${srcdir}/$s" >> .gdbinit
2939         done
2940 fi
2941 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2942
2943 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2944 # absolute path for gcc_tooldir based on inserting the number of up-directory
2945 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2946 # $(libsubdir)/@(unlibsubdir) based path.
2947 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2948 # make and thus we'd get different behavior depending on where we built the
2949 # sources.
2950 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2951     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
2952 else
2953 changequote(<<, >>)dnl
2954 # An explanation of the sed strings:
2955 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2956 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2957 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2958 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2959 #
2960 # (*) Note this pattern overwrites the first character of the string
2961 # with a forward slash if one is not already present.  This is not a
2962 # problem because the exact names of the sub-directories concerned is
2963 # unimportant, just the number of them matters.
2964 #
2965 # The practical upshot of these patterns is like this:
2966 #
2967 #  prefix     exec_prefix        result
2968 #  ------     -----------        ------
2969 #   /foo        /foo/bar          ../
2970 #   /foo/       /foo/bar          ../
2971 #   /foo        /foo/bar/         ../
2972 #   /foo/       /foo/bar/         ../
2973 #   /foo        /foo/bar/ugg      ../../
2974 #
2975     dollar='$$'
2976     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
2977 changequote([, ])dnl
2978 fi
2979 AC_SUBST(gcc_tooldir)
2980 AC_SUBST(dollar)
2981
2982 # Find a directory in which to install a shared libgcc.
2983
2984 AC_ARG_ENABLE(version-specific-runtime-libs,
2985 [  --enable-version-specific-runtime-libs
2986                           specify that runtime libraries should be
2987                           installed in a compiler-specific directory])
2988
2989 AC_ARG_WITH(slibdir,
2990 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2991 slibdir="$with_slibdir",
2992 if test "${enable_version_specific_runtime_libs+set}" = set; then
2993   slibdir='$(libsubdir)'
2994 elif test "$host" != "$target"; then
2995   slibdir='$(build_tooldir)/lib'
2996 else
2997   slibdir='$(libdir)'
2998 fi)
2999 AC_SUBST(slibdir)
3000
3001 objdir=`${PWDCMD-pwd}`
3002 AC_SUBST(objdir)
3003
3004 # Substitute configuration variables
3005 AC_SUBST(subdirs)
3006 AC_SUBST(srcdir)
3007 AC_SUBST(all_boot_languages)
3008 AC_SUBST(all_compilers)
3009 AC_SUBST(all_gtfiles)
3010 AC_SUBST(all_gtfiles_files_langs)
3011 AC_SUBST(all_gtfiles_files_files)
3012 AC_SUBST(all_lang_makefrags)
3013 AC_SUBST(all_lang_makefiles)
3014 AC_SUBST(all_languages)
3015 AC_SUBST(all_stagestuff)
3016 AC_SUBST(build_exeext)
3017 AC_SUBST(build_install_headers_dir)
3018 AC_SUBST(build_xm_file_list)
3019 AC_SUBST(build_xm_include_list)
3020 AC_SUBST(build_xm_defines)
3021 AC_SUBST(check_languages)
3022 AC_SUBST(cc_set_by_configure)
3023 AC_SUBST(quoted_cc_set_by_configure)
3024 AC_SUBST(cpp_install_dir)
3025 AC_SUBST(xmake_file)
3026 AC_SUBST(tmake_file)
3027 AC_SUBST(extra_headers_list)
3028 AC_SUBST(extra_objs)
3029 AC_SUBST(extra_parts)
3030 AC_SUBST(extra_passes)
3031 AC_SUBST(extra_programs)
3032 AC_SUBST(float_h_file)
3033 AC_SUBST(gcc_config_arguments)
3034 AC_SUBST(gcc_gxx_include_dir)
3035 AC_SUBST(libstdcxx_incdir)
3036 AC_SUBST(gcc_version)
3037 AC_SUBST(gcc_version_full)
3038 AC_SUBST(gcc_version_trigger)
3039 AC_SUBST(host_exeext)
3040 AC_SUBST(host_extra_gcc_objs)
3041 AC_SUBST(host_xm_file_list)
3042 AC_SUBST(host_xm_include_list)
3043 AC_SUBST(host_xm_defines)
3044 AC_SUBST(out_host_hook_obj)
3045 AC_SUBST(install)
3046 AC_SUBST(lang_opt_files)
3047 AC_SUBST(lang_specs_files)
3048 AC_SUBST(lang_tree_files)
3049 AC_SUBST(local_prefix)
3050 AC_SUBST(md_file)
3051 AC_SUBST(objc_boehm_gc)
3052 AC_SUBST(out_file)
3053 AC_SUBST(out_object_file)
3054 AC_SUBST(stage_prefix_set_by_configure)
3055 AC_SUBST(quoted_stage_prefix_set_by_configure)
3056 AC_SUBST(symbolic_link)
3057 AC_SUBST(thread_file)
3058 AC_SUBST(tm_file_list)
3059 AC_SUBST(tm_include_list)
3060 AC_SUBST(tm_defines)
3061 AC_SUBST(tm_p_file_list)
3062 AC_SUBST(tm_p_include_list)
3063 AC_SUBST(xm_file_list)
3064 AC_SUBST(xm_include_list)
3065 AC_SUBST(xm_defines)
3066 AC_SUBST(target_noncanonical)
3067 AC_SUBST(c_target_objs)
3068 AC_SUBST(cxx_target_objs)
3069 AC_SUBST(target_cpu_default)
3070
3071 AC_SUBST_FILE(language_hooks)
3072
3073 # If it doesn't already exist, create document directory
3074 echo "checking for the document directory." 1>&2
3075 if test -d doc ; then
3076   true
3077 else
3078   mkdir doc
3079 fi
3080
3081 # Echo link setup.
3082 if test x${build} = x${host} ; then
3083   if test x${host} = x${target} ; then
3084     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3085   else
3086     echo "Links are now set up to build a cross-compiler" 1>&2
3087     echo " from ${host} to ${target}." 1>&2
3088   fi
3089 else
3090   if test x${host} = x${target} ; then
3091     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3092     echo " for ${target}." 1>&2
3093   else
3094     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3095     echo " from ${host} to ${target}." 1>&2
3096   fi
3097 fi
3098
3099 # Configure the subdirectories
3100 # AC_CONFIG_SUBDIRS($subdirs)
3101
3102 # Create the Makefile
3103 # and configure language subdirectories
3104 AC_CONFIG_FILES($all_outputs)
3105
3106 AC_CONFIG_COMMANDS([default],
3107 [
3108 case ${CONFIG_HEADERS} in
3109   *auto-host.h:config.in*)
3110   echo > cstamp-h ;;
3111 esac
3112 # Make sure all the subdirs exist.
3113 for d in $subdirs
3114 do
3115     test -d $d || mkdir $d
3116 done
3117 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3118 # bootstrapping and the installation procedure can still use
3119 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3120 # FLAGS_TO_PASS has been modified to solve the problem there.
3121 # This is virtually a duplicate of what happens in configure.lang; we do
3122 # an extra check to make sure this only happens if ln -s can be used.
3123 if test "$symbolic_link" = "ln -s"; then
3124  for d in ${subdirs} fixinc ; do
3125         STARTDIR=`${PWDCMD-pwd}`
3126         cd $d
3127         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3128         do
3129                 rm -f $t
3130                 $symbolic_link ../$t $t 2>/dev/null
3131         done
3132         cd $STARTDIR
3133  done
3134 else true ; fi
3135 ],
3136 [subdirs='$subdirs'
3137 symbolic_link='$symbolic_link'
3138 ])
3139 AC_OUTPUT