gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 ACX_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     libstdcxx_incdir='c++/$(version)'
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # With demangler in GNU ld
 215 AC_ARG_WITH(demangler-in-ld,
 216 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 217 demangler_in_ld="$with_demangler_in_ld",
 218 demangler_in_ld=no)
 219
 220 # ----------------------
 221 # Find default assembler
 222 # ----------------------
 223
 224 # With GNU as
 225 AC_ARG_WITH(gnu-as,
 226 [  --with-gnu-as           arrange to work with GNU as],
 227 gas_flag="$with_gnu_as",
 228 gas_flag=no)
 229
 230 AC_ARG_WITH(as,
 231 [  --with-as               arrange to use the specified as (full pathname)],
 232 DEFAULT_ASSEMBLER="$with_as")
 233 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 234   if test ! -x "$DEFAULT_ASSEMBLER"; then
 235     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 236   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 237     gas_flag=yes
 238   fi
 239   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 240         [Define to enable the use of a default assembler.])
 241 fi
 242
 243 AC_MSG_CHECKING([whether a default assembler was specified])
 244 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 245   if test x"$gas_flag" = x"no"; then
 246     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 247   else
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 249   fi
 250 else
 251   AC_MSG_RESULT(no)
 252 fi
 253
 254 # ---------------
 255 # Find C compiler
 256 # ---------------
 257
 258 # If a non-executable a.out is present (e.g. created by GNU as above even if
 259 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 260 # file, even when creating an executable, so an execution test fails.
 261 # Remove possible default executable files to avoid this.
 262 #
 263 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 264 # Autoconf includes it.
 265 rm -f a.out a.exe b.out
 266
 267 # Find the native compiler
 268 AC_PROG_CC
 269 AM_PROG_CC_C_O
 270 # autoconf is lame and doesn't give us any substitution variable for this.
 271 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 272   NO_MINUS_C_MINUS_O=yes
 273 else
 274   OUTPUT_OPTION='-o $@'
 275 fi
 276 AC_SUBST(NO_MINUS_C_MINUS_O)
 277 AC_SUBST(OUTPUT_OPTION)
 278
 279 # -------------------------
 280 # Check C compiler features
 281 # -------------------------
 282
 283 AC_PROG_CPP
 284 AC_C_INLINE
 285
 286 # sizeof(char) is 1 by definition.
 287 AC_CHECK_SIZEOF(void *)
 288 AC_CHECK_SIZEOF(short)
 289 AC_CHECK_SIZEOF(int)
 290 AC_CHECK_SIZEOF(long)
 291 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 292 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 293
 294 # ---------------------
 295 # Warnings and checking
 296 # ---------------------
 297
 298 # Check $CC warning features (if it's GCC).
 299 # We want to use -pedantic, but we don't want warnings about
 300 # * 'long long'
 301 # * variadic macros
 302 # So, we only use -pedantic if we can disable those warnings.
 303
 304 AC_CACHE_CHECK(
 305   [whether ${CC} accepts -Wno-long-long],
 306   [ac_cv_prog_cc_w_no_long_long],
 307   [save_CFLAGS="$CFLAGS"
 308   CFLAGS="-Wno-long-long"
 309   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 310                     [ac_cv_prog_cc_w_no_long_long=yes],
 311                     [ac_cv_prog_cc_w_no_long_long=no])
 312   CFLAGS="$save_CFLAGS"
 313   ])
 314
 315 AC_CACHE_CHECK(
 316   [whether ${CC} accepts -Wno-variadic-macros],
 317   [ac_cv_prog_cc_w_no_variadic_macros],
 318   [save_CFLAGS="$CFLAGS"
 319   CFLAGS="-Wno-variadic-macros"
 320   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 321                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 322                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 323   CFLAGS="$save_CFLAGS"
 324   ])
 325
 326 strict1_warn=
 327 if test $ac_cv_prog_cc_w_no_long_long = yes \
 328    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 329   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 330 fi
 331 AC_SUBST(strict1_warn)
 332
 333 # Add -Wold-style-definition if it's accepted
 334 AC_CACHE_CHECK(
 335   [whether ${CC} accepts -Wold-style-definition],
 336   [ac_cv_prog_cc_w_old_style_definition],
 337   [save_CFLAGS="$CFLAGS"
 338   CFLAGS="-Wold-style-definition"
 339   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 340                     [ac_cv_prog_cc_w_old_style_definition=yes],
 341                     [ac_cv_prog_cc_w_old_style_definition=no])
 342   CFLAGS="$save_CFLAGS"
 343   ])
 344 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 345   strict1_warn="${strict1_warn} -Wold-style-definition"
 346 fi
 347
 348 # Enable -Werror, period.
 349 AC_ARG_ENABLE(werror_always,
 350 [  --enable-werror-always         enable -Werror always], [],
 351 [enable_werror_always=no])
 352 if test x${enable_werror_always} = xyes ; then
 353   strict1_warn="${strict1_warn} -Werror"
 354   WERROR=-Werror
 355 fi
 356
 357 # If the native compiler is GCC, we can enable warnings even in stage1.
 358 # That's useful for people building cross-compilers, or just running a
 359 # quick `make'.
 360 warn_cflags=
 361 if test "x$GCC" = "xyes"; then
 362   warn_cflags='$(GCC_WARN_CFLAGS)'
 363 fi
 364 AC_SUBST(warn_cflags)
 365
 366 # Enable -Werror in bootstrap stage2 and later.
 367 is_release=
 368 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 369   is_release=yes
 370 fi
 371 AC_ARG_ENABLE(werror,
 372 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 373 [if test x$is_release = x ; then
 374   # Default to "yes" on development branches.
 375   enable_werror=yes
 376 else
 377   # Default to "no" on release branches.
 378   enable_werror=no
 379 fi])
 380 if test x$enable_werror = xyes ; then
 381   WERROR=-Werror
 382 fi
 383 AC_SUBST(WERROR)
 384
 385 # Enable expensive internal checks
 386 AC_ARG_ENABLE(checking,
 387 [  --enable-checking[=LIST]
 388                           enable expensive run-time checks.  With LIST,
 389                           enable only specific categories of checks.
 390                           Categories are: yes,no,all,none,release.
 391                           Flags are: assert,fold,gc,gcac,misc,
 392                           rtlflag,rtl,runtime,tree,valgrind.],
 393 [ac_checking_flags="${enableval}"],[
 394 # Determine the default checks.
 395 if test x$is_release = x ; then
 396   ac_checking_flags=yes
 397 else
 398   ac_checking_flags=release
 399 fi])
 400 ac_assert_checking=1
 401 ac_checking=
 402 ac_fold_checking=
 403 ac_gc_checking=
 404 ac_gc_always_collect=
 405 ac_rtl_checking=
 406 ac_rtlflag_checking=
 407 ac_runtime_checking=1
 408 ac_tree_checking=
 409 ac_valgrind_checking=
 410 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 411 for check in $ac_checking_flags
 412 do
 413         case $check in
 414         # these set all the flags to specific states
 415         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 416                         ac_fold_checking= ; ac_gc_checking=1 ;
 417                         ac_gc_always_collect= ; ac_rtl_checking= ;
 418                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 419                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 420         no|none)        ac_assert_checking= ; ac_checking= ;
 421                         ac_fold_checking= ; ac_gc_checking= ;
 422                         ac_gc_always_collect= ; ac_rtl_checking= ;
 423                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 424                         ac_tree_checking= ; ac_valgrind_checking= ;;
 425         all)            ac_assert_checking=1 ; ac_checking=1 ;
 426                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 427                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 428                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 429                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 430         release)        ac_assert_checking=1 ; ac_checking= ;
 431                         ac_fold_checking= ; ac_gc_checking= ;
 432                         ac_gc_always_collect= ; ac_rtl_checking= ;
 433                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 434                         ac_tree_checking= ; ac_valgrind_checking= ;;
 435         # these enable particular checks
 436         assert)         ac_assert_checking=1 ;;
 437         fold)           ac_fold_checking=1 ;;
 438         gc)             ac_gc_checking=1 ;;
 439         gcac)           ac_gc_always_collect=1 ;;
 440         misc)           ac_checking=1 ;;
 441         rtl)            ac_rtl_checking=1 ;;
 442         rtlflag)        ac_rtlflag_checking=1 ;;
 443         runtime)        ac_runtime_checking=1 ;;
 444         tree)           ac_tree_checking=1 ;;
 445         valgrind)       ac_valgrind_checking=1 ;;
 446         *)      AC_MSG_ERROR(unknown check category $check) ;;
 447         esac
 448 done
 449 IFS="$ac_save_IFS"
 450
 451 nocommon_flag=""
 452 if test x$ac_checking != x ; then
 453   AC_DEFINE(ENABLE_CHECKING, 1,
 454 [Define if you want more run-time sanity checks.  This one gets a grab
 455    bag of miscellaneous but relatively cheap checks.])
 456   nocommon_flag=-fno-common
 457 fi
 458 AC_SUBST(nocommon_flag)
 459 if test x$ac_assert_checking != x ; then
 460   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 461 [Define if you want assertions enabled.  This is a cheap check.])
 462 fi
 463 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 464 if test x$ac_runtime_checking != x ; then
 465   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 466 [Define if you want runtime assertions enabled.  This is a cheap check.])
 467 fi
 468 if test x$ac_tree_checking != x ; then
 469   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 470 [Define if you want all operations on trees (the basic data
 471    structure of the front ends) to be checked for dynamic type safety
 472    at runtime.  This is moderately expensive.  The tree browser debugging
 473    routines will also be enabled by this option.
 474    ])
 475   TREEBROWSER=tree-browser.o
 476 fi
 477 AC_SUBST(TREEBROWSER)
 478 if test x$ac_rtl_checking != x ; then
 479   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 480 [Define if you want all operations on RTL (the basic data structure
 481    of the optimizer and back end) to be checked for dynamic type safety
 482    at runtime.  This is quite expensive.])
 483 fi
 484 if test x$ac_rtlflag_checking != x ; then
 485   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 486 [Define if you want RTL flag accesses to be checked against the RTL
 487    codes that are supported for each access macro.  This is relatively
 488    cheap.])
 489 fi
 490 if test x$ac_gc_checking != x ; then
 491   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 492 [Define if you want the garbage collector to do object poisoning and
 493    other memory allocation checks.  This is quite expensive.])
 494 fi
 495 if test x$ac_gc_always_collect != x ; then
 496   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 497 [Define if you want the garbage collector to operate in maximally
 498    paranoid mode, validating the entire heap and collecting garbage at
 499    every opportunity.  This is extremely expensive.])
 500 fi
 501 if test x$ac_fold_checking != x ; then
 502   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 503 [Define if you want fold checked that it never destructs its argument.
 504    This is quite expensive.])
 505 fi
 506 valgrind_path_defines=
 507 valgrind_command=
 508
 509 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 510 dnl # an if statement.  This was the source of very frustrating bugs
 511 dnl # in converting to autoconf 2.5x!
 512 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 513
 514 if test x$ac_valgrind_checking != x ; then
 515   # It is certainly possible that there's valgrind but no valgrind.h.
 516   # GCC relies on making annotations so we must have both.
 517   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 518   AC_TRY_CPP(
 519     [#include <valgrind/memcheck.h>
 520 #ifndef VALGRIND_DISCARD
 521 #error VALGRIND_DISCARD not defined
 522 #endif],
 523   [gcc_cv_header_valgrind_memcheck_h=yes],
 524   [gcc_cv_header_valgrind_memcheck_h=no])
 525   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 526   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 527   AC_TRY_CPP(
 528     [#include <memcheck.h>
 529 #ifndef VALGRIND_DISCARD
 530 #error VALGRIND_DISCARD not defined
 531 #endif],
 532   [gcc_cv_header_memcheck_h=yes],
 533   gcc_cv_header_memcheck_h=no)
 534   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 535   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 536         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 537   if test "x$valgrind_path" = "x" \
 538     || (test $have_valgrind_h = no \
 539         && test $gcc_cv_header_memcheck_h = no \
 540         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 541         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 542   fi
 543   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 544   valgrind_command="$valgrind_path -q"
 545   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 546 [Define if you want to run subprograms and generated programs
 547    through valgrind (a memory checker).  This is extremely expensive.])
 548   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 549     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 550         [Define if valgrind's valgrind/memcheck.h header is installed.])
 551   fi
 552   if test $gcc_cv_header_memcheck_h = yes; then
 553     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 554         [Define if valgrind's memcheck.h header is installed.])
 555   fi
 556 fi
 557 AC_SUBST(valgrind_path_defines)
 558 AC_SUBST(valgrind_command)
 559
 560 AC_ARG_ENABLE(mapped-location,
 561 [  --enable-mapped-location   location_t is fileline integer cookie],,
 562 enable_mapped_location=no)
 563
 564 if test "$enable_mapped_location" = yes ; then
 565   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 566 [Define if location_t is fileline integer cookie.])
 567 fi
 568
 569 # Enable code coverage collection
 570 AC_ARG_ENABLE(coverage,
 571 [  --enable-coverage[=LEVEL]
 572                           enable compiler's code coverage collection.
 573                           Use to measure compiler performance and locate
 574                           unused parts of the compiler. With LEVEL, specify
 575                           optimization. Values are opt, noopt,
 576                           default is noopt],
 577 [case "${enableval}" in
 578   yes|noopt)
 579     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 580     ;;
 581   opt)
 582     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 583     ;;
 584   no)
 585     # a.k.a. --disable-coverage
 586     coverage_flags=""
 587     ;;
 588   *)
 589     AC_MSG_ERROR(unknown coverage setting $enableval)
 590     ;;
 591 esac],
 592 [coverage_flags=""])
 593 AC_SUBST(coverage_flags)
 594
 595 AC_ARG_ENABLE(gather-detailed-mem-stats,
 596 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 597 [enable_gather_detailed_mem_stats=no])
 598 if test x$enable_gather_detailed_mem_stats = xyes ; then
 599   AC_DEFINE(GATHER_STATISTICS, 1,
 600         [Define to enable detailed memory allocation stats gathering.])
 601 fi
 602
 603 # -------------------------------
 604 # Miscenalleous configure options
 605 # -------------------------------
 606
 607 # With stabs
 608 AC_ARG_WITH(stabs,
 609 [  --with-stabs            arrange to use stabs instead of host debug format],
 610 stabs="$with_stabs",
 611 stabs=no)
 612
 613 # Determine whether or not multilibs are enabled.
 614 AC_ARG_ENABLE(multilib,
 615 [  --enable-multilib       enable library support for multiple ABIs],
 616 [], [enable_multilib=yes])
 617 AC_SUBST(enable_multilib)
 618
 619 # Enable __cxa_atexit for C++.
 620 AC_ARG_ENABLE(__cxa_atexit,
 621 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 622 [], [])
 623
 624 # Enable threads
 625 # Pass with no value to take the default
 626 # Pass with a value to specify a thread package
 627 AC_ARG_ENABLE(threads,
 628 [  --enable-threads        enable thread usage for target GCC
 629   --enable-threads=LIB    use LIB thread package for target GCC],,
 630 [enable_threads=''])
 631
 632 AC_ARG_ENABLE(objc-gc,
 633 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 634                           the GNU Objective-C runtime],
 635 if test x$enable_objc_gc = xno; then
 636         objc_boehm_gc=''
 637 else
 638         objc_boehm_gc=1
 639 fi,
 640 objc_boehm_gc='')
 641
 642 AC_ARG_WITH(dwarf2,
 643 [  --with-dwarf2           force the default debug format to be DWARF 2],
 644 dwarf2="$with_dwarf2",
 645 dwarf2=no)
 646
 647 AC_ARG_ENABLE(shared,
 648 [  --disable-shared        don't provide a shared libgcc],
 649 [
 650   case $enable_shared in
 651   yes | no) ;;
 652   *)
 653     enable_shared=no
 654     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 655     for pkg in $enableval; do
 656       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 657         enable_shared=yes
 658       fi
 659     done
 660     IFS="$ac_save_ifs"
 661     ;;
 662   esac
 663 ], [enable_shared=yes])
 664 AC_SUBST(enable_shared)
 665
 666 AC_ARG_WITH(sysroot,
 667 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 668 [
 669  case ${with_sysroot} in
 670  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 671  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 672  esac
 673
 674  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 675  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 676
 677  if test "x$exec_prefix" = xNONE; then
 678   if test "x$prefix" = xNONE; then
 679    test_prefix=/usr/local
 680   else
 681    test_prefix=$prefix
 682   fi
 683  else
 684   test_prefix=$exec_prefix
 685  fi
 686  case ${TARGET_SYSTEM_ROOT} in
 687  "${test_prefix}"|"${test_prefix}/"*|\
 688  '${exec_prefix}'|'${exec_prefix}/'*)
 689    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 690    TARGET_SYSTEM_ROOT_DEFINE="$t"
 691    ;;
 692  esac
 693 ], [
 694  TARGET_SYSTEM_ROOT=
 695  TARGET_SYSTEM_ROOT_DEFINE=
 696  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 697 ])
 698 AC_SUBST(TARGET_SYSTEM_ROOT)
 699 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 700 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 701
 702 # Build with intermodule optimisations
 703 AC_ARG_ENABLE(intermodule,
 704 [  --enable-intermodule    build the compiler in one step],
 705 [case ${enable_intermodule} in
 706   yes) onestep="-onestep";;
 707   *) onestep="";;
 708 esac],
 709 [onestep=""])
 710 AC_SUBST(onestep)
 711
 712 # Sanity check enable_languages in case someone does not run the toplevel
 713 # configure # script.
 714 AC_ARG_ENABLE(languages,
 715 [  --enable-languages=LIST specify which front-ends to build],
 716 [case ,${enable_languages}, in
 717        ,,|,yes,)
 718                 # go safe -- we cannot be much sure without the toplevel
 719                 # configure's
 720                 # analysis of which target libs are present and usable
 721                 enable_languages=c
 722                 ;;
 723          *,all,*)
 724                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 725                 ;;
 726         *,c,*)
 727                 ;;
 728         *)
 729                 enable_languages=c,${enable_languages}
 730                 ;;
 731 esac],
 732 [enable_languages=c])
 733
 734 subdirs=
 735 for lang in ${srcdir}/*/config-lang.in
 736 do
 737         case $lang in
 738         # The odd quoting in the next line works around
 739         # an apparent bug in bash 1.12 on linux.
 740 changequote(,)dnl
 741         ${srcdir}/[*]/config-lang.in) ;;
 742         *)
 743           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 744           if test "x$lang_alias" = x
 745           then
 746                 echo "$lang doesn't set \$language." 1>&2
 747                 exit 1
 748           fi
 749           case ",$enable_languages," in
 750           *,$lang_alias,*)
 751             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 752           esac
 753           ;;
 754 changequote([,])dnl
 755         esac
 756 done
 757
 758
 759 # -------------------------
 760 # Checks for other programs
 761 # -------------------------
 762
 763 AC_PROG_MAKE_SET
 764
 765 # Find some useful tools
 766 AC_PROG_AWK
 767 # We need awk to create options.c and options.h.
 768 # Bail out if it's missing.
 769 case ${AWK} in
 770   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 771 esac
 772
 773 gcc_AC_PROG_LN_S
 774 ACX_PROG_LN($LN_S)
 775 AC_PROG_RANLIB
 776 case "${host}" in
 777 *-*-darwin*)
 778   # By default, the Darwin ranlib will not treat common symbols as
 779   # definitions when  building the archive table of contents.  Other
 780   # ranlibs do that; pass an option to the Darwin ranlib that makes
 781   # it behave similarly.
 782   ranlib_flags="-c"
 783   ;;
 784 *)
 785   ranlib_flags=""
 786 esac
 787 AC_SUBST(ranlib_flags)
 788
 789 gcc_AC_PROG_INSTALL
 790
 791 # See if cmp has --ignore-initial.
 792 gcc_AC_PROG_CMP_IGNORE_INITIAL
 793
 794 # See if we have the mktemp command.
 795 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 796
 797 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 798
 799 # See if makeinfo has been installed and is modern enough
 800 # that we can use it.
 801 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 802   [GNU texinfo.* \([0-9][0-9.]*\)],
 803   [4.[2-9]*])
 804 if test $gcc_cv_prog_makeinfo_modern = no; then
 805   MAKEINFO="$MISSING makeinfo"
 806   AC_MSG_WARN([
 807 *** Makeinfo is missing or too old.
 808 *** Info documentation will not be built.])
 809   BUILD_INFO=
 810 else
 811   BUILD_INFO=info
 812 fi
 813 AC_SUBST(BUILD_INFO)
 814
 815 # Is pod2man recent enough to regenerate manpages?
 816 AC_MSG_CHECKING([for recent Pod::Man])
 817 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 818   AC_MSG_RESULT(yes)
 819   GENERATED_MANPAGES=generated-manpages
 820 else
 821   AC_MSG_RESULT(no)
 822   GENERATED_MANPAGES=
 823 fi
 824 AC_SUBST(GENERATED_MANPAGES)
 825
 826 # How about lex?
 827 dnl Don't use AC_PROG_LEX; we insist on flex.
 828 dnl LEXLIB is not useful in gcc.
 829 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 830
 831 # Bison?
 832 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 833
 834 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 835 # check for build == host before using them.
 836
 837 # NM
 838 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 839   && test -d ../binutils ; then
 840   NM='$(objdir)/../binutils/nm-new'
 841 else
 842   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 843 fi
 844
 845 # AR
 846 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 847   && test -d ../binutils ; then
 848   AR='$(objdir)/../binutils/ar'
 849 else
 850   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 851 fi
 852
 853
 854 # --------------------
 855 # Checks for C headers
 856 # --------------------
 857
 858 AC_MSG_CHECKING(for GNU C library)
 859 AC_CACHE_VAL(gcc_cv_glibc,
 860 [AC_TRY_COMPILE(
 861   [#include <features.h>],[
 862 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 863 #error Not a GNU C library system
 864 #endif],
 865   [gcc_cv_glibc=yes],
 866   gcc_cv_glibc=no)])
 867 AC_MSG_RESULT($gcc_cv_glibc)
 868 if test $gcc_cv_glibc = yes; then
 869   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 870 fi
 871
 872 # Need to reject headers which give warnings, so that the -Werror bootstrap
 873 # works later. *sigh*  This needs to come before all header checks.
 874 AC_PROG_CPP_WERROR
 875
 876 AC_HEADER_STDC
 877 AC_HEADER_TIME
 878 ACX_HEADER_STRING
 879 AC_HEADER_SYS_WAIT
 880 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 881                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 882                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 883                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 884
 885 # Check for thread headers.
 886 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 887 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 888
 889 # These tests can't be done till we know if we have limits.h.
 890 gcc_AC_C_CHAR_BIT
 891 AC_C_BIGENDIAN
 892
 893 # --------
 894 # UNSORTED
 895 # --------
 896
 897 # Stage specific cflags for build.
 898 stage1_cflags=
 899 case $build in
 900 vax-*-*)
 901   if test x$GCC = xyes
 902   then
 903     stage1_cflags="-Wa,-J"
 904   else
 905     stage1_cflags="-J"
 906   fi
 907   ;;
 908 powerpc-*-darwin*)
 909   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 910   # sources; use -no-cpp-precomp to get to GNU cpp.
 911   # Apple's GCC has bugs in designated initializer handling, so disable
 912   # that too.
 913   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 914   ;;
 915 esac
 916 AC_SUBST(stage1_cflags)
 917
 918 # These libraries may be used by collect2.
 919 # We may need a special search path to get them linked.
 920 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 921 [save_LIBS="$LIBS"
 922 for libs in '' -lld -lmld \
 923                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 924                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 925 do
 926         LIBS="$libs"
 927         AC_TRY_LINK_FUNC(ldopen,
 928                 [gcc_cv_collect2_libs="$libs"; break])
 929 done
 930 LIBS="$save_LIBS"
 931 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 932 case $gcc_cv_collect2_libs in
 933         "none required")        ;;
 934         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 935 esac
 936 AC_SUBST(COLLECT2_LIBS)
 937
 938 # When building Ada code on Alpha, we need exc_resume which is usually in
 939 # -lexc.  So test for it.
 940 save_LIBS="$LIBS"
 941 LIBS=
 942 AC_SEARCH_LIBS(exc_resume, exc)
 943 GNAT_LIBEXC="$LIBS"
 944 LIBS="$save_LIBS"
 945 AC_SUBST(GNAT_LIBEXC)
 946
 947 # Some systems put ldexp and frexp in libm instead of libc; assume
 948 # they're both in the same place.  jcf-dump needs them.
 949 save_LIBS="$LIBS"
 950 LIBS=
 951 AC_SEARCH_LIBS(ldexp, m)
 952 LDEXP_LIB="$LIBS"
 953 LIBS="$save_LIBS"
 954 AC_SUBST(LDEXP_LIB)
 955
 956 # Use <inttypes.h> only if it exists,
 957 # doesn't clash with <sys/types.h>, and declares intmax_t.
 958 AC_MSG_CHECKING(for inttypes.h)
 959 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 960 [AC_TRY_COMPILE(
 961   [#include <sys/types.h>
 962 #include <inttypes.h>],
 963   [intmax_t i = -1;],
 964   [gcc_cv_header_inttypes_h=yes],
 965   gcc_cv_header_inttypes_h=no)])
 966 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 967 if test $gcc_cv_header_inttypes_h = yes; then
 968   AC_DEFINE(HAVE_INTTYPES_H, 1,
 969         [Define if you have a working <inttypes.h> header file.])
 970 fi
 971
 972 dnl Disabled until we have a complete test for buggy enum bitfields.
 973 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 974
 975 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 976   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 977   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 978   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 979   putchar_unlocked putc_unlocked)
 980 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 981         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 982         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 983         gcc_UNLOCKED_FUNCS)
 984
 985 if test x$ac_cv_func_mbstowcs = xyes; then
 986   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 987 [    AC_TRY_RUN([#include <stdlib.h>
 988 int main()
 989 {
 990   mbstowcs(0, "", 0);
 991   return 0;
 992 }],
 993     gcc_cv_func_mbstowcs_works=yes,
 994     gcc_cv_func_mbstowcs_works=no,
 995     gcc_cv_func_mbstowcs_works=yes)])
 996   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 997     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 998   [Define this macro if mbstowcs does not crash when its
 999    first argument is NULL.])
1000   fi
1001 fi
1002
1003 AC_CHECK_TYPE(ssize_t, int)
1004
1005 # Try to determine the array type of the second argument of getgroups
1006 # for the target system (int or gid_t).
1007 AC_TYPE_GETGROUPS
1008 if test "${target}" = "${build}"; then
1009   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1010 else
1011   case "${target}" in
1012         # This condition may need some tweaking.  It should include all
1013         # targets where the array type of the second argument of getgroups
1014         # is int and the type of gid_t is not equivalent to int.
1015         *-*-sunos* | *-*-ultrix*)
1016                 TARGET_GETGROUPS_T=int
1017                 ;;
1018         *)
1019                 TARGET_GETGROUPS_T=gid_t
1020                 ;;
1021   esac
1022 fi
1023 AC_SUBST(TARGET_GETGROUPS_T)
1024
1025 gcc_AC_FUNC_PRINTF_PTR
1026 gcc_AC_FUNC_MMAP_BLACKLIST
1027
1028 case "${host}" in
1029 *-*-*vms*)
1030   # Under VMS, vfork works very differently than on Unix. The standard test
1031   # won't work, and it isn't easily adaptable. It makes more sense to
1032   # just force it.
1033   ac_cv_func_vfork_works=yes
1034   ;;
1035 esac
1036 AC_FUNC_VFORK
1037
1038 AM_ICONV
1039 # Until we have in-tree GNU iconv:
1040 LIBICONV_DEP=
1041 AC_SUBST(LIBICONV_DEP)
1042
1043 AM_LC_MESSAGES
1044
1045 AM_LANGINFO_CODESET
1046
1047 # We will need to find libiberty.h and ansidecl.h
1048 saved_CFLAGS="$CFLAGS"
1049 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1050 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd strsignal \
1051         strstr errno snprintf vsnprintf vasprintf malloc realloc calloc \
1052         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1053 #include "ansidecl.h"
1054 #include "system.h"])
1055
1056 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_SYS_RESOURCE_H
1060 #include <sys/resource.h>
1061 #endif
1062 ])
1063
1064 AC_TRY_COMPILE([
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_RESOURCE_H
1068 #include <sys/resource.h>
1069 #endif
1070 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1071 [Define to \`long' if <sys/resource.h> doesn't define.])])
1072
1073 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1074 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1075 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1076 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1077 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1078 #include "ansidecl.h"
1079 #include "system.h"
1080 #ifdef HAVE_LDFCN_H
1081 #undef FREAD
1082 #undef FWRITE
1083 #include <ldfcn.h>
1084 #endif
1085 ])
1086
1087 gcc_AC_CHECK_DECLS(times, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_SYS_TIMES_H
1091 #include <sys/times.h>
1092 #endif
1093 ])
1094
1095 # More time-related stuff.
1096 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1097 AC_TRY_COMPILE([
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_SYS_TIMES_H
1101 #include <sys/times.h>
1102 #endif
1103 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1104 if test $ac_cv_struct_tms = yes; then
1105   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1106   [Define if <sys/times.h> defines struct tms.])
1107 fi
1108
1109 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1110 # revisit after autoconf 2.50.
1111 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1112 AC_TRY_COMPILE([
1113 #include "ansidecl.h"
1114 #include "system.h"
1115 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1116 if test $gcc_cv_type_clock_t = yes; then
1117   AC_DEFINE(HAVE_CLOCK_T, 1,
1118   [Define if <time.h> defines clock_t.])
1119 fi
1120
1121 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1122 CFLAGS="$saved_CFLAGS"
1123
1124 gcc_AC_INITFINI_ARRAY
1125
1126 # mkdir takes a single argument on some systems.
1127 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1128
1129 # File extensions
1130 manext='.1'
1131 objext='.o'
1132 AC_SUBST(manext)
1133 AC_SUBST(objext)
1134
1135 # With Setjmp/Longjmp based exception handling.
1136 AC_ARG_ENABLE(sjlj-exceptions,
1137 [  --enable-sjlj-exceptions
1138                           arrange to use setjmp/longjmp exception handling],
1139 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1140 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1141   [Define 0/1 to force the choice for exception handling model.])])
1142
1143 # For platforms with the unwind ABI which includes an unwind library,
1144 # libunwind, we can choose to use the system libunwind.
1145 AC_ARG_WITH(system-libunwind,
1146 [  --with-system-libunwind use installed libunwind])
1147
1148 # --------------------------------------------------------
1149 # Build, host, and target specific configuration fragments
1150 # --------------------------------------------------------
1151
1152 # Collect build-machine-specific information.
1153 . ${srcdir}/config.build
1154
1155 # Collect host-machine-specific information.
1156 . ${srcdir}/config.host
1157
1158 target_gtfiles=
1159
1160 # Collect target-machine-specific information.
1161 . ${srcdir}/config.gcc
1162
1163 extra_objs="${host_extra_objs} ${extra_objs}"
1164 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1165
1166 # Default the target-machine variables that were not explicitly set.
1167 if test x"$tm_file" = x
1168 then tm_file=$cpu_type/$cpu_type.h; fi
1169
1170 if test x"$extra_headers" = x
1171 then extra_headers=; fi
1172
1173 if test x$md_file = x
1174 then md_file=$cpu_type/$cpu_type.md; fi
1175
1176 if test x$out_file = x
1177 then out_file=$cpu_type/$cpu_type.c; fi
1178
1179 if test x"$tmake_file" = x
1180 then tmake_file=$cpu_type/t-$cpu_type
1181 fi
1182
1183 if test x"$dwarf2" = xyes
1184 then tm_file="$tm_file tm-dwarf2.h"
1185 fi
1186
1187 # Say what files are being used for the output code and MD file.
1188 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1189 echo "Using \`$srcdir/config/$md_file' as machine description file."
1190
1191 # If any of the xm_file variables contain nonexistent files, warn
1192 # about them and drop them.
1193
1194 bx=
1195 for x in $build_xm_file; do
1196   if    test -f $srcdir/config/$x
1197   then      bx="$bx $x"
1198   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1199   fi
1200 done
1201 build_xm_file="$bx"
1202
1203 hx=
1204 for x in $host_xm_file; do
1205   if    test -f $srcdir/config/$x
1206   then      hx="$hx $x"
1207   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1208   fi
1209 done
1210 host_xm_file="$hx"
1211
1212 tx=
1213 for x in $xm_file; do
1214   if    test -f $srcdir/config/$x
1215   then      tx="$tx $x"
1216   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1217   fi
1218 done
1219 xm_file="$tx"
1220
1221 count=a
1222 for f in $tm_file; do
1223         count=${count}x
1224 done
1225 if test $count = ax; then
1226         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1227 else
1228         echo "Using the following target machine macro files:"
1229         for f in $tm_file; do
1230                 echo "  $srcdir/config/$f"
1231         done
1232 fi
1233
1234 if test x$need_64bit_hwint = xyes; then
1235         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1236 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1237 fi
1238
1239 if test x$use_long_long_for_widest_fast_int = xyes; then
1240         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1241 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1242 efficiently supported by the host hardware.])
1243 fi
1244
1245 count=a
1246 for f in $host_xm_file; do
1247         count=${count}x
1248 done
1249 if test $count = a; then
1250         :
1251 elif test $count = ax; then
1252         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1253 else
1254         echo "Using the following host machine macro files:"
1255         for f in $host_xm_file; do
1256                 echo "  $srcdir/config/$f"
1257         done
1258 fi
1259 echo "Using ${out_host_hook_obj} for host machine hooks."
1260
1261 if test "$host_xm_file" != "$build_xm_file"; then
1262         count=a
1263         for f in $build_xm_file; do
1264                 count=${count}x
1265         done
1266         if test $count = a; then
1267                 :
1268         elif test $count = ax; then
1269                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1270         else
1271                 echo "Using the following build machine macro files:"
1272                 for f in $build_xm_file; do
1273                         echo "  $srcdir/config/$f"
1274                 done
1275         fi
1276 fi
1277
1278 # ---------
1279 # Threading
1280 # ---------
1281
1282 # Check if a valid thread package
1283 case ${enable_threads} in
1284   "" | no)
1285     # No threads
1286     target_thread_file='single'
1287     ;;
1288   yes)
1289     # default
1290     target_thread_file='single'
1291     ;;
1292   aix | dce | gnat | irix | posix | posix95 | rtems | \
1293   single | solaris | vxworks | win32 )
1294     target_thread_file=${enable_threads}
1295     ;;
1296   *)
1297     echo "${enable_threads} is an unknown thread package" 1>&2
1298     exit 1
1299     ;;
1300 esac
1301
1302 if test x${thread_file} = x; then
1303   # No thread file set by target-specific clauses in config.gcc,
1304   # so use file chosen by default logic above
1305   thread_file=${target_thread_file}
1306 fi
1307
1308 # Make gthr-default.h if we have a thread file.
1309 gthread_flags=
1310 if test $thread_file != single; then
1311   rm -f gthr-default.h
1312   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1313   gthread_flags=-DHAVE_GTHR_DEFAULT
1314 fi
1315 AC_SUBST(gthread_flags)
1316
1317 # --------
1318 # UNSORTED
1319 # --------
1320
1321 use_cxa_atexit=no
1322 if test x$enable___cxa_atexit = xyes || \
1323    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1324   if test x$host = x$target; then
1325     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1326         [echo "__cxa_atexit can't be enabled on this target"])
1327   else
1328     # We can't check for __cxa_atexit when building a cross, so assume
1329     # it is available
1330     use_cxa_atexit=yes
1331   fi
1332   if test x$use_cxa_atexit = xyes; then
1333     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1334       [Define if you want to use __cxa_atexit, rather than atexit, to
1335       register C++ destructors for local statics and global objects.
1336       This is essential for fully standards-compliant handling of
1337       destructors, but requires __cxa_atexit in libc.])
1338   fi
1339 fi
1340
1341 # Look for a file containing extra machine modes.
1342 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1343   extra_modes_file='$(srcdir)'/config/${extra_modes}
1344   AC_SUBST(extra_modes_file)
1345   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1346   [Define to the name of a file containing a list of extra machine modes
1347    for this architecture.])
1348 fi
1349
1350 # Convert extra_options into a form suitable for Makefile use.
1351 extra_opt_files=
1352 for f in $extra_options; do
1353   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1354 done
1355 AC_SUBST(extra_opt_files)
1356
1357 # auto-host.h is the file containing items generated by autoconf and is
1358 # the first file included by config.h.
1359 # If host=build, it is correct to have bconfig include auto-host.h
1360 # as well.  If host!=build, we are in error and need to do more
1361 # work to find out the build config parameters.
1362 if test x$host = x$build
1363 then
1364         build_auto=auto-host.h
1365 else
1366         # We create a subdir, then run autoconf in the subdir.
1367         # To prevent recursion we set host and build for the new
1368         # invocation of configure to the build for this invocation
1369         # of configure.
1370         tempdir=build.$$
1371         rm -rf $tempdir
1372         mkdir $tempdir
1373         cd $tempdir
1374         case ${srcdir} in
1375         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1376         *) realsrcdir=../${srcdir};;
1377         esac
1378         saved_CFLAGS="${CFLAGS}"
1379         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1380         ${realsrcdir}/configure \
1381                 --enable-languages=${enable_languages-all} \
1382                 --target=$target_alias --host=$build_alias --build=$build_alias
1383         CFLAGS="${saved_CFLAGS}"
1384
1385         # We just finished tests for the build machine, so rename
1386         # the file auto-build.h in the gcc directory.
1387         mv auto-host.h ../auto-build.h
1388         cd ..
1389         rm -rf $tempdir
1390         build_auto=auto-build.h
1391 fi
1392 AC_SUBST(build_subdir)
1393
1394 tm_file="${tm_file} defaults.h"
1395 tm_p_file="${tm_p_file} tm-preds.h"
1396 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1397 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1398 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1399 # put this back in temporarily.
1400 xm_file="auto-host.h ansidecl.h ${xm_file}"
1401
1402 # --------
1403 # UNSORTED
1404 # --------
1405
1406 changequote(,)dnl
1407 # Compile in configure arguments.
1408 if test -f configargs.h ; then
1409         # Being re-configured.
1410         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1411         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1412 else
1413         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1414 fi
1415
1416 # Double all backslashes and backslash all quotes to turn
1417 # gcc_config_arguments into a C string.
1418 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1419 $gcc_config_arguments
1420 EOF
1421 gcc_config_arguments_str=`cat conftest.out`
1422 rm -f conftest.out
1423
1424 cat > configargs.h <<EOF
1425 /* Generated automatically. */
1426 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1427 static const char thread_model[] = "$thread_file";
1428
1429 static const struct {
1430   const char *name, *value;
1431 } configure_default_options[] = $configure_default_options;
1432 EOF
1433 changequote([,])dnl
1434
1435 # Internationalization
1436 ZW_GNU_GETTEXT_SISTER_DIR
1437
1438 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1439 # -liconv on the link line twice.
1440 case "$LIBINTL" in *$LIBICONV*)
1441         LIBICONV= ;;
1442 esac
1443
1444 AC_ARG_ENABLE(secureplt,
1445 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1446 [], [])
1447
1448 # Windows32 Registry support for specifying GCC installation paths.
1449 AC_ARG_ENABLE(win32-registry,
1450 [  --disable-win32-registry
1451                           disable lookup of installation paths in the
1452                           Registry on Windows hosts
1453   --enable-win32-registry enable registry lookup (default)
1454   --enable-win32-registry=KEY
1455                           use KEY instead of GCC version as the last portion
1456                           of the registry key],,)
1457
1458 case $host_os in
1459   win32 | pe | cygwin* | mingw32* | uwin*)
1460     if test "x$enable_win32_registry" != xno; then
1461       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1462     fi
1463
1464     if test "x$enable_win32_registry" != xno; then
1465       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1466   [Define to 1 if installation paths should be looked up in the Windows
1467    Registry. Ignored on non-Windows hosts.])
1468
1469       if test "x$enable_win32_registry" != xyes \
1470          && test "x$enable_win32_registry" != x; then
1471         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1472   [Define to be the last component of the Windows registry key under which
1473    to look for installation paths.  The full key used will be
1474    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1475    The default is the GCC version number.])
1476       fi
1477     fi
1478   ;;
1479 esac
1480
1481 # Get an absolute path to the GCC top-level source directory
1482 holddir=`${PWDCMD-pwd}`
1483 cd $srcdir
1484 topdir=`${PWDCMD-pwd}`
1485 cd $holddir
1486
1487 # Conditionalize the makefile for this host machine.
1488 xmake_file=
1489 for f in ${host_xmake_file}
1490 do
1491         if test -f ${srcdir}/config/$f
1492         then
1493                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1494         fi
1495 done
1496
1497 # Conditionalize the makefile for this target machine.
1498 tmake_file_=
1499 for f in ${tmake_file}
1500 do
1501         if test -f ${srcdir}/config/$f
1502         then
1503                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1504         fi
1505 done
1506 tmake_file="${tmake_file_}"
1507
1508 # If the host doesn't support symlinks, modify CC in
1509 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1510 # Otherwise, we can use "CC=$(CC)".
1511 rm -f symtest.tem
1512 case "$LN_S" in
1513         *-s*)
1514                 cc_set_by_configure="\$(CC)"
1515                 quoted_cc_set_by_configure="\$(CC)"
1516                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1517                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1518                 ;;
1519         *)
1520                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1521                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1522                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1523                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1524                 ;;
1525 esac
1526
1527 # This is a terrible hack which will go away some day.
1528 host_cc_for_libada=${CC}
1529 AC_SUBST(host_cc_for_libada)
1530
1531 out_object_file=`basename $out_file .c`.o
1532
1533 tm_file_list="options.h"
1534 tm_include_list="options.h"
1535 for f in $tm_file; do
1536   case $f in
1537     defaults.h )
1538        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1539        tm_include_list="${tm_include_list} $f"
1540        ;;
1541     * )
1542        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1543        tm_include_list="${tm_include_list} config/$f"
1544        ;;
1545   esac
1546 done
1547
1548 tm_p_file_list=
1549 tm_p_include_list=
1550 for f in $tm_p_file; do
1551   case $f in
1552     tm-preds.h )
1553        tm_p_file_list="${tm_p_file_list} $f"
1554        tm_p_include_list="${tm_p_include_list} $f"
1555        ;;
1556     * )
1557        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1558        tm_p_include_list="${tm_p_include_list} config/$f"
1559   esac
1560 done
1561
1562 xm_file_list=
1563 xm_include_list=
1564 for f in $xm_file; do
1565   case $f in
1566     ansidecl.h )
1567        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1568        xm_include_list="${xm_include_list} $f"
1569        ;;
1570     auto-host.h )
1571        xm_file_list="${xm_file_list} $f"
1572        xm_include_list="${xm_include_list} $f"
1573        ;;
1574     * )
1575        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1576        xm_include_list="${xm_include_list} config/$f"
1577        ;;
1578   esac
1579 done
1580
1581 host_xm_file_list=
1582 host_xm_include_list=
1583 for f in $host_xm_file; do
1584   case $f in
1585     ansidecl.h )
1586        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1587        host_xm_include_list="${host_xm_include_list} $f"
1588        ;;
1589     auto-host.h )
1590        host_xm_file_list="${host_xm_file_list} $f"
1591        host_xm_include_list="${host_xm_include_list} $f"
1592        ;;
1593     * )
1594        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1595        host_xm_include_list="${host_xm_include_list} config/$f"
1596        ;;
1597   esac
1598 done
1599
1600 build_xm_file_list=
1601 for f in $build_xm_file; do
1602   case $f in
1603     ansidecl.h )
1604        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1605        build_xm_include_list="${build_xm_include_list} $f"
1606        ;;
1607     auto-build.h | auto-host.h )
1608        build_xm_file_list="${build_xm_file_list} $f"
1609        build_xm_include_list="${build_xm_include_list} $f"
1610        ;;
1611     * )
1612        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1613        build_xm_include_list="${build_xm_include_list} config/$f"
1614        ;;
1615   esac
1616 done
1617
1618 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1619 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1620 CROSS=                                          AC_SUBST(CROSS)
1621 ALL=all.internal                                AC_SUBST(ALL)
1622 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1623 if test x$host != x$target
1624 then
1625         CROSS="-DCROSS_COMPILE"
1626         ALL=all.cross
1627         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1628         case "$host","$target" in
1629         # Darwin crosses can use the host system's libraries and headers,
1630         # because of the fat library support.  Of course, it must be the
1631         # same version of Darwin on both sides.  Allow the user to
1632         # just say --target=foo-darwin without a version number to mean
1633         # "the version on this system".
1634             *-*-darwin*,*-*-darwin*)
1635                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1636                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1637                 if test $hostos = $targetos -o $targetos = darwin ; then
1638                     CROSS=
1639                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1640                     with_headers=yes
1641                 fi
1642                 ;;
1643
1644             i?86-*-*,x86_64-*-* \
1645             | powerpc*-*-*,powerpc64*-*-*)
1646                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1647         esac
1648 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1649         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1650         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1651 fi
1652
1653 # If this is a cross-compiler that does not
1654 # have its own set of headers then define
1655 # inhibit_libc
1656
1657 # If this is using newlib, without having the headers available now,
1658 # then define inhibit_libc in LIBGCC2_CFLAGS.
1659 # This prevents libgcc2 from containing any code which requires libc
1660 # support.
1661 inhibit_libc=
1662 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1663        test x$with_newlib = xyes ; } &&
1664      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1665        inhibit_libc=-Dinhibit_libc
1666 fi
1667 AC_SUBST(inhibit_libc)
1668
1669 # When building gcc with a cross-compiler, we need to adjust things so
1670 # that the generator programs are still built with the native compiler.
1671 # Also, we cannot run fixincludes or fix-header.
1672
1673 # These are the normal (build=host) settings:
1674 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1675 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1676 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1677
1678 # Possibly disable fixproto, on a per-target basis.
1679 case ${use_fixproto} in
1680   no)
1681     STMP_FIXPROTO=
1682     ;;
1683   yes)
1684     STMP_FIXPROTO=stmp-fixproto
1685     ;;
1686 esac
1687 AC_SUBST(STMP_FIXPROTO)
1688
1689 # And these apply if build != host, or we are generating coverage data
1690 if test x$build != x$host || test "x$coverage_flags" != x
1691 then
1692     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1693
1694     if test "x$TARGET_SYSTEM_ROOT" = x; then
1695         if test "x$STMP_FIXPROTO" != x; then
1696           STMP_FIXPROTO=stmp-install-fixproto
1697         fi
1698     fi
1699 fi
1700
1701 # Expand extra_headers to include complete path.
1702 # This substitutes for lots of t-* files.
1703 extra_headers_list=
1704 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1705 for file in ${extra_headers} ; do
1706   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1707 done
1708
1709 # Define collect2 in Makefile.
1710 case $host_can_use_collect2 in
1711   no) collect2= ;;
1712   *) collect2='collect2$(exeext)' ;;
1713 esac
1714 AC_SUBST([collect2])
1715
1716 # Add a definition of USE_COLLECT2 if system wants one.
1717 case $use_collect2 in
1718   no) use_collect2= ;;
1719   "") ;;
1720   *)
1721     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1722     xm_defines="${xm_defines} USE_COLLECT2"
1723     case $host_can_use_collect2 in
1724       no)
1725         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1726         ;;
1727     esac
1728     ;;
1729 esac
1730
1731 # ---------------------------
1732 # Assembler & linker features
1733 # ---------------------------
1734
1735 # Identify the assembler which will work hand-in-glove with the newly
1736 # built GCC, so that we can examine its features.  This is the assembler
1737 # which will be driven by the driver program.
1738 #
1739 # If build != host, and we aren't building gas in-tree, we identify a
1740 # build->target assembler and hope that it will have the same features
1741 # as the host->target assembler we'll be using.
1742 AC_MSG_CHECKING(what assembler to use)
1743 in_tree_gas=no
1744 gcc_cv_as=
1745 gcc_cv_gas_major_version=
1746 gcc_cv_gas_minor_version=
1747 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1748 if test -x "$DEFAULT_ASSEMBLER"; then
1749         gcc_cv_as="$DEFAULT_ASSEMBLER"
1750 elif test -x as$build_exeext; then
1751         # Build using assembler in the current directory.
1752         gcc_cv_as=./as$build_exeext
1753 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1754      && test -f ../gas/Makefile \
1755      && test x$build = x$host; then
1756   # Single tree build which includes gas.  We want to prefer it
1757   # over whatever linker top-level may have detected, since
1758   # we'll use what we're building after installation anyway.
1759   in_tree_gas=yes
1760   _gcc_COMPUTE_GAS_VERSION
1761   rm -f as$build_exeext
1762   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1763   in_tree_gas_is_elf=no
1764   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1765      || (grep 'obj_format = multi' ../gas/Makefile \
1766          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1767   then
1768     in_tree_gas_is_elf=yes
1769   fi
1770 m4_pattern_allow([AS_FOR_TARGET])dnl
1771 elif test -x "$AS_FOR_TARGET"; then
1772         gcc_cv_as="$AS_FOR_TARGET"
1773 elif test -x "$AS" && test x$host = x$target; then
1774         gcc_cv_as="$AS"
1775 fi
1776
1777 gcc_version=`cat $srcdir/BASE-VER`
1778
1779 if test "x$gcc_cv_as" = x; then
1780         # Search the same directories that the installed compiler will
1781         # search.  Else we may find the wrong assembler and lose.  If we
1782         # do not find a suitable assembler binary, then try the user's
1783         # path.
1784         #
1785         # Also note we have to check MD_EXEC_PREFIX before checking the
1786         # user's path.  Unfortunately, there is no good way to get at the
1787         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1788         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1789         # to be fixed as part of the make/configure rewrite too.
1790
1791         if test "x$exec_prefix" = xNONE; then
1792                 if test "x$prefix" = xNONE; then
1793                         test_prefix=/usr/local
1794                 else
1795                         test_prefix=$prefix
1796                 fi
1797         else
1798                 test_prefix=$exec_prefix
1799         fi
1800
1801         # If the loop below does not find an assembler, then use whatever
1802         # one we can find in the users's path.  We are looking for a
1803         # ${build} -> ${target} assembler.
1804         if test "x$program_prefix" != xNONE; then
1805                 gcc_cv_as=${program_prefix}as$build_exeext
1806         elif test x$build != x$host && test x$build != x$target; then
1807                 gcc_cv_as=${target_noncanonical}-as$build_exeext
1808         else
1809                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1810         fi
1811
1812         if test x$host = x$build; then
1813             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1814                        $test_prefix/libexec/gcc/$target_noncanonical \
1815                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1816                        /usr/lib/gcc/$target_noncanonical \
1817                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1818                        $test_prefix/$target_noncanonical/bin"
1819         else
1820             test_dirs=
1821         fi
1822
1823         if test x$build = x$target; then
1824             test_dirs="$test_dirs \
1825                    /usr/libexec \
1826                    /usr/ccs/gcc \
1827                    /usr/ccs/bin \
1828                    /udk/usr/ccs/bin \
1829                    /bsd43/usr/lib/cmplrs/cc \
1830                    /usr/cross64/usr/bin \
1831                    /usr/lib/cmplrs/cc \
1832                    /sysv/usr/lib/cmplrs/cc \
1833                    /svr4/usr/lib/cmplrs/cc \
1834                    /usr/bin"
1835         fi
1836
1837         for dir in $test_dirs; do
1838                 if test -x $dir/as$build_exeext; then
1839                         gcc_cv_as=$dir/as$build_exeext
1840                         break;
1841                 fi
1842         done
1843 fi
1844 case $in_tree_gas in
1845   yes)
1846     AC_MSG_RESULT("newly built gas")
1847     ;;
1848   no)
1849     AC_MSG_RESULT($gcc_cv_as)
1850     ;;
1851 esac
1852
1853 # Identify the linker which will work hand-in-glove with the newly
1854 # built GCC, so that we can examine its features.  This is the linker
1855 # which will be driven by the driver program.
1856 #
1857 # If build != host, and we aren't building gas in-tree, we identify a
1858 # build->target linker and hope that it will have the same features
1859 # as the host->target linker we'll be using.
1860 AC_MSG_CHECKING(what linker to use)
1861 in_tree_ld=no
1862 gcc_cv_ld=
1863 gcc_cv_gld_major_version=
1864 gcc_cv_gld_minor_version=
1865 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1866 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1867 if test -x "$DEFAULT_LINKER"; then
1868         gcc_cv_ld="$DEFAULT_LINKER"
1869 elif test -x collect-ld$build_exeext; then
1870         # Build using linker in the current directory.
1871         gcc_cv_ld=./collect-ld$build_exeext
1872 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1873      && test -f ../ld/Makefile \
1874      && test x$build = x$host; then
1875         # Single tree build which includes ld.  We want to prefer it
1876         # over whatever linker top-level may have detected, since
1877         # we'll use what we're building after installation anyway.
1878         in_tree_ld=yes
1879         in_tree_ld_is_elf=no
1880         if (grep 'EMUL = .*elf' ../ld/Makefile \
1881             || grep 'EMUL = .*linux' ../ld/Makefile \
1882             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1883           in_tree_ld_is_elf=yes
1884         fi
1885         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1886         do
1887 changequote(,)dnl
1888                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1889 changequote([,])dnl
1890                 if test x$gcc_cv_gld_version != x; then
1891                         break
1892                 fi
1893         done
1894 changequote(,)dnl
1895         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1896         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1897 changequote([,])dnl
1898         rm -f collect-ld$build_exeext
1899         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1900 elif test -x "$LD_FOR_TARGET"; then
1901         gcc_cv_ld="$LD_FOR_TARGET"
1902 elif test -x "$LD" && test x$host = x$target; then
1903         gcc_cv_ld="$LD"
1904 fi
1905
1906 if test "x$gcc_cv_ld" = x; then
1907         # Search the same directories that the installed compiler will
1908         # search.  Else we may find the wrong linker and lose.  If we
1909         # do not find a suitable linker binary, then try the user's
1910         # path.
1911         #
1912         # Also note we have to check MD_EXEC_PREFIX before checking the
1913         # user's path.  Unfortunately, there is no good way to get at the
1914         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1915         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1916         # to be fixed as part of the make/configure rewrite too.
1917
1918         if test "x$exec_prefix" = xNONE; then
1919                 if test "x$prefix" = xNONE; then
1920                         test_prefix=/usr/local
1921                 else
1922                         test_prefix=$prefix
1923                 fi
1924         else
1925                 test_prefix=$exec_prefix
1926         fi
1927
1928         # If the loop below does not find a linker, then use whatever
1929         # one we can find in the users's path.  We are looking for a
1930         # ${build} -> ${target} linker.
1931         if test "x$program_prefix" != xNONE; then
1932                 gcc_cv_ld=${program_prefix}ld$build_exeext
1933         elif test x$build != x$host && test x$build != x$target; then
1934                 gcc_cv_ld=${target_noncanonical}-ld$build_exeext
1935         else
1936                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1937         fi
1938
1939         if test x$host = x$build; then
1940             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1941                        $test_prefix/libexec/gcc/$target_noncanonical \
1942                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1943                        /usr/lib/gcc/$target_noncanonical \
1944                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1945                        $test_prefix/$target_noncanonical/bin"
1946         else
1947             test_dirs=
1948         fi
1949
1950         if test x$build = x$target; then
1951             test_dirs="$test_dirs \
1952                    /usr/libexec \
1953                    /usr/ccs/gcc \
1954                    /usr/ccs/bin \
1955                    /udk/usr/ccs/bin \
1956                    /bsd43/usr/lib/cmplrs/cc \
1957                    /usr/cross64/usr/bin \
1958                    /usr/lib/cmplrs/cc \
1959                    /sysv/usr/lib/cmplrs/cc \
1960                    /svr4/usr/lib/cmplrs/cc \
1961                    /usr/bin"
1962         fi
1963
1964         for dir in $test_dirs; do
1965                 if test -x $dir/ld$build_exeext; then
1966                         gcc_cv_ld=$dir/ld$build_exeext
1967                         break;
1968                 fi
1969         done
1970 fi
1971 case $in_tree_ld in
1972   yes)
1973     AC_MSG_RESULT("newly built ld")
1974     ;;
1975   no)
1976     AC_MSG_RESULT($gcc_cv_ld)
1977     ;;
1978 esac
1979
1980 # Figure out what nm we will be using.
1981 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1982 AC_MSG_CHECKING(what nm to use)
1983 in_tree_nm=no
1984 if test -x nm$build_exeext; then
1985         gcc_cv_nm=./nm$build_exeext
1986 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1987      && test -f ../binutils/Makefile; then
1988         # Single tree build which includes binutils.
1989         in_tree_nm=yes
1990         gcc_cv_nm=./nm$build_exeext
1991         rm -f nm$build_exeext
1992         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1993 elif test "x$program_prefix" != xNONE; then
1994         gcc_cv_nm=${program_prefix}nm$build_exeext
1995 elif test x$build != x$host && test x$build != x$target; then
1996         gcc_cv_nm=${target_noncanonical}-nm$build_exeext
1997 else
1998         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1999 fi
2000 case $in_tree_nm in
2001   yes) AC_MSG_RESULT("newly built nm") ;;
2002   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
2003 esac
2004
2005 # Figure out what objdump we will be using.
2006 AC_MSG_CHECKING(what objdump to use)
2007 in_tree_objdump=no
2008 if test -x objdump$build_exeext; then
2009         gcc_cv_objdump=./objdump$build_exeext
2010 elif test -f $gcc_cv_binutils_srcdir/configure.in \
2011      && test -f ../binutils/Makefile; then
2012         # Single tree build which includes binutils.
2013         in_tree_objdump=yes
2014         gcc_cv_objdump=./objdump$build_exeext
2015         rm -f objdump$build_exeext
2016         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2017 elif test "x$program_prefix" != xNONE; then
2018         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2019 elif test x$build != x$host && test x$build != x$target; then
2020         gcc_cv_objdump=${target_noncanonical}-objdump$build_exeext
2021 else
2022         gcc_cv_objdump=`echo objdump | \
2023                 sed "${program_transform_name}"`$build_exeext
2024 fi
2025 case $in_tree_objdump in
2026   yes) AC_MSG_RESULT("newly built objdump") ;;
2027   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2028 esac
2029
2030 # Figure out what assembler alignment features are present.
2031 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2032  [2,6,0],,
2033 [.balign 4
2034 .p2align 2],,
2035 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2036   [Define if your assembler supports .balign and .p2align.])])
2037
2038 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2039  [2,8,0],,
2040  [.p2align 4,,7],,
2041 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2042   [Define if your assembler supports specifying the maximum number
2043    of bytes to skip when using the GAS .p2align command.])])
2044
2045 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2046  [elf,2,9,0],,
2047  [conftest_label1: .word 0
2048 .subsection -1
2049 conftest_label2: .word 0
2050 .previous],
2051  [if test x$gcc_cv_nm != x; then
2052     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2053     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2054     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2055     then :
2056     else gcc_cv_as_subsection_m1=yes
2057     fi
2058     rm -f conftest.nm1 conftest.nm2
2059   fi],
2060  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2061   [Define if your assembler supports .subsection and .subsection -1 starts
2062    emitting at the beginning of your section.])])
2063
2064 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2065  [2,2,0],,
2066  [      .weak foobar],,
2067 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2068
2069 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2070  [2,15,91],,
2071  [      .SPACE $TEXT$
2072         .NSUBSPA $CODE$,COMDAT],,
2073 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2074
2075 # .hidden needs to be supported in both the assembler and the linker,
2076 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2077 # This is irritatingly difficult to feature test for; we have to check the
2078 # date string after the version number.  If we've got an in-tree
2079 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2080 # to be safe.
2081 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2082 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2083  [elf,2,13,0],,
2084 [       .hidden foobar
2085 foobar:])
2086
2087 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2088 [if test $in_tree_ld = yes ; then
2089   gcc_cv_ld_hidden=no
2090   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2091      && test $in_tree_ld_is_elf = yes; then
2092      gcc_cv_ld_hidden=yes
2093   fi
2094 else
2095   gcc_cv_ld_hidden=yes
2096   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2097   if echo "$ld_ver" | grep GNU > /dev/null; then
2098 changequote(,)dnl
2099     ld_vers=`echo $ld_ver | sed -n \
2100         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2101         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2102         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2103         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2104         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2105         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2106         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   ].*$,\1,p'`
2107     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2108     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2109     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2110     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2111     if test 0"$ld_date" -lt 20020404; then
2112       if test -n "$ld_date"; then
2113         # If there was date string, but was earlier than 2002-04-04, fail
2114         gcc_cv_ld_hidden=no
2115       elif test -z "$ld_vers"; then
2116         # If there was no date string nor ld version number, something is wrong
2117         gcc_cv_ld_hidden=no
2118       else
2119         test -z "$ld_vers_patch" && ld_vers_patch=0
2120         if test "$ld_vers_major" -lt 2; then
2121           gcc_cv_ld_hidden=no
2122         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2123           gcc_cv_ld_hidden="no"
2124         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2125           gcc_cv_ld_hidden=no
2126         fi
2127       fi
2128 changequote([,])dnl
2129     fi
2130   else
2131     case "${target}" in
2132       hppa64*-*-hpux* | ia64*-*-hpux*)
2133         gcc_cv_ld_hidden=yes
2134         ;;
2135       *)
2136         gcc_cv_ld_hidden=no
2137         ;;
2138     esac
2139   fi
2140 fi])
2141 libgcc_visibility=no
2142 AC_SUBST(libgcc_visibility)
2143 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2144 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2145   libgcc_visibility=yes
2146   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2147   [Define if your assembler and linker support .hidden.])
2148 fi
2149
2150 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2151 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2152   [elf,2,11,0],,
2153 [       .data
2154         .uleb128 L2 - L1
2155 L1:
2156         .uleb128 1280
2157         .sleb128 -1010
2158 L2:],
2159  [# GAS versions before 2.11 do not support uleb128,
2160   # despite appearing to.
2161   # ??? There exists an elf-specific test that will crash
2162   # the assembler.  Perhaps it's better to figure out whether
2163   # arbitrary sections are supported and try the test.
2164   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2165   if echo "$as_ver" | grep GNU > /dev/null; then
2166 changequote(,)dnl
2167     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2168     as_major=`echo $as_ver | sed 's/\..*//'`
2169     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2170 changequote([,])dnl
2171     if test $as_major -eq 2 && test $as_minor -lt 11
2172     then :
2173     else gcc_cv_as_leb128=yes
2174     fi
2175   fi],
2176   [AC_DEFINE(HAVE_AS_LEB128, 1,
2177     [Define if your assembler supports .sleb128 and .uleb128.])])
2178
2179 # GAS versions up to and including 2.11.0 may mis-optimize
2180 # .eh_frame data.
2181 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2182   [elf,2,12,0],,
2183 [       .text
2184 .LFB1:
2185         .4byte  0
2186 .L1:
2187         .4byte  0
2188 .LFE1:
2189         .section        .eh_frame,"aw",@progbits
2190 __FRAME_BEGIN__:
2191         .4byte  .LECIE1-.LSCIE1
2192 .LSCIE1:
2193         .4byte  0x0
2194         .byte   0x1
2195         .ascii "z\0"
2196         .byte   0x1
2197         .byte   0x78
2198         .byte   0x1a
2199         .byte   0x0
2200         .byte   0x4
2201         .4byte  1
2202         .p2align 1
2203 .LECIE1:
2204 .LSFDE1:
2205         .4byte  .LEFDE1-.LASFDE1
2206 .LASFDE1:
2207         .4byte  .LASFDE1-__FRAME_BEGIN__
2208         .4byte  .LFB1
2209         .4byte  .LFE1-.LFB1
2210         .byte   0x4
2211         .4byte  .LFE1-.LFB1
2212         .byte   0x4
2213         .4byte  .L1-.LFB1
2214 .LEFDE1:],
2215 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2216 cat > conftest.lit <<EOF
2217  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2218  0010 01000000 12000000 18000000 00000000  ................
2219  0020 08000000 04080000 0044               .........D      @&t@
2220 EOF
2221 cat > conftest.big <<EOF
2222  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2223  0010 00000001 00000012 00000018 00000000  ................
2224  0020 00000008 04000000 0844               .........D      @&t@
2225 EOF
2226   # If the assembler didn't choke, and we can objdump,
2227   # and we got the correct data, then succeed.
2228   if test x$gcc_cv_objdump != x \
2229   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2230      | tail -3 > conftest.got \
2231   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2232     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2233   then
2234     gcc_cv_as_eh_frame=yes
2235   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2236     gcc_cv_as_eh_frame=buggy
2237   else
2238     # Uh oh, what do we do now?
2239     gcc_cv_as_eh_frame=no
2240   fi])
2241
2242 if test $gcc_cv_as_eh_frame = buggy; then
2243   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2244   [Define if your assembler mis-optimizes .eh_frame data.])
2245 fi
2246
2247 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2248  [elf,2,12,0], [--fatal-warnings],
2249  [.section .rodata.str, "aMS", @progbits, 1])
2250 if test $gcc_cv_as_shf_merge = no; then
2251   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2252     [elf,2,12,0], [--fatal-warnings],
2253     [.section .rodata.str, "aMS", %progbits, 1])
2254 fi
2255 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2256   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2257 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2258
2259 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2260  [elf,2,16,0], [--fatal-warnings],
2261  [.section .text,"axG",@progbits,.foo,comdat])
2262 if test $gcc_cv_as_comdat_group = yes; then
2263   gcc_cv_as_comdat_group_percent=no
2264 else
2265  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2266    [elf,2,16,0], [--fatal-warnings],
2267    [.section .text,"axG",%progbits,.foo,comdat])
2268 fi
2269 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2270   comdat_group=yes
2271   if test 0"$ld_date" -lt 20050308; then
2272     if test -n "$ld_date"; then
2273       # If there was date string, but was earlier than 2005-03-08, fail
2274       comdat_group=no
2275     elif test "$ld_vers_major" -lt 2; then
2276       comdat_group=no
2277     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2278       comdat_group=no
2279     fi
2280   fi
2281   if test $comdat_group = no; then
2282     gcc_cv_as_comdat_group=no
2283     gcc_cv_as_comdat_group_percent=no
2284   fi
2285 fi
2286 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2287   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2288 [Define 0/1 if your assembler and linker support COMDAT groups.])
2289
2290 # Thread-local storage - the check is heavily parametrized.
2291 conftest_s=
2292 tls_first_major=
2293 tls_first_minor=
2294 tls_as_opt=
2295 case "$target" in
2296 changequote(,)dnl
2297   alpha*-*-*)
2298     conftest_s='
2299         .section ".tdata","awT",@progbits
2300 foo:    .long   25
2301         .text
2302         ldq     $27,__tls_get_addr($29)         !literal!1
2303         lda     $16,foo($29)                    !tlsgd!1
2304         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2305         ldq     $27,__tls_get_addr($29)         !literal!2
2306         lda     $16,foo($29)                    !tlsldm!2
2307         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2308         ldq     $1,foo($29)                     !gotdtprel
2309         ldah    $2,foo($29)                     !dtprelhi
2310         lda     $3,foo($2)                      !dtprello
2311         lda     $4,foo($29)                     !dtprel
2312         ldq     $1,foo($29)                     !gottprel
2313         ldah    $2,foo($29)                     !tprelhi
2314         lda     $3,foo($2)                      !tprello
2315         lda     $4,foo($29)                     !tprel'
2316         tls_first_major=2
2317         tls_first_minor=13
2318         tls_as_opt=--fatal-warnings
2319         ;;
2320   frv*-*-*)
2321     conftest_s='
2322         .section ".tdata","awT",@progbits
2323 x:      .long   25
2324         .text
2325         call    #gettlsoff(x)'
2326         tls_first_major=2
2327         tls_first_minor=14
2328         ;;
2329   i[34567]86-*-*)
2330     conftest_s='
2331         .section ".tdata","awT",@progbits
2332 foo:    .long   25
2333         .text
2334         movl    %gs:0, %eax
2335         leal    foo@TLSGD(,%ebx,1), %eax
2336         leal    foo@TLSLDM(%ebx), %eax
2337         leal    foo@DTPOFF(%eax), %edx
2338         movl    foo@GOTTPOFF(%ebx), %eax
2339         subl    foo@GOTTPOFF(%ebx), %eax
2340         addl    foo@GOTNTPOFF(%ebx), %eax
2341         movl    foo@INDNTPOFF, %eax
2342         movl    $foo@TPOFF, %eax
2343         subl    $foo@TPOFF, %eax
2344         leal    foo@NTPOFF(%ecx), %eax'
2345         tls_first_major=2
2346         tls_first_minor=14
2347         tls_as_opt=--fatal-warnings
2348         ;;
2349   x86_64-*-*)
2350     conftest_s='
2351         .section ".tdata","awT",@progbits
2352 foo:    .long   25
2353         .text
2354         movq    %fs:0, %rax
2355         leaq    foo@TLSGD(%rip), %rdi
2356         leaq    foo@TLSLD(%rip), %rdi
2357         leaq    foo@DTPOFF(%rax), %rdx
2358         movq    foo@GOTTPOFF(%rip), %rax
2359         movq    $foo@TPOFF, %rax'
2360         tls_first_major=2
2361         tls_first_minor=14
2362         tls_as_opt=--fatal-warnings
2363         ;;
2364   ia64-*-*)
2365     conftest_s='
2366         .section ".tdata","awT",@progbits
2367 foo:    data8   25
2368         .text
2369         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2370         addl    r17 = @ltoff(@dtprel(foo#)), gp
2371         addl    r18 = @ltoff(@tprel(foo#)), gp
2372         addl    r19 = @dtprel(foo#), gp
2373         adds    r21 = @dtprel(foo#), r13
2374         movl    r23 = @dtprel(foo#)
2375         addl    r20 = @tprel(foo#), gp
2376         adds    r22 = @tprel(foo#), r13
2377         movl    r24 = @tprel(foo#)'
2378         tls_first_major=2
2379         tls_first_minor=13
2380         tls_as_opt=--fatal-warnings
2381         ;;
2382   mips*-*-*)
2383     conftest_s='
2384         .section .tdata,"awT",@progbits
2385 x:
2386         .word 2
2387         .text
2388         addiu $4, $28, %tlsgd(x)
2389         addiu $4, $28, %tlsldm(x)
2390         lui $4, %dtprel_hi(x)
2391         addiu $4, $4, %dtprel_lo(x)
2392         lw $4, %gottprel(x)($28)
2393         lui $4, %tprel_hi(x)
2394         addiu $4, $4, %tprel_lo(x)'
2395         tls_first_major=2
2396         tls_first_minor=16
2397         tls_as_opt='-32 --fatal-warnings'
2398         ;;
2399   powerpc-*-*)
2400     conftest_s='
2401         .section ".tdata","awT",@progbits
2402         .align 2
2403 ld0:    .space 4
2404 ld1:    .space 4
2405 x1:     .space 4
2406 x2:     .space 4
2407 x3:     .space 4
2408         .text
2409         addi 3,31,ld0@got@tlsgd
2410         bl __tls_get_addr
2411         addi 3,31,x1@got@tlsld
2412         bl __tls_get_addr
2413         addi 9,3,x1@dtprel
2414         addis 9,3,x2@dtprel@ha
2415         addi 9,9,x2@dtprel@l
2416         lwz 9,x3@got@tprel(31)
2417         add 9,9,x@tls
2418         addi 9,2,x1@tprel
2419         addis 9,2,x2@tprel@ha
2420         addi 9,9,x2@tprel@l'
2421         tls_first_major=2
2422         tls_first_minor=14
2423         tls_as_opt="-a32 --fatal-warnings"
2424         ;;
2425   powerpc64-*-*)
2426     conftest_s='
2427         .section ".tdata","awT",@progbits
2428         .align 3
2429 ld0:    .space 8
2430 ld1:    .space 8
2431 x1:     .space 8
2432 x2:     .space 8
2433 x3:     .space 8
2434         .text
2435         addi 3,2,ld0@got@tlsgd
2436         bl .__tls_get_addr
2437         nop
2438         addi 3,2,ld1@toc
2439         bl .__tls_get_addr
2440         nop
2441         addi 3,2,x1@got@tlsld
2442         bl .__tls_get_addr
2443         nop
2444         addi 9,3,x1@dtprel
2445         bl .__tls_get_addr
2446         nop
2447         addis 9,3,x2@dtprel@ha
2448         addi 9,9,x2@dtprel@l
2449         bl .__tls_get_addr
2450         nop
2451         ld 9,x3@got@dtprel(2)
2452         add 9,9,3
2453         bl .__tls_get_addr
2454         nop'
2455         tls_first_major=2
2456         tls_first_minor=14
2457         tls_as_opt="-a64 --fatal-warnings"
2458         ;;
2459   s390-*-*)
2460     conftest_s='
2461         .section ".tdata","awT",@progbits
2462 foo:    .long   25
2463         .text
2464         .long   foo@TLSGD
2465         .long   foo@TLSLDM
2466         .long   foo@DTPOFF
2467         .long   foo@NTPOFF
2468         .long   foo@GOTNTPOFF
2469         .long   foo@INDNTPOFF
2470         l       %r1,foo@GOTNTPOFF(%r12)
2471         l       %r1,0(%r1):tls_load:foo
2472         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2473         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2474         tls_first_major=2
2475         tls_first_minor=14
2476         tls_as_opt="-m31 --fatal-warnings"
2477         ;;
2478   s390x-*-*)
2479     conftest_s='
2480         .section ".tdata","awT",@progbits
2481 foo:    .long   25
2482         .text
2483         .quad   foo@TLSGD
2484         .quad   foo@TLSLDM
2485         .quad   foo@DTPOFF
2486         .quad   foo@NTPOFF
2487         .quad   foo@GOTNTPOFF
2488         lg      %r1,foo@GOTNTPOFF(%r12)
2489         larl    %r1,foo@INDNTPOFF
2490         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2491         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2492         tls_first_major=2
2493         tls_first_minor=14
2494         tls_as_opt="-m64 -Aesame --fatal-warnings"
2495         ;;
2496   sh-*-* | sh[34]-*-*)
2497     conftest_s='
2498         .section ".tdata","awT",@progbits
2499 foo:    .long   25
2500         .text
2501         .long   foo@TLSGD
2502         .long   foo@TLSLDM
2503         .long   foo@DTPOFF
2504         .long   foo@GOTTPOFF
2505         .long   foo@TPOFF'
2506         tls_first_major=2
2507         tls_first_minor=13
2508         tls_as_opt=--fatal-warnings
2509         ;;
2510   sparc*-*-*)
2511     case "$target" in
2512       sparc*-sun-solaris2.*)
2513         on_solaris=yes
2514         ;;
2515       *)
2516         on_solaris=no
2517         ;;
2518     esac
2519     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2520       conftest_s='
2521         .section ".tdata",#alloc,#write,#tls
2522 foo:    .long   25
2523         .text
2524         sethi   %tgd_hi22(foo), %o0
2525         add     %o0, %tgd_lo10(foo), %o1
2526         add     %l7, %o1, %o0, %tgd_add(foo)
2527         call    __tls_get_addr, %tgd_call(foo)
2528         sethi   %tldm_hi22(foo), %l1
2529         add     %l1, %tldm_lo10(foo), %l2
2530         add     %l7, %l2, %o0, %tldm_add(foo)
2531         call    __tls_get_addr, %tldm_call(foo)
2532         sethi   %tldo_hix22(foo), %l3
2533         xor     %l3, %tldo_lox10(foo), %l4
2534         add     %o0, %l4, %l5, %tldo_add(foo)
2535         sethi   %tie_hi22(foo), %o3
2536         add     %o3, %tie_lo10(foo), %o3
2537         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2538         add     %g7, %o2, %o4, %tie_add(foo)
2539         sethi   %tle_hix22(foo), %l1
2540         xor     %l1, %tle_lox10(foo), %o5
2541         ld      [%g7 + %o5], %o1'
2542         tls_first_major=0
2543         tls_first_minor=0
2544     else
2545       conftest_s='
2546         .section ".tdata","awT",@progbits
2547 foo:    .long   25
2548         .text
2549         sethi   %tgd_hi22(foo), %o0
2550         add     %o0, %tgd_lo10(foo), %o1
2551         add     %l7, %o1, %o0, %tgd_add(foo)
2552         call    __tls_get_addr, %tgd_call(foo)
2553         sethi   %tldm_hi22(foo), %l1
2554         add     %l1, %tldm_lo10(foo), %l2
2555         add     %l7, %l2, %o0, %tldm_add(foo)
2556         call    __tls_get_addr, %tldm_call(foo)
2557         sethi   %tldo_hix22(foo), %l3
2558         xor     %l3, %tldo_lox10(foo), %l4
2559         add     %o0, %l4, %l5, %tldo_add(foo)
2560         sethi   %tie_hi22(foo), %o3
2561         add     %o3, %tie_lo10(foo), %o3
2562         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2563         add     %g7, %o2, %o4, %tie_add(foo)
2564         sethi   %tle_hix22(foo), %l1
2565         xor     %l1, %tle_lox10(foo), %o5
2566         ld      [%g7 + %o5], %o1'
2567         tls_first_major=2
2568         tls_first_minor=14
2569         tls_as_opt="-32 --fatal-warnings"
2570       fi
2571         ;;
2572 changequote([,])dnl
2573 esac
2574 if test -z "$tls_first_major"; then
2575   : # If we don't have a check, assume no support.
2576 else
2577   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2578   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2579   [AC_DEFINE(HAVE_AS_TLS, 1,
2580             [Define if your assembler supports thread-local storage.])])
2581 fi
2582
2583 # Target-specific assembler checks.
2584
2585 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2586 gcc_cv_ld_static_dynamic=no
2587 if test $in_tree_ld = yes ; then
2588   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2589     gcc_cv_ld_static_dynamic=yes
2590   fi
2591 elif test x$gcc_cv_ld != x; then
2592         # Check if linker supports -Bstatic/-Bdynamic option
2593         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2594           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2595                 gcc_cv_ld_static_dynamic=yes
2596         fi
2597 fi
2598 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2599         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2600 [Define if your linker supports -Bstatic/-Bdynamic option.])
2601 fi
2602 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2603
2604 if test x"$demangler_in_ld" = xyes; then
2605   AC_MSG_CHECKING(linker --demangle support)
2606   gcc_cv_ld_demangle=no
2607   if test $in_tree_ld = yes; then
2608     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2609       gcc_cv_ld_demangle=yes
2610     fi
2611   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2612     # Check if the GNU linker supports --demangle option
2613     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2614       gcc_cv_ld_demangle=yes
2615     fi
2616   fi
2617   if test x"$gcc_cv_ld_demangle" = xyes; then
2618     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2619 [Define if your linker supports --demangle option.])
2620   fi
2621   AC_MSG_RESULT($gcc_cv_ld_demangle)
2622 fi
2623
2624 case "$target" in
2625   # All TARGET_ABI_OSF targets.
2626   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2627     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2628         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2629 [       .set nomacro
2630         .text
2631         extbl   $3, $2, $3      !lituse_bytoff!1
2632         ldq     $2, a($29)      !literal!1
2633         ldq     $4, b($29)      !literal!2
2634         ldq_u   $3, 0($2)       !lituse_base!1
2635         ldq     $27, f($29)     !literal!5
2636         jsr     $26, ($27), f   !lituse_jsr!5
2637         ldah    $29, 0($26)     !gpdisp!3
2638         lda     $0, c($29)      !gprel
2639         ldah    $1, d($29)      !gprelhigh
2640         lda     $1, d($1)       !gprellow
2641         lda     $29, 0($29)     !gpdisp!3],,
2642     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2643   [Define if your assembler supports explicit relocations.])])
2644     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2645         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2646 [       .set nomacro
2647         .text
2648         ldq     $27, a($29)     !literal!1
2649         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2650     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2651   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2652     ;;
2653
2654   cris-*-*)
2655     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2656       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2657       [-no-mul-bug-abort], [.text],,
2658       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2659                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2660     ;;
2661
2662   sparc*-*-*)
2663     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2664       [.register %g2, #scratch],,
2665       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2666                 [Define if your assembler supports .register.])])
2667
2668     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2669       [-relax], [.text],,
2670       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2671                 [Define if your assembler supports -relax option.])])
2672
2673     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2674       gcc_cv_as_sparc_ua_pcrel,,
2675       [-K PIC],
2676 [.text
2677 foo:
2678         nop
2679 .data
2680 .align 4
2681 .byte 0
2682 .uaword %r_disp32(foo)],
2683       [if test x$gcc_cv_ld != x \
2684        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2685          gcc_cv_as_sparc_ua_pcrel=yes
2686        fi
2687        rm -f conftest],
2688       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2689                 [Define if your assembler and linker support unaligned PC relative relocs.])
2690
2691       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2692         gcc_cv_as_sparc_ua_pcrel_hidden,,
2693         [-K PIC],
2694 [.data
2695 .align 4
2696 .byte 0x31
2697 .uaword %r_disp32(foo)
2698 .byte 0x32, 0x33, 0x34
2699 .global foo
2700 .hidden foo
2701 foo:
2702 .skip 4],
2703         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2704          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2705          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2706             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2707             if $gcc_cv_objdump -R conftest 2> /dev/null \
2708                | grep 'DISP32' > /dev/null 2>&1; then
2709                 :
2710             else
2711                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2712             fi
2713          fi
2714          rm -f conftest],
2715          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2716                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2717     ]) # unaligned pcrel relocs
2718
2719     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2720       gcc_cv_as_sparc_offsetable_lo10,,
2721       [-xarch=v9],
2722 [.text
2723         or %g1, %lo(ab) + 12, %g1
2724         or %g1, %lo(ab + 12), %g1],
2725       [if test x$gcc_cv_objdump != x \
2726        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2727           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2728          gcc_cv_as_sparc_offsetable_lo10=yes
2729        fi],
2730        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2731                  [Define if your assembler supports offsetable %lo().])])
2732     ;;
2733
2734 changequote(,)dnl
2735   i[34567]86-*-* | x86_64-*-*)
2736 changequote([,])dnl
2737     case $target_os in
2738       cygwin* | pe | mingw32*)
2739         # Used for DWARF 2 in PE
2740         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2741           gcc_cv_as_ix86_pe_secrel32,
2742           [2,15,91],,
2743 [.text
2744 foo:    nop
2745 .data
2746         .secrel32 foo],
2747           [if test x$gcc_cv_ld != x \
2748            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2749              gcc_cv_as_ix86_pe_secrel32=yes
2750            fi
2751            rm -f conftest],
2752           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2753             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2754         ;;
2755     esac
2756
2757     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2758        gcc_cv_as_ix86_filds_fists,
2759       [2,9,0],, [filds mem; fists mem],,
2760       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2761         [Define if your assembler uses the new HImode fild and fist notation.])])
2762
2763     gcc_GAS_CHECK_FEATURE([cmov syntax],
2764       gcc_cv_as_ix86_cmov_sun_syntax,,,
2765       [cmovl.l %edx, %eax],,
2766       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2767         [Define if your assembler supports the Sun syntax for cmov.])])
2768
2769     # This one is used unconditionally by i386.[ch]; it is to be defined
2770     # to 1 if the feature is present, 0 otherwise.
2771     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2772         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2773 [       .text
2774 .L0:
2775         nop
2776         .data
2777         .long .L0@GOTOFF])
2778     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2779       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2780       [Define true if the assembler supports '.long foo@GOTOFF'.])
2781     ;;
2782
2783   ia64*-*-*)
2784     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2785         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2786 [       .text
2787         addl r15 = @ltoffx(x#), gp
2788         ;;
2789         ld8.mov r16 = [[r15]], x#],,
2790     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2791           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2792
2793     ;;
2794
2795   powerpc*-*-*)
2796     case $target in
2797       *-*-aix*) conftest_s='    .machine "pwr5"
2798         .csect .text[[PR]]
2799         mfcr 3,128';;
2800       *-*-darwin*)
2801         gcc_GAS_CHECK_FEATURE([.machine directive support],
2802           gcc_cv_as_machine_directive,,,
2803           [     .machine ppc7400])
2804         if test x$gcc_cv_as_machine_directive != xyes; then
2805           echo "*** This target requires an assembler supporting \".machine\"" >&2
2806           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2807           test x$build = x$target && exit 1
2808         fi
2809         conftest_s='    .text
2810         mfcr r3,128';;
2811       *) conftest_s='   .machine power4
2812         .text
2813         mfcr 3,128';;
2814     esac
2815
2816     gcc_GAS_CHECK_FEATURE([mfcr field support],
2817       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2818       [$conftest_s],,
2819       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2820           [Define if your assembler supports mfcr field.])])
2821
2822     case $target in
2823       *-*-aix*) conftest_s='    .machine "pwr5"
2824         .csect .text[[PR]]
2825         popcntb 3,3';;
2826       *) conftest_s='   .machine power5
2827         .text
2828         popcntb 3,3';;
2829     esac
2830
2831     gcc_GAS_CHECK_FEATURE([popcntb support],
2832       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2833       [$conftest_s],,
2834       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2835           [Define if your assembler supports popcntb field.])])
2836
2837     case $target in
2838       *-*-aix*) conftest_s='    .csect .text[[PR]]
2839 LCF..0:
2840         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2841       *-*-darwin*)
2842         conftest_s='    .text
2843 LCF0:
2844         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2845       *) conftest_s='   .text
2846 .LCF0:
2847         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2848     esac
2849
2850     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2851       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2852       [$conftest_s],,
2853       [AC_DEFINE(HAVE_AS_REL16, 1,
2854           [Define if your assembler supports R_PPC_REL16 relocs.])])
2855     ;;
2856
2857   mips*-*-*)
2858     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2859       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2860 [       lw $4,%gp_rel(foo)($4)],,
2861       [if test x$target_cpu_default = x
2862        then target_cpu_default=MASK_EXPLICIT_RELOCS
2863        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2864        fi])
2865
2866     if test x$gas_flag = xyes \
2867        || test x"$host" != x"$build" \
2868        || test ! -x "$gcc_cv_as" \
2869        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2870       :
2871     else
2872       echo "*** This configuration requires the GNU assembler" >&2
2873       exit 1
2874     fi
2875     ;;
2876 esac
2877 # ??? Not all targets support dwarf2 debug_line, even within a version
2878 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2879 # info to the output file.  So, as supported targets are added to gas 2.11,
2880 # add some instruction here to (also) show we expect this might work.
2881 # ??? Once 2.11 is released, probably need to add first known working
2882 # version to the per-target configury.
2883 case "$target" in
2884   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2885   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2886   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2887     insn="nop"
2888     ;;
2889   ia64*-*-* | s390*-*-*)
2890     insn="nop 0"
2891     ;;
2892   mmix-*-*)
2893     insn="swym 0"
2894     ;;
2895 esac
2896 if test x"$insn" != x; then
2897  conftest_s="\
2898         .file 1 \"conftest.s\"
2899         .loc 1 3 0
2900         $insn"
2901  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2902   gcc_cv_as_dwarf2_debug_line,
2903   [elf,2,11,0],, [$conftest_s],
2904   [if test x$gcc_cv_objdump != x \
2905    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2906       | grep debug_line > /dev/null 2>&1; then
2907      gcc_cv_as_dwarf2_debug_line=yes
2908    fi])
2909
2910 # The .debug_line file table must be in the exact order that
2911 # we specified the files, since these indices are also used
2912 # by DW_AT_decl_file.  Approximate this test by testing if
2913 # the assembler bitches if the same index is assigned twice.
2914  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2915   gcc_cv_as_dwarf2_file_buggy,,,
2916 [       .file 1 "foo.s"
2917         .file 1 "bar.s"])
2918
2919  if test $gcc_cv_as_dwarf2_debug_line = yes \
2920  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2921         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2922   [Define if your assembler supports dwarf2 .file/.loc directives,
2923    and preserves file table indices exactly as given.])
2924  fi
2925
2926  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2927   gcc_cv_as_gdwarf2_flag,
2928   [elf,2,11,0], [--gdwarf2], [$insn],,
2929   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2930 [Define if your assembler supports the --gdwarf2 option.])])
2931
2932  gcc_GAS_CHECK_FEATURE([--gstabs option],
2933   gcc_cv_as_gstabs_flag,
2934   [elf,2,11,0], [--gstabs], [$insn],
2935   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2936    # and warns about it, but still exits successfully.  So check for
2937    # this.
2938    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2939    then :
2940    else gcc_cv_as_gstabs_flag=yes
2941    fi],
2942   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2943 [Define if your assembler supports the --gstabs option.])])
2944 fi
2945
2946 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2947 gcc_cv_ld_ro_rw_mix=unknown
2948 if test $in_tree_ld = yes ; then
2949   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2950      && test $in_tree_ld_is_elf = yes; then
2951     gcc_cv_ld_ro_rw_mix=read-write
2952   fi
2953 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2954   echo '.section myfoosect, "a"' > conftest1.s
2955   echo '.section myfoosect, "aw"' > conftest2.s
2956   echo '.byte 1' >> conftest2.s
2957   echo '.section myfoosect, "a"' > conftest3.s
2958   echo '.byte 0' >> conftest3.s
2959   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2960      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2961      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2962      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2963         conftest2.o conftest3.o > /dev/null 2>&1; then
2964     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2965                          | sed -e '/myfoosect/!d' -e N`
2966     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2967       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2968         gcc_cv_ld_ro_rw_mix=read-only
2969       else
2970         gcc_cv_ld_ro_rw_mix=read-write
2971       fi
2972     fi
2973   fi
2974 changequote(,)dnl
2975   rm -f conftest.* conftest[123].*
2976 changequote([,])dnl
2977 fi
2978 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2979         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2980   [Define if your linker links a mix of read-only
2981    and read-write sections into a read-write section.])
2982 fi
2983 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2984
2985 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2986 gcc_cv_ld_eh_frame_hdr=no
2987 if test $in_tree_ld = yes ; then
2988   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2989      && test $in_tree_ld_is_elf = yes; then
2990     gcc_cv_ld_eh_frame_hdr=yes
2991   fi
2992 elif test x$gcc_cv_ld != x; then
2993         # Check if linker supports --eh-frame-hdr option
2994         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2995                 gcc_cv_ld_eh_frame_hdr=yes
2996         fi
2997 fi
2998 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
2999 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3000         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3001 [Define if your linker supports --eh-frame-hdr option.])
3002 fi
3003 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3004
3005 AC_MSG_CHECKING(linker position independent executable support)
3006 gcc_cv_ld_pie=no
3007 if test $in_tree_ld = yes ; then
3008   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3009      && test $in_tree_ld_is_elf = yes; then
3010     gcc_cv_ld_pie=yes
3011   fi
3012 elif test x$gcc_cv_ld != x; then
3013         # Check if linker supports -pie option
3014         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3015                 gcc_cv_ld_pie=yes
3016         fi
3017 fi
3018 if test x"$gcc_cv_ld_pie" = xyes; then
3019         AC_DEFINE(HAVE_LD_PIE, 1,
3020 [Define if your linker supports -pie option.])
3021 fi
3022 AC_MSG_RESULT($gcc_cv_ld_pie)
3023
3024 # --------
3025 # UNSORTED
3026 # --------
3027
3028 AC_CACHE_CHECK(linker --as-needed support,
3029 gcc_cv_ld_as_needed,
3030 [gcc_cv_ld_as_needed=no
3031 if test $in_tree_ld = yes ; then
3032   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3033      && test $in_tree_ld_is_elf = yes; then
3034     gcc_cv_ld_as_needed=yes
3035   fi
3036 elif test x$gcc_cv_ld != x; then
3037         # Check if linker supports --as-needed and --no-as-needed options
3038         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3039                 gcc_cv_ld_as_needed=yes
3040         fi
3041 fi
3042 ])
3043 if test x"$gcc_cv_ld_as_needed" = xyes; then
3044         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3045 [Define if your linker supports --as-needed and --no-as-needed options.])
3046 fi
3047
3048 case "$target" in
3049   powerpc64*-*-linux*)
3050     AC_CACHE_CHECK(linker support for omitting dot symbols,
3051     gcc_cv_ld_no_dot_syms,
3052     [gcc_cv_ld_no_dot_syms=no
3053     if test $in_tree_ld = yes ; then
3054       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3055         gcc_cv_ld_no_dot_syms=yes
3056       fi
3057     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3058       cat > conftest1.s <<EOF
3059         .text
3060         bl .foo
3061 EOF
3062       cat > conftest2.s <<EOF
3063         .section ".opd","aw"
3064         .align 3
3065         .globl foo
3066         .type foo,@function
3067 foo:
3068         .quad .LEfoo,.TOC.@tocbase,0
3069         .text
3070 .LEfoo:
3071         blr
3072         .size foo,.-.LEfoo
3073 EOF
3074       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3075          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3076          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3077         gcc_cv_ld_no_dot_syms=yes
3078       fi
3079       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3080     fi
3081     ])
3082     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3083       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3084     [Define if your PowerPC64 linker only needs function descriptor syms.])
3085     fi
3086     ;;
3087 esac
3088
3089 AC_CACHE_CHECK(linker --sysroot support,
3090   gcc_cv_ld_sysroot,
3091   [gcc_cv_ld_sysroot=no
3092   if test $in_tree_ld = yes ; then
3093       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3094         gcc_cv_ld_sysroot=yes
3095       fi
3096   elif test x$gcc_cv_ld != x; then
3097     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3098       gcc_cv_ld_sysroot=yes
3099     fi
3100   fi])
3101 if test x"$gcc_cv_ld_sysroot" = xyes; then
3102   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3103   [Define if your linker supports --sysroot.])
3104 fi
3105
3106 if test x$with_sysroot = x && test x$host = x$target \
3107    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3108   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3109 [Define to PREFIX/include if cpp should also search that directory.])
3110 fi
3111
3112 # Find out what GC implementation we want, or may, use.
3113 AC_ARG_WITH(gc,
3114 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3115                           with the compiler],
3116 [case "$withval" in
3117   page)
3118     GGC=ggc-$withval
3119     ;;
3120   zone)
3121     GGC=ggc-$withval
3122     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3123     ;;
3124   *)
3125     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3126     ;;
3127 esac],
3128 [GGC=ggc-page])
3129 AC_SUBST(GGC)
3130 echo "Using $GGC for garbage collection."
3131
3132 # Use the system's zlib library.
3133 zlibdir=-L../zlib
3134 zlibinc="-I\$(srcdir)/../zlib"
3135 AC_ARG_WITH(system-zlib,
3136 [  --with-system-zlib      use installed libz],
3137 zlibdir=
3138 zlibinc=
3139 )
3140 AC_SUBST(zlibdir)
3141 AC_SUBST(zlibinc)
3142
3143 dnl Very limited version of automake's enable-maintainer-mode
3144
3145 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3146   dnl maintainer-mode is disabled by default
3147   AC_ARG_ENABLE(maintainer-mode,
3148 [  --enable-maintainer-mode
3149                           enable make rules and dependencies not useful
3150                           (and sometimes confusing) to the casual installer],
3151       maintainer_mode=$enableval,
3152       maintainer_mode=no)
3153
3154 AC_MSG_RESULT($maintainer_mode)
3155
3156 if test "$maintainer_mode" = "yes"; then
3157   MAINT=''
3158 else
3159   MAINT='#'
3160 fi
3161 AC_SUBST(MAINT)dnl
3162
3163 # --------------
3164 # Language hooks
3165 # --------------
3166
3167 # Make empty files to contain the specs and options for each language.
3168 # Then add #include lines to for a compiler that has specs and/or options.
3169
3170 lang_opt_files=
3171 lang_specs_files=
3172 lang_tree_files=
3173 for subdir in . $subdirs
3174 do
3175         if test -f $srcdir/$subdir/lang.opt; then
3176             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3177         fi
3178         if test -f $srcdir/$subdir/lang-specs.h; then
3179             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3180         fi
3181         if test -f $srcdir/$subdir/$subdir-tree.def; then
3182             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3183         fi
3184 done
3185
3186 # These (without "all_") are set in each config-lang.in.
3187 # `language' must be a single word so is spelled singularly.
3188 all_languages=
3189 all_boot_languages=
3190 all_compilers=
3191 all_stagestuff=
3192 all_outputs='Makefile gccbug mklibgcc libada-mk'
3193 # List of language makefile fragments.
3194 all_lang_makefrags=
3195 # List of language subdirectory makefiles.  Deprecated.
3196 all_lang_makefiles=
3197 # Files for gengtype
3198 all_gtfiles="$target_gtfiles"
3199 # Files for gengtype with language
3200 all_gtfiles_files_langs=
3201 all_gtfiles_files_files=
3202
3203 # Add the language fragments.
3204 # Languages are added via two mechanisms.  Some information must be
3205 # recorded in makefile variables, these are defined in config-lang.in.
3206 # We accumulate them and plug them into the main Makefile.
3207 # The other mechanism is a set of hooks for each of the main targets
3208 # like `clean', `install', etc.
3209
3210 language_hooks="Make-hooks"
3211
3212 for s in $subdirs
3213 do
3214                 language=
3215                 boot_language=
3216                 compilers=
3217                 stagestuff=
3218                 outputs=
3219                 gtfiles=
3220                 . ${srcdir}/$s/config-lang.in
3221                 if test "x$language" = x
3222                 then
3223                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3224                         exit 1
3225                 fi
3226                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3227                 if test -f ${srcdir}/$s/Makefile.in
3228                 then all_lang_makefiles="$s/Makefile"
3229                 fi
3230                 all_languages="$all_languages $language"
3231                 if test "x$boot_language" = xyes
3232                 then
3233                         all_boot_languages="$all_boot_languages $language"
3234                 fi
3235                 all_compilers="$all_compilers $compilers"
3236                 all_stagestuff="$all_stagestuff $stagestuff"
3237                 all_outputs="$all_outputs $outputs"
3238                 all_gtfiles="$all_gtfiles $gtfiles"
3239                 for f in $gtfiles
3240                 do
3241                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3242                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3243                 done
3244 done
3245
3246 # Pick up gtfiles for c
3247 gtfiles=
3248 s="c"
3249 . ${srcdir}/c-config-lang.in
3250 all_gtfiles="$all_gtfiles $gtfiles"
3251 for f in $gtfiles
3252 do
3253         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3254         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3255 done
3256
3257 check_languages=
3258 for language in $all_languages
3259 do
3260                 check_languages="$check_languages check-$language"
3261 done
3262
3263 # We link each language in with a set of hooks, reached indirectly via
3264 # lang.${target}.
3265
3266 rm -f Make-hooks
3267 touch Make-hooks
3268 target_list="all.build all.cross start.encap rest.encap tags \
3269         install-normal install-common install-man \
3270         uninstall info man srcextra srcman srcinfo \
3271         mostlyclean clean distclean maintainer-clean \
3272         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3273 for t in $target_list
3274 do
3275         x=
3276         for lang in $all_languages
3277         do
3278                         x="$x $lang.$t"
3279         done
3280         echo "lang.$t: $x" >> Make-hooks
3281 done
3282
3283 # --------
3284 # UNSORTED
3285 # --------
3286
3287 # Create .gdbinit.
3288
3289 echo "dir ." > .gdbinit
3290 echo "dir ${srcdir}" >> .gdbinit
3291 if test x$gdb_needs_out_file_path = xyes
3292 then
3293         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3294 fi
3295 if test "x$subdirs" != x; then
3296         for s in $subdirs
3297         do
3298                 echo "dir ${srcdir}/$s" >> .gdbinit
3299         done
3300 fi
3301 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3302
3303 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3304 # absolute path for gcc_tooldir based on inserting the number of up-directory
3305 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3306 # $(libsubdir)/@(unlibsubdir) based path.
3307 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3308 # make and thus we'd get different behavior depending on where we built the
3309 # sources.
3310 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3311     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3312 else
3313 changequote(<<, >>)dnl
3314 # An explanation of the sed strings:
3315 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3316 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3317 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3318 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3319 #
3320 # (*) Note this pattern overwrites the first character of the string
3321 # with a forward slash if one is not already present.  This is not a
3322 # problem because the exact names of the sub-directories concerned is
3323 # unimportant, just the number of them matters.
3324 #
3325 # The practical upshot of these patterns is like this:
3326 #
3327 #  prefix     exec_prefix        result
3328 #  ------     -----------        ------
3329 #   /foo        /foo/bar          ../
3330 #   /foo/       /foo/bar          ../
3331 #   /foo        /foo/bar/         ../
3332 #   /foo/       /foo/bar/         ../
3333 #   /foo        /foo/bar/ugg      ../../
3334 #
3335     dollar='$$'
3336     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3337 changequote([, ])dnl
3338 fi
3339 AC_SUBST(gcc_tooldir)
3340 AC_SUBST(dollar)
3341
3342 # Find a directory in which to install a shared libgcc.
3343
3344 AC_ARG_ENABLE(version-specific-runtime-libs,
3345 [  --enable-version-specific-runtime-libs
3346                           specify that runtime libraries should be
3347                           installed in a compiler-specific directory])
3348
3349 AC_ARG_WITH(slibdir,
3350 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3351 slibdir="$with_slibdir",
3352 if test "${enable_version_specific_runtime_libs+set}" = set; then
3353   slibdir='$(libsubdir)'
3354 elif test "$host" != "$target"; then
3355   slibdir='$(build_tooldir)/lib'
3356 else
3357   slibdir='$(libdir)'
3358 fi)
3359 AC_SUBST(slibdir)
3360
3361 objdir=`${PWDCMD-pwd}`
3362 AC_SUBST(objdir)
3363
3364 # Substitute configuration variables
3365 AC_SUBST(subdirs)
3366 AC_SUBST(srcdir)
3367 AC_SUBST(all_boot_languages)
3368 AC_SUBST(all_compilers)
3369 AC_SUBST(all_gtfiles)
3370 AC_SUBST(all_gtfiles_files_langs)
3371 AC_SUBST(all_gtfiles_files_files)
3372 AC_SUBST(all_lang_makefrags)
3373 AC_SUBST(all_lang_makefiles)
3374 AC_SUBST(all_languages)
3375 AC_SUBST(all_stagestuff)
3376 AC_SUBST(build_exeext)
3377 AC_SUBST(build_install_headers_dir)
3378 AC_SUBST(build_xm_file_list)
3379 AC_SUBST(build_xm_include_list)
3380 AC_SUBST(build_xm_defines)
3381 AC_SUBST(check_languages)
3382 AC_SUBST(cc_set_by_configure)
3383 AC_SUBST(quoted_cc_set_by_configure)
3384 AC_SUBST(cpp_install_dir)
3385 AC_SUBST(xmake_file)
3386 AC_SUBST(tmake_file)
3387 AC_SUBST(extra_gcc_objs)
3388 AC_SUBST(extra_headers_list)
3389 AC_SUBST(extra_objs)
3390 AC_SUBST(extra_parts)
3391 AC_SUBST(extra_passes)
3392 AC_SUBST(extra_programs)
3393 AC_SUBST(float_h_file)
3394 AC_SUBST(gcc_config_arguments)
3395 AC_SUBST(gcc_gxx_include_dir)
3396 AC_SUBST(libstdcxx_incdir)
3397 AC_SUBST(host_exeext)
3398 AC_SUBST(host_xm_file_list)
3399 AC_SUBST(host_xm_include_list)
3400 AC_SUBST(host_xm_defines)
3401 AC_SUBST(out_host_hook_obj)
3402 AC_SUBST(install)
3403 AC_SUBST(lang_opt_files)
3404 AC_SUBST(lang_specs_files)
3405 AC_SUBST(lang_tree_files)
3406 AC_SUBST(local_prefix)
3407 AC_SUBST(md_file)
3408 AC_SUBST(objc_boehm_gc)
3409 AC_SUBST(out_file)
3410 AC_SUBST(out_object_file)
3411 AC_SUBST(stage_prefix_set_by_configure)
3412 AC_SUBST(quoted_stage_prefix_set_by_configure)
3413 AC_SUBST(thread_file)
3414 AC_SUBST(tm_file_list)
3415 AC_SUBST(tm_include_list)
3416 AC_SUBST(tm_defines)
3417 AC_SUBST(tm_p_file_list)
3418 AC_SUBST(tm_p_include_list)
3419 AC_SUBST(xm_file_list)
3420 AC_SUBST(xm_include_list)
3421 AC_SUBST(xm_defines)
3422 AC_SUBST(c_target_objs)
3423 AC_SUBST(cxx_target_objs)
3424 AC_SUBST(target_cpu_default)
3425
3426 AC_SUBST_FILE(language_hooks)
3427
3428 # Echo link setup.
3429 if test x${build} = x${host} ; then
3430   if test x${host} = x${target} ; then
3431     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3432   else
3433     echo "Links are now set up to build a cross-compiler" 1>&2
3434     echo " from ${host} to ${target}." 1>&2
3435   fi
3436 else
3437   if test x${host} = x${target} ; then
3438     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3439     echo " for ${target}." 1>&2
3440   else
3441     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3442     echo " from ${host} to ${target}." 1>&2
3443   fi
3444 fi
3445
3446 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3447 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3448
3449 # Configure the subdirectories
3450 # AC_CONFIG_SUBDIRS($subdirs)
3451
3452 # Create the Makefile
3453 # and configure language subdirectories
3454 AC_CONFIG_FILES($all_outputs)
3455
3456 AC_CONFIG_COMMANDS([default],
3457 [
3458 case ${CONFIG_HEADERS} in
3459   *auto-host.h:config.in*)
3460   echo > cstamp-h ;;
3461 esac
3462 # Make sure all the subdirs exist.
3463 for d in $subdirs doc build
3464 do
3465     test -d $d || mkdir $d
3466 done
3467 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3468 # bootstrapping and the installation procedure can still use
3469 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3470 # FLAGS_TO_PASS has been modified to solve the problem there.
3471 # This is virtually a duplicate of what happens in configure.lang; we do
3472 # an extra check to make sure this only happens if ln -s can be used.
3473 case "$LN_S" in
3474   *-s*)
3475     for d in ${subdirs} ; do
3476         STARTDIR=`${PWDCMD-pwd}`
3477         cd $d
3478         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3479         do
3480                 rm -f $t
3481                 $LN_S ../$t $t 2>/dev/null
3482         done
3483         cd $STARTDIR
3484     done
3485   ;;
3486 esac
3487 ],
3488 [subdirs='$subdirs'])
3489 AC_OUTPUT