gcc/c-parse.in

   1 /* YACC parser for C syntax and for Objective C.  -*-c-*-
   2    Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996,
   3    1997, 1998, 1999, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 2, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GCC; see the file COPYING.  If not, write to the Free
  19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 02111-1307, USA.  */
  21
  22 /* This file defines the grammar of C and that of Objective C.
  23    @@ifobjc ... @@end_ifobjc  conditionals contain code for Objective C only.
  24    @@ifc ... @@end_ifc  conditionals contain code for C only.
  25    Sed commands in Makefile.in are used to convert this file into
  26    c-parse.y and into objc-parse.y.  */
  27
  28 /* To whomever it may concern: I have heard that such a thing was once
  29    written by AT&T, but I have never seen it.  */
  30
  31 @@ifc
  32 %expect 10 /* shift/reduce conflicts, and no reduce/reduce conflicts.  */
  33 @@end_ifc
  34
  35 %{
  36 #include "config.h"
  37 #include "system.h"
  38 #include "coretypes.h"
  39 #include "tm.h"
  40 #include "tree.h"
  41 #include "input.h"
  42 #include "cpplib.h"
  43 #include "intl.h"
  44 #include "timevar.h"
  45 #include "c-pragma.h"           /* For YYDEBUG definition, and parse_in.  */
  46 #include "c-tree.h"
  47 #include "flags.h"
  48 #include "varray.h"
  49 #include "output.h"
  50 #include "toplev.h"
  51 #include "ggc.h"
  52
  53 @@ifobjc
  54 #include "objc-act.h"
  55 @@end_ifobjc
  56
  57 /* Like YYERROR but do call yyerror.  */
  58 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
  59
  60 /* Like the default stack expander, except (1) use realloc when possible,
  61    (2) impose no hard maxiumum on stack size, (3) REALLY do not use alloca.
  62
  63    Irritatingly, YYSTYPE is defined after this %{ %} block, so we cannot
  64    give malloced_yyvs its proper type.  This is ok since all we need from
  65    it is to be able to free it.  */
  66
  67 static short *malloced_yyss;
  68 static void *malloced_yyvs;
  69
  70 #define yyoverflow(MSG, SS, SSSIZE, VS, VSSIZE, YYSSZ)                  \
  71 do {                                                                    \
  72   size_t newsize;                                                       \
  73   short *newss;                                                         \
  74   YYSTYPE *newvs;                                                       \
  75   newsize = *(YYSSZ) *= 2;                                              \
  76   if (malloced_yyss)                                                    \
  77     {                                                                   \
  78       newss = really_call_realloc (*(SS), newsize * sizeof (short));    \
  79       newvs = really_call_realloc (*(VS), newsize * sizeof (YYSTYPE));  \
  80     }                                                                   \
  81   else                                                                  \
  82     {                                                                   \
  83       newss = really_call_malloc (newsize * sizeof (short));            \
  84       newvs = really_call_malloc (newsize * sizeof (YYSTYPE));          \
  85       if (newss)                                                        \
  86         memcpy (newss, *(SS), (SSSIZE));                                \
  87       if (newvs)                                                        \
  88         memcpy (newvs, *(VS), (VSSIZE));                                \
  89     }                                                                   \
  90   if (!newss || !newvs)                                                 \
  91     {                                                                   \
  92       yyerror (MSG);                                                    \
  93       return 2;                                                         \
  94     }                                                                   \
  95   *(SS) = newss;                                                        \
  96   *(VS) = newvs;                                                        \
  97   malloced_yyss = newss;                                                \
  98   malloced_yyvs = (void *) newvs;                                       \
  99 } while (0)
 100 %}
 101
 102 %start program
 103
 104 %union {long itype; tree ttype; enum tree_code code;
 105         location_t location; }
 106
 107 /* All identifiers that are not reserved words
 108    and are not declared typedefs in the current block */
 109 %token IDENTIFIER
 110
 111 /* All identifiers that are declared typedefs in the current block.
 112    In some contexts, they are treated just like IDENTIFIER,
 113    but they can also serve as typespecs in declarations.  */
 114 %token TYPENAME
 115
 116 /* Reserved words that specify storage class.
 117    yylval contains an IDENTIFIER_NODE which indicates which one.  */
 118 %token SCSPEC                   /* Storage class other than static.  */
 119 %token STATIC                   /* Static storage class.  */
 120
 121 /* Reserved words that specify type.
 122    yylval contains an IDENTIFIER_NODE which indicates which one.  */
 123 %token TYPESPEC
 124
 125 /* Reserved words that qualify type: "const", "volatile", or "restrict".
 126    yylval contains an IDENTIFIER_NODE which indicates which one.  */
 127 %token TYPE_QUAL
 128
 129 /* Character or numeric constants.
 130    yylval is the node for the constant.  */
 131 %token CONSTANT
 132
 133 /* String constants in raw form.
 134    yylval is a STRING_CST node.  */
 135
 136 %token STRING
 137
 138 /* "...", used for functions with variable arglists.  */
 139 %token ELLIPSIS
 140
 141 /* the reserved words */
 142 /* SCO include files test "ASM", so use something else. */
 143 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
 144 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
 145 %token ATTRIBUTE EXTENSION LABEL
 146 %token REALPART IMAGPART VA_ARG CHOOSE_EXPR TYPES_COMPATIBLE_P
 147 %token PTR_VALUE PTR_BASE PTR_EXTENT
 148 %token FUNC_NAME
 149
 150 /* Add precedence rules to solve dangling else s/r conflict */
 151 %nonassoc IF
 152 %nonassoc ELSE
 153
 154 /* Define the operator tokens and their precedences.
 155    The value is an integer because, if used, it is the tree code
 156    to use in the expression made from the operator.  */
 157
 158 %right <code> ASSIGN '='
 159 %right <code> '?' ':'
 160 %left <code> OROR
 161 %left <code> ANDAND
 162 %left <code> '|'
 163 %left <code> '^'
 164 %left <code> '&'
 165 %left <code> EQCOMPARE
 166 %left <code> ARITHCOMPARE
 167 %left <code> LSHIFT RSHIFT
 168 %left <code> '+' '-'
 169 %left <code> '*' '/' '%'
 170 %right <code> UNARY PLUSPLUS MINUSMINUS
 171 %left HYPERUNARY
 172 %left <code> POINTSAT '.' '(' '['
 173
 174 /* The Objective-C keywords.  These are included in C and in
 175    Objective C, so that the token codes are the same in both.  */
 176 %token INTERFACE IMPLEMENTATION END SELECTOR DEFS ENCODE
 177 %token CLASSNAME PUBLIC PRIVATE PROTECTED PROTOCOL OBJECTNAME CLASS ALIAS
 178 %token AT_THROW AT_TRY AT_CATCH AT_FINALLY AT_SYNCHRONIZED
 179 %token OBJC_STRING
 180
 181 %type <code> unop
 182 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
 183 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
 184
 185 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT expr nonnull_exprlist exprlist
 186 %type <ttype> expr_no_commas cast_expr unary_expr primary STRING
 187 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
 188 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
 189 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
 190 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
 191 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
 192 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
 193 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
 194 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
 195 %type <ttype> declspecs_ts declspecs_nots
 196 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
 197 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
 198 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
 199 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
 200 %type <ttype> typespec_nonreserved_nonattr
 201
 202 %type <ttype> scspec SCSPEC STATIC TYPESPEC TYPE_QUAL maybe_type_qual
 203 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl
 204 %type <ttype> init maybeasm
 205 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
 206 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
 207 %type <ttype> any_word extension
 208
 209 %type <ttype> compstmt compstmt_start compstmt_nostart compstmt_primary_start
 210 %type <ttype> do_stmt_start poplevel stmt label
 211
 212 %type <ttype> c99_block_start c99_block_end
 213 %type <ttype> declarator
 214 %type <ttype> notype_declarator after_type_declarator
 215 %type <ttype> parm_declarator
 216 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
 217 %type <ttype> array_declarator
 218
 219 %type <ttype> structsp_attr structsp_nonattr
 220 %type <ttype> component_decl_list component_decl_list2
 221 %type <ttype> component_decl components components_notype component_declarator
 222 %type <ttype> component_notype_declarator
 223 %type <ttype> enumlist enumerator
 224 %type <ttype> struct_head union_head enum_head
 225 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
 226 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
 227 %type <ttype> xexpr parms parm firstparm identifiers
 228
 229 %type <ttype> parmlist parmlist_1 parmlist_2
 230 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
 231 %type <ttype> identifiers_or_typenames
 232
 233 %type <itype> setspecs setspecs_fp
 234
 235 %type <location> save_location
 236 \f
 237 @@ifobjc
 238 /* the Objective-C nonterminals */
 239
 240 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
 241 %type <ttype> methoddecl unaryselector keywordselector selector
 242 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
 243 %type <ttype> keywordexpr keywordarglist keywordarg
 244 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
 245 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
 246 %type <ttype> non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
 247
 248 %type <ttype> CLASSNAME OBJECTNAME OBJC_STRING
 249
 250 %type <ttype> superclass
 251 %type <itype> objc_try_catch_stmt objc_finally_block
 252 @@end_ifobjc
 253 \f
 254 %{
 255 /* Number of statements (loosely speaking) and compound statements
 256    seen so far.  */
 257 static int stmt_count;
 258 static int compstmt_count;
 259
 260 /* Input location of the end of the body of last simple_if;
 261    used by the stmt-rule immediately after simple_if returns.  */
 262 static location_t if_stmt_locus;
 263
 264
 265 /* List of types and structure classes of the current declaration.  */
 266 static GTY(()) tree current_declspecs;
 267 static GTY(()) tree prefix_attributes;
 268
 269 /* List of all the attributes applying to the identifier currently being
 270    declared; includes prefix_attributes and possibly some more attributes
 271    just after a comma.  */
 272 static GTY(()) tree all_prefix_attributes;
 273
 274 /* Stack of saved values of current_declspecs, prefix_attributes and
 275    all_prefix_attributes.  */
 276 static GTY(()) tree declspec_stack;
 277
 278 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
 279    should be called from the productions making use of setspecs.  */
 280 #define PUSH_DECLSPEC_STACK                                              \
 281   do {                                                                   \
 282     declspec_stack = tree_cons (build_tree_list (prefix_attributes,      \
 283                                                  all_prefix_attributes), \
 284                                 current_declspecs,                       \
 285                                 declspec_stack);                         \
 286   } while (0)
 287
 288 #define POP_DECLSPEC_STACK                                              \
 289   do {                                                                  \
 290     current_declspecs = TREE_VALUE (declspec_stack);                    \
 291     prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack));   \
 292     all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
 293     declspec_stack = TREE_CHAIN (declspec_stack);                       \
 294   } while (0)
 295
 296 /* For __extension__, save/restore the warning flags which are
 297    controlled by __extension__.  */
 298 #define SAVE_EXT_FLAGS()                        \
 299         size_int (pedantic                      \
 300                   | (warn_pointer_arith << 1)   \
 301                   | (warn_traditional << 2)     \
 302                   | (flag_iso << 3))
 303
 304 #define RESTORE_EXT_FLAGS(tval)                 \
 305   do {                                          \
 306     int val = tree_low_cst (tval, 0);           \
 307     pedantic = val & 1;                         \
 308     warn_pointer_arith = (val >> 1) & 1;        \
 309     warn_traditional = (val >> 2) & 1;          \
 310     flag_iso = (val >> 3) & 1;                  \
 311   } while (0)
 312
 313 @@ifobjc
 314 /* Objective-C specific parser/lexer information */
 315
 316 static enum tree_code objc_inherit_code;
 317 static int objc_pq_context = 0, objc_public_flag = 0;
 318
 319 /* The following flag is needed to contextualize ObjC lexical analysis.
 320    In some cases (e.g., 'int NSObject;'), it is undesirable to bind
 321    an identifier to an ObjC class, even if a class with that name
 322    exists.  */
 323 static int objc_need_raw_identifier;
 324 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   objc_need_raw_identifier = VAL
 325 @@end_ifobjc
 326
 327 @@ifc
 328 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   /* nothing */
 329 @@end_ifc
 330
 331 static bool parsing_iso_function_signature;
 332
 333 /* Tell yyparse how to print a token's value, if yydebug is set.  */
 334
 335 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
 336
 337 static void yyprint (FILE *, int, YYSTYPE);
 338 static void yyerror (const char *);
 339 static int yylexname (void);
 340 static inline int _yylex (void);
 341 static int  yylex (void);
 342 static void init_reswords (void);
 343
 344   /* Initialisation routine for this file.  */
 345 void
 346 c_parse_init (void)
 347 {
 348   init_reswords ();
 349 }
 350
 351 %}
 352 \f
 353 %%
 354 program: /* empty */
 355                 { if (pedantic)
 356                     pedwarn ("ISO C forbids an empty source file");
 357                 }
 358         | extdefs
 359         ;
 360
 361 /* the reason for the strange actions in this rule
 362  is so that notype_initdecls when reached via datadef
 363  can find a valid list of type and sc specs in $0. */
 364
 365 extdefs:
 366         {$<ttype>$ = NULL_TREE; } extdef
 367         | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
 368         ;
 369
 370 extdef:
 371         extdef_1
 372         { parsing_iso_function_signature = false; } /* Reset after any external definition.  */
 373         ;
 374
 375 extdef_1:
 376         fndef
 377         | datadef
 378 @@ifobjc
 379         | objcdef
 380 @@end_ifobjc
 381         | ASM_KEYWORD '(' expr ')' ';'
 382                 { STRIP_NOPS ($3);
 383                   if ((TREE_CODE ($3) == ADDR_EXPR
 384                        && TREE_CODE (TREE_OPERAND ($3, 0)) == STRING_CST)
 385                       || TREE_CODE ($3) == STRING_CST)
 386                     assemble_asm ($3);
 387                   else
 388                     error ("argument of `asm' is not a constant string"); }
 389         | extension extdef
 390                 { RESTORE_EXT_FLAGS ($1); }
 391         ;
 392
 393 datadef:
 394           setspecs notype_initdecls ';'
 395                 { if (pedantic)
 396                     error ("ISO C forbids data definition with no type or storage class");
 397                   else
 398                     warning ("data definition has no type or storage class");
 399
 400                   POP_DECLSPEC_STACK; }
 401         | declspecs_nots setspecs notype_initdecls ';'
 402                 { POP_DECLSPEC_STACK; }
 403         | declspecs_ts setspecs initdecls ';'
 404                 { POP_DECLSPEC_STACK; }
 405         | declspecs ';'
 406           { shadow_tag ($1); }
 407         | error ';'
 408         | error '}'
 409         | ';'
 410                 { if (pedantic)
 411                     pedwarn ("ISO C does not allow extra `;' outside of a function"); }
 412         ;
 413 \f
 414 fndef:
 415           declspecs_ts setspecs declarator
 416                 { if (! start_function (current_declspecs, $3,
 417                                         all_prefix_attributes))
 418                     YYERROR1;
 419                 }
 420           old_style_parm_decls save_location
 421                 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
 422                   store_parm_decls (); }
 423           compstmt_or_error
 424                 { finish_function ();
 425                   POP_DECLSPEC_STACK; }
 426         | declspecs_ts setspecs declarator error
 427                 { POP_DECLSPEC_STACK; }
 428         | declspecs_nots setspecs notype_declarator
 429                 { if (! start_function (current_declspecs, $3,
 430                                         all_prefix_attributes))
 431                     YYERROR1;
 432                 }
 433           old_style_parm_decls save_location
 434                 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
 435                   store_parm_decls (); }
 436           compstmt_or_error
 437                 { finish_function ();
 438                   POP_DECLSPEC_STACK; }
 439         | declspecs_nots setspecs notype_declarator error
 440                 { POP_DECLSPEC_STACK; }
 441         | setspecs notype_declarator
 442                 { if (! start_function (NULL_TREE, $2,
 443                                         all_prefix_attributes))
 444                     YYERROR1;
 445                 }
 446           old_style_parm_decls save_location
 447                 { DECL_SOURCE_LOCATION (current_function_decl) = $5;
 448                   store_parm_decls (); }
 449           compstmt_or_error
 450                 { finish_function ();
 451                   POP_DECLSPEC_STACK; }
 452         | setspecs notype_declarator error
 453                 { POP_DECLSPEC_STACK; }
 454         ;
 455
 456 identifier:
 457         IDENTIFIER
 458         | TYPENAME
 459 @@ifobjc
 460         | OBJECTNAME
 461         | CLASSNAME
 462 @@end_ifobjc
 463         ;
 464
 465 unop:     '&'
 466                 { $$ = ADDR_EXPR; }
 467         | '-'
 468                 { $$ = NEGATE_EXPR; }
 469         | '+'
 470                 { $$ = CONVERT_EXPR;
 471 @@ifc
 472   if (warn_traditional && !in_system_header)
 473     warning ("traditional C rejects the unary plus operator");
 474 @@end_ifc
 475                 }
 476         | PLUSPLUS
 477                 { $$ = PREINCREMENT_EXPR; }
 478         | MINUSMINUS
 479                 { $$ = PREDECREMENT_EXPR; }
 480         | '~'
 481                 { $$ = BIT_NOT_EXPR; }
 482         | '!'
 483                 { $$ = TRUTH_NOT_EXPR; }
 484         ;
 485
 486 expr:   nonnull_exprlist
 487                 { $$ = build_compound_expr ($1); }
 488         ;
 489
 490 exprlist:
 491           /* empty */
 492                 { $$ = NULL_TREE; }
 493         | nonnull_exprlist
 494         ;
 495
 496 nonnull_exprlist:
 497         expr_no_commas
 498                 { $$ = build_tree_list (NULL_TREE, $1); }
 499         | nonnull_exprlist ',' expr_no_commas
 500                 { chainon ($1, build_tree_list (NULL_TREE, $3)); }
 501         ;
 502
 503 unary_expr:
 504         primary
 505         | '*' cast_expr   %prec UNARY
 506                 { $$ = build_indirect_ref ($2, "unary *"); }
 507         /* __extension__ turns off -pedantic for following primary.  */
 508         | extension cast_expr     %prec UNARY
 509                 { $$ = $2;
 510                   RESTORE_EXT_FLAGS ($1); }
 511         | unop cast_expr  %prec UNARY
 512                 { $$ = build_unary_op ($1, $2, 0);
 513                   overflow_warning ($$); }
 514         /* Refer to the address of a label as a pointer.  */
 515         | ANDAND identifier
 516                 { $$ = finish_label_address_expr ($2); }
 517         | sizeof unary_expr  %prec UNARY
 518                 { skip_evaluation--;
 519                   if (TREE_CODE ($2) == COMPONENT_REF
 520                       && DECL_C_BIT_FIELD (TREE_OPERAND ($2, 1)))
 521                     error ("`sizeof' applied to a bit-field");
 522                   $$ = c_sizeof (TREE_TYPE ($2)); }
 523         | sizeof '(' typename ')'  %prec HYPERUNARY
 524                 { skip_evaluation--;
 525                   $$ = c_sizeof (groktypename ($3)); }
 526         | alignof unary_expr  %prec UNARY
 527                 { skip_evaluation--;
 528                   $$ = c_alignof_expr ($2); }
 529         | alignof '(' typename ')'  %prec HYPERUNARY
 530                 { skip_evaluation--;
 531                   $$ = c_alignof (groktypename ($3)); }
 532         | REALPART cast_expr %prec UNARY
 533                 { $$ = build_unary_op (REALPART_EXPR, $2, 0); }
 534         | IMAGPART cast_expr %prec UNARY
 535                 { $$ = build_unary_op (IMAGPART_EXPR, $2, 0); }
 536         ;
 537
 538 sizeof:
 539         SIZEOF { skip_evaluation++; }
 540         ;
 541
 542 alignof:
 543         ALIGNOF { skip_evaluation++; }
 544         ;
 545
 546 typeof:
 547         TYPEOF { skip_evaluation++; }
 548         ;
 549
 550 cast_expr:
 551         unary_expr
 552         | '(' typename ')' cast_expr  %prec UNARY
 553                 { $$ = c_cast_expr ($2, $4); }
 554         ;
 555
 556 expr_no_commas:
 557           cast_expr
 558         | expr_no_commas '+' expr_no_commas
 559                 { $$ = parser_build_binary_op ($2, $1, $3); }
 560         | expr_no_commas '-' expr_no_commas
 561                 { $$ = parser_build_binary_op ($2, $1, $3); }
 562         | expr_no_commas '*' expr_no_commas
 563                 { $$ = parser_build_binary_op ($2, $1, $3); }
 564         | expr_no_commas '/' expr_no_commas
 565                 { $$ = parser_build_binary_op ($2, $1, $3); }
 566         | expr_no_commas '%' expr_no_commas
 567                 { $$ = parser_build_binary_op ($2, $1, $3); }
 568         | expr_no_commas LSHIFT expr_no_commas
 569                 { $$ = parser_build_binary_op ($2, $1, $3); }
 570         | expr_no_commas RSHIFT expr_no_commas
 571                 { $$ = parser_build_binary_op ($2, $1, $3); }
 572         | expr_no_commas ARITHCOMPARE expr_no_commas
 573                 { $$ = parser_build_binary_op ($2, $1, $3); }
 574         | expr_no_commas EQCOMPARE expr_no_commas
 575                 { $$ = parser_build_binary_op ($2, $1, $3); }
 576         | expr_no_commas '&' expr_no_commas
 577                 { $$ = parser_build_binary_op ($2, $1, $3); }
 578         | expr_no_commas '|' expr_no_commas
 579                 { $$ = parser_build_binary_op ($2, $1, $3); }
 580         | expr_no_commas '^' expr_no_commas
 581                 { $$ = parser_build_binary_op ($2, $1, $3); }
 582         | expr_no_commas ANDAND
 583                 { $1 = c_common_truthvalue_conversion
 584                     (default_conversion ($1));
 585                   skip_evaluation += $1 == truthvalue_false_node; }
 586           expr_no_commas
 587                 { skip_evaluation -= $1 == truthvalue_false_node;
 588                   $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
 589         | expr_no_commas OROR
 590                 { $1 = c_common_truthvalue_conversion
 591                     (default_conversion ($1));
 592                   skip_evaluation += $1 == truthvalue_true_node; }
 593           expr_no_commas
 594                 { skip_evaluation -= $1 == truthvalue_true_node;
 595                   $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
 596         | expr_no_commas '?'
 597                 { $1 = c_common_truthvalue_conversion
 598                     (default_conversion ($1));
 599                   skip_evaluation += $1 == truthvalue_false_node; }
 600           expr ':'
 601                 { skip_evaluation += (($1 == truthvalue_true_node)
 602                                       - ($1 == truthvalue_false_node)); }
 603           expr_no_commas
 604                 { skip_evaluation -= $1 == truthvalue_true_node;
 605                   $$ = build_conditional_expr ($1, $4, $7); }
 606         | expr_no_commas '?'
 607                 { if (pedantic)
 608                     pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
 609                   /* Make sure first operand is calculated only once.  */
 610                   $<ttype>2 = save_expr ($1);
 611                   $1 = c_common_truthvalue_conversion
 612                     (default_conversion ($<ttype>2));
 613                   skip_evaluation += $1 == truthvalue_true_node; }
 614           ':' expr_no_commas
 615                 { skip_evaluation -= $1 == truthvalue_true_node;
 616                   $$ = build_conditional_expr ($1, $<ttype>2, $5); }
 617         | expr_no_commas '=' expr_no_commas
 618                 { char class;
 619                   $$ = build_modify_expr ($1, NOP_EXPR, $3);
 620                   class = TREE_CODE_CLASS (TREE_CODE ($$));
 621                   if (IS_EXPR_CODE_CLASS (class))
 622                     C_SET_EXP_ORIGINAL_CODE ($$, MODIFY_EXPR);
 623                 }
 624         | expr_no_commas ASSIGN expr_no_commas
 625                 { char class;
 626                   $$ = build_modify_expr ($1, $2, $3);
 627                   /* This inhibits warnings in
 628                      c_common_truthvalue_conversion.  */
 629                   class = TREE_CODE_CLASS (TREE_CODE ($$));
 630                   if (IS_EXPR_CODE_CLASS (class))
 631                     C_SET_EXP_ORIGINAL_CODE ($$, ERROR_MARK);
 632                 }
 633         ;
 634
 635 primary:
 636         IDENTIFIER
 637                 {
 638                   if (yychar == YYEMPTY)
 639                     yychar = YYLEX;
 640                   $$ = build_external_ref ($1, yychar == '(');
 641                 }
 642         | CONSTANT
 643         | STRING
 644         | FUNC_NAME
 645                 { $$ = fname_decl (C_RID_CODE ($$), $$); }
 646         | '(' typename ')' '{'
 647                 { start_init (NULL_TREE, NULL, 0);
 648                   $2 = groktypename ($2);
 649                   really_start_incremental_init ($2); }
 650           initlist_maybe_comma '}'  %prec UNARY
 651                 { tree constructor = pop_init_level (0);
 652                   tree type = $2;
 653                   finish_init ();
 654
 655                   if (pedantic && ! flag_isoc99)
 656                     pedwarn ("ISO C89 forbids compound literals");
 657                   $$ = build_compound_literal (type, constructor);
 658                 }
 659         | '(' expr ')'
 660                 { char class = TREE_CODE_CLASS (TREE_CODE ($2));
 661                   if (IS_EXPR_CODE_CLASS (class))
 662                     C_SET_EXP_ORIGINAL_CODE ($2, ERROR_MARK);
 663                   $$ = $2; }
 664         | '(' error ')'
 665                 { $$ = error_mark_node; }
 666         | compstmt_primary_start compstmt_nostart ')'
 667                  { tree saved_last_tree;
 668
 669                    if (pedantic)
 670                      pedwarn ("ISO C forbids braced-groups within expressions");
 671                   saved_last_tree = COMPOUND_BODY ($1);
 672                   RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
 673                   last_tree = saved_last_tree;
 674                   TREE_CHAIN (last_tree) = NULL_TREE;
 675                   if (!last_expr_type)
 676                     last_expr_type = void_type_node;
 677                   $$ = build1 (STMT_EXPR, last_expr_type, $1);
 678                   TREE_SIDE_EFFECTS ($$) = 1;
 679                 }
 680         | compstmt_primary_start error ')'
 681                 {
 682                   last_tree = COMPOUND_BODY ($1);
 683                   TREE_CHAIN (last_tree) = NULL_TREE;
 684                   $$ = error_mark_node;
 685                 }
 686         | primary '(' exprlist ')'   %prec '.'
 687                 { $$ = build_function_call ($1, $3); }
 688         | VA_ARG '(' expr_no_commas ',' typename ')'
 689                 { $$ = build_va_arg ($3, groktypename ($5)); }
 690
 691       | CHOOSE_EXPR '(' expr_no_commas ',' expr_no_commas ',' expr_no_commas ')'
 692                 {
 693                   tree c;
 694
 695                   c = fold ($3);
 696                   STRIP_NOPS (c);
 697                   if (TREE_CODE (c) != INTEGER_CST)
 698                     error ("first argument to __builtin_choose_expr not a constant");
 699                   $$ = integer_zerop (c) ? $7 : $5;
 700                 }
 701       | TYPES_COMPATIBLE_P '(' typename ',' typename ')'
 702                 {
 703                   tree e1, e2;
 704
 705                   e1 = TYPE_MAIN_VARIANT (groktypename ($3));
 706                   e2 = TYPE_MAIN_VARIANT (groktypename ($5));
 707
 708                   $$ = comptypes (e1, e2, COMPARE_STRICT)
 709                     ? build_int_2 (1, 0) : build_int_2 (0, 0);
 710                 }
 711         | primary '[' expr ']'   %prec '.'
 712                 { $$ = build_array_ref ($1, $3); }
 713         | primary '.' identifier
 714                 {
 715 @@ifobjc
 716                     if (!is_public ($1, $3))
 717                       $$ = error_mark_node;
 718                     else
 719 @@end_ifobjc
 720                       $$ = build_component_ref ($1, $3);
 721                 }
 722         | primary POINTSAT identifier
 723                 {
 724                   tree expr = build_indirect_ref ($1, "->");
 725
 726 @@ifobjc
 727                       if (!is_public (expr, $3))
 728                         $$ = error_mark_node;
 729                       else
 730 @@end_ifobjc
 731                         $$ = build_component_ref (expr, $3);
 732                 }
 733         | primary PLUSPLUS
 734                 { $$ = build_unary_op (POSTINCREMENT_EXPR, $1, 0); }
 735         | primary MINUSMINUS
 736                 { $$ = build_unary_op (POSTDECREMENT_EXPR, $1, 0); }
 737 @@ifobjc
 738         | objcmessageexpr
 739                 { $$ = build_message_expr ($1); }
 740         | objcselectorexpr
 741                 { $$ = build_selector_expr ($1); }
 742         | objcprotocolexpr
 743                 { $$ = build_protocol_expr ($1); }
 744         | objcencodeexpr
 745                 { $$ = build_encode_expr ($1); }
 746         | OBJC_STRING
 747                 { $$ = build_objc_string_object ($1); }
 748 @@end_ifobjc
 749         ;
 750
 751 old_style_parm_decls:
 752         old_style_parm_decls_1
 753         {
 754           parsing_iso_function_signature = false; /* Reset after decls.  */
 755         }
 756         ;
 757
 758 old_style_parm_decls_1:
 759         /* empty */
 760         {
 761           if (warn_traditional && !in_system_header
 762               && parsing_iso_function_signature)
 763             warning ("traditional C rejects ISO C style function definitions");
 764           if (warn_old_style_definition && !in_system_header
 765               && !parsing_iso_function_signature)
 766             warning ("old-style parameter declaration");
 767           parsing_iso_function_signature = false; /* Reset after warning.  */
 768         }
 769         | datadecls
 770         {
 771           if (warn_old_style_definition && !in_system_header)
 772             warning ("old-style parameter declaration");
 773         }
 774         ;
 775
 776 /* The following are analogous to lineno_decl, decls and decl
 777    except that they do not allow nested functions.
 778    They are used for old-style parm decls.  */
 779 lineno_datadecl:
 780           save_location datadecl
 781                 { }
 782         ;
 783
 784 datadecls:
 785         lineno_datadecl
 786         | errstmt
 787         | datadecls lineno_datadecl
 788         | lineno_datadecl errstmt
 789         ;
 790
 791 /* We don't allow prefix attributes here because they cause reduce/reduce
 792    conflicts: we can't know whether we're parsing a function decl with
 793    attribute suffix, or function defn with attribute prefix on first old
 794    style parm.  */
 795 datadecl:
 796         declspecs_ts_nosa setspecs initdecls ';'
 797                 { POP_DECLSPEC_STACK; }
 798         | declspecs_nots_nosa setspecs notype_initdecls ';'
 799                 { POP_DECLSPEC_STACK; }
 800         | declspecs_ts_nosa ';'
 801                 { shadow_tag_warned ($1, 1);
 802                   pedwarn ("empty declaration"); }
 803         | declspecs_nots_nosa ';'
 804                 { pedwarn ("empty declaration"); }
 805         ;
 806
 807 /* This combination which saves a lineno before a decl
 808    is the normal thing to use, rather than decl itself.
 809    This is to avoid shift/reduce conflicts in contexts
 810    where statement labels are allowed.  */
 811 lineno_decl:
 812           save_location decl
 813                 { }
 814         ;
 815
 816 /* records the type and storage class specs to use for processing
 817    the declarators that follow.
 818    Maintains a stack of outer-level values of current_declspecs,
 819    for the sake of parm declarations nested in function declarators.  */
 820 setspecs: /* empty */
 821                 { pending_xref_error ();
 822                   PUSH_DECLSPEC_STACK;
 823                   split_specs_attrs ($<ttype>0,
 824                                      &current_declspecs, &prefix_attributes);
 825                   all_prefix_attributes = prefix_attributes; }
 826         ;
 827
 828 /* Possibly attributes after a comma, which should reset all_prefix_attributes
 829    to prefix_attributes with these ones chained on the front.  */
 830 maybe_resetattrs:
 831           maybe_attribute
 832                 { all_prefix_attributes = chainon ($1, prefix_attributes); }
 833         ;
 834
 835 decl:
 836         declspecs_ts setspecs initdecls ';'
 837                 { POP_DECLSPEC_STACK; }
 838         | declspecs_nots setspecs notype_initdecls ';'
 839                 { POP_DECLSPEC_STACK; }
 840         | declspecs_ts setspecs nested_function
 841                 { POP_DECLSPEC_STACK; }
 842         | declspecs_nots setspecs notype_nested_function
 843                 { POP_DECLSPEC_STACK; }
 844         | declspecs ';'
 845                 { shadow_tag ($1); }
 846         | extension decl
 847                 { RESTORE_EXT_FLAGS ($1); }
 848         ;
 849
 850 /* A list of declaration specifiers.  These are:
 851
 852    - Storage class specifiers (scspec), which for GCC currently includes
 853    function specifiers ("inline").
 854
 855    - Type specifiers (typespec_*).
 856
 857    - Type qualifiers (TYPE_QUAL).
 858
 859    - Attribute specifier lists (attributes).
 860
 861    These are stored as a TREE_LIST; the head of the list is the last
 862    item in the specifier list.  Each entry in the list has either a
 863    TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
 864    is a single other specifier or qualifier; and a TREE_CHAIN that is the
 865    rest of the list.  TREE_STATIC is set on the list if something other
 866    than a storage class specifier or attribute has been seen; this is used
 867    to warn for the obsolescent usage of storage class specifiers other than
 868    at the start of the list.  (Doing this properly would require function
 869    specifiers to be handled separately from storage class specifiers.)
 870
 871    The various cases below are classified according to:
 872
 873    (a) Whether a storage class specifier is included or not; some
 874    places in the grammar disallow storage class specifiers (_sc or _nosc).
 875
 876    (b) Whether a type specifier has been seen; after a type specifier,
 877    a typedef name is an identifier to redeclare (_ts or _nots).
 878
 879    (c) Whether the list starts with an attribute; in certain places,
 880    the grammar requires specifiers that don't start with an attribute
 881    (_sa or _nosa).
 882
 883    (d) Whether the list ends with an attribute (or a specifier such that
 884    any following attribute would have been parsed as part of that specifier);
 885    this avoids shift-reduce conflicts in the parsing of attributes
 886    (_ea or _noea).
 887
 888    TODO:
 889
 890    (i) Distinguish between function specifiers and storage class specifiers,
 891    at least for the purpose of warnings about obsolescent usage.
 892
 893    (ii) Halve the number of productions here by eliminating the _sc/_nosc
 894    distinction and instead checking where required that storage class
 895    specifiers aren't present.  */
 896
 897 /* Declspecs which contain at least one type specifier or typedef name.
 898    (Just `const' or `volatile' is not enough.)
 899    A typedef'd name following these is taken as a name to be declared.
 900    Declspecs have a non-NULL TREE_VALUE, attributes do not.  */
 901
 902 declspecs_nosc_nots_nosa_noea:
 903           TYPE_QUAL
 904                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 905                   TREE_STATIC ($$) = 1; }
 906         | declspecs_nosc_nots_nosa_noea TYPE_QUAL
 907                 { $$ = tree_cons (NULL_TREE, $2, $1);
 908                   TREE_STATIC ($$) = 1; }
 909         | declspecs_nosc_nots_nosa_ea TYPE_QUAL
 910                 { $$ = tree_cons (NULL_TREE, $2, $1);
 911                   TREE_STATIC ($$) = 1; }
 912         ;
 913
 914 declspecs_nosc_nots_nosa_ea:
 915           declspecs_nosc_nots_nosa_noea attributes
 916                 { $$ = tree_cons ($2, NULL_TREE, $1);
 917                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 918         ;
 919
 920 declspecs_nosc_nots_sa_noea:
 921           declspecs_nosc_nots_sa_noea TYPE_QUAL
 922                 { $$ = tree_cons (NULL_TREE, $2, $1);
 923                   TREE_STATIC ($$) = 1; }
 924         | declspecs_nosc_nots_sa_ea TYPE_QUAL
 925                 { $$ = tree_cons (NULL_TREE, $2, $1);
 926                   TREE_STATIC ($$) = 1; }
 927         ;
 928
 929 declspecs_nosc_nots_sa_ea:
 930           attributes
 931                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
 932                   TREE_STATIC ($$) = 0; }
 933         | declspecs_nosc_nots_sa_noea attributes
 934                 { $$ = tree_cons ($2, NULL_TREE, $1);
 935                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 936         ;
 937
 938 declspecs_nosc_ts_nosa_noea:
 939           typespec_nonattr
 940                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 941                   TREE_STATIC ($$) = 1; }
 942         | declspecs_nosc_ts_nosa_noea TYPE_QUAL
 943                 { $$ = tree_cons (NULL_TREE, $2, $1);
 944                   TREE_STATIC ($$) = 1; }
 945         | declspecs_nosc_ts_nosa_ea TYPE_QUAL
 946                 { $$ = tree_cons (NULL_TREE, $2, $1);
 947                   TREE_STATIC ($$) = 1; }
 948         | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
 949                 { $$ = tree_cons (NULL_TREE, $2, $1);
 950                   TREE_STATIC ($$) = 1; }
 951         | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
 952                 { $$ = tree_cons (NULL_TREE, $2, $1);
 953                   TREE_STATIC ($$) = 1; }
 954         | declspecs_nosc_nots_nosa_noea typespec_nonattr
 955                 { $$ = tree_cons (NULL_TREE, $2, $1);
 956                   TREE_STATIC ($$) = 1; }
 957         | declspecs_nosc_nots_nosa_ea typespec_nonattr
 958                 { $$ = tree_cons (NULL_TREE, $2, $1);
 959                   TREE_STATIC ($$) = 1; }
 960         ;
 961
 962 declspecs_nosc_ts_nosa_ea:
 963           typespec_attr
 964                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
 965                   TREE_STATIC ($$) = 1; }
 966         | declspecs_nosc_ts_nosa_noea attributes
 967                 { $$ = tree_cons ($2, NULL_TREE, $1);
 968                   TREE_STATIC ($$) = TREE_STATIC ($1); }
 969         | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
 970                 { $$ = tree_cons (NULL_TREE, $2, $1);
 971                   TREE_STATIC ($$) = 1; }
 972         | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
 973                 { $$ = tree_cons (NULL_TREE, $2, $1);
 974                   TREE_STATIC ($$) = 1; }
 975         | declspecs_nosc_nots_nosa_noea typespec_attr
 976                 { $$ = tree_cons (NULL_TREE, $2, $1);
 977                   TREE_STATIC ($$) = 1; }
 978         | declspecs_nosc_nots_nosa_ea typespec_attr
 979                 { $$ = tree_cons (NULL_TREE, $2, $1);
 980                   TREE_STATIC ($$) = 1; }
 981         ;
 982
 983 declspecs_nosc_ts_sa_noea:
 984           declspecs_nosc_ts_sa_noea TYPE_QUAL
 985                 { $$ = tree_cons (NULL_TREE, $2, $1);
 986                   TREE_STATIC ($$) = 1; }
 987         | declspecs_nosc_ts_sa_ea TYPE_QUAL
 988                 { $$ = tree_cons (NULL_TREE, $2, $1);
 989                   TREE_STATIC ($$) = 1; }
 990         | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
 991                 { $$ = tree_cons (NULL_TREE, $2, $1);
 992                   TREE_STATIC ($$) = 1; }
 993         | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
 994                 { $$ = tree_cons (NULL_TREE, $2, $1);
 995                   TREE_STATIC ($$) = 1; }
 996         | declspecs_nosc_nots_sa_noea typespec_nonattr
 997                 { $$ = tree_cons (NULL_TREE, $2, $1);
 998                   TREE_STATIC ($$) = 1; }
 999         | declspecs_nosc_nots_sa_ea typespec_nonattr
1000                 { $$ = tree_cons (NULL_TREE, $2, $1);
1001                   TREE_STATIC ($$) = 1; }
1002         ;
1003
1004 declspecs_nosc_ts_sa_ea:
1005           declspecs_nosc_ts_sa_noea attributes
1006                 { $$ = tree_cons ($2, NULL_TREE, $1);
1007                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1008         | declspecs_nosc_ts_sa_noea typespec_reserved_attr
1009                 { $$ = tree_cons (NULL_TREE, $2, $1);
1010                   TREE_STATIC ($$) = 1; }
1011         | declspecs_nosc_ts_sa_ea typespec_reserved_attr
1012                 { $$ = tree_cons (NULL_TREE, $2, $1);
1013                   TREE_STATIC ($$) = 1; }
1014         | declspecs_nosc_nots_sa_noea typespec_attr
1015                 { $$ = tree_cons (NULL_TREE, $2, $1);
1016                   TREE_STATIC ($$) = 1; }
1017         | declspecs_nosc_nots_sa_ea typespec_attr
1018                 { $$ = tree_cons (NULL_TREE, $2, $1);
1019                   TREE_STATIC ($$) = 1; }
1020         ;
1021
1022 declspecs_sc_nots_nosa_noea:
1023           scspec
1024                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1025                   TREE_STATIC ($$) = 0; }
1026         | declspecs_sc_nots_nosa_noea TYPE_QUAL
1027                 { $$ = tree_cons (NULL_TREE, $2, $1);
1028                   TREE_STATIC ($$) = 1; }
1029         | declspecs_sc_nots_nosa_ea TYPE_QUAL
1030                 { $$ = tree_cons (NULL_TREE, $2, $1);
1031                   TREE_STATIC ($$) = 1; }
1032         | declspecs_nosc_nots_nosa_noea scspec
1033                 { if (extra_warnings && TREE_STATIC ($1))
1034                     warning ("`%s' is not at beginning of declaration",
1035                              IDENTIFIER_POINTER ($2));
1036                   $$ = tree_cons (NULL_TREE, $2, $1);
1037                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1038         | declspecs_nosc_nots_nosa_ea scspec
1039                 { if (extra_warnings && TREE_STATIC ($1))
1040                     warning ("`%s' is not at beginning of declaration",
1041                              IDENTIFIER_POINTER ($2));
1042                   $$ = tree_cons (NULL_TREE, $2, $1);
1043                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1044         | declspecs_sc_nots_nosa_noea scspec
1045                 { if (extra_warnings && TREE_STATIC ($1))
1046                     warning ("`%s' is not at beginning of declaration",
1047                              IDENTIFIER_POINTER ($2));
1048                   $$ = tree_cons (NULL_TREE, $2, $1);
1049                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1050         | declspecs_sc_nots_nosa_ea scspec
1051                 { if (extra_warnings && TREE_STATIC ($1))
1052                     warning ("`%s' is not at beginning of declaration",
1053                              IDENTIFIER_POINTER ($2));
1054                   $$ = tree_cons (NULL_TREE, $2, $1);
1055                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1056         ;
1057
1058 declspecs_sc_nots_nosa_ea:
1059           declspecs_sc_nots_nosa_noea attributes
1060                 { $$ = tree_cons ($2, NULL_TREE, $1);
1061                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1062         ;
1063
1064 declspecs_sc_nots_sa_noea:
1065           declspecs_sc_nots_sa_noea TYPE_QUAL
1066                 { $$ = tree_cons (NULL_TREE, $2, $1);
1067                   TREE_STATIC ($$) = 1; }
1068         | declspecs_sc_nots_sa_ea TYPE_QUAL
1069                 { $$ = tree_cons (NULL_TREE, $2, $1);
1070                   TREE_STATIC ($$) = 1; }
1071         | declspecs_nosc_nots_sa_noea scspec
1072                 { if (extra_warnings && TREE_STATIC ($1))
1073                     warning ("`%s' is not at beginning of declaration",
1074                              IDENTIFIER_POINTER ($2));
1075                   $$ = tree_cons (NULL_TREE, $2, $1);
1076                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1077         | declspecs_nosc_nots_sa_ea scspec
1078                 { if (extra_warnings && TREE_STATIC ($1))
1079                     warning ("`%s' is not at beginning of declaration",
1080                              IDENTIFIER_POINTER ($2));
1081                   $$ = tree_cons (NULL_TREE, $2, $1);
1082                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1083         | declspecs_sc_nots_sa_noea scspec
1084                 { if (extra_warnings && TREE_STATIC ($1))
1085                     warning ("`%s' is not at beginning of declaration",
1086                              IDENTIFIER_POINTER ($2));
1087                   $$ = tree_cons (NULL_TREE, $2, $1);
1088                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1089         | declspecs_sc_nots_sa_ea scspec
1090                 { if (extra_warnings && TREE_STATIC ($1))
1091                     warning ("`%s' is not at beginning of declaration",
1092                              IDENTIFIER_POINTER ($2));
1093                   $$ = tree_cons (NULL_TREE, $2, $1);
1094                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1095         ;
1096
1097 declspecs_sc_nots_sa_ea:
1098           declspecs_sc_nots_sa_noea attributes
1099                 { $$ = tree_cons ($2, NULL_TREE, $1);
1100                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1101         ;
1102
1103 declspecs_sc_ts_nosa_noea:
1104           declspecs_sc_ts_nosa_noea TYPE_QUAL
1105                 { $$ = tree_cons (NULL_TREE, $2, $1);
1106                   TREE_STATIC ($$) = 1; }
1107         | declspecs_sc_ts_nosa_ea TYPE_QUAL
1108                 { $$ = tree_cons (NULL_TREE, $2, $1);
1109                   TREE_STATIC ($$) = 1; }
1110         | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1111                 { $$ = tree_cons (NULL_TREE, $2, $1);
1112                   TREE_STATIC ($$) = 1; }
1113         | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1114                 { $$ = tree_cons (NULL_TREE, $2, $1);
1115                   TREE_STATIC ($$) = 1; }
1116         | declspecs_sc_nots_nosa_noea typespec_nonattr
1117                 { $$ = tree_cons (NULL_TREE, $2, $1);
1118                   TREE_STATIC ($$) = 1; }
1119         | declspecs_sc_nots_nosa_ea typespec_nonattr
1120                 { $$ = tree_cons (NULL_TREE, $2, $1);
1121                   TREE_STATIC ($$) = 1; }
1122         | declspecs_nosc_ts_nosa_noea scspec
1123                 { if (extra_warnings && TREE_STATIC ($1))
1124                     warning ("`%s' is not at beginning of declaration",
1125                              IDENTIFIER_POINTER ($2));
1126                   $$ = tree_cons (NULL_TREE, $2, $1);
1127                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1128         | declspecs_nosc_ts_nosa_ea scspec
1129                 { if (extra_warnings && TREE_STATIC ($1))
1130                     warning ("`%s' is not at beginning of declaration",
1131                              IDENTIFIER_POINTER ($2));
1132                   $$ = tree_cons (NULL_TREE, $2, $1);
1133                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1134         | declspecs_sc_ts_nosa_noea scspec
1135                 { if (extra_warnings && TREE_STATIC ($1))
1136                     warning ("`%s' is not at beginning of declaration",
1137                              IDENTIFIER_POINTER ($2));
1138                   $$ = tree_cons (NULL_TREE, $2, $1);
1139                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1140         | declspecs_sc_ts_nosa_ea scspec
1141                 { if (extra_warnings && TREE_STATIC ($1))
1142                     warning ("`%s' is not at beginning of declaration",
1143                              IDENTIFIER_POINTER ($2));
1144                   $$ = tree_cons (NULL_TREE, $2, $1);
1145                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1146         ;
1147
1148 declspecs_sc_ts_nosa_ea:
1149           declspecs_sc_ts_nosa_noea attributes
1150                 { $$ = tree_cons ($2, NULL_TREE, $1);
1151                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1152         | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1153                 { $$ = tree_cons (NULL_TREE, $2, $1);
1154                   TREE_STATIC ($$) = 1; }
1155         | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1156                 { $$ = tree_cons (NULL_TREE, $2, $1);
1157                   TREE_STATIC ($$) = 1; }
1158         | declspecs_sc_nots_nosa_noea typespec_attr
1159                 { $$ = tree_cons (NULL_TREE, $2, $1);
1160                   TREE_STATIC ($$) = 1; }
1161         | declspecs_sc_nots_nosa_ea typespec_attr
1162                 { $$ = tree_cons (NULL_TREE, $2, $1);
1163                   TREE_STATIC ($$) = 1; }
1164         ;
1165
1166 declspecs_sc_ts_sa_noea:
1167           declspecs_sc_ts_sa_noea TYPE_QUAL
1168                 { $$ = tree_cons (NULL_TREE, $2, $1);
1169                   TREE_STATIC ($$) = 1; }
1170         | declspecs_sc_ts_sa_ea TYPE_QUAL
1171                 { $$ = tree_cons (NULL_TREE, $2, $1);
1172                   TREE_STATIC ($$) = 1; }
1173         | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1174                 { $$ = tree_cons (NULL_TREE, $2, $1);
1175                   TREE_STATIC ($$) = 1; }
1176         | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1177                 { $$ = tree_cons (NULL_TREE, $2, $1);
1178                   TREE_STATIC ($$) = 1; }
1179         | declspecs_sc_nots_sa_noea typespec_nonattr
1180                 { $$ = tree_cons (NULL_TREE, $2, $1);
1181                   TREE_STATIC ($$) = 1; }
1182         | declspecs_sc_nots_sa_ea typespec_nonattr
1183                 { $$ = tree_cons (NULL_TREE, $2, $1);
1184                   TREE_STATIC ($$) = 1; }
1185         | declspecs_nosc_ts_sa_noea scspec
1186                 { if (extra_warnings && TREE_STATIC ($1))
1187                     warning ("`%s' is not at beginning of declaration",
1188                              IDENTIFIER_POINTER ($2));
1189                   $$ = tree_cons (NULL_TREE, $2, $1);
1190                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1191         | declspecs_nosc_ts_sa_ea scspec
1192                 { if (extra_warnings && TREE_STATIC ($1))
1193                     warning ("`%s' is not at beginning of declaration",
1194                              IDENTIFIER_POINTER ($2));
1195                   $$ = tree_cons (NULL_TREE, $2, $1);
1196                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1197         | declspecs_sc_ts_sa_noea scspec
1198                 { if (extra_warnings && TREE_STATIC ($1))
1199                     warning ("`%s' is not at beginning of declaration",
1200                              IDENTIFIER_POINTER ($2));
1201                   $$ = tree_cons (NULL_TREE, $2, $1);
1202                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1203         | declspecs_sc_ts_sa_ea scspec
1204                 { if (extra_warnings && TREE_STATIC ($1))
1205                     warning ("`%s' is not at beginning of declaration",
1206                              IDENTIFIER_POINTER ($2));
1207                   $$ = tree_cons (NULL_TREE, $2, $1);
1208                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1209         ;
1210
1211 declspecs_sc_ts_sa_ea:
1212           declspecs_sc_ts_sa_noea attributes
1213                 { $$ = tree_cons ($2, NULL_TREE, $1);
1214                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1215         | declspecs_sc_ts_sa_noea typespec_reserved_attr
1216                 { $$ = tree_cons (NULL_TREE, $2, $1);
1217                   TREE_STATIC ($$) = 1; }
1218         | declspecs_sc_ts_sa_ea typespec_reserved_attr
1219                 { $$ = tree_cons (NULL_TREE, $2, $1);
1220                   TREE_STATIC ($$) = 1; }
1221         | declspecs_sc_nots_sa_noea typespec_attr
1222                 { $$ = tree_cons (NULL_TREE, $2, $1);
1223                   TREE_STATIC ($$) = 1; }
1224         | declspecs_sc_nots_sa_ea typespec_attr
1225                 { $$ = tree_cons (NULL_TREE, $2, $1);
1226                   TREE_STATIC ($$) = 1; }
1227         ;
1228
1229 /* Particular useful classes of declspecs.  */
1230 declspecs_ts:
1231           declspecs_nosc_ts_nosa_noea
1232         | declspecs_nosc_ts_nosa_ea
1233         | declspecs_nosc_ts_sa_noea
1234         | declspecs_nosc_ts_sa_ea
1235         | declspecs_sc_ts_nosa_noea
1236         | declspecs_sc_ts_nosa_ea
1237         | declspecs_sc_ts_sa_noea
1238         | declspecs_sc_ts_sa_ea
1239         ;
1240
1241 declspecs_nots:
1242           declspecs_nosc_nots_nosa_noea
1243         | declspecs_nosc_nots_nosa_ea
1244         | declspecs_nosc_nots_sa_noea
1245         | declspecs_nosc_nots_sa_ea
1246         | declspecs_sc_nots_nosa_noea
1247         | declspecs_sc_nots_nosa_ea
1248         | declspecs_sc_nots_sa_noea
1249         | declspecs_sc_nots_sa_ea
1250         ;
1251
1252 declspecs_ts_nosa:
1253           declspecs_nosc_ts_nosa_noea
1254         | declspecs_nosc_ts_nosa_ea
1255         | declspecs_sc_ts_nosa_noea
1256         | declspecs_sc_ts_nosa_ea
1257         ;
1258
1259 declspecs_nots_nosa:
1260           declspecs_nosc_nots_nosa_noea
1261         | declspecs_nosc_nots_nosa_ea
1262         | declspecs_sc_nots_nosa_noea
1263         | declspecs_sc_nots_nosa_ea
1264         ;
1265
1266 declspecs_nosc_ts:
1267           declspecs_nosc_ts_nosa_noea
1268         | declspecs_nosc_ts_nosa_ea
1269         | declspecs_nosc_ts_sa_noea
1270         | declspecs_nosc_ts_sa_ea
1271         ;
1272
1273 declspecs_nosc_nots:
1274           declspecs_nosc_nots_nosa_noea
1275         | declspecs_nosc_nots_nosa_ea
1276         | declspecs_nosc_nots_sa_noea
1277         | declspecs_nosc_nots_sa_ea
1278         ;
1279
1280 declspecs_nosc:
1281           declspecs_nosc_ts_nosa_noea
1282         | declspecs_nosc_ts_nosa_ea
1283         | declspecs_nosc_ts_sa_noea
1284         | declspecs_nosc_ts_sa_ea
1285         | declspecs_nosc_nots_nosa_noea
1286         | declspecs_nosc_nots_nosa_ea
1287         | declspecs_nosc_nots_sa_noea
1288         | declspecs_nosc_nots_sa_ea
1289         ;
1290
1291 declspecs:
1292           declspecs_nosc_nots_nosa_noea
1293         | declspecs_nosc_nots_nosa_ea
1294         | declspecs_nosc_nots_sa_noea
1295         | declspecs_nosc_nots_sa_ea
1296         | declspecs_nosc_ts_nosa_noea
1297         | declspecs_nosc_ts_nosa_ea
1298         | declspecs_nosc_ts_sa_noea
1299         | declspecs_nosc_ts_sa_ea
1300         | declspecs_sc_nots_nosa_noea
1301         | declspecs_sc_nots_nosa_ea
1302         | declspecs_sc_nots_sa_noea
1303         | declspecs_sc_nots_sa_ea
1304         | declspecs_sc_ts_nosa_noea
1305         | declspecs_sc_ts_nosa_ea
1306         | declspecs_sc_ts_sa_noea
1307         | declspecs_sc_ts_sa_ea
1308         ;
1309
1310 /* A (possibly empty) sequence of type qualifiers and attributes.  */
1311 maybe_type_quals_attrs:
1312           /* empty */
1313                 { $$ = NULL_TREE; }
1314         | declspecs_nosc_nots
1315                 { $$ = $1; }
1316         ;
1317
1318 /* A type specifier (but not a type qualifier).
1319    Once we have seen one of these in a declaration,
1320    if a typedef name appears then it is being redeclared.
1321
1322    The _reserved versions start with a reserved word and may appear anywhere
1323    in the declaration specifiers; the _nonreserved versions may only
1324    appear before any other type specifiers, and after that are (if names)
1325    being redeclared.
1326
1327    FIXME: should the _nonreserved version be restricted to names being
1328    redeclared only?  The other entries there relate only the GNU extensions
1329    and Objective C, and are historically parsed thus, and don't make sense
1330    after other type specifiers, but it might be cleaner to count them as
1331    _reserved.
1332
1333    _attr means: specifiers that either end with attributes,
1334    or are such that any following attributes would
1335    be parsed as part of the specifier.
1336
1337    _nonattr: specifiers.  */
1338
1339 typespec_nonattr:
1340           typespec_reserved_nonattr
1341         | typespec_nonreserved_nonattr
1342         ;
1343
1344 typespec_attr:
1345           typespec_reserved_attr
1346         ;
1347
1348 typespec_reserved_nonattr:
1349           TYPESPEC
1350                 { OBJC_NEED_RAW_IDENTIFIER (1); }
1351         | structsp_nonattr
1352         ;
1353
1354 typespec_reserved_attr:
1355           structsp_attr
1356         ;
1357
1358 typespec_nonreserved_nonattr:
1359           TYPENAME
1360                 { /* For a typedef name, record the meaning, not the name.
1361                      In case of `foo foo, bar;'.  */
1362                   $$ = lookup_name ($1); }
1363 @@ifobjc
1364         | CLASSNAME protocolrefs
1365                 { $$ = get_static_reference ($1, $2); }
1366         | OBJECTNAME protocolrefs
1367                 { $$ = get_object_reference ($2); }
1368
1369 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1370    - nisse@lysator.liu.se */
1371         | non_empty_protocolrefs
1372                 { $$ = get_object_reference ($1); }
1373 @@end_ifobjc
1374         | typeof '(' expr ')'
1375                 { skip_evaluation--; $$ = TREE_TYPE ($3); }
1376         | typeof '(' typename ')'
1377                 { skip_evaluation--; $$ = groktypename ($3); }
1378         ;
1379
1380 /* typespec_nonreserved_attr does not exist.  */
1381
1382 initdecls:
1383         initdcl
1384         | initdecls ',' maybe_resetattrs initdcl
1385         ;
1386
1387 notype_initdecls:
1388         notype_initdcl
1389         | notype_initdecls ',' maybe_resetattrs notype_initdcl
1390         ;
1391
1392 maybeasm:
1393           /* empty */
1394                 { $$ = NULL_TREE; }
1395         | ASM_KEYWORD '(' STRING ')'
1396                 { $$ = $3; }
1397         ;
1398
1399 initdcl:
1400           declarator maybeasm maybe_attribute '='
1401                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1402                                           chainon ($3, all_prefix_attributes));
1403                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1404           init
1405 /* Note how the declaration of the variable is in effect while its init is parsed! */
1406                 { finish_init ();
1407                   finish_decl ($<ttype>5, $6, $2); }
1408         | declarator maybeasm maybe_attribute
1409                 { tree d = start_decl ($1, current_declspecs, 0,
1410                                        chainon ($3, all_prefix_attributes));
1411                   finish_decl (d, NULL_TREE, $2);
1412                 }
1413         ;
1414
1415 notype_initdcl:
1416           notype_declarator maybeasm maybe_attribute '='
1417                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1418                                           chainon ($3, all_prefix_attributes));
1419                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1420           init
1421 /* Note how the declaration of the variable is in effect while its init is parsed! */
1422                 { finish_init ();
1423                   finish_decl ($<ttype>5, $6, $2); }
1424         | notype_declarator maybeasm maybe_attribute
1425                 { tree d = start_decl ($1, current_declspecs, 0,
1426                                        chainon ($3, all_prefix_attributes));
1427                   finish_decl (d, NULL_TREE, $2); }
1428         ;
1429 /* the * rules are dummies to accept the Apollo extended syntax
1430    so that the header files compile. */
1431 maybe_attribute:
1432       /* empty */
1433                 { $$ = NULL_TREE; }
1434         | attributes
1435                 { $$ = $1; }
1436         ;
1437
1438 attributes:
1439       attribute
1440                 { $$ = $1; }
1441         | attributes attribute
1442                 { $$ = chainon ($1, $2); }
1443         ;
1444
1445 attribute:
1446       ATTRIBUTE '(' '(' attribute_list ')' ')'
1447                 { $$ = $4; }
1448         ;
1449
1450 attribute_list:
1451       attrib
1452                 { $$ = $1; }
1453         | attribute_list ',' attrib
1454                 { $$ = chainon ($1, $3); }
1455         ;
1456
1457 attrib:
1458     /* empty */
1459                 { $$ = NULL_TREE; }
1460         | any_word
1461                 { $$ = build_tree_list ($1, NULL_TREE); }
1462         | any_word '(' IDENTIFIER ')'
1463                 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1464         | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1465                 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1466         | any_word '(' exprlist ')'
1467                 { $$ = build_tree_list ($1, $3); }
1468         ;
1469
1470 /* This still leaves out most reserved keywords,
1471    shouldn't we include them?  */
1472
1473 any_word:
1474           identifier
1475         | scspec
1476         | TYPESPEC
1477         | TYPE_QUAL
1478         ;
1479
1480 scspec:
1481           STATIC
1482         | SCSPEC
1483         ;
1484 \f
1485 /* Initializers.  `init' is the entry point.  */
1486
1487 init:
1488         expr_no_commas
1489         | '{'
1490                 { really_start_incremental_init (NULL_TREE); }
1491           initlist_maybe_comma '}'
1492                 { $$ = pop_init_level (0); }
1493         | error
1494                 { $$ = error_mark_node; }
1495         ;
1496
1497 /* `initlist_maybe_comma' is the guts of an initializer in braces.  */
1498 initlist_maybe_comma:
1499           /* empty */
1500                 { if (pedantic)
1501                     pedwarn ("ISO C forbids empty initializer braces"); }
1502         | initlist1 maybecomma
1503         ;
1504
1505 initlist1:
1506           initelt
1507         | initlist1 ',' initelt
1508         ;
1509
1510 /* `initelt' is a single element of an initializer.
1511    It may use braces.  */
1512 initelt:
1513           designator_list '=' initval
1514                 { if (pedantic && ! flag_isoc99)
1515                     pedwarn ("ISO C89 forbids specifying subobject to initialize"); }
1516         | designator initval
1517                 { if (pedantic)
1518                     pedwarn ("obsolete use of designated initializer without `='"); }
1519         | identifier ':'
1520                 { set_init_label ($1);
1521                   if (pedantic)
1522                     pedwarn ("obsolete use of designated initializer with `:'"); }
1523           initval
1524                 {}
1525         | initval
1526         ;
1527
1528 initval:
1529           '{'
1530                 { push_init_level (0); }
1531           initlist_maybe_comma '}'
1532                 { process_init_element (pop_init_level (0)); }
1533         | expr_no_commas
1534                 { process_init_element ($1); }
1535         | error
1536         ;
1537
1538 designator_list:
1539           designator
1540         | designator_list designator
1541         ;
1542
1543 designator:
1544           '.' identifier
1545                 { set_init_label ($2); }
1546         | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1547                 { set_init_index ($2, $4);
1548                   if (pedantic)
1549                     pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1550         | '[' expr_no_commas ']'
1551                 { set_init_index ($2, NULL_TREE); }
1552         ;
1553 \f
1554 nested_function:
1555           declarator
1556                 { if (pedantic)
1557                     pedwarn ("ISO C forbids nested functions");
1558
1559                   push_function_context ();
1560                   if (! start_function (current_declspecs, $1,
1561                                         all_prefix_attributes))
1562                     {
1563                       pop_function_context ();
1564                       YYERROR1;
1565                     }
1566                   parsing_iso_function_signature = false; /* Don't warn about nested functions.  */
1567                 }
1568            old_style_parm_decls save_location
1569                 { tree decl = current_function_decl;
1570                   DECL_SOURCE_LOCATION (decl) = $4;
1571                   store_parm_decls (); }
1572 /* This used to use compstmt_or_error.
1573    That caused a bug with input `f(g) int g {}',
1574    where the use of YYERROR1 above caused an error
1575    which then was handled by compstmt_or_error.
1576    There followed a repeated execution of that same rule,
1577    which called YYERROR1 again, and so on.  */
1578           compstmt
1579                 { tree decl = current_function_decl;
1580                   finish_function ();
1581                   pop_function_context ();
1582                   add_decl_stmt (decl); }
1583         ;
1584
1585 notype_nested_function:
1586           notype_declarator
1587                 { if (pedantic)
1588                     pedwarn ("ISO C forbids nested functions");
1589
1590                   push_function_context ();
1591                   if (! start_function (current_declspecs, $1,
1592                                         all_prefix_attributes))
1593                     {
1594                       pop_function_context ();
1595                       YYERROR1;
1596                     }
1597                   parsing_iso_function_signature = false; /* Don't warn about nested functions.  */
1598                 }
1599           old_style_parm_decls save_location
1600                 { tree decl = current_function_decl;
1601                   DECL_SOURCE_LOCATION (decl) = $4;
1602                   store_parm_decls (); }
1603 /* This used to use compstmt_or_error.
1604    That caused a bug with input `f(g) int g {}',
1605    where the use of YYERROR1 above caused an error
1606    which then was handled by compstmt_or_error.
1607    There followed a repeated execution of that same rule,
1608    which called YYERROR1 again, and so on.  */
1609           compstmt
1610                 { tree decl = current_function_decl;
1611                   finish_function ();
1612                   pop_function_context ();
1613                   add_decl_stmt (decl); }
1614         ;
1615
1616 /* Any kind of declarator (thus, all declarators allowed
1617    after an explicit typespec).  */
1618
1619 declarator:
1620           after_type_declarator
1621         | notype_declarator
1622         ;
1623
1624 /* A declarator that is allowed only after an explicit typespec.  */
1625
1626 after_type_declarator:
1627           '(' maybe_attribute after_type_declarator ')'
1628                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1629         | after_type_declarator '(' parmlist_or_identifiers  %prec '.'
1630                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1631 /*      | after_type_declarator '(' error ')'  %prec '.'
1632                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1633                   poplevel (0, 0, 0); }  */
1634         | after_type_declarator array_declarator  %prec '.'
1635                 { $$ = set_array_declarator_type ($2, $1, 0); }
1636         | '*' maybe_type_quals_attrs after_type_declarator  %prec UNARY
1637                 { $$ = make_pointer_declarator ($2, $3); }
1638         | TYPENAME
1639 @@ifobjc
1640         | OBJECTNAME
1641 @@end_ifobjc
1642         ;
1643
1644 /* Kinds of declarator that can appear in a parameter list
1645    in addition to notype_declarator.  This is like after_type_declarator
1646    but does not allow a typedef name in parentheses as an identifier
1647    (because it would conflict with a function with that typedef as arg).  */
1648 parm_declarator:
1649           parm_declarator_starttypename
1650         | parm_declarator_nostarttypename
1651         ;
1652
1653 parm_declarator_starttypename:
1654           parm_declarator_starttypename '(' parmlist_or_identifiers  %prec '.'
1655                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1656 /*      | parm_declarator_starttypename '(' error ')'  %prec '.'
1657                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1658                   poplevel (0, 0, 0); }  */
1659         | parm_declarator_starttypename array_declarator  %prec '.'
1660                 { $$ = set_array_declarator_type ($2, $1, 0); }
1661         | TYPENAME
1662 @@ifobjc
1663         | OBJECTNAME
1664 @@end_ifobjc
1665         ;
1666
1667 parm_declarator_nostarttypename:
1668           parm_declarator_nostarttypename '(' parmlist_or_identifiers  %prec '.'
1669                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1670 /*      | parm_declarator_nostarttypename '(' error ')'  %prec '.'
1671                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1672                   poplevel (0, 0, 0); }  */
1673         | parm_declarator_nostarttypename array_declarator  %prec '.'
1674                 { $$ = set_array_declarator_type ($2, $1, 0); }
1675         | '*' maybe_type_quals_attrs parm_declarator_starttypename  %prec UNARY
1676                 { $$ = make_pointer_declarator ($2, $3); }
1677         | '*' maybe_type_quals_attrs parm_declarator_nostarttypename  %prec UNARY
1678                 { $$ = make_pointer_declarator ($2, $3); }
1679         | '(' maybe_attribute parm_declarator_nostarttypename ')'
1680                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1681         ;
1682
1683 /* A declarator allowed whether or not there has been
1684    an explicit typespec.  These cannot redeclare a typedef-name.  */
1685
1686 notype_declarator:
1687           notype_declarator '(' parmlist_or_identifiers  %prec '.'
1688                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1689 /*      | notype_declarator '(' error ')'  %prec '.'
1690                 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1691                   poplevel (0, 0, 0); }  */
1692         | '(' maybe_attribute notype_declarator ')'
1693                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1694         | '*' maybe_type_quals_attrs notype_declarator  %prec UNARY
1695                 { $$ = make_pointer_declarator ($2, $3); }
1696         | notype_declarator array_declarator  %prec '.'
1697                 { $$ = set_array_declarator_type ($2, $1, 0); }
1698         | IDENTIFIER
1699         ;
1700
1701 struct_head:
1702           STRUCT
1703                 { $$ = NULL_TREE; }
1704         | STRUCT attributes
1705                 { $$ = $2; }
1706         ;
1707
1708 union_head:
1709           UNION
1710                 { $$ = NULL_TREE; }
1711         | UNION attributes
1712                 { $$ = $2; }
1713         ;
1714
1715 enum_head:
1716           ENUM
1717                 { $$ = NULL_TREE; }
1718         | ENUM attributes
1719                 { $$ = $2; }
1720         ;
1721
1722 /* structsp_attr: struct/union/enum specifiers that either
1723    end with attributes, or are such that any following attributes would
1724    be parsed as part of the struct/union/enum specifier.
1725
1726    structsp_nonattr: other struct/union/enum specifiers.  */
1727
1728 structsp_attr:
1729           struct_head identifier '{'
1730                 { $$ = start_struct (RECORD_TYPE, $2);
1731                   /* Start scope of tag before parsing components.  */
1732                 }
1733           component_decl_list '}' maybe_attribute
1734                 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1735                                       chainon ($1, $7)); }
1736         | struct_head '{' component_decl_list '}' maybe_attribute
1737                 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1738                                       nreverse ($3), chainon ($1, $5));
1739                 }
1740         | union_head identifier '{'
1741                 { $$ = start_struct (UNION_TYPE, $2); }
1742           component_decl_list '}' maybe_attribute
1743                 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1744                                       chainon ($1, $7)); }
1745         | union_head '{' component_decl_list '}' maybe_attribute
1746                 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1747                                       nreverse ($3), chainon ($1, $5));
1748                 }
1749         | enum_head identifier '{'
1750                 { $$ = start_enum ($2); }
1751           enumlist maybecomma_warn '}' maybe_attribute
1752                 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1753                                     chainon ($1, $8)); }
1754         | enum_head '{'
1755                 { $$ = start_enum (NULL_TREE); }
1756           enumlist maybecomma_warn '}' maybe_attribute
1757                 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1758                                     chainon ($1, $7)); }
1759         ;
1760
1761 structsp_nonattr:
1762           struct_head identifier
1763                 { $$ = xref_tag (RECORD_TYPE, $2); }
1764         | union_head identifier
1765                 { $$ = xref_tag (UNION_TYPE, $2); }
1766         | enum_head identifier
1767                 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1768                   /* In ISO C, enumerated types can be referred to
1769                      only if already defined.  */
1770                   if (pedantic && !COMPLETE_TYPE_P ($$))
1771                     pedwarn ("ISO C forbids forward references to `enum' types"); }
1772         ;
1773
1774 maybecomma:
1775           /* empty */
1776         | ','
1777         ;
1778
1779 maybecomma_warn:
1780           /* empty */
1781         | ','
1782                 { if (pedantic && ! flag_isoc99)
1783                     pedwarn ("comma at end of enumerator list"); }
1784         ;
1785
1786 /* We chain the components in reverse order.  They are put in forward
1787    order in structsp_attr.
1788
1789    Note that component_declarator returns single decls, so components
1790    and components_notype can use TREE_CHAIN directly, wheras components
1791    and components_notype return lists (of comma separated decls), so
1792    component_decl_list and component_decl_list2 must use chainon.
1793
1794    The theory behind all this is that there will be more semicolon
1795    separated fields than comma separated fields, and so we'll be
1796    minimizing the number of node traversals required by chainon.  */
1797
1798 component_decl_list:
1799           component_decl_list2
1800                 { $$ = $1; }
1801         | component_decl_list2 component_decl
1802                 { $$ = chainon ($2, $1);
1803                   pedwarn ("no semicolon at end of struct or union"); }
1804         ;
1805
1806 component_decl_list2:   /* empty */
1807                 { $$ = NULL_TREE; }
1808         | component_decl_list2 component_decl ';'
1809                 { $$ = chainon ($2, $1); }
1810         | component_decl_list2 ';'
1811                 { if (pedantic)
1812                     pedwarn ("extra semicolon in struct or union specified"); }
1813 @@ifobjc
1814         /* foo(sizeof(struct{ @defs(ClassName)})); */
1815         | DEFS '(' CLASSNAME ')'
1816                 { $$ = nreverse (get_class_ivars_from_name ($3)); }
1817 @@end_ifobjc
1818         ;
1819
1820 component_decl:
1821           declspecs_nosc_ts setspecs components
1822                 { $$ = $3;
1823                   POP_DECLSPEC_STACK; }
1824         | declspecs_nosc_ts setspecs
1825                 {
1826                   /* Support for unnamed structs or unions as members of
1827                      structs or unions (which is [a] useful and [b] supports
1828                      MS P-SDK).  */
1829                   if (pedantic)
1830                     pedwarn ("ISO C doesn't support unnamed structs/unions");
1831
1832                   $$ = grokfield(NULL, current_declspecs, NULL_TREE);
1833                   POP_DECLSPEC_STACK; }
1834         | declspecs_nosc_nots setspecs components_notype
1835                 { $$ = $3;
1836                   POP_DECLSPEC_STACK; }
1837         | declspecs_nosc_nots
1838                 { if (pedantic)
1839                     pedwarn ("ISO C forbids member declarations with no members");
1840                   shadow_tag_warned ($1, pedantic);
1841                   $$ = NULL_TREE; }
1842         | error
1843                 { $$ = NULL_TREE; }
1844         | extension component_decl
1845                 { $$ = $2;
1846                   RESTORE_EXT_FLAGS ($1); }
1847         ;
1848
1849 components:
1850           component_declarator
1851         | components ',' maybe_resetattrs component_declarator
1852                 { TREE_CHAIN ($4) = $1; $$ = $4; }
1853         ;
1854
1855 components_notype:
1856           component_notype_declarator
1857         | components_notype ',' maybe_resetattrs component_notype_declarator
1858                 { TREE_CHAIN ($4) = $1; $$ = $4; }
1859         ;
1860
1861 component_declarator:
1862           declarator maybe_attribute
1863                 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1864                   decl_attributes (&$$,
1865                                    chainon ($2, all_prefix_attributes), 0); }
1866         | declarator ':' expr_no_commas maybe_attribute
1867                 { $$ = grokfield ($1, current_declspecs, $3);
1868                   decl_attributes (&$$,
1869                                    chainon ($4, all_prefix_attributes), 0); }
1870         | ':' expr_no_commas maybe_attribute
1871                 { $$ = grokfield (NULL_TREE, current_declspecs, $2);
1872                   decl_attributes (&$$,
1873                                    chainon ($3, all_prefix_attributes), 0); }
1874         ;
1875
1876 component_notype_declarator:
1877           notype_declarator maybe_attribute
1878                 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1879                   decl_attributes (&$$,
1880                                    chainon ($2, all_prefix_attributes), 0); }
1881         | notype_declarator ':' expr_no_commas maybe_attribute
1882                 { $$ = grokfield ($1, current_declspecs, $3);
1883                   decl_attributes (&$$,
1884                                    chainon ($4, all_prefix_attributes), 0); }
1885         | ':' expr_no_commas maybe_attribute
1886                 { $$ = grokfield (NULL_TREE, current_declspecs, $2);
1887                   decl_attributes (&$$,
1888                                    chainon ($3, all_prefix_attributes), 0); }
1889         ;
1890
1891 /* We chain the enumerators in reverse order.
1892    They are put in forward order in structsp_attr.  */
1893
1894 enumlist:
1895           enumerator
1896         | enumlist ',' enumerator
1897                 { if ($1 == error_mark_node)
1898                     $$ = $1;
1899                   else
1900                     TREE_CHAIN ($3) = $1, $$ = $3; }
1901         | error
1902                 { $$ = error_mark_node; }
1903         ;
1904
1905
1906 enumerator:
1907           identifier
1908                 { $$ = build_enumerator ($1, NULL_TREE); }
1909         | identifier '=' expr_no_commas
1910                 { $$ = build_enumerator ($1, $3); }
1911         ;
1912
1913 typename:
1914           declspecs_nosc
1915                 { pending_xref_error ();
1916                   $<ttype>$ = $1; }
1917           absdcl
1918                 { $$ = build_tree_list ($<ttype>2, $3); }
1919         ;
1920
1921 absdcl:   /* an absolute declarator */
1922         /* empty */
1923                 { $$ = NULL_TREE; }
1924         | absdcl1
1925         ;
1926
1927 absdcl_maybe_attribute:   /* absdcl maybe_attribute, but not just attributes */
1928         /* empty */
1929                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1930                                                          NULL_TREE),
1931                                         all_prefix_attributes); }
1932         | absdcl1
1933                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1934                                                          $1),
1935                                         all_prefix_attributes); }
1936         | absdcl1_noea attributes
1937                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1938                                                          $1),
1939                                         chainon ($2, all_prefix_attributes)); }
1940         ;
1941
1942 absdcl1:  /* a nonempty absolute declarator */
1943           absdcl1_ea
1944         | absdcl1_noea
1945         ;
1946
1947 absdcl1_noea:
1948           direct_absdcl1
1949         | '*' maybe_type_quals_attrs absdcl1_noea
1950                 { $$ = make_pointer_declarator ($2, $3); }
1951         ;
1952
1953 absdcl1_ea:
1954           '*' maybe_type_quals_attrs
1955                 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1956         | '*' maybe_type_quals_attrs absdcl1_ea
1957                 { $$ = make_pointer_declarator ($2, $3); }
1958         ;
1959
1960 direct_absdcl1:
1961           '(' maybe_attribute absdcl1 ')'
1962                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1963         | direct_absdcl1 '(' parmlist
1964                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1965         | direct_absdcl1 array_declarator
1966                 { $$ = set_array_declarator_type ($2, $1, 1); }
1967         | '(' parmlist
1968                 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
1969         | array_declarator
1970                 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
1971         ;
1972
1973 /* The [...] part of a declarator for an array type.  */
1974
1975 array_declarator:
1976         '[' maybe_type_quals_attrs expr ']'
1977                 { $$ = build_array_declarator ($3, $2, 0, 0); }
1978         | '[' maybe_type_quals_attrs ']'
1979                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
1980         | '[' maybe_type_quals_attrs '*' ']'
1981                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
1982         | '[' STATIC maybe_type_quals_attrs expr ']'
1983                 { $$ = build_array_declarator ($4, $3, 1, 0); }
1984         /* declspecs_nosc_nots is a synonym for type_quals_attrs.  */
1985         | '[' declspecs_nosc_nots STATIC expr ']'
1986                 { $$ = build_array_declarator ($4, $2, 1, 0); }
1987         ;
1988
1989 /* A nonempty series of declarations and statements (possibly followed by
1990    some labels) that can form the body of a compound statement.
1991    NOTE: we don't allow labels on declarations; this might seem like a
1992    natural extension, but there would be a conflict between attributes
1993    on the label and prefix attributes on the declaration.  */
1994
1995 stmts_and_decls:
1996           lineno_stmt_decl_or_labels_ending_stmt
1997         | lineno_stmt_decl_or_labels_ending_decl
1998         | lineno_stmt_decl_or_labels_ending_label
1999                 {
2000                   pedwarn ("deprecated use of label at end of compound statement");
2001                 }
2002         | lineno_stmt_decl_or_labels_ending_error
2003         ;
2004
2005 lineno_stmt_decl_or_labels_ending_stmt:
2006           lineno_stmt
2007         | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
2008         | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
2009         | lineno_stmt_decl_or_labels_ending_label lineno_stmt
2010         | lineno_stmt_decl_or_labels_ending_error lineno_stmt
2011         ;
2012
2013 lineno_stmt_decl_or_labels_ending_decl:
2014           lineno_decl
2015         | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
2016                 {
2017                   if ((pedantic && !flag_isoc99)
2018                       || warn_declaration_after_statement)
2019                     pedwarn_c90 ("ISO C90 forbids mixed declarations and code");
2020                 }
2021         | lineno_stmt_decl_or_labels_ending_decl lineno_decl
2022         | lineno_stmt_decl_or_labels_ending_error lineno_decl
2023         ;
2024
2025 lineno_stmt_decl_or_labels_ending_label:
2026           lineno_label
2027         | lineno_stmt_decl_or_labels_ending_stmt lineno_label
2028         | lineno_stmt_decl_or_labels_ending_decl lineno_label
2029         | lineno_stmt_decl_or_labels_ending_label lineno_label
2030         | lineno_stmt_decl_or_labels_ending_error lineno_label
2031         ;
2032
2033 lineno_stmt_decl_or_labels_ending_error:
2034         errstmt
2035         | lineno_stmt_decl_or_labels errstmt
2036         ;
2037
2038 lineno_stmt_decl_or_labels:
2039           lineno_stmt_decl_or_labels_ending_stmt
2040         | lineno_stmt_decl_or_labels_ending_decl
2041         | lineno_stmt_decl_or_labels_ending_label
2042         | lineno_stmt_decl_or_labels_ending_error
2043         ;
2044
2045 errstmt:  error ';'
2046         ;
2047
2048 pushlevel:  /* empty */
2049                 { pushlevel (0);
2050                   clear_last_expr ();
2051                   add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2052                 }
2053         ;
2054
2055 poplevel:  /* empty */
2056                 {
2057 @@ifobjc
2058                   if (c_dialect_objc ())
2059                     objc_clear_super_receiver ();
2060 @@end_ifobjc
2061                   $$ = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2062                 }
2063         ;
2064
2065 /* Start and end blocks created for the new scopes of C99.  */
2066 c99_block_start: /* empty */
2067                 { if (flag_isoc99)
2068                     {
2069                       $$ = c_begin_compound_stmt ();
2070                       pushlevel (0);
2071                       clear_last_expr ();
2072                       add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2073                     }
2074                   else
2075                     $$ = NULL_TREE;
2076                 }
2077         ;
2078
2079 /* Productions using c99_block_start and c99_block_end will need to do what's
2080    in compstmt: RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); $$ = $2; where
2081    $1 is the value of c99_block_start and $2 of c99_block_end.  */
2082 c99_block_end: /* empty */
2083                 { if (flag_isoc99)
2084                     {
2085                       tree scope_stmt = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2086                       $$ = poplevel (KEEP_MAYBE, 0, 0);
2087                       SCOPE_STMT_BLOCK (TREE_PURPOSE (scope_stmt))
2088                         = SCOPE_STMT_BLOCK (TREE_VALUE (scope_stmt))
2089                         = $$;
2090                     }
2091                   else
2092                     $$ = NULL_TREE; }
2093         ;
2094
2095 /* Read zero or more forward-declarations for labels
2096    that nested functions can jump to.  */
2097 maybe_label_decls:
2098           /* empty */
2099         | label_decls
2100                 { if (pedantic)
2101                     pedwarn ("ISO C forbids label declarations"); }
2102         ;
2103
2104 label_decls:
2105           label_decl
2106         | label_decls label_decl
2107         ;
2108
2109 label_decl:
2110           LABEL identifiers_or_typenames ';'
2111                 { tree link;
2112                   for (link = $2; link; link = TREE_CHAIN (link))
2113                     {
2114                       tree label = declare_label (TREE_VALUE (link));
2115                       C_DECLARED_LABEL_FLAG (label) = 1;
2116                       add_decl_stmt (label);
2117                     }
2118                 }
2119         ;
2120
2121 /* This is the body of a function definition.
2122    It causes syntax errors to ignore to the next openbrace.  */
2123 compstmt_or_error:
2124           compstmt
2125                 {}
2126         | error compstmt
2127         ;
2128
2129 compstmt_start: '{' { compstmt_count++;
2130                       $$ = c_begin_compound_stmt (); }
2131         ;
2132
2133 compstmt_nostart: '}'
2134                 { $$ = convert (void_type_node, integer_zero_node); }
2135         | pushlevel maybe_label_decls compstmt_contents_nonempty '}' poplevel
2136                 { $$ = poplevel (KEEP_MAYBE, 0, 0);
2137                   SCOPE_STMT_BLOCK (TREE_PURPOSE ($5))
2138                     = SCOPE_STMT_BLOCK (TREE_VALUE ($5))
2139                     = $$; }
2140         ;
2141
2142 compstmt_contents_nonempty:
2143           stmts_and_decls
2144         | error
2145         ;
2146
2147 compstmt_primary_start:
2148         '(' '{'
2149                 { if (current_function_decl == 0)
2150                     {
2151                       error ("braced-group within expression allowed only inside a function");
2152                       YYERROR;
2153                     }
2154                   /* We must force a BLOCK for this level
2155                      so that, if it is not expanded later,
2156                      there is a way to turn off the entire subtree of blocks
2157                      that are contained in it.  */
2158                   keep_next_level ();
2159                   compstmt_count++;
2160                   $$ = add_stmt (build_stmt (COMPOUND_STMT, last_tree));
2161                 }
2162         ;
2163
2164 compstmt: compstmt_start compstmt_nostart
2165                 { RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2166                   last_expr_type = NULL_TREE;
2167                   $$ = $1; }
2168         ;
2169
2170 /* Value is number of statements counted as of the closeparen.  */
2171 simple_if:
2172           if_prefix c99_block_lineno_labeled_stmt
2173                 { c_finish_then (); }
2174 /* Make sure c_expand_end_cond is run once
2175    for each call to c_expand_start_cond.
2176    Otherwise a crash is likely.  */
2177         | if_prefix error
2178         ;
2179
2180 if_prefix:
2181           /* We must build the IF_STMT node before parsing its
2182              condition so that STMT_LINENO refers to the line
2183              containing the "if", and not the line containing
2184              the close-parenthesis.
2185
2186              c_begin_if_stmt returns the IF_STMT node, which
2187              we later pass to c_expand_start_cond to fill
2188              in the condition and other tidbits.  */
2189           IF
2190                 { $<ttype>$ = c_begin_if_stmt (); }
2191             '(' expr ')'
2192                 { c_expand_start_cond (c_common_truthvalue_conversion ($4),
2193                                        compstmt_count,$<ttype>2);
2194                   $<itype>$ = stmt_count;
2195                   if_stmt_locus = $<location>-1; }
2196         ;
2197
2198 /* This is a subroutine of stmt.
2199    It is used twice, once for valid DO statements
2200    and once for catching errors in parsing the end test.  */
2201 do_stmt_start:
2202           DO
2203                 { stmt_count++;
2204                   compstmt_count++;
2205                   $<ttype>$
2206                     = add_stmt (build_stmt (DO_STMT, NULL_TREE,
2207                                             NULL_TREE));
2208                   /* In the event that a parse error prevents
2209                      parsing the complete do-statement, set the
2210                      condition now.  Otherwise, we can get crashes at
2211                      RTL-generation time.  */
2212                   DO_COND ($<ttype>$) = error_mark_node; }
2213           c99_block_lineno_labeled_stmt WHILE
2214                 { $$ = $<ttype>2;
2215                   RECHAIN_STMTS ($$, DO_BODY ($$)); }
2216         ;
2217
2218 /* The forced readahead in here is because we might be at the end of a
2219    line, and the line and file won't be bumped until yylex absorbs the
2220    first token on the next line.  */
2221
2222 save_location:
2223                 { if (yychar == YYEMPTY)
2224                     yychar = YYLEX;
2225                   $$ = input_location; }
2226         ;
2227
2228 lineno_labeled_stmt:
2229           lineno_stmt
2230         | lineno_label lineno_labeled_stmt
2231         ;
2232
2233 /* Like lineno_labeled_stmt, but a block in C99.  */
2234 c99_block_lineno_labeled_stmt:
2235           c99_block_start lineno_labeled_stmt c99_block_end
2236                 { if (flag_isoc99)
2237                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); }
2238         ;
2239
2240 lineno_stmt:
2241           save_location stmt
2242                 { if ($2)
2243                     {
2244                       STMT_LINENO ($2) = $1.line;
2245                       /* ??? We currently have no way of recording
2246                          the filename for a statement.  This probably
2247                          matters little in practice at the moment,
2248                          but I suspect that problems will occur when
2249                          doing inlining at the tree level.  */
2250                     }
2251                 }
2252         ;
2253
2254 lineno_label:
2255           save_location label
2256                 { if ($2)
2257                     {
2258                       STMT_LINENO ($2) = $1.line;
2259                     }
2260                 }
2261         ;
2262
2263 select_or_iter_stmt:
2264           simple_if ELSE
2265                 { c_expand_start_else ();
2266                   $<itype>1 = stmt_count; }
2267           c99_block_lineno_labeled_stmt
2268                 { c_finish_else ();
2269                   c_expand_end_cond ();
2270                   if (extra_warnings && stmt_count == $<itype>1)
2271                     warning ("empty body in an else-statement"); }
2272         | simple_if %prec IF
2273                 { c_expand_end_cond ();
2274                   /* This warning is here instead of in simple_if, because we
2275                      do not want a warning if an empty if is followed by an
2276                      else statement.  Increment stmt_count so we don't
2277                      give a second error if this is a nested `if'.  */
2278                   if (extra_warnings && stmt_count++ == $<itype>1)
2279                     warning ("%Hempty body in an if-statement",
2280                              &if_stmt_locus); }
2281 /* Make sure c_expand_end_cond is run once
2282    for each call to c_expand_start_cond.
2283    Otherwise a crash is likely.  */
2284         | simple_if ELSE error
2285                 { c_expand_end_cond (); }
2286        /* We must build the WHILE_STMT node before parsing its
2287           condition so that STMT_LINENO refers to the line
2288           containing the "while", and not the line containing
2289           the close-parenthesis.
2290
2291           c_begin_while_stmt returns the WHILE_STMT node, which
2292           we later pass to c_finish_while_stmt_cond to fill
2293           in the condition and other tidbits.  */
2294         | WHILE
2295                 { stmt_count++;
2296                   $<ttype>$ = c_begin_while_stmt (); }
2297           '(' expr ')'
2298                 { $4 = c_common_truthvalue_conversion ($4);
2299                   c_finish_while_stmt_cond
2300                     (c_common_truthvalue_conversion ($4), $<ttype>2);
2301                   $<ttype>$ = add_stmt ($<ttype>2); }
2302           c99_block_lineno_labeled_stmt
2303                 { RECHAIN_STMTS ($<ttype>6, WHILE_BODY ($<ttype>6)); }
2304         | do_stmt_start
2305           '(' expr ')' ';'
2306                 { DO_COND ($1) = c_common_truthvalue_conversion ($3); }
2307         | do_stmt_start error
2308                 { }
2309         | FOR
2310                 { $<ttype>$ = build_stmt (FOR_STMT, NULL_TREE, NULL_TREE,
2311                                           NULL_TREE, NULL_TREE);
2312                   add_stmt ($<ttype>$); }
2313           '(' for_init_stmt
2314                 { stmt_count++;
2315                   RECHAIN_STMTS ($<ttype>2, FOR_INIT_STMT ($<ttype>2)); }
2316           xexpr ';'
2317                 { if ($6)
2318                     FOR_COND ($<ttype>2)
2319                       = c_common_truthvalue_conversion ($6); }
2320           xexpr ')'
2321                 { FOR_EXPR ($<ttype>2) = $9; }
2322           c99_block_lineno_labeled_stmt
2323                 { RECHAIN_STMTS ($<ttype>2, FOR_BODY ($<ttype>2)); }
2324         | SWITCH '(' expr ')'
2325                 { stmt_count++;
2326                   $<ttype>$ = c_start_case ($3); }
2327           c99_block_lineno_labeled_stmt
2328                 { c_finish_case (); }
2329         ;
2330
2331 for_init_stmt:
2332           xexpr ';'
2333                 { add_stmt (build_stmt (EXPR_STMT, $1)); }
2334         | decl
2335                 { check_for_loop_decls (); }
2336         ;
2337
2338 /* Parse a single real statement, not including any labels.  */
2339 stmt:
2340           compstmt
2341                 { stmt_count++; $$ = $1; }
2342         | expr ';'
2343                 { stmt_count++;
2344                   $$ = c_expand_expr_stmt ($1); }
2345         | c99_block_start select_or_iter_stmt c99_block_end
2346                 { if (flag_isoc99)
2347                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2348                   $$ = NULL_TREE; }
2349         | BREAK ';'
2350                 { stmt_count++;
2351                   $$ = add_stmt (build_break_stmt ()); }
2352         | CONTINUE ';'
2353                 { stmt_count++;
2354                   $$ = add_stmt (build_continue_stmt ()); }
2355         | RETURN ';'
2356                 { stmt_count++;
2357                   $$ = c_expand_return (NULL_TREE); }
2358         | RETURN expr ';'
2359                 { stmt_count++;
2360                   $$ = c_expand_return ($2); }
2361         | ASM_KEYWORD maybe_type_qual '(' expr ')' ';'
2362                 { stmt_count++;
2363                   $$ = simple_asm_stmt ($4); }
2364         /* This is the case with just output operands.  */
2365         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ')' ';'
2366                 { stmt_count++;
2367                   $$ = build_asm_stmt ($2, $4, $6, NULL_TREE, NULL_TREE); }
2368         /* This is the case with input operands as well.  */
2369         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2370           asm_operands ')' ';'
2371                 { stmt_count++;
2372                   $$ = build_asm_stmt ($2, $4, $6, $8, NULL_TREE); }
2373         /* This is the case with clobbered registers as well.  */
2374         | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2375           asm_operands ':' asm_clobbers ')' ';'
2376                 { stmt_count++;
2377                   $$ = build_asm_stmt ($2, $4, $6, $8, $10); }
2378         | GOTO identifier ';'
2379                 { tree decl;
2380                   stmt_count++;
2381                   decl = lookup_label ($2);
2382                   if (decl != 0)
2383                     {
2384                       TREE_USED (decl) = 1;
2385                       $$ = add_stmt (build_stmt (GOTO_STMT, decl));
2386                     }
2387                   else
2388                     $$ = NULL_TREE;
2389                 }
2390         | GOTO '*' expr ';'
2391                 { if (pedantic)
2392                     pedwarn ("ISO C forbids `goto *expr;'");
2393                   stmt_count++;
2394                   $3 = convert (ptr_type_node, $3);
2395                   $$ = add_stmt (build_stmt (GOTO_STMT, $3)); }
2396         | ';'
2397                 { $$ = NULL_TREE; }
2398 @@ifobjc
2399         | AT_THROW expr ';'
2400                 { stmt_count++;
2401                   $$ = objc_build_throw_stmt ($2);
2402                 }
2403         | AT_THROW ';'
2404                 { stmt_count++;
2405                   $$ = objc_build_throw_stmt (NULL_TREE);
2406                 }
2407         | objc_try_catch_stmt
2408                 { objc_build_finally_prologue (); }
2409           objc_finally_block
2410                 { $$ = objc_build_try_catch_finally_stmt ($1, $3); }
2411         | AT_SYNCHRONIZED '(' expr ')'
2412                 { objc_build_synchronized_prologue ($3); }
2413           compstmt
2414                 { $$ = objc_build_synchronized_epilogue (); }
2415         ;
2416
2417 objc_try_catch_stmt:
2418           objc_try_stmt
2419                 { objc_build_try_epilogue (1); }
2420           objc_catch_list
2421                 { objc_build_catch_epilogue (); $$ = 1; }
2422         | objc_try_stmt
2423                 { objc_build_try_epilogue (0); $$ = 0; }
2424         ;
2425
2426
2427 objc_try_stmt:
2428           AT_TRY
2429                 { objc_build_try_prologue (); }
2430           compstmt
2431         ;
2432
2433 objc_catch_list:
2434           objc_catch_list objc_catch_block
2435         | objc_catch_block
2436         ;
2437
2438 objc_catch_block:
2439           AT_CATCH '(' parm ')'
2440                 { objc_build_catch_stmt ($3); }
2441           compstmt
2442                 { stmt_count++; }
2443         ;
2444
2445 objc_finally_block:
2446           AT_FINALLY compstmt
2447             { $$ = 1; }
2448         | /* NULL */
2449             { $$ = 0; }
2450 @@end_ifobjc
2451         ;
2452
2453 /* Any kind of label, including jump labels and case labels.
2454    ANSI C accepts labels only before statements, but we allow them
2455    also at the end of a compound statement.  */
2456
2457 label:    CASE expr_no_commas ':'
2458                 { stmt_count++;
2459                   $$ = do_case ($2, NULL_TREE); }
2460         | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2461                 { stmt_count++;
2462                   $$ = do_case ($2, $4); }
2463         | DEFAULT ':'
2464                 { stmt_count++;
2465                   $$ = do_case (NULL_TREE, NULL_TREE); }
2466         | identifier save_location ':' maybe_attribute
2467                 { tree label = define_label ($2, $1);
2468                   stmt_count++;
2469                   if (label)
2470                     {
2471                       decl_attributes (&label, $4, 0);
2472                       $$ = add_stmt (build_stmt (LABEL_STMT, label));
2473                     }
2474                   else
2475                     $$ = NULL_TREE;
2476                 }
2477         ;
2478
2479 /* Either a type-qualifier or nothing.  First thing in an `asm' statement.  */
2480
2481 maybe_type_qual:
2482         /* empty */
2483                 { emit_line_note (input_location);
2484                   $$ = NULL_TREE; }
2485         | TYPE_QUAL
2486                 { emit_line_note (input_location); }
2487         ;
2488
2489 xexpr:
2490         /* empty */
2491                 { $$ = NULL_TREE; }
2492         | expr
2493         ;
2494
2495 /* These are the operands other than the first string and colon
2496    in  asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x))  */
2497 asm_operands: /* empty */
2498                 { $$ = NULL_TREE; }
2499         | nonnull_asm_operands
2500         ;
2501
2502 nonnull_asm_operands:
2503           asm_operand
2504         | nonnull_asm_operands ',' asm_operand
2505                 { $$ = chainon ($1, $3); }
2506         ;
2507
2508 asm_operand:
2509           STRING '(' expr ')'
2510                 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1), $3); }
2511         | '[' identifier ']' STRING '(' expr ')'
2512                 { $2 = build_string (IDENTIFIER_LENGTH ($2),
2513                                      IDENTIFIER_POINTER ($2));
2514                   $$ = build_tree_list (build_tree_list ($2, $4), $6); }
2515         ;
2516
2517 asm_clobbers:
2518           STRING
2519                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE); }
2520         | asm_clobbers ',' STRING
2521                 { $$ = tree_cons (NULL_TREE, $3, $1); }
2522         ;
2523 \f
2524 /* This is what appears inside the parens in a function declarator.
2525    Its value is a list of ..._TYPE nodes.  Attributes must appear here
2526    to avoid a conflict with their appearance after an open parenthesis
2527    in an abstract declarator, as in
2528    "void bar (int (__attribute__((__mode__(SI))) int foo));".  */
2529 parmlist:
2530           maybe_attribute
2531                 { pushlevel (0);
2532                   declare_parm_level (); }
2533           parmlist_1
2534                 { $$ = $3;
2535                   poplevel (0, 0, 0); }
2536         ;
2537
2538 parmlist_1:
2539           parmlist_2 ')'
2540         | parms ';'
2541                 { mark_forward_parm_decls (); }
2542           maybe_attribute
2543                 { /* Dummy action so attributes are in known place
2544                      on parser stack.  */ }
2545           parmlist_1
2546                 { $$ = $6; }
2547         | error ')'
2548                 { $$ = tree_cons (NULL_TREE, NULL_TREE, NULL_TREE); }
2549         ;
2550
2551 /* This is what appears inside the parens in a function declarator.
2552    Is value is represented in the format that grokdeclarator expects.  */
2553 parmlist_2:  /* empty */
2554                 { $$ = get_parm_info (0); }
2555         | ELLIPSIS
2556                 { $$ = get_parm_info (0);
2557                   /* Gcc used to allow this as an extension.  However, it does
2558                      not work for all targets, and thus has been disabled.
2559                      Also, since func (...) and func () are indistinguishable,
2560                      it caused problems with the code in expand_builtin which
2561                      tries to verify that BUILT_IN_NEXT_ARG is being used
2562                      correctly.  */
2563                   error ("ISO C requires a named argument before `...'");
2564                   parsing_iso_function_signature = true;
2565                 }
2566         | parms
2567                 { $$ = get_parm_info (1);
2568                   parsing_iso_function_signature = true;
2569                 }
2570         | parms ',' ELLIPSIS
2571                 { $$ = get_parm_info (0);
2572                   parsing_iso_function_signature = true;
2573                 }
2574         ;
2575
2576 parms:
2577         firstparm
2578                 { push_parm_decl ($1); }
2579         | parms ',' parm
2580                 { push_parm_decl ($3); }
2581         ;
2582
2583 /* A single parameter declaration or parameter type name,
2584    as found in a parmlist.  */
2585 parm:
2586           declspecs_ts setspecs parm_declarator maybe_attribute
2587                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2588                                                          $3),
2589                                         chainon ($4, all_prefix_attributes));
2590                   POP_DECLSPEC_STACK; }
2591         | declspecs_ts setspecs notype_declarator maybe_attribute
2592                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2593                                                          $3),
2594                                         chainon ($4, all_prefix_attributes));
2595                   POP_DECLSPEC_STACK; }
2596         | declspecs_ts setspecs absdcl_maybe_attribute
2597                 { $$ = $3;
2598                   POP_DECLSPEC_STACK; }
2599         | declspecs_nots setspecs notype_declarator maybe_attribute
2600                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2601                                                          $3),
2602                                         chainon ($4, all_prefix_attributes));
2603                   POP_DECLSPEC_STACK; }
2604
2605         | declspecs_nots setspecs absdcl_maybe_attribute
2606                 { $$ = $3;
2607                   POP_DECLSPEC_STACK; }
2608         ;
2609
2610 /* The first parm, which must suck attributes from off the top of the parser
2611    stack.  */
2612 firstparm:
2613           declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2614                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2615                                                          $3),
2616                                         chainon ($4, all_prefix_attributes));
2617                   POP_DECLSPEC_STACK; }
2618         | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2619                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2620                                                          $3),
2621                                         chainon ($4, all_prefix_attributes));
2622                   POP_DECLSPEC_STACK; }
2623         | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2624                 { $$ = $3;
2625                   POP_DECLSPEC_STACK; }
2626         | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2627                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2628                                                          $3),
2629                                         chainon ($4, all_prefix_attributes));
2630                   POP_DECLSPEC_STACK; }
2631
2632         | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2633                 { $$ = $3;
2634                   POP_DECLSPEC_STACK; }
2635         ;
2636
2637 setspecs_fp:
2638           setspecs
2639                 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2640                   all_prefix_attributes = prefix_attributes; }
2641         ;
2642
2643 /* This is used in a function definition
2644    where either a parmlist or an identifier list is ok.
2645    Its value is a list of ..._TYPE nodes or a list of identifiers.  */
2646 parmlist_or_identifiers:
2647           maybe_attribute
2648                 { pushlevel (0);
2649                   declare_parm_level (); }
2650           parmlist_or_identifiers_1
2651                 { $$ = $3;
2652                   poplevel (0, 0, 0); }
2653         ;
2654
2655 parmlist_or_identifiers_1:
2656           parmlist_1
2657         | identifiers ')'
2658                 { tree t;
2659                   for (t = $1; t; t = TREE_CHAIN (t))
2660                     if (TREE_VALUE (t) == NULL_TREE)
2661                       error ("`...' in old-style identifier list");
2662                   $$ = tree_cons (NULL_TREE, NULL_TREE, $1);
2663
2664                   /* Make sure we have a parmlist after attributes.  */
2665                   if ($<ttype>-1 != 0
2666                       && (TREE_CODE ($$) != TREE_LIST
2667                           || TREE_PURPOSE ($$) == 0
2668                           || TREE_CODE (TREE_PURPOSE ($$)) != PARM_DECL))
2669                     YYERROR1;
2670                 }
2671         ;
2672
2673 /* A nonempty list of identifiers.  */
2674 identifiers:
2675         IDENTIFIER
2676                 { $$ = build_tree_list (NULL_TREE, $1); }
2677         | identifiers ',' IDENTIFIER
2678                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2679         ;
2680
2681 /* A nonempty list of identifiers, including typenames.  */
2682 identifiers_or_typenames:
2683         identifier
2684                 { $$ = build_tree_list (NULL_TREE, $1); }
2685         | identifiers_or_typenames ',' identifier
2686                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2687         ;
2688
2689 extension:
2690         EXTENSION
2691                 { $$ = SAVE_EXT_FLAGS();
2692                   pedantic = 0;
2693                   warn_pointer_arith = 0;
2694                   warn_traditional = 0;
2695                   flag_iso = 0; }
2696         ;
2697 \f
2698 @@ifobjc
2699 /* Objective-C productions.  */
2700
2701 objcdef:
2702           classdef
2703         | classdecl
2704         | aliasdecl
2705         | protocoldef
2706         | methoddef
2707         | END
2708                 {
2709                   if (objc_implementation_context)
2710                     {
2711                       finish_class (objc_implementation_context);
2712                       objc_ivar_chain = NULL_TREE;
2713                       objc_implementation_context = NULL_TREE;
2714                     }
2715                   else
2716                     warning ("`@end' must appear in an implementation context");
2717                 }
2718         ;
2719
2720 /* A nonempty list of identifiers.  */
2721 identifier_list:
2722         identifier
2723                 { $$ = build_tree_list (NULL_TREE, $1); }
2724         | identifier_list ',' identifier
2725                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2726         ;
2727
2728 classdecl:
2729           CLASS identifier_list ';'
2730                 {
2731                   objc_declare_class ($2);
2732                 }
2733         ;
2734
2735 aliasdecl:
2736           ALIAS identifier identifier ';'
2737                 {
2738                   objc_declare_alias ($2, $3);
2739                 }
2740         ;
2741
2742 superclass:
2743           ':' identifier { $$ = $2; }
2744         | /* NULL */ %prec HYPERUNARY    { $$ = NULL_TREE; }
2745         ;
2746
2747 class_ivars:
2748           '{' ivar_decl_list '}'
2749         | /* NULL */
2750         ;
2751
2752 classdef:
2753           INTERFACE identifier superclass protocolrefs
2754                 {
2755                   objc_interface_context = objc_ivar_context
2756                     = start_class (CLASS_INTERFACE_TYPE, $2, $3, $4);
2757                   objc_public_flag = 0;
2758                 }
2759           class_ivars
2760                 {
2761                   continue_class (objc_interface_context);
2762                 }
2763           methodprotolist END
2764                 {
2765                   finish_class (objc_interface_context);
2766                   objc_interface_context = NULL_TREE;
2767                 }
2768
2769         | IMPLEMENTATION identifier superclass
2770                 {
2771                   objc_implementation_context = objc_ivar_context
2772                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $3, NULL_TREE);
2773                   objc_public_flag = 0;
2774                 }
2775           class_ivars
2776                 {
2777                   objc_ivar_chain
2778                     = continue_class (objc_implementation_context);
2779                 }
2780
2781         | INTERFACE identifier '(' identifier ')' protocolrefs
2782                 {
2783                   objc_interface_context
2784                     = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2785                   continue_class (objc_interface_context);
2786                 }
2787           methodprotolist END
2788                 {
2789                   finish_class (objc_interface_context);
2790                   objc_interface_context = NULL_TREE;
2791                 }
2792
2793         | IMPLEMENTATION identifier '(' identifier ')'
2794                 {
2795                   objc_implementation_context
2796                     = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2797                   objc_ivar_chain
2798                     = continue_class (objc_implementation_context);
2799                 }
2800         ;
2801
2802 protocoldef:
2803           PROTOCOL identifier protocolrefs
2804                 {
2805                   objc_pq_context = 1;
2806                   objc_interface_context
2807                     = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2808                 }
2809           methodprotolist END
2810                 {
2811                   objc_pq_context = 0;
2812                   finish_protocol(objc_interface_context);
2813                   objc_interface_context = NULL_TREE;
2814                 }
2815         /* The @protocol forward-declaration production introduces a
2816            reduce/reduce conflict on ';', which should be resolved in
2817            favor of the production 'identifier_list -> identifier'.  */
2818         | PROTOCOL identifier_list ';'
2819                 {
2820                   objc_declare_protocols ($2);
2821                 }
2822         ;
2823
2824 protocolrefs:
2825           /* empty */
2826                 {
2827                   $$ = NULL_TREE;
2828                 }
2829         | non_empty_protocolrefs
2830         ;
2831
2832 non_empty_protocolrefs:
2833           ARITHCOMPARE identifier_list ARITHCOMPARE
2834                 {
2835                   if ($1 == LT_EXPR && $3 == GT_EXPR)
2836                     $$ = $2;
2837                   else
2838                     YYERROR1;
2839                 }
2840         ;
2841
2842 ivar_decl_list:
2843           ivar_decl_list visibility_spec ivar_decls
2844         | ivar_decls
2845         ;
2846
2847 visibility_spec:
2848           PRIVATE { objc_public_flag = 2; }
2849         | PROTECTED { objc_public_flag = 0; }
2850         | PUBLIC { objc_public_flag = 1; }
2851         ;
2852
2853 ivar_decls:
2854           /* empty */
2855                 {
2856                   $$ = NULL_TREE;
2857                 }
2858         | ivar_decls ivar_decl ';'
2859         | ivar_decls ';'
2860                 {
2861                   if (pedantic)
2862                     pedwarn ("extra semicolon in struct or union specified");
2863                 }
2864         ;
2865
2866
2867 /* There is a shift-reduce conflict here, because `components' may
2868    start with a `typename'.  It happens that shifting (the default resolution)
2869    does the right thing, because it treats the `typename' as part of
2870    a `typed_typespecs'.
2871
2872    It is possible that this same technique would allow the distinction
2873    between `notype_initdecls' and `initdecls' to be eliminated.
2874    But I am being cautious and not trying it.  */
2875
2876 ivar_decl:
2877         declspecs_nosc_ts setspecs ivars
2878                 { $$ = $3;
2879                   POP_DECLSPEC_STACK; }
2880         | declspecs_nosc_nots setspecs ivars
2881                 { $$ = $3;
2882                   POP_DECLSPEC_STACK; }
2883         | error
2884                 { $$ = NULL_TREE; }
2885         ;
2886
2887 ivars:
2888           /* empty */
2889                 { $$ = NULL_TREE; }
2890         | ivar_declarator
2891         | ivars ',' maybe_resetattrs ivar_declarator
2892         ;
2893
2894 ivar_declarator:
2895           declarator
2896                 {
2897                   $$ = add_instance_variable (objc_ivar_context,
2898                                               objc_public_flag,
2899                                               $1, current_declspecs,
2900                                               NULL_TREE);
2901                 }
2902         | declarator ':' expr_no_commas
2903                 {
2904                   $$ = add_instance_variable (objc_ivar_context,
2905                                               objc_public_flag,
2906                                               $1, current_declspecs, $3);
2907                 }
2908         | ':' expr_no_commas
2909                 {
2910                   $$ = add_instance_variable (objc_ivar_context,
2911                                               objc_public_flag,
2912                                               NULL_TREE,
2913                                               current_declspecs, $2);
2914                 }
2915         ;
2916
2917 methodtype:
2918           '+'
2919                 { objc_inherit_code = CLASS_METHOD_DECL; }
2920         | '-'
2921                 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2922         ;
2923
2924 methoddef:
2925           methodtype
2926                 {
2927                   objc_pq_context = 1;
2928                   if (!objc_implementation_context)
2929                     fatal_error ("method definition not in class context");
2930                 }
2931           methoddecl
2932                 {
2933                   objc_pq_context = 0;
2934                   objc_add_method (objc_implementation_context,
2935                                    $3,
2936                                    objc_inherit_code == CLASS_METHOD_DECL);
2937                   start_method_def ($3);
2938                 }
2939           optarglist
2940                 {
2941                   continue_method_def ();
2942                 }
2943           compstmt_or_error
2944                 {
2945                   finish_method_def ();
2946                 }
2947         ;
2948
2949 /* the reason for the strange actions in this rule
2950  is so that notype_initdecls when reached via datadef
2951  can find a valid list of type and sc specs in $0. */
2952
2953 methodprotolist:
2954           /* empty  */
2955         | methodprotolist methodproto
2956         | methodprotolist { $<ttype>$ = NULL_TREE; } datadef
2957         ;
2958
2959 semi_or_error:
2960           ';'
2961         | error
2962         ;
2963
2964 methodproto:
2965           methodtype
2966                 {
2967                   /* Remember protocol qualifiers in prototypes.  */
2968                   objc_pq_context = 1;
2969                 }
2970           methoddecl
2971                 {
2972                   /* Forget protocol qualifiers here.  */
2973                   objc_pq_context = 0;
2974                   objc_add_method (objc_interface_context,
2975                                    $3,
2976                                    objc_inherit_code == CLASS_METHOD_DECL);
2977                 }
2978           semi_or_error
2979         ;
2980
2981 methoddecl:
2982           '(' typename ')' unaryselector
2983                 {
2984                   $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
2985                 }
2986
2987         | unaryselector
2988                 {
2989                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
2990                 }
2991
2992         | '(' typename ')' keywordselector optparmlist
2993                 {
2994                   $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
2995                 }
2996
2997         | keywordselector optparmlist
2998                 {
2999                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
3000                 }
3001         ;
3002
3003 /* "optarglist" assumes that start_method_def has already been called...
3004    if it is not, the "xdecls" will not be placed in the proper scope */
3005
3006 optarglist:
3007           /* empty */
3008         | ';' myxdecls
3009         ;
3010
3011 /* to get around the following situation: "int foo (int a) int b; {}" that
3012    is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
3013
3014 myxdecls:
3015           /* empty */
3016         | mydecls
3017         ;
3018
3019 mydecls:
3020         mydecl
3021         | errstmt
3022         | mydecls mydecl
3023         | mydecl errstmt
3024         ;
3025
3026 mydecl:
3027         declspecs_ts setspecs myparms ';'
3028                 { POP_DECLSPEC_STACK; }
3029         | declspecs_ts ';'
3030                 { shadow_tag ($1); }
3031         | declspecs_nots ';'
3032                 { pedwarn ("empty declaration"); }
3033         ;
3034
3035 myparms:
3036         myparm
3037                 { push_parm_decl ($1); }
3038         | myparms ',' myparm
3039                 { push_parm_decl ($3); }
3040         ;
3041
3042 /* A single parameter declaration or parameter type name,
3043    as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
3044
3045 myparm:
3046           parm_declarator maybe_attribute
3047                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3048                                                          $1),
3049                                         chainon ($2, all_prefix_attributes)); }
3050         | notype_declarator maybe_attribute
3051                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3052                                                          $1),
3053                                         chainon ($2, all_prefix_attributes)); }
3054         | absdcl_maybe_attribute
3055                 { $$ = $1; }
3056         ;
3057
3058 optparmlist:
3059           /* empty */
3060                 {
3061                   $$ = NULL_TREE;
3062                 }
3063         | ',' ELLIPSIS
3064                 {
3065                   /* oh what a kludge! */
3066                   $$ = objc_ellipsis_node;
3067                 }
3068         | ','
3069                 {
3070                   pushlevel (0);
3071                 }
3072           parmlist_2
3073                 {
3074                   /* returns a tree list node generated by get_parm_info */
3075                   $$ = $3;
3076                   poplevel (0, 0, 0);
3077                 }
3078         ;
3079
3080 unaryselector:
3081           selector
3082         ;
3083
3084 keywordselector:
3085           keyworddecl
3086
3087         | keywordselector keyworddecl
3088                 {
3089                   $$ = chainon ($1, $2);
3090                 }
3091         ;
3092
3093 selector:
3094           IDENTIFIER
3095         | TYPENAME
3096         | CLASSNAME
3097         | OBJECTNAME
3098         | reservedwords
3099         ;
3100
3101 reservedwords:
3102           ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3103         | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3104         | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3105         | TYPESPEC | TYPE_QUAL
3106         ;
3107
3108 keyworddecl:
3109           selector ':' '(' typename ')' identifier
3110                 {
3111                   $$ = build_keyword_decl ($1, $4, $6);
3112                 }
3113
3114         | selector ':' identifier
3115                 {
3116                   $$ = build_keyword_decl ($1, NULL_TREE, $3);
3117                 }
3118
3119         | ':' '(' typename ')' identifier
3120                 {
3121                   $$ = build_keyword_decl (NULL_TREE, $3, $5);
3122                 }
3123
3124         | ':' identifier
3125                 {
3126                   $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3127                 }
3128         ;
3129
3130 messageargs:
3131           selector
3132         | keywordarglist
3133         ;
3134
3135 keywordarglist:
3136           keywordarg
3137         | keywordarglist keywordarg
3138                 {
3139                   $$ = chainon ($1, $2);
3140                 }
3141         ;
3142
3143
3144 keywordexpr:
3145           nonnull_exprlist
3146                 {
3147                   if (TREE_CHAIN ($1) == NULL_TREE)
3148                     /* just return the expr., remove a level of indirection */
3149                     $$ = TREE_VALUE ($1);
3150                   else
3151                     /* we have a comma expr., we will collapse later */
3152                     $$ = $1;
3153                 }
3154         ;
3155
3156 keywordarg:
3157           selector ':' keywordexpr
3158                 {
3159                   $$ = build_tree_list ($1, $3);
3160                 }
3161         | ':' keywordexpr
3162                 {
3163                   $$ = build_tree_list (NULL_TREE, $2);
3164                 }
3165         ;
3166
3167 receiver:
3168           expr
3169         | CLASSNAME
3170                 {
3171                   $$ = get_class_reference ($1);
3172                 }
3173         | TYPENAME
3174                 {
3175                   $$ = get_class_reference ($1);
3176                 }
3177         ;
3178
3179 objcmessageexpr:
3180           '[' receiver messageargs ']'
3181                 { $$ = build_tree_list ($2, $3); }
3182         ;
3183
3184 selectorarg:
3185           selector
3186         | keywordnamelist
3187         ;
3188
3189 keywordnamelist:
3190           keywordname
3191         | keywordnamelist keywordname
3192                 {
3193                   $$ = chainon ($1, $2);
3194                 }
3195         ;
3196
3197 keywordname:
3198           selector ':'
3199                 {
3200                   $$ = build_tree_list ($1, NULL_TREE);
3201                 }
3202         | ':'
3203                 {
3204                   $$ = build_tree_list (NULL_TREE, NULL_TREE);
3205                 }
3206         ;
3207
3208 objcselectorexpr:
3209           SELECTOR '(' selectorarg ')'
3210                 {
3211                   $$ = $3;
3212                 }
3213         ;
3214
3215 objcprotocolexpr:
3216           PROTOCOL '(' identifier ')'
3217                 {
3218                   $$ = $3;
3219                 }
3220         ;
3221
3222 /* extension to support C-structures in the archiver */
3223
3224 objcencodeexpr:
3225           ENCODE '(' typename ')'
3226                 {
3227                   $$ = groktypename ($3);
3228                 }
3229         ;
3230
3231 @@end_ifobjc
3232 %%
3233
3234 /* yylex() is a thin wrapper around c_lex(), all it does is translate
3235    cpplib.h's token codes into yacc's token codes.  */
3236
3237 static enum cpp_ttype last_token;
3238
3239 /* The reserved keyword table.  */
3240 struct resword
3241 {
3242   const char *word;
3243   ENUM_BITFIELD(rid) rid : 16;
3244   unsigned int disable   : 16;
3245 };
3246
3247 /* Disable mask.  Keywords are disabled if (reswords[i].disable & mask) is
3248    _true_.  */
3249 #define D_C89   0x01    /* not in C89 */
3250 #define D_EXT   0x02    /* GCC extension */
3251 #define D_EXT89 0x04    /* GCC extension incorporated in C99 */
3252 #define D_OBJC  0x08    /* Objective C only */
3253
3254 static const struct resword reswords[] =
3255 {
3256   { "_Bool",            RID_BOOL,       0 },
3257   { "_Complex",         RID_COMPLEX,    0 },
3258   { "__FUNCTION__",     RID_FUNCTION_NAME, 0 },
3259   { "__PRETTY_FUNCTION__", RID_PRETTY_FUNCTION_NAME, 0 },
3260   { "__alignof",        RID_ALIGNOF,    0 },
3261   { "__alignof__",      RID_ALIGNOF,    0 },
3262   { "__asm",            RID_ASM,        0 },
3263   { "__asm__",          RID_ASM,        0 },
3264   { "__attribute",      RID_ATTRIBUTE,  0 },
3265   { "__attribute__",    RID_ATTRIBUTE,  0 },
3266   { "__builtin_choose_expr", RID_CHOOSE_EXPR, 0 },
3267   { "__builtin_types_compatible_p", RID_TYPES_COMPATIBLE_P, 0 },
3268   { "__builtin_va_arg", RID_VA_ARG,     0 },
3269   { "__complex",        RID_COMPLEX,    0 },
3270   { "__complex__",      RID_COMPLEX,    0 },
3271   { "__const",          RID_CONST,      0 },
3272   { "__const__",        RID_CONST,      0 },
3273   { "__extension__",    RID_EXTENSION,  0 },
3274   { "__func__",         RID_C99_FUNCTION_NAME, 0 },
3275   { "__imag",           RID_IMAGPART,   0 },
3276   { "__imag__",         RID_IMAGPART,   0 },
3277   { "__inline",         RID_INLINE,     0 },
3278   { "__inline__",       RID_INLINE,     0 },
3279   { "__label__",        RID_LABEL,      0 },
3280   { "__ptrbase",        RID_PTRBASE,    0 },
3281   { "__ptrbase__",      RID_PTRBASE,    0 },
3282   { "__ptrextent",      RID_PTREXTENT,  0 },
3283   { "__ptrextent__",    RID_PTREXTENT,  0 },
3284   { "__ptrvalue",       RID_PTRVALUE,   0 },
3285   { "__ptrvalue__",     RID_PTRVALUE,   0 },
3286   { "__real",           RID_REALPART,   0 },
3287   { "__real__",         RID_REALPART,   0 },
3288   { "__restrict",       RID_RESTRICT,   0 },
3289   { "__restrict__",     RID_RESTRICT,   0 },
3290   { "__signed",         RID_SIGNED,     0 },
3291   { "__signed__",       RID_SIGNED,     0 },
3292   { "__thread",         RID_THREAD,     0 },
3293   { "__typeof",         RID_TYPEOF,     0 },
3294   { "__typeof__",       RID_TYPEOF,     0 },
3295   { "__volatile",       RID_VOLATILE,   0 },
3296   { "__volatile__",     RID_VOLATILE,   0 },
3297   { "asm",              RID_ASM,        D_EXT },
3298   { "auto",             RID_AUTO,       0 },
3299   { "break",            RID_BREAK,      0 },
3300   { "case",             RID_CASE,       0 },
3301   { "char",             RID_CHAR,       0 },
3302   { "const",            RID_CONST,      0 },
3303   { "continue",         RID_CONTINUE,   0 },
3304   { "default",          RID_DEFAULT,    0 },
3305   { "do",               RID_DO,         0 },
3306   { "double",           RID_DOUBLE,     0 },
3307   { "else",             RID_ELSE,       0 },
3308   { "enum",             RID_ENUM,       0 },
3309   { "extern",           RID_EXTERN,     0 },
3310   { "float",            RID_FLOAT,      0 },
3311   { "for",              RID_FOR,        0 },
3312   { "goto",             RID_GOTO,       0 },
3313   { "if",               RID_IF,         0 },
3314   { "inline",           RID_INLINE,     D_EXT89 },
3315   { "int",              RID_INT,        0 },
3316   { "long",             RID_LONG,       0 },
3317   { "register",         RID_REGISTER,   0 },
3318   { "restrict",         RID_RESTRICT,   D_C89 },
3319   { "return",           RID_RETURN,     0 },
3320   { "short",            RID_SHORT,      0 },
3321   { "signed",           RID_SIGNED,     0 },
3322   { "sizeof",           RID_SIZEOF,     0 },
3323   { "static",           RID_STATIC,     0 },
3324   { "struct",           RID_STRUCT,     0 },
3325   { "switch",           RID_SWITCH,     0 },
3326   { "typedef",          RID_TYPEDEF,    0 },
3327   { "typeof",           RID_TYPEOF,     D_EXT },
3328   { "union",            RID_UNION,      0 },
3329   { "unsigned",         RID_UNSIGNED,   0 },
3330   { "void",             RID_VOID,       0 },
3331   { "volatile",         RID_VOLATILE,   0 },
3332   { "while",            RID_WHILE,      0 },
3333 @@ifobjc
3334   { "id",               RID_ID,                 D_OBJC },
3335
3336   /* These objc keywords are recognized only immediately after
3337      an '@'.  */
3338   { "class",            RID_AT_CLASS,           D_OBJC },
3339   { "compatibility_alias", RID_AT_ALIAS,        D_OBJC },
3340   { "defs",             RID_AT_DEFS,            D_OBJC },
3341   { "encode",           RID_AT_ENCODE,          D_OBJC },
3342   { "end",              RID_AT_END,             D_OBJC },
3343   { "implementation",   RID_AT_IMPLEMENTATION,  D_OBJC },
3344   { "interface",        RID_AT_INTERFACE,       D_OBJC },
3345   { "private",          RID_AT_PRIVATE,         D_OBJC },
3346   { "protected",        RID_AT_PROTECTED,       D_OBJC },
3347   { "protocol",         RID_AT_PROTOCOL,        D_OBJC },
3348   { "public",           RID_AT_PUBLIC,          D_OBJC },
3349   { "selector",         RID_AT_SELECTOR,        D_OBJC },
3350   { "throw",            RID_AT_THROW,           D_OBJC },
3351   { "try",              RID_AT_TRY,             D_OBJC },
3352   { "catch",            RID_AT_CATCH,           D_OBJC },
3353   { "finally",          RID_AT_FINALLY,         D_OBJC },
3354   { "synchronized",     RID_AT_SYNCHRONIZED,    D_OBJC },
3355   /* These are recognized only in protocol-qualifier context
3356      (see above) */
3357   { "bycopy",           RID_BYCOPY,             D_OBJC },
3358   { "byref",            RID_BYREF,              D_OBJC },
3359   { "in",               RID_IN,                 D_OBJC },
3360   { "inout",            RID_INOUT,              D_OBJC },
3361   { "oneway",           RID_ONEWAY,             D_OBJC },
3362   { "out",              RID_OUT,                D_OBJC },
3363 @@end_ifobjc
3364 };
3365 #define N_reswords (sizeof reswords / sizeof (struct resword))
3366
3367 /* Table mapping from RID_* constants to yacc token numbers.
3368    Unfortunately we have to have entries for all the keywords in all
3369    three languages.  */
3370 static const short rid_to_yy[RID_MAX] =
3371 {
3372   /* RID_STATIC */      STATIC,
3373   /* RID_UNSIGNED */    TYPESPEC,
3374   /* RID_LONG */        TYPESPEC,
3375   /* RID_CONST */       TYPE_QUAL,
3376   /* RID_EXTERN */      SCSPEC,
3377   /* RID_REGISTER */    SCSPEC,
3378   /* RID_TYPEDEF */     SCSPEC,
3379   /* RID_SHORT */       TYPESPEC,
3380   /* RID_INLINE */      SCSPEC,
3381   /* RID_VOLATILE */    TYPE_QUAL,
3382   /* RID_SIGNED */      TYPESPEC,
3383   /* RID_AUTO */        SCSPEC,
3384   /* RID_RESTRICT */    TYPE_QUAL,
3385
3386   /* C extensions */
3387   /* RID_COMPLEX */     TYPESPEC,
3388   /* RID_THREAD */      SCSPEC,
3389
3390   /* C++ */
3391   /* RID_FRIEND */      0,
3392   /* RID_VIRTUAL */     0,
3393   /* RID_EXPLICIT */    0,
3394   /* RID_EXPORT */      0,
3395   /* RID_MUTABLE */     0,
3396
3397   /* ObjC */
3398   /* RID_IN */          TYPE_QUAL,
3399   /* RID_OUT */         TYPE_QUAL,
3400   /* RID_INOUT */       TYPE_QUAL,
3401   /* RID_BYCOPY */      TYPE_QUAL,
3402   /* RID_BYREF */       TYPE_QUAL,
3403   /* RID_ONEWAY */      TYPE_QUAL,
3404
3405   /* C */
3406   /* RID_INT */         TYPESPEC,
3407   /* RID_CHAR */        TYPESPEC,
3408   /* RID_FLOAT */       TYPESPEC,
3409   /* RID_DOUBLE */      TYPESPEC,
3410   /* RID_VOID */        TYPESPEC,
3411   /* RID_ENUM */        ENUM,
3412   /* RID_STRUCT */      STRUCT,
3413   /* RID_UNION */       UNION,
3414   /* RID_IF */          IF,
3415   /* RID_ELSE */        ELSE,
3416   /* RID_WHILE */       WHILE,
3417   /* RID_DO */          DO,
3418   /* RID_FOR */         FOR,
3419   /* RID_SWITCH */      SWITCH,
3420   /* RID_CASE */        CASE,
3421   /* RID_DEFAULT */     DEFAULT,
3422   /* RID_BREAK */       BREAK,
3423   /* RID_CONTINUE */    CONTINUE,
3424   /* RID_RETURN */      RETURN,
3425   /* RID_GOTO */        GOTO,
3426   /* RID_SIZEOF */      SIZEOF,
3427
3428   /* C extensions */
3429   /* RID_ASM */         ASM_KEYWORD,
3430   /* RID_TYPEOF */      TYPEOF,
3431   /* RID_ALIGNOF */     ALIGNOF,
3432   /* RID_ATTRIBUTE */   ATTRIBUTE,
3433   /* RID_VA_ARG */      VA_ARG,
3434   /* RID_EXTENSION */   EXTENSION,
3435   /* RID_IMAGPART */    IMAGPART,
3436   /* RID_REALPART */    REALPART,
3437   /* RID_LABEL */       LABEL,
3438   /* RID_PTRBASE */     PTR_BASE,
3439   /* RID_PTREXTENT */   PTR_EXTENT,
3440   /* RID_PTRVALUE */    PTR_VALUE,
3441
3442   /* RID_CHOOSE_EXPR */                 CHOOSE_EXPR,
3443   /* RID_TYPES_COMPATIBLE_P */          TYPES_COMPATIBLE_P,
3444
3445   /* RID_FUNCTION_NAME */               FUNC_NAME,
3446   /* RID_PRETTY_FUNCTION_NAME */        FUNC_NAME,
3447   /* RID_C99_FUNCTION_NAME */           FUNC_NAME,
3448
3449   /* C++ */
3450   /* RID_BOOL */        TYPESPEC,
3451   /* RID_WCHAR */       0,
3452   /* RID_CLASS */       0,
3453   /* RID_PUBLIC */      0,
3454   /* RID_PRIVATE */     0,
3455   /* RID_PROTECTED */   0,
3456   /* RID_TEMPLATE */    0,
3457   /* RID_NULL */        0,
3458   /* RID_CATCH */       0,
3459   /* RID_DELETE */      0,
3460   /* RID_FALSE */       0,
3461   /* RID_NAMESPACE */   0,
3462   /* RID_NEW */         0,
3463   /* RID_OPERATOR */    0,
3464   /* RID_THIS */        0,
3465   /* RID_THROW */       0,
3466   /* RID_TRUE */        0,
3467   /* RID_TRY */         0,
3468   /* RID_TYPENAME */    0,
3469   /* RID_TYPEID */      0,
3470   /* RID_USING */       0,
3471
3472   /* casts */
3473   /* RID_CONSTCAST */   0,
3474   /* RID_DYNCAST */     0,
3475   /* RID_REINTCAST */   0,
3476   /* RID_STATCAST */    0,
3477
3478   /* Objective C */
3479   /* RID_ID */                  OBJECTNAME,
3480   /* RID_AT_ENCODE */           ENCODE,
3481   /* RID_AT_END */              END,
3482   /* RID_AT_CLASS */            CLASS,
3483   /* RID_AT_ALIAS */            ALIAS,
3484   /* RID_AT_DEFS */             DEFS,
3485   /* RID_AT_PRIVATE */          PRIVATE,
3486   /* RID_AT_PROTECTED */        PROTECTED,
3487   /* RID_AT_PUBLIC */           PUBLIC,
3488   /* RID_AT_PROTOCOL */         PROTOCOL,
3489   /* RID_AT_SELECTOR */         SELECTOR,
3490   /* RID_AT_THROW */            AT_THROW,
3491   /* RID_AT_TRY */              AT_TRY,
3492   /* RID_AT_CATCH */            AT_CATCH,
3493   /* RID_AT_FINALLY */          AT_FINALLY,
3494   /* RID_AT_SYNCHRONIZED */     AT_SYNCHRONIZED,
3495   /* RID_AT_INTERFACE */        INTERFACE,
3496   /* RID_AT_IMPLEMENTATION */   IMPLEMENTATION
3497 };
3498
3499 static void
3500 init_reswords (void)
3501 {
3502   unsigned int i;
3503   tree id;
3504   int mask = (flag_isoc99 ? 0 : D_C89)
3505               | (flag_no_asm ? (flag_isoc99 ? D_EXT : D_EXT|D_EXT89) : 0);
3506
3507   if (!c_dialect_objc ())
3508      mask |= D_OBJC;
3509
3510   ridpointers = ggc_calloc ((int) RID_MAX, sizeof (tree));
3511   for (i = 0; i < N_reswords; i++)
3512     {
3513       /* If a keyword is disabled, do not enter it into the table
3514          and so create a canonical spelling that isn't a keyword.  */
3515       if (reswords[i].disable & mask)
3516         continue;
3517
3518       id = get_identifier (reswords[i].word);
3519       C_RID_CODE (id) = reswords[i].rid;
3520       C_IS_RESERVED_WORD (id) = 1;
3521       ridpointers [(int) reswords[i].rid] = id;
3522     }
3523 }
3524
3525 #define NAME(type) cpp_type2name (type)
3526
3527 static void
3528 yyerror (const char *msgid)
3529 {
3530   const char *string = _(msgid);
3531
3532   if (last_token == CPP_EOF)
3533     error ("%s at end of input", string);
3534   else if (last_token == CPP_CHAR || last_token == CPP_WCHAR)
3535     {
3536       unsigned int val = TREE_INT_CST_LOW (yylval.ttype);
3537       const char *const ell = (last_token == CPP_CHAR) ? "" : "L";
3538       if (val <= UCHAR_MAX && ISGRAPH (val))
3539         error ("%s before %s'%c'", string, ell, val);
3540       else
3541         error ("%s before %s'\\x%x'", string, ell, val);
3542     }
3543   else if (last_token == CPP_STRING
3544            || last_token == CPP_WSTRING)
3545     error ("%s before string constant", string);
3546   else if (last_token == CPP_NUMBER)
3547     error ("%s before numeric constant", string);
3548   else if (last_token == CPP_NAME)
3549     error ("%s before \"%s\"", string, IDENTIFIER_POINTER (yylval.ttype));
3550   else
3551     error ("%s before '%s' token", string, NAME(last_token));
3552 }
3553
3554 static int
3555 yylexname (void)
3556 {
3557   tree decl;
3558
3559 @@ifobjc
3560   int objc_force_identifier = objc_need_raw_identifier;
3561   OBJC_NEED_RAW_IDENTIFIER (0);
3562 @@end_ifobjc
3563
3564   if (C_IS_RESERVED_WORD (yylval.ttype))
3565     {
3566       enum rid rid_code = C_RID_CODE (yylval.ttype);
3567
3568 @@ifobjc
3569       /* Turn non-typedefed refs to "id" into plain identifiers; this
3570          allows constructs like "void foo(id id);" to work.  */
3571       if (rid_code == RID_ID)
3572       {
3573         decl = lookup_name (yylval.ttype);
3574         if (decl == NULL_TREE || TREE_CODE (decl) != TYPE_DECL)
3575           return IDENTIFIER;
3576       }
3577
3578       if (!OBJC_IS_AT_KEYWORD (rid_code)
3579           && (!OBJC_IS_PQ_KEYWORD (rid_code) || objc_pq_context))
3580 @@end_ifobjc
3581       {
3582         /* Return the canonical spelling for this keyword.  */
3583         yylval.ttype = ridpointers[(int) rid_code];
3584         return rid_to_yy[(int) rid_code];
3585       }
3586     }
3587
3588   decl = lookup_name (yylval.ttype);
3589   if (decl)
3590     {
3591       if (TREE_CODE (decl) == TYPE_DECL)
3592         return TYPENAME;
3593     }
3594 @@ifobjc
3595   else
3596     {
3597       tree objc_interface_decl = is_class_name (yylval.ttype);
3598       /* ObjC class names are in the same namespace as variables and
3599          typedefs, and hence are shadowed by local declarations.  */
3600       if (objc_interface_decl
3601           && (global_bindings_p ()
3602               || (!objc_force_identifier && !decl)))
3603         {
3604           yylval.ttype = objc_interface_decl;
3605           return CLASSNAME;
3606         }
3607     }
3608 @@end_ifobjc
3609
3610   return IDENTIFIER;
3611 }
3612
3613 static inline int
3614 _yylex (void)
3615 {
3616  get_next:
3617   last_token = c_lex (&yylval.ttype);
3618   switch (last_token)
3619     {
3620     case CPP_EQ:                                        return '=';
3621     case CPP_NOT:                                       return '!';
3622     case CPP_GREATER:   yylval.code = GT_EXPR;          return ARITHCOMPARE;
3623     case CPP_LESS:      yylval.code = LT_EXPR;          return ARITHCOMPARE;
3624     case CPP_PLUS:      yylval.code = PLUS_EXPR;        return '+';
3625     case CPP_MINUS:     yylval.code = MINUS_EXPR;       return '-';
3626     case CPP_MULT:      yylval.code = MULT_EXPR;        return '*';
3627     case CPP_DIV:       yylval.code = TRUNC_DIV_EXPR;   return '/';
3628     case CPP_MOD:       yylval.code = TRUNC_MOD_EXPR;   return '%';
3629     case CPP_AND:       yylval.code = BIT_AND_EXPR;     return '&';
3630     case CPP_OR:        yylval.code = BIT_IOR_EXPR;     return '|';
3631     case CPP_XOR:       yylval.code = BIT_XOR_EXPR;     return '^';
3632     case CPP_RSHIFT:    yylval.code = RSHIFT_EXPR;      return RSHIFT;
3633     case CPP_LSHIFT:    yylval.code = LSHIFT_EXPR;      return LSHIFT;
3634
3635     case CPP_COMPL:                                     return '~';
3636     case CPP_AND_AND:                                   return ANDAND;
3637     case CPP_OR_OR:                                     return OROR;
3638     case CPP_QUERY:                                     return '?';
3639     case CPP_OPEN_PAREN:                                return '(';
3640     case CPP_EQ_EQ:     yylval.code = EQ_EXPR;          return EQCOMPARE;
3641     case CPP_NOT_EQ:    yylval.code = NE_EXPR;          return EQCOMPARE;
3642     case CPP_GREATER_EQ:yylval.code = GE_EXPR;          return ARITHCOMPARE;
3643     case CPP_LESS_EQ:   yylval.code = LE_EXPR;          return ARITHCOMPARE;
3644
3645     case CPP_PLUS_EQ:   yylval.code = PLUS_EXPR;        return ASSIGN;
3646     case CPP_MINUS_EQ:  yylval.code = MINUS_EXPR;       return ASSIGN;
3647     case CPP_MULT_EQ:   yylval.code = MULT_EXPR;        return ASSIGN;
3648     case CPP_DIV_EQ:    yylval.code = TRUNC_DIV_EXPR;   return ASSIGN;
3649     case CPP_MOD_EQ:    yylval.code = TRUNC_MOD_EXPR;   return ASSIGN;
3650     case CPP_AND_EQ:    yylval.code = BIT_AND_EXPR;     return ASSIGN;
3651     case CPP_OR_EQ:     yylval.code = BIT_IOR_EXPR;     return ASSIGN;
3652     case CPP_XOR_EQ:    yylval.code = BIT_XOR_EXPR;     return ASSIGN;
3653     case CPP_RSHIFT_EQ: yylval.code = RSHIFT_EXPR;      return ASSIGN;
3654     case CPP_LSHIFT_EQ: yylval.code = LSHIFT_EXPR;      return ASSIGN;
3655
3656     case CPP_OPEN_SQUARE:                               return '[';
3657     case CPP_CLOSE_SQUARE:                              return ']';
3658     case CPP_OPEN_BRACE:                                return '{';
3659     case CPP_CLOSE_BRACE:                               return '}';
3660     case CPP_ELLIPSIS:                                  return ELLIPSIS;
3661
3662     case CPP_PLUS_PLUS:                                 return PLUSPLUS;
3663     case CPP_MINUS_MINUS:                               return MINUSMINUS;
3664     case CPP_DEREF:                                     return POINTSAT;
3665     case CPP_DOT:                                       return '.';
3666
3667       /* The following tokens may affect the interpretation of any
3668          identifiers following, if doing Objective-C.  */
3669     case CPP_COLON:             OBJC_NEED_RAW_IDENTIFIER (0);   return ':';
3670     case CPP_COMMA:             OBJC_NEED_RAW_IDENTIFIER (0);   return ',';
3671     case CPP_CLOSE_PAREN:       OBJC_NEED_RAW_IDENTIFIER (0);   return ')';
3672     case CPP_SEMICOLON:         OBJC_NEED_RAW_IDENTIFIER (0);   return ';';
3673
3674     case CPP_EOF:
3675       return 0;
3676
3677     case CPP_NAME:
3678       return yylexname ();
3679
3680     case CPP_AT_NAME:
3681       /* This only happens in Objective-C; it must be a keyword.  */
3682       return rid_to_yy [(int) C_RID_CODE (yylval.ttype)];
3683
3684     case CPP_NUMBER:
3685     case CPP_CHAR:
3686     case CPP_WCHAR:
3687       return CONSTANT;
3688
3689     case CPP_STRING:
3690     case CPP_WSTRING:
3691       return STRING;
3692
3693     case CPP_OBJC_STRING:
3694       return OBJC_STRING;
3695
3696       /* These tokens are C++ specific (and will not be generated
3697          in C mode, but let's be cautious).  */
3698     case CPP_SCOPE:
3699     case CPP_DEREF_STAR:
3700     case CPP_DOT_STAR:
3701     case CPP_MIN_EQ:
3702     case CPP_MAX_EQ:
3703     case CPP_MIN:
3704     case CPP_MAX:
3705       /* These tokens should not survive translation phase 4.  */
3706     case CPP_HASH:
3707     case CPP_PASTE:
3708       error ("syntax error at '%s' token", NAME(last_token));
3709       goto get_next;
3710
3711     default:
3712       abort ();
3713     }
3714   /* NOTREACHED */
3715 }
3716
3717 static int
3718 yylex (void)
3719 {
3720   int r;
3721   timevar_push (TV_LEX);
3722   r = _yylex();
3723   timevar_pop (TV_LEX);
3724   return r;
3725 }
3726
3727 /* Function used when yydebug is set, to print a token in more detail.  */
3728
3729 static void
3730 yyprint (FILE *file, int yychar, YYSTYPE yyl)
3731 {
3732   tree t = yyl.ttype;
3733
3734   fprintf (file, " [%s]", NAME(last_token));
3735
3736   switch (yychar)
3737     {
3738     case IDENTIFIER:
3739     case TYPENAME:
3740     case OBJECTNAME:
3741     case TYPESPEC:
3742     case TYPE_QUAL:
3743     case SCSPEC:
3744     case STATIC:
3745       if (IDENTIFIER_POINTER (t))
3746         fprintf (file, " `%s'", IDENTIFIER_POINTER (t));
3747       break;
3748
3749     case CONSTANT:
3750       fprintf (file, " %s", GET_MODE_NAME (TYPE_MODE (TREE_TYPE (t))));
3751       if (TREE_CODE (t) == INTEGER_CST)
3752         {
3753           fputs (" ", file);
3754           fprintf (file, HOST_WIDE_INT_PRINT_DOUBLE_HEX,
3755                    TREE_INT_CST_HIGH (t), TREE_INT_CST_LOW (t));
3756         }
3757       break;
3758     }
3759 }
3760 \f
3761 /* This is not the ideal place to put these, but we have to get them out
3762    of c-lex.c because cp/lex.c has its own versions.  */
3763
3764 /* Free malloced parser stacks if necessary.  */
3765
3766 void
3767 free_parser_stacks (void)
3768 {
3769 }
3770
3771 /* Parse the file.  */
3772 void
3773 c_parse_file (void)
3774 {
3775   yyparse ();
3776   /* In case there were missing closebraces, get us back to the global
3777      binding level.  */
3778   while (! global_bindings_p ())
3779     poplevel (0, 0, 0);
3780   /* __FUNCTION__ is defined at file scope ("").  This
3781      call may not be necessary as my tests indicate it
3782      still works without it.  */
3783   finish_fname_decls ();
3784
3785   if (malloced_yyss)
3786     {
3787       free (malloced_yyss);
3788       free (malloced_yyvs);
3789       malloced_yyss = 0;
3790     }
3791 }
3792
3793 #include "gt-c-parse.h"