gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144 changequote(<<, >>)dnl
 145     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/$libstdcxx_incdir"
 146 changequote([, ])dnl
 147   fi
 148 fi
 149
 150 AC_ARG_WITH(cpp_install_dir,
 151 [  --with-cpp-install-dir=DIR
 152                           install the user visible C preprocessor in DIR
 153                           (relative to PREFIX) as well as PREFIX/bin],
 154 [if test x$withval = xyes; then
 155   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 156 elif test x$withval != xno; then
 157   cpp_install_dir=$withval
 158 fi])
 159
 160 # We would like to our source tree to be readonly.  However when releases or
 161 # pre-releases are generated, the flex/bison generated files as well as the
 162 # various formats of manuals need to be included along with the rest of the
 163 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 164 # just that.
 165
 166 AC_MSG_CHECKING([whether to place generated files in the source directory])
 167   dnl generated-files-in-srcdir is disabled by default
 168   AC_ARG_ENABLE(generated-files-in-srcdir,
 169 [  --enable-generated-files-in-srcdir
 170                           put copies of generated files in source dir
 171                           intended for creating source tarballs for users
 172                           without texinfo bison or flex.],
 173       generated_files_in_srcdir=$enableval,
 174       generated_files_in_srcdir=no)
 175
 176 AC_MSG_RESULT($generated_files_in_srcdir)
 177
 178 if test "$generated_files_in_srcdir" = "yes"; then
 179   GENINSRC=''
 180 else
 181   GENINSRC='#'
 182 fi
 183 AC_SUBST(GENINSRC)
 184
 185 # -------------------
 186 # Find default linker
 187 # -------------------
 188
 189 # With GNU ld
 190 AC_ARG_WITH(gnu-ld,
 191 [  --with-gnu-ld           arrange to work with GNU ld.],
 192 gnu_ld_flag="$with_gnu_ld",
 193 gnu_ld_flag=no)
 194
 195 # With pre-defined ld
 196 AC_ARG_WITH(ld,
 197 [  --with-ld               arrange to use the specified ld (full pathname)],
 198 DEFAULT_LINKER="$with_ld")
 199 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 200   if test ! -x "$DEFAULT_LINKER"; then
 201     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 202   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 203     gnu_ld_flag=yes
 204   fi
 205   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 206         [Define to enable the use of a default linker.])
 207 fi
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 AC_MSG_CHECKING([whether a default assembler was specified])
 250 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 251   if test x"$gas_flag" = x"no"; then
 252     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 253   else
 254     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 255   fi
 256 else
 257   AC_MSG_RESULT(no)
 258 fi
 259
 260 # ---------------
 261 # Find C compiler
 262 # ---------------
 263
 264 # If a non-executable a.out is present (e.g. created by GNU as above even if
 265 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 266 # file, even when creating an executable, so an execution test fails.
 267 # Remove possible default executable files to avoid this.
 268 #
 269 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 270 # Autoconf includes it.
 271 rm -f a.out a.exe b.out
 272
 273 # Find the native compiler
 274 AC_PROG_CC
 275 AM_PROG_CC_C_O
 276 # autoconf is lame and doesn't give us any substitution variable for this.
 277 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 278   NO_MINUS_C_MINUS_O=yes
 279 else
 280   OUTPUT_OPTION='-o $@'
 281 fi
 282 AC_SUBST(NO_MINUS_C_MINUS_O)
 283 AC_SUBST(OUTPUT_OPTION)
 284
 285 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 286 # optimizations to be activated explicitly by the toplevel.
 287 case "$CC" in
 288   */prev-gcc/xgcc*) ;;
 289   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 290 esac
 291 AC_SUBST(CFLAGS)
 292
 293 # -------------------------
 294 # Check C compiler features
 295 # -------------------------
 296
 297 AC_PROG_CPP
 298 AC_C_INLINE
 299
 300 # sizeof(char) is 1 by definition.
 301 AC_CHECK_SIZEOF(void *)
 302 AC_CHECK_SIZEOF(short)
 303 AC_CHECK_SIZEOF(int)
 304 AC_CHECK_SIZEOF(long)
 305 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 306 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 307
 308 # ---------------------
 309 # Warnings and checking
 310 # ---------------------
 311
 312 # Check $CC warning features (if it's GCC).
 313 # We want to use -pedantic, but we don't want warnings about
 314 # * 'long long'
 315 # * variadic macros
 316 # * overlong strings
 317 # So, we only use -pedantic if we can disable those warnings.
 318
 319 AC_CACHE_CHECK(
 320   [whether ${CC} accepts -Wno-long-long],
 321   [ac_cv_prog_cc_w_no_long_long],
 322   [save_CFLAGS="$CFLAGS"
 323   CFLAGS="-Wno-long-long"
 324   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 325                     [ac_cv_prog_cc_w_no_long_long=yes],
 326                     [ac_cv_prog_cc_w_no_long_long=no])
 327   CFLAGS="$save_CFLAGS"
 328   ])
 329
 330 AC_CACHE_CHECK(
 331   [whether ${CC} accepts -Wno-variadic-macros],
 332   [ac_cv_prog_cc_w_no_variadic_macros],
 333   [save_CFLAGS="$CFLAGS"
 334   CFLAGS="-Wno-variadic-macros"
 335   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 336                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 337                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 338   CFLAGS="$save_CFLAGS"
 339   ])
 340
 341 AC_CACHE_CHECK(
 342   [whether ${CC} accepts -Wno-overlength-strings],
 343   [ac_cv_prog_cc_w_no_overlength_strings],
 344   [save_CFLAGS="$CFLAGS"
 345   CFLAGS="-Wno-overlength-strings"
 346   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 347                     [ac_cv_prog_cc_w_no_overlength_strings=yes],
 348                     [ac_cv_prog_cc_w_no_overlength_strings=no])
 349   CFLAGS="$save_CFLAGS"
 350   ])
 351
 352 strict_warn=
 353 if test $ac_cv_prog_cc_w_no_long_long = yes \
 354    && test $ac_cv_prog_cc_w_no_variadic_macros = yes \
 355    && test $ac_cv_prog_cc_w_no_overlength_strings = yes ; then
 356   strict_warn="-pedantic -Wno-long-long -Wno-variadic-macros -Wno-overlength-strings"
 357 fi
 358
 359 # Add -Wold-style-definition if it's accepted
 360 AC_CACHE_CHECK(
 361   [whether ${CC} accepts -Wold-style-definition],
 362   [ac_cv_prog_cc_w_old_style_definition],
 363   [save_CFLAGS="$CFLAGS"
 364   CFLAGS="-Wold-style-definition"
 365   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 366                     [ac_cv_prog_cc_w_old_style_definition=yes],
 367                     [ac_cv_prog_cc_w_old_style_definition=no])
 368   CFLAGS="$save_CFLAGS"
 369   ])
 370 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 371   strict_warn="${strict_warn} -Wold-style-definition"
 372 fi
 373
 374 # Add -Wmissing-format-attribute if it's accepted
 375 AC_CACHE_CHECK(
 376   [whether ${CC} accepts -Wmissing-format-attribute],
 377   [ac_cv_prog_cc_w_missing_format_attribute],
 378   [save_CFLAGS="$CFLAGS"
 379   CFLAGS="-Wmissing-format-attribute"
 380   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 381                     [ac_cv_prog_cc_w_missing_format_attribute=yes],
 382                     [ac_cv_prog_cc_w_missing_format_attribute=no])
 383   CFLAGS="$save_CFLAGS"
 384   ])
 385 if test $ac_cv_prog_cc_w_missing_format_attribute = yes ; then
 386   strict_warn="${strict_warn} -Wmissing-format-attribute"
 387 fi
 388
 389 # Enable -Werror, period.
 390 AC_ARG_ENABLE(werror_always,
 391 [  --enable-werror-always         enable -Werror always], [],
 392 [enable_werror_always=no])
 393 if test x${enable_werror_always} = xyes ; then
 394   strict_warn="${strict_warn} -Werror"
 395 fi
 396 AC_SUBST(strict_warn)
 397
 398 # Get C++ compatibility warning flag, if supported.
 399 AC_CACHE_CHECK(
 400   [whether ${CC} accepts -Wc++-compat],
 401   [ac_cv_prog_cc_w_cxx_compat],
 402   [save_CFLAGS="$CFLAGS"
 403   CFLAGS="-Wc++-compat"
 404   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 405                     [ac_cv_prog_cc_w_cxx_compat=yes],
 406                     [ac_cv_prog_cc_w_cxx_compat=no])
 407   CFLAGS="$save_CFLAGS"
 408   ])
 409 if test x${ac_cv_prog_cc_w_cxx_compat} = xyes; then
 410   cxx_compat_warn="-Wc++-compat"
 411 fi
 412 AC_SUBST(cxx_compat_warn)
 413
 414
 415 # If the native compiler is GCC, we can enable warnings even in stage1.
 416 # That's useful for people building cross-compilers, or just running a
 417 # quick `make'.
 418 warn_cflags=
 419 if test "x$GCC" = "xyes"; then
 420   warn_cflags='$(GCC_WARN_CFLAGS)'
 421 fi
 422 AC_SUBST(warn_cflags)
 423
 424 # Enable expensive internal checks
 425 is_release=
 426 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 427   is_release=yes
 428 fi
 429
 430 AC_ARG_ENABLE(checking,
 431 [  --enable-checking[=LIST]
 432                           enable expensive run-time checks.  With LIST,
 433                           enable only specific categories of checks.
 434                           Categories are: yes,no,all,none,release.
 435                           Flags are: assert,fold,gc,gcac,misc,
 436                           rtlflag,rtl,runtime,tree,valgrind.],
 437 [ac_checking_flags="${enableval}"],[
 438 # Determine the default checks.
 439 if test x$is_release = x ; then
 440   ac_checking_flags=yes
 441 else
 442   ac_checking_flags=release
 443 fi])
 444 ac_assert_checking=1
 445 ac_checking=
 446 ac_fold_checking=
 447 ac_gc_checking=
 448 ac_gc_always_collect=
 449 ac_rtl_checking=
 450 ac_rtlflag_checking=
 451 ac_runtime_checking=1
 452 ac_tree_checking=
 453 ac_valgrind_checking=
 454 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 455 for check in $ac_checking_flags
 456 do
 457         case $check in
 458         # these set all the flags to specific states
 459         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 460                         ac_fold_checking= ; ac_gc_checking=1 ;
 461                         ac_gc_always_collect= ; ac_rtl_checking= ;
 462                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 463                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 464         no|none)        ac_assert_checking= ; ac_checking= ;
 465                         ac_fold_checking= ; ac_gc_checking= ;
 466                         ac_gc_always_collect= ; ac_rtl_checking= ;
 467                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 468                         ac_tree_checking= ; ac_valgrind_checking= ;;
 469         all)            ac_assert_checking=1 ; ac_checking=1 ;
 470                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 471                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 472                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 473                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 474         release)        ac_assert_checking=1 ; ac_checking= ;
 475                         ac_fold_checking= ; ac_gc_checking= ;
 476                         ac_gc_always_collect= ; ac_rtl_checking= ;
 477                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 478                         ac_tree_checking= ; ac_valgrind_checking= ;;
 479         # these enable particular checks
 480         assert)         ac_assert_checking=1 ;;
 481         fold)           ac_fold_checking=1 ;;
 482         gc)             ac_gc_checking=1 ;;
 483         gcac)           ac_gc_always_collect=1 ;;
 484         misc)           ac_checking=1 ;;
 485         rtl)            ac_rtl_checking=1 ;;
 486         rtlflag)        ac_rtlflag_checking=1 ;;
 487         runtime)        ac_runtime_checking=1 ;;
 488         tree)           ac_tree_checking=1 ;;
 489         valgrind)       ac_valgrind_checking=1 ;;
 490         *)      AC_MSG_ERROR(unknown check category $check) ;;
 491         esac
 492 done
 493 IFS="$ac_save_IFS"
 494
 495 nocommon_flag=""
 496 if test x$ac_checking != x ; then
 497   AC_DEFINE(ENABLE_CHECKING, 1,
 498 [Define if you want more run-time sanity checks.  This one gets a grab
 499    bag of miscellaneous but relatively cheap checks.])
 500   nocommon_flag=-fno-common
 501 fi
 502 AC_SUBST(nocommon_flag)
 503 if test x$ac_assert_checking != x ; then
 504   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 505 [Define if you want assertions enabled.  This is a cheap check.])
 506 fi
 507 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 508 if test x$ac_runtime_checking != x ; then
 509   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 510 [Define if you want runtime assertions enabled.  This is a cheap check.])
 511 fi
 512 if test x$ac_tree_checking != x ; then
 513   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 514 [Define if you want all operations on trees (the basic data
 515    structure of the front ends) to be checked for dynamic type safety
 516    at runtime.  This is moderately expensive.  The tree browser debugging
 517    routines will also be enabled by this option.
 518    ])
 519   TREEBROWSER=tree-browser.o
 520 fi
 521 AC_SUBST(TREEBROWSER)
 522 if test x$ac_rtl_checking != x ; then
 523   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 524 [Define if you want all operations on RTL (the basic data structure
 525    of the optimizer and back end) to be checked for dynamic type safety
 526    at runtime.  This is quite expensive.])
 527 fi
 528 if test x$ac_rtlflag_checking != x ; then
 529   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 530 [Define if you want RTL flag accesses to be checked against the RTL
 531    codes that are supported for each access macro.  This is relatively
 532    cheap.])
 533 fi
 534 if test x$ac_gc_checking != x ; then
 535   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 536 [Define if you want the garbage collector to do object poisoning and
 537    other memory allocation checks.  This is quite expensive.])
 538 fi
 539 if test x$ac_gc_always_collect != x ; then
 540   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 541 [Define if you want the garbage collector to operate in maximally
 542    paranoid mode, validating the entire heap and collecting garbage at
 543    every opportunity.  This is extremely expensive.])
 544 fi
 545 if test x$ac_fold_checking != x ; then
 546   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 547 [Define if you want fold checked that it never destructs its argument.
 548    This is quite expensive.])
 549 fi
 550 valgrind_path_defines=
 551 valgrind_command=
 552
 553 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 554 dnl # an if statement.  This was the source of very frustrating bugs
 555 dnl # in converting to autoconf 2.5x!
 556 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 557
 558 if test x$ac_valgrind_checking != x ; then
 559   # It is certainly possible that there's valgrind but no valgrind.h.
 560   # GCC relies on making annotations so we must have both.
 561   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 562   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 563     [[#include <valgrind/memcheck.h>
 564 #ifndef VALGRIND_DISCARD
 565 #error VALGRIND_DISCARD not defined
 566 #endif]])],
 567   [gcc_cv_header_valgrind_memcheck_h=yes],
 568   [gcc_cv_header_valgrind_memcheck_h=no])
 569   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 570   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 571   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 572     [[#include <memcheck.h>
 573 #ifndef VALGRIND_DISCARD
 574 #error VALGRIND_DISCARD not defined
 575 #endif]])],
 576   [gcc_cv_header_memcheck_h=yes],
 577   [gcc_cv_header_memcheck_h=no])
 578   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 579   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 580         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 581   if test "x$valgrind_path" = "x" \
 582     || (test $have_valgrind_h = no \
 583         && test $gcc_cv_header_memcheck_h = no \
 584         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 585         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 586   fi
 587   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 588   valgrind_command="$valgrind_path -q"
 589   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 590 [Define if you want to run subprograms and generated programs
 591    through valgrind (a memory checker).  This is extremely expensive.])
 592   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 593     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 594         [Define if valgrind's valgrind/memcheck.h header is installed.])
 595   fi
 596   if test $gcc_cv_header_memcheck_h = yes; then
 597     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 598         [Define if valgrind's memcheck.h header is installed.])
 599   fi
 600 fi
 601 AC_SUBST(valgrind_path_defines)
 602 AC_SUBST(valgrind_command)
 603
 604 AC_ARG_ENABLE(mapped-location,
 605 [  --enable-mapped-location   location_t is fileline integer cookie],,
 606 enable_mapped_location=no)
 607
 608 if test "$enable_mapped_location" = yes ; then
 609   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 610 [Define if location_t is fileline integer cookie.])
 611 fi
 612
 613 # Enable code coverage collection
 614 AC_ARG_ENABLE(coverage,
 615 [  --enable-coverage[=LEVEL]
 616                           enable compiler's code coverage collection.
 617                           Use to measure compiler performance and locate
 618                           unused parts of the compiler. With LEVEL, specify
 619                           optimization. Values are opt, noopt,
 620                           default is noopt],
 621 [case "${enableval}" in
 622   yes|noopt)
 623     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 624     ;;
 625   opt)
 626     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 627     ;;
 628   no)
 629     # a.k.a. --disable-coverage
 630     coverage_flags=""
 631     ;;
 632   *)
 633     AC_MSG_ERROR(unknown coverage setting $enableval)
 634     ;;
 635 esac],
 636 [coverage_flags=""])
 637 AC_SUBST(coverage_flags)
 638
 639 AC_ARG_ENABLE(gather-detailed-mem-stats,
 640 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 641 [enable_gather_detailed_mem_stats=no])
 642 if test x$enable_gather_detailed_mem_stats = xyes ; then
 643   AC_DEFINE(GATHER_STATISTICS, 1,
 644         [Define to enable detailed memory allocation stats gathering.])
 645 fi
 646
 647 # -------------------------------
 648 # Miscenalleous configure options
 649 # -------------------------------
 650
 651 # With stabs
 652 AC_ARG_WITH(stabs,
 653 [  --with-stabs            arrange to use stabs instead of host debug format],
 654 stabs="$with_stabs",
 655 stabs=no)
 656
 657 # Determine whether or not multilibs are enabled.
 658 AC_ARG_ENABLE(multilib,
 659 [  --enable-multilib       enable library support for multiple ABIs],
 660 [], [enable_multilib=yes])
 661 AC_SUBST(enable_multilib)
 662
 663 # Enable __cxa_atexit for C++.
 664 AC_ARG_ENABLE(__cxa_atexit,
 665 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 666 [], [])
 667
 668 # Enable C extension for decimal float if target supports it.
 669 AC_ARG_ENABLE(decimal-float,
 670 [  --enable-decimal-float  enable decimal float extension to C],
 671 [
 672   if test x$enablevar = xyes ; then
 673     case $target in
 674     powerpc*-*-linux* | i?86*-*-linux*)
 675       enable_decimal_float=yes
 676       ;;
 677     *)
 678       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 679       enable_decimal_float=no
 680       ;;
 681     esac
 682   fi
 683 ], [enable_decimal_float=no])
 684
 685 AC_SUBST(enable_decimal_float)
 686
 687 dfp=`if test $enable_decimal_float = yes; then echo 1; else echo 0; fi`
 688 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 689 [Define to 1 to enable decimal float extension to C.])
 690
 691 # Enable threads
 692 # Pass with no value to take the default
 693 # Pass with a value to specify a thread package
 694 AC_ARG_ENABLE(threads,
 695 [  --enable-threads        enable thread usage for target GCC
 696   --enable-threads=LIB    use LIB thread package for target GCC],,
 697 [enable_threads=''])
 698
 699 AC_ARG_ENABLE(tls,
 700 [  --enable-tls            enable or disable generation of tls code
 701                           overriding the assembler check for tls support],
 702 [
 703   case $enable_tls in
 704     yes | no) ;;
 705     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 706 Valid choices are 'yes' and 'no'.]) ;;
 707   esac
 708 ], [enable_tls=''])
 709
 710 AC_ARG_ENABLE(objc-gc,
 711 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 712                           the GNU Objective-C runtime],
 713 if test x$enable_objc_gc = xno; then
 714         objc_boehm_gc=''
 715 else
 716         objc_boehm_gc=1
 717 fi,
 718 objc_boehm_gc='')
 719
 720 AC_ARG_WITH(dwarf2,
 721 [  --with-dwarf2           force the default debug format to be DWARF 2],
 722 dwarf2="$with_dwarf2",
 723 dwarf2=no)
 724
 725 AC_ARG_ENABLE(shared,
 726 [  --disable-shared        don't provide a shared libgcc],
 727 [
 728   case $enable_shared in
 729   yes | no) ;;
 730   *)
 731     enable_shared=no
 732     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 733     for pkg in $enableval; do
 734       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 735         enable_shared=yes
 736       fi
 737     done
 738     IFS="$ac_save_ifs"
 739     ;;
 740   esac
 741 ], [enable_shared=yes])
 742 AC_SUBST(enable_shared)
 743
 744 AC_ARG_WITH(build-sysroot,
 745   [  --with-build-sysroot=sysroot
 746                           use sysroot as the system root during the build])
 747
 748 AC_ARG_WITH(sysroot,
 749 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 750 [
 751  case ${with_sysroot} in
 752  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 753  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 754  esac
 755
 756  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 757  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 758
 759  if test "x$exec_prefix" = xNONE; then
 760   if test "x$prefix" = xNONE; then
 761    test_prefix=/usr/local
 762   else
 763    test_prefix=$prefix
 764   fi
 765  else
 766   test_prefix=$exec_prefix
 767  fi
 768  case ${TARGET_SYSTEM_ROOT} in
 769  "${test_prefix}"|"${test_prefix}/"*|\
 770  '${exec_prefix}'|'${exec_prefix}/'*)
 771    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 772    TARGET_SYSTEM_ROOT_DEFINE="$t"
 773    ;;
 774  esac
 775 ], [
 776  TARGET_SYSTEM_ROOT=
 777  TARGET_SYSTEM_ROOT_DEFINE=
 778  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 779 ])
 780 AC_SUBST(TARGET_SYSTEM_ROOT)
 781 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 782 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 783
 784 # Build with intermodule optimisations
 785 AC_ARG_ENABLE(intermodule,
 786 [  --enable-intermodule    build the compiler in one step],
 787 [case ${enable_intermodule} in
 788   yes) onestep="-onestep";;
 789   *) onestep="";;
 790 esac],
 791 [onestep=""])
 792 AC_SUBST(onestep)
 793
 794 # Sanity check enable_languages in case someone does not run the toplevel
 795 # configure # script.
 796 AC_ARG_ENABLE(languages,
 797 [  --enable-languages=LIST specify which front-ends to build],
 798 [case ,${enable_languages}, in
 799        ,,|,yes,)
 800                 # go safe -- we cannot be much sure without the toplevel
 801                 # configure's
 802                 # analysis of which target libs are present and usable
 803                 enable_languages=c
 804                 ;;
 805          *,all,*)
 806                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 807                 ;;
 808         *,c,*)
 809                 ;;
 810         *)
 811                 enable_languages=c,${enable_languages}
 812                 ;;
 813 esac],
 814 [enable_languages=c])
 815
 816 # Used by documentation targets
 817 AC_SUBST(datarootdir)
 818 AC_SUBST(docdir)
 819 AC_SUBST(htmldir)
 820
 821 # -------------------------
 822 # Checks for other programs
 823 # -------------------------
 824
 825 AC_PROG_MAKE_SET
 826
 827 # Find some useful tools
 828 AC_PROG_AWK
 829 # We need awk to create options.c and options.h.
 830 # Bail out if it's missing.
 831 case ${AWK} in
 832   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 833 esac
 834
 835 gcc_AC_PROG_LN_S
 836 ACX_PROG_LN($LN_S)
 837 AC_PROG_RANLIB
 838 case "${host}" in
 839 *-*-darwin*)
 840   # By default, the Darwin ranlib will not treat common symbols as
 841   # definitions when  building the archive table of contents.  Other
 842   # ranlibs do that; pass an option to the Darwin ranlib that makes
 843   # it behave similarly.
 844   ranlib_flags="-c"
 845   ;;
 846 *)
 847   ranlib_flags=""
 848 esac
 849 AC_SUBST(ranlib_flags)
 850
 851 gcc_AC_PROG_INSTALL
 852
 853 # See if cmp has --ignore-initial.
 854 gcc_AC_PROG_CMP_IGNORE_INITIAL
 855
 856 # See if we have the mktemp command.
 857 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 858
 859 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 860
 861 # See if makeinfo has been installed and is modern enough
 862 # that we can use it.
 863 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 864   [GNU texinfo.* \([0-9][0-9.]*\)],
 865   [4.[4-9]*])
 866 if test $gcc_cv_prog_makeinfo_modern = no; then
 867   MAKEINFO="$MISSING makeinfo"
 868   AC_MSG_WARN([
 869 *** Makeinfo is missing or too old.
 870 *** Info documentation will not be built.])
 871   BUILD_INFO=
 872 else
 873   BUILD_INFO=info
 874 fi
 875 AC_SUBST(BUILD_INFO)
 876
 877 # Is pod2man recent enough to regenerate manpages?
 878 AC_MSG_CHECKING([for recent Pod::Man])
 879 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 880   AC_MSG_RESULT(yes)
 881   GENERATED_MANPAGES=generated-manpages
 882 else
 883   AC_MSG_RESULT(no)
 884   GENERATED_MANPAGES=
 885 fi
 886 AC_SUBST(GENERATED_MANPAGES)
 887
 888 # How about lex?
 889 dnl Don't use AC_PROG_LEX; we insist on flex.
 890 dnl LEXLIB is not useful in gcc.
 891 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 892
 893 # Bison?
 894 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 895
 896 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 897 # check for build == host before using them.
 898
 899 # NM
 900 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 901   && test -d ../binutils ; then
 902   NM='$(objdir)/../binutils/nm-new'
 903 else
 904   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 905 fi
 906
 907 # AR
 908 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 909   && test -d ../binutils ; then
 910   AR='$(objdir)/../binutils/ar'
 911 else
 912   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 913 fi
 914
 915
 916 # --------------------
 917 # Checks for C headers
 918 # --------------------
 919
 920 AC_MSG_CHECKING(for GNU C library)
 921 AC_CACHE_VAL(gcc_cv_glibc,
 922 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 923   [[#include <features.h>]], [[
 924 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 925 #error Not a GNU C library system
 926 #endif]])],
 927   [gcc_cv_glibc=yes],
 928   [gcc_cv_glibc=no])])
 929 AC_MSG_RESULT($gcc_cv_glibc)
 930 if test $gcc_cv_glibc = yes; then
 931   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 932 fi
 933
 934 # Need to reject headers which give warnings, so that the -Werror bootstrap
 935 # works later. *sigh*  This needs to come before all header checks.
 936 AC_PROG_CPP_WERROR
 937
 938 AC_HEADER_STDC
 939 AC_HEADER_TIME
 940 ACX_HEADER_STRING
 941 AC_HEADER_SYS_WAIT
 942 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 943                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 944                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 945                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 946
 947 # Check for thread headers.
 948 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 949 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 950
 951 # These tests can't be done till we know if we have limits.h.
 952 gcc_AC_C_CHAR_BIT
 953 AC_C_BIGENDIAN
 954
 955 # --------
 956 # UNSORTED
 957 # --------
 958
 959
 960 # These libraries may be used by collect2.
 961 # We may need a special search path to get them linked.
 962 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 963 [save_LIBS="$LIBS"
 964 for libs in '' -lld -lmld \
 965                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 966                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 967 do
 968         LIBS="$libs"
 969         AC_TRY_LINK_FUNC(ldopen,
 970                 [gcc_cv_collect2_libs="$libs"; break])
 971 done
 972 LIBS="$save_LIBS"
 973 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 974 case $gcc_cv_collect2_libs in
 975         "none required")        ;;
 976         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 977 esac
 978 AC_SUBST(COLLECT2_LIBS)
 979
 980 # When building Ada code on Alpha, we need exc_resume which is usually in
 981 # -lexc.  So test for it.
 982 save_LIBS="$LIBS"
 983 LIBS=
 984 AC_SEARCH_LIBS(exc_resume, exc)
 985 GNAT_LIBEXC="$LIBS"
 986 LIBS="$save_LIBS"
 987 AC_SUBST(GNAT_LIBEXC)
 988
 989 # Some systems put ldexp and frexp in libm instead of libc; assume
 990 # they're both in the same place.  jcf-dump needs them.
 991 save_LIBS="$LIBS"
 992 LIBS=
 993 AC_SEARCH_LIBS(ldexp, m)
 994 LDEXP_LIB="$LIBS"
 995 LIBS="$save_LIBS"
 996 AC_SUBST(LDEXP_LIB)
 997
 998 # Use <inttypes.h> only if it exists,
 999 # doesn't clash with <sys/types.h>, and declares intmax_t.
1000 AC_MSG_CHECKING(for inttypes.h)
1001 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1002 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1003 [[#include <sys/types.h>
1004 #include <inttypes.h>]],
1005   [[intmax_t i = -1;]])],
1006   [gcc_cv_header_inttypes_h=yes],
1007   [gcc_cv_header_inttypes_h=no])])
1008 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1009 if test $gcc_cv_header_inttypes_h = yes; then
1010   AC_DEFINE(HAVE_INTTYPES_H, 1,
1011         [Define if you have a working <inttypes.h> header file.])
1012 fi
1013
1014 dnl Disabled until we have a complete test for buggy enum bitfields.
1015 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1016
1017 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1018   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1019   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1020   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1021   putchar_unlocked putc_unlocked)
1022 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1023         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1024         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1025         gcc_UNLOCKED_FUNCS)
1026
1027 if test x$ac_cv_func_mbstowcs = xyes; then
1028   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1029 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1030 int main()
1031 {
1032   mbstowcs(0, "", 0);
1033   return 0;
1034 }]])],
1035     [gcc_cv_func_mbstowcs_works=yes],
1036     [gcc_cv_func_mbstowcs_works=no],
1037     [gcc_cv_func_mbstowcs_works=yes])])
1038   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1039     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1040   [Define this macro if mbstowcs does not crash when its
1041    first argument is NULL.])
1042   fi
1043 fi
1044
1045 AC_CHECK_TYPE(ssize_t, int)
1046
1047 # Try to determine the array type of the second argument of getgroups
1048 # for the target system (int or gid_t).
1049 AC_TYPE_GETGROUPS
1050 if test "${target}" = "${build}"; then
1051   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1052 else
1053   case "${target}" in
1054         # This condition may need some tweaking.  It should include all
1055         # targets where the array type of the second argument of getgroups
1056         # is int and the type of gid_t is not equivalent to int.
1057         *-*-sunos* | *-*-ultrix*)
1058                 TARGET_GETGROUPS_T=int
1059                 ;;
1060         *)
1061                 TARGET_GETGROUPS_T=gid_t
1062                 ;;
1063   esac
1064 fi
1065 AC_SUBST(TARGET_GETGROUPS_T)
1066
1067 gcc_AC_FUNC_MMAP_BLACKLIST
1068
1069 case "${host}" in
1070 *-*-*vms*)
1071   # Under VMS, vfork works very differently than on Unix. The standard test
1072   # won't work, and it isn't easily adaptable. It makes more sense to
1073   # just force it.
1074   ac_cv_func_vfork_works=yes
1075   ;;
1076 esac
1077 AC_FUNC_FORK
1078
1079 AM_ICONV
1080 # Until we have in-tree GNU iconv:
1081 LIBICONV_DEP=
1082 AC_SUBST(LIBICONV_DEP)
1083
1084 AM_LC_MESSAGES
1085
1086 AM_LANGINFO_CODESET
1087
1088 # We will need to find libiberty.h and ansidecl.h
1089 saved_CFLAGS="$CFLAGS"
1090 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1091 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1092         strsignal strstr strverscmp \
1093         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1094         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1095 #include "ansidecl.h"
1096 #include "system.h"])
1097
1098 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1099 #include "ansidecl.h"
1100 #include "system.h"
1101 #ifdef HAVE_SYS_RESOURCE_H
1102 #include <sys/resource.h>
1103 #endif
1104 ])
1105
1106 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1107 #include "ansidecl.h"
1108 #include "system.h"
1109 #ifdef HAVE_SYS_RESOURCE_H
1110 #include <sys/resource.h>
1111 #endif
1112 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1113 [Define to \`long' if <sys/resource.h> doesn't define.])])
1114
1115 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1116 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1117 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1118 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1119 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1120 #include "ansidecl.h"
1121 #include "system.h"
1122 #ifdef HAVE_LDFCN_H
1123 #undef FREAD
1124 #undef FWRITE
1125 #include <ldfcn.h>
1126 #endif
1127 ])
1128
1129 gcc_AC_CHECK_DECLS(times, , ,[
1130 #include "ansidecl.h"
1131 #include "system.h"
1132 #ifdef HAVE_SYS_TIMES_H
1133 #include <sys/times.h>
1134 #endif
1135 ])
1136
1137 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1138 #include "ansidecl.h"
1139 #include "system.h"
1140 #include <signal.h>
1141 ])
1142
1143 # More time-related stuff.
1144 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1145 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1146 #include "ansidecl.h"
1147 #include "system.h"
1148 #ifdef HAVE_SYS_TIMES_H
1149 #include <sys/times.h>
1150 #endif
1151 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1152 if test $ac_cv_struct_tms = yes; then
1153   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1154   [Define if <sys/times.h> defines struct tms.])
1155 fi
1156
1157 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1158 # revisit after autoconf 2.50.
1159 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1160 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1161 #include "ansidecl.h"
1162 #include "system.h"
1163 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1164 if test $gcc_cv_type_clock_t = yes; then
1165   AC_DEFINE(HAVE_CLOCK_T, 1,
1166   [Define if <time.h> defines clock_t.])
1167 fi
1168
1169 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1170 CFLAGS="$saved_CFLAGS"
1171
1172 gcc_AC_INITFINI_ARRAY
1173
1174 # mkdir takes a single argument on some systems.
1175 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1176
1177 # File extensions
1178 manext='.1'
1179 objext='.o'
1180 AC_SUBST(manext)
1181 AC_SUBST(objext)
1182
1183 # With Setjmp/Longjmp based exception handling.
1184 AC_ARG_ENABLE(sjlj-exceptions,
1185 [  --enable-sjlj-exceptions
1186                           arrange to use setjmp/longjmp exception handling],
1187 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1188 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1189   [Define 0/1 to force the choice for exception handling model.])])
1190
1191 # For platforms with the unwind ABI which includes an unwind library,
1192 # libunwind, we can choose to use the system libunwind.
1193 AC_ARG_WITH(system-libunwind,
1194 [  --with-system-libunwind use installed libunwind])
1195
1196 # config.gcc also contains tests of with_system_libunwind.
1197 if test x$with_system_libunwind = xyes; then
1198         AC_DEFINE(HAVE_GETIPINFO, 1,
1199 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1200 fi
1201
1202 # --------------------------------------------------------
1203 # Build, host, and target specific configuration fragments
1204 # --------------------------------------------------------
1205
1206 # Collect build-machine-specific information.
1207 . ${srcdir}/config.build
1208
1209 # Collect host-machine-specific information.
1210 . ${srcdir}/config.host
1211
1212 target_gtfiles=
1213
1214 # Collect target-machine-specific information.
1215 . ${srcdir}/config.gcc
1216
1217 extra_objs="${host_extra_objs} ${extra_objs}"
1218 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1219
1220 # Default the target-machine variables that were not explicitly set.
1221 if test x"$tm_file" = x
1222 then tm_file=$cpu_type/$cpu_type.h; fi
1223
1224 if test x"$extra_headers" = x
1225 then extra_headers=; fi
1226
1227 if test x$md_file = x
1228 then md_file=$cpu_type/$cpu_type.md; fi
1229
1230 if test x$out_file = x
1231 then out_file=$cpu_type/$cpu_type.c; fi
1232
1233 if test x"$tmake_file" = x
1234 then tmake_file=$cpu_type/t-$cpu_type
1235 fi
1236
1237 if test x"$dwarf2" = xyes
1238 then tm_file="$tm_file tm-dwarf2.h"
1239 fi
1240
1241 # Say what files are being used for the output code and MD file.
1242 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1243 echo "Using \`$srcdir/config/$md_file' as machine description file."
1244
1245 # If any of the xm_file variables contain nonexistent files, warn
1246 # about them and drop them.
1247
1248 bx=
1249 for x in $build_xm_file; do
1250   if    test -f $srcdir/config/$x
1251   then      bx="$bx $x"
1252   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1253   fi
1254 done
1255 build_xm_file="$bx"
1256
1257 hx=
1258 for x in $host_xm_file; do
1259   if    test -f $srcdir/config/$x
1260   then      hx="$hx $x"
1261   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1262   fi
1263 done
1264 host_xm_file="$hx"
1265
1266 tx=
1267 for x in $xm_file; do
1268   if    test -f $srcdir/config/$x
1269   then      tx="$tx $x"
1270   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1271   fi
1272 done
1273 xm_file="$tx"
1274
1275 count=a
1276 for f in $tm_file; do
1277         count=${count}x
1278 done
1279 if test $count = ax; then
1280         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1281 else
1282         echo "Using the following target machine macro files:"
1283         for f in $tm_file; do
1284                 echo "  $srcdir/config/$f"
1285         done
1286 fi
1287
1288 if test x$need_64bit_hwint = xyes; then
1289         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1290 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1291 fi
1292
1293 if test x$use_long_long_for_widest_fast_int = xyes; then
1294         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1295 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1296 efficiently supported by the host hardware.])
1297 fi
1298
1299 count=a
1300 for f in $host_xm_file; do
1301         count=${count}x
1302 done
1303 if test $count = a; then
1304         :
1305 elif test $count = ax; then
1306         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1307 else
1308         echo "Using the following host machine macro files:"
1309         for f in $host_xm_file; do
1310                 echo "  $srcdir/config/$f"
1311         done
1312 fi
1313 echo "Using ${out_host_hook_obj} for host machine hooks."
1314
1315 if test "$host_xm_file" != "$build_xm_file"; then
1316         count=a
1317         for f in $build_xm_file; do
1318                 count=${count}x
1319         done
1320         if test $count = a; then
1321                 :
1322         elif test $count = ax; then
1323                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1324         else
1325                 echo "Using the following build machine macro files:"
1326                 for f in $build_xm_file; do
1327                         echo "  $srcdir/config/$f"
1328                 done
1329         fi
1330 fi
1331
1332 case ${host} in
1333   powerpc*-*-darwin*)
1334     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1335       gcc_cv_mcontext_underscores,
1336       AC_COMPILE_IFELSE([
1337 #include <sys/signal.h>
1338 #include <ucontext.h>
1339 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1340 ],
1341         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1342       if test $gcc_cv_mcontext_underscores = yes; then
1343         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1344           [mcontext_t fields start with __])
1345       fi
1346     ;;
1347 esac
1348
1349 # ---------
1350 # Threading
1351 # ---------
1352
1353 # Check if a valid thread package
1354 case ${enable_threads} in
1355   "" | no)
1356     # No threads
1357     target_thread_file='single'
1358     ;;
1359   yes)
1360     # default
1361     target_thread_file='single'
1362     ;;
1363   aix | dce | gnat | irix | posix | posix95 | rtems | \
1364   single | solaris | vxworks | win32 )
1365     target_thread_file=${enable_threads}
1366     ;;
1367   *)
1368     echo "${enable_threads} is an unknown thread package" 1>&2
1369     exit 1
1370     ;;
1371 esac
1372
1373 if test x${thread_file} = x; then
1374   # No thread file set by target-specific clauses in config.gcc,
1375   # so use file chosen by default logic above
1376   thread_file=${target_thread_file}
1377 fi
1378
1379 # Make gthr-default.h if we have a thread file.
1380 gthread_flags=
1381 if test $thread_file != single; then
1382   rm -f gthr-default.h
1383   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1384   gthread_flags=-DHAVE_GTHR_DEFAULT
1385 fi
1386 AC_SUBST(gthread_flags)
1387
1388 # --------
1389 # UNSORTED
1390 # --------
1391
1392 use_cxa_atexit=no
1393 if test x$enable___cxa_atexit = xyes || \
1394    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1395   if test x$host = x$target; then
1396     case $host in
1397       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1398       # keyed to flag_use_cxa_atexit
1399       *-*-mingw32*)
1400         use_cxa_atexit=yes
1401         ;;
1402       *)
1403         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1404           [echo "__cxa_atexit can't be enabled on this target"])
1405         ;;
1406     esac
1407   else
1408     # We can't check for __cxa_atexit when building a cross, so assume
1409     # it is available
1410     use_cxa_atexit=yes
1411   fi
1412   if test x$use_cxa_atexit = xyes; then
1413     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1414       [Define if you want to use __cxa_atexit, rather than atexit, to
1415       register C++ destructors for local statics and global objects.
1416       This is essential for fully standards-compliant handling of
1417       destructors, but requires __cxa_atexit in libc.])
1418   fi
1419 fi
1420
1421 use_getipinfo=yes
1422 if test x$with_system_libunwind = xyes; then
1423    if test x$host = x$target; then
1424      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1425    fi
1426 fi
1427 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1428 if test x$use_getipinfo = xyes; then
1429    AC_DEFINE(HAVE_GETIPINFO, 1,
1430         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1431 else
1432    echo "The system unwind library does not support _Unwind_GetIPInfo."
1433 fi
1434
1435 # Look for a file containing extra machine modes.
1436 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1437   extra_modes_file='$(srcdir)'/config/${extra_modes}
1438   AC_SUBST(extra_modes_file)
1439   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1440   [Define to the name of a file containing a list of extra machine modes
1441    for this architecture.])
1442 fi
1443
1444 # Convert extra_options into a form suitable for Makefile use.
1445 extra_opt_files=
1446 for f in $extra_options; do
1447   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1448 done
1449 AC_SUBST(extra_opt_files)
1450
1451 # auto-host.h is the file containing items generated by autoconf and is
1452 # the first file included by config.h.
1453 # If host=build, it is correct to have bconfig include auto-host.h
1454 # as well.  If host!=build, we are in error and need to do more
1455 # work to find out the build config parameters.
1456 if test x$host = x$build
1457 then
1458         build_auto=auto-host.h
1459 else
1460         # We create a subdir, then run autoconf in the subdir.
1461         # To prevent recursion we set host and build for the new
1462         # invocation of configure to the build for this invocation
1463         # of configure.
1464         tempdir=build.$$
1465         rm -rf $tempdir
1466         mkdir $tempdir
1467         cd $tempdir
1468         case ${srcdir} in
1469         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1470         *) realsrcdir=../${srcdir};;
1471         esac
1472         saved_CFLAGS="${CFLAGS}"
1473         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1474         ${realsrcdir}/configure \
1475                 --enable-languages=${enable_languages-all} \
1476                 --target=$target_alias --host=$build_alias --build=$build_alias
1477         CFLAGS="${saved_CFLAGS}"
1478
1479         # We just finished tests for the build machine, so rename
1480         # the file auto-build.h in the gcc directory.
1481         mv auto-host.h ../auto-build.h
1482         cd ..
1483         rm -rf $tempdir
1484         build_auto=auto-build.h
1485 fi
1486 AC_SUBST(build_subdir)
1487
1488 tm_file="${tm_file} defaults.h"
1489 tm_p_file="${tm_p_file} tm-preds.h"
1490 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1491 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1492 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1493 # put this back in temporarily.
1494 xm_file="auto-host.h ansidecl.h ${xm_file}"
1495
1496 # --------
1497 # UNSORTED
1498 # --------
1499
1500 changequote(,)dnl
1501 # Compile in configure arguments.
1502 if test -f configargs.h ; then
1503         # Being re-configured.
1504         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1505         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1506 else
1507         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1508 fi
1509
1510 # Double all backslashes and backslash all quotes to turn
1511 # gcc_config_arguments into a C string.
1512 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1513 $gcc_config_arguments
1514 EOF
1515 gcc_config_arguments_str=`cat conftest.out`
1516 rm -f conftest.out
1517
1518 cat > configargs.h <<EOF
1519 /* Generated automatically. */
1520 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1521 static const char thread_model[] = "$thread_file";
1522
1523 static const struct {
1524   const char *name, *value;
1525 } configure_default_options[] = $configure_default_options;
1526 EOF
1527 changequote([,])dnl
1528
1529 # Internationalization
1530 ZW_GNU_GETTEXT_SISTER_DIR
1531
1532 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1533 # -liconv on the link line twice.
1534 case "$LIBINTL" in *$LIBICONV*)
1535         LIBICONV= ;;
1536 esac
1537
1538 AC_ARG_ENABLE(secureplt,
1539 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1540 [], [])
1541
1542 # Windows32 Registry support for specifying GCC installation paths.
1543 AC_ARG_ENABLE(win32-registry,
1544 [  --disable-win32-registry
1545                           disable lookup of installation paths in the
1546                           Registry on Windows hosts
1547   --enable-win32-registry enable registry lookup (default)
1548   --enable-win32-registry=KEY
1549                           use KEY instead of GCC version as the last portion
1550                           of the registry key],,)
1551
1552 case $host_os in
1553   win32 | pe | cygwin* | mingw32* | uwin*)
1554     if test "x$enable_win32_registry" != xno; then
1555       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1556     fi
1557
1558     if test "x$enable_win32_registry" != xno; then
1559       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1560   [Define to 1 if installation paths should be looked up in the Windows
1561    Registry. Ignored on non-Windows hosts.])
1562
1563       if test "x$enable_win32_registry" != xyes \
1564          && test "x$enable_win32_registry" != x; then
1565         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1566   [Define to be the last component of the Windows registry key under which
1567    to look for installation paths.  The full key used will be
1568    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1569    The default is the GCC version number.])
1570       fi
1571     fi
1572   ;;
1573 esac
1574
1575 # Get an absolute path to the GCC top-level source directory
1576 holddir=`${PWDCMD-pwd}`
1577 cd $srcdir
1578 topdir=`${PWDCMD-pwd}`
1579 cd $holddir
1580
1581 # Conditionalize the makefile for this host machine.
1582 xmake_file=
1583 for f in ${host_xmake_file}
1584 do
1585         if test -f ${srcdir}/config/$f
1586         then
1587                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1588         fi
1589 done
1590
1591 # Conditionalize the makefile for this target machine.
1592 tmake_file_=
1593 for f in ${tmake_file}
1594 do
1595         if test -f ${srcdir}/config/$f
1596         then
1597                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1598         fi
1599 done
1600 tmake_file="${tmake_file_}"
1601
1602 # This is a terrible hack which will go away some day.
1603 host_cc_for_libada=${CC}
1604 AC_SUBST(host_cc_for_libada)
1605
1606 out_object_file=`basename $out_file .c`.o
1607
1608 tm_file_list="options.h"
1609 tm_include_list="options.h"
1610 for f in $tm_file; do
1611   case $f in
1612     defaults.h )
1613        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1614        tm_include_list="${tm_include_list} $f"
1615        ;;
1616     * )
1617        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1618        tm_include_list="${tm_include_list} config/$f"
1619        ;;
1620   esac
1621 done
1622
1623 tm_p_file_list=
1624 tm_p_include_list=
1625 for f in $tm_p_file; do
1626   case $f in
1627     tm-preds.h )
1628        tm_p_file_list="${tm_p_file_list} $f"
1629        tm_p_include_list="${tm_p_include_list} $f"
1630        ;;
1631     * )
1632        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1633        tm_p_include_list="${tm_p_include_list} config/$f"
1634   esac
1635 done
1636
1637 xm_file_list=
1638 xm_include_list=
1639 for f in $xm_file; do
1640   case $f in
1641     ansidecl.h )
1642        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1643        xm_include_list="${xm_include_list} $f"
1644        ;;
1645     auto-host.h )
1646        xm_file_list="${xm_file_list} $f"
1647        xm_include_list="${xm_include_list} $f"
1648        ;;
1649     * )
1650        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1651        xm_include_list="${xm_include_list} config/$f"
1652        ;;
1653   esac
1654 done
1655
1656 host_xm_file_list=
1657 host_xm_include_list=
1658 for f in $host_xm_file; do
1659   case $f in
1660     ansidecl.h )
1661        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1662        host_xm_include_list="${host_xm_include_list} $f"
1663        ;;
1664     auto-host.h )
1665        host_xm_file_list="${host_xm_file_list} $f"
1666        host_xm_include_list="${host_xm_include_list} $f"
1667        ;;
1668     * )
1669        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1670        host_xm_include_list="${host_xm_include_list} config/$f"
1671        ;;
1672   esac
1673 done
1674
1675 build_xm_file_list=
1676 for f in $build_xm_file; do
1677   case $f in
1678     ansidecl.h )
1679        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1680        build_xm_include_list="${build_xm_include_list} $f"
1681        ;;
1682     auto-build.h | auto-host.h )
1683        build_xm_file_list="${build_xm_file_list} $f"
1684        build_xm_include_list="${build_xm_include_list} $f"
1685        ;;
1686     * )
1687        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1688        build_xm_include_list="${build_xm_include_list} config/$f"
1689        ;;
1690   esac
1691 done
1692
1693 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1694 # cross-compiler which does not use the native headers and libraries.
1695 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1696 CROSS=                                          AC_SUBST(CROSS)
1697 ALL=all.internal                                AC_SUBST(ALL)
1698 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1699
1700 if test "x$with_build_sysroot" != x; then
1701   build_system_header_dir=$with_build_sysroot'$(NATIVE_SYSTEM_HEADER_DIR)'
1702 else
1703   # This value is used, even on a native system, because
1704   # CROSS_SYSTEM_HEADER_DIR is just
1705   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1706   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1707 fi
1708
1709 if test x$host != x$target
1710 then
1711         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1712         ALL=all.cross
1713         SYSTEM_HEADER_DIR=$build_system_header_dir
1714         case "$host","$target" in
1715         # Darwin crosses can use the host system's libraries and headers,
1716         # because of the fat library support.  Of course, it must be the
1717         # same version of Darwin on both sides.  Allow the user to
1718         # just say --target=foo-darwin without a version number to mean
1719         # "the version on this system".
1720             *-*-darwin*,*-*-darwin*)
1721                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1722                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1723                 if test $hostos = $targetos -o $targetos = darwin ; then
1724                     CROSS=
1725                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1726                     with_headers=yes
1727                 fi
1728                 ;;
1729
1730             i?86-*-*,x86_64-*-* \
1731             | powerpc*-*-*,powerpc64*-*-*)
1732                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1733         esac
1734 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1735         SYSTEM_HEADER_DIR=$build_system_header_dir
1736 fi
1737
1738 # If this is a cross-compiler that does not
1739 # have its own set of headers then define
1740 # inhibit_libc
1741
1742 # If this is using newlib, without having the headers available now,
1743 # then define inhibit_libc in LIBGCC2_CFLAGS.
1744 # This prevents libgcc2 from containing any code which requires libc
1745 # support.
1746 inhibit_libc=false
1747 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1748        test x$with_newlib = xyes ; } &&
1749      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1750        inhibit_libc=true
1751 fi
1752 AC_SUBST(inhibit_libc)
1753
1754 # When building gcc with a cross-compiler, we need to adjust things so
1755 # that the generator programs are still built with the native compiler.
1756 # Also, we cannot run fixincludes or fix-header.
1757
1758 # These are the normal (build=host) settings:
1759 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1760 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1761 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1762
1763 # Possibly disable fixproto, on a per-target basis.
1764 case ${use_fixproto} in
1765   no)
1766     STMP_FIXPROTO=
1767     ;;
1768   yes)
1769     STMP_FIXPROTO=stmp-fixproto
1770     ;;
1771 esac
1772 AC_SUBST(STMP_FIXPROTO)
1773
1774 # And these apply if build != host, or we are generating coverage data
1775 if test x$build != x$host || test "x$coverage_flags" != x
1776 then
1777     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1778
1779     if test "x$TARGET_SYSTEM_ROOT" = x; then
1780         if test "x$STMP_FIXPROTO" != x; then
1781           STMP_FIXPROTO=stmp-install-fixproto
1782         fi
1783     fi
1784 fi
1785
1786 # Expand extra_headers to include complete path.
1787 # This substitutes for lots of t-* files.
1788 extra_headers_list=
1789 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1790 for file in ${extra_headers} ; do
1791   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1792 done
1793
1794 # Define collect2 in Makefile.
1795 case $host_can_use_collect2 in
1796   no) collect2= ;;
1797   *) collect2='collect2$(exeext)' ;;
1798 esac
1799 AC_SUBST([collect2])
1800
1801 # Add a definition of USE_COLLECT2 if system wants one.
1802 case $use_collect2 in
1803   no) use_collect2= ;;
1804   "") ;;
1805   *)
1806     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1807     xm_defines="${xm_defines} USE_COLLECT2"
1808     case $host_can_use_collect2 in
1809       no)
1810         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1811         ;;
1812     esac
1813     ;;
1814 esac
1815
1816 # ---------------------------
1817 # Assembler & linker features
1818 # ---------------------------
1819
1820 # Identify the assembler which will work hand-in-glove with the newly
1821 # built GCC, so that we can examine its features.  This is the assembler
1822 # which will be driven by the driver program.
1823 #
1824 # If build != host, and we aren't building gas in-tree, we identify a
1825 # build->target assembler and hope that it will have the same features
1826 # as the host->target assembler we'll be using.
1827 gcc_cv_gas_major_version=
1828 gcc_cv_gas_minor_version=
1829 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1830
1831 m4_pattern_allow([AS_FOR_TARGET])dnl
1832 AS_VAR_SET_IF(gcc_cv_as,, [
1833 if test -x "$DEFAULT_ASSEMBLER"; then
1834         gcc_cv_as="$DEFAULT_ASSEMBLER"
1835 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1836      && test -f ../gas/Makefile \
1837      && test x$build = x$host; then
1838         gcc_cv_as=../gas/as-new$build_exeext
1839 elif test -x as$build_exeext; then
1840         # Build using assembler in the current directory.
1841         gcc_cv_as=./as$build_exeext
1842 elif test -x $AS_FOR_TARGET; then
1843         gcc_cv_as="$AS_FOR_TARGET"
1844 else
1845         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1846 fi])
1847
1848 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1849 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1850
1851 AC_MSG_CHECKING(what assembler to use)
1852 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1853   # Single tree build which includes gas.  We want to prefer it
1854   # over whatever linker top-level may have detected, since
1855   # we'll use what we're building after installation anyway.
1856   AC_MSG_RESULT(newly built gas)
1857   in_tree_gas=yes
1858   _gcc_COMPUTE_GAS_VERSION
1859   in_tree_gas_is_elf=no
1860   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1861      || (grep 'obj_format = multi' ../gas/Makefile \
1862          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1863   then
1864     in_tree_gas_is_elf=yes
1865   fi
1866 else
1867   AC_MSG_RESULT($gcc_cv_as)
1868   in_tree_gas=no
1869 fi
1870
1871 # Identify the linker which will work hand-in-glove with the newly
1872 # built GCC, so that we can examine its features.  This is the linker
1873 # which will be driven by the driver program.
1874 #
1875 # If build != host, and we aren't building gas in-tree, we identify a
1876 # build->target linker and hope that it will have the same features
1877 # as the host->target linker we'll be using.
1878 gcc_cv_gld_major_version=
1879 gcc_cv_gld_minor_version=
1880 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1881 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1882
1883 AS_VAR_SET_IF(gcc_cv_ld,, [
1884 if test -x "$DEFAULT_LINKER"; then
1885         gcc_cv_ld="$DEFAULT_LINKER"
1886 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1887      && test -f ../ld/Makefile \
1888      && test x$build = x$host; then
1889         gcc_cv_ld=../ld/ld-new$build_exeext
1890 elif test -x collect-ld$build_exeext; then
1891         # Build using linker in the current directory.
1892         gcc_cv_ld=./collect-ld$build_exeext
1893 elif test -x $LD_FOR_TARGET; then
1894         gcc_cv_ld="$LD_FOR_TARGET"
1895 else
1896         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1897 fi])
1898
1899 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1900 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1901
1902 AC_MSG_CHECKING(what linker to use)
1903 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1904         # Single tree build which includes ld.  We want to prefer it
1905         # over whatever linker top-level may have detected, since
1906         # we'll use what we're building after installation anyway.
1907         AC_MSG_RESULT(newly built ld)
1908         in_tree_ld=yes
1909         in_tree_ld_is_elf=no
1910         if (grep 'EMUL = .*elf' ../ld/Makefile \
1911             || grep 'EMUL = .*linux' ../ld/Makefile \
1912             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1913           in_tree_ld_is_elf=yes
1914         fi
1915         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1916         do
1917 changequote(,)dnl
1918                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1919                 if test x$gcc_cv_gld_version != x; then
1920                         break
1921                 fi
1922         done
1923         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1924         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1925 changequote([,])dnl
1926 else
1927         AC_MSG_RESULT($gcc_cv_ld)
1928         in_tree_ld=no
1929 fi
1930
1931 # Figure out what nm we will be using.
1932 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1933 AS_VAR_SET_IF(gcc_cv_nm,, [
1934 if test -f $gcc_cv_binutils_srcdir/configure.in \
1935      && test -f ../binutils/Makefile \
1936      && test x$build = x$host; then
1937         gcc_cv_nm=../binutils/nm-new$build_exeext
1938 elif test -x nm$build_exeext; then
1939         gcc_cv_nm=./nm$build_exeext
1940 elif test -x $NM_FOR_TARGET; then
1941         gcc_cv_nm="$NM_FOR_TARGET"
1942 else
1943         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1944 fi])
1945
1946 AC_MSG_CHECKING(what nm to use)
1947 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1948         # Single tree build which includes binutils.
1949         AC_MSG_RESULT(newly built nm)
1950         in_tree_nm=yes
1951 else
1952         AC_MSG_RESULT($gcc_cv_nm)
1953         in_tree_nm=no
1954 fi
1955
1956 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1957 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1958
1959 # Figure out what objdump we will be using.
1960 AS_VAR_SET_IF(gcc_cv_objdump,, [
1961 if test -f $gcc_cv_binutils_srcdir/configure.in \
1962      && test -f ../binutils/Makefile \
1963      && test x$build = x$host; then
1964         # Single tree build which includes binutils.
1965         gcc_cv_objdump=../binutils/objdump$build_exeext
1966 elif test -x objdump$build_exeext; then
1967         gcc_cv_objdump=./objdump$build_exeext
1968 elif test -x $OBJDUMP_FOR_TARGET; then
1969         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1970 else
1971         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1972 fi])
1973
1974 AC_MSG_CHECKING(what objdump to use)
1975 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1976         # Single tree build which includes binutils.
1977         AC_MSG_RESULT(newly built objdump)
1978 elif test x$gcc_cv_objdump = x; then
1979         AC_MSG_RESULT(not found)
1980 else
1981         AC_MSG_RESULT($gcc_cv_objdump)
1982 fi
1983
1984 # Figure out what assembler alignment features are present.
1985 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1986  [2,6,0],,
1987 [.balign 4
1988 .p2align 2],,
1989 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1990   [Define if your assembler supports .balign and .p2align.])])
1991
1992 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1993  [2,8,0],,
1994  [.p2align 4,,7],,
1995 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1996   [Define if your assembler supports specifying the maximum number
1997    of bytes to skip when using the GAS .p2align command.])])
1998
1999 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2000  [2,8,0],,
2001  [.literal16],,
2002 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2003   [Define if your assembler supports .literal16.])])
2004
2005 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2006  [elf,2,9,0],,
2007  [conftest_label1: .word 0
2008 .subsection -1
2009 conftest_label2: .word 0
2010 .previous],
2011  [if test x$gcc_cv_nm != x; then
2012     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2013     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2014     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2015     then :
2016     else gcc_cv_as_subsection_m1=yes
2017     fi
2018     rm -f conftest.nm1 conftest.nm2
2019   fi],
2020  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2021   [Define if your assembler supports .subsection and .subsection -1 starts
2022    emitting at the beginning of your section.])])
2023
2024 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2025  [2,2,0],,
2026  [      .weak foobar],,
2027 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2028
2029 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2030  [2,17,0],,
2031  [      .weakref foobar, barfnot],,
2032 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2033
2034 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2035  [2,15,91],,
2036  [      .SPACE $TEXT$
2037         .NSUBSPA $CODE$,COMDAT],,
2038 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2039
2040 # .hidden needs to be supported in both the assembler and the linker,
2041 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2042 # This is irritatingly difficult to feature test for; we have to check the
2043 # date string after the version number.  If we've got an in-tree
2044 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2045 # to be safe.
2046 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2047 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2048  [elf,2,13,0],,
2049 [       .hidden foobar
2050 foobar:])
2051
2052 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2053 [if test $in_tree_ld = yes ; then
2054   gcc_cv_ld_hidden=no
2055   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2056      && test $in_tree_ld_is_elf = yes; then
2057      gcc_cv_ld_hidden=yes
2058   fi
2059 else
2060   gcc_cv_ld_hidden=yes
2061   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2062   if echo "$ld_ver" | grep GNU > /dev/null; then
2063 changequote(,)dnl
2064     ld_vers=`echo $ld_ver | sed -n \
2065         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2066         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2067         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2068         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2069         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2070         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2071         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   -].*$,\1,p'`
2072     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2073     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2074     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2075     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2076     if test 0"$ld_date" -lt 20020404; then
2077       if test -n "$ld_date"; then
2078         # If there was date string, but was earlier than 2002-04-04, fail
2079         gcc_cv_ld_hidden=no
2080       elif test -z "$ld_vers"; then
2081         # If there was no date string nor ld version number, something is wrong
2082         gcc_cv_ld_hidden=no
2083       else
2084         test -z "$ld_vers_patch" && ld_vers_patch=0
2085         if test "$ld_vers_major" -lt 2; then
2086           gcc_cv_ld_hidden=no
2087         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2088           gcc_cv_ld_hidden="no"
2089         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2090           gcc_cv_ld_hidden=no
2091         fi
2092       fi
2093 changequote([,])dnl
2094     fi
2095   else
2096     case "${target}" in
2097       hppa64*-*-hpux* | ia64*-*-hpux*)
2098         gcc_cv_ld_hidden=yes
2099         ;;
2100       *)
2101         gcc_cv_ld_hidden=no
2102         ;;
2103     esac
2104   fi
2105 fi])
2106 libgcc_visibility=no
2107 AC_SUBST(libgcc_visibility)
2108 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2109 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2110   libgcc_visibility=yes
2111   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2112   [Define if your assembler and linker support .hidden.])
2113 fi
2114
2115 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2116 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2117   [elf,2,11,0],,
2118 [       .data
2119         .uleb128 L2 - L1
2120 L1:
2121         .uleb128 1280
2122         .sleb128 -1010
2123 L2:],
2124  [# GAS versions before 2.11 do not support uleb128,
2125   # despite appearing to.
2126   # ??? There exists an elf-specific test that will crash
2127   # the assembler.  Perhaps it's better to figure out whether
2128   # arbitrary sections are supported and try the test.
2129   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2130   if echo "$as_ver" | grep GNU > /dev/null; then
2131 changequote(,)dnl
2132     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2133     as_major=`echo $as_ver | sed 's/\..*//'`
2134     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2135 changequote([,])dnl
2136     if test $as_major -eq 2 && test $as_minor -lt 11
2137     then :
2138     else gcc_cv_as_leb128=yes
2139     fi
2140   fi],
2141   [AC_DEFINE(HAVE_AS_LEB128, 1,
2142     [Define if your assembler supports .sleb128 and .uleb128.])])
2143
2144 # GAS versions up to and including 2.11.0 may mis-optimize
2145 # .eh_frame data.
2146 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2147   [elf,2,12,0],,
2148 [       .text
2149 .LFB1:
2150         .4byte  0
2151 .L1:
2152         .4byte  0
2153 .LFE1:
2154         .section        .eh_frame,"aw",@progbits
2155 __FRAME_BEGIN__:
2156         .4byte  .LECIE1-.LSCIE1
2157 .LSCIE1:
2158         .4byte  0x0
2159         .byte   0x1
2160         .ascii "z\0"
2161         .byte   0x1
2162         .byte   0x78
2163         .byte   0x1a
2164         .byte   0x0
2165         .byte   0x4
2166         .4byte  1
2167         .p2align 1
2168 .LECIE1:
2169 .LSFDE1:
2170         .4byte  .LEFDE1-.LASFDE1
2171 .LASFDE1:
2172         .4byte  .LASFDE1-__FRAME_BEGIN__
2173         .4byte  .LFB1
2174         .4byte  .LFE1-.LFB1
2175         .byte   0x4
2176         .4byte  .LFE1-.LFB1
2177         .byte   0x4
2178         .4byte  .L1-.LFB1
2179 .LEFDE1:],
2180 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2181 cat > conftest.lit <<EOF
2182  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2183  0010 01000000 12000000 18000000 00000000  ................
2184  0020 08000000 04080000 0044               .........D      @&t@
2185 EOF
2186 cat > conftest.big <<EOF
2187  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2188  0010 00000001 00000012 00000018 00000000  ................
2189  0020 00000008 04000000 0844               .........D      @&t@
2190 EOF
2191   # If the assembler didn't choke, and we can objdump,
2192   # and we got the correct data, then succeed.
2193   # The text in the here-document typically retains its unix-style line
2194   # endings, while the output of objdump will use host line endings.
2195   # Therefore, use diff -b for the comparisons.
2196   if test x$gcc_cv_objdump != x \
2197   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2198      | tail -3 > conftest.got \
2199   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2200     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2201   then
2202     gcc_cv_as_eh_frame=yes
2203   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2204     gcc_cv_as_eh_frame=buggy
2205   else
2206     # Uh oh, what do we do now?
2207     gcc_cv_as_eh_frame=no
2208   fi])
2209
2210 if test $gcc_cv_as_eh_frame = buggy; then
2211   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2212   [Define if your assembler mis-optimizes .eh_frame data.])
2213 fi
2214
2215 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2216  [elf,2,12,0], [--fatal-warnings],
2217  [.section .rodata.str, "aMS", @progbits, 1])
2218 if test $gcc_cv_as_shf_merge = no; then
2219   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2220     [elf,2,12,0], [--fatal-warnings],
2221     [.section .rodata.str, "aMS", %progbits, 1])
2222 fi
2223 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2224   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2225 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2226
2227 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2228  [elf,2,16,0], [--fatal-warnings],
2229  [.section .text,"axG",@progbits,.foo,comdat])
2230 if test $gcc_cv_as_comdat_group = yes; then
2231   gcc_cv_as_comdat_group_percent=no
2232 else
2233  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2234    [elf,2,16,0], [--fatal-warnings],
2235    [.section .text,"axG",%progbits,.foo,comdat])
2236 fi
2237 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2238   comdat_group=yes
2239   if test 0"$ld_date" -lt 20050308; then
2240     if test -n "$ld_date"; then
2241       # If there was date string, but was earlier than 2005-03-08, fail
2242       comdat_group=no
2243     elif test "$ld_vers_major" -lt 2; then
2244       comdat_group=no
2245     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2246       comdat_group=no
2247     fi
2248   fi
2249 else
2250   # assume linkers other than GNU ld don't support COMDAT group
2251   comdat_group=no
2252 fi
2253 if test $comdat_group = no; then
2254   gcc_cv_as_comdat_group=no
2255   gcc_cv_as_comdat_group_percent=no
2256 fi
2257 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2258   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2259 [Define 0/1 if your assembler and linker support COMDAT groups.])
2260
2261 # Thread-local storage - the check is heavily parametrized.
2262 conftest_s=
2263 tls_first_major=
2264 tls_first_minor=
2265 tls_as_opt=
2266 case "$target" in
2267 changequote(,)dnl
2268   alpha*-*-*)
2269     conftest_s='
2270         .section ".tdata","awT",@progbits
2271 foo:    .long   25
2272         .text
2273         ldq     $27,__tls_get_addr($29)         !literal!1
2274         lda     $16,foo($29)                    !tlsgd!1
2275         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2276         ldq     $27,__tls_get_addr($29)         !literal!2
2277         lda     $16,foo($29)                    !tlsldm!2
2278         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2279         ldq     $1,foo($29)                     !gotdtprel
2280         ldah    $2,foo($29)                     !dtprelhi
2281         lda     $3,foo($2)                      !dtprello
2282         lda     $4,foo($29)                     !dtprel
2283         ldq     $1,foo($29)                     !gottprel
2284         ldah    $2,foo($29)                     !tprelhi
2285         lda     $3,foo($2)                      !tprello
2286         lda     $4,foo($29)                     !tprel'
2287         tls_first_major=2
2288         tls_first_minor=13
2289         tls_as_opt=--fatal-warnings
2290         ;;
2291   frv*-*-*)
2292     conftest_s='
2293         .section ".tdata","awT",@progbits
2294 x:      .long   25
2295         .text
2296         call    #gettlsoff(x)'
2297         tls_first_major=2
2298         tls_first_minor=14
2299         ;;
2300   hppa*-*-linux*)
2301     conftest_s='
2302 t1:     .reg    %r20
2303 t2:     .reg    %r21
2304 gp:     .reg    %r19
2305         .section ".tdata","awT",@progbits
2306 foo:    .long   25
2307         .text
2308         .align  4
2309         addil LT%foo-$tls_gdidx$,gp
2310         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2311         b __tls_get_addr
2312         nop
2313         addil LT%foo-$tls_ldidx$,gp
2314         b __tls_get_addr
2315         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2316         addil LR%foo-$tls_dtpoff$,%ret0
2317         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2318         mfctl %cr27,%t1
2319         addil LT%foo-$tls_ieoff$,gp
2320         ldw RT%foo-$tls_ieoff$(%r1),%t2
2321         add %t1,%t2,%t3
2322         mfctl %cr27,%t1
2323         addil LR%foo-$tls_leoff$,%t1
2324         ldo RR%foo-$tls_leoff$(%r1),%t2'
2325         tls_first_major=2
2326         tls_first_minor=15
2327         tls_as_opt=--fatal-warnings
2328         ;;
2329   arm*-*-*)
2330     conftest_s='
2331         .section ".tdata","awT",%progbits
2332 foo:    .long   25
2333         .text
2334 .word foo(gottpoff)
2335 .word foo(tpoff)
2336 .word foo(tlsgd)
2337 .word foo(tlsldm)
2338 .word foo(tlsldo)'
2339         tls_first_major=2
2340         tls_first_minor=17
2341         ;;
2342   i[34567]86-*-*)
2343     conftest_s='
2344         .section ".tdata","awT",@progbits
2345 foo:    .long   25
2346         .text
2347         movl    %gs:0, %eax
2348         leal    foo@TLSGD(,%ebx,1), %eax
2349         leal    foo@TLSLDM(%ebx), %eax
2350         leal    foo@DTPOFF(%eax), %edx
2351         movl    foo@GOTTPOFF(%ebx), %eax
2352         subl    foo@GOTTPOFF(%ebx), %eax
2353         addl    foo@GOTNTPOFF(%ebx), %eax
2354         movl    foo@INDNTPOFF, %eax
2355         movl    $foo@TPOFF, %eax
2356         subl    $foo@TPOFF, %eax
2357         leal    foo@NTPOFF(%ecx), %eax'
2358         tls_first_major=2
2359         tls_first_minor=14
2360         tls_as_opt=--fatal-warnings
2361         ;;
2362   x86_64-*-*)
2363     conftest_s='
2364         .section ".tdata","awT",@progbits
2365 foo:    .long   25
2366         .text
2367         movq    %fs:0, %rax
2368         leaq    foo@TLSGD(%rip), %rdi
2369         leaq    foo@TLSLD(%rip), %rdi
2370         leaq    foo@DTPOFF(%rax), %rdx
2371         movq    foo@GOTTPOFF(%rip), %rax
2372         movq    $foo@TPOFF, %rax'
2373         tls_first_major=2
2374         tls_first_minor=14
2375         tls_as_opt=--fatal-warnings
2376         ;;
2377   ia64-*-*)
2378     conftest_s='
2379         .section ".tdata","awT",@progbits
2380 foo:    data8   25
2381         .text
2382         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2383         addl    r17 = @ltoff(@dtprel(foo#)), gp
2384         addl    r18 = @ltoff(@tprel(foo#)), gp
2385         addl    r19 = @dtprel(foo#), gp
2386         adds    r21 = @dtprel(foo#), r13
2387         movl    r23 = @dtprel(foo#)
2388         addl    r20 = @tprel(foo#), gp
2389         adds    r22 = @tprel(foo#), r13
2390         movl    r24 = @tprel(foo#)'
2391         tls_first_major=2
2392         tls_first_minor=13
2393         tls_as_opt=--fatal-warnings
2394         ;;
2395   mips*-*-*)
2396     conftest_s='
2397         .section .tdata,"awT",@progbits
2398 x:
2399         .word 2
2400         .text
2401         addiu $4, $28, %tlsgd(x)
2402         addiu $4, $28, %tlsldm(x)
2403         lui $4, %dtprel_hi(x)
2404         addiu $4, $4, %dtprel_lo(x)
2405         lw $4, %gottprel(x)($28)
2406         lui $4, %tprel_hi(x)
2407         addiu $4, $4, %tprel_lo(x)'
2408         tls_first_major=2
2409         tls_first_minor=16
2410         tls_as_opt='-32 --fatal-warnings'
2411         ;;
2412   powerpc-*-*)
2413     conftest_s='
2414         .section ".tdata","awT",@progbits
2415         .align 2
2416 ld0:    .space 4
2417 ld1:    .space 4
2418 x1:     .space 4
2419 x2:     .space 4
2420 x3:     .space 4
2421         .text
2422         addi 3,31,ld0@got@tlsgd
2423         bl __tls_get_addr
2424         addi 3,31,x1@got@tlsld
2425         bl __tls_get_addr
2426         addi 9,3,x1@dtprel
2427         addis 9,3,x2@dtprel@ha
2428         addi 9,9,x2@dtprel@l
2429         lwz 9,x3@got@tprel(31)
2430         add 9,9,x@tls
2431         addi 9,2,x1@tprel
2432         addis 9,2,x2@tprel@ha
2433         addi 9,9,x2@tprel@l'
2434         tls_first_major=2
2435         tls_first_minor=14
2436         tls_as_opt="-a32 --fatal-warnings"
2437         ;;
2438   powerpc64-*-*)
2439     conftest_s='
2440         .section ".tdata","awT",@progbits
2441         .align 3
2442 ld0:    .space 8
2443 ld1:    .space 8
2444 x1:     .space 8
2445 x2:     .space 8
2446 x3:     .space 8
2447         .text
2448         addi 3,2,ld0@got@tlsgd
2449         bl .__tls_get_addr
2450         nop
2451         addi 3,2,ld1@toc
2452         bl .__tls_get_addr
2453         nop
2454         addi 3,2,x1@got@tlsld
2455         bl .__tls_get_addr
2456         nop
2457         addi 9,3,x1@dtprel
2458         bl .__tls_get_addr
2459         nop
2460         addis 9,3,x2@dtprel@ha
2461         addi 9,9,x2@dtprel@l
2462         bl .__tls_get_addr
2463         nop
2464         ld 9,x3@got@dtprel(2)
2465         add 9,9,3
2466         bl .__tls_get_addr
2467         nop'
2468         tls_first_major=2
2469         tls_first_minor=14
2470         tls_as_opt="-a64 --fatal-warnings"
2471         ;;
2472   s390-*-*)
2473     conftest_s='
2474         .section ".tdata","awT",@progbits
2475 foo:    .long   25
2476         .text
2477         .long   foo@TLSGD
2478         .long   foo@TLSLDM
2479         .long   foo@DTPOFF
2480         .long   foo@NTPOFF
2481         .long   foo@GOTNTPOFF
2482         .long   foo@INDNTPOFF
2483         l       %r1,foo@GOTNTPOFF(%r12)
2484         l       %r1,0(%r1):tls_load:foo
2485         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2486         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2487         tls_first_major=2
2488         tls_first_minor=14
2489         tls_as_opt="-m31 --fatal-warnings"
2490         ;;
2491   s390x-*-*)
2492     conftest_s='
2493         .section ".tdata","awT",@progbits
2494 foo:    .long   25
2495         .text
2496         .quad   foo@TLSGD
2497         .quad   foo@TLSLDM
2498         .quad   foo@DTPOFF
2499         .quad   foo@NTPOFF
2500         .quad   foo@GOTNTPOFF
2501         lg      %r1,foo@GOTNTPOFF(%r12)
2502         larl    %r1,foo@INDNTPOFF
2503         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2504         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2505         tls_first_major=2
2506         tls_first_minor=14
2507         tls_as_opt="-m64 -Aesame --fatal-warnings"
2508         ;;
2509   sh-*-* | sh[34]-*-*)
2510     conftest_s='
2511         .section ".tdata","awT",@progbits
2512 foo:    .long   25
2513         .text
2514         .long   foo@TLSGD
2515         .long   foo@TLSLDM
2516         .long   foo@DTPOFF
2517         .long   foo@GOTTPOFF
2518         .long   foo@TPOFF'
2519         tls_first_major=2
2520         tls_first_minor=13
2521         tls_as_opt=--fatal-warnings
2522         ;;
2523   sparc*-*-*)
2524     case "$target" in
2525       sparc*-sun-solaris2.[56789]*)
2526         # TLS was introduced in the Solaris 9 4/04 release but
2527         # we do not enable it by default on Solaris 9 either.
2528         if test "x$enable_tls" = xyes ; then
2529           on_solaris=yes
2530         else
2531           enable_tls=no;
2532         fi
2533         ;;
2534       sparc*-sun-solaris2.*)
2535         on_solaris=yes
2536         ;;
2537       *)
2538         on_solaris=no
2539         ;;
2540     esac
2541     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2542       conftest_s='
2543         .section ".tdata",#alloc,#write,#tls
2544 foo:    .long   25
2545         .text
2546         sethi   %tgd_hi22(foo), %o0
2547         add     %o0, %tgd_lo10(foo), %o1
2548         add     %l7, %o1, %o0, %tgd_add(foo)
2549         call    __tls_get_addr, %tgd_call(foo)
2550         sethi   %tldm_hi22(foo), %l1
2551         add     %l1, %tldm_lo10(foo), %l2
2552         add     %l7, %l2, %o0, %tldm_add(foo)
2553         call    __tls_get_addr, %tldm_call(foo)
2554         sethi   %tldo_hix22(foo), %l3
2555         xor     %l3, %tldo_lox10(foo), %l4
2556         add     %o0, %l4, %l5, %tldo_add(foo)
2557         sethi   %tie_hi22(foo), %o3
2558         add     %o3, %tie_lo10(foo), %o3
2559         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2560         add     %g7, %o2, %o4, %tie_add(foo)
2561         sethi   %tle_hix22(foo), %l1
2562         xor     %l1, %tle_lox10(foo), %o5
2563         ld      [%g7 + %o5], %o1'
2564         tls_first_major=0
2565         tls_first_minor=0
2566     else
2567       conftest_s='
2568         .section ".tdata","awT",@progbits
2569 foo:    .long   25
2570         .text
2571         sethi   %tgd_hi22(foo), %o0
2572         add     %o0, %tgd_lo10(foo), %o1
2573         add     %l7, %o1, %o0, %tgd_add(foo)
2574         call    __tls_get_addr, %tgd_call(foo)
2575         sethi   %tldm_hi22(foo), %l1
2576         add     %l1, %tldm_lo10(foo), %l2
2577         add     %l7, %l2, %o0, %tldm_add(foo)
2578         call    __tls_get_addr, %tldm_call(foo)
2579         sethi   %tldo_hix22(foo), %l3
2580         xor     %l3, %tldo_lox10(foo), %l4
2581         add     %o0, %l4, %l5, %tldo_add(foo)
2582         sethi   %tie_hi22(foo), %o3
2583         add     %o3, %tie_lo10(foo), %o3
2584         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2585         add     %g7, %o2, %o4, %tie_add(foo)
2586         sethi   %tle_hix22(foo), %l1
2587         xor     %l1, %tle_lox10(foo), %o5
2588         ld      [%g7 + %o5], %o1'
2589         tls_first_major=2
2590         tls_first_minor=14
2591         tls_as_opt="-32 --fatal-warnings"
2592       fi
2593         ;;
2594 changequote([,])dnl
2595 esac
2596 set_have_as_tls=no
2597 if test "x$enable_tls" = xno ; then
2598   : # TLS explicitly disabled.
2599 elif test "x$enable_tls" = xyes ; then
2600   set_have_as_tls=yes # TLS explicitly enabled.
2601 elif test -z "$tls_first_major"; then
2602   : # If we don't have a check, assume no support.
2603 else
2604   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2605   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2606   [set_have_as_tls=yes])
2607 fi
2608 if test $set_have_as_tls = yes ; then
2609   AC_DEFINE(HAVE_AS_TLS, 1,
2610             [Define if your assembler supports thread-local storage.])
2611 fi
2612
2613 # Target-specific assembler checks.
2614
2615 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2616 gcc_cv_ld_static_dynamic=no
2617 if test $in_tree_ld = yes ; then
2618   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2619     gcc_cv_ld_static_dynamic=yes
2620   fi
2621 elif test x$gcc_cv_ld != x; then
2622         # Check if linker supports -Bstatic/-Bdynamic option
2623         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2624           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2625                 gcc_cv_ld_static_dynamic=yes
2626         fi
2627 fi
2628 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2629         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2630 [Define if your linker supports -Bstatic/-Bdynamic option.])
2631 fi
2632 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2633
2634 if test x"$demangler_in_ld" = xyes; then
2635   AC_MSG_CHECKING(linker --demangle support)
2636   gcc_cv_ld_demangle=no
2637   if test $in_tree_ld = yes; then
2638     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2639       gcc_cv_ld_demangle=yes
2640     fi
2641   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2642     # Check if the GNU linker supports --demangle option
2643     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2644       gcc_cv_ld_demangle=yes
2645     fi
2646   fi
2647   if test x"$gcc_cv_ld_demangle" = xyes; then
2648     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2649 [Define if your linker supports --demangle option.])
2650   fi
2651   AC_MSG_RESULT($gcc_cv_ld_demangle)
2652 fi
2653
2654 case "$target" in
2655   # All TARGET_ABI_OSF targets.
2656   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2657     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2658         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2659 [       .set nomacro
2660         .text
2661         extbl   $3, $2, $3      !lituse_bytoff!1
2662         ldq     $2, a($29)      !literal!1
2663         ldq     $4, b($29)      !literal!2
2664         ldq_u   $3, 0($2)       !lituse_base!1
2665         ldq     $27, f($29)     !literal!5
2666         jsr     $26, ($27), f   !lituse_jsr!5
2667         ldah    $29, 0($26)     !gpdisp!3
2668         lda     $0, c($29)      !gprel
2669         ldah    $1, d($29)      !gprelhigh
2670         lda     $1, d($1)       !gprellow
2671         lda     $29, 0($29)     !gpdisp!3],,
2672     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2673   [Define if your assembler supports explicit relocations.])])
2674     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2675         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2676 [       .set nomacro
2677         .text
2678         ldq     $27, a($29)     !literal!1
2679         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2680     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2681   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2682     ;;
2683
2684   cris-*-*)
2685     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2686       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2687       [-no-mul-bug-abort], [.text],,
2688       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2689                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2690     ;;
2691
2692   sparc*-*-*)
2693     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2694       [.register %g2, #scratch],,
2695       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2696                 [Define if your assembler supports .register.])])
2697
2698     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2699       [-relax], [.text],,
2700       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2701                 [Define if your assembler supports -relax option.])])
2702
2703     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2704       gcc_cv_as_sparc_ua_pcrel,,
2705       [-K PIC],
2706 [.text
2707 foo:
2708         nop
2709 .data
2710 .align 4
2711 .byte 0
2712 .uaword %r_disp32(foo)],
2713       [if test x$gcc_cv_ld != x \
2714        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2715          gcc_cv_as_sparc_ua_pcrel=yes
2716        fi
2717        rm -f conftest],
2718       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2719                 [Define if your assembler and linker support unaligned PC relative relocs.])
2720
2721       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2722         gcc_cv_as_sparc_ua_pcrel_hidden,,
2723         [-K PIC],
2724 [.data
2725 .align 4
2726 .byte 0x31
2727 .uaword %r_disp32(foo)
2728 .byte 0x32, 0x33, 0x34
2729 .global foo
2730 .hidden foo
2731 foo:
2732 .skip 4],
2733         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2734          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2735          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2736             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2737             if $gcc_cv_objdump -R conftest 2> /dev/null \
2738                | grep 'DISP32' > /dev/null 2>&1; then
2739                 :
2740             else
2741                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2742             fi
2743          fi
2744          rm -f conftest],
2745          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2746                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2747     ]) # unaligned pcrel relocs
2748
2749     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2750       gcc_cv_as_sparc_offsetable_lo10,,
2751       [-xarch=v9],
2752 [.text
2753         or %g1, %lo(ab) + 12, %g1
2754         or %g1, %lo(ab + 12), %g1],
2755       [if test x$gcc_cv_objdump != x \
2756        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2757           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2758          gcc_cv_as_sparc_offsetable_lo10=yes
2759        fi],
2760        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2761                  [Define if your assembler supports offsetable %lo().])])
2762     ;;
2763
2764 changequote(,)dnl
2765   i[34567]86-*-* | x86_64-*-*)
2766 changequote([,])dnl
2767     case $target_os in
2768       cygwin* | pe | mingw32*)
2769         # Used for DWARF 2 in PE
2770         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2771           gcc_cv_as_ix86_pe_secrel32,
2772           [2,15,91],,
2773 [.text
2774 foo:    nop
2775 .data
2776         .secrel32 foo],
2777           [if test x$gcc_cv_ld != x \
2778            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2779              gcc_cv_as_ix86_pe_secrel32=yes
2780            fi
2781            rm -f conftest],
2782           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2783             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2784         ;;
2785     esac
2786
2787     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2788        gcc_cv_as_ix86_filds_fists,
2789       [2,9,0],, [filds mem; fists mem],,
2790       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2791         [Define if your assembler uses the new HImode fild and fist notation.])])
2792
2793     gcc_GAS_CHECK_FEATURE([cmov syntax],
2794       gcc_cv_as_ix86_cmov_sun_syntax,,,
2795       [cmovl.l %edx, %eax],,
2796       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2797         [Define if your assembler supports the Sun syntax for cmov.])])
2798
2799     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2800       gcc_cv_as_ix86_ffreep,,,
2801       [ffreep %st(1)],,
2802       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2803         [Define if your assembler supports the ffreep mnemonic.])])
2804
2805     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2806       gcc_cv_as_ix86_diff_sect_delta,,,
2807       [.section .rodata
2808 .L1:
2809         .long .L2-.L1
2810         .long .L3-.L1
2811         .text
2812 .L3:    nop
2813 .L2:    nop],,
2814       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2815         [Define if your assembler supports the subtraction of symbols in different sections.])])
2816
2817     # This one is used unconditionally by i386.[ch]; it is to be defined
2818     # to 1 if the feature is present, 0 otherwise.
2819     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2820         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2821 [       .text
2822 .L0:
2823         nop
2824         .data
2825         .long .L0@GOTOFF])
2826     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2827       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2828       [Define true if the assembler supports '.long foo@GOTOFF'.])
2829     ;;
2830
2831   ia64*-*-*)
2832     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2833         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2834 [       .text
2835         addl r15 = @ltoffx(x#), gp
2836         ;;
2837         ld8.mov r16 = [[r15]], x#],,
2838     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2839           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2840
2841     ;;
2842
2843   powerpc*-*-*)
2844     case $target in
2845       *-*-aix*) conftest_s='    .machine "pwr5"
2846         .csect .text[[PR]]
2847         mfcr 3,128';;
2848       *-*-darwin*)
2849         gcc_GAS_CHECK_FEATURE([.machine directive support],
2850           gcc_cv_as_machine_directive,,,
2851           [     .machine ppc7400])
2852         if test x$gcc_cv_as_machine_directive != xyes; then
2853           echo "*** This target requires an assembler supporting \".machine\"" >&2
2854           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2855           test x$build = x$target && exit 1
2856         fi
2857         conftest_s='    .text
2858         mfcr r3,128';;
2859       *) conftest_s='   .machine power4
2860         .text
2861         mfcr 3,128';;
2862     esac
2863
2864     gcc_GAS_CHECK_FEATURE([mfcr field support],
2865       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2866       [$conftest_s],,
2867       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2868           [Define if your assembler supports mfcr field.])])
2869
2870     case $target in
2871       *-*-aix*) conftest_s='    .machine "pwr5"
2872         .csect .text[[PR]]
2873         popcntb 3,3';;
2874       *) conftest_s='   .machine power5
2875         .text
2876         popcntb 3,3';;
2877     esac
2878
2879     gcc_GAS_CHECK_FEATURE([popcntb support],
2880       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2881       [$conftest_s],,
2882       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2883           [Define if your assembler supports popcntb field.])])
2884
2885     case $target in
2886       *-*-aix*) conftest_s='    .machine "pwr5x"
2887         .csect .text[[PR]]
2888         frin 1,1';;
2889       *) conftest_s='   .machine power5
2890         .text
2891         frin 1,1';;
2892     esac
2893
2894     gcc_GAS_CHECK_FEATURE([fp round support],
2895       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2896       [$conftest_s],,
2897       [AC_DEFINE(HAVE_AS_FPRND, 1,
2898           [Define if your assembler supports fprnd.])])
2899
2900     case $target in
2901       *-*-aix*) conftest_s='    .machine "pwr6"
2902         .csect .text[[PR]]
2903         mffgpr 1,3';;
2904       *) conftest_s='   .machine power6
2905         .text
2906         mffgpr 1,3';;
2907     esac
2908
2909     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2910       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2911       [$conftest_s],,
2912       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2913           [Define if your assembler supports mffgpr and mftgpr.])])
2914
2915     case $target in
2916       *-*-aix*) conftest_s='    .csect .text[[PR]]
2917 LCF..0:
2918         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2919       *-*-darwin*)
2920         conftest_s='    .text
2921 LCF0:
2922         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2923       *) conftest_s='   .text
2924 .LCF0:
2925         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2926     esac
2927
2928     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2929       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2930       [$conftest_s],,
2931       [AC_DEFINE(HAVE_AS_REL16, 1,
2932           [Define if your assembler supports R_PPC_REL16 relocs.])])
2933     ;;
2934
2935   mips*-*-*)
2936     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2937       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2938 [       lw $4,%gp_rel(foo)($4)],,
2939       [if test x$target_cpu_default = x
2940        then target_cpu_default=MASK_EXPLICIT_RELOCS
2941        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2942        fi])
2943     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2944       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2945       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2946                  [Define if the assembler understands -mno-shared.])])
2947     ;;
2948 esac
2949
2950 # Mips and HP-UX need the GNU assembler.
2951 # Linux on IA64 might be able to use the Intel assembler.
2952
2953 case "$target" in
2954   mips*-*-* | *-*-hpux* )
2955     if test x$gas_flag = xyes \
2956        || test x"$host" != x"$build" \
2957        || test ! -x "$gcc_cv_as" \
2958        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2959       :
2960     else
2961       echo "*** This configuration requires the GNU assembler" >&2
2962       exit 1
2963     fi
2964     ;;
2965 esac
2966
2967 # ??? Not all targets support dwarf2 debug_line, even within a version
2968 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2969 # info to the output file.  So, as supported targets are added to gas 2.11,
2970 # add some instruction here to (also) show we expect this might work.
2971 # ??? Once 2.11 is released, probably need to add first known working
2972 # version to the per-target configury.
2973 case "$target" in
2974   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2975   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2976   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
2977     insn="nop"
2978     ;;
2979   ia64*-*-* | s390*-*-*)
2980     insn="nop 0"
2981     ;;
2982   mmix-*-*)
2983     insn="swym 0"
2984     ;;
2985 esac
2986 if test x"$insn" != x; then
2987  conftest_s="\
2988         .file 1 \"conftest.s\"
2989         .loc 1 3 0
2990         $insn"
2991  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2992   gcc_cv_as_dwarf2_debug_line,
2993   [elf,2,11,0],, [$conftest_s],
2994   [if test x$gcc_cv_objdump != x \
2995    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2996       | grep debug_line > /dev/null 2>&1; then
2997      gcc_cv_as_dwarf2_debug_line=yes
2998    fi])
2999
3000 # The .debug_line file table must be in the exact order that
3001 # we specified the files, since these indices are also used
3002 # by DW_AT_decl_file.  Approximate this test by testing if
3003 # the assembler bitches if the same index is assigned twice.
3004  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3005   gcc_cv_as_dwarf2_file_buggy,,,
3006 [       .file 1 "foo.s"
3007         .file 1 "bar.s"])
3008
3009  if test $gcc_cv_as_dwarf2_debug_line = yes \
3010  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3011         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3012   [Define if your assembler supports dwarf2 .file/.loc directives,
3013    and preserves file table indices exactly as given.])
3014  fi
3015
3016  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3017   gcc_cv_as_gdwarf2_flag,
3018   [elf,2,11,0], [--gdwarf2], [$insn],,
3019   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3020 [Define if your assembler supports the --gdwarf2 option.])])
3021
3022  gcc_GAS_CHECK_FEATURE([--gstabs option],
3023   gcc_cv_as_gstabs_flag,
3024   [elf,2,11,0], [--gstabs], [$insn],
3025   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3026    # and warns about it, but still exits successfully.  So check for
3027    # this.
3028    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3029    then :
3030    else gcc_cv_as_gstabs_flag=yes
3031    fi],
3032   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3033 [Define if your assembler supports the --gstabs option.])])
3034 fi
3035
3036 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3037 gcc_cv_ld_ro_rw_mix=unknown
3038 if test $in_tree_ld = yes ; then
3039   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3040      && test $in_tree_ld_is_elf = yes; then
3041     gcc_cv_ld_ro_rw_mix=read-write
3042   fi
3043 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3044   echo '.section myfoosect, "a"' > conftest1.s
3045   echo '.section myfoosect, "aw"' > conftest2.s
3046   echo '.byte 1' >> conftest2.s
3047   echo '.section myfoosect, "a"' > conftest3.s
3048   echo '.byte 0' >> conftest3.s
3049   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3050      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3051      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3052      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3053         conftest2.o conftest3.o > /dev/null 2>&1; then
3054     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3055                          | sed -e '/myfoosect/!d' -e N`
3056     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3057       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3058         gcc_cv_ld_ro_rw_mix=read-only
3059       else
3060         gcc_cv_ld_ro_rw_mix=read-write
3061       fi
3062     fi
3063   fi
3064 changequote(,)dnl
3065   rm -f conftest.* conftest[123].*
3066 changequote([,])dnl
3067 fi
3068 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3069         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3070   [Define if your linker links a mix of read-only
3071    and read-write sections into a read-write section.])
3072 fi
3073 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3074
3075 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3076 gcc_cv_ld_eh_frame_hdr=no
3077 if test $in_tree_ld = yes ; then
3078   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3079      && test $in_tree_ld_is_elf = yes; then
3080     gcc_cv_ld_eh_frame_hdr=yes
3081   fi
3082 elif test x$gcc_cv_ld != x; then
3083         # Check if linker supports --eh-frame-hdr option
3084         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3085                 gcc_cv_ld_eh_frame_hdr=yes
3086         fi
3087 fi
3088 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3089 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3090         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3091 [Define if your linker supports --eh-frame-hdr option.])
3092 fi
3093 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3094
3095 AC_MSG_CHECKING(linker position independent executable support)
3096 gcc_cv_ld_pie=no
3097 if test $in_tree_ld = yes ; then
3098   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3099      && test $in_tree_ld_is_elf = yes; then
3100     gcc_cv_ld_pie=yes
3101   fi
3102 elif test x$gcc_cv_ld != x; then
3103         # Check if linker supports -pie option
3104         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3105                 gcc_cv_ld_pie=yes
3106         fi
3107 fi
3108 if test x"$gcc_cv_ld_pie" = xyes; then
3109         AC_DEFINE(HAVE_LD_PIE, 1,
3110 [Define if your linker supports -pie option.])
3111 fi
3112 AC_MSG_RESULT($gcc_cv_ld_pie)
3113
3114 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3115 gcc_cv_ld_eh_gc_sections=no
3116 if test $in_tree_ld = yes ; then
3117   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3118      && test $in_tree_ld_is_elf = yes; then
3119     gcc_cv_ld_eh_gc_sections=yes
3120   fi
3121 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3122   cat > conftest.s <<EOF
3123         .section        .text
3124 .globl _start
3125         .type _start, @function
3126 _start:
3127         .long foo
3128         .size _start, .-_start
3129         .section        .text.foo,"ax",@progbits
3130         .type foo, @function
3131 foo:
3132         .long 0
3133         .size foo, .-foo
3134         .section        .gcc_except_table.foo,"a",@progbits
3135 .L0:
3136         .long 0
3137         .section        .eh_frame,"a",@progbits
3138         .long .L0
3139 EOF
3140   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3141     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3142          | grep "gc-sections option ignored" > /dev/null; then
3143       gcc_cv_ld_eh_gc_sections=no
3144     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3145       gcc_cv_ld_eh_gc_sections=yes
3146       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3147       if test x$gcc_cv_as_comdat_group != xyes; then
3148         gcc_cv_ld_eh_gc_sections=no
3149         cat > conftest.s <<EOF
3150         .section        .text
3151 .globl _start
3152         .type _start, @function
3153 _start:
3154         .long foo
3155         .size _start, .-_start
3156         .section        .gnu.linkonce.t.foo,"ax",@progbits
3157         .type foo, @function
3158 foo:
3159         .long 0
3160         .size foo, .-foo
3161         .section        .gcc_except_table.foo,"a",@progbits
3162 .L0:
3163         .long 0
3164         .section        .eh_frame,"a",@progbits
3165         .long .L0
3166 EOF
3167         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3168           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3169                | grep "gc-sections option ignored" > /dev/null; then
3170             gcc_cv_ld_eh_gc_sections=no
3171           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3172             gcc_cv_ld_eh_gc_sections=yes
3173           fi
3174         fi
3175       fi
3176     fi
3177   fi
3178   rm -f conftest.s conftest.o conftest
3179 fi
3180 case "$target" in
3181   hppa*-*-linux*)
3182     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3183     gcc_cv_ld_eh_gc_sections=no
3184     ;;
3185 esac
3186 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3187         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3188   [Define if your linker supports garbage collection of
3189    sections in presence of EH frames.])
3190 fi
3191 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3192
3193 # --------
3194 # UNSORTED
3195 # --------
3196
3197 AC_CACHE_CHECK(linker --as-needed support,
3198 gcc_cv_ld_as_needed,
3199 [gcc_cv_ld_as_needed=no
3200 if test $in_tree_ld = yes ; then
3201   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3202      && test $in_tree_ld_is_elf = yes; then
3203     gcc_cv_ld_as_needed=yes
3204   fi
3205 elif test x$gcc_cv_ld != x; then
3206         # Check if linker supports --as-needed and --no-as-needed options
3207         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3208                 gcc_cv_ld_as_needed=yes
3209         fi
3210 fi
3211 ])
3212 if test x"$gcc_cv_ld_as_needed" = xyes; then
3213         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3214 [Define if your linker supports --as-needed and --no-as-needed options.])
3215 fi
3216
3217 case "$target:$tm_file" in
3218   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3219     AC_CACHE_CHECK(linker support for omitting dot symbols,
3220     gcc_cv_ld_no_dot_syms,
3221     [gcc_cv_ld_no_dot_syms=no
3222     if test $in_tree_ld = yes ; then
3223       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3224         gcc_cv_ld_no_dot_syms=yes
3225       fi
3226     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3227       cat > conftest1.s <<EOF
3228         .text
3229         bl .foo
3230 EOF
3231       cat > conftest2.s <<EOF
3232         .section ".opd","aw"
3233         .align 3
3234         .globl foo
3235         .type foo,@function
3236 foo:
3237         .quad .LEfoo,.TOC.@tocbase,0
3238         .text
3239 .LEfoo:
3240         blr
3241         .size foo,.-.LEfoo
3242 EOF
3243       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3244          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3245          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3246         gcc_cv_ld_no_dot_syms=yes
3247       fi
3248       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3249     fi
3250     ])
3251     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3252       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3253     [Define if your PowerPC64 linker only needs function descriptor syms.])
3254     fi
3255     ;;
3256 esac
3257
3258 AC_CACHE_CHECK(linker --sysroot support,
3259   gcc_cv_ld_sysroot,
3260   [gcc_cv_ld_sysroot=no
3261   if test $in_tree_ld = yes ; then
3262       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3263         gcc_cv_ld_sysroot=yes
3264       fi
3265   elif test x$gcc_cv_ld != x; then
3266     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3267       gcc_cv_ld_sysroot=yes
3268     fi
3269   fi])
3270 if test x"$gcc_cv_ld_sysroot" = xyes; then
3271   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3272   [Define if your linker supports --sysroot.])
3273 fi
3274
3275 if test x$with_sysroot = x && test x$host = x$target \
3276    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3277    && test "$prefix" != "NONE"; then
3278   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3279 [Define to PREFIX/include if cpp should also search that directory.])
3280 fi
3281
3282 # Test for stack protector support in target C library.
3283 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3284       gcc_cv_libc_provides_ssp,
3285       [gcc_cv_libc_provides_ssp=no
3286     case "$target" in
3287        *-*-linux*)
3288       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3289         if test "x$with_sysroot" = x; then
3290           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3291         elif test "x$with_sysroot" = xyes; then
3292           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3293         else
3294           glibc_header_dir="${with_sysroot}/usr/include"
3295         fi
3296       else
3297         glibc_header_dir=/usr/include
3298       fi
3299       # glibc 2.4 and later provides __stack_chk_fail and
3300       # either __stack_chk_guard, or TLS access to stack guard canary.
3301       if test -f $glibc_header_dir/features.h \
3302          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3303             $glibc_header_dir/features.h > /dev/null; then
3304         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3305            $glibc_header_dir/features.h > /dev/null; then
3306           gcc_cv_libc_provides_ssp=yes
3307         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3308              $glibc_header_dir/features.h > /dev/null \
3309              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3310              $glibc_header_dir/features.h > /dev/null; then
3311           gcc_cv_libc_provides_ssp=yes
3312         fi
3313         fi
3314         ;;
3315        *-*-darwin*)
3316          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3317            [echo "no __stack_chk_fail on this target"])
3318         ;;
3319   *) gcc_cv_libc_provides_ssp=no ;;
3320     esac])
3321
3322 if test x$gcc_cv_libc_provides_ssp = xyes; then
3323   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3324             [Define if your target C library provides stack protector support])
3325 fi
3326
3327 # Check if TFmode long double should be used by default or not.
3328 # Some glibc targets used DFmode long double, but with glibc 2.4
3329 # and later they can use TFmode.
3330 case "$target" in
3331   powerpc*-*-*gnu* | \
3332   sparc*-*-linux* | \
3333   s390*-*-linux* | \
3334   alpha*-*-linux*)
3335     AC_ARG_WITH(long-double-128,
3336 [  --with-long-double-128  Use 128-bit long double by default.],
3337       gcc_cv_target_ldbl128="$with_long_double_128",
3338       [gcc_cv_target_ldbl128=no
3339       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3340         if test "x$with_sysroot" = x; then
3341           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3342         elif test "x$with_sysroot" = xyes; then
3343           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3344         else
3345           glibc_header_dir="${with_sysroot}/usr/include"
3346         fi
3347       else
3348         glibc_header_dir=/usr/include
3349       fi
3350 changequote(,)dnl
3351       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3352         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3353       && gcc_cv_target_ldbl128=yes
3354 changequote([,])dnl
3355       ])
3356     ;;
3357 esac
3358 if test x$gcc_cv_target_ldbl128 = xyes; then
3359   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3360             [Define if TFmode long double should be the default])
3361 fi
3362
3363 # Find out what GC implementation we want, or may, use.
3364 AC_ARG_WITH(gc,
3365 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3366                           with the compiler],
3367 [case "$withval" in
3368   page)
3369     GGC=ggc-$withval
3370     ;;
3371   zone)
3372     GGC=ggc-$withval
3373     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3374     ;;
3375   *)
3376     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3377     ;;
3378 esac],
3379 [GGC=ggc-page])
3380 AC_SUBST(GGC)
3381 echo "Using $GGC for garbage collection."
3382
3383 # Use the system's zlib library.
3384 zlibdir=-L../zlib
3385 zlibinc="-I\$(srcdir)/../zlib"
3386 AC_ARG_WITH(system-zlib,
3387 [  --with-system-zlib      use installed libz],
3388 zlibdir=
3389 zlibinc=
3390 )
3391 AC_SUBST(zlibdir)
3392 AC_SUBST(zlibinc)
3393
3394 dnl Very limited version of automake's enable-maintainer-mode
3395
3396 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3397   dnl maintainer-mode is disabled by default
3398   AC_ARG_ENABLE(maintainer-mode,
3399 [  --enable-maintainer-mode
3400                           enable make rules and dependencies not useful
3401                           (and sometimes confusing) to the casual installer],
3402       maintainer_mode=$enableval,
3403       maintainer_mode=no)
3404
3405 AC_MSG_RESULT($maintainer_mode)
3406
3407 if test "$maintainer_mode" = "yes"; then
3408   MAINT=''
3409 else
3410   MAINT='#'
3411 fi
3412 AC_SUBST(MAINT)dnl
3413
3414 # --------------
3415 # Language hooks
3416 # --------------
3417
3418 # Make empty files to contain the specs and options for each language.
3419 # Then add #include lines to for a compiler that has specs and/or options.
3420
3421 subdirs=
3422 lang_opt_files=
3423 lang_specs_files=
3424 lang_tree_files=
3425 # These (without "all_") are set in each config-lang.in.
3426 # `language' must be a single word so is spelled singularly.
3427 all_languages=
3428 all_compilers=
3429 all_outputs='Makefile gccbug libada-mk'
3430 # List of language makefile fragments.
3431 all_lang_makefrags=
3432 # List of language subdirectory makefiles.  Deprecated.
3433 all_lang_makefiles=
3434 # Files for gengtype
3435 all_gtfiles="$target_gtfiles"
3436 # Files for gengtype with language
3437 all_gtfiles_files_langs=
3438 all_gtfiles_files_files=
3439
3440 # These are the languages that are set in --enable-languages,
3441 # and are available in the GCC tree.
3442 all_selected_languages=
3443
3444 # Add the language fragments.
3445 # Languages are added via two mechanisms.  Some information must be
3446 # recorded in makefile variables, these are defined in config-lang.in.
3447 # We accumulate them and plug them into the main Makefile.
3448 # The other mechanism is a set of hooks for each of the main targets
3449 # like `clean', `install', etc.
3450
3451 language_hooks="Make-hooks"
3452
3453 for lang in ${srcdir}/*/config-lang.in
3454 do
3455 changequote(,)dnl
3456         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3457
3458         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3459         if test "x$lang_alias" = x
3460         then
3461               echo "$lang doesn't set \$language." 1>&2
3462               exit 1
3463         fi
3464         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3465         subdirs="$subdirs $subdir"
3466         case ",$enable_languages," in
3467         *,$lang_alias,*)
3468             all_selected_languages="$all_selected_languages $lang_alias"
3469             if test -f $srcdir/$subdir/lang-specs.h; then
3470                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3471             fi
3472             ;;
3473         esac
3474 changequote([,])dnl
3475
3476         language=
3477         boot_language=
3478         compilers=
3479         outputs=
3480         gtfiles=
3481         subdir_requires=
3482         . ${srcdir}/$subdir/config-lang.in
3483         if test "x$language" = x
3484         then
3485                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3486                 exit 1
3487         fi
3488
3489         ok=:
3490         case ",$enable_languages," in
3491                 *,$lang_alias,*) ;;
3492                 *)
3493                         for i in $subdir_requires; do
3494                                 test -f "${srcdir}/$i/config-lang.in" && continue
3495                                 ok=false
3496                                 break
3497                         done
3498                 ;;
3499         esac
3500         $ok || continue
3501
3502         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3503         if test -f $srcdir/$subdir/lang.opt; then
3504             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3505         fi
3506         if test -f $srcdir/$subdir/$subdir-tree.def; then
3507             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3508         fi
3509         if test -f ${srcdir}/$subdir/Makefile.in
3510                 then all_lang_makefiles="$subdir/Makefile"
3511         fi
3512         all_languages="$all_languages $language"
3513         all_compilers="$all_compilers $compilers"
3514         all_outputs="$all_outputs $outputs"
3515         all_gtfiles="$all_gtfiles $gtfiles"
3516         for f in $gtfiles
3517         do
3518                 all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3519                 all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3520         done
3521 done
3522
3523 # Pick up gtfiles for c
3524 gtfiles=
3525 subdir="c"
3526 . ${srcdir}/c-config-lang.in
3527 all_gtfiles="$all_gtfiles $gtfiles"
3528 for f in $gtfiles
3529 do
3530         all_gtfiles_files_langs="$all_gtfiles_files_langs ${subdir} "
3531         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3532 done
3533
3534 check_languages=
3535 for language in $all_selected_languages
3536 do
3537         check_languages="$check_languages check-$language"
3538 done
3539
3540 # We link each language in with a set of hooks, reached indirectly via
3541 # lang.${target}.  Only do so for selected languages.
3542
3543 rm -f Make-hooks
3544 touch Make-hooks
3545 target_list="all.cross start.encap rest.encap tags \
3546         install-common install-man install-info dvi pdf html \
3547         uninstall info man srcextra srcman srcinfo \
3548         mostlyclean clean distclean maintainer-clean"
3549
3550 for t in $target_list
3551 do
3552         x=
3553         for lang in $all_selected_languages
3554         do
3555                 x="$x $lang.$t"
3556         done
3557         echo "lang.$t: $x" >> Make-hooks
3558 done
3559
3560 # --------
3561 # UNSORTED
3562 # --------
3563
3564 # Create .gdbinit.
3565
3566 echo "dir ." > .gdbinit
3567 echo "dir ${srcdir}" >> .gdbinit
3568 if test x$gdb_needs_out_file_path = xyes
3569 then
3570         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3571 fi
3572 if test "x$subdirs" != x; then
3573         for s in $subdirs
3574         do
3575                 echo "dir ${srcdir}/$s" >> .gdbinit
3576         done
3577 fi
3578 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3579
3580 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3581 # absolute path for gcc_tooldir based on inserting the number of up-directory
3582 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3583 # $(libsubdir)/@(unlibsubdir) based path.
3584 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3585 # make and thus we'd get different behavior depending on where we built the
3586 # sources.
3587 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3588     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3589 else
3590 changequote(<<, >>)dnl
3591 # An explanation of the sed strings:
3592 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3593 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3594 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3595 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3596 #
3597 # (*) Note this pattern overwrites the first character of the string
3598 # with a forward slash if one is not already present.  This is not a
3599 # problem because the exact names of the sub-directories concerned is
3600 # unimportant, just the number of them matters.
3601 #
3602 # The practical upshot of these patterns is like this:
3603 #
3604 #  prefix     exec_prefix        result
3605 #  ------     -----------        ------
3606 #   /foo        /foo/bar          ../
3607 #   /foo/       /foo/bar          ../
3608 #   /foo        /foo/bar/         ../
3609 #   /foo/       /foo/bar/         ../
3610 #   /foo        /foo/bar/ugg      ../../
3611 #
3612     dollar='$$'
3613     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3614 changequote([, ])dnl
3615 fi
3616 AC_SUBST(gcc_tooldir)
3617 AC_SUBST(dollar)
3618
3619 # Find a directory in which to install a shared libgcc.
3620
3621 AC_ARG_ENABLE(version-specific-runtime-libs,
3622 [  --enable-version-specific-runtime-libs
3623                           specify that runtime libraries should be
3624                           installed in a compiler-specific directory])
3625
3626 AC_ARG_WITH(slibdir,
3627 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3628 slibdir="$with_slibdir",
3629 if test "${enable_version_specific_runtime_libs+set}" = set; then
3630   slibdir='$(libsubdir)'
3631 elif test "$host" != "$target"; then
3632   slibdir='$(build_tooldir)/lib'
3633 else
3634   slibdir='$(libdir)'
3635 fi)
3636 AC_SUBST(slibdir)
3637
3638 objdir=`${PWDCMD-pwd}`
3639 AC_SUBST(objdir)
3640
3641 AC_ARG_WITH(datarootdir,
3642 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3643 datarootdir="\${prefix}/$with_datarootdir",
3644 datarootdir='$(prefix)/share')
3645 AC_SUBST(datarootdir)
3646
3647 AC_ARG_WITH(docdir,
3648 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3649 docdir="\${prefix}/$with_docdir",
3650 docdir='$(datarootdir)')
3651 AC_SUBST(docdir)
3652
3653 AC_ARG_WITH(htmldir,
3654 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3655 htmldir="\${prefix}/$with_htmldir",
3656 htmldir='$(docdir)')
3657 AC_SUBST(htmldir)
3658
3659 # Substitute configuration variables
3660 AC_SUBST(subdirs)
3661 AC_SUBST(srcdir)
3662 AC_SUBST(all_compilers)
3663 AC_SUBST(all_gtfiles)
3664 AC_SUBST(all_gtfiles_files_langs)
3665 AC_SUBST(all_gtfiles_files_files)
3666 AC_SUBST(all_lang_makefrags)
3667 AC_SUBST(all_lang_makefiles)
3668 AC_SUBST(all_languages)
3669 AC_SUBST(all_selected_languages)
3670 AC_SUBST(build_exeext)
3671 AC_SUBST(build_install_headers_dir)
3672 AC_SUBST(build_xm_file_list)
3673 AC_SUBST(build_xm_include_list)
3674 AC_SUBST(build_xm_defines)
3675 AC_SUBST(check_languages)
3676 AC_SUBST(cpp_install_dir)
3677 AC_SUBST(xmake_file)
3678 AC_SUBST(tmake_file)
3679 AC_SUBST(extra_gcc_objs)
3680 AC_SUBST(extra_headers_list)
3681 AC_SUBST(extra_objs)
3682 AC_SUBST(extra_parts)
3683 AC_SUBST(extra_passes)
3684 AC_SUBST(extra_programs)
3685 AC_SUBST(float_h_file)
3686 AC_SUBST(gcc_config_arguments)
3687 AC_SUBST(gcc_gxx_include_dir)
3688 AC_SUBST(host_exeext)
3689 AC_SUBST(host_xm_file_list)
3690 AC_SUBST(host_xm_include_list)
3691 AC_SUBST(host_xm_defines)
3692 AC_SUBST(out_host_hook_obj)
3693 AC_SUBST(install)
3694 AC_SUBST(lang_opt_files)
3695 AC_SUBST(lang_specs_files)
3696 AC_SUBST(lang_tree_files)
3697 AC_SUBST(local_prefix)
3698 AC_SUBST(md_file)
3699 AC_SUBST(objc_boehm_gc)
3700 AC_SUBST(out_file)
3701 AC_SUBST(out_object_file)
3702 AC_SUBST(thread_file)
3703 AC_SUBST(tm_file_list)
3704 AC_SUBST(tm_include_list)
3705 AC_SUBST(tm_defines)
3706 AC_SUBST(tm_p_file_list)
3707 AC_SUBST(tm_p_include_list)
3708 AC_SUBST(xm_file_list)
3709 AC_SUBST(xm_include_list)
3710 AC_SUBST(xm_defines)
3711 AC_SUBST(c_target_objs)
3712 AC_SUBST(cxx_target_objs)
3713 AC_SUBST(target_cpu_default)
3714
3715 AC_SUBST_FILE(language_hooks)
3716
3717 # Echo link setup.
3718 if test x${build} = x${host} ; then
3719   if test x${host} = x${target} ; then
3720     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3721   else
3722     echo "Links are now set up to build a cross-compiler" 1>&2
3723     echo " from ${host} to ${target}." 1>&2
3724   fi
3725 else
3726   if test x${host} = x${target} ; then
3727     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3728     echo " for ${target}." 1>&2
3729   else
3730     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3731     echo " from ${host} to ${target}." 1>&2
3732   fi
3733 fi
3734
3735 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3736 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3737
3738 # Configure the subdirectories
3739 # AC_CONFIG_SUBDIRS($subdirs)
3740
3741 # Create the Makefile
3742 # and configure language subdirectories
3743 AC_CONFIG_FILES($all_outputs)
3744
3745 AC_CONFIG_COMMANDS([default],
3746 [
3747 case ${CONFIG_HEADERS} in
3748   *auto-host.h:config.in*)
3749   echo > cstamp-h ;;
3750 esac
3751 # Make sure all the subdirs exist.
3752 for d in $subdirs doc build
3753 do
3754     test -d $d || mkdir $d
3755 done
3756 ],
3757 [subdirs='$subdirs'])
3758 AC_OUTPUT