gcc/ada/uname.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                U N A M E                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Types; use Types;
  35 package Uname is
  36
  37    ---------------------------
  38    -- Unit Name Conventions --
  39    ---------------------------
  40
  41    --  Units are associated with a unique ASCII name as follows. First we
  42    --  have the fully expanded name of the unit, with lower case letters
  43    --  (except for the use of upper case letters for encoding upper half
  44    --  and wide characters, as described in Namet), and periods. Following
  45    --  this is one of the following suffixes:
  46
  47    --    %s  for package/subprogram/generic declarations (specs)
  48    --    %b  for package/subprogram/generic bodies and subunits
  49
  50    --  Unit names are stored in the names table, and referred to by the
  51    --  corresponding Name_Id values. The subtype Unit_Name, which is a
  52    --  synonym for Name_Id, is used to indicate that a Name_Id value that
  53    --  holds a unit name (as defined above) is expected.
  54
  55    --  Note: as far as possible the conventions for unit names are encapsulated
  56    --  in this package. The one exception is that package Fname, which provides
  57    --  conversion routines from unit names to file names must be aware of the
  58    --  precise conventions that are used.
  59
  60    -------------------
  61    -- Display Names --
  62    -------------------
  63
  64    --  For display purposes, unit names are printed out with the suffix
  65    --  " (body)" for a body and " (spec)" for a spec. These formats are
  66    --  used for the Write_Unit_Name and Get_Unit_Name_String subprograms.
  67
  68    -----------------
  69    -- Subprograms --
  70    -----------------
  71
  72    function Get_Body_Name (N : Unit_Name_Type) return Unit_Name_Type;
  73    --  Given the name of a spec, this function returns the name of the
  74    --  corresponding body, i.e. characters %s replaced by %b
  75
  76    function Get_Parent_Body_Name (N : Unit_Name_Type) return Unit_Name_Type;
  77    --  Given the name of a subunit, returns the name of the parent body
  78
  79    function Get_Parent_Spec_Name (N : Unit_Name_Type) return Unit_Name_Type;
  80    --  Given the name of a child unit spec or body, returns the unit name
  81    --  of the parent spec. Returns No_Name if the given name is not the name
  82    --  of a child unit.
  83
  84    procedure Get_External_Unit_Name_String (N : Unit_Name_Type);
  85    --  Given the name of a body or spec unit, this procedure places in
  86    --  Name_Buffer the name of the unit with periods replaced by double
  87    --  underscores. The spec/body indication is eliminated. The length
  88    --  of the stored name is placed in Name_Len. All letters are lower
  89    --  case, corresponding to the string used in external names.
  90
  91    function Get_Spec_Name (N : Unit_Name_Type) return Unit_Name_Type;
  92    --  Given the name of a body, this function returns the name of the
  93    --  corresponding spec, i.e. characters %b replaced by %s
  94
  95    function Get_Unit_Name (N : Node_Id) return Unit_Name_Type;
  96    --  This procedure returns the unit name that corresponds to the given node,
  97    --  which is one of the following:
  98    --
  99    --    N_Subprogram_Declaration         (spec) cases
 100    --    N_Package_Declaration
 101    --    N_Generic_Declaration
 102    --    N_With_Clause
 103    --    N_Function_Instantiation
 104    --    N_Package_Instantiation
 105    --    N_Procedure_Instantiation
 106    --    N_Pragma (Elaborate case)
 107    --
 108    --    N_Package_Body                   (body) cases
 109    --    N_Subprogram_Body
 110    --    N_Identifier
 111    --    N_Selected_Component
 112    --
 113    --    N_Subprogram_Body_Stub           (subunit) cases
 114    --    N_Package_Body_Stub
 115    --    N_Task_Body_Stub
 116    --    N_Protected_Body_Stub
 117    --    N_Subunit
 118
 119    procedure Get_Unit_Name_String (N : Unit_Name_Type);
 120    --  Places the display name of the unit in Name_Buffer and sets Name_Len
 121    --  to the length of the stored name, i.e. it uses the same interface as
 122    --  the Get_Name_String routine in the Namet package. The name contains
 123    --  an indication of spec or body, and is decoded.
 124
 125    function Is_Body_Name (N : Unit_Name_Type) return Boolean;
 126    --  Returns True iff the given name is the unit name of a body (i.e. if
 127    --  it ends with the characters %b).
 128
 129    function Is_Child_Name (N : Unit_Name_Type) return Boolean;
 130    --  Returns True iff the given name is a child unit name (of either a
 131    --  body or a spec).
 132
 133    function Is_Spec_Name (N : Unit_Name_Type) return Boolean;
 134    --  Returns True iff the given name is the unit name of a specification
 135    --  (i.e. if it ends with the characters %s).
 136
 137    function Name_To_Unit_Name (N : Name_Id) return Unit_Name_Type;
 138    --  Given the Id of the Ada name of a unit, this function returns the
 139    --  corresponding unit name of the spec (by appending %s to the name).
 140
 141    function New_Child
 142      (Old  : Unit_Name_Type;
 143       Newp : Unit_Name_Type) return Unit_Name_Type;
 144    --   Old is a child unit name (for either a body or spec). Newp is the
 145    --   unit name of the actual parent (this may be different from the
 146    --   parent in old). The returned unit name is formed by taking the
 147    --   parent name from Newp and the child unit name from Old, with the
 148    --   result being a body or spec depending on Old. For example:
 149    --
 150    --     Old    = A.B.C (body)
 151    --     Newp   = A.R (spec)
 152    --     result = A.R.C (body)
 153    --
 154    --   See spec of Load_Unit for extensive discussion of why this routine
 155    --   needs to be used (the call in the body of Load_Unit is the only one).
 156
 157    function Uname_Ge (Left, Right : Unit_Name_Type) return Boolean;
 158    function Uname_Gt (Left, Right : Unit_Name_Type) return Boolean;
 159    function Uname_Le (Left, Right : Unit_Name_Type) return Boolean;
 160    function Uname_Lt (Left, Right : Unit_Name_Type) return Boolean;
 161    --  These functions perform lexicographic ordering of unit names. The
 162    --  ordering is suitable for printing, and is not quite a straightforward
 163    --  comparison of the names, since the convention is that specs appear
 164    --  before bodies. Note that the standard = and /= operators work fine
 165    --  because all unit names are hashed into the name table, so if two names
 166    --  are the same, they always have the same Name_Id value.
 167
 168    procedure Write_Unit_Name (N : Unit_Name_Type);
 169    --  Given a unit name, this procedure writes the display name to the
 170    --  standard output file. Name_Buffer and Name_Len are set as described
 171    --  above for the Get_Unit_Name_String call on return.
 172
 173 end Uname;