gcc/ada/sem_res.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ R E S                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Debug;    use Debug;
  29 with Debug_A;  use Debug_A;
  30 with Einfo;    use Einfo;
  31 with Elists;   use Elists;
  32 with Errout;   use Errout;
  33 with Expander; use Expander;
  34 with Exp_Disp; use Exp_Disp;
  35 with Exp_Ch6;  use Exp_Ch6;
  36 with Exp_Ch7;  use Exp_Ch7;
  37 with Exp_Tss;  use Exp_Tss;
  38 with Exp_Util; use Exp_Util;
  39 with Fname;    use Fname;
  40 with Freeze;   use Freeze;
  41 with Itypes;   use Itypes;
  42 with Lib;      use Lib;
  43 with Lib.Xref; use Lib.Xref;
  44 with Namet;    use Namet;
  45 with Nmake;    use Nmake;
  46 with Nlists;   use Nlists;
  47 with Opt;      use Opt;
  48 with Output;   use Output;
  49 with Restrict; use Restrict;
  50 with Rident;   use Rident;
  51 with Rtsfind;  use Rtsfind;
  52 with Sem;      use Sem;
  53 with Sem_Aux;  use Sem_Aux;
  54 with Sem_Aggr; use Sem_Aggr;
  55 with Sem_Attr; use Sem_Attr;
  56 with Sem_Cat;  use Sem_Cat;
  57 with Sem_Ch4;  use Sem_Ch4;
  58 with Sem_Ch6;  use Sem_Ch6;
  59 with Sem_Ch8;  use Sem_Ch8;
  60 with Sem_Ch13; use Sem_Ch13;
  61 with Sem_Disp; use Sem_Disp;
  62 with Sem_Dist; use Sem_Dist;
  63 with Sem_Elim; use Sem_Elim;
  64 with Sem_Elab; use Sem_Elab;
  65 with Sem_Eval; use Sem_Eval;
  66 with Sem_Intr; use Sem_Intr;
  67 with Sem_Util; use Sem_Util;
  68 with Sem_Type; use Sem_Type;
  69 with Sem_Warn; use Sem_Warn;
  70 with Sinfo;    use Sinfo;
  71 with Snames;   use Snames;
  72 with Stand;    use Stand;
  73 with Stringt;  use Stringt;
  74 with Style;    use Style;
  75 with Tbuild;   use Tbuild;
  76 with Uintp;    use Uintp;
  77 with Urealp;   use Urealp;
  78
  79 package body Sem_Res is
  80
  81    -----------------------
  82    -- Local Subprograms --
  83    -----------------------
  84
  85    --  Second pass (top-down) type checking and overload resolution procedures
  86    --  Typ is the type required by context. These procedures propagate the
  87    --  type information recursively to the descendants of N. If the node
  88    --  is not overloaded, its Etype is established in the first pass. If
  89    --  overloaded,  the Resolve routines set the correct type. For arith.
  90    --  operators, the Etype is the base type of the context.
  91
  92    --  Note that Resolve_Attribute is separated off in Sem_Attr
  93
  94    procedure Check_Discriminant_Use (N : Node_Id);
  95    --  Enforce the restrictions on the use of discriminants when constraining
  96    --  a component of a discriminated type (record or concurrent type).
  97
  98    procedure Check_For_Visible_Operator (N : Node_Id; T : Entity_Id);
  99    --  Given a node for an operator associated with type T, check that
 100    --  the operator is visible. Operators all of whose operands are
 101    --  universal must be checked for visibility during resolution
 102    --  because their type is not determinable based on their operands.
 103
 104    procedure Check_Fully_Declared_Prefix
 105      (Typ  : Entity_Id;
 106       Pref : Node_Id);
 107    --  Check that the type of the prefix of a dereference is not incomplete
 108
 109    function Check_Infinite_Recursion (N : Node_Id) return Boolean;
 110    --  Given a call node, N, which is known to occur immediately within the
 111    --  subprogram being called, determines whether it is a detectable case of
 112    --  an infinite recursion, and if so, outputs appropriate messages. Returns
 113    --  True if an infinite recursion is detected, and False otherwise.
 114
 115    procedure Check_Initialization_Call (N : Entity_Id; Nam : Entity_Id);
 116    --  If the type of the object being initialized uses the secondary stack
 117    --  directly or indirectly, create a transient scope for the call to the
 118    --  init proc. This is because we do not create transient scopes for the
 119    --  initialization of individual components within the init proc itself.
 120    --  Could be optimized away perhaps?
 121
 122    procedure Check_No_Direct_Boolean_Operators (N : Node_Id);
 123    --  N is the node for a logical operator. If the operator is predefined, and
 124    --  the root type of the operands is Standard.Boolean, then a check is made
 125    --  for restriction No_Direct_Boolean_Operators. This procedure also handles
 126    --  the style check for Style_Check_Boolean_And_Or.
 127
 128    function Is_Definite_Access_Type (E : Entity_Id) return Boolean;
 129    --  Determine whether E is an access type declared by an access
 130    --  declaration, and not an (anonymous) allocator type.
 131
 132    function Is_Predefined_Op (Nam : Entity_Id) return Boolean;
 133    --  Utility to check whether the name in the call is a predefined
 134    --  operator, in which case the call is made into an operator node.
 135    --  An instance of an intrinsic conversion operation may be given
 136    --  an operator name, but is not treated like an operator.
 137
 138    procedure Replace_Actual_Discriminants (N : Node_Id; Default : Node_Id);
 139    --  If a default expression in entry call N depends on the discriminants
 140    --  of the task, it must be replaced with a reference to the discriminant
 141    --  of the task being called.
 142
 143    procedure Resolve_Op_Concat_Arg
 144      (N       : Node_Id;
 145       Arg     : Node_Id;
 146       Typ     : Entity_Id;
 147       Is_Comp : Boolean);
 148    --  Internal procedure for Resolve_Op_Concat to resolve one operand of
 149    --  concatenation operator.  The operand is either of the array type or of
 150    --  the component type. If the operand is an aggregate, and the component
 151    --  type is composite, this is ambiguous if component type has aggregates.
 152
 153    procedure Resolve_Op_Concat_First (N : Node_Id; Typ : Entity_Id);
 154    --  Does the first part of the work of Resolve_Op_Concat
 155
 156    procedure Resolve_Op_Concat_Rest (N : Node_Id; Typ : Entity_Id);
 157    --  Does the "rest" of the work of Resolve_Op_Concat, after the left operand
 158    --  has been resolved. See Resolve_Op_Concat for details.
 159
 160    procedure Resolve_Allocator                 (N : Node_Id; Typ : Entity_Id);
 161    procedure Resolve_Arithmetic_Op             (N : Node_Id; Typ : Entity_Id);
 162    procedure Resolve_Call                      (N : Node_Id; Typ : Entity_Id);
 163    procedure Resolve_Character_Literal         (N : Node_Id; Typ : Entity_Id);
 164    procedure Resolve_Comparison_Op             (N : Node_Id; Typ : Entity_Id);
 165    procedure Resolve_Conditional_Expression    (N : Node_Id; Typ : Entity_Id);
 166    procedure Resolve_Equality_Op               (N : Node_Id; Typ : Entity_Id);
 167    procedure Resolve_Explicit_Dereference      (N : Node_Id; Typ : Entity_Id);
 168    procedure Resolve_Entity_Name               (N : Node_Id; Typ : Entity_Id);
 169    procedure Resolve_Indexed_Component         (N : Node_Id; Typ : Entity_Id);
 170    procedure Resolve_Integer_Literal           (N : Node_Id; Typ : Entity_Id);
 171    procedure Resolve_Logical_Op                (N : Node_Id; Typ : Entity_Id);
 172    procedure Resolve_Membership_Op             (N : Node_Id; Typ : Entity_Id);
 173    procedure Resolve_Null                      (N : Node_Id; Typ : Entity_Id);
 174    procedure Resolve_Operator_Symbol           (N : Node_Id; Typ : Entity_Id);
 175    procedure Resolve_Op_Concat                 (N : Node_Id; Typ : Entity_Id);
 176    procedure Resolve_Op_Expon                  (N : Node_Id; Typ : Entity_Id);
 177    procedure Resolve_Op_Not                    (N : Node_Id; Typ : Entity_Id);
 178    procedure Resolve_Qualified_Expression      (N : Node_Id; Typ : Entity_Id);
 179    procedure Resolve_Range                     (N : Node_Id; Typ : Entity_Id);
 180    procedure Resolve_Real_Literal              (N : Node_Id; Typ : Entity_Id);
 181    procedure Resolve_Reference                 (N : Node_Id; Typ : Entity_Id);
 182    procedure Resolve_Selected_Component        (N : Node_Id; Typ : Entity_Id);
 183    procedure Resolve_Shift                     (N : Node_Id; Typ : Entity_Id);
 184    procedure Resolve_Short_Circuit             (N : Node_Id; Typ : Entity_Id);
 185    procedure Resolve_Slice                     (N : Node_Id; Typ : Entity_Id);
 186    procedure Resolve_String_Literal            (N : Node_Id; Typ : Entity_Id);
 187    procedure Resolve_Subprogram_Info           (N : Node_Id; Typ : Entity_Id);
 188    procedure Resolve_Type_Conversion           (N : Node_Id; Typ : Entity_Id);
 189    procedure Resolve_Unary_Op                  (N : Node_Id; Typ : Entity_Id);
 190    procedure Resolve_Unchecked_Expression      (N : Node_Id; Typ : Entity_Id);
 191    procedure Resolve_Unchecked_Type_Conversion (N : Node_Id; Typ : Entity_Id);
 192
 193    function Operator_Kind
 194      (Op_Name   : Name_Id;
 195       Is_Binary : Boolean) return Node_Kind;
 196    --  Utility to map the name of an operator into the corresponding Node. Used
 197    --  by other node rewriting procedures.
 198
 199    procedure Resolve_Actuals (N : Node_Id; Nam : Entity_Id);
 200    --  Resolve actuals of call, and add default expressions for missing ones.
 201    --  N is the Node_Id for the subprogram call, and Nam is the entity of the
 202    --  called subprogram.
 203
 204    procedure Resolve_Entry_Call (N : Node_Id; Typ : Entity_Id);
 205    --  Called from Resolve_Call, when the prefix denotes an entry or element
 206    --  of entry family. Actuals are resolved as for subprograms, and the node
 207    --  is rebuilt as an entry call. Also called for protected operations. Typ
 208    --  is the context type, which is used when the operation is a protected
 209    --  function with no arguments, and the return value is indexed.
 210
 211    procedure Resolve_Intrinsic_Operator (N : Node_Id; Typ : Entity_Id);
 212    --  A call to a user-defined intrinsic operator is rewritten as a call
 213    --  to the corresponding predefined operator, with suitable conversions.
 214
 215    procedure Resolve_Intrinsic_Unary_Operator (N : Node_Id; Typ : Entity_Id);
 216    --  Ditto, for unary operators (only arithmetic ones)
 217
 218    procedure Rewrite_Operator_As_Call (N : Node_Id; Nam : Entity_Id);
 219    --  If an operator node resolves to a call to a user-defined operator,
 220    --  rewrite the node as a function call.
 221
 222    procedure Make_Call_Into_Operator
 223      (N     : Node_Id;
 224       Typ   : Entity_Id;
 225       Op_Id : Entity_Id);
 226    --  Inverse transformation: if an operator is given in functional notation,
 227    --  then after resolving the node, transform into an operator node, so
 228    --  that operands are resolved properly. Recall that predefined operators
 229    --  do not have a full signature and special resolution rules apply.
 230
 231    procedure Rewrite_Renamed_Operator
 232      (N   : Node_Id;
 233       Op  : Entity_Id;
 234       Typ : Entity_Id);
 235    --  An operator can rename another, e.g. in  an instantiation. In that
 236    --  case, the proper operator node must be constructed and resolved.
 237
 238    procedure Set_String_Literal_Subtype (N : Node_Id; Typ : Entity_Id);
 239    --  The String_Literal_Subtype is built for all strings that are not
 240    --  operands of a static concatenation operation. If the argument is
 241    --  not a N_String_Literal node, then the call has no effect.
 242
 243    procedure Set_Slice_Subtype (N : Node_Id);
 244    --  Build subtype of array type, with the range specified by the slice
 245
 246    procedure Simplify_Type_Conversion (N : Node_Id);
 247    --  Called after N has been resolved and evaluated, but before range checks
 248    --  have been applied. Currently simplifies a combination of floating-point
 249    --  to integer conversion and Truncation attribute.
 250
 251    function Unique_Fixed_Point_Type (N : Node_Id) return Entity_Id;
 252    --  A universal_fixed expression in an universal context is unambiguous
 253    --  if there is only one applicable fixed point type. Determining whether
 254    --  there is only one requires a search over all visible entities, and
 255    --  happens only in very pathological cases (see 6115-006).
 256
 257    function Valid_Conversion
 258      (N       : Node_Id;
 259       Target  : Entity_Id;
 260       Operand : Node_Id) return Boolean;
 261    --  Verify legality rules given in 4.6 (8-23). Target is the target
 262    --  type of the conversion, which may be an implicit conversion of
 263    --  an actual parameter to an anonymous access type (in which case
 264    --  N denotes the actual parameter and N = Operand).
 265
 266    -------------------------
 267    -- Ambiguous_Character --
 268    -------------------------
 269
 270    procedure Ambiguous_Character (C : Node_Id) is
 271       E : Entity_Id;
 272
 273    begin
 274       if Nkind (C) = N_Character_Literal then
 275          Error_Msg_N ("ambiguous character literal", C);
 276
 277          --  First the ones in Standard
 278
 279          Error_Msg_N
 280            ("\\possible interpretation: Character!", C);
 281          Error_Msg_N
 282            ("\\possible interpretation: Wide_Character!", C);
 283
 284          --  Include Wide_Wide_Character in Ada 2005 mode
 285
 286          if Ada_Version >= Ada_05 then
 287             Error_Msg_N
 288               ("\\possible interpretation: Wide_Wide_Character!", C);
 289          end if;
 290
 291          --  Now any other types that match
 292
 293          E := Current_Entity (C);
 294          while Present (E) loop
 295             Error_Msg_NE ("\\possible interpretation:}!", C, Etype (E));
 296             E := Homonym (E);
 297          end loop;
 298       end if;
 299    end Ambiguous_Character;
 300
 301    -------------------------
 302    -- Analyze_And_Resolve --
 303    -------------------------
 304
 305    procedure Analyze_And_Resolve (N : Node_Id) is
 306    begin
 307       Analyze (N);
 308       Resolve (N);
 309    end Analyze_And_Resolve;
 310
 311    procedure Analyze_And_Resolve (N : Node_Id; Typ : Entity_Id) is
 312    begin
 313       Analyze (N);
 314       Resolve (N, Typ);
 315    end Analyze_And_Resolve;
 316
 317    --  Version withs check(s) suppressed
 318
 319    procedure Analyze_And_Resolve
 320      (N        : Node_Id;
 321       Typ      : Entity_Id;
 322       Suppress : Check_Id)
 323    is
 324       Scop : constant Entity_Id := Current_Scope;
 325
 326    begin
 327       if Suppress = All_Checks then
 328          declare
 329             Svg : constant Suppress_Array := Scope_Suppress;
 330          begin
 331             Scope_Suppress := (others => True);
 332             Analyze_And_Resolve (N, Typ);
 333             Scope_Suppress := Svg;
 334          end;
 335
 336       else
 337          declare
 338             Svg : constant Boolean := Scope_Suppress (Suppress);
 339
 340          begin
 341             Scope_Suppress (Suppress) := True;
 342             Analyze_And_Resolve (N, Typ);
 343             Scope_Suppress (Suppress) := Svg;
 344          end;
 345       end if;
 346
 347       if Current_Scope /= Scop
 348         and then Scope_Is_Transient
 349       then
 350          --  This can only happen if a transient scope was created
 351          --  for an inner expression, which will be removed upon
 352          --  completion of the analysis of an enclosing construct.
 353          --  The transient scope must have the suppress status of
 354          --  the enclosing environment, not of this Analyze call.
 355
 356          Scope_Stack.Table (Scope_Stack.Last).Save_Scope_Suppress :=
 357            Scope_Suppress;
 358       end if;
 359    end Analyze_And_Resolve;
 360
 361    procedure Analyze_And_Resolve
 362      (N        : Node_Id;
 363       Suppress : Check_Id)
 364    is
 365       Scop : constant Entity_Id := Current_Scope;
 366
 367    begin
 368       if Suppress = All_Checks then
 369          declare
 370             Svg : constant Suppress_Array := Scope_Suppress;
 371          begin
 372             Scope_Suppress := (others => True);
 373             Analyze_And_Resolve (N);
 374             Scope_Suppress := Svg;
 375          end;
 376
 377       else
 378          declare
 379             Svg : constant Boolean := Scope_Suppress (Suppress);
 380
 381          begin
 382             Scope_Suppress (Suppress) := True;
 383             Analyze_And_Resolve (N);
 384             Scope_Suppress (Suppress) := Svg;
 385          end;
 386       end if;
 387
 388       if Current_Scope /= Scop
 389         and then Scope_Is_Transient
 390       then
 391          Scope_Stack.Table (Scope_Stack.Last).Save_Scope_Suppress :=
 392            Scope_Suppress;
 393       end if;
 394    end Analyze_And_Resolve;
 395
 396    ----------------------------
 397    -- Check_Discriminant_Use --
 398    ----------------------------
 399
 400    procedure Check_Discriminant_Use (N : Node_Id) is
 401       PN   : constant Node_Id   := Parent (N);
 402       Disc : constant Entity_Id := Entity (N);
 403       P    : Node_Id;
 404       D    : Node_Id;
 405
 406    begin
 407       --  Any use in a spec-expression is legal
 408
 409       if In_Spec_Expression then
 410          null;
 411
 412       elsif Nkind (PN) = N_Range then
 413
 414          --  Discriminant cannot be used to constrain a scalar type
 415
 416          P := Parent (PN);
 417
 418          if Nkind (P) = N_Range_Constraint
 419            and then Nkind (Parent (P)) = N_Subtype_Indication
 420            and then Nkind (Parent (Parent (P))) = N_Component_Definition
 421          then
 422             Error_Msg_N ("discriminant cannot constrain scalar type", N);
 423
 424          elsif Nkind (P) = N_Index_Or_Discriminant_Constraint then
 425
 426             --  The following check catches the unusual case where
 427             --  a discriminant appears within an index constraint
 428             --  that is part of a larger expression within a constraint
 429             --  on a component, e.g. "C : Int range 1 .. F (new A(1 .. D))".
 430             --  For now we only check case of record components, and
 431             --  note that a similar check should also apply in the
 432             --  case of discriminant constraints below. ???
 433
 434             --  Note that the check for N_Subtype_Declaration below is to
 435             --  detect the valid use of discriminants in the constraints of a
 436             --  subtype declaration when this subtype declaration appears
 437             --  inside the scope of a record type (which is syntactically
 438             --  illegal, but which may be created as part of derived type
 439             --  processing for records). See Sem_Ch3.Build_Derived_Record_Type
 440             --  for more info.
 441
 442             if Ekind (Current_Scope) = E_Record_Type
 443               and then Scope (Disc) = Current_Scope
 444               and then not
 445                 (Nkind (Parent (P)) = N_Subtype_Indication
 446                   and then
 447                     Nkind_In (Parent (Parent (P)), N_Component_Definition,
 448                                                    N_Subtype_Declaration)
 449                   and then Paren_Count (N) = 0)
 450             then
 451                Error_Msg_N
 452                  ("discriminant must appear alone in component constraint", N);
 453                return;
 454             end if;
 455
 456             --   Detect a common error:
 457
 458             --   type R (D : Positive := 100) is record
 459             --     Name : String (1 .. D);
 460             --   end record;
 461
 462             --  The default value causes an object of type R to be allocated
 463             --  with room for Positive'Last characters. The RM does not mandate
 464             --  the allocation of the maximum size, but that is what GNAT does
 465             --  so we should warn the programmer that there is a problem.
 466
 467             Check_Large : declare
 468                SI : Node_Id;
 469                T  : Entity_Id;
 470                TB : Node_Id;
 471                CB : Entity_Id;
 472
 473                function Large_Storage_Type (T : Entity_Id) return Boolean;
 474                --  Return True if type T has a large enough range that
 475                --  any array whose index type covered the whole range of
 476                --  the type would likely raise Storage_Error.
 477
 478                ------------------------
 479                -- Large_Storage_Type --
 480                ------------------------
 481
 482                function Large_Storage_Type (T : Entity_Id) return Boolean is
 483                begin
 484                   --  The type is considered large if its bounds are known at
 485                   --  compile time and if it requires at least as many bits as
 486                   --  a Positive to store the possible values.
 487
 488                   return Compile_Time_Known_Value (Type_Low_Bound (T))
 489                     and then Compile_Time_Known_Value (Type_High_Bound (T))
 490                     and then
 491                       Minimum_Size (T, Biased => True) >=
 492                         RM_Size (Standard_Positive);
 493                end Large_Storage_Type;
 494
 495             --  Start of processing for Check_Large
 496
 497             begin
 498                --  Check that the Disc has a large range
 499
 500                if not Large_Storage_Type (Etype (Disc)) then
 501                   goto No_Danger;
 502                end if;
 503
 504                --  If the enclosing type is limited, we allocate only the
 505                --  default value, not the maximum, and there is no need for
 506                --  a warning.
 507
 508                if Is_Limited_Type (Scope (Disc)) then
 509                   goto No_Danger;
 510                end if;
 511
 512                --  Check that it is the high bound
 513
 514                if N /= High_Bound (PN)
 515                  or else No (Discriminant_Default_Value (Disc))
 516                then
 517                   goto No_Danger;
 518                end if;
 519
 520                --  Check the array allows a large range at this bound.
 521                --  First find the array
 522
 523                SI := Parent (P);
 524
 525                if Nkind (SI) /= N_Subtype_Indication then
 526                   goto No_Danger;
 527                end if;
 528
 529                T := Entity (Subtype_Mark (SI));
 530
 531                if not Is_Array_Type (T) then
 532                   goto No_Danger;
 533                end if;
 534
 535                --  Next, find the dimension
 536
 537                TB := First_Index (T);
 538                CB := First (Constraints (P));
 539                while True
 540                  and then Present (TB)
 541                  and then Present (CB)
 542                  and then CB /= PN
 543                loop
 544                   Next_Index (TB);
 545                   Next (CB);
 546                end loop;
 547
 548                if CB /= PN then
 549                   goto No_Danger;
 550                end if;
 551
 552                --  Now, check the dimension has a large range
 553
 554                if not Large_Storage_Type (Etype (TB)) then
 555                   goto No_Danger;
 556                end if;
 557
 558                --  Warn about the danger
 559
 560                Error_Msg_N
 561                  ("?creation of & object may raise Storage_Error!",
 562                   Scope (Disc));
 563
 564                <<No_Danger>>
 565                   null;
 566
 567             end Check_Large;
 568          end if;
 569
 570       --  Legal case is in index or discriminant constraint
 571
 572       elsif Nkind_In (PN, N_Index_Or_Discriminant_Constraint,
 573                           N_Discriminant_Association)
 574       then
 575          if Paren_Count (N) > 0 then
 576             Error_Msg_N
 577               ("discriminant in constraint must appear alone",  N);
 578
 579          elsif Nkind (N) = N_Expanded_Name
 580            and then Comes_From_Source (N)
 581          then
 582             Error_Msg_N
 583               ("discriminant must appear alone as a direct name", N);
 584          end if;
 585
 586          return;
 587
 588       --  Otherwise, context is an expression. It should not be within
 589       --  (i.e. a subexpression of) a constraint for a component.
 590
 591       else
 592          D := PN;
 593          P := Parent (PN);
 594          while not Nkind_In (P, N_Component_Declaration,
 595                                 N_Subtype_Indication,
 596                                 N_Entry_Declaration)
 597          loop
 598             D := P;
 599             P := Parent (P);
 600             exit when No (P);
 601          end loop;
 602
 603          --  If the discriminant is used in an expression that is a bound
 604          --  of a scalar type, an Itype is created and the bounds are attached
 605          --  to its range,  not to the original subtype indication. Such use
 606          --  is of course a double fault.
 607
 608          if (Nkind (P) = N_Subtype_Indication
 609               and then Nkind_In (Parent (P), N_Component_Definition,
 610                                              N_Derived_Type_Definition)
 611               and then D = Constraint (P))
 612
 613          --  The constraint itself may be given by a subtype indication,
 614          --  rather than by a more common discrete range.
 615
 616            or else (Nkind (P) = N_Subtype_Indication
 617                       and then
 618                     Nkind (Parent (P)) = N_Index_Or_Discriminant_Constraint)
 619            or else Nkind (P) = N_Entry_Declaration
 620            or else Nkind (D) = N_Defining_Identifier
 621          then
 622             Error_Msg_N
 623               ("discriminant in constraint must appear alone",  N);
 624          end if;
 625       end if;
 626    end Check_Discriminant_Use;
 627
 628    --------------------------------
 629    -- Check_For_Visible_Operator --
 630    --------------------------------
 631
 632    procedure Check_For_Visible_Operator (N : Node_Id; T : Entity_Id) is
 633    begin
 634       if Is_Invisible_Operator (N, T) then
 635          Error_Msg_NE
 636            ("operator for} is not directly visible!", N, First_Subtype (T));
 637          Error_Msg_N ("use clause would make operation legal!", N);
 638       end if;
 639    end Check_For_Visible_Operator;
 640
 641    ----------------------------------
 642    --  Check_Fully_Declared_Prefix --
 643    ----------------------------------
 644
 645    procedure Check_Fully_Declared_Prefix
 646      (Typ  : Entity_Id;
 647       Pref : Node_Id)
 648    is
 649    begin
 650       --  Check that the designated type of the prefix of a dereference is
 651       --  not an incomplete type. This cannot be done unconditionally, because
 652       --  dereferences of private types are legal in default expressions. This
 653       --  case is taken care of in Check_Fully_Declared, called below. There
 654       --  are also 2005 cases where it is legal for the prefix to be unfrozen.
 655
 656       --  This consideration also applies to similar checks for allocators,
 657       --  qualified expressions, and type conversions.
 658
 659       --  An additional exception concerns other per-object expressions that
 660       --  are not directly related to component declarations, in particular
 661       --  representation pragmas for tasks. These will be per-object
 662       --  expressions if they depend on discriminants or some global entity.
 663       --  If the task has access discriminants, the designated type may be
 664       --  incomplete at the point the expression is resolved. This resolution
 665       --  takes place within the body of the initialization procedure, where
 666       --  the discriminant is replaced by its discriminal.
 667
 668       if Is_Entity_Name (Pref)
 669         and then Ekind (Entity (Pref)) = E_In_Parameter
 670       then
 671          null;
 672
 673       --  Ada 2005 (AI-326): Tagged incomplete types allowed. The wrong usages
 674       --  are handled by Analyze_Access_Attribute, Analyze_Assignment,
 675       --  Analyze_Object_Renaming, and Freeze_Entity.
 676
 677       elsif Ada_Version >= Ada_05
 678         and then Is_Entity_Name (Pref)
 679         and then Is_Access_Type (Etype (Pref))
 680         and then Ekind (Directly_Designated_Type (Etype (Pref))) =
 681                                                        E_Incomplete_Type
 682         and then Is_Tagged_Type (Directly_Designated_Type (Etype (Pref)))
 683       then
 684          null;
 685       else
 686          Check_Fully_Declared (Typ, Parent (Pref));
 687       end if;
 688    end Check_Fully_Declared_Prefix;
 689
 690    ------------------------------
 691    -- Check_Infinite_Recursion --
 692    ------------------------------
 693
 694    function Check_Infinite_Recursion (N : Node_Id) return Boolean is
 695       P : Node_Id;
 696       C : Node_Id;
 697
 698       function Same_Argument_List return Boolean;
 699       --  Check whether list of actuals is identical to list of formals
 700       --  of called function (which is also the enclosing scope).
 701
 702       ------------------------
 703       -- Same_Argument_List --
 704       ------------------------
 705
 706       function Same_Argument_List return Boolean is
 707          A    : Node_Id;
 708          F    : Entity_Id;
 709          Subp : Entity_Id;
 710
 711       begin
 712          if not Is_Entity_Name (Name (N)) then
 713             return False;
 714          else
 715             Subp := Entity (Name (N));
 716          end if;
 717
 718          F := First_Formal (Subp);
 719          A := First_Actual (N);
 720          while Present (F) and then Present (A) loop
 721             if not Is_Entity_Name (A)
 722               or else Entity (A) /= F
 723             then
 724                return False;
 725             end if;
 726
 727             Next_Actual (A);
 728             Next_Formal (F);
 729          end loop;
 730
 731          return True;
 732       end Same_Argument_List;
 733
 734    --  Start of processing for Check_Infinite_Recursion
 735
 736    begin
 737       --  Special case, if this is a procedure call and is a call to the
 738       --  current procedure with the same argument list, then this is for
 739       --  sure an infinite recursion and we insert a call to raise SE.
 740
 741       if Is_List_Member (N)
 742         and then List_Length (List_Containing (N)) = 1
 743         and then Same_Argument_List
 744       then
 745          declare
 746             P : constant Node_Id := Parent (N);
 747          begin
 748             if Nkind (P) = N_Handled_Sequence_Of_Statements
 749               and then Nkind (Parent (P)) = N_Subprogram_Body
 750               and then Is_Empty_List (Declarations (Parent (P)))
 751             then
 752                Error_Msg_N ("!?infinite recursion", N);
 753                Error_Msg_N ("\!?Storage_Error will be raised at run time", N);
 754                Insert_Action (N,
 755                  Make_Raise_Storage_Error (Sloc (N),
 756                    Reason => SE_Infinite_Recursion));
 757                return True;
 758             end if;
 759          end;
 760       end if;
 761
 762       --  If not that special case, search up tree, quitting if we reach a
 763       --  construct (e.g. a conditional) that tells us that this is not a
 764       --  case for an infinite recursion warning.
 765
 766       C := N;
 767       loop
 768          P := Parent (C);
 769
 770          --  If no parent, then we were not inside a subprogram, this can for
 771          --  example happen when processing certain pragmas in a spec. Just
 772          --  return False in this case.
 773
 774          if No (P) then
 775             return False;
 776          end if;
 777
 778          --  Done if we get to subprogram body, this is definitely an infinite
 779          --  recursion case if we did not find anything to stop us.
 780
 781          exit when Nkind (P) = N_Subprogram_Body;
 782
 783          --  If appearing in conditional, result is false
 784
 785          if Nkind_In (P, N_Or_Else,
 786                          N_And_Then,
 787                          N_If_Statement,
 788                          N_Case_Statement)
 789          then
 790             return False;
 791
 792          elsif Nkind (P) = N_Handled_Sequence_Of_Statements
 793            and then C /= First (Statements (P))
 794          then
 795             --  If the call is the expression of a return statement and the
 796             --  actuals are identical to the formals, it's worth a warning.
 797             --  However, we skip this if there is an immediately preceding
 798             --  raise statement, since the call is never executed.
 799
 800             --  Furthermore, this corresponds to a common idiom:
 801
 802             --    function F (L : Thing) return Boolean is
 803             --    begin
 804             --       raise Program_Error;
 805             --       return F (L);
 806             --    end F;
 807
 808             --  for generating a stub function
 809
 810             if Nkind (Parent (N)) = N_Simple_Return_Statement
 811               and then Same_Argument_List
 812             then
 813                exit when not Is_List_Member (Parent (N));
 814
 815                --  OK, return statement is in a statement list, look for raise
 816
 817                declare
 818                   Nod : Node_Id;
 819
 820                begin
 821                   --  Skip past N_Freeze_Entity nodes generated by expansion
 822
 823                   Nod := Prev (Parent (N));
 824                   while Present (Nod)
 825                     and then Nkind (Nod) = N_Freeze_Entity
 826                   loop
 827                      Prev (Nod);
 828                   end loop;
 829
 830                   --  If no raise statement, give warning
 831
 832                   exit when Nkind (Nod) /= N_Raise_Statement
 833                     and then
 834                       (Nkind (Nod) not in N_Raise_xxx_Error
 835                          or else Present (Condition (Nod)));
 836                end;
 837             end if;
 838
 839             return False;
 840
 841          else
 842             C := P;
 843          end if;
 844       end loop;
 845
 846       Error_Msg_N ("!?possible infinite recursion", N);
 847       Error_Msg_N ("\!?Storage_Error may be raised at run time", N);
 848
 849       return True;
 850    end Check_Infinite_Recursion;
 851
 852    -------------------------------
 853    -- Check_Initialization_Call --
 854    -------------------------------
 855
 856    procedure Check_Initialization_Call (N : Entity_Id; Nam : Entity_Id) is
 857       Typ : constant Entity_Id := Etype (First_Formal (Nam));
 858
 859       function Uses_SS (T : Entity_Id) return Boolean;
 860       --  Check whether the creation of an object of the type will involve
 861       --  use of the secondary stack. If T is a record type, this is true
 862       --  if the expression for some component uses the secondary stack, e.g.
 863       --  through a call to a function that returns an unconstrained value.
 864       --  False if T is controlled, because cleanups occur elsewhere.
 865
 866       -------------
 867       -- Uses_SS --
 868       -------------
 869
 870       function Uses_SS (T : Entity_Id) return Boolean is
 871          Comp      : Entity_Id;
 872          Expr      : Node_Id;
 873          Full_Type : Entity_Id := Underlying_Type (T);
 874
 875       begin
 876          --  Normally we want to use the underlying type, but if it's not set
 877          --  then continue with T.
 878
 879          if not Present (Full_Type) then
 880             Full_Type := T;
 881          end if;
 882
 883          if Is_Controlled (Full_Type) then
 884             return False;
 885
 886          elsif Is_Array_Type (Full_Type) then
 887             return Uses_SS (Component_Type (Full_Type));
 888
 889          elsif Is_Record_Type (Full_Type) then
 890             Comp := First_Component (Full_Type);
 891             while Present (Comp) loop
 892                if Ekind (Comp) = E_Component
 893                  and then Nkind (Parent (Comp)) = N_Component_Declaration
 894                then
 895                   --  The expression for a dynamic component may be rewritten
 896                   --  as a dereference, so retrieve original node.
 897
 898                   Expr := Original_Node (Expression (Parent (Comp)));
 899
 900                   --  Return True if the expression is a call to a function
 901                   --  (including an attribute function such as Image) with
 902                   --  a result that requires a transient scope.
 903
 904                   if (Nkind (Expr) = N_Function_Call
 905                        or else (Nkind (Expr) = N_Attribute_Reference
 906                                  and then Present (Expressions (Expr))))
 907                     and then Requires_Transient_Scope (Etype (Expr))
 908                   then
 909                      return True;
 910
 911                   elsif Uses_SS (Etype (Comp)) then
 912                      return True;
 913                   end if;
 914                end if;
 915
 916                Next_Component (Comp);
 917             end loop;
 918
 919             return False;
 920
 921          else
 922             return False;
 923          end if;
 924       end Uses_SS;
 925
 926    --  Start of processing for Check_Initialization_Call
 927
 928    begin
 929       --  Establish a transient scope if the type needs it
 930
 931       if Uses_SS (Typ) then
 932          Establish_Transient_Scope (First_Actual (N), Sec_Stack => True);
 933       end if;
 934    end Check_Initialization_Call;
 935
 936    ---------------------------------------
 937    -- Check_No_Direct_Boolean_Operators --
 938    ---------------------------------------
 939
 940    procedure Check_No_Direct_Boolean_Operators (N : Node_Id) is
 941    begin
 942       if Scope (Entity (N)) = Standard_Standard
 943         and then Root_Type (Etype (Left_Opnd (N))) = Standard_Boolean
 944       then
 945          --  Restriction only applies to original source code
 946
 947          if Comes_From_Source (N) then
 948             Check_Restriction (No_Direct_Boolean_Operators, N);
 949          end if;
 950       end if;
 951
 952       if Style_Check then
 953          Check_Boolean_Operator (N);
 954       end if;
 955    end Check_No_Direct_Boolean_Operators;
 956
 957    ------------------------------
 958    -- Check_Parameterless_Call --
 959    ------------------------------
 960
 961    procedure Check_Parameterless_Call (N : Node_Id) is
 962       Nam : Node_Id;
 963
 964       function Prefix_Is_Access_Subp return Boolean;
 965       --  If the prefix is of an access_to_subprogram type, the node must be
 966       --  rewritten as a call. Ditto if the prefix is overloaded and all its
 967       --  interpretations are access to subprograms.
 968
 969       ---------------------------
 970       -- Prefix_Is_Access_Subp --
 971       ---------------------------
 972
 973       function Prefix_Is_Access_Subp return Boolean is
 974          I   : Interp_Index;
 975          It  : Interp;
 976
 977       begin
 978          if not Is_Overloaded (N) then
 979             return
 980               Ekind (Etype (N)) = E_Subprogram_Type
 981                 and then Base_Type (Etype (Etype (N))) /= Standard_Void_Type;
 982          else
 983             Get_First_Interp (N, I, It);
 984             while Present (It.Typ) loop
 985                if Ekind (It.Typ) /= E_Subprogram_Type
 986                  or else Base_Type (Etype (It.Typ)) = Standard_Void_Type
 987                then
 988                   return False;
 989                end if;
 990
 991                Get_Next_Interp (I, It);
 992             end loop;
 993
 994             return True;
 995          end if;
 996       end Prefix_Is_Access_Subp;
 997
 998    --  Start of processing for Check_Parameterless_Call
 999
1000    begin
1001       --  Defend against junk stuff if errors already detected
1002
1003       if Total_Errors_Detected /= 0 then
1004          if Nkind (N) in N_Has_Etype and then Etype (N) = Any_Type then
1005             return;
1006          elsif Nkind (N) in N_Has_Chars
1007            and then Chars (N) in Error_Name_Or_No_Name
1008          then
1009             return;
1010          end if;
1011
1012          Require_Entity (N);
1013       end if;
1014
1015       --  If the context expects a value, and the name is a procedure, this is
1016       --  most likely a missing 'Access. Don't try to resolve the parameterless
1017       --  call, error will be caught when the outer call is analyzed.
1018
1019       if Is_Entity_Name (N)
1020         and then Ekind (Entity (N)) = E_Procedure
1021         and then not Is_Overloaded (N)
1022         and then
1023          Nkind_In (Parent (N), N_Parameter_Association,
1024                                N_Function_Call,
1025                                N_Procedure_Call_Statement)
1026       then
1027          return;
1028       end if;
1029
1030       --  Rewrite as call if overloadable entity that is (or could be, in the
1031       --  overloaded case) a function call. If we know for sure that the entity
1032       --  is an enumeration literal, we do not rewrite it.
1033
1034       if (Is_Entity_Name (N)
1035             and then Is_Overloadable (Entity (N))
1036             and then (Ekind (Entity (N)) /= E_Enumeration_Literal
1037                         or else Is_Overloaded (N)))
1038
1039       --  Rewrite as call if it is an explicit dereference of an expression of
1040       --  a subprogram access type, and the subprogram type is not that of a
1041       --  procedure or entry.
1042
1043       or else
1044         (Nkind (N) = N_Explicit_Dereference and then Prefix_Is_Access_Subp)
1045
1046       --  Rewrite as call if it is a selected component which is a function,
1047       --  this is the case of a call to a protected function (which may be
1048       --  overloaded with other protected operations).
1049
1050       or else
1051         (Nkind (N) = N_Selected_Component
1052           and then (Ekind (Entity (Selector_Name (N))) = E_Function
1053                       or else
1054                         ((Ekind (Entity (Selector_Name (N))) = E_Entry
1055                             or else
1056                           Ekind (Entity (Selector_Name (N))) = E_Procedure)
1057                             and then Is_Overloaded (Selector_Name (N)))))
1058
1059       --  If one of the above three conditions is met, rewrite as call.
1060       --  Apply the rewriting only once.
1061
1062       then
1063          if Nkind (Parent (N)) /= N_Function_Call
1064            or else N /= Name (Parent (N))
1065          then
1066             Nam := New_Copy (N);
1067
1068             --  If overloaded, overload set belongs to new copy
1069
1070             Save_Interps (N, Nam);
1071
1072             --  Change node to parameterless function call (note that the
1073             --  Parameter_Associations associations field is left set to Empty,
1074             --  its normal default value since there are no parameters)
1075
1076             Change_Node (N, N_Function_Call);
1077             Set_Name (N, Nam);
1078             Set_Sloc (N, Sloc (Nam));
1079             Analyze_Call (N);
1080          end if;
1081
1082       elsif Nkind (N) = N_Parameter_Association then
1083          Check_Parameterless_Call (Explicit_Actual_Parameter (N));
1084       end if;
1085    end Check_Parameterless_Call;
1086
1087    -----------------------------
1088    -- Is_Definite_Access_Type --
1089    -----------------------------
1090
1091    function Is_Definite_Access_Type (E : Entity_Id) return Boolean is
1092       Btyp : constant Entity_Id := Base_Type (E);
1093    begin
1094       return Ekind (Btyp) = E_Access_Type
1095         or else (Ekind (Btyp) = E_Access_Subprogram_Type
1096                   and then Comes_From_Source (Btyp));
1097    end Is_Definite_Access_Type;
1098
1099    ----------------------
1100    -- Is_Predefined_Op --
1101    ----------------------
1102
1103    function Is_Predefined_Op (Nam : Entity_Id) return Boolean is
1104    begin
1105       return Is_Intrinsic_Subprogram (Nam)
1106         and then not Is_Generic_Instance (Nam)
1107         and then Chars (Nam) in Any_Operator_Name
1108         and then (No (Alias (Nam))
1109                    or else Is_Predefined_Op (Alias (Nam)));
1110    end Is_Predefined_Op;
1111
1112    -----------------------------
1113    -- Make_Call_Into_Operator --
1114    -----------------------------
1115
1116    procedure Make_Call_Into_Operator
1117      (N     : Node_Id;
1118       Typ   : Entity_Id;
1119       Op_Id : Entity_Id)
1120    is
1121       Op_Name   : constant Name_Id := Chars (Op_Id);
1122       Act1      : Node_Id := First_Actual (N);
1123       Act2      : Node_Id := Next_Actual (Act1);
1124       Error     : Boolean := False;
1125       Func      : constant Entity_Id := Entity (Name (N));
1126       Is_Binary : constant Boolean   := Present (Act2);
1127       Op_Node   : Node_Id;
1128       Opnd_Type : Entity_Id;
1129       Orig_Type : Entity_Id := Empty;
1130       Pack      : Entity_Id;
1131
1132       type Kind_Test is access function (E : Entity_Id) return Boolean;
1133
1134       function Operand_Type_In_Scope (S : Entity_Id) return Boolean;
1135       --  If the operand is not universal, and the operator is given by a
1136       --  expanded name,  verify that the operand has an interpretation with
1137       --  a type defined in the given scope of the operator.
1138
1139       function Type_In_P (Test : Kind_Test) return Entity_Id;
1140       --  Find a type of the given class in the package Pack that contains
1141       --  the operator.
1142
1143       ---------------------------
1144       -- Operand_Type_In_Scope --
1145       ---------------------------
1146
1147       function Operand_Type_In_Scope (S : Entity_Id) return Boolean is
1148          Nod : constant Node_Id := Right_Opnd (Op_Node);
1149          I   : Interp_Index;
1150          It  : Interp;
1151
1152       begin
1153          if not Is_Overloaded (Nod) then
1154             return Scope (Base_Type (Etype (Nod))) = S;
1155
1156          else
1157             Get_First_Interp (Nod, I, It);
1158             while Present (It.Typ) loop
1159                if Scope (Base_Type (It.Typ)) = S then
1160                   return True;
1161                end if;
1162
1163                Get_Next_Interp (I, It);
1164             end loop;
1165
1166             return False;
1167          end if;
1168       end Operand_Type_In_Scope;
1169
1170       ---------------
1171       -- Type_In_P --
1172       ---------------
1173
1174       function Type_In_P (Test : Kind_Test) return Entity_Id is
1175          E : Entity_Id;
1176
1177          function In_Decl return Boolean;
1178          --  Verify that node is not part of the type declaration for the
1179          --  candidate type, which would otherwise be invisible.
1180
1181          -------------
1182          -- In_Decl --
1183          -------------
1184
1185          function In_Decl return Boolean is
1186             Decl_Node : constant Node_Id := Parent (E);
1187             N2        : Node_Id;
1188
1189          begin
1190             N2 := N;
1191
1192             if Etype (E) = Any_Type then
1193                return True;
1194
1195             elsif No (Decl_Node) then
1196                return False;
1197
1198             else
1199                while Present (N2)
1200                  and then Nkind (N2) /= N_Compilation_Unit
1201                loop
1202                   if N2 = Decl_Node then
1203                      return True;
1204                   else
1205                      N2 := Parent (N2);
1206                   end if;
1207                end loop;
1208
1209                return False;
1210             end if;
1211          end In_Decl;
1212
1213       --  Start of processing for Type_In_P
1214
1215       begin
1216          --  If the context type is declared in the prefix package, this
1217          --  is the desired base type.
1218
1219          if Scope (Base_Type (Typ)) = Pack
1220            and then Test (Typ)
1221          then
1222             return Base_Type (Typ);
1223
1224          else
1225             E := First_Entity (Pack);
1226             while Present (E) loop
1227                if Test (E)
1228                  and then not In_Decl
1229                then
1230                   return E;
1231                end if;
1232
1233                Next_Entity (E);
1234             end loop;
1235
1236             return Empty;
1237          end if;
1238       end Type_In_P;
1239
1240    --  Start of processing for Make_Call_Into_Operator
1241
1242    begin
1243       Op_Node := New_Node (Operator_Kind (Op_Name, Is_Binary), Sloc (N));
1244
1245       --  Binary operator
1246
1247       if Is_Binary then
1248          Set_Left_Opnd  (Op_Node, Relocate_Node (Act1));
1249          Set_Right_Opnd (Op_Node, Relocate_Node (Act2));
1250          Save_Interps (Act1, Left_Opnd  (Op_Node));
1251          Save_Interps (Act2, Right_Opnd (Op_Node));
1252          Act1 := Left_Opnd (Op_Node);
1253          Act2 := Right_Opnd (Op_Node);
1254
1255       --  Unary operator
1256
1257       else
1258          Set_Right_Opnd (Op_Node, Relocate_Node (Act1));
1259          Save_Interps (Act1, Right_Opnd (Op_Node));
1260          Act1 := Right_Opnd (Op_Node);
1261       end if;
1262
1263       --  If the operator is denoted by an expanded name, and the prefix is
1264       --  not Standard, but the operator is a predefined one whose scope is
1265       --  Standard, then this is an implicit_operator, inserted as an
1266       --  interpretation by the procedure of the same name. This procedure
1267       --  overestimates the presence of implicit operators, because it does
1268       --  not examine the type of the operands. Verify now that the operand
1269       --  type appears in the given scope. If right operand is universal,
1270       --  check the other operand. In the case of concatenation, either
1271       --  argument can be the component type, so check the type of the result.
1272       --  If both arguments are literals, look for a type of the right kind
1273       --  defined in the given scope. This elaborate nonsense is brought to
1274       --  you courtesy of b33302a. The type itself must be frozen, so we must
1275       --  find the type of the proper class in the given scope.
1276
1277       --  A final wrinkle is the multiplication operator for fixed point
1278       --  types, which is defined in Standard only, and not in the scope of
1279       --  the fixed_point type itself.
1280
1281       if Nkind (Name (N)) = N_Expanded_Name then
1282          Pack := Entity (Prefix (Name (N)));
1283
1284          --  If the entity being called is defined in the given package,
1285          --  it is a renaming of a predefined operator, and known to be
1286          --  legal.
1287
1288          if Scope (Entity (Name (N))) = Pack
1289             and then Pack /= Standard_Standard
1290          then
1291             null;
1292
1293          --  Visibility does not need to be checked in an instance: if the
1294          --  operator was not visible in the generic it has been diagnosed
1295          --  already, else there is an implicit copy of it in the instance.
1296
1297          elsif In_Instance then
1298             null;
1299
1300          elsif (Op_Name =  Name_Op_Multiply
1301               or else Op_Name = Name_Op_Divide)
1302            and then Is_Fixed_Point_Type (Etype (Left_Opnd  (Op_Node)))
1303            and then Is_Fixed_Point_Type (Etype (Right_Opnd (Op_Node)))
1304          then
1305             if Pack /= Standard_Standard then
1306                Error := True;
1307             end if;
1308
1309          --  Ada 2005, AI-420:  Predefined equality on Universal_Access
1310          --  is available.
1311
1312          elsif Ada_Version >= Ada_05
1313            and then (Op_Name = Name_Op_Eq or else Op_Name = Name_Op_Ne)
1314            and then Ekind (Etype (Act1)) = E_Anonymous_Access_Type
1315          then
1316             null;
1317
1318          else
1319             Opnd_Type := Base_Type (Etype (Right_Opnd (Op_Node)));
1320
1321             if Op_Name = Name_Op_Concat then
1322                Opnd_Type := Base_Type (Typ);
1323
1324             elsif (Scope (Opnd_Type) = Standard_Standard
1325                      and then Is_Binary)
1326               or else (Nkind (Right_Opnd (Op_Node)) = N_Attribute_Reference
1327                         and then Is_Binary
1328                         and then not Comes_From_Source (Opnd_Type))
1329             then
1330                Opnd_Type := Base_Type (Etype (Left_Opnd (Op_Node)));
1331             end if;
1332
1333             if Scope (Opnd_Type) = Standard_Standard then
1334
1335                --  Verify that the scope contains a type that corresponds to
1336                --  the given literal. Optimize the case where Pack is Standard.
1337
1338                if Pack /= Standard_Standard then
1339
1340                   if Opnd_Type = Universal_Integer then
1341                      Orig_Type :=  Type_In_P (Is_Integer_Type'Access);
1342
1343                   elsif Opnd_Type = Universal_Real then
1344                      Orig_Type := Type_In_P (Is_Real_Type'Access);
1345
1346                   elsif Opnd_Type = Any_String then
1347                      Orig_Type := Type_In_P (Is_String_Type'Access);
1348
1349                   elsif Opnd_Type = Any_Access then
1350                      Orig_Type :=  Type_In_P (Is_Definite_Access_Type'Access);
1351
1352                   elsif Opnd_Type = Any_Composite then
1353                      Orig_Type := Type_In_P (Is_Composite_Type'Access);
1354
1355                      if Present (Orig_Type) then
1356                         if Has_Private_Component (Orig_Type) then
1357                            Orig_Type := Empty;
1358                         else
1359                            Set_Etype (Act1, Orig_Type);
1360
1361                            if Is_Binary then
1362                               Set_Etype (Act2, Orig_Type);
1363                            end if;
1364                         end if;
1365                      end if;
1366
1367                   else
1368                      Orig_Type := Empty;
1369                   end if;
1370
1371                   Error := No (Orig_Type);
1372                end if;
1373
1374             elsif Ekind (Opnd_Type) = E_Allocator_Type
1375                and then No (Type_In_P (Is_Definite_Access_Type'Access))
1376             then
1377                Error := True;
1378
1379             --  If the type is defined elsewhere, and the operator is not
1380             --  defined in the given scope (by a renaming declaration, e.g.)
1381             --  then this is an error as well. If an extension of System is
1382             --  present, and the type may be defined there, Pack must be
1383             --  System itself.
1384
1385             elsif Scope (Opnd_Type) /= Pack
1386               and then Scope (Op_Id) /= Pack
1387               and then (No (System_Aux_Id)
1388                          or else Scope (Opnd_Type) /= System_Aux_Id
1389                          or else Pack /= Scope (System_Aux_Id))
1390             then
1391                if not Is_Overloaded (Right_Opnd (Op_Node)) then
1392                   Error := True;
1393                else
1394                   Error := not Operand_Type_In_Scope (Pack);
1395                end if;
1396
1397             elsif Pack = Standard_Standard
1398               and then not Operand_Type_In_Scope (Standard_Standard)
1399             then
1400                Error := True;
1401             end if;
1402          end if;
1403
1404          if Error then
1405             Error_Msg_Node_2 := Pack;
1406             Error_Msg_NE
1407               ("& not declared in&", N, Selector_Name (Name (N)));
1408             Set_Etype (N, Any_Type);
1409             return;
1410          end if;
1411       end if;
1412
1413       Set_Chars  (Op_Node, Op_Name);
1414
1415       if not Is_Private_Type (Etype (N)) then
1416          Set_Etype (Op_Node, Base_Type (Etype (N)));
1417       else
1418          Set_Etype (Op_Node, Etype (N));
1419       end if;
1420
1421       --  If this is a call to a function that renames a predefined equality,
1422       --  the renaming declaration provides a type that must be used to
1423       --  resolve the operands. This must be done now because resolution of
1424       --  the equality node will not resolve any remaining ambiguity, and it
1425       --  assumes that the first operand is not overloaded.
1426
1427       if (Op_Name = Name_Op_Eq or else Op_Name = Name_Op_Ne)
1428         and then Ekind (Func) = E_Function
1429         and then Is_Overloaded (Act1)
1430       then
1431          Resolve (Act1, Base_Type (Etype (First_Formal (Func))));
1432          Resolve (Act2, Base_Type (Etype (First_Formal (Func))));
1433       end if;
1434
1435       Set_Entity (Op_Node, Op_Id);
1436       Generate_Reference (Op_Id, N, ' ');
1437
1438       --  Do rewrite setting Comes_From_Source on the result if the original
1439       --  call came from source. Although it is not strictly the case that the
1440       --  operator as such comes from the source, logically it corresponds
1441       --  exactly to the function call in the source, so it should be marked
1442       --  this way (e.g. to make sure that validity checks work fine).
1443
1444       declare
1445          CS : constant Boolean := Comes_From_Source (N);
1446       begin
1447          Rewrite (N, Op_Node);
1448          Set_Comes_From_Source (N, CS);
1449       end;
1450
1451       --  If this is an arithmetic operator and the result type is private,
1452       --  the operands and the result must be wrapped in conversion to
1453       --  expose the underlying numeric type and expand the proper checks,
1454       --  e.g. on division.
1455
1456       if Is_Private_Type (Typ) then
1457          case Nkind (N) is
1458             when N_Op_Add  | N_Op_Subtract | N_Op_Multiply | N_Op_Divide |
1459             N_Op_Expon     | N_Op_Mod      | N_Op_Rem      =>
1460                Resolve_Intrinsic_Operator (N, Typ);
1461
1462             when N_Op_Plus | N_Op_Minus    | N_Op_Abs      =>
1463                Resolve_Intrinsic_Unary_Operator (N, Typ);
1464
1465             when others =>
1466                Resolve (N, Typ);
1467          end case;
1468       else
1469          Resolve (N, Typ);
1470       end if;
1471
1472       --  For predefined operators on literals, the operation freezes
1473       --  their type.
1474
1475       if Present (Orig_Type) then
1476          Set_Etype (Act1, Orig_Type);
1477          Freeze_Expression (Act1);
1478       end if;
1479    end Make_Call_Into_Operator;
1480
1481    -------------------
1482    -- Operator_Kind --
1483    -------------------
1484
1485    function Operator_Kind
1486      (Op_Name   : Name_Id;
1487       Is_Binary : Boolean) return Node_Kind
1488    is
1489       Kind : Node_Kind;
1490
1491    begin
1492       if Is_Binary then
1493          if    Op_Name =  Name_Op_And      then
1494             Kind := N_Op_And;
1495          elsif Op_Name =  Name_Op_Or       then
1496             Kind := N_Op_Or;
1497          elsif Op_Name =  Name_Op_Xor      then
1498             Kind := N_Op_Xor;
1499          elsif Op_Name =  Name_Op_Eq       then
1500             Kind := N_Op_Eq;
1501          elsif Op_Name =  Name_Op_Ne       then
1502             Kind := N_Op_Ne;
1503          elsif Op_Name =  Name_Op_Lt       then
1504             Kind := N_Op_Lt;
1505          elsif Op_Name =  Name_Op_Le       then
1506             Kind := N_Op_Le;
1507          elsif Op_Name =  Name_Op_Gt       then
1508             Kind := N_Op_Gt;
1509          elsif Op_Name =  Name_Op_Ge       then
1510             Kind := N_Op_Ge;
1511          elsif Op_Name =  Name_Op_Add      then
1512             Kind := N_Op_Add;
1513          elsif Op_Name =  Name_Op_Subtract then
1514             Kind := N_Op_Subtract;
1515          elsif Op_Name =  Name_Op_Concat   then
1516             Kind := N_Op_Concat;
1517          elsif Op_Name =  Name_Op_Multiply then
1518             Kind := N_Op_Multiply;
1519          elsif Op_Name =  Name_Op_Divide   then
1520             Kind := N_Op_Divide;
1521          elsif Op_Name =  Name_Op_Mod      then
1522             Kind := N_Op_Mod;
1523          elsif Op_Name =  Name_Op_Rem      then
1524             Kind := N_Op_Rem;
1525          elsif Op_Name =  Name_Op_Expon    then
1526             Kind := N_Op_Expon;
1527          else
1528             raise Program_Error;
1529          end if;
1530
1531       --  Unary operators
1532
1533       else
1534          if    Op_Name =  Name_Op_Add      then
1535             Kind := N_Op_Plus;
1536          elsif Op_Name =  Name_Op_Subtract then
1537             Kind := N_Op_Minus;
1538          elsif Op_Name =  Name_Op_Abs      then
1539             Kind := N_Op_Abs;
1540          elsif Op_Name =  Name_Op_Not      then
1541             Kind := N_Op_Not;
1542          else
1543             raise Program_Error;
1544          end if;
1545       end if;
1546
1547       return Kind;
1548    end Operator_Kind;
1549
1550    ----------------------------
1551    -- Preanalyze_And_Resolve --
1552    ----------------------------
1553
1554    procedure Preanalyze_And_Resolve (N : Node_Id; T : Entity_Id) is
1555       Save_Full_Analysis : constant Boolean := Full_Analysis;
1556
1557    begin
1558       Full_Analysis := False;
1559       Expander_Mode_Save_And_Set (False);
1560
1561       --  We suppress all checks for this analysis, since the checks will
1562       --  be applied properly, and in the right location, when the default
1563       --  expression is reanalyzed and reexpanded later on.
1564
1565       Analyze_And_Resolve (N, T, Suppress => All_Checks);
1566
1567       Expander_Mode_Restore;
1568       Full_Analysis := Save_Full_Analysis;
1569    end Preanalyze_And_Resolve;
1570
1571    --  Version without context type
1572
1573    procedure Preanalyze_And_Resolve (N : Node_Id) is
1574       Save_Full_Analysis : constant Boolean := Full_Analysis;
1575
1576    begin
1577       Full_Analysis := False;
1578       Expander_Mode_Save_And_Set (False);
1579
1580       Analyze (N);
1581       Resolve (N, Etype (N), Suppress => All_Checks);
1582
1583       Expander_Mode_Restore;
1584       Full_Analysis := Save_Full_Analysis;
1585    end Preanalyze_And_Resolve;
1586
1587    ----------------------------------
1588    -- Replace_Actual_Discriminants --
1589    ----------------------------------
1590
1591    procedure Replace_Actual_Discriminants (N : Node_Id; Default : Node_Id) is
1592       Loc : constant Source_Ptr := Sloc (N);
1593       Tsk : Node_Id := Empty;
1594
1595       function Process_Discr (Nod : Node_Id) return Traverse_Result;
1596
1597       -------------------
1598       -- Process_Discr --
1599       -------------------
1600
1601       function Process_Discr (Nod : Node_Id) return Traverse_Result is
1602          Ent : Entity_Id;
1603
1604       begin
1605          if Nkind (Nod) = N_Identifier then
1606             Ent := Entity (Nod);
1607
1608             if Present (Ent)
1609               and then Ekind (Ent) = E_Discriminant
1610             then
1611                Rewrite (Nod,
1612                  Make_Selected_Component (Loc,
1613                    Prefix        => New_Copy_Tree (Tsk, New_Sloc => Loc),
1614                    Selector_Name => Make_Identifier (Loc, Chars (Ent))));
1615
1616                Set_Etype (Nod, Etype (Ent));
1617             end if;
1618
1619          end if;
1620
1621          return OK;
1622       end Process_Discr;
1623
1624       procedure Replace_Discrs is new Traverse_Proc (Process_Discr);
1625
1626    --  Start of processing for Replace_Actual_Discriminants
1627
1628    begin
1629       if not Expander_Active then
1630          return;
1631       end if;
1632
1633       if Nkind (Name (N)) = N_Selected_Component then
1634          Tsk := Prefix (Name (N));
1635
1636       elsif Nkind (Name (N)) = N_Indexed_Component then
1637          Tsk := Prefix (Prefix (Name (N)));
1638       end if;
1639
1640       if No (Tsk) then
1641          return;
1642       else
1643          Replace_Discrs (Default);
1644       end if;
1645    end Replace_Actual_Discriminants;
1646
1647    -------------
1648    -- Resolve --
1649    -------------
1650
1651    procedure Resolve (N : Node_Id; Typ : Entity_Id) is
1652       Ambiguous : Boolean   := False;
1653       Ctx_Type  : Entity_Id := Typ;
1654       Expr_Type : Entity_Id := Empty; -- prevent junk warning
1655       Err_Type  : Entity_Id := Empty;
1656       Found     : Boolean   := False;
1657       From_Lib  : Boolean;
1658       I         : Interp_Index;
1659       I1        : Interp_Index := 0;  -- prevent junk warning
1660       It        : Interp;
1661       It1       : Interp;
1662       Seen      : Entity_Id := Empty; -- prevent junk warning
1663
1664       function Comes_From_Predefined_Lib_Unit (Nod : Node_Id) return Boolean;
1665       --  Determine whether a node comes from a predefined library unit or
1666       --  Standard.
1667
1668       procedure Patch_Up_Value (N : Node_Id; Typ : Entity_Id);
1669       --  Try and fix up a literal so that it matches its expected type. New
1670       --  literals are manufactured if necessary to avoid cascaded errors.
1671
1672       procedure Report_Ambiguous_Argument;
1673       --  Additional diagnostics when an ambiguous call has an ambiguous
1674       --  argument (typically a controlling actual).
1675
1676       procedure Resolution_Failed;
1677       --  Called when attempt at resolving current expression fails
1678
1679       ------------------------------------
1680       -- Comes_From_Predefined_Lib_Unit --
1681       -------------------------------------
1682
1683       function Comes_From_Predefined_Lib_Unit (Nod : Node_Id) return Boolean is
1684       begin
1685          return
1686            Sloc (Nod) = Standard_Location
1687              or else Is_Predefined_File_Name (Unit_File_Name (
1688                        Get_Source_Unit (Sloc (Nod))));
1689       end Comes_From_Predefined_Lib_Unit;
1690
1691       --------------------
1692       -- Patch_Up_Value --
1693       --------------------
1694
1695       procedure Patch_Up_Value (N : Node_Id; Typ : Entity_Id) is
1696       begin
1697          if Nkind (N) = N_Integer_Literal
1698            and then Is_Real_Type (Typ)
1699          then
1700             Rewrite (N,
1701               Make_Real_Literal (Sloc (N),
1702                 Realval => UR_From_Uint (Intval (N))));
1703             Set_Etype (N, Universal_Real);
1704             Set_Is_Static_Expression (N);
1705
1706          elsif Nkind (N) = N_Real_Literal
1707            and then Is_Integer_Type (Typ)
1708          then
1709             Rewrite (N,
1710               Make_Integer_Literal (Sloc (N),
1711                 Intval => UR_To_Uint (Realval (N))));
1712             Set_Etype (N, Universal_Integer);
1713             Set_Is_Static_Expression (N);
1714
1715          elsif Nkind (N) = N_String_Literal
1716            and then Is_Character_Type (Typ)
1717          then
1718             Set_Character_Literal_Name (Char_Code (Character'Pos ('A')));
1719             Rewrite (N,
1720               Make_Character_Literal (Sloc (N),
1721                 Chars => Name_Find,
1722                 Char_Literal_Value =>
1723                   UI_From_Int (Character'Pos ('A'))));
1724             Set_Etype (N, Any_Character);
1725             Set_Is_Static_Expression (N);
1726
1727          elsif Nkind (N) /= N_String_Literal
1728            and then Is_String_Type (Typ)
1729          then
1730             Rewrite (N,
1731               Make_String_Literal (Sloc (N),
1732                 Strval => End_String));
1733
1734          elsif Nkind (N) = N_Range then
1735             Patch_Up_Value (Low_Bound (N), Typ);
1736             Patch_Up_Value (High_Bound (N), Typ);
1737          end if;
1738       end Patch_Up_Value;
1739
1740       -------------------------------
1741       -- Report_Ambiguous_Argument --
1742       -------------------------------
1743
1744       procedure Report_Ambiguous_Argument is
1745          Arg : constant Node_Id := First (Parameter_Associations (N));
1746          I   : Interp_Index;
1747          It  : Interp;
1748
1749       begin
1750          if Nkind (Arg) = N_Function_Call
1751            and then Is_Entity_Name (Name (Arg))
1752            and then Is_Overloaded (Name (Arg))
1753          then
1754             Error_Msg_NE ("ambiguous call to&", Arg, Name (Arg));
1755
1756             --  Could use comments on what is going on here ???
1757
1758             Get_First_Interp (Name (Arg), I, It);
1759             while Present (It.Nam) loop
1760                Error_Msg_Sloc := Sloc (It.Nam);
1761
1762                if Nkind (Parent (It.Nam)) = N_Full_Type_Declaration then
1763                   Error_Msg_N ("interpretation (inherited) #!", Arg);
1764                else
1765                   Error_Msg_N ("interpretation #!", Arg);
1766                end if;
1767
1768                Get_Next_Interp (I, It);
1769             end loop;
1770          end if;
1771       end Report_Ambiguous_Argument;
1772
1773       -----------------------
1774       -- Resolution_Failed --
1775       -----------------------
1776
1777       procedure Resolution_Failed is
1778       begin
1779          Patch_Up_Value (N, Typ);
1780          Set_Etype (N, Typ);
1781          Debug_A_Exit ("resolving  ", N, " (done, resolution failed)");
1782          Set_Is_Overloaded (N, False);
1783
1784          --  The caller will return without calling the expander, so we need
1785          --  to set the analyzed flag. Note that it is fine to set Analyzed
1786          --  to True even if we are in the middle of a shallow analysis,
1787          --  (see the spec of sem for more details) since this is an error
1788          --  situation anyway, and there is no point in repeating the
1789          --  analysis later (indeed it won't work to repeat it later, since
1790          --  we haven't got a clear resolution of which entity is being
1791          --  referenced.)
1792
1793          Set_Analyzed (N, True);
1794          return;
1795       end Resolution_Failed;
1796
1797    --  Start of processing for Resolve
1798
1799    begin
1800       if N = Error then
1801          return;
1802       end if;
1803
1804       --  Access attribute on remote subprogram cannot be used for
1805       --  a non-remote access-to-subprogram type.
1806
1807       if Nkind (N) = N_Attribute_Reference
1808         and then (Attribute_Name (N) = Name_Access
1809                     or else Attribute_Name (N) = Name_Unrestricted_Access
1810                     or else Attribute_Name (N) = Name_Unchecked_Access)
1811         and then Comes_From_Source (N)
1812         and then Is_Entity_Name (Prefix (N))
1813         and then Is_Subprogram (Entity (Prefix (N)))
1814         and then Is_Remote_Call_Interface (Entity (Prefix (N)))
1815         and then not Is_Remote_Access_To_Subprogram_Type (Typ)
1816       then
1817          Error_Msg_N
1818            ("prefix must statically denote a non-remote subprogram", N);
1819       end if;
1820
1821       From_Lib := Comes_From_Predefined_Lib_Unit (N);
1822
1823       --  If the context is a Remote_Access_To_Subprogram, access attributes
1824       --  must be resolved with the corresponding fat pointer. There is no need
1825       --  to check for the attribute name since the return type of an
1826       --  attribute is never a remote type.
1827
1828       if Nkind (N) = N_Attribute_Reference
1829         and then Comes_From_Source (N)
1830         and then (Is_Remote_Call_Interface (Typ)
1831                     or else Is_Remote_Types (Typ))
1832       then
1833          declare
1834             Attr      : constant Attribute_Id :=
1835                           Get_Attribute_Id (Attribute_Name (N));
1836             Pref      : constant Node_Id      := Prefix (N);
1837             Decl      : Node_Id;
1838             Spec      : Node_Id;
1839             Is_Remote : Boolean := True;
1840
1841          begin
1842             --  Check that Typ is a remote access-to-subprogram type
1843
1844             if Is_Remote_Access_To_Subprogram_Type (Typ) then
1845                --  Prefix (N) must statically denote a remote subprogram
1846                --  declared in a package specification.
1847
1848                if Attr = Attribute_Access then
1849                   Decl := Unit_Declaration_Node (Entity (Pref));
1850
1851                   if Nkind (Decl) = N_Subprogram_Body then
1852                      Spec := Corresponding_Spec (Decl);
1853
1854                      if not No (Spec) then
1855                         Decl := Unit_Declaration_Node (Spec);
1856                      end if;
1857                   end if;
1858
1859                   Spec := Parent (Decl);
1860
1861                   if not Is_Entity_Name (Prefix (N))
1862                     or else Nkind (Spec) /= N_Package_Specification
1863                     or else
1864                       not Is_Remote_Call_Interface (Defining_Entity (Spec))
1865                   then
1866                      Is_Remote := False;
1867                      Error_Msg_N
1868                        ("prefix must statically denote a remote subprogram ",
1869                         N);
1870                   end if;
1871                end if;
1872
1873                --   If we are generating code for a distributed program.
1874                --   perform semantic checks against the corresponding
1875                --   remote entities.
1876
1877                if (Attr = Attribute_Access
1878                     or else Attr = Attribute_Unchecked_Access
1879                     or else Attr = Attribute_Unrestricted_Access)
1880                  and then Expander_Active
1881                  and then Get_PCS_Name /= Name_No_DSA
1882                then
1883                   Check_Subtype_Conformant
1884                     (New_Id  => Entity (Prefix (N)),
1885                      Old_Id  => Designated_Type
1886                        (Corresponding_Remote_Type (Typ)),
1887                      Err_Loc => N);
1888
1889                   if Is_Remote then
1890                      Process_Remote_AST_Attribute (N, Typ);
1891                   end if;
1892                end if;
1893             end if;
1894          end;
1895       end if;
1896
1897       Debug_A_Entry ("resolving  ", N);
1898
1899       if Comes_From_Source (N) then
1900          if Is_Fixed_Point_Type (Typ) then
1901             Check_Restriction (No_Fixed_Point, N);
1902
1903          elsif Is_Floating_Point_Type (Typ)
1904            and then Typ /= Universal_Real
1905            and then Typ /= Any_Real
1906          then
1907             Check_Restriction (No_Floating_Point, N);
1908          end if;
1909       end if;
1910
1911       --  Return if already analyzed
1912
1913       if Analyzed (N) then
1914          Debug_A_Exit ("resolving  ", N, "  (done, already analyzed)");
1915          return;
1916
1917       --  Return if type = Any_Type (previous error encountered)
1918
1919       elsif Etype (N) = Any_Type then
1920          Debug_A_Exit ("resolving  ", N, "  (done, Etype = Any_Type)");
1921          return;
1922       end if;
1923
1924       Check_Parameterless_Call (N);
1925
1926       --  If not overloaded, then we know the type, and all that needs doing
1927       --  is to check that this type is compatible with the context.
1928
1929       if not Is_Overloaded (N) then
1930          Found := Covers (Typ, Etype (N));
1931          Expr_Type := Etype (N);
1932
1933       --  In the overloaded case, we must select the interpretation that
1934       --  is compatible with the context (i.e. the type passed to Resolve)
1935
1936       else
1937          --  Loop through possible interpretations
1938
1939          Get_First_Interp (N, I, It);
1940          Interp_Loop : while Present (It.Typ) loop
1941
1942             --  We are only interested in interpretations that are compatible
1943             --  with the expected type, any other interpretations are ignored.
1944
1945             if not Covers (Typ, It.Typ) then
1946                if Debug_Flag_V then
1947                   Write_Str ("    interpretation incompatible with context");
1948                   Write_Eol;
1949                end if;
1950
1951             else
1952                --  Skip the current interpretation if it is disabled by an
1953                --  abstract operator. This action is performed only when the
1954                --  type against which we are resolving is the same as the
1955                --  type of the interpretation.
1956
1957                if Ada_Version >= Ada_05
1958                  and then It.Typ = Typ
1959                  and then Typ /= Universal_Integer
1960                  and then Typ /= Universal_Real
1961                  and then Present (It.Abstract_Op)
1962                then
1963                   goto Continue;
1964                end if;
1965
1966                --  First matching interpretation
1967
1968                if not Found then
1969                   Found := True;
1970                   I1    := I;
1971                   Seen  := It.Nam;
1972                   Expr_Type := It.Typ;
1973
1974                --  Matching interpretation that is not the first, maybe an
1975                --  error, but there are some cases where preference rules are
1976                --  used to choose between the two possibilities. These and
1977                --  some more obscure cases are handled in Disambiguate.
1978
1979                else
1980                   --  If the current statement is part of a predefined library
1981                   --  unit, then all interpretations which come from user level
1982                   --  packages should not be considered.
1983
1984                   if From_Lib
1985                     and then not Comes_From_Predefined_Lib_Unit (It.Nam)
1986                   then
1987                      goto Continue;
1988                   end if;
1989
1990                   Error_Msg_Sloc := Sloc (Seen);
1991                   It1 := Disambiguate (N, I1, I, Typ);
1992
1993                   --  Disambiguation has succeeded. Skip the remaining
1994                   --  interpretations.
1995
1996                   if It1 /= No_Interp then
1997                      Seen := It1.Nam;
1998                      Expr_Type := It1.Typ;
1999
2000                      while Present (It.Typ) loop
2001                         Get_Next_Interp (I, It);
2002                      end loop;
2003
2004                   else
2005                      --  Before we issue an ambiguity complaint, check for
2006                      --  the case of a subprogram call where at least one
2007                      --  of the arguments is Any_Type, and if so, suppress
2008                      --  the message, since it is a cascaded error.
2009
2010                      if Nkind_In (N, N_Function_Call,
2011                                      N_Procedure_Call_Statement)
2012                      then
2013                         declare
2014                            A : Node_Id;
2015                            E : Node_Id;
2016
2017                         begin
2018                            A := First_Actual (N);
2019                            while Present (A) loop
2020                               E := A;
2021
2022                               if Nkind (E) = N_Parameter_Association then
2023                                  E := Explicit_Actual_Parameter (E);
2024                               end if;
2025
2026                               if Etype (E) = Any_Type then
2027                                  if Debug_Flag_V then
2028                                     Write_Str ("Any_Type in call");
2029                                     Write_Eol;
2030                                  end if;
2031
2032                                  exit Interp_Loop;
2033                               end if;
2034
2035                               Next_Actual (A);
2036                            end loop;
2037                         end;
2038
2039                      elsif Nkind (N) in N_Binary_Op
2040                        and then (Etype (Left_Opnd (N)) = Any_Type
2041                                   or else Etype (Right_Opnd (N)) = Any_Type)
2042                      then
2043                         exit Interp_Loop;
2044
2045                      elsif Nkind (N) in  N_Unary_Op
2046                        and then Etype (Right_Opnd (N)) = Any_Type
2047                      then
2048                         exit Interp_Loop;
2049                      end if;
2050
2051                      --  Not that special case, so issue message using the
2052                      --  flag Ambiguous to control printing of the header
2053                      --  message only at the start of an ambiguous set.
2054
2055                      if not Ambiguous then
2056                         if Nkind (N) = N_Function_Call
2057                           and then Nkind (Name (N)) = N_Explicit_Dereference
2058                         then
2059                            Error_Msg_N
2060                              ("ambiguous expression "
2061                                & "(cannot resolve indirect call)!", N);
2062                         else
2063                            Error_Msg_NE -- CODEFIX
2064                              ("ambiguous expression (cannot resolve&)!",
2065                               N, It.Nam);
2066                         end if;
2067
2068                         Ambiguous := True;
2069
2070                         if Nkind (Parent (Seen)) = N_Full_Type_Declaration then
2071                            Error_Msg_N
2072                              ("\\possible interpretation (inherited)#!", N);
2073                         else
2074                            Error_Msg_N -- CODEFIX
2075                              ("\\possible interpretation#!", N);
2076                         end if;
2077
2078                         if Nkind_In
2079                           (N, N_Procedure_Call_Statement, N_Function_Call)
2080                           and then Present (Parameter_Associations (N))
2081                         then
2082                            Report_Ambiguous_Argument;
2083                         end if;
2084                      end if;
2085
2086                      Error_Msg_Sloc := Sloc (It.Nam);
2087
2088                      --  By default, the error message refers to the candidate
2089                      --  interpretation. But if it is a predefined operator, it
2090                      --  is implicitly declared at the declaration of the type
2091                      --  of the operand. Recover the sloc of that declaration
2092                      --  for the error message.
2093
2094                      if Nkind (N) in N_Op
2095                        and then Scope (It.Nam) = Standard_Standard
2096                        and then not Is_Overloaded (Right_Opnd (N))
2097                        and then Scope (Base_Type (Etype (Right_Opnd (N)))) /=
2098                                                              Standard_Standard
2099                      then
2100                         Err_Type := First_Subtype (Etype (Right_Opnd (N)));
2101
2102                         if Comes_From_Source (Err_Type)
2103                           and then Present (Parent (Err_Type))
2104                         then
2105                            Error_Msg_Sloc := Sloc (Parent (Err_Type));
2106                         end if;
2107
2108                      elsif Nkind (N) in N_Binary_Op
2109                        and then Scope (It.Nam) = Standard_Standard
2110                        and then not Is_Overloaded (Left_Opnd (N))
2111                        and then Scope (Base_Type (Etype (Left_Opnd (N)))) /=
2112                                                              Standard_Standard
2113                      then
2114                         Err_Type := First_Subtype (Etype (Left_Opnd (N)));
2115
2116                         if Comes_From_Source (Err_Type)
2117                           and then Present (Parent (Err_Type))
2118                         then
2119                            Error_Msg_Sloc := Sloc (Parent (Err_Type));
2120                         end if;
2121
2122                      --  If this is an indirect call, use the subprogram_type
2123                      --  in the message, to have a meaningful location.
2124                      --  Indicate as well if this is an inherited operation,
2125                      --  created by a type declaration.
2126
2127                      elsif Nkind (N) = N_Function_Call
2128                        and then Nkind (Name (N)) = N_Explicit_Dereference
2129                        and then Is_Type (It.Nam)
2130                      then
2131                         Err_Type := It.Nam;
2132                         Error_Msg_Sloc :=
2133                           Sloc (Associated_Node_For_Itype (Err_Type));
2134                      else
2135                         Err_Type := Empty;
2136                      end if;
2137
2138                      if Nkind (N) in N_Op
2139                        and then Scope (It.Nam) = Standard_Standard
2140                        and then Present (Err_Type)
2141                      then
2142                         --  Special-case the message for universal_fixed
2143                         --  operators, which are not declared with the type
2144                         --  of the operand, but appear forever in Standard.
2145
2146                         if  It.Typ = Universal_Fixed
2147                           and then Scope (It.Nam) = Standard_Standard
2148                         then
2149                            Error_Msg_N
2150                              ("\\possible interpretation as " &
2151                                 "universal_fixed operation " &
2152                                   "(RM 4.5.5 (19))", N);
2153                         else
2154                            Error_Msg_N
2155                              ("\\possible interpretation (predefined)#!", N);
2156                         end if;
2157
2158                      elsif
2159                        Nkind (Parent (It.Nam)) = N_Full_Type_Declaration
2160                      then
2161                         Error_Msg_N
2162                           ("\\possible interpretation (inherited)#!", N);
2163                      else
2164                         Error_Msg_N -- CODEFIX
2165                           ("\\possible interpretation#!", N);
2166                      end if;
2167
2168                   end if;
2169                end if;
2170
2171                --  We have a matching interpretation, Expr_Type is the type
2172                --  from this interpretation, and Seen is the entity.
2173
2174                --  For an operator, just set the entity name. The type will be
2175                --  set by the specific operator resolution routine.
2176
2177                if Nkind (N) in N_Op then
2178                   Set_Entity (N, Seen);
2179                   Generate_Reference (Seen, N);
2180
2181                elsif Nkind (N) = N_Character_Literal then
2182                   Set_Etype (N, Expr_Type);
2183
2184                elsif Nkind (N) = N_Conditional_Expression then
2185                   Set_Etype (N, Expr_Type);
2186
2187                --  For an explicit dereference, attribute reference, range,
2188                --  short-circuit form (which is not an operator node), or call
2189                --  with a name that is an explicit dereference, there is
2190                --  nothing to be done at this point.
2191
2192                elsif Nkind_In (N, N_Explicit_Dereference,
2193                                   N_Attribute_Reference,
2194                                   N_And_Then,
2195                                   N_Indexed_Component,
2196                                   N_Or_Else,
2197                                   N_Range,
2198                                   N_Selected_Component,
2199                                   N_Slice)
2200                  or else Nkind (Name (N)) = N_Explicit_Dereference
2201                then
2202                   null;
2203
2204                --  For procedure or function calls, set the type of the name,
2205                --  and also the entity pointer for the prefix
2206
2207                elsif Nkind_In (N, N_Procedure_Call_Statement, N_Function_Call)
2208                  and then (Is_Entity_Name (Name (N))
2209                             or else Nkind (Name (N)) = N_Operator_Symbol)
2210                then
2211                   Set_Etype  (Name (N), Expr_Type);
2212                   Set_Entity (Name (N), Seen);
2213                   Generate_Reference (Seen, Name (N));
2214
2215                elsif Nkind (N) = N_Function_Call
2216                  and then Nkind (Name (N)) = N_Selected_Component
2217                then
2218                   Set_Etype (Name (N), Expr_Type);
2219                   Set_Entity (Selector_Name (Name (N)), Seen);
2220                   Generate_Reference (Seen, Selector_Name (Name (N)));
2221
2222                --  For all other cases, just set the type of the Name
2223
2224                else
2225                   Set_Etype (Name (N), Expr_Type);
2226                end if;
2227
2228             end if;
2229
2230             <<Continue>>
2231
2232             --  Move to next interpretation
2233
2234             exit Interp_Loop when No (It.Typ);
2235
2236             Get_Next_Interp (I, It);
2237          end loop Interp_Loop;
2238       end if;
2239
2240       --  At this stage Found indicates whether or not an acceptable
2241       --  interpretation exists. If not, then we have an error, except
2242       --  that if the context is Any_Type as a result of some other error,
2243       --  then we suppress the error report.
2244
2245       if not Found then
2246          if Typ /= Any_Type then
2247
2248             --  If type we are looking for is Void, then this is the procedure
2249             --  call case, and the error is simply that what we gave is not a
2250             --  procedure name (we think of procedure calls as expressions with
2251             --  types internally, but the user doesn't think of them this way!)
2252
2253             if Typ = Standard_Void_Type then
2254
2255                --  Special case message if function used as a procedure
2256
2257                if Nkind (N) = N_Procedure_Call_Statement
2258                  and then Is_Entity_Name (Name (N))
2259                  and then Ekind (Entity (Name (N))) = E_Function
2260                then
2261                   Error_Msg_NE
2262                     ("cannot use function & in a procedure call",
2263                      Name (N), Entity (Name (N)));
2264
2265                --  Otherwise give general message (not clear what cases this
2266                --  covers, but no harm in providing for them!)
2267
2268                else
2269                   Error_Msg_N ("expect procedure name in procedure call", N);
2270                end if;
2271
2272                Found := True;
2273
2274             --  Otherwise we do have a subexpression with the wrong type
2275
2276             --  Check for the case of an allocator which uses an access type
2277             --  instead of the designated type. This is a common error and we
2278             --  specialize the message, posting an error on the operand of the
2279             --  allocator, complaining that we expected the designated type of
2280             --  the allocator.
2281
2282             elsif Nkind (N) = N_Allocator
2283               and then Ekind (Typ) in Access_Kind
2284               and then Ekind (Etype (N)) in Access_Kind
2285               and then Designated_Type (Etype (N)) = Typ
2286             then
2287                Wrong_Type (Expression (N), Designated_Type (Typ));
2288                Found := True;
2289
2290             --  Check for view mismatch on Null in instances, for which the
2291             --  view-swapping mechanism has no identifier.
2292
2293             elsif (In_Instance or else In_Inlined_Body)
2294               and then (Nkind (N) = N_Null)
2295               and then Is_Private_Type (Typ)
2296               and then Is_Access_Type (Full_View (Typ))
2297             then
2298                Resolve (N, Full_View (Typ));
2299                Set_Etype (N, Typ);
2300                return;
2301
2302             --  Check for an aggregate. Sometimes we can get bogus aggregates
2303             --  from misuse of parentheses, and we are about to complain about
2304             --  the aggregate without even looking inside it.
2305
2306             --  Instead, if we have an aggregate of type Any_Composite, then
2307             --  analyze and resolve the component fields, and then only issue
2308             --  another message if we get no errors doing this (otherwise
2309             --  assume that the errors in the aggregate caused the problem).
2310
2311             elsif Nkind (N) = N_Aggregate
2312               and then Etype (N) = Any_Composite
2313             then
2314                --  Disable expansion in any case. If there is a type mismatch
2315                --  it may be fatal to try to expand the aggregate. The flag
2316                --  would otherwise be set to false when the error is posted.
2317
2318                Expander_Active := False;
2319
2320                declare
2321                   procedure Check_Aggr (Aggr : Node_Id);
2322                   --  Check one aggregate, and set Found to True if we have a
2323                   --  definite error in any of its elements
2324
2325                   procedure Check_Elmt (Aelmt : Node_Id);
2326                   --  Check one element of aggregate and set Found to True if
2327                   --  we definitely have an error in the element.
2328
2329                   ----------------
2330                   -- Check_Aggr --
2331                   ----------------
2332
2333                   procedure Check_Aggr (Aggr : Node_Id) is
2334                      Elmt : Node_Id;
2335
2336                   begin
2337                      if Present (Expressions (Aggr)) then
2338                         Elmt := First (Expressions (Aggr));
2339                         while Present (Elmt) loop
2340                            Check_Elmt (Elmt);
2341                            Next (Elmt);
2342                         end loop;
2343                      end if;
2344
2345                      if Present (Component_Associations (Aggr)) then
2346                         Elmt := First (Component_Associations (Aggr));
2347                         while Present (Elmt) loop
2348
2349                            --  If this is a default-initialized component, then
2350                            --  there is nothing to check. The box will be
2351                            --  replaced by the appropriate call during late
2352                            --  expansion.
2353
2354                            if not Box_Present (Elmt) then
2355                               Check_Elmt (Expression (Elmt));
2356                            end if;
2357
2358                            Next (Elmt);
2359                         end loop;
2360                      end if;
2361                   end Check_Aggr;
2362
2363                   ----------------
2364                   -- Check_Elmt --
2365                   ----------------
2366
2367                   procedure Check_Elmt (Aelmt : Node_Id) is
2368                   begin
2369                      --  If we have a nested aggregate, go inside it (to
2370                      --  attempt a naked analyze-resolve of the aggregate
2371                      --  can cause undesirable cascaded errors). Do not
2372                      --  resolve expression if it needs a type from context,
2373                      --  as for integer * fixed expression.
2374
2375                      if Nkind (Aelmt) = N_Aggregate then
2376                         Check_Aggr (Aelmt);
2377
2378                      else
2379                         Analyze (Aelmt);
2380
2381                         if not Is_Overloaded (Aelmt)
2382                           and then Etype (Aelmt) /= Any_Fixed
2383                         then
2384                            Resolve (Aelmt);
2385                         end if;
2386
2387                         if Etype (Aelmt) = Any_Type then
2388                            Found := True;
2389                         end if;
2390                      end if;
2391                   end Check_Elmt;
2392
2393                begin
2394                   Check_Aggr (N);
2395                end;
2396             end if;
2397
2398             --  If an error message was issued already, Found got reset
2399             --  to True, so if it is still False, issue the standard
2400             --  Wrong_Type message.
2401
2402             if not Found then
2403                if Is_Overloaded (N)
2404                  and then Nkind (N) = N_Function_Call
2405                then
2406                   declare
2407                      Subp_Name : Node_Id;
2408                   begin
2409                      if Is_Entity_Name (Name (N)) then
2410                         Subp_Name := Name (N);
2411
2412                      elsif Nkind (Name (N)) = N_Selected_Component then
2413
2414                         --  Protected operation: retrieve operation name
2415
2416                         Subp_Name := Selector_Name (Name (N));
2417                      else
2418                         raise Program_Error;
2419                      end if;
2420
2421                      Error_Msg_Node_2 := Typ;
2422                      Error_Msg_NE ("no visible interpretation of&" &
2423                        " matches expected type&", N, Subp_Name);
2424                   end;
2425
2426                   if All_Errors_Mode then
2427                      declare
2428                         Index : Interp_Index;
2429                         It    : Interp;
2430
2431                      begin
2432                         Error_Msg_N ("\\possible interpretations:", N);
2433
2434                         Get_First_Interp (Name (N), Index, It);
2435                         while Present (It.Nam) loop
2436                            Error_Msg_Sloc := Sloc (It.Nam);
2437                            Error_Msg_Node_2 := It.Nam;
2438                            Error_Msg_NE
2439                              ("\\  type& for & declared#", N, It.Typ);
2440                            Get_Next_Interp (Index, It);
2441                         end loop;
2442                      end;
2443
2444                   else
2445                      Error_Msg_N ("\use -gnatf for details", N);
2446                   end if;
2447                else
2448                   Wrong_Type (N, Typ);
2449                end if;
2450             end if;
2451          end if;
2452
2453          Resolution_Failed;
2454          return;
2455
2456       --  Test if we have more than one interpretation for the context
2457
2458       elsif Ambiguous then
2459          Resolution_Failed;
2460          return;
2461
2462       --  Here we have an acceptable interpretation for the context
2463
2464       else
2465          --  Propagate type information and normalize tree for various
2466          --  predefined operations. If the context only imposes a class of
2467          --  types, rather than a specific type, propagate the actual type
2468          --  downward.
2469
2470          if Typ = Any_Integer
2471            or else Typ = Any_Boolean
2472            or else Typ = Any_Modular
2473            or else Typ = Any_Real
2474            or else Typ = Any_Discrete
2475          then
2476             Ctx_Type := Expr_Type;
2477
2478             --  Any_Fixed is legal in a real context only if a specific
2479             --  fixed point type is imposed. If Norman Cohen can be
2480             --  confused by this, it deserves a separate message.
2481
2482             if Typ = Any_Real
2483               and then Expr_Type = Any_Fixed
2484             then
2485                Error_Msg_N ("illegal context for mixed mode operation", N);
2486                Set_Etype (N, Universal_Real);
2487                Ctx_Type := Universal_Real;
2488             end if;
2489          end if;
2490
2491          --  A user-defined operator is transformed into a function call at
2492          --  this point, so that further processing knows that operators are
2493          --  really operators (i.e. are predefined operators). User-defined
2494          --  operators that are intrinsic are just renamings of the predefined
2495          --  ones, and need not be turned into calls either, but if they rename
2496          --  a different operator, we must transform the node accordingly.
2497          --  Instantiations of Unchecked_Conversion are intrinsic but are
2498          --  treated as functions, even if given an operator designator.
2499
2500          if Nkind (N) in N_Op
2501            and then Present (Entity (N))
2502            and then Ekind (Entity (N)) /= E_Operator
2503          then
2504
2505             if not Is_Predefined_Op (Entity (N)) then
2506                Rewrite_Operator_As_Call (N, Entity (N));
2507
2508             elsif Present (Alias (Entity (N)))
2509               and then
2510                 Nkind (Parent (Parent (Entity (N)))) =
2511                                     N_Subprogram_Renaming_Declaration
2512             then
2513                Rewrite_Renamed_Operator (N, Alias (Entity (N)), Typ);
2514
2515                --  If the node is rewritten, it will be fully resolved in
2516                --  Rewrite_Renamed_Operator.
2517
2518                if Analyzed (N) then
2519                   return;
2520                end if;
2521             end if;
2522          end if;
2523
2524          case N_Subexpr'(Nkind (N)) is
2525
2526             when N_Aggregate => Resolve_Aggregate                (N, Ctx_Type);
2527
2528             when N_Allocator => Resolve_Allocator                (N, Ctx_Type);
2529
2530             when N_Short_Circuit
2531                              => Resolve_Short_Circuit            (N, Ctx_Type);
2532
2533             when N_Attribute_Reference
2534                              => Resolve_Attribute                (N, Ctx_Type);
2535
2536             when N_Character_Literal
2537                              => Resolve_Character_Literal        (N, Ctx_Type);
2538
2539             when N_Conditional_Expression
2540                              => Resolve_Conditional_Expression   (N, Ctx_Type);
2541
2542             when N_Expanded_Name
2543                              => Resolve_Entity_Name              (N, Ctx_Type);
2544
2545             when N_Extension_Aggregate
2546                              => Resolve_Extension_Aggregate      (N, Ctx_Type);
2547
2548             when N_Explicit_Dereference
2549                              => Resolve_Explicit_Dereference     (N, Ctx_Type);
2550
2551             when N_Function_Call
2552                              => Resolve_Call                     (N, Ctx_Type);
2553
2554             when N_Identifier
2555                              => Resolve_Entity_Name              (N, Ctx_Type);
2556
2557             when N_Indexed_Component
2558                              => Resolve_Indexed_Component        (N, Ctx_Type);
2559
2560             when N_Integer_Literal
2561                              => Resolve_Integer_Literal          (N, Ctx_Type);
2562
2563             when N_Membership_Test
2564                              => Resolve_Membership_Op            (N, Ctx_Type);
2565
2566             when N_Null      => Resolve_Null                     (N, Ctx_Type);
2567
2568             when N_Op_And | N_Op_Or | N_Op_Xor
2569                              => Resolve_Logical_Op               (N, Ctx_Type);
2570
2571             when N_Op_Eq | N_Op_Ne
2572                              => Resolve_Equality_Op              (N, Ctx_Type);
2573
2574             when N_Op_Lt | N_Op_Le | N_Op_Gt | N_Op_Ge
2575                              => Resolve_Comparison_Op            (N, Ctx_Type);
2576
2577             when N_Op_Not    => Resolve_Op_Not                   (N, Ctx_Type);
2578
2579             when N_Op_Add    | N_Op_Subtract | N_Op_Multiply |
2580                  N_Op_Divide | N_Op_Mod      | N_Op_Rem
2581
2582                              => Resolve_Arithmetic_Op            (N, Ctx_Type);
2583
2584             when N_Op_Concat => Resolve_Op_Concat                (N, Ctx_Type);
2585
2586             when N_Op_Expon  => Resolve_Op_Expon                 (N, Ctx_Type);
2587
2588             when N_Op_Plus | N_Op_Minus  | N_Op_Abs
2589                              => Resolve_Unary_Op                 (N, Ctx_Type);
2590
2591             when N_Op_Shift  => Resolve_Shift                    (N, Ctx_Type);
2592
2593             when N_Procedure_Call_Statement
2594                              => Resolve_Call                     (N, Ctx_Type);
2595
2596             when N_Operator_Symbol
2597                              => Resolve_Operator_Symbol          (N, Ctx_Type);
2598
2599             when N_Qualified_Expression
2600                              => Resolve_Qualified_Expression     (N, Ctx_Type);
2601
2602             when N_Raise_xxx_Error
2603                              => Set_Etype (N, Ctx_Type);
2604
2605             when N_Range     => Resolve_Range                    (N, Ctx_Type);
2606
2607             when N_Real_Literal
2608                              => Resolve_Real_Literal             (N, Ctx_Type);
2609
2610             when N_Reference => Resolve_Reference                (N, Ctx_Type);
2611
2612             when N_Selected_Component
2613                              => Resolve_Selected_Component       (N, Ctx_Type);
2614
2615             when N_Slice     => Resolve_Slice                    (N, Ctx_Type);
2616
2617             when N_String_Literal
2618                              => Resolve_String_Literal           (N, Ctx_Type);
2619
2620             when N_Subprogram_Info
2621                              => Resolve_Subprogram_Info          (N, Ctx_Type);
2622
2623             when N_Type_Conversion
2624                              => Resolve_Type_Conversion          (N, Ctx_Type);
2625
2626             when N_Unchecked_Expression =>
2627                Resolve_Unchecked_Expression                      (N, Ctx_Type);
2628
2629             when N_Unchecked_Type_Conversion =>
2630                Resolve_Unchecked_Type_Conversion                 (N, Ctx_Type);
2631
2632          end case;
2633
2634          --  If the subexpression was replaced by a non-subexpression, then
2635          --  all we do is to expand it. The only legitimate case we know of
2636          --  is converting procedure call statement to entry call statements,
2637          --  but there may be others, so we are making this test general.
2638
2639          if Nkind (N) not in N_Subexpr then
2640             Debug_A_Exit ("resolving  ", N, "  (done)");
2641             Expand (N);
2642             return;
2643          end if;
2644
2645          --  The expression is definitely NOT overloaded at this point, so
2646          --  we reset the Is_Overloaded flag to avoid any confusion when
2647          --  reanalyzing the node.
2648
2649          Set_Is_Overloaded (N, False);
2650
2651          --  Freeze expression type, entity if it is a name, and designated
2652          --  type if it is an allocator (RM 13.14(10,11,13)).
2653
2654          --  Now that the resolution of the type of the node is complete,
2655          --  and we did not detect an error, we can expand this node. We
2656          --  skip the expand call if we are in a default expression, see
2657          --  section "Handling of Default Expressions" in Sem spec.
2658
2659          Debug_A_Exit ("resolving  ", N, "  (done)");
2660
2661          --  We unconditionally freeze the expression, even if we are in
2662          --  default expression mode (the Freeze_Expression routine tests
2663          --  this flag and only freezes static types if it is set).
2664
2665          Freeze_Expression (N);
2666
2667          --  Now we can do the expansion
2668
2669          Expand (N);
2670       end if;
2671    end Resolve;
2672
2673    -------------
2674    -- Resolve --
2675    -------------
2676
2677    --  Version with check(s) suppressed
2678
2679    procedure Resolve (N : Node_Id; Typ : Entity_Id; Suppress : Check_Id) is
2680    begin
2681       if Suppress = All_Checks then
2682          declare
2683             Svg : constant Suppress_Array := Scope_Suppress;
2684          begin
2685             Scope_Suppress := (others => True);
2686             Resolve (N, Typ);
2687             Scope_Suppress := Svg;
2688          end;
2689
2690       else
2691          declare
2692             Svg : constant Boolean := Scope_Suppress (Suppress);
2693          begin
2694             Scope_Suppress (Suppress) := True;
2695             Resolve (N, Typ);
2696             Scope_Suppress (Suppress) := Svg;
2697          end;
2698       end if;
2699    end Resolve;
2700
2701    -------------
2702    -- Resolve --
2703    -------------
2704
2705    --  Version with implicit type
2706
2707    procedure Resolve (N : Node_Id) is
2708    begin
2709       Resolve (N, Etype (N));
2710    end Resolve;
2711
2712    ---------------------
2713    -- Resolve_Actuals --
2714    ---------------------
2715
2716    procedure Resolve_Actuals (N : Node_Id; Nam : Entity_Id) is
2717       Loc    : constant Source_Ptr := Sloc (N);
2718       A      : Node_Id;
2719       F      : Entity_Id;
2720       A_Typ  : Entity_Id;
2721       F_Typ  : Entity_Id;
2722       Prev   : Node_Id := Empty;
2723       Orig_A : Node_Id;
2724
2725       procedure Check_Argument_Order;
2726       --  Performs a check for the case where the actuals are all simple
2727       --  identifiers that correspond to the formal names, but in the wrong
2728       --  order, which is considered suspicious and cause for a warning.
2729
2730       procedure Check_Prefixed_Call;
2731       --  If the original node is an overloaded call in prefix notation,
2732       --  insert an 'Access or a dereference as needed over the first actual.
2733       --  Try_Object_Operation has already verified that there is a valid
2734       --  interpretation, but the form of the actual can only be determined
2735       --  once the primitive operation is identified.
2736
2737       procedure Insert_Default;
2738       --  If the actual is missing in a call, insert in the actuals list
2739       --  an instance of the default expression. The insertion is always
2740       --  a named association.
2741
2742       function Same_Ancestor (T1, T2 : Entity_Id) return Boolean;
2743       --  Check whether T1 and T2, or their full views, are derived from a
2744       --  common type. Used to enforce the restrictions on array conversions
2745       --  of AI95-00246.
2746
2747       function Static_Concatenation (N : Node_Id) return Boolean;
2748       --  Predicate to determine whether an actual that is a concatenation
2749       --  will be evaluated statically and does not need a transient scope.
2750       --  This must be determined before the actual is resolved and expanded
2751       --  because if needed the transient scope must be introduced earlier.
2752
2753       --------------------------
2754       -- Check_Argument_Order --
2755       --------------------------
2756
2757       procedure Check_Argument_Order is
2758       begin
2759          --  Nothing to do if no parameters, or original node is neither a
2760          --  function call nor a procedure call statement (happens in the
2761          --  operator-transformed-to-function call case), or the call does
2762          --  not come from source, or this warning is off.
2763
2764          if not Warn_On_Parameter_Order
2765            or else
2766              No (Parameter_Associations (N))
2767            or else
2768              not Nkind_In (Original_Node (N), N_Procedure_Call_Statement,
2769                                               N_Function_Call)
2770            or else
2771              not Comes_From_Source (N)
2772          then
2773             return;
2774          end if;
2775
2776          declare
2777             Nargs : constant Nat := List_Length (Parameter_Associations (N));
2778
2779          begin
2780             --  Nothing to do if only one parameter
2781
2782             if Nargs < 2 then
2783                return;
2784             end if;
2785
2786             --  Here if at least two arguments
2787
2788             declare
2789                Actuals : array (1 .. Nargs) of Node_Id;
2790                Actual  : Node_Id;
2791                Formal  : Node_Id;
2792
2793                Wrong_Order : Boolean := False;
2794                --  Set True if an out of order case is found
2795
2796             begin
2797                --  Collect identifier names of actuals, fail if any actual is
2798                --  not a simple identifier, and record max length of name.
2799
2800                Actual := First (Parameter_Associations (N));
2801                for J in Actuals'Range loop
2802                   if Nkind (Actual) /= N_Identifier then
2803                      return;
2804                   else
2805                      Actuals (J) := Actual;
2806                      Next (Actual);
2807                   end if;
2808                end loop;
2809
2810                --  If we got this far, all actuals are identifiers and the list
2811                --  of their names is stored in the Actuals array.
2812
2813                Formal := First_Formal (Nam);
2814                for J in Actuals'Range loop
2815
2816                   --  If we ran out of formals, that's odd, probably an error
2817                   --  which will be detected elsewhere, but abandon the search.
2818
2819                   if No (Formal) then
2820                      return;
2821                   end if;
2822
2823                   --  If name matches and is in order OK
2824
2825                   if Chars (Formal) = Chars (Actuals (J)) then
2826                      null;
2827
2828                   else
2829                      --  If no match, see if it is elsewhere in list and if so
2830                      --  flag potential wrong order if type is compatible.
2831
2832                      for K in Actuals'Range loop
2833                         if Chars (Formal) = Chars (Actuals (K))
2834                           and then
2835                             Has_Compatible_Type (Actuals (K), Etype (Formal))
2836                         then
2837                            Wrong_Order := True;
2838                            goto Continue;
2839                         end if;
2840                      end loop;
2841
2842                      --  No match
2843
2844                      return;
2845                   end if;
2846
2847                   <<Continue>> Next_Formal (Formal);
2848                end loop;
2849
2850                --  If Formals left over, also probably an error, skip warning
2851
2852                if Present (Formal) then
2853                   return;
2854                end if;
2855
2856                --  Here we give the warning if something was out of order
2857
2858                if Wrong_Order then
2859                   Error_Msg_N
2860                     ("actuals for this call may be in wrong order?", N);
2861                end if;
2862             end;
2863          end;
2864       end Check_Argument_Order;
2865
2866       -------------------------
2867       -- Check_Prefixed_Call --
2868       -------------------------
2869
2870       procedure Check_Prefixed_Call is
2871          Act    : constant Node_Id   := First_Actual (N);
2872          A_Type : constant Entity_Id := Etype (Act);
2873          F_Type : constant Entity_Id := Etype (First_Formal (Nam));
2874          Orig   : constant Node_Id := Original_Node (N);
2875          New_A  : Node_Id;
2876
2877       begin
2878          --  Check whether the call is a prefixed call, with or without
2879          --  additional actuals.
2880
2881          if Nkind (Orig) = N_Selected_Component
2882            or else
2883              (Nkind (Orig) = N_Indexed_Component
2884                and then Nkind (Prefix (Orig)) = N_Selected_Component
2885                and then Is_Entity_Name (Prefix (Prefix (Orig)))
2886                and then Is_Entity_Name (Act)
2887                and then Chars (Act) = Chars (Prefix (Prefix (Orig))))
2888          then
2889             if Is_Access_Type (A_Type)
2890               and then not Is_Access_Type (F_Type)
2891             then
2892                --  Introduce dereference on object in prefix
2893
2894                New_A :=
2895                  Make_Explicit_Dereference (Sloc (Act),
2896                    Prefix => Relocate_Node (Act));
2897                Rewrite (Act, New_A);
2898                Analyze (Act);
2899
2900             elsif Is_Access_Type (F_Type)
2901               and then not Is_Access_Type (A_Type)
2902             then
2903                --  Introduce an implicit 'Access in prefix
2904
2905                if not Is_Aliased_View (Act) then
2906                   Error_Msg_NE
2907                     ("object in prefixed call to& must be aliased"
2908                          & " (RM-2005 4.3.1 (13))",
2909                     Prefix (Act), Nam);
2910                end if;
2911
2912                Rewrite (Act,
2913                  Make_Attribute_Reference (Loc,
2914                    Attribute_Name => Name_Access,
2915                    Prefix         => Relocate_Node (Act)));
2916             end if;
2917
2918             Analyze (Act);
2919          end if;
2920       end Check_Prefixed_Call;
2921
2922       --------------------
2923       -- Insert_Default --
2924       --------------------
2925
2926       procedure Insert_Default is
2927          Actval : Node_Id;
2928          Assoc  : Node_Id;
2929
2930       begin
2931          --  Missing argument in call, nothing to insert
2932
2933          if No (Default_Value (F)) then
2934             return;
2935
2936          else
2937             --  Note that we do a full New_Copy_Tree, so that any associated
2938             --  Itypes are properly copied. This may not be needed any more,
2939             --  but it does no harm as a safety measure! Defaults of a generic
2940             --  formal may be out of bounds of the corresponding actual (see
2941             --  cc1311b) and an additional check may be required.
2942
2943             Actval :=
2944               New_Copy_Tree
2945                 (Default_Value (F),
2946                  New_Scope => Current_Scope,
2947                  New_Sloc  => Loc);
2948
2949             if Is_Concurrent_Type (Scope (Nam))
2950               and then Has_Discriminants (Scope (Nam))
2951             then
2952                Replace_Actual_Discriminants (N, Actval);
2953             end if;
2954
2955             if Is_Overloadable (Nam)
2956               and then Present (Alias (Nam))
2957             then
2958                if Base_Type (Etype (F)) /= Base_Type (Etype (Actval))
2959                  and then not Is_Tagged_Type (Etype (F))
2960                then
2961                   --  If default is a real literal, do not introduce a
2962                   --  conversion whose effect may depend on the run-time
2963                   --  size of universal real.
2964
2965                   if Nkind (Actval) = N_Real_Literal then
2966                      Set_Etype (Actval, Base_Type (Etype (F)));
2967                   else
2968                      Actval := Unchecked_Convert_To (Etype (F), Actval);
2969                   end if;
2970                end if;
2971
2972                if Is_Scalar_Type (Etype (F)) then
2973                   Enable_Range_Check (Actval);
2974                end if;
2975
2976                Set_Parent (Actval, N);
2977
2978                --  Resolve aggregates with their base type, to avoid scope
2979                --  anomalies: the subtype was first built in the subprogram
2980                --  declaration, and the current call may be nested.
2981
2982                if Nkind (Actval) = N_Aggregate then
2983                   Analyze_And_Resolve (Actval, Etype (F));
2984                else
2985                   Analyze_And_Resolve (Actval, Etype (Actval));
2986                end if;
2987
2988             else
2989                Set_Parent (Actval, N);
2990
2991                --  See note above concerning aggregates
2992
2993                if Nkind (Actval) = N_Aggregate
2994                  and then Has_Discriminants (Etype (Actval))
2995                then
2996                   Analyze_And_Resolve (Actval, Base_Type (Etype (Actval)));
2997
2998                --  Resolve entities with their own type, which may differ
2999                --  from the type of a reference in a generic context (the
3000                --  view swapping mechanism did not anticipate the re-analysis
3001                --  of default values in calls).
3002
3003                elsif Is_Entity_Name (Actval) then
3004                   Analyze_And_Resolve (Actval, Etype (Entity (Actval)));
3005
3006                else
3007                   Analyze_And_Resolve (Actval, Etype (Actval));
3008                end if;
3009             end if;
3010
3011             --  If default is a tag indeterminate function call, propagate
3012             --  tag to obtain proper dispatching.
3013
3014             if Is_Controlling_Formal (F)
3015               and then Nkind (Default_Value (F)) = N_Function_Call
3016             then
3017                Set_Is_Controlling_Actual (Actval);
3018             end if;
3019
3020          end if;
3021
3022          --  If the default expression raises constraint error, then just
3023          --  silently replace it with an N_Raise_Constraint_Error node,
3024          --  since we already gave the warning on the subprogram spec.
3025
3026          if Raises_Constraint_Error (Actval) then
3027             Rewrite (Actval,
3028               Make_Raise_Constraint_Error (Loc,
3029                 Reason => CE_Range_Check_Failed));
3030             Set_Raises_Constraint_Error (Actval);
3031             Set_Etype (Actval, Etype (F));
3032          end if;
3033
3034          Assoc :=
3035            Make_Parameter_Association (Loc,
3036              Explicit_Actual_Parameter => Actval,
3037              Selector_Name => Make_Identifier (Loc, Chars (F)));
3038
3039          --  Case of insertion is first named actual
3040
3041          if No (Prev) or else
3042             Nkind (Parent (Prev)) /= N_Parameter_Association
3043          then
3044             Set_Next_Named_Actual (Assoc, First_Named_Actual (N));
3045             Set_First_Named_Actual (N, Actval);
3046
3047             if No (Prev) then
3048                if No (Parameter_Associations (N)) then
3049                   Set_Parameter_Associations (N, New_List (Assoc));
3050                else
3051                   Append (Assoc, Parameter_Associations (N));
3052                end if;
3053
3054             else
3055                Insert_After (Prev, Assoc);
3056             end if;
3057
3058          --  Case of insertion is not first named actual
3059
3060          else
3061             Set_Next_Named_Actual
3062               (Assoc, Next_Named_Actual (Parent (Prev)));
3063             Set_Next_Named_Actual (Parent (Prev), Actval);
3064             Append (Assoc, Parameter_Associations (N));
3065          end if;
3066
3067          Mark_Rewrite_Insertion (Assoc);
3068          Mark_Rewrite_Insertion (Actval);
3069
3070          Prev := Actval;
3071       end Insert_Default;
3072
3073       -------------------
3074       -- Same_Ancestor --
3075       -------------------
3076
3077       function Same_Ancestor (T1, T2 : Entity_Id) return Boolean is
3078          FT1 : Entity_Id := T1;
3079          FT2 : Entity_Id := T2;
3080
3081       begin
3082          if Is_Private_Type (T1)
3083            and then Present (Full_View (T1))
3084          then
3085             FT1 := Full_View (T1);
3086          end if;
3087
3088          if Is_Private_Type (T2)
3089            and then Present (Full_View (T2))
3090          then
3091             FT2 := Full_View (T2);
3092          end if;
3093
3094          return Root_Type (Base_Type (FT1)) = Root_Type (Base_Type (FT2));
3095       end Same_Ancestor;
3096
3097       --------------------------
3098       -- Static_Concatenation --
3099       --------------------------
3100
3101       function Static_Concatenation (N : Node_Id) return Boolean is
3102       begin
3103          case Nkind (N) is
3104             when N_String_Literal =>
3105                return True;
3106
3107             when N_Op_Concat =>
3108
3109                --  Concatenation is static when both operands are static
3110                --  and the concatenation operator is a predefined one.
3111
3112                return Scope (Entity (N)) = Standard_Standard
3113                         and then
3114                       Static_Concatenation (Left_Opnd (N))
3115                         and then
3116                       Static_Concatenation (Right_Opnd (N));
3117
3118             when others =>
3119                if Is_Entity_Name (N) then
3120                   declare
3121                      Ent : constant Entity_Id := Entity (N);
3122                   begin
3123                      return Ekind (Ent) = E_Constant
3124                               and then Present (Constant_Value (Ent))
3125                               and then
3126                                 Is_Static_Expression (Constant_Value (Ent));
3127                   end;
3128
3129                else
3130                   return False;
3131                end if;
3132          end case;
3133       end Static_Concatenation;
3134
3135    --  Start of processing for Resolve_Actuals
3136
3137    begin
3138       Check_Argument_Order;
3139
3140       if Present (First_Actual (N)) then
3141          Check_Prefixed_Call;
3142       end if;
3143
3144       A := First_Actual (N);
3145       F := First_Formal (Nam);
3146       while Present (F) loop
3147          if No (A) and then Needs_No_Actuals (Nam) then
3148             null;
3149
3150          --  If we have an error in any actual or formal, indicated by a type
3151          --  of Any_Type, then abandon resolution attempt, and set result type
3152          --  to Any_Type.
3153
3154          elsif (Present (A) and then Etype (A) = Any_Type)
3155            or else Etype (F) = Any_Type
3156          then
3157             Set_Etype (N, Any_Type);
3158             return;
3159          end if;
3160
3161          --  Case where actual is present
3162
3163          --  If the actual is an entity, generate a reference to it now. We
3164          --  do this before the actual is resolved, because a formal of some
3165          --  protected subprogram, or a task discriminant, will be rewritten
3166          --  during expansion, and the reference to the source entity may
3167          --  be lost.
3168
3169          if Present (A)
3170            and then Is_Entity_Name (A)
3171            and then Comes_From_Source (N)
3172          then
3173             Orig_A := Entity (A);
3174
3175             if Present (Orig_A) then
3176                if Is_Formal (Orig_A)
3177                  and then Ekind (F) /= E_In_Parameter
3178                then
3179                   Generate_Reference (Orig_A, A, 'm');
3180                elsif not Is_Overloaded (A) then
3181                   Generate_Reference (Orig_A, A);
3182                end if;
3183             end if;
3184          end if;
3185
3186          if Present (A)
3187            and then (Nkind (Parent (A)) /= N_Parameter_Association
3188                        or else
3189                      Chars (Selector_Name (Parent (A))) = Chars (F))
3190          then
3191             --  If style checking mode on, check match of formal name
3192
3193             if Style_Check then
3194                if Nkind (Parent (A)) = N_Parameter_Association then
3195                   Check_Identifier (Selector_Name (Parent (A)), F);
3196                end if;
3197             end if;
3198
3199             --  If the formal is Out or In_Out, do not resolve and expand the
3200             --  conversion, because it is subsequently expanded into explicit
3201             --  temporaries and assignments. However, the object of the
3202             --  conversion can be resolved. An exception is the case of tagged
3203             --  type conversion with a class-wide actual. In that case we want
3204             --  the tag check to occur and no temporary will be needed (no
3205             --  representation change can occur) and the parameter is passed by
3206             --  reference, so we go ahead and resolve the type conversion.
3207             --  Another exception is the case of reference to component or
3208             --  subcomponent of a bit-packed array, in which case we want to
3209             --  defer expansion to the point the in and out assignments are
3210             --  performed.
3211
3212             if Ekind (F) /= E_In_Parameter
3213               and then Nkind (A) = N_Type_Conversion
3214               and then not Is_Class_Wide_Type (Etype (Expression (A)))
3215             then
3216                if Ekind (F) = E_In_Out_Parameter
3217                  and then Is_Array_Type (Etype (F))
3218                then
3219                   if Has_Aliased_Components (Etype (Expression (A)))
3220                     /= Has_Aliased_Components (Etype (F))
3221                   then
3222
3223                      --  In a view conversion, the conversion must be legal in
3224                      --  both directions, and thus both component types must be
3225                      --  aliased, or neither (4.6 (8)).
3226
3227                      --  The additional rule 4.6 (24.9.2) seems unduly
3228                      --  restrictive: the privacy requirement should not apply
3229                      --  to generic types, and should be checked in an
3230                      --  instance. ARG query is in order ???
3231
3232                      Error_Msg_N
3233                        ("both component types in a view conversion must be"
3234                          & " aliased, or neither", A);
3235
3236                   elsif
3237                      not Same_Ancestor (Etype (F), Etype (Expression (A)))
3238                   then
3239                      if Is_By_Reference_Type (Etype (F))
3240                         or else Is_By_Reference_Type (Etype (Expression (A)))
3241                      then
3242                         Error_Msg_N
3243                           ("view conversion between unrelated by reference " &
3244                            "array types not allowed (\'A'I-00246)", A);
3245                      else
3246                         declare
3247                            Comp_Type : constant Entity_Id :=
3248                                          Component_Type
3249                                            (Etype (Expression (A)));
3250                         begin
3251                            if Comes_From_Source (A)
3252                              and then Ada_Version >= Ada_05
3253                              and then
3254                                ((Is_Private_Type (Comp_Type)
3255                                    and then not Is_Generic_Type (Comp_Type))
3256                                  or else Is_Tagged_Type (Comp_Type)
3257                                  or else Is_Volatile (Comp_Type))
3258                            then
3259                               Error_Msg_N
3260                                 ("component type of a view conversion cannot"
3261                                    & " be private, tagged, or volatile"
3262                                    & " (RM 4.6 (24))",
3263                                    Expression (A));
3264                            end if;
3265                         end;
3266                      end if;
3267                   end if;
3268                end if;
3269
3270                if (Conversion_OK (A)
3271                      or else Valid_Conversion (A, Etype (A), Expression (A)))
3272                  and then not Is_Ref_To_Bit_Packed_Array (Expression (A))
3273                then
3274                   Resolve (Expression (A));
3275                end if;
3276
3277             --  If the actual is a function call that returns a limited
3278             --  unconstrained object that needs finalization, create a
3279             --  transient scope for it, so that it can receive the proper
3280             --  finalization list.
3281
3282             elsif Nkind (A) = N_Function_Call
3283               and then Is_Limited_Record (Etype (F))
3284               and then not Is_Constrained (Etype (F))
3285               and then Expander_Active
3286               and then
3287                 (Is_Controlled (Etype (F)) or else Has_Task (Etype (F)))
3288             then
3289                Establish_Transient_Scope (A, False);
3290
3291             --  A small optimization: if one of the actuals is a concatenation
3292             --  create a block around a procedure call to recover stack space.
3293             --  This alleviates stack usage when several procedure calls in
3294             --  the same statement list use concatenation. We do not perform
3295             --  this wrapping for code statements, where the argument is a
3296             --  static string, and we want to preserve warnings involving
3297             --  sequences of such statements.
3298
3299             elsif Nkind (A) = N_Op_Concat
3300               and then Nkind (N) = N_Procedure_Call_Statement
3301               and then Expander_Active
3302               and then
3303                 not (Is_Intrinsic_Subprogram (Nam)
3304                       and then Chars (Nam) = Name_Asm)
3305               and then not Static_Concatenation (A)
3306             then
3307                Establish_Transient_Scope (A, False);
3308                Resolve (A, Etype (F));
3309
3310             else
3311                if Nkind (A) = N_Type_Conversion
3312                  and then Is_Array_Type (Etype (F))
3313                  and then not Same_Ancestor (Etype (F), Etype (Expression (A)))
3314                  and then
3315                   (Is_Limited_Type (Etype (F))
3316                      or else Is_Limited_Type (Etype (Expression (A))))
3317                then
3318                   Error_Msg_N
3319                     ("conversion between unrelated limited array types " &
3320                      "not allowed (\A\I-00246)", A);
3321
3322                   if Is_Limited_Type (Etype (F)) then
3323                      Explain_Limited_Type (Etype (F), A);
3324                   end if;
3325
3326                   if Is_Limited_Type (Etype (Expression (A))) then
3327                      Explain_Limited_Type (Etype (Expression (A)), A);
3328                   end if;
3329                end if;
3330
3331                --  (Ada 2005: AI-251): If the actual is an allocator whose
3332                --  directly designated type is a class-wide interface, we build
3333                --  an anonymous access type to use it as the type of the
3334                --  allocator. Later, when the subprogram call is expanded, if
3335                --  the interface has a secondary dispatch table the expander
3336                --  will add a type conversion to force the correct displacement
3337                --  of the pointer.
3338
3339                if Nkind (A) = N_Allocator then
3340                   declare
3341                      DDT : constant Entity_Id :=
3342                              Directly_Designated_Type (Base_Type (Etype (F)));
3343
3344                      New_Itype : Entity_Id;
3345
3346                   begin
3347                      if Is_Class_Wide_Type (DDT)
3348                        and then Is_Interface (DDT)
3349                      then
3350                         New_Itype := Create_Itype (E_Anonymous_Access_Type, A);
3351                         Set_Etype (New_Itype, Etype (A));
3352                         Set_Directly_Designated_Type (New_Itype,
3353                           Directly_Designated_Type (Etype (A)));
3354                         Set_Etype (A, New_Itype);
3355                      end if;
3356
3357                      --  Ada 2005, AI-162:If the actual is an allocator, the
3358                      --  innermost enclosing statement is the master of the
3359                      --  created object. This needs to be done with expansion
3360                      --  enabled only, otherwise the transient scope will not
3361                      --  be removed in the expansion of the wrapped construct.
3362
3363                      if (Is_Controlled (DDT) or else Has_Task (DDT))
3364                        and then Expander_Active
3365                      then
3366                         Establish_Transient_Scope (A, False);
3367                      end if;
3368                   end;
3369                end if;
3370
3371                --  (Ada 2005): The call may be to a primitive operation of
3372                --   a tagged synchronized type, declared outside of the type.
3373                --   In this case the controlling actual must be converted to
3374                --   its corresponding record type, which is the formal type.
3375                --   The actual may be a subtype, either because of a constraint
3376                --   or because it is a generic actual, so use base type to
3377                --   locate concurrent type.
3378
3379                A_Typ := Base_Type (Etype (A));
3380                F_Typ := Base_Type (Etype (F));
3381
3382                declare
3383                   Full_A_Typ : Entity_Id;
3384
3385                begin
3386                   if Present (Full_View (A_Typ)) then
3387                      Full_A_Typ := Base_Type (Full_View (A_Typ));
3388                   else
3389                      Full_A_Typ := A_Typ;
3390                   end if;
3391
3392                   --  Tagged synchronized type (case 1): the actual is a
3393                   --  concurrent type
3394
3395                   if Is_Concurrent_Type (A_Typ)
3396                     and then Corresponding_Record_Type (A_Typ) = F_Typ
3397                   then
3398                      Rewrite (A,
3399                        Unchecked_Convert_To
3400                          (Corresponding_Record_Type (A_Typ), A));
3401                      Resolve (A, Etype (F));
3402
3403                   --  Tagged synchronized type (case 2): the formal is a
3404                   --  concurrent type
3405
3406                   elsif Ekind (Full_A_Typ) = E_Record_Type
3407                     and then Present
3408                                (Corresponding_Concurrent_Type (Full_A_Typ))
3409                     and then Is_Concurrent_Type (F_Typ)
3410                     and then Present (Corresponding_Record_Type (F_Typ))
3411                     and then Full_A_Typ = Corresponding_Record_Type (F_Typ)
3412                   then
3413                      Resolve (A, Corresponding_Record_Type (F_Typ));
3414
3415                   --  Common case
3416
3417                   else
3418                      Resolve (A, Etype (F));
3419                   end if;
3420                end;
3421             end if;
3422
3423             A_Typ := Etype (A);
3424             F_Typ := Etype (F);
3425
3426             --  For mode IN, if actual is an entity, and the type of the formal
3427             --  has warnings suppressed, then we reset Never_Set_In_Source for
3428             --  the calling entity. The reason for this is to catch cases like
3429             --  GNAT.Spitbol.Patterns.Vstring_Var where the called subprogram
3430             --  uses trickery to modify an IN parameter.
3431
3432             if Ekind (F) = E_In_Parameter
3433               and then Is_Entity_Name (A)
3434               and then Present (Entity (A))
3435               and then Ekind (Entity (A)) = E_Variable
3436               and then Has_Warnings_Off (F_Typ)
3437             then
3438                Set_Never_Set_In_Source (Entity (A), False);
3439             end if;
3440
3441             --  Perform error checks for IN and IN OUT parameters
3442
3443             if Ekind (F) /= E_Out_Parameter then
3444
3445                --  Check unset reference. For scalar parameters, it is clearly
3446                --  wrong to pass an uninitialized value as either an IN or
3447                --  IN-OUT parameter. For composites, it is also clearly an
3448                --  error to pass a completely uninitialized value as an IN
3449                --  parameter, but the case of IN OUT is trickier. We prefer
3450                --  not to give a warning here. For example, suppose there is
3451                --  a routine that sets some component of a record to False.
3452                --  It is perfectly reasonable to make this IN-OUT and allow
3453                --  either initialized or uninitialized records to be passed
3454                --  in this case.
3455
3456                --  For partially initialized composite values, we also avoid
3457                --  warnings, since it is quite likely that we are passing a
3458                --  partially initialized value and only the initialized fields
3459                --  will in fact be read in the subprogram.
3460
3461                if Is_Scalar_Type (A_Typ)
3462                  or else (Ekind (F) = E_In_Parameter
3463                             and then not Is_Partially_Initialized_Type (A_Typ))
3464                then
3465                   Check_Unset_Reference (A);
3466                end if;
3467
3468                --  In Ada 83 we cannot pass an OUT parameter as an IN or IN OUT
3469                --  actual to a nested call, since this is case of reading an
3470                --  out parameter, which is not allowed.
3471
3472                if Ada_Version = Ada_83
3473                  and then Is_Entity_Name (A)
3474                  and then Ekind (Entity (A)) = E_Out_Parameter
3475                then
3476                   Error_Msg_N ("(Ada 83) illegal reading of out parameter", A);
3477                end if;
3478             end if;
3479
3480             --  Case of OUT or IN OUT parameter
3481
3482             if Ekind (F) /= E_In_Parameter then
3483
3484                --  For an Out parameter, check for useless assignment. Note
3485                --  that we can't set Last_Assignment this early, because we may
3486                --  kill current values in Resolve_Call, and that call would
3487                --  clobber the Last_Assignment field.
3488
3489                --  Note: call Warn_On_Useless_Assignment before doing the check
3490                --  below for Is_OK_Variable_For_Out_Formal so that the setting
3491                --  of Referenced_As_LHS/Referenced_As_Out_Formal properly
3492                --  reflects the last assignment, not this one!
3493
3494                if Ekind (F) = E_Out_Parameter then
3495                   if Warn_On_Modified_As_Out_Parameter (F)
3496                     and then Is_Entity_Name (A)
3497                     and then Present (Entity (A))
3498                     and then Comes_From_Source (N)
3499                   then
3500                      Warn_On_Useless_Assignment (Entity (A), A);
3501                   end if;
3502                end if;
3503
3504                --  Validate the form of the actual. Note that the call to
3505                --  Is_OK_Variable_For_Out_Formal generates the required
3506                --  reference in this case.
3507
3508                if not Is_OK_Variable_For_Out_Formal (A) then
3509                   Error_Msg_NE ("actual for& must be a variable", A, F);
3510                end if;
3511
3512                --  What's the following about???
3513
3514                if Is_Entity_Name (A) then
3515                   Kill_Checks (Entity (A));
3516                else
3517                   Kill_All_Checks;
3518                end if;
3519             end if;
3520
3521             if Etype (A) = Any_Type then
3522                Set_Etype (N, Any_Type);
3523                return;
3524             end if;
3525
3526             --  Apply appropriate range checks for in, out, and in-out
3527             --  parameters. Out and in-out parameters also need a separate
3528             --  check, if there is a type conversion, to make sure the return
3529             --  value meets the constraints of the variable before the
3530             --  conversion.
3531
3532             --  Gigi looks at the check flag and uses the appropriate types.
3533             --  For now since one flag is used there is an optimization which
3534             --  might not be done in the In Out case since Gigi does not do
3535             --  any analysis. More thought required about this ???
3536
3537             if Ekind (F) = E_In_Parameter
3538               or else Ekind (F) = E_In_Out_Parameter
3539             then
3540                if Is_Scalar_Type (Etype (A)) then
3541                   Apply_Scalar_Range_Check (A, F_Typ);
3542
3543                elsif Is_Array_Type (Etype (A)) then
3544                   Apply_Length_Check (A, F_Typ);
3545
3546                elsif Is_Record_Type (F_Typ)
3547                  and then Has_Discriminants (F_Typ)
3548                  and then Is_Constrained (F_Typ)
3549                  and then (not Is_Derived_Type (F_Typ)
3550                              or else Comes_From_Source (Nam))
3551                then
3552                   Apply_Discriminant_Check (A, F_Typ);
3553
3554                elsif Is_Access_Type (F_Typ)
3555                  and then Is_Array_Type (Designated_Type (F_Typ))
3556                  and then Is_Constrained (Designated_Type (F_Typ))
3557                then
3558                   Apply_Length_Check (A, F_Typ);
3559
3560                elsif Is_Access_Type (F_Typ)
3561                  and then Has_Discriminants (Designated_Type (F_Typ))
3562                  and then Is_Constrained (Designated_Type (F_Typ))
3563                then
3564                   Apply_Discriminant_Check (A, F_Typ);
3565
3566                else
3567                   Apply_Range_Check (A, F_Typ);
3568                end if;
3569
3570                --  Ada 2005 (AI-231)
3571
3572                if Ada_Version >= Ada_05
3573                  and then Is_Access_Type (F_Typ)
3574                  and then Can_Never_Be_Null (F_Typ)
3575                  and then Known_Null (A)
3576                then
3577                   Apply_Compile_Time_Constraint_Error
3578                     (N      => A,
3579                      Msg    => "(Ada 2005) null not allowed in "
3580                                & "null-excluding formal?",
3581                      Reason => CE_Null_Not_Allowed);
3582                end if;
3583             end if;
3584
3585             if Ekind (F) = E_Out_Parameter
3586               or else Ekind (F) = E_In_Out_Parameter
3587             then
3588                if Nkind (A) = N_Type_Conversion then
3589                   if Is_Scalar_Type (A_Typ) then
3590                      Apply_Scalar_Range_Check
3591                        (Expression (A), Etype (Expression (A)), A_Typ);
3592                   else
3593                      Apply_Range_Check
3594                        (Expression (A), Etype (Expression (A)), A_Typ);
3595                   end if;
3596
3597                else
3598                   if Is_Scalar_Type (F_Typ) then
3599                      Apply_Scalar_Range_Check (A, A_Typ, F_Typ);
3600
3601                   elsif Is_Array_Type (F_Typ)
3602                     and then Ekind (F) = E_Out_Parameter
3603                   then
3604                      Apply_Length_Check (A, F_Typ);
3605
3606                   else
3607                      Apply_Range_Check (A, A_Typ, F_Typ);
3608                   end if;
3609                end if;
3610             end if;
3611
3612             --  An actual associated with an access parameter is implicitly
3613             --  converted to the anonymous access type of the formal and must
3614             --  satisfy the legality checks for access conversions.
3615
3616             if Ekind (F_Typ) = E_Anonymous_Access_Type then
3617                if not Valid_Conversion (A, F_Typ, A) then
3618                   Error_Msg_N
3619                     ("invalid implicit conversion for access parameter", A);
3620                end if;
3621             end if;
3622
3623             --  Check bad case of atomic/volatile argument (RM C.6(12))
3624
3625             if Is_By_Reference_Type (Etype (F))
3626               and then Comes_From_Source (N)
3627             then
3628                if Is_Atomic_Object (A)
3629                  and then not Is_Atomic (Etype (F))
3630                then
3631                   Error_Msg_N
3632                     ("cannot pass atomic argument to non-atomic formal",
3633                      N);
3634
3635                elsif Is_Volatile_Object (A)
3636                  and then not Is_Volatile (Etype (F))
3637                then
3638                   Error_Msg_N
3639                     ("cannot pass volatile argument to non-volatile formal",
3640                      N);
3641                end if;
3642             end if;
3643
3644             --  Check that subprograms don't have improper controlling
3645             --  arguments (RM 3.9.2 (9)).
3646
3647             --  A primitive operation may have an access parameter of an
3648             --  incomplete tagged type, but a dispatching call is illegal
3649             --  if the type is still incomplete.
3650
3651             if Is_Controlling_Formal (F) then
3652                Set_Is_Controlling_Actual (A);
3653
3654                if Ekind (Etype (F)) = E_Anonymous_Access_Type then
3655                   declare
3656                      Desig : constant Entity_Id := Designated_Type (Etype (F));
3657                   begin
3658                      if Ekind (Desig) = E_Incomplete_Type
3659                        and then No (Full_View (Desig))
3660                        and then No (Non_Limited_View (Desig))
3661                      then
3662                         Error_Msg_NE
3663                           ("premature use of incomplete type& " &
3664                            "in dispatching call", A, Desig);
3665                      end if;
3666                   end;
3667                end if;
3668
3669             elsif Nkind (A) = N_Explicit_Dereference then
3670                Validate_Remote_Access_To_Class_Wide_Type (A);
3671             end if;
3672
3673             if (Is_Class_Wide_Type (A_Typ) or else Is_Dynamically_Tagged (A))
3674               and then not Is_Class_Wide_Type (F_Typ)
3675               and then not Is_Controlling_Formal (F)
3676             then
3677                Error_Msg_N ("class-wide argument not allowed here!", A);
3678
3679                if Is_Subprogram (Nam)
3680                  and then Comes_From_Source (Nam)
3681                then
3682                   Error_Msg_Node_2 := F_Typ;
3683                   Error_Msg_NE
3684                     ("& is not a dispatching operation of &!", A, Nam);
3685                end if;
3686
3687             elsif Is_Access_Type (A_Typ)
3688               and then Is_Access_Type (F_Typ)
3689               and then Ekind (F_Typ) /= E_Access_Subprogram_Type
3690               and then Ekind (F_Typ) /= E_Anonymous_Access_Subprogram_Type
3691               and then (Is_Class_Wide_Type (Designated_Type (A_Typ))
3692                          or else (Nkind (A) = N_Attribute_Reference
3693                                    and then
3694                                      Is_Class_Wide_Type (Etype (Prefix (A)))))
3695               and then not Is_Class_Wide_Type (Designated_Type (F_Typ))
3696               and then not Is_Controlling_Formal (F)
3697
3698               --  Disable these checks for call to imported C++ subprograms
3699
3700               and then not
3701                 (Is_Entity_Name (Name (N))
3702                   and then Is_Imported (Entity (Name (N)))
3703                   and then Convention (Entity (Name (N))) = Convention_CPP)
3704             then
3705                Error_Msg_N
3706                  ("access to class-wide argument not allowed here!", A);
3707
3708                if Is_Subprogram (Nam)
3709                  and then Comes_From_Source (Nam)
3710                then
3711                   Error_Msg_Node_2 := Designated_Type (F_Typ);
3712                   Error_Msg_NE
3713                     ("& is not a dispatching operation of &!", A, Nam);
3714                end if;
3715             end if;
3716
3717             Eval_Actual (A);
3718
3719             --  If it is a named association, treat the selector_name as
3720             --  a proper identifier, and mark the corresponding entity.
3721
3722             if Nkind (Parent (A)) = N_Parameter_Association then
3723                Set_Entity (Selector_Name (Parent (A)), F);
3724                Generate_Reference (F, Selector_Name (Parent (A)));
3725                Set_Etype (Selector_Name (Parent (A)), F_Typ);
3726                Generate_Reference (F_Typ, N, ' ');
3727             end if;
3728
3729             Prev := A;
3730
3731             if Ekind (F) /= E_Out_Parameter then
3732                Check_Unset_Reference (A);
3733             end if;
3734
3735             Next_Actual (A);
3736
3737          --  Case where actual is not present
3738
3739          else
3740             Insert_Default;
3741          end if;
3742
3743          Next_Formal (F);
3744       end loop;
3745    end Resolve_Actuals;
3746
3747    -----------------------
3748    -- Resolve_Allocator --
3749    -----------------------
3750
3751    procedure Resolve_Allocator (N : Node_Id; Typ : Entity_Id) is
3752       E        : constant Node_Id := Expression (N);
3753       Subtyp   : Entity_Id;
3754       Discrim  : Entity_Id;
3755       Constr   : Node_Id;
3756       Aggr     : Node_Id;
3757       Assoc    : Node_Id := Empty;
3758       Disc_Exp : Node_Id;
3759
3760       procedure Check_Allocator_Discrim_Accessibility
3761         (Disc_Exp  : Node_Id;
3762          Alloc_Typ : Entity_Id);
3763       --  Check that accessibility level associated with an access discriminant
3764       --  initialized in an allocator by the expression Disc_Exp is not deeper
3765       --  than the level of the allocator type Alloc_Typ. An error message is
3766       --  issued if this condition is violated. Specialized checks are done for
3767       --  the cases of a constraint expression which is an access attribute or
3768       --  an access discriminant.
3769
3770       function In_Dispatching_Context return Boolean;
3771       --  If the allocator is an actual in a call, it is allowed to be class-
3772       --  wide when the context is not because it is a controlling actual.
3773
3774       procedure Propagate_Coextensions (Root : Node_Id);
3775       --  Propagate all nested coextensions which are located one nesting
3776       --  level down the tree to the node Root. Example:
3777       --
3778       --    Top_Record
3779       --       Level_1_Coextension
3780       --          Level_2_Coextension
3781       --
3782       --  The algorithm is paired with delay actions done by the Expander. In
3783       --  the above example, assume all coextensions are controlled types.
3784       --  The cycle of analysis, resolution and expansion will yield:
3785       --
3786       --  1) Analyze Top_Record
3787       --  2) Analyze Level_1_Coextension
3788       --  3) Analyze Level_2_Coextension
3789       --  4) Resolve Level_2_Coextension. The allocator is marked as a
3790       --       coextension.
3791       --  5) Expand Level_2_Coextension. A temporary variable Temp_1 is
3792       --       generated to capture the allocated object. Temp_1 is attached
3793       --       to the coextension chain of Level_2_Coextension.
3794       --  6) Resolve Level_1_Coextension. The allocator is marked as a
3795       --       coextension. A forward tree traversal is performed which finds
3796       --       Level_2_Coextension's list and copies its contents into its
3797       --       own list.
3798       --  7) Expand Level_1_Coextension. A temporary variable Temp_2 is
3799       --       generated to capture the allocated object. Temp_2 is attached
3800       --       to the coextension chain of Level_1_Coextension. Currently, the
3801       --       contents of the list are [Temp_2, Temp_1].
3802       --  8) Resolve Top_Record. A forward tree traversal is performed which
3803       --       finds Level_1_Coextension's list and copies its contents into
3804       --       its own list.
3805       --  9) Expand Top_Record. Generate finalization calls for Temp_1 and
3806       --       Temp_2 and attach them to Top_Record's finalization list.
3807
3808       -------------------------------------------
3809       -- Check_Allocator_Discrim_Accessibility --
3810       -------------------------------------------
3811
3812       procedure Check_Allocator_Discrim_Accessibility
3813         (Disc_Exp  : Node_Id;
3814          Alloc_Typ : Entity_Id)
3815       is
3816       begin
3817          if Type_Access_Level (Etype (Disc_Exp)) >
3818             Type_Access_Level (Alloc_Typ)
3819          then
3820             Error_Msg_N
3821               ("operand type has deeper level than allocator type", Disc_Exp);
3822
3823          --  When the expression is an Access attribute the level of the prefix
3824          --  object must not be deeper than that of the allocator's type.
3825
3826          elsif Nkind (Disc_Exp) = N_Attribute_Reference
3827            and then Get_Attribute_Id (Attribute_Name (Disc_Exp))
3828                       = Attribute_Access
3829            and then Object_Access_Level (Prefix (Disc_Exp))
3830                       > Type_Access_Level (Alloc_Typ)
3831          then
3832             Error_Msg_N
3833               ("prefix of attribute has deeper level than allocator type",
3834                Disc_Exp);
3835
3836          --  When the expression is an access discriminant the check is against
3837          --  the level of the prefix object.
3838
3839          elsif Ekind (Etype (Disc_Exp)) = E_Anonymous_Access_Type
3840            and then Nkind (Disc_Exp) = N_Selected_Component
3841            and then Object_Access_Level (Prefix (Disc_Exp))
3842                       > Type_Access_Level (Alloc_Typ)
3843          then
3844             Error_Msg_N
3845               ("access discriminant has deeper level than allocator type",
3846                Disc_Exp);
3847
3848          --  All other cases are legal
3849
3850          else
3851             null;
3852          end if;
3853       end Check_Allocator_Discrim_Accessibility;
3854
3855       ----------------------------
3856       -- In_Dispatching_Context --
3857       ----------------------------
3858
3859       function In_Dispatching_Context return Boolean is
3860          Par : constant Node_Id := Parent (N);
3861       begin
3862          return Nkind_In (Par, N_Function_Call, N_Procedure_Call_Statement)
3863            and then Is_Entity_Name (Name (Par))
3864            and then Is_Dispatching_Operation (Entity (Name (Par)));
3865       end In_Dispatching_Context;
3866
3867       ----------------------------
3868       -- Propagate_Coextensions --
3869       ----------------------------
3870
3871       procedure Propagate_Coextensions (Root : Node_Id) is
3872
3873          procedure Copy_List (From : Elist_Id; To : Elist_Id);
3874          --  Copy the contents of list From into list To, preserving the
3875          --  order of elements.
3876
3877          function Process_Allocator (Nod : Node_Id) return Traverse_Result;
3878          --  Recognize an allocator or a rewritten allocator node and add it
3879          --  along with its nested coextensions to the list of Root.
3880
3881          ---------------
3882          -- Copy_List --
3883          ---------------
3884
3885          procedure Copy_List (From : Elist_Id; To : Elist_Id) is
3886             From_Elmt : Elmt_Id;
3887          begin
3888             From_Elmt := First_Elmt (From);
3889             while Present (From_Elmt) loop
3890                Append_Elmt (Node (From_Elmt), To);
3891                Next_Elmt (From_Elmt);
3892             end loop;
3893          end Copy_List;
3894
3895          -----------------------
3896          -- Process_Allocator --
3897          -----------------------
3898
3899          function Process_Allocator (Nod : Node_Id) return Traverse_Result is
3900             Orig_Nod : Node_Id := Nod;
3901
3902          begin
3903             --  This is a possible rewritten subtype indication allocator. Any
3904             --  nested coextensions will appear as discriminant constraints.
3905
3906             if Nkind (Nod) = N_Identifier
3907               and then Present (Original_Node (Nod))
3908               and then Nkind (Original_Node (Nod)) = N_Subtype_Indication
3909             then
3910                declare
3911                   Discr      : Node_Id;
3912                   Discr_Elmt : Elmt_Id;
3913
3914                begin
3915                   if Is_Record_Type (Entity (Nod)) then
3916                      Discr_Elmt :=
3917                        First_Elmt (Discriminant_Constraint (Entity (Nod)));
3918                      while Present (Discr_Elmt) loop
3919                         Discr := Node (Discr_Elmt);
3920
3921                         if Nkind (Discr) = N_Identifier
3922                           and then Present (Original_Node (Discr))
3923                           and then Nkind (Original_Node (Discr)) = N_Allocator
3924                           and then Present (Coextensions (
3925                                      Original_Node (Discr)))
3926                         then
3927                            if No (Coextensions (Root)) then
3928                               Set_Coextensions (Root, New_Elmt_List);
3929                            end if;
3930
3931                            Copy_List
3932                              (From => Coextensions (Original_Node (Discr)),
3933                               To   => Coextensions (Root));
3934                         end if;
3935
3936                         Next_Elmt (Discr_Elmt);
3937                      end loop;
3938
3939                      --  There is no need to continue the traversal of this
3940                      --  subtree since all the information has already been
3941                      --  propagated.
3942
3943                      return Skip;
3944                   end if;
3945                end;
3946
3947             --  Case of either a stand alone allocator or a rewritten allocator
3948             --  with an aggregate.
3949
3950             else
3951                if Present (Original_Node (Nod)) then
3952                   Orig_Nod := Original_Node (Nod);
3953                end if;
3954
3955                if Nkind (Orig_Nod) = N_Allocator then
3956
3957                   --  Propagate the list of nested coextensions to the Root
3958                   --  allocator. This is done through list copy since a single
3959                   --  allocator may have multiple coextensions. Do not touch
3960                   --  coextensions roots.
3961
3962                   if not Is_Coextension_Root (Orig_Nod)
3963                     and then Present (Coextensions (Orig_Nod))
3964                   then
3965                      if No (Coextensions (Root)) then
3966                         Set_Coextensions (Root, New_Elmt_List);
3967                      end if;
3968
3969                      Copy_List
3970                        (From => Coextensions (Orig_Nod),
3971                         To   => Coextensions (Root));
3972                   end if;
3973
3974                   --  There is no need to continue the traversal of this
3975                   --  subtree since all the information has already been
3976                   --  propagated.
3977
3978                   return Skip;
3979                end if;
3980             end if;
3981
3982             --  Keep on traversing, looking for the next allocator
3983
3984             return OK;
3985          end Process_Allocator;
3986
3987          procedure Process_Allocators is
3988            new Traverse_Proc (Process_Allocator);
3989
3990       --  Start of processing for Propagate_Coextensions
3991
3992       begin
3993          Process_Allocators (Expression (Root));
3994       end Propagate_Coextensions;
3995
3996    --  Start of processing for Resolve_Allocator
3997
3998    begin
3999       --  Replace general access with specific type
4000
4001       if Ekind (Etype (N)) = E_Allocator_Type then
4002          Set_Etype (N, Base_Type (Typ));
4003       end if;
4004
4005       if Is_Abstract_Type (Typ) then
4006          Error_Msg_N ("type of allocator cannot be abstract",  N);
4007       end if;
4008
4009       --  For qualified expression, resolve the expression using the
4010       --  given subtype (nothing to do for type mark, subtype indication)
4011
4012       if Nkind (E) = N_Qualified_Expression then
4013          if Is_Class_Wide_Type (Etype (E))
4014            and then not Is_Class_Wide_Type (Designated_Type (Typ))
4015            and then not In_Dispatching_Context
4016          then
4017             Error_Msg_N
4018               ("class-wide allocator not allowed for this access type", N);
4019          end if;
4020
4021          Resolve (Expression (E), Etype (E));
4022          Check_Unset_Reference (Expression (E));
4023
4024          --  A qualified expression requires an exact match of the type,
4025          --  class-wide matching is not allowed.
4026
4027          if (Is_Class_Wide_Type (Etype (Expression (E)))
4028                  or else Is_Class_Wide_Type (Etype (E)))
4029            and then Base_Type (Etype (Expression (E))) /= Base_Type (Etype (E))
4030          then
4031             Wrong_Type (Expression (E), Etype (E));
4032          end if;
4033
4034          --  A special accessibility check is needed for allocators that
4035          --  constrain access discriminants. The level of the type of the
4036          --  expression used to constrain an access discriminant cannot be
4037          --  deeper than the type of the allocator (in contrast to access
4038          --  parameters, where the level of the actual can be arbitrary).
4039
4040          --  We can't use Valid_Conversion to perform this check because
4041          --  in general the type of the allocator is unrelated to the type
4042          --  of the access discriminant.
4043
4044          if Ekind (Typ) /= E_Anonymous_Access_Type
4045            or else Is_Local_Anonymous_Access (Typ)
4046          then
4047             Subtyp := Entity (Subtype_Mark (E));
4048
4049             Aggr := Original_Node (Expression (E));
4050
4051             if Has_Discriminants (Subtyp)
4052               and then Nkind_In (Aggr, N_Aggregate, N_Extension_Aggregate)
4053             then
4054                Discrim := First_Discriminant (Base_Type (Subtyp));
4055
4056                --  Get the first component expression of the aggregate
4057
4058                if Present (Expressions (Aggr)) then
4059                   Disc_Exp := First (Expressions (Aggr));
4060
4061                elsif Present (Component_Associations (Aggr)) then
4062                   Assoc := First (Component_Associations (Aggr));
4063
4064                   if Present (Assoc) then
4065                      Disc_Exp := Expression (Assoc);
4066                   else
4067                      Disc_Exp := Empty;
4068                   end if;
4069
4070                else
4071                   Disc_Exp := Empty;
4072                end if;
4073
4074                while Present (Discrim) and then Present (Disc_Exp) loop
4075                   if Ekind (Etype (Discrim)) = E_Anonymous_Access_Type then
4076                      Check_Allocator_Discrim_Accessibility (Disc_Exp, Typ);
4077                   end if;
4078
4079                   Next_Discriminant (Discrim);
4080
4081                   if Present (Discrim) then
4082                      if Present (Assoc) then
4083                         Next (Assoc);
4084                         Disc_Exp := Expression (Assoc);
4085
4086                      elsif Present (Next (Disc_Exp)) then
4087                         Next (Disc_Exp);
4088
4089                      else
4090                         Assoc := First (Component_Associations (Aggr));
4091
4092                         if Present (Assoc) then
4093                            Disc_Exp := Expression (Assoc);
4094                         else
4095                            Disc_Exp := Empty;
4096                         end if;
4097                      end if;
4098                   end if;
4099                end loop;
4100             end if;
4101          end if;
4102
4103       --  For a subtype mark or subtype indication, freeze the subtype
4104
4105       else
4106          Freeze_Expression (E);
4107
4108          if Is_Access_Constant (Typ) and then not No_Initialization (N) then
4109             Error_Msg_N
4110               ("initialization required for access-to-constant allocator", N);
4111          end if;
4112
4113          --  A special accessibility check is needed for allocators that
4114          --  constrain access discriminants. The level of the type of the
4115          --  expression used to constrain an access discriminant cannot be
4116          --  deeper than the type of the allocator (in contrast to access
4117          --  parameters, where the level of the actual can be arbitrary).
4118          --  We can't use Valid_Conversion to perform this check because
4119          --  in general the type of the allocator is unrelated to the type
4120          --  of the access discriminant.
4121
4122          if Nkind (Original_Node (E)) = N_Subtype_Indication
4123            and then (Ekind (Typ) /= E_Anonymous_Access_Type
4124                       or else Is_Local_Anonymous_Access (Typ))
4125          then
4126             Subtyp := Entity (Subtype_Mark (Original_Node (E)));
4127
4128             if Has_Discriminants (Subtyp) then
4129                Discrim := First_Discriminant (Base_Type (Subtyp));
4130                Constr := First (Constraints (Constraint (Original_Node (E))));
4131                while Present (Discrim) and then Present (Constr) loop
4132                   if Ekind (Etype (Discrim)) = E_Anonymous_Access_Type then
4133                      if Nkind (Constr) = N_Discriminant_Association then
4134                         Disc_Exp := Original_Node (Expression (Constr));
4135                      else
4136                         Disc_Exp := Original_Node (Constr);
4137                      end if;
4138
4139                      Check_Allocator_Discrim_Accessibility (Disc_Exp, Typ);
4140                   end if;
4141
4142                   Next_Discriminant (Discrim);
4143                   Next (Constr);
4144                end loop;
4145             end if;
4146          end if;
4147       end if;
4148
4149       --  Ada 2005 (AI-344): A class-wide allocator requires an accessibility
4150       --  check that the level of the type of the created object is not deeper
4151       --  than the level of the allocator's access type, since extensions can
4152       --  now occur at deeper levels than their ancestor types. This is a
4153       --  static accessibility level check; a run-time check is also needed in
4154       --  the case of an initialized allocator with a class-wide argument (see
4155       --  Expand_Allocator_Expression).
4156
4157       if Ada_Version >= Ada_05
4158         and then Is_Class_Wide_Type (Designated_Type (Typ))
4159       then
4160          declare
4161             Exp_Typ : Entity_Id;
4162
4163          begin
4164             if Nkind (E) = N_Qualified_Expression then
4165                Exp_Typ := Etype (E);
4166             elsif Nkind (E) = N_Subtype_Indication then
4167                Exp_Typ := Entity (Subtype_Mark (Original_Node (E)));
4168             else
4169                Exp_Typ := Entity (E);
4170             end if;
4171
4172             if Type_Access_Level (Exp_Typ) > Type_Access_Level (Typ) then
4173                if In_Instance_Body then
4174                   Error_Msg_N ("?type in allocator has deeper level than" &
4175                                " designated class-wide type", E);
4176                   Error_Msg_N ("\?Program_Error will be raised at run time",
4177                                E);
4178                   Rewrite (N,
4179                     Make_Raise_Program_Error (Sloc (N),
4180                       Reason => PE_Accessibility_Check_Failed));
4181                   Set_Etype (N, Typ);
4182
4183                --  Do not apply Ada 2005 accessibility checks on a class-wide
4184                --  allocator if the type given in the allocator is a formal
4185                --  type. A run-time check will be performed in the instance.
4186
4187                elsif not Is_Generic_Type (Exp_Typ) then
4188                   Error_Msg_N ("type in allocator has deeper level than" &
4189                                " designated class-wide type", E);
4190                end if;
4191             end if;
4192          end;
4193       end if;
4194
4195       --  Check for allocation from an empty storage pool
4196
4197       if No_Pool_Assigned (Typ) then
4198          declare
4199             Loc : constant Source_Ptr := Sloc (N);
4200          begin
4201             Error_Msg_N ("?allocation from empty storage pool!", N);
4202             Error_Msg_N ("\?Storage_Error will be raised at run time!", N);
4203             Insert_Action (N,
4204               Make_Raise_Storage_Error (Loc,
4205                 Reason => SE_Empty_Storage_Pool));
4206          end;
4207
4208       --  If the context is an unchecked conversion, as may happen within
4209       --  an inlined subprogram, the allocator is being resolved with its
4210       --  own anonymous type. In that case, if the target type has a specific
4211       --  storage pool, it must be inherited explicitly by the allocator type.
4212
4213       elsif Nkind (Parent (N)) = N_Unchecked_Type_Conversion
4214         and then No (Associated_Storage_Pool (Typ))
4215       then
4216          Set_Associated_Storage_Pool
4217            (Typ, Associated_Storage_Pool (Etype (Parent (N))));
4218       end if;
4219
4220       --  An erroneous allocator may be rewritten as a raise Program_Error
4221       --  statement.
4222
4223       if Nkind (N) = N_Allocator then
4224
4225          --  An anonymous access discriminant is the definition of a
4226          --  coextension.
4227
4228          if Ekind (Typ) = E_Anonymous_Access_Type
4229            and then Nkind (Associated_Node_For_Itype (Typ)) =
4230                       N_Discriminant_Specification
4231          then
4232             --  Avoid marking an allocator as a dynamic coextension if it is
4233             --  within a static construct.
4234
4235             if not Is_Static_Coextension (N) then
4236                Set_Is_Dynamic_Coextension (N);
4237             end if;
4238
4239          --  Cleanup for potential static coextensions
4240
4241          else
4242             Set_Is_Dynamic_Coextension (N, False);
4243             Set_Is_Static_Coextension  (N, False);
4244          end if;
4245
4246          --  There is no need to propagate any nested coextensions if they
4247          --  are marked as static since they will be rewritten on the spot.
4248
4249          if not Is_Static_Coextension (N) then
4250             Propagate_Coextensions (N);
4251          end if;
4252       end if;
4253    end Resolve_Allocator;
4254
4255    ---------------------------
4256    -- Resolve_Arithmetic_Op --
4257    ---------------------------
4258
4259    --  Used for resolving all arithmetic operators except exponentiation
4260
4261    procedure Resolve_Arithmetic_Op (N : Node_Id; Typ : Entity_Id) is
4262       L   : constant Node_Id := Left_Opnd (N);
4263       R   : constant Node_Id := Right_Opnd (N);
4264       TL  : constant Entity_Id := Base_Type (Etype (L));
4265       TR  : constant Entity_Id := Base_Type (Etype (R));
4266       T   : Entity_Id;
4267       Rop : Node_Id;
4268
4269       B_Typ : constant Entity_Id := Base_Type (Typ);
4270       --  We do the resolution using the base type, because intermediate values
4271       --  in expressions always are of the base type, not a subtype of it.
4272
4273       function Expected_Type_Is_Any_Real (N : Node_Id) return Boolean;
4274       --  Returns True if N is in a context that expects "any real type"
4275
4276       function Is_Integer_Or_Universal (N : Node_Id) return Boolean;
4277       --  Return True iff given type is Integer or universal real/integer
4278
4279       procedure Set_Mixed_Mode_Operand (N : Node_Id; T : Entity_Id);
4280       --  Choose type of integer literal in fixed-point operation to conform
4281       --  to available fixed-point type. T is the type of the other operand,
4282       --  which is needed to determine the expected type of N.
4283
4284       procedure Set_Operand_Type (N : Node_Id);
4285       --  Set operand type to T if universal
4286
4287       -------------------------------
4288       -- Expected_Type_Is_Any_Real --
4289       -------------------------------
4290
4291       function Expected_Type_Is_Any_Real (N : Node_Id) return Boolean is
4292       begin
4293          --  N is the expression after "delta" in a fixed_point_definition;
4294          --  see RM-3.5.9(6):
4295
4296          return Nkind_In (Parent (N), N_Ordinary_Fixed_Point_Definition,
4297                                       N_Decimal_Fixed_Point_Definition,
4298
4299          --  N is one of the bounds in a real_range_specification;
4300          --  see RM-3.5.7(5):
4301
4302                                       N_Real_Range_Specification,
4303
4304          --  N is the expression of a delta_constraint;
4305          --  see RM-J.3(3):
4306
4307                                       N_Delta_Constraint);
4308       end Expected_Type_Is_Any_Real;
4309
4310       -----------------------------
4311       -- Is_Integer_Or_Universal --
4312       -----------------------------
4313
4314       function Is_Integer_Or_Universal (N : Node_Id) return Boolean is
4315          T     : Entity_Id;
4316          Index : Interp_Index;
4317          It    : Interp;
4318
4319       begin
4320          if not Is_Overloaded (N) then
4321             T := Etype (N);
4322             return Base_Type (T) = Base_Type (Standard_Integer)
4323               or else T = Universal_Integer
4324               or else T = Universal_Real;
4325          else
4326             Get_First_Interp (N, Index, It);
4327             while Present (It.Typ) loop
4328                if Base_Type (It.Typ) = Base_Type (Standard_Integer)
4329                  or else It.Typ = Universal_Integer
4330                  or else It.Typ = Universal_Real
4331                then
4332                   return True;
4333                end if;
4334
4335                Get_Next_Interp (Index, It);
4336             end loop;
4337          end if;
4338
4339          return False;
4340       end Is_Integer_Or_Universal;
4341
4342       ----------------------------
4343       -- Set_Mixed_Mode_Operand --
4344       ----------------------------
4345
4346       procedure Set_Mixed_Mode_Operand (N : Node_Id; T : Entity_Id) is
4347          Index : Interp_Index;
4348          It    : Interp;
4349
4350       begin
4351          if Universal_Interpretation (N) = Universal_Integer then
4352
4353             --  A universal integer literal is resolved as standard integer
4354             --  except in the case of a fixed-point result, where we leave it
4355             --  as universal (to be handled by Exp_Fixd later on)
4356
4357             if Is_Fixed_Point_Type (T) then
4358                Resolve (N, Universal_Integer);
4359             else
4360                Resolve (N, Standard_Integer);
4361             end if;
4362
4363          elsif Universal_Interpretation (N) = Universal_Real
4364            and then (T = Base_Type (Standard_Integer)
4365                       or else T = Universal_Integer
4366                       or else T = Universal_Real)
4367          then
4368             --  A universal real can appear in a fixed-type context. We resolve
4369             --  the literal with that context, even though this might raise an
4370             --  exception prematurely (the other operand may be zero).
4371
4372             Resolve (N, B_Typ);
4373
4374          elsif Etype (N) = Base_Type (Standard_Integer)
4375            and then T = Universal_Real
4376            and then Is_Overloaded (N)
4377          then
4378             --  Integer arg in mixed-mode operation. Resolve with universal
4379             --  type, in case preference rule must be applied.
4380
4381             Resolve (N, Universal_Integer);
4382
4383          elsif Etype (N) = T
4384            and then B_Typ /= Universal_Fixed
4385          then
4386             --  Not a mixed-mode operation, resolve with context
4387
4388             Resolve (N, B_Typ);
4389
4390          elsif Etype (N) = Any_Fixed then
4391
4392             --  N may itself be a mixed-mode operation, so use context type
4393
4394             Resolve (N, B_Typ);
4395
4396          elsif Is_Fixed_Point_Type (T)
4397            and then B_Typ = Universal_Fixed
4398            and then Is_Overloaded (N)
4399          then
4400             --  Must be (fixed * fixed) operation, operand must have one
4401             --  compatible interpretation.
4402
4403             Resolve (N, Any_Fixed);
4404
4405          elsif Is_Fixed_Point_Type (B_Typ)
4406            and then (T = Universal_Real
4407                       or else Is_Fixed_Point_Type (T))
4408            and then Is_Overloaded (N)
4409          then
4410             --  C * F(X) in a fixed context, where C is a real literal or a
4411             --  fixed-point expression. F must have either a fixed type
4412             --  interpretation or an integer interpretation, but not both.
4413
4414             Get_First_Interp (N, Index, It);
4415             while Present (It.Typ) loop
4416                if Base_Type (It.Typ) = Base_Type (Standard_Integer) then
4417
4418                   if Analyzed (N) then
4419                      Error_Msg_N ("ambiguous operand in fixed operation", N);
4420                   else
4421                      Resolve (N, Standard_Integer);
4422                   end if;
4423
4424                elsif Is_Fixed_Point_Type (It.Typ) then
4425
4426                   if Analyzed (N) then
4427                      Error_Msg_N ("ambiguous operand in fixed operation", N);
4428                   else
4429                      Resolve (N, It.Typ);
4430                   end if;
4431                end if;
4432
4433                Get_Next_Interp (Index, It);
4434             end loop;
4435
4436             --  Reanalyze the literal with the fixed type of the context. If
4437             --  context is Universal_Fixed, we are within a conversion, leave
4438             --  the literal as a universal real because there is no usable
4439             --  fixed type, and the target of the conversion plays no role in
4440             --  the resolution.
4441
4442             declare
4443                Op2 : Node_Id;
4444                T2  : Entity_Id;
4445
4446             begin
4447                if N = L then
4448                   Op2 := R;
4449                else
4450                   Op2 := L;
4451                end if;
4452
4453                if B_Typ = Universal_Fixed
4454                   and then Nkind (Op2) = N_Real_Literal
4455                then
4456                   T2 := Universal_Real;
4457                else
4458                   T2 := B_Typ;
4459                end if;
4460
4461                Set_Analyzed (Op2, False);
4462                Resolve (Op2, T2);
4463             end;
4464
4465          else
4466             Resolve (N);
4467          end if;
4468       end Set_Mixed_Mode_Operand;
4469
4470       ----------------------
4471       -- Set_Operand_Type --
4472       ----------------------
4473
4474       procedure Set_Operand_Type (N : Node_Id) is
4475       begin
4476          if Etype (N) = Universal_Integer
4477            or else Etype (N) = Universal_Real
4478          then
4479             Set_Etype (N, T);
4480          end if;
4481       end Set_Operand_Type;
4482
4483    --  Start of processing for Resolve_Arithmetic_Op
4484
4485    begin
4486       if Comes_From_Source (N)
4487         and then Ekind (Entity (N)) = E_Function
4488         and then Is_Imported (Entity (N))
4489         and then Is_Intrinsic_Subprogram (Entity (N))
4490       then
4491          Resolve_Intrinsic_Operator (N, Typ);
4492          return;
4493
4494       --  Special-case for mixed-mode universal expressions or fixed point
4495       --  type operation: each argument is resolved separately. The same
4496       --  treatment is required if one of the operands of a fixed point
4497       --  operation is universal real, since in this case we don't do a
4498       --  conversion to a specific fixed-point type (instead the expander
4499       --  takes care of the case).
4500
4501       elsif (B_Typ = Universal_Integer or else B_Typ = Universal_Real)
4502         and then Present (Universal_Interpretation (L))
4503         and then Present (Universal_Interpretation (R))
4504       then
4505          Resolve (L, Universal_Interpretation (L));
4506          Resolve (R, Universal_Interpretation (R));
4507          Set_Etype (N, B_Typ);
4508
4509       elsif (B_Typ = Universal_Real
4510               or else Etype (N) = Universal_Fixed
4511               or else (Etype (N) = Any_Fixed
4512                         and then Is_Fixed_Point_Type (B_Typ))
4513               or else (Is_Fixed_Point_Type (B_Typ)
4514                         and then (Is_Integer_Or_Universal (L)
4515                                    or else
4516                                   Is_Integer_Or_Universal (R))))
4517         and then Nkind_In (N, N_Op_Multiply, N_Op_Divide)
4518       then
4519          if TL = Universal_Integer or else TR = Universal_Integer then
4520             Check_For_Visible_Operator (N, B_Typ);
4521          end if;
4522
4523          --  If context is a fixed type and one operand is integer, the
4524          --  other is resolved with the type of the context.
4525
4526          if Is_Fixed_Point_Type (B_Typ)
4527            and then (Base_Type (TL) = Base_Type (Standard_Integer)
4528                       or else TL = Universal_Integer)
4529          then
4530             Resolve (R, B_Typ);
4531             Resolve (L, TL);
4532
4533          elsif Is_Fixed_Point_Type (B_Typ)
4534            and then (Base_Type (TR) = Base_Type (Standard_Integer)
4535                       or else TR = Universal_Integer)
4536          then
4537             Resolve (L, B_Typ);
4538             Resolve (R, TR);
4539
4540          else
4541             Set_Mixed_Mode_Operand (L, TR);
4542             Set_Mixed_Mode_Operand (R, TL);
4543          end if;
4544
4545          --  Check the rule in RM05-4.5.5(19.1/2) disallowing universal_fixed
4546          --  multiplying operators from being used when the expected type is
4547          --  also universal_fixed. Note that B_Typ will be Universal_Fixed in
4548          --  some cases where the expected type is actually Any_Real;
4549          --  Expected_Type_Is_Any_Real takes care of that case.
4550
4551          if Etype (N) = Universal_Fixed
4552            or else Etype (N) = Any_Fixed
4553          then
4554             if B_Typ = Universal_Fixed
4555               and then not Expected_Type_Is_Any_Real (N)
4556               and then not Nkind_In (Parent (N), N_Type_Conversion,
4557                                                  N_Unchecked_Type_Conversion)
4558             then
4559                Error_Msg_N ("type cannot be determined from context!", N);
4560                Error_Msg_N ("\explicit conversion to result type required", N);
4561
4562                Set_Etype (L, Any_Type);
4563                Set_Etype (R, Any_Type);
4564
4565             else
4566                if Ada_Version = Ada_83
4567                  and then Etype (N) = Universal_Fixed
4568                  and then not
4569                    Nkind_In (Parent (N), N_Type_Conversion,
4570                                          N_Unchecked_Type_Conversion)
4571                then
4572                   Error_Msg_N
4573                     ("(Ada 83) fixed-point operation "
4574                      & "needs explicit conversion", N);
4575                end if;
4576
4577                --  The expected type is "any real type" in contexts like
4578                --    type T is delta <universal_fixed-expression> ...
4579                --  in which case we need to set the type to Universal_Real
4580                --  so that static expression evaluation will work properly.
4581
4582                if Expected_Type_Is_Any_Real (N) then
4583                   Set_Etype (N, Universal_Real);
4584                else
4585                   Set_Etype (N, B_Typ);
4586                end if;
4587             end if;
4588
4589          elsif Is_Fixed_Point_Type (B_Typ)
4590            and then (Is_Integer_Or_Universal (L)
4591                        or else Nkind (L) = N_Real_Literal
4592                        or else Nkind (R) = N_Real_Literal
4593                        or else Is_Integer_Or_Universal (R))
4594          then
4595             Set_Etype (N, B_Typ);
4596
4597          elsif Etype (N) = Any_Fixed then
4598
4599             --  If no previous errors, this is only possible if one operand
4600             --  is overloaded and the context is universal. Resolve as such.
4601
4602             Set_Etype (N, B_Typ);
4603          end if;
4604
4605       else
4606          if (TL = Universal_Integer or else TL = Universal_Real)
4607               and then
4608             (TR = Universal_Integer or else TR = Universal_Real)
4609          then
4610             Check_For_Visible_Operator (N, B_Typ);
4611          end if;
4612
4613          --  If the context is Universal_Fixed and the operands are also
4614          --  universal fixed, this is an error, unless there is only one
4615          --  applicable fixed_point type (usually duration).
4616
4617          if B_Typ = Universal_Fixed and then Etype (L) = Universal_Fixed then
4618             T := Unique_Fixed_Point_Type (N);
4619
4620             if T  = Any_Type then
4621                Set_Etype (N, T);
4622                return;
4623             else
4624                Resolve (L, T);
4625                Resolve (R, T);
4626             end if;
4627
4628          else
4629             Resolve (L, B_Typ);
4630             Resolve (R, B_Typ);
4631          end if;
4632
4633          --  If one of the arguments was resolved to a non-universal type.
4634          --  label the result of the operation itself with the same type.
4635          --  Do the same for the universal argument, if any.
4636
4637          T := Intersect_Types (L, R);
4638          Set_Etype (N, Base_Type (T));
4639          Set_Operand_Type (L);
4640          Set_Operand_Type (R);
4641       end if;
4642
4643       Generate_Operator_Reference (N, Typ);
4644       Eval_Arithmetic_Op (N);
4645
4646       --  Set overflow and division checking bit. Much cleverer code needed
4647       --  here eventually and perhaps the Resolve routines should be separated
4648       --  for the various arithmetic operations, since they will need
4649       --  different processing. ???
4650
4651       if Nkind (N) in N_Op then
4652          if not Overflow_Checks_Suppressed (Etype (N)) then
4653             Enable_Overflow_Check (N);
4654          end if;
4655
4656          --  Give warning if explicit division by zero
4657
4658          if Nkind_In (N, N_Op_Divide, N_Op_Rem, N_Op_Mod)
4659            and then not Division_Checks_Suppressed (Etype (N))
4660          then
4661             Rop := Right_Opnd (N);
4662
4663             if Compile_Time_Known_Value (Rop)
4664               and then ((Is_Integer_Type (Etype (Rop))
4665                            and then Expr_Value (Rop) = Uint_0)
4666                           or else
4667                         (Is_Real_Type (Etype (Rop))
4668                            and then Expr_Value_R (Rop) = Ureal_0))
4669             then
4670                --  Specialize the warning message according to the operation
4671
4672                case Nkind (N) is
4673                   when N_Op_Divide =>
4674                      Apply_Compile_Time_Constraint_Error
4675                        (N, "division by zero?", CE_Divide_By_Zero,
4676                         Loc => Sloc (Right_Opnd (N)));
4677
4678                   when N_Op_Rem =>
4679                      Apply_Compile_Time_Constraint_Error
4680                        (N, "rem with zero divisor?", CE_Divide_By_Zero,
4681                         Loc => Sloc (Right_Opnd (N)));
4682
4683                   when N_Op_Mod =>
4684                      Apply_Compile_Time_Constraint_Error
4685                        (N, "mod with zero divisor?", CE_Divide_By_Zero,
4686                         Loc => Sloc (Right_Opnd (N)));
4687
4688                   --  Division by zero can only happen with division, rem,
4689                   --  and mod operations.
4690
4691                   when others =>
4692                      raise Program_Error;
4693                end case;
4694
4695             --  Otherwise just set the flag to check at run time
4696
4697             else
4698                Activate_Division_Check (N);
4699             end if;
4700          end if;
4701
4702          --  If Restriction No_Implicit_Conditionals is active, then it is
4703          --  violated if either operand can be negative for mod, or for rem
4704          --  if both operands can be negative.
4705
4706          if Restrictions.Set (No_Implicit_Conditionals)
4707            and then Nkind_In (N, N_Op_Rem, N_Op_Mod)
4708          then
4709             declare
4710                Lo : Uint;
4711                Hi : Uint;
4712                OK : Boolean;
4713
4714                LNeg : Boolean;
4715                RNeg : Boolean;
4716                --  Set if corresponding operand might be negative
4717
4718             begin
4719                Determine_Range
4720                  (Left_Opnd (N), OK, Lo, Hi, Assume_Valid => True);
4721                LNeg := (not OK) or else Lo < 0;
4722
4723                Determine_Range
4724                  (Right_Opnd (N), OK, Lo, Hi, Assume_Valid => True);
4725                RNeg := (not OK) or else Lo < 0;
4726
4727                --  Check if we will be generating conditionals. There are two
4728                --  cases where that can happen, first for REM, the only case
4729                --  is largest negative integer mod -1, where the division can
4730                --  overflow, but we still have to give the right result. The
4731                --  front end generates a test for this annoying case. Here we
4732                --  just test if both operands can be negative (that's what the
4733                --  expander does, so we match its logic here).
4734
4735                --  The second case is mod where either operand can be negative.
4736                --  In this case, the back end has to generate additonal tests.
4737
4738                if (Nkind (N) = N_Op_Rem and then (LNeg and RNeg))
4739                     or else
4740                   (Nkind (N) = N_Op_Mod and then (LNeg or RNeg))
4741                then
4742                   Check_Restriction (No_Implicit_Conditionals, N);
4743                end if;
4744             end;
4745          end if;
4746       end if;
4747
4748       Check_Unset_Reference (L);
4749       Check_Unset_Reference (R);
4750    end Resolve_Arithmetic_Op;
4751
4752    ------------------
4753    -- Resolve_Call --
4754    ------------------
4755
4756    procedure Resolve_Call (N : Node_Id; Typ : Entity_Id) is
4757       Loc     : constant Source_Ptr := Sloc (N);
4758       Subp    : constant Node_Id    := Name (N);
4759       Nam     : Entity_Id;
4760       I       : Interp_Index;
4761       It      : Interp;
4762       Norm_OK : Boolean;
4763       Scop    : Entity_Id;
4764       Rtype   : Entity_Id;
4765
4766    begin
4767       --  The context imposes a unique interpretation with type Typ on a
4768       --  procedure or function call. Find the entity of the subprogram that
4769       --  yields the expected type, and propagate the corresponding formal
4770       --  constraints on the actuals. The caller has established that an
4771       --  interpretation exists, and emitted an error if not unique.
4772
4773       --  First deal with the case of a call to an access-to-subprogram,
4774       --  dereference made explicit in Analyze_Call.
4775
4776       if Ekind (Etype (Subp)) = E_Subprogram_Type then
4777          if not Is_Overloaded (Subp) then
4778             Nam := Etype (Subp);
4779
4780          else
4781             --  Find the interpretation whose type (a subprogram type) has a
4782             --  return type that is compatible with the context. Analysis of
4783             --  the node has established that one exists.
4784
4785             Nam := Empty;
4786
4787             Get_First_Interp (Subp,  I, It);
4788             while Present (It.Typ) loop
4789                if Covers (Typ, Etype (It.Typ)) then
4790                   Nam := It.Typ;
4791                   exit;
4792                end if;
4793
4794                Get_Next_Interp (I, It);
4795             end loop;
4796
4797             if No (Nam) then
4798                raise Program_Error;
4799             end if;
4800          end if;
4801
4802          --  If the prefix is not an entity, then resolve it
4803
4804          if not Is_Entity_Name (Subp) then
4805             Resolve (Subp, Nam);
4806          end if;
4807
4808          --  For an indirect call, we always invalidate checks, since we do not
4809          --  know whether the subprogram is local or global. Yes we could do
4810          --  better here, e.g. by knowing that there are no local subprograms,
4811          --  but it does not seem worth the effort. Similarly, we kill all
4812          --  knowledge of current constant values.
4813
4814          Kill_Current_Values;
4815
4816       --  If this is a procedure call which is really an entry call, do
4817       --  the conversion of the procedure call to an entry call. Protected
4818       --  operations use the same circuitry because the name in the call
4819       --  can be an arbitrary expression with special resolution rules.
4820
4821       elsif Nkind_In (Subp, N_Selected_Component, N_Indexed_Component)
4822         or else (Is_Entity_Name (Subp)
4823                   and then Ekind (Entity (Subp)) = E_Entry)
4824       then
4825          Resolve_Entry_Call (N, Typ);
4826          Check_Elab_Call (N);
4827
4828          --  Kill checks and constant values, as above for indirect case
4829          --  Who knows what happens when another task is activated?
4830
4831          Kill_Current_Values;
4832          return;
4833
4834       --  Normal subprogram call with name established in Resolve
4835
4836       elsif not (Is_Type (Entity (Subp))) then
4837          Nam := Entity (Subp);
4838          Set_Entity_With_Style_Check (Subp, Nam);
4839
4840       --  Otherwise we must have the case of an overloaded call
4841
4842       else
4843          pragma Assert (Is_Overloaded (Subp));
4844
4845          --  Initialize Nam to prevent warning (we know it will be assigned
4846          --  in the loop below, but the compiler does not know that).
4847
4848          Nam := Empty;
4849
4850          Get_First_Interp (Subp,  I, It);
4851          while Present (It.Typ) loop
4852             if Covers (Typ, It.Typ) then
4853                Nam := It.Nam;
4854                Set_Entity_With_Style_Check (Subp, Nam);
4855                exit;
4856             end if;
4857
4858             Get_Next_Interp (I, It);
4859          end loop;
4860       end if;
4861
4862       if Is_Access_Subprogram_Type (Base_Type (Etype (Nam)))
4863          and then not Is_Access_Subprogram_Type (Base_Type (Typ))
4864          and then Nkind (Subp) /= N_Explicit_Dereference
4865          and then Present (Parameter_Associations (N))
4866       then
4867          --  The prefix is a parameterless function call that returns an access
4868          --  to subprogram. If parameters are present in the current call, add
4869          --  add an explicit dereference. We use the base type here because
4870          --  within an instance these may be subtypes.
4871
4872          --  The dereference is added either in Analyze_Call or here. Should
4873          --  be consolidated ???
4874
4875          Set_Is_Overloaded (Subp, False);
4876          Set_Etype (Subp, Etype (Nam));
4877          Insert_Explicit_Dereference (Subp);
4878          Nam := Designated_Type (Etype (Nam));
4879          Resolve (Subp, Nam);
4880       end if;
4881
4882       --  Check that a call to Current_Task does not occur in an entry body
4883
4884       if Is_RTE (Nam, RE_Current_Task) then
4885          declare
4886             P : Node_Id;
4887
4888          begin
4889             P := N;
4890             loop
4891                P := Parent (P);
4892
4893                --  Exclude calls that occur within the default of a formal
4894                --  parameter of the entry, since those are evaluated outside
4895                --  of the body.
4896
4897                exit when No (P) or else Nkind (P) = N_Parameter_Specification;
4898
4899                if Nkind (P) = N_Entry_Body
4900                  or else (Nkind (P) = N_Subprogram_Body
4901                            and then Is_Entry_Barrier_Function (P))
4902                then
4903                   Rtype := Etype (N);
4904                   Error_Msg_NE
4905                     ("?& should not be used in entry body (RM C.7(17))",
4906                      N, Nam);
4907                   Error_Msg_NE
4908                     ("\Program_Error will be raised at run time?", N, Nam);
4909                   Rewrite (N,
4910                     Make_Raise_Program_Error (Loc,
4911                       Reason => PE_Current_Task_In_Entry_Body));
4912                   Set_Etype (N, Rtype);
4913                   return;
4914                end if;
4915             end loop;
4916          end;
4917       end if;
4918
4919       --  Check that a procedure call does not occur in the context of the
4920       --  entry call statement of a conditional or timed entry call. Note that
4921       --  the case of a call to a subprogram renaming of an entry will also be
4922       --  rejected. The test for N not being an N_Entry_Call_Statement is
4923       --  defensive, covering the possibility that the processing of entry
4924       --  calls might reach this point due to later modifications of the code
4925       --  above.
4926
4927       if Nkind (Parent (N)) = N_Entry_Call_Alternative
4928         and then Nkind (N) /= N_Entry_Call_Statement
4929         and then Entry_Call_Statement (Parent (N)) = N
4930       then
4931          if Ada_Version < Ada_05 then
4932             Error_Msg_N ("entry call required in select statement", N);
4933
4934          --  Ada 2005 (AI-345): If a procedure_call_statement is used
4935          --  for a procedure_or_entry_call, the procedure_name or
4936          --  procedure_prefix of the procedure_call_statement shall denote
4937          --  an entry renamed by a procedure, or (a view of) a primitive
4938          --  subprogram of a limited interface whose first parameter is
4939          --  a controlling parameter.
4940
4941          elsif Nkind (N) = N_Procedure_Call_Statement
4942            and then not Is_Renamed_Entry (Nam)
4943            and then not Is_Controlling_Limited_Procedure (Nam)
4944          then
4945             Error_Msg_N
4946              ("entry call or dispatching primitive of interface required", N);
4947          end if;
4948       end if;
4949
4950       --  Check that this is not a call to a protected procedure or entry from
4951       --  within a protected function.
4952
4953       if Ekind (Current_Scope) = E_Function
4954         and then Ekind (Scope (Current_Scope)) = E_Protected_Type
4955         and then Ekind (Nam) /= E_Function
4956         and then Scope (Nam) = Scope (Current_Scope)
4957       then
4958          Error_Msg_N ("within protected function, protected " &
4959            "object is constant", N);
4960          Error_Msg_N ("\cannot call operation that may modify it", N);
4961       end if;
4962
4963       --  Freeze the subprogram name if not in a spec-expression. Note that we
4964       --  freeze procedure calls as well as function calls. Procedure calls are
4965       --  not frozen according to the rules (RM 13.14(14)) because it is
4966       --  impossible to have a procedure call to a non-frozen procedure in pure
4967       --  Ada, but in the code that we generate in the expander, this rule
4968       --  needs extending because we can generate procedure calls that need
4969       --  freezing.
4970
4971       if Is_Entity_Name (Subp) and then not In_Spec_Expression then
4972          Freeze_Expression (Subp);
4973       end if;
4974
4975       --  For a predefined operator, the type of the result is the type imposed
4976       --  by context, except for a predefined operation on universal fixed.
4977       --  Otherwise The type of the call is the type returned by the subprogram
4978       --  being called.
4979
4980       if Is_Predefined_Op (Nam) then
4981          if Etype (N) /= Universal_Fixed then
4982             Set_Etype (N, Typ);
4983          end if;
4984
4985       --  If the subprogram returns an array type, and the context requires the
4986       --  component type of that array type, the node is really an indexing of
4987       --  the parameterless call. Resolve as such. A pathological case occurs
4988       --  when the type of the component is an access to the array type. In
4989       --  this case the call is truly ambiguous.
4990
4991       elsif (Needs_No_Actuals (Nam) or else Needs_One_Actual (Nam))
4992         and then
4993           ((Is_Array_Type (Etype (Nam))
4994                    and then Covers (Typ, Component_Type (Etype (Nam))))
4995              or else (Is_Access_Type (Etype (Nam))
4996                         and then Is_Array_Type (Designated_Type (Etype (Nam)))
4997                         and then
4998                           Covers (Typ,
4999                             Component_Type (Designated_Type (Etype (Nam))))))
5000       then
5001          declare
5002             Index_Node : Node_Id;
5003             New_Subp   : Node_Id;
5004             Ret_Type   : constant Entity_Id := Etype (Nam);
5005
5006          begin
5007             if Is_Access_Type (Ret_Type)
5008               and then Ret_Type = Component_Type (Designated_Type (Ret_Type))
5009             then
5010                Error_Msg_N
5011                  ("cannot disambiguate function call and indexing", N);
5012             else
5013                New_Subp := Relocate_Node (Subp);
5014                Set_Entity (Subp, Nam);
5015
5016                if (Is_Array_Type (Ret_Type)
5017                     and then Component_Type (Ret_Type) /= Any_Type)
5018                  or else
5019                   (Is_Access_Type (Ret_Type)
5020                     and then
5021                       Component_Type (Designated_Type (Ret_Type)) /= Any_Type)
5022                then
5023                   if Needs_No_Actuals (Nam) then
5024
5025                      --  Indexed call to a parameterless function
5026
5027                      Index_Node :=
5028                        Make_Indexed_Component (Loc,
5029                          Prefix =>
5030                            Make_Function_Call (Loc,
5031                              Name => New_Subp),
5032                          Expressions => Parameter_Associations (N));
5033                   else
5034                      --  An Ada 2005 prefixed call to a primitive operation
5035                      --  whose first parameter is the prefix. This prefix was
5036                      --  prepended to the parameter list, which is actually a
5037                      --  list of indices. Remove the prefix in order to build
5038                      --  the proper indexed component.
5039
5040                      Index_Node :=
5041                         Make_Indexed_Component (Loc,
5042                           Prefix =>
5043                             Make_Function_Call (Loc,
5044                                Name => New_Subp,
5045                                Parameter_Associations =>
5046                                  New_List
5047                                    (Remove_Head (Parameter_Associations (N)))),
5048                            Expressions => Parameter_Associations (N));
5049                   end if;
5050
5051                   --  Since we are correcting a node classification error made
5052                   --  by the parser, we call Replace rather than Rewrite.
5053
5054                   Replace (N, Index_Node);
5055                   Set_Etype (Prefix (N), Ret_Type);
5056                   Set_Etype (N, Typ);
5057                   Resolve_Indexed_Component (N, Typ);
5058                   Check_Elab_Call (Prefix (N));
5059                end if;
5060             end if;
5061
5062             return;
5063          end;
5064
5065       else
5066          Set_Etype (N, Etype (Nam));
5067       end if;
5068
5069       --  In the case where the call is to an overloaded subprogram, Analyze
5070       --  calls Normalize_Actuals once per overloaded subprogram. Therefore in
5071       --  such a case Normalize_Actuals needs to be called once more to order
5072       --  the actuals correctly. Otherwise the call will have the ordering
5073       --  given by the last overloaded subprogram whether this is the correct
5074       --  one being called or not.
5075
5076       if Is_Overloaded (Subp) then
5077          Normalize_Actuals (N, Nam, False, Norm_OK);
5078          pragma Assert (Norm_OK);
5079       end if;
5080
5081       --  In any case, call is fully resolved now. Reset Overload flag, to
5082       --  prevent subsequent overload resolution if node is analyzed again
5083
5084       Set_Is_Overloaded (Subp, False);
5085       Set_Is_Overloaded (N, False);
5086
5087       --  If we are calling the current subprogram from immediately within its
5088       --  body, then that is the case where we can sometimes detect cases of
5089       --  infinite recursion statically. Do not try this in case restriction
5090       --  No_Recursion is in effect anyway, and do it only for source calls.
5091
5092       if Comes_From_Source (N) then
5093          Scop := Current_Scope;
5094
5095          --  Issue warning for possible infinite recursion in the absence
5096          --  of the No_Recursion restriction.
5097
5098          if Nam = Scop
5099            and then not Restriction_Active (No_Recursion)
5100            and then Check_Infinite_Recursion (N)
5101          then
5102             --  Here we detected and flagged an infinite recursion, so we do
5103             --  not need to test the case below for further warnings. Also if
5104             --  we now have a raise SE node, we are all done.
5105
5106             if Nkind (N) = N_Raise_Storage_Error then
5107                return;
5108             end if;
5109
5110          --  If call is to immediately containing subprogram, then check for
5111          --  the case of a possible run-time detectable infinite recursion.
5112
5113          else
5114             Scope_Loop : while Scop /= Standard_Standard loop
5115                if Nam = Scop then
5116
5117                   --  Although in general case, recursion is not statically
5118                   --  checkable, the case of calling an immediately containing
5119                   --  subprogram is easy to catch.
5120
5121                   Check_Restriction (No_Recursion, N);
5122
5123                   --  If the recursive call is to a parameterless subprogram,
5124                   --  then even if we can't statically detect infinite
5125                   --  recursion, this is pretty suspicious, and we output a
5126                   --  warning. Furthermore, we will try later to detect some
5127                   --  cases here at run time by expanding checking code (see
5128                   --  Detect_Infinite_Recursion in package Exp_Ch6).
5129
5130                   --  If the recursive call is within a handler, do not emit a
5131                   --  warning, because this is a common idiom: loop until input
5132                   --  is correct, catch illegal input in handler and restart.
5133
5134                   if No (First_Formal (Nam))
5135                     and then Etype (Nam) = Standard_Void_Type
5136                     and then not Error_Posted (N)
5137                     and then Nkind (Parent (N)) /= N_Exception_Handler
5138                   then
5139                      --  For the case of a procedure call. We give the message
5140                      --  only if the call is the first statement in a sequence
5141                      --  of statements, or if all previous statements are
5142                      --  simple assignments. This is simply a heuristic to
5143                      --  decrease false positives, without losing too many good
5144                      --  warnings. The idea is that these previous statements
5145                      --  may affect global variables the procedure depends on.
5146
5147                      if Nkind (N) = N_Procedure_Call_Statement
5148                        and then Is_List_Member (N)
5149                      then
5150                         declare
5151                            P : Node_Id;
5152                         begin
5153                            P := Prev (N);
5154                            while Present (P) loop
5155                               if Nkind (P) /= N_Assignment_Statement then
5156                                  exit Scope_Loop;
5157                               end if;
5158
5159                               Prev (P);
5160                            end loop;
5161                         end;
5162                      end if;
5163
5164                      --  Do not give warning if we are in a conditional context
5165
5166                      declare
5167                         K : constant Node_Kind := Nkind (Parent (N));
5168                      begin
5169                         if (K = N_Loop_Statement
5170                             and then Present (Iteration_Scheme (Parent (N))))
5171                           or else K = N_If_Statement
5172                           or else K = N_Elsif_Part
5173                           or else K = N_Case_Statement_Alternative
5174                         then
5175                            exit Scope_Loop;
5176                         end if;
5177                      end;
5178
5179                      --  Here warning is to be issued
5180
5181                      Set_Has_Recursive_Call (Nam);
5182                      Error_Msg_N
5183                        ("?possible infinite recursion!", N);
5184                      Error_Msg_N
5185                        ("\?Storage_Error may be raised at run time!", N);
5186                   end if;
5187
5188                   exit Scope_Loop;
5189                end if;
5190
5191                Scop := Scope (Scop);
5192             end loop Scope_Loop;
5193          end if;
5194       end if;
5195
5196       --  If subprogram name is a predefined operator, it was given in
5197       --  functional notation. Replace call node with operator node, so
5198       --  that actuals can be resolved appropriately.
5199
5200       if Is_Predefined_Op (Nam) or else Ekind (Nam) = E_Operator then
5201          Make_Call_Into_Operator (N, Typ, Entity (Name (N)));
5202          return;
5203
5204       elsif Present (Alias (Nam))
5205         and then Is_Predefined_Op (Alias (Nam))
5206       then
5207          Resolve_Actuals (N, Nam);
5208          Make_Call_Into_Operator (N, Typ, Alias (Nam));
5209          return;
5210       end if;
5211
5212       --  Create a transient scope if the resulting type requires it
5213
5214       --  There are several notable exceptions:
5215
5216       --  a) In init procs, the transient scope overhead is not needed, and is
5217       --  even incorrect when the call is a nested initialization call for a
5218       --  component whose expansion may generate adjust calls. However, if the
5219       --  call is some other procedure call within an initialization procedure
5220       --  (for example a call to Create_Task in the init_proc of the task
5221       --  run-time record) a transient scope must be created around this call.
5222
5223       --  b) Enumeration literal pseudo-calls need no transient scope
5224
5225       --  c) Intrinsic subprograms (Unchecked_Conversion and source info
5226       --  functions) do not use the secondary stack even though the return
5227       --  type may be unconstrained.
5228
5229       --  d) Calls to a build-in-place function, since such functions may
5230       --  allocate their result directly in a target object, and cases where
5231       --  the result does get allocated in the secondary stack are checked for
5232       --  within the specialized Exp_Ch6 procedures for expanding those
5233       --  build-in-place calls.
5234
5235       --  e) If the subprogram is marked Inline_Always, then even if it returns
5236       --  an unconstrained type the call does not require use of the secondary
5237       --  stack. However, inlining will only take place if the body to inline
5238       --  is already present. It may not be available if e.g. the subprogram is
5239       --  declared in a child instance.
5240
5241       --  If this is an initialization call for a type whose construction
5242       --  uses the secondary stack, and it is not a nested call to initialize
5243       --  a component, we do need to create a transient scope for it. We
5244       --  check for this by traversing the type in Check_Initialization_Call.
5245
5246       if Is_Inlined (Nam)
5247         and then Has_Pragma_Inline_Always (Nam)
5248         and then Nkind (Unit_Declaration_Node (Nam)) = N_Subprogram_Declaration
5249         and then Present (Body_To_Inline (Unit_Declaration_Node (Nam)))
5250       then
5251          null;
5252
5253       elsif Ekind (Nam) = E_Enumeration_Literal
5254         or else Is_Build_In_Place_Function (Nam)
5255         or else Is_Intrinsic_Subprogram (Nam)
5256       then
5257          null;
5258
5259       elsif Expander_Active
5260         and then Is_Type (Etype (Nam))
5261         and then Requires_Transient_Scope (Etype (Nam))
5262         and then
5263           (not Within_Init_Proc
5264             or else
5265               (not Is_Init_Proc (Nam) and then Ekind (Nam) /= E_Function))
5266       then
5267          Establish_Transient_Scope (N, Sec_Stack => True);
5268
5269          --  If the call appears within the bounds of a loop, it will
5270          --  be rewritten and reanalyzed, nothing left to do here.
5271
5272          if Nkind (N) /= N_Function_Call then
5273             return;
5274          end if;
5275
5276       elsif Is_Init_Proc (Nam)
5277         and then not Within_Init_Proc
5278       then
5279          Check_Initialization_Call (N, Nam);
5280       end if;
5281
5282       --  A protected function cannot be called within the definition of the
5283       --  enclosing protected type.
5284
5285       if Is_Protected_Type (Scope (Nam))
5286         and then In_Open_Scopes (Scope (Nam))
5287         and then not Has_Completion (Scope (Nam))
5288       then
5289          Error_Msg_NE
5290            ("& cannot be called before end of protected definition", N, Nam);
5291       end if;
5292
5293       --  Propagate interpretation to actuals, and add default expressions
5294       --  where needed.
5295
5296       if Present (First_Formal (Nam)) then
5297          Resolve_Actuals (N, Nam);
5298
5299       --  Overloaded literals are rewritten as function calls, for purpose of
5300       --  resolution. After resolution, we can replace the call with the
5301       --  literal itself.
5302
5303       elsif Ekind (Nam) = E_Enumeration_Literal then
5304          Copy_Node (Subp, N);
5305          Resolve_Entity_Name (N, Typ);
5306
5307          --  Avoid validation, since it is a static function call
5308
5309          Generate_Reference (Nam, Subp);
5310          return;
5311       end if;
5312
5313       --  If the subprogram is not global, then kill all saved values and
5314       --  checks. This is a bit conservative, since in many cases we could do
5315       --  better, but it is not worth the effort. Similarly, we kill constant
5316       --  values. However we do not need to do this for internal entities
5317       --  (unless they are inherited user-defined subprograms), since they
5318       --  are not in the business of molesting local values.
5319
5320       --  If the flag Suppress_Value_Tracking_On_Calls is set, then we also
5321       --  kill all checks and values for calls to global subprograms. This
5322       --  takes care of the case where an access to a local subprogram is
5323       --  taken, and could be passed directly or indirectly and then called
5324       --  from almost any context.
5325
5326       --  Note: we do not do this step till after resolving the actuals. That
5327       --  way we still take advantage of the current value information while
5328       --  scanning the actuals.
5329
5330       --  We suppress killing values if we are processing the nodes associated
5331       --  with N_Freeze_Entity nodes. Otherwise the declaration of a tagged
5332       --  type kills all the values as part of analyzing the code that
5333       --  initializes the dispatch tables.
5334
5335       if Inside_Freezing_Actions = 0
5336         and then (not Is_Library_Level_Entity (Nam)
5337                    or else Suppress_Value_Tracking_On_Call
5338                              (Nearest_Dynamic_Scope (Current_Scope)))
5339         and then (Comes_From_Source (Nam)
5340                    or else (Present (Alias (Nam))
5341                              and then Comes_From_Source (Alias (Nam))))
5342       then
5343          Kill_Current_Values;
5344       end if;
5345
5346       --  If we are warning about unread OUT parameters, this is the place to
5347       --  set Last_Assignment for OUT and IN OUT parameters. We have to do this
5348       --  after the above call to Kill_Current_Values (since that call clears
5349       --  the Last_Assignment field of all local variables).
5350
5351       if (Warn_On_Modified_Unread or Warn_On_All_Unread_Out_Parameters)
5352         and then Comes_From_Source (N)
5353         and then In_Extended_Main_Source_Unit (N)
5354       then
5355          declare
5356             F : Entity_Id;
5357             A : Node_Id;
5358
5359          begin
5360             F := First_Formal (Nam);
5361             A := First_Actual (N);
5362             while Present (F) and then Present (A) loop
5363                if (Ekind (F) = E_Out_Parameter
5364                      or else
5365                    Ekind (F) = E_In_Out_Parameter)
5366                  and then Warn_On_Modified_As_Out_Parameter (F)
5367                  and then Is_Entity_Name (A)
5368                  and then Present (Entity (A))
5369                  and then Comes_From_Source (N)
5370                  and then Safe_To_Capture_Value (N, Entity (A))
5371                then
5372                   Set_Last_Assignment (Entity (A), A);
5373                end if;
5374
5375                Next_Formal (F);
5376                Next_Actual (A);
5377             end loop;
5378          end;
5379       end if;
5380
5381       --  If the subprogram is a primitive operation, check whether or not
5382       --  it is a correct dispatching call.
5383
5384       if Is_Overloadable (Nam)
5385         and then Is_Dispatching_Operation (Nam)
5386       then
5387          Check_Dispatching_Call (N);
5388
5389       elsif Ekind (Nam) /= E_Subprogram_Type
5390         and then Is_Abstract_Subprogram (Nam)
5391         and then not In_Instance
5392       then
5393          Error_Msg_NE ("cannot call abstract subprogram &!", N, Nam);
5394       end if;
5395
5396       --  If this is a dispatching call, generate the appropriate reference,
5397       --  for better source navigation in GPS.
5398
5399       if Is_Overloadable (Nam)
5400         and then Present (Controlling_Argument (N))
5401       then
5402          Generate_Reference (Nam, Subp, 'R');
5403
5404       --  Normal case, not a dispatching call
5405
5406       else
5407          Generate_Reference (Nam, Subp);
5408       end if;
5409
5410       if Is_Intrinsic_Subprogram (Nam) then
5411          Check_Intrinsic_Call (N);
5412       end if;
5413
5414       --  Check for violation of restriction No_Specific_Termination_Handlers
5415       --  and warn on a potentially blocking call to Abort_Task.
5416
5417       if Is_RTE (Nam, RE_Set_Specific_Handler)
5418            or else
5419          Is_RTE (Nam, RE_Specific_Handler)
5420       then
5421          Check_Restriction (No_Specific_Termination_Handlers, N);
5422
5423       elsif Is_RTE (Nam, RE_Abort_Task) then
5424          Check_Potentially_Blocking_Operation (N);
5425       end if;
5426
5427       --  Issue an error for a call to an eliminated subprogram
5428
5429       Check_For_Eliminated_Subprogram (Subp, Nam);
5430
5431       --  All done, evaluate call and deal with elaboration issues
5432
5433       Eval_Call (N);
5434       Check_Elab_Call (N);
5435       Warn_On_Overlapping_Actuals (Nam, N);
5436    end Resolve_Call;
5437
5438    -------------------------------
5439    -- Resolve_Character_Literal --
5440    -------------------------------
5441
5442    procedure Resolve_Character_Literal (N : Node_Id; Typ : Entity_Id) is
5443       B_Typ : constant Entity_Id := Base_Type (Typ);
5444       C     : Entity_Id;
5445
5446    begin
5447       --  Verify that the character does belong to the type of the context
5448
5449       Set_Etype (N, B_Typ);
5450       Eval_Character_Literal (N);
5451
5452       --  Wide_Wide_Character literals must always be defined, since the set
5453       --  of wide wide character literals is complete, i.e. if a character
5454       --  literal is accepted by the parser, then it is OK for wide wide
5455       --  character (out of range character literals are rejected).
5456
5457       if Root_Type (B_Typ) = Standard_Wide_Wide_Character then
5458          return;
5459
5460       --  Always accept character literal for type Any_Character, which
5461       --  occurs in error situations and in comparisons of literals, both
5462       --  of which should accept all literals.
5463
5464       elsif B_Typ = Any_Character then
5465          return;
5466
5467       --  For Standard.Character or a type derived from it, check that
5468       --  the literal is in range
5469
5470       elsif Root_Type (B_Typ) = Standard_Character then
5471          if In_Character_Range (UI_To_CC (Char_Literal_Value (N))) then
5472             return;
5473          end if;
5474
5475       --  For Standard.Wide_Character or a type derived from it, check
5476       --  that the literal is in range
5477
5478       elsif Root_Type (B_Typ) = Standard_Wide_Character then
5479          if In_Wide_Character_Range (UI_To_CC (Char_Literal_Value (N))) then
5480             return;
5481          end if;
5482
5483       --  For Standard.Wide_Wide_Character or a type derived from it, we
5484       --  know the literal is in range, since the parser checked!
5485
5486       elsif Root_Type (B_Typ) = Standard_Wide_Wide_Character then
5487          return;
5488
5489       --  If the entity is already set, this has already been resolved in a
5490       --  generic context, or comes from expansion. Nothing else to do.
5491
5492       elsif Present (Entity (N)) then
5493          return;
5494
5495       --  Otherwise we have a user defined character type, and we can use the
5496       --  standard visibility mechanisms to locate the referenced entity.
5497
5498       else
5499          C := Current_Entity (N);
5500          while Present (C) loop
5501             if Etype (C) = B_Typ then
5502                Set_Entity_With_Style_Check (N, C);
5503                Generate_Reference (C, N);
5504                return;
5505             end if;
5506
5507             C := Homonym (C);
5508          end loop;
5509       end if;
5510
5511       --  If we fall through, then the literal does not match any of the
5512       --  entries of the enumeration type. This isn't just a constraint
5513       --  error situation, it is an illegality (see RM 4.2).
5514
5515       Error_Msg_NE
5516         ("character not defined for }", N, First_Subtype (B_Typ));
5517    end Resolve_Character_Literal;
5518
5519    ---------------------------
5520    -- Resolve_Comparison_Op --
5521    ---------------------------
5522
5523    --  Context requires a boolean type, and plays no role in resolution.
5524    --  Processing identical to that for equality operators. The result
5525    --  type is the base type, which matters when pathological subtypes of
5526    --  booleans with limited ranges are used.
5527
5528    procedure Resolve_Comparison_Op (N : Node_Id; Typ : Entity_Id) is
5529       L : constant Node_Id := Left_Opnd (N);
5530       R : constant Node_Id := Right_Opnd (N);
5531       T : Entity_Id;
5532
5533    begin
5534       --  If this is an intrinsic operation which is not predefined, use the
5535       --  types of its declared arguments to resolve the possibly overloaded
5536       --  operands. Otherwise the operands are unambiguous and specify the
5537       --  expected type.
5538
5539       if Scope (Entity (N)) /= Standard_Standard then
5540          T := Etype (First_Entity (Entity (N)));
5541
5542       else
5543          T := Find_Unique_Type (L, R);
5544
5545          if T = Any_Fixed then
5546             T := Unique_Fixed_Point_Type (L);
5547          end if;
5548       end if;
5549
5550       Set_Etype (N, Base_Type (Typ));
5551       Generate_Reference (T, N, ' ');
5552
5553       if T /= Any_Type then
5554          if T = Any_String    or else
5555             T = Any_Composite or else
5556             T = Any_Character
5557          then
5558             if T = Any_Character then
5559                Ambiguous_Character (L);
5560             else
5561                Error_Msg_N ("ambiguous operands for comparison", N);
5562             end if;
5563
5564             Set_Etype (N, Any_Type);
5565             return;
5566
5567          else
5568             Resolve (L, T);
5569             Resolve (R, T);
5570             Check_Unset_Reference (L);
5571             Check_Unset_Reference (R);
5572             Generate_Operator_Reference (N, T);
5573             Check_Low_Bound_Tested (N);
5574             Eval_Relational_Op (N);
5575          end if;
5576       end if;
5577    end Resolve_Comparison_Op;
5578
5579    ------------------------------------
5580    -- Resolve_Conditional_Expression --
5581    ------------------------------------
5582
5583    procedure Resolve_Conditional_Expression (N : Node_Id; Typ : Entity_Id) is
5584       Condition : constant Node_Id := First (Expressions (N));
5585       Then_Expr : constant Node_Id := Next (Condition);
5586       Else_Expr : Node_Id := Next (Then_Expr);
5587
5588    begin
5589       Resolve (Condition, Any_Boolean);
5590       Resolve (Then_Expr, Typ);
5591
5592       --  If ELSE expression present, just resolve using the determined type
5593
5594       if Present (Else_Expr) then
5595          Resolve (Else_Expr, Typ);
5596
5597       --  If no ELSE expression is present, root type must be Standard.Boolean
5598       --  and we provide a Standard.True result converted to the appropriate
5599       --  Boolean type (in case it is a derived boolean type).
5600
5601       elsif Root_Type (Typ) = Standard_Boolean then
5602          Else_Expr :=
5603            Convert_To (Typ, New_Occurrence_Of (Standard_True, Sloc (N)));
5604          Analyze_And_Resolve (Else_Expr, Typ);
5605          Append_To (Expressions (N), Else_Expr);
5606
5607       else
5608          Error_Msg_N ("can only omit ELSE expression in Boolean case", N);
5609          Append_To (Expressions (N), Error);
5610       end if;
5611
5612       Set_Etype (N, Typ);
5613       Eval_Conditional_Expression (N);
5614    end Resolve_Conditional_Expression;
5615
5616    -----------------------------------------
5617    -- Resolve_Discrete_Subtype_Indication --
5618    -----------------------------------------
5619
5620    procedure Resolve_Discrete_Subtype_Indication
5621      (N   : Node_Id;
5622       Typ : Entity_Id)
5623    is
5624       R : Node_Id;
5625       S : Entity_Id;
5626
5627    begin
5628       Analyze (Subtype_Mark (N));
5629       S := Entity (Subtype_Mark (N));
5630
5631       if Nkind (Constraint (N)) /= N_Range_Constraint then
5632          Error_Msg_N ("expect range constraint for discrete type", N);
5633          Set_Etype (N, Any_Type);
5634
5635       else
5636          R := Range_Expression (Constraint (N));
5637
5638          if R = Error then
5639             return;
5640          end if;
5641
5642          Analyze (R);
5643
5644          if Base_Type (S) /= Base_Type (Typ) then
5645             Error_Msg_NE
5646               ("expect subtype of }", N, First_Subtype (Typ));
5647
5648             --  Rewrite the constraint as a range of Typ
5649             --  to allow compilation to proceed further.
5650
5651             Set_Etype (N, Typ);
5652             Rewrite (Low_Bound (R),
5653               Make_Attribute_Reference (Sloc (Low_Bound (R)),
5654                 Prefix =>         New_Occurrence_Of (Typ, Sloc (R)),
5655                 Attribute_Name => Name_First));
5656             Rewrite (High_Bound (R),
5657               Make_Attribute_Reference (Sloc (High_Bound (R)),
5658                 Prefix =>         New_Occurrence_Of (Typ, Sloc (R)),
5659                 Attribute_Name => Name_First));
5660
5661          else
5662             Resolve (R, Typ);
5663             Set_Etype (N, Etype (R));
5664
5665             --  Additionally, we must check that the bounds are compatible
5666             --  with the given subtype, which might be different from the
5667             --  type of the context.
5668
5669             Apply_Range_Check (R, S);
5670
5671             --  ??? If the above check statically detects a Constraint_Error
5672             --  it replaces the offending bound(s) of the range R with a
5673             --  Constraint_Error node. When the itype which uses these bounds
5674             --  is frozen the resulting call to Duplicate_Subexpr generates
5675             --  a new temporary for the bounds.
5676
5677             --  Unfortunately there are other itypes that are also made depend
5678             --  on these bounds, so when Duplicate_Subexpr is called they get
5679             --  a forward reference to the newly created temporaries and Gigi
5680             --  aborts on such forward references. This is probably sign of a
5681             --  more fundamental problem somewhere else in either the order of
5682             --  itype freezing or the way certain itypes are constructed.
5683
5684             --  To get around this problem we call Remove_Side_Effects right
5685             --  away if either bounds of R are a Constraint_Error.
5686
5687             declare
5688                L : constant Node_Id := Low_Bound (R);
5689                H : constant Node_Id := High_Bound (R);
5690
5691             begin
5692                if Nkind (L) = N_Raise_Constraint_Error then
5693                   Remove_Side_Effects (L);
5694                end if;
5695
5696                if Nkind (H) = N_Raise_Constraint_Error then
5697                   Remove_Side_Effects (H);
5698                end if;
5699             end;
5700
5701             Check_Unset_Reference (Low_Bound  (R));
5702             Check_Unset_Reference (High_Bound (R));
5703          end if;
5704       end if;
5705    end Resolve_Discrete_Subtype_Indication;
5706
5707    -------------------------
5708    -- Resolve_Entity_Name --
5709    -------------------------
5710
5711    --  Used to resolve identifiers and expanded names
5712
5713    procedure Resolve_Entity_Name (N : Node_Id; Typ : Entity_Id) is
5714       E : constant Entity_Id := Entity (N);
5715
5716    begin
5717       --  If garbage from errors, set to Any_Type and return
5718
5719       if No (E) and then Total_Errors_Detected /= 0 then
5720          Set_Etype (N, Any_Type);
5721          return;
5722       end if;
5723
5724       --  Replace named numbers by corresponding literals. Note that this is
5725       --  the one case where Resolve_Entity_Name must reset the Etype, since
5726       --  it is currently marked as universal.
5727
5728       if Ekind (E) = E_Named_Integer then
5729          Set_Etype (N, Typ);
5730          Eval_Named_Integer (N);
5731
5732       elsif Ekind (E) = E_Named_Real then
5733          Set_Etype (N, Typ);
5734          Eval_Named_Real (N);
5735
5736       --  Allow use of subtype only if it is a concurrent type where we are
5737       --  currently inside the body. This will eventually be expanded into a
5738       --  call to Self (for tasks) or _object (for protected objects). Any
5739       --  other use of a subtype is invalid.
5740
5741       elsif Is_Type (E) then
5742          if Is_Concurrent_Type (E)
5743            and then In_Open_Scopes (E)
5744          then
5745             null;
5746          else
5747             Error_Msg_N
5748                ("invalid use of subtype mark in expression or call", N);
5749          end if;
5750
5751       --  Check discriminant use if entity is discriminant in current scope,
5752       --  i.e. discriminant of record or concurrent type currently being
5753       --  analyzed. Uses in corresponding body are unrestricted.
5754
5755       elsif Ekind (E) = E_Discriminant
5756         and then Scope (E) = Current_Scope
5757         and then not Has_Completion (Current_Scope)
5758       then
5759          Check_Discriminant_Use (N);
5760
5761       --  A parameterless generic function cannot appear in a context that
5762       --  requires resolution.
5763
5764       elsif Ekind (E) = E_Generic_Function then
5765          Error_Msg_N ("illegal use of generic function", N);
5766
5767       elsif Ekind (E) = E_Out_Parameter
5768         and then Ada_Version = Ada_83
5769         and then (Nkind (Parent (N)) in N_Op
5770                     or else (Nkind (Parent (N)) = N_Assignment_Statement
5771                               and then N = Expression (Parent (N)))
5772                     or else Nkind (Parent (N)) = N_Explicit_Dereference)
5773       then
5774          Error_Msg_N ("(Ada 83) illegal reading of out parameter", N);
5775
5776       --  In all other cases, just do the possible static evaluation
5777
5778       else
5779          --  A deferred constant that appears in an expression must have a
5780          --  completion, unless it has been removed by in-place expansion of
5781          --  an aggregate.
5782
5783          if Ekind (E) = E_Constant
5784            and then Comes_From_Source (E)
5785            and then No (Constant_Value (E))
5786            and then Is_Frozen (Etype (E))
5787            and then not In_Spec_Expression
5788            and then not Is_Imported (E)
5789          then
5790
5791             if No_Initialization (Parent (E))
5792               or else (Present (Full_View (E))
5793                         and then No_Initialization (Parent (Full_View (E))))
5794             then
5795                null;
5796             else
5797                Error_Msg_N (
5798                  "deferred constant is frozen before completion", N);
5799             end if;
5800          end if;
5801
5802          Eval_Entity_Name (N);
5803       end if;
5804    end Resolve_Entity_Name;
5805
5806    -------------------
5807    -- Resolve_Entry --
5808    -------------------
5809
5810    procedure Resolve_Entry (Entry_Name : Node_Id) is
5811       Loc    : constant Source_Ptr := Sloc (Entry_Name);
5812       Nam    : Entity_Id;
5813       New_N  : Node_Id;
5814       S      : Entity_Id;
5815       Tsk    : Entity_Id;
5816       E_Name : Node_Id;
5817       Index  : Node_Id;
5818
5819       function Actual_Index_Type (E : Entity_Id) return Entity_Id;
5820       --  If the bounds of the entry family being called depend on task
5821       --  discriminants, build a new index subtype where a discriminant is
5822       --  replaced with the value of the discriminant of the target task.
5823       --  The target task is the prefix of the entry name in the call.
5824
5825       -----------------------
5826       -- Actual_Index_Type --
5827       -----------------------
5828
5829       function Actual_Index_Type (E : Entity_Id) return Entity_Id is
5830          Typ   : constant Entity_Id := Entry_Index_Type (E);
5831          Tsk   : constant Entity_Id := Scope (E);
5832          Lo    : constant Node_Id   := Type_Low_Bound  (Typ);
5833          Hi    : constant Node_Id   := Type_High_Bound (Typ);
5834          New_T : Entity_Id;
5835
5836          function Actual_Discriminant_Ref (Bound : Node_Id) return Node_Id;
5837          --  If the bound is given by a discriminant, replace with a reference
5838          --  to the discriminant of the same name in the target task. If the
5839          --  entry name is the target of a requeue statement and the entry is
5840          --  in the current protected object, the bound to be used is the
5841          --  discriminal of the object (see apply_range_checks for details of
5842          --  the transformation).
5843
5844          -----------------------------
5845          -- Actual_Discriminant_Ref --
5846          -----------------------------
5847
5848          function Actual_Discriminant_Ref (Bound : Node_Id) return Node_Id is
5849             Typ : constant Entity_Id := Etype (Bound);
5850             Ref : Node_Id;
5851
5852          begin
5853             Remove_Side_Effects (Bound);
5854
5855             if not Is_Entity_Name (Bound)
5856               or else Ekind (Entity (Bound)) /= E_Discriminant
5857             then
5858                return Bound;
5859
5860             elsif Is_Protected_Type (Tsk)
5861               and then In_Open_Scopes (Tsk)
5862               and then Nkind (Parent (Entry_Name)) = N_Requeue_Statement
5863             then
5864                return New_Occurrence_Of (Discriminal (Entity (Bound)), Loc);
5865
5866             else
5867                Ref :=
5868                  Make_Selected_Component (Loc,
5869                    Prefix => New_Copy_Tree (Prefix (Prefix (Entry_Name))),
5870                    Selector_Name => New_Occurrence_Of (Entity (Bound), Loc));
5871                Analyze (Ref);
5872                Resolve (Ref, Typ);
5873                return Ref;
5874             end if;
5875          end Actual_Discriminant_Ref;
5876
5877       --  Start of processing for Actual_Index_Type
5878
5879       begin
5880          if not Has_Discriminants (Tsk)
5881            or else (not Is_Entity_Name (Lo)
5882                      and then
5883                     not Is_Entity_Name (Hi))
5884          then
5885             return Entry_Index_Type (E);
5886
5887          else
5888             New_T := Create_Itype (Ekind (Typ), Parent (Entry_Name));
5889             Set_Etype        (New_T, Base_Type (Typ));
5890             Set_Size_Info    (New_T, Typ);
5891             Set_RM_Size      (New_T, RM_Size (Typ));
5892             Set_Scalar_Range (New_T,
5893               Make_Range (Sloc (Entry_Name),
5894                 Low_Bound  => Actual_Discriminant_Ref (Lo),
5895                 High_Bound => Actual_Discriminant_Ref (Hi)));
5896
5897             return New_T;
5898          end if;
5899       end Actual_Index_Type;
5900
5901    --  Start of processing of Resolve_Entry
5902
5903    begin
5904       --  Find name of entry being called, and resolve prefix of name
5905       --  with its own type. The prefix can be overloaded, and the name
5906       --  and signature of the entry must be taken into account.
5907
5908       if Nkind (Entry_Name) = N_Indexed_Component then
5909
5910          --  Case of dealing with entry family within the current tasks
5911
5912          E_Name := Prefix (Entry_Name);
5913
5914       else
5915          E_Name := Entry_Name;
5916       end if;
5917
5918       if Is_Entity_Name (E_Name) then
5919
5920          --  Entry call to an entry (or entry family) in the current task. This
5921          --  is legal even though the task will deadlock. Rewrite as call to
5922          --  current task.
5923
5924          --  This can also be a call to an entry in an enclosing task. If this
5925          --  is a single task, we have to retrieve its name, because the scope
5926          --  of the entry is the task type, not the object. If the enclosing
5927          --  task is a task type, the identity of the task is given by its own
5928          --  self variable.
5929
5930          --  Finally this can be a requeue on an entry of the same task or
5931          --  protected object.
5932
5933          S := Scope (Entity (E_Name));
5934
5935          for J in reverse 0 .. Scope_Stack.Last loop
5936             if Is_Task_Type (Scope_Stack.Table (J).Entity)
5937               and then not Comes_From_Source (S)
5938             then
5939                --  S is an enclosing task or protected object. The concurrent
5940                --  declaration has been converted into a type declaration, and
5941                --  the object itself has an object declaration that follows
5942                --  the type in the same declarative part.
5943
5944                Tsk := Next_Entity (S);
5945                while Etype (Tsk) /= S loop
5946                   Next_Entity (Tsk);
5947                end loop;
5948
5949                S := Tsk;
5950                exit;
5951
5952             elsif S = Scope_Stack.Table (J).Entity then
5953
5954                --  Call to current task. Will be transformed into call to Self
5955
5956                exit;
5957
5958             end if;
5959          end loop;
5960
5961          New_N :=
5962            Make_Selected_Component (Loc,
5963              Prefix => New_Occurrence_Of (S, Loc),
5964              Selector_Name =>
5965                New_Occurrence_Of (Entity (E_Name), Loc));
5966          Rewrite (E_Name, New_N);
5967          Analyze (E_Name);
5968
5969       elsif Nkind (Entry_Name) = N_Selected_Component
5970         and then Is_Overloaded (Prefix (Entry_Name))
5971       then
5972          --  Use the entry name (which must be unique at this point) to find
5973          --  the prefix that returns the corresponding task type or protected
5974          --  type.
5975
5976          declare
5977             Pref : constant Node_Id := Prefix (Entry_Name);
5978             Ent  : constant Entity_Id :=  Entity (Selector_Name (Entry_Name));
5979             I    : Interp_Index;
5980             It   : Interp;
5981
5982          begin
5983             Get_First_Interp (Pref, I, It);
5984             while Present (It.Typ) loop
5985                if Scope (Ent) = It.Typ then
5986                   Set_Etype (Pref, It.Typ);
5987                   exit;
5988                end if;
5989
5990                Get_Next_Interp (I, It);
5991             end loop;
5992          end;
5993       end if;
5994
5995       if Nkind (Entry_Name) = N_Selected_Component then
5996          Resolve (Prefix (Entry_Name));
5997
5998       else pragma Assert (Nkind (Entry_Name) = N_Indexed_Component);
5999          Nam := Entity (Selector_Name (Prefix (Entry_Name)));
6000          Resolve (Prefix (Prefix (Entry_Name)));
6001          Index :=  First (Expressions (Entry_Name));
6002          Resolve (Index, Entry_Index_Type (Nam));
6003
6004          --  Up to this point the expression could have been the actual in a
6005          --  simple entry call, and be given by a named association.
6006
6007          if Nkind (Index) = N_Parameter_Association then
6008             Error_Msg_N ("expect expression for entry index", Index);
6009          else
6010             Apply_Range_Check (Index, Actual_Index_Type (Nam));
6011          end if;
6012       end if;
6013    end Resolve_Entry;
6014
6015    ------------------------
6016    -- Resolve_Entry_Call --
6017    ------------------------
6018
6019    procedure Resolve_Entry_Call (N : Node_Id; Typ : Entity_Id) is
6020       Entry_Name  : constant Node_Id    := Name (N);
6021       Loc         : constant Source_Ptr := Sloc (Entry_Name);
6022       Actuals     : List_Id;
6023       First_Named : Node_Id;
6024       Nam         : Entity_Id;
6025       Norm_OK     : Boolean;
6026       Obj         : Node_Id;
6027       Was_Over    : Boolean;
6028
6029    begin
6030       --  We kill all checks here, because it does not seem worth the effort to
6031       --  do anything better, an entry call is a big operation.
6032
6033       Kill_All_Checks;
6034
6035       --  Processing of the name is similar for entry calls and protected
6036       --  operation calls. Once the entity is determined, we can complete
6037       --  the resolution of the actuals.
6038
6039       --  The selector may be overloaded, in the case of a protected object
6040       --  with overloaded functions. The type of the context is used for
6041       --  resolution.
6042
6043       if Nkind (Entry_Name) = N_Selected_Component
6044         and then Is_Overloaded (Selector_Name (Entry_Name))
6045         and then Typ /= Standard_Void_Type
6046       then
6047          declare
6048             I  : Interp_Index;
6049             It : Interp;
6050
6051          begin
6052             Get_First_Interp (Selector_Name (Entry_Name), I, It);
6053             while Present (It.Typ) loop
6054                if Covers (Typ, It.Typ) then
6055                   Set_Entity (Selector_Name (Entry_Name), It.Nam);
6056                   Set_Etype  (Entry_Name, It.Typ);
6057
6058                   Generate_Reference (It.Typ, N, ' ');
6059                end if;
6060
6061                Get_Next_Interp (I, It);
6062             end loop;
6063          end;
6064       end if;
6065
6066       Resolve_Entry (Entry_Name);
6067
6068       if Nkind (Entry_Name) = N_Selected_Component then
6069
6070          --  Simple entry call
6071
6072          Nam := Entity (Selector_Name (Entry_Name));
6073          Obj := Prefix (Entry_Name);
6074          Was_Over := Is_Overloaded (Selector_Name (Entry_Name));
6075
6076       else pragma Assert (Nkind (Entry_Name) = N_Indexed_Component);
6077
6078          --  Call to member of entry family
6079
6080          Nam := Entity (Selector_Name (Prefix (Entry_Name)));
6081          Obj := Prefix (Prefix (Entry_Name));
6082          Was_Over := Is_Overloaded (Selector_Name (Prefix (Entry_Name)));
6083       end if;
6084
6085       --  We cannot in general check the maximum depth of protected entry
6086       --  calls at compile time. But we can tell that any protected entry
6087       --  call at all violates a specified nesting depth of zero.
6088
6089       if Is_Protected_Type (Scope (Nam)) then
6090          Check_Restriction (Max_Entry_Queue_Length, N);
6091       end if;
6092
6093       --  Use context type to disambiguate a protected function that can be
6094       --  called without actuals and that returns an array type, and where
6095       --  the argument list may be an indexing of the returned value.
6096
6097       if Ekind (Nam) = E_Function
6098         and then Needs_No_Actuals (Nam)
6099         and then Present (Parameter_Associations (N))
6100         and then
6101           ((Is_Array_Type (Etype (Nam))
6102              and then Covers (Typ, Component_Type (Etype (Nam))))
6103
6104             or else (Is_Access_Type (Etype (Nam))
6105                       and then Is_Array_Type (Designated_Type (Etype (Nam)))
6106                       and then Covers (Typ,
6107                         Component_Type (Designated_Type (Etype (Nam))))))
6108       then
6109          declare
6110             Index_Node : Node_Id;
6111
6112          begin
6113             Index_Node :=
6114               Make_Indexed_Component (Loc,
6115                 Prefix =>
6116                   Make_Function_Call (Loc,
6117                     Name => Relocate_Node (Entry_Name)),
6118                 Expressions => Parameter_Associations (N));
6119
6120             --  Since we are correcting a node classification error made by
6121             --  the parser, we call Replace rather than Rewrite.
6122
6123             Replace (N, Index_Node);
6124             Set_Etype (Prefix (N), Etype (Nam));
6125             Set_Etype (N, Typ);
6126             Resolve_Indexed_Component (N, Typ);
6127             return;
6128          end;
6129       end if;
6130
6131       --  The operation name may have been overloaded. Order the actuals
6132       --  according to the formals of the resolved entity, and set the
6133       --  return type to that of the operation.
6134
6135       if Was_Over then
6136          Normalize_Actuals (N, Nam, False, Norm_OK);
6137          pragma Assert (Norm_OK);
6138          Set_Etype (N, Etype (Nam));
6139       end if;
6140
6141       Resolve_Actuals (N, Nam);
6142       Generate_Reference (Nam, Entry_Name);
6143
6144       if Ekind (Nam) = E_Entry
6145         or else Ekind (Nam) = E_Entry_Family
6146       then
6147          Check_Potentially_Blocking_Operation (N);
6148       end if;
6149
6150       --  Verify that a procedure call cannot masquerade as an entry
6151       --  call where an entry call is expected.
6152
6153       if Ekind (Nam) = E_Procedure then
6154          if Nkind (Parent (N)) = N_Entry_Call_Alternative
6155            and then N = Entry_Call_Statement (Parent (N))
6156          then
6157             Error_Msg_N ("entry call required in select statement", N);
6158
6159          elsif Nkind (Parent (N)) = N_Triggering_Alternative
6160            and then N = Triggering_Statement (Parent (N))
6161          then
6162             Error_Msg_N ("triggering statement cannot be procedure call", N);
6163
6164          elsif Ekind (Scope (Nam)) = E_Task_Type
6165            and then not In_Open_Scopes (Scope (Nam))
6166          then
6167             Error_Msg_N ("task has no entry with this name", Entry_Name);
6168          end if;
6169       end if;
6170
6171       --  After resolution, entry calls and protected procedure calls are
6172       --  changed into entry calls, for expansion. The structure of the node
6173       --  does not change, so it can safely be done in place. Protected
6174       --  function calls must keep their structure because they are
6175       --  subexpressions.
6176
6177       if Ekind (Nam) /= E_Function then
6178
6179          --  A protected operation that is not a function may modify the
6180          --  corresponding object, and cannot apply to a constant. If this
6181          --  is an internal call, the prefix is the type itself.
6182
6183          if Is_Protected_Type (Scope (Nam))
6184            and then not Is_Variable (Obj)
6185            and then (not Is_Entity_Name (Obj)
6186                        or else not Is_Type (Entity (Obj)))
6187          then
6188             Error_Msg_N
6189               ("prefix of protected procedure or entry call must be variable",
6190                Entry_Name);
6191          end if;
6192
6193          Actuals := Parameter_Associations (N);
6194          First_Named := First_Named_Actual (N);
6195
6196          Rewrite (N,
6197            Make_Entry_Call_Statement (Loc,
6198              Name                   => Entry_Name,
6199              Parameter_Associations => Actuals));
6200
6201          Set_First_Named_Actual (N, First_Named);
6202          Set_Analyzed (N, True);
6203
6204       --  Protected functions can return on the secondary stack, in which
6205       --  case we must trigger the transient scope mechanism.
6206
6207       elsif Expander_Active
6208         and then Requires_Transient_Scope (Etype (Nam))
6209       then
6210          Establish_Transient_Scope (N, Sec_Stack => True);
6211       end if;
6212    end Resolve_Entry_Call;
6213
6214    -------------------------
6215    -- Resolve_Equality_Op --
6216    -------------------------
6217
6218    --  Both arguments must have the same type, and the boolean context does
6219    --  not participate in the resolution. The first pass verifies that the
6220    --  interpretation is not ambiguous, and the type of the left argument is
6221    --  correctly set, or is Any_Type in case of ambiguity. If both arguments
6222    --  are strings or aggregates, allocators, or Null, they are ambiguous even
6223    --  though they carry a single (universal) type. Diagnose this case here.
6224
6225    procedure Resolve_Equality_Op (N : Node_Id; Typ : Entity_Id) is
6226       L : constant Node_Id   := Left_Opnd (N);
6227       R : constant Node_Id   := Right_Opnd (N);
6228       T : Entity_Id := Find_Unique_Type (L, R);
6229
6230       function Find_Unique_Access_Type return Entity_Id;
6231       --  In the case of allocators, make a last-ditch attempt to find a single
6232       --  access type with the right designated type. This is semantically
6233       --  dubious, and of no interest to any real code, but c48008a makes it
6234       --  all worthwhile.
6235
6236       -----------------------------
6237       -- Find_Unique_Access_Type --
6238       -----------------------------
6239
6240       function Find_Unique_Access_Type return Entity_Id is
6241          Acc : Entity_Id;
6242          E   : Entity_Id;
6243          S   : Entity_Id;
6244
6245       begin
6246          if Ekind (Etype (R)) =  E_Allocator_Type then
6247             Acc := Designated_Type (Etype (R));
6248          elsif Ekind (Etype (L)) =  E_Allocator_Type then
6249             Acc := Designated_Type (Etype (L));
6250          else
6251             return Empty;
6252          end if;
6253
6254          S := Current_Scope;
6255          while S /= Standard_Standard loop
6256             E := First_Entity (S);
6257             while Present (E) loop
6258                if Is_Type (E)
6259                  and then Is_Access_Type (E)
6260                  and then Ekind (E) /= E_Allocator_Type
6261                  and then Designated_Type (E) = Base_Type (Acc)
6262                then
6263                   return E;
6264                end if;
6265
6266                Next_Entity (E);
6267             end loop;
6268
6269             S := Scope (S);
6270          end loop;
6271
6272          return Empty;
6273       end Find_Unique_Access_Type;
6274
6275    --  Start of processing for Resolve_Equality_Op
6276
6277    begin
6278       Set_Etype (N, Base_Type (Typ));
6279       Generate_Reference (T, N, ' ');
6280
6281       if T = Any_Fixed then
6282          T := Unique_Fixed_Point_Type (L);
6283       end if;
6284
6285       if T /= Any_Type then
6286          if T = Any_String
6287            or else T = Any_Composite
6288            or else T = Any_Character
6289          then
6290             if T = Any_Character then
6291                Ambiguous_Character (L);
6292             else
6293                Error_Msg_N ("ambiguous operands for equality", N);
6294             end if;
6295
6296             Set_Etype (N, Any_Type);
6297             return;
6298
6299          elsif T = Any_Access
6300            or else Ekind (T) = E_Allocator_Type
6301            or else Ekind (T) = E_Access_Attribute_Type
6302          then
6303             T := Find_Unique_Access_Type;
6304
6305             if No (T) then
6306                Error_Msg_N ("ambiguous operands for equality", N);
6307                Set_Etype (N, Any_Type);
6308                return;
6309             end if;
6310          end if;
6311
6312          Resolve (L, T);
6313          Resolve (R, T);
6314
6315          --  If the unique type is a class-wide type then it will be expanded
6316          --  into a dispatching call to the predefined primitive. Therefore we
6317          --  check here for potential violation of such restriction.
6318
6319          if Is_Class_Wide_Type (T) then
6320             Check_Restriction (No_Dispatching_Calls, N);
6321          end if;
6322
6323          if Warn_On_Redundant_Constructs
6324            and then Comes_From_Source (N)
6325            and then Is_Entity_Name (R)
6326            and then Entity (R) = Standard_True
6327            and then Comes_From_Source (R)
6328          then
6329             Error_Msg_N ("?comparison with True is redundant!", R);
6330          end if;
6331
6332          Check_Unset_Reference (L);
6333          Check_Unset_Reference (R);
6334          Generate_Operator_Reference (N, T);
6335          Check_Low_Bound_Tested (N);
6336
6337          --  If this is an inequality, it may be the implicit inequality
6338          --  created for a user-defined operation, in which case the corres-
6339          --  ponding equality operation is not intrinsic, and the operation
6340          --  cannot be constant-folded. Else fold.
6341
6342          if Nkind (N) = N_Op_Eq
6343            or else Comes_From_Source (Entity (N))
6344            or else Ekind (Entity (N)) = E_Operator
6345            or else Is_Intrinsic_Subprogram
6346              (Corresponding_Equality (Entity (N)))
6347          then
6348             Eval_Relational_Op (N);
6349
6350          elsif Nkind (N) = N_Op_Ne
6351            and then Is_Abstract_Subprogram (Entity (N))
6352          then
6353             Error_Msg_NE ("cannot call abstract subprogram &!", N, Entity (N));
6354          end if;
6355
6356          --  Ada 2005: If one operand is an anonymous access type, convert the
6357          --  other operand to it, to ensure that the underlying types match in
6358          --  the back-end. Same for access_to_subprogram, and the conversion
6359          --  verifies that the types are subtype conformant.
6360
6361          --  We apply the same conversion in the case one of the operands is a
6362          --  private subtype of the type of the other.
6363
6364          --  Why the Expander_Active test here ???
6365
6366          if Expander_Active
6367            and then
6368              (Ekind (T) =  E_Anonymous_Access_Type
6369                or else Ekind (T) = E_Anonymous_Access_Subprogram_Type
6370                or else Is_Private_Type (T))
6371          then
6372             if Etype (L) /= T then
6373                Rewrite (L,
6374                  Make_Unchecked_Type_Conversion (Sloc (L),
6375                    Subtype_Mark => New_Occurrence_Of (T, Sloc (L)),
6376                    Expression   => Relocate_Node (L)));
6377                Analyze_And_Resolve (L, T);
6378             end if;
6379
6380             if (Etype (R)) /= T then
6381                Rewrite (R,
6382                   Make_Unchecked_Type_Conversion (Sloc (R),
6383                     Subtype_Mark => New_Occurrence_Of (Etype (L), Sloc (R)),
6384                     Expression   => Relocate_Node (R)));
6385                Analyze_And_Resolve (R, T);
6386             end if;
6387          end if;
6388       end if;
6389    end Resolve_Equality_Op;
6390
6391    ----------------------------------
6392    -- Resolve_Explicit_Dereference --
6393    ----------------------------------
6394
6395    procedure Resolve_Explicit_Dereference (N : Node_Id; Typ : Entity_Id) is
6396       Loc   : constant Source_Ptr := Sloc (N);
6397       New_N : Node_Id;
6398       P     : constant Node_Id := Prefix (N);
6399       I     : Interp_Index;
6400       It    : Interp;
6401
6402    begin
6403       Check_Fully_Declared_Prefix (Typ, P);
6404
6405       if Is_Overloaded (P) then
6406
6407          --  Use the context type to select the prefix that has the correct
6408          --  designated type.
6409
6410          Get_First_Interp (P, I, It);
6411          while Present (It.Typ) loop
6412             exit when Is_Access_Type (It.Typ)
6413               and then Covers (Typ, Designated_Type (It.Typ));
6414             Get_Next_Interp (I, It);
6415          end loop;
6416
6417          if Present (It.Typ) then
6418             Resolve (P, It.Typ);
6419          else
6420             --  If no interpretation covers the designated type of the prefix,
6421             --  this is the pathological case where not all implementations of
6422             --  the prefix allow the interpretation of the node as a call. Now
6423             --  that the expected type is known, Remove other interpretations
6424             --  from prefix, rewrite it as a call, and resolve again, so that
6425             --  the proper call node is generated.
6426
6427             Get_First_Interp (P, I, It);
6428             while Present (It.Typ) loop
6429                if Ekind (It.Typ) /= E_Access_Subprogram_Type then
6430                   Remove_Interp (I);
6431                end if;
6432
6433                Get_Next_Interp (I, It);
6434             end loop;
6435
6436             New_N :=
6437               Make_Function_Call (Loc,
6438                 Name =>
6439                   Make_Explicit_Dereference (Loc,
6440                     Prefix => P),
6441                 Parameter_Associations => New_List);
6442
6443             Save_Interps (N, New_N);
6444             Rewrite (N, New_N);
6445             Analyze_And_Resolve (N, Typ);
6446             return;
6447          end if;
6448
6449          Set_Etype (N, Designated_Type (It.Typ));
6450
6451       else
6452          Resolve (P);
6453       end if;
6454
6455       if Is_Access_Type (Etype (P)) then
6456          Apply_Access_Check (N);
6457       end if;
6458
6459       --  If the designated type is a packed unconstrained array type, and the
6460       --  explicit dereference is not in the context of an attribute reference,
6461       --  then we must compute and set the actual subtype, since it is needed
6462       --  by Gigi. The reason we exclude the attribute case is that this is
6463       --  handled fine by Gigi, and in fact we use such attributes to build the
6464       --  actual subtype. We also exclude generated code (which builds actual
6465       --  subtypes directly if they are needed).
6466
6467       if Is_Array_Type (Etype (N))
6468         and then Is_Packed (Etype (N))
6469         and then not Is_Constrained (Etype (N))
6470         and then Nkind (Parent (N)) /= N_Attribute_Reference
6471         and then Comes_From_Source (N)
6472       then
6473          Set_Etype (N, Get_Actual_Subtype (N));
6474       end if;
6475
6476       --  Note: No Eval processing is required for an explicit dereference,
6477       --  because such a name can never be static.
6478
6479    end Resolve_Explicit_Dereference;
6480
6481    -------------------------------
6482    -- Resolve_Indexed_Component --
6483    -------------------------------
6484
6485    procedure Resolve_Indexed_Component (N : Node_Id; Typ : Entity_Id) is
6486       Name       : constant Node_Id := Prefix  (N);
6487       Expr       : Node_Id;
6488       Array_Type : Entity_Id := Empty; -- to prevent junk warning
6489       Index      : Node_Id;
6490
6491    begin
6492       if Is_Overloaded (Name) then
6493
6494          --  Use the context type to select the prefix that yields the correct
6495          --  component type.
6496
6497          declare
6498             I     : Interp_Index;
6499             It    : Interp;
6500             I1    : Interp_Index := 0;
6501             P     : constant Node_Id := Prefix (N);
6502             Found : Boolean := False;
6503
6504          begin
6505             Get_First_Interp (P, I, It);
6506             while Present (It.Typ) loop
6507                if (Is_Array_Type (It.Typ)
6508                      and then Covers (Typ, Component_Type (It.Typ)))
6509                  or else (Is_Access_Type (It.Typ)
6510                             and then Is_Array_Type (Designated_Type (It.Typ))
6511                             and then Covers
6512                               (Typ, Component_Type (Designated_Type (It.Typ))))
6513                then
6514                   if Found then
6515                      It := Disambiguate (P, I1, I, Any_Type);
6516
6517                      if It = No_Interp then
6518                         Error_Msg_N ("ambiguous prefix for indexing",  N);
6519                         Set_Etype (N, Typ);
6520                         return;
6521
6522                      else
6523                         Found := True;
6524                         Array_Type := It.Typ;
6525                         I1 := I;
6526                      end if;
6527
6528                   else
6529                      Found := True;
6530                      Array_Type := It.Typ;
6531                      I1 := I;
6532                   end if;
6533                end if;
6534
6535                Get_Next_Interp (I, It);
6536             end loop;
6537          end;
6538
6539       else
6540          Array_Type := Etype (Name);
6541       end if;
6542
6543       Resolve (Name, Array_Type);
6544       Array_Type := Get_Actual_Subtype_If_Available (Name);
6545
6546       --  If prefix is access type, dereference to get real array type.
6547       --  Note: we do not apply an access check because the expander always
6548       --  introduces an explicit dereference, and the check will happen there.
6549
6550       if Is_Access_Type (Array_Type) then
6551          Array_Type := Designated_Type (Array_Type);
6552       end if;
6553
6554       --  If name was overloaded, set component type correctly now
6555       --  If a misplaced call to an entry family (which has no index types)
6556       --  return. Error will be diagnosed from calling context.
6557
6558       if Is_Array_Type (Array_Type) then
6559          Set_Etype (N, Component_Type (Array_Type));
6560       else
6561          return;
6562       end if;
6563
6564       Index := First_Index (Array_Type);
6565       Expr  := First (Expressions (N));
6566
6567       --  The prefix may have resolved to a string literal, in which case its
6568       --  etype has a special representation. This is only possible currently
6569       --  if the prefix is a static concatenation, written in functional
6570       --  notation.
6571
6572       if Ekind (Array_Type) = E_String_Literal_Subtype then
6573          Resolve (Expr, Standard_Positive);
6574
6575       else
6576          while Present (Index) and Present (Expr) loop
6577             Resolve (Expr, Etype (Index));
6578             Check_Unset_Reference (Expr);
6579
6580             if Is_Scalar_Type (Etype (Expr)) then
6581                Apply_Scalar_Range_Check (Expr, Etype (Index));
6582             else
6583                Apply_Range_Check (Expr, Get_Actual_Subtype (Index));
6584             end if;
6585
6586             Next_Index (Index);
6587             Next (Expr);
6588          end loop;
6589       end if;
6590
6591       --  Do not generate the warning on suspicious index if we are analyzing
6592       --  package Ada.Tags; otherwise we will report the warning with the
6593       --  Prims_Ptr field of the dispatch table.
6594
6595       if Scope (Etype (Prefix (N))) = Standard_Standard
6596         or else not
6597           Is_RTU (Cunit_Entity (Get_Source_Unit (Etype (Prefix (N)))),
6598                   Ada_Tags)
6599       then
6600          Warn_On_Suspicious_Index (Name, First (Expressions (N)));
6601          Eval_Indexed_Component (N);
6602       end if;
6603    end Resolve_Indexed_Component;
6604
6605    -----------------------------
6606    -- Resolve_Integer_Literal --
6607    -----------------------------
6608
6609    procedure Resolve_Integer_Literal (N : Node_Id; Typ : Entity_Id) is
6610    begin
6611       Set_Etype (N, Typ);
6612       Eval_Integer_Literal (N);
6613    end Resolve_Integer_Literal;
6614
6615    --------------------------------
6616    -- Resolve_Intrinsic_Operator --
6617    --------------------------------
6618
6619    procedure Resolve_Intrinsic_Operator  (N : Node_Id; Typ : Entity_Id) is
6620       Btyp : constant Entity_Id := Base_Type (Underlying_Type (Typ));
6621       Op   : Entity_Id;
6622       Arg1 : Node_Id;
6623       Arg2 : Node_Id;
6624
6625    begin
6626       Op := Entity (N);
6627       while Scope (Op) /= Standard_Standard loop
6628          Op := Homonym (Op);
6629          pragma Assert (Present (Op));
6630       end loop;
6631
6632       Set_Entity (N, Op);
6633       Set_Is_Overloaded (N, False);
6634
6635       --  If the operand type is private, rewrite with suitable conversions on
6636       --  the operands and the result, to expose the proper underlying numeric
6637       --  type.
6638
6639       if Is_Private_Type (Typ) then
6640          Arg1 := Unchecked_Convert_To (Btyp, Left_Opnd  (N));
6641
6642          if Nkind (N) = N_Op_Expon then
6643             Arg2 := Unchecked_Convert_To (Standard_Integer, Right_Opnd (N));
6644          else
6645             Arg2 := Unchecked_Convert_To (Btyp, Right_Opnd (N));
6646          end if;
6647
6648          Save_Interps (Left_Opnd (N),  Expression (Arg1));
6649          Save_Interps (Right_Opnd (N), Expression (Arg2));
6650
6651          Set_Left_Opnd  (N, Arg1);
6652          Set_Right_Opnd (N, Arg2);
6653
6654          Set_Etype (N, Btyp);
6655          Rewrite (N, Unchecked_Convert_To (Typ, N));
6656          Resolve (N, Typ);
6657
6658       elsif Typ /= Etype (Left_Opnd (N))
6659         or else Typ /= Etype (Right_Opnd (N))
6660       then
6661          --  Add explicit conversion where needed, and save interpretations in
6662          --  case operands are overloaded.
6663
6664          Arg1 := Convert_To (Typ, Left_Opnd  (N));
6665          Arg2 := Convert_To (Typ, Right_Opnd (N));
6666
6667          if Nkind (Arg1) = N_Type_Conversion then
6668             Save_Interps (Left_Opnd (N), Expression (Arg1));
6669          else
6670             Save_Interps (Left_Opnd (N), Arg1);
6671          end if;
6672
6673          if Nkind (Arg2) = N_Type_Conversion then
6674             Save_Interps (Right_Opnd (N), Expression (Arg2));
6675          else
6676             Save_Interps (Right_Opnd (N), Arg2);
6677          end if;
6678
6679          Rewrite (Left_Opnd  (N), Arg1);
6680          Rewrite (Right_Opnd (N), Arg2);
6681          Analyze (Arg1);
6682          Analyze (Arg2);
6683          Resolve_Arithmetic_Op (N, Typ);
6684
6685       else
6686          Resolve_Arithmetic_Op (N, Typ);
6687       end if;
6688    end Resolve_Intrinsic_Operator;
6689
6690    --------------------------------------
6691    -- Resolve_Intrinsic_Unary_Operator --
6692    --------------------------------------
6693
6694    procedure Resolve_Intrinsic_Unary_Operator
6695      (N   : Node_Id;
6696       Typ : Entity_Id)
6697    is
6698       Btyp : constant Entity_Id := Base_Type (Underlying_Type (Typ));
6699       Op   : Entity_Id;
6700       Arg2 : Node_Id;
6701
6702    begin
6703       Op := Entity (N);
6704       while Scope (Op) /= Standard_Standard loop
6705          Op := Homonym (Op);
6706          pragma Assert (Present (Op));
6707       end loop;
6708
6709       Set_Entity (N, Op);
6710
6711       if Is_Private_Type (Typ) then
6712          Arg2 := Unchecked_Convert_To (Btyp, Right_Opnd (N));
6713          Save_Interps (Right_Opnd (N), Expression (Arg2));
6714
6715          Set_Right_Opnd (N, Arg2);
6716
6717          Set_Etype (N, Btyp);
6718          Rewrite (N, Unchecked_Convert_To (Typ, N));
6719          Resolve (N, Typ);
6720
6721       else
6722          Resolve_Unary_Op (N, Typ);
6723       end if;
6724    end Resolve_Intrinsic_Unary_Operator;
6725
6726    ------------------------
6727    -- Resolve_Logical_Op --
6728    ------------------------
6729
6730    procedure Resolve_Logical_Op (N : Node_Id; Typ : Entity_Id) is
6731       B_Typ : Entity_Id;
6732
6733    begin
6734       Check_No_Direct_Boolean_Operators (N);
6735
6736       --  Predefined operations on scalar types yield the base type. On the
6737       --  other hand, logical operations on arrays yield the type of the
6738       --  arguments (and the context).
6739
6740       if Is_Array_Type (Typ) then
6741          B_Typ := Typ;
6742       else
6743          B_Typ := Base_Type (Typ);
6744       end if;
6745
6746       --  The following test is required because the operands of the operation
6747       --  may be literals, in which case the resulting type appears to be
6748       --  compatible with a signed integer type, when in fact it is compatible
6749       --  only with modular types. If the context itself is universal, the
6750       --  operation is illegal.
6751
6752       if not Valid_Boolean_Arg (Typ) then
6753          Error_Msg_N ("invalid context for logical operation", N);
6754          Set_Etype (N, Any_Type);
6755          return;
6756
6757       elsif Typ = Any_Modular then
6758          Error_Msg_N
6759            ("no modular type available in this context", N);
6760          Set_Etype (N, Any_Type);
6761          return;
6762       elsif Is_Modular_Integer_Type (Typ)
6763         and then Etype (Left_Opnd (N)) = Universal_Integer
6764         and then Etype (Right_Opnd (N)) = Universal_Integer
6765       then
6766          Check_For_Visible_Operator (N, B_Typ);
6767       end if;
6768
6769       Resolve (Left_Opnd (N), B_Typ);
6770       Resolve (Right_Opnd (N), B_Typ);
6771
6772       Check_Unset_Reference (Left_Opnd  (N));
6773       Check_Unset_Reference (Right_Opnd (N));
6774
6775       Set_Etype (N, B_Typ);
6776       Generate_Operator_Reference (N, B_Typ);
6777       Eval_Logical_Op (N);
6778    end Resolve_Logical_Op;
6779
6780    ---------------------------
6781    -- Resolve_Membership_Op --
6782    ---------------------------
6783
6784    --  The context can only be a boolean type, and does not determine
6785    --  the arguments. Arguments should be unambiguous, but the preference
6786    --  rule for universal types applies.
6787
6788    procedure Resolve_Membership_Op (N : Node_Id; Typ : Entity_Id) is
6789       pragma Warnings (Off, Typ);
6790
6791       L : constant Node_Id := Left_Opnd  (N);
6792       R : constant Node_Id := Right_Opnd (N);
6793       T : Entity_Id;
6794
6795       procedure Resolve_Set_Membership;
6796       --  Analysis has determined a unique type for the left operand.
6797       --  Use it to resolve the disjuncts.
6798
6799       ----------------------------
6800       -- Resolve_Set_Membership --
6801       ----------------------------
6802
6803       procedure Resolve_Set_Membership is
6804          Alt : Node_Id;
6805
6806       begin
6807          Resolve (L, Etype (L));
6808
6809          Alt := First (Alternatives (N));
6810          while Present (Alt) loop
6811
6812             --  Alternative is an expression, a range
6813             --  or a subtype mark.
6814
6815             if not Is_Entity_Name (Alt)
6816               or else not Is_Type (Entity (Alt))
6817             then
6818                Resolve (Alt, Etype (L));
6819             end if;
6820
6821             Next (Alt);
6822          end loop;
6823       end Resolve_Set_Membership;
6824
6825    --  Start of processing for Resolve_Membership_Op
6826
6827    begin
6828       if L = Error or else R = Error then
6829          return;
6830       end if;
6831
6832       if Present (Alternatives (N)) then
6833          Resolve_Set_Membership;
6834          return;
6835
6836       elsif not Is_Overloaded (R)
6837         and then
6838           (Etype (R) = Universal_Integer or else
6839            Etype (R) = Universal_Real)
6840         and then Is_Overloaded (L)
6841       then
6842          T := Etype (R);
6843
6844       --  Ada 2005 (AI-251): Support the following case:
6845
6846       --      type I is interface;
6847       --      type T is tagged ...
6848
6849       --      function Test (O : I'Class) is
6850       --      begin
6851       --         return O in T'Class.
6852       --      end Test;
6853
6854       --  In this case we have nothing else to do. The membership test will be
6855       --  done at run-time.
6856
6857       elsif Ada_Version >= Ada_05
6858         and then Is_Class_Wide_Type (Etype (L))
6859         and then Is_Interface (Etype (L))
6860         and then Is_Class_Wide_Type (Etype (R))
6861         and then not Is_Interface (Etype (R))
6862       then
6863          return;
6864
6865       else
6866          T := Intersect_Types (L, R);
6867       end if;
6868
6869       Resolve (L, T);
6870       Check_Unset_Reference (L);
6871
6872       if Nkind (R) = N_Range
6873         and then not Is_Scalar_Type (T)
6874       then
6875          Error_Msg_N ("scalar type required for range", R);
6876       end if;
6877
6878       if Is_Entity_Name (R) then
6879          Freeze_Expression (R);
6880       else
6881          Resolve (R, T);
6882          Check_Unset_Reference (R);
6883       end if;
6884
6885       Eval_Membership_Op (N);
6886    end Resolve_Membership_Op;
6887
6888    ------------------
6889    -- Resolve_Null --
6890    ------------------
6891
6892    procedure Resolve_Null (N : Node_Id; Typ : Entity_Id) is
6893       Loc : constant Source_Ptr := Sloc (N);
6894
6895    begin
6896       --  Handle restriction against anonymous null access values This
6897       --  restriction can be turned off using -gnatdj.
6898
6899       --  Ada 2005 (AI-231): Remove restriction
6900
6901       if Ada_Version < Ada_05
6902         and then not Debug_Flag_J
6903         and then Ekind (Typ) = E_Anonymous_Access_Type
6904         and then Comes_From_Source (N)
6905       then
6906          --  In the common case of a call which uses an explicitly null value
6907          --  for an access parameter, give specialized error message.
6908
6909          if Nkind_In (Parent (N), N_Procedure_Call_Statement,
6910                                   N_Function_Call)
6911          then
6912             Error_Msg_N
6913               ("null is not allowed as argument for an access parameter", N);
6914
6915          --  Standard message for all other cases (are there any?)
6916
6917          else
6918             Error_Msg_N
6919               ("null cannot be of an anonymous access type", N);
6920          end if;
6921       end if;
6922
6923       --  Ada 2005 (AI-231): Generate the null-excluding check in case of
6924       --  assignment to a null-excluding object
6925
6926       if Ada_Version >= Ada_05
6927         and then Can_Never_Be_Null (Typ)
6928         and then Nkind (Parent (N)) = N_Assignment_Statement
6929       then
6930          if not Inside_Init_Proc then
6931             Insert_Action
6932               (Compile_Time_Constraint_Error (N,
6933                  "(Ada 2005) null not allowed in null-excluding objects?"),
6934                Make_Raise_Constraint_Error (Loc,
6935                  Reason => CE_Access_Check_Failed));
6936          else
6937             Insert_Action (N,
6938               Make_Raise_Constraint_Error (Loc,
6939                 Reason => CE_Access_Check_Failed));
6940          end if;
6941       end if;
6942
6943       --  In a distributed context, null for a remote access to subprogram may
6944       --  need to be replaced with a special record aggregate. In this case,
6945       --  return after having done the transformation.
6946
6947       if (Ekind (Typ) = E_Record_Type
6948            or else Is_Remote_Access_To_Subprogram_Type (Typ))
6949         and then Remote_AST_Null_Value (N, Typ)
6950       then
6951          return;
6952       end if;
6953
6954       --  The null literal takes its type from the context
6955
6956       Set_Etype (N, Typ);
6957    end Resolve_Null;
6958
6959    -----------------------
6960    -- Resolve_Op_Concat --
6961    -----------------------
6962
6963    procedure Resolve_Op_Concat (N : Node_Id; Typ : Entity_Id) is
6964
6965       --  We wish to avoid deep recursion, because concatenations are often
6966       --  deeply nested, as in A&B&...&Z. Therefore, we walk down the left
6967       --  operands nonrecursively until we find something that is not a simple
6968       --  concatenation (A in this case). We resolve that, and then walk back
6969       --  up the tree following Parent pointers, calling Resolve_Op_Concat_Rest
6970       --  to do the rest of the work at each level. The Parent pointers allow
6971       --  us to avoid recursion, and thus avoid running out of memory. See also
6972       --  Sem_Ch4.Analyze_Concatenation, where a similar approach is used.
6973
6974       NN  : Node_Id := N;
6975       Op1 : Node_Id;
6976
6977    begin
6978       --  The following code is equivalent to:
6979
6980       --    Resolve_Op_Concat_First (NN, Typ);
6981       --    Resolve_Op_Concat_Arg (N, ...);
6982       --    Resolve_Op_Concat_Rest (N, Typ);
6983
6984       --  where the Resolve_Op_Concat_Arg call recurses back here if the left
6985       --  operand is a concatenation.
6986
6987       --  Walk down left operands
6988
6989       loop
6990          Resolve_Op_Concat_First (NN, Typ);
6991          Op1 := Left_Opnd (NN);
6992          exit when not (Nkind (Op1) = N_Op_Concat
6993                          and then not Is_Array_Type (Component_Type (Typ))
6994                          and then Entity (Op1) = Entity (NN));
6995          NN := Op1;
6996       end loop;
6997
6998       --  Now (given the above example) NN is A&B and Op1 is A
6999
7000       --  First resolve Op1 ...
7001
7002       Resolve_Op_Concat_Arg (NN, Op1, Typ, Is_Component_Left_Opnd  (NN));
7003
7004       --  ... then walk NN back up until we reach N (where we started), calling
7005       --  Resolve_Op_Concat_Rest along the way.
7006
7007       loop
7008          Resolve_Op_Concat_Rest (NN, Typ);
7009          exit when NN = N;
7010          NN := Parent (NN);
7011       end loop;
7012    end Resolve_Op_Concat;
7013
7014    ---------------------------
7015    -- Resolve_Op_Concat_Arg --
7016    ---------------------------
7017
7018    procedure Resolve_Op_Concat_Arg
7019      (N       : Node_Id;
7020       Arg     : Node_Id;
7021       Typ     : Entity_Id;
7022       Is_Comp : Boolean)
7023    is
7024       Btyp : constant Entity_Id := Base_Type (Typ);
7025
7026    begin
7027       if In_Instance then
7028          if Is_Comp
7029            or else (not Is_Overloaded (Arg)
7030                      and then Etype (Arg) /= Any_Composite
7031                      and then Covers (Component_Type (Typ), Etype (Arg)))
7032          then
7033             Resolve (Arg, Component_Type (Typ));
7034          else
7035             Resolve (Arg, Btyp);
7036          end if;
7037
7038       elsif Has_Compatible_Type (Arg, Component_Type (Typ)) then
7039          if Nkind (Arg) = N_Aggregate
7040            and then Is_Composite_Type (Component_Type (Typ))
7041          then
7042             if Is_Private_Type (Component_Type (Typ)) then
7043                Resolve (Arg, Btyp);
7044             else
7045                Error_Msg_N ("ambiguous aggregate must be qualified", Arg);
7046                Set_Etype (Arg, Any_Type);
7047             end if;
7048
7049          else
7050             if Is_Overloaded (Arg)
7051               and then Has_Compatible_Type (Arg, Typ)
7052               and then Etype (Arg) /= Any_Type
7053             then
7054                declare
7055                   I    : Interp_Index;
7056                   It   : Interp;
7057                   Func : Entity_Id;
7058
7059                begin
7060                   Get_First_Interp (Arg, I, It);
7061                   Func := It.Nam;
7062                   Get_Next_Interp (I, It);
7063
7064                   --  Special-case the error message when the overloading is
7065                   --  caused by a function that yields an array and can be
7066                   --  called without parameters.
7067
7068                   if It.Nam = Func then
7069                      Error_Msg_Sloc := Sloc (Func);
7070                      Error_Msg_N ("ambiguous call to function#", Arg);
7071                      Error_Msg_NE
7072                        ("\\interpretation as call yields&", Arg, Typ);
7073                      Error_Msg_NE
7074                        ("\\interpretation as indexing of call yields&",
7075                          Arg, Component_Type (Typ));
7076
7077                   else
7078                      Error_Msg_N
7079                        ("ambiguous operand for concatenation!", Arg);
7080                      Get_First_Interp (Arg, I, It);
7081                      while Present (It.Nam) loop
7082                         Error_Msg_Sloc := Sloc (It.Nam);
7083
7084                         if Base_Type (It.Typ) = Base_Type (Typ)
7085                           or else Base_Type (It.Typ) =
7086                             Base_Type (Component_Type (Typ))
7087                         then
7088                            Error_Msg_N -- CODEFIX
7089                              ("\\possible interpretation#", Arg);
7090                         end if;
7091
7092                         Get_Next_Interp (I, It);
7093                      end loop;
7094                   end if;
7095                end;
7096             end if;
7097
7098             Resolve (Arg, Component_Type (Typ));
7099
7100             if Nkind (Arg) = N_String_Literal then
7101                Set_Etype (Arg, Component_Type (Typ));
7102             end if;
7103
7104             if Arg = Left_Opnd (N) then
7105                Set_Is_Component_Left_Opnd (N);
7106             else
7107                Set_Is_Component_Right_Opnd (N);
7108             end if;
7109          end if;
7110
7111       else
7112          Resolve (Arg, Btyp);
7113       end if;
7114
7115       Check_Unset_Reference (Arg);
7116    end Resolve_Op_Concat_Arg;
7117
7118    -----------------------------
7119    -- Resolve_Op_Concat_First --
7120    -----------------------------
7121
7122    procedure Resolve_Op_Concat_First (N : Node_Id; Typ : Entity_Id) is
7123       Btyp : constant Entity_Id := Base_Type (Typ);
7124       Op1  : constant Node_Id := Left_Opnd (N);
7125       Op2  : constant Node_Id := Right_Opnd (N);
7126
7127    begin
7128       --  The parser folds an enormous sequence of concatenations of string
7129       --  literals into "" & "...", where the Is_Folded_In_Parser flag is set
7130       --  in the right operand. If the expression resolves to a predefined "&"
7131       --  operator, all is well. Otherwise, the parser's folding is wrong, so
7132       --  we give an error. See P_Simple_Expression in Par.Ch4.
7133
7134       if Nkind (Op2) = N_String_Literal
7135         and then Is_Folded_In_Parser (Op2)
7136         and then Ekind (Entity (N)) = E_Function
7137       then
7138          pragma Assert (Nkind (Op1) = N_String_Literal  --  should be ""
7139                and then String_Length (Strval (Op1)) = 0);
7140          Error_Msg_N ("too many user-defined concatenations", N);
7141          return;
7142       end if;
7143
7144       Set_Etype (N, Btyp);
7145
7146       if Is_Limited_Composite (Btyp) then
7147          Error_Msg_N ("concatenation not available for limited array", N);
7148          Explain_Limited_Type (Btyp, N);
7149       end if;
7150    end Resolve_Op_Concat_First;
7151
7152    ----------------------------
7153    -- Resolve_Op_Concat_Rest --
7154    ----------------------------
7155
7156    procedure Resolve_Op_Concat_Rest (N : Node_Id; Typ : Entity_Id) is
7157       Op1  : constant Node_Id := Left_Opnd (N);
7158       Op2  : constant Node_Id := Right_Opnd (N);
7159
7160    begin
7161       Resolve_Op_Concat_Arg (N, Op2, Typ, Is_Component_Right_Opnd  (N));
7162
7163       Generate_Operator_Reference (N, Typ);
7164
7165       if Is_String_Type (Typ) then
7166          Eval_Concatenation (N);
7167       end if;
7168
7169       --  If this is not a static concatenation, but the result is a string
7170       --  type (and not an array of strings) ensure that static string operands
7171       --  have their subtypes properly constructed.
7172
7173       if Nkind (N) /= N_String_Literal
7174         and then Is_Character_Type (Component_Type (Typ))
7175       then
7176          Set_String_Literal_Subtype (Op1, Typ);
7177          Set_String_Literal_Subtype (Op2, Typ);
7178       end if;
7179    end Resolve_Op_Concat_Rest;
7180
7181    ----------------------
7182    -- Resolve_Op_Expon --
7183    ----------------------
7184
7185    procedure Resolve_Op_Expon (N : Node_Id; Typ : Entity_Id) is
7186       B_Typ : constant Entity_Id := Base_Type (Typ);
7187
7188    begin
7189       --  Catch attempts to do fixed-point exponentiation with universal
7190       --  operands, which is a case where the illegality is not caught during
7191       --  normal operator analysis.
7192
7193       if Is_Fixed_Point_Type (Typ) and then Comes_From_Source (N) then
7194          Error_Msg_N ("exponentiation not available for fixed point", N);
7195          return;
7196       end if;
7197
7198       if Comes_From_Source (N)
7199         and then Ekind (Entity (N)) = E_Function
7200         and then Is_Imported (Entity (N))
7201         and then Is_Intrinsic_Subprogram (Entity (N))
7202       then
7203          Resolve_Intrinsic_Operator (N, Typ);
7204          return;
7205       end if;
7206
7207       if Etype (Left_Opnd (N)) = Universal_Integer
7208         or else Etype (Left_Opnd (N)) = Universal_Real
7209       then
7210          Check_For_Visible_Operator (N, B_Typ);
7211       end if;
7212
7213       --  We do the resolution using the base type, because intermediate values
7214       --  in expressions always are of the base type, not a subtype of it.
7215
7216       Resolve (Left_Opnd (N), B_Typ);
7217       Resolve (Right_Opnd (N), Standard_Integer);
7218
7219       Check_Unset_Reference (Left_Opnd  (N));
7220       Check_Unset_Reference (Right_Opnd (N));
7221
7222       Set_Etype (N, B_Typ);
7223       Generate_Operator_Reference (N, B_Typ);
7224       Eval_Op_Expon (N);
7225
7226       --  Set overflow checking bit. Much cleverer code needed here eventually
7227       --  and perhaps the Resolve routines should be separated for the various
7228       --  arithmetic operations, since they will need different processing. ???
7229
7230       if Nkind (N) in N_Op then
7231          if not Overflow_Checks_Suppressed (Etype (N)) then
7232             Enable_Overflow_Check (N);
7233          end if;
7234       end if;
7235    end Resolve_Op_Expon;
7236
7237    --------------------
7238    -- Resolve_Op_Not --
7239    --------------------
7240
7241    procedure Resolve_Op_Not (N : Node_Id; Typ : Entity_Id) is
7242       B_Typ : Entity_Id;
7243
7244       function Parent_Is_Boolean return Boolean;
7245       --  This function determines if the parent node is a boolean operator
7246       --  or operation (comparison op, membership test, or short circuit form)
7247       --  and the not in question is the left operand of this operation.
7248       --  Note that if the not is in parens, then false is returned.
7249
7250       -----------------------
7251       -- Parent_Is_Boolean --
7252       -----------------------
7253
7254       function Parent_Is_Boolean return Boolean is
7255       begin
7256          if Paren_Count (N) /= 0 then
7257             return False;
7258
7259          else
7260             case Nkind (Parent (N)) is
7261                when N_Op_And   |
7262                     N_Op_Eq    |
7263                     N_Op_Ge    |
7264                     N_Op_Gt    |
7265                     N_Op_Le    |
7266                     N_Op_Lt    |
7267                     N_Op_Ne    |
7268                     N_Op_Or    |
7269                     N_Op_Xor   |
7270                     N_In       |
7271                     N_Not_In   |
7272                     N_And_Then |
7273                     N_Or_Else  =>
7274
7275                   return Left_Opnd (Parent (N)) = N;
7276
7277                when others =>
7278                   return False;
7279             end case;
7280          end if;
7281       end Parent_Is_Boolean;
7282
7283    --  Start of processing for Resolve_Op_Not
7284
7285    begin
7286       --  Predefined operations on scalar types yield the base type. On the
7287       --  other hand, logical operations on arrays yield the type of the
7288       --  arguments (and the context).
7289
7290       if Is_Array_Type (Typ) then
7291          B_Typ := Typ;
7292       else
7293          B_Typ := Base_Type (Typ);
7294       end if;
7295
7296       --  Straightforward case of incorrect arguments
7297
7298       if not Valid_Boolean_Arg (Typ) then
7299          Error_Msg_N ("invalid operand type for operator&", N);
7300          Set_Etype (N, Any_Type);
7301          return;
7302
7303       --  Special case of probable missing parens
7304
7305       elsif Typ = Universal_Integer or else Typ = Any_Modular then
7306          if Parent_Is_Boolean then
7307             Error_Msg_N
7308               ("operand of not must be enclosed in parentheses",
7309                Right_Opnd (N));
7310          else
7311             Error_Msg_N
7312               ("no modular type available in this context", N);
7313          end if;
7314
7315          Set_Etype (N, Any_Type);
7316          return;
7317
7318       --  OK resolution of not
7319
7320       else
7321          --  Warn if non-boolean types involved. This is a case like not a < b
7322          --  where a and b are modular, where we will get (not a) < b and most
7323          --  likely not (a < b) was intended.
7324
7325          if Warn_On_Questionable_Missing_Parens
7326            and then not Is_Boolean_Type (Typ)
7327            and then Parent_Is_Boolean
7328          then
7329             Error_Msg_N ("?not expression should be parenthesized here!", N);
7330          end if;
7331
7332          --  Warn on double negation if checking redundant constructs
7333
7334          if Warn_On_Redundant_Constructs
7335            and then Comes_From_Source (N)
7336            and then Comes_From_Source (Right_Opnd (N))
7337            and then Root_Type (Typ) = Standard_Boolean
7338            and then Nkind (Right_Opnd (N)) = N_Op_Not
7339          then
7340             Error_Msg_N ("redundant double negation?", N);
7341          end if;
7342
7343          --  Complete resolution and evaluation of NOT
7344
7345          Resolve (Right_Opnd (N), B_Typ);
7346          Check_Unset_Reference (Right_Opnd (N));
7347          Set_Etype (N, B_Typ);
7348          Generate_Operator_Reference (N, B_Typ);
7349          Eval_Op_Not (N);
7350       end if;
7351    end Resolve_Op_Not;
7352
7353    -----------------------------
7354    -- Resolve_Operator_Symbol --
7355    -----------------------------
7356
7357    --  Nothing to be done, all resolved already
7358
7359    procedure Resolve_Operator_Symbol (N : Node_Id; Typ : Entity_Id) is
7360       pragma Warnings (Off, N);
7361       pragma Warnings (Off, Typ);
7362
7363    begin
7364       null;
7365    end Resolve_Operator_Symbol;
7366
7367    ----------------------------------
7368    -- Resolve_Qualified_Expression --
7369    ----------------------------------
7370
7371    procedure Resolve_Qualified_Expression (N : Node_Id; Typ : Entity_Id) is
7372       pragma Warnings (Off, Typ);
7373
7374       Target_Typ : constant Entity_Id := Entity (Subtype_Mark (N));
7375       Expr       : constant Node_Id   := Expression (N);
7376
7377    begin
7378       Resolve (Expr, Target_Typ);
7379
7380       --  A qualified expression requires an exact match of the type,
7381       --  class-wide matching is not allowed. However, if the qualifying
7382       --  type is specific and the expression has a class-wide type, it
7383       --  may still be okay, since it can be the result of the expansion
7384       --  of a call to a dispatching function, so we also have to check
7385       --  class-wideness of the type of the expression's original node.
7386
7387       if (Is_Class_Wide_Type (Target_Typ)
7388            or else
7389              (Is_Class_Wide_Type (Etype (Expr))
7390                and then Is_Class_Wide_Type (Etype (Original_Node (Expr)))))
7391         and then Base_Type (Etype (Expr)) /= Base_Type (Target_Typ)
7392       then
7393          Wrong_Type (Expr, Target_Typ);
7394       end if;
7395
7396       --  If the target type is unconstrained, then we reset the type of
7397       --  the result from the type of the expression. For other cases, the
7398       --  actual subtype of the expression is the target type.
7399
7400       if Is_Composite_Type (Target_Typ)
7401         and then not Is_Constrained (Target_Typ)
7402       then
7403          Set_Etype (N, Etype (Expr));
7404       end if;
7405
7406       Eval_Qualified_Expression (N);
7407    end Resolve_Qualified_Expression;
7408
7409    -------------------
7410    -- Resolve_Range --
7411    -------------------
7412
7413    procedure Resolve_Range (N : Node_Id; Typ : Entity_Id) is
7414       L : constant Node_Id := Low_Bound (N);
7415       H : constant Node_Id := High_Bound (N);
7416
7417    begin
7418       Set_Etype (N, Typ);
7419       Resolve (L, Typ);
7420       Resolve (H, Typ);
7421
7422       Check_Unset_Reference (L);
7423       Check_Unset_Reference (H);
7424
7425       --  We have to check the bounds for being within the base range as
7426       --  required for a non-static context. Normally this is automatic and
7427       --  done as part of evaluating expressions, but the N_Range node is an
7428       --  exception, since in GNAT we consider this node to be a subexpression,
7429       --  even though in Ada it is not. The circuit in Sem_Eval could check for
7430       --  this, but that would put the test on the main evaluation path for
7431       --  expressions.
7432
7433       Check_Non_Static_Context (L);
7434       Check_Non_Static_Context (H);
7435
7436       --  Check for an ambiguous range over character literals. This will
7437       --  happen with a membership test involving only literals.
7438
7439       if Typ = Any_Character then
7440          Ambiguous_Character (L);
7441          Set_Etype (N, Any_Type);
7442          return;
7443       end if;
7444
7445       --  If bounds are static, constant-fold them, so size computations
7446       --  are identical between front-end and back-end. Do not perform this
7447       --  transformation while analyzing generic units, as type information
7448       --  would then be lost when reanalyzing the constant node in the
7449       --  instance.
7450
7451       if Is_Discrete_Type (Typ) and then Expander_Active then
7452          if Is_OK_Static_Expression (L) then
7453             Fold_Uint  (L, Expr_Value (L), Is_Static_Expression (L));
7454          end if;
7455
7456          if Is_OK_Static_Expression (H) then
7457             Fold_Uint  (H, Expr_Value (H), Is_Static_Expression (H));
7458          end if;
7459       end if;
7460    end Resolve_Range;
7461
7462    --------------------------
7463    -- Resolve_Real_Literal --
7464    --------------------------
7465
7466    procedure Resolve_Real_Literal (N : Node_Id; Typ : Entity_Id) is
7467       Actual_Typ : constant Entity_Id := Etype (N);
7468
7469    begin
7470       --  Special processing for fixed-point literals to make sure that the
7471       --  value is an exact multiple of small where this is required. We
7472       --  skip this for the universal real case, and also for generic types.
7473
7474       if Is_Fixed_Point_Type (Typ)
7475         and then Typ /= Universal_Fixed
7476         and then Typ /= Any_Fixed
7477         and then not Is_Generic_Type (Typ)
7478       then
7479          declare
7480             Val   : constant Ureal := Realval (N);
7481             Cintr : constant Ureal := Val / Small_Value (Typ);
7482             Cint  : constant Uint  := UR_Trunc (Cintr);
7483             Den   : constant Uint  := Norm_Den (Cintr);
7484             Stat  : Boolean;
7485
7486          begin
7487             --  Case of literal is not an exact multiple of the Small
7488
7489             if Den /= 1 then
7490
7491                --  For a source program literal for a decimal fixed-point
7492                --  type, this is statically illegal (RM 4.9(36)).
7493
7494                if Is_Decimal_Fixed_Point_Type (Typ)
7495                  and then Actual_Typ = Universal_Real
7496                  and then Comes_From_Source (N)
7497                then
7498                   Error_Msg_N ("value has extraneous low order digits", N);
7499                end if;
7500
7501                --  Generate a warning if literal from source
7502
7503                if Is_Static_Expression (N)
7504                  and then Warn_On_Bad_Fixed_Value
7505                then
7506                   Error_Msg_N
7507                     ("?static fixed-point value is not a multiple of Small!",
7508                      N);
7509                end if;
7510
7511                --  Replace literal by a value that is the exact representation
7512                --  of a value of the type, i.e. a multiple of the small value,
7513                --  by truncation, since Machine_Rounds is false for all GNAT
7514                --  fixed-point types (RM 4.9(38)).
7515
7516                Stat := Is_Static_Expression (N);
7517                Rewrite (N,
7518                  Make_Real_Literal (Sloc (N),
7519                    Realval => Small_Value (Typ) * Cint));
7520
7521                Set_Is_Static_Expression (N, Stat);
7522             end if;
7523
7524             --  In all cases, set the corresponding integer field
7525
7526             Set_Corresponding_Integer_Value (N, Cint);
7527          end;
7528       end if;
7529
7530       --  Now replace the actual type by the expected type as usual
7531
7532       Set_Etype (N, Typ);
7533       Eval_Real_Literal (N);
7534    end Resolve_Real_Literal;
7535
7536    -----------------------
7537    -- Resolve_Reference --
7538    -----------------------
7539
7540    procedure Resolve_Reference (N : Node_Id; Typ : Entity_Id) is
7541       P : constant Node_Id := Prefix (N);
7542
7543    begin
7544       --  Replace general access with specific type
7545
7546       if Ekind (Etype (N)) = E_Allocator_Type then
7547          Set_Etype (N, Base_Type (Typ));
7548       end if;
7549
7550       Resolve (P, Designated_Type (Etype (N)));
7551
7552       --  If we are taking the reference of a volatile entity, then treat
7553       --  it as a potential modification of this entity. This is much too
7554       --  conservative, but is necessary because remove side effects can
7555       --  result in transformations of normal assignments into reference
7556       --  sequences that otherwise fail to notice the modification.
7557
7558       if Is_Entity_Name (P) and then Treat_As_Volatile (Entity (P)) then
7559          Note_Possible_Modification (P, Sure => False);
7560       end if;
7561    end Resolve_Reference;
7562
7563    --------------------------------
7564    -- Resolve_Selected_Component --
7565    --------------------------------
7566
7567    procedure Resolve_Selected_Component (N : Node_Id; Typ : Entity_Id) is
7568       Comp  : Entity_Id;
7569       Comp1 : Entity_Id        := Empty; -- prevent junk warning
7570       P     : constant Node_Id := Prefix  (N);
7571       S     : constant Node_Id := Selector_Name (N);
7572       T     : Entity_Id        := Etype (P);
7573       I     : Interp_Index;
7574       I1    : Interp_Index := 0; -- prevent junk warning
7575       It    : Interp;
7576       It1   : Interp;
7577       Found : Boolean;
7578
7579       function Init_Component return Boolean;
7580       --  Check whether this is the initialization of a component within an
7581       --  init proc (by assignment or call to another init proc). If true,
7582       --  there is no need for a discriminant check.
7583
7584       --------------------
7585       -- Init_Component --
7586       --------------------
7587
7588       function Init_Component return Boolean is
7589       begin
7590          return Inside_Init_Proc
7591            and then Nkind (Prefix (N)) = N_Identifier
7592            and then Chars (Prefix (N)) = Name_uInit
7593            and then Nkind (Parent (Parent (N))) = N_Case_Statement_Alternative;
7594       end Init_Component;
7595
7596    --  Start of processing for Resolve_Selected_Component
7597
7598    begin
7599       if Is_Overloaded (P) then
7600
7601          --  Use the context type to select the prefix that has a selector
7602          --  of the correct name and type.
7603
7604          Found := False;
7605          Get_First_Interp (P, I, It);
7606
7607          Search : while Present (It.Typ) loop
7608             if Is_Access_Type (It.Typ) then
7609                T := Designated_Type (It.Typ);
7610             else
7611                T := It.Typ;
7612             end if;
7613
7614             if Is_Record_Type (T) then
7615
7616                --  The visible components of a class-wide type are those of
7617                --  the root type.
7618
7619                if Is_Class_Wide_Type (T) then
7620                   T := Etype (T);
7621                end if;
7622
7623                Comp := First_Entity (T);
7624                while Present (Comp) loop
7625                   if Chars (Comp) = Chars (S)
7626                     and then Covers (Etype (Comp), Typ)
7627                   then
7628                      if not Found then
7629                         Found := True;
7630                         I1  := I;
7631                         It1 := It;
7632                         Comp1 := Comp;
7633
7634                      else
7635                         It := Disambiguate (P, I1, I, Any_Type);
7636
7637                         if It = No_Interp then
7638                            Error_Msg_N
7639                              ("ambiguous prefix for selected component",  N);
7640                            Set_Etype (N, Typ);
7641                            return;
7642
7643                         else
7644                            It1 := It;
7645
7646                            --  There may be an implicit dereference. Retrieve
7647                            --  designated record type.
7648
7649                            if Is_Access_Type (It1.Typ) then
7650                               T := Designated_Type (It1.Typ);
7651                            else
7652                               T := It1.Typ;
7653                            end if;
7654
7655                            if Scope (Comp1) /= T then
7656
7657                               --  Resolution chooses the new interpretation.
7658                               --  Find the component with the right name.
7659
7660                               Comp1 := First_Entity (T);
7661                               while Present (Comp1)
7662                                 and then Chars (Comp1) /= Chars (S)
7663                               loop
7664                                  Comp1 := Next_Entity (Comp1);
7665                               end loop;
7666                            end if;
7667
7668                            exit Search;
7669                         end if;
7670                      end if;
7671                   end if;
7672
7673                   Comp := Next_Entity (Comp);
7674                end loop;
7675
7676             end if;
7677
7678             Get_Next_Interp (I, It);
7679          end loop Search;
7680
7681          Resolve (P, It1.Typ);
7682          Set_Etype (N, Typ);
7683          Set_Entity_With_Style_Check (S, Comp1);
7684
7685       else
7686          --  Resolve prefix with its type
7687
7688          Resolve (P, T);
7689       end if;
7690
7691       --  Generate cross-reference. We needed to wait until full overloading
7692       --  resolution was complete to do this, since otherwise we can't tell if
7693       --  we are an lvalue or not.
7694
7695       if May_Be_Lvalue (N) then
7696          Generate_Reference (Entity (S), S, 'm');
7697       else
7698          Generate_Reference (Entity (S), S, 'r');
7699       end if;
7700
7701       --  If prefix is an access type, the node will be transformed into an
7702       --  explicit dereference during expansion. The type of the node is the
7703       --  designated type of that of the prefix.
7704
7705       if Is_Access_Type (Etype (P)) then
7706          T := Designated_Type (Etype (P));
7707          Check_Fully_Declared_Prefix (T, P);
7708       else
7709          T := Etype (P);
7710       end if;
7711
7712       if Has_Discriminants (T)
7713         and then (Ekind (Entity (S)) = E_Component
7714                    or else
7715                   Ekind (Entity (S)) = E_Discriminant)
7716         and then Present (Original_Record_Component (Entity (S)))
7717         and then Ekind (Original_Record_Component (Entity (S))) = E_Component
7718         and then Present (Discriminant_Checking_Func
7719                            (Original_Record_Component (Entity (S))))
7720         and then not Discriminant_Checks_Suppressed (T)
7721         and then not Init_Component
7722       then
7723          Set_Do_Discriminant_Check (N);
7724       end if;
7725
7726       if Ekind (Entity (S)) = E_Void then
7727          Error_Msg_N ("premature use of component", S);
7728       end if;
7729
7730       --  If the prefix is a record conversion, this may be a renamed
7731       --  discriminant whose bounds differ from those of the original
7732       --  one, so we must ensure that a range check is performed.
7733
7734       if Nkind (P) = N_Type_Conversion
7735         and then Ekind (Entity (S)) = E_Discriminant
7736         and then Is_Discrete_Type (Typ)
7737       then
7738          Set_Etype (N, Base_Type (Typ));
7739       end if;
7740
7741       --  Note: No Eval processing is required, because the prefix is of a
7742       --  record type, or protected type, and neither can possibly be static.
7743
7744    end Resolve_Selected_Component;
7745
7746    -------------------
7747    -- Resolve_Shift --
7748    -------------------
7749
7750    procedure Resolve_Shift (N : Node_Id; Typ : Entity_Id) is
7751       B_Typ : constant Entity_Id := Base_Type (Typ);
7752       L     : constant Node_Id   := Left_Opnd  (N);
7753       R     : constant Node_Id   := Right_Opnd (N);
7754
7755    begin
7756       --  We do the resolution using the base type, because intermediate values
7757       --  in expressions always are of the base type, not a subtype of it.
7758
7759       Resolve (L, B_Typ);
7760       Resolve (R, Standard_Natural);
7761
7762       Check_Unset_Reference (L);
7763       Check_Unset_Reference (R);
7764
7765       Set_Etype (N, B_Typ);
7766       Generate_Operator_Reference (N, B_Typ);
7767       Eval_Shift (N);
7768    end Resolve_Shift;
7769
7770    ---------------------------
7771    -- Resolve_Short_Circuit --
7772    ---------------------------
7773
7774    procedure Resolve_Short_Circuit (N : Node_Id; Typ : Entity_Id) is
7775       B_Typ : constant Entity_Id := Base_Type (Typ);
7776       L     : constant Node_Id   := Left_Opnd  (N);
7777       R     : constant Node_Id   := Right_Opnd (N);
7778
7779    begin
7780       Resolve (L, B_Typ);
7781       Resolve (R, B_Typ);
7782
7783       --  Check for issuing warning for always False assert/check, this happens
7784       --  when assertions are turned off, in which case the pragma Assert/Check
7785       --  was transformed into:
7786
7787       --     if False and then <condition> then ...
7788
7789       --  and we detect this pattern
7790
7791       if Warn_On_Assertion_Failure
7792         and then Is_Entity_Name (R)
7793         and then Entity (R) = Standard_False
7794         and then Nkind (Parent (N)) = N_If_Statement
7795         and then Nkind (N) = N_And_Then
7796         and then Is_Entity_Name (L)
7797         and then Entity (L) = Standard_False
7798       then
7799          declare
7800             Orig : constant Node_Id := Original_Node (Parent (N));
7801
7802          begin
7803             if Nkind (Orig) = N_Pragma
7804               and then Pragma_Name (Orig) = Name_Assert
7805             then
7806                --  Don't want to warn if original condition is explicit False
7807
7808                declare
7809                   Expr : constant Node_Id :=
7810                            Original_Node
7811                              (Expression
7812                                (First (Pragma_Argument_Associations (Orig))));
7813                begin
7814                   if Is_Entity_Name (Expr)
7815                     and then Entity (Expr) = Standard_False
7816                   then
7817                      null;
7818                   else
7819                      --  Issue warning. Note that we don't want to make this
7820                      --  an unconditional warning, because if the assert is
7821                      --  within deleted code we do not want the warning. But
7822                      --  we do not want the deletion of the IF/AND-THEN to
7823                      --  take this message with it. We achieve this by making
7824                      --  sure that the expanded code points to the Sloc of
7825                      --  the expression, not the original pragma.
7826
7827                      Error_Msg_N ("?assertion would fail at run-time", Orig);
7828                   end if;
7829                end;
7830
7831             --  Similar processing for Check pragma
7832
7833             elsif Nkind (Orig) = N_Pragma
7834               and then Pragma_Name (Orig) = Name_Check
7835             then
7836                --  Don't want to warn if original condition is explicit False
7837
7838                declare
7839                   Expr : constant Node_Id :=
7840                            Original_Node
7841                              (Expression
7842                                 (Next (First
7843                                   (Pragma_Argument_Associations (Orig)))));
7844                begin
7845                   if Is_Entity_Name (Expr)
7846                     and then Entity (Expr) = Standard_False
7847                   then
7848                      null;
7849                   else
7850                      Error_Msg_N ("?check would fail at run-time", Orig);
7851                   end if;
7852                end;
7853             end if;
7854          end;
7855       end if;
7856
7857       --  Continue with processing of short circuit
7858
7859       Check_Unset_Reference (L);
7860       Check_Unset_Reference (R);
7861
7862       Set_Etype (N, B_Typ);
7863       Eval_Short_Circuit (N);
7864    end Resolve_Short_Circuit;
7865
7866    -------------------
7867    -- Resolve_Slice --
7868    -------------------
7869
7870    procedure Resolve_Slice (N : Node_Id; Typ : Entity_Id) is
7871       Name       : constant Node_Id := Prefix (N);
7872       Drange     : constant Node_Id := Discrete_Range (N);
7873       Array_Type : Entity_Id        := Empty;
7874       Index      : Node_Id;
7875
7876    begin
7877       if Is_Overloaded (Name) then
7878
7879          --  Use the context type to select the prefix that yields the correct
7880          --  array type.
7881
7882          declare
7883             I      : Interp_Index;
7884             I1     : Interp_Index := 0;
7885             It     : Interp;
7886             P      : constant Node_Id := Prefix (N);
7887             Found  : Boolean := False;
7888
7889          begin
7890             Get_First_Interp (P, I,  It);
7891             while Present (It.Typ) loop
7892                if (Is_Array_Type (It.Typ)
7893                     and then Covers (Typ,  It.Typ))
7894                  or else (Is_Access_Type (It.Typ)
7895                            and then Is_Array_Type (Designated_Type (It.Typ))
7896                            and then Covers (Typ, Designated_Type (It.Typ)))
7897                then
7898                   if Found then
7899                      It := Disambiguate (P, I1, I, Any_Type);
7900
7901                      if It = No_Interp then
7902                         Error_Msg_N ("ambiguous prefix for slicing",  N);
7903                         Set_Etype (N, Typ);
7904                         return;
7905                      else
7906                         Found := True;
7907                         Array_Type := It.Typ;
7908                         I1 := I;
7909                      end if;
7910                   else
7911                      Found := True;
7912                      Array_Type := It.Typ;
7913                      I1 := I;
7914                   end if;
7915                end if;
7916
7917                Get_Next_Interp (I, It);
7918             end loop;
7919          end;
7920
7921       else
7922          Array_Type := Etype (Name);
7923       end if;
7924
7925       Resolve (Name, Array_Type);
7926
7927       if Is_Access_Type (Array_Type) then
7928          Apply_Access_Check (N);
7929          Array_Type := Designated_Type (Array_Type);
7930
7931          --  If the prefix is an access to an unconstrained array, we must use
7932          --  the actual subtype of the object to perform the index checks. The
7933          --  object denoted by the prefix is implicit in the node, so we build
7934          --  an explicit representation for it in order to compute the actual
7935          --  subtype.
7936
7937          if not Is_Constrained (Array_Type) then
7938             Remove_Side_Effects (Prefix (N));
7939
7940             declare
7941                Obj : constant Node_Id :=
7942                        Make_Explicit_Dereference (Sloc (N),
7943                          Prefix => New_Copy_Tree (Prefix (N)));
7944             begin
7945                Set_Etype (Obj, Array_Type);
7946                Set_Parent (Obj, Parent (N));
7947                Array_Type := Get_Actual_Subtype (Obj);
7948             end;
7949          end if;
7950
7951       elsif Is_Entity_Name (Name)
7952         or else (Nkind (Name) = N_Function_Call
7953                   and then not Is_Constrained (Etype (Name)))
7954       then
7955          Array_Type := Get_Actual_Subtype (Name);
7956
7957       --  If the name is a selected component that depends on discriminants,
7958       --  build an actual subtype for it. This can happen only when the name
7959       --  itself is overloaded; otherwise the actual subtype is created when
7960       --  the selected component is analyzed.
7961
7962       elsif Nkind (Name) = N_Selected_Component
7963         and then Full_Analysis
7964         and then Depends_On_Discriminant (First_Index (Array_Type))
7965       then
7966          declare
7967             Act_Decl : constant Node_Id :=
7968                          Build_Actual_Subtype_Of_Component (Array_Type, Name);
7969          begin
7970             Insert_Action (N, Act_Decl);
7971             Array_Type := Defining_Identifier (Act_Decl);
7972          end;
7973
7974       --  Maybe this should just be "else", instead of checking for the
7975       --  specific case of slice??? This is needed for the case where
7976       --  the prefix is an Image attribute, which gets expanded to a
7977       --  slice, and so has a constrained subtype which we want to use
7978       --  for the slice range check applied below (the range check won't
7979       --  get done if the unconstrained subtype of the 'Image is used).
7980
7981       elsif Nkind (Name) = N_Slice then
7982          Array_Type := Etype (Name);
7983       end if;
7984
7985       --  If name was overloaded, set slice type correctly now
7986
7987       Set_Etype (N, Array_Type);
7988
7989       --  If the range is specified by a subtype mark, no resolution is
7990       --  necessary. Else resolve the bounds, and apply needed checks.
7991
7992       if not Is_Entity_Name (Drange) then
7993          Index := First_Index (Array_Type);
7994          Resolve (Drange, Base_Type (Etype (Index)));
7995
7996          if Nkind (Drange) = N_Range
7997
7998             --  Do not apply the range check to nodes associated with the
7999             --  frontend expansion of the dispatch table. We first check
8000             --  if Ada.Tags is already loaded to void the addition of an
8001             --  undesired dependence on such run-time unit.
8002
8003            and then
8004              (not Tagged_Type_Expansion
8005                or else not
8006                  (RTU_Loaded (Ada_Tags)
8007                    and then Nkind (Prefix (N)) = N_Selected_Component
8008                    and then Present (Entity (Selector_Name (Prefix (N))))
8009                    and then Entity (Selector_Name (Prefix (N))) =
8010                                          RTE_Record_Component (RE_Prims_Ptr)))
8011          then
8012             Apply_Range_Check (Drange, Etype (Index));
8013          end if;
8014       end if;
8015
8016       Set_Slice_Subtype (N);
8017
8018       if Nkind (Drange) = N_Range then
8019          Warn_On_Suspicious_Index (Name, Low_Bound  (Drange));
8020          Warn_On_Suspicious_Index (Name, High_Bound (Drange));
8021       end if;
8022
8023       Eval_Slice (N);
8024    end Resolve_Slice;
8025
8026    ----------------------------
8027    -- Resolve_String_Literal --
8028    ----------------------------
8029
8030    procedure Resolve_String_Literal (N : Node_Id; Typ : Entity_Id) is
8031       C_Typ      : constant Entity_Id  := Component_Type (Typ);
8032       R_Typ      : constant Entity_Id  := Root_Type (C_Typ);
8033       Loc        : constant Source_Ptr := Sloc (N);
8034       Str        : constant String_Id  := Strval (N);
8035       Strlen     : constant Nat        := String_Length (Str);
8036       Subtype_Id : Entity_Id;
8037       Need_Check : Boolean;
8038
8039    begin
8040       --  For a string appearing in a concatenation, defer creation of the
8041       --  string_literal_subtype until the end of the resolution of the
8042       --  concatenation, because the literal may be constant-folded away. This
8043       --  is a useful optimization for long concatenation expressions.
8044
8045       --  If the string is an aggregate built for a single character (which
8046       --  happens in a non-static context) or a is null string to which special
8047       --  checks may apply, we build the subtype. Wide strings must also get a
8048       --  string subtype if they come from a one character aggregate. Strings
8049       --  generated by attributes might be static, but it is often hard to
8050       --  determine whether the enclosing context is static, so we generate
8051       --  subtypes for them as well, thus losing some rarer optimizations ???
8052       --  Same for strings that come from a static conversion.
8053
8054       Need_Check :=
8055         (Strlen = 0 and then Typ /= Standard_String)
8056           or else Nkind (Parent (N)) /= N_Op_Concat
8057           or else (N /= Left_Opnd (Parent (N))
8058                     and then N /= Right_Opnd (Parent (N)))
8059           or else ((Typ = Standard_Wide_String
8060                       or else Typ = Standard_Wide_Wide_String)
8061                     and then Nkind (Original_Node (N)) /= N_String_Literal);
8062
8063       --  If the resolving type is itself a string literal subtype, we can just
8064       --  reuse it, since there is no point in creating another.
8065
8066       if Ekind (Typ) = E_String_Literal_Subtype then
8067          Subtype_Id := Typ;
8068
8069       elsif Nkind (Parent (N)) = N_Op_Concat
8070         and then not Need_Check
8071         and then not Nkind_In (Original_Node (N), N_Character_Literal,
8072                                                   N_Attribute_Reference,
8073                                                   N_Qualified_Expression,
8074                                                   N_Type_Conversion)
8075       then
8076          Subtype_Id := Typ;
8077
8078       --  Otherwise we must create a string literal subtype. Note that the
8079       --  whole idea of string literal subtypes is simply to avoid the need
8080       --  for building a full fledged array subtype for each literal.
8081
8082       else
8083          Set_String_Literal_Subtype (N, Typ);
8084          Subtype_Id := Etype (N);
8085       end if;
8086
8087       if Nkind (Parent (N)) /= N_Op_Concat
8088         or else Need_Check
8089       then
8090          Set_Etype (N, Subtype_Id);
8091          Eval_String_Literal (N);
8092       end if;
8093
8094       if Is_Limited_Composite (Typ)
8095         or else Is_Private_Composite (Typ)
8096       then
8097          Error_Msg_N ("string literal not available for private array", N);
8098          Set_Etype (N, Any_Type);
8099          return;
8100       end if;
8101
8102       --  The validity of a null string has been checked in the call to
8103       --  Eval_String_Literal.
8104
8105       if Strlen = 0 then
8106          return;
8107
8108       --  Always accept string literal with component type Any_Character, which
8109       --  occurs in error situations and in comparisons of literals, both of
8110       --  which should accept all literals.
8111
8112       elsif R_Typ = Any_Character then
8113          return;
8114
8115       --  If the type is bit-packed, then we always transform the string
8116       --  literal into a full fledged aggregate.
8117
8118       elsif Is_Bit_Packed_Array (Typ) then
8119          null;
8120
8121       --  Deal with cases of Wide_Wide_String, Wide_String, and String
8122
8123       else
8124          --  For Standard.Wide_Wide_String, or any other type whose component
8125          --  type is Standard.Wide_Wide_Character, we know that all the
8126          --  characters in the string must be acceptable, since the parser
8127          --  accepted the characters as valid character literals.
8128
8129          if R_Typ = Standard_Wide_Wide_Character then
8130             null;
8131
8132          --  For the case of Standard.String, or any other type whose component
8133          --  type is Standard.Character, we must make sure that there are no
8134          --  wide characters in the string, i.e. that it is entirely composed
8135          --  of characters in range of type Character.
8136
8137          --  If the string literal is the result of a static concatenation, the
8138          --  test has already been performed on the components, and need not be
8139          --  repeated.
8140
8141          elsif R_Typ = Standard_Character
8142            and then Nkind (Original_Node (N)) /= N_Op_Concat
8143          then
8144             for J in 1 .. Strlen loop
8145                if not In_Character_Range (Get_String_Char (Str, J)) then
8146
8147                   --  If we are out of range, post error. This is one of the
8148                   --  very few places that we place the flag in the middle of
8149                   --  a token, right under the offending wide character. Not
8150                   --  quite clear if this is right wrt wide character encoding
8151                   --  sequences, but it's only an error message!
8152
8153                   Error_Msg
8154                     ("literal out of range of type Standard.Character",
8155                      Source_Ptr (Int (Loc) + J));
8156                   return;
8157                end if;
8158             end loop;
8159
8160          --  For the case of Standard.Wide_String, or any other type whose
8161          --  component type is Standard.Wide_Character, we must make sure that
8162          --  there are no wide characters in the string, i.e. that it is
8163          --  entirely composed of characters in range of type Wide_Character.
8164
8165          --  If the string literal is the result of a static concatenation,
8166          --  the test has already been performed on the components, and need
8167          --  not be repeated.
8168
8169          elsif R_Typ = Standard_Wide_Character
8170            and then Nkind (Original_Node (N)) /= N_Op_Concat
8171          then
8172             for J in 1 .. Strlen loop
8173                if not In_Wide_Character_Range (Get_String_Char (Str, J)) then
8174
8175                   --  If we are out of range, post error. This is one of the
8176                   --  very few places that we place the flag in the middle of
8177                   --  a token, right under the offending wide character.
8178
8179                   --  This is not quite right, because characters in general
8180                   --  will take more than one character position ???
8181
8182                   Error_Msg
8183                     ("literal out of range of type Standard.Wide_Character",
8184                      Source_Ptr (Int (Loc) + J));
8185                   return;
8186                end if;
8187             end loop;
8188
8189          --  If the root type is not a standard character, then we will convert
8190          --  the string into an aggregate and will let the aggregate code do
8191          --  the checking. Standard Wide_Wide_Character is also OK here.
8192
8193          else
8194             null;
8195          end if;
8196
8197          --  See if the component type of the array corresponding to the string
8198          --  has compile time known bounds. If yes we can directly check
8199          --  whether the evaluation of the string will raise constraint error.
8200          --  Otherwise we need to transform the string literal into the
8201          --  corresponding character aggregate and let the aggregate
8202          --  code do the checking.
8203
8204          if Is_Standard_Character_Type (R_Typ) then
8205
8206             --  Check for the case of full range, where we are definitely OK
8207
8208             if Component_Type (Typ) = Base_Type (Component_Type (Typ)) then
8209                return;
8210             end if;
8211
8212             --  Here the range is not the complete base type range, so check
8213
8214             declare
8215                Comp_Typ_Lo : constant Node_Id :=
8216                                Type_Low_Bound (Component_Type (Typ));
8217                Comp_Typ_Hi : constant Node_Id :=
8218                                Type_High_Bound (Component_Type (Typ));
8219
8220                Char_Val : Uint;
8221
8222             begin
8223                if Compile_Time_Known_Value (Comp_Typ_Lo)
8224                  and then Compile_Time_Known_Value (Comp_Typ_Hi)
8225                then
8226                   for J in 1 .. Strlen loop
8227                      Char_Val := UI_From_Int (Int (Get_String_Char (Str, J)));
8228
8229                      if Char_Val < Expr_Value (Comp_Typ_Lo)
8230                        or else Char_Val > Expr_Value (Comp_Typ_Hi)
8231                      then
8232                         Apply_Compile_Time_Constraint_Error
8233                           (N, "character out of range?", CE_Range_Check_Failed,
8234                            Loc => Source_Ptr (Int (Loc) + J));
8235                      end if;
8236                   end loop;
8237
8238                   return;
8239                end if;
8240             end;
8241          end if;
8242       end if;
8243
8244       --  If we got here we meed to transform the string literal into the
8245       --  equivalent qualified positional array aggregate. This is rather
8246       --  heavy artillery for this situation, but it is hard work to avoid.
8247
8248       declare
8249          Lits : constant List_Id    := New_List;
8250          P    : Source_Ptr := Loc + 1;
8251          C    : Char_Code;
8252
8253       begin
8254          --  Build the character literals, we give them source locations that
8255          --  correspond to the string positions, which is a bit tricky given
8256          --  the possible presence of wide character escape sequences.
8257
8258          for J in 1 .. Strlen loop
8259             C := Get_String_Char (Str, J);
8260             Set_Character_Literal_Name (C);
8261
8262             Append_To (Lits,
8263               Make_Character_Literal (P,
8264                 Chars              => Name_Find,
8265                 Char_Literal_Value => UI_From_CC (C)));
8266
8267             if In_Character_Range (C) then
8268                P := P + 1;
8269
8270             --  Should we have a call to Skip_Wide here ???
8271             --  ???     else
8272             --             Skip_Wide (P);
8273
8274             end if;
8275          end loop;
8276
8277          Rewrite (N,
8278            Make_Qualified_Expression (Loc,
8279              Subtype_Mark => New_Reference_To (Typ, Loc),
8280              Expression   =>
8281                Make_Aggregate (Loc, Expressions => Lits)));
8282
8283          Analyze_And_Resolve (N, Typ);
8284       end;
8285    end Resolve_String_Literal;
8286
8287    -----------------------------
8288    -- Resolve_Subprogram_Info --
8289    -----------------------------
8290
8291    procedure Resolve_Subprogram_Info (N : Node_Id; Typ : Entity_Id) is
8292    begin
8293       Set_Etype (N, Typ);
8294    end Resolve_Subprogram_Info;
8295
8296    -----------------------------
8297    -- Resolve_Type_Conversion --
8298    -----------------------------
8299
8300    procedure Resolve_Type_Conversion (N : Node_Id; Typ : Entity_Id) is
8301       Conv_OK     : constant Boolean   := Conversion_OK (N);
8302       Operand     : constant Node_Id   := Expression (N);
8303       Operand_Typ : constant Entity_Id := Etype (Operand);
8304       Target_Typ  : constant Entity_Id := Etype (N);
8305       Rop         : Node_Id;
8306       Orig_N      : Node_Id;
8307       Orig_T      : Node_Id;
8308
8309    begin
8310       if not Conv_OK
8311         and then not Valid_Conversion (N, Target_Typ, Operand)
8312       then
8313          return;
8314       end if;
8315
8316       if Etype (Operand) = Any_Fixed then
8317
8318          --  Mixed-mode operation involving a literal. Context must be a fixed
8319          --  type which is applied to the literal subsequently.
8320
8321          if Is_Fixed_Point_Type (Typ) then
8322             Set_Etype (Operand, Universal_Real);
8323
8324          elsif Is_Numeric_Type (Typ)
8325            and then Nkind_In (Operand, N_Op_Multiply, N_Op_Divide)
8326            and then (Etype (Right_Opnd (Operand)) = Universal_Real
8327                        or else
8328                      Etype (Left_Opnd  (Operand)) = Universal_Real)
8329          then
8330             --  Return if expression is ambiguous
8331
8332             if Unique_Fixed_Point_Type (N) = Any_Type then
8333                return;
8334
8335             --  If nothing else, the available fixed type is Duration
8336
8337             else
8338                Set_Etype (Operand, Standard_Duration);
8339             end if;
8340
8341             --  Resolve the real operand with largest available precision
8342
8343             if Etype (Right_Opnd (Operand)) = Universal_Real then
8344                Rop := New_Copy_Tree (Right_Opnd (Operand));
8345             else
8346                Rop := New_Copy_Tree (Left_Opnd (Operand));
8347             end if;
8348
8349             Resolve (Rop, Universal_Real);
8350
8351             --  If the operand is a literal (it could be a non-static and
8352             --  illegal exponentiation) check whether the use of Duration
8353             --  is potentially inaccurate.
8354
8355             if Nkind (Rop) = N_Real_Literal
8356               and then Realval (Rop) /= Ureal_0
8357               and then abs (Realval (Rop)) < Delta_Value (Standard_Duration)
8358             then
8359                Error_Msg_N
8360                  ("?universal real operand can only " &
8361                   "be interpreted as Duration!",
8362                   Rop);
8363                Error_Msg_N
8364                  ("\?precision will be lost in the conversion!", Rop);
8365             end if;
8366
8367          elsif Is_Numeric_Type (Typ)
8368            and then Nkind (Operand) in N_Op
8369            and then Unique_Fixed_Point_Type (N) /= Any_Type
8370          then
8371             Set_Etype (Operand, Standard_Duration);
8372
8373          else
8374             Error_Msg_N ("invalid context for mixed mode operation", N);
8375             Set_Etype (Operand, Any_Type);
8376             return;
8377          end if;
8378       end if;
8379
8380       Resolve (Operand);
8381
8382       --  Note: we do the Eval_Type_Conversion call before applying the
8383       --  required checks for a subtype conversion. This is important, since
8384       --  both are prepared under certain circumstances to change the type
8385       --  conversion to a constraint error node, but in the case of
8386       --  Eval_Type_Conversion this may reflect an illegality in the static
8387       --  case, and we would miss the illegality (getting only a warning
8388       --  message), if we applied the type conversion checks first.
8389
8390       Eval_Type_Conversion (N);
8391
8392       --  Even when evaluation is not possible, we may be able to simplify the
8393       --  conversion or its expression. This needs to be done before applying
8394       --  checks, since otherwise the checks may use the original expression
8395       --  and defeat the simplifications. This is specifically the case for
8396       --  elimination of the floating-point Truncation attribute in
8397       --  float-to-int conversions.
8398
8399       Simplify_Type_Conversion (N);
8400
8401       --  If after evaluation we still have a type conversion, then we may need
8402       --  to apply checks required for a subtype conversion.
8403
8404       --  Skip these type conversion checks if universal fixed operands
8405       --  operands involved, since range checks are handled separately for
8406       --  these cases (in the appropriate Expand routines in unit Exp_Fixd).
8407
8408       if Nkind (N) = N_Type_Conversion
8409         and then not Is_Generic_Type (Root_Type (Target_Typ))
8410         and then Target_Typ  /= Universal_Fixed
8411         and then Operand_Typ /= Universal_Fixed
8412       then
8413          Apply_Type_Conversion_Checks (N);
8414       end if;
8415
8416       --  Issue warning for conversion of simple object to its own type. We
8417       --  have to test the original nodes, since they may have been rewritten
8418       --  by various optimizations.
8419
8420       Orig_N := Original_Node (N);
8421
8422       if Warn_On_Redundant_Constructs
8423         and then Comes_From_Source (Orig_N)
8424         and then Nkind (Orig_N) = N_Type_Conversion
8425         and then not In_Instance
8426       then
8427          Orig_N := Original_Node (Expression (Orig_N));
8428          Orig_T := Target_Typ;
8429
8430          --  If the node is part of a larger expression, the Target_Type
8431          --  may not be the original type of the node if the context is a
8432          --  condition. Recover original type to see if conversion is needed.
8433
8434          if Is_Boolean_Type (Orig_T)
8435           and then Nkind (Parent (N)) in N_Op
8436          then
8437             Orig_T := Etype (Parent (N));
8438          end if;
8439
8440          if Is_Entity_Name (Orig_N)
8441            and then
8442              (Etype (Entity (Orig_N)) = Orig_T
8443                 or else
8444                   (Ekind (Entity (Orig_N)) = E_Loop_Parameter
8445                      and then Covers (Orig_T, Etype (Entity (Orig_N)))))
8446          then
8447             --  One more check, do not give warning if the analyzed conversion
8448             --  has an expression with non-static bounds, and the bounds of the
8449             --  target are static. This avoids junk warnings in cases where the
8450             --  conversion is necessary to establish staticness, for example in
8451             --  a case statement.
8452
8453             if not Is_OK_Static_Subtype (Operand_Typ)
8454               and then Is_OK_Static_Subtype (Target_Typ)
8455             then
8456                null;
8457
8458             --  Here we give the redundant conversion warning
8459
8460             else
8461                Error_Msg_Node_2 := Orig_T;
8462                Error_Msg_NE -- CODEFIX
8463                  ("?redundant conversion, & is of type &!",
8464                   N, Entity (Orig_N));
8465             end if;
8466          end if;
8467       end if;
8468
8469       --  Ada 2005 (AI-251): Handle class-wide interface type conversions.
8470       --  No need to perform any interface conversion if the type of the
8471       --  expression coincides with the target type.
8472
8473       if Ada_Version >= Ada_05
8474         and then Expander_Active
8475         and then Operand_Typ /= Target_Typ
8476       then
8477          declare
8478             Opnd   : Entity_Id := Operand_Typ;
8479             Target : Entity_Id := Target_Typ;
8480
8481          begin
8482             if Is_Access_Type (Opnd) then
8483                Opnd := Directly_Designated_Type (Opnd);
8484             end if;
8485
8486             if Is_Access_Type (Target_Typ) then
8487                Target := Directly_Designated_Type (Target);
8488             end if;
8489
8490             if Opnd = Target then
8491                null;
8492
8493             --  Conversion from interface type
8494
8495             elsif Is_Interface (Opnd) then
8496
8497                --  Ada 2005 (AI-217): Handle entities from limited views
8498
8499                if From_With_Type (Opnd) then
8500                   Error_Msg_Qual_Level := 99;
8501                   Error_Msg_NE ("missing WITH clause on package &", N,
8502                     Cunit_Entity (Get_Source_Unit (Base_Type (Opnd))));
8503                   Error_Msg_N
8504                     ("type conversions require visibility of the full view",
8505                      N);
8506
8507                elsif From_With_Type (Target)
8508                  and then not
8509                    (Is_Access_Type (Target_Typ)
8510                       and then Present (Non_Limited_View (Etype (Target))))
8511                then
8512                   Error_Msg_Qual_Level := 99;
8513                   Error_Msg_NE ("missing WITH clause on package &", N,
8514                     Cunit_Entity (Get_Source_Unit (Base_Type (Target))));
8515                   Error_Msg_N
8516                     ("type conversions require visibility of the full view",
8517                      N);
8518
8519                else
8520                   Expand_Interface_Conversion (N, Is_Static => False);
8521                end if;
8522
8523             --  Conversion to interface type
8524
8525             elsif Is_Interface (Target) then
8526
8527                --  Handle subtypes
8528
8529                if Ekind (Opnd) = E_Protected_Subtype
8530                  or else Ekind (Opnd) = E_Task_Subtype
8531                then
8532                   Opnd := Etype (Opnd);
8533                end if;
8534
8535                if not Interface_Present_In_Ancestor
8536                         (Typ   => Opnd,
8537                          Iface => Target)
8538                then
8539                   if Is_Class_Wide_Type (Opnd) then
8540
8541                      --  The static analysis is not enough to know if the
8542                      --  interface is implemented or not. Hence we must pass
8543                      --  the work to the expander to generate code to evaluate
8544                      --  the conversion at run-time.
8545
8546                      Expand_Interface_Conversion (N, Is_Static => False);
8547
8548                   else
8549                      Error_Msg_Name_1 := Chars (Etype (Target));
8550                      Error_Msg_Name_2 := Chars (Opnd);
8551                      Error_Msg_N
8552                        ("wrong interface conversion (% is not a progenitor " &
8553                         "of %)", N);
8554                   end if;
8555
8556                else
8557                   Expand_Interface_Conversion (N);
8558                end if;
8559             end if;
8560          end;
8561       end if;
8562    end Resolve_Type_Conversion;
8563
8564    ----------------------
8565    -- Resolve_Unary_Op --
8566    ----------------------
8567
8568    procedure Resolve_Unary_Op (N : Node_Id; Typ : Entity_Id) is
8569       B_Typ : constant Entity_Id := Base_Type (Typ);
8570       R     : constant Node_Id   := Right_Opnd (N);
8571       OK    : Boolean;
8572       Lo    : Uint;
8573       Hi    : Uint;
8574
8575    begin
8576       --  Deal with intrinsic unary operators
8577
8578       if Comes_From_Source (N)
8579         and then Ekind (Entity (N)) = E_Function
8580         and then Is_Imported (Entity (N))
8581         and then Is_Intrinsic_Subprogram (Entity (N))
8582       then
8583          Resolve_Intrinsic_Unary_Operator (N, Typ);
8584          return;
8585       end if;
8586
8587       --  Deal with universal cases
8588
8589       if Etype (R) = Universal_Integer
8590            or else
8591          Etype (R) = Universal_Real
8592       then
8593          Check_For_Visible_Operator (N, B_Typ);
8594       end if;
8595
8596       Set_Etype (N, B_Typ);
8597       Resolve (R, B_Typ);
8598
8599       --  Generate warning for expressions like abs (x mod 2)
8600
8601       if Warn_On_Redundant_Constructs
8602         and then Nkind (N) = N_Op_Abs
8603       then
8604          Determine_Range (Right_Opnd (N), OK, Lo, Hi);
8605
8606          if OK and then Hi >= Lo and then Lo >= 0 then
8607             Error_Msg_N
8608              ("?abs applied to known non-negative value has no effect", N);
8609          end if;
8610       end if;
8611
8612       --  Deal with reference generation
8613
8614       Check_Unset_Reference (R);
8615       Generate_Operator_Reference (N, B_Typ);
8616       Eval_Unary_Op (N);
8617
8618       --  Set overflow checking bit. Much cleverer code needed here eventually
8619       --  and perhaps the Resolve routines should be separated for the various
8620       --  arithmetic operations, since they will need different processing ???
8621
8622       if Nkind (N) in N_Op then
8623          if not Overflow_Checks_Suppressed (Etype (N)) then
8624             Enable_Overflow_Check (N);
8625          end if;
8626       end if;
8627
8628       --  Generate warning for expressions like -5 mod 3 for integers. No need
8629       --  to worry in the floating-point case, since parens do not affect the
8630       --  result so there is no point in giving in a warning.
8631
8632       declare
8633          Norig : constant Node_Id := Original_Node (N);
8634          Rorig : Node_Id;
8635          Val   : Uint;
8636          HB    : Uint;
8637          LB    : Uint;
8638          Lval  : Uint;
8639          Opnd  : Node_Id;
8640
8641       begin
8642          if Warn_On_Questionable_Missing_Parens
8643            and then Comes_From_Source (Norig)
8644            and then Is_Integer_Type (Typ)
8645            and then Nkind (Norig) = N_Op_Minus
8646          then
8647             Rorig := Original_Node (Right_Opnd (Norig));
8648
8649             --  We are looking for cases where the right operand is not
8650             --  parenthesized, and is a binary operator, multiply, divide, or
8651             --  mod. These are the cases where the grouping can affect results.
8652
8653             if Paren_Count (Rorig) = 0
8654               and then Nkind_In (Rorig, N_Op_Mod, N_Op_Multiply, N_Op_Divide)
8655             then
8656                --  For mod, we always give the warning, since the value is
8657                --  affected by the parenthesization (e.g. (-5) mod 315 /=
8658                --  -(5 mod 315)). But for the other cases, the only concern is
8659                --  overflow, e.g. for the case of 8 big signed (-(2 * 64)
8660                --  overflows, but (-2) * 64 does not). So we try to give the
8661                --  message only when overflow is possible.
8662
8663                if Nkind (Rorig) /= N_Op_Mod
8664                  and then Compile_Time_Known_Value (R)
8665                then
8666                   Val := Expr_Value (R);
8667
8668                   if Compile_Time_Known_Value (Type_High_Bound (Typ)) then
8669                      HB := Expr_Value (Type_High_Bound (Typ));
8670                   else
8671                      HB := Expr_Value (Type_High_Bound (Base_Type (Typ)));
8672                   end if;
8673
8674                   if Compile_Time_Known_Value (Type_Low_Bound (Typ)) then
8675                      LB := Expr_Value (Type_Low_Bound (Typ));
8676                   else
8677                      LB := Expr_Value (Type_Low_Bound (Base_Type (Typ)));
8678                   end if;
8679
8680                   --  Note that the test below is deliberately excluding the
8681                   --  largest negative number, since that is a potentially
8682                   --  troublesome case (e.g. -2 * x, where the result is the
8683                   --  largest negative integer has an overflow with 2 * x).
8684
8685                   if Val > LB and then Val <= HB then
8686                      return;
8687                   end if;
8688                end if;
8689
8690                --  For the multiplication case, the only case we have to worry
8691                --  about is when (-a)*b is exactly the largest negative number
8692                --  so that -(a*b) can cause overflow. This can only happen if
8693                --  a is a power of 2, and more generally if any operand is a
8694                --  constant that is not a power of 2, then the parentheses
8695                --  cannot affect whether overflow occurs. We only bother to
8696                --  test the left most operand
8697
8698                --  Loop looking at left operands for one that has known value
8699
8700                Opnd := Rorig;
8701                Opnd_Loop : while Nkind (Opnd) = N_Op_Multiply loop
8702                   if Compile_Time_Known_Value (Left_Opnd (Opnd)) then
8703                      Lval := UI_Abs (Expr_Value (Left_Opnd (Opnd)));
8704
8705                      --  Operand value of 0 or 1 skips warning
8706
8707                      if Lval <= 1 then
8708                         return;
8709
8710                      --  Otherwise check power of 2, if power of 2, warn, if
8711                      --  anything else, skip warning.
8712
8713                      else
8714                         while Lval /= 2 loop
8715                            if Lval mod 2 = 1 then
8716                               return;
8717                            else
8718                               Lval := Lval / 2;
8719                            end if;
8720                         end loop;
8721
8722                         exit Opnd_Loop;
8723                      end if;
8724                   end if;
8725
8726                   --  Keep looking at left operands
8727
8728                   Opnd := Left_Opnd (Opnd);
8729                end loop Opnd_Loop;
8730
8731                --  For rem or "/" we can only have a problematic situation
8732                --  if the divisor has a value of minus one or one. Otherwise
8733                --  overflow is impossible (divisor > 1) or we have a case of
8734                --  division by zero in any case.
8735
8736                if Nkind_In (Rorig, N_Op_Divide, N_Op_Rem)
8737                  and then Compile_Time_Known_Value (Right_Opnd (Rorig))
8738                  and then UI_Abs (Expr_Value (Right_Opnd (Rorig))) /= 1
8739                then
8740                   return;
8741                end if;
8742
8743                --  If we fall through warning should be issued
8744
8745                Error_Msg_N
8746                  ("?unary minus expression should be parenthesized here!", N);
8747             end if;
8748          end if;
8749       end;
8750    end Resolve_Unary_Op;
8751
8752    ----------------------------------
8753    -- Resolve_Unchecked_Expression --
8754    ----------------------------------
8755
8756    procedure Resolve_Unchecked_Expression
8757      (N   : Node_Id;
8758       Typ : Entity_Id)
8759    is
8760    begin
8761       Resolve (Expression (N), Typ, Suppress => All_Checks);
8762       Set_Etype (N, Typ);
8763    end Resolve_Unchecked_Expression;
8764
8765    ---------------------------------------
8766    -- Resolve_Unchecked_Type_Conversion --
8767    ---------------------------------------
8768
8769    procedure Resolve_Unchecked_Type_Conversion
8770      (N   : Node_Id;
8771       Typ : Entity_Id)
8772    is
8773       pragma Warnings (Off, Typ);
8774
8775       Operand   : constant Node_Id   := Expression (N);
8776       Opnd_Type : constant Entity_Id := Etype (Operand);
8777
8778    begin
8779       --  Resolve operand using its own type
8780
8781       Resolve (Operand, Opnd_Type);
8782       Eval_Unchecked_Conversion (N);
8783
8784    end Resolve_Unchecked_Type_Conversion;
8785
8786    ------------------------------
8787    -- Rewrite_Operator_As_Call --
8788    ------------------------------
8789
8790    procedure Rewrite_Operator_As_Call (N : Node_Id; Nam : Entity_Id) is
8791       Loc     : constant Source_Ptr := Sloc (N);
8792       Actuals : constant List_Id    := New_List;
8793       New_N   : Node_Id;
8794
8795    begin
8796       if Nkind (N) in  N_Binary_Op then
8797          Append (Left_Opnd (N), Actuals);
8798       end if;
8799
8800       Append (Right_Opnd (N), Actuals);
8801
8802       New_N :=
8803         Make_Function_Call (Sloc => Loc,
8804           Name => New_Occurrence_Of (Nam, Loc),
8805           Parameter_Associations => Actuals);
8806
8807       Preserve_Comes_From_Source (New_N, N);
8808       Preserve_Comes_From_Source (Name (New_N), N);
8809       Rewrite (N, New_N);
8810       Set_Etype (N, Etype (Nam));
8811    end Rewrite_Operator_As_Call;
8812
8813    ------------------------------
8814    -- Rewrite_Renamed_Operator --
8815    ------------------------------
8816
8817    procedure Rewrite_Renamed_Operator
8818      (N   : Node_Id;
8819       Op  : Entity_Id;
8820       Typ : Entity_Id)
8821    is
8822       Nam       : constant Name_Id := Chars (Op);
8823       Is_Binary : constant Boolean := Nkind (N) in N_Binary_Op;
8824       Op_Node   : Node_Id;
8825
8826    begin
8827       --  Rewrite the operator node using the real operator, not its renaming.
8828       --  Exclude user-defined intrinsic operations of the same name, which are
8829       --  treated separately and rewritten as calls.
8830
8831       if Ekind (Op) /= E_Function
8832         or else Chars (N) /= Nam
8833       then
8834          Op_Node := New_Node (Operator_Kind (Nam, Is_Binary), Sloc (N));
8835          Set_Chars      (Op_Node, Nam);
8836          Set_Etype      (Op_Node, Etype (N));
8837          Set_Entity     (Op_Node, Op);
8838          Set_Right_Opnd (Op_Node, Right_Opnd (N));
8839
8840          --  Indicate that both the original entity and its renaming are
8841          --  referenced at this point.
8842
8843          Generate_Reference (Entity (N), N);
8844          Generate_Reference (Op, N);
8845
8846          if Is_Binary then
8847             Set_Left_Opnd  (Op_Node, Left_Opnd  (N));
8848          end if;
8849
8850          Rewrite (N, Op_Node);
8851
8852          --  If the context type is private, add the appropriate conversions
8853          --  so that the operator is applied to the full view. This is done
8854          --  in the routines that resolve intrinsic operators,
8855
8856          if Is_Intrinsic_Subprogram (Op)
8857            and then Is_Private_Type (Typ)
8858          then
8859             case Nkind (N) is
8860                when N_Op_Add   | N_Op_Subtract | N_Op_Multiply | N_Op_Divide |
8861                     N_Op_Expon | N_Op_Mod      | N_Op_Rem      =>
8862                   Resolve_Intrinsic_Operator (N, Typ);
8863
8864                when N_Op_Plus  | N_Op_Minus    | N_Op_Abs      =>
8865                   Resolve_Intrinsic_Unary_Operator (N, Typ);
8866
8867                when others =>
8868                   Resolve (N, Typ);
8869             end case;
8870          end if;
8871
8872       elsif Ekind (Op) = E_Function
8873         and then Is_Intrinsic_Subprogram (Op)
8874       then
8875          --  Operator renames a user-defined operator of the same name. Use
8876          --  the original operator in the node, which is the one that Gigi
8877          --  knows about.
8878
8879          Set_Entity (N, Op);
8880          Set_Is_Overloaded (N, False);
8881       end if;
8882    end Rewrite_Renamed_Operator;
8883
8884    -----------------------
8885    -- Set_Slice_Subtype --
8886    -----------------------
8887
8888    --  Build an implicit subtype declaration to represent the type delivered
8889    --  by the slice. This is an abbreviated version of an array subtype. We
8890    --  define an index subtype for the slice, using either the subtype name
8891    --  or the discrete range of the slice. To be consistent with index usage
8892    --  elsewhere, we create a list header to hold the single index. This list
8893    --  is not otherwise attached to the syntax tree.
8894
8895    procedure Set_Slice_Subtype (N : Node_Id) is
8896       Loc           : constant Source_Ptr := Sloc (N);
8897       Index_List    : constant List_Id    := New_List;
8898       Index         : Node_Id;
8899       Index_Subtype : Entity_Id;
8900       Index_Type    : Entity_Id;
8901       Slice_Subtype : Entity_Id;
8902       Drange        : constant Node_Id := Discrete_Range (N);
8903
8904    begin
8905       if Is_Entity_Name (Drange) then
8906          Index_Subtype := Entity (Drange);
8907
8908       else
8909          --  We force the evaluation of a range. This is definitely needed in
8910          --  the renamed case, and seems safer to do unconditionally. Note in
8911          --  any case that since we will create and insert an Itype referring
8912          --  to this range, we must make sure any side effect removal actions
8913          --  are inserted before the Itype definition.
8914
8915          if Nkind (Drange) = N_Range then
8916             Force_Evaluation (Low_Bound (Drange));
8917             Force_Evaluation (High_Bound (Drange));
8918          end if;
8919
8920          Index_Type := Base_Type (Etype (Drange));
8921
8922          Index_Subtype := Create_Itype (Subtype_Kind (Ekind (Index_Type)), N);
8923
8924          Set_Scalar_Range (Index_Subtype, Drange);
8925          Set_Etype        (Index_Subtype, Index_Type);
8926          Set_Size_Info    (Index_Subtype, Index_Type);
8927          Set_RM_Size      (Index_Subtype, RM_Size (Index_Type));
8928       end if;
8929
8930       Slice_Subtype := Create_Itype (E_Array_Subtype, N);
8931
8932       Index := New_Occurrence_Of (Index_Subtype, Loc);
8933       Set_Etype (Index, Index_Subtype);
8934       Append (Index, Index_List);
8935
8936       Set_First_Index    (Slice_Subtype, Index);
8937       Set_Etype          (Slice_Subtype, Base_Type (Etype (N)));
8938       Set_Is_Constrained (Slice_Subtype, True);
8939
8940       Check_Compile_Time_Size (Slice_Subtype);
8941
8942       --  The Etype of the existing Slice node is reset to this slice subtype.
8943       --  Its bounds are obtained from its first index.
8944
8945       Set_Etype (N, Slice_Subtype);
8946
8947       --  In the packed case, this must be immediately frozen
8948
8949       --  Couldn't we always freeze here??? and if we did, then the above
8950       --  call to Check_Compile_Time_Size could be eliminated, which would
8951       --  be nice, because then that routine could be made private to Freeze.
8952
8953       --  Why the test for In_Spec_Expression here ???
8954
8955       if Is_Packed (Slice_Subtype) and not In_Spec_Expression then
8956          Freeze_Itype (Slice_Subtype, N);
8957       end if;
8958
8959    end Set_Slice_Subtype;
8960
8961    --------------------------------
8962    -- Set_String_Literal_Subtype --
8963    --------------------------------
8964
8965    procedure Set_String_Literal_Subtype (N : Node_Id; Typ : Entity_Id) is
8966       Loc        : constant Source_Ptr := Sloc (N);
8967       Low_Bound  : constant Node_Id :=
8968                      Type_Low_Bound (Etype (First_Index (Typ)));
8969       Subtype_Id : Entity_Id;
8970
8971    begin
8972       if Nkind (N) /= N_String_Literal then
8973          return;
8974       end if;
8975
8976       Subtype_Id := Create_Itype (E_String_Literal_Subtype, N);
8977       Set_String_Literal_Length (Subtype_Id, UI_From_Int
8978                                                (String_Length (Strval (N))));
8979       Set_Etype          (Subtype_Id, Base_Type (Typ));
8980       Set_Is_Constrained (Subtype_Id);
8981       Set_Etype          (N, Subtype_Id);
8982
8983       if Is_OK_Static_Expression (Low_Bound) then
8984
8985       --  The low bound is set from the low bound of the corresponding
8986       --  index type. Note that we do not store the high bound in the
8987       --  string literal subtype, but it can be deduced if necessary
8988       --  from the length and the low bound.
8989
8990          Set_String_Literal_Low_Bound (Subtype_Id, Low_Bound);
8991
8992       else
8993          Set_String_Literal_Low_Bound
8994            (Subtype_Id, Make_Integer_Literal (Loc, 1));
8995          Set_Etype (String_Literal_Low_Bound (Subtype_Id), Standard_Positive);
8996
8997          --  Build bona fide subtype for the string, and wrap it in an
8998          --  unchecked conversion, because the backend expects the
8999          --  String_Literal_Subtype to have a static lower bound.
9000
9001          declare
9002             Index_List    : constant List_Id    := New_List;
9003             Index_Type    : constant Entity_Id := Etype (First_Index (Typ));
9004             High_Bound    : constant Node_Id :=
9005                                Make_Op_Add (Loc,
9006                                   Left_Opnd => New_Copy_Tree (Low_Bound),
9007                                   Right_Opnd =>
9008                                     Make_Integer_Literal (Loc,
9009                                       String_Length (Strval (N)) - 1));
9010             Array_Subtype : Entity_Id;
9011             Index_Subtype : Entity_Id;
9012             Drange        : Node_Id;
9013             Index         : Node_Id;
9014
9015          begin
9016             Index_Subtype :=
9017               Create_Itype (Subtype_Kind (Ekind (Index_Type)), N);
9018             Drange := Make_Range (Loc, New_Copy_Tree (Low_Bound), High_Bound);
9019             Set_Scalar_Range (Index_Subtype, Drange);
9020             Set_Parent (Drange, N);
9021             Analyze_And_Resolve (Drange, Index_Type);
9022
9023             --  In the context, the Index_Type may already have a constraint,
9024             --  so use common base type on string subtype. The base type may
9025             --  be used when generating attributes of the string, for example
9026             --  in the context of a slice assignment.
9027
9028             Set_Etype        (Index_Subtype, Base_Type (Index_Type));
9029             Set_Size_Info    (Index_Subtype, Index_Type);
9030             Set_RM_Size      (Index_Subtype, RM_Size (Index_Type));
9031
9032             Array_Subtype := Create_Itype (E_Array_Subtype, N);
9033
9034             Index := New_Occurrence_Of (Index_Subtype, Loc);
9035             Set_Etype (Index, Index_Subtype);
9036             Append (Index, Index_List);
9037
9038             Set_First_Index    (Array_Subtype, Index);
9039             Set_Etype          (Array_Subtype, Base_Type (Typ));
9040             Set_Is_Constrained (Array_Subtype, True);
9041
9042             Rewrite (N,
9043               Make_Unchecked_Type_Conversion (Loc,
9044                 Subtype_Mark => New_Occurrence_Of (Array_Subtype, Loc),
9045                 Expression => Relocate_Node (N)));
9046             Set_Etype (N, Array_Subtype);
9047          end;
9048       end if;
9049    end Set_String_Literal_Subtype;
9050
9051    ------------------------------
9052    -- Simplify_Type_Conversion --
9053    ------------------------------
9054
9055    procedure Simplify_Type_Conversion (N : Node_Id) is
9056    begin
9057       if Nkind (N) = N_Type_Conversion then
9058          declare
9059             Operand    : constant Node_Id   := Expression (N);
9060             Target_Typ : constant Entity_Id := Etype (N);
9061             Opnd_Typ   : constant Entity_Id := Etype (Operand);
9062
9063          begin
9064             if Is_Floating_Point_Type (Opnd_Typ)
9065               and then
9066                 (Is_Integer_Type (Target_Typ)
9067                    or else (Is_Fixed_Point_Type (Target_Typ)
9068                               and then Conversion_OK (N)))
9069               and then Nkind (Operand) = N_Attribute_Reference
9070               and then Attribute_Name (Operand) = Name_Truncation
9071
9072             --  Special processing required if the conversion is the expression
9073             --  of a Truncation attribute reference. In this case we replace:
9074
9075             --     ityp (ftyp'Truncation (x))
9076
9077             --  by
9078
9079             --     ityp (x)
9080
9081             --  with the Float_Truncate flag set, which is more efficient
9082
9083             then
9084                Rewrite (Operand,
9085                  Relocate_Node (First (Expressions (Operand))));
9086                Set_Float_Truncate (N, True);
9087             end if;
9088          end;
9089       end if;
9090    end Simplify_Type_Conversion;
9091
9092    -----------------------------
9093    -- Unique_Fixed_Point_Type --
9094    -----------------------------
9095
9096    function Unique_Fixed_Point_Type (N : Node_Id) return Entity_Id is
9097       T1   : Entity_Id := Empty;
9098       T2   : Entity_Id;
9099       Item : Node_Id;
9100       Scop : Entity_Id;
9101
9102       procedure Fixed_Point_Error;
9103       --  Give error messages for true ambiguity. Messages are posted on node
9104       --  N, and entities T1, T2 are the possible interpretations.
9105
9106       -----------------------
9107       -- Fixed_Point_Error --
9108       -----------------------
9109
9110       procedure Fixed_Point_Error is
9111       begin
9112          Error_Msg_N ("ambiguous universal_fixed_expression", N);
9113          Error_Msg_NE ("\\possible interpretation as}", N, T1);
9114          Error_Msg_NE ("\\possible interpretation as}", N, T2);
9115       end Fixed_Point_Error;
9116
9117    --  Start of processing for Unique_Fixed_Point_Type
9118
9119    begin
9120       --  The operations on Duration are visible, so Duration is always a
9121       --  possible interpretation.
9122
9123       T1 := Standard_Duration;
9124
9125       --  Look for fixed-point types in enclosing scopes
9126
9127       Scop := Current_Scope;
9128       while Scop /= Standard_Standard loop
9129          T2 := First_Entity (Scop);
9130          while Present (T2) loop
9131             if Is_Fixed_Point_Type (T2)
9132               and then Current_Entity (T2) = T2
9133               and then Scope (Base_Type (T2)) = Scop
9134             then
9135                if Present (T1) then
9136                   Fixed_Point_Error;
9137                   return Any_Type;
9138                else
9139                   T1 := T2;
9140                end if;
9141             end if;
9142
9143             Next_Entity (T2);
9144          end loop;
9145
9146          Scop := Scope (Scop);
9147       end loop;
9148
9149       --  Look for visible fixed type declarations in the context
9150
9151       Item := First (Context_Items (Cunit (Current_Sem_Unit)));
9152       while Present (Item) loop
9153          if Nkind (Item) = N_With_Clause then
9154             Scop := Entity (Name (Item));
9155             T2 := First_Entity (Scop);
9156             while Present (T2) loop
9157                if Is_Fixed_Point_Type (T2)
9158                  and then Scope (Base_Type (T2)) = Scop
9159                  and then (Is_Potentially_Use_Visible (T2)
9160                              or else In_Use (T2))
9161                then
9162                   if Present (T1) then
9163                      Fixed_Point_Error;
9164                      return Any_Type;
9165                   else
9166                      T1 := T2;
9167                   end if;
9168                end if;
9169
9170                Next_Entity (T2);
9171             end loop;
9172          end if;
9173
9174          Next (Item);
9175       end loop;
9176
9177       if Nkind (N) = N_Real_Literal then
9178          Error_Msg_NE ("?real literal interpreted as }!", N, T1);
9179       else
9180          Error_Msg_NE ("?universal_fixed expression interpreted as }!", N, T1);
9181       end if;
9182
9183       return T1;
9184    end Unique_Fixed_Point_Type;
9185
9186    ----------------------
9187    -- Valid_Conversion --
9188    ----------------------
9189
9190    function Valid_Conversion
9191      (N       : Node_Id;
9192       Target  : Entity_Id;
9193       Operand : Node_Id) return Boolean
9194    is
9195       Target_Type : constant Entity_Id := Base_Type (Target);
9196       Opnd_Type   : Entity_Id := Etype (Operand);
9197
9198       function Conversion_Check
9199         (Valid : Boolean;
9200          Msg   : String) return Boolean;
9201       --  Little routine to post Msg if Valid is False, returns Valid value
9202
9203       function Valid_Tagged_Conversion
9204         (Target_Type : Entity_Id;
9205          Opnd_Type   : Entity_Id) return Boolean;
9206       --  Specifically test for validity of tagged conversions
9207
9208       function Valid_Array_Conversion return Boolean;
9209       --  Check index and component conformance, and accessibility levels
9210       --  if the component types are anonymous access types (Ada 2005)
9211
9212       ----------------------
9213       -- Conversion_Check --
9214       ----------------------
9215
9216       function Conversion_Check
9217         (Valid : Boolean;
9218          Msg   : String) return Boolean
9219       is
9220       begin
9221          if not Valid then
9222             Error_Msg_N (Msg, Operand);
9223          end if;
9224
9225          return Valid;
9226       end Conversion_Check;
9227
9228       ----------------------------
9229       -- Valid_Array_Conversion --
9230       ----------------------------
9231
9232       function Valid_Array_Conversion return Boolean
9233       is
9234          Opnd_Comp_Type : constant Entity_Id := Component_Type (Opnd_Type);
9235          Opnd_Comp_Base : constant Entity_Id := Base_Type (Opnd_Comp_Type);
9236
9237          Opnd_Index      : Node_Id;
9238          Opnd_Index_Type : Entity_Id;
9239
9240          Target_Comp_Type : constant Entity_Id :=
9241                               Component_Type (Target_Type);
9242          Target_Comp_Base : constant Entity_Id :=
9243                               Base_Type (Target_Comp_Type);
9244
9245          Target_Index      : Node_Id;
9246          Target_Index_Type : Entity_Id;
9247
9248       begin
9249          --  Error if wrong number of dimensions
9250
9251          if
9252            Number_Dimensions (Target_Type) /= Number_Dimensions (Opnd_Type)
9253          then
9254             Error_Msg_N
9255               ("incompatible number of dimensions for conversion", Operand);
9256             return False;
9257
9258          --  Number of dimensions matches
9259
9260          else
9261             --  Loop through indexes of the two arrays
9262
9263             Target_Index := First_Index (Target_Type);
9264             Opnd_Index   := First_Index (Opnd_Type);
9265             while Present (Target_Index) and then Present (Opnd_Index) loop
9266                Target_Index_Type := Etype (Target_Index);
9267                Opnd_Index_Type   := Etype (Opnd_Index);
9268
9269                --  Error if index types are incompatible
9270
9271                if not (Is_Integer_Type (Target_Index_Type)
9272                        and then Is_Integer_Type (Opnd_Index_Type))
9273                  and then (Root_Type (Target_Index_Type)
9274                            /= Root_Type (Opnd_Index_Type))
9275                then
9276                   Error_Msg_N
9277                     ("incompatible index types for array conversion",
9278                      Operand);
9279                   return False;
9280                end if;
9281
9282                Next_Index (Target_Index);
9283                Next_Index (Opnd_Index);
9284             end loop;
9285
9286             --  If component types have same base type, all set
9287
9288             if Target_Comp_Base  = Opnd_Comp_Base then
9289                null;
9290
9291                --  Here if base types of components are not the same. The only
9292                --  time this is allowed is if we have anonymous access types.
9293
9294                --  The conversion of arrays of anonymous access types can lead
9295                --  to dangling pointers. AI-392 formalizes the accessibility
9296                --  checks that must be applied to such conversions to prevent
9297                --  out-of-scope references.
9298
9299             elsif
9300               (Ekind (Target_Comp_Base) = E_Anonymous_Access_Type
9301                  or else
9302                Ekind (Target_Comp_Base) = E_Anonymous_Access_Subprogram_Type)
9303               and then Ekind (Opnd_Comp_Base) = Ekind (Target_Comp_Base)
9304               and then
9305                 Subtypes_Statically_Match (Target_Comp_Type, Opnd_Comp_Type)
9306             then
9307                if Type_Access_Level (Target_Type) <
9308                    Type_Access_Level (Opnd_Type)
9309                then
9310                   if In_Instance_Body then
9311                      Error_Msg_N ("?source array type " &
9312                        "has deeper accessibility level than target", Operand);
9313                      Error_Msg_N ("\?Program_Error will be raised at run time",
9314                          Operand);
9315                      Rewrite (N,
9316                        Make_Raise_Program_Error (Sloc (N),
9317                          Reason => PE_Accessibility_Check_Failed));
9318                      Set_Etype (N, Target_Type);
9319                      return False;
9320
9321                   --  Conversion not allowed because of accessibility levels
9322
9323                   else
9324                      Error_Msg_N ("source array type " &
9325                        "has deeper accessibility level than target", Operand);
9326                      return False;
9327                   end if;
9328                else
9329                   null;
9330                end if;
9331
9332             --  All other cases where component base types do not match
9333
9334             else
9335                Error_Msg_N
9336                  ("incompatible component types for array conversion",
9337                   Operand);
9338                return False;
9339             end if;
9340
9341             --  Check that component subtypes statically match. For numeric
9342             --  types this means that both must be either constrained or
9343             --  unconstrained. For enumeration types the bounds must match.
9344             --  All of this is checked in Subtypes_Statically_Match.
9345
9346             if not Subtypes_Statically_Match
9347                             (Target_Comp_Type, Opnd_Comp_Type)
9348             then
9349                Error_Msg_N
9350                  ("component subtypes must statically match", Operand);
9351                return False;
9352             end if;
9353          end if;
9354
9355          return True;
9356       end Valid_Array_Conversion;
9357
9358       -----------------------------
9359       -- Valid_Tagged_Conversion --
9360       -----------------------------
9361
9362       function Valid_Tagged_Conversion
9363         (Target_Type : Entity_Id;
9364          Opnd_Type   : Entity_Id) return Boolean
9365       is
9366       begin
9367          --  Upward conversions are allowed (RM 4.6(22))
9368
9369          if Covers (Target_Type, Opnd_Type)
9370            or else Is_Ancestor (Target_Type, Opnd_Type)
9371          then
9372             return True;
9373
9374          --  Downward conversion are allowed if the operand is class-wide
9375          --  (RM 4.6(23)).
9376
9377          elsif Is_Class_Wide_Type (Opnd_Type)
9378            and then Covers (Opnd_Type, Target_Type)
9379          then
9380             return True;
9381
9382          elsif Covers (Opnd_Type, Target_Type)
9383            or else Is_Ancestor (Opnd_Type, Target_Type)
9384          then
9385             return
9386               Conversion_Check (False,
9387                 "downward conversion of tagged objects not allowed");
9388
9389          --  Ada 2005 (AI-251): The conversion to/from interface types is
9390          --  always valid
9391
9392          elsif Is_Interface (Target_Type) or else Is_Interface (Opnd_Type) then
9393             return True;
9394
9395          --  If the operand is a class-wide type obtained through a limited_
9396          --  with clause, and the context includes the non-limited view, use
9397          --  it to determine whether the conversion is legal.
9398
9399          elsif Is_Class_Wide_Type (Opnd_Type)
9400            and then From_With_Type (Opnd_Type)
9401            and then Present (Non_Limited_View (Etype (Opnd_Type)))
9402            and then Is_Interface (Non_Limited_View (Etype (Opnd_Type)))
9403          then
9404             return True;
9405
9406          elsif Is_Access_Type (Opnd_Type)
9407            and then Is_Interface (Directly_Designated_Type (Opnd_Type))
9408          then
9409             return True;
9410
9411          else
9412             Error_Msg_NE
9413               ("invalid tagged conversion, not compatible with}",
9414                N, First_Subtype (Opnd_Type));
9415             return False;
9416          end if;
9417       end Valid_Tagged_Conversion;
9418
9419    --  Start of processing for Valid_Conversion
9420
9421    begin
9422       Check_Parameterless_Call (Operand);
9423
9424       if Is_Overloaded (Operand) then
9425          declare
9426             I   : Interp_Index;
9427             I1  : Interp_Index;
9428             It  : Interp;
9429             It1 : Interp;
9430             N1  : Entity_Id;
9431
9432          begin
9433             --  Remove procedure calls, which syntactically cannot appear in
9434             --  this context, but which cannot be removed by type checking,
9435             --  because the context does not impose a type.
9436
9437             --  When compiling for VMS, spurious ambiguities can be produced
9438             --  when arithmetic operations have a literal operand and return
9439             --  System.Address or a descendant of it. These ambiguities are
9440             --  otherwise resolved by the context, but for conversions there
9441             --  is no context type and the removal of the spurious operations
9442             --  must be done explicitly here.
9443
9444             --  The node may be labelled overloaded, but still contain only
9445             --  one interpretation because others were discarded in previous
9446             --  filters. If this is the case, retain the single interpretation
9447             --  if legal.
9448
9449             Get_First_Interp (Operand, I, It);
9450             Opnd_Type := It.Typ;
9451             Get_Next_Interp (I, It);
9452
9453             if Present (It.Typ)
9454               and then Opnd_Type /= Standard_Void_Type
9455             then
9456                --  More than one candidate interpretation is available
9457
9458                Get_First_Interp (Operand, I, It);
9459                while Present (It.Typ) loop
9460                   if It.Typ = Standard_Void_Type then
9461                      Remove_Interp (I);
9462                   end if;
9463
9464                   if Present (System_Aux_Id)
9465                     and then Is_Descendent_Of_Address (It.Typ)
9466                   then
9467                      Remove_Interp (I);
9468                   end if;
9469
9470                   Get_Next_Interp (I, It);
9471                end loop;
9472             end if;
9473
9474             Get_First_Interp (Operand, I, It);
9475             I1  := I;
9476             It1 := It;
9477
9478             if No (It.Typ) then
9479                Error_Msg_N ("illegal operand in conversion", Operand);
9480                return False;
9481             end if;
9482
9483             Get_Next_Interp (I, It);
9484
9485             if Present (It.Typ) then
9486                N1  := It1.Nam;
9487                It1 :=  Disambiguate (Operand, I1, I, Any_Type);
9488
9489                if It1 = No_Interp then
9490                   Error_Msg_N ("ambiguous operand in conversion", Operand);
9491
9492                   Error_Msg_Sloc := Sloc (It.Nam);
9493                   Error_Msg_N -- CODEFIX
9494                     ("\\possible interpretation#!", Operand);
9495
9496                   Error_Msg_Sloc := Sloc (N1);
9497                   Error_Msg_N -- CODEFIX
9498                     ("\\possible interpretation#!", Operand);
9499
9500                   return False;
9501                end if;
9502             end if;
9503
9504             Set_Etype (Operand, It1.Typ);
9505             Opnd_Type := It1.Typ;
9506          end;
9507       end if;
9508
9509       --  Numeric types
9510
9511       if Is_Numeric_Type (Target_Type)  then
9512
9513          --  A universal fixed expression can be converted to any numeric type
9514
9515          if Opnd_Type = Universal_Fixed then
9516             return True;
9517
9518          --  Also no need to check when in an instance or inlined body, because
9519          --  the legality has been established when the template was analyzed.
9520          --  Furthermore, numeric conversions may occur where only a private
9521          --  view of the operand type is visible at the instantiation point.
9522          --  This results in a spurious error if we check that the operand type
9523          --  is a numeric type.
9524
9525          --  Note: in a previous version of this unit, the following tests were
9526          --  applied only for generated code (Comes_From_Source set to False),
9527          --  but in fact the test is required for source code as well, since
9528          --  this situation can arise in source code.
9529
9530          elsif In_Instance or else In_Inlined_Body then
9531                return True;
9532
9533          --  Otherwise we need the conversion check
9534
9535          else
9536             return Conversion_Check
9537                     (Is_Numeric_Type (Opnd_Type),
9538                      "illegal operand for numeric conversion");
9539          end if;
9540
9541       --  Array types
9542
9543       elsif Is_Array_Type (Target_Type) then
9544          if not Is_Array_Type (Opnd_Type)
9545            or else Opnd_Type = Any_Composite
9546            or else Opnd_Type = Any_String
9547          then
9548             Error_Msg_N
9549               ("illegal operand for array conversion", Operand);
9550             return False;
9551          else
9552             return Valid_Array_Conversion;
9553          end if;
9554
9555       --  Ada 2005 (AI-251): Anonymous access types where target references an
9556       --  interface type.
9557
9558       elsif (Ekind (Target_Type) = E_General_Access_Type
9559               or else
9560              Ekind (Target_Type) = E_Anonymous_Access_Type)
9561         and then Is_Interface (Directly_Designated_Type (Target_Type))
9562       then
9563          --  Check the static accessibility rule of 4.6(17). Note that the
9564          --  check is not enforced when within an instance body, since the
9565          --  RM requires such cases to be caught at run time.
9566
9567          if Ekind (Target_Type) /= E_Anonymous_Access_Type then
9568             if Type_Access_Level (Opnd_Type) >
9569                Type_Access_Level (Target_Type)
9570             then
9571                --  In an instance, this is a run-time check, but one we know
9572                --  will fail, so generate an appropriate warning. The raise
9573                --  will be generated by Expand_N_Type_Conversion.
9574
9575                if In_Instance_Body then
9576                   Error_Msg_N
9577                     ("?cannot convert local pointer to non-local access type",
9578                      Operand);
9579                   Error_Msg_N
9580                     ("\?Program_Error will be raised at run time", Operand);
9581                else
9582                   Error_Msg_N
9583                     ("cannot convert local pointer to non-local access type",
9584                      Operand);
9585                   return False;
9586                end if;
9587
9588             --  Special accessibility checks are needed in the case of access
9589             --  discriminants declared for a limited type.
9590
9591             elsif Ekind (Opnd_Type) = E_Anonymous_Access_Type
9592               and then not Is_Local_Anonymous_Access (Opnd_Type)
9593             then
9594                --  When the operand is a selected access discriminant the check
9595                --  needs to be made against the level of the object denoted by
9596                --  the prefix of the selected name (Object_Access_Level handles
9597                --  checking the prefix of the operand for this case).
9598
9599                if Nkind (Operand) = N_Selected_Component
9600                  and then Object_Access_Level (Operand) >
9601                           Type_Access_Level (Target_Type)
9602                then
9603                   --  In an instance, this is a run-time check, but one we know
9604                   --  will fail, so generate an appropriate warning. The raise
9605                   --  will be generated by Expand_N_Type_Conversion.
9606
9607                   if In_Instance_Body then
9608                      Error_Msg_N
9609                        ("?cannot convert access discriminant to non-local" &
9610                         " access type", Operand);
9611                      Error_Msg_N
9612                        ("\?Program_Error will be raised at run time", Operand);
9613                   else
9614                      Error_Msg_N
9615                        ("cannot convert access discriminant to non-local" &
9616                         " access type", Operand);
9617                      return False;
9618                   end if;
9619                end if;
9620
9621                --  The case of a reference to an access discriminant from
9622                --  within a limited type declaration (which will appear as
9623                --  a discriminal) is always illegal because the level of the
9624                --  discriminant is considered to be deeper than any (nameable)
9625                --  access type.
9626
9627                if Is_Entity_Name (Operand)
9628                  and then not Is_Local_Anonymous_Access (Opnd_Type)
9629                  and then (Ekind (Entity (Operand)) = E_In_Parameter
9630                             or else Ekind (Entity (Operand)) = E_Constant)
9631                  and then Present (Discriminal_Link (Entity (Operand)))
9632                then
9633                   Error_Msg_N
9634                     ("discriminant has deeper accessibility level than target",
9635                      Operand);
9636                   return False;
9637                end if;
9638             end if;
9639          end if;
9640
9641          return True;
9642
9643       --  General and anonymous access types
9644
9645       elsif (Ekind (Target_Type) = E_General_Access_Type
9646         or else Ekind (Target_Type) = E_Anonymous_Access_Type)
9647           and then
9648             Conversion_Check
9649               (Is_Access_Type (Opnd_Type)
9650                  and then Ekind (Opnd_Type) /=
9651                    E_Access_Subprogram_Type
9652                  and then Ekind (Opnd_Type) /=
9653                    E_Access_Protected_Subprogram_Type,
9654                "must be an access-to-object type")
9655       then
9656          if Is_Access_Constant (Opnd_Type)
9657            and then not Is_Access_Constant (Target_Type)
9658          then
9659             Error_Msg_N
9660               ("access-to-constant operand type not allowed", Operand);
9661             return False;
9662          end if;
9663
9664          --  Check the static accessibility rule of 4.6(17). Note that the
9665          --  check is not enforced when within an instance body, since the RM
9666          --  requires such cases to be caught at run time.
9667
9668          if Ekind (Target_Type) /= E_Anonymous_Access_Type
9669            or else Is_Local_Anonymous_Access (Target_Type)
9670          then
9671             if Type_Access_Level (Opnd_Type)
9672               > Type_Access_Level (Target_Type)
9673             then
9674                --  In an instance, this is a run-time check, but one we know
9675                --  will fail, so generate an appropriate warning. The raise
9676                --  will be generated by Expand_N_Type_Conversion.
9677
9678                if In_Instance_Body then
9679                   Error_Msg_N
9680                     ("?cannot convert local pointer to non-local access type",
9681                      Operand);
9682                   Error_Msg_N
9683                     ("\?Program_Error will be raised at run time", Operand);
9684
9685                else
9686                   --  Avoid generation of spurious error message
9687
9688                   if not Error_Posted (N) then
9689                      Error_Msg_N
9690                       ("cannot convert local pointer to non-local access type",
9691                        Operand);
9692                   end if;
9693
9694                   return False;
9695                end if;
9696
9697             --  Special accessibility checks are needed in the case of access
9698             --  discriminants declared for a limited type.
9699
9700             elsif Ekind (Opnd_Type) = E_Anonymous_Access_Type
9701               and then not Is_Local_Anonymous_Access (Opnd_Type)
9702             then
9703
9704                --  When the operand is a selected access discriminant the check
9705                --  needs to be made against the level of the object denoted by
9706                --  the prefix of the selected name (Object_Access_Level handles
9707                --  checking the prefix of the operand for this case).
9708
9709                if Nkind (Operand) = N_Selected_Component
9710                  and then Object_Access_Level (Operand) >
9711                           Type_Access_Level (Target_Type)
9712                then
9713                   --  In an instance, this is a run-time check, but one we know
9714                   --  will fail, so generate an appropriate warning. The raise
9715                   --  will be generated by Expand_N_Type_Conversion.
9716
9717                   if In_Instance_Body then
9718                      Error_Msg_N
9719                        ("?cannot convert access discriminant to non-local" &
9720                         " access type", Operand);
9721                      Error_Msg_N
9722                        ("\?Program_Error will be raised at run time",
9723                         Operand);
9724
9725                   else
9726                      Error_Msg_N
9727                        ("cannot convert access discriminant to non-local" &
9728                         " access type", Operand);
9729                      return False;
9730                   end if;
9731                end if;
9732
9733                --  The case of a reference to an access discriminant from
9734                --  within a limited type declaration (which will appear as
9735                --  a discriminal) is always illegal because the level of the
9736                --  discriminant is considered to be deeper than any (nameable)
9737                --  access type.
9738
9739                if Is_Entity_Name (Operand)
9740                  and then (Ekind (Entity (Operand)) = E_In_Parameter
9741                             or else Ekind (Entity (Operand)) = E_Constant)
9742                  and then Present (Discriminal_Link (Entity (Operand)))
9743                then
9744                   Error_Msg_N
9745                     ("discriminant has deeper accessibility level than target",
9746                      Operand);
9747                   return False;
9748                end if;
9749             end if;
9750          end if;
9751
9752          --  In the presence of limited_with clauses we have to use non-limited
9753          --  views, if available.
9754
9755          Check_Limited : declare
9756             function Full_Designated_Type (T : Entity_Id) return Entity_Id;
9757             --  Helper function to handle limited views
9758
9759             --------------------------
9760             -- Full_Designated_Type --
9761             --------------------------
9762
9763             function Full_Designated_Type (T : Entity_Id) return Entity_Id is
9764                Desig : constant Entity_Id := Designated_Type (T);
9765
9766             begin
9767                --  Handle the limited view of a type
9768
9769                if Is_Incomplete_Type (Desig)
9770                  and then From_With_Type (Desig)
9771                  and then Present (Non_Limited_View (Desig))
9772                then
9773                   return Available_View (Desig);
9774                else
9775                   return Desig;
9776                end if;
9777             end Full_Designated_Type;
9778
9779             --  Local Declarations
9780
9781             Target : constant Entity_Id := Full_Designated_Type (Target_Type);
9782             Opnd   : constant Entity_Id := Full_Designated_Type (Opnd_Type);
9783
9784             Same_Base : constant Boolean :=
9785                           Base_Type (Target) = Base_Type (Opnd);
9786
9787          --  Start of processing for Check_Limited
9788
9789          begin
9790             if Is_Tagged_Type (Target) then
9791                return Valid_Tagged_Conversion (Target, Opnd);
9792
9793             else
9794                if not Same_Base then
9795                   Error_Msg_NE
9796                     ("target designated type not compatible with }",
9797                      N, Base_Type (Opnd));
9798                   return False;
9799
9800                --  Ada 2005 AI-384: legality rule is symmetric in both
9801                --  designated types. The conversion is legal (with possible
9802                --  constraint check) if either designated type is
9803                --  unconstrained.
9804
9805                elsif Subtypes_Statically_Match (Target, Opnd)
9806                  or else
9807                    (Has_Discriminants (Target)
9808                      and then
9809                       (not Is_Constrained (Opnd)
9810                         or else not Is_Constrained (Target)))
9811                then
9812                   --  Special case, if Value_Size has been used to make the
9813                   --  sizes different, the conversion is not allowed even
9814                   --  though the subtypes statically match.
9815
9816                   if Known_Static_RM_Size (Target)
9817                     and then Known_Static_RM_Size (Opnd)
9818                     and then RM_Size (Target) /= RM_Size (Opnd)
9819                   then
9820                      Error_Msg_NE
9821                        ("target designated subtype not compatible with }",
9822                         N, Opnd);
9823                      Error_Msg_NE
9824                        ("\because sizes of the two designated subtypes differ",
9825                         N, Opnd);
9826                      return False;
9827
9828                   --  Normal case where conversion is allowed
9829
9830                   else
9831                      return True;
9832                   end if;
9833
9834                else
9835                   Error_Msg_NE
9836                     ("target designated subtype not compatible with }",
9837                      N, Opnd);
9838                   return False;
9839                end if;
9840             end if;
9841          end Check_Limited;
9842
9843       --  Access to subprogram types. If the operand is an access parameter,
9844       --  the type has a deeper accessibility that any master, and cannot
9845       --  be assigned. We must make an exception if the conversion is part
9846       --  of an assignment and the target is the return object of an extended
9847       --  return statement, because in that case the accessibility check
9848       --  takes place after the return.
9849
9850       elsif Is_Access_Subprogram_Type (Target_Type)
9851         and then No (Corresponding_Remote_Type (Opnd_Type))
9852       then
9853          if Ekind (Base_Type (Opnd_Type)) = E_Anonymous_Access_Subprogram_Type
9854            and then Is_Entity_Name (Operand)
9855            and then Ekind (Entity (Operand)) = E_In_Parameter
9856            and then
9857              (Nkind (Parent (N)) /= N_Assignment_Statement
9858                or else not Is_Entity_Name (Name (Parent (N)))
9859                or else not Is_Return_Object (Entity (Name (Parent (N)))))
9860          then
9861             Error_Msg_N
9862               ("illegal attempt to store anonymous access to subprogram",
9863                Operand);
9864             Error_Msg_N
9865               ("\value has deeper accessibility than any master " &
9866                "(RM 3.10.2 (13))",
9867                Operand);
9868
9869             Error_Msg_NE
9870              ("\use named access type for& instead of access parameter",
9871                Operand, Entity (Operand));
9872          end if;
9873
9874          --  Check that the designated types are subtype conformant
9875
9876          Check_Subtype_Conformant (New_Id  => Designated_Type (Target_Type),
9877                                    Old_Id  => Designated_Type (Opnd_Type),
9878                                    Err_Loc => N);
9879
9880          --  Check the static accessibility rule of 4.6(20)
9881
9882          if Type_Access_Level (Opnd_Type) >
9883             Type_Access_Level (Target_Type)
9884          then
9885             Error_Msg_N
9886               ("operand type has deeper accessibility level than target",
9887                Operand);
9888
9889          --  Check that if the operand type is declared in a generic body,
9890          --  then the target type must be declared within that same body
9891          --  (enforces last sentence of 4.6(20)).
9892
9893          elsif Present (Enclosing_Generic_Body (Opnd_Type)) then
9894             declare
9895                O_Gen : constant Node_Id :=
9896                          Enclosing_Generic_Body (Opnd_Type);
9897
9898                T_Gen : Node_Id;
9899
9900             begin
9901                T_Gen := Enclosing_Generic_Body (Target_Type);
9902                while Present (T_Gen) and then T_Gen /= O_Gen loop
9903                   T_Gen := Enclosing_Generic_Body (T_Gen);
9904                end loop;
9905
9906                if T_Gen /= O_Gen then
9907                   Error_Msg_N
9908                     ("target type must be declared in same generic body"
9909                      & " as operand type", N);
9910                end if;
9911             end;
9912          end if;
9913
9914          return True;
9915
9916       --  Remote subprogram access types
9917
9918       elsif Is_Remote_Access_To_Subprogram_Type (Target_Type)
9919         and then Is_Remote_Access_To_Subprogram_Type (Opnd_Type)
9920       then
9921          --  It is valid to convert from one RAS type to another provided
9922          --  that their specification statically match.
9923
9924          Check_Subtype_Conformant
9925            (New_Id  =>
9926               Designated_Type (Corresponding_Remote_Type (Target_Type)),
9927             Old_Id  =>
9928               Designated_Type (Corresponding_Remote_Type (Opnd_Type)),
9929             Err_Loc =>
9930               N);
9931          return True;
9932
9933       --  If both are tagged types, check legality of view conversions
9934
9935       elsif Is_Tagged_Type (Target_Type)
9936         and then Is_Tagged_Type (Opnd_Type)
9937       then
9938          return Valid_Tagged_Conversion (Target_Type, Opnd_Type);
9939
9940       --  Types derived from the same root type are convertible
9941
9942       elsif Root_Type (Target_Type) = Root_Type (Opnd_Type) then
9943          return True;
9944
9945       --  In an instance or an inlined body, there may be inconsistent
9946       --  views of the same type, or of types derived from a common root.
9947
9948       elsif (In_Instance or In_Inlined_Body)
9949         and then
9950           Root_Type (Underlying_Type (Target_Type)) =
9951           Root_Type (Underlying_Type (Opnd_Type))
9952       then
9953          return True;
9954
9955       --  Special check for common access type error case
9956
9957       elsif Ekind (Target_Type) = E_Access_Type
9958          and then Is_Access_Type (Opnd_Type)
9959       then
9960          Error_Msg_N ("target type must be general access type!", N);
9961          Error_Msg_NE ("add ALL to }!", N, Target_Type);
9962          return False;
9963
9964       else
9965          Error_Msg_NE ("invalid conversion, not compatible with }",
9966            N, Opnd_Type);
9967          return False;
9968       end if;
9969    end Valid_Conversion;
9970
9971 end Sem_Res;