gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 # autoconf is lame and doesn't give us any substitution variable for this.
 280 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 281   NO_MINUS_C_MINUS_O=yes
 282 else
 283   OUTPUT_OPTION='-o $@'
 284 fi
 285 AC_SUBST(NO_MINUS_C_MINUS_O)
 286 AC_SUBST(OUTPUT_OPTION)
 287
 288 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 289 # optimizations to be activated explicitly by the toplevel.
 290 case "$CC" in
 291   */prev-gcc/xgcc*) ;;
 292   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 293 esac
 294 AC_SUBST(CFLAGS)
 295
 296 # -------------------------
 297 # Check C compiler features
 298 # -------------------------
 299
 300 AC_USE_SYSTEM_EXTENSIONS
 301 AC_PROG_CPP
 302 AC_C_INLINE
 303
 304 # sizeof(char) is 1 by definition.
 305 AC_CHECK_SIZEOF(void *)
 306 AC_CHECK_SIZEOF(short)
 307 AC_CHECK_SIZEOF(int)
 308 AC_CHECK_SIZEOF(long)
 309 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 310 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 311
 312 # ---------------------
 313 # Warnings and checking
 314 # ---------------------
 315
 316 # Check $CC warning features (if it's GCC).
 317 # We want to use -pedantic, but we don't want warnings about
 318 # * 'long long'
 319 # * variadic macros
 320 # * overlong strings
 321 # So, we only use -pedantic if we can disable those warnings.
 322
 323 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 324                           -Wmissing-prototypes], [loose_warn])
 325 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 326 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 327                           -Wmissing-format-attribute], [strict_warn])
 328 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 329                                      -Wno-overlength-strings], [strict_warn])
 330 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 331
 332 # The above macros do nothing if the compiler is not GCC.  However, the
 333 # Makefile has more goo to add other flags, so this variabl is used to
 334 # enables warnings only for GCC.
 335 warn_cflags=
 336 if test "x$GCC" = "xyes"; then
 337   warn_cflags='$(GCC_WARN_CFLAGS)'
 338 fi
 339 AC_SUBST(warn_cflags)
 340
 341 # Enable expensive internal checks
 342 is_release=
 343 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 344   is_release=yes
 345 fi
 346
 347 AC_ARG_ENABLE(checking,
 348 [  --enable-checking[=LIST]
 349                           enable expensive run-time checks.  With LIST,
 350                           enable only specific categories of checks.
 351                           Categories are: yes,no,all,none,release.
 352                           Flags are: assert,df,fold,gc,gcac,misc,
 353                           rtlflag,rtl,runtime,tree,valgrind,types.],
 354 [ac_checking_flags="${enableval}"],[
 355 # Determine the default checks.
 356 if test x$is_release = x ; then
 357   ac_checking_flags=yes
 358 else
 359   ac_checking_flags=release
 360 fi])
 361 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 362 for check in release $ac_checking_flags
 363 do
 364         case $check in
 365         # these set all the flags to specific states
 366         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 367                         ac_fold_checking= ; ac_gc_checking=1 ;
 368                         ac_gc_always_collect= ; ac_rtl_checking= ;
 369                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 370                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 371                         ac_types_checking=1 ;;
 372         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 373                         ac_fold_checking= ; ac_gc_checking= ;
 374                         ac_gc_always_collect= ; ac_rtl_checking= ;
 375                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 376                         ac_tree_checking= ; ac_valgrind_checking= ;
 377                         ac_types_checking= ;;
 378         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 379                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 380                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 383                         ac_types_checking=1 ;;
 384         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 385                         ac_fold_checking= ; ac_gc_checking= ;
 386                         ac_gc_always_collect= ; ac_rtl_checking= ;
 387                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 388                         ac_tree_checking= ; ac_valgrind_checking= ;
 389                         ac_types_checking= ;;
 390         # these enable particular checks
 391         assert)         ac_assert_checking=1 ;;
 392         df)             ac_df_checking=1 ;;
 393         fold)           ac_fold_checking=1 ;;
 394         gc)             ac_gc_checking=1 ;;
 395         gcac)           ac_gc_always_collect=1 ;;
 396         misc)           ac_checking=1 ;;
 397         rtl)            ac_rtl_checking=1 ;;
 398         rtlflag)        ac_rtlflag_checking=1 ;;
 399         runtime)        ac_runtime_checking=1 ;;
 400         tree)           ac_tree_checking=1 ;;
 401         types)          ac_types_checking=1 ;;
 402         valgrind)       ac_valgrind_checking=1 ;;
 403         *)      AC_MSG_ERROR(unknown check category $check) ;;
 404         esac
 405 done
 406 IFS="$ac_save_IFS"
 407
 408 nocommon_flag=""
 409 if test x$ac_checking != x ; then
 410   AC_DEFINE(ENABLE_CHECKING, 1,
 411 [Define if you want more run-time sanity checks.  This one gets a grab
 412    bag of miscellaneous but relatively cheap checks.])
 413   nocommon_flag=-fno-common
 414 fi
 415 AC_SUBST(nocommon_flag)
 416 if test x$ac_df_checking != x ; then
 417   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 418 [Define if you want more run-time sanity checks for dataflow.])
 419 fi
 420 if test x$ac_assert_checking != x ; then
 421   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 422 [Define if you want assertions enabled.  This is a cheap check.])
 423 fi
 424 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 425 if test x$ac_runtime_checking != x ; then
 426   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 427 [Define if you want runtime assertions enabled.  This is a cheap check.])
 428 fi
 429 if test x$ac_tree_checking != x ; then
 430   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 431 [Define if you want all operations on trees (the basic data
 432    structure of the front ends) to be checked for dynamic type safety
 433    at runtime.  This is moderately expensive.  The tree browser debugging
 434    routines will also be enabled by this option.
 435    ])
 436   TREEBROWSER=tree-browser.o
 437 fi
 438 if test x$ac_types_checking != x ; then
 439   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 440 [Define if you want all gimple types to be verified after gimplifiation.
 441    This is cheap.
 442    ])
 443 fi
 444 AC_SUBST(TREEBROWSER)
 445 if test x$ac_rtl_checking != x ; then
 446   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 447 [Define if you want all operations on RTL (the basic data structure
 448    of the optimizer and back end) to be checked for dynamic type safety
 449    at runtime.  This is quite expensive.])
 450 fi
 451 if test x$ac_rtlflag_checking != x ; then
 452   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 453 [Define if you want RTL flag accesses to be checked against the RTL
 454    codes that are supported for each access macro.  This is relatively
 455    cheap.])
 456 fi
 457 if test x$ac_gc_checking != x ; then
 458   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 459 [Define if you want the garbage collector to do object poisoning and
 460    other memory allocation checks.  This is quite expensive.])
 461 fi
 462 if test x$ac_gc_always_collect != x ; then
 463   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 464 [Define if you want the garbage collector to operate in maximally
 465    paranoid mode, validating the entire heap and collecting garbage at
 466    every opportunity.  This is extremely expensive.])
 467 fi
 468 if test x$ac_fold_checking != x ; then
 469   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 470 [Define if you want fold checked that it never destructs its argument.
 471    This is quite expensive.])
 472 fi
 473 valgrind_path_defines=
 474 valgrind_command=
 475
 476 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 477 dnl # an if statement.  This was the source of very frustrating bugs
 478 dnl # in converting to autoconf 2.5x!
 479 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 480
 481 if test x$ac_valgrind_checking != x ; then
 482   # It is certainly possible that there's valgrind but no valgrind.h.
 483   # GCC relies on making annotations so we must have both.
 484   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 485   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 486     [[#include <valgrind/memcheck.h>
 487 #ifndef VALGRIND_DISCARD
 488 #error VALGRIND_DISCARD not defined
 489 #endif]])],
 490   [gcc_cv_header_valgrind_memcheck_h=yes],
 491   [gcc_cv_header_valgrind_memcheck_h=no])
 492   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 493   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 494   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 495     [[#include <memcheck.h>
 496 #ifndef VALGRIND_DISCARD
 497 #error VALGRIND_DISCARD not defined
 498 #endif]])],
 499   [gcc_cv_header_memcheck_h=yes],
 500   [gcc_cv_header_memcheck_h=no])
 501   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 502   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 503         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 504   if test "x$valgrind_path" = "x" \
 505     || (test $have_valgrind_h = no \
 506         && test $gcc_cv_header_memcheck_h = no \
 507         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 508         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 509   fi
 510   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 511   valgrind_command="$valgrind_path -q"
 512   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 513 [Define if you want to run subprograms and generated programs
 514    through valgrind (a memory checker).  This is extremely expensive.])
 515   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 516     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 517         [Define if valgrind's valgrind/memcheck.h header is installed.])
 518   fi
 519   if test $gcc_cv_header_memcheck_h = yes; then
 520     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 521         [Define if valgrind's memcheck.h header is installed.])
 522   fi
 523 fi
 524 AC_SUBST(valgrind_path_defines)
 525 AC_SUBST(valgrind_command)
 526
 527 # Enable code coverage collection
 528 AC_ARG_ENABLE(coverage,
 529 [  --enable-coverage[=LEVEL]
 530                           enable compiler's code coverage collection.
 531                           Use to measure compiler performance and locate
 532                           unused parts of the compiler. With LEVEL, specify
 533                           optimization. Values are opt, noopt,
 534                           default is noopt],
 535 [case "${enableval}" in
 536   yes|noopt)
 537     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 538     ;;
 539   opt)
 540     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 541     ;;
 542   no)
 543     # a.k.a. --disable-coverage
 544     coverage_flags=""
 545     ;;
 546   *)
 547     AC_MSG_ERROR(unknown coverage setting $enableval)
 548     ;;
 549 esac],
 550 [coverage_flags=""])
 551 AC_SUBST(coverage_flags)
 552
 553 AC_ARG_ENABLE(gather-detailed-mem-stats,
 554 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 555 [enable_gather_detailed_mem_stats=no])
 556 if test x$enable_gather_detailed_mem_stats = xyes ; then
 557   AC_DEFINE(GATHER_STATISTICS, 1,
 558         [Define to enable detailed memory allocation stats gathering.])
 559 fi
 560
 561 # -------------------------------
 562 # Miscenalleous configure options
 563 # -------------------------------
 564
 565 # With stabs
 566 AC_ARG_WITH(stabs,
 567 [  --with-stabs            arrange to use stabs instead of host debug format],
 568 stabs="$with_stabs",
 569 stabs=no)
 570
 571 # Determine whether or not multilibs are enabled.
 572 AC_ARG_ENABLE(multilib,
 573 [  --enable-multilib       enable library support for multiple ABIs],
 574 [], [enable_multilib=yes])
 575 AC_SUBST(enable_multilib)
 576
 577 # Enable __cxa_atexit for C++.
 578 AC_ARG_ENABLE(__cxa_atexit,
 579 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 580 [], [])
 581
 582 # Enable C extension for decimal float if target supports it.
 583 AC_ARG_ENABLE(decimal-float,
 584 [  --enable-decimal-float={no,yes,bid,dpd}
 585                         enable decimal float extension to C.  Selecting 'bid'
 586                         or 'dpd' choses which decimal floating point format
 587                         to use],
 588 [
 589   case $enable_decimal_float in
 590     yes | no | bid | dpd) ;;
 591     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 592 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 593   esac
 594 ],
 595 [
 596   case $target in
 597     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 598       enable_decimal_float=yes
 599       ;;
 600     *)
 601       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 602       enable_decimal_float=no
 603       ;;
 604   esac
 605 ])
 606
 607 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 608 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 609 [Define to 1 to enable decimal float extension to C.])
 610
 611 # x86's use BID format instead of DPD
 612 case x$enable_decimal_float in
 613   xyes)
 614     case $target in
 615       i?86*-*-linux* | x86_64*-*-linux*)
 616         enable_decimal_float=bid
 617         ;;
 618       *)
 619         enable_decimal_float=dpd
 620         ;;
 621     esac
 622     ;;
 623   xno)
 624     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 625     # dependency on libdecnumber.
 626     enable_decimal_float=dpd
 627     ;;
 628 esac
 629 AC_SUBST(enable_decimal_float)
 630
 631 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 632 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 633 [Define to 1 to specify that we are using the BID decimal floating
 634 point format instead of DPD])
 635
 636 # Enable C extension for fixed-point arithmetic.
 637 AC_ARG_ENABLE(fixed-point,
 638 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 639 [
 640 ],
 641 [
 642   case $target in
 643     mips*-*-*)
 644       case $host in
 645         mips*-sgi-irix*)
 646           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 647           enable_fixed_point=no
 648           ;;
 649         *)
 650           enable_fixed_point=yes
 651           ;;
 652       esac
 653       ;;
 654     *)
 655       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 656       enable_fixed_point=no
 657       ;;
 658   esac
 659 ])
 660 AC_SUBST(enable_fixed_point)
 661
 662 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 663 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 664 [Define to 1 to enable fixed-point arithmetic extension to C.])
 665
 666 # Enable threads
 667 # Pass with no value to take the default
 668 # Pass with a value to specify a thread package
 669 AC_ARG_ENABLE(threads,
 670 [  --enable-threads        enable thread usage for target GCC
 671   --enable-threads=LIB    use LIB thread package for target GCC],,
 672 [enable_threads=''])
 673
 674 AC_ARG_ENABLE(tls,
 675 [  --enable-tls            enable or disable generation of tls code
 676                           overriding the assembler check for tls support],
 677 [
 678   case $enable_tls in
 679     yes | no) ;;
 680     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 681 Valid choices are 'yes' and 'no'.]) ;;
 682   esac
 683 ], [enable_tls=''])
 684
 685 AC_ARG_ENABLE(objc-gc,
 686 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 687                           the GNU Objective-C runtime],
 688 if test x$enable_objc_gc = xno; then
 689         objc_boehm_gc=''
 690 else
 691         objc_boehm_gc=1
 692 fi,
 693 objc_boehm_gc='')
 694
 695 AC_ARG_WITH(dwarf2,
 696 [  --with-dwarf2           force the default debug format to be DWARF 2],
 697 dwarf2="$with_dwarf2",
 698 dwarf2=no)
 699
 700 AC_ARG_ENABLE(shared,
 701 [  --disable-shared        don't provide a shared libgcc],
 702 [
 703   case $enable_shared in
 704   yes | no) ;;
 705   *)
 706     enable_shared=no
 707     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 708     for pkg in $enableval; do
 709       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 710         enable_shared=yes
 711       fi
 712     done
 713     IFS="$ac_save_ifs"
 714     ;;
 715   esac
 716 ], [enable_shared=yes])
 717 AC_SUBST(enable_shared)
 718
 719 AC_ARG_WITH(build-sysroot,
 720   [  --with-build-sysroot=sysroot
 721                           use sysroot as the system root during the build])
 722
 723 AC_ARG_WITH(sysroot,
 724 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 725 [
 726  case ${with_sysroot} in
 727  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 728  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 729  esac
 730
 731  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 732  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 733
 734  if test "x$prefix" = xNONE; then
 735   test_prefix=/usr/local
 736  else
 737   test_prefix=$prefix
 738  fi
 739  if test "x$exec_prefix" = xNONE; then
 740   test_exec_prefix=$test_prefix
 741  else
 742   test_exec_prefix=$exec_prefix
 743  fi
 744  case ${TARGET_SYSTEM_ROOT} in
 745  "${test_prefix}"|"${test_prefix}/"*|\
 746  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 747  '${prefix}'|'${prefix}/'*|\
 748  '${exec_prefix}'|'${exec_prefix}/'*)
 749    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 750    TARGET_SYSTEM_ROOT_DEFINE="$t"
 751    ;;
 752  esac
 753 ], [
 754  TARGET_SYSTEM_ROOT=
 755  TARGET_SYSTEM_ROOT_DEFINE=
 756  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 757 ])
 758 AC_SUBST(TARGET_SYSTEM_ROOT)
 759 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 760 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 761
 762 # Build with intermodule optimisations
 763 AC_ARG_ENABLE(intermodule,
 764 [  --enable-intermodule    build the compiler in one step],
 765 [case ${enable_intermodule} in
 766   yes) onestep="-onestep";;
 767   *) onestep="";;
 768 esac],
 769 [onestep=""])
 770 AC_SUBST(onestep)
 771
 772 ACX_PKGVERSION([GCC])
 773 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 774
 775 # Sanity check enable_languages in case someone does not run the toplevel
 776 # configure # script.
 777 AC_ARG_ENABLE(languages,
 778 [  --enable-languages=LIST specify which front-ends to build],
 779 [case ,${enable_languages}, in
 780        ,,|,yes,)
 781                 # go safe -- we cannot be much sure without the toplevel
 782                 # configure's
 783                 # analysis of which target libs are present and usable
 784                 enable_languages=c
 785                 ;;
 786          *,all,*)
 787                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 788                 ;;
 789         *,c,*)
 790                 ;;
 791         *)
 792                 enable_languages=c,${enable_languages}
 793                 ;;
 794 esac],
 795 [enable_languages=c])
 796
 797 # Used by documentation targets
 798 AC_SUBST(datarootdir)
 799 AC_SUBST(docdir)
 800 AC_SUBST(htmldir)
 801
 802 # -------------------------
 803 # Checks for other programs
 804 # -------------------------
 805
 806 AC_PROG_MAKE_SET
 807
 808 # Find some useful tools
 809 AC_PROG_AWK
 810 # We need awk to create options.c and options.h.
 811 # Bail out if it's missing.
 812 case ${AWK} in
 813   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 814 esac
 815
 816 gcc_AC_PROG_LN_S
 817 ACX_PROG_LN($LN_S)
 818 AC_PROG_RANLIB
 819 case "${host}" in
 820 *-*-darwin*)
 821   # By default, the Darwin ranlib will not treat common symbols as
 822   # definitions when  building the archive table of contents.  Other
 823   # ranlibs do that; pass an option to the Darwin ranlib that makes
 824   # it behave similarly.
 825   ranlib_flags="-c"
 826   ;;
 827 *)
 828   ranlib_flags=""
 829 esac
 830 AC_SUBST(ranlib_flags)
 831
 832 gcc_AC_PROG_INSTALL
 833
 834 # See if cmp has --ignore-initial.
 835 gcc_AC_PROG_CMP_IGNORE_INITIAL
 836
 837 # See if we have the mktemp command.
 838 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 839
 840 # See if makeinfo has been installed and is modern enough
 841 # that we can use it.
 842 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 843   [GNU texinfo.* \([0-9][0-9.]*\)],
 844   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 845 if test $gcc_cv_prog_makeinfo_modern = no; then
 846   AC_MSG_WARN([
 847 *** Makeinfo is missing or too old.
 848 *** Info documentation will not be built.])
 849   BUILD_INFO=
 850 else
 851   BUILD_INFO=info
 852 fi
 853 AC_SUBST(BUILD_INFO)
 854
 855 # Is pod2man recent enough to regenerate manpages?
 856 AC_MSG_CHECKING([for recent Pod::Man])
 857 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 858   AC_MSG_RESULT(yes)
 859   GENERATED_MANPAGES=generated-manpages
 860 else
 861   AC_MSG_RESULT(no)
 862   GENERATED_MANPAGES=
 863 fi
 864 AC_SUBST(GENERATED_MANPAGES)
 865
 866 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 867
 868 # How about lex?
 869 dnl Don't use AC_PROG_LEX; we insist on flex.
 870 dnl LEXLIB is not useful in gcc.
 871 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 872
 873 # Bison?
 874 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 875
 876 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 877 # check for build == host before using them.
 878
 879 # NM
 880 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 881   && test -d ../binutils ; then
 882   NM='$(objdir)/../binutils/nm-new'
 883 else
 884   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 885 fi
 886
 887 # AR
 888 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 889   && test -d ../binutils ; then
 890   AR='$(objdir)/../binutils/ar'
 891 else
 892   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 893 fi
 894
 895
 896 # --------------------
 897 # Checks for C headers
 898 # --------------------
 899
 900 # Need to reject headers which give warnings, so that the -Werror bootstrap
 901 # works later. *sigh*  This needs to come before all header checks.
 902 AC_PROG_CPP_WERROR
 903
 904 AC_HEADER_STDC
 905 AC_HEADER_TIME
 906 ACX_HEADER_STRING
 907 AC_HEADER_SYS_WAIT
 908 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 909                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 910                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 911                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 912
 913 # Check for thread headers.
 914 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 915 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 916
 917 # These tests can't be done till we know if we have limits.h.
 918 gcc_AC_C_CHAR_BIT
 919 AC_C_BIGENDIAN
 920
 921 # --------
 922 # UNSORTED
 923 # --------
 924
 925
 926 # These libraries may be used by collect2.
 927 # We may need a special search path to get them linked.
 928 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 929 [save_LIBS="$LIBS"
 930 for libs in '' -lld -lmld \
 931                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 932                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 933 do
 934         LIBS="$libs"
 935         AC_TRY_LINK_FUNC(ldopen,
 936                 [gcc_cv_collect2_libs="$libs"; break])
 937 done
 938 LIBS="$save_LIBS"
 939 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 940 case $gcc_cv_collect2_libs in
 941         "none required")        ;;
 942         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 943 esac
 944 AC_SUBST(COLLECT2_LIBS)
 945
 946 # When building Ada code on Alpha, we need exc_resume which is usually in
 947 # -lexc.  So test for it.
 948 save_LIBS="$LIBS"
 949 LIBS=
 950 AC_SEARCH_LIBS(exc_resume, exc)
 951 GNAT_LIBEXC="$LIBS"
 952 LIBS="$save_LIBS"
 953 AC_SUBST(GNAT_LIBEXC)
 954
 955 # Some systems put ldexp and frexp in libm instead of libc; assume
 956 # they're both in the same place.  jcf-dump needs them.
 957 save_LIBS="$LIBS"
 958 LIBS=
 959 AC_SEARCH_LIBS(ldexp, m)
 960 LDEXP_LIB="$LIBS"
 961 LIBS="$save_LIBS"
 962 AC_SUBST(LDEXP_LIB)
 963
 964 # Use <inttypes.h> only if it exists,
 965 # doesn't clash with <sys/types.h>, and declares intmax_t.
 966 AC_MSG_CHECKING(for inttypes.h)
 967 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 968 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 969 [[#include <sys/types.h>
 970 #include <inttypes.h>]],
 971   [[intmax_t i = -1;]])],
 972   [gcc_cv_header_inttypes_h=yes],
 973   [gcc_cv_header_inttypes_h=no])])
 974 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 975 if test $gcc_cv_header_inttypes_h = yes; then
 976   AC_DEFINE(HAVE_INTTYPES_H, 1,
 977         [Define if you have a working <inttypes.h> header file.])
 978 fi
 979
 980 dnl Disabled until we have a complete test for buggy enum bitfields.
 981 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 982
 983 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 984   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 985   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 986   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 987   putchar_unlocked putc_unlocked)
 988 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 989         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 990         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 991         gcc_UNLOCKED_FUNCS)
 992
 993 if test x$ac_cv_func_mbstowcs = xyes; then
 994   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 995 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 996 int main()
 997 {
 998   mbstowcs(0, "", 0);
 999   return 0;
1000 }]])],
1001     [gcc_cv_func_mbstowcs_works=yes],
1002     [gcc_cv_func_mbstowcs_works=no],
1003     [gcc_cv_func_mbstowcs_works=yes])])
1004   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1005     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1006   [Define this macro if mbstowcs does not crash when its
1007    first argument is NULL.])
1008   fi
1009 fi
1010
1011 AC_CHECK_TYPE(ssize_t, int)
1012
1013 # Try to determine the array type of the second argument of getgroups
1014 # for the target system (int or gid_t).
1015 AC_TYPE_GETGROUPS
1016 if test "${target}" = "${build}"; then
1017   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1018 else
1019   case "${target}" in
1020         # This condition may need some tweaking.  It should include all
1021         # targets where the array type of the second argument of getgroups
1022         # is int and the type of gid_t is not equivalent to int.
1023         *-*-sunos* | *-*-ultrix*)
1024                 TARGET_GETGROUPS_T=int
1025                 ;;
1026         *)
1027                 TARGET_GETGROUPS_T=gid_t
1028                 ;;
1029   esac
1030 fi
1031 AC_SUBST(TARGET_GETGROUPS_T)
1032
1033 gcc_AC_FUNC_MMAP_BLACKLIST
1034
1035 case "${host}" in
1036 *-*-*vms*)
1037   # Under VMS, vfork works very differently than on Unix. The standard test
1038   # won't work, and it isn't easily adaptable. It makes more sense to
1039   # just force it.
1040   ac_cv_func_vfork_works=yes
1041   ;;
1042 esac
1043 AC_FUNC_FORK
1044
1045 AM_ICONV
1046 # Until we have in-tree GNU iconv:
1047 LIBICONV_DEP=
1048 AC_SUBST(LIBICONV_DEP)
1049
1050 AM_LC_MESSAGES
1051
1052 AM_LANGINFO_CODESET
1053
1054 # We will need to find libiberty.h and ansidecl.h
1055 saved_CFLAGS="$CFLAGS"
1056 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1057 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1058         strsignal strstr strverscmp \
1059         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1060         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1061 #include "ansidecl.h"
1062 #include "system.h"])
1063
1064 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_RESOURCE_H
1068 #include <sys/resource.h>
1069 #endif
1070 ])
1071
1072 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1073 #include "ansidecl.h"
1074 #include "system.h"
1075 #ifdef HAVE_SYS_RESOURCE_H
1076 #include <sys/resource.h>
1077 #endif
1078 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1079 [Define to \`long' if <sys/resource.h> doesn't define.])])
1080
1081 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1082 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1083 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1084 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1085 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1086 #include "ansidecl.h"
1087 #include "system.h"
1088 #ifdef HAVE_LDFCN_H
1089 #undef FREAD
1090 #undef FWRITE
1091 #include <ldfcn.h>
1092 #endif
1093 ])
1094
1095 gcc_AC_CHECK_DECLS(times, , ,[
1096 #include "ansidecl.h"
1097 #include "system.h"
1098 #ifdef HAVE_SYS_TIMES_H
1099 #include <sys/times.h>
1100 #endif
1101 ])
1102
1103 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1104 #include "ansidecl.h"
1105 #include "system.h"
1106 #include <signal.h>
1107 ])
1108
1109 # More time-related stuff.
1110 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1111 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1112 #include "ansidecl.h"
1113 #include "system.h"
1114 #ifdef HAVE_SYS_TIMES_H
1115 #include <sys/times.h>
1116 #endif
1117 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1118 if test $ac_cv_struct_tms = yes; then
1119   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1120   [Define if <sys/times.h> defines struct tms.])
1121 fi
1122
1123 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1124 # revisit after autoconf 2.50.
1125 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1126 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1127 #include "ansidecl.h"
1128 #include "system.h"
1129 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1130 if test $gcc_cv_type_clock_t = yes; then
1131   AC_DEFINE(HAVE_CLOCK_T, 1,
1132   [Define if <time.h> defines clock_t.])
1133 fi
1134
1135 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1136 CFLAGS="$saved_CFLAGS"
1137
1138 gcc_AC_INITFINI_ARRAY
1139
1140 # mkdir takes a single argument on some systems.
1141 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1142
1143 # File extensions
1144 manext='.1'
1145 objext='.o'
1146 AC_SUBST(manext)
1147 AC_SUBST(objext)
1148
1149 # With Setjmp/Longjmp based exception handling.
1150 AC_ARG_ENABLE(sjlj-exceptions,
1151 [  --enable-sjlj-exceptions
1152                           arrange to use setjmp/longjmp exception handling],
1153 [case $target in
1154   *-*-hpux10*)
1155     if test $enableval != yes; then
1156       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1157       enableval=yes
1158     fi
1159     ;;
1160 esac
1161 force_sjlj_exceptions=yes],
1162 [case $target in
1163   *-*-hpux10*)
1164     force_sjlj_exceptions=yes
1165     enableval=yes
1166     ;;
1167   *)
1168     force_sjlj_exceptions=no
1169     ;;
1170 esac])
1171 if test $force_sjlj_exceptions = yes; then
1172   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1173   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1174     [Define 0/1 to force the choice for exception handling model.])
1175 fi
1176
1177 # For platforms with the unwind ABI which includes an unwind library,
1178 # libunwind, we can choose to use the system libunwind.
1179 AC_ARG_WITH(system-libunwind,
1180 [  --with-system-libunwind use installed libunwind])
1181
1182 # config.gcc also contains tests of with_system_libunwind.
1183 if test x$with_system_libunwind = xyes; then
1184         AC_DEFINE(HAVE_GETIPINFO, 1,
1185 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1186 fi
1187
1188 # --------------------------------------------------------
1189 # Build, host, and target specific configuration fragments
1190 # --------------------------------------------------------
1191
1192 # Collect build-machine-specific information.
1193 . ${srcdir}/config.build
1194
1195 # Collect host-machine-specific information.
1196 . ${srcdir}/config.host
1197
1198 target_gtfiles=
1199
1200 # Collect target-machine-specific information.
1201 . ${srcdir}/config.gcc
1202
1203 extra_objs="${host_extra_objs} ${extra_objs}"
1204 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1205
1206 # Default the target-machine variables that were not explicitly set.
1207 if test x"$tm_file" = x
1208 then tm_file=$cpu_type/$cpu_type.h; fi
1209
1210 if test x"$extra_headers" = x
1211 then extra_headers=; fi
1212
1213 if test x$md_file = x
1214 then md_file=$cpu_type/$cpu_type.md; fi
1215
1216 if test x$out_file = x
1217 then out_file=$cpu_type/$cpu_type.c; fi
1218
1219 if test x"$tmake_file" = x
1220 then tmake_file=$cpu_type/t-$cpu_type
1221 fi
1222
1223 if test x"$dwarf2" = xyes
1224 then tm_file="$tm_file tm-dwarf2.h"
1225 fi
1226
1227 # Say what files are being used for the output code and MD file.
1228 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1229 echo "Using \`$srcdir/config/$md_file' as machine description file."
1230
1231 # If any of the xm_file variables contain nonexistent files, warn
1232 # about them and drop them.
1233
1234 bx=
1235 for x in $build_xm_file; do
1236   if    test -f $srcdir/config/$x
1237   then      bx="$bx $x"
1238   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1239   fi
1240 done
1241 build_xm_file="$bx"
1242
1243 hx=
1244 for x in $host_xm_file; do
1245   if    test -f $srcdir/config/$x
1246   then      hx="$hx $x"
1247   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1248   fi
1249 done
1250 host_xm_file="$hx"
1251
1252 tx=
1253 for x in $xm_file; do
1254   if    test -f $srcdir/config/$x
1255   then      tx="$tx $x"
1256   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1257   fi
1258 done
1259 xm_file="$tx"
1260
1261 count=a
1262 for f in $tm_file; do
1263         count=${count}x
1264 done
1265 if test $count = ax; then
1266         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1267 else
1268         echo "Using the following target machine macro files:"
1269         for f in $tm_file; do
1270                 echo "  $srcdir/config/$f"
1271         done
1272 fi
1273
1274 if test x$need_64bit_hwint = xyes; then
1275         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1276 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1277 fi
1278
1279 if test x$use_long_long_for_widest_fast_int = xyes; then
1280         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1281 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1282 efficiently supported by the host hardware.])
1283 fi
1284
1285 count=a
1286 for f in $host_xm_file; do
1287         count=${count}x
1288 done
1289 if test $count = a; then
1290         :
1291 elif test $count = ax; then
1292         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1293 else
1294         echo "Using the following host machine macro files:"
1295         for f in $host_xm_file; do
1296                 echo "  $srcdir/config/$f"
1297         done
1298 fi
1299 echo "Using ${out_host_hook_obj} for host machine hooks."
1300
1301 if test "$host_xm_file" != "$build_xm_file"; then
1302         count=a
1303         for f in $build_xm_file; do
1304                 count=${count}x
1305         done
1306         if test $count = a; then
1307                 :
1308         elif test $count = ax; then
1309                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1310         else
1311                 echo "Using the following build machine macro files:"
1312                 for f in $build_xm_file; do
1313                         echo "  $srcdir/config/$f"
1314                 done
1315         fi
1316 fi
1317
1318 case ${host} in
1319   powerpc*-*-darwin*)
1320     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1321       gcc_cv_mcontext_underscores,
1322       AC_COMPILE_IFELSE([
1323 #include <sys/cdefs.h>
1324 #include <sys/signal.h>
1325 #include <ucontext.h>
1326 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1327 ],
1328         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1329       if test $gcc_cv_mcontext_underscores = yes; then
1330         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1331           [mcontext_t fields start with __])
1332       fi
1333     ;;
1334 esac
1335
1336 # ---------
1337 # Threading
1338 # ---------
1339
1340 # Check if a valid thread package
1341 case ${enable_threads} in
1342   "" | no)
1343     # No threads
1344     target_thread_file='single'
1345     ;;
1346   yes)
1347     # default
1348     target_thread_file='single'
1349     ;;
1350   aix | dce | gnat | irix | posix | posix95 | rtems | \
1351   single | solaris | vxworks | win32 | mipssde)
1352     target_thread_file=${enable_threads}
1353     ;;
1354   *)
1355     echo "${enable_threads} is an unknown thread package" 1>&2
1356     exit 1
1357     ;;
1358 esac
1359
1360 if test x${thread_file} = x; then
1361   # No thread file set by target-specific clauses in config.gcc,
1362   # so use file chosen by default logic above
1363   thread_file=${target_thread_file}
1364 fi
1365
1366 # Make gthr-default.h if we have a thread file.
1367 gthread_flags=
1368 if test $thread_file != single; then
1369   rm -f gthr-default.h
1370   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1371   gthread_flags=-DHAVE_GTHR_DEFAULT
1372 fi
1373 AC_SUBST(gthread_flags)
1374
1375 # --------
1376 # UNSORTED
1377 # --------
1378
1379 use_cxa_atexit=no
1380 if test x$enable___cxa_atexit = xyes || \
1381    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1382   if test x$host = x$target; then
1383     case $host in
1384       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1385       # keyed to flag_use_cxa_atexit
1386       *-*-mingw32*)
1387         use_cxa_atexit=yes
1388         ;;
1389       *)
1390         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1391           [echo "__cxa_atexit can't be enabled on this target"])
1392         ;;
1393     esac
1394   else
1395     # We can't check for __cxa_atexit when building a cross, so assume
1396     # it is available
1397     use_cxa_atexit=yes
1398   fi
1399   if test x$use_cxa_atexit = xyes; then
1400     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1401       [Define if you want to use __cxa_atexit, rather than atexit, to
1402       register C++ destructors for local statics and global objects.
1403       This is essential for fully standards-compliant handling of
1404       destructors, but requires __cxa_atexit in libc.])
1405   fi
1406 fi
1407
1408 use_getipinfo=yes
1409 if test x$with_system_libunwind = xyes; then
1410    if test x$host = x$target; then
1411      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1412    fi
1413 fi
1414 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1415 if test x$use_getipinfo = xyes; then
1416    AC_DEFINE(HAVE_GETIPINFO, 1,
1417         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1418 else
1419    echo "The system unwind library does not support _Unwind_GetIPInfo."
1420 fi
1421
1422 # Look for a file containing extra machine modes.
1423 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1424   extra_modes_file='$(srcdir)'/config/${extra_modes}
1425   AC_SUBST(extra_modes_file)
1426   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1427   [Define to the name of a file containing a list of extra machine modes
1428    for this architecture.])
1429 fi
1430
1431 # Convert extra_options into a form suitable for Makefile use.
1432 extra_opt_files=
1433 for f in $extra_options; do
1434   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1435 done
1436 AC_SUBST(extra_opt_files)
1437
1438 # auto-host.h is the file containing items generated by autoconf and is
1439 # the first file included by config.h.
1440 # If host=build, it is correct to have bconfig include auto-host.h
1441 # as well.  If host!=build, we are in error and need to do more
1442 # work to find out the build config parameters.
1443 if test x$host = x$build
1444 then
1445         build_auto=auto-host.h
1446 else
1447         # We create a subdir, then run autoconf in the subdir.
1448         # To prevent recursion we set host and build for the new
1449         # invocation of configure to the build for this invocation
1450         # of configure.
1451         tempdir=build.$$
1452         rm -rf $tempdir
1453         mkdir $tempdir
1454         cd $tempdir
1455         case ${srcdir} in
1456         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1457         *) realsrcdir=../${srcdir};;
1458         esac
1459         saved_CFLAGS="${CFLAGS}"
1460         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1461         ${realsrcdir}/configure \
1462                 --enable-languages=${enable_languages-all} \
1463                 --target=$target_alias --host=$build_alias --build=$build_alias
1464         CFLAGS="${saved_CFLAGS}"
1465
1466         # We just finished tests for the build machine, so rename
1467         # the file auto-build.h in the gcc directory.
1468         mv auto-host.h ../auto-build.h
1469         cd ..
1470         rm -rf $tempdir
1471         build_auto=auto-build.h
1472 fi
1473 AC_SUBST(build_subdir)
1474
1475 tm_file="${tm_file} defaults.h"
1476 tm_p_file="${tm_p_file} tm-preds.h"
1477 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1478 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1479 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1480 # put this back in temporarily.
1481 xm_file="auto-host.h ansidecl.h ${xm_file}"
1482
1483 # --------
1484 # UNSORTED
1485 # --------
1486
1487 changequote(,)dnl
1488 # Compile in configure arguments.
1489 if test -f configargs.h ; then
1490         # Being re-configured.
1491         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1492         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1493 else
1494         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1495 fi
1496
1497 # Double all backslashes and backslash all quotes to turn
1498 # gcc_config_arguments into a C string.
1499 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1500 $gcc_config_arguments
1501 EOF
1502 gcc_config_arguments_str=`cat conftest.out`
1503 rm -f conftest.out
1504
1505 cat > configargs.h <<EOF
1506 /* Generated automatically. */
1507 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1508 static const char thread_model[] = "$thread_file";
1509
1510 static const struct {
1511   const char *name, *value;
1512 } configure_default_options[] = $configure_default_options;
1513 EOF
1514 changequote([,])dnl
1515
1516 # Internationalization
1517 ZW_GNU_GETTEXT_SISTER_DIR
1518
1519 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1520 # -liconv on the link line twice.
1521 case "$LIBINTL" in *$LIBICONV*)
1522         LIBICONV= ;;
1523 esac
1524
1525 AC_ARG_ENABLE(secureplt,
1526 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1527 [], [])
1528
1529 # Windows32 Registry support for specifying GCC installation paths.
1530 AC_ARG_ENABLE(win32-registry,
1531 [  --disable-win32-registry
1532                           disable lookup of installation paths in the
1533                           Registry on Windows hosts
1534   --enable-win32-registry enable registry lookup (default)
1535   --enable-win32-registry=KEY
1536                           use KEY instead of GCC version as the last portion
1537                           of the registry key],,)
1538
1539 case $host_os in
1540   win32 | pe | cygwin* | mingw32* | uwin*)
1541     if test "x$enable_win32_registry" != xno; then
1542       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1543     fi
1544
1545     if test "x$enable_win32_registry" != xno; then
1546       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1547   [Define to 1 if installation paths should be looked up in the Windows
1548    Registry. Ignored on non-Windows hosts.])
1549
1550       if test "x$enable_win32_registry" != xyes \
1551          && test "x$enable_win32_registry" != x; then
1552         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1553   [Define to be the last component of the Windows registry key under which
1554    to look for installation paths.  The full key used will be
1555    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1556    The default is the GCC version number.])
1557       fi
1558     fi
1559   ;;
1560 esac
1561
1562 # Get an absolute path to the GCC top-level source directory
1563 holddir=`${PWDCMD-pwd}`
1564 cd $srcdir
1565 topdir=`${PWDCMD-pwd}`
1566 cd $holddir
1567
1568 # Conditionalize the makefile for this host machine.
1569 xmake_file=
1570 for f in ${host_xmake_file}
1571 do
1572         if test -f ${srcdir}/config/$f
1573         then
1574                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1575         fi
1576 done
1577
1578 # Conditionalize the makefile for this target machine.
1579 tmake_file_=
1580 for f in ${tmake_file}
1581 do
1582         if test -f ${srcdir}/config/$f
1583         then
1584                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1585         fi
1586 done
1587 tmake_file="${tmake_file_}"
1588
1589 # This is a terrible hack which will go away some day.
1590 host_cc_for_libada=${CC}
1591 AC_SUBST(host_cc_for_libada)
1592
1593 out_object_file=`basename $out_file .c`.o
1594
1595 tm_file_list="options.h"
1596 tm_include_list="options.h"
1597 for f in $tm_file; do
1598   case $f in
1599     ./* )
1600        f=`echo $f | sed 's/^..//'`
1601        tm_file_list="${tm_file_list} $f"
1602        tm_include_list="${tm_include_list} $f"
1603        ;;
1604     defaults.h )
1605        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1606        tm_include_list="${tm_include_list} $f"
1607        ;;
1608     * )
1609        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1610        tm_include_list="${tm_include_list} config/$f"
1611        ;;
1612   esac
1613 done
1614
1615 tm_p_file_list=
1616 tm_p_include_list=
1617 for f in $tm_p_file; do
1618   case $f in
1619     tm-preds.h )
1620        tm_p_file_list="${tm_p_file_list} $f"
1621        tm_p_include_list="${tm_p_include_list} $f"
1622        ;;
1623     * )
1624        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1625        tm_p_include_list="${tm_p_include_list} config/$f"
1626   esac
1627 done
1628
1629 xm_file_list=
1630 xm_include_list=
1631 for f in $xm_file; do
1632   case $f in
1633     ansidecl.h )
1634        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1635        xm_include_list="${xm_include_list} $f"
1636        ;;
1637     auto-host.h )
1638        xm_file_list="${xm_file_list} $f"
1639        xm_include_list="${xm_include_list} $f"
1640        ;;
1641     * )
1642        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1643        xm_include_list="${xm_include_list} config/$f"
1644        ;;
1645   esac
1646 done
1647
1648 host_xm_file_list=
1649 host_xm_include_list=
1650 for f in $host_xm_file; do
1651   case $f in
1652     ansidecl.h )
1653        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1654        host_xm_include_list="${host_xm_include_list} $f"
1655        ;;
1656     auto-host.h )
1657        host_xm_file_list="${host_xm_file_list} $f"
1658        host_xm_include_list="${host_xm_include_list} $f"
1659        ;;
1660     * )
1661        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1662        host_xm_include_list="${host_xm_include_list} config/$f"
1663        ;;
1664   esac
1665 done
1666
1667 build_xm_file_list=
1668 for f in $build_xm_file; do
1669   case $f in
1670     ansidecl.h )
1671        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1672        build_xm_include_list="${build_xm_include_list} $f"
1673        ;;
1674     auto-build.h | auto-host.h )
1675        build_xm_file_list="${build_xm_file_list} $f"
1676        build_xm_include_list="${build_xm_include_list} $f"
1677        ;;
1678     * )
1679        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1680        build_xm_include_list="${build_xm_include_list} config/$f"
1681        ;;
1682   esac
1683 done
1684
1685 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1686 # cross-compiler which does not use the native headers and libraries.
1687 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1688 CROSS=                                          AC_SUBST(CROSS)
1689 ALL=all.internal                                AC_SUBST(ALL)
1690 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1691
1692 if test "x$with_build_sysroot" != x; then
1693   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1694 else
1695   # This value is used, even on a native system, because
1696   # CROSS_SYSTEM_HEADER_DIR is just
1697   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1698   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1699 fi
1700
1701 if test x$host != x$target
1702 then
1703         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1704         ALL=all.cross
1705         SYSTEM_HEADER_DIR=$build_system_header_dir
1706         case "$host","$target" in
1707         # Darwin crosses can use the host system's libraries and headers,
1708         # because of the fat library support.  Of course, it must be the
1709         # same version of Darwin on both sides.  Allow the user to
1710         # just say --target=foo-darwin without a version number to mean
1711         # "the version on this system".
1712             *-*-darwin*,*-*-darwin*)
1713                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1714                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1715                 if test $hostos = $targetos -o $targetos = darwin ; then
1716                     CROSS=
1717                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1718                     with_headers=yes
1719                 fi
1720                 ;;
1721
1722             i?86-*-*,x86_64-*-* \
1723             | powerpc*-*-*,powerpc64*-*-*)
1724                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1725         esac
1726 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1727         SYSTEM_HEADER_DIR=$build_system_header_dir
1728 fi
1729
1730 # If this is a cross-compiler that does not
1731 # have its own set of headers then define
1732 # inhibit_libc
1733
1734 # If this is using newlib, without having the headers available now,
1735 # then define inhibit_libc in LIBGCC2_CFLAGS.
1736 # This prevents libgcc2 from containing any code which requires libc
1737 # support.
1738 : ${inhibit_libc=false}
1739 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1740        test x$with_newlib = xyes ; } &&
1741      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1742        inhibit_libc=true
1743 fi
1744 AC_SUBST(inhibit_libc)
1745
1746 # When building gcc with a cross-compiler, we need to adjust things so
1747 # that the generator programs are still built with the native compiler.
1748 # Also, we cannot run fixincludes or fix-header.
1749
1750 # These are the normal (build=host) settings:
1751 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1752 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1753 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1754
1755 # Possibly disable fixproto, on a per-target basis.
1756 case ${use_fixproto} in
1757   no)
1758     STMP_FIXPROTO=
1759     ;;
1760   yes)
1761     STMP_FIXPROTO=stmp-fixproto
1762     ;;
1763 esac
1764 AC_SUBST(STMP_FIXPROTO)
1765
1766 # And these apply if build != host, or we are generating coverage data
1767 if test x$build != x$host || test "x$coverage_flags" != x
1768 then
1769     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1770
1771     if test "x$TARGET_SYSTEM_ROOT" = x; then
1772         if test "x$STMP_FIXPROTO" != x; then
1773           STMP_FIXPROTO=stmp-install-fixproto
1774         fi
1775     fi
1776 fi
1777
1778 # Expand extra_headers to include complete path.
1779 # This substitutes for lots of t-* files.
1780 extra_headers_list=
1781 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1782 for file in ${extra_headers} ; do
1783   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1784 done
1785
1786 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1787 if test x"$use_gcc_tgmath" = xyes
1788 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1789 fi
1790
1791 # Define collect2 in Makefile.
1792 case $host_can_use_collect2 in
1793   no) collect2= ;;
1794   *) collect2='collect2$(exeext)' ;;
1795 esac
1796 AC_SUBST([collect2])
1797
1798 # Add a definition of USE_COLLECT2 if system wants one.
1799 case $use_collect2 in
1800   no) use_collect2= ;;
1801   "") ;;
1802   *)
1803     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1804     xm_defines="${xm_defines} USE_COLLECT2"
1805     case $host_can_use_collect2 in
1806       no)
1807         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1808         ;;
1809     esac
1810     ;;
1811 esac
1812
1813 # ---------------------------
1814 # Assembler & linker features
1815 # ---------------------------
1816
1817 # Identify the assembler which will work hand-in-glove with the newly
1818 # built GCC, so that we can examine its features.  This is the assembler
1819 # which will be driven by the driver program.
1820 #
1821 # If build != host, and we aren't building gas in-tree, we identify a
1822 # build->target assembler and hope that it will have the same features
1823 # as the host->target assembler we'll be using.
1824 gcc_cv_gas_major_version=
1825 gcc_cv_gas_minor_version=
1826 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1827
1828 m4_pattern_allow([AS_FOR_TARGET])dnl
1829 AS_VAR_SET_IF(gcc_cv_as,, [
1830 if test -x "$DEFAULT_ASSEMBLER"; then
1831         gcc_cv_as="$DEFAULT_ASSEMBLER"
1832 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1833      && test -f ../gas/Makefile \
1834      && test x$build = x$host; then
1835         gcc_cv_as=../gas/as-new$build_exeext
1836 elif test -x as$build_exeext; then
1837         # Build using assembler in the current directory.
1838         gcc_cv_as=./as$build_exeext
1839 elif test -x $AS_FOR_TARGET; then
1840         gcc_cv_as="$AS_FOR_TARGET"
1841 else
1842         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1843 fi])
1844
1845 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1846 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1847 case "$ORIGINAL_AS_FOR_TARGET" in
1848   ./as | ./as$build_exeext) ;;
1849   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1850 esac
1851
1852 AC_MSG_CHECKING(what assembler to use)
1853 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1854   # Single tree build which includes gas.  We want to prefer it
1855   # over whatever linker top-level may have detected, since
1856   # we'll use what we're building after installation anyway.
1857   AC_MSG_RESULT(newly built gas)
1858   in_tree_gas=yes
1859   _gcc_COMPUTE_GAS_VERSION
1860   in_tree_gas_is_elf=no
1861   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1862      || (grep 'obj_format = multi' ../gas/Makefile \
1863          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1864   then
1865     in_tree_gas_is_elf=yes
1866   fi
1867 else
1868   AC_MSG_RESULT($gcc_cv_as)
1869   in_tree_gas=no
1870 fi
1871
1872 # Identify the linker which will work hand-in-glove with the newly
1873 # built GCC, so that we can examine its features.  This is the linker
1874 # which will be driven by the driver program.
1875 #
1876 # If build != host, and we aren't building gas in-tree, we identify a
1877 # build->target linker and hope that it will have the same features
1878 # as the host->target linker we'll be using.
1879 gcc_cv_gld_major_version=
1880 gcc_cv_gld_minor_version=
1881 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1882 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1883
1884 AS_VAR_SET_IF(gcc_cv_ld,, [
1885 if test -x "$DEFAULT_LINKER"; then
1886         gcc_cv_ld="$DEFAULT_LINKER"
1887 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1888      && test -f ../ld/Makefile \
1889      && test x$build = x$host; then
1890         gcc_cv_ld=../ld/ld-new$build_exeext
1891 elif test -x collect-ld$build_exeext; then
1892         # Build using linker in the current directory.
1893         gcc_cv_ld=./collect-ld$build_exeext
1894 elif test -x $LD_FOR_TARGET; then
1895         gcc_cv_ld="$LD_FOR_TARGET"
1896 else
1897         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1898 fi])
1899
1900 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1901 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1902 case "$ORIGINAL_LD_FOR_TARGET" in
1903   ./collect-ld | ./collect-ld$build_exeext) ;;
1904   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1905 esac
1906
1907 AC_MSG_CHECKING(what linker to use)
1908 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1909         # Single tree build which includes ld.  We want to prefer it
1910         # over whatever linker top-level may have detected, since
1911         # we'll use what we're building after installation anyway.
1912         AC_MSG_RESULT(newly built ld)
1913         in_tree_ld=yes
1914         in_tree_ld_is_elf=no
1915         if (grep 'EMUL = .*elf' ../ld/Makefile \
1916             || grep 'EMUL = .*linux' ../ld/Makefile \
1917             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1918           in_tree_ld_is_elf=yes
1919         fi
1920         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1921         do
1922 changequote(,)dnl
1923                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1924                 if test x$gcc_cv_gld_version != x; then
1925                         break
1926                 fi
1927         done
1928         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1929         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1930 changequote([,])dnl
1931 else
1932         AC_MSG_RESULT($gcc_cv_ld)
1933         in_tree_ld=no
1934 fi
1935
1936 # Figure out what nm we will be using.
1937 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1938 AS_VAR_SET_IF(gcc_cv_nm,, [
1939 if test -f $gcc_cv_binutils_srcdir/configure.in \
1940      && test -f ../binutils/Makefile \
1941      && test x$build = x$host; then
1942         gcc_cv_nm=../binutils/nm-new$build_exeext
1943 elif test -x nm$build_exeext; then
1944         gcc_cv_nm=./nm$build_exeext
1945 elif test -x $NM_FOR_TARGET; then
1946         gcc_cv_nm="$NM_FOR_TARGET"
1947 else
1948         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1949 fi])
1950
1951 AC_MSG_CHECKING(what nm to use)
1952 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1953         # Single tree build which includes binutils.
1954         AC_MSG_RESULT(newly built nm)
1955         in_tree_nm=yes
1956 else
1957         AC_MSG_RESULT($gcc_cv_nm)
1958         in_tree_nm=no
1959 fi
1960
1961 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1962 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1963 case "$ORIGINAL_NM_FOR_TARGET" in
1964   ./nm | ./nm$build_exeext) ;;
1965   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1966 esac
1967
1968
1969 # Figure out what objdump we will be using.
1970 AS_VAR_SET_IF(gcc_cv_objdump,, [
1971 if test -f $gcc_cv_binutils_srcdir/configure.in \
1972      && test -f ../binutils/Makefile \
1973      && test x$build = x$host; then
1974         # Single tree build which includes binutils.
1975         gcc_cv_objdump=../binutils/objdump$build_exeext
1976 elif test -x objdump$build_exeext; then
1977         gcc_cv_objdump=./objdump$build_exeext
1978 elif test -x $OBJDUMP_FOR_TARGET; then
1979         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1980 else
1981         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1982 fi])
1983
1984 AC_MSG_CHECKING(what objdump to use)
1985 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1986         # Single tree build which includes binutils.
1987         AC_MSG_RESULT(newly built objdump)
1988 elif test x$gcc_cv_objdump = x; then
1989         AC_MSG_RESULT(not found)
1990 else
1991         AC_MSG_RESULT($gcc_cv_objdump)
1992 fi
1993
1994 # Figure out what assembler alignment features are present.
1995 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1996  [2,6,0],,
1997 [.balign 4
1998 .p2align 2],,
1999 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2000   [Define if your assembler supports .balign and .p2align.])])
2001
2002 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2003  [2,8,0],,
2004  [.p2align 4,,7],,
2005 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2006   [Define if your assembler supports specifying the maximum number
2007    of bytes to skip when using the GAS .p2align command.])])
2008
2009 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2010  [2,8,0],,
2011  [.literal16],,
2012 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2013   [Define if your assembler supports .literal16.])])
2014
2015 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2016  [elf,2,9,0],,
2017  [conftest_label1: .word 0
2018 .subsection -1
2019 conftest_label2: .word 0
2020 .previous],
2021  [if test x$gcc_cv_nm != x; then
2022     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2023     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2024     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2025     then :
2026     else gcc_cv_as_subsection_m1=yes
2027     fi
2028     rm -f conftest.nm1 conftest.nm2
2029   fi],
2030  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2031   [Define if your assembler supports .subsection and .subsection -1 starts
2032    emitting at the beginning of your section.])])
2033
2034 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2035  [2,2,0],,
2036  [      .weak foobar],,
2037 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2038
2039 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2040  [2,17,0],,
2041  [      .weakref foobar, barfnot],,
2042 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2043
2044 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2045  [2,15,91],,
2046  [      .SPACE $TEXT$
2047         .NSUBSPA $CODE$,COMDAT],,
2048 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2049
2050 # .hidden needs to be supported in both the assembler and the linker,
2051 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2052 # This is irritatingly difficult to feature test for; we have to check the
2053 # date string after the version number.  If we've got an in-tree
2054 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2055 # to be safe.
2056 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2057 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2058  [elf,2,13,0],,
2059 [       .hidden foobar
2060 foobar:])
2061
2062 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2063 [if test $in_tree_ld = yes ; then
2064   gcc_cv_ld_hidden=no
2065   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2066      && test $in_tree_ld_is_elf = yes; then
2067      gcc_cv_ld_hidden=yes
2068   fi
2069 else
2070   gcc_cv_ld_hidden=yes
2071   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2072   if echo "$ld_ver" | grep GNU > /dev/null; then
2073 changequote(,)dnl
2074     ld_vers=`echo $ld_ver | sed -n \
2075         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2076     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2077     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2078     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2079     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2080     if test 0"$ld_date" -lt 20020404; then
2081       if test -n "$ld_date"; then
2082         # If there was date string, but was earlier than 2002-04-04, fail
2083         gcc_cv_ld_hidden=no
2084       elif test -z "$ld_vers"; then
2085         # If there was no date string nor ld version number, something is wrong
2086         gcc_cv_ld_hidden=no
2087       else
2088         test -z "$ld_vers_patch" && ld_vers_patch=0
2089         if test "$ld_vers_major" -lt 2; then
2090           gcc_cv_ld_hidden=no
2091         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2092           gcc_cv_ld_hidden="no"
2093         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2094           gcc_cv_ld_hidden=no
2095         fi
2096       fi
2097 changequote([,])dnl
2098     fi
2099   else
2100     case "${target}" in
2101       hppa64*-*-hpux* | ia64*-*-hpux*)
2102         gcc_cv_ld_hidden=yes
2103         ;;
2104       *)
2105         gcc_cv_ld_hidden=no
2106         ;;
2107     esac
2108   fi
2109 fi])
2110 libgcc_visibility=no
2111 AC_SUBST(libgcc_visibility)
2112 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2113 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2114   libgcc_visibility=yes
2115   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2116   [Define if your assembler and linker support .hidden.])
2117 fi
2118
2119 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2120 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2121   [elf,2,11,0],,
2122 [       .data
2123         .uleb128 L2 - L1
2124 L1:
2125         .uleb128 1280
2126         .sleb128 -1010
2127 L2:],
2128  [# GAS versions before 2.11 do not support uleb128,
2129   # despite appearing to.
2130   # ??? There exists an elf-specific test that will crash
2131   # the assembler.  Perhaps it's better to figure out whether
2132   # arbitrary sections are supported and try the test.
2133   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2134   if echo "$as_ver" | grep GNU > /dev/null; then
2135 changequote(,)dnl
2136     as_vers=`echo $as_ver | sed -n \
2137         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2138     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2139     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2140 changequote([,])dnl
2141     if test $as_major -eq 2 && test $as_minor -lt 11
2142     then :
2143     else gcc_cv_as_leb128=yes
2144     fi
2145   fi],
2146   [AC_DEFINE(HAVE_AS_LEB128, 1,
2147     [Define if your assembler supports .sleb128 and .uleb128.])])
2148
2149 # GAS versions up to and including 2.11.0 may mis-optimize
2150 # .eh_frame data.
2151 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2152   [elf,2,12,0],,
2153 [       .text
2154 .LFB1:
2155         .4byte  0
2156 .L1:
2157         .4byte  0
2158 .LFE1:
2159         .section        .eh_frame,"aw",@progbits
2160 __FRAME_BEGIN__:
2161         .4byte  .LECIE1-.LSCIE1
2162 .LSCIE1:
2163         .4byte  0x0
2164         .byte   0x1
2165         .ascii "z\0"
2166         .byte   0x1
2167         .byte   0x78
2168         .byte   0x1a
2169         .byte   0x0
2170         .byte   0x4
2171         .4byte  1
2172         .p2align 1
2173 .LECIE1:
2174 .LSFDE1:
2175         .4byte  .LEFDE1-.LASFDE1
2176 .LASFDE1:
2177         .4byte  .LASFDE1-__FRAME_BEGIN__
2178         .4byte  .LFB1
2179         .4byte  .LFE1-.LFB1
2180         .byte   0x4
2181         .4byte  .LFE1-.LFB1
2182         .byte   0x4
2183         .4byte  .L1-.LFB1
2184 .LEFDE1:],
2185 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2186 cat > conftest.lit <<EOF
2187  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2188  0010 01000000 12000000 18000000 00000000  ................
2189  0020 08000000 04080000 0044               .........D      @&t@
2190 EOF
2191 cat > conftest.big <<EOF
2192  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2193  0010 00000001 00000012 00000018 00000000  ................
2194  0020 00000008 04000000 0844               .........D      @&t@
2195 EOF
2196   # If the assembler didn't choke, and we can objdump,
2197   # and we got the correct data, then succeed.
2198   # The text in the here-document typically retains its unix-style line
2199   # endings, while the output of objdump will use host line endings.
2200   # Therefore, use diff -b for the comparisons.
2201   if test x$gcc_cv_objdump != x \
2202   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2203      | tail -3 > conftest.got \
2204   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2205     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2206   then
2207     gcc_cv_as_eh_frame=yes
2208   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2209     gcc_cv_as_eh_frame=buggy
2210   else
2211     # Uh oh, what do we do now?
2212     gcc_cv_as_eh_frame=no
2213   fi])
2214
2215 if test $gcc_cv_as_eh_frame = buggy; then
2216   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2217   [Define if your assembler mis-optimizes .eh_frame data.])
2218 fi
2219
2220 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2221  [elf,2,12,0], [--fatal-warnings],
2222  [.section .rodata.str, "aMS", @progbits, 1])
2223 if test $gcc_cv_as_shf_merge = no; then
2224   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2225     [elf,2,12,0], [--fatal-warnings],
2226     [.section .rodata.str, "aMS", %progbits, 1])
2227 fi
2228 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2229   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2230 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2231
2232 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2233  [elf,2,16,0], [--fatal-warnings],
2234  [.section .text,"axG",@progbits,.foo,comdat])
2235 if test $gcc_cv_as_comdat_group = yes; then
2236   gcc_cv_as_comdat_group_percent=no
2237 else
2238  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2239    [elf,2,16,0], [--fatal-warnings],
2240    [.section .text,"axG",%progbits,.foo,comdat])
2241 fi
2242 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2243   comdat_group=yes
2244   if test 0"$ld_date" -lt 20050308; then
2245     if test -n "$ld_date"; then
2246       # If there was date string, but was earlier than 2005-03-08, fail
2247       comdat_group=no
2248     elif test "$ld_vers_major" -lt 2; then
2249       comdat_group=no
2250     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2251       comdat_group=no
2252     fi
2253   fi
2254 else
2255   # assume linkers other than GNU ld don't support COMDAT group
2256   comdat_group=no
2257 fi
2258 if test $comdat_group = no; then
2259   gcc_cv_as_comdat_group=no
2260   gcc_cv_as_comdat_group_percent=no
2261 fi
2262 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2263   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2264 [Define 0/1 if your assembler and linker support COMDAT groups.])
2265
2266 # Thread-local storage - the check is heavily parametrized.
2267 conftest_s=
2268 tls_first_major=
2269 tls_first_minor=
2270 tls_as_opt=
2271 case "$target" in
2272 changequote(,)dnl
2273   alpha*-*-*)
2274     conftest_s='
2275         .section ".tdata","awT",@progbits
2276 foo:    .long   25
2277         .text
2278         ldq     $27,__tls_get_addr($29)         !literal!1
2279         lda     $16,foo($29)                    !tlsgd!1
2280         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2281         ldq     $27,__tls_get_addr($29)         !literal!2
2282         lda     $16,foo($29)                    !tlsldm!2
2283         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2284         ldq     $1,foo($29)                     !gotdtprel
2285         ldah    $2,foo($29)                     !dtprelhi
2286         lda     $3,foo($2)                      !dtprello
2287         lda     $4,foo($29)                     !dtprel
2288         ldq     $1,foo($29)                     !gottprel
2289         ldah    $2,foo($29)                     !tprelhi
2290         lda     $3,foo($2)                      !tprello
2291         lda     $4,foo($29)                     !tprel'
2292         tls_first_major=2
2293         tls_first_minor=13
2294         tls_as_opt=--fatal-warnings
2295         ;;
2296   frv*-*-*)
2297     conftest_s='
2298         .section ".tdata","awT",@progbits
2299 x:      .long   25
2300         .text
2301         call    #gettlsoff(x)'
2302         tls_first_major=2
2303         tls_first_minor=14
2304         ;;
2305   hppa*-*-linux*)
2306     conftest_s='
2307 t1:     .reg    %r20
2308 t2:     .reg    %r21
2309 gp:     .reg    %r19
2310         .section ".tdata","awT",@progbits
2311 foo:    .long   25
2312         .text
2313         .align  4
2314         addil LT%foo-$tls_gdidx$,gp
2315         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2316         b __tls_get_addr
2317         nop
2318         addil LT%foo-$tls_ldidx$,gp
2319         b __tls_get_addr
2320         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2321         addil LR%foo-$tls_dtpoff$,%ret0
2322         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2323         mfctl %cr27,%t1
2324         addil LT%foo-$tls_ieoff$,gp
2325         ldw RT%foo-$tls_ieoff$(%r1),%t2
2326         add %t1,%t2,%t3
2327         mfctl %cr27,%t1
2328         addil LR%foo-$tls_leoff$,%t1
2329         ldo RR%foo-$tls_leoff$(%r1),%t2'
2330         tls_first_major=2
2331         tls_first_minor=15
2332         tls_as_opt=--fatal-warnings
2333         ;;
2334   arm*-*-*)
2335     conftest_s='
2336         .section ".tdata","awT",%progbits
2337 foo:    .long   25
2338         .text
2339 .word foo(gottpoff)
2340 .word foo(tpoff)
2341 .word foo(tlsgd)
2342 .word foo(tlsldm)
2343 .word foo(tlsldo)'
2344         tls_first_major=2
2345         tls_first_minor=17
2346         ;;
2347   i[34567]86-*-*)
2348     conftest_s='
2349         .section ".tdata","awT",@progbits
2350 foo:    .long   25
2351         .text
2352         movl    %gs:0, %eax
2353         leal    foo@TLSGD(,%ebx,1), %eax
2354         leal    foo@TLSLDM(%ebx), %eax
2355         leal    foo@DTPOFF(%eax), %edx
2356         movl    foo@GOTTPOFF(%ebx), %eax
2357         subl    foo@GOTTPOFF(%ebx), %eax
2358         addl    foo@GOTNTPOFF(%ebx), %eax
2359         movl    foo@INDNTPOFF, %eax
2360         movl    $foo@TPOFF, %eax
2361         subl    $foo@TPOFF, %eax
2362         leal    foo@NTPOFF(%ecx), %eax'
2363         tls_first_major=2
2364         tls_first_minor=14
2365         tls_as_opt=--fatal-warnings
2366         ;;
2367   x86_64-*-*)
2368     conftest_s='
2369         .section ".tdata","awT",@progbits
2370 foo:    .long   25
2371         .text
2372         movq    %fs:0, %rax
2373         leaq    foo@TLSGD(%rip), %rdi
2374         leaq    foo@TLSLD(%rip), %rdi
2375         leaq    foo@DTPOFF(%rax), %rdx
2376         movq    foo@GOTTPOFF(%rip), %rax
2377         movq    $foo@TPOFF, %rax'
2378         tls_first_major=2
2379         tls_first_minor=14
2380         tls_as_opt=--fatal-warnings
2381         ;;
2382   ia64-*-*)
2383     conftest_s='
2384         .section ".tdata","awT",@progbits
2385 foo:    data8   25
2386         .text
2387         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2388         addl    r17 = @ltoff(@dtprel(foo#)), gp
2389         addl    r18 = @ltoff(@tprel(foo#)), gp
2390         addl    r19 = @dtprel(foo#), gp
2391         adds    r21 = @dtprel(foo#), r13
2392         movl    r23 = @dtprel(foo#)
2393         addl    r20 = @tprel(foo#), gp
2394         adds    r22 = @tprel(foo#), r13
2395         movl    r24 = @tprel(foo#)'
2396         tls_first_major=2
2397         tls_first_minor=13
2398         tls_as_opt=--fatal-warnings
2399         ;;
2400   mips*-*-*)
2401     conftest_s='
2402         .section .tdata,"awT",@progbits
2403 x:
2404         .word 2
2405         .text
2406         addiu $4, $28, %tlsgd(x)
2407         addiu $4, $28, %tlsldm(x)
2408         lui $4, %dtprel_hi(x)
2409         addiu $4, $4, %dtprel_lo(x)
2410         lw $4, %gottprel(x)($28)
2411         lui $4, %tprel_hi(x)
2412         addiu $4, $4, %tprel_lo(x)'
2413         tls_first_major=2
2414         tls_first_minor=16
2415         tls_as_opt='-32 --fatal-warnings'
2416         ;;
2417   powerpc-*-*)
2418     conftest_s='
2419         .section ".tdata","awT",@progbits
2420         .align 2
2421 ld0:    .space 4
2422 ld1:    .space 4
2423 x1:     .space 4
2424 x2:     .space 4
2425 x3:     .space 4
2426         .text
2427         addi 3,31,ld0@got@tlsgd
2428         bl __tls_get_addr
2429         addi 3,31,x1@got@tlsld
2430         bl __tls_get_addr
2431         addi 9,3,x1@dtprel
2432         addis 9,3,x2@dtprel@ha
2433         addi 9,9,x2@dtprel@l
2434         lwz 9,x3@got@tprel(31)
2435         add 9,9,x@tls
2436         addi 9,2,x1@tprel
2437         addis 9,2,x2@tprel@ha
2438         addi 9,9,x2@tprel@l'
2439         tls_first_major=2
2440         tls_first_minor=14
2441         tls_as_opt="-a32 --fatal-warnings"
2442         ;;
2443   powerpc64-*-*)
2444     conftest_s='
2445         .section ".tdata","awT",@progbits
2446         .align 3
2447 ld0:    .space 8
2448 ld1:    .space 8
2449 x1:     .space 8
2450 x2:     .space 8
2451 x3:     .space 8
2452         .text
2453         addi 3,2,ld0@got@tlsgd
2454         bl .__tls_get_addr
2455         nop
2456         addi 3,2,ld1@toc
2457         bl .__tls_get_addr
2458         nop
2459         addi 3,2,x1@got@tlsld
2460         bl .__tls_get_addr
2461         nop
2462         addi 9,3,x1@dtprel
2463         bl .__tls_get_addr
2464         nop
2465         addis 9,3,x2@dtprel@ha
2466         addi 9,9,x2@dtprel@l
2467         bl .__tls_get_addr
2468         nop
2469         ld 9,x3@got@dtprel(2)
2470         add 9,9,3
2471         bl .__tls_get_addr
2472         nop'
2473         tls_first_major=2
2474         tls_first_minor=14
2475         tls_as_opt="-a64 --fatal-warnings"
2476         ;;
2477   s390-*-*)
2478     conftest_s='
2479         .section ".tdata","awT",@progbits
2480 foo:    .long   25
2481         .text
2482         .long   foo@TLSGD
2483         .long   foo@TLSLDM
2484         .long   foo@DTPOFF
2485         .long   foo@NTPOFF
2486         .long   foo@GOTNTPOFF
2487         .long   foo@INDNTPOFF
2488         l       %r1,foo@GOTNTPOFF(%r12)
2489         l       %r1,0(%r1):tls_load:foo
2490         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2491         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2492         tls_first_major=2
2493         tls_first_minor=14
2494         tls_as_opt="-m31 --fatal-warnings"
2495         ;;
2496   s390x-*-*)
2497     conftest_s='
2498         .section ".tdata","awT",@progbits
2499 foo:    .long   25
2500         .text
2501         .quad   foo@TLSGD
2502         .quad   foo@TLSLDM
2503         .quad   foo@DTPOFF
2504         .quad   foo@NTPOFF
2505         .quad   foo@GOTNTPOFF
2506         lg      %r1,foo@GOTNTPOFF(%r12)
2507         larl    %r1,foo@INDNTPOFF
2508         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2509         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2510         tls_first_major=2
2511         tls_first_minor=14
2512         tls_as_opt="-m64 -Aesame --fatal-warnings"
2513         ;;
2514   sh-*-* | sh[34]-*-*)
2515     conftest_s='
2516         .section ".tdata","awT",@progbits
2517 foo:    .long   25
2518         .text
2519         .long   foo@TLSGD
2520         .long   foo@TLSLDM
2521         .long   foo@DTPOFF
2522         .long   foo@GOTTPOFF
2523         .long   foo@TPOFF'
2524         tls_first_major=2
2525         tls_first_minor=13
2526         tls_as_opt=--fatal-warnings
2527         ;;
2528   sparc*-*-*)
2529     case "$target" in
2530       sparc*-sun-solaris2.[56789]*)
2531         # TLS was introduced in the Solaris 9 4/04 release but
2532         # we do not enable it by default on Solaris 9 either.
2533         if test "x$enable_tls" = xyes ; then
2534           on_solaris=yes
2535         else
2536           enable_tls=no;
2537         fi
2538         ;;
2539       sparc*-sun-solaris2.*)
2540         on_solaris=yes
2541         ;;
2542       *)
2543         on_solaris=no
2544         ;;
2545     esac
2546     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2547       conftest_s='
2548         .section ".tdata",#alloc,#write,#tls
2549 foo:    .long   25
2550         .text
2551         sethi   %tgd_hi22(foo), %o0
2552         add     %o0, %tgd_lo10(foo), %o1
2553         add     %l7, %o1, %o0, %tgd_add(foo)
2554         call    __tls_get_addr, %tgd_call(foo)
2555         sethi   %tldm_hi22(foo), %l1
2556         add     %l1, %tldm_lo10(foo), %l2
2557         add     %l7, %l2, %o0, %tldm_add(foo)
2558         call    __tls_get_addr, %tldm_call(foo)
2559         sethi   %tldo_hix22(foo), %l3
2560         xor     %l3, %tldo_lox10(foo), %l4
2561         add     %o0, %l4, %l5, %tldo_add(foo)
2562         sethi   %tie_hi22(foo), %o3
2563         add     %o3, %tie_lo10(foo), %o3
2564         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2565         add     %g7, %o2, %o4, %tie_add(foo)
2566         sethi   %tle_hix22(foo), %l1
2567         xor     %l1, %tle_lox10(foo), %o5
2568         ld      [%g7 + %o5], %o1'
2569         tls_first_major=0
2570         tls_first_minor=0
2571     else
2572       conftest_s='
2573         .section ".tdata","awT",@progbits
2574 foo:    .long   25
2575         .text
2576         sethi   %tgd_hi22(foo), %o0
2577         add     %o0, %tgd_lo10(foo), %o1
2578         add     %l7, %o1, %o0, %tgd_add(foo)
2579         call    __tls_get_addr, %tgd_call(foo)
2580         sethi   %tldm_hi22(foo), %l1
2581         add     %l1, %tldm_lo10(foo), %l2
2582         add     %l7, %l2, %o0, %tldm_add(foo)
2583         call    __tls_get_addr, %tldm_call(foo)
2584         sethi   %tldo_hix22(foo), %l3
2585         xor     %l3, %tldo_lox10(foo), %l4
2586         add     %o0, %l4, %l5, %tldo_add(foo)
2587         sethi   %tie_hi22(foo), %o3
2588         add     %o3, %tie_lo10(foo), %o3
2589         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2590         add     %g7, %o2, %o4, %tie_add(foo)
2591         sethi   %tle_hix22(foo), %l1
2592         xor     %l1, %tle_lox10(foo), %o5
2593         ld      [%g7 + %o5], %o1'
2594         tls_first_major=2
2595         tls_first_minor=14
2596         tls_as_opt="-32 --fatal-warnings"
2597       fi
2598         ;;
2599 changequote([,])dnl
2600 esac
2601 set_have_as_tls=no
2602 if test "x$enable_tls" = xno ; then
2603   : # TLS explicitly disabled.
2604 elif test "x$enable_tls" = xyes ; then
2605   set_have_as_tls=yes # TLS explicitly enabled.
2606 elif test -z "$tls_first_major"; then
2607   : # If we don't have a check, assume no support.
2608 else
2609   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2610   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2611   [set_have_as_tls=yes])
2612 fi
2613 if test $set_have_as_tls = yes ; then
2614   AC_DEFINE(HAVE_AS_TLS, 1,
2615             [Define if your assembler supports thread-local storage.])
2616 fi
2617
2618 # Target-specific assembler checks.
2619
2620 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2621 gcc_cv_ld_static_dynamic=no
2622 if test $in_tree_ld = yes ; then
2623   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2624     gcc_cv_ld_static_dynamic=yes
2625   fi
2626 elif test x$gcc_cv_ld != x; then
2627         # Check if linker supports -Bstatic/-Bdynamic option
2628         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2629           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2630                 gcc_cv_ld_static_dynamic=yes
2631         fi
2632 fi
2633 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2634         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2635 [Define if your linker supports -Bstatic/-Bdynamic option.])
2636 fi
2637 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2638
2639 if test x"$demangler_in_ld" = xyes; then
2640   AC_MSG_CHECKING(linker --demangle support)
2641   gcc_cv_ld_demangle=no
2642   if test $in_tree_ld = yes; then
2643     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2644       gcc_cv_ld_demangle=yes
2645     fi
2646   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2647     # Check if the GNU linker supports --demangle option
2648     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2649       gcc_cv_ld_demangle=yes
2650     fi
2651   fi
2652   if test x"$gcc_cv_ld_demangle" = xyes; then
2653     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2654 [Define if your linker supports --demangle option.])
2655   fi
2656   AC_MSG_RESULT($gcc_cv_ld_demangle)
2657 fi
2658
2659 case "$target" in
2660   # All TARGET_ABI_OSF targets.
2661   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2662     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2663         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2664 [       .set nomacro
2665         .text
2666         extbl   $3, $2, $3      !lituse_bytoff!1
2667         ldq     $2, a($29)      !literal!1
2668         ldq     $4, b($29)      !literal!2
2669         ldq_u   $3, 0($2)       !lituse_base!1
2670         ldq     $27, f($29)     !literal!5
2671         jsr     $26, ($27), f   !lituse_jsr!5
2672         ldah    $29, 0($26)     !gpdisp!3
2673         lda     $0, c($29)      !gprel
2674         ldah    $1, d($29)      !gprelhigh
2675         lda     $1, d($1)       !gprellow
2676         lda     $29, 0($29)     !gpdisp!3],,
2677     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2678   [Define if your assembler supports explicit relocations.])])
2679     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2680         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2681 [       .set nomacro
2682         .text
2683         ldq     $27, a($29)     !literal!1
2684         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2685     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2686   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2687     ;;
2688
2689   cris-*-*)
2690     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2691       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2692       [-no-mul-bug-abort], [.text],,
2693       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2694                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2695     ;;
2696
2697   sparc*-*-*)
2698     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2699       [.register %g2, #scratch],,
2700       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2701                 [Define if your assembler supports .register.])])
2702
2703     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2704       [-relax], [.text],,
2705       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2706                 [Define if your assembler supports -relax option.])])
2707
2708     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2709       gcc_cv_as_sparc_ua_pcrel,,
2710       [-K PIC],
2711 [.text
2712 foo:
2713         nop
2714 .data
2715 .align 4
2716 .byte 0
2717 .uaword %r_disp32(foo)],
2718       [if test x$gcc_cv_ld != x \
2719        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2720          gcc_cv_as_sparc_ua_pcrel=yes
2721        fi
2722        rm -f conftest],
2723       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2724                 [Define if your assembler and linker support unaligned PC relative relocs.])
2725
2726       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2727         gcc_cv_as_sparc_ua_pcrel_hidden,,
2728         [-K PIC],
2729 [.data
2730 .align 4
2731 .byte 0x31
2732 .uaword %r_disp32(foo)
2733 .byte 0x32, 0x33, 0x34
2734 .global foo
2735 .hidden foo
2736 foo:
2737 .skip 4],
2738         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2739          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2740          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2741             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2742             if $gcc_cv_objdump -R conftest 2> /dev/null \
2743                | grep 'DISP32' > /dev/null 2>&1; then
2744                 :
2745             else
2746                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2747             fi
2748          fi
2749          rm -f conftest],
2750          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2751                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2752     ]) # unaligned pcrel relocs
2753
2754     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2755       gcc_cv_as_sparc_offsetable_lo10,,
2756       [-xarch=v9],
2757 [.text
2758         or %g1, %lo(ab) + 12, %g1
2759         or %g1, %lo(ab + 12), %g1],
2760       [if test x$gcc_cv_objdump != x \
2761        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2762           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2763          gcc_cv_as_sparc_offsetable_lo10=yes
2764        fi],
2765        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2766                  [Define if your assembler supports offsetable %lo().])])
2767     ;;
2768
2769 changequote(,)dnl
2770   i[34567]86-*-* | x86_64-*-*)
2771 changequote([,])dnl
2772     case $target_os in
2773       cygwin* | pe | mingw32*)
2774         # Used for DWARF 2 in PE
2775         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2776           gcc_cv_as_ix86_pe_secrel32,
2777           [2,15,91],,
2778 [.text
2779 foo:    nop
2780 .data
2781         .secrel32 foo],
2782           [if test x$gcc_cv_ld != x \
2783            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2784              gcc_cv_as_ix86_pe_secrel32=yes
2785            fi
2786            rm -f conftest],
2787           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2788             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2789         ;;
2790     esac
2791
2792     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2793        gcc_cv_as_ix86_filds_fists,
2794       [2,9,0],, [filds mem; fists mem],,
2795       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2796         [Define if your assembler uses the new HImode fild and fist notation.])])
2797
2798     gcc_GAS_CHECK_FEATURE([cmov syntax],
2799       gcc_cv_as_ix86_cmov_sun_syntax,,,
2800       [cmovl.l %edx, %eax],,
2801       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2802         [Define if your assembler supports the Sun syntax for cmov.])])
2803
2804     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2805       gcc_cv_as_ix86_ffreep,,,
2806       [ffreep %st(1)],,
2807       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2808         [Define if your assembler supports the ffreep mnemonic.])])
2809
2810     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2811       gcc_cv_as_ix86_sahf,,,
2812       [sahf],,
2813       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2814         [Define if your assembler supports the sahf mnemonic.])])
2815
2816     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2817       gcc_cv_as_ix86_diff_sect_delta,,,
2818       [.section .rodata
2819 .L1:
2820         .long .L2-.L1
2821         .long .L3-.L1
2822         .text
2823 .L3:    nop
2824 .L2:    nop],,
2825       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2826         [Define if your assembler supports the subtraction of symbols in different sections.])])
2827
2828     # This one is used unconditionally by i386.[ch]; it is to be defined
2829     # to 1 if the feature is present, 0 otherwise.
2830     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2831         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2832 [       .text
2833 .L0:
2834         nop
2835         .data
2836         .long .L0@GOTOFF])
2837     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2838       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2839       [Define true if the assembler supports '.long foo@GOTOFF'.])
2840     ;;
2841
2842   ia64*-*-*)
2843     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2844         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2845 [       .text
2846         addl r15 = @ltoffx(x#), gp
2847         ;;
2848         ld8.mov r16 = [[r15]], x#],,
2849     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2850           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2851
2852     ;;
2853
2854   powerpc*-*-*)
2855     case $target in
2856       *-*-aix*) conftest_s='    .machine "pwr5"
2857         .csect .text[[PR]]
2858         mfcr 3,128';;
2859       *-*-darwin*)
2860         gcc_GAS_CHECK_FEATURE([.machine directive support],
2861           gcc_cv_as_machine_directive,,,
2862           [     .machine ppc7400])
2863         if test x$gcc_cv_as_machine_directive != xyes; then
2864           echo "*** This target requires an assembler supporting \".machine\"" >&2
2865           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2866           test x$build = x$target && exit 1
2867         fi
2868         conftest_s='    .text
2869         mfcr r3,128';;
2870       *) conftest_s='   .machine power4
2871         .text
2872         mfcr 3,128';;
2873     esac
2874
2875     gcc_GAS_CHECK_FEATURE([mfcr field support],
2876       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2877       [$conftest_s],,
2878       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2879           [Define if your assembler supports mfcr field.])])
2880
2881     case $target in
2882       *-*-aix*) conftest_s='    .machine "pwr5"
2883         .csect .text[[PR]]
2884         popcntb 3,3';;
2885       *) conftest_s='   .machine power5
2886         .text
2887         popcntb 3,3';;
2888     esac
2889
2890     gcc_GAS_CHECK_FEATURE([popcntb support],
2891       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2892       [$conftest_s],,
2893       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2894           [Define if your assembler supports popcntb field.])])
2895
2896     case $target in
2897       *-*-aix*) conftest_s='    .machine "pwr5x"
2898         .csect .text[[PR]]
2899         frin 1,1';;
2900       *) conftest_s='   .machine power5
2901         .text
2902         frin 1,1';;
2903     esac
2904
2905     gcc_GAS_CHECK_FEATURE([fp round support],
2906       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2907       [$conftest_s],,
2908       [AC_DEFINE(HAVE_AS_FPRND, 1,
2909           [Define if your assembler supports fprnd.])])
2910
2911     case $target in
2912       *-*-aix*) conftest_s='    .machine "pwr6"
2913         .csect .text[[PR]]
2914         mffgpr 1,3';;
2915       *) conftest_s='   .machine power6
2916         .text
2917         mffgpr 1,3';;
2918     esac
2919
2920     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2921       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2922       [$conftest_s],,
2923       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2924           [Define if your assembler supports mffgpr and mftgpr.])])
2925
2926     case $target in
2927       *-*-aix*) conftest_s='    .csect .text[[PR]]
2928 LCF..0:
2929         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2930       *-*-darwin*)
2931         conftest_s='    .text
2932 LCF0:
2933         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2934       *) conftest_s='   .text
2935 .LCF0:
2936         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2937     esac
2938
2939     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2940       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2941       [$conftest_s],,
2942       [AC_DEFINE(HAVE_AS_REL16, 1,
2943           [Define if your assembler supports R_PPC_REL16 relocs.])])
2944
2945     case $target in
2946       *-*-aix*) conftest_s='    .machine "pwr6"
2947         .csect .text[[PR]]
2948         cmpb 3,4,5';;
2949       *) conftest_s='   .machine power6
2950         .text
2951         cmpb 3,4,5';;
2952     esac
2953
2954     gcc_GAS_CHECK_FEATURE([compare bytes support],
2955       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2956       [$conftest_s],,
2957       [AC_DEFINE(HAVE_AS_CMPB, 1,
2958           [Define if your assembler supports cmpb.])])
2959
2960     case $target in
2961       *-*-aix*) conftest_s='    .machine "pwr6"
2962         .csect .text[[PR]]
2963         dadd 1,2,3';;
2964       *) conftest_s='   .machine power6
2965         .text
2966         dadd 1,2,3';;
2967     esac
2968
2969     gcc_GAS_CHECK_FEATURE([decimal float support],
2970       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2971       [$conftest_s],,
2972       [AC_DEFINE(HAVE_AS_DFP, 1,
2973           [Define if your assembler supports DFP instructions.])])
2974
2975     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2976       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
2977       [.gnu_attribute 4,1],,
2978       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2979           [Define if your assembler supports .gnu_attribute.])])
2980     ;;
2981
2982   mips*-*-*)
2983     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2984       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2985 [       lw $4,%gp_rel(foo)($4)],,
2986       [if test x$target_cpu_default = x
2987        then target_cpu_default=MASK_EXPLICIT_RELOCS
2988        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2989        fi])
2990     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2991       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2992       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2993                  [Define if the assembler understands -mno-shared.])])
2994
2995     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2996       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
2997       [.gnu_attribute 4,1],,
2998       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2999           [Define if your assembler supports .gnu_attribute.])])
3000
3001     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3002       gcc_cv_as_mips_dtprelword, [2,18,0],,
3003       [.section .tdata,"awT",@progbits
3004 x:
3005         .word 2
3006         .text
3007         .dtprelword x+0x8000],,
3008       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3009           [Define if your assembler supports .dtprelword.])])
3010     ;;
3011 esac
3012
3013 # Mips and HP-UX need the GNU assembler.
3014 # Linux on IA64 might be able to use the Intel assembler.
3015
3016 case "$target" in
3017   mips*-*-* | *-*-hpux* )
3018     if test x$gas_flag = xyes \
3019        || test x"$host" != x"$build" \
3020        || test ! -x "$gcc_cv_as" \
3021        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3022       :
3023     else
3024       echo "*** This configuration requires the GNU assembler" >&2
3025       exit 1
3026     fi
3027     ;;
3028 esac
3029
3030 # ??? Not all targets support dwarf2 debug_line, even within a version
3031 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3032 # info to the output file.  So, as supported targets are added to gas 2.11,
3033 # add some instruction here to (also) show we expect this might work.
3034 # ??? Once 2.11 is released, probably need to add first known working
3035 # version to the per-target configury.
3036 case "$target" in
3037   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3038   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3039   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3040     insn="nop"
3041     ;;
3042   ia64*-*-* | s390*-*-*)
3043     insn="nop 0"
3044     ;;
3045   mmix-*-*)
3046     insn="swym 0"
3047     ;;
3048 esac
3049 if test x"$insn" != x; then
3050  conftest_s="\
3051         .file 1 \"conftest.s\"
3052         .loc 1 3 0
3053         $insn"
3054  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3055   gcc_cv_as_dwarf2_debug_line,
3056   [elf,2,11,0],, [$conftest_s],
3057   [if test x$gcc_cv_objdump != x \
3058    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3059       | grep debug_line > /dev/null 2>&1; then
3060      gcc_cv_as_dwarf2_debug_line=yes
3061    fi])
3062
3063 # The .debug_line file table must be in the exact order that
3064 # we specified the files, since these indices are also used
3065 # by DW_AT_decl_file.  Approximate this test by testing if
3066 # the assembler bitches if the same index is assigned twice.
3067  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3068   gcc_cv_as_dwarf2_file_buggy,,,
3069 [       .file 1 "foo.s"
3070         .file 1 "bar.s"])
3071
3072  if test $gcc_cv_as_dwarf2_debug_line = yes \
3073  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3074         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3075   [Define if your assembler supports dwarf2 .file/.loc directives,
3076    and preserves file table indices exactly as given.])
3077  fi
3078
3079  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3080   gcc_cv_as_gdwarf2_flag,
3081   [elf,2,11,0], [--gdwarf2], [$insn],,
3082   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3083 [Define if your assembler supports the --gdwarf2 option.])])
3084
3085  gcc_GAS_CHECK_FEATURE([--gstabs option],
3086   gcc_cv_as_gstabs_flag,
3087   [elf,2,11,0], [--gstabs], [$insn],
3088   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3089    # and warns about it, but still exits successfully.  So check for
3090    # this.
3091    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3092    then :
3093    else gcc_cv_as_gstabs_flag=yes
3094    fi],
3095   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3096 [Define if your assembler supports the --gstabs option.])])
3097
3098  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3099   gcc_cv_as_debug_prefix_map_flag,
3100   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3101   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3102 [Define if your assembler supports the --debug-prefix-map option.])])
3103 fi
3104
3105 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3106  [gcc_cv_as_line_zero],
3107  [gcc_cv_as_line_zero=no
3108   if test $in_tree_gas = yes; then
3109     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3110   elif test "x$gcc_cv_as" != x; then
3111     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3112     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3113        test "x`cat conftest.out`" = x
3114     then
3115       gcc_cv_as_line_zero=yes
3116     else
3117       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3118       cat conftest.s >&AS_MESSAGE_LOG_FD
3119       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3120       cat conftest.out >&AS_MESSAGE_LOG_FD
3121     fi
3122     rm -f conftest.o conftest.s conftest.out
3123   fi])
3124 if test "x$gcc_cv_as_line_zero" = xyes; then
3125   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3126 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3127 fi
3128
3129 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3130 gcc_cv_ld_ro_rw_mix=unknown
3131 if test $in_tree_ld = yes ; then
3132   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3133      && test $in_tree_ld_is_elf = yes; then
3134     gcc_cv_ld_ro_rw_mix=read-write
3135   fi
3136 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3137   echo '.section myfoosect, "a"' > conftest1.s
3138   echo '.section myfoosect, "aw"' > conftest2.s
3139   echo '.byte 1' >> conftest2.s
3140   echo '.section myfoosect, "a"' > conftest3.s
3141   echo '.byte 0' >> conftest3.s
3142   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3143      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3144      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3145      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3146         conftest2.o conftest3.o > /dev/null 2>&1; then
3147     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3148                          | sed -e '/myfoosect/!d' -e N`
3149     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3150       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3151         gcc_cv_ld_ro_rw_mix=read-only
3152       else
3153         gcc_cv_ld_ro_rw_mix=read-write
3154       fi
3155     fi
3156   fi
3157 changequote(,)dnl
3158   rm -f conftest.* conftest[123].*
3159 changequote([,])dnl
3160 fi
3161 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3162         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3163   [Define if your linker links a mix of read-only
3164    and read-write sections into a read-write section.])
3165 fi
3166 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3167
3168 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3169 gcc_cv_ld_eh_frame_hdr=no
3170 if test $in_tree_ld = yes ; then
3171   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3172      && test $in_tree_ld_is_elf = yes; then
3173     gcc_cv_ld_eh_frame_hdr=yes
3174   fi
3175 elif test x$gcc_cv_ld != x; then
3176         # Check if linker supports --eh-frame-hdr option
3177         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3178                 gcc_cv_ld_eh_frame_hdr=yes
3179         fi
3180 fi
3181 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3182 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3183         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3184 [Define if your linker supports --eh-frame-hdr option.])
3185 fi
3186 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3187
3188 AC_MSG_CHECKING(linker position independent executable support)
3189 gcc_cv_ld_pie=no
3190 if test $in_tree_ld = yes ; then
3191   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3192      && test $in_tree_ld_is_elf = yes; then
3193     gcc_cv_ld_pie=yes
3194   fi
3195 elif test x$gcc_cv_ld != x; then
3196         # Check if linker supports -pie option
3197         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3198                 gcc_cv_ld_pie=yes
3199         fi
3200 fi
3201 if test x"$gcc_cv_ld_pie" = xyes; then
3202         AC_DEFINE(HAVE_LD_PIE, 1,
3203 [Define if your linker supports -pie option.])
3204 fi
3205 AC_MSG_RESULT($gcc_cv_ld_pie)
3206
3207 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3208 gcc_cv_ld_eh_gc_sections=no
3209 if test $in_tree_ld = yes ; then
3210   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3211      && test $in_tree_ld_is_elf = yes; then
3212     gcc_cv_ld_eh_gc_sections=yes
3213   fi
3214 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3215   cat > conftest.s <<EOF
3216         .section        .text
3217 .globl _start
3218         .type _start, @function
3219 _start:
3220         .long foo
3221         .size _start, .-_start
3222         .section        .text.foo,"ax",@progbits
3223         .type foo, @function
3224 foo:
3225         .long 0
3226         .size foo, .-foo
3227         .section        .gcc_except_table.foo,"a",@progbits
3228 .L0:
3229         .long 0
3230         .section        .eh_frame,"a",@progbits
3231         .long .L0
3232 EOF
3233   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3234     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3235          | grep "gc-sections option ignored" > /dev/null; then
3236       gcc_cv_ld_eh_gc_sections=no
3237     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3238       gcc_cv_ld_eh_gc_sections=yes
3239       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3240       if test x$gcc_cv_as_comdat_group != xyes; then
3241         gcc_cv_ld_eh_gc_sections=no
3242         cat > conftest.s <<EOF
3243         .section        .text
3244 .globl _start
3245         .type _start, @function
3246 _start:
3247         .long foo
3248         .size _start, .-_start
3249         .section        .gnu.linkonce.t.foo,"ax",@progbits
3250         .type foo, @function
3251 foo:
3252         .long 0
3253         .size foo, .-foo
3254         .section        .gcc_except_table.foo,"a",@progbits
3255 .L0:
3256         .long 0
3257         .section        .eh_frame,"a",@progbits
3258         .long .L0
3259 EOF
3260         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3261           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3262                | grep "gc-sections option ignored" > /dev/null; then
3263             gcc_cv_ld_eh_gc_sections=no
3264           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3265             gcc_cv_ld_eh_gc_sections=yes
3266           fi
3267         fi
3268       fi
3269     fi
3270   fi
3271   rm -f conftest.s conftest.o conftest
3272 fi
3273 case "$target" in
3274   hppa*-*-linux*)
3275     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3276     gcc_cv_ld_eh_gc_sections=no
3277     ;;
3278 esac
3279 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3280         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3281   [Define if your linker supports garbage collection of
3282    sections in presence of EH frames.])
3283 fi
3284 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3285
3286 # --------
3287 # UNSORTED
3288 # --------
3289
3290 AC_CACHE_CHECK(linker --as-needed support,
3291 gcc_cv_ld_as_needed,
3292 [gcc_cv_ld_as_needed=no
3293 if test $in_tree_ld = yes ; then
3294   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3295      && test $in_tree_ld_is_elf = yes; then
3296     gcc_cv_ld_as_needed=yes
3297   fi
3298 elif test x$gcc_cv_ld != x; then
3299         # Check if linker supports --as-needed and --no-as-needed options
3300         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3301                 gcc_cv_ld_as_needed=yes
3302         fi
3303 fi
3304 ])
3305 if test x"$gcc_cv_ld_as_needed" = xyes; then
3306         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3307 [Define if your linker supports --as-needed and --no-as-needed options.])
3308 fi
3309
3310 case "$target:$tm_file" in
3311   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3312     AC_CACHE_CHECK(linker support for omitting dot symbols,
3313     gcc_cv_ld_no_dot_syms,
3314     [gcc_cv_ld_no_dot_syms=no
3315     if test $in_tree_ld = yes ; then
3316       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3317         gcc_cv_ld_no_dot_syms=yes
3318       fi
3319     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3320       cat > conftest1.s <<EOF
3321         .text
3322         bl .foo
3323 EOF
3324       cat > conftest2.s <<EOF
3325         .section ".opd","aw"
3326         .align 3
3327         .globl foo
3328         .type foo,@function
3329 foo:
3330         .quad .LEfoo,.TOC.@tocbase,0
3331         .text
3332 .LEfoo:
3333         blr
3334         .size foo,.-.LEfoo
3335 EOF
3336       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3337          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3338          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3339         gcc_cv_ld_no_dot_syms=yes
3340       fi
3341       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3342     fi
3343     ])
3344     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3345       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3346     [Define if your PowerPC64 linker only needs function descriptor syms.])
3347     fi
3348     ;;
3349 esac
3350
3351 AC_CACHE_CHECK(linker --sysroot support,
3352   gcc_cv_ld_sysroot,
3353   [gcc_cv_ld_sysroot=no
3354   if test $in_tree_ld = yes ; then
3355       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3356         gcc_cv_ld_sysroot=yes
3357       fi
3358   elif test x$gcc_cv_ld != x; then
3359     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3360       gcc_cv_ld_sysroot=yes
3361     fi
3362   fi])
3363 if test x"$gcc_cv_ld_sysroot" = xyes; then
3364   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3365   [Define if your linker supports --sysroot.])
3366 fi
3367
3368 if test x$with_sysroot = x && test x$host = x$target \
3369    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3370    && test "$prefix" != "NONE"; then
3371   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3372 [Define to PREFIX/include if cpp should also search that directory.])
3373 fi
3374
3375 # Test for stack protector support in target C library.
3376 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3377       gcc_cv_libc_provides_ssp,
3378       [gcc_cv_libc_provides_ssp=no
3379     case "$target" in
3380        *-*-linux*)
3381       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3382         if test "x$with_sysroot" = x; then
3383           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3384         elif test "x$with_build_sysroot" != "x"; then
3385           glibc_header_dir="${with_build_sysroot}/usr/include"
3386         elif test "x$with_sysroot" = xyes; then
3387           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3388         else
3389           glibc_header_dir="${with_sysroot}/usr/include"
3390         fi
3391       else
3392         glibc_header_dir=/usr/include
3393       fi
3394       # glibc 2.4 and later provides __stack_chk_fail and
3395       # either __stack_chk_guard, or TLS access to stack guard canary.
3396       if test -f $glibc_header_dir/features.h \
3397          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3398             $glibc_header_dir/features.h > /dev/null; then
3399         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3400            $glibc_header_dir/features.h > /dev/null; then
3401           gcc_cv_libc_provides_ssp=yes
3402         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3403              $glibc_header_dir/features.h > /dev/null \
3404              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3405              $glibc_header_dir/features.h > /dev/null; then
3406           gcc_cv_libc_provides_ssp=yes
3407         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3408              $glibc_header_dir/features.h > /dev/null && \
3409              test -f $glibc_header_dir/bits/uClibc_config.h && \
3410              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3411              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3412           gcc_cv_libc_provides_ssp=yes
3413         fi
3414       fi
3415         ;;
3416        *-*-darwin*)
3417          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3418            [echo "no __stack_chk_fail on this target"])
3419         ;;
3420   *) gcc_cv_libc_provides_ssp=no ;;
3421     esac])
3422
3423 if test x$gcc_cv_libc_provides_ssp = xyes; then
3424   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3425             [Define if your target C library provides stack protector support])
3426 fi
3427
3428 # Check if TFmode long double should be used by default or not.
3429 # Some glibc targets used DFmode long double, but with glibc 2.4
3430 # and later they can use TFmode.
3431 case "$target" in
3432   powerpc*-*-linux* | \
3433   powerpc*-*-gnu* | \
3434   sparc*-*-linux* | \
3435   s390*-*-linux* | \
3436   alpha*-*-linux*)
3437     AC_ARG_WITH(long-double-128,
3438 [  --with-long-double-128  Use 128-bit long double by default.],
3439       gcc_cv_target_ldbl128="$with_long_double_128",
3440       [gcc_cv_target_ldbl128=no
3441       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3442         if test "x$with_sysroot" = x; then
3443           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3444         elif test "x$with_build_sysroot" != "x"; then
3445           glibc_header_dir="${with_build_sysroot}/usr/include"
3446         elif test "x$with_sysroot" = xyes; then
3447           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3448         else
3449           glibc_header_dir="${with_sysroot}/usr/include"
3450         fi
3451       else
3452         glibc_header_dir=/usr/include
3453       fi
3454 changequote(,)dnl
3455       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3456         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3457       && gcc_cv_target_ldbl128=yes
3458 changequote([,])dnl
3459       ])
3460     ;;
3461 esac
3462 if test x$gcc_cv_target_ldbl128 = xyes; then
3463   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3464             [Define if TFmode long double should be the default])
3465 fi
3466
3467 # Find out what GC implementation we want, or may, use.
3468 AC_ARG_WITH(gc,
3469 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3470                           with the compiler],
3471 [case "$withval" in
3472   page)
3473     GGC=ggc-$withval
3474     ;;
3475   zone)
3476     GGC=ggc-$withval
3477     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3478     ;;
3479   *)
3480     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3481     ;;
3482 esac],
3483 [GGC=ggc-page])
3484 AC_SUBST(GGC)
3485 echo "Using $GGC for garbage collection."
3486
3487 # Use the system's zlib library.
3488 zlibdir=-L../zlib
3489 zlibinc="-I\$(srcdir)/../zlib"
3490 AC_ARG_WITH(system-zlib,
3491 [  --with-system-zlib      use installed libz],
3492 zlibdir=
3493 zlibinc=
3494 )
3495 AC_SUBST(zlibdir)
3496 AC_SUBST(zlibinc)
3497
3498 dnl Very limited version of automake's enable-maintainer-mode
3499
3500 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3501   dnl maintainer-mode is disabled by default
3502   AC_ARG_ENABLE(maintainer-mode,
3503 [  --enable-maintainer-mode
3504                           enable make rules and dependencies not useful
3505                           (and sometimes confusing) to the casual installer],
3506       maintainer_mode=$enableval,
3507       maintainer_mode=no)
3508
3509 AC_MSG_RESULT($maintainer_mode)
3510
3511 if test "$maintainer_mode" = "yes"; then
3512   MAINT=''
3513 else
3514   MAINT='#'
3515 fi
3516 AC_SUBST(MAINT)dnl
3517
3518 # --------------
3519 # Language hooks
3520 # --------------
3521
3522 # Make empty files to contain the specs and options for each language.
3523 # Then add #include lines to for a compiler that has specs and/or options.
3524
3525 subdirs=
3526 lang_opt_files=
3527 lang_specs_files=
3528 lang_tree_files=
3529 # These (without "all_") are set in each config-lang.in.
3530 # `language' must be a single word so is spelled singularly.
3531 all_languages=
3532 all_compilers=
3533 all_outputs='Makefile gccbug libada-mk'
3534 # List of language makefile fragments.
3535 all_lang_makefrags=
3536 # List of language subdirectory makefiles.  Deprecated.
3537 all_lang_makefiles=
3538 # Additional files for gengtype
3539 all_gtfiles="$target_gtfiles"
3540
3541 # These are the languages that are set in --enable-languages,
3542 # and are available in the GCC tree.
3543 all_selected_languages=
3544
3545 # Add the language fragments.
3546 # Languages are added via two mechanisms.  Some information must be
3547 # recorded in makefile variables, these are defined in config-lang.in.
3548 # We accumulate them and plug them into the main Makefile.
3549 # The other mechanism is a set of hooks for each of the main targets
3550 # like `clean', `install', etc.
3551
3552 language_hooks="Make-hooks"
3553
3554 for lang in ${srcdir}/*/config-lang.in
3555 do
3556 changequote(,)dnl
3557         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3558
3559         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3560         if test "x$lang_alias" = x
3561         then
3562               echo "$lang doesn't set \$language." 1>&2
3563               exit 1
3564         fi
3565         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3566         subdirs="$subdirs $subdir"
3567         case ",$enable_languages," in
3568         *,$lang_alias,*)
3569             all_selected_languages="$all_selected_languages $lang_alias"
3570             if test -f $srcdir/$subdir/lang-specs.h; then
3571                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3572             fi
3573             ;;
3574         esac
3575 changequote([,])dnl
3576
3577         language=
3578         boot_language=
3579         compilers=
3580         outputs=
3581         gtfiles=
3582         subdir_requires=
3583         . ${srcdir}/$subdir/config-lang.in
3584         if test "x$language" = x
3585         then
3586                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3587                 exit 1
3588         fi
3589
3590         ok=:
3591         case ",$enable_languages," in
3592                 *,$lang_alias,*) ;;
3593                 *)
3594                         for i in $subdir_requires; do
3595                                 test -f "${srcdir}/$i/config-lang.in" && continue
3596                                 ok=false
3597                                 break
3598                         done
3599                 ;;
3600         esac
3601         $ok || continue
3602
3603         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3604         if test -f $srcdir/$subdir/lang.opt; then
3605             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3606         fi
3607         if test -f $srcdir/$subdir/$subdir-tree.def; then
3608             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3609         fi
3610         if test -f ${srcdir}/$subdir/Makefile.in
3611                 then all_lang_makefiles="$subdir/Makefile"
3612         fi
3613         all_languages="$all_languages $language"
3614         all_compilers="$all_compilers $compilers"
3615         all_outputs="$all_outputs $outputs"
3616         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3617 done
3618
3619 # Pick up gtfiles for c
3620 gtfiles=
3621 . ${srcdir}/c-config-lang.in
3622 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3623
3624 check_languages=
3625 for language in $all_selected_languages
3626 do
3627         check_languages="$check_languages check-$language"
3628 done
3629
3630 # We link each language in with a set of hooks, reached indirectly via
3631 # lang.${target}.  Only do so for selected languages.
3632
3633 rm -f Make-hooks
3634 touch Make-hooks
3635 target_list="all.cross start.encap rest.encap tags \
3636         install-common install-man install-info install-pdf dvi pdf \
3637         html uninstall info man srcextra srcman srcinfo \
3638         mostlyclean clean distclean maintainer-clean"
3639
3640 for t in $target_list
3641 do
3642         x=
3643         for lang in $all_selected_languages
3644         do
3645                 x="$x $lang.$t"
3646         done
3647         echo "lang.$t: $x" >> Make-hooks
3648 done
3649
3650 # --------
3651 # UNSORTED
3652 # --------
3653
3654 # Create .gdbinit.
3655
3656 echo "dir ." > .gdbinit
3657 echo "dir ${srcdir}" >> .gdbinit
3658 if test x$gdb_needs_out_file_path = xyes
3659 then
3660         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3661 fi
3662 if test "x$subdirs" != x; then
3663         for s in $subdirs
3664         do
3665                 echo "dir ${srcdir}/$s" >> .gdbinit
3666         done
3667 fi
3668 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3669
3670 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3671 AC_SUBST(gcc_tooldir)
3672 AC_SUBST(dollar)
3673
3674 # Find a directory in which to install a shared libgcc.
3675
3676 AC_ARG_ENABLE(version-specific-runtime-libs,
3677 [  --enable-version-specific-runtime-libs
3678                           specify that runtime libraries should be
3679                           installed in a compiler-specific directory])
3680
3681 AC_ARG_WITH(slibdir,
3682 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3683 slibdir="$with_slibdir",
3684 if test "${enable_version_specific_runtime_libs+set}" = set; then
3685   slibdir='$(libsubdir)'
3686 elif test "$host" != "$target"; then
3687   slibdir='$(build_tooldir)/lib'
3688 else
3689   slibdir='$(libdir)'
3690 fi)
3691 AC_SUBST(slibdir)
3692
3693 objdir=`${PWDCMD-pwd}`
3694 AC_SUBST(objdir)
3695
3696 AC_ARG_WITH(datarootdir,
3697 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3698 datarootdir="\${prefix}/$with_datarootdir",
3699 datarootdir='$(prefix)/share')
3700 AC_SUBST(datarootdir)
3701
3702 AC_ARG_WITH(docdir,
3703 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3704 docdir="\${prefix}/$with_docdir",
3705 docdir='$(datarootdir)')
3706 AC_SUBST(docdir)
3707
3708 AC_ARG_WITH(htmldir,
3709 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3710 htmldir="\${prefix}/$with_htmldir",
3711 htmldir='$(docdir)')
3712 AC_SUBST(htmldir)
3713
3714 # Substitute configuration variables
3715 AC_SUBST(subdirs)
3716 AC_SUBST(srcdir)
3717 AC_SUBST(all_compilers)
3718 AC_SUBST(all_gtfiles)
3719 AC_SUBST(all_lang_makefrags)
3720 AC_SUBST(all_lang_makefiles)
3721 AC_SUBST(all_languages)
3722 AC_SUBST(all_selected_languages)
3723 AC_SUBST(build_exeext)
3724 AC_SUBST(build_install_headers_dir)
3725 AC_SUBST(build_xm_file_list)
3726 AC_SUBST(build_xm_include_list)
3727 AC_SUBST(build_xm_defines)
3728 AC_SUBST(build_file_translate)
3729 AC_SUBST(check_languages)
3730 AC_SUBST(cpp_install_dir)
3731 AC_SUBST(xmake_file)
3732 AC_SUBST(tmake_file)
3733 AC_SUBST(extra_gcc_objs)
3734 AC_SUBST(extra_headers_list)
3735 AC_SUBST(extra_objs)
3736 AC_SUBST(extra_parts)
3737 AC_SUBST(extra_passes)
3738 AC_SUBST(extra_programs)
3739 AC_SUBST(float_h_file)
3740 AC_SUBST(gcc_config_arguments)
3741 AC_SUBST(gcc_gxx_include_dir)
3742 AC_SUBST(host_exeext)
3743 AC_SUBST(host_xm_file_list)
3744 AC_SUBST(host_xm_include_list)
3745 AC_SUBST(host_xm_defines)
3746 AC_SUBST(out_host_hook_obj)
3747 AC_SUBST(install)
3748 AC_SUBST(lang_opt_files)
3749 AC_SUBST(lang_specs_files)
3750 AC_SUBST(lang_tree_files)
3751 AC_SUBST(local_prefix)
3752 AC_SUBST(md_file)
3753 AC_SUBST(objc_boehm_gc)
3754 AC_SUBST(out_file)
3755 AC_SUBST(out_object_file)
3756 AC_SUBST(thread_file)
3757 AC_SUBST(tm_file_list)
3758 AC_SUBST(tm_include_list)
3759 AC_SUBST(tm_defines)
3760 AC_SUBST(tm_p_file_list)
3761 AC_SUBST(tm_p_include_list)
3762 AC_SUBST(xm_file_list)
3763 AC_SUBST(xm_include_list)
3764 AC_SUBST(xm_defines)
3765 AC_SUBST(c_target_objs)
3766 AC_SUBST(cxx_target_objs)
3767 AC_SUBST(target_cpu_default)
3768
3769 AC_SUBST_FILE(language_hooks)
3770
3771 # Echo link setup.
3772 if test x${build} = x${host} ; then
3773   if test x${host} = x${target} ; then
3774     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3775   else
3776     echo "Links are now set up to build a cross-compiler" 1>&2
3777     echo " from ${host} to ${target}." 1>&2
3778   fi
3779 else
3780   if test x${host} = x${target} ; then
3781     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3782     echo " for ${target}." 1>&2
3783   else
3784     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3785     echo " from ${host} to ${target}." 1>&2
3786   fi
3787 fi
3788
3789 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3790 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3791
3792 # Configure the subdirectories
3793 # AC_CONFIG_SUBDIRS($subdirs)
3794
3795 # Create the Makefile
3796 # and configure language subdirectories
3797 AC_CONFIG_FILES($all_outputs)
3798
3799 AC_CONFIG_COMMANDS([default],
3800 [
3801 case ${CONFIG_HEADERS} in
3802   *auto-host.h:config.in*)
3803   echo > cstamp-h ;;
3804 esac
3805 # Make sure all the subdirs exist.
3806 for d in $subdirs doc build
3807 do
3808     test -d $d || mkdir $d
3809 done
3810 ],
3811 [subdirs='$subdirs'])
3812 AC_OUTPUT