gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144 changequote(<<, >>)dnl
 145     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/$libstdcxx_incdir"
 146 changequote([, ])dnl
 147   fi
 148 fi
 149
 150 AC_ARG_WITH(cpp_install_dir,
 151 [  --with-cpp-install-dir=DIR
 152                           install the user visible C preprocessor in DIR
 153                           (relative to PREFIX) as well as PREFIX/bin],
 154 [if test x$withval = xyes; then
 155   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 156 elif test x$withval != xno; then
 157   cpp_install_dir=$withval
 158 fi])
 159
 160 # We would like to our source tree to be readonly.  However when releases or
 161 # pre-releases are generated, the flex/bison generated files as well as the
 162 # various formats of manuals need to be included along with the rest of the
 163 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 164 # just that.
 165
 166 AC_MSG_CHECKING([whether to place generated files in the source directory])
 167   dnl generated-files-in-srcdir is disabled by default
 168   AC_ARG_ENABLE(generated-files-in-srcdir,
 169 [  --enable-generated-files-in-srcdir
 170                           put copies of generated files in source dir
 171                           intended for creating source tarballs for users
 172                           without texinfo bison or flex.],
 173       generated_files_in_srcdir=$enableval,
 174       generated_files_in_srcdir=no)
 175
 176 AC_MSG_RESULT($generated_files_in_srcdir)
 177
 178 if test "$generated_files_in_srcdir" = "yes"; then
 179   GENINSRC=''
 180 else
 181   GENINSRC='#'
 182 fi
 183 AC_SUBST(GENINSRC)
 184
 185 # -------------------
 186 # Find default linker
 187 # -------------------
 188
 189 # With GNU ld
 190 AC_ARG_WITH(gnu-ld,
 191 [  --with-gnu-ld           arrange to work with GNU ld.],
 192 gnu_ld_flag="$with_gnu_ld",
 193 gnu_ld_flag=no)
 194
 195 # With pre-defined ld
 196 AC_ARG_WITH(ld,
 197 [  --with-ld               arrange to use the specified ld (full pathname)],
 198 DEFAULT_LINKER="$with_ld")
 199 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 200   if test ! -x "$DEFAULT_LINKER"; then
 201     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 202   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 203     gnu_ld_flag=yes
 204   fi
 205   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 206         [Define to enable the use of a default linker.])
 207 fi
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 AC_MSG_CHECKING([whether a default assembler was specified])
 250 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 251   if test x"$gas_flag" = x"no"; then
 252     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 253   else
 254     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 255   fi
 256 else
 257   AC_MSG_RESULT(no)
 258 fi
 259
 260 # ---------------
 261 # Find C compiler
 262 # ---------------
 263
 264 # If a non-executable a.out is present (e.g. created by GNU as above even if
 265 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 266 # file, even when creating an executable, so an execution test fails.
 267 # Remove possible default executable files to avoid this.
 268 #
 269 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 270 # Autoconf includes it.
 271 rm -f a.out a.exe b.out
 272
 273 # Find the native compiler
 274 AC_PROG_CC
 275 AM_PROG_CC_C_O
 276 # autoconf is lame and doesn't give us any substitution variable for this.
 277 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 278   NO_MINUS_C_MINUS_O=yes
 279 else
 280   OUTPUT_OPTION='-o $@'
 281 fi
 282 AC_SUBST(NO_MINUS_C_MINUS_O)
 283 AC_SUBST(OUTPUT_OPTION)
 284
 285 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 286 # optimizations to be activated explicitly by the toplevel.
 287 case "$CC" in
 288   */prev-gcc/xgcc*) ;;
 289   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 290 esac
 291 AC_SUBST(CFLAGS)
 292
 293 # -------------------------
 294 # Check C compiler features
 295 # -------------------------
 296
 297 AC_PROG_CPP
 298 AC_C_INLINE
 299
 300 # sizeof(char) is 1 by definition.
 301 AC_CHECK_SIZEOF(void *)
 302 AC_CHECK_SIZEOF(short)
 303 AC_CHECK_SIZEOF(int)
 304 AC_CHECK_SIZEOF(long)
 305 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 306 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 307
 308 # ---------------------
 309 # Warnings and checking
 310 # ---------------------
 311
 312 # Check $CC warning features (if it's GCC).
 313 # We want to use -pedantic, but we don't want warnings about
 314 # * 'long long'
 315 # * variadic macros
 316 # * overlong strings
 317 # So, we only use -pedantic if we can disable those warnings.
 318
 319 AC_CACHE_CHECK(
 320   [whether ${CC} accepts -Wno-long-long],
 321   [ac_cv_prog_cc_w_no_long_long],
 322   [save_CFLAGS="$CFLAGS"
 323   CFLAGS="-Wno-long-long"
 324   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 325                     [ac_cv_prog_cc_w_no_long_long=yes],
 326                     [ac_cv_prog_cc_w_no_long_long=no])
 327   CFLAGS="$save_CFLAGS"
 328   ])
 329
 330 AC_CACHE_CHECK(
 331   [whether ${CC} accepts -Wno-variadic-macros],
 332   [ac_cv_prog_cc_w_no_variadic_macros],
 333   [save_CFLAGS="$CFLAGS"
 334   CFLAGS="-Wno-variadic-macros"
 335   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 336                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 337                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 338   CFLAGS="$save_CFLAGS"
 339   ])
 340
 341 AC_CACHE_CHECK(
 342   [whether ${CC} accepts -Wno-overlength-strings],
 343   [ac_cv_prog_cc_w_no_overlength_strings],
 344   [save_CFLAGS="$CFLAGS"
 345   CFLAGS="-Wno-overlength-strings"
 346   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 347                     [ac_cv_prog_cc_w_no_overlength_strings=yes],
 348                     [ac_cv_prog_cc_w_no_overlength_strings=no])
 349   CFLAGS="$save_CFLAGS"
 350   ])
 351
 352 strict1_warn=
 353 if test $ac_cv_prog_cc_w_no_long_long = yes \
 354    && test $ac_cv_prog_cc_w_no_variadic_macros = yes \
 355    && test $ac_cv_prog_cc_w_no_overlength_strings = yes ; then
 356   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros -Wno-overlength-strings"
 357 fi
 358
 359 # Add -Wold-style-definition if it's accepted
 360 AC_CACHE_CHECK(
 361   [whether ${CC} accepts -Wold-style-definition],
 362   [ac_cv_prog_cc_w_old_style_definition],
 363   [save_CFLAGS="$CFLAGS"
 364   CFLAGS="-Wold-style-definition"
 365   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 366                     [ac_cv_prog_cc_w_old_style_definition=yes],
 367                     [ac_cv_prog_cc_w_old_style_definition=no])
 368   CFLAGS="$save_CFLAGS"
 369   ])
 370 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 371   strict1_warn="${strict1_warn} -Wold-style-definition"
 372 fi
 373
 374 # Add -Wmissing-format-attribute if it's accepted
 375 AC_CACHE_CHECK(
 376   [whether ${CC} accepts -Wmissing-format-attribute],
 377   [ac_cv_prog_cc_w_missing_format_attribute],
 378   [save_CFLAGS="$CFLAGS"
 379   CFLAGS="-Wmissing-format-attribute"
 380   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 381                     [ac_cv_prog_cc_w_missing_format_attribute=yes],
 382                     [ac_cv_prog_cc_w_missing_format_attribute=no])
 383   CFLAGS="$save_CFLAGS"
 384   ])
 385 if test $ac_cv_prog_cc_w_missing_format_attribute = yes ; then
 386   strict1_warn="${strict1_warn} -Wmissing-format-attribute"
 387 fi
 388
 389 # Enable -Werror, period.
 390 AC_ARG_ENABLE(werror_always,
 391 [  --enable-werror-always         enable -Werror always], [],
 392 [enable_werror_always=no])
 393 if test x${enable_werror_always} = xyes ; then
 394   strict1_warn="${strict1_warn} -Werror"
 395   WERROR=-Werror
 396 fi
 397
 398 AC_SUBST(strict1_warn)
 399
 400 # Get C++ compatibility warning flag, if supported.
 401 AC_CACHE_CHECK(
 402   [whether ${CC} accepts -Wc++-compat],
 403   [ac_cv_prog_cc_w_cxx_compat],
 404   [save_CFLAGS="$CFLAGS"
 405   CFLAGS="-Wc++-compat"
 406   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 407                     [ac_cv_prog_cc_w_cxx_compat=yes],
 408                     [ac_cv_prog_cc_w_cxx_compat=no])
 409   CFLAGS="$save_CFLAGS"
 410   ])
 411 if test x${ac_cv_prog_cc_w_cxx_compat} = xyes; then
 412   cxx_compat_warn="-Wc++-compat"
 413 fi
 414 AC_SUBST(cxx_compat_warn)
 415
 416
 417 # If the native compiler is GCC, we can enable warnings even in stage1.
 418 # That's useful for people building cross-compilers, or just running a
 419 # quick `make'.
 420 warn_cflags=
 421 if test "x$GCC" = "xyes"; then
 422   warn_cflags='$(GCC_WARN_CFLAGS)'
 423 fi
 424 AC_SUBST(warn_cflags)
 425
 426 # Enable -Werror in bootstrap stage2 and later.
 427 is_release=
 428 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 429   is_release=yes
 430 fi
 431 AC_ARG_ENABLE(werror,
 432 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 433 [if test x$is_release = x ; then
 434   # Default to "yes" on development branches.
 435   enable_werror=yes
 436 else
 437   # Default to "no" on release branches.
 438   enable_werror=no
 439 fi])
 440 if test x$enable_werror = xyes ; then
 441   WERROR=-Werror
 442 fi
 443 AC_SUBST(WERROR)
 444
 445 # Enable expensive internal checks
 446 AC_ARG_ENABLE(checking,
 447 [  --enable-checking[=LIST]
 448                           enable expensive run-time checks.  With LIST,
 449                           enable only specific categories of checks.
 450                           Categories are: yes,no,all,none,release.
 451                           Flags are: assert,fold,gc,gcac,misc,
 452                           rtlflag,rtl,runtime,tree,valgrind.],
 453 [ac_checking_flags="${enableval}"],[
 454 # Determine the default checks.
 455 if test x$is_release = x ; then
 456   ac_checking_flags=yes
 457 else
 458   ac_checking_flags=release
 459 fi])
 460 ac_assert_checking=1
 461 ac_checking=
 462 ac_fold_checking=
 463 ac_gc_checking=
 464 ac_gc_always_collect=
 465 ac_rtl_checking=
 466 ac_rtlflag_checking=
 467 ac_runtime_checking=1
 468 ac_tree_checking=
 469 ac_valgrind_checking=
 470 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 471 for check in $ac_checking_flags
 472 do
 473         case $check in
 474         # these set all the flags to specific states
 475         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 476                         ac_fold_checking= ; ac_gc_checking=1 ;
 477                         ac_gc_always_collect= ; ac_rtl_checking= ;
 478                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 479                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 480         no|none)        ac_assert_checking= ; ac_checking= ;
 481                         ac_fold_checking= ; ac_gc_checking= ;
 482                         ac_gc_always_collect= ; ac_rtl_checking= ;
 483                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 484                         ac_tree_checking= ; ac_valgrind_checking= ;;
 485         all)            ac_assert_checking=1 ; ac_checking=1 ;
 486                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 487                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 488                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 489                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 490         release)        ac_assert_checking=1 ; ac_checking= ;
 491                         ac_fold_checking= ; ac_gc_checking= ;
 492                         ac_gc_always_collect= ; ac_rtl_checking= ;
 493                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 494                         ac_tree_checking= ; ac_valgrind_checking= ;;
 495         # these enable particular checks
 496         assert)         ac_assert_checking=1 ;;
 497         fold)           ac_fold_checking=1 ;;
 498         gc)             ac_gc_checking=1 ;;
 499         gcac)           ac_gc_always_collect=1 ;;
 500         misc)           ac_checking=1 ;;
 501         rtl)            ac_rtl_checking=1 ;;
 502         rtlflag)        ac_rtlflag_checking=1 ;;
 503         runtime)        ac_runtime_checking=1 ;;
 504         tree)           ac_tree_checking=1 ;;
 505         valgrind)       ac_valgrind_checking=1 ;;
 506         *)      AC_MSG_ERROR(unknown check category $check) ;;
 507         esac
 508 done
 509 IFS="$ac_save_IFS"
 510
 511 nocommon_flag=""
 512 if test x$ac_checking != x ; then
 513   AC_DEFINE(ENABLE_CHECKING, 1,
 514 [Define if you want more run-time sanity checks.  This one gets a grab
 515    bag of miscellaneous but relatively cheap checks.])
 516   nocommon_flag=-fno-common
 517 fi
 518 AC_SUBST(nocommon_flag)
 519 if test x$ac_assert_checking != x ; then
 520   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 521 [Define if you want assertions enabled.  This is a cheap check.])
 522 fi
 523 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 524 if test x$ac_runtime_checking != x ; then
 525   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 526 [Define if you want runtime assertions enabled.  This is a cheap check.])
 527 fi
 528 if test x$ac_tree_checking != x ; then
 529   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 530 [Define if you want all operations on trees (the basic data
 531    structure of the front ends) to be checked for dynamic type safety
 532    at runtime.  This is moderately expensive.  The tree browser debugging
 533    routines will also be enabled by this option.
 534    ])
 535   TREEBROWSER=tree-browser.o
 536 fi
 537 AC_SUBST(TREEBROWSER)
 538 if test x$ac_rtl_checking != x ; then
 539   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 540 [Define if you want all operations on RTL (the basic data structure
 541    of the optimizer and back end) to be checked for dynamic type safety
 542    at runtime.  This is quite expensive.])
 543 fi
 544 if test x$ac_rtlflag_checking != x ; then
 545   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 546 [Define if you want RTL flag accesses to be checked against the RTL
 547    codes that are supported for each access macro.  This is relatively
 548    cheap.])
 549 fi
 550 if test x$ac_gc_checking != x ; then
 551   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 552 [Define if you want the garbage collector to do object poisoning and
 553    other memory allocation checks.  This is quite expensive.])
 554 fi
 555 if test x$ac_gc_always_collect != x ; then
 556   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 557 [Define if you want the garbage collector to operate in maximally
 558    paranoid mode, validating the entire heap and collecting garbage at
 559    every opportunity.  This is extremely expensive.])
 560 fi
 561 if test x$ac_fold_checking != x ; then
 562   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 563 [Define if you want fold checked that it never destructs its argument.
 564    This is quite expensive.])
 565 fi
 566 valgrind_path_defines=
 567 valgrind_command=
 568
 569 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 570 dnl # an if statement.  This was the source of very frustrating bugs
 571 dnl # in converting to autoconf 2.5x!
 572 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 573
 574 if test x$ac_valgrind_checking != x ; then
 575   # It is certainly possible that there's valgrind but no valgrind.h.
 576   # GCC relies on making annotations so we must have both.
 577   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 578   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 579     [[#include <valgrind/memcheck.h>
 580 #ifndef VALGRIND_DISCARD
 581 #error VALGRIND_DISCARD not defined
 582 #endif]])],
 583   [gcc_cv_header_valgrind_memcheck_h=yes],
 584   [gcc_cv_header_valgrind_memcheck_h=no])
 585   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 586   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 587   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 588     [[#include <memcheck.h>
 589 #ifndef VALGRIND_DISCARD
 590 #error VALGRIND_DISCARD not defined
 591 #endif]])],
 592   [gcc_cv_header_memcheck_h=yes],
 593   [gcc_cv_header_memcheck_h=no])
 594   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 595   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 596         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 597   if test "x$valgrind_path" = "x" \
 598     || (test $have_valgrind_h = no \
 599         && test $gcc_cv_header_memcheck_h = no \
 600         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 601         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 602   fi
 603   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 604   valgrind_command="$valgrind_path -q"
 605   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 606 [Define if you want to run subprograms and generated programs
 607    through valgrind (a memory checker).  This is extremely expensive.])
 608   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 609     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 610         [Define if valgrind's valgrind/memcheck.h header is installed.])
 611   fi
 612   if test $gcc_cv_header_memcheck_h = yes; then
 613     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 614         [Define if valgrind's memcheck.h header is installed.])
 615   fi
 616 fi
 617 AC_SUBST(valgrind_path_defines)
 618 AC_SUBST(valgrind_command)
 619
 620 AC_ARG_ENABLE(mapped-location,
 621 [  --enable-mapped-location   location_t is fileline integer cookie],,
 622 enable_mapped_location=no)
 623
 624 if test "$enable_mapped_location" = yes ; then
 625   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 626 [Define if location_t is fileline integer cookie.])
 627 fi
 628
 629 # Enable code coverage collection
 630 AC_ARG_ENABLE(coverage,
 631 [  --enable-coverage[=LEVEL]
 632                           enable compiler's code coverage collection.
 633                           Use to measure compiler performance and locate
 634                           unused parts of the compiler. With LEVEL, specify
 635                           optimization. Values are opt, noopt,
 636                           default is noopt],
 637 [case "${enableval}" in
 638   yes|noopt)
 639     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 640     ;;
 641   opt)
 642     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 643     ;;
 644   no)
 645     # a.k.a. --disable-coverage
 646     coverage_flags=""
 647     ;;
 648   *)
 649     AC_MSG_ERROR(unknown coverage setting $enableval)
 650     ;;
 651 esac],
 652 [coverage_flags=""])
 653 AC_SUBST(coverage_flags)
 654
 655 AC_ARG_ENABLE(gather-detailed-mem-stats,
 656 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 657 [enable_gather_detailed_mem_stats=no])
 658 if test x$enable_gather_detailed_mem_stats = xyes ; then
 659   AC_DEFINE(GATHER_STATISTICS, 1,
 660         [Define to enable detailed memory allocation stats gathering.])
 661 fi
 662
 663 # -------------------------------
 664 # Miscenalleous configure options
 665 # -------------------------------
 666
 667 # With stabs
 668 AC_ARG_WITH(stabs,
 669 [  --with-stabs            arrange to use stabs instead of host debug format],
 670 stabs="$with_stabs",
 671 stabs=no)
 672
 673 # Determine whether or not multilibs are enabled.
 674 AC_ARG_ENABLE(multilib,
 675 [  --enable-multilib       enable library support for multiple ABIs],
 676 [], [enable_multilib=yes])
 677 AC_SUBST(enable_multilib)
 678
 679 # Enable __cxa_atexit for C++.
 680 AC_ARG_ENABLE(__cxa_atexit,
 681 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 682 [], [])
 683
 684 # Enable C extension for decimal float if target supports it.
 685 AC_ARG_ENABLE(decimal-float,
 686 [  --enable-decimal-float  enable decimal float extension to C],
 687 [
 688   if test x$enablevar = xyes ; then
 689     case $target in
 690     powerpc*-*-linux* | i?86*-*-linux*)
 691       enable_decimal_float=yes
 692       ;;
 693     *)
 694       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 695       enable_decimal_float=no
 696       ;;
 697     esac
 698   fi
 699 ], [enable_decimal_float=no])
 700
 701 AC_SUBST(enable_decimal_float)
 702
 703 dfp=`if test $enable_decimal_float = yes; then echo 1; else echo 0; fi`
 704 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 705 [Define to 1 to enable decimal float extension to C.])
 706
 707 # Enable threads
 708 # Pass with no value to take the default
 709 # Pass with a value to specify a thread package
 710 AC_ARG_ENABLE(threads,
 711 [  --enable-threads        enable thread usage for target GCC
 712   --enable-threads=LIB    use LIB thread package for target GCC],,
 713 [enable_threads=''])
 714
 715 AC_ARG_ENABLE(tls,
 716 [  --enable-tls            enable or disable generation of tls code
 717                           overriding the assembler check for tls support],
 718 [
 719   case $enable_tls in
 720     yes | no) ;;
 721     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 722 Valid choices are 'yes' and 'no'.]) ;;
 723   esac
 724 ], [enable_tls=''])
 725
 726 AC_ARG_ENABLE(objc-gc,
 727 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 728                           the GNU Objective-C runtime],
 729 if test x$enable_objc_gc = xno; then
 730         objc_boehm_gc=''
 731 else
 732         objc_boehm_gc=1
 733 fi,
 734 objc_boehm_gc='')
 735
 736 AC_ARG_WITH(dwarf2,
 737 [  --with-dwarf2           force the default debug format to be DWARF 2],
 738 dwarf2="$with_dwarf2",
 739 dwarf2=no)
 740
 741 AC_ARG_ENABLE(shared,
 742 [  --disable-shared        don't provide a shared libgcc],
 743 [
 744   case $enable_shared in
 745   yes | no) ;;
 746   *)
 747     enable_shared=no
 748     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 749     for pkg in $enableval; do
 750       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 751         enable_shared=yes
 752       fi
 753     done
 754     IFS="$ac_save_ifs"
 755     ;;
 756   esac
 757 ], [enable_shared=yes])
 758 AC_SUBST(enable_shared)
 759
 760 AC_ARG_WITH(build-sysroot,
 761   [  --with-build-sysroot=sysroot
 762                           use sysroot as the system root during the build])
 763
 764 AC_ARG_WITH(sysroot,
 765 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 766 [
 767  case ${with_sysroot} in
 768  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 769  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 770  esac
 771
 772  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 773  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 774
 775  if test "x$exec_prefix" = xNONE; then
 776   if test "x$prefix" = xNONE; then
 777    test_prefix=/usr/local
 778   else
 779    test_prefix=$prefix
 780   fi
 781  else
 782   test_prefix=$exec_prefix
 783  fi
 784  case ${TARGET_SYSTEM_ROOT} in
 785  "${test_prefix}"|"${test_prefix}/"*|\
 786  '${exec_prefix}'|'${exec_prefix}/'*)
 787    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 788    TARGET_SYSTEM_ROOT_DEFINE="$t"
 789    ;;
 790  esac
 791 ], [
 792  TARGET_SYSTEM_ROOT=
 793  TARGET_SYSTEM_ROOT_DEFINE=
 794  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 795 ])
 796 AC_SUBST(TARGET_SYSTEM_ROOT)
 797 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 798 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 799
 800 # Build with intermodule optimisations
 801 AC_ARG_ENABLE(intermodule,
 802 [  --enable-intermodule    build the compiler in one step],
 803 [case ${enable_intermodule} in
 804   yes) onestep="-onestep";;
 805   *) onestep="";;
 806 esac],
 807 [onestep=""])
 808 AC_SUBST(onestep)
 809
 810 # Sanity check enable_languages in case someone does not run the toplevel
 811 # configure # script.
 812 AC_ARG_ENABLE(languages,
 813 [  --enable-languages=LIST specify which front-ends to build],
 814 [case ,${enable_languages}, in
 815        ,,|,yes,)
 816                 # go safe -- we cannot be much sure without the toplevel
 817                 # configure's
 818                 # analysis of which target libs are present and usable
 819                 enable_languages=c
 820                 ;;
 821          *,all,*)
 822                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 823                 ;;
 824         *,c,*)
 825                 ;;
 826         *)
 827                 enable_languages=c,${enable_languages}
 828                 ;;
 829 esac],
 830 [enable_languages=c])
 831
 832 # Used by documentation targets
 833 AC_SUBST(datarootdir)
 834 AC_SUBST(docdir)
 835 AC_SUBST(htmldir)
 836
 837 # -------------------------
 838 # Checks for other programs
 839 # -------------------------
 840
 841 AC_PROG_MAKE_SET
 842
 843 # Find some useful tools
 844 AC_PROG_AWK
 845 # We need awk to create options.c and options.h.
 846 # Bail out if it's missing.
 847 case ${AWK} in
 848   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 849 esac
 850
 851 gcc_AC_PROG_LN_S
 852 ACX_PROG_LN($LN_S)
 853 AC_PROG_RANLIB
 854 case "${host}" in
 855 *-*-darwin*)
 856   # By default, the Darwin ranlib will not treat common symbols as
 857   # definitions when  building the archive table of contents.  Other
 858   # ranlibs do that; pass an option to the Darwin ranlib that makes
 859   # it behave similarly.
 860   ranlib_flags="-c"
 861   ;;
 862 *)
 863   ranlib_flags=""
 864 esac
 865 AC_SUBST(ranlib_flags)
 866
 867 gcc_AC_PROG_INSTALL
 868
 869 # See if cmp has --ignore-initial.
 870 gcc_AC_PROG_CMP_IGNORE_INITIAL
 871
 872 # See if we have the mktemp command.
 873 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 874
 875 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 876
 877 # See if makeinfo has been installed and is modern enough
 878 # that we can use it.
 879 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 880   [GNU texinfo.* \([0-9][0-9.]*\)],
 881   [4.[4-9]*])
 882 if test $gcc_cv_prog_makeinfo_modern = no; then
 883   MAKEINFO="$MISSING makeinfo"
 884   AC_MSG_WARN([
 885 *** Makeinfo is missing or too old.
 886 *** Info documentation will not be built.])
 887   BUILD_INFO=
 888 else
 889   BUILD_INFO=info
 890 fi
 891 AC_SUBST(BUILD_INFO)
 892
 893 # Is pod2man recent enough to regenerate manpages?
 894 AC_MSG_CHECKING([for recent Pod::Man])
 895 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 896   AC_MSG_RESULT(yes)
 897   GENERATED_MANPAGES=generated-manpages
 898 else
 899   AC_MSG_RESULT(no)
 900   GENERATED_MANPAGES=
 901 fi
 902 AC_SUBST(GENERATED_MANPAGES)
 903
 904 # How about lex?
 905 dnl Don't use AC_PROG_LEX; we insist on flex.
 906 dnl LEXLIB is not useful in gcc.
 907 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 908
 909 # Bison?
 910 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 911
 912 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 913 # check for build == host before using them.
 914
 915 # NM
 916 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 917   && test -d ../binutils ; then
 918   NM='$(objdir)/../binutils/nm-new'
 919 else
 920   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 921 fi
 922
 923 # AR
 924 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 925   && test -d ../binutils ; then
 926   AR='$(objdir)/../binutils/ar'
 927 else
 928   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 929 fi
 930
 931
 932 # --------------------
 933 # Checks for C headers
 934 # --------------------
 935
 936 AC_MSG_CHECKING(for GNU C library)
 937 AC_CACHE_VAL(gcc_cv_glibc,
 938 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 939   [[#include <features.h>]], [[
 940 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 941 #error Not a GNU C library system
 942 #endif]])],
 943   [gcc_cv_glibc=yes],
 944   [gcc_cv_glibc=no])])
 945 AC_MSG_RESULT($gcc_cv_glibc)
 946 if test $gcc_cv_glibc = yes; then
 947   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 948 fi
 949
 950 # Need to reject headers which give warnings, so that the -Werror bootstrap
 951 # works later. *sigh*  This needs to come before all header checks.
 952 AC_PROG_CPP_WERROR
 953
 954 AC_HEADER_STDC
 955 AC_HEADER_TIME
 956 ACX_HEADER_STRING
 957 AC_HEADER_SYS_WAIT
 958 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 959                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 960                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 961                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 962
 963 # Check for thread headers.
 964 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 965 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 966
 967 # These tests can't be done till we know if we have limits.h.
 968 gcc_AC_C_CHAR_BIT
 969 AC_C_BIGENDIAN
 970
 971 # --------
 972 # UNSORTED
 973 # --------
 974
 975 # Stage specific cflags for build.
 976 stage1_cflags=
 977 case $build in
 978 vax-*-*)
 979   if test x$GCC = xyes
 980   then
 981     stage1_cflags="-Wa,-J"
 982   else
 983     stage1_cflags="-J"
 984   fi
 985   ;;
 986 powerpc*-*-darwin*)
 987   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 988   # sources; use -no-cpp-precomp to get to GNU cpp.
 989   # Apple's GCC has bugs in designated initializer handling, so disable
 990   # that too.
 991   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 992   ;;
 993 esac
 994 AC_SUBST(stage1_cflags)
 995
 996 # These libraries may be used by collect2.
 997 # We may need a special search path to get them linked.
 998 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 999 [save_LIBS="$LIBS"
1000 for libs in '' -lld -lmld \
1001                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1002                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1003 do
1004         LIBS="$libs"
1005         AC_TRY_LINK_FUNC(ldopen,
1006                 [gcc_cv_collect2_libs="$libs"; break])
1007 done
1008 LIBS="$save_LIBS"
1009 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1010 case $gcc_cv_collect2_libs in
1011         "none required")        ;;
1012         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1013 esac
1014 AC_SUBST(COLLECT2_LIBS)
1015
1016 # When building Ada code on Alpha, we need exc_resume which is usually in
1017 # -lexc.  So test for it.
1018 save_LIBS="$LIBS"
1019 LIBS=
1020 AC_SEARCH_LIBS(exc_resume, exc)
1021 GNAT_LIBEXC="$LIBS"
1022 LIBS="$save_LIBS"
1023 AC_SUBST(GNAT_LIBEXC)
1024
1025 # Some systems put ldexp and frexp in libm instead of libc; assume
1026 # they're both in the same place.  jcf-dump needs them.
1027 save_LIBS="$LIBS"
1028 LIBS=
1029 AC_SEARCH_LIBS(ldexp, m)
1030 LDEXP_LIB="$LIBS"
1031 LIBS="$save_LIBS"
1032 AC_SUBST(LDEXP_LIB)
1033
1034 # Use <inttypes.h> only if it exists,
1035 # doesn't clash with <sys/types.h>, and declares intmax_t.
1036 AC_MSG_CHECKING(for inttypes.h)
1037 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1038 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1039 [[#include <sys/types.h>
1040 #include <inttypes.h>]],
1041   [[intmax_t i = -1;]])],
1042   [gcc_cv_header_inttypes_h=yes],
1043   [gcc_cv_header_inttypes_h=no])])
1044 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1045 if test $gcc_cv_header_inttypes_h = yes; then
1046   AC_DEFINE(HAVE_INTTYPES_H, 1,
1047         [Define if you have a working <inttypes.h> header file.])
1048 fi
1049
1050 dnl Disabled until we have a complete test for buggy enum bitfields.
1051 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1052
1053 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1054   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1055   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1056   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1057   putchar_unlocked putc_unlocked)
1058 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1059         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1060         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1061         gcc_UNLOCKED_FUNCS)
1062
1063 if test x$ac_cv_func_mbstowcs = xyes; then
1064   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1065 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1066 int main()
1067 {
1068   mbstowcs(0, "", 0);
1069   return 0;
1070 }]])],
1071     [gcc_cv_func_mbstowcs_works=yes],
1072     [gcc_cv_func_mbstowcs_works=no],
1073     [gcc_cv_func_mbstowcs_works=yes])])
1074   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1075     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1076   [Define this macro if mbstowcs does not crash when its
1077    first argument is NULL.])
1078   fi
1079 fi
1080
1081 AC_CHECK_TYPE(ssize_t, int)
1082
1083 # Try to determine the array type of the second argument of getgroups
1084 # for the target system (int or gid_t).
1085 AC_TYPE_GETGROUPS
1086 if test "${target}" = "${build}"; then
1087   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1088 else
1089   case "${target}" in
1090         # This condition may need some tweaking.  It should include all
1091         # targets where the array type of the second argument of getgroups
1092         # is int and the type of gid_t is not equivalent to int.
1093         *-*-sunos* | *-*-ultrix*)
1094                 TARGET_GETGROUPS_T=int
1095                 ;;
1096         *)
1097                 TARGET_GETGROUPS_T=gid_t
1098                 ;;
1099   esac
1100 fi
1101 AC_SUBST(TARGET_GETGROUPS_T)
1102
1103 gcc_AC_FUNC_MMAP_BLACKLIST
1104
1105 case "${host}" in
1106 *-*-*vms*)
1107   # Under VMS, vfork works very differently than on Unix. The standard test
1108   # won't work, and it isn't easily adaptable. It makes more sense to
1109   # just force it.
1110   ac_cv_func_vfork_works=yes
1111   ;;
1112 esac
1113 AC_FUNC_FORK
1114
1115 AM_ICONV
1116 # Until we have in-tree GNU iconv:
1117 LIBICONV_DEP=
1118 AC_SUBST(LIBICONV_DEP)
1119
1120 AM_LC_MESSAGES
1121
1122 AM_LANGINFO_CODESET
1123
1124 # We will need to find libiberty.h and ansidecl.h
1125 saved_CFLAGS="$CFLAGS"
1126 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1127 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1128         strsignal strstr strverscmp \
1129         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1130         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1131 #include "ansidecl.h"
1132 #include "system.h"])
1133
1134 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1135 #include "ansidecl.h"
1136 #include "system.h"
1137 #ifdef HAVE_SYS_RESOURCE_H
1138 #include <sys/resource.h>
1139 #endif
1140 ])
1141
1142 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1143 #include "ansidecl.h"
1144 #include "system.h"
1145 #ifdef HAVE_SYS_RESOURCE_H
1146 #include <sys/resource.h>
1147 #endif
1148 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1149 [Define to \`long' if <sys/resource.h> doesn't define.])])
1150
1151 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1152 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1153 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1154 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1155 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1156 #include "ansidecl.h"
1157 #include "system.h"
1158 #ifdef HAVE_LDFCN_H
1159 #undef FREAD
1160 #undef FWRITE
1161 #include <ldfcn.h>
1162 #endif
1163 ])
1164
1165 gcc_AC_CHECK_DECLS(times, , ,[
1166 #include "ansidecl.h"
1167 #include "system.h"
1168 #ifdef HAVE_SYS_TIMES_H
1169 #include <sys/times.h>
1170 #endif
1171 ])
1172
1173 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1174 #include "ansidecl.h"
1175 #include "system.h"
1176 #include <signal.h>
1177 ])
1178
1179 # More time-related stuff.
1180 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1181 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1182 #include "ansidecl.h"
1183 #include "system.h"
1184 #ifdef HAVE_SYS_TIMES_H
1185 #include <sys/times.h>
1186 #endif
1187 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1188 if test $ac_cv_struct_tms = yes; then
1189   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1190   [Define if <sys/times.h> defines struct tms.])
1191 fi
1192
1193 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1194 # revisit after autoconf 2.50.
1195 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1196 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1197 #include "ansidecl.h"
1198 #include "system.h"
1199 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1200 if test $gcc_cv_type_clock_t = yes; then
1201   AC_DEFINE(HAVE_CLOCK_T, 1,
1202   [Define if <time.h> defines clock_t.])
1203 fi
1204
1205 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1206 CFLAGS="$saved_CFLAGS"
1207
1208 gcc_AC_INITFINI_ARRAY
1209
1210 # mkdir takes a single argument on some systems.
1211 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1212
1213 # File extensions
1214 manext='.1'
1215 objext='.o'
1216 AC_SUBST(manext)
1217 AC_SUBST(objext)
1218
1219 # With Setjmp/Longjmp based exception handling.
1220 AC_ARG_ENABLE(sjlj-exceptions,
1221 [  --enable-sjlj-exceptions
1222                           arrange to use setjmp/longjmp exception handling],
1223 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1224 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1225   [Define 0/1 to force the choice for exception handling model.])])
1226
1227 # For platforms with the unwind ABI which includes an unwind library,
1228 # libunwind, we can choose to use the system libunwind.
1229 AC_ARG_WITH(system-libunwind,
1230 [  --with-system-libunwind use installed libunwind])
1231
1232 # config.gcc also contains tests of with_system_libunwind.
1233 if test x$with_system_libunwind = xyes; then
1234         AC_DEFINE(HAVE_GETIPINFO, 1,
1235 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1236 fi
1237
1238 # --------------------------------------------------------
1239 # Build, host, and target specific configuration fragments
1240 # --------------------------------------------------------
1241
1242 # Collect build-machine-specific information.
1243 . ${srcdir}/config.build
1244
1245 # Collect host-machine-specific information.
1246 . ${srcdir}/config.host
1247
1248 target_gtfiles=
1249
1250 # Collect target-machine-specific information.
1251 . ${srcdir}/config.gcc
1252
1253 extra_objs="${host_extra_objs} ${extra_objs}"
1254 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1255
1256 # Default the target-machine variables that were not explicitly set.
1257 if test x"$tm_file" = x
1258 then tm_file=$cpu_type/$cpu_type.h; fi
1259
1260 if test x"$extra_headers" = x
1261 then extra_headers=; fi
1262
1263 if test x$md_file = x
1264 then md_file=$cpu_type/$cpu_type.md; fi
1265
1266 if test x$out_file = x
1267 then out_file=$cpu_type/$cpu_type.c; fi
1268
1269 if test x"$tmake_file" = x
1270 then tmake_file=$cpu_type/t-$cpu_type
1271 fi
1272
1273 if test x"$dwarf2" = xyes
1274 then tm_file="$tm_file tm-dwarf2.h"
1275 fi
1276
1277 # Say what files are being used for the output code and MD file.
1278 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1279 echo "Using \`$srcdir/config/$md_file' as machine description file."
1280
1281 # If any of the xm_file variables contain nonexistent files, warn
1282 # about them and drop them.
1283
1284 bx=
1285 for x in $build_xm_file; do
1286   if    test -f $srcdir/config/$x
1287   then      bx="$bx $x"
1288   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1289   fi
1290 done
1291 build_xm_file="$bx"
1292
1293 hx=
1294 for x in $host_xm_file; do
1295   if    test -f $srcdir/config/$x
1296   then      hx="$hx $x"
1297   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1298   fi
1299 done
1300 host_xm_file="$hx"
1301
1302 tx=
1303 for x in $xm_file; do
1304   if    test -f $srcdir/config/$x
1305   then      tx="$tx $x"
1306   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1307   fi
1308 done
1309 xm_file="$tx"
1310
1311 count=a
1312 for f in $tm_file; do
1313         count=${count}x
1314 done
1315 if test $count = ax; then
1316         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1317 else
1318         echo "Using the following target machine macro files:"
1319         for f in $tm_file; do
1320                 echo "  $srcdir/config/$f"
1321         done
1322 fi
1323
1324 if test x$need_64bit_hwint = xyes; then
1325         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1326 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1327 fi
1328
1329 if test x$use_long_long_for_widest_fast_int = xyes; then
1330         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1331 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1332 efficiently supported by the host hardware.])
1333 fi
1334
1335 count=a
1336 for f in $host_xm_file; do
1337         count=${count}x
1338 done
1339 if test $count = a; then
1340         :
1341 elif test $count = ax; then
1342         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1343 else
1344         echo "Using the following host machine macro files:"
1345         for f in $host_xm_file; do
1346                 echo "  $srcdir/config/$f"
1347         done
1348 fi
1349 echo "Using ${out_host_hook_obj} for host machine hooks."
1350
1351 if test "$host_xm_file" != "$build_xm_file"; then
1352         count=a
1353         for f in $build_xm_file; do
1354                 count=${count}x
1355         done
1356         if test $count = a; then
1357                 :
1358         elif test $count = ax; then
1359                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1360         else
1361                 echo "Using the following build machine macro files:"
1362                 for f in $build_xm_file; do
1363                         echo "  $srcdir/config/$f"
1364                 done
1365         fi
1366 fi
1367
1368 case ${host} in
1369   powerpc*-*-darwin*)
1370     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1371       gcc_cv_mcontext_underscores,
1372       AC_COMPILE_IFELSE([
1373 #include <sys/signal.h>
1374 #include <ucontext.h>
1375 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1376 ],
1377         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1378       if test $gcc_cv_mcontext_underscores = yes; then
1379         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1380           [mcontext_t fields start with __])
1381       fi
1382     ;;
1383 esac
1384
1385 # ---------
1386 # Threading
1387 # ---------
1388
1389 # Check if a valid thread package
1390 case ${enable_threads} in
1391   "" | no)
1392     # No threads
1393     target_thread_file='single'
1394     ;;
1395   yes)
1396     # default
1397     target_thread_file='single'
1398     ;;
1399   aix | dce | gnat | irix | posix | posix95 | rtems | \
1400   single | solaris | vxworks | win32 )
1401     target_thread_file=${enable_threads}
1402     ;;
1403   *)
1404     echo "${enable_threads} is an unknown thread package" 1>&2
1405     exit 1
1406     ;;
1407 esac
1408
1409 if test x${thread_file} = x; then
1410   # No thread file set by target-specific clauses in config.gcc,
1411   # so use file chosen by default logic above
1412   thread_file=${target_thread_file}
1413 fi
1414
1415 # Make gthr-default.h if we have a thread file.
1416 gthread_flags=
1417 if test $thread_file != single; then
1418   rm -f gthr-default.h
1419   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1420   gthread_flags=-DHAVE_GTHR_DEFAULT
1421 fi
1422 AC_SUBST(gthread_flags)
1423
1424 # --------
1425 # UNSORTED
1426 # --------
1427
1428 use_cxa_atexit=no
1429 if test x$enable___cxa_atexit = xyes || \
1430    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1431   if test x$host = x$target; then
1432     case $host in
1433       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1434       # keyed to flag_use_cxa_atexit
1435       *-*-mingw32*)
1436         use_cxa_atexit=yes
1437         ;;
1438       *)
1439         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1440           [echo "__cxa_atexit can't be enabled on this target"])
1441         ;;
1442     esac
1443   else
1444     # We can't check for __cxa_atexit when building a cross, so assume
1445     # it is available
1446     use_cxa_atexit=yes
1447   fi
1448   if test x$use_cxa_atexit = xyes; then
1449     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1450       [Define if you want to use __cxa_atexit, rather than atexit, to
1451       register C++ destructors for local statics and global objects.
1452       This is essential for fully standards-compliant handling of
1453       destructors, but requires __cxa_atexit in libc.])
1454   fi
1455 fi
1456
1457 use_getipinfo=yes
1458 if test x$with_system_libunwind = xyes; then
1459    if test x$host = x$target; then
1460      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1461    fi
1462 fi
1463 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1464 if test x$use_getipinfo = xyes; then
1465    AC_DEFINE(HAVE_GETIPINFO, 1,
1466         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1467 else
1468    echo "The system unwind library does not support _Unwind_GetIPInfo."
1469 fi
1470
1471 # Look for a file containing extra machine modes.
1472 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1473   extra_modes_file='$(srcdir)'/config/${extra_modes}
1474   AC_SUBST(extra_modes_file)
1475   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1476   [Define to the name of a file containing a list of extra machine modes
1477    for this architecture.])
1478 fi
1479
1480 # Convert extra_options into a form suitable for Makefile use.
1481 extra_opt_files=
1482 for f in $extra_options; do
1483   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1484 done
1485 AC_SUBST(extra_opt_files)
1486
1487 # auto-host.h is the file containing items generated by autoconf and is
1488 # the first file included by config.h.
1489 # If host=build, it is correct to have bconfig include auto-host.h
1490 # as well.  If host!=build, we are in error and need to do more
1491 # work to find out the build config parameters.
1492 if test x$host = x$build
1493 then
1494         build_auto=auto-host.h
1495 else
1496         # We create a subdir, then run autoconf in the subdir.
1497         # To prevent recursion we set host and build for the new
1498         # invocation of configure to the build for this invocation
1499         # of configure.
1500         tempdir=build.$$
1501         rm -rf $tempdir
1502         mkdir $tempdir
1503         cd $tempdir
1504         case ${srcdir} in
1505         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1506         *) realsrcdir=../${srcdir};;
1507         esac
1508         saved_CFLAGS="${CFLAGS}"
1509         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1510         ${realsrcdir}/configure \
1511                 --enable-languages=${enable_languages-all} \
1512                 --target=$target_alias --host=$build_alias --build=$build_alias
1513         CFLAGS="${saved_CFLAGS}"
1514
1515         # We just finished tests for the build machine, so rename
1516         # the file auto-build.h in the gcc directory.
1517         mv auto-host.h ../auto-build.h
1518         cd ..
1519         rm -rf $tempdir
1520         build_auto=auto-build.h
1521 fi
1522 AC_SUBST(build_subdir)
1523
1524 tm_file="${tm_file} defaults.h"
1525 tm_p_file="${tm_p_file} tm-preds.h"
1526 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1527 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1528 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1529 # put this back in temporarily.
1530 xm_file="auto-host.h ansidecl.h ${xm_file}"
1531
1532 # --------
1533 # UNSORTED
1534 # --------
1535
1536 changequote(,)dnl
1537 # Compile in configure arguments.
1538 if test -f configargs.h ; then
1539         # Being re-configured.
1540         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1541         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1542 else
1543         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1544 fi
1545
1546 # Double all backslashes and backslash all quotes to turn
1547 # gcc_config_arguments into a C string.
1548 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1549 $gcc_config_arguments
1550 EOF
1551 gcc_config_arguments_str=`cat conftest.out`
1552 rm -f conftest.out
1553
1554 cat > configargs.h <<EOF
1555 /* Generated automatically. */
1556 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1557 static const char thread_model[] = "$thread_file";
1558
1559 static const struct {
1560   const char *name, *value;
1561 } configure_default_options[] = $configure_default_options;
1562 EOF
1563 changequote([,])dnl
1564
1565 # Internationalization
1566 ZW_GNU_GETTEXT_SISTER_DIR
1567
1568 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1569 # -liconv on the link line twice.
1570 case "$LIBINTL" in *$LIBICONV*)
1571         LIBICONV= ;;
1572 esac
1573
1574 AC_ARG_ENABLE(secureplt,
1575 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1576 [], [])
1577
1578 # Windows32 Registry support for specifying GCC installation paths.
1579 AC_ARG_ENABLE(win32-registry,
1580 [  --disable-win32-registry
1581                           disable lookup of installation paths in the
1582                           Registry on Windows hosts
1583   --enable-win32-registry enable registry lookup (default)
1584   --enable-win32-registry=KEY
1585                           use KEY instead of GCC version as the last portion
1586                           of the registry key],,)
1587
1588 case $host_os in
1589   win32 | pe | cygwin* | mingw32* | uwin*)
1590     if test "x$enable_win32_registry" != xno; then
1591       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1592     fi
1593
1594     if test "x$enable_win32_registry" != xno; then
1595       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1596   [Define to 1 if installation paths should be looked up in the Windows
1597    Registry. Ignored on non-Windows hosts.])
1598
1599       if test "x$enable_win32_registry" != xyes \
1600          && test "x$enable_win32_registry" != x; then
1601         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1602   [Define to be the last component of the Windows registry key under which
1603    to look for installation paths.  The full key used will be
1604    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1605    The default is the GCC version number.])
1606       fi
1607     fi
1608   ;;
1609 esac
1610
1611 # Get an absolute path to the GCC top-level source directory
1612 holddir=`${PWDCMD-pwd}`
1613 cd $srcdir
1614 topdir=`${PWDCMD-pwd}`
1615 cd $holddir
1616
1617 # Conditionalize the makefile for this host machine.
1618 xmake_file=
1619 for f in ${host_xmake_file}
1620 do
1621         if test -f ${srcdir}/config/$f
1622         then
1623                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1624         fi
1625 done
1626
1627 # Conditionalize the makefile for this target machine.
1628 tmake_file_=
1629 for f in ${tmake_file}
1630 do
1631         if test -f ${srcdir}/config/$f
1632         then
1633                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1634         fi
1635 done
1636 tmake_file="${tmake_file_}"
1637
1638 # If the host doesn't support symlinks, modify CC in
1639 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1640 # Otherwise, we can use "CC=$(CC)".
1641 rm -f symtest.tem
1642 case "$LN_S" in
1643         *-s*)
1644                 cc_set_by_configure="\$(CC)"
1645                 quoted_cc_set_by_configure="\$(CC)"
1646                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1647                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1648                 ;;
1649         *)
1650                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1651                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1652                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1653                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1654                 ;;
1655 esac
1656
1657 # This is a terrible hack which will go away some day.
1658 host_cc_for_libada=${CC}
1659 AC_SUBST(host_cc_for_libada)
1660
1661 out_object_file=`basename $out_file .c`.o
1662
1663 tm_file_list="options.h"
1664 tm_include_list="options.h"
1665 for f in $tm_file; do
1666   case $f in
1667     defaults.h )
1668        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1669        tm_include_list="${tm_include_list} $f"
1670        ;;
1671     * )
1672        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1673        tm_include_list="${tm_include_list} config/$f"
1674        ;;
1675   esac
1676 done
1677
1678 tm_p_file_list=
1679 tm_p_include_list=
1680 for f in $tm_p_file; do
1681   case $f in
1682     tm-preds.h )
1683        tm_p_file_list="${tm_p_file_list} $f"
1684        tm_p_include_list="${tm_p_include_list} $f"
1685        ;;
1686     * )
1687        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1688        tm_p_include_list="${tm_p_include_list} config/$f"
1689   esac
1690 done
1691
1692 xm_file_list=
1693 xm_include_list=
1694 for f in $xm_file; do
1695   case $f in
1696     ansidecl.h )
1697        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1698        xm_include_list="${xm_include_list} $f"
1699        ;;
1700     auto-host.h )
1701        xm_file_list="${xm_file_list} $f"
1702        xm_include_list="${xm_include_list} $f"
1703        ;;
1704     * )
1705        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1706        xm_include_list="${xm_include_list} config/$f"
1707        ;;
1708   esac
1709 done
1710
1711 host_xm_file_list=
1712 host_xm_include_list=
1713 for f in $host_xm_file; do
1714   case $f in
1715     ansidecl.h )
1716        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1717        host_xm_include_list="${host_xm_include_list} $f"
1718        ;;
1719     auto-host.h )
1720        host_xm_file_list="${host_xm_file_list} $f"
1721        host_xm_include_list="${host_xm_include_list} $f"
1722        ;;
1723     * )
1724        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1725        host_xm_include_list="${host_xm_include_list} config/$f"
1726        ;;
1727   esac
1728 done
1729
1730 build_xm_file_list=
1731 for f in $build_xm_file; do
1732   case $f in
1733     ansidecl.h )
1734        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1735        build_xm_include_list="${build_xm_include_list} $f"
1736        ;;
1737     auto-build.h | auto-host.h )
1738        build_xm_file_list="${build_xm_file_list} $f"
1739        build_xm_include_list="${build_xm_include_list} $f"
1740        ;;
1741     * )
1742        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1743        build_xm_include_list="${build_xm_include_list} config/$f"
1744        ;;
1745   esac
1746 done
1747
1748 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1749 # cross-compiler which does not use the native headers and libraries.
1750 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1751 CROSS=                                          AC_SUBST(CROSS)
1752 ALL=all.internal                                AC_SUBST(ALL)
1753 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1754
1755 if test "x$with_build_sysroot" != x; then
1756   build_system_header_dir=$with_build_sysroot'$(NATIVE_SYSTEM_HEADER_DIR)'
1757 else
1758   # This value is used, even on a native system, because
1759   # CROSS_SYSTEM_HEADER_DIR is just
1760   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1761   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1762 fi
1763
1764 if test x$host != x$target
1765 then
1766         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1767         ALL=all.cross
1768         SYSTEM_HEADER_DIR=$build_system_header_dir
1769         case "$host","$target" in
1770         # Darwin crosses can use the host system's libraries and headers,
1771         # because of the fat library support.  Of course, it must be the
1772         # same version of Darwin on both sides.  Allow the user to
1773         # just say --target=foo-darwin without a version number to mean
1774         # "the version on this system".
1775             *-*-darwin*,*-*-darwin*)
1776                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1777                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1778                 if test $hostos = $targetos -o $targetos = darwin ; then
1779                     CROSS=
1780                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1781                     with_headers=yes
1782                 fi
1783                 ;;
1784
1785             i?86-*-*,x86_64-*-* \
1786             | powerpc*-*-*,powerpc64*-*-*)
1787                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1788         esac
1789 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1790         SYSTEM_HEADER_DIR=$build_system_header_dir
1791 fi
1792
1793 # If this is a cross-compiler that does not
1794 # have its own set of headers then define
1795 # inhibit_libc
1796
1797 # If this is using newlib, without having the headers available now,
1798 # then define inhibit_libc in LIBGCC2_CFLAGS.
1799 # This prevents libgcc2 from containing any code which requires libc
1800 # support.
1801 inhibit_libc=false
1802 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1803        test x$with_newlib = xyes ; } &&
1804      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1805        inhibit_libc=true
1806 fi
1807 AC_SUBST(inhibit_libc)
1808
1809 # When building gcc with a cross-compiler, we need to adjust things so
1810 # that the generator programs are still built with the native compiler.
1811 # Also, we cannot run fixincludes or fix-header.
1812
1813 # These are the normal (build=host) settings:
1814 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1815 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1816 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1817
1818 # Possibly disable fixproto, on a per-target basis.
1819 case ${use_fixproto} in
1820   no)
1821     STMP_FIXPROTO=
1822     ;;
1823   yes)
1824     STMP_FIXPROTO=stmp-fixproto
1825     ;;
1826 esac
1827 AC_SUBST(STMP_FIXPROTO)
1828
1829 # And these apply if build != host, or we are generating coverage data
1830 if test x$build != x$host || test "x$coverage_flags" != x
1831 then
1832     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1833
1834     if test "x$TARGET_SYSTEM_ROOT" = x; then
1835         if test "x$STMP_FIXPROTO" != x; then
1836           STMP_FIXPROTO=stmp-install-fixproto
1837         fi
1838     fi
1839 fi
1840
1841 # Expand extra_headers to include complete path.
1842 # This substitutes for lots of t-* files.
1843 extra_headers_list=
1844 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1845 for file in ${extra_headers} ; do
1846   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1847 done
1848
1849 # Define collect2 in Makefile.
1850 case $host_can_use_collect2 in
1851   no) collect2= ;;
1852   *) collect2='collect2$(exeext)' ;;
1853 esac
1854 AC_SUBST([collect2])
1855
1856 # Add a definition of USE_COLLECT2 if system wants one.
1857 case $use_collect2 in
1858   no) use_collect2= ;;
1859   "") ;;
1860   *)
1861     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1862     xm_defines="${xm_defines} USE_COLLECT2"
1863     case $host_can_use_collect2 in
1864       no)
1865         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1866         ;;
1867     esac
1868     ;;
1869 esac
1870
1871 # ---------------------------
1872 # Assembler & linker features
1873 # ---------------------------
1874
1875 # Identify the assembler which will work hand-in-glove with the newly
1876 # built GCC, so that we can examine its features.  This is the assembler
1877 # which will be driven by the driver program.
1878 #
1879 # If build != host, and we aren't building gas in-tree, we identify a
1880 # build->target assembler and hope that it will have the same features
1881 # as the host->target assembler we'll be using.
1882 gcc_cv_gas_major_version=
1883 gcc_cv_gas_minor_version=
1884 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1885
1886 m4_pattern_allow([AS_FOR_TARGET])dnl
1887 AS_VAR_SET_IF(gcc_cv_as,, [
1888 if test -x "$DEFAULT_ASSEMBLER"; then
1889         gcc_cv_as="$DEFAULT_ASSEMBLER"
1890 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1891      && test -f ../gas/Makefile \
1892      && test x$build = x$host; then
1893         gcc_cv_as=../gas/as-new$build_exeext
1894 elif test -x as$build_exeext; then
1895         # Build using assembler in the current directory.
1896         gcc_cv_as=./as$build_exeext
1897 elif test -x $AS_FOR_TARGET; then
1898         gcc_cv_as="$AS_FOR_TARGET"
1899 else
1900         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1901 fi])
1902
1903 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1904 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1905
1906 AC_MSG_CHECKING(what assembler to use)
1907 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1908   # Single tree build which includes gas.  We want to prefer it
1909   # over whatever linker top-level may have detected, since
1910   # we'll use what we're building after installation anyway.
1911   AC_MSG_RESULT(newly built gas)
1912   in_tree_gas=yes
1913   _gcc_COMPUTE_GAS_VERSION
1914   in_tree_gas_is_elf=no
1915   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1916      || (grep 'obj_format = multi' ../gas/Makefile \
1917          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1918   then
1919     in_tree_gas_is_elf=yes
1920   fi
1921 else
1922   AC_MSG_RESULT($gcc_cv_as)
1923   in_tree_gas=no
1924 fi
1925
1926 # Identify the linker which will work hand-in-glove with the newly
1927 # built GCC, so that we can examine its features.  This is the linker
1928 # which will be driven by the driver program.
1929 #
1930 # If build != host, and we aren't building gas in-tree, we identify a
1931 # build->target linker and hope that it will have the same features
1932 # as the host->target linker we'll be using.
1933 gcc_cv_gld_major_version=
1934 gcc_cv_gld_minor_version=
1935 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1936 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1937
1938 AS_VAR_SET_IF(gcc_cv_ld,, [
1939 if test -x "$DEFAULT_LINKER"; then
1940         gcc_cv_ld="$DEFAULT_LINKER"
1941 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1942      && test -f ../ld/Makefile \
1943      && test x$build = x$host; then
1944         gcc_cv_ld=../ld/ld-new$build_exeext
1945 elif test -x collect-ld$build_exeext; then
1946         # Build using linker in the current directory.
1947         gcc_cv_ld=./collect-ld$build_exeext
1948 elif test -x $LD_FOR_TARGET; then
1949         gcc_cv_ld="$LD_FOR_TARGET"
1950 else
1951         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1952 fi])
1953
1954 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1955 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1956
1957 AC_MSG_CHECKING(what linker to use)
1958 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1959         # Single tree build which includes ld.  We want to prefer it
1960         # over whatever linker top-level may have detected, since
1961         # we'll use what we're building after installation anyway.
1962         AC_MSG_RESULT(newly built ld)
1963         in_tree_ld=yes
1964         in_tree_ld_is_elf=no
1965         if (grep 'EMUL = .*elf' ../ld/Makefile \
1966             || grep 'EMUL = .*linux' ../ld/Makefile \
1967             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1968           in_tree_ld_is_elf=yes
1969         fi
1970         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1971         do
1972 changequote(,)dnl
1973                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1974                 if test x$gcc_cv_gld_version != x; then
1975                         break
1976                 fi
1977         done
1978         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1979         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1980 changequote([,])dnl
1981 else
1982         AC_MSG_RESULT($gcc_cv_ld)
1983         in_tree_ld=no
1984 fi
1985
1986 # Figure out what nm we will be using.
1987 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1988 AS_VAR_SET_IF(gcc_cv_nm,, [
1989 if test -f $gcc_cv_binutils_srcdir/configure.in \
1990      && test -f ../binutils/Makefile \
1991      && test x$build = x$host; then
1992         gcc_cv_nm=../binutils/nm-new$build_exeext
1993 elif test -x nm$build_exeext; then
1994         gcc_cv_nm=./nm$build_exeext
1995 elif test -x $NM_FOR_TARGET; then
1996         gcc_cv_nm="$NM_FOR_TARGET"
1997 else
1998         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1999 fi])
2000
2001 AC_MSG_CHECKING(what nm to use)
2002 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2003         # Single tree build which includes binutils.
2004         AC_MSG_RESULT(newly built nm)
2005         in_tree_nm=yes
2006 else
2007         AC_MSG_RESULT($gcc_cv_nm)
2008         in_tree_nm=no
2009 fi
2010
2011 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2012 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2013
2014 # Figure out what objdump we will be using.
2015 AS_VAR_SET_IF(gcc_cv_objdump,, [
2016 if test -f $gcc_cv_binutils_srcdir/configure.in \
2017      && test -f ../binutils/Makefile \
2018      && test x$build = x$host; then
2019         # Single tree build which includes binutils.
2020         gcc_cv_objdump=../binutils/objdump$build_exeext
2021 elif test -x objdump$build_exeext; then
2022         gcc_cv_objdump=./objdump$build_exeext
2023 elif test -x $OBJDUMP_FOR_TARGET; then
2024         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2025 else
2026         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2027 fi])
2028
2029 AC_MSG_CHECKING(what objdump to use)
2030 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2031         # Single tree build which includes binutils.
2032         AC_MSG_RESULT(newly built objdump)
2033 elif test x$gcc_cv_objdump = x; then
2034         AC_MSG_RESULT(not found)
2035 else
2036         AC_MSG_RESULT($gcc_cv_objdump)
2037 fi
2038
2039 # Figure out what assembler alignment features are present.
2040 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2041  [2,6,0],,
2042 [.balign 4
2043 .p2align 2],,
2044 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2045   [Define if your assembler supports .balign and .p2align.])])
2046
2047 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2048  [2,8,0],,
2049  [.p2align 4,,7],,
2050 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2051   [Define if your assembler supports specifying the maximum number
2052    of bytes to skip when using the GAS .p2align command.])])
2053
2054 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2055  [elf,2,9,0],,
2056  [conftest_label1: .word 0
2057 .subsection -1
2058 conftest_label2: .word 0
2059 .previous],
2060  [if test x$gcc_cv_nm != x; then
2061     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2062     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2063     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2064     then :
2065     else gcc_cv_as_subsection_m1=yes
2066     fi
2067     rm -f conftest.nm1 conftest.nm2
2068   fi],
2069  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2070   [Define if your assembler supports .subsection and .subsection -1 starts
2071    emitting at the beginning of your section.])])
2072
2073 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2074  [2,2,0],,
2075  [      .weak foobar],,
2076 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2077
2078 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2079  [2,17,0],,
2080  [      .weakref foobar, barfnot],,
2081 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2082
2083 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2084  [2,15,91],,
2085  [      .SPACE $TEXT$
2086         .NSUBSPA $CODE$,COMDAT],,
2087 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2088
2089 # .hidden needs to be supported in both the assembler and the linker,
2090 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2091 # This is irritatingly difficult to feature test for; we have to check the
2092 # date string after the version number.  If we've got an in-tree
2093 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2094 # to be safe.
2095 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2096 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2097  [elf,2,13,0],,
2098 [       .hidden foobar
2099 foobar:])
2100
2101 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2102 [if test $in_tree_ld = yes ; then
2103   gcc_cv_ld_hidden=no
2104   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2105      && test $in_tree_ld_is_elf = yes; then
2106      gcc_cv_ld_hidden=yes
2107   fi
2108 else
2109   gcc_cv_ld_hidden=yes
2110   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2111   if echo "$ld_ver" | grep GNU > /dev/null; then
2112 changequote(,)dnl
2113     ld_vers=`echo $ld_ver | sed -n \
2114         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2115         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2116         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2117         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2118         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2119         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2120         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   -].*$,\1,p'`
2121     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2122     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2123     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2124     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2125     if test 0"$ld_date" -lt 20020404; then
2126       if test -n "$ld_date"; then
2127         # If there was date string, but was earlier than 2002-04-04, fail
2128         gcc_cv_ld_hidden=no
2129       elif test -z "$ld_vers"; then
2130         # If there was no date string nor ld version number, something is wrong
2131         gcc_cv_ld_hidden=no
2132       else
2133         test -z "$ld_vers_patch" && ld_vers_patch=0
2134         if test "$ld_vers_major" -lt 2; then
2135           gcc_cv_ld_hidden=no
2136         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2137           gcc_cv_ld_hidden="no"
2138         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2139           gcc_cv_ld_hidden=no
2140         fi
2141       fi
2142 changequote([,])dnl
2143     fi
2144   else
2145     case "${target}" in
2146       hppa64*-*-hpux* | ia64*-*-hpux*)
2147         gcc_cv_ld_hidden=yes
2148         ;;
2149       *)
2150         gcc_cv_ld_hidden=no
2151         ;;
2152     esac
2153   fi
2154 fi])
2155 libgcc_visibility=no
2156 AC_SUBST(libgcc_visibility)
2157 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2158 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2159   libgcc_visibility=yes
2160   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2161   [Define if your assembler and linker support .hidden.])
2162 fi
2163
2164 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2165 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2166   [elf,2,11,0],,
2167 [       .data
2168         .uleb128 L2 - L1
2169 L1:
2170         .uleb128 1280
2171         .sleb128 -1010
2172 L2:],
2173  [# GAS versions before 2.11 do not support uleb128,
2174   # despite appearing to.
2175   # ??? There exists an elf-specific test that will crash
2176   # the assembler.  Perhaps it's better to figure out whether
2177   # arbitrary sections are supported and try the test.
2178   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2179   if echo "$as_ver" | grep GNU > /dev/null; then
2180 changequote(,)dnl
2181     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2182     as_major=`echo $as_ver | sed 's/\..*//'`
2183     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2184 changequote([,])dnl
2185     if test $as_major -eq 2 && test $as_minor -lt 11
2186     then :
2187     else gcc_cv_as_leb128=yes
2188     fi
2189   fi],
2190   [AC_DEFINE(HAVE_AS_LEB128, 1,
2191     [Define if your assembler supports .sleb128 and .uleb128.])])
2192
2193 # GAS versions up to and including 2.11.0 may mis-optimize
2194 # .eh_frame data.
2195 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2196   [elf,2,12,0],,
2197 [       .text
2198 .LFB1:
2199         .4byte  0
2200 .L1:
2201         .4byte  0
2202 .LFE1:
2203         .section        .eh_frame,"aw",@progbits
2204 __FRAME_BEGIN__:
2205         .4byte  .LECIE1-.LSCIE1
2206 .LSCIE1:
2207         .4byte  0x0
2208         .byte   0x1
2209         .ascii "z\0"
2210         .byte   0x1
2211         .byte   0x78
2212         .byte   0x1a
2213         .byte   0x0
2214         .byte   0x4
2215         .4byte  1
2216         .p2align 1
2217 .LECIE1:
2218 .LSFDE1:
2219         .4byte  .LEFDE1-.LASFDE1
2220 .LASFDE1:
2221         .4byte  .LASFDE1-__FRAME_BEGIN__
2222         .4byte  .LFB1
2223         .4byte  .LFE1-.LFB1
2224         .byte   0x4
2225         .4byte  .LFE1-.LFB1
2226         .byte   0x4
2227         .4byte  .L1-.LFB1
2228 .LEFDE1:],
2229 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2230 cat > conftest.lit <<EOF
2231  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2232  0010 01000000 12000000 18000000 00000000  ................
2233  0020 08000000 04080000 0044               .........D      @&t@
2234 EOF
2235 cat > conftest.big <<EOF
2236  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2237  0010 00000001 00000012 00000018 00000000  ................
2238  0020 00000008 04000000 0844               .........D      @&t@
2239 EOF
2240   # If the assembler didn't choke, and we can objdump,
2241   # and we got the correct data, then succeed.
2242   # The text in the here-document typically retains its unix-style line
2243   # endings, while the output of objdump will use host line endings.
2244   # Therefore, use diff -b for the comparisons.
2245   if test x$gcc_cv_objdump != x \
2246   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2247      | tail -3 > conftest.got \
2248   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2249     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2250   then
2251     gcc_cv_as_eh_frame=yes
2252   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2253     gcc_cv_as_eh_frame=buggy
2254   else
2255     # Uh oh, what do we do now?
2256     gcc_cv_as_eh_frame=no
2257   fi])
2258
2259 if test $gcc_cv_as_eh_frame = buggy; then
2260   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2261   [Define if your assembler mis-optimizes .eh_frame data.])
2262 fi
2263
2264 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2265  [elf,2,12,0], [--fatal-warnings],
2266  [.section .rodata.str, "aMS", @progbits, 1])
2267 if test $gcc_cv_as_shf_merge = no; then
2268   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2269     [elf,2,12,0], [--fatal-warnings],
2270     [.section .rodata.str, "aMS", %progbits, 1])
2271 fi
2272 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2273   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2274 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2275
2276 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2277  [elf,2,16,0], [--fatal-warnings],
2278  [.section .text,"axG",@progbits,.foo,comdat])
2279 if test $gcc_cv_as_comdat_group = yes; then
2280   gcc_cv_as_comdat_group_percent=no
2281 else
2282  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2283    [elf,2,16,0], [--fatal-warnings],
2284    [.section .text,"axG",%progbits,.foo,comdat])
2285 fi
2286 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2287   comdat_group=yes
2288   if test 0"$ld_date" -lt 20050308; then
2289     if test -n "$ld_date"; then
2290       # If there was date string, but was earlier than 2005-03-08, fail
2291       comdat_group=no
2292     elif test "$ld_vers_major" -lt 2; then
2293       comdat_group=no
2294     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2295       comdat_group=no
2296     fi
2297   fi
2298 else
2299   # assume linkers other than GNU ld don't support COMDAT group
2300   comdat_group=no
2301 fi
2302 if test $comdat_group = no; then
2303   gcc_cv_as_comdat_group=no
2304   gcc_cv_as_comdat_group_percent=no
2305 fi
2306 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2307   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2308 [Define 0/1 if your assembler and linker support COMDAT groups.])
2309
2310 # Thread-local storage - the check is heavily parametrized.
2311 conftest_s=
2312 tls_first_major=
2313 tls_first_minor=
2314 tls_as_opt=
2315 case "$target" in
2316 changequote(,)dnl
2317   alpha*-*-*)
2318     conftest_s='
2319         .section ".tdata","awT",@progbits
2320 foo:    .long   25
2321         .text
2322         ldq     $27,__tls_get_addr($29)         !literal!1
2323         lda     $16,foo($29)                    !tlsgd!1
2324         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2325         ldq     $27,__tls_get_addr($29)         !literal!2
2326         lda     $16,foo($29)                    !tlsldm!2
2327         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2328         ldq     $1,foo($29)                     !gotdtprel
2329         ldah    $2,foo($29)                     !dtprelhi
2330         lda     $3,foo($2)                      !dtprello
2331         lda     $4,foo($29)                     !dtprel
2332         ldq     $1,foo($29)                     !gottprel
2333         ldah    $2,foo($29)                     !tprelhi
2334         lda     $3,foo($2)                      !tprello
2335         lda     $4,foo($29)                     !tprel'
2336         tls_first_major=2
2337         tls_first_minor=13
2338         tls_as_opt=--fatal-warnings
2339         ;;
2340   frv*-*-*)
2341     conftest_s='
2342         .section ".tdata","awT",@progbits
2343 x:      .long   25
2344         .text
2345         call    #gettlsoff(x)'
2346         tls_first_major=2
2347         tls_first_minor=14
2348         ;;
2349   hppa*-*-linux*)
2350     conftest_s='
2351 t1:     .reg    %r20
2352 t2:     .reg    %r21
2353 gp:     .reg    %r19
2354         .section ".tdata","awT",@progbits
2355 foo:    .long   25
2356         .text
2357         .align  4
2358         addil LT%foo-$tls_gdidx$,gp
2359         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2360         b __tls_get_addr
2361         nop
2362         addil LT%foo-$tls_ldidx$,gp
2363         b __tls_get_addr
2364         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2365         addil LR%foo-$tls_dtpoff$,%ret0
2366         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2367         mfctl %cr27,%t1
2368         addil LT%foo-$tls_ieoff$,gp
2369         ldw RT%foo-$tls_ieoff$(%r1),%t2
2370         add %t1,%t2,%t3
2371         mfctl %cr27,%t1
2372         addil LR%foo-$tls_leoff$,%t1
2373         ldo RR%foo-$tls_leoff$(%r1),%t2'
2374         tls_first_major=2
2375         tls_first_minor=15
2376         tls_as_opt=--fatal-warnings
2377         ;;
2378   arm*-*-*)
2379     conftest_s='
2380         .section ".tdata","awT",%progbits
2381 foo:    .long   25
2382         .text
2383 .word foo(gottpoff)
2384 .word foo(tpoff)
2385 .word foo(tlsgd)
2386 .word foo(tlsldm)
2387 .word foo(tlsldo)'
2388         tls_first_major=2
2389         tls_first_minor=17
2390         ;;
2391   i[34567]86-*-*)
2392     conftest_s='
2393         .section ".tdata","awT",@progbits
2394 foo:    .long   25
2395         .text
2396         movl    %gs:0, %eax
2397         leal    foo@TLSGD(,%ebx,1), %eax
2398         leal    foo@TLSLDM(%ebx), %eax
2399         leal    foo@DTPOFF(%eax), %edx
2400         movl    foo@GOTTPOFF(%ebx), %eax
2401         subl    foo@GOTTPOFF(%ebx), %eax
2402         addl    foo@GOTNTPOFF(%ebx), %eax
2403         movl    foo@INDNTPOFF, %eax
2404         movl    $foo@TPOFF, %eax
2405         subl    $foo@TPOFF, %eax
2406         leal    foo@NTPOFF(%ecx), %eax'
2407         tls_first_major=2
2408         tls_first_minor=14
2409         tls_as_opt=--fatal-warnings
2410         ;;
2411   x86_64-*-*)
2412     conftest_s='
2413         .section ".tdata","awT",@progbits
2414 foo:    .long   25
2415         .text
2416         movq    %fs:0, %rax
2417         leaq    foo@TLSGD(%rip), %rdi
2418         leaq    foo@TLSLD(%rip), %rdi
2419         leaq    foo@DTPOFF(%rax), %rdx
2420         movq    foo@GOTTPOFF(%rip), %rax
2421         movq    $foo@TPOFF, %rax'
2422         tls_first_major=2
2423         tls_first_minor=14
2424         tls_as_opt=--fatal-warnings
2425         ;;
2426   ia64-*-*)
2427     conftest_s='
2428         .section ".tdata","awT",@progbits
2429 foo:    data8   25
2430         .text
2431         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2432         addl    r17 = @ltoff(@dtprel(foo#)), gp
2433         addl    r18 = @ltoff(@tprel(foo#)), gp
2434         addl    r19 = @dtprel(foo#), gp
2435         adds    r21 = @dtprel(foo#), r13
2436         movl    r23 = @dtprel(foo#)
2437         addl    r20 = @tprel(foo#), gp
2438         adds    r22 = @tprel(foo#), r13
2439         movl    r24 = @tprel(foo#)'
2440         tls_first_major=2
2441         tls_first_minor=13
2442         tls_as_opt=--fatal-warnings
2443         ;;
2444   mips*-*-*)
2445     conftest_s='
2446         .section .tdata,"awT",@progbits
2447 x:
2448         .word 2
2449         .text
2450         addiu $4, $28, %tlsgd(x)
2451         addiu $4, $28, %tlsldm(x)
2452         lui $4, %dtprel_hi(x)
2453         addiu $4, $4, %dtprel_lo(x)
2454         lw $4, %gottprel(x)($28)
2455         lui $4, %tprel_hi(x)
2456         addiu $4, $4, %tprel_lo(x)'
2457         tls_first_major=2
2458         tls_first_minor=16
2459         tls_as_opt='-32 --fatal-warnings'
2460         ;;
2461   powerpc-*-*)
2462     conftest_s='
2463         .section ".tdata","awT",@progbits
2464         .align 2
2465 ld0:    .space 4
2466 ld1:    .space 4
2467 x1:     .space 4
2468 x2:     .space 4
2469 x3:     .space 4
2470         .text
2471         addi 3,31,ld0@got@tlsgd
2472         bl __tls_get_addr
2473         addi 3,31,x1@got@tlsld
2474         bl __tls_get_addr
2475         addi 9,3,x1@dtprel
2476         addis 9,3,x2@dtprel@ha
2477         addi 9,9,x2@dtprel@l
2478         lwz 9,x3@got@tprel(31)
2479         add 9,9,x@tls
2480         addi 9,2,x1@tprel
2481         addis 9,2,x2@tprel@ha
2482         addi 9,9,x2@tprel@l'
2483         tls_first_major=2
2484         tls_first_minor=14
2485         tls_as_opt="-a32 --fatal-warnings"
2486         ;;
2487   powerpc64-*-*)
2488     conftest_s='
2489         .section ".tdata","awT",@progbits
2490         .align 3
2491 ld0:    .space 8
2492 ld1:    .space 8
2493 x1:     .space 8
2494 x2:     .space 8
2495 x3:     .space 8
2496         .text
2497         addi 3,2,ld0@got@tlsgd
2498         bl .__tls_get_addr
2499         nop
2500         addi 3,2,ld1@toc
2501         bl .__tls_get_addr
2502         nop
2503         addi 3,2,x1@got@tlsld
2504         bl .__tls_get_addr
2505         nop
2506         addi 9,3,x1@dtprel
2507         bl .__tls_get_addr
2508         nop
2509         addis 9,3,x2@dtprel@ha
2510         addi 9,9,x2@dtprel@l
2511         bl .__tls_get_addr
2512         nop
2513         ld 9,x3@got@dtprel(2)
2514         add 9,9,3
2515         bl .__tls_get_addr
2516         nop'
2517         tls_first_major=2
2518         tls_first_minor=14
2519         tls_as_opt="-a64 --fatal-warnings"
2520         ;;
2521   s390-*-*)
2522     conftest_s='
2523         .section ".tdata","awT",@progbits
2524 foo:    .long   25
2525         .text
2526         .long   foo@TLSGD
2527         .long   foo@TLSLDM
2528         .long   foo@DTPOFF
2529         .long   foo@NTPOFF
2530         .long   foo@GOTNTPOFF
2531         .long   foo@INDNTPOFF
2532         l       %r1,foo@GOTNTPOFF(%r12)
2533         l       %r1,0(%r1):tls_load:foo
2534         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2535         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2536         tls_first_major=2
2537         tls_first_minor=14
2538         tls_as_opt="-m31 --fatal-warnings"
2539         ;;
2540   s390x-*-*)
2541     conftest_s='
2542         .section ".tdata","awT",@progbits
2543 foo:    .long   25
2544         .text
2545         .quad   foo@TLSGD
2546         .quad   foo@TLSLDM
2547         .quad   foo@DTPOFF
2548         .quad   foo@NTPOFF
2549         .quad   foo@GOTNTPOFF
2550         lg      %r1,foo@GOTNTPOFF(%r12)
2551         larl    %r1,foo@INDNTPOFF
2552         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2553         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2554         tls_first_major=2
2555         tls_first_minor=14
2556         tls_as_opt="-m64 -Aesame --fatal-warnings"
2557         ;;
2558   sh-*-* | sh[34]-*-*)
2559     conftest_s='
2560         .section ".tdata","awT",@progbits
2561 foo:    .long   25
2562         .text
2563         .long   foo@TLSGD
2564         .long   foo@TLSLDM
2565         .long   foo@DTPOFF
2566         .long   foo@GOTTPOFF
2567         .long   foo@TPOFF'
2568         tls_first_major=2
2569         tls_first_minor=13
2570         tls_as_opt=--fatal-warnings
2571         ;;
2572   sparc*-*-*)
2573     case "$target" in
2574       sparc*-sun-solaris2.[56789]*)
2575         # TLS was introduced in the Solaris 9 4/04 release but
2576         # we do not enable it by default on Solaris 9 either.
2577         if test "x$enable_tls" = xyes ; then
2578           on_solaris=yes
2579         else
2580           enable_tls=no;
2581         fi
2582         ;;
2583       sparc*-sun-solaris2.*)
2584         on_solaris=yes
2585         ;;
2586       *)
2587         on_solaris=no
2588         ;;
2589     esac
2590     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2591       conftest_s='
2592         .section ".tdata",#alloc,#write,#tls
2593 foo:    .long   25
2594         .text
2595         sethi   %tgd_hi22(foo), %o0
2596         add     %o0, %tgd_lo10(foo), %o1
2597         add     %l7, %o1, %o0, %tgd_add(foo)
2598         call    __tls_get_addr, %tgd_call(foo)
2599         sethi   %tldm_hi22(foo), %l1
2600         add     %l1, %tldm_lo10(foo), %l2
2601         add     %l7, %l2, %o0, %tldm_add(foo)
2602         call    __tls_get_addr, %tldm_call(foo)
2603         sethi   %tldo_hix22(foo), %l3
2604         xor     %l3, %tldo_lox10(foo), %l4
2605         add     %o0, %l4, %l5, %tldo_add(foo)
2606         sethi   %tie_hi22(foo), %o3
2607         add     %o3, %tie_lo10(foo), %o3
2608         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2609         add     %g7, %o2, %o4, %tie_add(foo)
2610         sethi   %tle_hix22(foo), %l1
2611         xor     %l1, %tle_lox10(foo), %o5
2612         ld      [%g7 + %o5], %o1'
2613         tls_first_major=0
2614         tls_first_minor=0
2615     else
2616       conftest_s='
2617         .section ".tdata","awT",@progbits
2618 foo:    .long   25
2619         .text
2620         sethi   %tgd_hi22(foo), %o0
2621         add     %o0, %tgd_lo10(foo), %o1
2622         add     %l7, %o1, %o0, %tgd_add(foo)
2623         call    __tls_get_addr, %tgd_call(foo)
2624         sethi   %tldm_hi22(foo), %l1
2625         add     %l1, %tldm_lo10(foo), %l2
2626         add     %l7, %l2, %o0, %tldm_add(foo)
2627         call    __tls_get_addr, %tldm_call(foo)
2628         sethi   %tldo_hix22(foo), %l3
2629         xor     %l3, %tldo_lox10(foo), %l4
2630         add     %o0, %l4, %l5, %tldo_add(foo)
2631         sethi   %tie_hi22(foo), %o3
2632         add     %o3, %tie_lo10(foo), %o3
2633         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2634         add     %g7, %o2, %o4, %tie_add(foo)
2635         sethi   %tle_hix22(foo), %l1
2636         xor     %l1, %tle_lox10(foo), %o5
2637         ld      [%g7 + %o5], %o1'
2638         tls_first_major=2
2639         tls_first_minor=14
2640         tls_as_opt="-32 --fatal-warnings"
2641       fi
2642         ;;
2643 changequote([,])dnl
2644 esac
2645 set_have_as_tls=no
2646 if test "x$enable_tls" = xno ; then
2647   : # TLS explicitly disabled.
2648 elif test "x$enable_tls" = xyes ; then
2649   set_have_as_tls=yes # TLS explicitly enabled.
2650 elif test -z "$tls_first_major"; then
2651   : # If we don't have a check, assume no support.
2652 else
2653   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2654   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2655   [set_have_as_tls=yes])
2656 fi
2657 if test $set_have_as_tls = yes ; then
2658   AC_DEFINE(HAVE_AS_TLS, 1,
2659             [Define if your assembler supports thread-local storage.])
2660 fi
2661
2662 # Target-specific assembler checks.
2663
2664 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2665 gcc_cv_ld_static_dynamic=no
2666 if test $in_tree_ld = yes ; then
2667   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2668     gcc_cv_ld_static_dynamic=yes
2669   fi
2670 elif test x$gcc_cv_ld != x; then
2671         # Check if linker supports -Bstatic/-Bdynamic option
2672         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2673           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2674                 gcc_cv_ld_static_dynamic=yes
2675         fi
2676 fi
2677 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2678         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2679 [Define if your linker supports -Bstatic/-Bdynamic option.])
2680 fi
2681 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2682
2683 if test x"$demangler_in_ld" = xyes; then
2684   AC_MSG_CHECKING(linker --demangle support)
2685   gcc_cv_ld_demangle=no
2686   if test $in_tree_ld = yes; then
2687     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2688       gcc_cv_ld_demangle=yes
2689     fi
2690   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2691     # Check if the GNU linker supports --demangle option
2692     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2693       gcc_cv_ld_demangle=yes
2694     fi
2695   fi
2696   if test x"$gcc_cv_ld_demangle" = xyes; then
2697     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2698 [Define if your linker supports --demangle option.])
2699   fi
2700   AC_MSG_RESULT($gcc_cv_ld_demangle)
2701 fi
2702
2703 case "$target" in
2704   # All TARGET_ABI_OSF targets.
2705   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2706     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2707         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2708 [       .set nomacro
2709         .text
2710         extbl   $3, $2, $3      !lituse_bytoff!1
2711         ldq     $2, a($29)      !literal!1
2712         ldq     $4, b($29)      !literal!2
2713         ldq_u   $3, 0($2)       !lituse_base!1
2714         ldq     $27, f($29)     !literal!5
2715         jsr     $26, ($27), f   !lituse_jsr!5
2716         ldah    $29, 0($26)     !gpdisp!3
2717         lda     $0, c($29)      !gprel
2718         ldah    $1, d($29)      !gprelhigh
2719         lda     $1, d($1)       !gprellow
2720         lda     $29, 0($29)     !gpdisp!3],,
2721     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2722   [Define if your assembler supports explicit relocations.])])
2723     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2724         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2725 [       .set nomacro
2726         .text
2727         ldq     $27, a($29)     !literal!1
2728         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2729     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2730   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2731     ;;
2732
2733   cris-*-*)
2734     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2735       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2736       [-no-mul-bug-abort], [.text],,
2737       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2738                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2739     ;;
2740
2741   sparc*-*-*)
2742     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2743       [.register %g2, #scratch],,
2744       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2745                 [Define if your assembler supports .register.])])
2746
2747     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2748       [-relax], [.text],,
2749       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2750                 [Define if your assembler supports -relax option.])])
2751
2752     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2753       gcc_cv_as_sparc_ua_pcrel,,
2754       [-K PIC],
2755 [.text
2756 foo:
2757         nop
2758 .data
2759 .align 4
2760 .byte 0
2761 .uaword %r_disp32(foo)],
2762       [if test x$gcc_cv_ld != x \
2763        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2764          gcc_cv_as_sparc_ua_pcrel=yes
2765        fi
2766        rm -f conftest],
2767       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2768                 [Define if your assembler and linker support unaligned PC relative relocs.])
2769
2770       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2771         gcc_cv_as_sparc_ua_pcrel_hidden,,
2772         [-K PIC],
2773 [.data
2774 .align 4
2775 .byte 0x31
2776 .uaword %r_disp32(foo)
2777 .byte 0x32, 0x33, 0x34
2778 .global foo
2779 .hidden foo
2780 foo:
2781 .skip 4],
2782         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2783          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2784          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2785             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2786             if $gcc_cv_objdump -R conftest 2> /dev/null \
2787                | grep 'DISP32' > /dev/null 2>&1; then
2788                 :
2789             else
2790                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2791             fi
2792          fi
2793          rm -f conftest],
2794          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2795                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2796     ]) # unaligned pcrel relocs
2797
2798     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2799       gcc_cv_as_sparc_offsetable_lo10,,
2800       [-xarch=v9],
2801 [.text
2802         or %g1, %lo(ab) + 12, %g1
2803         or %g1, %lo(ab + 12), %g1],
2804       [if test x$gcc_cv_objdump != x \
2805        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2806           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2807          gcc_cv_as_sparc_offsetable_lo10=yes
2808        fi],
2809        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2810                  [Define if your assembler supports offsetable %lo().])])
2811     ;;
2812
2813 changequote(,)dnl
2814   i[34567]86-*-* | x86_64-*-*)
2815 changequote([,])dnl
2816     case $target_os in
2817       cygwin* | pe | mingw32*)
2818         # Used for DWARF 2 in PE
2819         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2820           gcc_cv_as_ix86_pe_secrel32,
2821           [2,15,91],,
2822 [.text
2823 foo:    nop
2824 .data
2825         .secrel32 foo],
2826           [if test x$gcc_cv_ld != x \
2827            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2828              gcc_cv_as_ix86_pe_secrel32=yes
2829            fi
2830            rm -f conftest],
2831           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2832             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2833         ;;
2834     esac
2835
2836     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2837        gcc_cv_as_ix86_filds_fists,
2838       [2,9,0],, [filds mem; fists mem],,
2839       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2840         [Define if your assembler uses the new HImode fild and fist notation.])])
2841
2842     gcc_GAS_CHECK_FEATURE([cmov syntax],
2843       gcc_cv_as_ix86_cmov_sun_syntax,,,
2844       [cmovl.l %edx, %eax],,
2845       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2846         [Define if your assembler supports the Sun syntax for cmov.])])
2847
2848     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2849       gcc_cv_as_ix86_ffreep,,,
2850       [ffreep %st(1)],,
2851       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2852         [Define if your assembler supports the ffreep mnemonic.])])
2853
2854     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2855       gcc_cv_as_ix86_diff_sect_delta,,,
2856       [.section .rodata
2857 .L1:
2858         .long .L2-.L1
2859         .long .L3-.L1
2860         .text
2861 .L3:    nop
2862 .L2:    nop],,
2863       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2864         [Define if your assembler supports the subtraction of symbols in different sections.])])
2865
2866     # This one is used unconditionally by i386.[ch]; it is to be defined
2867     # to 1 if the feature is present, 0 otherwise.
2868     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2869         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2870 [       .text
2871 .L0:
2872         nop
2873         .data
2874         .long .L0@GOTOFF])
2875     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2876       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2877       [Define true if the assembler supports '.long foo@GOTOFF'.])
2878     ;;
2879
2880   ia64*-*-*)
2881     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2882         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2883 [       .text
2884         addl r15 = @ltoffx(x#), gp
2885         ;;
2886         ld8.mov r16 = [[r15]], x#],,
2887     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2888           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2889
2890     ;;
2891
2892   powerpc*-*-*)
2893     case $target in
2894       *-*-aix*) conftest_s='    .machine "pwr5"
2895         .csect .text[[PR]]
2896         mfcr 3,128';;
2897       *-*-darwin*)
2898         gcc_GAS_CHECK_FEATURE([.machine directive support],
2899           gcc_cv_as_machine_directive,,,
2900           [     .machine ppc7400])
2901         if test x$gcc_cv_as_machine_directive != xyes; then
2902           echo "*** This target requires an assembler supporting \".machine\"" >&2
2903           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2904           test x$build = x$target && exit 1
2905         fi
2906         conftest_s='    .text
2907         mfcr r3,128';;
2908       *) conftest_s='   .machine power4
2909         .text
2910         mfcr 3,128';;
2911     esac
2912
2913     gcc_GAS_CHECK_FEATURE([mfcr field support],
2914       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2915       [$conftest_s],,
2916       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2917           [Define if your assembler supports mfcr field.])])
2918
2919     case $target in
2920       *-*-aix*) conftest_s='    .machine "pwr5"
2921         .csect .text[[PR]]
2922         popcntb 3,3';;
2923       *) conftest_s='   .machine power5
2924         .text
2925         popcntb 3,3';;
2926     esac
2927
2928     gcc_GAS_CHECK_FEATURE([popcntb support],
2929       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2930       [$conftest_s],,
2931       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2932           [Define if your assembler supports popcntb field.])])
2933
2934     case $target in
2935       *-*-aix*) conftest_s='    .machine "pwr5x"
2936         .csect .text[[PR]]
2937         frin 1,1';;
2938       *) conftest_s='   .machine power5
2939         .text
2940         frin 1,1';;
2941     esac
2942
2943     gcc_GAS_CHECK_FEATURE([fp round support],
2944       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2945       [$conftest_s],,
2946       [AC_DEFINE(HAVE_AS_FPRND, 1,
2947           [Define if your assembler supports fprnd.])])
2948
2949     case $target in
2950       *-*-aix*) conftest_s='    .machine "pwr6"
2951         .csect .text[[PR]]
2952         mffgpr 1,3';;
2953       *) conftest_s='   .machine power6
2954         .text
2955         mffgpr 1,3';;
2956     esac
2957
2958     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2959       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2960       [$conftest_s],,
2961       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2962           [Define if your assembler supports mffgpr and mftgpr.])])
2963
2964     case $target in
2965       *-*-aix*) conftest_s='    .csect .text[[PR]]
2966 LCF..0:
2967         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2968       *-*-darwin*)
2969         conftest_s='    .text
2970 LCF0:
2971         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2972       *) conftest_s='   .text
2973 .LCF0:
2974         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2975     esac
2976
2977     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2978       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2979       [$conftest_s],,
2980       [AC_DEFINE(HAVE_AS_REL16, 1,
2981           [Define if your assembler supports R_PPC_REL16 relocs.])])
2982     ;;
2983
2984   mips*-*-*)
2985     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2986       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2987 [       lw $4,%gp_rel(foo)($4)],,
2988       [if test x$target_cpu_default = x
2989        then target_cpu_default=MASK_EXPLICIT_RELOCS
2990        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2991        fi])
2992     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2993       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2994       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2995                  [Define if the assembler understands -mno-shared.])])
2996     ;;
2997 esac
2998
2999 # Mips and HP-UX need the GNU assembler.
3000 # Linux on IA64 might be able to use the Intel assembler.
3001
3002 case "$target" in
3003   mips*-*-* | *-*-hpux* )
3004     if test x$gas_flag = xyes \
3005        || test x"$host" != x"$build" \
3006        || test ! -x "$gcc_cv_as" \
3007        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3008       :
3009     else
3010       echo "*** This configuration requires the GNU assembler" >&2
3011       exit 1
3012     fi
3013     ;;
3014 esac
3015
3016 # ??? Not all targets support dwarf2 debug_line, even within a version
3017 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3018 # info to the output file.  So, as supported targets are added to gas 2.11,
3019 # add some instruction here to (also) show we expect this might work.
3020 # ??? Once 2.11 is released, probably need to add first known working
3021 # version to the per-target configury.
3022 case "$target" in
3023   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3024   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3025   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-*)
3026     insn="nop"
3027     ;;
3028   ia64*-*-* | s390*-*-*)
3029     insn="nop 0"
3030     ;;
3031   mmix-*-*)
3032     insn="swym 0"
3033     ;;
3034 esac
3035 if test x"$insn" != x; then
3036  conftest_s="\
3037         .file 1 \"conftest.s\"
3038         .loc 1 3 0
3039         $insn"
3040  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3041   gcc_cv_as_dwarf2_debug_line,
3042   [elf,2,11,0],, [$conftest_s],
3043   [if test x$gcc_cv_objdump != x \
3044    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3045       | grep debug_line > /dev/null 2>&1; then
3046      gcc_cv_as_dwarf2_debug_line=yes
3047    fi])
3048
3049 # The .debug_line file table must be in the exact order that
3050 # we specified the files, since these indices are also used
3051 # by DW_AT_decl_file.  Approximate this test by testing if
3052 # the assembler bitches if the same index is assigned twice.
3053  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3054   gcc_cv_as_dwarf2_file_buggy,,,
3055 [       .file 1 "foo.s"
3056         .file 1 "bar.s"])
3057
3058  if test $gcc_cv_as_dwarf2_debug_line = yes \
3059  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3060         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3061   [Define if your assembler supports dwarf2 .file/.loc directives,
3062    and preserves file table indices exactly as given.])
3063  fi
3064
3065  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3066   gcc_cv_as_gdwarf2_flag,
3067   [elf,2,11,0], [--gdwarf2], [$insn],,
3068   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3069 [Define if your assembler supports the --gdwarf2 option.])])
3070
3071  gcc_GAS_CHECK_FEATURE([--gstabs option],
3072   gcc_cv_as_gstabs_flag,
3073   [elf,2,11,0], [--gstabs], [$insn],
3074   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3075    # and warns about it, but still exits successfully.  So check for
3076    # this.
3077    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3078    then :
3079    else gcc_cv_as_gstabs_flag=yes
3080    fi],
3081   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3082 [Define if your assembler supports the --gstabs option.])])
3083 fi
3084
3085 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3086 gcc_cv_ld_ro_rw_mix=unknown
3087 if test $in_tree_ld = yes ; then
3088   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3089      && test $in_tree_ld_is_elf = yes; then
3090     gcc_cv_ld_ro_rw_mix=read-write
3091   fi
3092 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3093   echo '.section myfoosect, "a"' > conftest1.s
3094   echo '.section myfoosect, "aw"' > conftest2.s
3095   echo '.byte 1' >> conftest2.s
3096   echo '.section myfoosect, "a"' > conftest3.s
3097   echo '.byte 0' >> conftest3.s
3098   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3099      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3100      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3101      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3102         conftest2.o conftest3.o > /dev/null 2>&1; then
3103     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3104                          | sed -e '/myfoosect/!d' -e N`
3105     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3106       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3107         gcc_cv_ld_ro_rw_mix=read-only
3108       else
3109         gcc_cv_ld_ro_rw_mix=read-write
3110       fi
3111     fi
3112   fi
3113 changequote(,)dnl
3114   rm -f conftest.* conftest[123].*
3115 changequote([,])dnl
3116 fi
3117 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3118         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3119   [Define if your linker links a mix of read-only
3120    and read-write sections into a read-write section.])
3121 fi
3122 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3123
3124 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3125 gcc_cv_ld_eh_frame_hdr=no
3126 if test $in_tree_ld = yes ; then
3127   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3128      && test $in_tree_ld_is_elf = yes; then
3129     gcc_cv_ld_eh_frame_hdr=yes
3130   fi
3131 elif test x$gcc_cv_ld != x; then
3132         # Check if linker supports --eh-frame-hdr option
3133         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3134                 gcc_cv_ld_eh_frame_hdr=yes
3135         fi
3136 fi
3137 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3138 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3139         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3140 [Define if your linker supports --eh-frame-hdr option.])
3141 fi
3142 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3143
3144 AC_MSG_CHECKING(linker position independent executable support)
3145 gcc_cv_ld_pie=no
3146 if test $in_tree_ld = yes ; then
3147   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3148      && test $in_tree_ld_is_elf = yes; then
3149     gcc_cv_ld_pie=yes
3150   fi
3151 elif test x$gcc_cv_ld != x; then
3152         # Check if linker supports -pie option
3153         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3154                 gcc_cv_ld_pie=yes
3155         fi
3156 fi
3157 if test x"$gcc_cv_ld_pie" = xyes; then
3158         AC_DEFINE(HAVE_LD_PIE, 1,
3159 [Define if your linker supports -pie option.])
3160 fi
3161 AC_MSG_RESULT($gcc_cv_ld_pie)
3162
3163 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3164 gcc_cv_ld_eh_gc_sections=no
3165 if test $in_tree_ld = yes ; then
3166   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3167      && test $in_tree_ld_is_elf = yes; then
3168     gcc_cv_ld_eh_gc_sections=yes
3169   fi
3170 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3171   cat > conftest.s <<EOF
3172         .section        .text
3173 .globl _start
3174         .type _start, @function
3175 _start:
3176         .long foo
3177         .size _start, .-_start
3178         .section        .text.foo,"ax",@progbits
3179         .type foo, @function
3180 foo:
3181         .long 0
3182         .size foo, .-foo
3183         .section        .gcc_except_table.foo,"a",@progbits
3184 .L0:
3185         .long 0
3186         .section        .eh_frame,"a",@progbits
3187         .long .L0
3188 EOF
3189   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3190     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3191          | grep "gc-sections option ignored" > /dev/null; then
3192       gcc_cv_ld_eh_gc_sections=no
3193     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3194       gcc_cv_ld_eh_gc_sections=yes
3195       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3196       if test x$gcc_cv_as_comdat_group != xyes; then
3197         gcc_cv_ld_eh_gc_sections=no
3198         cat > conftest.s <<EOF
3199         .section        .text
3200 .globl _start
3201         .type _start, @function
3202 _start:
3203         .long foo
3204         .size _start, .-_start
3205         .section        .gnu.linkonce.t.foo,"ax",@progbits
3206         .type foo, @function
3207 foo:
3208         .long 0
3209         .size foo, .-foo
3210         .section        .gcc_except_table.foo,"a",@progbits
3211 .L0:
3212         .long 0
3213         .section        .eh_frame,"a",@progbits
3214         .long .L0
3215 EOF
3216         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3217           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3218                | grep "gc-sections option ignored" > /dev/null; then
3219             gcc_cv_ld_eh_gc_sections=no
3220           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3221             gcc_cv_ld_eh_gc_sections=yes
3222           fi
3223         fi
3224       fi
3225     fi
3226   fi
3227   rm -f conftest.s conftest.o conftest
3228 fi
3229 case "$target" in
3230   hppa*-*-linux*)
3231     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3232     gcc_cv_ld_eh_gc_sections=no
3233     ;;
3234 esac
3235 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3236         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3237   [Define if your linker supports garbage collection of
3238    sections in presence of EH frames.])
3239 fi
3240 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3241
3242 # --------
3243 # UNSORTED
3244 # --------
3245
3246 AC_CACHE_CHECK(linker --as-needed support,
3247 gcc_cv_ld_as_needed,
3248 [gcc_cv_ld_as_needed=no
3249 if test $in_tree_ld = yes ; then
3250   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3251      && test $in_tree_ld_is_elf = yes; then
3252     gcc_cv_ld_as_needed=yes
3253   fi
3254 elif test x$gcc_cv_ld != x; then
3255         # Check if linker supports --as-needed and --no-as-needed options
3256         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3257                 gcc_cv_ld_as_needed=yes
3258         fi
3259 fi
3260 ])
3261 if test x"$gcc_cv_ld_as_needed" = xyes; then
3262         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3263 [Define if your linker supports --as-needed and --no-as-needed options.])
3264 fi
3265
3266 case "$target:$tm_file" in
3267   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3268     AC_CACHE_CHECK(linker support for omitting dot symbols,
3269     gcc_cv_ld_no_dot_syms,
3270     [gcc_cv_ld_no_dot_syms=no
3271     if test $in_tree_ld = yes ; then
3272       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3273         gcc_cv_ld_no_dot_syms=yes
3274       fi
3275     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3276       cat > conftest1.s <<EOF
3277         .text
3278         bl .foo
3279 EOF
3280       cat > conftest2.s <<EOF
3281         .section ".opd","aw"
3282         .align 3
3283         .globl foo
3284         .type foo,@function
3285 foo:
3286         .quad .LEfoo,.TOC.@tocbase,0
3287         .text
3288 .LEfoo:
3289         blr
3290         .size foo,.-.LEfoo
3291 EOF
3292       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3293          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3294          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3295         gcc_cv_ld_no_dot_syms=yes
3296       fi
3297       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3298     fi
3299     ])
3300     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3301       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3302     [Define if your PowerPC64 linker only needs function descriptor syms.])
3303     fi
3304     ;;
3305 esac
3306
3307 AC_CACHE_CHECK(linker --sysroot support,
3308   gcc_cv_ld_sysroot,
3309   [gcc_cv_ld_sysroot=no
3310   if test $in_tree_ld = yes ; then
3311       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3312         gcc_cv_ld_sysroot=yes
3313       fi
3314   elif test x$gcc_cv_ld != x; then
3315     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3316       gcc_cv_ld_sysroot=yes
3317     fi
3318   fi])
3319 if test x"$gcc_cv_ld_sysroot" = xyes; then
3320   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3321   [Define if your linker supports --sysroot.])
3322 fi
3323
3324 if test x$with_sysroot = x && test x$host = x$target \
3325    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3326    && test "$prefix" != "NONE"; then
3327   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3328 [Define to PREFIX/include if cpp should also search that directory.])
3329 fi
3330
3331 # Test for stack protector support in target C library.
3332 case "$target" in
3333   *-*-linux*)
3334     AC_CACHE_CHECK(__stack_chk_fail in target GNU C library,
3335       gcc_cv_libc_provides_ssp,
3336       [gcc_cv_libc_provides_ssp=no
3337       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3338         if test "x$with_sysroot" = x; then
3339           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3340         elif test "x$with_sysroot" = xyes; then
3341           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3342         else
3343           glibc_header_dir="${with_sysroot}/usr/include"
3344         fi
3345       else
3346         glibc_header_dir=/usr/include
3347       fi
3348       # glibc 2.4 and later provides __stack_chk_fail and
3349       # either __stack_chk_guard, or TLS access to stack guard canary.
3350       if test -f $glibc_header_dir/features.h \
3351          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3352             $glibc_header_dir/features.h > /dev/null; then
3353         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3354            $glibc_header_dir/features.h > /dev/null; then
3355           gcc_cv_libc_provides_ssp=yes
3356         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3357              $glibc_header_dir/features.h > /dev/null \
3358              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3359              $glibc_header_dir/features.h > /dev/null; then
3360           gcc_cv_libc_provides_ssp=yes
3361         fi
3362       fi]) ;;
3363   *) gcc_cv_libc_provides_ssp=no ;;
3364 esac
3365 if test x$gcc_cv_libc_provides_ssp = xyes; then
3366   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3367             [Define if your target C library provides stack protector support])
3368 fi
3369
3370 # Check if TFmode long double should be used by default or not.
3371 # Some glibc targets used DFmode long double, but with glibc 2.4
3372 # and later they can use TFmode.
3373 case "$target" in
3374   powerpc*-*-*gnu* | \
3375   sparc*-*-linux* | \
3376   s390*-*-linux* | \
3377   alpha*-*-linux*)
3378     AC_ARG_WITH(long-double-128,
3379 [  --with-long-double-128  Use 128-bit long double by default.],
3380       gcc_cv_target_ldbl128="$with_long_double_128",
3381       [gcc_cv_target_ldbl128=no
3382       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3383         if test "x$with_sysroot" = x; then
3384           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3385         elif test "x$with_sysroot" = xyes; then
3386           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3387         else
3388           glibc_header_dir="${with_sysroot}/usr/include"
3389         fi
3390       else
3391         glibc_header_dir=/usr/include
3392       fi
3393 changequote(,)dnl
3394       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3395         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3396       && gcc_cv_target_ldbl128=yes
3397 changequote([,])dnl
3398       ])
3399     ;;
3400 esac
3401 if test x$gcc_cv_target_ldbl128 = xyes; then
3402   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3403             [Define if TFmode long double should be the default])
3404 fi
3405
3406 # Find out what GC implementation we want, or may, use.
3407 AC_ARG_WITH(gc,
3408 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3409                           with the compiler],
3410 [case "$withval" in
3411   page)
3412     GGC=ggc-$withval
3413     ;;
3414   zone)
3415     GGC=ggc-$withval
3416     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3417     ;;
3418   *)
3419     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3420     ;;
3421 esac],
3422 [GGC=ggc-page])
3423 AC_SUBST(GGC)
3424 echo "Using $GGC for garbage collection."
3425
3426 # Use the system's zlib library.
3427 zlibdir=-L../zlib
3428 zlibinc="-I\$(srcdir)/../zlib"
3429 AC_ARG_WITH(system-zlib,
3430 [  --with-system-zlib      use installed libz],
3431 zlibdir=
3432 zlibinc=
3433 )
3434 AC_SUBST(zlibdir)
3435 AC_SUBST(zlibinc)
3436
3437 dnl Very limited version of automake's enable-maintainer-mode
3438
3439 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3440   dnl maintainer-mode is disabled by default
3441   AC_ARG_ENABLE(maintainer-mode,
3442 [  --enable-maintainer-mode
3443                           enable make rules and dependencies not useful
3444                           (and sometimes confusing) to the casual installer],
3445       maintainer_mode=$enableval,
3446       maintainer_mode=no)
3447
3448 AC_MSG_RESULT($maintainer_mode)
3449
3450 if test "$maintainer_mode" = "yes"; then
3451   MAINT=''
3452 else
3453   MAINT='#'
3454 fi
3455 AC_SUBST(MAINT)dnl
3456
3457 # --------------
3458 # Language hooks
3459 # --------------
3460
3461 # Make empty files to contain the specs and options for each language.
3462 # Then add #include lines to for a compiler that has specs and/or options.
3463
3464 subdirs=
3465 lang_opt_files=
3466 lang_specs_files=
3467 lang_tree_files=
3468 # These (without "all_") are set in each config-lang.in.
3469 # `language' must be a single word so is spelled singularly.
3470 all_languages=
3471 all_boot_languages=
3472 all_compilers=
3473 all_stagestuff=
3474 all_outputs='Makefile gccbug mklibgcc libada-mk'
3475 # List of language makefile fragments.
3476 all_lang_makefrags=
3477 # List of language subdirectory makefiles.  Deprecated.
3478 all_lang_makefiles=
3479 # Files for gengtype
3480 all_gtfiles="$target_gtfiles"
3481 # Files for gengtype with language
3482 all_gtfiles_files_langs=
3483 all_gtfiles_files_files=
3484
3485 # These are the languages that are set in --enable-languages,
3486 # and are available in the GCC tree.
3487 all_selected_languages=
3488
3489 # Add the language fragments.
3490 # Languages are added via two mechanisms.  Some information must be
3491 # recorded in makefile variables, these are defined in config-lang.in.
3492 # We accumulate them and plug them into the main Makefile.
3493 # The other mechanism is a set of hooks for each of the main targets
3494 # like `clean', `install', etc.
3495
3496 language_hooks="Make-hooks"
3497
3498 for lang in ${srcdir}/*/config-lang.in
3499 do
3500 changequote(,)dnl
3501         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3502
3503         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3504         if test "x$lang_alias" = x
3505         then
3506               echo "$lang doesn't set \$language." 1>&2
3507               exit 1
3508         fi
3509         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3510         subdirs="$subdirs $subdir"
3511         case ",$enable_languages," in
3512         *,$lang_alias,*)
3513             all_selected_languages="$all_selected_languages $lang_alias"
3514             if test -f $srcdir/$subdir/lang-specs.h; then
3515                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3516             fi
3517             ;;
3518         esac
3519 changequote([,])dnl
3520
3521         language=
3522         boot_language=
3523         compilers=
3524         stagestuff=
3525         outputs=
3526         gtfiles=
3527         subdir_requires=
3528         . ${srcdir}/$subdir/config-lang.in
3529         if test "x$language" = x
3530         then
3531                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3532                 exit 1
3533         fi
3534
3535         ok=:
3536         case ",$enable_languages," in
3537                 *,$lang_alias,*) ;;
3538                 *)
3539                         for i in $subdir_requires; do
3540                                 test -f "${srcdir}/$i/config-lang.in" && continue
3541                                 ok=false
3542                                 break
3543                         done
3544                 ;;
3545         esac
3546         $ok || continue
3547
3548         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3549         if test -f $srcdir/$subdir/lang.opt; then
3550             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3551         fi
3552         if test -f $srcdir/$subdir/$subdir-tree.def; then
3553             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3554         fi
3555         if test -f ${srcdir}/$subdir/Makefile.in
3556                 then all_lang_makefiles="$subdir/Makefile"
3557         fi
3558         all_languages="$all_languages $language"
3559         if test "x$boot_language" = xyes
3560         then
3561                 all_boot_languages="$all_boot_languages $language"
3562         fi
3563         all_compilers="$all_compilers $compilers"
3564         all_stagestuff="$all_stagestuff $stagestuff"
3565         all_outputs="$all_outputs $outputs"
3566         all_gtfiles="$all_gtfiles $gtfiles"
3567         for f in $gtfiles
3568         do
3569                 all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3570                 all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3571         done
3572 done
3573
3574 # Pick up gtfiles for c
3575 gtfiles=
3576 subdir="c"
3577 . ${srcdir}/c-config-lang.in
3578 all_gtfiles="$all_gtfiles $gtfiles"
3579 for f in $gtfiles
3580 do
3581         all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3582         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3583 done
3584
3585 check_languages=
3586 for language in $all_selected_languages
3587 do
3588         check_languages="$check_languages check-$language"
3589 done
3590
3591 # We link each language in with a set of hooks, reached indirectly via
3592 # lang.${target}.  Only do so for selected languages.
3593
3594 rm -f Make-hooks
3595 touch Make-hooks
3596 target_list="all.cross start.encap rest.encap tags \
3597         install-common install-man install-info dvi pdf html \
3598         uninstall info man srcextra srcman srcinfo \
3599         mostlyclean clean distclean maintainer-clean \
3600         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3601
3602 for t in $target_list
3603 do
3604         x=
3605         for lang in $all_selected_languages
3606         do
3607                 x="$x $lang.$t"
3608         done
3609         echo "lang.$t: $x" >> Make-hooks
3610 done
3611
3612 # --------
3613 # UNSORTED
3614 # --------
3615
3616 # Create .gdbinit.
3617
3618 echo "dir ." > .gdbinit
3619 echo "dir ${srcdir}" >> .gdbinit
3620 if test x$gdb_needs_out_file_path = xyes
3621 then
3622         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3623 fi
3624 if test "x$subdirs" != x; then
3625         for s in $subdirs
3626         do
3627                 echo "dir ${srcdir}/$s" >> .gdbinit
3628         done
3629 fi
3630 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3631
3632 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3633 # absolute path for gcc_tooldir based on inserting the number of up-directory
3634 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3635 # $(libsubdir)/@(unlibsubdir) based path.
3636 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3637 # make and thus we'd get different behavior depending on where we built the
3638 # sources.
3639 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3640     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3641 else
3642 changequote(<<, >>)dnl
3643 # An explanation of the sed strings:
3644 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3645 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3646 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3647 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3648 #
3649 # (*) Note this pattern overwrites the first character of the string
3650 # with a forward slash if one is not already present.  This is not a
3651 # problem because the exact names of the sub-directories concerned is
3652 # unimportant, just the number of them matters.
3653 #
3654 # The practical upshot of these patterns is like this:
3655 #
3656 #  prefix     exec_prefix        result
3657 #  ------     -----------        ------
3658 #   /foo        /foo/bar          ../
3659 #   /foo/       /foo/bar          ../
3660 #   /foo        /foo/bar/         ../
3661 #   /foo/       /foo/bar/         ../
3662 #   /foo        /foo/bar/ugg      ../../
3663 #
3664     dollar='$$'
3665     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3666 changequote([, ])dnl
3667 fi
3668 AC_SUBST(gcc_tooldir)
3669 AC_SUBST(dollar)
3670
3671 # Find a directory in which to install a shared libgcc.
3672
3673 AC_ARG_ENABLE(version-specific-runtime-libs,
3674 [  --enable-version-specific-runtime-libs
3675                           specify that runtime libraries should be
3676                           installed in a compiler-specific directory])
3677
3678 AC_ARG_WITH(slibdir,
3679 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3680 slibdir="$with_slibdir",
3681 if test "${enable_version_specific_runtime_libs+set}" = set; then
3682   slibdir='$(libsubdir)'
3683 elif test "$host" != "$target"; then
3684   slibdir='$(build_tooldir)/lib'
3685 else
3686   slibdir='$(libdir)'
3687 fi)
3688 AC_SUBST(slibdir)
3689
3690 objdir=`${PWDCMD-pwd}`
3691 AC_SUBST(objdir)
3692
3693 AC_ARG_WITH(datarootdir,
3694 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3695 datarootdir="\${prefix}/$with_datarootdir",
3696 datarootdir='$(prefix)/share')
3697 AC_SUBST(datarootdir)
3698
3699 AC_ARG_WITH(docdir,
3700 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3701 docdir="\${prefix}/$with_docdir",
3702 docdir='$(datarootdir)')
3703 AC_SUBST(docdir)
3704
3705 AC_ARG_WITH(htmldir,
3706 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3707 htmldir="\${prefix}/$with_htmldir",
3708 htmldir='$(docdir)')
3709 AC_SUBST(htmldir)
3710
3711 # Substitute configuration variables
3712 AC_SUBST(subdirs)
3713 AC_SUBST(srcdir)
3714 AC_SUBST(all_boot_languages)
3715 AC_SUBST(all_compilers)
3716 AC_SUBST(all_gtfiles)
3717 AC_SUBST(all_gtfiles_files_langs)
3718 AC_SUBST(all_gtfiles_files_files)
3719 AC_SUBST(all_lang_makefrags)
3720 AC_SUBST(all_lang_makefiles)
3721 AC_SUBST(all_languages)
3722 AC_SUBST(all_selected_languages)
3723 AC_SUBST(all_stagestuff)
3724 AC_SUBST(build_exeext)
3725 AC_SUBST(build_install_headers_dir)
3726 AC_SUBST(build_xm_file_list)
3727 AC_SUBST(build_xm_include_list)
3728 AC_SUBST(build_xm_defines)
3729 AC_SUBST(check_languages)
3730 AC_SUBST(cc_set_by_configure)
3731 AC_SUBST(quoted_cc_set_by_configure)
3732 AC_SUBST(cpp_install_dir)
3733 AC_SUBST(xmake_file)
3734 AC_SUBST(tmake_file)
3735 AC_SUBST(extra_gcc_objs)
3736 AC_SUBST(extra_headers_list)
3737 AC_SUBST(extra_objs)
3738 AC_SUBST(extra_parts)
3739 AC_SUBST(extra_passes)
3740 AC_SUBST(extra_programs)
3741 AC_SUBST(float_h_file)
3742 AC_SUBST(gcc_config_arguments)
3743 AC_SUBST(gcc_gxx_include_dir)
3744 AC_SUBST(host_exeext)
3745 AC_SUBST(host_xm_file_list)
3746 AC_SUBST(host_xm_include_list)
3747 AC_SUBST(host_xm_defines)
3748 AC_SUBST(out_host_hook_obj)
3749 AC_SUBST(install)
3750 AC_SUBST(lang_opt_files)
3751 AC_SUBST(lang_specs_files)
3752 AC_SUBST(lang_tree_files)
3753 AC_SUBST(local_prefix)
3754 AC_SUBST(md_file)
3755 AC_SUBST(objc_boehm_gc)
3756 AC_SUBST(out_file)
3757 AC_SUBST(out_object_file)
3758 AC_SUBST(stage_prefix_set_by_configure)
3759 AC_SUBST(quoted_stage_prefix_set_by_configure)
3760 AC_SUBST(thread_file)
3761 AC_SUBST(tm_file_list)
3762 AC_SUBST(tm_include_list)
3763 AC_SUBST(tm_defines)
3764 AC_SUBST(tm_p_file_list)
3765 AC_SUBST(tm_p_include_list)
3766 AC_SUBST(xm_file_list)
3767 AC_SUBST(xm_include_list)
3768 AC_SUBST(xm_defines)
3769 AC_SUBST(c_target_objs)
3770 AC_SUBST(cxx_target_objs)
3771 AC_SUBST(target_cpu_default)
3772
3773 AC_SUBST_FILE(language_hooks)
3774
3775 # Echo link setup.
3776 if test x${build} = x${host} ; then
3777   if test x${host} = x${target} ; then
3778     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3779   else
3780     echo "Links are now set up to build a cross-compiler" 1>&2
3781     echo " from ${host} to ${target}." 1>&2
3782   fi
3783 else
3784   if test x${host} = x${target} ; then
3785     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3786     echo " for ${target}." 1>&2
3787   else
3788     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3789     echo " from ${host} to ${target}." 1>&2
3790   fi
3791 fi
3792
3793 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3794 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3795
3796 # Configure the subdirectories
3797 # AC_CONFIG_SUBDIRS($subdirs)
3798
3799 # Create the Makefile
3800 # and configure language subdirectories
3801 AC_CONFIG_FILES($all_outputs)
3802
3803 AC_CONFIG_COMMANDS([default],
3804 [
3805 case ${CONFIG_HEADERS} in
3806   *auto-host.h:config.in*)
3807   echo > cstamp-h ;;
3808 esac
3809 # Make sure all the subdirs exist.
3810 for d in $subdirs doc build
3811 do
3812     test -d $d || mkdir $d
3813 done
3814 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3815 # bootstrapping and the installation procedure can still use
3816 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3817 # FLAGS_TO_PASS has been modified to solve the problem there.
3818 # This is virtually a duplicate of what happens in configure.lang; we do
3819 # an extra check to make sure this only happens if ln -s can be used.
3820 case "$LN_S" in
3821   *-s*)
3822     for d in ${subdirs} ; do
3823         STARTDIR=`${PWDCMD-pwd}`
3824         cd $d
3825         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3826         do
3827                 rm -f $t
3828                 $LN_S ../$t $t 2>/dev/null
3829         done
3830         cd $STARTDIR
3831     done
3832   ;;
3833 esac
3834 ],
3835 [subdirs='$subdirs'])
3836 AC_OUTPUT