gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [AS_HELP_STRING([--with-local-prefix=DIR],
 109                 [specifies directory to put local include])],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 128                 [specifies directory to put g++ header files])],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 145   fi
 146 fi
 147
 148 AC_ARG_WITH(cpp_install_dir,
 149 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 150                 [install the user visible C preprocessor in DIR
 151                  (relative to PREFIX) as well as PREFIX/bin])],
 152 [if test x$withval = xyes; then
 153   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 154 elif test x$withval != xno; then
 155   cpp_install_dir=$withval
 156 fi])
 157
 158 # We would like to our source tree to be readonly.  However when releases or
 159 # pre-releases are generated, the flex/bison generated files as well as the
 160 # various formats of manuals need to be included along with the rest of the
 161 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 162 # just that.
 163
 164 AC_MSG_CHECKING([whether to place generated files in the source directory])
 165   dnl generated-files-in-srcdir is disabled by default
 166   AC_ARG_ENABLE(generated-files-in-srcdir,
 167     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 168                     [put copies of generated files in source dir
 169                      intended for creating source tarballs for users
 170                      without texinfo bison or flex])],
 171       generated_files_in_srcdir=$enableval,
 172       generated_files_in_srcdir=no)
 173
 174 AC_MSG_RESULT($generated_files_in_srcdir)
 175
 176 if test "$generated_files_in_srcdir" = "yes"; then
 177   GENINSRC=''
 178 else
 179   GENINSRC='#'
 180 fi
 181 AC_SUBST(GENINSRC)
 182
 183 # -------------------
 184 # Find default linker
 185 # -------------------
 186
 187 # With GNU ld
 188 AC_ARG_WITH(gnu-ld,
 189 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 190 gnu_ld_flag="$with_gnu_ld",
 191 gnu_ld_flag=no)
 192
 193 # With pre-defined ld
 194 AC_ARG_WITH(ld,
 195 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 196 DEFAULT_LINKER="$with_ld")
 197 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 198   if test ! -x "$DEFAULT_LINKER"; then
 199     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 200   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 201     gnu_ld_flag=yes
 202   fi
 203   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 204         [Define to enable the use of a default linker.])
 205 fi
 206
 207 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 208 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 209
 210 AC_MSG_CHECKING([whether a default linker was specified])
 211 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 212   if test x"$gnu_ld_flag" = x"no"; then
 213     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 214   else
 215     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 216   fi
 217 else
 218   AC_MSG_RESULT(no)
 219 fi
 220
 221 # With demangler in GNU ld
 222 AC_ARG_WITH(demangler-in-ld,
 223 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 224 demangler_in_ld="$with_demangler_in_ld",
 225 demangler_in_ld=no)
 226
 227 # ----------------------
 228 # Find default assembler
 229 # ----------------------
 230
 231 # With GNU as
 232 AC_ARG_WITH(gnu-as,
 233 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 234 gas_flag="$with_gnu_as",
 235 gas_flag=no)
 236
 237 AC_ARG_WITH(as,
 238 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 239 DEFAULT_ASSEMBLER="$with_as")
 240 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 241   if test ! -x "$DEFAULT_ASSEMBLER"; then
 242     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 243   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 244     gas_flag=yes
 245   fi
 246   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 247         [Define to enable the use of a default assembler.])
 248 fi
 249
 250 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 251 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 252
 253 AC_MSG_CHECKING([whether a default assembler was specified])
 254 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 255   if test x"$gas_flag" = x"no"; then
 256     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 257   else
 258     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 259   fi
 260 else
 261   AC_MSG_RESULT(no)
 262 fi
 263
 264 # ---------------
 265 # Find C compiler
 266 # ---------------
 267
 268 # If a non-executable a.out is present (e.g. created by GNU as above even if
 269 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 270 # file, even when creating an executable, so an execution test fails.
 271 # Remove possible default executable files to avoid this.
 272 #
 273 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 274 # Autoconf includes it.
 275 rm -f a.out a.exe b.out
 276
 277 # Find the native compiler
 278 AC_PROG_CC
 279 AM_PROG_CC_C_O
 280 AC_PROG_CXX
 281 ACX_PROG_GNAT([-I"$srcdir"/ada])
 282
 283 # autoconf is lame and doesn't give us any substitution variable for this.
 284 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 285   NO_MINUS_C_MINUS_O=yes
 286 else
 287   OUTPUT_OPTION='-o $@'
 288 fi
 289 AC_SUBST(NO_MINUS_C_MINUS_O)
 290 AC_SUBST(OUTPUT_OPTION)
 291
 292 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 293 # optimizations to be activated explicitly by the toplevel.
 294 case "$CC" in
 295   */prev-gcc/xgcc*) ;;
 296   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 297 esac
 298 AC_SUBST(CFLAGS)
 299
 300 # -------------------------
 301 # Check C compiler features
 302 # -------------------------
 303
 304 AC_USE_SYSTEM_EXTENSIONS
 305 AC_PROG_CPP
 306 AC_C_INLINE
 307
 308 AC_SYS_LARGEFILE
 309
 310 # sizeof(char) is 1 by definition.
 311 AC_CHECK_SIZEOF(void *)
 312 AC_CHECK_SIZEOF(short)
 313 AC_CHECK_SIZEOF(int)
 314 AC_CHECK_SIZEOF(long)
 315 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 316 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 317 GCC_STDINT_TYPES
 318
 319 # ---------------------
 320 # Warnings and checking
 321 # ---------------------
 322
 323 # Check $CC warning features (if it's GCC).
 324 # We want to use -pedantic, but we don't want warnings about
 325 # * 'long long'
 326 # * variadic macros
 327 # * overlong strings
 328 # So, we only use -pedantic if we can disable those warnings.
 329
 330 ACX_PROG_CC_WARNING_OPTS(
 331         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
 332 ACX_PROG_CC_WARNING_OPTS(
 333         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 334         [c_loose_warn])
 335 ACX_PROG_CC_WARNING_OPTS(
 336         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 337 ACX_PROG_CC_WARNING_OPTS(
 338         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 339 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 340         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 341                        [-Wno-overlength-strings])), [strict_warn])
 342 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 343
 344 # The above macros do nothing if the compiler is not GCC.  However, the
 345 # Makefile has more goo to add other flags, so these variables are used
 346 # to enable warnings only for GCC.
 347 warn_cflags=
 348 warn_cxxflags=
 349 if test "x$GCC" = "xyes"; then
 350   warn_cflags='$(GCC_WARN_CFLAGS)'
 351   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 352 fi
 353 AC_SUBST(warn_cflags)
 354 AC_SUBST(warn_cxxflags)
 355
 356 # Enable expensive internal checks
 357 is_release=
 358 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 359   is_release=yes
 360 fi
 361
 362 AC_ARG_ENABLE(checking,
 363 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 364                 [enable expensive run-time checks.  With LIST,
 365                  enable only specific categories of checks.
 366                  Categories are: yes,no,all,none,release.
 367                  Flags are: assert,df,fold,gc,gcac,gimple,misc,
 368                  rtlflag,rtl,runtime,tree,valgrind,types])],
 369 [ac_checking_flags="${enableval}"],[
 370 # Determine the default checks.
 371 if test x$is_release = x ; then
 372   ac_checking_flags=yes
 373 else
 374   ac_checking_flags=release
 375 fi])
 376 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 377 for check in release $ac_checking_flags
 378 do
 379         case $check in
 380         # these set all the flags to specific states
 381         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 382                         ac_fold_checking= ; ac_gc_checking=1 ;
 383                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 384                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 385                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 386                         ac_types_checking=1 ;;
 387         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 388                         ac_fold_checking= ; ac_gc_checking= ;
 389                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 390                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 391                         ac_tree_checking= ; ac_valgrind_checking= ;
 392                         ac_types_checking= ;;
 393         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 394                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 395                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 396                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 397                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 398                         ac_types_checking=1 ;;
 399         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 400                         ac_fold_checking= ; ac_gc_checking= ;
 401                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 402                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 403                         ac_tree_checking= ; ac_valgrind_checking= ;
 404                         ac_types_checking= ;;
 405         # these enable particular checks
 406         assert)         ac_assert_checking=1 ;;
 407         df)             ac_df_checking=1 ;;
 408         fold)           ac_fold_checking=1 ;;
 409         gc)             ac_gc_checking=1 ;;
 410         gcac)           ac_gc_always_collect=1 ;;
 411         gimple)         ac_gimple_checking=1 ;;
 412         misc)           ac_checking=1 ;;
 413         rtl)            ac_rtl_checking=1 ;;
 414         rtlflag)        ac_rtlflag_checking=1 ;;
 415         runtime)        ac_runtime_checking=1 ;;
 416         tree)           ac_tree_checking=1 ;;
 417         types)          ac_types_checking=1 ;;
 418         valgrind)       ac_valgrind_checking=1 ;;
 419         *)      AC_MSG_ERROR(unknown check category $check) ;;
 420         esac
 421 done
 422 IFS="$ac_save_IFS"
 423
 424 nocommon_flag=""
 425 if test x$ac_checking != x ; then
 426   AC_DEFINE(ENABLE_CHECKING, 1,
 427 [Define if you want more run-time sanity checks.  This one gets a grab
 428    bag of miscellaneous but relatively cheap checks.])
 429   nocommon_flag=-fno-common
 430 fi
 431 AC_SUBST(nocommon_flag)
 432 if test x$ac_df_checking != x ; then
 433   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 434 [Define if you want more run-time sanity checks for dataflow.])
 435 fi
 436 if test x$ac_assert_checking != x ; then
 437   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 438 [Define if you want assertions enabled.  This is a cheap check.])
 439 fi
 440 if test x$ac_gimple_checking != x ; then
 441   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 442 [Define if you want operations on GIMPLE (the basic data structure of
 443 the high-level optimizers) to be checked for dynamic type safety at
 444 runtime.  This is moderately expensive.])
 445 fi
 446 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 447 if test x$ac_runtime_checking != x ; then
 448   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 449 [Define if you want runtime assertions enabled.  This is a cheap check.])
 450 fi
 451 if test x$ac_tree_checking != x ; then
 452   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 453 [Define if you want all operations on trees (the basic data
 454    structure of the front ends) to be checked for dynamic type safety
 455    at runtime.  This is moderately expensive.  The tree browser debugging
 456    routines will also be enabled by this option.
 457    ])
 458   TREEBROWSER=tree-browser.o
 459 fi
 460 if test x$ac_types_checking != x ; then
 461   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 462 [Define if you want all gimple types to be verified after gimplifiation.
 463    This is cheap.
 464    ])
 465 fi
 466 AC_SUBST(TREEBROWSER)
 467 if test x$ac_rtl_checking != x ; then
 468   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 469 [Define if you want all operations on RTL (the basic data structure
 470    of the optimizer and back end) to be checked for dynamic type safety
 471    at runtime.  This is quite expensive.])
 472 fi
 473 if test x$ac_rtlflag_checking != x ; then
 474   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 475 [Define if you want RTL flag accesses to be checked against the RTL
 476    codes that are supported for each access macro.  This is relatively
 477    cheap.])
 478 fi
 479 if test x$ac_gc_checking != x ; then
 480   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 481 [Define if you want the garbage collector to do object poisoning and
 482    other memory allocation checks.  This is quite expensive.])
 483 fi
 484 if test x$ac_gc_always_collect != x ; then
 485   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 486 [Define if you want the garbage collector to operate in maximally
 487    paranoid mode, validating the entire heap and collecting garbage at
 488    every opportunity.  This is extremely expensive.])
 489 fi
 490 if test x$ac_fold_checking != x ; then
 491   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 492 [Define if you want fold checked that it never destructs its argument.
 493    This is quite expensive.])
 494 fi
 495 valgrind_path_defines=
 496 valgrind_command=
 497
 498 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 499 dnl # an if statement.  This was the source of very frustrating bugs
 500 dnl # in converting to autoconf 2.5x!
 501 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 502
 503 if test x$ac_valgrind_checking != x ; then
 504   # It is certainly possible that there's valgrind but no valgrind.h.
 505   # GCC relies on making annotations so we must have both.
 506   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 507   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 508     [[#include <valgrind/memcheck.h>
 509 #ifndef VALGRIND_DISCARD
 510 #error VALGRIND_DISCARD not defined
 511 #endif]])],
 512   [gcc_cv_header_valgrind_memcheck_h=yes],
 513   [gcc_cv_header_valgrind_memcheck_h=no])
 514   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 515   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 516   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 517     [[#include <memcheck.h>
 518 #ifndef VALGRIND_DISCARD
 519 #error VALGRIND_DISCARD not defined
 520 #endif]])],
 521   [gcc_cv_header_memcheck_h=yes],
 522   [gcc_cv_header_memcheck_h=no])
 523   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 524   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 525         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 526   if test "x$valgrind_path" = "x" \
 527     || (test $have_valgrind_h = no \
 528         && test $gcc_cv_header_memcheck_h = no \
 529         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 530         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 531   fi
 532   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 533   valgrind_command="$valgrind_path -q"
 534   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 535 [Define if you want to run subprograms and generated programs
 536    through valgrind (a memory checker).  This is extremely expensive.])
 537   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 538     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 539         [Define if valgrind's valgrind/memcheck.h header is installed.])
 540   fi
 541   if test $gcc_cv_header_memcheck_h = yes; then
 542     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 543         [Define if valgrind's memcheck.h header is installed.])
 544   fi
 545 fi
 546 AC_SUBST(valgrind_path_defines)
 547 AC_SUBST(valgrind_command)
 548
 549 # Enable code coverage collection
 550 AC_ARG_ENABLE(coverage,
 551 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 552                 [enable compiler's code coverage collection.
 553                  Use to measure compiler performance and locate
 554                  unused parts of the compiler. With LEVEL, specify
 555                  optimization. Values are opt, noopt,
 556                  default is noopt])],
 557 [case "${enableval}" in
 558   yes|noopt)
 559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 560     ;;
 561   opt)
 562     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 563     ;;
 564   no)
 565     # a.k.a. --disable-coverage
 566     coverage_flags=""
 567     ;;
 568   *)
 569     AC_MSG_ERROR(unknown coverage setting $enableval)
 570     ;;
 571 esac],
 572 [coverage_flags=""])
 573 AC_SUBST(coverage_flags)
 574
 575 AC_ARG_ENABLE(gather-detailed-mem-stats,
 576 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 577                 [enable detailed memory allocation stats gathering])], [],
 578 [enable_gather_detailed_mem_stats=no])
 579 if test x$enable_gather_detailed_mem_stats = xyes ; then
 580   AC_DEFINE(GATHER_STATISTICS, 1,
 581         [Define to enable detailed memory allocation stats gathering.])
 582 fi
 583
 584 # -------------------------------
 585 # Miscenalleous configure options
 586 # -------------------------------
 587
 588 # See if we are building gcc with C++.
 589 AC_ARG_ENABLE(build-with-cxx,
 590 [AS_HELP_STRING([--enable-build-with-cxx],
 591                 [build with C++ compiler instead of C compiler])],
 592 ENABLE_BUILD_WITH_CXX=$enableval,
 593 ENABLE_BUILD_WITH_CXX=no)
 594 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 595 if test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
 596   AC_DEFINE(ENABLE_BUILD_WITH_CXX, 1,
 597             [Define if building with C++.])
 598 fi
 599
 600 # With stabs
 601 AC_ARG_WITH(stabs,
 602 [AS_HELP_STRING([--with-stabs],
 603                 [arrange to use stabs instead of host debug format])],
 604 stabs="$with_stabs",
 605 stabs=no)
 606
 607 # Determine whether or not multilibs are enabled.
 608 AC_ARG_ENABLE(multilib,
 609 [AS_HELP_STRING([--enable-multilib],
 610                 [enable library support for multiple ABIs])],
 611 [], [enable_multilib=yes])
 612 AC_SUBST(enable_multilib)
 613
 614 # Enable __cxa_atexit for C++.
 615 AC_ARG_ENABLE(__cxa_atexit,
 616 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 617 [], [])
 618
 619 # Enable C extension for decimal float if target supports it.
 620 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 621
 622 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 623 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 624 [Define to 1 to enable decimal float extension to C.])
 625
 626 # Use default_decimal_float for dependency.
 627 enable_decimal_float=$default_decimal_float
 628
 629 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 630 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 631 [Define to 1 to specify that we are using the BID decimal floating
 632 point format instead of DPD])
 633
 634 # Enable C extension for fixed-point arithmetic.
 635 AC_ARG_ENABLE(fixed-point,
 636 [AS_HELP_STRING([--enable-fixed-point],
 637                 [enable fixed-point arithmetic extension to C])],
 638 [],
 639 [
 640   case $target in
 641     mips*-*-*)
 642       case $host in
 643         mips*-sgi-irix*)
 644           AC_MSG_WARN([fixed-point is not supported on IRIX, ignored])
 645           enable_fixed_point=no
 646           ;;
 647         *)
 648           enable_fixed_point=yes
 649           ;;
 650       esac
 651       ;;
 652     *)
 653       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 654       enable_fixed_point=no
 655       ;;
 656   esac
 657 ])
 658 AC_SUBST(enable_fixed_point)
 659
 660 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 661 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 662 [Define to 1 to enable fixed-point arithmetic extension to C.])
 663
 664 # Enable threads
 665 # Pass with no value to take the default
 666 # Pass with a value to specify a thread package
 667 AC_ARG_ENABLE(threads,
 668 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 669                 [enable thread usage for target GCC,
 670                  using LIB thread package])],,
 671 [enable_threads=''])
 672
 673 AC_ARG_ENABLE(tls,
 674 [AS_HELP_STRING([--enable-tls],
 675                 [enable or disable generation of tls code
 676                  overriding the assembler check for tls support])],
 677 [
 678   case $enable_tls in
 679     yes | no) ;;
 680     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 681 Valid choices are 'yes' and 'no'.]) ;;
 682   esac
 683 ], [enable_tls=''])
 684
 685 AC_ARG_ENABLE(objc-gc,
 686 [AS_HELP_STRING([--enable-objc-gc],
 687                 [enable the use of Boehm's garbage collector with
 688                  the GNU Objective-C runtime])],
 689 if test x$enable_objc_gc = xno; then
 690         objc_boehm_gc=''
 691 else
 692         objc_boehm_gc=1
 693 fi,
 694 objc_boehm_gc='')
 695
 696 AC_ARG_WITH(dwarf2,
 697 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 698 dwarf2="$with_dwarf2",
 699 dwarf2=no)
 700
 701 AC_ARG_ENABLE(shared,
 702 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 703 [
 704   case $enable_shared in
 705   yes | no) ;;
 706   *)
 707     enable_shared=no
 708     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 709     for pkg in $enableval; do
 710       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 711         enable_shared=yes
 712       fi
 713     done
 714     IFS="$ac_save_ifs"
 715     ;;
 716   esac
 717 ], [enable_shared=yes])
 718 AC_SUBST(enable_shared)
 719
 720 AC_ARG_WITH(build-sysroot,
 721   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 722                   [use sysroot as the system root during the build])])
 723
 724 AC_ARG_WITH(sysroot,
 725 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 726                 [search for usr/lib, usr/include, et al, within DIR])],
 727 [
 728  case ${with_sysroot} in
 729  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 730  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 731  esac
 732
 733  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 734  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 735
 736  if test "x$prefix" = xNONE; then
 737   test_prefix=/usr/local
 738  else
 739   test_prefix=$prefix
 740  fi
 741  if test "x$exec_prefix" = xNONE; then
 742   test_exec_prefix=$test_prefix
 743  else
 744   test_exec_prefix=$exec_prefix
 745  fi
 746  case ${TARGET_SYSTEM_ROOT} in
 747  "${test_prefix}"|"${test_prefix}/"*|\
 748  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 749  '${prefix}'|'${prefix}/'*|\
 750  '${exec_prefix}'|'${exec_prefix}/'*)
 751    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 752    TARGET_SYSTEM_ROOT_DEFINE="$t"
 753    ;;
 754  esac
 755 ], [
 756  TARGET_SYSTEM_ROOT=
 757  TARGET_SYSTEM_ROOT_DEFINE=
 758  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 759 ])
 760 AC_SUBST(TARGET_SYSTEM_ROOT)
 761 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 762 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 763
 764 AC_ARG_WITH(specs,
 765   [AS_HELP_STRING([--with-specs=SPECS],
 766                   [add SPECS to driver command-line processing])],
 767   [CONFIGURE_SPECS=$withval],
 768   [CONFIGURE_SPECS=]
 769 )
 770 AC_SUBST(CONFIGURE_SPECS)
 771
 772 ACX_PKGVERSION([GCC])
 773 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 774
 775 # Sanity check enable_languages in case someone does not run the toplevel
 776 # configure # script.
 777 AC_ARG_ENABLE(languages,
 778 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 779 [case ,${enable_languages}, in
 780        ,,|,yes,)
 781                 # go safe -- we cannot be much sure without the toplevel
 782                 # configure's
 783                 # analysis of which target libs are present and usable
 784                 enable_languages=c
 785                 ;;
 786          *,all,*)
 787                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 788                 ;;
 789         *,c,*)
 790                 ;;
 791         *)
 792                 enable_languages=c,${enable_languages}
 793                 ;;
 794 esac],
 795 [enable_languages=c])
 796
 797 AC_ARG_WITH(multilib-list,
 798 [AS_HELP_STRING([--with-multilib-list], [select multilibs (SH only)])],
 799 :,
 800 with_multilib_list=default)
 801
 802 # -------------------------
 803 # Checks for other programs
 804 # -------------------------
 805
 806 AC_PROG_MAKE_SET
 807
 808 # Find some useful tools
 809 AC_PROG_AWK
 810 # We need awk to create options.c and options.h.
 811 # Bail out if it's missing.
 812 case ${AWK} in
 813   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 814 esac
 815
 816 gcc_AC_PROG_LN_S
 817 ACX_PROG_LN($LN_S)
 818 AC_PROG_RANLIB
 819 case "${host}" in
 820 *-*-darwin*)
 821   # By default, the Darwin ranlib will not treat common symbols as
 822   # definitions when  building the archive table of contents.  Other
 823   # ranlibs do that; pass an option to the Darwin ranlib that makes
 824   # it behave similarly.
 825   ranlib_flags="-c"
 826   ;;
 827 *)
 828   ranlib_flags=""
 829 esac
 830 AC_SUBST(ranlib_flags)
 831
 832 gcc_AC_PROG_INSTALL
 833
 834 # See if cmp has --ignore-initial.
 835 gcc_AC_PROG_CMP_IGNORE_INITIAL
 836
 837 # See if we have the mktemp command.
 838 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 839
 840 # See if makeinfo has been installed and is modern enough
 841 # that we can use it.
 842 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 843   [GNU texinfo.* \([0-9][0-9.]*\)],
 844   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 845 if test $gcc_cv_prog_makeinfo_modern = no; then
 846   AC_MSG_WARN([
 847 *** Makeinfo is missing or too old.
 848 *** Info documentation will not be built.])
 849   BUILD_INFO=
 850 else
 851   BUILD_INFO=info
 852 fi
 853 AC_SUBST(BUILD_INFO)
 854
 855 # Is pod2man recent enough to regenerate manpages?
 856 AC_MSG_CHECKING([for recent Pod::Man])
 857 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 858   AC_MSG_RESULT(yes)
 859   GENERATED_MANPAGES=generated-manpages
 860 else
 861   AC_MSG_RESULT(no)
 862   GENERATED_MANPAGES=
 863 fi
 864 AC_SUBST(GENERATED_MANPAGES)
 865
 866 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 867
 868 # How about lex?
 869 dnl Don't use AC_PROG_LEX; we insist on flex.
 870 dnl LEXLIB is not useful in gcc.
 871 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 872
 873 # Bison?
 874 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 875
 876 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 877 # check for build == host before using them.
 878
 879 # NM
 880 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 881   && test -d ../binutils ; then
 882   NM='${objdir}/../binutils/nm-new'
 883 else
 884   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 885 fi
 886
 887 # AR
 888 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 889   && test -d ../binutils ; then
 890   AR='${objdir}/../binutils/ar'
 891 else
 892   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 893 fi
 894
 895
 896 # --------------------
 897 # Checks for C headers
 898 # --------------------
 899
 900 # Need to reject headers which give warnings, so that the -Werror bootstrap
 901 # works later. *sigh*  This needs to come before all header checks.
 902 AC_PROG_CPP_WERROR
 903
 904 AC_HEADER_STDC
 905 AC_HEADER_TIME
 906 ACX_HEADER_STRING
 907 AC_HEADER_SYS_WAIT
 908 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 909                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 910                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 911                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 912
 913 # Check for thread headers.
 914 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 915 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 916
 917 # These tests can't be done till we know if we have limits.h.
 918 gcc_AC_C_CHAR_BIT
 919 AC_C_BIGENDIAN
 920
 921 # ----------------------
 922 # Checks for C++ headers
 923 # ----------------------
 924
 925 dnl Autoconf will give an error in the configure script if there is no
 926 dnl C++ preprocessor.  Hack to prevent that.
 927 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
 928 AC_PROG_CXXCPP
 929 m4_popdef([AC_MSG_ERROR])[]dnl
 930
 931 AC_LANG_PUSH(C++)
 932
 933 AC_CHECK_HEADERS(unordered_map)
 934 AC_CHECK_HEADERS(tr1/unordered_map)
 935 AC_CHECK_HEADERS(ext/hash_map)
 936
 937 AC_LANG_POP(C++)
 938
 939 # --------
 940 # UNSORTED
 941 # --------
 942
 943
 944 # These libraries may be used by collect2.
 945 # We may need a special search path to get them linked.
 946 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 947 [save_LIBS="$LIBS"
 948 for libs in '' -lld -lmld \
 949                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 950                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 951 do
 952         LIBS="$libs"
 953         AC_TRY_LINK_FUNC(ldopen,
 954                 [gcc_cv_collect2_libs="$libs"; break])
 955 done
 956 LIBS="$save_LIBS"
 957 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 958 case $gcc_cv_collect2_libs in
 959         "none required")        ;;
 960         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 961 esac
 962 AC_SUBST(COLLECT2_LIBS)
 963
 964 # When building Ada code on Alpha, we need exc_resume which is usually in
 965 # -lexc.  So test for it.
 966 save_LIBS="$LIBS"
 967 LIBS=
 968 AC_SEARCH_LIBS(exc_resume, exc)
 969 GNAT_LIBEXC="$LIBS"
 970 LIBS="$save_LIBS"
 971 AC_SUBST(GNAT_LIBEXC)
 972
 973 # Some systems put ldexp and frexp in libm instead of libc; assume
 974 # they're both in the same place.  jcf-dump needs them.
 975 save_LIBS="$LIBS"
 976 LIBS=
 977 AC_SEARCH_LIBS(ldexp, m)
 978 LDEXP_LIB="$LIBS"
 979 LIBS="$save_LIBS"
 980 AC_SUBST(LDEXP_LIB)
 981
 982 # Use <inttypes.h> only if it exists,
 983 # doesn't clash with <sys/types.h>, and declares intmax_t.
 984 AC_MSG_CHECKING(for inttypes.h)
 985 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 986 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 987 [[#include <sys/types.h>
 988 #include <inttypes.h>]],
 989   [[intmax_t i = -1;]])],
 990   [gcc_cv_header_inttypes_h=yes],
 991   [gcc_cv_header_inttypes_h=no])])
 992 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 993 if test $gcc_cv_header_inttypes_h = yes; then
 994   AC_DEFINE(HAVE_INTTYPES_H, 1,
 995         [Define if you have a working <inttypes.h> header file.])
 996 fi
 997
 998 dnl Disabled until we have a complete test for buggy enum bitfields.
 999 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1000
1001 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1002   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1003   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1004   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1005   putchar_unlocked putc_unlocked)
1006 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1007         sysconf strsignal getrusage nl_langinfo \
1008         gettimeofday mbstowcs wcswidth mmap setlocale \
1009         gcc_UNLOCKED_FUNCS)
1010
1011 if test x$ac_cv_func_mbstowcs = xyes; then
1012   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1013 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1014 int main()
1015 {
1016   mbstowcs(0, "", 0);
1017   return 0;
1018 }]])],
1019     [gcc_cv_func_mbstowcs_works=yes],
1020     [gcc_cv_func_mbstowcs_works=no],
1021     [gcc_cv_func_mbstowcs_works=yes])])
1022   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1023     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1024   [Define this macro if mbstowcs does not crash when its
1025    first argument is NULL.])
1026   fi
1027 fi
1028
1029 AC_CHECK_TYPE(ssize_t, int)
1030 AC_CHECK_TYPE(caddr_t, char *)
1031
1032 gcc_AC_FUNC_MMAP_BLACKLIST
1033
1034 case "${host}" in
1035 *-*-*vms*)
1036   # Under VMS, vfork works very differently than on Unix. The standard test
1037   # won't work, and it isn't easily adaptable. It makes more sense to
1038   # just force it.
1039   ac_cv_func_vfork_works=yes
1040   ;;
1041 esac
1042 AC_FUNC_FORK
1043
1044 AM_ICONV
1045 # Until we have in-tree GNU iconv:
1046 LIBICONV_DEP=
1047 AC_SUBST(LIBICONV_DEP)
1048
1049 AM_LC_MESSAGES
1050
1051 AM_LANGINFO_CODESET
1052
1053 # We will need to find libiberty.h and ansidecl.h
1054 saved_CFLAGS="$CFLAGS"
1055 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1056 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1057         strsignal strstr strverscmp \
1058         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1059         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1060 #include "ansidecl.h"
1061 #include "system.h"])
1062
1063 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1064 #include "ansidecl.h"
1065 #include "system.h"
1066 #ifdef HAVE_SYS_RESOURCE_H
1067 #include <sys/resource.h>
1068 #endif
1069 ])
1070
1071 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1072 #include "ansidecl.h"
1073 #include "system.h"
1074 #ifdef HAVE_SYS_RESOURCE_H
1075 #include <sys/resource.h>
1076 #endif
1077 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1078 [Define to `long' if <sys/resource.h> doesn't define.])])
1079
1080 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1081 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1082 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1083 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1084 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_LDFCN_H
1088 #undef FREAD
1089 #undef FWRITE
1090 #include <ldfcn.h>
1091 #endif
1092 ])
1093
1094 gcc_AC_CHECK_DECLS(times, , ,[
1095 #include "ansidecl.h"
1096 #include "system.h"
1097 #ifdef HAVE_SYS_TIMES_H
1098 #include <sys/times.h>
1099 #endif
1100 ])
1101
1102 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1103 #include "ansidecl.h"
1104 #include "system.h"
1105 #include <signal.h>
1106 ])
1107
1108 # More time-related stuff.
1109 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1110 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1111 #include "ansidecl.h"
1112 #include "system.h"
1113 #ifdef HAVE_SYS_TIMES_H
1114 #include <sys/times.h>
1115 #endif
1116 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1117 if test $ac_cv_struct_tms = yes; then
1118   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1119   [Define if <sys/times.h> defines struct tms.])
1120 fi
1121
1122 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1123 # revisit after autoconf 2.50.
1124 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1125 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1126 #include "ansidecl.h"
1127 #include "system.h"
1128 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1129 if test $gcc_cv_type_clock_t = yes; then
1130   AC_DEFINE(HAVE_CLOCK_T, 1,
1131   [Define if <time.h> defines clock_t.])
1132 fi
1133
1134 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1135 CFLAGS="$saved_CFLAGS"
1136
1137 gcc_AC_INITFINI_ARRAY
1138
1139 # mkdir takes a single argument on some systems.
1140 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1141
1142 # File extensions
1143 manext='.1'
1144 objext='.o'
1145 AC_SUBST(manext)
1146 AC_SUBST(objext)
1147
1148 # With Setjmp/Longjmp based exception handling.
1149 AC_ARG_ENABLE(sjlj-exceptions,
1150 [AS_HELP_STRING([--enable-sjlj-exceptions],
1151                 [arrange to use setjmp/longjmp exception handling])],
1152 [case $target in
1153   *-*-hpux10*)
1154     if test $enableval != yes; then
1155       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1156       enableval=yes
1157     fi
1158     ;;
1159 esac
1160 force_sjlj_exceptions=yes],
1161 [case $target in
1162   *-*-hpux10*)
1163     force_sjlj_exceptions=yes
1164     enableval=yes
1165     ;;
1166   *)
1167     force_sjlj_exceptions=no
1168     ;;
1169 esac])
1170 if test $force_sjlj_exceptions = yes; then
1171   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1172   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1173     [Define 0/1 to force the choice for exception handling model.])
1174 fi
1175
1176 # For platforms with the unwind ABI which includes an unwind library,
1177 # libunwind, we can choose to use the system libunwind.
1178 # config.gcc also contains tests of with_system_libunwind.
1179 GCC_CHECK_UNWIND_GETIPINFO
1180
1181 # --------------------------------------------------------
1182 # Build, host, and target specific configuration fragments
1183 # --------------------------------------------------------
1184
1185 # Collect build-machine-specific information.
1186 . ${srcdir}/config.build
1187
1188 # Collect host-machine-specific information.
1189 . ${srcdir}/config.host
1190
1191 target_gtfiles=
1192
1193 # Collect target-machine-specific information.
1194 . ${srcdir}/config.gcc
1195
1196 extra_objs="${host_extra_objs} ${extra_objs}"
1197 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1198
1199 # Default the target-machine variables that were not explicitly set.
1200 if test x"$tm_file" = x
1201 then tm_file=$cpu_type/$cpu_type.h; fi
1202
1203 if test x"$extra_headers" = x
1204 then extra_headers=; fi
1205
1206 if test x$md_file = x
1207 then md_file=$cpu_type/$cpu_type.md; fi
1208
1209 if test x$out_file = x
1210 then out_file=$cpu_type/$cpu_type.c; fi
1211
1212 if test x"$tmake_file" = x
1213 then tmake_file=$cpu_type/t-$cpu_type
1214 fi
1215
1216 if test x"$dwarf2" = xyes
1217 then tm_file="$tm_file tm-dwarf2.h"
1218 fi
1219
1220 # Say what files are being used for the output code and MD file.
1221 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1222 echo "Using \`$srcdir/config/$md_file' as machine description file."
1223
1224 # If any of the xm_file variables contain nonexistent files, warn
1225 # about them and drop them.
1226
1227 bx=
1228 for x in $build_xm_file; do
1229   if    test -f $srcdir/config/$x
1230   then      bx="$bx $x"
1231   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1232   fi
1233 done
1234 build_xm_file="$bx"
1235
1236 hx=
1237 for x in $host_xm_file; do
1238   if    test -f $srcdir/config/$x
1239   then      hx="$hx $x"
1240   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1241   fi
1242 done
1243 host_xm_file="$hx"
1244
1245 tx=
1246 for x in $xm_file; do
1247   if    test -f $srcdir/config/$x
1248   then      tx="$tx $x"
1249   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1250   fi
1251 done
1252 xm_file="$tx"
1253
1254 count=a
1255 for f in $tm_file; do
1256         count=${count}x
1257 done
1258 if test $count = ax; then
1259         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1260 else
1261         echo "Using the following target machine macro files:"
1262         for f in $tm_file; do
1263                 echo "  $srcdir/config/$f"
1264         done
1265 fi
1266
1267 if test x$need_64bit_hwint = xyes; then
1268         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1269 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1270 fi
1271
1272 if test x$use_long_long_for_widest_fast_int = xyes; then
1273         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1274 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1275 efficiently supported by the host hardware.])
1276 fi
1277
1278 count=a
1279 for f in $host_xm_file; do
1280         count=${count}x
1281 done
1282 if test $count = a; then
1283         :
1284 elif test $count = ax; then
1285         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1286 else
1287         echo "Using the following host machine macro files:"
1288         for f in $host_xm_file; do
1289                 echo "  $srcdir/config/$f"
1290         done
1291 fi
1292 echo "Using ${out_host_hook_obj} for host machine hooks."
1293
1294 if test "$host_xm_file" != "$build_xm_file"; then
1295         count=a
1296         for f in $build_xm_file; do
1297                 count=${count}x
1298         done
1299         if test $count = a; then
1300                 :
1301         elif test $count = ax; then
1302                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1303         else
1304                 echo "Using the following build machine macro files:"
1305                 for f in $build_xm_file; do
1306                         echo "  $srcdir/config/$f"
1307                 done
1308         fi
1309 fi
1310
1311 case ${host} in
1312   powerpc*-*-darwin*)
1313     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1314       gcc_cv_mcontext_underscores,
1315       AC_COMPILE_IFELSE([
1316 #include <sys/cdefs.h>
1317 #include <sys/signal.h>
1318 #include <ucontext.h>
1319 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1320 ],
1321         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1322       if test $gcc_cv_mcontext_underscores = yes; then
1323         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1324           [mcontext_t fields start with __])
1325       fi
1326     ;;
1327 esac
1328
1329 # ---------
1330 # Threading
1331 # ---------
1332
1333 # Check if a valid thread package
1334 case ${enable_threads} in
1335   "" | no)
1336     # No threads
1337     target_thread_file='single'
1338     ;;
1339   yes)
1340     # default
1341     target_thread_file='single'
1342     ;;
1343   aix | dce | gnat | irix | posix | posix95 | rtems | \
1344   single | vxworks | win32 | mipssde)
1345     target_thread_file=${enable_threads}
1346     ;;
1347   *)
1348     echo "${enable_threads} is an unknown thread package" 1>&2
1349     exit 1
1350     ;;
1351 esac
1352
1353 if test x${thread_file} = x; then
1354   # No thread file set by target-specific clauses in config.gcc,
1355   # so use file chosen by default logic above
1356   thread_file=${target_thread_file}
1357 fi
1358
1359 # Make gthr-default.h if we have a thread file.
1360 gthread_flags=
1361 if test $thread_file != single; then
1362   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1363   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1364     rm -f gthr-default.h-t
1365   else
1366     mv -f gthr-default.h-t gthr-default.h
1367   fi
1368   gthread_flags=-DHAVE_GTHR_DEFAULT
1369 fi
1370 AC_SUBST(gthread_flags)
1371
1372 # --------
1373 # UNSORTED
1374 # --------
1375
1376 use_cxa_atexit=no
1377 if test x$enable___cxa_atexit = xyes || \
1378    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1379   if test x$host = x$target; then
1380     case $host in
1381       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1382       # keyed to flag_use_cxa_atexit
1383       *-*-mingw32*)
1384         use_cxa_atexit=yes
1385         ;;
1386       *)
1387         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1388           [echo "__cxa_atexit can't be enabled on this target"])
1389         ;;
1390     esac
1391   else
1392     # We can't check for __cxa_atexit when building a cross, so assume
1393     # it is available
1394     use_cxa_atexit=yes
1395   fi
1396   if test x$use_cxa_atexit = xyes; then
1397     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1398       [Define if you want to use __cxa_atexit, rather than atexit, to
1399       register C++ destructors for local statics and global objects.
1400       This is essential for fully standards-compliant handling of
1401       destructors, but requires __cxa_atexit in libc.])
1402   fi
1403 fi
1404
1405 # Look for a file containing extra machine modes.
1406 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1407   extra_modes_file='$(srcdir)'/config/${extra_modes}
1408   AC_SUBST(extra_modes_file)
1409   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1410   [Define to the name of a file containing a list of extra machine modes
1411    for this architecture.])
1412 fi
1413
1414 # Convert extra_options into a form suitable for Makefile use.
1415 extra_opt_files=
1416 all_opt_files=
1417 for f in $extra_options; do
1418   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1419   all_opt_files="$all_opt_files $srcdir/config/$f"
1420 done
1421 AC_SUBST(extra_opt_files)
1422
1423 # auto-host.h is the file containing items generated by autoconf and is
1424 # the first file included by config.h.
1425 # If host=build, it is correct to have bconfig include auto-host.h
1426 # as well.  If host!=build, we are in error and need to do more
1427 # work to find out the build config parameters.
1428 if test x$host = x$build
1429 then
1430         build_auto=auto-host.h
1431 else
1432         # We create a subdir, then run autoconf in the subdir.
1433         # To prevent recursion we set host and build for the new
1434         # invocation of configure to the build for this invocation
1435         # of configure.
1436         tempdir=build.$$
1437         rm -rf $tempdir
1438         mkdir $tempdir
1439         cd $tempdir
1440         case ${srcdir} in
1441         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1442         *) realsrcdir=../${srcdir};;
1443         esac
1444         saved_CFLAGS="${CFLAGS}"
1445         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1446         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1447         ${realsrcdir}/configure \
1448                 --enable-languages=${enable_languages-all} \
1449                 --target=$target_alias --host=$build_alias --build=$build_alias
1450         CFLAGS="${saved_CFLAGS}"
1451
1452         # We just finished tests for the build machine, so rename
1453         # the file auto-build.h in the gcc directory.
1454         mv auto-host.h ../auto-build.h
1455         cd ..
1456         rm -rf $tempdir
1457         build_auto=auto-build.h
1458 fi
1459 AC_SUBST(build_subdir)
1460
1461 tm_file="${tm_file} defaults.h"
1462 tm_p_file="${tm_p_file} tm-preds.h"
1463 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1464 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1465 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1466 # put this back in temporarily.
1467 xm_file="auto-host.h ansidecl.h ${xm_file}"
1468
1469 # --------
1470 # UNSORTED
1471 # --------
1472
1473 changequote(,)dnl
1474 # Compile in configure arguments.
1475 if test -f configargs.h ; then
1476         # Being re-configured.
1477         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1478         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1479 else
1480         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1481 fi
1482
1483 # Double all backslashes and backslash all quotes to turn
1484 # gcc_config_arguments into a C string.
1485 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1486 $gcc_config_arguments
1487 EOF
1488 gcc_config_arguments_str=`cat conftest.out`
1489 rm -f conftest.out
1490
1491 cat > configargs.h <<EOF
1492 /* Generated automatically. */
1493 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1494 static const char thread_model[] = "$thread_file";
1495
1496 static const struct {
1497   const char *name, *value;
1498 } configure_default_options[] = $configure_default_options;
1499 EOF
1500 changequote([,])dnl
1501
1502 changequote(,)dnl
1503 gcc_BASEVER=`cat $srcdir/BASE-VER`
1504 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1505 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1506 if test -f $srcdir/REVISION ; then
1507         gcc_REVISION=`cat $srcdir/REVISION`
1508 else
1509         gcc_REVISION=""
1510 fi
1511 cat > plugin-version.h <<EOF
1512 #include "configargs.h"
1513
1514 static char basever[] = "$gcc_BASEVER";
1515 static char datestamp[] = "$gcc_DATESTAMP";
1516 static char devphase[] = "$gcc_DEVPHASE";
1517 static char revision[] = "$gcc_REVISION";
1518
1519 /* FIXME plugins: We should make the version information more precise.
1520    One way to do is to add a checksum. */
1521
1522 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1523                                                 devphase, revision,
1524                                                 configuration_arguments};
1525 EOF
1526 changequote([,])dnl
1527
1528 # Internationalization
1529 ZW_GNU_GETTEXT_SISTER_DIR
1530
1531 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1532 # -liconv on the link line twice.
1533 case "$LIBINTL" in *$LIBICONV*)
1534         LIBICONV= ;;
1535 esac
1536
1537 AC_ARG_ENABLE(secureplt,
1538 [AS_HELP_STRING([--enable-secureplt],
1539                 [enable -msecure-plt by default for PowerPC])],
1540 [], [])
1541
1542 AC_ARG_ENABLE(leading-mingw64-underscores,
1543   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1544                  [enable leading underscores on 64 bit mingw targets]),
1545   [],[])
1546 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1547   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1548     [Define if we should use leading underscore on 64 bit mingw targets])])
1549
1550 AC_ARG_ENABLE(cld,
1551 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1552 [enable_cld=no])
1553
1554 AC_ARG_ENABLE(frame-pointer,
1555 [AS_HELP_STRING([--enable-frame-pointer],
1556                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1557 [
1558 case $target_os in
1559 linux* | darwin[[8912]]*)
1560   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1561   # DWARF2.
1562   enable_frame_pointer=no
1563   ;;
1564 *)
1565   enable_frame_pointer=yes
1566   ;;
1567 esac
1568 ])
1569
1570 # Windows32 Registry support for specifying GCC installation paths.
1571 AC_ARG_ENABLE(win32-registry,
1572 [AS_HELP_STRING([--disable-win32-registry],
1573                 [disable lookup of installation paths in the
1574                  Registry on Windows hosts])
1575 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1576 AS_HELP_STRING([--enable-win32-registry=KEY],
1577                [use KEY instead of GCC version as the last portion
1578                 of the registry key])],,)
1579
1580 case $host_os in
1581   win32 | pe | cygwin* | mingw32* | uwin*)
1582     if test "x$enable_win32_registry" != xno; then
1583       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1584     fi
1585
1586     if test "x$enable_win32_registry" != xno; then
1587       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1588   [Define to 1 if installation paths should be looked up in the Windows
1589    Registry. Ignored on non-Windows hosts.])
1590
1591       if test "x$enable_win32_registry" != xyes \
1592          && test "x$enable_win32_registry" != x; then
1593         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1594   [Define to be the last component of the Windows registry key under which
1595    to look for installation paths.  The full key used will be
1596    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1597    The default is the GCC version number.])
1598       fi
1599     fi
1600   ;;
1601 esac
1602
1603 # Get an absolute path to the GCC top-level source directory
1604 holddir=`${PWDCMD-pwd}`
1605 cd $srcdir
1606 topdir=`${PWDCMD-pwd}`
1607 cd $holddir
1608
1609 # Conditionalize the makefile for this host machine.
1610 xmake_file=
1611 for f in ${host_xmake_file}
1612 do
1613         if test -f ${srcdir}/config/$f
1614         then
1615                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1616         fi
1617 done
1618
1619 # Conditionalize the makefile for this target machine.
1620 tmake_file_=
1621 for f in ${tmake_file}
1622 do
1623         if test -f ${srcdir}/config/$f
1624         then
1625                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1626         fi
1627 done
1628 tmake_file="${tmake_file_}"
1629
1630 out_object_file=`basename $out_file .c`.o
1631
1632 tm_file_list="options.h"
1633 tm_include_list="options.h insn-constants.h"
1634 for f in $tm_file; do
1635   case $f in
1636     ./* )
1637        f=`echo $f | sed 's/^..//'`
1638        tm_file_list="${tm_file_list} $f"
1639        tm_include_list="${tm_include_list} $f"
1640        ;;
1641     defaults.h )
1642        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1643        tm_include_list="${tm_include_list} $f"
1644        ;;
1645     * )
1646        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1647        tm_include_list="${tm_include_list} config/$f"
1648        ;;
1649   esac
1650 done
1651
1652 libgcc_tm_file_list=
1653 libgcc_tm_include_list=
1654 for f in $libgcc_tm_file; do
1655   libgcc_tm_file_list="${libgcc_tm_file_list} \$(srcdir)/../libgcc/config/$f"
1656   libgcc_tm_include_list="${libgcc_tm_include_list} ../libgcc/config/$f"
1657 done
1658
1659 tm_p_file_list=
1660 tm_p_include_list=
1661 for f in $tm_p_file; do
1662   case $f in
1663     tm-preds.h )
1664        tm_p_file_list="${tm_p_file_list} $f"
1665        tm_p_include_list="${tm_p_include_list} $f"
1666        ;;
1667     * )
1668        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1669        tm_p_include_list="${tm_p_include_list} config/$f"
1670   esac
1671 done
1672
1673 xm_file_list=
1674 xm_include_list=
1675 for f in $xm_file; do
1676   case $f in
1677     ansidecl.h )
1678        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1679        xm_include_list="${xm_include_list} $f"
1680        ;;
1681     auto-host.h )
1682        xm_file_list="${xm_file_list} $f"
1683        xm_include_list="${xm_include_list} $f"
1684        ;;
1685     * )
1686        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1687        xm_include_list="${xm_include_list} config/$f"
1688        ;;
1689   esac
1690 done
1691
1692 host_xm_file_list=
1693 host_xm_include_list=
1694 for f in $host_xm_file; do
1695   case $f in
1696     ansidecl.h )
1697        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1698        host_xm_include_list="${host_xm_include_list} $f"
1699        ;;
1700     auto-host.h )
1701        host_xm_file_list="${host_xm_file_list} $f"
1702        host_xm_include_list="${host_xm_include_list} $f"
1703        ;;
1704     * )
1705        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1706        host_xm_include_list="${host_xm_include_list} config/$f"
1707        ;;
1708   esac
1709 done
1710
1711 build_xm_file_list=
1712 for f in $build_xm_file; do
1713   case $f in
1714     ansidecl.h )
1715        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1716        build_xm_include_list="${build_xm_include_list} $f"
1717        ;;
1718     auto-build.h | auto-host.h )
1719        build_xm_file_list="${build_xm_file_list} $f"
1720        build_xm_include_list="${build_xm_include_list} $f"
1721        ;;
1722     * )
1723        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1724        build_xm_include_list="${build_xm_include_list} config/$f"
1725        ;;
1726   esac
1727 done
1728
1729 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1730 # cross-compiler which does not use the native headers and libraries.
1731 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1732 CROSS=                                          AC_SUBST(CROSS)
1733 ALL=all.internal                                AC_SUBST(ALL)
1734 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1735
1736 if test "x$with_build_sysroot" != x; then
1737   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1738 else
1739   # This value is used, even on a native system, because
1740   # CROSS_SYSTEM_HEADER_DIR is just
1741   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1742   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1743 fi
1744
1745 if test x$host != x$target
1746 then
1747         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1748         ALL=all.cross
1749         SYSTEM_HEADER_DIR=$build_system_header_dir
1750         case "$host","$target" in
1751         # Darwin crosses can use the host system's libraries and headers,
1752         # because of the fat library support.  Of course, it must be the
1753         # same version of Darwin on both sides.  Allow the user to
1754         # just say --target=foo-darwin without a version number to mean
1755         # "the version on this system".
1756             *-*-darwin*,*-*-darwin*)
1757                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1758                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1759                 if test $hostos = $targetos -o $targetos = darwin ; then
1760                     CROSS=
1761                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1762                     with_headers=yes
1763                 fi
1764                 ;;
1765
1766             i?86-*-*,x86_64-*-* \
1767             | powerpc*-*-*,powerpc64*-*-*)
1768                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1769         esac
1770
1771         case $target in
1772                 *-*-mingw*)
1773                         if test "x$with_headers" = x; then
1774                                 with_headers=yes
1775                         fi
1776                         ;;
1777                 *)
1778                         ;;
1779         esac
1780 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1781         SYSTEM_HEADER_DIR=$build_system_header_dir
1782 fi
1783
1784 # If this is a cross-compiler that does not
1785 # have its own set of headers then define
1786 # inhibit_libc
1787
1788 # If this is using newlib, without having the headers available now,
1789 # then define inhibit_libc in LIBGCC2_CFLAGS.
1790 # This prevents libgcc2 from containing any code which requires libc
1791 # support.
1792 : ${inhibit_libc=false}
1793 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1794        test x$with_newlib = xyes ; } &&
1795      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1796        inhibit_libc=true
1797 fi
1798 AC_SUBST(inhibit_libc)
1799
1800 # When building gcc with a cross-compiler, we need to adjust things so
1801 # that the generator programs are still built with the native compiler.
1802 # Also, we cannot run fixincludes.
1803
1804 # These are the normal (build=host) settings:
1805 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1806 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1807 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1808 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1809
1810 # And these apply if build != host, or we are generating coverage data
1811 if test x$build != x$host || test "x$coverage_flags" != x
1812 then
1813     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1814     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1815 fi
1816
1817 # Expand extra_headers to include complete path.
1818 # This substitutes for lots of t-* files.
1819 extra_headers_list=
1820 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1821 for file in ${extra_headers} ; do
1822   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1823 done
1824
1825 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1826 if test x"$use_gcc_tgmath" = xyes
1827 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1828 fi
1829
1830 # Define collect2 in Makefile.
1831 case $host_can_use_collect2 in
1832   no) collect2= ;;
1833   *) collect2='collect2$(exeext)' ;;
1834 esac
1835 AC_SUBST([collect2])
1836
1837 # Add a definition of USE_COLLECT2 if system wants one.
1838 case $use_collect2 in
1839   no) use_collect2= ;;
1840   "") ;;
1841   *)
1842     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1843     xm_defines="${xm_defines} USE_COLLECT2"
1844     case $host_can_use_collect2 in
1845       no)
1846         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1847         ;;
1848     esac
1849     ;;
1850 esac
1851
1852 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1853 [Define to the name of the LTO plugin DSO that must be
1854   passed to the linker's -plugin=LIB option.])
1855
1856 # ---------------------------
1857 # Assembler & linker features
1858 # ---------------------------
1859
1860 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1861 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1862 # However when ld-new is first executed from the build tree, libtool will
1863 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1864 # to the build tree.  While doing this we need to use the previous-stage
1865 # linker, or we have an infinite loop.  The presence of a shell script as
1866 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1867 # the gcc/collect-ld script.  So we need to know how libtool works, or
1868 # exec-tool will fail.
1869
1870 m4_defun([_LT_CONFIG_COMMANDS], [])
1871 AC_PROG_LIBTOOL
1872 AC_SUBST(objdir)
1873 AC_SUBST(enable_fast_install)
1874
1875 # Identify the assembler which will work hand-in-glove with the newly
1876 # built GCC, so that we can examine its features.  This is the assembler
1877 # which will be driven by the driver program.
1878 #
1879 # If build != host, and we aren't building gas in-tree, we identify a
1880 # build->target assembler and hope that it will have the same features
1881 # as the host->target assembler we'll be using.
1882 gcc_cv_gas_major_version=
1883 gcc_cv_gas_minor_version=
1884 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1885
1886 m4_pattern_allow([AS_FOR_TARGET])dnl
1887 AS_VAR_SET_IF(gcc_cv_as,, [
1888 if test -x "$DEFAULT_ASSEMBLER"; then
1889         gcc_cv_as="$DEFAULT_ASSEMBLER"
1890 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1891      && test -f ../gas/Makefile \
1892      && test x$build = x$host; then
1893         gcc_cv_as=../gas/as-new$build_exeext
1894 elif test -x as$build_exeext; then
1895         # Build using assembler in the current directory.
1896         gcc_cv_as=./as$build_exeext
1897 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1898         gcc_cv_as="$AS_FOR_TARGET"
1899 else
1900         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1901 fi])
1902
1903 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1904 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1905 case "$ORIGINAL_AS_FOR_TARGET" in
1906   ./as | ./as$build_exeext) ;;
1907   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1908 esac
1909
1910 AC_MSG_CHECKING(what assembler to use)
1911 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1912   # Single tree build which includes gas.  We want to prefer it
1913   # over whatever linker top-level may have detected, since
1914   # we'll use what we're building after installation anyway.
1915   AC_MSG_RESULT(newly built gas)
1916   in_tree_gas=yes
1917   _gcc_COMPUTE_GAS_VERSION
1918   in_tree_gas_is_elf=no
1919   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1920      || (grep 'obj_format = multi' ../gas/Makefile \
1921          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1922   then
1923     in_tree_gas_is_elf=yes
1924   fi
1925 else
1926   AC_MSG_RESULT($gcc_cv_as)
1927   in_tree_gas=no
1928 fi
1929
1930 # Identify the linker which will work hand-in-glove with the newly
1931 # built GCC, so that we can examine its features.  This is the linker
1932 # which will be driven by the driver program.
1933 #
1934 # If build != host, and we aren't building gas in-tree, we identify a
1935 # build->target linker and hope that it will have the same features
1936 # as the host->target linker we'll be using.
1937 gcc_cv_gld_major_version=
1938 gcc_cv_gld_minor_version=
1939 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1940 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1941
1942 AS_VAR_SET_IF(gcc_cv_ld,, [
1943 if test -x "$DEFAULT_LINKER"; then
1944         gcc_cv_ld="$DEFAULT_LINKER"
1945 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1946      && test -f ../ld/Makefile \
1947      && test x$build = x$host; then
1948         gcc_cv_ld=../ld/ld-new$build_exeext
1949 elif test -x collect-ld$build_exeext; then
1950         # Build using linker in the current directory.
1951         gcc_cv_ld=./collect-ld$build_exeext
1952 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
1953         gcc_cv_ld="$LD_FOR_TARGET"
1954 else
1955         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1956 fi])
1957
1958 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1959 PLUGIN_LD=`basename $gcc_cv_ld`
1960 AC_ARG_WITH(plugin-ld,
1961 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
1962 [if test x"$withval" != x; then
1963    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1964    PLUGIN_LD="$withval"
1965  fi])
1966 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1967 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1968
1969 # Check to see if we are using gold instead of ld
1970 AC_MSG_CHECKING(whether we are using gold)
1971 ld_is_gold=no
1972 if test x$gcc_cv_ld != x; then
1973   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1974      | grep "GNU gold" > /dev/null; then
1975     ld_is_gold=yes
1976   fi
1977 fi
1978 AC_MSG_RESULT($ld_is_gold)
1979
1980 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1981 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1982 case "$ORIGINAL_LD_FOR_TARGET" in
1983   ./collect-ld | ./collect-ld$build_exeext) ;;
1984   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1985 esac
1986
1987 AC_MSG_CHECKING(what linker to use)
1988 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
1989    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
1990         # Single tree build which includes ld.  We want to prefer it
1991         # over whatever linker top-level may have detected, since
1992         # we'll use what we're building after installation anyway.
1993         AC_MSG_RESULT(newly built ld)
1994         in_tree_ld=yes
1995         in_tree_ld_is_elf=no
1996         if (grep 'EMUL = .*elf' ../ld/Makefile \
1997             || grep 'EMUL = .*linux' ../ld/Makefile \
1998             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1999           in_tree_ld_is_elf=yes
2000         elif test "$ld_is_gold" = yes; then
2001           in_tree_ld_is_elf=yes
2002         fi
2003         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
2004         do
2005 changequote(,)dnl
2006                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
2007                 if test x$gcc_cv_gld_version != x; then
2008                         break
2009                 fi
2010         done
2011         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2012         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2013 changequote([,])dnl
2014 else
2015         AC_MSG_RESULT($gcc_cv_ld)
2016         in_tree_ld=no
2017 fi
2018
2019 # Figure out what nm we will be using.
2020 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2021 AS_VAR_SET_IF(gcc_cv_nm,, [
2022 if test -f $gcc_cv_binutils_srcdir/configure.in \
2023      && test -f ../binutils/Makefile \
2024      && test x$build = x$host; then
2025         gcc_cv_nm=../binutils/nm-new$build_exeext
2026 elif test -x nm$build_exeext; then
2027         gcc_cv_nm=./nm$build_exeext
2028 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2029         gcc_cv_nm="$NM_FOR_TARGET"
2030 else
2031         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2032 fi])
2033
2034 AC_MSG_CHECKING(what nm to use)
2035 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2036         # Single tree build which includes binutils.
2037         AC_MSG_RESULT(newly built nm)
2038         in_tree_nm=yes
2039 else
2040         AC_MSG_RESULT($gcc_cv_nm)
2041         in_tree_nm=no
2042 fi
2043
2044 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2045 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2046 case "$ORIGINAL_NM_FOR_TARGET" in
2047   ./nm | ./nm$build_exeext) ;;
2048   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2049 esac
2050
2051
2052 # Figure out what objdump we will be using.
2053 AS_VAR_SET_IF(gcc_cv_objdump,, [
2054 if test -f $gcc_cv_binutils_srcdir/configure.in \
2055      && test -f ../binutils/Makefile \
2056      && test x$build = x$host; then
2057         # Single tree build which includes binutils.
2058         gcc_cv_objdump=../binutils/objdump$build_exeext
2059 elif test -x objdump$build_exeext; then
2060         gcc_cv_objdump=./objdump$build_exeext
2061 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2062         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2063 else
2064         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2065 fi])
2066
2067 AC_MSG_CHECKING(what objdump to use)
2068 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2069         # Single tree build which includes binutils.
2070         AC_MSG_RESULT(newly built objdump)
2071 elif test x$gcc_cv_objdump = x; then
2072         AC_MSG_RESULT(not found)
2073 else
2074         AC_MSG_RESULT($gcc_cv_objdump)
2075 fi
2076
2077 # Figure out what readelf we will be using.
2078 AS_VAR_SET_IF(gcc_cv_readelf,, [
2079 if test -f $gcc_cv_binutils_srcdir/configure.in \
2080      && test -f ../binutils/Makefile \
2081      && test x$build = x$host; then
2082         # Single tree build which includes binutils.
2083         gcc_cv_readelf=../binutils/readelf$build_exeext
2084 elif test -x readelf$build_exeext; then
2085         gcc_cv_readelf=./readelf$build_exeext
2086 else
2087         AC_PATH_PROG(gcc_cv_readelf, readelf)
2088 fi])
2089
2090 AC_MSG_CHECKING(what readelf to use)
2091 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2092         # Single tree build which includes binutils.
2093         AC_MSG_RESULT(newly built readelf)
2094 elif test x$gcc_cv_readelf = x; then
2095         AC_MSG_RESULT(not found)
2096 else
2097         AC_MSG_RESULT($gcc_cv_readelf)
2098 fi
2099
2100 # Figure out what assembler alignment features are present.
2101 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2102  [2,6,0],,
2103 [.balign 4
2104 .p2align 2],,
2105 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2106   [Define if your assembler supports .balign and .p2align.])])
2107
2108 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2109  [2,8,0],,
2110  [.p2align 4,,7],,
2111 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2112   [Define if your assembler supports specifying the maximum number
2113    of bytes to skip when using the GAS .p2align command.])])
2114
2115 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2116  [2,8,0],,
2117  [.literal16],,
2118 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2119   [Define if your assembler supports .literal16.])])
2120
2121 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2122  [elf,2,9,0],,
2123  [conftest_label1: .word 0
2124 .subsection -1
2125 conftest_label2: .word 0
2126 .previous],
2127  [if test x$gcc_cv_nm != x; then
2128     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2129     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2130     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2131     then :
2132     else gcc_cv_as_subsection_m1=yes
2133     fi
2134     rm -f conftest.nm1 conftest.nm2
2135   fi],
2136  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2137   [Define if your assembler supports .subsection and .subsection -1 starts
2138    emitting at the beginning of your section.])])
2139
2140 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2141  [2,2,0],,
2142  [      .weak foobar],,
2143 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2144
2145 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2146  [2,17,0],,
2147  [      .weakref foobar, barfnot],,
2148 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2149
2150 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2151  [2,15,91],,
2152  [      .SPACE $TEXT$
2153         .NSUBSPA $CODE$,COMDAT],,
2154 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2155
2156 # .hidden needs to be supported in both the assembler and the linker,
2157 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2158 # This is irritatingly difficult to feature test for; we have to check the
2159 # date string after the version number.  If we've got an in-tree
2160 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2161 # to be safe.
2162 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2163 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2164  [elf,2,13,0],,
2165 [       .hidden foobar
2166 foobar:],[
2167 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2168 # STV_HIDDEN, so disable .hidden support if so.
2169 case "${target}" in
2170   i?86-*-solaris2*)
2171     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2172       cat > conftest.s <<EOF
2173 .globl hidden
2174         .hidden hidden
2175 hidden:
2176 .globl default
2177         .set    default,hidden
2178 EOF
2179       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2180         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2181         grep '\.hidden default' > /dev/null; then
2182         gcc_cv_as_hidden=no
2183       else
2184         gcc_cv_as_hidden=yes
2185       fi
2186     else
2187       # Assume bug is present if objdump is missing.
2188       gcc_cv_as_hidden=no
2189     fi
2190     ;;
2191   *)
2192     gcc_cv_as_hidden=yes
2193     ;;
2194 esac])
2195
2196 # gnu_indirect_function type is an extension proposed at
2197 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2198 # selection of function implementation
2199 AC_ARG_ENABLE(gnu-indirect-function,
2200  [AS_HELP_STRING([--enable-gnu-indirect-function],
2201                  [enable the use of the @gnu_indirect_function to glibc systems])],
2202  [case $enable_gnu_indirect_function in
2203     yes | no) ;;
2204     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2205 Valid choices are 'yes' and 'no'.]) ;;
2206   esac],
2207  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2208 if test x$enable_gnu_indirect_function = xyes; then
2209   AC_DEFINE(HAVE_GNU_INDIRECT_FUNCTION, 1,
2210    [Define if your system supports gnu indirect functions.])
2211 fi
2212
2213 changequote(,)dnl
2214 if test $in_tree_ld != yes ; then
2215   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2216   if echo "$ld_ver" | grep GNU > /dev/null; then
2217     if test x"$ld_is_gold" = xyes; then
2218       # GNU gold --version looks like this:
2219       #
2220       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2221       #
2222       # We extract the binutils version which is more familiar and specific
2223       # than the gold version.
2224       ld_vers=`echo $ld_ver | sed -n \
2225           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2226     else
2227       # GNU ld --version looks like this:
2228       #
2229       # GNU ld (GNU Binutils) 2.21.51.20110225
2230       ld_vers=`echo $ld_ver | sed -n \
2231           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2232     fi
2233     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2234     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2235     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2236     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2237   else
2238     case "${target}" in
2239       *-*-solaris2*)
2240         #
2241         # Solaris 2 ld -V output looks like this for a regular version:
2242         #
2243         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2244         #
2245         # but test versions add stuff at the end:
2246         #
2247         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2248         #
2249         ld_ver=`$gcc_cv_ld -V 2>&1`
2250         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2251           ld_vers=`echo $ld_ver | sed -n \
2252             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2253           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2254           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2255         fi
2256         ;;
2257     esac
2258   fi
2259 fi
2260 changequote([,])dnl
2261
2262 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2263 [[if test $in_tree_ld = yes ; then
2264   gcc_cv_ld_hidden=no
2265   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2266      && test $in_tree_ld_is_elf = yes; then
2267      gcc_cv_ld_hidden=yes
2268   fi
2269 else
2270   gcc_cv_ld_hidden=yes
2271   if test x"$ld_is_gold" = xyes; then
2272     :
2273   elif echo "$ld_ver" | grep GNU > /dev/null; then
2274     if test 0"$ld_date" -lt 20020404; then
2275       if test -n "$ld_date"; then
2276         # If there was date string, but was earlier than 2002-04-04, fail
2277         gcc_cv_ld_hidden=no
2278       elif test -z "$ld_vers"; then
2279         # If there was no date string nor ld version number, something is wrong
2280         gcc_cv_ld_hidden=no
2281       else
2282         test -z "$ld_vers_patch" && ld_vers_patch=0
2283         if test "$ld_vers_major" -lt 2; then
2284           gcc_cv_ld_hidden=no
2285         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2286           gcc_cv_ld_hidden="no"
2287         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2288           gcc_cv_ld_hidden=no
2289         fi
2290       fi
2291     fi
2292   else
2293     case "${target}" in
2294       hppa64*-*-hpux* | ia64*-*-hpux*)
2295         gcc_cv_ld_hidden=yes
2296         ;;
2297       *-*-solaris2.8*)
2298         # .hidden support was backported to Solaris 8, starting with ld
2299         # version 1.276.
2300         if test "$ld_vers_minor" -ge 276; then
2301           gcc_cv_ld_hidden=yes
2302         else
2303           gcc_cv_ld_hidden=no
2304         fi
2305         ;;
2306       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2307         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2308         # .symbolic was only added in Solaris 9 12/02.
2309         gcc_cv_ld_hidden=yes
2310         ;;
2311       *)
2312         gcc_cv_ld_hidden=no
2313         ;;
2314     esac
2315   fi
2316 fi]])
2317 libgcc_visibility=no
2318 AC_SUBST(libgcc_visibility)
2319 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2320 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2321   libgcc_visibility=yes
2322   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2323   [Define if your assembler and linker support .hidden.])
2324 fi
2325
2326 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2327 gcc_cv_ld_ro_rw_mix=unknown
2328 if test $in_tree_ld = yes ; then
2329   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2330      && test $in_tree_ld_is_elf = yes; then
2331     gcc_cv_ld_ro_rw_mix=read-write
2332   fi
2333 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2334   echo '.section myfoosect, "a"' > conftest1.s
2335   echo '.section myfoosect, "aw"' > conftest2.s
2336   echo '.byte 1' >> conftest2.s
2337   echo '.section myfoosect, "a"' > conftest3.s
2338   echo '.byte 0' >> conftest3.s
2339   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2340      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2341      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2342      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2343         conftest2.o conftest3.o > /dev/null 2>&1; then
2344     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2345                          | sed -e '/myfoosect/!d' -e N`
2346     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2347       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2348         gcc_cv_ld_ro_rw_mix=read-only
2349       else
2350         gcc_cv_ld_ro_rw_mix=read-write
2351       fi
2352     fi
2353   fi
2354 changequote(,)dnl
2355   rm -f conftest.* conftest[123].*
2356 changequote([,])dnl
2357 fi
2358 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2359         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2360   [Define if your linker links a mix of read-only
2361    and read-write sections into a read-write section.])
2362 fi
2363 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2364
2365 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2366 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2367   [elf,2,11,0],,
2368 [       .data
2369         .uleb128 L2 - L1
2370 L1:
2371         .uleb128 1280
2372         .sleb128 -1010
2373 L2:],
2374 [[# GAS versions before 2.11 do not support uleb128,
2375   # despite appearing to.
2376   # ??? There exists an elf-specific test that will crash
2377   # the assembler.  Perhaps it's better to figure out whether
2378   # arbitrary sections are supported and try the test.
2379   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2380   if echo "$as_ver" | grep GNU > /dev/null; then
2381     as_vers=`echo $as_ver | sed -n \
2382         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2383     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2384     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2385     if test $as_major -eq 2 && test $as_minor -lt 11
2386     then :
2387     else gcc_cv_as_leb128=yes
2388     fi
2389   fi]],
2390   [AC_DEFINE(HAVE_AS_LEB128, 1,
2391     [Define if your assembler supports .sleb128 and .uleb128.])])
2392
2393 # Check if we have assembler support for unwind directives.
2394 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2395   ,,
2396 [       .text
2397         .cfi_startproc
2398         .cfi_offset 0, 0
2399         .cfi_same_value 1
2400         .cfi_def_cfa 1, 2
2401         .cfi_escape 1, 2, 3, 4, 5
2402         .cfi_endproc],
2403 [case "$target" in
2404   *-*-solaris*)
2405     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2406     # read-only and read-write sections, we need to make sure that the
2407     # assembler used emits read-write .eh_frame sections.
2408     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2409       if test "x$gcc_cv_objdump" != x; then
2410         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2411                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2412           gcc_cv_as_cfi_directive=no
2413         else
2414           case "$target" in
2415             i?86-*-solaris2.1[[0-9]]*)
2416               # On Solaris/x86, make sure that GCC and gas agree on using
2417               # read-only .eh_frame sections for 64-bit.
2418               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2419                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2420                         sed -e /.eh_frame/!d -e N | \
2421                         grep READONLY > /dev/null; then
2422                 gcc_cv_as_cfi_directive=yes
2423               else
2424                 gcc_cv_as_cfi_directive=no
2425               fi
2426               ;;
2427             *)
2428               gcc_cv_as_cfi_directive=yes
2429               ;;
2430           esac
2431         fi
2432       else
2433         # no objdump, err on the side of caution
2434         gcc_cv_as_cfi_directive=no
2435       fi
2436     else
2437       gcc_cv_as_cfi_directive=yes
2438     fi
2439     ;;
2440   *-*-*)
2441     gcc_cv_as_cfi_directive=yes
2442     ;;
2443 esac])
2444 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2445 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2446   ,,
2447 [       .text
2448         .cfi_startproc
2449         .cfi_adjust_cfa_offset 64
2450         .skip 75040, 0
2451         .cfi_adjust_cfa_offset 128
2452         .cfi_endproc],
2453 [[
2454 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2455     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2456    gcc_cv_as_cfi_advance_working=yes
2457 fi
2458 ]])
2459 else
2460   # no objdump, err on the side of caution
2461   gcc_cv_as_cfi_advance_working=no
2462 fi
2463 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2464 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2465   [`if test $gcc_cv_as_cfi_directive = yes \
2466        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2467   [Define 0/1 if your assembler supports CFI directives.])
2468
2469 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2470 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2471   gcc_cv_as_cfi_personality_directive, ,,
2472 [       .text
2473         .cfi_startproc
2474         .cfi_personality 0, symbol
2475         .cfi_endproc])
2476 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2477   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2478     then echo 1; else echo 0; fi`],
2479   [Define 0/1 if your assembler supports .cfi_personality.])
2480
2481 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2482   gcc_cv_as_cfi_sections_directive, ,,
2483 [       .text
2484         .cfi_sections .debug_frame, .eh_frame
2485         .cfi_startproc
2486         .cfi_endproc],
2487 [case $target_os in
2488   win32 | pe | cygwin* | mingw32* | uwin*)
2489     # Need to check that we generated the correct relocation for the
2490     # .debug_frame section.  This was fixed for binutils 2.21.
2491     gcc_cv_as_cfi_sections_directive=no
2492     if test "x$gcc_cv_objdump" != x; then
2493      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2494         grep secrel > /dev/null; then
2495       gcc_cv_as_cfi_sections_directive=yes
2496      fi
2497     fi
2498     ;;
2499   *)
2500     gcc_cv_as_cfi_sections_directive=yes
2501     ;;
2502 esac])
2503 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2504 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2505   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2506     then echo 1; else echo 0; fi`],
2507   [Define 0/1 if your assembler supports .cfi_sections.])
2508
2509 # GAS versions up to and including 2.11.0 may mis-optimize
2510 # .eh_frame data.
2511 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2512   [elf,2,12,0],,
2513 [       .text
2514 .LFB1:
2515         .4byte  0
2516 .L1:
2517         .4byte  0
2518 .LFE1:
2519         .section        .eh_frame,"aw",@progbits
2520 __FRAME_BEGIN__:
2521         .4byte  .LECIE1-.LSCIE1
2522 .LSCIE1:
2523         .4byte  0x0
2524         .byte   0x1
2525         .ascii "z\0"
2526         .byte   0x1
2527         .byte   0x78
2528         .byte   0x1a
2529         .byte   0x0
2530         .byte   0x4
2531         .4byte  1
2532         .p2align 1
2533 .LECIE1:
2534 .LSFDE1:
2535         .4byte  .LEFDE1-.LASFDE1
2536 .LASFDE1:
2537         .4byte  .LASFDE1-__FRAME_BEGIN__
2538         .4byte  .LFB1
2539         .4byte  .LFE1-.LFB1
2540         .byte   0x4
2541         .4byte  .LFE1-.LFB1
2542         .byte   0x4
2543         .4byte  .L1-.LFB1
2544 .LEFDE1:],
2545 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2546 cat > conftest.lit <<EOF
2547  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2548  0010 01000000 12000000 18000000 00000000  ................
2549  0020 08000000 04080000 0044               .........D      @&t@
2550 EOF
2551 cat > conftest.big <<EOF
2552  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2553  0010 00000001 00000012 00000018 00000000  ................
2554  0020 00000008 04000000 0844               .........D      @&t@
2555 EOF
2556   # If the assembler didn't choke, and we can objdump,
2557   # and we got the correct data, then succeed.
2558   # The text in the here-document typically retains its unix-style line
2559   # endings, while the output of objdump will use host line endings.
2560   # Therefore, use diff -b for the comparisons.
2561   if test x$gcc_cv_objdump != x \
2562   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2563      | tail -3 > conftest.got \
2564   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2565     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2566   then
2567     gcc_cv_as_eh_frame=yes
2568   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2569     gcc_cv_as_eh_frame=buggy
2570   else
2571     # Uh oh, what do we do now?
2572     gcc_cv_as_eh_frame=no
2573   fi])
2574
2575 if test $gcc_cv_as_eh_frame = buggy; then
2576   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2577   [Define if your assembler mis-optimizes .eh_frame data.])
2578 fi
2579
2580 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2581  [elf,2,12,0], [--fatal-warnings],
2582  [.section .rodata.str, "aMS", @progbits, 1])
2583 if test $gcc_cv_as_shf_merge = no; then
2584   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2585     [elf,2,12,0], [--fatal-warnings],
2586     [.section .rodata.str, "aMS", %progbits, 1])
2587 fi
2588 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2589   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2590 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2591
2592 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2593  [elf,2,16,0], [--fatal-warnings],
2594  [.section .text,"axG",@progbits,.foo,comdat])
2595 if test $gcc_cv_as_comdat_group = yes; then
2596   gcc_cv_as_comdat_group_percent=no
2597 else
2598  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2599    [elf,2,16,0], [--fatal-warnings],
2600    [.section .text,"axG",%progbits,.foo,comdat])
2601 fi
2602 if test x"$ld_is_gold" = xyes; then
2603   comdat_group=yes
2604 elif test $in_tree_ld = yes ; then
2605   comdat_group=no
2606   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2607      && test $in_tree_ld_is_elf = yes; then
2608      comdat_group=yes
2609   fi
2610 elif echo "$ld_ver" | grep GNU > /dev/null; then
2611   comdat_group=yes
2612   if test 0"$ld_date" -lt 20050308; then
2613     if test -n "$ld_date"; then
2614       # If there was date string, but was earlier than 2005-03-08, fail
2615       comdat_group=no
2616     elif test "$ld_vers_major" -lt 2; then
2617       comdat_group=no
2618     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2619       comdat_group=no
2620     fi
2621   fi
2622 else
2623 changequote(,)dnl
2624   case "${target}" in
2625     *-*-solaris2.1[1-9]*)
2626       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2627       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2628       # version 1.688.
2629       #
2630       # FIXME: Maybe need to refine later when COMDAT group support with
2631       # Sun as is implemented.
2632       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2633         comdat_group=yes
2634       else
2635         comdat_group=no
2636       fi
2637       ;;
2638     *)
2639       # Assume linkers other than GNU ld don't support COMDAT group.
2640       comdat_group=no
2641       ;;
2642   esac
2643 changequote([,])dnl
2644 fi
2645 # Allow overriding the automatic COMDAT group tests above.
2646 AC_ARG_ENABLE(comdat,
2647   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2648   [comdat_group="$enable_comdat"])
2649 if test $comdat_group = no; then
2650   gcc_cv_as_comdat_group=no
2651   gcc_cv_as_comdat_group_percent=no
2652 fi
2653 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2654   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2655 [Define 0/1 if your assembler and linker support COMDAT groups.])
2656
2657 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2658  gcc_cv_as_discriminator,
2659  [2,19,51],,
2660 [       .text
2661         .file 1 "conf.c"
2662         .loc 1 1 0 discriminator 1],,
2663 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2664   [Define if your assembler supports the .loc discriminator sub-directive.])])
2665
2666 # Thread-local storage - the check is heavily parameterized.
2667 conftest_s=
2668 tls_first_major=
2669 tls_first_minor=
2670 tls_as_opt=
2671 case "$target" in
2672 changequote(,)dnl
2673   alpha*-*-*)
2674     conftest_s='
2675         .section ".tdata","awT",@progbits
2676 foo:    .long   25
2677         .text
2678         ldq     $27,__tls_get_addr($29)         !literal!1
2679         lda     $16,foo($29)                    !tlsgd!1
2680         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2681         ldq     $27,__tls_get_addr($29)         !literal!2
2682         lda     $16,foo($29)                    !tlsldm!2
2683         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2684         ldq     $1,foo($29)                     !gotdtprel
2685         ldah    $2,foo($29)                     !dtprelhi
2686         lda     $3,foo($2)                      !dtprello
2687         lda     $4,foo($29)                     !dtprel
2688         ldq     $1,foo($29)                     !gottprel
2689         ldah    $2,foo($29)                     !tprelhi
2690         lda     $3,foo($2)                      !tprello
2691         lda     $4,foo($29)                     !tprel'
2692         tls_first_major=2
2693         tls_first_minor=13
2694         tls_as_opt=--fatal-warnings
2695         ;;
2696   cris-*-*|crisv32-*-*)
2697     conftest_s='
2698         .section ".tdata","awT",@progbits
2699 x:      .long   25
2700         .text
2701         move.d x:IE,$r10
2702         nop'
2703         tls_first_major=2
2704         tls_first_minor=20
2705         tls_as_opt=--fatal-warnings
2706         ;;
2707   frv*-*-*)
2708     conftest_s='
2709         .section ".tdata","awT",@progbits
2710 x:      .long   25
2711         .text
2712         call    #gettlsoff(x)'
2713         tls_first_major=2
2714         tls_first_minor=14
2715         ;;
2716   hppa*-*-linux*)
2717     conftest_s='
2718 t1:     .reg    %r20
2719 t2:     .reg    %r21
2720 gp:     .reg    %r19
2721         .section ".tdata","awT",@progbits
2722 foo:    .long   25
2723         .text
2724         .align  4
2725         addil LT%foo-$tls_gdidx$,gp
2726         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2727         b __tls_get_addr
2728         nop
2729         addil LT%foo-$tls_ldidx$,gp
2730         b __tls_get_addr
2731         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2732         addil LR%foo-$tls_dtpoff$,%ret0
2733         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2734         mfctl %cr27,%t1
2735         addil LT%foo-$tls_ieoff$,gp
2736         ldw RT%foo-$tls_ieoff$(%r1),%t2
2737         add %t1,%t2,%t3
2738         mfctl %cr27,%t1
2739         addil LR%foo-$tls_leoff$,%t1
2740         ldo RR%foo-$tls_leoff$(%r1),%t2'
2741         tls_first_major=2
2742         tls_first_minor=15
2743         tls_as_opt=--fatal-warnings
2744         ;;
2745   arm*-*-*)
2746     conftest_s='
2747         .section ".tdata","awT",%progbits
2748 foo:    .long   25
2749         .text
2750 .word foo(gottpoff)
2751 .word foo(tpoff)
2752 .word foo(tlsgd)
2753 .word foo(tlsldm)
2754 .word foo(tlsldo)'
2755         tls_first_major=2
2756         tls_first_minor=17
2757         ;;
2758   i[34567]86-*-*)
2759     case "$target" in
2760       i[34567]86-*-solaris2.*)
2761         on_solaris=yes
2762         tga_func=___tls_get_addr
2763         ;;
2764       *)
2765         on_solaris=no
2766         ;;
2767     esac
2768     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2769       conftest_s='
2770         .section .tdata,"awt",@progbits'
2771       tls_first_major=0
2772       tls_first_minor=0
2773 changequote([,])dnl
2774       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2775 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2776 changequote(,)dnl
2777     else
2778       conftest_s='
2779         .section ".tdata","awT",@progbits'
2780       tls_first_major=2
2781       tls_first_minor=14
2782       tls_as_opt="--fatal-warnings"
2783     fi
2784     conftest_s="$conftest_s
2785 foo:    .long   25
2786         .text
2787         movl    %gs:0, %eax
2788         leal    foo@tlsgd(,%ebx,1), %eax
2789         leal    foo@tlsldm(%ebx), %eax
2790         leal    foo@dtpoff(%eax), %edx
2791         movl    foo@gottpoff(%ebx), %eax
2792         subl    foo@gottpoff(%ebx), %eax
2793         addl    foo@gotntpoff(%ebx), %eax
2794         movl    foo@indntpoff, %eax
2795         movl    \$foo@tpoff, %eax
2796         subl    \$foo@tpoff, %eax
2797         leal    foo@ntpoff(%ecx), %eax"
2798     ;;
2799   x86_64-*-*)
2800     conftest_s='
2801         .section ".tdata","awT",@progbits
2802 foo:    .long   25
2803         .text
2804         movq    %fs:0, %rax
2805         leaq    foo@TLSGD(%rip), %rdi
2806         leaq    foo@TLSLD(%rip), %rdi
2807         leaq    foo@DTPOFF(%rax), %rdx
2808         movq    foo@GOTTPOFF(%rip), %rax
2809         movq    $foo@TPOFF, %rax'
2810         tls_first_major=2
2811         tls_first_minor=14
2812         tls_as_opt=--fatal-warnings
2813         ;;
2814   ia64-*-*)
2815     conftest_s='
2816         .section ".tdata","awT",@progbits
2817 foo:    data8   25
2818         .text
2819         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2820         addl    r17 = @ltoff(@dtprel(foo#)), gp
2821         addl    r18 = @ltoff(@tprel(foo#)), gp
2822         addl    r19 = @dtprel(foo#), gp
2823         adds    r21 = @dtprel(foo#), r13
2824         movl    r23 = @dtprel(foo#)
2825         addl    r20 = @tprel(foo#), gp
2826         adds    r22 = @tprel(foo#), r13
2827         movl    r24 = @tprel(foo#)'
2828         tls_first_major=2
2829         tls_first_minor=13
2830         tls_as_opt=--fatal-warnings
2831         ;;
2832   mips*-*-*)
2833     conftest_s='
2834         .section .tdata,"awT",@progbits
2835 x:
2836         .word 2
2837         .text
2838         addiu $4, $28, %tlsgd(x)
2839         addiu $4, $28, %tlsldm(x)
2840         lui $4, %dtprel_hi(x)
2841         addiu $4, $4, %dtprel_lo(x)
2842         lw $4, %gottprel(x)($28)
2843         lui $4, %tprel_hi(x)
2844         addiu $4, $4, %tprel_lo(x)'
2845         tls_first_major=2
2846         tls_first_minor=16
2847         tls_as_opt='-32 --fatal-warnings'
2848         ;;
2849   m68k-*-*)
2850     conftest_s='
2851         .section .tdata,"awT",@progbits
2852 x:
2853         .word 2
2854         .text
2855 foo:
2856         move.l x@TLSGD(%a5),%a0
2857         move.l x@TLSLDM(%a5),%a0
2858         move.l x@TLSLDO(%a5),%a0
2859         move.l x@TLSIE(%a5),%a0
2860         move.l x@TLSLE(%a5),%a0'
2861         tls_first_major=2
2862         tls_first_minor=19
2863         tls_as_opt='--fatal-warnings'
2864         ;;
2865   powerpc-*-*)
2866     conftest_s='
2867         .section ".tdata","awT",@progbits
2868         .align 2
2869 ld0:    .space 4
2870 ld1:    .space 4
2871 x1:     .space 4
2872 x2:     .space 4
2873 x3:     .space 4
2874         .text
2875         addi 3,31,ld0@got@tlsgd
2876         bl __tls_get_addr
2877         addi 3,31,x1@got@tlsld
2878         bl __tls_get_addr
2879         addi 9,3,x1@dtprel
2880         addis 9,3,x2@dtprel@ha
2881         addi 9,9,x2@dtprel@l
2882         lwz 9,x3@got@tprel(31)
2883         add 9,9,x@tls
2884         addi 9,2,x1@tprel
2885         addis 9,2,x2@tprel@ha
2886         addi 9,9,x2@tprel@l'
2887         tls_first_major=2
2888         tls_first_minor=14
2889         tls_as_opt="-a32 --fatal-warnings"
2890         ;;
2891   powerpc64-*-*)
2892     conftest_s='
2893         .section ".tdata","awT",@progbits
2894         .align 3
2895 ld0:    .space 8
2896 ld1:    .space 8
2897 x1:     .space 8
2898 x2:     .space 8
2899 x3:     .space 8
2900         .text
2901         addi 3,2,ld0@got@tlsgd
2902         bl .__tls_get_addr
2903         nop
2904         addi 3,2,ld1@toc
2905         bl .__tls_get_addr
2906         nop
2907         addi 3,2,x1@got@tlsld
2908         bl .__tls_get_addr
2909         nop
2910         addi 9,3,x1@dtprel
2911         bl .__tls_get_addr
2912         nop
2913         addis 9,3,x2@dtprel@ha
2914         addi 9,9,x2@dtprel@l
2915         bl .__tls_get_addr
2916         nop
2917         ld 9,x3@got@dtprel(2)
2918         add 9,9,3
2919         bl .__tls_get_addr
2920         nop'
2921         tls_first_major=2
2922         tls_first_minor=14
2923         tls_as_opt="-a64 --fatal-warnings"
2924         ;;
2925   s390-*-*)
2926     conftest_s='
2927         .section ".tdata","awT",@progbits
2928 foo:    .long   25
2929         .text
2930         .long   foo@TLSGD
2931         .long   foo@TLSLDM
2932         .long   foo@DTPOFF
2933         .long   foo@NTPOFF
2934         .long   foo@GOTNTPOFF
2935         .long   foo@INDNTPOFF
2936         l       %r1,foo@GOTNTPOFF(%r12)
2937         l       %r1,0(%r1):tls_load:foo
2938         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2939         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2940         tls_first_major=2
2941         tls_first_minor=14
2942         tls_as_opt="-m31 --fatal-warnings"
2943         ;;
2944   s390x-*-*)
2945     conftest_s='
2946         .section ".tdata","awT",@progbits
2947 foo:    .long   25
2948         .text
2949         .quad   foo@TLSGD
2950         .quad   foo@TLSLDM
2951         .quad   foo@DTPOFF
2952         .quad   foo@NTPOFF
2953         .quad   foo@GOTNTPOFF
2954         lg      %r1,foo@GOTNTPOFF(%r12)
2955         larl    %r1,foo@INDNTPOFF
2956         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2957         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2958         tls_first_major=2
2959         tls_first_minor=14
2960         tls_as_opt="-m64 -Aesame --fatal-warnings"
2961         ;;
2962   sh-*-* | sh[34]-*-*)
2963     conftest_s='
2964         .section ".tdata","awT",@progbits
2965 foo:    .long   25
2966         .text
2967         .long   foo@TLSGD
2968         .long   foo@TLSLDM
2969         .long   foo@DTPOFF
2970         .long   foo@GOTTPOFF
2971         .long   foo@TPOFF'
2972         tls_first_major=2
2973         tls_first_minor=13
2974         tls_as_opt=--fatal-warnings
2975         ;;
2976   sparc*-*-*)
2977     case "$target" in
2978       sparc*-sun-solaris2.*)
2979         on_solaris=yes
2980         tga_func=__tls_get_addr
2981         ;;
2982       *)
2983         on_solaris=no
2984         ;;
2985     esac
2986     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2987       conftest_s='
2988         .section ".tdata",#alloc,#write,#tls'
2989         tls_first_major=0
2990         tls_first_minor=0
2991     else
2992       conftest_s='
2993         .section ".tdata","awT",@progbits'
2994         tls_first_major=2
2995         tls_first_minor=14
2996         tls_as_opt="-32 --fatal-warnings"
2997     fi
2998     conftest_s="$conftest_s
2999 foo:    .long   25
3000         .text
3001         sethi   %tgd_hi22(foo), %o0
3002         add     %o0, %tgd_lo10(foo), %o1
3003         add     %l7, %o1, %o0, %tgd_add(foo)
3004         call    __tls_get_addr, %tgd_call(foo)
3005         sethi   %tldm_hi22(foo), %l1
3006         add     %l1, %tldm_lo10(foo), %l2
3007         add     %l7, %l2, %o0, %tldm_add(foo)
3008         call    __tls_get_addr, %tldm_call(foo)
3009         sethi   %tldo_hix22(foo), %l3
3010         xor     %l3, %tldo_lox10(foo), %l4
3011         add     %o0, %l4, %l5, %tldo_add(foo)
3012         sethi   %tie_hi22(foo), %o3
3013         add     %o3, %tie_lo10(foo), %o3
3014         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3015         add     %g7, %o2, %o4, %tie_add(foo)
3016         sethi   %tle_hix22(foo), %l1
3017         xor     %l1, %tle_lox10(foo), %o5
3018         ld      [%g7 + %o5], %o1"
3019         ;;
3020   xtensa*-*-*)
3021     conftest_s='
3022         .section ".tdata","awT",@progbits
3023 foo:    .long   25
3024         .text
3025         movi    a8, foo@TLSFUNC
3026         movi    a10, foo@TLSARG
3027         callx8.tls a8, foo@TLSCALL'
3028         tls_first_major=2
3029         tls_first_minor=19
3030         ;;
3031 changequote([,])dnl
3032 esac
3033 set_have_as_tls=no
3034 if test "x$enable_tls" = xno ; then
3035   : # TLS explicitly disabled.
3036 elif test "x$enable_tls" = xyes ; then
3037   set_have_as_tls=yes # TLS explicitly enabled.
3038 elif test -z "$tls_first_major"; then
3039   : # If we don't have a check, assume no support.
3040 else
3041   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3042   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3043   [set_have_as_tls=yes])
3044 fi
3045 case "$target" in
3046   *-*-irix6*)
3047     # IRIX 6.5 rld and libc.so lack TLS support, so even if gas and gld
3048     # with TLS support are in use, native TLS cannot work.
3049     set_have_as_tls=no
3050     ;;
3051   *-*-osf*)
3052     # Tru64 UNIX loader and libc.so lack TLS support, so even if gas and
3053     # gld with TLS support are in use, native TLS cannot work.
3054     set_have_as_tls=no
3055     ;;
3056   # TLS was introduced in the Solaris 9 FCS release and backported to
3057   # Solaris 8 patches.  Support for GNU-style TLS on x86 was only
3058   # introduced in Solaris 9 4/04, replacing the earlier Sun style that Sun
3059   # ld and GCC don't support any longer.
3060   *-*-solaris2.*)
3061     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3062     ld_tls_support=no
3063     # Check ld and ld.so.1 TLS support.
3064     if echo "$ld_ver" | grep GNU > /dev/null; then
3065       # Assume all interesting versions of GNU ld have TLS support.
3066       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3067       ld_tls_support=yes
3068     else
3069       case "$target" in
3070         # Solaris 8/x86 ld has GNU style TLS support since version 1.280.
3071         i?86-*-solaris2.8)
3072           min_tls_ld_vers_minor=280
3073           ;;
3074         # Solaris 8/SPARC ld has TLS support since version 1.272.
3075         sparc*-*-solaris2.8)
3076           min_tls_ld_vers_minor=272
3077           ;;
3078         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3079         i?86-*-solaris2.9)
3080           min_tls_ld_vers_minor=374
3081           ;;
3082         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3083         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3084           min_tls_ld_vers_minor=343
3085           ;;
3086       esac
3087       if test "$ld_vers_major" -gt 1 || \
3088         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3089         ld_tls_support=yes
3090       else
3091         set_have_as_tls=no
3092       fi
3093     fi
3094     AC_MSG_RESULT($ld_tls_support)
3095
3096     save_LIBS="$LIBS"
3097     save_LDFLAGS="$LDFLAGS"
3098     LIBS=
3099     LDFLAGS=
3100
3101     AC_MSG_CHECKING(alternate thread library)
3102     case "$target" in
3103       # TLS support was backported to Solaris 8 patches, but only lives in
3104       # the alternate thread library which became the default in Solaris 9.
3105       # We want to always use that, irrespective of TLS support.
3106       *-*-solaris2.8)
3107         # Take multilib subdir into account.  There's no spec to handle
3108         # this.  The 64 symlink exists since Solaris 8.
3109         lwp_dir=/usr/lib/lwp
3110         lwp_spec="-L$lwp_dir%{m64:/64} -R$lwp_dir%{m64:/64}"
3111         LDFLAGS="-L$lwp_dir -R$lwp_dir"
3112         ;;
3113       *-*-solaris2*)
3114         lwp_dir="none"
3115         lwp_spec=""
3116         ;;
3117     esac
3118     # Always define LIB_THREAD_LDFLAGS_SPEC, even without TLS support.
3119     AC_DEFINE_UNQUOTED(LIB_THREAD_LDFLAGS_SPEC, "$lwp_spec",
3120         [Define to the linker flags to use for -pthread.])
3121     AC_MSG_RESULT($lwp_dir)
3122
3123     AC_MSG_CHECKING(library containing $tga_func)
3124     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3125     # (32-bit x86) only lived in libthread, so check for that.  Keep
3126     # set_have_as_tls if found, disable if not.
3127     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3128     # Clear LIBS if we cannot support TLS.
3129     if test $set_have_as_tls = no; then
3130       LIBS=
3131     fi
3132     # Always define LIB_TLS_SPEC, even without TLS support.
3133     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3134         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3135     AC_MSG_RESULT($LIBS)
3136
3137     LIBS="$save_LIBS"
3138     LDFLAGS="$save_LDFLAGS"
3139     ;;
3140 esac
3141 if test $set_have_as_tls = yes ; then
3142   AC_DEFINE(HAVE_AS_TLS, 1,
3143             [Define if your assembler and linker support thread-local storage.])
3144 fi
3145
3146 # Target-specific assembler checks.
3147
3148 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3149 gcc_cv_ld_static_dynamic=no
3150 gcc_cv_ld_static_option='-Bstatic'
3151 gcc_cv_ld_dynamic_option='-Bdynamic'
3152 if test $in_tree_ld = yes ; then
3153   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3154     gcc_cv_ld_static_dynamic=yes
3155   fi
3156 elif test x$gcc_cv_ld != x; then
3157   # Check if linker supports -Bstatic/-Bdynamic option
3158   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3159      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3160       gcc_cv_ld_static_dynamic=yes
3161   else
3162     case "$target" in
3163       # Tru64 UNIX support -noso/-so_archive instead of -Bstatic/-Bdynamic.
3164       alpha*-dec-osf*)
3165         gcc_cv_ld_static_dynamic=yes
3166         gcc_cv_ld_static_option="-noso"
3167         gcc_cv_ld_dynamic_option="-so_archive"
3168         ;;
3169       # IRIX 6 ld supports -Bstatic/-Bdynamic.
3170       mips-sgi-irix6*)
3171         gcc_cv_ld_static_dynamic=yes
3172         ;;
3173       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3174       *-*-solaris2*)
3175         gcc_cv_ld_static_dynamic=yes
3176         ;;
3177     esac
3178   fi
3179 fi
3180 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3181         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3182 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3183         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3184 [Define to the linker option to disable use of shared objects.])
3185         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3186 [Define to the linker option to enable use of shared objects.])
3187 fi
3188 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3189
3190 if test x"$demangler_in_ld" = xyes; then
3191   AC_MSG_CHECKING(linker --demangle support)
3192   gcc_cv_ld_demangle=no
3193   if test $in_tree_ld = yes; then
3194     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3195       gcc_cv_ld_demangle=yes
3196     fi
3197   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3198     # Check if the GNU linker supports --demangle option
3199     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3200       gcc_cv_ld_demangle=yes
3201     fi
3202   fi
3203   if test x"$gcc_cv_ld_demangle" = xyes; then
3204     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3205 [Define if your linker supports --demangle option.])
3206   fi
3207   AC_MSG_RESULT($gcc_cv_ld_demangle)
3208 fi
3209
3210 AC_MSG_CHECKING(linker plugin support)
3211 gcc_cv_lto_plugin=0
3212 if test -f liblto_plugin.la; then
3213   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3214     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
3215       gcc_cv_lto_plugin=2
3216     elif test "$ld_is_gold" = yes -a "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -eq 20; then
3217       gcc_cv_lto_plugin=1
3218
3219     fi
3220   elif test x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld" && echo "$ld_ver" | grep GNU > /dev/null; then
3221     # Require GNU ld or gold 2.21+ for plugin support by default.
3222     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3223       gcc_cv_lto_plugin=2
3224     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3225     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3226       gcc_cv_lto_plugin=1
3227     fi
3228   elif test x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" != x"$gcc_cv_ld"; then
3229     # Allow -fuse-linker-plugin if plugin linker differs from
3230     # default/specified linker.
3231     gcc_cv_lto_plugin=1
3232   fi
3233 fi
3234 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3235   [Define to the level of your linker's plugin support.])
3236 AC_MSG_RESULT($gcc_cv_lto_plugin)
3237
3238 case "$target" in
3239   # All TARGET_ABI_OSF targets.
3240   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3241     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3242         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3243 [       .set nomacro
3244         .text
3245         extbl   $3, $2, $3      !lituse_bytoff!1
3246         ldq     $2, a($29)      !literal!1
3247         ldq     $4, b($29)      !literal!2
3248         ldq_u   $3, 0($2)       !lituse_base!1
3249         ldq     $27, f($29)     !literal!5
3250         jsr     $26, ($27), f   !lituse_jsr!5
3251         ldah    $29, 0($26)     !gpdisp!3
3252         lda     $0, c($29)      !gprel
3253         ldah    $1, d($29)      !gprelhigh
3254         lda     $1, d($1)       !gprellow
3255         lda     $29, 0($29)     !gpdisp!3],,
3256     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3257   [Define if your assembler supports explicit relocations.])])
3258     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3259         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3260 [       .set nomacro
3261         .text
3262         ldq     $27, a($29)     !literal!1
3263         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3264     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3265   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3266     ;;
3267
3268   cris-*-*)
3269     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3270       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3271       [-no-mul-bug-abort], [.text],,
3272       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3273                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3274     ;;
3275
3276   sparc*-*-*)
3277     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3278       [.register %g2, #scratch],,
3279       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3280                 [Define if your assembler supports .register.])])
3281
3282     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3283       [-relax], [.text],,
3284       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3285                 [Define if your assembler supports -relax option.])])
3286
3287     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3288       gcc_cv_as_sparc_gotdata_op,,
3289       [-K PIC],
3290 [.text
3291 .align 4
3292 foo:
3293         nop
3294 bar:
3295         sethi %gdop_hix22(foo), %g1
3296         xor    %g1, %gdop_lox10(foo), %g1
3297         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3298       [if test x$gcc_cv_ld != x \
3299        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3300          if test x$gcc_cv_objdump != x; then
3301            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3302               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3303                gcc_cv_as_sparc_gotdata_op=no
3304            else
3305                gcc_cv_as_sparc_gotdata_op=yes
3306            fi
3307          fi
3308        fi
3309        rm -f conftest],
3310       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3311                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3312
3313     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3314       gcc_cv_as_sparc_ua_pcrel,,
3315       [-K PIC],
3316 [.text
3317 foo:
3318         nop
3319 .data
3320 .align 4
3321 .byte 0
3322 .uaword %r_disp32(foo)],
3323       [if test x$gcc_cv_ld != x \
3324        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3325          gcc_cv_as_sparc_ua_pcrel=yes
3326        fi
3327        rm -f conftest],
3328       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3329                 [Define if your assembler and linker support unaligned PC relative relocs.])
3330
3331       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3332         gcc_cv_as_sparc_ua_pcrel_hidden,,
3333         [-K PIC],
3334 [.data
3335 .align 4
3336 .byte 0x31
3337 .uaword %r_disp32(foo)
3338 .byte 0x32, 0x33, 0x34
3339 .global foo
3340 .hidden foo
3341 foo:
3342 .skip 4],
3343         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3344          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3345          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3346             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3347             if $gcc_cv_objdump -R conftest 2> /dev/null \
3348                | grep 'DISP32' > /dev/null 2>&1; then
3349                 :
3350             else
3351                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3352             fi
3353          fi
3354          rm -f conftest],
3355          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3356                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3357     ]) # unaligned pcrel relocs
3358
3359     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3360       gcc_cv_as_sparc_offsetable_lo10,,
3361       [-xarch=v9],
3362 [.text
3363         or %g1, %lo(ab) + 12, %g1
3364         or %g1, %lo(ab + 12), %g1],
3365       [if test x$gcc_cv_objdump != x \
3366        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3367           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3368          gcc_cv_as_sparc_offsetable_lo10=yes
3369        fi],
3370        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3371                  [Define if your assembler supports offsetable %lo().])])
3372     ;;
3373
3374 changequote(,)dnl
3375   i[34567]86-*-* | x86_64-*-*)
3376 changequote([,])dnl
3377     case $target_os in
3378       cygwin*)
3379         # Full C++ conformance when using a shared libstdc++-v3 requires some
3380         # support from the Cygwin DLL, which in more recent versions exports
3381         # wrappers to aid in interposing and redirecting operators new, delete,
3382         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3383         # are configuring for a version of Cygwin that exports the wrappers.
3384         if test x$host = x$target; then
3385           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3386         else
3387           # Can't check presence of libc functions during cross-compile, so
3388           # we just have to assume we're building for an up-to-date target.
3389           gcc_ac_cygwin_dll_wrappers=yes
3390         fi
3391         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3392           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3393           [Define if you want to generate code by default that assumes that the
3394            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3395     esac
3396     case $target_os in
3397       cygwin* | pe | mingw32*)
3398         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3399         # definition is used unconditionally to initialise the default state of
3400         # the target option variable that governs usage of the feature.
3401         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3402          [2,19,52],,[.comm foo,1,32])
3403         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3404           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3405           [Define if your assembler supports specifying the alignment
3406            of objects allocated using the GAS .comm command.])
3407         # Used for DWARF 2 in PE
3408         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3409           gcc_cv_as_ix86_pe_secrel32,
3410           [2,15,91],,
3411 [.text
3412 foo:    nop
3413 .data
3414         .secrel32 foo],
3415           [if test x$gcc_cv_ld != x \
3416            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3417              gcc_cv_as_ix86_pe_secrel32=yes
3418            fi
3419            rm -f conftest],
3420           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3421             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3422         # Test if the assembler supports the extended form of the .section
3423         # directive that specifies section alignment.  LTO support uses this,
3424         # but normally only after installation, so we warn but don't fail the
3425         # configure if LTO is enabled but the assembler does not support it.
3426         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3427           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3428         if test x$gcc_cv_as_section_has_align != xyes; then
3429           case ",$enable_languages," in
3430             *,lto,*)
3431               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3432               ;;
3433           esac
3434         fi
3435         ;;
3436     esac
3437
3438     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3439        gcc_cv_as_ix86_filds,,,
3440        [filds mem; fists mem],,
3441        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3442          [Define if your assembler uses filds and fists mnemonics.])])
3443
3444     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3445        gcc_cv_as_ix86_fildq,,,
3446        [fildq mem; fistpq mem],,
3447        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3448          [Define if your assembler uses fildq and fistq mnemonics.])])
3449
3450     gcc_GAS_CHECK_FEATURE([cmov syntax],
3451       gcc_cv_as_ix86_cmov_sun_syntax,,,
3452       [cmovl.l %edx, %eax],,
3453       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3454         [Define if your assembler supports the Sun syntax for cmov.])])
3455
3456     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3457       gcc_cv_as_ix86_ffreep,,,
3458       [ffreep %st(1)],,
3459       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3460         [Define if your assembler supports the ffreep mnemonic.])])
3461
3462     gcc_GAS_CHECK_FEATURE([.quad directive],
3463       gcc_cv_as_ix86_quad,,,
3464       [.quad 0],,
3465       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3466         [Define if your assembler supports the .quad directive.])])
3467
3468     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3469       gcc_cv_as_ix86_sahf,,,
3470       [.code64
3471        sahf],,
3472       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3473         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3474
3475     gcc_GAS_CHECK_FEATURE([swap suffix],
3476       gcc_cv_as_ix86_swap,,,
3477       [movl.s %esp, %ebp],,
3478       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3479         [Define if your assembler supports the swap suffix.])])
3480
3481     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3482       gcc_cv_as_ix86_diff_sect_delta,,,
3483       [.section .rodata
3484 .L1:
3485         .long .L2-.L1
3486         .long .L3-.L1
3487         .text
3488 .L3:    nop
3489 .L2:    nop],,
3490       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3491         [Define if your assembler supports the subtraction of symbols in different sections.])])
3492
3493     # These two are used unconditionally by i386.[ch]; it is to be defined
3494     # to 1 if the feature is present, 0 otherwise.
3495     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3496         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3497 [       .text
3498 .L0:
3499         nop
3500         .data
3501         .long .L0@GOTOFF])
3502     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3503       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3504       [Define true if the assembler supports '.long foo@GOTOFF'.])
3505
3506     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3507         gcc_cv_as_ix86_rep_lock_prefix,,,
3508         [rep movsl
3509          lock addl %edi, (%eax,%esi)
3510          lock orl $0, (%esp)],,
3511         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3512           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3513
3514     ;;
3515
3516   ia64*-*-*)
3517     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3518         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3519 [       .text
3520         addl r15 = @ltoffx(x#), gp
3521         ;;
3522         ld8.mov r16 = [[r15]], x#],,
3523     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3524           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3525
3526     ;;
3527
3528   powerpc*-*-*)
3529     case $target in
3530       *-*-aix*) conftest_s='    .machine "pwr5"
3531         .csect .text[[PR]]
3532         mfcr 3,128';;
3533       *-*-darwin*)
3534         gcc_GAS_CHECK_FEATURE([.machine directive support],
3535           gcc_cv_as_machine_directive,,,
3536           [     .machine ppc7400])
3537         if test x$gcc_cv_as_machine_directive != xyes; then
3538           echo "*** This target requires an assembler supporting \".machine\"" >&2
3539           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3540           test x$build = x$target && exit 1
3541         fi
3542         conftest_s='    .text
3543         mfcr r3,128';;
3544       *) conftest_s='   .machine power4
3545         .text
3546         mfcr 3,128';;
3547     esac
3548
3549     gcc_GAS_CHECK_FEATURE([mfcr field support],
3550       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3551       [$conftest_s],,
3552       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3553           [Define if your assembler supports mfcr field.])])
3554
3555     case $target in
3556       *-*-aix*) conftest_s='    .machine "pwr5"
3557         .csect .text[[PR]]
3558         popcntb 3,3';;
3559       *) conftest_s='   .machine power5
3560         .text
3561         popcntb 3,3';;
3562     esac
3563
3564     gcc_GAS_CHECK_FEATURE([popcntb support],
3565       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3566       [$conftest_s],,
3567       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3568           [Define if your assembler supports popcntb field.])])
3569
3570     case $target in
3571       *-*-aix*) conftest_s='    .machine "pwr5x"
3572         .csect .text[[PR]]
3573         frin 1,1';;
3574       *) conftest_s='   .machine power5
3575         .text
3576         frin 1,1';;
3577     esac
3578
3579     gcc_GAS_CHECK_FEATURE([fp round support],
3580       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3581       [$conftest_s],,
3582       [AC_DEFINE(HAVE_AS_FPRND, 1,
3583           [Define if your assembler supports fprnd.])])
3584
3585     case $target in
3586       *-*-aix*) conftest_s='    .machine "pwr6"
3587         .csect .text[[PR]]
3588         mffgpr 1,3';;
3589       *) conftest_s='   .machine power6
3590         .text
3591         mffgpr 1,3';;
3592     esac
3593
3594     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3595       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3596       [$conftest_s],,
3597       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3598           [Define if your assembler supports mffgpr and mftgpr.])])
3599
3600     case $target in
3601       *-*-aix*) conftest_s='    .csect .text[[PR]]
3602 LCF..0:
3603         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3604       *-*-darwin*)
3605         conftest_s='    .text
3606 LCF0:
3607         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3608       *) conftest_s='   .text
3609 .LCF0:
3610         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3611     esac
3612
3613     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3614       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3615       [$conftest_s],,
3616       [AC_DEFINE(HAVE_AS_REL16, 1,
3617           [Define if your assembler supports R_PPC_REL16 relocs.])])
3618
3619     case $target in
3620       *-*-aix*) conftest_s='    .machine "pwr6"
3621         .csect .text[[PR]]
3622         cmpb 3,4,5';;
3623       *) conftest_s='   .machine power6
3624         .text
3625         cmpb 3,4,5';;
3626     esac
3627
3628     gcc_GAS_CHECK_FEATURE([compare bytes support],
3629       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3630       [$conftest_s],,
3631       [AC_DEFINE(HAVE_AS_CMPB, 1,
3632           [Define if your assembler supports cmpb.])])
3633
3634     case $target in
3635       *-*-aix*) conftest_s='    .machine "pwr6"
3636         .csect .text[[PR]]
3637         dadd 1,2,3';;
3638       *) conftest_s='   .machine power6
3639         .text
3640         dadd 1,2,3';;
3641     esac
3642
3643     gcc_GAS_CHECK_FEATURE([decimal float support],
3644       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3645       [$conftest_s],,
3646       [AC_DEFINE(HAVE_AS_DFP, 1,
3647           [Define if your assembler supports DFP instructions.])])
3648
3649     case $target in
3650       *-*-aix*) conftest_s='    .machine "pwr7"
3651         .csect .text[[PR]]
3652         lxvd2x 1,2,3';;
3653       *) conftest_s='   .machine power7
3654         .text
3655         lxvd2x 1,2,3';;
3656     esac
3657
3658     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3659       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3660       [$conftest_s],,
3661       [AC_DEFINE(HAVE_AS_VSX, 1,
3662           [Define if your assembler supports VSX instructions.])])
3663
3664     case $target in
3665       *-*-aix*) conftest_s='    .machine "pwr7"
3666         .csect .text[[PR]]
3667         popcntd 3,3';;
3668       *) conftest_s='   .machine power7
3669         .text
3670         popcntd 3,3';;
3671     esac
3672
3673     gcc_GAS_CHECK_FEATURE([popcntd support],
3674       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3675       [$conftest_s],,
3676       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3677           [Define if your assembler supports POPCNTD instructions.])])
3678
3679     case $target in
3680       *-*-aix*) conftest_s='    .csect .text[[PR]]
3681         lwsync';;
3682       *) conftest_s='   .text
3683         lwsync';;
3684     esac
3685
3686     gcc_GAS_CHECK_FEATURE([lwsync support],
3687       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3688       [$conftest_s],,
3689       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3690           [Define if your assembler supports LWSYNC instructions.])])
3691
3692     case $target in
3693       *-*-aix*) conftest_s='    .machine "476"
3694         .csect .text[[PR]]
3695         dci 0';;
3696       *) conftest_s='   .machine "476"
3697         .text
3698         dci 0';;
3699     esac
3700
3701     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3702       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3703       [$conftest_s],,
3704       [AC_DEFINE(HAVE_AS_DCI, 1,
3705           [Define if your assembler supports the DCI/ICI instructions.])])
3706
3707     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3708       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3709       [.gnu_attribute 4,1],,
3710       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3711           [Define if your assembler supports .gnu_attribute.])])
3712
3713     gcc_GAS_CHECK_FEATURE([tls marker support],
3714       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3715       [ bl __tls_get_addr(x@tlsgd)],,
3716       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3717           [Define if your assembler supports arg info for __tls_get_addr.])])
3718
3719     case $target in
3720       *-*-aix*)
3721         gcc_GAS_CHECK_FEATURE([.ref support],
3722           gcc_cv_as_aix_ref, [2.21.0],,
3723           [     .csect stuff[[rw]]
3724              stuff:
3725                 .long 1
3726                 .extern sym
3727                 .ref sym
3728           ],,
3729           [AC_DEFINE(HAVE_AS_REF, 1,
3730             [Define if your assembler supports .ref])])
3731         ;;
3732     esac
3733     ;;
3734
3735   mips*-*-*)
3736     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3737       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3738 [       lw $4,%gp_rel(foo)($4)],,
3739       [if test x$target_cpu_default = x
3740        then target_cpu_default=MASK_EXPLICIT_RELOCS
3741        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3742        fi])
3743     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3744       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3745       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3746                  [Define if the assembler understands -mno-shared.])])
3747
3748     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3749       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3750       [.gnu_attribute 4,1],,
3751       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3752           [Define if your assembler supports .gnu_attribute.])])
3753
3754     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3755       gcc_cv_as_mips_dtprelword, [2,18,0],,
3756       [.section .tdata,"awT",@progbits
3757 x:
3758         .word 2
3759         .text
3760         .dtprelword x+0x8000],,
3761       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3762           [Define if your assembler supports .dtprelword.])])
3763
3764     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
3765       gcc_cv_as_mips_dspr1_mult,,,
3766 [       .set    mips32r2
3767         .set    nodspr2
3768         .set    dsp
3769         madd    $ac3,$4,$5
3770         maddu   $ac3,$4,$5
3771         msub    $ac3,$4,$5
3772         msubu   $ac3,$4,$5
3773         mult    $ac3,$4,$5
3774         multu   $ac3,$4,$5],,
3775       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
3776           [Define if your assembler supports DSPR1 mult.])])
3777
3778     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3779     gcc_cv_as_ld_jalr_reloc=no
3780     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3781       if test $in_tree_ld = yes ; then
3782         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3783            && test $in_tree_ld_is_elf = yes; then
3784           gcc_cv_as_ld_jalr_reloc=yes
3785         fi
3786       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3787         echo '  .ent x' > conftest.s
3788         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3789         echo '  ld $25,%call16(y)($28)' >> conftest.s
3790         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3791         echo '1:        jalr $25' >> conftest.s
3792         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3793         echo '1:        jalr $25' >> conftest.s
3794         echo '  .end x' >> conftest.s
3795         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3796            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3797           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3798              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3799             gcc_cv_as_ld_jalr_reloc=yes
3800           fi
3801         fi
3802         rm -f conftest.*
3803       fi
3804     fi
3805     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3806       if test x$target_cpu_default = x; then
3807         target_cpu_default=MASK_RELAX_PIC_CALLS
3808       else
3809         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3810       fi
3811     fi
3812     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3813
3814     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3815       [gcc_cv_ld_mips_personality_relaxation],
3816       [gcc_cv_ld_mips_personality_relaxation=no
3817        if test $in_tree_ld = yes ; then
3818          if test "$gcc_cv_gld_major_version" -eq 2 \
3819                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3820                  -o "$gcc_cv_gld_major_version" -gt 2; then
3821            gcc_cv_ld_mips_personality_relaxation=yes
3822          fi
3823        elif test x$gcc_cv_as != x \
3824                  -a x$gcc_cv_ld != x \
3825                  -a x$gcc_cv_readelf != x ; then
3826          cat > conftest.s <<EOF
3827         .cfi_startproc
3828         .cfi_personality 0x80,indirect_ptr
3829         .ent test
3830 test:
3831         nop
3832         .end test
3833         .cfi_endproc
3834
3835         .section .data,"aw",@progbits
3836 indirect_ptr:
3837         .dc.a personality
3838 EOF
3839          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3840             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3841            if $gcc_cv_readelf -d conftest 2>&1 \
3842               | grep TEXTREL > /dev/null 2>&1; then
3843              :
3844            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3845                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3846              :
3847            else
3848              gcc_cv_ld_mips_personality_relaxation=yes
3849            fi
3850          fi
3851        fi
3852        rm -f conftest.s conftest.o conftest])
3853     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3854             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3855       [Define if your linker can relax absolute .eh_frame personality
3856 pointers into PC-relative form.])
3857     fi
3858     ;;
3859 esac
3860
3861 # Mips and HP-UX need the GNU assembler.
3862 # Linux on IA64 might be able to use the Intel assembler.
3863
3864 case "$target" in
3865   mips*-*-* | *-*-hpux* )
3866     if test x$gas_flag = xyes \
3867        || test x"$host" != x"$build" \
3868        || test ! -x "$gcc_cv_as" \
3869        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3870       :
3871     else
3872       echo "*** This configuration requires the GNU assembler" >&2
3873       exit 1
3874     fi
3875     ;;
3876 esac
3877
3878 # ??? Not all targets support dwarf2 debug_line, even within a version
3879 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3880 # info to the output file.  So, as supported targets are added to gas 2.11,
3881 # add some instruction here to (also) show we expect this might work.
3882 # ??? Once 2.11 is released, probably need to add first known working
3883 # version to the per-target configury.
3884 case "$cpu_type" in
3885   alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze | mips \
3886   | pa | rs6000 | score | sparc | spu | xstormy16 | xtensa)
3887     insn="nop"
3888     ;;
3889   ia64 | s390)
3890     insn="nop 0"
3891     ;;
3892   mmix)
3893     insn="swym 0"
3894     ;;
3895 esac
3896 if test x"$insn" != x; then
3897  conftest_s="\
3898         .file 1 \"conftest.s\"
3899         .loc 1 3 0
3900         $insn"
3901  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3902   gcc_cv_as_dwarf2_debug_line,
3903   [elf,2,11,0],, [$conftest_s],
3904   [if test x$gcc_cv_objdump != x \
3905    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3906       | grep debug_line > /dev/null 2>&1; then
3907      gcc_cv_as_dwarf2_debug_line=yes
3908    fi])
3909
3910 # The .debug_line file table must be in the exact order that
3911 # we specified the files, since these indices are also used
3912 # by DW_AT_decl_file.  Approximate this test by testing if
3913 # the assembler bitches if the same index is assigned twice.
3914  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3915   gcc_cv_as_dwarf2_file_buggy,,,
3916 [       .file 1 "foo.s"
3917         .file 1 "bar.s"])
3918
3919  if test $gcc_cv_as_dwarf2_debug_line = yes \
3920  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3921         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3922   [Define if your assembler supports dwarf2 .file/.loc directives,
3923    and preserves file table indices exactly as given.])
3924  fi
3925
3926  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3927   gcc_cv_as_gdwarf2_flag,
3928   [elf,2,11,0], [--gdwarf2], [$insn],,
3929   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3930 [Define if your assembler supports the --gdwarf2 option.])])
3931
3932  gcc_GAS_CHECK_FEATURE([--gstabs option],
3933   gcc_cv_as_gstabs_flag,
3934   [elf,2,11,0], [--gstabs], [$insn],
3935   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3936    # and warns about it, but still exits successfully.  So check for
3937    # this.
3938    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3939    then :
3940    else gcc_cv_as_gstabs_flag=yes
3941    fi],
3942   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3943 [Define if your assembler supports the --gstabs option.])])
3944
3945  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3946   gcc_cv_as_debug_prefix_map_flag,
3947   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3948   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3949 [Define if your assembler supports the --debug-prefix-map option.])])
3950 fi
3951
3952 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3953  ,,
3954 [.lcomm bar,4,16],,
3955 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3956   [Define if your assembler supports .lcomm with an alignment field.])])
3957
3958 AC_ARG_ENABLE(gnu-unique-object,
3959  [AS_HELP_STRING([--enable-gnu-unique-object],
3960    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
3961  [case $enable_gnu_unique_object in
3962     yes | no) ;;
3963     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3964 Valid choices are 'yes' and 'no'.]) ;;
3965   esac],
3966  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3967    [elf,2,19,52],,
3968    [.type foo, @gnu_unique_object],,
3969 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3970    [[if test x$host = x$build -a x$host = x$target &&
3971        ldd --version 2>/dev/null &&
3972        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
3973       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
3974       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
3975       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3976       if test "$glibcnum" -ge 2011 ; then
3977         enable_gnu_unique_object=yes
3978       fi
3979     fi]])])
3980 if test x$enable_gnu_unique_object = xyes; then
3981   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3982    [Define if your assembler supports @gnu_unique_object.])
3983 fi
3984
3985 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3986  [gcc_cv_as_line_zero],
3987  [gcc_cv_as_line_zero=no
3988   if test $in_tree_gas = yes; then
3989     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3990   elif test "x$gcc_cv_as" != x; then
3991     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3992     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3993        test "x`cat conftest.out`" = x
3994     then
3995       gcc_cv_as_line_zero=yes
3996     else
3997       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3998       cat conftest.s >&AS_MESSAGE_LOG_FD
3999       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4000       cat conftest.out >&AS_MESSAGE_LOG_FD
4001     fi
4002     rm -f conftest.o conftest.s conftest.out
4003   fi])
4004 if test "x$gcc_cv_as_line_zero" = xyes; then
4005   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4006 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4007 fi
4008
4009 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4010 gcc_cv_ld_eh_frame_hdr=no
4011 if test $in_tree_ld = yes ; then
4012   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4013      && test $in_tree_ld_is_elf = yes; then
4014     gcc_cv_ld_eh_frame_hdr=yes
4015   fi
4016 elif test x$gcc_cv_ld != x; then
4017   if echo "$ld_ver" | grep GNU > /dev/null; then
4018     # Check if linker supports --eh-frame-hdr option
4019     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4020       gcc_cv_ld_eh_frame_hdr=yes
4021     fi
4022   else
4023     case "$target" in
4024       *-*-solaris2*)
4025         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4026         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4027           gcc_cv_ld_eh_frame_hdr=yes
4028         fi
4029         ;;
4030     esac
4031   fi
4032 fi
4033 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4034 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4035         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4036 [Define if your linker supports .eh_frame_hdr.])
4037 fi
4038 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4039
4040 AC_MSG_CHECKING(linker position independent executable support)
4041 gcc_cv_ld_pie=no
4042 if test $in_tree_ld = yes ; then
4043   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
4044      && test $in_tree_ld_is_elf = yes; then
4045     gcc_cv_ld_pie=yes
4046   fi
4047 elif test x$gcc_cv_ld != x; then
4048         # Check if linker supports -pie option
4049         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4050                 gcc_cv_ld_pie=yes
4051         fi
4052 fi
4053 if test x"$gcc_cv_ld_pie" = xyes; then
4054         AC_DEFINE(HAVE_LD_PIE, 1,
4055 [Define if your linker supports -pie option.])
4056 fi
4057 AC_MSG_RESULT($gcc_cv_ld_pie)
4058
4059 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
4060 gcc_cv_ld_eh_gc_sections=no
4061 if test $in_tree_ld = yes ; then
4062   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
4063      && test $in_tree_ld_is_elf = yes; then
4064     gcc_cv_ld_eh_gc_sections=yes
4065   fi
4066 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
4067   cat > conftest.s <<EOF
4068         .section        .text
4069 .globl _start
4070         .type _start, @function
4071 _start:
4072         .long foo
4073         .size _start, .-_start
4074         .section        .text.foo,"ax",@progbits
4075         .type foo, @function
4076 foo:
4077         .long 0
4078         .size foo, .-foo
4079         .section        .gcc_except_table.foo,"a",@progbits
4080 .L0:
4081         .long 0
4082         .section        .eh_frame,"a",@progbits
4083         .long .L0
4084 EOF
4085   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4086     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4087          | grep "gc-sections option ignored" > /dev/null; then
4088       gcc_cv_ld_eh_gc_sections=no
4089     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4090          | grep gcc_except_table > /dev/null; then
4091       gcc_cv_ld_eh_gc_sections=yes
4092       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
4093       if test x$gcc_cv_as_comdat_group != xyes; then
4094         gcc_cv_ld_eh_gc_sections=no
4095         cat > conftest.s <<EOF
4096         .section        .text
4097 .globl _start
4098         .type _start, @function
4099 _start:
4100         .long foo
4101         .size _start, .-_start
4102         .section        .gnu.linkonce.t.foo,"ax",@progbits
4103         .type foo, @function
4104 foo:
4105         .long 0
4106         .size foo, .-foo
4107         .section        .gcc_except_table.foo,"a",@progbits
4108 .L0:
4109         .long 0
4110         .section        .eh_frame,"a",@progbits
4111         .long .L0
4112 EOF
4113         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4114           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4115                | grep "gc-sections option ignored" > /dev/null; then
4116             gcc_cv_ld_eh_gc_sections=no
4117           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4118                | grep gcc_except_table > /dev/null; then
4119             gcc_cv_ld_eh_gc_sections=yes
4120           fi
4121         fi
4122       fi
4123     fi
4124   fi
4125   rm -f conftest.s conftest.o conftest
4126 fi
4127 case "$target" in
4128   hppa*-*-linux*)
4129     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4130     gcc_cv_ld_eh_gc_sections=no
4131     ;;
4132 esac
4133 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4134         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4135   [Define if your linker supports garbage collection of
4136    sections in presence of EH frames.])
4137 fi
4138 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4139
4140 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
4141 gcc_cv_ld_eh_gc_sections_bug=no
4142 if test $in_tree_ld = yes ; then
4143   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
4144      && test $in_tree_ld_is_elf = yes; then
4145     gcc_cv_ld_eh_gc_sections_bug=yes
4146   fi
4147 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
4148   gcc_cv_ld_eh_gc_sections_bug=yes
4149   cat > conftest.s <<EOF
4150         .section        .text
4151 .globl _start
4152         .type _start, @function
4153 _start:
4154         .long foo
4155         .size _start, .-_start
4156         .section        .text.startup.foo,"ax",@progbits
4157         .type foo, @function
4158 foo:
4159         .long 0
4160         .size foo, .-foo
4161         .section        .gcc_except_table.foo,"a",@progbits
4162 .L0:
4163         .long 0
4164         .section        .eh_frame,"a",@progbits
4165         .long .L0
4166 EOF
4167   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4168     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4169          | grep "gc-sections option ignored" > /dev/null; then
4170       :
4171     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4172          | grep gcc_except_table > /dev/null; then
4173       gcc_cv_ld_eh_gc_sections_bug=no
4174     fi
4175   fi
4176   rm -f conftest.s conftest.o conftest
4177 fi
4178 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
4179         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
4180   [Define if your linker has buggy garbage collection of
4181    sections support when .text.startup.foo like sections are used.])
4182 fi
4183 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
4184
4185 # --------
4186 # UNSORTED
4187 # --------
4188
4189 AC_CACHE_CHECK(linker --as-needed support,
4190 gcc_cv_ld_as_needed,
4191 [gcc_cv_ld_as_needed=no
4192 if test $in_tree_ld = yes ; then
4193   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4194      && test $in_tree_ld_is_elf = yes; then
4195     gcc_cv_ld_as_needed=yes
4196   fi
4197 elif test x$gcc_cv_ld != x; then
4198         # Check if linker supports --as-needed and --no-as-needed options
4199         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
4200                 gcc_cv_ld_as_needed=yes
4201         fi
4202 fi
4203 ])
4204 if test x"$gcc_cv_ld_as_needed" = xyes; then
4205         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
4206 [Define if your linker supports --as-needed and --no-as-needed options.])
4207 fi
4208
4209 case "$target:$tm_file" in
4210   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
4211     AC_CACHE_CHECK(linker support for omitting dot symbols,
4212     gcc_cv_ld_no_dot_syms,
4213     [gcc_cv_ld_no_dot_syms=no
4214     if test $in_tree_ld = yes ; then
4215       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
4216         gcc_cv_ld_no_dot_syms=yes
4217       fi
4218     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4219       cat > conftest1.s <<EOF
4220         .text
4221         bl .foo
4222 EOF
4223       cat > conftest2.s <<EOF
4224         .section ".opd","aw"
4225         .align 3
4226         .globl foo
4227         .type foo,@function
4228 foo:
4229         .quad .LEfoo,.TOC.@tocbase,0
4230         .text
4231 .LEfoo:
4232         blr
4233         .size foo,.-.LEfoo
4234 EOF
4235       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
4236          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
4237          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
4238         gcc_cv_ld_no_dot_syms=yes
4239       fi
4240       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
4241     fi
4242     ])
4243     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
4244       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
4245     [Define if your PowerPC64 linker only needs function descriptor syms.])
4246     fi
4247
4248     AC_CACHE_CHECK(linker large toc support,
4249     gcc_cv_ld_large_toc,
4250     [gcc_cv_ld_large_toc=no
4251     if test $in_tree_ld = yes ; then
4252       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
4253         gcc_cv_ld_large_toc=yes
4254       fi
4255     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
4256       cat > conftest.s <<EOF
4257         .section ".tbss","awT",@nobits
4258         .align 3
4259 ie0:    .space 8
4260         .global _start
4261         .text
4262 _start:
4263         addis 9,13,ie0@got@tprel@ha
4264         ld 9,ie0@got@tprel@l(9)
4265 EOF
4266       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
4267          && $gcc_cv_ld -melf64ppc --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
4268         gcc_cv_ld_large_toc=yes
4269       fi
4270       rm -f conftest conftest.o conftest.s
4271     fi
4272     ])
4273     if test x"$gcc_cv_ld_large_toc" = xyes; then
4274       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
4275     [Define if your PowerPC64 linker supports a large TOC.])
4276     fi
4277     ;;
4278 esac
4279
4280 AC_CACHE_CHECK(linker --build-id support,
4281   gcc_cv_ld_buildid,
4282   [gcc_cv_ld_buildid=no
4283   if test $in_tree_ld = yes ; then
4284     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4285        "$gcc_cv_gld_minor_version" -ge 18 -o \
4286        "$gcc_cv_gld_major_version" -gt 2 \
4287        && test $in_tree_ld_is_elf = yes; then
4288       gcc_cv_ld_buildid=yes
4289     fi
4290   elif test x$gcc_cv_ld != x; then
4291     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
4292       gcc_cv_ld_buildid=yes
4293     fi
4294   fi])
4295 if test x"$gcc_cv_ld_buildid" = xyes; then
4296   AC_DEFINE(HAVE_LD_BUILDID, 1,
4297   [Define if your linker supports --build-id.])
4298 fi
4299
4300 AC_ARG_ENABLE(linker-build-id,
4301 [AS_HELP_STRING([--enable-linker-build-id],
4302                 [compiler will always pass --build-id to linker])],
4303 [],
4304 enable_linker_build_id=no)
4305
4306 if test x"$enable_linker_build_id" = xyes; then
4307   if test x"$gcc_cv_ld_buildid" = xyes; then
4308     AC_DEFINE(ENABLE_LD_BUILDID, 1,
4309     [Define if gcc should always pass --build-id to linker.])
4310   else
4311     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
4312   fi
4313 fi
4314
4315 # In binutils 2.21, GNU ld gained support for new emulations fully
4316 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
4317 AC_CACHE_CHECK(linker *_sol2 emulation support,
4318   gcc_cv_ld_sol2_emulation,
4319   [gcc_cv_ld_sol2_emulation=no
4320   if test $in_tree_ld = yes ; then
4321     if test "$gcc_cv_gld_major_version" -eq 2 -a \
4322        "$gcc_cv_gld_minor_version" -ge 21 -o \
4323        "$gcc_cv_gld_major_version" -gt 2 \
4324        && test $in_tree_ld_is_elf = yes; then
4325       gcc_cv_ld_sol2_emulation=yes
4326     fi
4327   elif test x$gcc_cv_ld != x; then
4328     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
4329        grep _sol2 > /dev/null; then
4330       gcc_cv_ld_sol2_emulation=yes
4331     fi
4332   fi])
4333 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
4334   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
4335   [Define if your linker supports the *_sol2 emulations.])
4336 fi
4337
4338 AC_CACHE_CHECK(linker --sysroot support,
4339   gcc_cv_ld_sysroot,
4340   [gcc_cv_ld_sysroot=no
4341   if test $in_tree_ld = yes ; then
4342       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
4343         gcc_cv_ld_sysroot=yes
4344       fi
4345   elif test x$gcc_cv_ld != x; then
4346     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
4347       gcc_cv_ld_sysroot=yes
4348     fi
4349   fi])
4350 if test x"$gcc_cv_ld_sysroot" = xyes; then
4351   AC_DEFINE(HAVE_LD_SYSROOT, 1,
4352   [Define if your linker supports --sysroot.])
4353 fi
4354
4355 if test x$with_sysroot = x && test x$host = x$target \
4356    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4357    && test "$prefix" != "NONE"; then
4358   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4359 [Define to PREFIX/include if cpp should also search that directory.])
4360 fi
4361
4362 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
4363   if test "x$with_headers" != x; then
4364     target_header_dir=$with_headers
4365   elif test "x$with_sysroot" = x; then
4366     target_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
4367   elif test "x$with_build_sysroot" != "x"; then
4368     target_header_dir="${with_build_sysroot}/usr/include"
4369   elif test "x$with_sysroot" = xyes; then
4370     target_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
4371   else
4372     target_header_dir="${with_sysroot}/usr/include"
4373   fi
4374 else
4375   target_header_dir=/usr/include
4376 fi
4377
4378 # Test for stack protector support in target C library.
4379 AC_CACHE_CHECK(__stack_chk_fail in target C library,
4380       gcc_cv_libc_provides_ssp,
4381       [gcc_cv_libc_provides_ssp=no
4382     case "$target" in
4383        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
4384       [# glibc 2.4 and later provides __stack_chk_fail and
4385       # either __stack_chk_guard, or TLS access to stack guard canary.
4386       if test -f $target_header_dir/features.h \
4387          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
4388             $target_header_dir/features.h > /dev/null; then
4389         if $EGREP '^[   ]*#[    ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
4390            $target_header_dir/features.h > /dev/null; then
4391           gcc_cv_libc_provides_ssp=yes
4392         elif $EGREP '^[         ]*#[    ]*define[       ]+__GLIBC__[    ]+2' \
4393              $target_header_dir/features.h > /dev/null \
4394              && $EGREP '^[      ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
4395              $target_header_dir/features.h > /dev/null; then
4396           gcc_cv_libc_provides_ssp=yes
4397         elif $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
4398              $target_header_dir/features.h > /dev/null && \
4399              test -f $target_header_dir/bits/uClibc_config.h && \
4400              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
4401              $target_header_dir/bits/uClibc_config.h > /dev/null; then
4402           gcc_cv_libc_provides_ssp=yes
4403         fi
4404       fi]
4405         ;;
4406        *-*-gnu*)
4407          # Avoid complicated tests (see
4408          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
4409          # simply assert that glibc does provide this, which is true for all
4410          # realistically usable GNU/Hurd configurations.
4411          gcc_cv_libc_provides_ssp=yes;;
4412        *-*-darwin* | *-*-freebsd*)
4413          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
4414            [echo "no __stack_chk_fail on this target"])
4415         ;;
4416   *) gcc_cv_libc_provides_ssp=no ;;
4417     esac])
4418
4419 if test x$gcc_cv_libc_provides_ssp = xyes; then
4420   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
4421             [Define if your target C library provides stack protector support])
4422 fi
4423
4424 # Test for <sys/sdt.h> on the target.
4425 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
4426 AC_MSG_CHECKING(sys/sdt.h in the target C library)
4427 have_sys_sdt_h=no
4428 if test -f $target_header_dir/sys/sdt.h; then
4429   AC_DEFINE(HAVE_SYS_SDT_H, 1,
4430             [Define if your target C library provides sys/sdt.h])
4431 fi
4432 AC_MSG_RESULT($have_sys_sdt_h)
4433
4434 # Check if TFmode long double should be used by default or not.
4435 # Some glibc targets used DFmode long double, but with glibc 2.4
4436 # and later they can use TFmode.
4437 case "$target" in
4438   powerpc*-*-linux* | \
4439   sparc*-*-linux* | \
4440   s390*-*-linux* | \
4441   alpha*-*-linux*)
4442     AC_ARG_WITH(long-double-128,
4443       [AS_HELP_STRING([--with-long-double-128],
4444                       [use 128-bit long double by default])],
4445       gcc_cv_target_ldbl128="$with_long_double_128",
4446       [[gcc_cv_target_ldbl128=no
4447       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
4448         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
4449       && gcc_cv_target_ldbl128=yes
4450       ]])
4451     ;;
4452 esac
4453 if test x$gcc_cv_target_ldbl128 = xyes; then
4454   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
4455             [Define if TFmode long double should be the default])
4456 fi
4457
4458 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
4459 gcc_cv_target_dl_iterate_phdr=unknown
4460 case "$target" in
4461   *-*-solaris2*)
4462     # <link.h> needs both a dl_iterate_phdr declaration and support for
4463     # compilation with largefile support.
4464     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
4465       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
4466       gcc_cv_target_dl_iterate_phdr=yes
4467     else
4468       gcc_cv_target_dl_iterate_phdr=no
4469     fi
4470     ;;
4471 esac
4472 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
4473 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
4474    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
4475 [Define if your target C library provides the `dl_iterate_phdr' function.])
4476 fi
4477 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
4478
4479 # Find out what GC implementation we want, or may, use.
4480 AC_ARG_WITH(gc,
4481 [AS_HELP_STRING([--with-gc={page,zone}],
4482                 [choose the garbage collection mechanism to use
4483                  with the compiler])],
4484 [case "$withval" in
4485   page)
4486     GGC=ggc-$withval
4487     ;;
4488   zone)
4489     GGC=ggc-$withval
4490     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
4491     ;;
4492   *)
4493     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
4494     ;;
4495 esac],
4496 [GGC=ggc-page])
4497 AC_SUBST(GGC)
4498 echo "Using $GGC for garbage collection."
4499
4500 # Libraries to use on the host.  This will normally be set by the top
4501 # level Makefile.  Here we simply capture the value for our Makefile.
4502 if test -z "${HOST_LIBS+set}"; then
4503   HOST_LIBS=
4504 fi
4505 AC_SUBST(HOST_LIBS)
4506
4507 # Use the system's zlib library.
4508 zlibdir=-L../zlib
4509 zlibinc="-I\$(srcdir)/../zlib"
4510 AC_ARG_WITH(system-zlib,
4511 [AS_HELP_STRING([--with-system-zlib], [use installed libz])],
4512 zlibdir=
4513 zlibinc=
4514 )
4515 AC_SUBST(zlibdir)
4516 AC_SUBST(zlibinc)
4517
4518 dnl Very limited version of automake's enable-maintainer-mode
4519
4520 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
4521   dnl maintainer-mode is disabled by default
4522   AC_ARG_ENABLE(maintainer-mode,
4523 [AS_HELP_STRING([--enable-maintainer-mode],
4524                 [enable make rules and dependencies not useful
4525                  (and sometimes confusing) to the casual installer])],
4526       maintainer_mode=$enableval,
4527       maintainer_mode=no)
4528
4529 AC_MSG_RESULT($maintainer_mode)
4530
4531 if test "$maintainer_mode" = "yes"; then
4532   MAINT=''
4533 else
4534   MAINT='#'
4535 fi
4536 AC_SUBST(MAINT)dnl
4537
4538 # --------------
4539 # Language hooks
4540 # --------------
4541
4542 # Make empty files to contain the specs and options for each language.
4543 # Then add #include lines to for a compiler that has specs and/or options.
4544
4545 subdirs=
4546 lang_opt_files=
4547 lang_specs_files=
4548 lang_tree_files=
4549 # These (without "all_") are set in each config-lang.in.
4550 # `language' must be a single word so is spelled singularly.
4551 all_languages=
4552 all_compilers=
4553 all_outputs='Makefile'
4554 # List of language makefile fragments.
4555 all_lang_makefrags=
4556 # Additional files for gengtype
4557 all_gtfiles="$target_gtfiles"
4558
4559 # These are the languages that are set in --enable-languages,
4560 # and are available in the GCC tree.
4561 all_selected_languages=
4562
4563 # Add the language fragments.
4564 # Languages are added via two mechanisms.  Some information must be
4565 # recorded in makefile variables, these are defined in config-lang.in.
4566 # We accumulate them and plug them into the main Makefile.
4567 # The other mechanism is a set of hooks for each of the main targets
4568 # like `clean', `install', etc.
4569
4570 language_hooks="Make-hooks"
4571
4572 for lang in ${srcdir}/*/config-lang.in
4573 do
4574 changequote(,)dnl
4575         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4576
4577         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4578         if test "x$lang_alias" = x
4579         then
4580               echo "$lang doesn't set \$language." 1>&2
4581               exit 1
4582         fi
4583         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4584         subdirs="$subdirs $subdir"
4585
4586         # $gcc_subdir is where the gcc integration files are to be found
4587         # for a language, both for internal compiler purposes (compiler
4588         # sources implementing front-end to GCC tree converters), and for
4589         # build infrastructure purposes (Make-lang.in, etc.)
4590         #
4591         # This will be <subdir> (relative to $srcdir) if a line like
4592         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4593         # is found in <langdir>/config-lang.in, and will remain <langdir>
4594         # otherwise.
4595         #
4596         # Except for the language alias (fetched above), the regular
4597         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4598         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4599         # only this and the language alias.
4600
4601         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4602         if [ "$gcc_subdir" = "" ]; then
4603            gcc_subdir="$subdir"
4604         fi
4605
4606         case ",$enable_languages," in
4607         *,$lang_alias,*)
4608             all_selected_languages="$all_selected_languages $lang_alias"
4609             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4610                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4611             fi
4612             ;;
4613         esac
4614 changequote([,])dnl
4615
4616         language=
4617         boot_language=
4618         compilers=
4619         outputs=
4620         gtfiles=
4621         subdir_requires=
4622         . ${srcdir}/$gcc_subdir/config-lang.in
4623         if test "x$language" = x
4624         then
4625                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4626                 exit 1
4627         fi
4628
4629         ok=:
4630         case ",$enable_languages," in
4631                 *,$lang_alias,*) ;;
4632                 *)
4633                         for i in $subdir_requires; do
4634                                 test -f "${srcdir}/$i/config-lang.in" && continue
4635                                 ok=false
4636                                 break
4637                         done
4638                 ;;
4639         esac
4640         $ok || continue
4641
4642         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4643         if test -f $srcdir/$gcc_subdir/lang.opt; then
4644             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4645             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
4646         fi
4647         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4648             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4649         fi
4650         all_languages="$all_languages $language"
4651         all_compilers="$all_compilers $compilers"
4652         all_outputs="$all_outputs $outputs"
4653         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4654         case ",$enable_languages," in
4655                 *,lto,*)
4656                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4657                     enable_lto=yes
4658                     AC_SUBST(enable_lto)
4659                     ;;
4660                 *) ;;
4661         esac
4662 done
4663
4664 # Pick up gtfiles for c
4665 gtfiles=
4666 . ${srcdir}/c-config-lang.in
4667 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
4668
4669 check_languages=
4670 for language in $all_selected_languages
4671 do
4672         check_languages="$check_languages check-$language"
4673 done
4674
4675 # We link each language in with a set of hooks, reached indirectly via
4676 # lang.${target}.  Only do so for selected languages.
4677
4678 rm -f Make-hooks
4679 touch Make-hooks
4680 target_list="all.cross start.encap rest.encap tags \
4681         install-common install-man install-info install-pdf install-html dvi \
4682         pdf html uninstall info man srcextra srcman srcinfo \
4683         mostlyclean clean distclean maintainer-clean install-plugin"
4684
4685 for t in $target_list
4686 do
4687         x=
4688         for lang in $all_selected_languages
4689         do
4690                 x="$x $lang.$t"
4691         done
4692         echo "lang.$t: $x" >> Make-hooks
4693 done
4694
4695 # --------
4696 # Option include files
4697 # --------
4698
4699 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
4700 option_includes="option-includes.mk"
4701 AC_SUBST_FILE(option_includes)
4702
4703 # --------
4704 # UNSORTED
4705 # --------
4706
4707 # Create .gdbinit.
4708
4709 echo "dir ." > .gdbinit
4710 echo "dir ${srcdir}" >> .gdbinit
4711 if test x$gdb_needs_out_file_path = xyes
4712 then
4713         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4714 fi
4715 if test "x$subdirs" != x; then
4716         for s in $subdirs
4717         do
4718                 echo "dir ${srcdir}/$s" >> .gdbinit
4719         done
4720 fi
4721 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4722
4723 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4724 AC_SUBST(gcc_tooldir)
4725 AC_SUBST(dollar)
4726
4727 # Find a directory in which to install a shared libgcc.
4728
4729 AC_ARG_ENABLE(version-specific-runtime-libs,
4730 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
4731                 [specify that runtime libraries should be
4732                  installed in a compiler-specific directory])])
4733
4734 AC_ARG_WITH(slibdir,
4735 [AS_HELP_STRING([--with-slibdir=DIR], [shared libraries in DIR @<:@LIBDIR@:>@])],
4736 slibdir="$with_slibdir",
4737 if test "${enable_version_specific_runtime_libs+set}" = set; then
4738   slibdir='$(libsubdir)'
4739 elif test "$host" != "$target"; then
4740   slibdir='$(build_tooldir)/lib'
4741 else
4742   slibdir='$(libdir)'
4743 fi)
4744 AC_SUBST(slibdir)
4745
4746 # Substitute configuration variables
4747 AC_SUBST(subdirs)
4748 AC_SUBST(srcdir)
4749 AC_SUBST(all_compilers)
4750 AC_SUBST(all_gtfiles)
4751 AC_SUBST(all_lang_makefrags)
4752 AC_SUBST(all_languages)
4753 AC_SUBST(all_selected_languages)
4754 AC_SUBST(build_exeext)
4755 AC_SUBST(build_install_headers_dir)
4756 AC_SUBST(build_xm_file_list)
4757 AC_SUBST(build_xm_include_list)
4758 AC_SUBST(build_xm_defines)
4759 AC_SUBST(build_file_translate)
4760 AC_SUBST(check_languages)
4761 AC_SUBST(cpp_install_dir)
4762 AC_SUBST(xmake_file)
4763 AC_SUBST(tmake_file)
4764 AC_SUBST(TM_ENDIAN_CONFIG)
4765 AC_SUBST(TM_MULTILIB_CONFIG)
4766 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4767 AC_SUBST(extra_gcc_objs)
4768 AC_SUBST(user_headers_inc_next_pre)
4769 AC_SUBST(user_headers_inc_next_post)
4770 AC_SUBST(extra_headers_list)
4771 AC_SUBST(extra_objs)
4772 AC_SUBST(extra_parts)
4773 AC_SUBST(extra_passes)
4774 AC_SUBST(extra_programs)
4775 AC_SUBST(float_h_file)
4776 AC_SUBST(gcc_config_arguments)
4777 AC_SUBST(gcc_gxx_include_dir)
4778 AC_SUBST(host_exeext)
4779 AC_SUBST(host_xm_file_list)
4780 AC_SUBST(host_xm_include_list)
4781 AC_SUBST(host_xm_defines)
4782 AC_SUBST(out_host_hook_obj)
4783 AC_SUBST(install)
4784 AC_SUBST(lang_opt_files)
4785 AC_SUBST(lang_specs_files)
4786 AC_SUBST(lang_tree_files)
4787 AC_SUBST(local_prefix)
4788 AC_SUBST(md_file)
4789 AC_SUBST(objc_boehm_gc)
4790 AC_SUBST(out_file)
4791 AC_SUBST(out_object_file)
4792 AC_SUBST(thread_file)
4793 AC_SUBST(tm_file_list)
4794 AC_SUBST(tm_include_list)
4795 AC_SUBST(tm_defines)
4796 AC_SUBST(libgcc_tm_file_list)
4797 AC_SUBST(libgcc_tm_include_list)
4798 AC_SUBST(tm_p_file_list)
4799 AC_SUBST(tm_p_include_list)
4800 AC_SUBST(xm_file_list)
4801 AC_SUBST(xm_include_list)
4802 AC_SUBST(xm_defines)
4803 AC_SUBST(use_gcc_stdint)
4804 AC_SUBST(c_target_objs)
4805 AC_SUBST(cxx_target_objs)
4806 AC_SUBST(fortran_target_objs)
4807 AC_SUBST(target_cpu_default)
4808
4809 AC_SUBST_FILE(language_hooks)
4810
4811 # Echo link setup.
4812 if test x${build} = x${host} ; then
4813   if test x${host} = x${target} ; then
4814     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4815   else
4816     echo "Links are now set up to build a cross-compiler" 1>&2
4817     echo " from ${host} to ${target}." 1>&2
4818   fi
4819 else
4820   if test x${host} = x${target} ; then
4821     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4822     echo " for ${target}." 1>&2
4823   else
4824     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4825     echo " from ${host} to ${target}." 1>&2
4826   fi
4827 fi
4828
4829 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4830 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4831
4832 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4833 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4834
4835 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4836 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4837 if test "x${CLOOGLIBS}" != "x" ; then
4838    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4839 fi
4840
4841 # Check for plugin support
4842 AC_ARG_ENABLE(plugin,
4843 [AS_HELP_STRING([--enable-plugin], [enable plugin support])],
4844 enable_plugin=$enableval,
4845 enable_plugin=yes; default_plugin=yes)
4846
4847 pluginlibs=
4848
4849 case "${host}" in
4850   *-*-darwin*)
4851     if test x$build = x$host; then
4852       export_sym_check="nm${exeext} -g"
4853     elif test x$host = x$target; then
4854       export_sym_check="$gcc_cv_nm -g"
4855     else
4856       export_sym_check=
4857     fi
4858   ;;
4859   *)
4860     if test x$build = x$host; then
4861       export_sym_check="objdump${exeext} -T"
4862     elif test x$host = x$target; then
4863       export_sym_check="$gcc_cv_objdump -T"
4864     else
4865       export_sym_check=
4866     fi
4867   ;;
4868 esac
4869
4870 if test x"$enable_plugin" = x"yes"; then
4871
4872   AC_MSG_CHECKING([for exported symbols])
4873   if test "x$export_sym_check" != x; then
4874     echo "int main() {return 0;} int foobar() {return 0;}" > conftest.c
4875     ${CC} ${CFLAGS} ${LDFLAGS} conftest.c -o conftest > /dev/null 2>&1
4876     if $export_sym_check conftest | grep foobar > /dev/null; then
4877       : # No need to use a flag
4878       AC_MSG_RESULT([yes])
4879     else
4880       AC_MSG_RESULT([yes])
4881       AC_MSG_CHECKING([for -rdynamic])
4882       ${CC} ${CFLAGS} ${LDFLAGS} -rdynamic conftest.c -o conftest > /dev/null 2>&1
4883       if $export_sym_check conftest | grep foobar > /dev/null; then
4884         plugin_rdynamic=yes
4885         pluginlibs="-rdynamic"
4886       else
4887         plugin_rdynamic=no
4888         enable_plugin=no
4889       fi
4890       AC_MSG_RESULT([$plugin_rdynamic])
4891     fi
4892   else
4893     AC_MSG_RESULT([unable to check])
4894   fi
4895
4896   # Check -ldl
4897   saved_LIBS="$LIBS"
4898   AC_SEARCH_LIBS([dlopen], [dl])
4899   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
4900     pluginlibs="$pluginlibs -ldl"
4901   fi
4902   LIBS="$saved_LIBS"
4903
4904   # Check that we can build shared objects with -fPIC -shared
4905   saved_LDFLAGS="$LDFLAGS"
4906   saved_CFLAGS="$CFLAGS"
4907   case "${host}" in
4908     *-*-darwin*)
4909       CFLAGS=`echo $CFLAGS | sed s/-mdynamic-no-pic//g`
4910       CFLAGS="$CFLAGS -fPIC"
4911       LDFLAGS="$LDFLAGS -shared -undefined dynamic_lookup"
4912     ;;
4913     *)
4914       CFLAGS="$CFLAGS -fPIC"
4915       LDFLAGS="$LDFLAGS -fPIC -shared"
4916     ;;
4917   esac
4918   AC_MSG_CHECKING([for -fPIC -shared])
4919   AC_TRY_LINK(
4920     [extern int X;],[return X == 0;],
4921     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4922     [AC_MSG_RESULT([no]); have_pic_shared=no])
4923   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
4924     pluginlibs=
4925     enable_plugin=no
4926   fi
4927   LDFLAGS="$saved_LDFLAGS"
4928   CFLAGS="$saved_CFLAGS"
4929
4930   # If plugin support had been requested but not available, fail.
4931   if test x"$enable_plugin" = x"no" ; then
4932     if test x"$default_plugin" != x"yes"; then
4933       AC_MSG_ERROR([
4934 Building GCC with plugin support requires a host that supports
4935 -fPIC, -shared, -ldl and -rdynamic.])
4936     fi
4937   fi
4938 fi
4939
4940 AC_SUBST(pluginlibs)
4941 AC_SUBST(enable_plugin)
4942 if test x"$enable_plugin" = x"yes"; then
4943   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4944 fi
4945
4946
4947 AC_ARG_ENABLE(libquadmath-support,
4948 [AS_HELP_STRING([--disable-libquadmath-support],
4949   [disable libquadmath support for Fortran])],
4950 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
4951 ENABLE_LIBQUADMATH_SUPPORT=yes)
4952 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
4953   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
4954             [Define to 1 to enable libquadmath support])
4955 fi
4956
4957
4958 # Specify what hash style to use by default.
4959 AC_ARG_WITH([linker-hash-style],
4960 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
4961                 [specify the linker hash style])],
4962 [case x"$withval" in
4963    xsysv)
4964      LINKER_HASH_STYLE=sysv
4965      ;;
4966    xgnu)
4967      LINKER_HASH_STYLE=gnu
4968      ;;
4969    xboth)
4970      LINKER_HASH_STYLE=both
4971      ;;
4972    *)
4973      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
4974      ;;
4975  esac],
4976 [LINKER_HASH_STYLE=''])
4977 if test x"${LINKER_HASH_STYLE}" != x; then
4978   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
4979                                          [The linker hash style])
4980 fi
4981
4982 # Configure the subdirectories
4983 # AC_CONFIG_SUBDIRS($subdirs)
4984
4985 # Create the Makefile
4986 # and configure language subdirectories
4987 AC_CONFIG_FILES($all_outputs)
4988
4989 AC_CONFIG_COMMANDS([default],
4990 [
4991 case ${CONFIG_HEADERS} in
4992   *auto-host.h:config.in*)
4993   echo > cstamp-h ;;
4994 esac
4995 # Make sure all the subdirs exist.
4996 for d in $subdirs doc build c-family
4997 do
4998     test -d $d || mkdir $d
4999 done
5000 ],
5001 [subdirs='$subdirs'])
5002 AC_OUTPUT
5003