gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 326                           -Wmissing-prototypes], [loose_warn])
 327 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 328 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 329                           -Wmissing-format-attribute], [strict_warn])
 330 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 331                                      -Wno-overlength-strings], [strict_warn])
 332 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 333
 334 # The above macros do nothing if the compiler is not GCC.  However, the
 335 # Makefile has more goo to add other flags, so this variabl is used to
 336 # enables warnings only for GCC.
 337 warn_cflags=
 338 if test "x$GCC" = "xyes"; then
 339   warn_cflags='$(GCC_WARN_CFLAGS)'
 340 fi
 341 AC_SUBST(warn_cflags)
 342
 343 # Enable expensive internal checks
 344 is_release=
 345 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 346   is_release=yes
 347 fi
 348
 349 AC_ARG_ENABLE(checking,
 350 [  --enable-checking[=LIST]
 351                           enable expensive run-time checks.  With LIST,
 352                           enable only specific categories of checks.
 353                           Categories are: yes,no,all,none,release.
 354                           Flags are: assert,df,fold,gc,gcac,misc,
 355                           rtlflag,rtl,runtime,tree,valgrind,types.],
 356 [ac_checking_flags="${enableval}"],[
 357 # Determine the default checks.
 358 if test x$is_release = x ; then
 359   ac_checking_flags=yes
 360 else
 361   ac_checking_flags=release
 362 fi])
 363 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 364 for check in release $ac_checking_flags
 365 do
 366         case $check in
 367         # these set all the flags to specific states
 368         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 369                         ac_fold_checking= ; ac_gc_checking=1 ;
 370                         ac_gc_always_collect= ; ac_rtl_checking= ;
 371                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 372                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 373                         ac_types_checking=1 ;;
 374         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 375                         ac_fold_checking= ; ac_gc_checking= ;
 376                         ac_gc_always_collect= ; ac_rtl_checking= ;
 377                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 378                         ac_tree_checking= ; ac_valgrind_checking= ;
 379                         ac_types_checking= ;;
 380         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 381                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 382                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 383                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 384                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 385                         ac_types_checking=1 ;;
 386         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 387                         ac_fold_checking= ; ac_gc_checking= ;
 388                         ac_gc_always_collect= ; ac_rtl_checking= ;
 389                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 390                         ac_tree_checking= ; ac_valgrind_checking= ;
 391                         ac_types_checking= ;;
 392         # these enable particular checks
 393         assert)         ac_assert_checking=1 ;;
 394         df)             ac_df_checking=1 ;;
 395         fold)           ac_fold_checking=1 ;;
 396         gc)             ac_gc_checking=1 ;;
 397         gcac)           ac_gc_always_collect=1 ;;
 398         misc)           ac_checking=1 ;;
 399         rtl)            ac_rtl_checking=1 ;;
 400         rtlflag)        ac_rtlflag_checking=1 ;;
 401         runtime)        ac_runtime_checking=1 ;;
 402         tree)           ac_tree_checking=1 ;;
 403         types)          ac_types_checking=1 ;;
 404         valgrind)       ac_valgrind_checking=1 ;;
 405         *)      AC_MSG_ERROR(unknown check category $check) ;;
 406         esac
 407 done
 408 IFS="$ac_save_IFS"
 409
 410 nocommon_flag=""
 411 if test x$ac_checking != x ; then
 412   AC_DEFINE(ENABLE_CHECKING, 1,
 413 [Define if you want more run-time sanity checks.  This one gets a grab
 414    bag of miscellaneous but relatively cheap checks.])
 415   nocommon_flag=-fno-common
 416 fi
 417 AC_SUBST(nocommon_flag)
 418 if test x$ac_df_checking != x ; then
 419   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 420 [Define if you want more run-time sanity checks for dataflow.])
 421 fi
 422 if test x$ac_assert_checking != x ; then
 423   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 424 [Define if you want assertions enabled.  This is a cheap check.])
 425 fi
 426 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 427 if test x$ac_runtime_checking != x ; then
 428   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 429 [Define if you want runtime assertions enabled.  This is a cheap check.])
 430 fi
 431 if test x$ac_tree_checking != x ; then
 432   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 433 [Define if you want all operations on trees (the basic data
 434    structure of the front ends) to be checked for dynamic type safety
 435    at runtime.  This is moderately expensive.  The tree browser debugging
 436    routines will also be enabled by this option.
 437    ])
 438   TREEBROWSER=tree-browser.o
 439 fi
 440 if test x$ac_types_checking != x ; then
 441   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 442 [Define if you want all gimple types to be verified after gimplifiation.
 443    This is cheap.
 444    ])
 445 fi
 446 AC_SUBST(TREEBROWSER)
 447 if test x$ac_rtl_checking != x ; then
 448   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 449 [Define if you want all operations on RTL (the basic data structure
 450    of the optimizer and back end) to be checked for dynamic type safety
 451    at runtime.  This is quite expensive.])
 452 fi
 453 if test x$ac_rtlflag_checking != x ; then
 454   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 455 [Define if you want RTL flag accesses to be checked against the RTL
 456    codes that are supported for each access macro.  This is relatively
 457    cheap.])
 458 fi
 459 if test x$ac_gc_checking != x ; then
 460   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 461 [Define if you want the garbage collector to do object poisoning and
 462    other memory allocation checks.  This is quite expensive.])
 463 fi
 464 if test x$ac_gc_always_collect != x ; then
 465   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 466 [Define if you want the garbage collector to operate in maximally
 467    paranoid mode, validating the entire heap and collecting garbage at
 468    every opportunity.  This is extremely expensive.])
 469 fi
 470 if test x$ac_fold_checking != x ; then
 471   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 472 [Define if you want fold checked that it never destructs its argument.
 473    This is quite expensive.])
 474 fi
 475 valgrind_path_defines=
 476 valgrind_command=
 477
 478 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 479 dnl # an if statement.  This was the source of very frustrating bugs
 480 dnl # in converting to autoconf 2.5x!
 481 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 482
 483 if test x$ac_valgrind_checking != x ; then
 484   # It is certainly possible that there's valgrind but no valgrind.h.
 485   # GCC relies on making annotations so we must have both.
 486   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 487   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 488     [[#include <valgrind/memcheck.h>
 489 #ifndef VALGRIND_DISCARD
 490 #error VALGRIND_DISCARD not defined
 491 #endif]])],
 492   [gcc_cv_header_valgrind_memcheck_h=yes],
 493   [gcc_cv_header_valgrind_memcheck_h=no])
 494   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_memcheck_h=yes],
 502   [gcc_cv_header_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 504   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 505         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 506   if test "x$valgrind_path" = "x" \
 507     || (test $have_valgrind_h = no \
 508         && test $gcc_cv_header_memcheck_h = no \
 509         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 510         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 511   fi
 512   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 513   valgrind_command="$valgrind_path -q"
 514   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 515 [Define if you want to run subprograms and generated programs
 516    through valgrind (a memory checker).  This is extremely expensive.])
 517   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 518     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 519         [Define if valgrind's valgrind/memcheck.h header is installed.])
 520   fi
 521   if test $gcc_cv_header_memcheck_h = yes; then
 522     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 523         [Define if valgrind's memcheck.h header is installed.])
 524   fi
 525 fi
 526 AC_SUBST(valgrind_path_defines)
 527 AC_SUBST(valgrind_command)
 528
 529 # Enable code coverage collection
 530 AC_ARG_ENABLE(coverage,
 531 [  --enable-coverage[=LEVEL]
 532                           enable compiler's code coverage collection.
 533                           Use to measure compiler performance and locate
 534                           unused parts of the compiler. With LEVEL, specify
 535                           optimization. Values are opt, noopt,
 536                           default is noopt],
 537 [case "${enableval}" in
 538   yes|noopt)
 539     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 540     ;;
 541   opt)
 542     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 543     ;;
 544   no)
 545     # a.k.a. --disable-coverage
 546     coverage_flags=""
 547     ;;
 548   *)
 549     AC_MSG_ERROR(unknown coverage setting $enableval)
 550     ;;
 551 esac],
 552 [coverage_flags=""])
 553 AC_SUBST(coverage_flags)
 554
 555 AC_ARG_ENABLE(gather-detailed-mem-stats,
 556 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 557 [enable_gather_detailed_mem_stats=no])
 558 if test x$enable_gather_detailed_mem_stats = xyes ; then
 559   AC_DEFINE(GATHER_STATISTICS, 1,
 560         [Define to enable detailed memory allocation stats gathering.])
 561 fi
 562
 563 # -------------------------------
 564 # Miscenalleous configure options
 565 # -------------------------------
 566
 567 # With stabs
 568 AC_ARG_WITH(stabs,
 569 [  --with-stabs            arrange to use stabs instead of host debug format],
 570 stabs="$with_stabs",
 571 stabs=no)
 572
 573 # Determine whether or not multilibs are enabled.
 574 AC_ARG_ENABLE(multilib,
 575 [  --enable-multilib       enable library support for multiple ABIs],
 576 [], [enable_multilib=yes])
 577 AC_SUBST(enable_multilib)
 578
 579 # Enable __cxa_atexit for C++.
 580 AC_ARG_ENABLE(__cxa_atexit,
 581 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 582 [], [])
 583
 584 # Enable C extension for decimal float if target supports it.
 585 AC_ARG_ENABLE(decimal-float,
 586 [  --enable-decimal-float={no,yes,bid,dpd}
 587                         enable decimal float extension to C.  Selecting 'bid'
 588                         or 'dpd' choses which decimal floating point format
 589                         to use],
 590 [
 591   case $enable_decimal_float in
 592     yes | no | bid | dpd) ;;
 593     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 594 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 595   esac
 596 ],
 597 [
 598   case $target in
 599     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 600       enable_decimal_float=yes
 601       ;;
 602     *)
 603       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 604       enable_decimal_float=no
 605       ;;
 606   esac
 607 ])
 608
 609 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 610 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 611 [Define to 1 to enable decimal float extension to C.])
 612
 613 # x86's use BID format instead of DPD
 614 case x$enable_decimal_float in
 615   xyes)
 616     case $target in
 617       i?86*-*-linux* | x86_64*-*-linux*)
 618         enable_decimal_float=bid
 619         ;;
 620       *)
 621         enable_decimal_float=dpd
 622         ;;
 623     esac
 624     ;;
 625   xno)
 626     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 627     # dependency on libdecnumber.
 628     enable_decimal_float=dpd
 629     ;;
 630 esac
 631 AC_SUBST(enable_decimal_float)
 632
 633 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 635 [Define to 1 to specify that we are using the BID decimal floating
 636 point format instead of DPD])
 637
 638 # Enable C extension for fixed-point arithmetic.
 639 AC_ARG_ENABLE(fixed-point,
 640 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 641 [
 642 ],
 643 [
 644   case $target in
 645     mips*-*-*)
 646       case $host in
 647         mips*-sgi-irix*)
 648           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 649           enable_fixed_point=no
 650           ;;
 651         *)
 652           enable_fixed_point=yes
 653           ;;
 654       esac
 655       ;;
 656     *)
 657       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 658       enable_fixed_point=no
 659       ;;
 660   esac
 661 ])
 662 AC_SUBST(enable_fixed_point)
 663
 664 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 665 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 666 [Define to 1 to enable fixed-point arithmetic extension to C.])
 667
 668 # Enable threads
 669 # Pass with no value to take the default
 670 # Pass with a value to specify a thread package
 671 AC_ARG_ENABLE(threads,
 672 [  --enable-threads        enable thread usage for target GCC
 673   --enable-threads=LIB    use LIB thread package for target GCC],,
 674 [enable_threads=''])
 675
 676 AC_ARG_ENABLE(tls,
 677 [  --enable-tls            enable or disable generation of tls code
 678                           overriding the assembler check for tls support],
 679 [
 680   case $enable_tls in
 681     yes | no) ;;
 682     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 683 Valid choices are 'yes' and 'no'.]) ;;
 684   esac
 685 ], [enable_tls=''])
 686
 687 AC_ARG_ENABLE(objc-gc,
 688 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 689                           the GNU Objective-C runtime],
 690 if test x$enable_objc_gc = xno; then
 691         objc_boehm_gc=''
 692 else
 693         objc_boehm_gc=1
 694 fi,
 695 objc_boehm_gc='')
 696
 697 AC_ARG_WITH(dwarf2,
 698 [  --with-dwarf2           force the default debug format to be DWARF 2],
 699 dwarf2="$with_dwarf2",
 700 dwarf2=no)
 701
 702 AC_ARG_ENABLE(shared,
 703 [  --disable-shared        don't provide a shared libgcc],
 704 [
 705   case $enable_shared in
 706   yes | no) ;;
 707   *)
 708     enable_shared=no
 709     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 710     for pkg in $enableval; do
 711       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 712         enable_shared=yes
 713       fi
 714     done
 715     IFS="$ac_save_ifs"
 716     ;;
 717   esac
 718 ], [enable_shared=yes])
 719 AC_SUBST(enable_shared)
 720
 721 AC_ARG_WITH(build-sysroot,
 722   [  --with-build-sysroot=sysroot
 723                           use sysroot as the system root during the build])
 724
 725 AC_ARG_WITH(sysroot,
 726 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 727 [
 728  case ${with_sysroot} in
 729  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 730  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 731  esac
 732
 733  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 734  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 735
 736  if test "x$prefix" = xNONE; then
 737   test_prefix=/usr/local
 738  else
 739   test_prefix=$prefix
 740  fi
 741  if test "x$exec_prefix" = xNONE; then
 742   test_exec_prefix=$test_prefix
 743  else
 744   test_exec_prefix=$exec_prefix
 745  fi
 746  case ${TARGET_SYSTEM_ROOT} in
 747  "${test_prefix}"|"${test_prefix}/"*|\
 748  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 749  '${prefix}'|'${prefix}/'*|\
 750  '${exec_prefix}'|'${exec_prefix}/'*)
 751    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 752    TARGET_SYSTEM_ROOT_DEFINE="$t"
 753    ;;
 754  esac
 755 ], [
 756  TARGET_SYSTEM_ROOT=
 757  TARGET_SYSTEM_ROOT_DEFINE=
 758  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 759 ])
 760 AC_SUBST(TARGET_SYSTEM_ROOT)
 761 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 762 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 763
 764 # Build with intermodule optimisations
 765 AC_ARG_ENABLE(intermodule,
 766 [  --enable-intermodule    build the compiler in one step],
 767 [case ${enable_intermodule} in
 768   yes) onestep="-onestep";;
 769   *) onestep="";;
 770 esac],
 771 [onestep=""])
 772 AC_SUBST(onestep)
 773
 774 ACX_PKGVERSION([GCC])
 775 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 776
 777 # Sanity check enable_languages in case someone does not run the toplevel
 778 # configure # script.
 779 AC_ARG_ENABLE(languages,
 780 [  --enable-languages=LIST specify which front-ends to build],
 781 [case ,${enable_languages}, in
 782        ,,|,yes,)
 783                 # go safe -- we cannot be much sure without the toplevel
 784                 # configure's
 785                 # analysis of which target libs are present and usable
 786                 enable_languages=c
 787                 ;;
 788          *,all,*)
 789                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 790                 ;;
 791         *,c,*)
 792                 ;;
 793         *)
 794                 enable_languages=c,${enable_languages}
 795                 ;;
 796 esac],
 797 [enable_languages=c])
 798
 799 # Used by documentation targets
 800 AC_SUBST(datarootdir)
 801 AC_SUBST(docdir)
 802 AC_SUBST(htmldir)
 803
 804 # -------------------------
 805 # Checks for other programs
 806 # -------------------------
 807
 808 AC_PROG_MAKE_SET
 809
 810 # Find some useful tools
 811 AC_PROG_AWK
 812 # We need awk to create options.c and options.h.
 813 # Bail out if it's missing.
 814 case ${AWK} in
 815   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 816 esac
 817
 818 gcc_AC_PROG_LN_S
 819 ACX_PROG_LN($LN_S)
 820 AC_PROG_RANLIB
 821 case "${host}" in
 822 *-*-darwin*)
 823   # By default, the Darwin ranlib will not treat common symbols as
 824   # definitions when  building the archive table of contents.  Other
 825   # ranlibs do that; pass an option to the Darwin ranlib that makes
 826   # it behave similarly.
 827   ranlib_flags="-c"
 828   ;;
 829 *)
 830   ranlib_flags=""
 831 esac
 832 AC_SUBST(ranlib_flags)
 833
 834 gcc_AC_PROG_INSTALL
 835
 836 # See if cmp has --ignore-initial.
 837 gcc_AC_PROG_CMP_IGNORE_INITIAL
 838
 839 # See if we have the mktemp command.
 840 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 841
 842 # See if makeinfo has been installed and is modern enough
 843 # that we can use it.
 844 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 845   [GNU texinfo.* \([0-9][0-9.]*\)],
 846   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 847 if test $gcc_cv_prog_makeinfo_modern = no; then
 848   AC_MSG_WARN([
 849 *** Makeinfo is missing or too old.
 850 *** Info documentation will not be built.])
 851   BUILD_INFO=
 852 else
 853   BUILD_INFO=info
 854 fi
 855 AC_SUBST(BUILD_INFO)
 856
 857 # Is pod2man recent enough to regenerate manpages?
 858 AC_MSG_CHECKING([for recent Pod::Man])
 859 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 860   AC_MSG_RESULT(yes)
 861   GENERATED_MANPAGES=generated-manpages
 862 else
 863   AC_MSG_RESULT(no)
 864   GENERATED_MANPAGES=
 865 fi
 866 AC_SUBST(GENERATED_MANPAGES)
 867
 868 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 869
 870 # How about lex?
 871 dnl Don't use AC_PROG_LEX; we insist on flex.
 872 dnl LEXLIB is not useful in gcc.
 873 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 874
 875 # Bison?
 876 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 877
 878 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 879 # check for build == host before using them.
 880
 881 # NM
 882 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 883   && test -d ../binutils ; then
 884   NM='$(objdir)/../binutils/nm-new'
 885 else
 886   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 887 fi
 888
 889 # AR
 890 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 891   && test -d ../binutils ; then
 892   AR='$(objdir)/../binutils/ar'
 893 else
 894   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 895 fi
 896
 897
 898 # --------------------
 899 # Checks for C headers
 900 # --------------------
 901
 902 # Need to reject headers which give warnings, so that the -Werror bootstrap
 903 # works later. *sigh*  This needs to come before all header checks.
 904 AC_PROG_CPP_WERROR
 905
 906 AC_HEADER_STDC
 907 AC_HEADER_TIME
 908 ACX_HEADER_STRING
 909 AC_HEADER_SYS_WAIT
 910 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 911                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 912                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 913                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 914
 915 # Check for thread headers.
 916 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 917 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 918
 919 # These tests can't be done till we know if we have limits.h.
 920 gcc_AC_C_CHAR_BIT
 921 AC_C_BIGENDIAN
 922
 923 # --------
 924 # UNSORTED
 925 # --------
 926
 927
 928 # These libraries may be used by collect2.
 929 # We may need a special search path to get them linked.
 930 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 931 [save_LIBS="$LIBS"
 932 for libs in '' -lld -lmld \
 933                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 934                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 935 do
 936         LIBS="$libs"
 937         AC_TRY_LINK_FUNC(ldopen,
 938                 [gcc_cv_collect2_libs="$libs"; break])
 939 done
 940 LIBS="$save_LIBS"
 941 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 942 case $gcc_cv_collect2_libs in
 943         "none required")        ;;
 944         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 945 esac
 946 AC_SUBST(COLLECT2_LIBS)
 947
 948 # When building Ada code on Alpha, we need exc_resume which is usually in
 949 # -lexc.  So test for it.
 950 save_LIBS="$LIBS"
 951 LIBS=
 952 AC_SEARCH_LIBS(exc_resume, exc)
 953 GNAT_LIBEXC="$LIBS"
 954 LIBS="$save_LIBS"
 955 AC_SUBST(GNAT_LIBEXC)
 956
 957 # Some systems put ldexp and frexp in libm instead of libc; assume
 958 # they're both in the same place.  jcf-dump needs them.
 959 save_LIBS="$LIBS"
 960 LIBS=
 961 AC_SEARCH_LIBS(ldexp, m)
 962 LDEXP_LIB="$LIBS"
 963 LIBS="$save_LIBS"
 964 AC_SUBST(LDEXP_LIB)
 965
 966 # Use <inttypes.h> only if it exists,
 967 # doesn't clash with <sys/types.h>, and declares intmax_t.
 968 AC_MSG_CHECKING(for inttypes.h)
 969 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 970 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 971 [[#include <sys/types.h>
 972 #include <inttypes.h>]],
 973   [[intmax_t i = -1;]])],
 974   [gcc_cv_header_inttypes_h=yes],
 975   [gcc_cv_header_inttypes_h=no])])
 976 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 977 if test $gcc_cv_header_inttypes_h = yes; then
 978   AC_DEFINE(HAVE_INTTYPES_H, 1,
 979         [Define if you have a working <inttypes.h> header file.])
 980 fi
 981
 982 dnl Disabled until we have a complete test for buggy enum bitfields.
 983 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 984
 985 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 986   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 987   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 988   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 989   putchar_unlocked putc_unlocked)
 990 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 991         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 992         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 993         gcc_UNLOCKED_FUNCS)
 994
 995 if test x$ac_cv_func_mbstowcs = xyes; then
 996   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 997 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 998 int main()
 999 {
1000   mbstowcs(0, "", 0);
1001   return 0;
1002 }]])],
1003     [gcc_cv_func_mbstowcs_works=yes],
1004     [gcc_cv_func_mbstowcs_works=no],
1005     [gcc_cv_func_mbstowcs_works=yes])])
1006   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1007     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1008   [Define this macro if mbstowcs does not crash when its
1009    first argument is NULL.])
1010   fi
1011 fi
1012
1013 AC_CHECK_TYPE(ssize_t, int)
1014
1015 # Try to determine the array type of the second argument of getgroups
1016 # for the target system (int or gid_t).
1017 AC_TYPE_GETGROUPS
1018 if test "${target}" = "${build}"; then
1019   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1020 else
1021   case "${target}" in
1022         # This condition may need some tweaking.  It should include all
1023         # targets where the array type of the second argument of getgroups
1024         # is int and the type of gid_t is not equivalent to int.
1025         *-*-sunos* | *-*-ultrix*)
1026                 TARGET_GETGROUPS_T=int
1027                 ;;
1028         *)
1029                 TARGET_GETGROUPS_T=gid_t
1030                 ;;
1031   esac
1032 fi
1033 AC_SUBST(TARGET_GETGROUPS_T)
1034
1035 gcc_AC_FUNC_MMAP_BLACKLIST
1036
1037 case "${host}" in
1038 *-*-*vms*)
1039   # Under VMS, vfork works very differently than on Unix. The standard test
1040   # won't work, and it isn't easily adaptable. It makes more sense to
1041   # just force it.
1042   ac_cv_func_vfork_works=yes
1043   ;;
1044 esac
1045 AC_FUNC_FORK
1046
1047 AM_ICONV
1048 # Until we have in-tree GNU iconv:
1049 LIBICONV_DEP=
1050 AC_SUBST(LIBICONV_DEP)
1051
1052 AM_LC_MESSAGES
1053
1054 AM_LANGINFO_CODESET
1055
1056 # We will need to find libiberty.h and ansidecl.h
1057 saved_CFLAGS="$CFLAGS"
1058 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1059 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1060         strsignal strstr strverscmp \
1061         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1062         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1063 #include "ansidecl.h"
1064 #include "system.h"])
1065
1066 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1067 #include "ansidecl.h"
1068 #include "system.h"
1069 #ifdef HAVE_SYS_RESOURCE_H
1070 #include <sys/resource.h>
1071 #endif
1072 ])
1073
1074 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_SYS_RESOURCE_H
1078 #include <sys/resource.h>
1079 #endif
1080 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1081 [Define to `long' if <sys/resource.h> doesn't define.])])
1082
1083 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1084 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1085 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1086 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1087 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_LDFCN_H
1091 #undef FREAD
1092 #undef FWRITE
1093 #include <ldfcn.h>
1094 #endif
1095 ])
1096
1097 gcc_AC_CHECK_DECLS(times, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_SYS_TIMES_H
1101 #include <sys/times.h>
1102 #endif
1103 ])
1104
1105 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1106 #include "ansidecl.h"
1107 #include "system.h"
1108 #include <signal.h>
1109 ])
1110
1111 # More time-related stuff.
1112 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1113 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1114 #include "ansidecl.h"
1115 #include "system.h"
1116 #ifdef HAVE_SYS_TIMES_H
1117 #include <sys/times.h>
1118 #endif
1119 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1120 if test $ac_cv_struct_tms = yes; then
1121   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1122   [Define if <sys/times.h> defines struct tms.])
1123 fi
1124
1125 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1126 # revisit after autoconf 2.50.
1127 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1128 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1129 #include "ansidecl.h"
1130 #include "system.h"
1131 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1132 if test $gcc_cv_type_clock_t = yes; then
1133   AC_DEFINE(HAVE_CLOCK_T, 1,
1134   [Define if <time.h> defines clock_t.])
1135 fi
1136
1137 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1138 CFLAGS="$saved_CFLAGS"
1139
1140 gcc_AC_INITFINI_ARRAY
1141
1142 # mkdir takes a single argument on some systems.
1143 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1144
1145 # File extensions
1146 manext='.1'
1147 objext='.o'
1148 AC_SUBST(manext)
1149 AC_SUBST(objext)
1150
1151 # With Setjmp/Longjmp based exception handling.
1152 AC_ARG_ENABLE(sjlj-exceptions,
1153 [  --enable-sjlj-exceptions
1154                           arrange to use setjmp/longjmp exception handling],
1155 [case $target in
1156   *-*-hpux10*)
1157     if test $enableval != yes; then
1158       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1159       enableval=yes
1160     fi
1161     ;;
1162 esac
1163 force_sjlj_exceptions=yes],
1164 [case $target in
1165   *-*-hpux10*)
1166     force_sjlj_exceptions=yes
1167     enableval=yes
1168     ;;
1169   *)
1170     force_sjlj_exceptions=no
1171     ;;
1172 esac])
1173 if test $force_sjlj_exceptions = yes; then
1174   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1175   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1176     [Define 0/1 to force the choice for exception handling model.])
1177 fi
1178
1179 # For platforms with the unwind ABI which includes an unwind library,
1180 # libunwind, we can choose to use the system libunwind.
1181 AC_ARG_WITH(system-libunwind,
1182 [  --with-system-libunwind use installed libunwind])
1183
1184 # config.gcc also contains tests of with_system_libunwind.
1185 if test x$with_system_libunwind = xyes; then
1186         AC_DEFINE(HAVE_GETIPINFO, 1,
1187 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1188 fi
1189
1190 # --------------------------------------------------------
1191 # Build, host, and target specific configuration fragments
1192 # --------------------------------------------------------
1193
1194 # Collect build-machine-specific information.
1195 . ${srcdir}/config.build
1196
1197 # Collect host-machine-specific information.
1198 . ${srcdir}/config.host
1199
1200 target_gtfiles=
1201
1202 # Collect target-machine-specific information.
1203 . ${srcdir}/config.gcc
1204
1205 extra_objs="${host_extra_objs} ${extra_objs}"
1206 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1207
1208 # Default the target-machine variables that were not explicitly set.
1209 if test x"$tm_file" = x
1210 then tm_file=$cpu_type/$cpu_type.h; fi
1211
1212 if test x"$extra_headers" = x
1213 then extra_headers=; fi
1214
1215 if test x$md_file = x
1216 then md_file=$cpu_type/$cpu_type.md; fi
1217
1218 if test x$out_file = x
1219 then out_file=$cpu_type/$cpu_type.c; fi
1220
1221 if test x"$tmake_file" = x
1222 then tmake_file=$cpu_type/t-$cpu_type
1223 fi
1224
1225 if test x"$dwarf2" = xyes
1226 then tm_file="$tm_file tm-dwarf2.h"
1227 fi
1228
1229 # Say what files are being used for the output code and MD file.
1230 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1231 echo "Using \`$srcdir/config/$md_file' as machine description file."
1232
1233 # If any of the xm_file variables contain nonexistent files, warn
1234 # about them and drop them.
1235
1236 bx=
1237 for x in $build_xm_file; do
1238   if    test -f $srcdir/config/$x
1239   then      bx="$bx $x"
1240   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1241   fi
1242 done
1243 build_xm_file="$bx"
1244
1245 hx=
1246 for x in $host_xm_file; do
1247   if    test -f $srcdir/config/$x
1248   then      hx="$hx $x"
1249   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1250   fi
1251 done
1252 host_xm_file="$hx"
1253
1254 tx=
1255 for x in $xm_file; do
1256   if    test -f $srcdir/config/$x
1257   then      tx="$tx $x"
1258   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1259   fi
1260 done
1261 xm_file="$tx"
1262
1263 count=a
1264 for f in $tm_file; do
1265         count=${count}x
1266 done
1267 if test $count = ax; then
1268         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1269 else
1270         echo "Using the following target machine macro files:"
1271         for f in $tm_file; do
1272                 echo "  $srcdir/config/$f"
1273         done
1274 fi
1275
1276 if test x$need_64bit_hwint = xyes; then
1277         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1278 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1279 fi
1280
1281 if test x$use_long_long_for_widest_fast_int = xyes; then
1282         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1283 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1284 efficiently supported by the host hardware.])
1285 fi
1286
1287 count=a
1288 for f in $host_xm_file; do
1289         count=${count}x
1290 done
1291 if test $count = a; then
1292         :
1293 elif test $count = ax; then
1294         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1295 else
1296         echo "Using the following host machine macro files:"
1297         for f in $host_xm_file; do
1298                 echo "  $srcdir/config/$f"
1299         done
1300 fi
1301 echo "Using ${out_host_hook_obj} for host machine hooks."
1302
1303 if test "$host_xm_file" != "$build_xm_file"; then
1304         count=a
1305         for f in $build_xm_file; do
1306                 count=${count}x
1307         done
1308         if test $count = a; then
1309                 :
1310         elif test $count = ax; then
1311                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1312         else
1313                 echo "Using the following build machine macro files:"
1314                 for f in $build_xm_file; do
1315                         echo "  $srcdir/config/$f"
1316                 done
1317         fi
1318 fi
1319
1320 case ${host} in
1321   powerpc*-*-darwin*)
1322     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1323       gcc_cv_mcontext_underscores,
1324       AC_COMPILE_IFELSE([
1325 #include <sys/cdefs.h>
1326 #include <sys/signal.h>
1327 #include <ucontext.h>
1328 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1329 ],
1330         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1331       if test $gcc_cv_mcontext_underscores = yes; then
1332         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1333           [mcontext_t fields start with __])
1334       fi
1335     ;;
1336 esac
1337
1338 # ---------
1339 # Threading
1340 # ---------
1341
1342 # Check if a valid thread package
1343 case ${enable_threads} in
1344   "" | no)
1345     # No threads
1346     target_thread_file='single'
1347     ;;
1348   yes)
1349     # default
1350     target_thread_file='single'
1351     ;;
1352   aix | dce | gnat | irix | posix | posix95 | rtems | \
1353   single | solaris | vxworks | win32 | mipssde)
1354     target_thread_file=${enable_threads}
1355     ;;
1356   *)
1357     echo "${enable_threads} is an unknown thread package" 1>&2
1358     exit 1
1359     ;;
1360 esac
1361
1362 if test x${thread_file} = x; then
1363   # No thread file set by target-specific clauses in config.gcc,
1364   # so use file chosen by default logic above
1365   thread_file=${target_thread_file}
1366 fi
1367
1368 # Make gthr-default.h if we have a thread file.
1369 gthread_flags=
1370 if test $thread_file != single; then
1371   rm -f gthr-default.h
1372   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1373   gthread_flags=-DHAVE_GTHR_DEFAULT
1374 fi
1375 AC_SUBST(gthread_flags)
1376
1377 # --------
1378 # UNSORTED
1379 # --------
1380
1381 use_cxa_atexit=no
1382 if test x$enable___cxa_atexit = xyes || \
1383    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1384   if test x$host = x$target; then
1385     case $host in
1386       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1387       # keyed to flag_use_cxa_atexit
1388       *-*-mingw32*)
1389         use_cxa_atexit=yes
1390         ;;
1391       *)
1392         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1393           [echo "__cxa_atexit can't be enabled on this target"])
1394         ;;
1395     esac
1396   else
1397     # We can't check for __cxa_atexit when building a cross, so assume
1398     # it is available
1399     use_cxa_atexit=yes
1400   fi
1401   if test x$use_cxa_atexit = xyes; then
1402     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1403       [Define if you want to use __cxa_atexit, rather than atexit, to
1404       register C++ destructors for local statics and global objects.
1405       This is essential for fully standards-compliant handling of
1406       destructors, but requires __cxa_atexit in libc.])
1407   fi
1408 fi
1409
1410 use_getipinfo=yes
1411 if test x$with_system_libunwind = xyes; then
1412    if test x$host = x$target; then
1413      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1414    fi
1415 fi
1416 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1417 if test x$use_getipinfo = xyes; then
1418    AC_DEFINE(HAVE_GETIPINFO, 1,
1419         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1420 else
1421    echo "The system unwind library does not support _Unwind_GetIPInfo."
1422 fi
1423
1424 # Look for a file containing extra machine modes.
1425 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1426   extra_modes_file='$(srcdir)'/config/${extra_modes}
1427   AC_SUBST(extra_modes_file)
1428   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1429   [Define to the name of a file containing a list of extra machine modes
1430    for this architecture.])
1431 fi
1432
1433 # Convert extra_options into a form suitable for Makefile use.
1434 extra_opt_files=
1435 for f in $extra_options; do
1436   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1437 done
1438 AC_SUBST(extra_opt_files)
1439
1440 # auto-host.h is the file containing items generated by autoconf and is
1441 # the first file included by config.h.
1442 # If host=build, it is correct to have bconfig include auto-host.h
1443 # as well.  If host!=build, we are in error and need to do more
1444 # work to find out the build config parameters.
1445 if test x$host = x$build
1446 then
1447         build_auto=auto-host.h
1448 else
1449         # We create a subdir, then run autoconf in the subdir.
1450         # To prevent recursion we set host and build for the new
1451         # invocation of configure to the build for this invocation
1452         # of configure.
1453         tempdir=build.$$
1454         rm -rf $tempdir
1455         mkdir $tempdir
1456         cd $tempdir
1457         case ${srcdir} in
1458         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1459         *) realsrcdir=../${srcdir};;
1460         esac
1461         saved_CFLAGS="${CFLAGS}"
1462         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1463         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1464         ${realsrcdir}/configure \
1465                 --enable-languages=${enable_languages-all} \
1466                 --target=$target_alias --host=$build_alias --build=$build_alias
1467         CFLAGS="${saved_CFLAGS}"
1468
1469         # We just finished tests for the build machine, so rename
1470         # the file auto-build.h in the gcc directory.
1471         mv auto-host.h ../auto-build.h
1472         cd ..
1473         rm -rf $tempdir
1474         build_auto=auto-build.h
1475 fi
1476 AC_SUBST(build_subdir)
1477
1478 tm_file="${tm_file} defaults.h"
1479 tm_p_file="${tm_p_file} tm-preds.h"
1480 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1481 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1482 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1483 # put this back in temporarily.
1484 xm_file="auto-host.h ansidecl.h ${xm_file}"
1485
1486 # --------
1487 # UNSORTED
1488 # --------
1489
1490 changequote(,)dnl
1491 # Compile in configure arguments.
1492 if test -f configargs.h ; then
1493         # Being re-configured.
1494         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1495         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1496 else
1497         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1498 fi
1499
1500 # Double all backslashes and backslash all quotes to turn
1501 # gcc_config_arguments into a C string.
1502 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1503 $gcc_config_arguments
1504 EOF
1505 gcc_config_arguments_str=`cat conftest.out`
1506 rm -f conftest.out
1507
1508 cat > configargs.h <<EOF
1509 /* Generated automatically. */
1510 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1511 static const char thread_model[] = "$thread_file";
1512
1513 static const struct {
1514   const char *name, *value;
1515 } configure_default_options[] = $configure_default_options;
1516 EOF
1517 changequote([,])dnl
1518
1519 # Internationalization
1520 ZW_GNU_GETTEXT_SISTER_DIR
1521
1522 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1523 # -liconv on the link line twice.
1524 case "$LIBINTL" in *$LIBICONV*)
1525         LIBICONV= ;;
1526 esac
1527
1528 AC_ARG_ENABLE(secureplt,
1529 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1530 [], [])
1531
1532 AC_ARG_ENABLE(cld,
1533 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1534 [enable_cld=no])
1535
1536 # Windows32 Registry support for specifying GCC installation paths.
1537 AC_ARG_ENABLE(win32-registry,
1538 [  --disable-win32-registry
1539                           disable lookup of installation paths in the
1540                           Registry on Windows hosts
1541   --enable-win32-registry enable registry lookup (default)
1542   --enable-win32-registry=KEY
1543                           use KEY instead of GCC version as the last portion
1544                           of the registry key],,)
1545
1546 case $host_os in
1547   win32 | pe | cygwin* | mingw32* | uwin*)
1548     if test "x$enable_win32_registry" != xno; then
1549       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1550     fi
1551
1552     if test "x$enable_win32_registry" != xno; then
1553       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1554   [Define to 1 if installation paths should be looked up in the Windows
1555    Registry. Ignored on non-Windows hosts.])
1556
1557       if test "x$enable_win32_registry" != xyes \
1558          && test "x$enable_win32_registry" != x; then
1559         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1560   [Define to be the last component of the Windows registry key under which
1561    to look for installation paths.  The full key used will be
1562    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1563    The default is the GCC version number.])
1564       fi
1565     fi
1566   ;;
1567 esac
1568
1569 # Get an absolute path to the GCC top-level source directory
1570 holddir=`${PWDCMD-pwd}`
1571 cd $srcdir
1572 topdir=`${PWDCMD-pwd}`
1573 cd $holddir
1574
1575 # Conditionalize the makefile for this host machine.
1576 xmake_file=
1577 for f in ${host_xmake_file}
1578 do
1579         if test -f ${srcdir}/config/$f
1580         then
1581                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1582         fi
1583 done
1584
1585 # Conditionalize the makefile for this target machine.
1586 tmake_file_=
1587 for f in ${tmake_file}
1588 do
1589         if test -f ${srcdir}/config/$f
1590         then
1591                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1592         fi
1593 done
1594 tmake_file="${tmake_file_}"
1595
1596 # This is a terrible hack which will go away some day.
1597 host_cc_for_libada=${CC}
1598 AC_SUBST(host_cc_for_libada)
1599
1600 out_object_file=`basename $out_file .c`.o
1601
1602 tm_file_list="options.h"
1603 tm_include_list="options.h"
1604 for f in $tm_file; do
1605   case $f in
1606     ./* )
1607        f=`echo $f | sed 's/^..//'`
1608        tm_file_list="${tm_file_list} $f"
1609        tm_include_list="${tm_include_list} $f"
1610        ;;
1611     defaults.h )
1612        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1613        tm_include_list="${tm_include_list} $f"
1614        ;;
1615     * )
1616        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1617        tm_include_list="${tm_include_list} config/$f"
1618        ;;
1619   esac
1620 done
1621
1622 tm_p_file_list=
1623 tm_p_include_list=
1624 for f in $tm_p_file; do
1625   case $f in
1626     tm-preds.h )
1627        tm_p_file_list="${tm_p_file_list} $f"
1628        tm_p_include_list="${tm_p_include_list} $f"
1629        ;;
1630     * )
1631        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1632        tm_p_include_list="${tm_p_include_list} config/$f"
1633   esac
1634 done
1635
1636 xm_file_list=
1637 xm_include_list=
1638 for f in $xm_file; do
1639   case $f in
1640     ansidecl.h )
1641        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1642        xm_include_list="${xm_include_list} $f"
1643        ;;
1644     auto-host.h )
1645        xm_file_list="${xm_file_list} $f"
1646        xm_include_list="${xm_include_list} $f"
1647        ;;
1648     * )
1649        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1650        xm_include_list="${xm_include_list} config/$f"
1651        ;;
1652   esac
1653 done
1654
1655 host_xm_file_list=
1656 host_xm_include_list=
1657 for f in $host_xm_file; do
1658   case $f in
1659     ansidecl.h )
1660        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1661        host_xm_include_list="${host_xm_include_list} $f"
1662        ;;
1663     auto-host.h )
1664        host_xm_file_list="${host_xm_file_list} $f"
1665        host_xm_include_list="${host_xm_include_list} $f"
1666        ;;
1667     * )
1668        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1669        host_xm_include_list="${host_xm_include_list} config/$f"
1670        ;;
1671   esac
1672 done
1673
1674 build_xm_file_list=
1675 for f in $build_xm_file; do
1676   case $f in
1677     ansidecl.h )
1678        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1679        build_xm_include_list="${build_xm_include_list} $f"
1680        ;;
1681     auto-build.h | auto-host.h )
1682        build_xm_file_list="${build_xm_file_list} $f"
1683        build_xm_include_list="${build_xm_include_list} $f"
1684        ;;
1685     * )
1686        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1687        build_xm_include_list="${build_xm_include_list} config/$f"
1688        ;;
1689   esac
1690 done
1691
1692 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1693 # cross-compiler which does not use the native headers and libraries.
1694 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1695 CROSS=                                          AC_SUBST(CROSS)
1696 ALL=all.internal                                AC_SUBST(ALL)
1697 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1698
1699 if test "x$with_build_sysroot" != x; then
1700   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1701 else
1702   # This value is used, even on a native system, because
1703   # CROSS_SYSTEM_HEADER_DIR is just
1704   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1705   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1706 fi
1707
1708 if test x$host != x$target
1709 then
1710         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1711         ALL=all.cross
1712         SYSTEM_HEADER_DIR=$build_system_header_dir
1713         case "$host","$target" in
1714         # Darwin crosses can use the host system's libraries and headers,
1715         # because of the fat library support.  Of course, it must be the
1716         # same version of Darwin on both sides.  Allow the user to
1717         # just say --target=foo-darwin without a version number to mean
1718         # "the version on this system".
1719             *-*-darwin*,*-*-darwin*)
1720                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1721                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1722                 if test $hostos = $targetos -o $targetos = darwin ; then
1723                     CROSS=
1724                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1725                     with_headers=yes
1726                 fi
1727                 ;;
1728
1729             i?86-*-*,x86_64-*-* \
1730             | powerpc*-*-*,powerpc64*-*-*)
1731                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1732         esac
1733 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1734         SYSTEM_HEADER_DIR=$build_system_header_dir
1735 fi
1736
1737 # If this is a cross-compiler that does not
1738 # have its own set of headers then define
1739 # inhibit_libc
1740
1741 # If this is using newlib, without having the headers available now,
1742 # then define inhibit_libc in LIBGCC2_CFLAGS.
1743 # This prevents libgcc2 from containing any code which requires libc
1744 # support.
1745 : ${inhibit_libc=false}
1746 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1747        test x$with_newlib = xyes ; } &&
1748      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1749        inhibit_libc=true
1750 fi
1751 AC_SUBST(inhibit_libc)
1752
1753 # When building gcc with a cross-compiler, we need to adjust things so
1754 # that the generator programs are still built with the native compiler.
1755 # Also, we cannot run fixincludes or fix-header.
1756
1757 # These are the normal (build=host) settings:
1758 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1759 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1760 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1761 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1762
1763 # Possibly disable fixproto, on a per-target basis.
1764 case ${use_fixproto} in
1765   no)
1766     STMP_FIXPROTO=
1767     ;;
1768   yes)
1769     STMP_FIXPROTO=stmp-fixproto
1770     ;;
1771 esac
1772 AC_SUBST(STMP_FIXPROTO)
1773
1774 # And these apply if build != host, or we are generating coverage data
1775 if test x$build != x$host || test "x$coverage_flags" != x
1776 then
1777     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1778     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1779
1780     if test "x$TARGET_SYSTEM_ROOT" = x; then
1781         if test "x$STMP_FIXPROTO" != x; then
1782           STMP_FIXPROTO=stmp-install-fixproto
1783         fi
1784     fi
1785 fi
1786
1787 # Expand extra_headers to include complete path.
1788 # This substitutes for lots of t-* files.
1789 extra_headers_list=
1790 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1791 for file in ${extra_headers} ; do
1792   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1793 done
1794
1795 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1796 if test x"$use_gcc_tgmath" = xyes
1797 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1798 fi
1799
1800 # Define collect2 in Makefile.
1801 case $host_can_use_collect2 in
1802   no) collect2= ;;
1803   *) collect2='collect2$(exeext)' ;;
1804 esac
1805 AC_SUBST([collect2])
1806
1807 # Add a definition of USE_COLLECT2 if system wants one.
1808 case $use_collect2 in
1809   no) use_collect2= ;;
1810   "") ;;
1811   *)
1812     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1813     xm_defines="${xm_defines} USE_COLLECT2"
1814     case $host_can_use_collect2 in
1815       no)
1816         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1817         ;;
1818     esac
1819     ;;
1820 esac
1821
1822 # ---------------------------
1823 # Assembler & linker features
1824 # ---------------------------
1825
1826 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1827 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1828 # However when ld-new is first executed from the build tree, libtool will
1829 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1830 # to the build tree.  While doing this we need to use the previous-stage
1831 # linker, or we have an infinite loop.  The presence of a shell script as
1832 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1833 # the gcc/collect-ld script.  So we need to know how libtool works, or
1834 # exec-tool will fail.
1835
1836 m4_defun([_LT_CONFIG_COMMANDS], [])
1837 AC_PROG_LIBTOOL
1838 AC_SUBST(objdir)
1839 AC_SUBST(enable_fast_install)
1840
1841 # Identify the assembler which will work hand-in-glove with the newly
1842 # built GCC, so that we can examine its features.  This is the assembler
1843 # which will be driven by the driver program.
1844 #
1845 # If build != host, and we aren't building gas in-tree, we identify a
1846 # build->target assembler and hope that it will have the same features
1847 # as the host->target assembler we'll be using.
1848 gcc_cv_gas_major_version=
1849 gcc_cv_gas_minor_version=
1850 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1851
1852 m4_pattern_allow([AS_FOR_TARGET])dnl
1853 AS_VAR_SET_IF(gcc_cv_as,, [
1854 if test -x "$DEFAULT_ASSEMBLER"; then
1855         gcc_cv_as="$DEFAULT_ASSEMBLER"
1856 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1857      && test -f ../gas/Makefile \
1858      && test x$build = x$host; then
1859         gcc_cv_as=../gas/as-new$build_exeext
1860 elif test -x as$build_exeext; then
1861         # Build using assembler in the current directory.
1862         gcc_cv_as=./as$build_exeext
1863 elif test -x $AS_FOR_TARGET; then
1864         gcc_cv_as="$AS_FOR_TARGET"
1865 else
1866         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1867 fi])
1868
1869 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1870 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1871 case "$ORIGINAL_AS_FOR_TARGET" in
1872   ./as | ./as$build_exeext) ;;
1873   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1874 esac
1875
1876 AC_MSG_CHECKING(what assembler to use)
1877 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1878   # Single tree build which includes gas.  We want to prefer it
1879   # over whatever linker top-level may have detected, since
1880   # we'll use what we're building after installation anyway.
1881   AC_MSG_RESULT(newly built gas)
1882   in_tree_gas=yes
1883   _gcc_COMPUTE_GAS_VERSION
1884   in_tree_gas_is_elf=no
1885   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1886      || (grep 'obj_format = multi' ../gas/Makefile \
1887          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1888   then
1889     in_tree_gas_is_elf=yes
1890   fi
1891 else
1892   AC_MSG_RESULT($gcc_cv_as)
1893   in_tree_gas=no
1894 fi
1895
1896 # Identify the linker which will work hand-in-glove with the newly
1897 # built GCC, so that we can examine its features.  This is the linker
1898 # which will be driven by the driver program.
1899 #
1900 # If build != host, and we aren't building gas in-tree, we identify a
1901 # build->target linker and hope that it will have the same features
1902 # as the host->target linker we'll be using.
1903 gcc_cv_gld_major_version=
1904 gcc_cv_gld_minor_version=
1905 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1906 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1907
1908 AS_VAR_SET_IF(gcc_cv_ld,, [
1909 if test -x "$DEFAULT_LINKER"; then
1910         gcc_cv_ld="$DEFAULT_LINKER"
1911 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1912      && test -f ../ld/Makefile \
1913      && test x$build = x$host; then
1914         gcc_cv_ld=../ld/ld-new$build_exeext
1915 elif test -x collect-ld$build_exeext; then
1916         # Build using linker in the current directory.
1917         gcc_cv_ld=./collect-ld$build_exeext
1918 elif test -x $LD_FOR_TARGET; then
1919         gcc_cv_ld="$LD_FOR_TARGET"
1920 else
1921         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1922 fi])
1923
1924 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1925 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1926 case "$ORIGINAL_LD_FOR_TARGET" in
1927   ./collect-ld | ./collect-ld$build_exeext) ;;
1928   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1929 esac
1930
1931 AC_MSG_CHECKING(what linker to use)
1932 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1933         # Single tree build which includes ld.  We want to prefer it
1934         # over whatever linker top-level may have detected, since
1935         # we'll use what we're building after installation anyway.
1936         AC_MSG_RESULT(newly built ld)
1937         in_tree_ld=yes
1938         in_tree_ld_is_elf=no
1939         if (grep 'EMUL = .*elf' ../ld/Makefile \
1940             || grep 'EMUL = .*linux' ../ld/Makefile \
1941             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1942           in_tree_ld_is_elf=yes
1943         fi
1944         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1945         do
1946 changequote(,)dnl
1947                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1948                 if test x$gcc_cv_gld_version != x; then
1949                         break
1950                 fi
1951         done
1952         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1953         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1954 changequote([,])dnl
1955 else
1956         AC_MSG_RESULT($gcc_cv_ld)
1957         in_tree_ld=no
1958 fi
1959
1960 # Figure out what nm we will be using.
1961 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1962 AS_VAR_SET_IF(gcc_cv_nm,, [
1963 if test -f $gcc_cv_binutils_srcdir/configure.in \
1964      && test -f ../binutils/Makefile \
1965      && test x$build = x$host; then
1966         gcc_cv_nm=../binutils/nm-new$build_exeext
1967 elif test -x nm$build_exeext; then
1968         gcc_cv_nm=./nm$build_exeext
1969 elif test -x $NM_FOR_TARGET; then
1970         gcc_cv_nm="$NM_FOR_TARGET"
1971 else
1972         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1973 fi])
1974
1975 AC_MSG_CHECKING(what nm to use)
1976 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1977         # Single tree build which includes binutils.
1978         AC_MSG_RESULT(newly built nm)
1979         in_tree_nm=yes
1980 else
1981         AC_MSG_RESULT($gcc_cv_nm)
1982         in_tree_nm=no
1983 fi
1984
1985 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1986 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1987 case "$ORIGINAL_NM_FOR_TARGET" in
1988   ./nm | ./nm$build_exeext) ;;
1989   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1990 esac
1991
1992
1993 # Figure out what objdump we will be using.
1994 AS_VAR_SET_IF(gcc_cv_objdump,, [
1995 if test -f $gcc_cv_binutils_srcdir/configure.in \
1996      && test -f ../binutils/Makefile \
1997      && test x$build = x$host; then
1998         # Single tree build which includes binutils.
1999         gcc_cv_objdump=../binutils/objdump$build_exeext
2000 elif test -x objdump$build_exeext; then
2001         gcc_cv_objdump=./objdump$build_exeext
2002 elif test -x $OBJDUMP_FOR_TARGET; then
2003         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2004 else
2005         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2006 fi])
2007
2008 AC_MSG_CHECKING(what objdump to use)
2009 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2010         # Single tree build which includes binutils.
2011         AC_MSG_RESULT(newly built objdump)
2012 elif test x$gcc_cv_objdump = x; then
2013         AC_MSG_RESULT(not found)
2014 else
2015         AC_MSG_RESULT($gcc_cv_objdump)
2016 fi
2017
2018 # Figure out what assembler alignment features are present.
2019 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2020  [2,6,0],,
2021 [.balign 4
2022 .p2align 2],,
2023 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2024   [Define if your assembler supports .balign and .p2align.])])
2025
2026 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2027  [2,8,0],,
2028  [.p2align 4,,7],,
2029 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2030   [Define if your assembler supports specifying the maximum number
2031    of bytes to skip when using the GAS .p2align command.])])
2032
2033 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2034  [2,8,0],,
2035  [.literal16],,
2036 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2037   [Define if your assembler supports .literal16.])])
2038
2039 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2040  [elf,2,9,0],,
2041  [conftest_label1: .word 0
2042 .subsection -1
2043 conftest_label2: .word 0
2044 .previous],
2045  [if test x$gcc_cv_nm != x; then
2046     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2047     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2048     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2049     then :
2050     else gcc_cv_as_subsection_m1=yes
2051     fi
2052     rm -f conftest.nm1 conftest.nm2
2053   fi],
2054  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2055   [Define if your assembler supports .subsection and .subsection -1 starts
2056    emitting at the beginning of your section.])])
2057
2058 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2059  [2,2,0],,
2060  [      .weak foobar],,
2061 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2062
2063 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2064  [2,17,0],,
2065  [      .weakref foobar, barfnot],,
2066 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2067
2068 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2069  [2,15,91],,
2070  [      .SPACE $TEXT$
2071         .NSUBSPA $CODE$,COMDAT],,
2072 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2073
2074 # .hidden needs to be supported in both the assembler and the linker,
2075 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2076 # This is irritatingly difficult to feature test for; we have to check the
2077 # date string after the version number.  If we've got an in-tree
2078 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2079 # to be safe.
2080 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2081 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2082  [elf,2,13,0],,
2083 [       .hidden foobar
2084 foobar:])
2085
2086 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2087 [if test $in_tree_ld = yes ; then
2088   gcc_cv_ld_hidden=no
2089   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2090      && test $in_tree_ld_is_elf = yes; then
2091      gcc_cv_ld_hidden=yes
2092   fi
2093 else
2094   gcc_cv_ld_hidden=yes
2095   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2096   if echo "$ld_ver" | grep GNU > /dev/null; then
2097 changequote(,)dnl
2098     ld_vers=`echo $ld_ver | sed -n \
2099         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2100     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2101     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2102     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2103     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2104     if test 0"$ld_date" -lt 20020404; then
2105       if test -n "$ld_date"; then
2106         # If there was date string, but was earlier than 2002-04-04, fail
2107         gcc_cv_ld_hidden=no
2108       elif test -z "$ld_vers"; then
2109         # If there was no date string nor ld version number, something is wrong
2110         gcc_cv_ld_hidden=no
2111       else
2112         test -z "$ld_vers_patch" && ld_vers_patch=0
2113         if test "$ld_vers_major" -lt 2; then
2114           gcc_cv_ld_hidden=no
2115         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2116           gcc_cv_ld_hidden="no"
2117         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2118           gcc_cv_ld_hidden=no
2119         fi
2120       fi
2121 changequote([,])dnl
2122     fi
2123   else
2124     case "${target}" in
2125       hppa64*-*-hpux* | ia64*-*-hpux*)
2126         gcc_cv_ld_hidden=yes
2127         ;;
2128       *)
2129         gcc_cv_ld_hidden=no
2130         ;;
2131     esac
2132   fi
2133 fi])
2134 libgcc_visibility=no
2135 AC_SUBST(libgcc_visibility)
2136 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2137 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2138   libgcc_visibility=yes
2139   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2140   [Define if your assembler and linker support .hidden.])
2141 fi
2142
2143 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2144 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2145   [elf,2,11,0],,
2146 [       .data
2147         .uleb128 L2 - L1
2148 L1:
2149         .uleb128 1280
2150         .sleb128 -1010
2151 L2:],
2152  [# GAS versions before 2.11 do not support uleb128,
2153   # despite appearing to.
2154   # ??? There exists an elf-specific test that will crash
2155   # the assembler.  Perhaps it's better to figure out whether
2156   # arbitrary sections are supported and try the test.
2157   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2158   if echo "$as_ver" | grep GNU > /dev/null; then
2159 changequote(,)dnl
2160     as_vers=`echo $as_ver | sed -n \
2161         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2162     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2163     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2164 changequote([,])dnl
2165     if test $as_major -eq 2 && test $as_minor -lt 11
2166     then :
2167     else gcc_cv_as_leb128=yes
2168     fi
2169   fi],
2170   [AC_DEFINE(HAVE_AS_LEB128, 1,
2171     [Define if your assembler supports .sleb128 and .uleb128.])])
2172
2173 # GAS versions up to and including 2.11.0 may mis-optimize
2174 # .eh_frame data.
2175 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2176   [elf,2,12,0],,
2177 [       .text
2178 .LFB1:
2179         .4byte  0
2180 .L1:
2181         .4byte  0
2182 .LFE1:
2183         .section        .eh_frame,"aw",@progbits
2184 __FRAME_BEGIN__:
2185         .4byte  .LECIE1-.LSCIE1
2186 .LSCIE1:
2187         .4byte  0x0
2188         .byte   0x1
2189         .ascii "z\0"
2190         .byte   0x1
2191         .byte   0x78
2192         .byte   0x1a
2193         .byte   0x0
2194         .byte   0x4
2195         .4byte  1
2196         .p2align 1
2197 .LECIE1:
2198 .LSFDE1:
2199         .4byte  .LEFDE1-.LASFDE1
2200 .LASFDE1:
2201         .4byte  .LASFDE1-__FRAME_BEGIN__
2202         .4byte  .LFB1
2203         .4byte  .LFE1-.LFB1
2204         .byte   0x4
2205         .4byte  .LFE1-.LFB1
2206         .byte   0x4
2207         .4byte  .L1-.LFB1
2208 .LEFDE1:],
2209 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2210 cat > conftest.lit <<EOF
2211  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2212  0010 01000000 12000000 18000000 00000000  ................
2213  0020 08000000 04080000 0044               .........D      @&t@
2214 EOF
2215 cat > conftest.big <<EOF
2216  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2217  0010 00000001 00000012 00000018 00000000  ................
2218  0020 00000008 04000000 0844               .........D      @&t@
2219 EOF
2220   # If the assembler didn't choke, and we can objdump,
2221   # and we got the correct data, then succeed.
2222   # The text in the here-document typically retains its unix-style line
2223   # endings, while the output of objdump will use host line endings.
2224   # Therefore, use diff -b for the comparisons.
2225   if test x$gcc_cv_objdump != x \
2226   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2227      | tail -3 > conftest.got \
2228   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2229     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2230   then
2231     gcc_cv_as_eh_frame=yes
2232   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2233     gcc_cv_as_eh_frame=buggy
2234   else
2235     # Uh oh, what do we do now?
2236     gcc_cv_as_eh_frame=no
2237   fi])
2238
2239 if test $gcc_cv_as_eh_frame = buggy; then
2240   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2241   [Define if your assembler mis-optimizes .eh_frame data.])
2242 fi
2243
2244 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2245  [elf,2,12,0], [--fatal-warnings],
2246  [.section .rodata.str, "aMS", @progbits, 1])
2247 if test $gcc_cv_as_shf_merge = no; then
2248   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2249     [elf,2,12,0], [--fatal-warnings],
2250     [.section .rodata.str, "aMS", %progbits, 1])
2251 fi
2252 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2253   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2254 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2255
2256 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2257  [elf,2,16,0], [--fatal-warnings],
2258  [.section .text,"axG",@progbits,.foo,comdat])
2259 if test $gcc_cv_as_comdat_group = yes; then
2260   gcc_cv_as_comdat_group_percent=no
2261 else
2262  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2263    [elf,2,16,0], [--fatal-warnings],
2264    [.section .text,"axG",%progbits,.foo,comdat])
2265 fi
2266 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2267   comdat_group=yes
2268   if test 0"$ld_date" -lt 20050308; then
2269     if test -n "$ld_date"; then
2270       # If there was date string, but was earlier than 2005-03-08, fail
2271       comdat_group=no
2272     elif test "$ld_vers_major" -lt 2; then
2273       comdat_group=no
2274     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2275       comdat_group=no
2276     fi
2277   fi
2278 else
2279   # assume linkers other than GNU ld don't support COMDAT group
2280   comdat_group=no
2281 fi
2282 if test $comdat_group = no; then
2283   gcc_cv_as_comdat_group=no
2284   gcc_cv_as_comdat_group_percent=no
2285 fi
2286 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2287   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2288 [Define 0/1 if your assembler and linker support COMDAT groups.])
2289
2290 # Thread-local storage - the check is heavily parametrized.
2291 conftest_s=
2292 tls_first_major=
2293 tls_first_minor=
2294 tls_as_opt=
2295 case "$target" in
2296 changequote(,)dnl
2297   alpha*-*-*)
2298     conftest_s='
2299         .section ".tdata","awT",@progbits
2300 foo:    .long   25
2301         .text
2302         ldq     $27,__tls_get_addr($29)         !literal!1
2303         lda     $16,foo($29)                    !tlsgd!1
2304         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2305         ldq     $27,__tls_get_addr($29)         !literal!2
2306         lda     $16,foo($29)                    !tlsldm!2
2307         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2308         ldq     $1,foo($29)                     !gotdtprel
2309         ldah    $2,foo($29)                     !dtprelhi
2310         lda     $3,foo($2)                      !dtprello
2311         lda     $4,foo($29)                     !dtprel
2312         ldq     $1,foo($29)                     !gottprel
2313         ldah    $2,foo($29)                     !tprelhi
2314         lda     $3,foo($2)                      !tprello
2315         lda     $4,foo($29)                     !tprel'
2316         tls_first_major=2
2317         tls_first_minor=13
2318         tls_as_opt=--fatal-warnings
2319         ;;
2320   frv*-*-*)
2321     conftest_s='
2322         .section ".tdata","awT",@progbits
2323 x:      .long   25
2324         .text
2325         call    #gettlsoff(x)'
2326         tls_first_major=2
2327         tls_first_minor=14
2328         ;;
2329   hppa*-*-linux*)
2330     conftest_s='
2331 t1:     .reg    %r20
2332 t2:     .reg    %r21
2333 gp:     .reg    %r19
2334         .section ".tdata","awT",@progbits
2335 foo:    .long   25
2336         .text
2337         .align  4
2338         addil LT%foo-$tls_gdidx$,gp
2339         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2340         b __tls_get_addr
2341         nop
2342         addil LT%foo-$tls_ldidx$,gp
2343         b __tls_get_addr
2344         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2345         addil LR%foo-$tls_dtpoff$,%ret0
2346         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2347         mfctl %cr27,%t1
2348         addil LT%foo-$tls_ieoff$,gp
2349         ldw RT%foo-$tls_ieoff$(%r1),%t2
2350         add %t1,%t2,%t3
2351         mfctl %cr27,%t1
2352         addil LR%foo-$tls_leoff$,%t1
2353         ldo RR%foo-$tls_leoff$(%r1),%t2'
2354         tls_first_major=2
2355         tls_first_minor=15
2356         tls_as_opt=--fatal-warnings
2357         ;;
2358   arm*-*-*)
2359     conftest_s='
2360         .section ".tdata","awT",%progbits
2361 foo:    .long   25
2362         .text
2363 .word foo(gottpoff)
2364 .word foo(tpoff)
2365 .word foo(tlsgd)
2366 .word foo(tlsldm)
2367 .word foo(tlsldo)'
2368         tls_first_major=2
2369         tls_first_minor=17
2370         ;;
2371   i[34567]86-*-*)
2372     conftest_s='
2373         .section ".tdata","awT",@progbits
2374 foo:    .long   25
2375         .text
2376         movl    %gs:0, %eax
2377         leal    foo@TLSGD(,%ebx,1), %eax
2378         leal    foo@TLSLDM(%ebx), %eax
2379         leal    foo@DTPOFF(%eax), %edx
2380         movl    foo@GOTTPOFF(%ebx), %eax
2381         subl    foo@GOTTPOFF(%ebx), %eax
2382         addl    foo@GOTNTPOFF(%ebx), %eax
2383         movl    foo@INDNTPOFF, %eax
2384         movl    $foo@TPOFF, %eax
2385         subl    $foo@TPOFF, %eax
2386         leal    foo@NTPOFF(%ecx), %eax'
2387         tls_first_major=2
2388         tls_first_minor=14
2389         tls_as_opt=--fatal-warnings
2390         ;;
2391   x86_64-*-*)
2392     conftest_s='
2393         .section ".tdata","awT",@progbits
2394 foo:    .long   25
2395         .text
2396         movq    %fs:0, %rax
2397         leaq    foo@TLSGD(%rip), %rdi
2398         leaq    foo@TLSLD(%rip), %rdi
2399         leaq    foo@DTPOFF(%rax), %rdx
2400         movq    foo@GOTTPOFF(%rip), %rax
2401         movq    $foo@TPOFF, %rax'
2402         tls_first_major=2
2403         tls_first_minor=14
2404         tls_as_opt=--fatal-warnings
2405         ;;
2406   ia64-*-*)
2407     conftest_s='
2408         .section ".tdata","awT",@progbits
2409 foo:    data8   25
2410         .text
2411         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2412         addl    r17 = @ltoff(@dtprel(foo#)), gp
2413         addl    r18 = @ltoff(@tprel(foo#)), gp
2414         addl    r19 = @dtprel(foo#), gp
2415         adds    r21 = @dtprel(foo#), r13
2416         movl    r23 = @dtprel(foo#)
2417         addl    r20 = @tprel(foo#), gp
2418         adds    r22 = @tprel(foo#), r13
2419         movl    r24 = @tprel(foo#)'
2420         tls_first_major=2
2421         tls_first_minor=13
2422         tls_as_opt=--fatal-warnings
2423         ;;
2424   mips*-*-*)
2425     conftest_s='
2426         .section .tdata,"awT",@progbits
2427 x:
2428         .word 2
2429         .text
2430         addiu $4, $28, %tlsgd(x)
2431         addiu $4, $28, %tlsldm(x)
2432         lui $4, %dtprel_hi(x)
2433         addiu $4, $4, %dtprel_lo(x)
2434         lw $4, %gottprel(x)($28)
2435         lui $4, %tprel_hi(x)
2436         addiu $4, $4, %tprel_lo(x)'
2437         tls_first_major=2
2438         tls_first_minor=16
2439         tls_as_opt='-32 --fatal-warnings'
2440         ;;
2441   powerpc-*-*)
2442     conftest_s='
2443         .section ".tdata","awT",@progbits
2444         .align 2
2445 ld0:    .space 4
2446 ld1:    .space 4
2447 x1:     .space 4
2448 x2:     .space 4
2449 x3:     .space 4
2450         .text
2451         addi 3,31,ld0@got@tlsgd
2452         bl __tls_get_addr
2453         addi 3,31,x1@got@tlsld
2454         bl __tls_get_addr
2455         addi 9,3,x1@dtprel
2456         addis 9,3,x2@dtprel@ha
2457         addi 9,9,x2@dtprel@l
2458         lwz 9,x3@got@tprel(31)
2459         add 9,9,x@tls
2460         addi 9,2,x1@tprel
2461         addis 9,2,x2@tprel@ha
2462         addi 9,9,x2@tprel@l'
2463         tls_first_major=2
2464         tls_first_minor=14
2465         tls_as_opt="-a32 --fatal-warnings"
2466         ;;
2467   powerpc64-*-*)
2468     conftest_s='
2469         .section ".tdata","awT",@progbits
2470         .align 3
2471 ld0:    .space 8
2472 ld1:    .space 8
2473 x1:     .space 8
2474 x2:     .space 8
2475 x3:     .space 8
2476         .text
2477         addi 3,2,ld0@got@tlsgd
2478         bl .__tls_get_addr
2479         nop
2480         addi 3,2,ld1@toc
2481         bl .__tls_get_addr
2482         nop
2483         addi 3,2,x1@got@tlsld
2484         bl .__tls_get_addr
2485         nop
2486         addi 9,3,x1@dtprel
2487         bl .__tls_get_addr
2488         nop
2489         addis 9,3,x2@dtprel@ha
2490         addi 9,9,x2@dtprel@l
2491         bl .__tls_get_addr
2492         nop
2493         ld 9,x3@got@dtprel(2)
2494         add 9,9,3
2495         bl .__tls_get_addr
2496         nop'
2497         tls_first_major=2
2498         tls_first_minor=14
2499         tls_as_opt="-a64 --fatal-warnings"
2500         ;;
2501   s390-*-*)
2502     conftest_s='
2503         .section ".tdata","awT",@progbits
2504 foo:    .long   25
2505         .text
2506         .long   foo@TLSGD
2507         .long   foo@TLSLDM
2508         .long   foo@DTPOFF
2509         .long   foo@NTPOFF
2510         .long   foo@GOTNTPOFF
2511         .long   foo@INDNTPOFF
2512         l       %r1,foo@GOTNTPOFF(%r12)
2513         l       %r1,0(%r1):tls_load:foo
2514         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2515         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2516         tls_first_major=2
2517         tls_first_minor=14
2518         tls_as_opt="-m31 --fatal-warnings"
2519         ;;
2520   s390x-*-*)
2521     conftest_s='
2522         .section ".tdata","awT",@progbits
2523 foo:    .long   25
2524         .text
2525         .quad   foo@TLSGD
2526         .quad   foo@TLSLDM
2527         .quad   foo@DTPOFF
2528         .quad   foo@NTPOFF
2529         .quad   foo@GOTNTPOFF
2530         lg      %r1,foo@GOTNTPOFF(%r12)
2531         larl    %r1,foo@INDNTPOFF
2532         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2533         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2534         tls_first_major=2
2535         tls_first_minor=14
2536         tls_as_opt="-m64 -Aesame --fatal-warnings"
2537         ;;
2538   sh-*-* | sh[34]-*-*)
2539     conftest_s='
2540         .section ".tdata","awT",@progbits
2541 foo:    .long   25
2542         .text
2543         .long   foo@TLSGD
2544         .long   foo@TLSLDM
2545         .long   foo@DTPOFF
2546         .long   foo@GOTTPOFF
2547         .long   foo@TPOFF'
2548         tls_first_major=2
2549         tls_first_minor=13
2550         tls_as_opt=--fatal-warnings
2551         ;;
2552   sparc*-*-*)
2553     case "$target" in
2554       sparc*-sun-solaris2.[56789]*)
2555         # TLS was introduced in the Solaris 9 4/04 release but
2556         # we do not enable it by default on Solaris 9 either.
2557         if test "x$enable_tls" = xyes ; then
2558           on_solaris=yes
2559         else
2560           enable_tls=no;
2561         fi
2562         ;;
2563       sparc*-sun-solaris2.*)
2564         on_solaris=yes
2565         ;;
2566       *)
2567         on_solaris=no
2568         ;;
2569     esac
2570     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2571       conftest_s='
2572         .section ".tdata",#alloc,#write,#tls
2573 foo:    .long   25
2574         .text
2575         sethi   %tgd_hi22(foo), %o0
2576         add     %o0, %tgd_lo10(foo), %o1
2577         add     %l7, %o1, %o0, %tgd_add(foo)
2578         call    __tls_get_addr, %tgd_call(foo)
2579         sethi   %tldm_hi22(foo), %l1
2580         add     %l1, %tldm_lo10(foo), %l2
2581         add     %l7, %l2, %o0, %tldm_add(foo)
2582         call    __tls_get_addr, %tldm_call(foo)
2583         sethi   %tldo_hix22(foo), %l3
2584         xor     %l3, %tldo_lox10(foo), %l4
2585         add     %o0, %l4, %l5, %tldo_add(foo)
2586         sethi   %tie_hi22(foo), %o3
2587         add     %o3, %tie_lo10(foo), %o3
2588         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2589         add     %g7, %o2, %o4, %tie_add(foo)
2590         sethi   %tle_hix22(foo), %l1
2591         xor     %l1, %tle_lox10(foo), %o5
2592         ld      [%g7 + %o5], %o1'
2593         tls_first_major=0
2594         tls_first_minor=0
2595     else
2596       conftest_s='
2597         .section ".tdata","awT",@progbits
2598 foo:    .long   25
2599         .text
2600         sethi   %tgd_hi22(foo), %o0
2601         add     %o0, %tgd_lo10(foo), %o1
2602         add     %l7, %o1, %o0, %tgd_add(foo)
2603         call    __tls_get_addr, %tgd_call(foo)
2604         sethi   %tldm_hi22(foo), %l1
2605         add     %l1, %tldm_lo10(foo), %l2
2606         add     %l7, %l2, %o0, %tldm_add(foo)
2607         call    __tls_get_addr, %tldm_call(foo)
2608         sethi   %tldo_hix22(foo), %l3
2609         xor     %l3, %tldo_lox10(foo), %l4
2610         add     %o0, %l4, %l5, %tldo_add(foo)
2611         sethi   %tie_hi22(foo), %o3
2612         add     %o3, %tie_lo10(foo), %o3
2613         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2614         add     %g7, %o2, %o4, %tie_add(foo)
2615         sethi   %tle_hix22(foo), %l1
2616         xor     %l1, %tle_lox10(foo), %o5
2617         ld      [%g7 + %o5], %o1'
2618         tls_first_major=2
2619         tls_first_minor=14
2620         tls_as_opt="-32 --fatal-warnings"
2621       fi
2622         ;;
2623 changequote([,])dnl
2624 esac
2625 set_have_as_tls=no
2626 if test "x$enable_tls" = xno ; then
2627   : # TLS explicitly disabled.
2628 elif test "x$enable_tls" = xyes ; then
2629   set_have_as_tls=yes # TLS explicitly enabled.
2630 elif test -z "$tls_first_major"; then
2631   : # If we don't have a check, assume no support.
2632 else
2633   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2634   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2635   [set_have_as_tls=yes])
2636 fi
2637 if test $set_have_as_tls = yes ; then
2638   AC_DEFINE(HAVE_AS_TLS, 1,
2639             [Define if your assembler supports thread-local storage.])
2640 fi
2641
2642 # Target-specific assembler checks.
2643
2644 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2645 gcc_cv_ld_static_dynamic=no
2646 if test $in_tree_ld = yes ; then
2647   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2648     gcc_cv_ld_static_dynamic=yes
2649   fi
2650 elif test x$gcc_cv_ld != x; then
2651         # Check if linker supports -Bstatic/-Bdynamic option
2652         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2653           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2654                 gcc_cv_ld_static_dynamic=yes
2655         fi
2656 fi
2657 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2658         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2659 [Define if your linker supports -Bstatic/-Bdynamic option.])
2660 fi
2661 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2662
2663 if test x"$demangler_in_ld" = xyes; then
2664   AC_MSG_CHECKING(linker --demangle support)
2665   gcc_cv_ld_demangle=no
2666   if test $in_tree_ld = yes; then
2667     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2668       gcc_cv_ld_demangle=yes
2669     fi
2670   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2671     # Check if the GNU linker supports --demangle option
2672     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2673       gcc_cv_ld_demangle=yes
2674     fi
2675   fi
2676   if test x"$gcc_cv_ld_demangle" = xyes; then
2677     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2678 [Define if your linker supports --demangle option.])
2679   fi
2680   AC_MSG_RESULT($gcc_cv_ld_demangle)
2681 fi
2682
2683 case "$target" in
2684   # All TARGET_ABI_OSF targets.
2685   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2686     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2687         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2688 [       .set nomacro
2689         .text
2690         extbl   $3, $2, $3      !lituse_bytoff!1
2691         ldq     $2, a($29)      !literal!1
2692         ldq     $4, b($29)      !literal!2
2693         ldq_u   $3, 0($2)       !lituse_base!1
2694         ldq     $27, f($29)     !literal!5
2695         jsr     $26, ($27), f   !lituse_jsr!5
2696         ldah    $29, 0($26)     !gpdisp!3
2697         lda     $0, c($29)      !gprel
2698         ldah    $1, d($29)      !gprelhigh
2699         lda     $1, d($1)       !gprellow
2700         lda     $29, 0($29)     !gpdisp!3],,
2701     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2702   [Define if your assembler supports explicit relocations.])])
2703     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2704         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2705 [       .set nomacro
2706         .text
2707         ldq     $27, a($29)     !literal!1
2708         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2709     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2710   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2711     ;;
2712
2713   cris-*-*)
2714     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2715       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2716       [-no-mul-bug-abort], [.text],,
2717       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2718                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2719     ;;
2720
2721   sparc*-*-*)
2722     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2723       [.register %g2, #scratch],,
2724       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2725                 [Define if your assembler supports .register.])])
2726
2727     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2728       [-relax], [.text],,
2729       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2730                 [Define if your assembler supports -relax option.])])
2731
2732     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2733       gcc_cv_as_sparc_ua_pcrel,,
2734       [-K PIC],
2735 [.text
2736 foo:
2737         nop
2738 .data
2739 .align 4
2740 .byte 0
2741 .uaword %r_disp32(foo)],
2742       [if test x$gcc_cv_ld != x \
2743        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2744          gcc_cv_as_sparc_ua_pcrel=yes
2745        fi
2746        rm -f conftest],
2747       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2748                 [Define if your assembler and linker support unaligned PC relative relocs.])
2749
2750       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2751         gcc_cv_as_sparc_ua_pcrel_hidden,,
2752         [-K PIC],
2753 [.data
2754 .align 4
2755 .byte 0x31
2756 .uaword %r_disp32(foo)
2757 .byte 0x32, 0x33, 0x34
2758 .global foo
2759 .hidden foo
2760 foo:
2761 .skip 4],
2762         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2763          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2764          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2765             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2766             if $gcc_cv_objdump -R conftest 2> /dev/null \
2767                | grep 'DISP32' > /dev/null 2>&1; then
2768                 :
2769             else
2770                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2771             fi
2772          fi
2773          rm -f conftest],
2774          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2775                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2776     ]) # unaligned pcrel relocs
2777
2778     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2779       gcc_cv_as_sparc_offsetable_lo10,,
2780       [-xarch=v9],
2781 [.text
2782         or %g1, %lo(ab) + 12, %g1
2783         or %g1, %lo(ab + 12), %g1],
2784       [if test x$gcc_cv_objdump != x \
2785        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2786           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2787          gcc_cv_as_sparc_offsetable_lo10=yes
2788        fi],
2789        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2790                  [Define if your assembler supports offsetable %lo().])])
2791     ;;
2792
2793 changequote(,)dnl
2794   i[34567]86-*-* | x86_64-*-*)
2795 changequote([,])dnl
2796     case $target_os in
2797       cygwin* | pe | mingw32*)
2798         # Used for DWARF 2 in PE
2799         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2800           gcc_cv_as_ix86_pe_secrel32,
2801           [2,15,91],,
2802 [.text
2803 foo:    nop
2804 .data
2805         .secrel32 foo],
2806           [if test x$gcc_cv_ld != x \
2807            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2808              gcc_cv_as_ix86_pe_secrel32=yes
2809            fi
2810            rm -f conftest],
2811           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2812             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2813         ;;
2814     esac
2815
2816     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2817        gcc_cv_as_ix86_filds_fists,
2818       [2,9,0],, [filds mem; fists mem],,
2819       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2820         [Define if your assembler uses the new HImode fild and fist notation.])])
2821
2822     gcc_GAS_CHECK_FEATURE([cmov syntax],
2823       gcc_cv_as_ix86_cmov_sun_syntax,,,
2824       [cmovl.l %edx, %eax],,
2825       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2826         [Define if your assembler supports the Sun syntax for cmov.])])
2827
2828     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2829       gcc_cv_as_ix86_ffreep,,,
2830       [ffreep %st(1)],,
2831       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2832         [Define if your assembler supports the ffreep mnemonic.])])
2833
2834     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2835       gcc_cv_as_ix86_sahf,,,
2836       [sahf],,
2837       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2838         [Define if your assembler supports the sahf mnemonic.])])
2839
2840     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2841       gcc_cv_as_ix86_diff_sect_delta,,,
2842       [.section .rodata
2843 .L1:
2844         .long .L2-.L1
2845         .long .L3-.L1
2846         .text
2847 .L3:    nop
2848 .L2:    nop],,
2849       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2850         [Define if your assembler supports the subtraction of symbols in different sections.])])
2851
2852     # This one is used unconditionally by i386.[ch]; it is to be defined
2853     # to 1 if the feature is present, 0 otherwise.
2854     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2855         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2856 [       .text
2857 .L0:
2858         nop
2859         .data
2860         .long .L0@GOTOFF])
2861     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2862       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2863       [Define true if the assembler supports '.long foo@GOTOFF'.])
2864     ;;
2865
2866   ia64*-*-*)
2867     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2868         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2869 [       .text
2870         addl r15 = @ltoffx(x#), gp
2871         ;;
2872         ld8.mov r16 = [[r15]], x#],,
2873     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2874           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2875
2876     ;;
2877
2878   powerpc*-*-*)
2879     case $target in
2880       *-*-aix*) conftest_s='    .machine "pwr5"
2881         .csect .text[[PR]]
2882         mfcr 3,128';;
2883       *-*-darwin*)
2884         gcc_GAS_CHECK_FEATURE([.machine directive support],
2885           gcc_cv_as_machine_directive,,,
2886           [     .machine ppc7400])
2887         if test x$gcc_cv_as_machine_directive != xyes; then
2888           echo "*** This target requires an assembler supporting \".machine\"" >&2
2889           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2890           test x$build = x$target && exit 1
2891         fi
2892         conftest_s='    .text
2893         mfcr r3,128';;
2894       *) conftest_s='   .machine power4
2895         .text
2896         mfcr 3,128';;
2897     esac
2898
2899     gcc_GAS_CHECK_FEATURE([mfcr field support],
2900       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2901       [$conftest_s],,
2902       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2903           [Define if your assembler supports mfcr field.])])
2904
2905     case $target in
2906       *-*-aix*) conftest_s='    .machine "pwr5"
2907         .csect .text[[PR]]
2908         popcntb 3,3';;
2909       *) conftest_s='   .machine power5
2910         .text
2911         popcntb 3,3';;
2912     esac
2913
2914     gcc_GAS_CHECK_FEATURE([popcntb support],
2915       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2916       [$conftest_s],,
2917       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2918           [Define if your assembler supports popcntb field.])])
2919
2920     case $target in
2921       *-*-aix*) conftest_s='    .machine "pwr5x"
2922         .csect .text[[PR]]
2923         frin 1,1';;
2924       *) conftest_s='   .machine power5
2925         .text
2926         frin 1,1';;
2927     esac
2928
2929     gcc_GAS_CHECK_FEATURE([fp round support],
2930       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2931       [$conftest_s],,
2932       [AC_DEFINE(HAVE_AS_FPRND, 1,
2933           [Define if your assembler supports fprnd.])])
2934
2935     case $target in
2936       *-*-aix*) conftest_s='    .machine "pwr6"
2937         .csect .text[[PR]]
2938         mffgpr 1,3';;
2939       *) conftest_s='   .machine power6
2940         .text
2941         mffgpr 1,3';;
2942     esac
2943
2944     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2945       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2946       [$conftest_s],,
2947       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2948           [Define if your assembler supports mffgpr and mftgpr.])])
2949
2950     case $target in
2951       *-*-aix*) conftest_s='    .csect .text[[PR]]
2952 LCF..0:
2953         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2954       *-*-darwin*)
2955         conftest_s='    .text
2956 LCF0:
2957         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2958       *) conftest_s='   .text
2959 .LCF0:
2960         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2961     esac
2962
2963     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2964       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2965       [$conftest_s],,
2966       [AC_DEFINE(HAVE_AS_REL16, 1,
2967           [Define if your assembler supports R_PPC_REL16 relocs.])])
2968
2969     case $target in
2970       *-*-aix*) conftest_s='    .machine "pwr6"
2971         .csect .text[[PR]]
2972         cmpb 3,4,5';;
2973       *) conftest_s='   .machine power6
2974         .text
2975         cmpb 3,4,5';;
2976     esac
2977
2978     gcc_GAS_CHECK_FEATURE([compare bytes support],
2979       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2980       [$conftest_s],,
2981       [AC_DEFINE(HAVE_AS_CMPB, 1,
2982           [Define if your assembler supports cmpb.])])
2983
2984     case $target in
2985       *-*-aix*) conftest_s='    .machine "pwr6"
2986         .csect .text[[PR]]
2987         dadd 1,2,3';;
2988       *) conftest_s='   .machine power6
2989         .text
2990         dadd 1,2,3';;
2991     esac
2992
2993     gcc_GAS_CHECK_FEATURE([decimal float support],
2994       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2995       [$conftest_s],,
2996       [AC_DEFINE(HAVE_AS_DFP, 1,
2997           [Define if your assembler supports DFP instructions.])])
2998
2999     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3000       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3001       [.gnu_attribute 4,1],,
3002       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3003           [Define if your assembler supports .gnu_attribute.])])
3004     ;;
3005
3006   mips*-*-*)
3007     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3008       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3009 [       lw $4,%gp_rel(foo)($4)],,
3010       [if test x$target_cpu_default = x
3011        then target_cpu_default=MASK_EXPLICIT_RELOCS
3012        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3013        fi])
3014     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3015       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3016       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3017                  [Define if the assembler understands -mno-shared.])])
3018
3019     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3020       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3021       [.gnu_attribute 4,1],,
3022       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3023           [Define if your assembler supports .gnu_attribute.])])
3024
3025     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3026       gcc_cv_as_mips_dtprelword, [2,18,0],,
3027       [.section .tdata,"awT",@progbits
3028 x:
3029         .word 2
3030         .text
3031         .dtprelword x+0x8000],,
3032       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3033           [Define if your assembler supports .dtprelword.])])
3034     ;;
3035 esac
3036
3037 # Mips and HP-UX need the GNU assembler.
3038 # Linux on IA64 might be able to use the Intel assembler.
3039
3040 case "$target" in
3041   mips*-*-* | *-*-hpux* )
3042     if test x$gas_flag = xyes \
3043        || test x"$host" != x"$build" \
3044        || test ! -x "$gcc_cv_as" \
3045        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3046       :
3047     else
3048       echo "*** This configuration requires the GNU assembler" >&2
3049       exit 1
3050     fi
3051     ;;
3052 esac
3053
3054 # ??? Not all targets support dwarf2 debug_line, even within a version
3055 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3056 # info to the output file.  So, as supported targets are added to gas 2.11,
3057 # add some instruction here to (also) show we expect this might work.
3058 # ??? Once 2.11 is released, probably need to add first known working
3059 # version to the per-target configury.
3060 case "$target" in
3061   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3062   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3063   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3064     insn="nop"
3065     ;;
3066   ia64*-*-* | s390*-*-*)
3067     insn="nop 0"
3068     ;;
3069   mmix-*-*)
3070     insn="swym 0"
3071     ;;
3072 esac
3073 if test x"$insn" != x; then
3074  conftest_s="\
3075         .file 1 \"conftest.s\"
3076         .loc 1 3 0
3077         $insn"
3078  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3079   gcc_cv_as_dwarf2_debug_line,
3080   [elf,2,11,0],, [$conftest_s],
3081   [if test x$gcc_cv_objdump != x \
3082    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3083       | grep debug_line > /dev/null 2>&1; then
3084      gcc_cv_as_dwarf2_debug_line=yes
3085    fi])
3086
3087 # The .debug_line file table must be in the exact order that
3088 # we specified the files, since these indices are also used
3089 # by DW_AT_decl_file.  Approximate this test by testing if
3090 # the assembler bitches if the same index is assigned twice.
3091  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3092   gcc_cv_as_dwarf2_file_buggy,,,
3093 [       .file 1 "foo.s"
3094         .file 1 "bar.s"])
3095
3096  if test $gcc_cv_as_dwarf2_debug_line = yes \
3097  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3098         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3099   [Define if your assembler supports dwarf2 .file/.loc directives,
3100    and preserves file table indices exactly as given.])
3101  fi
3102
3103  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3104   gcc_cv_as_gdwarf2_flag,
3105   [elf,2,11,0], [--gdwarf2], [$insn],,
3106   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3107 [Define if your assembler supports the --gdwarf2 option.])])
3108
3109  gcc_GAS_CHECK_FEATURE([--gstabs option],
3110   gcc_cv_as_gstabs_flag,
3111   [elf,2,11,0], [--gstabs], [$insn],
3112   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3113    # and warns about it, but still exits successfully.  So check for
3114    # this.
3115    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3116    then :
3117    else gcc_cv_as_gstabs_flag=yes
3118    fi],
3119   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3120 [Define if your assembler supports the --gstabs option.])])
3121
3122  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3123   gcc_cv_as_debug_prefix_map_flag,
3124   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3125   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3126 [Define if your assembler supports the --debug-prefix-map option.])])
3127 fi
3128
3129 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3130  [gcc_cv_as_line_zero],
3131  [gcc_cv_as_line_zero=no
3132   if test $in_tree_gas = yes; then
3133     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3134   elif test "x$gcc_cv_as" != x; then
3135     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3136     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3137        test "x`cat conftest.out`" = x
3138     then
3139       gcc_cv_as_line_zero=yes
3140     else
3141       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3142       cat conftest.s >&AS_MESSAGE_LOG_FD
3143       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3144       cat conftest.out >&AS_MESSAGE_LOG_FD
3145     fi
3146     rm -f conftest.o conftest.s conftest.out
3147   fi])
3148 if test "x$gcc_cv_as_line_zero" = xyes; then
3149   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3150 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3151 fi
3152
3153 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3154 gcc_cv_ld_ro_rw_mix=unknown
3155 if test $in_tree_ld = yes ; then
3156   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3157      && test $in_tree_ld_is_elf = yes; then
3158     gcc_cv_ld_ro_rw_mix=read-write
3159   fi
3160 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3161   echo '.section myfoosect, "a"' > conftest1.s
3162   echo '.section myfoosect, "aw"' > conftest2.s
3163   echo '.byte 1' >> conftest2.s
3164   echo '.section myfoosect, "a"' > conftest3.s
3165   echo '.byte 0' >> conftest3.s
3166   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3167      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3168      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3169      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3170         conftest2.o conftest3.o > /dev/null 2>&1; then
3171     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3172                          | sed -e '/myfoosect/!d' -e N`
3173     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3174       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3175         gcc_cv_ld_ro_rw_mix=read-only
3176       else
3177         gcc_cv_ld_ro_rw_mix=read-write
3178       fi
3179     fi
3180   fi
3181 changequote(,)dnl
3182   rm -f conftest.* conftest[123].*
3183 changequote([,])dnl
3184 fi
3185 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3186         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3187   [Define if your linker links a mix of read-only
3188    and read-write sections into a read-write section.])
3189 fi
3190 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3191
3192 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3193 gcc_cv_ld_eh_frame_hdr=no
3194 if test $in_tree_ld = yes ; then
3195   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3196      && test $in_tree_ld_is_elf = yes; then
3197     gcc_cv_ld_eh_frame_hdr=yes
3198   fi
3199 elif test x$gcc_cv_ld != x; then
3200         # Check if linker supports --eh-frame-hdr option
3201         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3202                 gcc_cv_ld_eh_frame_hdr=yes
3203         fi
3204 fi
3205 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3206 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3207         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3208 [Define if your linker supports --eh-frame-hdr option.])
3209 fi
3210 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3211
3212 AC_MSG_CHECKING(linker position independent executable support)
3213 gcc_cv_ld_pie=no
3214 if test $in_tree_ld = yes ; then
3215   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3216      && test $in_tree_ld_is_elf = yes; then
3217     gcc_cv_ld_pie=yes
3218   fi
3219 elif test x$gcc_cv_ld != x; then
3220         # Check if linker supports -pie option
3221         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3222                 gcc_cv_ld_pie=yes
3223         fi
3224 fi
3225 if test x"$gcc_cv_ld_pie" = xyes; then
3226         AC_DEFINE(HAVE_LD_PIE, 1,
3227 [Define if your linker supports -pie option.])
3228 fi
3229 AC_MSG_RESULT($gcc_cv_ld_pie)
3230
3231 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3232 gcc_cv_ld_eh_gc_sections=no
3233 if test $in_tree_ld = yes ; then
3234   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3235      && test $in_tree_ld_is_elf = yes; then
3236     gcc_cv_ld_eh_gc_sections=yes
3237   fi
3238 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3239   cat > conftest.s <<EOF
3240         .section        .text
3241 .globl _start
3242         .type _start, @function
3243 _start:
3244         .long foo
3245         .size _start, .-_start
3246         .section        .text.foo,"ax",@progbits
3247         .type foo, @function
3248 foo:
3249         .long 0
3250         .size foo, .-foo
3251         .section        .gcc_except_table.foo,"a",@progbits
3252 .L0:
3253         .long 0
3254         .section        .eh_frame,"a",@progbits
3255         .long .L0
3256 EOF
3257   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3258     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3259          | grep "gc-sections option ignored" > /dev/null; then
3260       gcc_cv_ld_eh_gc_sections=no
3261     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3262       gcc_cv_ld_eh_gc_sections=yes
3263       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3264       if test x$gcc_cv_as_comdat_group != xyes; then
3265         gcc_cv_ld_eh_gc_sections=no
3266         cat > conftest.s <<EOF
3267         .section        .text
3268 .globl _start
3269         .type _start, @function
3270 _start:
3271         .long foo
3272         .size _start, .-_start
3273         .section        .gnu.linkonce.t.foo,"ax",@progbits
3274         .type foo, @function
3275 foo:
3276         .long 0
3277         .size foo, .-foo
3278         .section        .gcc_except_table.foo,"a",@progbits
3279 .L0:
3280         .long 0
3281         .section        .eh_frame,"a",@progbits
3282         .long .L0
3283 EOF
3284         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3285           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3286                | grep "gc-sections option ignored" > /dev/null; then
3287             gcc_cv_ld_eh_gc_sections=no
3288           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3289             gcc_cv_ld_eh_gc_sections=yes
3290           fi
3291         fi
3292       fi
3293     fi
3294   fi
3295   rm -f conftest.s conftest.o conftest
3296 fi
3297 case "$target" in
3298   hppa*-*-linux*)
3299     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3300     gcc_cv_ld_eh_gc_sections=no
3301     ;;
3302 esac
3303 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3304         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3305   [Define if your linker supports garbage collection of
3306    sections in presence of EH frames.])
3307 fi
3308 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3309
3310 # --------
3311 # UNSORTED
3312 # --------
3313
3314 AC_CACHE_CHECK(linker --as-needed support,
3315 gcc_cv_ld_as_needed,
3316 [gcc_cv_ld_as_needed=no
3317 if test $in_tree_ld = yes ; then
3318   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3319      && test $in_tree_ld_is_elf = yes; then
3320     gcc_cv_ld_as_needed=yes
3321   fi
3322 elif test x$gcc_cv_ld != x; then
3323         # Check if linker supports --as-needed and --no-as-needed options
3324         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3325                 gcc_cv_ld_as_needed=yes
3326         fi
3327 fi
3328 ])
3329 if test x"$gcc_cv_ld_as_needed" = xyes; then
3330         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3331 [Define if your linker supports --as-needed and --no-as-needed options.])
3332 fi
3333
3334 case "$target:$tm_file" in
3335   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3336     AC_CACHE_CHECK(linker support for omitting dot symbols,
3337     gcc_cv_ld_no_dot_syms,
3338     [gcc_cv_ld_no_dot_syms=no
3339     if test $in_tree_ld = yes ; then
3340       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3341         gcc_cv_ld_no_dot_syms=yes
3342       fi
3343     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3344       cat > conftest1.s <<EOF
3345         .text
3346         bl .foo
3347 EOF
3348       cat > conftest2.s <<EOF
3349         .section ".opd","aw"
3350         .align 3
3351         .globl foo
3352         .type foo,@function
3353 foo:
3354         .quad .LEfoo,.TOC.@tocbase,0
3355         .text
3356 .LEfoo:
3357         blr
3358         .size foo,.-.LEfoo
3359 EOF
3360       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3361          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3362          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3363         gcc_cv_ld_no_dot_syms=yes
3364       fi
3365       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3366     fi
3367     ])
3368     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3369       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3370     [Define if your PowerPC64 linker only needs function descriptor syms.])
3371     fi
3372     ;;
3373 esac
3374
3375 AC_CACHE_CHECK(linker --sysroot support,
3376   gcc_cv_ld_sysroot,
3377   [gcc_cv_ld_sysroot=no
3378   if test $in_tree_ld = yes ; then
3379       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3380         gcc_cv_ld_sysroot=yes
3381       fi
3382   elif test x$gcc_cv_ld != x; then
3383     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3384       gcc_cv_ld_sysroot=yes
3385     fi
3386   fi])
3387 if test x"$gcc_cv_ld_sysroot" = xyes; then
3388   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3389   [Define if your linker supports --sysroot.])
3390 fi
3391
3392 if test x$with_sysroot = x && test x$host = x$target \
3393    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3394    && test "$prefix" != "NONE"; then
3395   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3396 [Define to PREFIX/include if cpp should also search that directory.])
3397 fi
3398
3399 # Test for stack protector support in target C library.
3400 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3401       gcc_cv_libc_provides_ssp,
3402       [gcc_cv_libc_provides_ssp=no
3403     case "$target" in
3404        *-*-linux*)
3405       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3406         if test "x$with_sysroot" = x; then
3407           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3408         elif test "x$with_build_sysroot" != "x"; then
3409           glibc_header_dir="${with_build_sysroot}/usr/include"
3410         elif test "x$with_sysroot" = xyes; then
3411           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3412         else
3413           glibc_header_dir="${with_sysroot}/usr/include"
3414         fi
3415       else
3416         glibc_header_dir=/usr/include
3417       fi
3418       # glibc 2.4 and later provides __stack_chk_fail and
3419       # either __stack_chk_guard, or TLS access to stack guard canary.
3420       if test -f $glibc_header_dir/features.h \
3421          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3422             $glibc_header_dir/features.h > /dev/null; then
3423         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3424            $glibc_header_dir/features.h > /dev/null; then
3425           gcc_cv_libc_provides_ssp=yes
3426         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3427              $glibc_header_dir/features.h > /dev/null \
3428              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3429              $glibc_header_dir/features.h > /dev/null; then
3430           gcc_cv_libc_provides_ssp=yes
3431         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3432              $glibc_header_dir/features.h > /dev/null && \
3433              test -f $glibc_header_dir/bits/uClibc_config.h && \
3434              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3435              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3436           gcc_cv_libc_provides_ssp=yes
3437         fi
3438       fi
3439         ;;
3440        *-*-darwin*)
3441          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3442            [echo "no __stack_chk_fail on this target"])
3443         ;;
3444   *) gcc_cv_libc_provides_ssp=no ;;
3445     esac])
3446
3447 if test x$gcc_cv_libc_provides_ssp = xyes; then
3448   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3449             [Define if your target C library provides stack protector support])
3450 fi
3451
3452 # Check if TFmode long double should be used by default or not.
3453 # Some glibc targets used DFmode long double, but with glibc 2.4
3454 # and later they can use TFmode.
3455 case "$target" in
3456   powerpc*-*-linux* | \
3457   powerpc*-*-gnu* | \
3458   sparc*-*-linux* | \
3459   s390*-*-linux* | \
3460   alpha*-*-linux*)
3461     AC_ARG_WITH(long-double-128,
3462 [  --with-long-double-128  Use 128-bit long double by default.],
3463       gcc_cv_target_ldbl128="$with_long_double_128",
3464       [gcc_cv_target_ldbl128=no
3465       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3466         if test "x$with_sysroot" = x; then
3467           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3468         elif test "x$with_build_sysroot" != "x"; then
3469           glibc_header_dir="${with_build_sysroot}/usr/include"
3470         elif test "x$with_sysroot" = xyes; then
3471           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3472         else
3473           glibc_header_dir="${with_sysroot}/usr/include"
3474         fi
3475       else
3476         glibc_header_dir=/usr/include
3477       fi
3478 changequote(,)dnl
3479       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3480         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3481       && gcc_cv_target_ldbl128=yes
3482 changequote([,])dnl
3483       ])
3484     ;;
3485 esac
3486 if test x$gcc_cv_target_ldbl128 = xyes; then
3487   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3488             [Define if TFmode long double should be the default])
3489 fi
3490
3491 # Find out what GC implementation we want, or may, use.
3492 AC_ARG_WITH(gc,
3493 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3494                           with the compiler],
3495 [case "$withval" in
3496   page)
3497     GGC=ggc-$withval
3498     ;;
3499   zone)
3500     GGC=ggc-$withval
3501     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3502     ;;
3503   *)
3504     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3505     ;;
3506 esac],
3507 [GGC=ggc-page])
3508 AC_SUBST(GGC)
3509 echo "Using $GGC for garbage collection."
3510
3511 # Use the system's zlib library.
3512 zlibdir=-L../zlib
3513 zlibinc="-I\$(srcdir)/../zlib"
3514 AC_ARG_WITH(system-zlib,
3515 [  --with-system-zlib      use installed libz],
3516 zlibdir=
3517 zlibinc=
3518 )
3519 AC_SUBST(zlibdir)
3520 AC_SUBST(zlibinc)
3521
3522 dnl Very limited version of automake's enable-maintainer-mode
3523
3524 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3525   dnl maintainer-mode is disabled by default
3526   AC_ARG_ENABLE(maintainer-mode,
3527 [  --enable-maintainer-mode
3528                           enable make rules and dependencies not useful
3529                           (and sometimes confusing) to the casual installer],
3530       maintainer_mode=$enableval,
3531       maintainer_mode=no)
3532
3533 AC_MSG_RESULT($maintainer_mode)
3534
3535 if test "$maintainer_mode" = "yes"; then
3536   MAINT=''
3537 else
3538   MAINT='#'
3539 fi
3540 AC_SUBST(MAINT)dnl
3541
3542 # --------------
3543 # Language hooks
3544 # --------------
3545
3546 # Make empty files to contain the specs and options for each language.
3547 # Then add #include lines to for a compiler that has specs and/or options.
3548
3549 subdirs=
3550 lang_opt_files=
3551 lang_specs_files=
3552 lang_tree_files=
3553 # These (without "all_") are set in each config-lang.in.
3554 # `language' must be a single word so is spelled singularly.
3555 all_languages=
3556 all_compilers=
3557 all_outputs='Makefile gccbug libada-mk'
3558 # List of language makefile fragments.
3559 all_lang_makefrags=
3560 # List of language subdirectory makefiles.  Deprecated.
3561 all_lang_makefiles=
3562 # Additional files for gengtype
3563 all_gtfiles="$target_gtfiles"
3564
3565 # These are the languages that are set in --enable-languages,
3566 # and are available in the GCC tree.
3567 all_selected_languages=
3568
3569 # Add the language fragments.
3570 # Languages are added via two mechanisms.  Some information must be
3571 # recorded in makefile variables, these are defined in config-lang.in.
3572 # We accumulate them and plug them into the main Makefile.
3573 # The other mechanism is a set of hooks for each of the main targets
3574 # like `clean', `install', etc.
3575
3576 language_hooks="Make-hooks"
3577
3578 for lang in ${srcdir}/*/config-lang.in
3579 do
3580 changequote(,)dnl
3581         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3582
3583         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3584         if test "x$lang_alias" = x
3585         then
3586               echo "$lang doesn't set \$language." 1>&2
3587               exit 1
3588         fi
3589         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3590         subdirs="$subdirs $subdir"
3591
3592         # $gcc_subdir is where the gcc integration files are to be found
3593         # for a language, both for internal compiler purposes (compiler
3594         # sources implementing front-end to GCC tree converters), and for
3595         # build infrastructure purposes (Make-lang.in, etc.)
3596         #
3597         # This will be <subdir> (relative to $srcdir) if a line like
3598         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3599         # is found in <langdir>/config-lang.in, and will remain <langdir>
3600         # otherwise.
3601         #
3602         # Except for the language alias (fetched above), the regular
3603         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3604         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3605         # only this and the language alias.
3606
3607         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3608         if [ "$gcc_subdir" = "" ]; then
3609            gcc_subdir="$subdir"
3610         fi
3611
3612         case ",$enable_languages," in
3613         *,$lang_alias,*)
3614             all_selected_languages="$all_selected_languages $lang_alias"
3615             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3616                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3617             fi
3618             ;;
3619         esac
3620 changequote([,])dnl
3621
3622         language=
3623         boot_language=
3624         compilers=
3625         outputs=
3626         gtfiles=
3627         subdir_requires=
3628         . ${srcdir}/$gcc_subdir/config-lang.in
3629         if test "x$language" = x
3630         then
3631                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3632                 exit 1
3633         fi
3634
3635         ok=:
3636         case ",$enable_languages," in
3637                 *,$lang_alias,*) ;;
3638                 *)
3639                         for i in $subdir_requires; do
3640                                 test -f "${srcdir}/$i/config-lang.in" && continue
3641                                 ok=false
3642                                 break
3643                         done
3644                 ;;
3645         esac
3646         $ok || continue
3647
3648         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3649         if test -f $srcdir/$gcc_subdir/lang.opt; then
3650             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3651         fi
3652         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3653             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3654         fi
3655         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3656                 then all_lang_makefiles="$gcc_subdir/Makefile"
3657         fi
3658         all_languages="$all_languages $language"
3659         all_compilers="$all_compilers $compilers"
3660         all_outputs="$all_outputs $outputs"
3661         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3662 done
3663
3664 # Pick up gtfiles for c
3665 gtfiles=
3666 . ${srcdir}/c-config-lang.in
3667 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3668
3669 check_languages=
3670 for language in $all_selected_languages
3671 do
3672         check_languages="$check_languages check-$language"
3673 done
3674
3675 # We link each language in with a set of hooks, reached indirectly via
3676 # lang.${target}.  Only do so for selected languages.
3677
3678 rm -f Make-hooks
3679 touch Make-hooks
3680 target_list="all.cross start.encap rest.encap tags \
3681         install-common install-man install-info install-pdf dvi pdf \
3682         html uninstall info man srcextra srcman srcinfo \
3683         mostlyclean clean distclean maintainer-clean"
3684
3685 for t in $target_list
3686 do
3687         x=
3688         for lang in $all_selected_languages
3689         do
3690                 x="$x $lang.$t"
3691         done
3692         echo "lang.$t: $x" >> Make-hooks
3693 done
3694
3695 # --------
3696 # UNSORTED
3697 # --------
3698
3699 # Create .gdbinit.
3700
3701 echo "dir ." > .gdbinit
3702 echo "dir ${srcdir}" >> .gdbinit
3703 if test x$gdb_needs_out_file_path = xyes
3704 then
3705         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3706 fi
3707 if test "x$subdirs" != x; then
3708         for s in $subdirs
3709         do
3710                 echo "dir ${srcdir}/$s" >> .gdbinit
3711         done
3712 fi
3713 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3714
3715 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3716 AC_SUBST(gcc_tooldir)
3717 AC_SUBST(dollar)
3718
3719 # Find a directory in which to install a shared libgcc.
3720
3721 AC_ARG_ENABLE(version-specific-runtime-libs,
3722 [  --enable-version-specific-runtime-libs
3723                           specify that runtime libraries should be
3724                           installed in a compiler-specific directory])
3725
3726 AC_ARG_WITH(slibdir,
3727 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3728 slibdir="$with_slibdir",
3729 if test "${enable_version_specific_runtime_libs+set}" = set; then
3730   slibdir='$(libsubdir)'
3731 elif test "$host" != "$target"; then
3732   slibdir='$(build_tooldir)/lib'
3733 else
3734   slibdir='$(libdir)'
3735 fi)
3736 AC_SUBST(slibdir)
3737
3738 AC_ARG_WITH(datarootdir,
3739 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3740 datarootdir="\${prefix}/$with_datarootdir",
3741 datarootdir='$(prefix)/share')
3742 AC_SUBST(datarootdir)
3743
3744 AC_ARG_WITH(docdir,
3745 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3746 docdir="\${prefix}/$with_docdir",
3747 docdir='$(datarootdir)')
3748 AC_SUBST(docdir)
3749
3750 AC_ARG_WITH(htmldir,
3751 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3752 htmldir="\${prefix}/$with_htmldir",
3753 htmldir='$(docdir)')
3754 AC_SUBST(htmldir)
3755
3756 # Substitute configuration variables
3757 AC_SUBST(subdirs)
3758 AC_SUBST(srcdir)
3759 AC_SUBST(all_compilers)
3760 AC_SUBST(all_gtfiles)
3761 AC_SUBST(all_lang_makefrags)
3762 AC_SUBST(all_lang_makefiles)
3763 AC_SUBST(all_languages)
3764 AC_SUBST(all_selected_languages)
3765 AC_SUBST(build_exeext)
3766 AC_SUBST(build_install_headers_dir)
3767 AC_SUBST(build_xm_file_list)
3768 AC_SUBST(build_xm_include_list)
3769 AC_SUBST(build_xm_defines)
3770 AC_SUBST(build_file_translate)
3771 AC_SUBST(check_languages)
3772 AC_SUBST(cpp_install_dir)
3773 AC_SUBST(xmake_file)
3774 AC_SUBST(tmake_file)
3775 AC_SUBST(extra_gcc_objs)
3776 AC_SUBST(extra_headers_list)
3777 AC_SUBST(extra_objs)
3778 AC_SUBST(extra_parts)
3779 AC_SUBST(extra_passes)
3780 AC_SUBST(extra_programs)
3781 AC_SUBST(float_h_file)
3782 AC_SUBST(gcc_config_arguments)
3783 AC_SUBST(gcc_gxx_include_dir)
3784 AC_SUBST(host_exeext)
3785 AC_SUBST(host_xm_file_list)
3786 AC_SUBST(host_xm_include_list)
3787 AC_SUBST(host_xm_defines)
3788 AC_SUBST(out_host_hook_obj)
3789 AC_SUBST(install)
3790 AC_SUBST(lang_opt_files)
3791 AC_SUBST(lang_specs_files)
3792 AC_SUBST(lang_tree_files)
3793 AC_SUBST(local_prefix)
3794 AC_SUBST(md_file)
3795 AC_SUBST(objc_boehm_gc)
3796 AC_SUBST(out_file)
3797 AC_SUBST(out_object_file)
3798 AC_SUBST(thread_file)
3799 AC_SUBST(tm_file_list)
3800 AC_SUBST(tm_include_list)
3801 AC_SUBST(tm_defines)
3802 AC_SUBST(tm_p_file_list)
3803 AC_SUBST(tm_p_include_list)
3804 AC_SUBST(xm_file_list)
3805 AC_SUBST(xm_include_list)
3806 AC_SUBST(xm_defines)
3807 AC_SUBST(c_target_objs)
3808 AC_SUBST(cxx_target_objs)
3809 AC_SUBST(fortran_target_objs)
3810 AC_SUBST(target_cpu_default)
3811
3812 AC_SUBST_FILE(language_hooks)
3813
3814 # Echo link setup.
3815 if test x${build} = x${host} ; then
3816   if test x${host} = x${target} ; then
3817     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3818   else
3819     echo "Links are now set up to build a cross-compiler" 1>&2
3820     echo " from ${host} to ${target}." 1>&2
3821   fi
3822 else
3823   if test x${host} = x${target} ; then
3824     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3825     echo " for ${target}." 1>&2
3826   else
3827     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3828     echo " from ${host} to ${target}." 1>&2
3829   fi
3830 fi
3831
3832 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3833 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3834
3835 # Configure the subdirectories
3836 # AC_CONFIG_SUBDIRS($subdirs)
3837
3838 # Create the Makefile
3839 # and configure language subdirectories
3840 AC_CONFIG_FILES($all_outputs)
3841
3842 AC_CONFIG_COMMANDS([default],
3843 [
3844 case ${CONFIG_HEADERS} in
3845   *auto-host.h:config.in*)
3846   echo > cstamp-h ;;
3847 esac
3848 # Make sure all the subdirs exist.
3849 for d in $subdirs doc build
3850 do
3851     test -d $d || mkdir $d
3852 done
3853 ],
3854 [subdirs='$subdirs'])
3855 AC_OUTPUT